configure.in

   1 dnl Define our own header notice with own copyright
   2 define([AC_INIT_NOTICE],
   3 [#### Configuration script for XEmacs.  Largely divergent from FSF.
   4 #### Guess values for system-dependent variables and create Makefiles.
   5 #### Generated automatically using autoconf version] AC_ACVERSION [
   6 #### Copyright (C) 1992, 93, 94, 95, 96 Free Software Foundation, Inc.
   7 #### Copyright (C) 1993-1995 Board of Trustees, University of Illinois.
   8 #### Copyright (C) 1996, 1997 Sun Microsystems, Inc.
   9 #### Copyright (C) 1995, 1996 Ben Wing.
  10 #### Copyright (C) 1998, 1999 J. Kean Johnston.
  11
  12 ### Don't edit this script!
  13 ### This script was automatically generated by the `autoconf' program
  14 ### from the file `./configure.in'.
  15 ### To rebuild it, execute the command
  16 ###     autoconf
  17 ### in the this directory.  You must have autoconf version 2.13 or later.
  18
  19 ### This file is part of XEmacs.
  20
  21 ### XEmacs is free software; you can redistribute it and/or modify it
  22 ### under the terms of the GNU General Public License as published by
  23 ### the Free Software Foundation; either version 2, or (at your
  24 ### option) any later version.
  25
  26 ### XEmacs is distributed in the hope that it will be useful, but
  27 ### WITHOUT ANY WARRANTY; without even the implied warranty of
  28 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  29 ### General Public License for more details.
  30
  31 ### You should have received a copy of the GNU General Public License
  32 ### along with XEmacs; see the file COPYING.  If not, write to the Free
  33 ### Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  34 ### 02111-1307, USA.
  35
  36 ### For usage, run `./configure --help'
  37 ### For more detailed information on building and installing XEmacs,
  38 ### read the file `INSTALL'.
  39 ###
  40 ### If configure succeeds, it leaves its status in config.status.
  41 ### A log of configuration tests can be found in config.log.
  42 ### If configure fails after disturbing the status quo,
  43 ###     config.status is removed.
  44 ])
  45
  46 dnl Since XEmacs has configuration requirements that autoconf cannot
  47 dnl meet, this file is an unholy marriage of custom-baked
  48 dnl configuration code and autoconf macros.
  49
  50 dnl We use the m4 quoting characters [ ] (as established by the
  51 dnl autoconf system), so quote them like this: [[foo]]
  52
  53 AC_PREREQ(2.13)dnl
  54 dnl Redefine some standard autoconf macros
  55 dnl here is how XEmacs is different:
  56 dnl - no cache file
  57 dnl - non-standard options
  58 dnl - suport for extra-verbosity
  59 dnl - ordinary libs are handled separately from X libs (might be a mistake)
  60 dnl - various random kludges (e.g. -with-dnet=no
  61
  62 dnl PRINT_VAR(var var ...)  prints values of shell variables
  63 define([PRINT_VAR],[for var in patsubst([$1],[[
  64 ]+],[ ]); do eval "echo \"$var = '\$$var'\""; done])
  65
  66 dnl Disable cache files:
  67 dnl This is controversial, but I am convinced this is the right way to go,
  68 dnl at least by default.  Otherwise there are too many surprises.
  69 define([AC_CACHE_LOAD], )dnl
  70 define([AC_CACHE_SAVE], )dnl
  71 define([AC_CACHE_VAL], [
  72 $2
  73 ])dnl
  74
  75 dnl Redefine AC_TRY_RUN_NATIVE to not throw away stderr while running
  76 dnl AC_TRY_RUN_NATIVE(PROGRAM, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
  77 define([AC_TRY_RUN_NATIVE],
  78 [cat > conftest.$ac_ext <<EOF
  79 [#]line __oline__ "configure"
  80 #include "confdefs.h"
  81 [$1]
  82 EOF
  83 if AC_TRY_EVAL(ac_link) && test -s conftest && (./conftest; exit $?) 2>&AC_FD_CC
  84 then
  85 dnl Do not remove the temporary files here, so they can be examined.
  86   ifelse([$2], , :, [$2])
  87 else
  88   conftest_rc="$?"
  89   echo "configure: failed program was:" >&AC_FD_CC
  90   cat conftest.$ac_ext >&AC_FD_CC
  91 ifelse([$3], , , [  rm -fr conftest*
  92   $3
  93 ])dnl
  94 fi
  95 rm -fr conftest*])dnl AC_TRY_RUN_NATIVE
  96
  97
  98 dnl Avoid spurious cross-compiling warnings from AC_TRY_RUN
  99 dnl XEmacs is unlikely to ever cross-compile
 100 define([AC_TRY_RUN],[AC_TRY_RUN_NATIVE([$1], [$2], [$3])])dnl
 101
 102 dnl Redefine AC_DEFINE* to provide more output if extra_verbose
 103 dnl Set VARIABLE to VALUE, verbatim, or 1.
 104 dnl AC_DEFINE(VARIABLE [, VALUE])
 105 define([AC_DEFINE],
 106 [{ test "$extra_verbose" = "yes" && cat << \EOF
 107     Defining $1[]ifelse($#, 2, [ = $2],)
 108 EOF
 109 cat >> confdefs.h <<\EOF
 110 [#define] $1 ifelse($#, 2, [$2], 1)
 111 EOF
 112 }
 113 ])dnl AC_DEFINE
 114
 115 define([AC_DEFINE_UNQUOTED],
 116 [{ test "$extra_verbose" = "yes" && cat << EOF
 117     Defining $1[]ifelse($#, 2, [ = $2],)
 118 EOF
 119 cat >> confdefs.h <<EOF
 120 [#define] $1 ifelse($#, 2, [$2], 1)
 121 EOF
 122 }
 123 ])dnl AC_DEFINE_UNQUOTED
 124
 125 dnl redefine AC_CHECK_LIB in accordance with our own value of ac_link
 126 dnl Add in extra kludgy check to support with_dnet=no
 127 dnl Add in extra LDFLAGS arg, which PRECEDE libs
 128 dnl Support --with-dnet=no
 129
 130 dnl AC_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
 131 dnl             [, OTHER-LIBRARIES] [, LDFLAGS]]]])
 132 define([AC_CHECK_LIB],
 133 [ifelse([$1],dnet, [if test "$with_dnet" = "no" ; then
 134 ac_cv_lib_dnet_dnet_ntoa=no
 135 ifelse([$4], , , [$4]
 136 )dnl
 137 else
 138 ])]
 139 AC_CHECK_LIB_ORIG_HACKED([$1],[$2],[$3],[$4],[$5], [$6])
 140 [ifelse([$1],dnet,[fi
 141 ])]dnl
 142 )dnl AC_CHECK_LIB
 143
 144 define([AC_CHECK_LIB_ORIG_HACKED],
 145 [ifelse([$5],,AC_MSG_CHECKING([for $2 in -l$1]),
 146 xe_msg_checking="for [$2] in -l[$1]"
 147 test -n "[$5]" && xe_msg_checking="$xe_msg_checking using extra libs [$5]"
 148 AC_MSG_CHECKING("$xe_msg_checking"))
 149 dnl Use a cache variable name containing both the library and function name,
 150 dnl because the test really is for library $1 defining function $2, not
 151 dnl just for library $1.  Separate tests with the same $1 and different $2s
 152 dnl may have different results.
 153 ac_lib_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
 154 AC_CACHE_VAL(ac_cv_lib_$ac_lib_var,
 155 [xe_check_libs="$6 -l$1 $5"
 156 AC_TRY_LINK(dnl
 157 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 158 [/* Override any gcc2 internal prototype to avoid an error.  */
 159 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 160 extern "C"
 161 #endif
 162 ])dnl
 163 [/* We use char because int might match the return type of a gcc2
 164     builtin and then its argument prototype would still apply.  */
 165 char $2();
 166 ]),
 167             [$2()],
 168             eval "ac_cv_lib_$ac_lib_var=yes",
 169             eval "ac_cv_lib_$ac_lib_var=no")
 170 xe_check_libs=""
 171 ])dnl
 172 if eval "test \"`echo '$ac_cv_lib_'$ac_lib_var`\" = yes" ; then
 173   AC_MSG_RESULT(yes)
 174   ifelse([$3], ,
 175 [changequote(, )dnl
 176   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 177     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 178 changequote([, ])dnl
 179   AC_DEFINE_UNQUOTED($ac_tr_lib)
 180   XE_PREPEND([-l$1], LIBS)
 181 ], [$3])
 182 else
 183   AC_MSG_RESULT(no)
 184 ifelse([$4], , , [$4
 185 ])dnl
 186 fi
 187 ])dnl AC_CHECK_LIB_ORIG_HACKED
 188
 189
 190 dnl AC_LANG_C()
 191 define([AC_LANG_C],
 192 [define([AC_LANG], [C])dnl
 193 ac_ext=c
 194 dnl CFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
 195 dnl ac_cpp='$CPP $CPPFLAGS'
 196 dnl ac_compile='${CC-cc} -c $CFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC'
 197 dnl ac_link='${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC'
 198 xe_cppflags='$CPPFLAGS $c_switch_site $c_switch_machine $c_switch_system $c_switch_x_site $X_CFLAGS'
 199 xe_ldflags='$LDFLAGS $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_x_site $ld_switch_run'
 200 xe_libs='$ld_call_shared $xe_check_libs $X_EXTRA_LIBS $libs_x $X_PRE_LIBS $LIBS $libs_machine $libs_system $libs_standard'
 201 ac_cpp='$CPP '"$xe_cppflags"
 202 ac_compile='${CC-cc} -c $CFLAGS '"$xe_cppflags"' conftest.$ac_ext 1>&AC_FD_CC'
 203 ac_link='${CC-cc} -o conftest $CFLAGS '"$xe_cppflags $xe_ldflags"' conftest.$ac_ext '"$xe_libs"' 1>&AC_FD_CC'
 204 cross_compiling=no
 205 ]) dnl AC_LANG_C
 206
 207 dnl The construct foo=`echo $w1 $w2 $w3` fails on some systems if $w1 = -e or -n
 208 dnl So we use the following instead.
 209 dnl XE_SPACE(var, words)
 210 define([XE_SPACE],[
 211 T=""
 212 for W in $2; do if test -z "$T"; then T="$W"; else T="$T $W"; fi; done
 213 $1="$T"
 214 ])dnl XE_SPACE
 215
 216 dnl XE_ADD_OBJS(foo.o ...)
 217 define([XE_ADD_OBJS],
 218 [extra_objs="$extra_objs [$1]" && dnl
 219  if test "$extra_verbose" = "yes"; then
 220    echo "    xemacs will be linked with \"[$1]\""
 221  fi])dnl XE_ADD_OBJS
 222
 223 dnl XE_APPEND(value, varname)
 224 define([XE_APPEND],
 225 [[$2]="$[$2] [$1]" && dnl
 226  if test "$extra_verbose" = "yes"; then echo "    Appending \"[$1]\" to \$[$2]"; fi])
 227
 228 dnl XE_PREPEND(value, varname)
 229 define([XE_PREPEND],
 230 [[$2]="[$1] $[$2]" && dnl
 231  if test "$extra_verbose" = "yes"; then echo "    Prepending \"[$1]\" to \$[$2]"; fi])
 232
 233 dnl XE_DIE(message)
 234 define([XE_DIE], [{ echo "Error:" $1 >&2; exit 1; }])
 235
 236 dnl XE_STRIP_4TH_COMPONENT(var)
 237 dnl Changes i986-pc-linux-gnu to i986-pc-linux, as God (not RMS) intended.
 238 define([XE_STRIP_4TH_COMPONENT],
 239 [$1=`echo "$$1" | sed '[s/^\([^-][^-]*-[^-][^-]*-[^-][^-]*\)-.*$/\1/]'`])
 240
 241 dnl Initialize some variables set by options.
 242 dnl The variables have the same names as the options, with
 243 dnl dashes changed to underlines.
 244
 245 define([AC_INIT_PARSE_ARGS],[
 246
 247 dnl Get sane consistent behavior from various shells
 248 dnl Avoid losing with weird user CDPATHs
 249
 250 if test -n "$ZSH_VERSION"; then
 251   dnl zsh's Bourne shell emulation options
 252   setopt NO_BAD_PATTERN NO_BANG_HIST NO_BG_NICE NO_EQUALS NO_FUNCTION_ARGZERO
 253   setopt GLOB_SUBST NO_HUP INTERACTIVE_COMMENTS KSH_ARRAYS NO_MULTIOS NO_NOMATCH
 254   setopt RM_STAR_SILENT POSIX_BUILTINS SH_FILE_EXPANSION SH_GLOB SH_OPTION_LETTERS
 255   setopt SH_WORD_SPLIT BSD_ECHO IGNORE_BRACES
 256   dnl zsh-3.1-beta drops core on the following
 257   dnl unset CDPATH
 258   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 259 elif test -n "$BASH_VERSION"; then
 260   dnl Use Posix mode with bash
 261   set -o posix
 262   unset CDPATH
 263 else
 264   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 265 fi
 266
 267 dnl Initialize some variables set by options.
 268 dnl The variables have the same names as the options, with
 269 dnl dashes changed to underlines.
 270 exec_prefix=NONE
 271 host=NONE
 272 no_create=
 273 nonopt=NONE
 274 no_recursion=
 275 prefix=NONE
 276 program_prefix=NONE
 277 program_suffix=NONE
 278 program_transform_name=s,x,x,
 279 silent=
 280 site=
 281 srcdir=
 282 target=NONE
 283 verbose=
 284 x_includes=NONE
 285 x_libraries=NONE
 286
 287 dnl Installation directory options.
 288 dnl These are left unexpanded so users can "make install exec_prefix=/foo"
 289 dnl and all the variables that are supposed to be based on exec_prefix
 290 dnl by default will actually change.
 291 dnl Use braces instead of parens because sh, perl, etc. also accept them.
 292 dnl If you change these, you need to synchronize with the settings of the
 293 dnl various ..._USER_DEFINED variables further down.
 294 bindir='${exec_prefix}/bin'
 295 sbindir='${exec_prefix}/sbin'
 296 libexecdir='${exec_prefix}/libexec'
 297 datadir='${prefix}/share'
 298 sysconfdir='${prefix}/etc'
 299 sharedstatedir='${prefix}/com'
 300 localstatedir='${prefix}/var'
 301 libdir='${{exec_prefix}}/lib'
 302 includedir='${prefix}/include'
 303 oldincludedir='/usr/include'
 304 infodir='${prefix}/info'
 305 mandir='${prefix}/man'
 306
 307 dnl Initialize some other variables.
 308 subdirs=
 309 MFLAGS= MAKEFLAGS=
 310 SHELL=${CONFIG_SHELL-/bin/sh}
 311 dnl Maximum number of lines to put in a shell here document.
 312 ac_max_here_lines=12
 313 ])dnl AC_INIT_PARSE_ARGS
 314
 315 AC_INIT(src/lisp.h)dnl
 316 AC_CONFIG_HEADER(src/config.h lwlib/config.h)
 317 dnl Remove any more than one leading "." element from the path name.
 318 dnl If we do not remove them, then another "./" will be prepended to
 319 dnl the file name each time we use config.status, and the program name
 320 dnl will get larger and larger.  This would not be a problem, except
 321 dnl that since progname gets recorded in all the Makefiles this script
 322 dnl produces, move-if-change thinks they're different when they're
 323 dnl not.
 324 dnl
 325 dnl It would be nice if we could put the ./ in a \( \) group and then
 326 dnl apply the * operator to that, so we remove as many leading './././'s
 327 dnl as are present, but some seds (like Ultrix's sed) don't allow you to
 328 dnl apply * to a \( \) group.  Bleah.
 329 progname="`echo $0 | sed 's:^\./\./:\./:'`"
 330
 331 dnl -----------------------------
 332 dnl Establish some default values
 333 dnl -----------------------------
 334
 335 XE_APPEND(lib-src, MAKE_SUBDIR)
 336 XE_APPEND(lib-src, INSTALL_ARCH_DEP_SUBDIR)
 337
 338 prefix='/usr/local'
 339 exec_prefix='${prefix}'
 340 bindir='${exec_prefix}/bin'
 341 dnl FSF 19.29 changes to:
 342 dnl datadir='${prefix}/share'
 343 dnl sharedstatedir='${prefix}/com'
 344 dnl libexecdir='${exec_prefix}/libexec'
 345 datadir='${prefix}/lib'
 346 statedir='${prefix}/lib'
 347 libdir='${exec_prefix}/lib'
 348 mandir='${prefix}/man/man1'
 349 inststaticdir='${PROGNAME}'
 350 instvardir='${PROGNAME}-${version}'
 351 infodir='${datadir}/${instvardir}/info'
 352 infopath=''
 353 install_pp=''
 354 lispdir='${datadir}/${instvardir}/lisp'
 355 moduledir='${datadir}/${instvardir}/${configuration}/modules'
 356 sitelispdir='${datadir}/${inststaticdir}/site-lisp'
 357 sitemoduledir='${datadir}/${inststaticdir}/site-modules'
 358 pkgdir='${datadir}/${instvardir}/lisp'
 359 package_path=''
 360 etcdir='${datadir}/${instvardir}/etc'
 361 archlibdir='${datadir}/${instvardir}/${configuration}'
 362 docdir='${archlibdir}'
 363 with_prefix='yes'
 364 with_site_lisp='no'
 365 with_site_modules='yes'
 366 with_menubars=''
 367 with_scrollbars=''
 368 with_widgets=''
 369 with_dialogs=''
 370 with_file_coding=''
 371 cpp='' cppflags='' libs='' ldflags=''
 372 dynamic=''
 373 with_x11=''
 374 with_msw=''
 375 rel_alloc='default'
 376 with_system_malloc='default'
 377 with_dlmalloc='default'
 378 native_sound_lib=''
 379 dnl use_assertions should be 'yes' by default.  Too many people in this
 380 dnl world have core dumps turned off by default or \"cannot find where the
 381 dnl core file went\".  At least we should get some useful output ...
 382 use_assertions="yes"
 383 dnl the following is set to yes or no later.
 384 with_toolbars=""
 385 with_tty=""
 386 use_union_type="no"
 387 with_dnet=""
 388 pdump="no"
 389 dnl dragndrop is still experimental.  When it is stable, comment out the following line:
 390 with_dragndrop="no"
 391
 392 dnl ------------------
 393 dnl Options Processing
 394 dnl ------------------
 395
 396 define([USAGE_ERROR],
 397 [(echo "$progname: Usage error:"
 398 echo " " $1
 399 echo "  Use \`$progname --help' to show usage.") >&2 && exit 1])
 400
 401 dnl Record all the arguments, so we can save them in config.status.
 402 arguments="$@"
 403
 404 dnl Shell Magic: Quote the quoted arguments in ARGUMENTS.  At a later date,
 405 dnl in order to get the arguments back in $@, we have to do an
 406 dnl 'eval set x "$quoted_arguments"; shift'
 407 dnl # We use sed to turn embedded ' into '"'"'.  I truly hate sh quoting.
 408 quoted_sed_magic=s/"'"/"'"'"'"'"'"'"'"/g
 409 quoted_arguments=
 410 for i in "$@"; do
 411    case "$i" in
 412    -no-create | --no-create | --no-creat | --no-crea | --no-cre \
 413    | --no-cr | --no-c) ;;
 414    -no-recursion | --no-recursion | --no-recursio | --no-recursi \
 415    | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;
 416    *)
 417    quoted_i="`echo '' $i | sed -e 's:^ ::' -e $quoted_sed_magic`"
 418    quoted_arguments="$quoted_arguments '$quoted_i'" ;;
 419    esac
 420 done
 421
 422 dnl Do not use shift -- that destroys the argument list, which autoconf needs
 423 dnl to produce config.status.  It turns out that "set - $arguments" does not
 424 dnl work portably.
 425 dnl However, it also turns out that many shells cannot expand ${10} at all.
 426 dnl So using an index variable does not work either.  It is possible to use
 427 dnl some shell magic to make 'set x "$arguments"; shift' work portably.
 428 while test $# != 0; do
 429   arg="$1"; shift
 430   case "$arg" in
 431     --no-create|--no-recursion) ;;
 432     dnl Anything starting with a hyphen we assume is an option.
 433     -* )
 434       dnl Separate the switch name from the value it is being given.
 435       case "$arg" in
 436         -*=*)
 437           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\([[^=]]*\)=.*$:\1:'`
 438           val=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*[[^=]]*=\(.*\)$:\1:'`
 439           valomitted=no
 440         ;;
 441            dnl special case these strings since echo may silently eat them:
 442            dnl --help ) opt=help val=yes valomitted=yes ;;
 443            dnl --version ) opt=version val=yes valomitted=yes ;;
 444            dnl -e ) opt=e val=yes valomitted=yes ;;
 445            dnl -E ) opt=E val=yes valomitted=yes ;;
 446            dnl -n ) opt=n val=yes valomitted=yes ;;
 447         -*)
 448            dnl If FOO is a boolean argument, --FOO is equivalent to
 449            dnl --FOO=yes.  Otherwise, the value comes from the next
 450            dnl argument - see below.
 451           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\(.*\)$:\1:'`
 452           val="yes" valomitted=yes
 453         ;;
 454       esac
 455
 456       dnl translate "-" in option string to "_"
 457       optname="$opt"
 458       opt="`echo '' $opt | sed -e 's:^ ::' | tr - _`"
 459
 460       dnl Support --without-FOO as a synonym for --with-FOO=no
 461       case "${valomitted}-${opt}" in yes-without_* )
 462         opt=`echo $opt | sed 's/without/with/'`
 463         valomitted="no" val="no" ;;
 464       esac
 465
 466       dnl Process the option.
 467       case "$opt" in
 468
 469       dnl Process (many) boolean options
 470         with_site_lisp  | \
 471         with_prefix     | \
 472         with_site_modules | \
 473         with_x          | \
 474         with_x11        | \
 475         with_msw        | \
 476         with_gcc        | \
 477         dynamic         | \
 478         with_ncurses    | \
 479         with_dnet       | \
 480         with_socks      | \
 481         with_dragndrop  | \
 482         with_cde        | \
 483         with_offix      | \
 484         with_gpm        | \
 485         with_xpm        | \
 486         with_xface      | \
 487         with_gif        | \
 488         with_jpeg       | \
 489         with_png        | \
 490         with_tiff       | \
 491         with_wmcommand  | \
 492         with_xmu        | \
 493         with_purify     | \
 494         with_quantify   | \
 495         with_toolbars   | \
 496         with_tty        | \
 497         with_xfs        | \
 498         with_i18n3      | \
 499         with_mule       | \
 500         with_utf_2000   | \
 501         with_text_coding| \
 502         with_file_coding| \
 503         with_canna      | \
 504         with_wnn        | \
 505         with_wnn6       | \
 506         with_workshop   | \
 507         with_sparcworks | \
 508         with_tooltalk   | \
 509         with_ldap       | \
 510         with_postgresql | \
 511         with_pop        | \
 512         with_kerberos   | \
 513         with_hesiod     | \
 514         with_dnet       | \
 515         with_infodock   | \
 516         external_widget | \
 517         verbose         | \
 518         extra_verbose   | \
 519         usage_tracking  | \
 520         use_union_type  | \
 521         pdump           | \
 522         debug           | \
 523         use_assertions  | \
 524         memory_usage_stats | \
 525         with_clash_detection | \
 526         with_modules | \
 527         quick_build )
 528           dnl Make sure the value given was either "yes" or "no".
 529           case "$val" in
 530             y | ye | yes )      val=yes ;;
 531             n | no )            val=no  ;;
 532             * ) USAGE_ERROR("The \`--$optname' option requires a boolean value: \`yes' or \`no'.") ;;
 533           esac
 534           eval "$opt=\"$val\"" ;;
 535
 536
 537         dnl Options that take a user-supplied value, as in --x-includes=/usr/X11R6/include
 538         dnl The cache-file option is ignored (for compatibility with other configures)
 539         srcdir          | \
 540         compiler        | \
 541         cflags          | \
 542         cpp             | \
 543         cppflags        | \
 544         libs            | \
 545         ldflags         | \
 546         cache_file      | \
 547         native_sound_lib| \
 548         site_lisp       | \
 549         x_includes      | \
 550         x_libraries     | \
 551         site_includes   | \
 552         site_libraries  | \
 553         site_prefixes   | \
 554         site_runtime_libraries )
 555           dnl If the value was omitted, get it from the next argument.
 556           if test "$valomitted" = "yes" ; then
 557             dnl Get the next argument from the argument list, if there is one.
 558             if test "$#" = 0 ; then
 559               USAGE_ERROR("The \`--$optname' option requires a value.");
 560             fi
 561             val="$1"; shift
 562           fi
 563           eval "$opt=\"$val\""
 564         ;;
 565
 566         dnl Options that take "yes", "no", or "default" values
 567         rel_alloc | \
 568         with_dlmalloc | \
 569         with_debug_malloc  | use_debug_malloc | \
 570         with_system_malloc | use_system_malloc )
 571           case "$val" in
 572             y | ye | yes )      val=yes ;;
 573             n | no )            val=no  ;;
 574             d | de | def | defa | defau | defaul | default ) val=default ;;
 575             * ) USAGE_ERROR(["The \`--$optname' option requires one of these values:
 576   \`yes', \`no', or \`default'."]) ;;
 577           esac
 578           case "$opt" in use_* ) opt="`echo $opt | sed s/use/with/`" ;; esac
 579           eval "$opt=\"$val\""
 580         ;;
 581
 582         dnl Has the user requested database support?
 583         "with_database" )
 584           with_database_berkdb=no
 585           with_database_dbm=no
 586           with_database_gdbm=no
 587           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 588             case "$x" in
 589               no ) ;;
 590               b | be | ber | berk | berkd | berkdb )       with_database_berkdb=yes ;;
 591               d | db | dbm )                               with_database_dbm=yes    ;;
 592               g | gn | gnu | gnud | gnudb | gnudbm | gdbm) with_database_gdbm=yes   ;;
 593               * ) USAGE_ERROR(["The \`--$optname' option value
 594   must be either \`no' or a comma-separated list
 595   of one or more of \`berkdb' and either \`dbm' or \`gnudbm'."]) ;;
 596             esac
 597           done
 598           if test "$with_database_dbm"  = "yes" -a \
 599                   "$with_database_gdbm" = "yes"; then
 600           USAGE_ERROR("Only one of \`dbm' and \`gnudbm' may be specified
 601   with the \`--$optname' option.")
 602           fi
 603         ;;
 604
 605         dnl Has the user requested sound support?
 606         "with_sound" )
 607         dnl values is a subset of all,native,nas,esd
 608         dnl or their negatives: none,nonative,nonas,noesd
 609           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 610             case "$x" in
 611               dnl all and none are only permitted as the first in the list.
 612               n | no | non | none ) new_sdefault=no ;;
 613               a | al | all | both ) new_sdefault=yes ;;
 614
 615               native )       with_native_sound=yes ;;
 616               nonative )     with_native_sound=no ;;
 617
 618               nas )          with_nas_sound=yes ;;
 619               nonas )        with_nas_sound=no ;;
 620
 621               esd )          with_esd_sound=yes ;;
 622               noesd )        with_esd_sound=no ;;
 623
 624               * ) bogus_sound=yes ;;
 625             esac
 626             if test "$bogus_sound" -o \
 627                  \( -n "$new_sdefault" -a -n "$sound_notfirst" \) ; then
 628                 types="\`all', \`none', \`(no)native', \`no(nas)', \`(no)esd'."
 629                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 630   $types.
 631 The default is to autodetect all sound support."])
 632             elif test -n "$new_sdefault" ; then
 633                 with_native_sound=$new_sdefault
 634                 with_nas_sound=$new_sdefault
 635                 with_esd_sound=$new_sdefault
 636                 new_sdefault=   # reset this
 637             fi
 638             sound_notfirst=true
 639           done
 640         ;;
 641
 642         dnl Has the user specified a prefered Athena widget set?
 643         dnl This bit expands any alias names out for us...
 644         "with_athena" )
 645           case "$val" in
 646             xa | xaw )                    val=xaw    ;;
 647             3 | 3d | xaw3d )              val=3d     ;;
 648             dnl No `n' for next, someone may try `no'
 649             ne | nex | next | naxtaw)     val=next   ;;
 650             dnl Have not tested the next two...
 651             9 | 95 | xaw95 )              val=95     ;;
 652             xp | xpm | xawxpm )           val=xpm    ;;
 653             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 654   \`xaw', \`3d', \`next', \`95', or \`xpm'."]) ;;
 655           esac
 656           eval "$opt=\"$val\""
 657         ;;
 658
 659         dnl Has the user requested XIM support?
 660         "with_xim" )
 661           case "$val" in
 662             y | ye | yes )                val=yes   ;;
 663             n | no | non | none )         val=no    ;;
 664             x | xl | xli | xlib )         val=xlib  ;;
 665             m | mo | mot | moti | motif ) val=motif ;;
 666             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 667   \`motif', \`xlib', \`yes', or \`no'."]) ;;
 668           esac
 669           eval "$opt=\"$val\""
 670         ;;
 671
 672         dnl Mail locking specification
 673         "mail_locking" )
 674           case "$val" in
 675             lockf )     val=lockf ;;
 676             flock )     val=flock ;;
 677             file | dot ) val=file  ;;
 678             locking )   val=locking  ;;
 679             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 680   \`lockf', \`flock', \`file', \`locking', or \`mmdf'."]) ;;
 681           esac
 682           eval "$opt=\"$val\""
 683         ;;
 684
 685         dnl Has the user requested error-checking?
 686         "error_checking" )
 687           dnl value can be all, none, and/or a list of categories to check.
 688           dnl Example: --error-checking=all,noextents,nobufpos
 689           dnl Example: --error-checking=none,malloc,gc
 690
 691           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 692             case "$x" in
 693               dnl all and none are only permitted as the first in the list.
 694               n | no | non | none ) new_default=no ;;
 695               a | al | all )        new_default=yes ;;
 696
 697               extents )       error_check_extents=yes ;;
 698               noextents )     error_check_extents=no ;;
 699
 700               typecheck )     error_check_typecheck=yes ;;
 701               notypecheck )   error_check_typecheck=no ;;
 702
 703               bufpos )        error_check_bufpos=yes ;;
 704               nobufpos )      error_check_bufpos=no ;;
 705
 706               gc )            error_check_gc=yes ;;
 707               nogc )          error_check_gc=no ;;
 708
 709               malloc )        error_check_malloc=yes ;;
 710               nomalloc )      error_check_malloc=no ;;
 711
 712               byte_code )     error_check_byte_code=yes ;;
 713               nobyte_code )   error_check_byte_code=no ;;
 714
 715               glyphs )     error_check_glyphs=yes ;;
 716               noglyphs )   error_check_glyphs=no ;;
 717
 718               * ) bogus_error_check=yes ;;
 719             esac
 720             if test "$bogus_error_check" -o \
 721                  \( -n "$new_default" -a -n "$echeck_notfirst" \) ; then
 722                 if test "$error_check_default" = yes ; then
 723                   types="\`all' (default), \`none', \`noextents', \`notypecheck', \`nobufpos', \`nogc', \`nomalloc', \`noglyphs' and \`nobyte-code'."
 724                 else
 725                   types="\`all', \`none' (default), \`extents', \`typecheck', \`bufpos', \`gc', \`malloc', \`glyphs' and \`byte-code'."
 726                 fi
 727                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 728   $types."])
 729             elif test -n "$new_default" ; then
 730                 error_check_extents=$new_default
 731                 error_check_typecheck=$new_default
 732                 error_check_bufpos=$new_default
 733                 error_check_gc=$new_default
 734                 error_check_malloc=$new_default
 735                 error_check_byte_code=$new_default
 736                 error_check_glyphs=$new_default
 737                 new_default=    # reset this
 738             fi
 739             echeck_notfirst=true
 740           done
 741         ;;
 742
 743         dnl Has the user tried to tell us where the X files are?
 744         dnl I think these are dopey, but no less than three alpha
 745         dnl testers, at large sites, have said they have their X files
 746         dnl installed in odd places.
 747
 748         dnl Has the user specified one of the path options?
 749         prefix | exec_prefix | bindir | datadir | statedir | libdir | \
 750         mandir | infodir | infopath | lispdir | etcdir | pkgdir | \
 751         archlibdir | docdir | package_path )
 752            dnl If the value was omitted, get it from the next argument.
 753            if test "$valomitted" = "yes"; then
 754              if test "$#" = 0; then
 755                  USAGE_ERROR("The \`--$optname' option requires a value.");
 756              fi
 757              val="$1"; shift
 758            fi
 759            eval "$opt=\"$val\""
 760
 761            dnl You need to synchronize this with the way the
 762            dnl default values are built.
 763            case "$opt" in
 764              dnl prefix is taken care of by --with-prefix
 765              exec_prefix ) AC_DEFINE(EXEC_PREFIX_USER_DEFINED) ;;
 766              lispdir ) AC_DEFINE(LISPDIR_USER_DEFINED) ;;
 767              sitelispdir ) AC_DEFINE(SITELISPDIR_USER_DEFINED) ;;
 768              moduledir ) AC_DEFINE(MODULEDIR_USER_DEFINED) ;;
 769              etcdir  )  AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 770              infodir ) AC_DEFINE(INFODIR_USER_DEFINED) ;;
 771              infopath ) AC_DEFINE(INFOPATH_USER_DEFINED) ;;
 772              package_path ) AC_DEFINE(PACKAGE_PATH_USER_DEFINED) ;;
 773              datadir )
 774                 AC_DEFINE(INFODIR_USER_DEFINED)
 775                 AC_DEFINE(LISPDIR_USER_DEFINED)
 776             AC_DEFINE(MODULEDIR_USER_DEFINED)
 777                 AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 778              docdir ) AC_DEFINE(DOCDIR_USER_DEFINED) ;;
 779              exec_prefix | libdir | archlibdir ) AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
 780            esac
 781         ;;
 782
 783         dnl --no-create added by autoconf for use by config.status
 784         "no_create" ) ;;
 785
 786         dnl Has the user asked for some help?
 787         "usage" | "help" ) ${PAGER-more} ${srcdir}/configure.usage; exit 0 ;;
 788
 789         dnl Has the user specified the toolkit(s) to use for GUI elements?
 790         "with_menubars"   | \
 791         "with_scrollbars" | \
 792         "with_dialogs" | \
 793         "with_widgets" )
 794           case "$val" in
 795             l | lu | luc | luci | lucid )               val=lucid  ;;
 796             m | mo | mot | moti | motif )               val=motif  ;;
 797             a | at | ath | athe | athen | athena )      val=athena ;;
 798             n | no | non | none )                       val=no ;;
 799             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 800   \`lucid', \`motif', \`athena', or \`no'."]) ;;
 801           esac
 802           eval "$opt=\"$val\""
 803         ;;
 804
 805         dnl Obsolete legacy argument?  Warn, but otherwise ignore.
 806         "use_minimal_tagbits" | \
 807         "use_indexed_lrecord_implementation" | \
 808         "run_in_place"  | \
 809         "const_is_losing" | \
 810         "with_gnu_make" )
 811           AC_MSG_WARN([Obsolete option \`--$optname' ignored.])
 812         ;;
 813
 814         dnl Unrecognized option?  No mercy for user errors.
 815         * ) USAGE_ERROR("Unrecognized option: $arg") ;;
 816
 817       esac
 818     ;;
 819
 820     dnl Assume anything with multiple hyphens is a configuration name.
 821     *-*-*) configuration="$arg" ;;
 822
 823     dnl Unrecognized argument?  No mercy for user errors.
 824     *) USAGE_ERROR("Unrecognized argument: $arg") ;;
 825
 826   esac
 827 done
 828
 829 dnl -------------------------
 830 dnl Finish options processing
 831 dnl -------------------------
 832
 833 dnl Several options are equivalent to, and override, environment variables.
 834 test -n "$cpp"      && CPP="$cpp"
 835 test -n "$cppflags" && CPPFLAGS="$cppflags"
 836 test -n "$libs"     && LIBS="$libs"
 837 test -n "$ldflags"  && LDFLAGS="$ldflags"
 838
 839 dnl Get the arguments back.  See the diatribe on Shell Magic above.
 840 eval set x "$quoted_arguments"; shift
 841
 842 dnl --extra-verbose implies --verbose
 843 test "$extra_verbose" = "yes" && verbose=yes
 844
 845 dnl with_x is an obsolete synonym for with_x11
 846 test -n "$with_x" && with_x11="$with_x"
 847
 848 dnl --with-quantify or --with-purify imply --use-system-malloc
 849 if test "$with_purify" = "yes" -o "$with_quantify" = "yes"; then
 850   test "$with_system_malloc" = "default" && with_system_malloc=yes
 851 fi
 852
 853 dnl XE_CHECK_FEATURE_DEPENDENCY(feature1, feature2)
 854 define([XE_CHECK_FEATURE_DEPENDENCY],
 855 [if test "$with_$1 $with_$2" = "yes no"; then
 856   USAGE_ERROR("--with-$1 requires --with-$2")
 857 elif test "$with_$2" = "no" ; then with_$1=no
 858 elif test "$with_$1" = "yes"; then with_$2=yes
 859 fi
 860 ])
 861
 862 dnl CDE requires tooltalk
 863 XE_CHECK_FEATURE_DEPENDENCY(cde, tooltalk)
 864
 865 dnl Find the source directory.
 866 case "$srcdir" in
 867
 868   dnl If srcdir is not specified, see if  "." or ".." might work.
 869   "" )
 870     for dir in "`echo $0 | sed 's|//|/|' | sed 's|/[[^/]]*$||'`" "." ".." ; do
 871       if test -f "$dir/src/lisp.h" -a \
 872               -f "$dir/lisp/version.el" ; then
 873         srcdir="$dir"
 874         break
 875       fi
 876     done
 877     if test -z "$srcdir" ; then
 878       USAGE_ERROR(["Neither the current directory nor its parent seem to
 879   contain the XEmacs sources.  If you do not want to build XEmacs in its
 880   source tree, you should run \`$progname' in the directory in which
 881   you wish to build XEmacs, using the \`--srcdir' option to say where the
 882   sources may be found."])
 883     fi
 884   ;;
 885
 886   dnl Otherwise, check if the directory they specified is okay.
 887   * )
 888     if test ! -f "$srcdir/src/lisp.h" -o \
 889             ! -f "$srcdir/lisp/version.el" ; then
 890       USAGE_ERROR(["The directory specified with the \`--srcdir' option,
 891   \`$srcdir', doesn't seem to contain the XEmacs sources.  You should
 892   either run the \`$progname' script at the top of the XEmacs source
 893   tree, or use the \`--srcdir' option to specify the XEmacs source directory."])
 894     fi
 895   ;;
 896 esac
 897
 898 dnl ###########################################################################
 899 if test -z "$configuration"; then
 900   dnl Guess the configuration
 901   configuration=`${CONFIG_SHELL-/bin/sh} $srcdir/config.guess`
 902   if test -z "$configuration"; then
 903     USAGE_ERROR(["XEmacs has not been ported to this host type.
 904 Try explicitly specifying the CONFIGURATION when rerunning configure."])
 905   fi
 906 fi
 907
 908 AC_PROG_LN_S
 909
 910 dnl Make symlinks for etc, lisp, and info directories while the path
 911 dnl is still relative.  We do not symlink lock because someone may
 912 dnl have stuck the source on a read-only partition.  Instead we
 913 dnl create it as an actual directory later on if it does not already
 914 dnl exist.
 915 for dir in lisp etc man info tests; do
 916   if test ! -d "$dir" ; then
 917     echo Making symbolic link to "$srcdir/$dir"
 918     ${LN_S} "$srcdir/$dir" "$dir"
 919   fi
 920 done
 921
 922 dnl Do our best to deal with automounter brokenness
 923 dnl CANONICALIZE_PATH(varname)
 924 define([CANONICALIZE_PATH],
 925 [if test -d "/net"; then
 926   if test -d "/tmp_mnt/net"; then tdir="tmp_mnt/net"; else tdir="tmp_mnt"; fi
 927   $1=`echo "[$]$1" | \
 928    sed -e "s|^${tdir}/|/net/|" -e "s|^/a/|/net/|" -e "s|^/amd/|/net/|"`
 929 fi])dnl
 930
 931 dnl Calculate canonical name for blddir (i.e. current directory).
 932 dnl PWD may already be the preferable absolute name for ".",
 933 dnl but we can't trust it - it is sometimes inaccurate.
 934 absolute_pwd="`pwd`";
 935 if test -n "$PWD" -a "`cd $PWD && pwd`" = "$absolute_pwd"
 936 then blddir="$PWD"
 937 else blddir="$absolute_pwd"; CANONICALIZE_PATH(blddir)
 938 fi
 939 AC_SUBST(blddir)
 940
 941 dnl Make srcdir absolute, if not already.  It is important to
 942 dnl avoid running the path through pwd unnecessary, since pwd can
 943 dnl give you automounter prefixes, which can go away.
 944 case "$srcdir" in
 945   /* ) ;;
 946   .  ) srcdir="$blddir" ;;
 947   *  ) srcdir="`cd $srcdir && pwd`"; CANONICALIZE_PATH(srcdir) ;;
 948 esac
 949
 950 dnl Check if the source directory already has a configured system in it.
 951 if test `pwd` != `sh -c cd $srcdir && pwd`  \
 952    && test -f "$srcdir/src/config.h"; then
 953   (echo "$progname: WARNING: The directory tree \`$srcdir' is being used"
 954    echo "   as a build directory right now; it has been configured in its own"
 955    echo "   right.  To configure in another directory as well, you MUST"
 956    echo "   use GNU make.  If you do not have GNU make, then you must"
 957    echo "   now do \`make distclean' in $srcdir,"
 958    echo "   and then run $progname again.") >&2
 959   extrasub='/^VPATH[[    ]]*=/c\
 960 vpath %.c $(srcdir)\
 961 vpath %.h $(srcdir)\
 962 vpath %.y $(srcdir)\
 963 vpath %.l $(srcdir)\
 964 vpath %.s $(srcdir)\
 965 vpath %.in $(srcdir)'
 966 fi
 967
 968 dnl ----------------------------------------
 969 dnl Find out which version of XEmacs this is
 970 dnl ----------------------------------------
 971 . "$srcdir/version.sh" || exit 1;
 972 dnl Must do the following first to determine verbosity for AC_DEFINE
 973 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
 974 : "${extra_verbose=$beta}"
 975 version="${emacs_major_version}.${emacs_minor_version}"
 976 AC_DEFINE_UNQUOTED(EMACS_MAJOR_VERSION, $emacs_major_version)
 977 AC_DEFINE_UNQUOTED(EMACS_MINOR_VERSION, $emacs_minor_version)
 978 if test -n "$emacs_beta_version" ; then
 979   if test "$beta" = "yes"; then
 980         version="${version}-b${emacs_beta_version}"
 981         AC_DEFINE_UNQUOTED(EMACS_BETA_VERSION, $emacs_beta_version)
 982   else
 983         version="${version}.${emacs_beta_version}"
 984         AC_DEFINE_UNQUOTED(EMACS_PATCH_LEVEL, $emacs_beta_version)
 985   fi
 986 fi
 987 AC_DEFINE_UNQUOTED(XEMACS_CODENAME, "$xemacs_codename")
 988 AC_DEFINE_UNQUOTED(EMACS_VERSION, "$version")
 989
 990 if test "$with_infodock" = "yes"; then
 991   if test ! -f ../../ID-INSTALL; then
 992     echo "Cannot build InfoDock without InfoDock sources"
 993     with_infodock=no
 994   fi
 995 fi
 996
 997 if test "$with_infodock" = "yes"; then
 998   dnl InfoDock version numbers.  XEmacs will use the same style of numbering
 999   dnl after the release of XEmacs 21.0.
1000   AC_DEFINE_UNQUOTED(INFODOCK_MAJOR_VERSION, $infodock_major_version)
1001   AC_DEFINE_UNQUOTED(INFODOCK_MINOR_VERSION, $infodock_minor_version)
1002   AC_DEFINE_UNQUOTED(INFODOCK_BUILD_VERSION, $infodock_build_version)
1003   version=${infodock_major_version}.${infodock_minor_version}.${infodock_build_version}
1004   PROGNAME=infodock
1005   CPPFLAGS="$CPPFLAGS -DINFODOCK"
1006 else
1007   PROGNAME=xemacs
1008 fi
1009
1010 AC_DEFINE_UNQUOTED(EMACS_PROGNAME, "$PROGNAME")
1011
1012 dnl ----------------------------------
1013 dnl Error checking and debugging flags
1014 dnl ----------------------------------
1015 dnl Error checking default to "yes" in beta versions, to "no" in releases.
1016 dnl Same goes for --debug and --extra-verbosity.
1017 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
1018 test "${error_check_extents=$beta}"   = yes && AC_DEFINE(ERROR_CHECK_EXTENTS)
1019 test "${error_check_typecheck=$beta}" = yes && AC_DEFINE(ERROR_CHECK_TYPECHECK)
1020 test "${error_check_bufpos=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_BUFPOS)
1021 test "${error_check_gc=$beta}"        = yes && AC_DEFINE(ERROR_CHECK_GC)
1022 test "${error_check_malloc=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_MALLOC)
1023 test "${error_check_byte_code=$beta}" = yes && AC_DEFINE(ERROR_CHECK_BYTE_CODE)
1024 test "${error_check_glyphs=$beta}" = yes && AC_DEFINE(ERROR_CHECK_GLYPHS)
1025 dnl debug=yes must be set when error checking is present.  This should be
1026 dnl fixed up.
1027 dnl debug implies other options
1028 if test "${debug:=$beta}" = "yes"; then
1029   use_assertions=yes memory_usage_stats=yes
1030   XE_ADD_OBJS(debug.o)
1031   XE_ADD_OBJS(tests.o)
1032   AC_DEFINE(DEBUG_XEMACS)
1033 fi
1034 test "$use_assertions"     = "yes" && AC_DEFINE(USE_ASSERTIONS)
1035 test "$memory_usage_stats" = "yes" && AC_DEFINE(MEMORY_USAGE_STATS)
1036
1037 dnl ------------------------------
1038 dnl Determine the s&m files to use
1039 dnl ------------------------------
1040 dnl Given the configuration name, set machfile and opsysfile to the
1041 dnl names of the m/*.h and s/*.h files we should use.
1042
1043 dnl Canonicalize the configuration name.
1044 AC_MSG_CHECKING("host system type")
1045 dnl allow -workshop suffix on configuration name
1046 internal_configuration=`echo $configuration | sed 's/-\(workshop\)//'`
1047 canonical=`${CONFIG_SHELL-/bin/sh} $srcdir/config.sub "$internal_configuration"`
1048 XE_STRIP_4TH_COMPONENT(configuration)
1049 XE_STRIP_4TH_COMPONENT(canonical)
1050 AC_MSG_RESULT($configuration)
1051
1052 dnl If you add support for a new configuration, add code to this
1053 dnl switch statement to recognize your configuration name and select
1054 dnl the appropriate operating system and machine description files.
1055
1056 dnl You would hope that you could choose an m/*.h file pretty much
1057 dnl based on the machine portion of the configuration name, and an s-
1058 dnl file based on the operating system portion.  However, it turns out
1059 dnl that each m/*.h file is pretty manufacturer-specific - for
1060 dnl example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
1061 dnl all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
1062 dnl machines.  So we basically have to have a special case for each
1063 dnl configuration name.
1064
1065 dnl As far as handling version numbers on operating systems is
1066 dnl concerned, make sure things will fail in a fixable way.  If
1067 dnl /etc/MACHINES says nothing about version numbers, be
1068 dnl prepared to handle anything reasonably.  If version numbers
1069 dnl matter, be sure /etc/MACHINES says something about it.
1070
1071 dnl Eric Raymond says we should accept strings like "sysvr4" to mean
1072 dnl "System V Release 4"; he writes, "The old convention encouraged"
1073 dnl "confusion between `system' and `release' levels'."
1074
1075 machine='' opsys=''
1076
1077 dnl Straightforward machine determination
1078 case "$canonical" in
1079   sparc-*-*        ) machine=sparc ;;
1080   alpha*-*-*       ) machine=alpha ;;
1081   vax-*-*          ) machine=vax ;;
1082   mips-dec-*       ) machine=pmax ;;
1083   mips-sgi-irix6*  ) machine=iris6d ;;
1084   mips-sgi-*       ) machine=iris4d ;;
1085   mips*-linux      ) machine=mips ;;
1086   romp-ibm-*       ) machine=ibmrt ;;
1087   rs6000-ibm-aix*  ) machine=ibmrs6000 ;;
1088   powerpc-ibm-aix* ) machine=ibmrs6000 ;;
1089   powerpc*-*       ) machine=powerpc ;;
1090   hppa-*-*         ) machine=hp800 ;;
1091   m88k-dg-*        ) machine=aviion ;;
1092   m68*-sony-*      ) machine=news ;;
1093   mips-sony-*      ) machine=news-risc ;;
1094   clipper-*        ) machine=clipper ;;
1095   arm*             ) machine=arm ;;
1096   ns32k-*          ) machine=ns32000 ;;
1097 esac
1098
1099 dnl Straightforward OS determination
1100 case "$canonical" in
1101   *-*-linux*    ) opsys=linux ;;
1102   *-*-netbsd*   ) opsys=netbsd ;;
1103   *-*-openbsd*  ) opsys=openbsd ;;
1104   *-*-nextstep* ) opsys=nextstep ;;
1105   *-*-vms       ) opsys=vms ;;
1106
1107   dnl DEC OSF
1108   *-dec-osf1.3 | *-dec-osf2* ) opsys=decosf1-3 ;;
1109   *-dec-osf1.2 | *-dec-osf1* ) opsys=decosf1-2 ;;
1110   *-dec-osf3.[[2-9]]         ) opsys=decosf3-2 ;;
1111   *-dec-osf3*                ) opsys=decosf3-1 ;;
1112   *-dec-osf4*                ) opsys=decosf4-0 ;;
1113
1114   dnl DEC Ultrix
1115   *-*-ultrix[[0-3]].* | *-*-ultrix4.0* ) opsys=bsd4-2 ;;
1116   *-*-ultrix4.[[12]]* ) opsys=bsd4-3 ;;
1117   *-*-ultrix* )         opsys=ultrix4-3 ;;
1118
1119   dnl AIX
1120   *-*-aix3.1*  ) opsys=aix3-1   ;;
1121   *-*-aix3.2.5 ) opsys=aix3-2-5 ;;
1122   *-*-aix3*    ) opsys=aix3-2   ;;
1123   *-*-aix4.0*  ) opsys=aix4     ;;
1124   *-*-aix4.1*  ) opsys=aix4-1   ;;
1125   *-*-aix4*    ) opsys=aix4-2   ;;
1126
1127   dnl Other generic OSes
1128   *-gnu* )                      opsys=gnu    ;;
1129   *-*-bsd4.[[01]] )             opsys=bsd4-1 ;;
1130   *-*-bsd4.2 )                  opsys=bsd4-2 ;;
1131   *-*-bsd4.3 )                  opsys=bsd4-3 ;;
1132   *-*-aos4.2 )                  opsys=bsd4-2 ;;
1133   *-*-aos*   )                  opsys=bsd4-3 ;;
1134   *-*-sysv0    | *-*-sysvr0 )   opsys=usg5-0 ;;
1135   *-*-sysv2    | *-*-sysvr2 )   opsys=usg5-2 ;;
1136   *-*-sysv2.2  | *-*-sysvr2.2 ) opsys=usg5-2-2 ;;
1137   *-*-sysv3*   | *-*-sysvr3* )  opsys=usg5-3 ;;
1138   *-*-sysv4.1* | *-*-sysvr4.1* )opsys=usg5-4 NON_GNU_CPP=/usr/lib/cpp ;;
1139   *-*-sysv4.[[2-9]]* | *-sysvr4.[[2-9]]* )
1140         if test -z "$NON_GNU_CPP" ; then
1141           for prog in "/usr/ccs/lib/cpp" "/lib/cpp"; do
1142             if test -f "$prog"; then NON_GNU_CPP="$prog"; break; fi
1143           done
1144         fi
1145         opsys=usg5-4-2 ;;
1146     *-sysv4* | *-sysvr4* )      opsys=usg5-4 ;;
1147     *-*-mach_bsd4.3* )          opsys=mach-bsd4-3 ;;
1148 esac
1149
1150 case "$canonical" in
1151
1152   dnl NetBSD ports
1153   *-*-netbsd* )
1154     case "$canonical" in
1155       i[[3-9]]86-*-netbsd*) machine=intel386 ;;
1156       hp300-*-netbsd* | amiga-*-netbsd* | sun3-*-netbsd* | mac68k-*-netbsd* | da30-*-netbsd* | m68k-*-netbsd* )
1157                       dnl Yes, this is somewhat bogus.
1158                       machine=hp9000s300 ;;
1159       pc532-*-netbsd* | ns32k-*-netbsd* )  machine=ns32000 ;;
1160       pmax-*-netbsd*  | mips-*-netbsd*  )  machine=pmax ;;
1161     esac
1162   ;;
1163
1164   dnl OpenBSD ports
1165   *-*-openbsd* )
1166     case "${canonical}" in
1167       i386-*-openbsd*)          machine=intel386 ;;
1168       m68k-*-openbsd*)          machine=hp9000s300 ;;
1169       mipsel-*-openbsd*)        machine=pmax ;;
1170      esac
1171    ;;
1172
1173   dnl Acorn RISCiX:
1174   arm-acorn-riscix1.1* ) machine=acorn opsys=riscix1-1 ;;
1175   arm-acorn-riscix1.2* | arm-acorn-riscix ) machine=acorn opsys=riscix1-2 ;;
1176
1177   dnl Alliant machines
1178   fx80-alliant-* ) machine=alliant4     opsys=bsd4-2 ;;
1179   i860-alliant-* ) machine=alliant-2800 opsys=bsd4-3 ;;
1180
1181   dnl Altos 3068
1182   m68*-altos-sysv* ) machine=altos opsys=usg5-2 ;;
1183
1184   dnl Amdahl UTS
1185   580-amdahl-sysv* ) machine=amdahl opsys=usg5-2-2 ;;
1186
1187   dnl Apollo, Domain/OS
1188   m68*-apollo-* ) machine=apollo opsys=bsd4-3 ;;
1189
1190   dnl AT&T 3b2, 3b5, 3b15, 3b20
1191   we32k-att-sysv* ) machine=att3b opsys=usg5-2-2 ;;
1192
1193   dnl AT&T 3b1 - The Mighty Unix PC!
1194   m68*-att-sysv* ) machine=7300 opsys=usg5-2-2 ;;
1195
1196   dnl Bull machines
1197   rs6000-bull-bosx* ) machine=ibmrs6000 opsys=aix3-2 ;; # dpx20
1198   m68*-bull-sysv3*  ) machine=dpx2      opsys=usg5-3 ;; # dpx2
1199   m68*-bull-sysv2*  ) machine=sps7      opsys=usg5-2 ;; # sps7
1200
1201   dnl CCI 5/32, 6/32 -- see "Tahoe".
1202
1203   dnl Celerity
1204   celerity-celerity-bsd* ) machine=celerity opsys=bsd4-2 ;;
1205
1206   dnl Convex
1207   *-convex-bsd* | *-convex-convexos* )
1208     machine=convex opsys=bsd4-3
1209     NON_GNU_CPP="cc -E -P"
1210   ;;
1211
1212   dnl Cubix QBx/386
1213   i[[3-9]]86-cubix-sysv* ) machine=intel386 opsys=usg5-3 ;;
1214
1215   dnl Data General AViiON Machines
1216   i586-dg-dgux*R4*   | i586-dg-dgux5.4.4* ) machine=aviion opsys=dgux5-4r4 ;;
1217   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* ) opsys=dgux5-4r3 ;;
1218   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* ) opsys=dgux5-4r2 ;;
1219   m88k-dg-dgux*                           ) opsys=dgux     ;;
1220
1221   dnl Motorola Delta machines
1222   m68k-motorola-sysv* | m68000-motorola-sysv* ) machine=delta opsys=usg5-3 ;;
1223   m88k-motorola-sysv4* )
1224     dnl jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
1225     dnl needs POSIX_SIGNALS and therefore needs usg5-4-2.
1226     dnl I hope there are not other 4.0 versions for this machine
1227     dnl which really need usg5-4 instead.
1228     machine=delta88k opsys=usg5-4-2
1229   ;;
1230   m88k-motorola-sysv* | m88k-motorola-m88kbcs* ) machine=delta88k opsys=usg5-3 ;;
1231
1232   dnl Dual machines
1233   m68*-dual-sysv*    ) machine=dual opsys=usg5-2   ;;
1234   m68*-dual-uniplus* ) machine=dual opsys=unipl5-2 ;;
1235
1236   dnl Encore machines
1237   ns16k-encore-bsd* ) machine=ns16000 opsys=umax ;;
1238
1239   dnl Gould Power Node and NP1
1240   pn-gould-bsd4.2* ) machine=gould     opsys=bsd4-2 ;;
1241   pn-gould-bsd4.3* ) machine=gould     opsys=bsd4-3 ;;
1242   np1-gould-bsd* )   machine=gould-np1 opsys=bsd4-3 ;;
1243
1244   dnl Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
1245   dnl as far as XEmacs is concerned).
1246   m88k-harris-cxux* )
1247     dnl Build needs to be different on 7.0 and later releases
1248     case "`uname -r`" in
1249        [[56]].[[0-9]] ) machine=nh4000 opsys=cxux  ;;
1250        [[7]].[[0-9]]  ) machine=nh4000 opsys=cxux7 ;;
1251     esac
1252     NON_GNU_CPP="/lib/cpp"
1253   ;;
1254   dnl Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
1255   m68k-harris-cxux* ) machine=nh3000 opsys=cxux ;;
1256   dnl Harris power pc NightHawk running Power UNIX (Series 6000)
1257   powerpc-harris-powerunix ) machine=nh6000 opsys=powerunix NON_GNU_CPP="cc -Xo -E -P" ;;
1258
1259   dnl Honeywell XPS100
1260   xps*-honeywell-sysv* ) machine=xps100 opsys=usg5-2 ;;
1261
1262   dnl HP 9000 series 200 or 300
1263   m68*-hp-bsd* ) machine=hp9000s300 opsys=bsd4-3 ;;
1264
1265   dnl HP-UX
1266   *-hp-hpux* )
1267     dnl Figure out machine and opsys orthogonally
1268     case "$canonical" in
1269       m68*  ) machine=hp9000s300 ;;
1270       hppa* ) machine=hp800      ;;
1271     esac
1272
1273     case "$canonical" in
1274       *-hp-hpux7*  )  opsys=hpux   ;;
1275       *-hp-hpux8*  )  opsys=hpux8  ;;
1276       *-hp-hpux9*  )  opsys=hpux9  ;;
1277       *-hp-hpux10* )  opsys=hpux10 ;;
1278       *-hp-hpux11* )  opsys=hpux11 ;;
1279       *            )  opsys=hpux   ;;
1280     esac
1281
1282     dnl HP has a broken "strcat"
1283     case "$opsys" in hpux9 | hpux10 ) XE_ADD_OBJS(strcat.o) ;; esac
1284
1285     if test "$opsys" = "hpux10" -o "$opsys" = "hpux11"; then \
1286         ansi_flag="-Ae"; else ansi_flag="-Aa"; fi
1287     NON_GNU_CC="cc $ansi_flag" NON_GNU_CPP="cc $ansi_flag -E"
1288
1289     case "$canonical" in *-hp-hpux*shr* ) opsys="${opsys}-shr" ;; esac
1290   ;;
1291
1292   dnl Orion machines
1293   orion-orion-bsd*   ) machine=orion    opsys=bsd4-2 ;;
1294   clipper-orion-bsd* ) machine=orion105 opsys=bsd4-2 ;;
1295
1296   dnl IBM machines
1297   i[[3-9]]86-ibm-aix1.1* ) machine=ibmps2-aix opsys=usg5-2-2 ;;
1298   i[[3-9]]86-ibm-aix1.[[23]]* | i[[3-9]]86-ibm-aix* ) machine=ibmps2-aix opsys=usg5-3 ;;
1299   i370-ibm-aix*) machine=ibm370aix opsys=usg5-3 ;;
1300   romp-ibm-aos*    ) opsys=bsd4-3 ;;
1301   romp-ibm-bsd*    ) opsys=bsd4-3 ;;
1302   romp-ibm-mach*   ) opsys=mach-bsd4-3 ;;
1303
1304   dnl Integrated Solutions "Optimum V"
1305   m68*-isi-bsd4.2* ) machine=isi-ov opsys=bsd4-2 ;;
1306   m68*-isi-bsd4.3* ) machine=isi-ov opsys=bsd4-3 ;;
1307
1308   dnl Intel 386 machines where we do care about the manufacturer
1309   i[[3-9]]86-intsys-sysv* ) machine=is386 opsys=usg5-2-2 ;;
1310
1311   dnl Prime EXL
1312   i[[3-9]]86-prime-sysv* ) machine=i386 opsys=usg5-3 ;;
1313
1314   dnl Sequent Symmetry running Dynix
1315   i[[3-9]]86-sequent-bsd* ) machine=symmetry opsys=bsd4-3 ;;
1316
1317   dnl Sequent Symmetry running DYNIX/ptx
1318   i[[3-9]]86-sequent-ptx* ) machine=sequent-ptx opsys=ptx NON_GNU_CPP="/lib/cpp" ;;
1319
1320   dnl Unspecified sysv on an ncr machine defaults to svr4.2.
1321   dnl (Plain usg5-4 does not turn on POSIX signals, which we need.)
1322   i[[3-9]]86-ncr-sysv* ) machine=ncr386 opsys=usg5-4-2 ;;
1323
1324   dnl Intel Paragon OSF/1
1325   i860-intel-osf1* ) machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp ;;
1326
1327   dnl Intel 860
1328   i860-*-sysv4* ) machine=i860 opsys=usg5-4 NON_GNU_CC="/bin/cc" NON_GNU_CPP="/usr/ccs/lib/cpp" ;;
1329
1330   dnl Masscomp machines
1331   m68*-masscomp-rtu* ) machine=masscomp opsys=rtu ;;
1332
1333   dnl Megatest machines
1334   m68*-megatest-bsd* ) machine=mega68 opsys=bsd4-2 ;;
1335
1336   dnl Workstations sold by MIPS
1337   dnl This is not necessarily all workstations using the MIPS processor -
1338   dnl Irises are produced by SGI, and DECstations by DEC.
1339   mips-mips-usg* ) machine=mips4 ;;
1340   mips-mips-riscos4 )
1341     machine=mips4
1342     NON_GNU_CC="cc -systype bsd43"
1343     NON_GNU_CPP="cc -systype bsd43 -E"
1344     case "$canonical" in
1345       mips-mips-riscos4* ) opsys=bsd4-3  ;;
1346       mips-mips-riscos5* ) opsys=riscos5 ;;
1347     esac
1348   ;;
1349   mips-mips-bsd* ) machine=mips opsys=bsd4-3 ;;
1350   mips-mips-*    ) machine=mips opsys=usg5-2-2 ;;
1351
1352   dnl NeXT
1353   m68*-next-* | m68k-*-nextstep* ) machine=m68k opsys=nextstep ;;
1354
1355   dnl The complete machine from National Semiconductor
1356   ns32k-ns-genix* ) machine=ns32000 opsys=usg5-2 ;;
1357
1358   dnl NCR machines
1359   m68*-ncr-sysv2* | m68*-ncr-sysvr2* ) machine=tower32   opsys=usg5-2-2 ;;
1360   m68*-ncr-sysv3* | m68*-ncr-sysvr3* ) machine=tower32v3 opsys=usg5-3 ;;
1361
1362   dnl Nixdorf Targon 31
1363   m68*-nixdorf-sysv* ) machine=targon31 opsys=usg5-2-2 ;;
1364
1365   dnl Nu (TI or LMI)
1366   m68*-nu-sysv* ) machine=nu opsys=usg5-2 ;;
1367
1368   dnl Plexus
1369   m68*-plexus-sysv* ) machine=plexus opsys=usg5-2 ;;
1370
1371   dnl Pyramid machines
1372   pyramid-pyramid-bsd* ) machine=pyramid opsys=bsd4-2 ;;
1373
1374   dnl Sequent Balance
1375   ns32k-sequent-bsd4.2* ) machine=sequent opsys=bsd4-2 ;;
1376   ns32k-sequent-bsd4.3* ) machine=sequent opsys=bsd4-3 ;;
1377
1378   dnl Siemens Nixdorf
1379   mips-siemens-sysv* | mips-sni-sysv*)
1380     machine=mips-siemens opsys=usg5-4
1381     NON_GNU_CC=/usr/ccs/bin/cc
1382     NON_GNU_CPP=/usr/ccs/lib/cpp
1383   ;;
1384
1385   dnl NEC
1386   mips-nec-sysv*)
1387     machine=mips-nec
1388     NON_GNU_CC=/usr/ccs/bin/cc
1389     NON_GNU_CPP=/usr/ccs/lib/cpp
1390   ;;
1391
1392   dnl Silicon Graphics machines
1393   dnl Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
1394   m68*-sgi-iris3.5* ) machine=irist opsys=iris3-5 ;;
1395   m68*-sgi-iris3.6* | m68*-sgi-iris*) machine=irist opsys=iris3-6 ;;
1396   dnl Iris 4D
1397   mips-sgi-irix3.*    ) opsys=irix3-3 ;;
1398   mips-sgi-irix4.*    ) opsys=irix4-0 ;;
1399   mips-sgi-irix6*     ) opsys=irix6-0 ;;
1400   mips-sgi-irix5.1*   ) opsys=irix5-1 ;;
1401   mips-sgi-irix5.2*   ) opsys=irix5-2 ;;
1402   mips-sgi-irix5.*    ) opsys=irix5-3 ;;
1403   mips-sgi-irix*      ) opsys=irix5-0 ;;
1404
1405   dnl SONY machines
1406   *-sony-newsos[[34]]* | *-sony-news[[34]]* ) opsys=bsd4-3 ;;
1407   *-sony-news* ) opsys=newsos5 ;;
1408
1409   dnl Stride
1410   m68*-stride-sysv* ) machine=stride opsys=usg5-2 ;;
1411
1412   dnl Suns
1413   *-*-solaris* | *-*-sunos* | *-sun-mach* | *-sun-bsd* )
1414     dnl Hardware type
1415     case "$canonical" in
1416       m68*-sunos1* )             machine=sun1     ;;
1417       m68*-sunos2* )             machine=sun2     ;;
1418       m68* )                     machine=sun3     ;;
1419       i*86*-sun-sunos[[34]]* )   machine=sun386   ;;
1420       i*86-*-* )                 machine=intel386 ;;
1421       rs6000* )                  machine=rs6000   ;;
1422     esac
1423
1424     dnl Make $canonical even more so.
1425     case "$canonical" in *-sunos5*)
1426       canonical=`echo $canonical | sed -e s/sunos5/solaris2/`;;
1427     esac
1428
1429     dnl On SunOS 4, use /usr/lib/cpp, sans dynodump, /bin/ranlib
1430     dnl On SunOS 5, use cc -E,        need dynodump, RANLIB not needed
1431     dnl But, SunOS 5.6 no longer needs dynodump because it has a similar
1432     dnl function integrated.
1433     case "$canonical" in
1434       *-sunos4* )
1435         #test -f /usr/lib/cpp     && NON_GNU_CPP=/usr/lib/cpp ;;
1436         : ;;
1437       *-solaris2* )
1438         #test -f /usr/ccs/lib/cpp && NON_GNU_CPP=/usr/ccs/lib/cpp
1439         RANLIB=':' ;;
1440     esac
1441
1442     case "$canonical" in
1443       *-solaris*          )
1444         opsys=sol2
1445         os_release=`uname -r | sed -e 's/^\([[0-9]]\)\.\([[0-9]]\).*/\1\2/'`
1446         AC_DEFINE_UNQUOTED(OS_RELEASE, $os_release) ;;
1447
1448       dnl The last Sun386 ran 4.0.
1449       i*86-*-sunos4*      ) opsys=sunos4-0      ;;
1450       *-sunos4.0*         ) opsys=sunos4-0      ;;
1451       *-sunos4.1.2*       ) opsys=sunos4-1-2    ;;
1452       *-sunos4.1.3*       ) opsys=sunos4-1-3    ;;
1453       *-sunos4.1.[[4-9]]* ) opsys=sunos4-1-4    ;;
1454       *-sunos4* | *-sunos ) opsys=sunos4-1      ;;
1455       *-mach*             ) opsys=mach-bsd4-3   ;;
1456       *                   ) opsys=bsd4-2        ;;
1457     esac
1458
1459     case "$canonical" in *-sunos4*shr* ) opsys="${opsys}-shr" ;; esac
1460
1461     dnl Watch out for a compiler guaranteed not to work.
1462     test "$opsys $CC" = "sol2 /usr/ucb/cc" && CC=""
1463   ;;
1464
1465   dnl Tadpole 68k
1466   m68*-tadpole-sysv* ) machine=tad68k opsys=usg5-3 ;;
1467
1468   dnl Tahoe machines
1469   tahoe-tahoe-bsd4.2* ) machine=tahoe opsys=bsd4-2 ;;
1470   tahoe-tahoe-bsd4.3* ) machine=tahoe opsys=bsd4-3 ;;
1471
1472   dnl Tandem Integrity S2
1473   mips-tandem-sysv* ) machine=tandem-s2 opsys=usg5-3 ;;
1474
1475   dnl Tektronix XD88
1476   m88k-tektronix-sysv3* ) machine=tekxd88 opsys=usg5-3 ;;
1477
1478   dnl Tektronix 16000 box (6130?)
1479   ns16k-tektronix-bsd* ) machine=ns16000 opsys=bsd4-2 ;;
1480   dnl Tektronix 4300
1481   dnl src/m/tek4300.h hints that this is a m68k machine.
1482   m68*-tektronix-bsd* ) machine=tek4300 opsys=bsd4-3 ;;
1483
1484   dnl Titan P2 or P3
1485   titan-titan-sysv* ) machine=titan opsys=usg5-3 ;;
1486
1487   dnl Ustation E30 (SS5E)
1488   m68*-unisys-uniplus* ) machine=ustation opsystem=unipl5-2 ;;
1489
1490   dnl Vaxen.
1491   vax-dec-* )
1492     case "$canonical" in
1493       *-sysv[[01]]* | *-sysvr[[01]]* )  opsys=usg5-0 ;;
1494       *-sysv2* | *-sysvr2* )            opsys=usg5-2 ;;
1495       *-mach* )                         opsys=mach-bsd4-3 ;;
1496     esac
1497   ;;
1498
1499   dnl Whitechapel MG1
1500   ns16k-whitechapel-* ) machine=mg1 ;;
1501
1502   dnl Wicat
1503   m68*-wicat-sysv* ) machine=wicat opsys=usg5-2 ;;
1504
1505   dnl Intel 386 machines where we do not care about the manufacturer
1506   i[[3-9]]86-*-* )
1507     machine=intel386
1508     case "$canonical" in
1509       *-isc1.* | *-isc2.[[01]]* ) opsys=386-ix ;;
1510       *-isc2.2* )               opsys=isc2-2 ;;
1511       *-isc4.0* )               opsys=isc4-0 ;;
1512       *-isc4.* )                opsys=isc4-1
1513                                 GCC_TEST_OPTIONS=-posix
1514                                 NON_GCC_TEST_OPTIONS=-Xp
1515                                 ;;
1516       *-isc* )                  opsys=isc3-0 ;;
1517       *-esix5* )                opsys=esix5r4 NON_GNU_CPP=/usr/lib/cpp ;;
1518       *-esix* )                 opsys=esix ;;
1519       *-mach* )                 opsys=mach-bsd4-3 ;;
1520       *-xenix* )                opsys=xenix ;;
1521       *-sco3.2v4* )             opsys=sco4 NON_GNU_CPP=/lib/cpp  ;;
1522       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
1523       *-bsdi4* )                opsys=bsdos4 ;;
1524       *-bsdi3* )                opsys=bsdos3 ;;
1525       *-bsdi2.1* )              opsys=bsdos2-1 ;;
1526       *-bsdi2* )                opsys=bsdos2 ;;
1527       *-sco3.2v5* )             opsys=sco5 ;
1528         dnl This is a pain.  Like the current USL cc, SCO cc -E
1529         dnl tokenizes as it preprocesses, making configure very
1530         dnl unhappy.  Unfortunately, /lib/cpp does not understand
1531         dnl flags like "-b elf", so we have to cheat in order to
1532         dnl pick up the right defines for UNEXEC from the s-file.
1533         dnl 01/05/95 robertl@dgii.com
1534         if test "$dynamic" = "yes" ; then
1535                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE -D_SCO_ELF"  ;
1536         else
1537                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE"  ;
1538         fi ;;
1539       *-sysv5* )                opsys=sco7 ;;
1540       *-386bsd* )               opsys=386bsd ;;
1541       *-freebsd* )              opsys=freebsd ;;
1542       *-nextstep* )             opsys=nextstep ;;
1543       *-pc-cygwin* )            opsys=cygwin32 ;;
1544       *-pc-mingw* )             opsys=mingw32 ;
1545                                 test -z "$with_tty" && with_tty="no";;
1546       dnl Otherwise, we fall through to the generic opsys code at the bottom.
1547     esac
1548   ;;
1549
1550   dnl Linux/68k
1551   m68k-*-linux* ) machine=m68k opsys=linux ;;
1552
1553 esac
1554
1555 if test -z "$machine" -o -z "$opsys"; then
1556   (echo "$progname: XEmacs hasn't been ported to \`$canonical' systems."
1557    echo "$progname: Check \`etc/MACHINES' for recognized configuration names."
1558   ) >&2
1559   exit 1
1560 fi
1561
1562 if test -z "$dynamic"; then
1563   case "$opsys" in
1564     hpux* | sunos4* ) dynamic=no ;;
1565     *) dynamic=yes ;;
1566   esac
1567 fi
1568 if test "$dynamic" = "yes"; then
1569   case "$opsys" in
1570     hpux* | sunos4* | sco5 ) opsys="${opsys}-shr" ;;
1571     decosf* ) ld_call_shared="-call_shared" ;;
1572   esac
1573 else dnl "$dynamic" = "no"
1574   case "$opsys" in
1575     sol2 )
1576       echo "Static linking is not supported on Solaris 2."
1577       echo "Rerun configure without specifying --dynamic=no."
1578       exit 1 ;;
1579     linux   ) ld_call_shared="-Bstatic" ;;
1580     decosf* ) ld_call_shared="-non_shared" ;;
1581   esac
1582 fi
1583
1584 dnl Use xlc by default on AIX
1585 case "$opsys" in aix*) NON_GNU_CC=xlc ;; esac
1586
1587 stack_trace_eye_catcher=`echo ${PROGNAME}_${version}_${canonical} | sed 'y/.-/__/'`
1588 AC_DEFINE_UNQUOTED(STACK_TRACE_EYE_CATCHER, $stack_trace_eye_catcher)
1589
1590 machfile="m/${machine}.h"
1591 opsysfile="s/${opsys}.h"
1592
1593 dnl --------------------------------------------------
1594 dnl Determine the compiler, set up for feature testing
1595 dnl --------------------------------------------------
1596
1597 dnl Sun Development environment support
1598 test "$with_sparcworks" = "yes" && with_workshop=yes # compatibility alias
1599 XE_CHECK_FEATURE_DEPENDENCY(workshop, tooltalk)
1600 if test "$with_workshop" = "yes"; then
1601   AC_DEFINE(SUNPRO)
1602   XE_ADD_OBJS(sunpro.o)
1603 fi
1604
1605 if test "$with_clash_detection" != "no"; then
1606   AC_DEFINE(CLASH_DETECTION)
1607   XE_ADD_OBJS(filelock.o)
1608 fi
1609
1610 dnl Choose a compiler from (in order)
1611 dnl --compiler, env var CC, with_gcc=no && ${NON_GNU_CC:-cc}, AC_PROG_CC
1612 test -n "$compiler" && CC="$compiler"
1613 if test "$with_gcc" = "no"; then dnl Try to find a non-gcc compiler
1614   case "$CC" in "" | *gcc* ) CC="${NON_GNU_CC-cc}" ;; esac
1615 fi
1616
1617 dnl If we don't set CFLAGS here, AC_PROG_CC will set it.
1618 dnl But we know better what's good for us, so we do our own
1619 dnl computation of real CFLAGS later.
1620 dnl --cflags overrides environment variable CFLAGS
1621 test "${cflags-unset}" != unset && CFLAGS="$cflags"
1622 if test "${CFLAGS-unset}" != unset
1623   then cflags_specified=yes;
1624   else cflags_specified=no;
1625 fi
1626
1627 xe_save_CFLAGS="$CFLAGS"
1628
1629 AC_PROG_CC dnl Autoconf has its own magic for compiler autodetection
1630
1631 dnl Retry using random guesswork if AC_PROG_CC got it wrong...
1632 if   test "$with_gcc" = "no"  -a "$GCC" = "yes"; then
1633   CC=${NON_GNU_CC-cc}
1634   AC_PROG_CC
1635 elif test "$with_gcc" = "yes" -a "$GCC" != "yes" ; then
1636   CC=gcc
1637   AC_PROG_CC
1638 fi
1639 CFLAGS="$xe_save_CFLAGS"
1640
1641 dnl Figure out what C preprocessor to use.
1642
1643 dnl On Sun systems, people sometimes set up the variable CPP
1644 dnl with a value that is a directory, not an executable at all.
1645 dnl Detect that case, and ignore that value.
1646 test -n "$CPP" -a -d "$CPP" && CPP=
1647
1648 test -n "$NON_GNU_CPP" -a "$GCC" != "yes" -a -z "$CPP" && CPP="$NON_GNU_CPP"
1649
1650 AC_PROG_CPP
1651
1652 dnl --------------------------------------------------------------------
1653 dnl Compiler feature macros
1654 dnl --------------------------------------------------------------------
1655
1656 AC_AIX dnl Defines _ALL_SOURCE on AIX.
1657
1658 dnl Determine which SMART_INCLUDE macro will work for this system
1659 cat > $srcdir/conffoo.h <<EOF
1660 #define CONFFOO 1
1661 EOF
1662 AC_MSG_CHECKING(for a working inclusion macro)
1663 AC_TRY_COMPILE(,[
1664 #define SMART_INCLUDE(path,file) <path/file>
1665 #define CONFFOO_H_PATH $srcdir
1666 #define CONFFOO_INCLUDE(file) SMART_INCLUDE (CONFFOO_H_PATH,file)
1667 #include CONFFOO_INCLUDE(conffoo.h)
1668 ], [ AC_MSG_RESULT(direct); AC_DEFINE(SMART_INCLUDE_INDIRECTIONS,0) ],
1669 AC_TRY_COMPILE(,[
1670 #define GLUE_INCLUDE(path,file)  <##path##/##file##>
1671 #define SMART_INCLUDE(path,file) GLUE_INCLUDE(path,file)
1672 #define CONFFOO_H_PATH $srcdir
1673 #define CONFFOO_INCLUDE(file) SMART_INCLUDE(CONFFOO_H_PATH,file)
1674 #include CONFFOO_INCLUDE(conffoo.h)
1675 ], [ AC_MSG_RESULT(simple); AC_DEFINE(SMART_INCLUDE_INDIRECTIONS,1) ],
1676 AC_TRY_COMPILE(,[
1677 #define GLUE_INCLUDE_2(path,file)  <##path##/##file##>
1678 #define GLUE_INCLUDE_1(path,file) GLUE_INCLUDE_2(path,file)
1679 #define SMART_INCLUDE(path,file) GLUE_INCLUDE_1(path,file)
1680 #define CONFFOO_H_PATH $srcdir
1681 #define CONFFOO_INCLUDE(file) SMART_INCLUDE (CONFFOO_H_PATH,file)
1682 #include CONFFOO_INCLUDE(conffoo.h)
1683 ], [ AC_MSG_RESULT(double); AC_DEFINE(SMART_INCLUDE_INDIRECTIONS,2) ],
1684   AC_MSG_ERROR([Cannot define a proper SMART_INCLUDE macro. Please report.]))))
1685 rm -f $srcdir/conffoo.h
1686
1687
1688 dnl We want feature macros defined here and in config.h.in, so that
1689 dnl the compilation environment at configure time and compile time agree.
1690
1691 AC_MSG_CHECKING(for GNU libc)
1692 AC_TRY_COMPILE([#include <features.h>],[
1693 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
1694 #error Not a GNU libc system :-(
1695 ******* ======= ******** &&&&&&&&
1696 #endif
1697 ], have_glibc=yes, have_glibc=no)
1698 AC_MSG_RESULT($have_glibc)
1699 dnl I'm tired of pop being broken with GLIBC -slb
1700 dnl Well. then why not fix fucking pop?
1701 test "$have_glibc" = "yes" && AC_DEFINE(_GNU_SOURCE)
1702
1703 dnl We'd like to use vendor extensions, where available.
1704 dnl We'd like to use functions from the latest Unix98 standards.
1705 dnl See http://www.opengroup.org/onlinepubs/007908799/xsh/compilation.html
1706 case "$opsys" in
1707   sol2)
1708    AC_DEFINE(__EXTENSIONS__)
1709    dnl Solaris 2 before 2.5 had some bugs with feature test macro interaction.
1710    if test "$os_release" -ge 55; then
1711      AC_DEFINE(_XOPEN_SOURCE,500)
1712      AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1713    fi ;;
1714   linux)
1715     AC_DEFINE(_POSIX_C_SOURCE,199506L)
1716     AC_DEFINE(_XOPEN_SOURCE,500)
1717     AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1718     ;;
1719 esac
1720
1721 dnl Identify compilers to enable compiler-specific hacks.
1722 dnl Add support for other compilers HERE!
1723 dnl GCC is already identified elsewhere.
1724 AC_TRY_RUN([int main () {
1725 #if defined __SUNPRO_C
1726 return 11;
1727 #elif defined __DECC
1728 return 12;
1729 #else
1730 return 0;
1731 #endif
1732 }], [],
1733 [case "$conftest_rc" in
1734   11) echo "You appear to be using the SunPro C compiler."; __SUNPRO_C=yes ;;
1735   12) echo "You appear to be using the DEC C compiler."   ; __DECC=yes ;;
1736 esac])
1737
1738
1739 dnl case "$canonical" in
1740 dnl   *-sun-sunos* ) test "$CPP" = "acc -E" && CPP="acc -E -Xs" ;;
1741 dnl esac
1742
1743 dnl --------------------------------------------------------------------
1744 dnl Extract some information from the operating system and machine files
1745 dnl --------------------------------------------------------------------
1746
1747 echo "Extracting information from the machine- and system-dependent headers..."
1748
1749 dnl It is not important that this name contain the PID; you cannot run
1750 dnl two configures in the same directory and have anything work
1751 dnl anyway.
1752 tempcname="conftest.c"
1753
1754 dnl CPP_to_sh(CPP_SYMBOL, SH_VAR, DEFAULT_VALUE)
1755 define([CPP_to_sh],
1756 [[#]ifndef [$1]
1757 [#]define [$1]ifelse([$3],,, [ "$3"])
1758 [#]endif
1759 configure___ [$2]=[$1]
1760 ])dnl CPP_to_sh
1761
1762 dnl CPP_boolean_to_sh(CPP_SYMBOL, SH_VAR)
1763 define([CPP_boolean_to_sh],
1764 [[#]ifdef [$1]
1765 configure___ [$2]=yes
1766 [#]else
1767 configure___ [$2]=no
1768 [#]endif
1769 ])dnl CPP_boolean_to_sh
1770
1771 cat > $tempcname <<EOF
1772 #define NOT_C_CODE
1773 #define C_SWITCH_SITE
1774 #define C_SWITCH_X_SITE
1775 #define LD_SWITCH_SITE
1776 #define LD_SWITCH_X_SITE
1777 #define LD_SWITCH_X_SITE_AUX
1778 #define OS_RELEASE $os_release
1779 #include "$srcdir/src/$opsysfile"
1780 #include "$srcdir/src/$machfile"
1781
1782 CPP_to_sh(LIBS_MACHINE, libs_machine)
1783 CPP_to_sh(LIBS_SYSTEM,  libs_system)
1784 CPP_to_sh(LIBS_TERMCAP, libs_termcap)
1785 CPP_to_sh(LIB_STANDARD, libs_standard)
1786
1787 CPP_to_sh(OBJECTS_MACHINE, objects_machine)
1788 CPP_to_sh(OBJECTS_SYSTEM,  objects_system)
1789
1790 CPP_to_sh(C_SWITCH_MACHINE,   c_switch_machine)
1791 CPP_to_sh(C_SWITCH_SYSTEM,    c_switch_system)
1792
1793 CPP_to_sh(LD_SWITCH_MACHINE,  ld_switch_machine)
1794 CPP_to_sh(LD_SWITCH_SYSTEM,   ld_switch_system)
1795
1796 CPP_to_sh(UNEXEC, unexec, unexec.o)
1797
1798 CPP_to_sh(LD_SWITCH_SHARED, ld_switch_shared, -c)
1799
1800 #define ORDINARY_LD "\$(CC) \$(CFLAGS)"
1801 configure___ ordinary_ld=ORDINARY_LD
1802
1803 #ifdef ORDINARY_LINK
1804 #define LD ORDINARY_LD
1805 #else /* no ORDINARY LINK */
1806 #ifdef COFF_ENCAPSULATE
1807 #define LD "\$(CC) -nostdlib"
1808 #else /* not COFF_ENCAPSULATE */
1809 #ifdef LINKER
1810 #define LD LINKER
1811 #else /* ! defined (LINKER) */
1812 #define LD "ld"
1813 #endif /* ! defined (LINKER) */
1814 #endif /* ! defined (COFF_ENCAPSULATE) */
1815 #endif /* not ORDINARY_LINK */
1816 configure___ ld=LD
1817
1818 CPP_to_sh(LIB_GCC, lib_gcc)
1819 CPP_to_sh(LD_TEXT_START_ADDR, ld_text_start_addr)
1820
1821 #if ! defined (ORDINARY_LINK) && !defined (START_FILES)
1822 #ifdef NO_REMAP
1823 #ifdef COFF_ENCAPSULATE
1824 #define START_FILES "pre-crt0.o /usr/local/lib/gcc-crt0.o"
1825 #else /* ! defined (COFF_ENCAPSULATE) */
1826 #define START_FILES "pre-crt0.o /lib/crt0.o"
1827 #endif /* ! defined (COFF_ENCAPSULATE) */
1828 #else /* ! defined (NO_REMAP) */
1829 #define START_FILES "ecrt0.o"
1830 #endif /* ! defined (NO_REMAP) */
1831 #endif /* no ORDINARY_LINK */
1832 #ifndef START_FILES
1833 #define START_FILES
1834 #endif
1835 configure___ start_files=START_FILES
1836
1837 CPP_boolean_to_sh(ORDINARY_LINK, ordinary_link)
1838 CPP_boolean_to_sh(SYSTEM_MALLOC, system_malloc)
1839 CPP_boolean_to_sh(TERMINFO, have_terminfo)
1840 dnl The MAIL_USE_xxx variables come from the s&m headers
1841 CPP_boolean_to_sh(MAIL_USE_FLOCK, mail_use_flock)
1842 CPP_boolean_to_sh(MAIL_USE_LOCKF, mail_use_lockf)
1843 CPP_boolean_to_sh(MAIL_USE_LOCKING, mail_use_locking)
1844 CPP_boolean_to_sh(HAVE_WIN32_PROCESSES, win32_processes)
1845 EOF
1846
1847 dnl The value of CPP is a quoted variable reference, so we need to do this
1848 dnl to get its actual value...
1849 CPP=`eval "echo $CPP $CPPFLAGS"`
1850 define(TAB, [   ])dnl
1851 changequote(, )dnl
1852 eval `$CPP -Isrc $tempcname \
1853         | sed -n -e "s/[ TAB]*=[ TAB\"]*/='/" -e "s/[ TAB\"]*\$/'/" -e "s/^configure___//p"`
1854 changequote([, ])dnl
1855
1856 rm $tempcname
1857
1858 if test "$pdump" = "yes"; then
1859   ordinary_link="yes"
1860   ld="${ordinary_ld}"
1861   start_files=
1862   libs_standard=
1863   unexec=
1864   lib_gcc=
1865 fi
1866
1867 dnl For debugging...
1868 test "$extra_verbose" = "yes" && \
1869   PRINT_VAR(libs_machine libs_system libs_termcap libs_standard
1870   objects_machine objects_system c_switch_machine c_switch_system
1871   ld_switch_machine ld_switch_system unexec ld_switch_shared
1872   ld lib_gcc ld_text_start_addr start_files ordinary_link
1873   have_terminfo mail_use_flock mail_use_lockf) && echo ""
1874
1875 dnl Pick up mingw32 include path
1876 case "$opsys" in mingw*) mingw_include=`eval "gcc -print-file-name=libc.a"` ;
1877         mingw_include=`eval "dirname $mingw_include"` ;
1878         mingw_include="-I$mingw_include/../include/mingw32" ;
1879         XE_APPEND($mingw_include, c_switch_system) ;;
1880 esac
1881
1882 dnl Non-ordinary link usually requires -lc
1883 test "$ordinary_link" = "no" -a -z "$libs_standard" && libs_standard="-lc"
1884
1885 dnl Compiler-specific hacks
1886 dnl DEC C requires -std
1887 test "$__DECC" = "yes" && XE_APPEND(-std, c_switch_site)
1888
1889 dnl Calculalate value of CFLAGS:
1890 dnl Use either command line flag, environment var, or autodetection
1891 if test "$cflags_specified" = "no"; then
1892   dnl Following values of CFLAGS are known to work well.
1893   dnl Should we take debugging options into consideration?
1894   if   test "$GCC" = "yes"; then
1895     CFLAGS="-g -O3 -Wall -Wno-switch -Wpointer-arith -Winline -Wmissing-prototypes -Wshadow"
1896     dnl I'm not convinced this is a good idea any more. -sb
1897     dnl test "$opsys $machine" = "linux intel386" && \
1898     dnl CFLAGS="$CFLAGS -fno-strength-reduce -malign-loops=2 -malign-jumps=2 -malign-functions=2"
1899   elif test "$__SUNPRO_C" = "yes"; then
1900     case "$opsys" in
1901       sol2    ) CFLAGS="-v -xO4" ;;
1902       sunos4* ) CFLAGS="-xO2";;
1903     esac
1904   elif test "$__DECC" = "yes"; then
1905     CFLAGS="-O3"
1906   elif test "$CC" = "xlc"; then
1907     CFLAGS="-g -O3 -qstrict -qnoansialias -qlibansi -qinfo -qro -qmaxmem=20000"
1908   dnl ### Add optimal CFLAGS support for other compilers HERE!
1909   else
1910     CFLAGS="-O" ;dnl The only POSIX-approved flag
1911   fi
1912 fi
1913
1914 dnl Search for GCC specific build problems we know about
1915 if test "$GCC" = "yes"; then
1916 AC_MSG_CHECKING(for buggy gcc versions)
1917 GCC_VERSION=`$CC --version`
1918 case `uname -s`:`uname -m`:$GCC_VERSION in
1919         dnl egcs 2.90.21 (egcs-1.00 release)
1920         dnl egcs 2.90.29 (egcs-1.0.3 release)
1921     *:sun4*:2.8.1|*:sun4*:egcs-2.90.*)
1922         dnl Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures
1923         dnl without also using `-fno-schedule-insns'.
1924         case "$CFLAGS" in
1925             *-O2*|*-O3*)
1926                 case "$CFLAGS" in
1927                     *-fno-schedule-insns*) ;;
1928                     *)
1929                         AC_MSG_RESULT(Yes)
1930                         AC_MSG_WARN(Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures)
1931                         AC_MSG_WARN(without also using -fno-schedule-insns.)
1932                         AC_MSG_ERROR(Aborting due to known problem)
1933                         ;;
1934                 esac
1935                 ;;
1936         esac
1937         ;;
1938         dnl egcs-2.91.57 (egcs-1.1 release)
1939         dnl egcs-2.91.66 (egcs-1.1.2 release)
1940     Linux:alpha:egcs-2.91.*)
1941         AC_MSG_RESULT(Yes)
1942         AC_MSG_WARN(There have been reports of egcs-1.1 not compiling XEmacs correctly on)
1943         AC_MSG_WARN(Alpha Linux.  There have also been reports that egcs-1.0.3a is O.K.)
1944         AC_MSG_ERROR(Aborting due to known problem)
1945         ;;
1946     *:i*86*:2.7.2*)
1947         case "$GCC_VERSION" in
1948             2.7.2)
1949                 case "$CFLAGS" in
1950                     *-O2*|*-O3*)
1951                         case "$CFLAGS" in
1952                             *-fno-strength-reduce*) ;;
1953                             *)
1954                                 AC_MSG_RESULT(Yes)
1955                                 AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1956                                 AC_MSG_WARN(-fno-strength-reduce.)
1957                                 AC_MSG_ERROR(Aborting due to known problem)
1958                                 ;;
1959                         esac
1960                         ;;
1961                 esac
1962                 ;;
1963         esac
1964         case "$CFLAGS" in
1965          *-fno-caller-saves*) ;;
1966          *)
1967             AC_MSG_RESULT(Yes)
1968             AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1969             AC_MSG_WARN(-fno-caller-saves.)
1970             AC_MSG_ERROR(Aborting due to known problem)
1971             ;;
1972         esac
1973         ;;
1974 esac
1975 fi
1976 AC_MSG_RESULT(No)
1977
1978 dnl Inform compiler that certain flags are meant for the linker
1979 dnl XE_PROTECT_LINKER_FLAGS(shell_var)
1980 define([XE_PROTECT_LINKER_FLAGS], [
1981 if test "$GCC" = "yes"; then
1982   set x $[$1]; shift; [$1]=""
1983   while test -n "[$]1"; do
1984     case [$]1 in
1985       -L  | -l  | -u               ) [$1]="$[$1] [$]1 [$]2"; shift ;;
1986       -L* | -l* | -u* | -Wl* | -pg ) [$1]="$[$1] [$]1" ;;
1987       -Xlinker* ) ;;
1988       * ) [$1]="$[$1] -Xlinker [$]1" ;;
1989     esac
1990     shift
1991   done
1992 fi])dnl
1993 XE_PROTECT_LINKER_FLAGS(ld_switch_system)
1994 XE_PROTECT_LINKER_FLAGS(ld_switch_machine)
1995 XE_PROTECT_LINKER_FLAGS(LDFLAGS)
1996 XE_PROTECT_LINKER_FLAGS(ld_call_shared)
1997
1998 dnl Add s&m-determined objects (including unexec) to link line
1999 test -n "$objects_machine" && XE_ADD_OBJS($objects_machine)
2000 test -n "$objects_system"  && XE_ADD_OBJS($objects_system)
2001 test -n "$unexec"          && test ! "$pdump" = "yes" && XE_ADD_OBJS($unexec)
2002 test "$pdump" = "yes" && XE_ADD_OBJS(dumper.o)
2003
2004 dnl Dynodump (Solaris 2.x, x<6)
2005 AC_MSG_CHECKING(for dynodump)
2006 if test "$unexec" != "unexsol2.o"; then
2007   AC_MSG_RESULT(no)
2008 else
2009   AC_MSG_RESULT(yes)
2010   AC_DEFINE(DYNODUMP)
2011   XE_APPEND(dynodump, MAKE_SUBDIR)
2012   XE_APPEND(dynodump, SRC_SUBDIR_DEPS)
2013   case "$machine" in
2014     sparc   ) dynodump_arch=sparc ;;
2015     *86*    ) dynodump_arch=i386  ;;
2016     powerpc ) dynodump_arch=ppc   ;;
2017   esac
2018   dnl Dynodump requires the system linker
2019   test "$GCC" = "yes" && XE_APPEND(-fno-gnu-linker, ld_switch_site)
2020 fi
2021
2022 dnl Feed s&m crud to src/Makefile
2023
2024 dnl Linux/powerpc needs the following magic for some reason
2025 test "$machine$opsys" = "powerpclinux" && start_flags="-T $srcdir/src/ppc.ldscript"
2026
2027 if test "$unexec" = "unexaix.o"; then
2028 dnl AIX needs various hacks to make static linking work.
2029   if   test "$dynamic" = "no"; then
2030   start_flags="-Wl,-bnso,-bnodelcsect"
2031   test "$GCC" = "yes" && start_flags="-B/bin/ ${start_flags}"
2032   for f in "/lib/syscalls.exp" "/lib/threads.exp"; do
2033     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; fi
2034   done
2035   for f in "/usr/lpp/X11/bin/smt.exp" "/usr/bin/X11/smt.exp"; do
2036     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; break; fi
2037   done
2038   AC_CHECK_LIB(C, terminateAndUnload, XE_APPEND(-lC, libs_system))
2039   fi
2040 elif test -n "$ld_text_start_addr"; then
2041   start_flags="-T $ld_text_start_addr -e __start"
2042 fi
2043 AC_SUBST(start_flags)
2044
2045 AC_SUBST(ld_switch_shared)
2046 AC_SUBST(start_files)
2047 if test "$ordinary_link" = "no" -a "$GCC" = "yes"; then
2048  test -z "$linker" &&  linker='$(CC) -nostdlib'
2049  test -z "$lib_gcc" && lib_gcc='`$(CC) -print-libgcc-file-name`'
2050 fi
2051 test "$GCC" != "yes" && lib_gcc=
2052 AC_SUBST(ld)
2053 AC_SUBST(lib_gcc)
2054
2055 dnl ---------------------------------------------------------------
2056 dnl Add site and system specific flags to compile and link commands
2057 dnl ---------------------------------------------------------------
2058
2059 dnl Allow use of either ":" or spaces for lists of directories
2060 define(COLON_TO_SPACE,
2061   [case "$[$1]" in *:* [)] [$1]="`echo '' $[$1] | sed -e 's/^ //' -e 's/:/ /g'`";; esac])dnl
2062
2063 dnl --site-libraries (multiple dirs)
2064 COLON_TO_SPACE(site_libraries)
2065 if test -n "$site_libraries"; then
2066   for arg in $site_libraries; do
2067     case "$arg" in
2068      -* ) ;;
2069      * ) test -d "$arg" || \
2070            XE_DIE("Invalid site library \`$arg': no such directory")
2071        arg="-L${arg}" ;;
2072     esac
2073     XE_APPEND($arg, ld_switch_site)
2074   done
2075 fi
2076
2077 dnl --site-includes (multiple dirs)
2078 COLON_TO_SPACE(site_includes)
2079 if test -n "$site_includes"; then
2080   for arg in $site_includes; do
2081     case "$arg" in
2082       -* ) ;;
2083       * ) test -d "$arg" || \
2084            XE_DIE("Invalid site include \`$arg': no such directory")
2085       arg="-I${arg}" ;;
2086     esac
2087     XE_APPEND($arg, c_switch_site)
2088   done
2089 fi
2090
2091 dnl --site-prefixes (multiple dirs)
2092 dnl --site-prefixes=dir1:dir2 is a convenient shorthand for
2093 dnl --site-libraries=dir1/lib:dir2/lib --site-includes=dir1/include:dir2/include
2094 dnl Site prefixes take precedence over the standard places, but not over
2095 dnl site-includes and site-libraries.
2096 COLON_TO_SPACE(site_prefixes)
2097 if test -n "$site_prefixes"; then
2098   for dir in $site_prefixes; do
2099     lib_dir="${dir}/lib"
2100     inc_dir="${dir}/include"
2101     if test ! -d "$dir"; then
2102       XE_DIE("Invalid site prefix \`$dir': no such directory")
2103     elif test ! -d "$lib_dir"; then
2104       XE_DIE("Invalid site prefix \`$dir': no such directory \`$lib_dir'")
2105     else
2106       if test -d "$inc_dir"; then
2107         XE_APPEND("-I$inc_dir", c_switch_site)
2108       fi
2109       XE_APPEND("-L$lib_dir", ld_switch_site)
2110     fi
2111   done
2112 fi
2113
2114 dnl GNU software installs by default into /usr/local/{include,lib}
2115 dnl if test -d "/usr/local/include" -a -d "/usr/local/lib"; then
2116 dnl   XE_APPEND("-L/usr/local/lib",    ld_switch_site)
2117 dnl   XE_APPEND("-I/usr/local/include", c_switch_site)
2118 dnl fi
2119
2120 dnl Extra system-specific library directories - please add to list
2121 for dir in "/usr/ccs/lib"; do
2122   test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2123 done
2124
2125 dnl --site-runtime-libraries (multiple dirs)
2126 COLON_TO_SPACE(site_runtime_libraries)
2127 if test -n "$site_runtime_libraries"; then
2128   LD_RUN_PATH="`echo $site_runtime_libraries | sed -e 's/  */:/g'`"
2129   export LD_RUN_PATH
2130 fi
2131
2132 dnl Linux systems have dynamic runtime library directories listed in
2133 dnl /etc/ld.so.conf.  Since those are used at run time, it seems pretty
2134 dnl safe to use them at link time, and less controversial than forcing
2135 dnl the run-time to use the link-time libraries.  This also helps avoid
2136 dnl mismatches between the link-time and run-time libraries.
2137
2138 dnl #### Unfortunately, there are horrible libc4 and libc5 libraries
2139 dnl listed in /etc/ld.so.conf on some systems, and including them on
2140 dnl the link path leads to linking in utterly broken libc's.
2141 dnl There are many clever ways of approaching this problem,
2142 dnl but finding out that actually works...
2143
2144 dnl if test -z "$LD_RUN_PATH" -a -r "/etc/ld.so.conf"; then
2145 dnl   for dir in `cat /etc/ld.so.conf`; do
2146 dnl     test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2147 dnl   done
2148 dnl   add_runtime_path=no
2149 dnl fi
2150
2151 dnl -------------------------------------
2152 dnl Compute runtime library path
2153 dnl -------------------------------------
2154
2155 if test -n "$add_runtime_path"; then :;
2156 elif test "$dynamic" = "no"; then add_runtime_path=no
2157 elif test -n "$LD_RUN_PATH"; then add_runtime_path=yes
2158 else case "$opsys" in
2159        sol2 | irix* | *bsd* | decosf* ) add_runtime_path=yes ;;
2160        * ) add_runtime_path=no ;;
2161      esac
2162 fi
2163
2164 if test "$add_runtime_path" = "yes"; then
2165   dnl Try to autodetect runtime library flag (usually -R),
2166   dnl and whether it works (or at least does no harm)
2167   AC_MSG_CHECKING("for runtime libraries flag")
2168   case "$opsys" in
2169     sol2 ) dash_r="-R" ;;
2170     decosf* | linux* | irix*) dash_r="-rpath " ;;
2171     *)
2172       dash_r=""
2173       for try_dash_r in "-R" "-R " "-rpath "; do
2174         xe_check_libs="${try_dash_r}/no/such/file-or-directory"
2175         XE_PROTECT_LINKER_FLAGS(xe_check_libs)
2176         AC_TRY_LINK(, , dash_r="$try_dash_r")
2177         xe_check_libs=""
2178         test -n "$dash_r" && break
2179       done ;;
2180   esac
2181   if test -n "$dash_r";
2182     then AC_MSG_RESULT("\"${dash_r}\"")
2183     else AC_MSG_RESULT(NONE)
2184   fi
2185 fi
2186
2187 xe_add_unique_runpath_dir='
2188   xe_add_p=yes
2189   for xe_dir in $runpath_dirs; do   dnl Uniquify
2190     test "$xe_dir" = "$xe_runpath_dir" && xe_add_p=no
2191   done
2192   if test "$xe_add_p" = "yes"; then
2193     test -n "$runpath" && runpath="${runpath}:"
2194     runpath="${runpath}${xe_runpath_dir}"
2195     runpath_dirs="$runpath_dirs $xe_runpath_dir"
2196   fi'
2197
2198
2199 dnl XE_ADD_RUNPATH_DIR(directory)
2200 define([XE_ADD_RUNPATH_DIR],[{
2201 xe_runpath_dir=$1
2202 dnl PRINT_VAR(ld_switch_site ld_switch_x_site runpath xe_runpath_dir LD_RUN_PATH xe_ldflags)
2203   test "$xe_runpath_dir" != "/lib"     -a \
2204         "$xe_runpath_dir" != "/usr/lib" -a \
2205         -n "`ls ${xe_runpath_dir}/*.s[[ol]] 2>/dev/null`" && \
2206   eval "$xe_add_unique_runpath_dir"
2207 }])dnl
2208
2209 dnl XE_COMPUTE_RUNPATH()
2210 define([XE_COMPUTE_RUNPATH],[
2211 if test "$add_runtime_path" = "yes" -a -n "$dash_r"; then
2212   dnl Remove runtime paths from current ld switches
2213   ld_switch_site=`echo   '' $ld_switch_site   | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2214   ld_switch_x_site=`echo '' $ld_switch_x_site | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2215   dnl PRINT_VAR(ld_switch_site ld_switch_x_site)
2216
2217   dnl Fix up Runtime path
2218   dnl If LD_RUN_PATH is set in environment, use that.
2219   dnl In this case, assume user has set the right value.
2220   runpath="" runpath_dirs=""
2221   if test -n "$LD_RUN_PATH"; then
2222     runpath="$LD_RUN_PATH"
2223   elif test "$GCC" = "yes"; then
2224     dnl Compute runpath from gcc's -v output
2225     ld_switch_run_save="$ld_switch_run"; ld_switch_run=""
2226     echo "int main(int argc, char *argv[[]]) {return 0;}" > conftest.c
2227     xe_runpath_link='${CC-cc} -o conftest -v $CFLAGS '"$xe_ldflags"' conftest.$ac_ext 2>&1 1>/dev/null'
2228     for arg in `eval "$xe_runpath_link" | grep ' -L'`; do
2229       case "$arg" in P,* | -L* | -R* )
2230         for dir in `echo '' "$arg" | sed -e 's:^ ::' -e 's/^..//' -e 'y/:/ /'`; do
2231           XE_ADD_RUNPATH_DIR("$dir")
2232         done ;;
2233       esac
2234     done
2235     ld_switch_run="$ld_switch_run_save"
2236     rm -f conftest*
2237   else
2238     dnl Add all directories with .so files to runpath
2239     for arg in $ld_switch_site $ld_switch_x_site; do
2240       case "$arg" in -L*) XE_ADD_RUNPATH_DIR(`echo '' "$arg" | sed -e 's:^ ::' -e 's/^-L//'`);; esac
2241     done
2242     dnl Sometimes /opt/SUNWdt/lib is the only installed Motif available
2243     if test "$opsys $need_motif" = "sol2 yes"; then
2244       xe_runpath_dir="/opt/SUNWdt/lib";
2245       eval "$xe_add_unique_runpath_dir";
2246     fi
2247   fi dnl Compute $runpath
2248
2249   if test -n "$runpath"; then
2250     ld_switch_run="${dash_r}${runpath}"
2251     XE_PROTECT_LINKER_FLAGS(ld_switch_run)
2252     test "$extra_verbose" = "yes" && echo "Setting runpath to $runpath"
2253   fi
2254 fi
2255 ])dnl
2256 XE_COMPUTE_RUNPATH()
2257
2258 dnl JKJ REMOVEME
2259 dnl XE_SHLIB_STUFF
2260
2261 dnl -----------------------------------
2262 dnl Do some misc autoconf-special tests
2263 dnl -----------------------------------
2264
2265 dnl Do the opsystem or machine files prohibit the use of the GNU malloc?
2266 dnl Assume not, until told otherwise.
2267 GNU_MALLOC=yes
2268 if test "$with_dlmalloc" != "no"; then
2269         doug_lea_malloc=yes
2270 else
2271         doug_lea_malloc=no
2272 fi
2273 after_morecore_hook_exists=yes
2274 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
2275 AC_MSG_CHECKING(whether __after_morecore_hook exists)
2276 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
2277   [AC_MSG_RESULT(yes)],
2278   [AC_MSG_RESULT(no)
2279    after_morecore_hook_exists=no])
2280 if test "$system_malloc" = "yes" ; then
2281   GNU_MALLOC=no
2282   GNU_MALLOC_reason="
2283     - The GNU allocators don't work with this system configuration."
2284 elif test "$with_system_malloc" = "yes" ; then
2285   GNU_MALLOC=no
2286   GNU_MALLOC_reason="
2287     - User chose not to use GNU allocators."
2288 elif test "$with_debug_malloc" = "yes" ; then
2289   GNU_MALLOC=no
2290   GNU_MALLOC_reason="
2291     - User chose to use Debugging Malloc."
2292 fi
2293
2294 if test "$doug_lea_malloc" = "yes" -a "$GNU_MALLOC" = "yes" ; then
2295   GNU_MALLOC_reason="
2296     - Using Doug Lea's new malloc from the GNU C Library."
2297   AC_DEFINE(DOUG_LEA_MALLOC)
2298   if test "$after_morecore_hook_exists" = "no" ; then
2299     GNU_MALLOC_reason="
2300     - Using Doug Lea's new malloc from the Linux C Library."
2301     AC_DEFINE(_NO_MALLOC_WARNING_)
2302   fi
2303 fi
2304
2305 dnl #### mcheck is broken in all versions of Linux libc and glibc.
2306 dnl Try this again when 2.1 hits the streets.
2307 dnl Avoid using free-hook.c if support exists for malloc debugging in libc
2308 dnl have_libmcheck=no
2309 dnl if test "$error_check_malloc" = "yes" -a \
2310 dnl    "$have_glibc" = "yes" -a \
2311 dnl    "$doug_lea_malloc" = "yes"; then
2312 dnl   AC_CHECK_HEADERS(mcheck.h)
2313 dnl   AC_CHECK_LIB(mcheck, mcheck, have_libmcheck=yes, have_libmcheck=no)
2314 dnl fi
2315
2316 dnl if test "$have_libmcheck" = "yes"; then
2317 dnl   AC_DEFINE(HAVE_LIBMCHECK)
2318 dnl   libmcheck=-lmcheck
2319 dnl   AC_SUBST(libmcheck)
2320 dnl fi
2321
2322 dnl Some other nice autoconf tests.  If you add a test here which
2323 dnl should make an entry in src/config.h, do not forget to add an
2324 dnl #undef clause to src/config.h.in for autoconf to modify.
2325
2326 AC_PROG_RANLIB
2327 AC_PROG_INSTALL
2328 AC_PROG_YACC
2329
2330 dnl checks for header files
2331 AC_CHECK_HEADERS(dnl
2332   a.out.h dnl
2333   cygwin/version.h dnl
2334   fcntl.h dnl
2335   inttypes.h dnl
2336   libgen.h dnl
2337   locale.h dnl
2338   mach/mach.h dnl
2339   sys/param.h dnl
2340   sys/pstat.h dnl
2341   sys/stropts.h dnl
2342   sys/time.h dnl
2343   sys/timeb.h dnl
2344   sys/un.h dnl
2345   kstat.h dnl
2346   ulimit.h dnl
2347   unistd.h dnl
2348   utime.h dnl
2349 )
2350 AC_HEADER_SYS_WAIT
2351 AC_HEADER_STDC
2352 AC_HEADER_TIME
2353 AC_DECL_SYS_SIGLIST
2354
2355 dnl Some systems have utime.h but do not declare the struct anyplace.
2356 AC_MSG_CHECKING(for struct utimbuf)
2357 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2358 #include <sys/time.h>
2359 #include <time.h>
2360 #else
2361 #ifdef HAVE_SYS_TIME_H
2362 #include <sys/time.h>
2363 #else
2364 #include <time.h>
2365 #endif
2366 #endif
2367 #ifdef HAVE_UTIME_H
2368 #include <utime.h>
2369 #endif], [static struct utimbuf x; x.actime = x.modtime;],
2370   [AC_MSG_RESULT(yes)
2371    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
2372   AC_MSG_RESULT(no))
2373
2374 dnl checks for typedefs
2375 AC_TYPE_SIGNAL
2376 AC_TYPE_SIZE_T
2377 AC_TYPE_PID_T
2378 AC_TYPE_UID_T
2379 AC_TYPE_MODE_T
2380 AC_TYPE_OFF_T
2381 AC_CHECK_TYPE(ssize_t, int)
2382
2383 AC_MSG_CHECKING(for struct timeval)
2384 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2385 #include <sys/time.h>
2386 #include <time.h>
2387 #else
2388 #ifdef HAVE_SYS_TIME_H
2389 #include <sys/time.h>
2390 #else
2391 #include <time.h>
2392 #endif
2393 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
2394   [AC_MSG_RESULT(yes)
2395   HAVE_TIMEVAL=yes
2396   AC_DEFINE(HAVE_TIMEVAL)],
2397   [AC_MSG_RESULT(no)
2398    HAVE_TIMEVAL=no])
2399
2400 dnl checks for structure members
2401 AC_STRUCT_TM
2402 AC_STRUCT_TIMEZONE
2403
2404 dnl checks for compiler characteristics
2405 AC_C_CONST
2406
2407 dnl check for Make feature
2408 AC_PROG_MAKE_SET
2409
2410 dnl check byte order
2411 AC_C_BIGENDIAN
2412
2413 dnl define SIZEOF_TYPE
2414 AC_CHECK_SIZEOF(short)
2415 if test "$ac_cv_sizeof_short" = 0; then
2416   echo ""
2417   echo "*** PANIC *** Configure tests are not working - compiler is broken."
2418   echo "*** PANIC *** Please examine config.log for compilation errors."
2419   exit 1
2420 fi
2421 AC_CHECK_SIZEOF(int)
2422 AC_CHECK_SIZEOF(long)
2423 AC_CHECK_SIZEOF(long long)
2424 AC_CHECK_SIZEOF(void *)
2425
2426 dnl check for long file names
2427 AC_SYS_LONG_FILE_NAMES
2428
2429 dnl -lm is required by LISP_FLOAT_TYPE, among other things
2430 AC_CHECK_FUNC(sin, ,AC_CHECK_LIB(m, sin))
2431
2432 dnl Floating operation support is now unconditional
2433 AC_DEFINE(LISP_FLOAT_TYPE)
2434
2435 AC_TRY_LINK([#include <math.h>],
2436   [return atanh(1.0) + asinh(1.0) + acosh(1.0); ],
2437   AC_DEFINE(HAVE_INVERSE_HYPERBOLIC))
2438
2439 dnl Determine type of mail locking from configure args and s&m headers
2440 AC_CHECKING(type of mail spool file locking)
2441 AC_CHECK_FUNCS(lockf flock)
2442 dnl The mail_use_xxx variables are set according to the s&m headers.
2443 test -z "$mail_locking" -a "$mail_use_flock" = "yes" && mail_locking=flock
2444 test -z "$mail_locking" -a "$mail_use_lockf" = "yes" && mail_locking=lockf
2445 test -z "$mail_locking" -a "$mail_use_locking" = "yes" && mail_locking=locking
2446 if   test "$mail_locking" = "lockf"; then AC_DEFINE(MAIL_LOCK_LOCKF)
2447 elif test "$mail_locking" = "flock"; then AC_DEFINE(MAIL_LOCK_FLOCK)
2448 elif test "$mail_locking" = "locking"; then AC_DEFINE(MAIL_LOCK_LOCKING)
2449 else mail_locking="dot-locking"; AC_DEFINE(MAIL_LOCK_DOT)
2450 fi
2451 test "$mail_locking" = "lockf" -a "$ac_cv_func_lockf" != "yes" && \
2452   XE_DIE("lockf mail locking requested but not available.")
2453 test "$mail_locking" = "flock" -a "$ac_cv_func_flock" != "yes" && \
2454   XE_DIE("flock mail locking requested but not available.")
2455 test "$mail_locking" = "locking" -a "$ac_cv_func_locking" != "yes" && \
2456   XE_DIE("locking mail locking requested but not available.")
2457
2458 case "$opsys" in decosf*)
2459   AC_CHECK_LIB(pthreads, cma_open)
2460   test "$ac_cv_lib_pthreads_cma_open" = "yes" && \
2461     c_switch_site="$c_switch_site -threads" ;;
2462 esac
2463
2464 AC_MSG_CHECKING(whether the -xildoff compiler flag is required)
2465 if   ${CC-cc} '-###' -xildon  no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ; then
2466   if ${CC-cc} '-###' -xildoff no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ;
2467     then AC_MSG_RESULT(no);
2468     else AC_MSG_RESULT(yes); XE_APPEND(-xildoff, ld_switch_site)
2469   fi
2470   else AC_MSG_RESULT(no)
2471 fi
2472
2473 dnl Link with "-z ignore" on Solaris if supported
2474 if test "$opsys" = "sol2"; then
2475   if test "$os_release" -ge 56; then
2476     AC_MSG_CHECKING(for \"-z ignore\" linker flag)
2477     case "`ld -h 2>&1`" in
2478       *-z\ ignore\|record* ) AC_MSG_RESULT(yes)
2479         XE_PREPEND(-z ignore, ld_switch_site) ;;
2480       *) AC_MSG_RESULT(no) ;;
2481     esac
2482   fi
2483 fi
2484
2485 dnl ----------------------
2486 dnl Choose a window system
2487 dnl ----------------------
2488
2489 AC_CHECKING("for specified window system")
2490
2491 if test "$with_x11" != "no"; then
2492   dnl User-specified --x-includes or --x-libraries implies --with-x11.
2493   test "$x_includes $x_libraries" != "NONE NONE" && \
2494    window_system=x11 with_x11=yes
2495
2496   dnl Autodetection of X11 libraries and includes
2497   dnl -------------------------------------------
2498   dnl AC_PATH_XTRA thinks it can find our X headers and includes, but
2499   dnl it often gets it wrong, so we only use it as a last resort.
2500
2501   dnl $OPENWINHOME implies --x-includes and --x-libraries
2502   dnl Not (yet) handled by autoconf2
2503   if test "$x_includes $x_libraries" = "NONE NONE" \
2504     -a -n "$OPENWINHOME" \
2505     -a "$OPENWINHOME" != "/usr/openwin" \
2506     -a -d "$OPENWINHOME"; then
2507       test -d "$OPENWINHOME/lib"           && x_libraries="$OPENWINHOME/lib"
2508       test -d "$OPENWINHOME/include"       && x_includes="$OPENWINHOME/include"
2509       test -d "$OPENWINHOME/share/include" && x_includes="$OPENWINHOME/share/include"
2510   fi
2511
2512   if test "$x_includes" = "NONE"; then
2513     dnl AC_PATH_XTRA often guesses /usr/include, when some other
2514     dnl include directory is a MUCH better guess (Linux, HP-UX 10.20).
2515     dnl This is a workaround for idiot (esp. HP) system vendors, who
2516     dnl provide a /usr/include/X11, but DON'T FULLY POPULATE IT.
2517     for dir in "/usr/X11" "/usr/X11R6"; do
2518       if test -d "$dir/include/X11"; then x_includes="$dir/include"; break; fi
2519     done
2520   fi
2521
2522   if test "$x_libraries" = "NONE"; then
2523     for dir in "/usr/X11/lib" "/usr/X11R6/lib" "/usr/lib/X11R6"; do
2524       if test -r "$dir/libX11.a"; then x_libraries="$dir"; break; fi
2525     done
2526   fi
2527
2528   AC_PATH_XTRA # Autoconf claims to find X library and include dirs for us.
2529   if test "$no_x" = "yes"
2530   then with_x11=no  window_system=none HAVE_X_WINDOWS=no
2531   else with_x11=yes window_system=x11  HAVE_X_WINDOWS=yes
2532   fi
2533 fi
2534
2535 case "$with_x11" in
2536   yes ) window_system=x11  HAVE_X_WINDOWS=yes ;;
2537   no  ) window_system=none HAVE_X_WINDOWS=no  ;;
2538 esac
2539
2540 if test "$with_x11" = "yes"; then
2541   AC_DEFINE(HAVE_X_WINDOWS)
2542   XE_APPEND(lwlib, MAKE_SUBDIR)
2543   XE_APPEND(lwlib, SRC_SUBDIR_DEPS)
2544
2545   dnl Try to find Motif/CDE/Tooltalk dirs
2546   dnl These take precedence over other X libs/includes, so PRE-pend
2547   for lib_dir in "/usr/dt/lib" "/usr/lib/Motif2.1" "/usr/lib/Motif1.2" "/usr/lib/Motif1.1"; do
2548     inc_dir=`echo $lib_dir | sed -e 's/lib/include/'`
2549     if test -d "$lib_dir" -a -d "$inc_dir"; then
2550       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2551         x_libraries="$lib_dir $x_libraries"
2552         XE_PREPEND(-L${lib_dir}, X_LIBS) ;;
2553       esac
2554       case "$x_includes" in "$inc_dir"* ) ;; *)
2555         x_includes="$inc_dir $x_includes"
2556         XE_PREPEND(-I${inc_dir}, X_CFLAGS) ;;
2557       esac
2558       break; dnl only need ONE Motif implementation!
2559       fi
2560   done
2561
2562   dnl Contrib X libs/includes do NOT take precedence, so AP-pend
2563   for rel in "X11R6" "X11R5" "X11R4"; do
2564     lib_dir="/usr/contrib/$rel/lib" inc_dir="/usr/contrib/$rel/include"
2565     if test -d "$lib_dir" -a -d "$inc_dir"; then
2566       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2567         x_libraries="$x_libraries $lib_dir"
2568         XE_APPEND(-L${lib_dir}, X_LIBS)
2569       esac
2570       case "$x_includes" in "$inc_dir"* ) ;; *)
2571         x_includes="$x_includes $inc_dir"
2572         XE_APPEND(-I${inc_dir}, X_CFLAGS)
2573       esac
2574       break; dnl Only need ONE X11 implementation !
2575     fi
2576   done
2577
2578   dnl Avoid version mismatch for shared library libXm.so on osf4
2579   if test "$GCC" = yes -a -d /usr/shlib; then XE_APPEND(-L/usr/shlib, X_LIBS); fi
2580
2581   ld_switch_x_site="$X_LIBS"
2582
2583   XE_COMPUTE_RUNPATH()
2584
2585   if test "$extra_verbose" = "yes"; then
2586     echo; echo "X11 compilation variables:"
2587     PRINT_VAR(x_libraries x_includes X_CFLAGS X_LIBS X_PRE_LIBS X_EXTRA_LIBS)
2588     echo
2589   fi
2590
2591   dnl Set up bitmaps search path.
2592   dnl The original suggestion was to unconditionally to append X11/bitmaps
2593   dnl to each element of $x_includes, I'm pretty sure this is the wrong
2594   dnl thing to do.  We test for bitmaps and X11/bitmaps directories on each
2595   dnl element and add them to BITMAPDIR if they exist.
2596   bitmapdirs=
2597   if test "$x_includes" != NONE; then
2598     for i in $x_includes; do
2599       if test -d "$i/bitmaps"; then
2600         bitmapdirs="$i/bitmaps:$bitmapdirs"
2601       fi
2602       if test -d "$i/X11/bitmaps"; then
2603         bitmapdirs="$i/X11/bitmaps:$bitmapdirs"
2604       fi
2605     done
2606     bitmapdirs=`echo "$bitmapdirs" | sed s/.$//`
2607   fi
2608   test ! -z "$bitmapdirs" && AC_DEFINE_UNQUOTED(BITMAPDIR, "$bitmapdirs")
2609
2610   dnl Autodetect defines extracted from X config by xmkmf, e.g. NARROWPROTO
2611   AC_CHECKING(for X defines extracted by xmkmf)
2612   rm -fr conftestdir
2613   if mkdir conftestdir; then
2614     cd conftestdir
2615     cat > Imakefile <<'EOF'
2616 xetest:
2617         @echo ${PROTO_DEFINES} ${STD_DEFINES}
2618 EOF
2619     if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
2620       # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
2621       xmkmf_defines=`${MAKE-make} xetest 2>/dev/null | grep -v make`
2622     fi
2623     cd ..
2624     rm -fr conftestdir
2625     for word in $xmkmf_defines; do
2626       case "$word" in
2627         -D*=* ) ;;
2628         -D* ) word=`echo '' $word | sed -e 's:^ *-D::'`
2629               AC_DEFINE_UNQUOTED($word) ;;
2630       esac
2631     done
2632   fi
2633
2634   dnl make sure we can find Intrinsic.h
2635   AC_CHECK_HEADER(X11/Intrinsic.h, ,
2636    [AC_MSG_ERROR("Unable to find X11 header files.")])
2637
2638   dnl -lXt and -lX11 are required
2639   dnl Some broken systems require the magic "-b i486-linuxaout" flag
2640   AC_CHECK_LIB(X11, XOpenDisplay, have_lib_x11=yes)
2641   if test "$have_lib_x11" != "yes"; then
2642     AC_CHECK_LIB(X11, XGetFontProperty,
2643       ld_switch_x_site="-b i486-linuxaout $ld_switch_x_site",
2644       [AC_MSG_ERROR("Unable to find X11 libraries.")],
2645       -b i486-linuxaout)
2646   fi
2647   libs_x="-lX11"
2648   test "$extra_verbose" = "yes" && echo "    Setting libs_x to \"-lX11\""
2649
2650   dnl Autodetect -lXext
2651   AC_CHECK_LIB(Xext, XShapeSelectInput, XE_PREPEND(-lXext, libs_x))
2652
2653   dnl Require -lXt
2654   AC_CHECK_LIB(Xt, XtOpenDisplay, XE_PREPEND(-lXt, libs_x),
2655     AC_MSG_ERROR("Unable to find X11 libraries."))
2656
2657   AC_MSG_CHECKING(the version of X11 being used)
2658   AC_TRY_RUN([#include <X11/Intrinsic.h>
2659     int main(int c, char *v[]) { return c>1 ? XlibSpecificationRelease : 0; }],
2660     [./conftest foobar; x11_release=$?],[x11_release=4],[x11_release=4])
2661   AC_MSG_RESULT(R${x11_release})
2662   AC_DEFINE_UNQUOTED(THIS_IS_X11R${x11_release})
2663
2664   AC_CHECK_FUNCS(XConvertCase)
2665
2666   AC_CHECK_HEADERS(X11/Xlocale.h)
2667
2668   dnl remove this - we should avoid checking for specific OS
2669   AC_MSG_CHECKING(for XFree86)
2670   if test -d "/usr/X386/include" -o \
2671           -f "/etc/XF86Config"    -o \
2672           -f "/etc/X11/XF86Config" -o \
2673           -f "/usr/X11R6/lib/X11/XF86Config"; then
2674     AC_MSG_RESULT(yes)
2675     AC_DEFINE(HAVE_XFREE386)
2676   else
2677     AC_MSG_RESULT(no)
2678   fi
2679
2680   dnl autodetect -lXmu
2681   test -z "$with_xmu" && { AC_CHECK_LIB(Xmu, XmuReadBitmapDataFromFile,
2682                            with_xmu=yes, with_xmu=no) }
2683   if test "$with_xmu" = "no"; then
2684     XE_ADD_OBJS(xmu.o)
2685   else
2686     XE_PREPEND(-lXmu, libs_x)
2687     AC_DEFINE(HAVE_XMU)
2688   fi
2689
2690   dnl Autodetect -lXbsd
2691   dnl #### Someone, please add a better function than main
2692   AC_CHECK_LIB(Xbsd, main, XE_PREPEND(-lXbsd, libs_x))
2693
2694   dnl Problem with the MIT distribution of X on AIX
2695   if test "$unexec" = "unexaix.o" -a "$x11_release" = "6"; then
2696     dnl X11R6 requires thread-safe code on AIX for some reason
2697     if test "$GCC" = "yes"; then
2698       XE_PREPEND(-mthreads, X_CFLAGS)
2699       XE_PREPEND(-mthreads, libs_x)
2700     else
2701       case "$CC" in
2702         "xlc" ) CC="xlc_r" ;;
2703         "xlC" ) CC="xlC_r" ;;
2704         "cc"  ) CC="cc_r" ;;
2705       esac
2706     fi
2707   fi
2708
2709 fi dnl $with_x11 = yes
2710
2711 if test "$with_msw" != "no"; then
2712   AC_CHECKING(for MS-Windows)
2713   AC_CHECK_LIB(gdi32,main,with_msw=yes)
2714   if test "$with_msw" = "yes"; then
2715     AC_DEFINE(HAVE_MS_WINDOWS)
2716     install_pp="$blddir/lib-src/installexe.sh"
2717     XE_APPEND(-lshell32 -lgdi32 -luser32 -lcomctl32 -lwinspool, libs_system)
2718     test "$with_dragndrop" != no && XE_APPEND(msw, dragndrop_proto)
2719     if test "$window_system" != x11; then
2720         window_system=msw
2721         test "$with_scrollbars" != "no" && with_scrollbars=msw \
2722             && XE_ADD_OBJS(scrollbar-msw.o)
2723         test "$with_menubars"   != "no" && with_menubars=msw \
2724             && XE_ADD_OBJS(menubar-msw.o)
2725         test "$with_toolbars"   != "no" && with_toolbars=msw \
2726             && XE_ADD_OBJS(toolbar-msw.o)
2727         test "$with_dialogs"   != "no" && with_dialogs=msw \
2728             && XE_ADD_OBJS(dialog-msw.o)
2729         test "$with_widgets"   != "no" && with_widgets=msw
2730     else
2731         test "$with_scrollbars" != "no" && XE_ADD_OBJS(scrollbar-msw.o)
2732         test "$with_menubars"   != "no" && XE_ADD_OBJS(menubar-msw.o)
2733         test "$with_toolbars"   != "no" && XE_ADD_OBJS(toolbar-msw.o)
2734         test "$with_dialogs"    != "no" && XE_ADD_OBJS(dialog-msw.o)
2735     fi
2736     dnl check for our special version of select
2737     AC_TRY_RUN([#include <fcntl.h>
2738     int main() { return (open("/dev/windows", O_RDONLY, 0) > 0)? 0 : 1; }],
2739     [AC_DEFINE(HAVE_MSG_SELECT)])
2740     with_file_coding=yes
2741     XE_ADD_OBJS(console-msw.o device-msw.o event-msw.o frame-msw.o objects-msw.o select-msw.o redisplay-msw.o glyphs-msw.o gui-msw.o)
2742   fi
2743 fi
2744
2745 AC_SUBST(install_pp)
2746
2747 test -z "$window_system" && window_system="none"
2748
2749 dnl Test for features that require a window system - ANY window system
2750 if test "$window_system" = "none"; then
2751   for feature in menubars scrollbars toolbars dialogs dragndrop xface
2752   do
2753     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2754        AC_MSG_WARN([--with-$feature ignored:  Not valid without window system support])
2755     fi
2756     eval "with_${feature}=no"
2757   done
2758 else
2759   test -z "$with_toolbars" && with_toolbars=yes
2760 fi
2761
2762 dnl ### Test for features that require mswindows support - currently none
2763 dnl ### MS-Windows folks: add code here..... (martin)
2764 if test "$with_msw" != "yes"; then
2765   for feature in   MARTIN_IS_CLUELESS_ABOUT_MSW_FEATURES
2766   do
2767     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2768        AC_MSG_WARN([--with-$feature ignored:  Not valid without MS-Windows support])
2769     fi
2770     eval "with_${feature}=no"
2771   done
2772 else
2773   :
2774 fi
2775
2776 dnl Test for features that require X11 support
2777 if test "$with_x11" != "yes"; then
2778   dnl It ought to be reasonable to have no output device at all, and only use
2779   dnl XEmacs in --batch mode.
2780   dnl if test "$with_tty" = "no" ; then
2781   dnl   AC_MSG_ERROR([No window system support and no TTY support - Unable to proceed.])
2782   dnl fi
2783   for feature in tooltalk cde offix wmcommand xim xmu nas_sound
2784   do
2785     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2786        AC_MSG_WARN([--with-$feature ignored:  Not valid without X support])
2787     fi
2788     eval "with_${feature}=no"
2789   done
2790 fi
2791
2792 dnl FSF 19.29 has some bitmapdir stuff here.
2793 bitmapdir=
2794
2795 case "$window_system" in
2796   x11  ) HAVE_X_WINDOWS=yes; echo "  Using X11." ;;
2797   msw  ) HAVE_X_WINDOWS=no ; echo "  Using MS-Windows." ;;
2798   none ) HAVE_X_WINDOWS=no ; echo "  Using no window system." ;;
2799 esac
2800
2801 case "$x_libraries" in *X11R4* )
2802   test "$opsys" = "hpux9"     && opsysfile="s/hpux9-x11r4.h"
2803   test "$opsys" = "hpux9-shr" && opsysfile="s/hpux9shxr4.h"
2804 esac
2805
2806 dnl Enable or disable proper handling of WM_COMMAND
2807 AC_CHECKING(for WM_COMMAND option);
2808 dnl if test "$with_wmcommand" = "yes"; then
2809 if test "$with_wmcommand" != "no"; then
2810   AC_DEFINE(HAVE_WMCOMMAND)
2811 fi
2812
2813 dnl Autodetect Xauth
2814 dnl -lXau is only used by gnuclient, so use a special variable for Xauth X libs
2815 test -z "$with_xauth" && test "$window_system" = "none" && with_xauth=no
2816 test -z "$with_xauth" && { AC_CHECK_HEADER(X11/Xauth.h,          ,with_xauth=no) }
2817 test -z "$with_xauth" && { AC_CHECK_LIB(Xau, XauGetAuthByAddr,[:],with_xauth=no) }
2818 test -z "$with_xauth" && with_xauth=yes
2819 if test "$with_xauth" = "yes"; then
2820   AC_DEFINE(HAVE_XAUTH)
2821   XE_SPACE(libs_xauth, $X_EXTRA_LIBS -lXau $libs_x $X_PRE_LIBS)
2822 fi
2823 AC_SUBST(libs_xauth)
2824
2825 dnl This one is for the static initializeds variables in
2826 dnl offix.c, so that the thing is dumped after lastfile.o
2827 AC_SUBST(dnd_objs)
2828
2829 dnl Autodetect tooltalk
2830 if test "$with_tooltalk" != "no" ; then
2831   dnl autodetect the location of tt_c.h
2832   dnl tt_c.h might be in Tt or desktop include directories
2833   for dir in "" "Tt/" "desktop/" ; do
2834     AC_CHECK_HEADER(${dir}tt_c.h, tt_c_h_file="${dir}tt_c.h"; break)
2835   done
2836   if test -z "$tt_c_h_file"; then
2837     if test "$with_tooltalk" = "yes"; then
2838       USAGE_ERROR("Unable to find required tooltalk header files.")
2839     fi
2840     with_tooltalk=no
2841   fi
2842 fi
2843 if test "$with_tooltalk" != "no" ; then
2844   for extra_libs in "" "-lI18N -lce" "-lcxx"; do
2845     AC_CHECK_LIB(tt, tt_message_create,
2846       tt_libs="-ltt $extra_libs"; break, [:],$extra_libs)
2847   done
2848   if test -z "$tt_libs"; then
2849     if test "$with_tooltalk" = "yes"; then
2850       USAGE_ERROR("Unable to find required tooltalk libraries.")
2851     fi
2852     with_tooltalk=no
2853   fi
2854 fi
2855 test -z "$with_tooltalk" && with_tooltalk=yes
2856 if test "$with_tooltalk" = "yes"; then
2857   AC_DEFINE(TOOLTALK)
2858   AC_DEFINE_UNQUOTED(TT_C_H_FILE, "$tt_c_h_file")
2859   XE_PREPEND($tt_libs, libs_x)
2860   XE_ADD_OBJS(tooltalk.o)
2861 fi
2862
2863 dnl Autodetect CDE
2864 test -z "$with_cde" && { AC_CHECK_HEADER(Dt/Dt.h,               , with_cde=no) }
2865 test -z "$with_cde" && { AC_CHECK_LIB(DtSvc, DtDndDragStart, [:], with_cde=no) }
2866 test -z "$with_cde" && with_cde=yes
2867 if test "$with_dragndrop" = no; then
2868   AC_MSG_WARN([No CDE without generic Drag'n'Drop support])
2869   with_cde=no
2870 fi
2871 if test "$with_cde" = "yes" ; then
2872   AC_DEFINE(HAVE_CDE)
2873   XE_PREPEND(-lDtSvc, libs_x)
2874   XE_APPEND(CDE, dragndrop_proto)
2875   with_tooltalk=yes # CDE requires Tooltalk
2876   need_motif=yes    # CDE requires Motif
2877 fi
2878
2879 dnl Always compile OffiX unless --without-offix is given, no
2880 dnl X11 support is compiled in, no standard Xmu is available,
2881 dnl or dragndrop support is disabled
2882 dnl Because OffiX support currently loses when more than one display
2883 dnl is in use, we now disable it by default -slb 07/10/1998.
2884 test "$window_system" != "x11" && with_offix=no
2885 if test "$with_xmu" != yes -a "$with_x11" = yes; then
2886   AC_MSG_WARN([No OffiX without real Xmu support])
2887   with_offix=no
2888 fi
2889 if test "$with_dragndrop" = no; then
2890   AC_MSG_WARN([No OffiX without generic Drag'n'Drop support])
2891   with_offix=no
2892 fi
2893 if test "$with_cde" = yes; then
2894   AC_MSG_WARN([CDE already found, disabling OffiX support])
2895   with_offix=no
2896 fi
2897 test -z "$with_offix" && with_offix=no
2898 if test "$with_offix" = "yes"; then
2899   AC_DEFINE(HAVE_OFFIX_DND)
2900   XE_APPEND(offix.o, dnd_objs)
2901   XE_APPEND(OffiX, dragndrop_proto)
2902 fi
2903
2904 dnl Autodetect Drag'n'Drop support
2905 dnl always included if CDE, Offix, or MSWindows are defined
2906 AC_MSG_CHECKING(if drag and drop API is needed)
2907 if test "$with_dragndrop" != "no" ; then
2908   if test -n "$dragndrop_proto" ; then
2909     with_dragndrop=yes
2910     AC_MSG_RESULT([yes (${dragndrop_proto} )])
2911     AC_DEFINE(HAVE_DRAGNDROP)
2912     XE_APPEND(dragdrop.o, extra_objs)
2913   else
2914     with_dragndrop=no
2915     AC_MSG_RESULT(no)
2916   fi
2917 fi
2918
2919 dnl Autodetect LDAP
2920 AC_CHECKING(for LDAP)
2921 test -z "$with_ldap" && { AC_CHECK_HEADER(ldap.h, ,with_ldap=no) }
2922 test -z "$with_ldap" && { AC_CHECK_HEADER(lber.h, ,with_ldap=no) }
2923 if test "$with_ldap" != "no"; then
2924   AC_CHECK_LIB(ldap, ldap_search, with_ldap_nolber=yes, with_ldap_nolber=no)
2925   test "$with_ldap_nolber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_lber=yes, with_ldap_lber=no, -llber) }
2926   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krb=yes, with_ldap_krb=no, -llber -lkrb) }
2927   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" -a "$with_ldap_krb" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krbdes=yes, with_ldap_krbdes=no, -llber -lkrb -ldes) }
2928   test -z "$with_ldap" -a \( "$with_ldap_lber" = "yes" -o "$with_ldap_nolber" = "yes" -o "$with_ldap_krb" = "yes" -o "$with_ldap_krbdes" = "yes" \) && with_ldap=yes
2929 fi
2930 if test "$with_ldap" = "yes"; then
2931   AC_DEFINE(HAVE_LDAP)
2932   XE_ADD_OBJS(eldap.o)
2933   if test "$with_ldap_nolber" = "yes" ; then
2934     XE_PREPEND(-lldap, LIBS)
2935   else
2936     if test "$with_ldap_krb" = "yes" ; then
2937       XE_PREPEND(-lkrb, LIBS)
2938     fi
2939     if test "$with_ldap_krbdes" = "yes" ; then
2940       XE_PREPEND(-ldes, LIBS)
2941       XE_PREPEND(-lkrb, LIBS)
2942     fi
2943     XE_PREPEND(-llber, LIBS)
2944     XE_PREPEND(-lldap, LIBS)
2945   fi
2946   AC_CHECK_FUNCS(ldap_set_option ldap_get_lderrno ldap_result2error ldap_parse_result)
2947 fi
2948
2949 dnl Autodetect PostgreSQL
2950 dnl The default installation location (non-Linux) is /usr/local/pgsql;
2951 dnl  a different prefix can be selected at build/install time.  If PostgreSQL
2952 dnl  is installed into a different prefix, that prefix must be specified in
2953 dnl  in the --site-prefixes flag.
2954 dnl The default RPM-based Linux installation location is /usr.
2955 AC_CHECKING(for PostgreSQL)
2956 postgres_h_path=""
2957 postgres_includes_found=no
2958 save_c_switch_site="$c_switch_site"
2959
2960 dnl First, test standard location and site prefixes only:
2961 if test "$with_postgresql" != "no"; then
2962         AC_CHECK_HEADER(libpq-fe.h,postgres_includes_found=yes)
2963 fi
2964
2965 dnl Otherwise, test different known headers locations on linux:
2966 if test "$postgres_includes_found" = "no" -a "$with_postgresql" != "no" -a \
2967         -d "/usr/local/pgsql/include"; then
2968         c_switch_site="$c_switch_site -I/usr/local/pgsql/include"
2969         AC_CHECK_HEADER(libpq-fe.h,postgres_includes_found=yes)
2970         if test "$postgres_includes_found" != "yes"; then
2971                 postgres_h_path="/usr/local/pgsql/include"
2972         fi
2973         c_switch_site="$save_c_switch_site"
2974 fi
2975 if test "$postgres_includes_found" = "no" -a "$with_postgresql" != "no" -a \
2976         -d "/usr/include/pgsql"; then
2977         c_switch_site="$c_switch_site -I/usr/include/pgsql"
2978         AC_CHECK_HEADER(libpq-fe.h,postgres_includes_found=yes)
2979         if test "$postgres_includes_found" = "yes"; then
2980                 postgres_h_path="pgsql"
2981         fi
2982                 c_switch_site="$save_c_switch_site"
2983         fi
2984 if test "$postgres_includes_found" = "no" -a "$with_postgresql" != "no" -a \
2985         -d "/usr/include/postgresql"; then
2986         c_switch_site="$c_switch_site -I/usr/include/postgresql"
2987         AC_CHECK_HEADER(libpq-fe.h,postgres_includes_found=yes)
2988         if test "$postgres_includes_found" = "yes"; then
2989                 postgres_h_path="postgresql"
2990 fi
2991         c_switch_site="$save_c_switch_site"
2992 fi
2993
2994 dnl Finally, check if we can link with libpq:
2995 if test "$postgres_includes_found" = "yes"; then
2996         AC_CHECK_LIB(pq,PQconnectdb,with_postgresql=yes,with_postgresql=no)
2997 fi
2998 if test "$with_postgresql" = "yes"; then
2999         AC_CHECK_LIB(pq,PQconnectStart,with_postgresqlv7=yes,with_postgresqlv7=no)
3000 fi
3001 if test "$with_postgresql" = "yes"; then
3002         if test -n "$postgres_h_path"; then
3003                 AC_DEFINE_UNQUOTED(POSTGRES_H_PATH, $postgres_h_path)
3004         fi
3005         AC_DEFINE(HAVE_POSTGRESQL)
3006         if test "$with_postgresqlv7" = "yes"; then
3007                 AC_DEFINE(HAVE_POSTGRESQLV7)
3008         fi
3009         XE_PREPEND(-lpq, LIBS)
3010         XE_ADD_OBJS(postgresql.o)
3011 fi
3012
3013 dnl ----------------------
3014 dnl Graphics libraries
3015 dnl ----------------------
3016
3017 if test "$window_system" != "none"; then
3018   AC_CHECKING(for graphics libraries)
3019
3020   dnl Autodetect Xpm
3021   xpm_problem=""
3022   if test -z "$with_xpm"; then
3023     AC_MSG_CHECKING(for Xpm - no older than 3.4f)
3024     xe_check_libs=-lXpm
3025     AC_TRY_RUN([#define XPM_NUMBERS
3026 #include <X11/xpm.h>
3027     int main(int c, char **v) {
3028     return c == 1 ? 0 :
3029       XpmIncludeVersion != XpmLibraryVersion() ? 1 :
3030       XpmIncludeVersion < 30406 ? 2 : 0 ;}],
3031     [./conftest dummy_arg; xpm_status=$?;
3032       if test "$xpm_status" = "0"; then
3033         with_xpm=yes;
3034       else
3035         with_xpm=no;
3036         if test "$xpm_status" = "1"; then
3037           xpm_problem="Xpm library version and header file version don't match!"
3038         elif test "$xpm_status" = "2"; then
3039           xpm_problem="Xpm library version is too old!"
3040         else
3041           xpm_problem="Internal xpm detection logic error!"
3042         fi
3043         echo "
3044 *** WARNING *** $xpm_problem
3045   I'm not touching that with a 10-foot pole!
3046   If you really want to use the installed version of Xpm, rerun
3047   configure and add '--with-xpm=yes', but don't blame me if XEmacs crashes!"
3048     fi],
3049     [with_xpm=no])
3050     xe_check_libs=
3051     AC_MSG_RESULT($with_xpm)
3052   fi
3053   if test "$with_xpm" = "yes"; then
3054     AC_DEFINE(HAVE_XPM)
3055     XE_PREPEND(-lXpm, libs_x)
3056     AC_MSG_CHECKING(for \"FOR_MSW\" xpm)
3057     xe_check_libs=-lXpm
3058     AC_TRY_LINK(, [XpmCreatePixmapFromData()],
3059     [xpm_for_msw=no],
3060     [xpm_for_msw=yes])
3061     xe_check_libs=
3062     AC_MSG_RESULT($xpm_for_msw)
3063     if test "$xpm_for_msw" = "yes"; then
3064       AC_DEFINE(FOR_MSW)
3065     fi
3066   fi
3067
3068   dnl Autodetect XFACE
3069   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
3070   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
3071   test -z "$with_xface" && with_xface=yes
3072   if test "$with_xface" = "yes"; then
3073     AC_DEFINE(HAVE_XFACE)
3074     XE_PREPEND(-lcompface, libs_x)
3075   fi
3076
3077   dnl For a brief period we had the GIF code split out into a separate library,
3078   dnl but patent problems, etc. sort of squashed that idea.
3079   dnl We default to building with builtin GIF decoding
3080   if test "$with_gif" != "no"; then
3081     with_gif="yes"
3082     AC_DEFINE(HAVE_GIF)
3083     XE_ADD_OBJS(dgif_lib.o gif_io.o)
3084   fi
3085
3086   dnl Too many stupid linkers can't detect cascaded lib dependencies until runtime
3087   dnl So we always search for libz compression support.
3088   if test "$with_png $with_tiff" != "no no"; then
3089     AC_CHECK_LIB(c,  inflate, [:], [
3090     AC_CHECK_LIB(z,  inflate, [XE_PREPEND(-lz,  libs_x)],[
3091     AC_CHECK_LIB(gz, inflate, [XE_PREPEND(-lgz, libs_x)])])])
3092   fi
3093
3094   dnl autodetect JPEG
3095   test -z "$with_jpeg" && { AC_CHECK_HEADER(jpeglib.h,                    ,with_jpeg=no) }
3096   test -z "$with_jpeg" && { AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,[:],with_jpeg=no) }
3097   test -z "$with_jpeg" && with_jpeg=yes
3098   if test "$with_jpeg" = "yes"; then
3099     AC_DEFINE(HAVE_JPEG)
3100     XE_PREPEND(-ljpeg, libs_x)
3101   fi
3102
3103   dnl autodetect PNG
3104   png_problem=""
3105   test -z "$with_png" && { AC_CHECK_FUNC(pow,                  ,with_png=no) }
3106   test -z "$with_png" && { AC_CHECK_HEADER(png.h,              ,with_png=no) }
3107   test -z "$with_png" && { AC_CHECK_LIB(png, png_read_image,[:],with_png=no) }
3108   if test -z "$with_png"; then
3109     AC_MSG_CHECKING(for workable png version information)
3110     xe_check_libs="-lpng -lz"
3111     AC_TRY_RUN([#include <png.h>
3112     int main(int c, char **v) {
3113     if (c == 1) return 0;
3114     if (strcmp(png_libpng_ver, PNG_LIBPNG_VER_STRING) != 0) return 1;
3115     return (PNG_LIBPNG_VER < 10002) ? 2 : 0 ;}],
3116     [./conftest dummy_arg; png_status=$?;
3117       if test "$png_status" = "0"; then
3118         with_png=yes;
3119       else
3120         with_png=no;
3121         if test "$png_status" = "1"; then
3122           png_problem="PNG library version and header file don't match!"
3123         elif test "$png_status" = "2"; then
3124           png_problem="PNG library version too old (pre 1.0.2)!"
3125         fi
3126         echo "
3127 *** WARNING *** $png_problem
3128   I'm not touching that with a 10-foot pole!
3129   If you really want to use the installed version of libPNG, rerun
3130   configure and add '--with-png=yes', but don't blame me if XEmacs crashes!"
3131     fi],
3132     [with_png=no])
3133     xe_check_libs=
3134     AC_MSG_RESULT($with_png)
3135   fi
3136   if test "$with_png" = "yes"; then
3137     AC_DEFINE(HAVE_PNG)
3138     XE_PREPEND(-lpng, libs_x)
3139   fi
3140
3141   dnl autodetect TIFF
3142   test -z "$with_tiff" && { AC_CHECK_HEADER(tiffio.h,            ,with_tiff=no) }
3143   test -z "$with_tiff" && { AC_CHECK_LIB(tiff, TIFFClientOpen,[:],with_tiff=no) }
3144   test -z "$with_tiff" && with_tiff=yes
3145   if test "$with_tiff" = "yes"; then
3146     AC_DEFINE(HAVE_TIFF)
3147     XE_PREPEND(-ltiff, libs_x)
3148   fi
3149 fi
3150
3151 dnl ----------------------
3152 dnl X-Specific Graphics libraries
3153 dnl ----------------------
3154
3155 if test "$with_x11" = "yes"; then
3156
3157   AC_CHECKING(for X11 graphics libraries)
3158
3159   AC_CHECKING(for the Athena widgets)
3160
3161   dnl What in heck did the user actually want?
3162   case "$with_athena" in
3163     dnl This is the default, old fashioned flat Athena.
3164     "xaw" | "") athena_variant=Xaw      athena_3d=no  ;;
3165     "3d")       athena_variant=Xaw3d    athena_3d=yes ;;
3166     "next")     athena_variant=neXtaw   athena_3d=yes ;;
3167     "95")       athena_variant=Xaw95    athena_3d=yes ;;
3168     "xpm")      athena_variant=XawXpm   athena_3d=yes ;;
3169     *)          XE_DIE("Unknown Athena widget set \`$with_athena'. This should not happen.") ;;
3170   esac
3171
3172   dnl Search for the Athena library...
3173   if test "$athena_3d" = "no"; then
3174     AC_CHECK_LIB($athena_variant, XawScrollbarSetThumb,
3175       [
3176         dnl Must not be a 3d library...
3177         AC_CHECK_LIB($athena_variant, threeDClassRec,
3178           AC_MSG_WARN("Could not find a non-3d Athena widget library."),
3179           athena_lib=$athena_variant)
3180       ],
3181       AC_MSG_WARN("Could not find an Athena widget library."))
3182   else
3183     dnl The real configuration, need 3d library
3184     AC_CHECK_LIB($athena_variant, threeDClassRec, athena_lib=$athena_variant,
3185       dnl OK, couldn't find it with a proper name, try the standard Athena lib
3186       dnl If that is 3d, presume the user asked for what they have installed.
3187       AC_CHECK_LIB(Xaw, threeDClassRec,
3188         [
3189           athena_lib=Xaw;
3190           AC_MSG_WARN("Assuming that libXaw is actually $athena_variant.");
3191         ],
3192         AC_MSG_WARN("Could not find a 3d Athena widget library that looked like $athena_variant.")))
3193   fi
3194
3195   dnl Now we locate the Athena headers that we need.
3196   if test "$athena_3d" = "no"; then
3197     AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3198       AC_MSG_WARN("Could not find a non-3d Athena header set."),
3199       AC_CHECK_HEADER(X11/Xaw/XawInit.h,
3200         athena_h_path=X11/Xaw,
3201         AC_MSG_WARN("Could not find a non-3d Athena header set.")))
3202   else
3203     dnl The three-d Athena headers are so much more slippery.
3204     dnl Curse this `Lets replace standard libraries' thing that they did. :/
3205     AC_CHECK_HEADER(X11/$athena_variant/XawInit.h,
3206       AC_CHECK_HEADER(X11/$athena_variant/ThreeD.h,
3207         athena_h_path=X11/$athena_variant,))
3208
3209     dnl Is the variant specific header directory directly under include?
3210     if test -z "$athena_h_path"; then
3211       AC_CHECK_HEADER($athena_variant/XawInit.h,
3212         AC_CHECK_HEADER($athena_variant/ThreeD.h,
3213           athena_h_path=$athena_variant,))
3214     fi
3215
3216     dnl If we couldn't find the specific variant, try the generic Athena 3d headers
3217     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3218       AC_CHECK_HEADER(X11/Xaw3d/XawInit.h,
3219         AC_CHECK_HEADER(X11/Xaw3d/ThreeD.h,
3220           [
3221             AC_MSG_WARN("Assuming that X11/Xaw3d headers are suitable for $athena_variant.")
3222             athena_h_path=X11/Xaw3d
3223           ],))
3224     fi
3225
3226     dnl Also generic 3d headers directly under include dir
3227     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3228       AC_CHECK_HEADER(Xaw3d/XawInit.h,
3229         AC_CHECK_HEADER(Xaw3d/ThreeD.h,
3230           [
3231             AC_MSG_WARN("Assuming that Xaw3d headers are suitable for $athena_variant.")
3232             athena_h_path=Xaw3d
3233           ],))
3234     fi
3235
3236     dnl If nothing yet found, see if Xaw is a 3d header set...
3237     dnl We AC_MSG_WARN if we fail because I am all out of ideas...
3238     if test -z "$athena_h_path"; then
3239       AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3240         [
3241           AC_MSG_WARN("Assuming that X11/Xaw headers are suitable for $athena_variant.")
3242           athena_h_path=X11/Xaw
3243         ],
3244         AC_MSG_WARN("Could not find a suitable 3d Athena header set."))
3245     fi
3246   fi
3247
3248   dnl Do we actually have a usable Athena widget set? Please?
3249   if test -n "$athena_lib" -a -n "$athena_h_path"; then
3250     have_xaw=yes
3251   else
3252     have_xaw=no
3253   fi
3254
3255   dnl autodetect Motif - but only add to libs_x later (if necessary)
3256   AC_CHECK_HEADER(Xm/Xm.h,
3257    [AC_CHECK_LIB(Xm, XmStringFree, have_motif=yes, have_motif=no)],
3258    have_motif=no)
3259
3260   if test "$have_motif" = "yes"; then
3261     dnl autodetect lesstif
3262     AC_MSG_CHECKING(for Lesstif)
3263     AC_EGREP_CPP(yes,
3264 [#include <Xm/Xm.h>
3265 #ifdef LESSTIF_VERSION
3266 yes
3267 #endif
3268 ], have_lesstif=yes, have_lesstif=no)
3269   AC_MSG_RESULT($have_lesstif)
3270   fi
3271
3272 fi dnl "$with_x11" = "yes"
3273
3274 dnl Finish ensuring that we have values for the various toolkit items.
3275 dnl Not all toolkits support all widgets
3276 dnl if Motif is available we use it for the dialog boxes.
3277
3278 case "$with_menubars" in "" | "yes" | "athena" )
3279   with_menubars="lucid" ;;
3280 esac
3281 case "$with_dialogs" in "" | "yes" | "lucid" )
3282   if   test "$have_motif"     = "yes"; then with_dialogs="motif"
3283   elif test "$have_xaw"       = "yes"; then with_dialogs="athena"
3284   else with_dialogs=no
3285   fi ;;
3286 esac
3287 case "$with_scrollbars" in "" | "yes" )
3288   with_scrollbars="lucid" ;;
3289 esac
3290 case "$with_widgets" in "" | "yes" | "lucid")
3291   if   test "$have_motif" = "yes"; then with_widgets="motif"
3292   elif test "$have_xaw"   = "yes"; then with_widgets="athena"
3293   else with_widgets=no
3294   fi ;;
3295 esac
3296
3297 all_widgets="$with_menubars $with_scrollbars $with_dialogs $with_toolbars $with_widgets"
3298
3299 case "$all_widgets" in
3300   *athena* )
3301     if test "$have_xaw" != "yes"; then
3302       XE_DIE("Could not find a suitable Athena library to build with.")
3303     fi
3304
3305     dnl Add the Lucid widget Athena code
3306     XE_APPEND(lwlib-Xaw.o, lwlib_objs)
3307
3308     dnl Add the Athena widget library we located earlier
3309     XE_PREPEND(-l$athena_lib, libs_x)
3310
3311     dnl Export the path for lwlib, used to build and include the headers
3312     dnl from the right place later on.
3313     AC_DEFINE_UNQUOTED(ATHENA_H_PATH, $athena_h_path)
3314
3315     AC_DEFINE(LWLIB_USES_ATHENA)
3316     AC_DEFINE(NEED_ATHENA)
3317
3318     if test "$athena_3d" = "yes"; then
3319       AC_DEFINE(HAVE_ATHENA_3D)
3320     fi
3321   ;;
3322 esac
3323
3324 case "$all_widgets" in *motif* )
3325   AC_DEFINE(LWLIB_USES_MOTIF)
3326   AC_DEFINE(NEED_MOTIF)
3327   XE_APPEND(lwlib-Xm.o, lwlib_objs)
3328   need_motif=yes ;;
3329 esac
3330
3331 test "$with_menubars"   = "lucid" && XE_APPEND(xlwmenu.o, lwlib_objs)
3332 test "$with_menubars"   = "motif" && XE_APPEND(xlwmenu.o, lwlib_objs)
3333 test "$with_scrollbars" = "lucid" && XE_APPEND(xlwscrollbar.o, lwlib_objs)
3334 test "$with_widgets"   != "no" && test "$with_widgets" != "msw" && \
3335         XE_APPEND(xlwtabs.o xlwgcs.o, lwlib_objs)
3336 case "$with_widgets" in athena* )
3337         XE_APPEND(xlwradio.o xlwcheckbox.o xlwgauge.o, lwlib_objs);;
3338 esac
3339 case "$all_widgets" in *lucid* )
3340   AC_DEFINE(NEED_LUCID)
3341   XE_APPEND(lwlib-Xlw.o, lwlib_objs) ;;
3342 esac
3343
3344 AC_SUBST(lwlib_objs)
3345
3346 test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA)
3347 test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA)
3348
3349 if test "$athena_3d" = "yes"; then
3350   test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA3D)
3351   test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA3D)
3352 fi
3353
3354 case "$with_widgets" in athena* ) AC_DEFINE(LWLIB_WIDGETS_ATHENA);; esac
3355 test "$with_widgets" != "no" && test "$with_widgets" != "msw" && \
3356         AC_DEFINE(LWLIB_TABS_LUCID)
3357
3358 test "$with_menubars"   != "no"    && AC_DEFINE(HAVE_MENUBARS)
3359 test "$with_scrollbars" != "no"    && AC_DEFINE(HAVE_SCROLLBARS)
3360 test "$with_dialogs"    != "no"    && AC_DEFINE(HAVE_DIALOGS)
3361 test "$with_toolbars"   != "no"    && AC_DEFINE(HAVE_TOOLBARS)
3362 test "$with_widgets"    != "no"    && AC_DEFINE(HAVE_WIDGETS)
3363
3364 test "$with_menubars"   = "lucid"  && AC_DEFINE(LWLIB_MENUBARS_LUCID)
3365 test "$with_scrollbars" = "lucid"  && AC_DEFINE(LWLIB_SCROLLBARS_LUCID)
3366
3367 test "$with_menubars"   = "motif"  && AC_DEFINE(LWLIB_MENUBARS_MOTIF)
3368 test "$with_scrollbars" = "motif"  && AC_DEFINE(LWLIB_SCROLLBARS_MOTIF)
3369 test "$with_dialogs"    = "motif"  && AC_DEFINE(LWLIB_DIALOGS_MOTIF)
3370 test "$with_widgets"    = "motif"  && AC_DEFINE(LWLIB_WIDGETS_MOTIF)
3371
3372 test "$with_menubars"   != "no"    && XE_ADD_OBJS(menubar.o)
3373 test "$with_scrollbars" != "no"    && XE_ADD_OBJS(scrollbar.o)
3374 test "$with_dialogs"    != "no"    && XE_ADD_OBJS(dialog.o)
3375 test "$with_toolbars"   != "no"    && XE_ADD_OBJS(toolbar.o)
3376
3377 if test "$with_x11" = "yes"; then
3378   test "$with_menubars"   != "no"  && XE_ADD_OBJS(menubar-x.o)
3379   test "$with_scrollbars" != "no"  && XE_ADD_OBJS(scrollbar-x.o)
3380   test "$with_dialogs"    != "no"  && XE_ADD_OBJS(dialog-x.o)
3381   test "$with_toolbars"   != "no"  && XE_ADD_OBJS(toolbar-x.o)
3382   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-x.o)
3383 fi
3384
3385 dnl ----------------------
3386 dnl Mule-dependent options
3387 dnl ----------------------
3388
3389 test -z "$with_mule" && with_mule=no
3390 test -z "$with_file_coding" && with_file_coding=no
3391
3392 dnl if test "$with_mule" = "yes" && test ! -d "$srcdir/lisp/mule"; then
3393 dnl     echo "Attempt to Build with Mule without Mule/Lisp"
3394 dnl     echo "Please install the XEmacs/Mule tarball or"
3395 dnl     echo "rerun configure with --with-mule=no"
3396 dnl     exit 1
3397 dnl fi
3398
3399 if test "$with_file_coding" = "yes" && test "$with_mule" = "no"; then
3400   AC_DEFINE(FILE_CODING)
3401   XE_ADD_OBJS(file-coding.o)
3402 fi
3403
3404 if test "$with_mule" = "yes" ; then
3405   AC_CHECKING(for Mule-related features)
3406   AC_DEFINE(MULE)
3407   AC_DEFINE(FILE_CODING)
3408   XE_ADD_OBJS(mule.o mule-ccl.o mule-charset.o)
3409   if test "$with_utf_2000" = "yes" && test "$with_text_coding" = "yes"; then
3410     AC_DEFINE(TEXT_CODING)
3411     XE_ADD_OBJS(text-coding.o)
3412   else
3413     XE_ADD_OBJS(file-coding.o)
3414   fi
3415   dnl Use -lintl to get internationalized strerror for Mule
3416   AC_CHECK_HEADERS(libintl.h)
3417   AC_CHECK_LIB(intl, strerror)
3418
3419   if test "$with_utf_2000" = "yes" ; then
3420     AC_DEFINE(CHAR_IS_UCS4)
3421     AC_DEFINE(UTF2000)
3422     AC_DEFINE(HAVE_GGC)
3423   fi
3424
3425   AC_CHECKING(for Mule input methods)
3426   dnl Do we have the XmIm* routines?  And if so, do we want to use them?
3427   dnl XIM seems to be flaky except on Solaris...
3428   dnl test -z "$with_xim" -a "$opsys" != "sol2" && with_xim=no
3429   case "$with_xim" in "" | "yes" )
3430     AC_CHECKING(for XIM)
3431     AC_CHECK_LIB(X11, XOpenIM, with_xim=xlib, with_xim=no)
3432     dnl XIM + Lesstif is not (yet?) usable
3433     if test "$have_motif $have_lesstif" = "yes no"; then
3434       AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif)
3435     fi ;;
3436   esac
3437   if test "$with_xim" != "no"; then
3438     AC_DEFINE(HAVE_XIM)
3439     if test "$with_xim" = "xlib"; then
3440       AC_DEFINE(XIM_XLIB)
3441       XE_ADD_OBJS(input-method-xlib.o)
3442     fi
3443     if test "$with_xim" = "motif"; then
3444       AC_DEFINE(XIM_MOTIF)
3445       need_motif=yes
3446       XE_ADD_OBJS(input-method-motif.o)
3447     fi
3448     if test "$with_xim" = "motif"; then
3449       with_xfs=no
3450     fi
3451   fi
3452
3453   dnl "with_xfs" = "yes"
3454   if test "$with_xfs" = "yes" ; then
3455     AC_CHECKING(for XFontSet)
3456     AC_CHECK_LIB(X11, XmbDrawString, [:], with_xfs=no)
3457     if test "$with_xfs" = "yes" && test "$with_menubars" = "lucid"; then
3458       AC_DEFINE(USE_XFONTSET)
3459       if test "$with_xim" = "no" ; then
3460         XE_ADD_OBJS(input-method-xfs.o)
3461       fi
3462     fi
3463   fi dnl with_xfs
3464
3465   dnl Autodetect WNN
3466   test "$with_wnn6" = "yes" && with_wnn=yes # wnn6 implies wnn support
3467   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/jllib.h, ,with_wnn=no) }
3468   dnl Detour to find crypt
3469   if test "$with_wnn" != "no"; then
3470     AC_CHECK_FUNCS(crypt)
3471     test "$ac_cv_func_crypt" != "yes" && { AC_CHECK_LIB(crypt, crypt) }
3472   fi
3473   dnl Back to our regularly scheduled wnn hunting
3474   if test -z "$with_wnn" -o "$with_wnn" = "yes"; then
3475     AC_CHECK_LIB(wnn,jl_dic_list_e,libwnn=wnn,
3476       AC_CHECK_LIB(wnn4,jl_dic_list_e,libwnn=wnn4,
3477         AC_CHECK_LIB(wnn6,jl_dic_list_e,libwnn=wnn6,
3478           AC_CHECK_LIB(wnn6_fromsrc,dic_list_e,libwnn=wnn6_fromsrc,with_wnn=no))))
3479   fi
3480   test -z "$with_wnn" && with_wnn=yes
3481   if test "$with_wnn" = "yes"; then
3482     AC_DEFINE(HAVE_WNN)
3483     XE_PREPEND(-l$libwnn, libs_x)
3484     XE_ADD_OBJS(mule-wnnfns.o)
3485     if test "$with_wnn6" != "no"; then
3486       AC_CHECK_LIB($libwnn, jl_fi_dic_list, with_wnn6=yes)
3487       test "$with_wnn6" = "yes" && AC_DEFINE(WNN6)
3488     fi
3489   fi
3490
3491   dnl Autodetect canna
3492   canna_includes_found=no
3493   if test "$with_canna" != "no"; then
3494     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3495   fi
3496   if test "$canna_includes_found" = "no" -a "$with_canna" != "no" -a \
3497       -d "/usr/local/canna/include"; then
3498     save_c_switch_site="$c_switch_site"
3499     c_switch_site="$c_switch_site -I/usr/local/canna/include"
3500     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3501     if test "$canna_includes_found" != "yes"; then
3502       c_switch_site="$save_c_switch_site"
3503       with_canna="no"
3504     fi
3505   fi
3506
3507   test -z "$with_canna" && { AC_CHECK_HEADER(canna/RK.h,         , with_canna=no) }
3508   test -z "$with_canna" && { AC_CHECK_LIB(RKC, RkBgnBun,       [:],with_canna=no) }
3509   test -z "$with_canna" && { AC_CHECK_LIB(canna,jrKanjiControl,[:],with_canna=no) }
3510   test -z "$with_canna" && with_canna=yes
3511   if test "$with_canna" = "yes"; then
3512     AC_DEFINE(HAVE_CANNA)
3513     XE_PREPEND(-lcanna -lRKC, libs_x)
3514     XE_ADD_OBJS(mule-canna.o)
3515   fi
3516
3517 else dnl "$with_mule" = "no"
3518   for feature in xim canna wnn; do
3519     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3520       AC_MSG_WARN("--with-${feature} ignored:  Not valid without Mule support")
3521     fi
3522     eval "with_${feature}=no"
3523   done
3524 fi dnl with_mule
3525
3526
3527 dnl At this point, we know whether we need the motif lib or not.
3528 if test "$need_motif" = "yes" ; then
3529   XE_PREPEND(-lXm, libs_x)
3530   dnl AIX needs the following library for use with Motif
3531   AC_CHECK_LIB(i18n, layout_object_getvalue, [XE_PREPEND(-li18n, libs_x)])
3532   XE_COMPUTE_RUNPATH()
3533 fi
3534
3535 AC_CHECK_FUNCS(cbrt closedir dup2 eaccess fmod fpathconf frexp ftime getaddrinfo gethostname getnameinfo getpagesize gettimeofday getcwd getpt getwd logb lrand48 matherr mkdir mktime perror poll random rename res_init rint rmdir select setitimer setpgid setlocale setsid sigblock sighold sigprocmask snprintf stpcpy strcasecmp strerror tzset ulimit usleep utimes waitpid vsnprintf fsync ftruncate umask)
3536
3537 dnl Use our own realpath always.
3538 XE_ADD_OBJS(realpath.o)
3539
3540 dnl Check whether the system provides getloadavg (Solaris 7 has it)
3541 AC_CHECK_FUNCS(getloadavg)
3542
3543 if test "$ac_cv_func_getloadavg" != "yes"
3544 then
3545   XE_ADD_OBJS(getloadavg.o)
3546
3547   dnl Used by getloadavg() - does not require root priveleges
3548   AC_CHECK_LIB(kstat, kstat_open)
3549
3550   dnl Another way to get the load average
3551   AC_CHECK_LIB(kvm, kvm_read)
3552 fi
3553
3554 dnl If netdb.h does not declare h_errno, we must declare it by hand.
3555 AC_MSG_CHECKING(whether netdb declares h_errno)
3556 AC_TRY_LINK([#include <netdb.h>],
3557   [return h_errno;],
3558   [AC_MSG_RESULT(yes)
3559    AC_DEFINE(HAVE_H_ERRNO)],
3560   [AC_MSG_RESULT(no)])
3561
3562 AC_MSG_CHECKING(for sigsetjmp)
3563 AC_TRY_COMPILE([#include <setjmp.h>],
3564         [sigjmp_buf bar; sigsetjmp (bar, 0);],
3565   [AC_MSG_RESULT(yes)
3566    AC_DEFINE(HAVE_SIGSETJMP)],
3567   [AC_MSG_RESULT(no)])
3568
3569 AC_MSG_CHECKING(whether localtime caches TZ)
3570 AC_CACHE_VAL(emacs_cv_localtime_cache,
3571 [if test "$ac_cv_func_tzset" = "yes"; then
3572 AC_TRY_RUN([#include <time.h>
3573 #if STDC_HEADERS
3574 # include <stdlib.h>
3575 #endif
3576 extern char **environ;
3577 unset_TZ ()
3578 {
3579   char **from, **to;
3580   for (to = from = environ; (*to = *from); from++)
3581     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
3582       to++;
3583 }
3584 char TZ_GMT0[] = "TZ=GMT0";
3585 char TZ_PST8[] = "TZ=PST8";
3586 main()
3587 {
3588   time_t now = time ((time_t *) 0);
3589   int hour_GMT0, hour_unset;
3590   if (putenv (TZ_GMT0) != 0)
3591     exit (1);
3592   hour_GMT0 = localtime (&now)->tm_hour;
3593   unset_TZ ();
3594   hour_unset = localtime (&now)->tm_hour;
3595   if (putenv (TZ_PST8) != 0)
3596     exit (1);
3597   if (localtime (&now)->tm_hour == hour_GMT0)
3598     exit (1);
3599   unset_TZ ();
3600   if (localtime (&now)->tm_hour != hour_unset)
3601     exit (1);
3602   exit (0);
3603 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3604 [# If we have tzset, assume the worst when cross-compiling.
3605 emacs_cv_localtime_cache=yes])
3606 else
3607         # If we lack tzset, report that localtime does not cache TZ,
3608         # since we can't invalidate the cache if we don't have tzset.
3609         emacs_cv_localtime_cache=no
3610 fi],[:])dnl
3611 AC_MSG_RESULT($emacs_cv_localtime_cache)
3612 if test $emacs_cv_localtime_cache = yes; then
3613   AC_DEFINE(LOCALTIME_CACHE)
3614 fi
3615
3616 if test "$HAVE_TIMEVAL" = "yes"; then
3617 AC_MSG_CHECKING(whether gettimeofday accepts one or two arguments)
3618 AC_TRY_LINK([
3619 #ifdef TIME_WITH_SYS_TIME
3620 #include <sys/time.h>
3621 #include <time.h>
3622 #else
3623 #ifdef HAVE_SYS_TIME_H
3624 #include <sys/time.h>
3625 #else
3626 #include <time.h>
3627 #endif
3628 #endif
3629   ],
3630   [
3631   struct timeval time;
3632   gettimeofday (&time, 0);
3633 ],
3634   [AC_MSG_RESULT(two)],
3635   [AC_MSG_RESULT(one)
3636    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
3637 fi
3638
3639
3640 AC_C_INLINE
3641 test "$ac_cv_c_inline" != "no" -a "$GCC" = "yes" && XE_ADD_OBJS(inline.o)
3642
3643 dnl HP-UX has a working alloca in libPW.
3644 dnl case "${GCC}${opsys}" in hpux* )
3645 dnl  AC_CHECK_FUNC(alloca, [:], [AC_CHECK_LIB(PW, alloca)])
3646 dnl esac
3647
3648 AC_FUNC_ALLOCA
3649 test -n "$ALLOCA" && XE_ADD_OBJS($ALLOCA)
3650
3651 dnl Check whether vfork exists and works correctly. (This does more
3652 dnl than just check for its existence.) If so, it defines HAVE_VFORK_H.
3653 dnl If not, it defines vfork to be fork.
3654 AC_FUNC_VFORK
3655
3656 dnl Check whether strcoll exists and works correctly. (This does more
3657 dnl than just check for its existence.) If so, it defines HAVE_STRCOLL.
3658 AC_FUNC_STRCOLL
3659
3660 dnl If `getpgrp' takes no argument (the POSIX.1 version), define
3661 dnl `GETPGRP_VOID'.  Otherwise, it is the BSD version, which takes a
3662 dnl process ID as an argument.
3663 AC_CHECK_FUNCS(getpgrp)
3664 AC_FUNC_GETPGRP
3665
3666 dnl We used to call AC_FUNC_MMAP here
3667 dnl Instead we now use following, suggested by Neal Becker
3668 AC_MSG_CHECKING(for working mmap)
3669 case "$opsys" in ultrix* ) have_mmap=no ;; *)
3670 AC_TRY_RUN([#include <stdio.h>
3671 #include <unistd.h>
3672 #include <fcntl.h>
3673 #include <sys/mman.h>
3674
3675 #ifndef MAP_VARIABLE
3676 #define MAP_VARIABLE 0
3677 #endif
3678
3679 #ifndef MAP_FAILED
3680 #define MAP_FAILED -1
3681 #endif
3682
3683 int main (int argc, char *argv[])
3684 {
3685   int fd = -1;
3686   caddr_t p;
3687 #ifndef MAP_ANONYMOUS
3688   fd = open ("/dev/zero", O_RDWR);
3689   if (fd < 0)
3690     return 1;
3691 #define MAP_ANONYMOUS 0
3692 #endif
3693   if (mmap(0, 1024, PROT_READ | PROT_WRITE,
3694            MAP_PRIVATE | MAP_VARIABLE | MAP_ANONYMOUS,
3695            fd, 0) != (void *) MAP_FAILED)
3696     return 0;
3697   perror ("conftest: mmap failed");
3698   return 1;
3699 }], have_mmap=yes, have_mmap=no) ;;
3700 esac
3701 AC_MSG_RESULT($have_mmap)
3702 test "$have_mmap" = "yes" && AC_DEFINE(HAVE_MMAP)
3703
3704 dnl rel_alloc requires either GNU malloc or system malloc with mmap
3705 dnl We only turn rel_alloc on by default if mmap is available.
3706 test "$GNU_MALLOC" != "yes" -a "$have_mmap" != "yes" && rel_alloc=no
3707 if test "$rel_alloc $have_mmap" = "default yes"; then
3708   if test "$doug_lea_malloc" = "yes"; then
3709     dnl Check if malloc() calls mmap(), making rel_alloc pointless.
3710     AC_MSG_CHECKING(for M_MMAP_THRESHOLD)
3711     AC_TRY_COMPILE([#include <malloc.h>],[
3712 #ifndef M_MMAP_THRESHOLD
3713 #error No M_MMAP_THRESHOLD :-(
3714 !@+$%^&*_)(_ - unlikely to compile...
3715 #endif
3716 ], [rel_alloc=no; AC_MSG_RESULT(yes);], [rel_alloc=yes; AC_MSG_RESULT(no);])
3717   else
3718     rel_alloc=yes
3719   fi
3720 fi
3721 test "$rel_alloc" = "yes" && AC_DEFINE(REL_ALLOC)
3722
3723 dnl Check for terminal I/O variants
3724 dnl TERMIOS systems may have termio.h, but not vice-versa, I think.
3725 AC_CHECK_HEADER(termios.h,
3726   AC_DEFINE(HAVE_TERMIOS)
3727   AC_DEFINE(SIGNALS_VIA_CHARACTERS)
3728   AC_DEFINE(NO_TERMIO),
3729   [AC_CHECK_HEADER(termio.h, [AC_DEFINE(HAVE_TERMIO)])])
3730
3731
3732 dnl Check for Internet sockets.
3733 AC_CHECK_FUNC(socket,
3734  [AC_CHECK_HEADER(netinet/in.h,
3735    [AC_CHECK_HEADER(arpa/inet.h, [
3736   AC_DEFINE(HAVE_SOCKETS)
3737       AC_MSG_CHECKING("for sun_len member in struct sockaddr_un")
3738       AC_TRY_LINK([
3739 #include <sys/types.h>
3740 #include <sys/socket.h>
3741 #include <sys/un.h>
3742       ],
3743       [static struct sockaddr_un x; x.sun_len = 1;],
3744       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)],
3745       [AC_MSG_RESULT(no)])
3746       AC_MSG_CHECKING("for ip_mreq struct in netinet/in.h")
3747       AC_TRY_LINK([
3748 #include <sys/types.h>
3749 #include <netinet/in.h>
3750       ],
3751       [static struct ip_mreq x;],
3752       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MULTICAST)],
3753       [AC_MSG_RESULT(no)])])])])
3754
3755 dnl Check for SYS V IPC. (Inferior to sockets.)
3756 AC_CHECK_FUNC(msgget,
3757   [AC_CHECK_HEADER(sys/ipc.h,
3758     [AC_CHECK_HEADER(sys/msg.h,
3759       [AC_DEFINE(HAVE_SYSVIPC)])])])
3760
3761 dnl Check for directory variants
3762 AC_CHECK_HEADER(dirent.h, [AC_DEFINE(SYSV_SYSTEM_DIR)],
3763   [AC_CHECK_HEADER(sys/dir.h, , [AC_DEFINE(NONSYSTEM_DIR_LIBRARY)])])
3764
3765 dnl Check for nlist.h
3766 AC_CHECK_HEADER(nlist.h, AC_DEFINE(NLIST_STRUCT), )
3767
3768 dnl Check for sound of various sorts.
3769
3770 dnl Autodetect native sound
3771 AC_CHECKING("for sound support")
3772 test -z "$with_native_sound" -a -n "$native_sound_lib" && with_native_sound=yes
3773
3774 if test "$with_native_sound" != "no"; then
3775   dnl Maybe sound is already on include path...
3776   if test -n "$native_sound_lib"; then
3777     AC_CHECK_HEADER(multimedia/audio_device.h,
3778       [sound_found=yes sound_cflags=""
3779       XE_ADD_OBJS(sunplay.o)])
3780   fi
3781
3782   dnl Autodetect Sun native sound from SUNWaudmo package
3783   if test -z "$sound_found" -a -d "/usr/demo/SOUND"; then
3784     sound_found=yes
3785     XE_ADD_OBJS(sunplay.o)
3786     if test -d "/usr/demo/SOUND/include"
3787       then sound_cflags="-I/usr/demo/SOUND/include"
3788       else sound_cflags="-I/usr/demo/SOUND"
3789     fi
3790     if test -z "$native_sound_lib" ; then
3791       if test -r "/usr/demo/SOUND/lib/libaudio.a"
3792         then native_sound_lib="/usr/demo/SOUND/lib/libaudio.a"
3793         else native_sound_lib="/usr/demo/SOUND/libaudio.a"
3794       fi
3795     fi
3796   fi
3797
3798   dnl Check for SGI and HP native sound libs
3799   if test -z "$sound_found"; then
3800     case "$canonical" in
3801     *-sgi-* )
3802       if test -z "$native_sound_lib"; then
3803         AC_CHECK_LIB(audio, ALopenport, native_sound_lib="-laudio")
3804       fi
3805       if test -n "$native_sound_lib"; then
3806         sound_found=yes sound_cflags=""
3807         XE_ADD_OBJS(sgiplay.o)
3808       fi ;;
3809     hppa*-hp-hpux* )
3810       if test -z "$native_sound_lib"; then
3811         AC_CHECK_LIB(Alib, AOpenAudio, native_sound_lib="-lAlib")
3812       fi
3813       if test -n "$native_sound_lib"; then
3814         sound_found=yes
3815         XE_ADD_OBJS(hpplay.o)
3816         if test "$GCC" = "yes" # Kludge city
3817           then sound_cflags="-Dconst= -Dvolatile= -I/usr/audio/examples"
3818           else sound_cflags="+e -I/usr/audio/examples"
3819         fi
3820       fi ;;
3821     esac
3822   fi
3823
3824   dnl Check for Linux/BSD native sound
3825   if test -z "$sound_found"; then
3826     for dir in "machine" "sys" "linux"; do
3827       AC_CHECK_HEADER(${dir}/soundcard.h,
3828         sound_found=yes
3829        need_miscplay=yes
3830         XE_ADD_OBJS(linuxplay.o)
3831         [AC_DEFINE_UNQUOTED(SOUNDCARD_H_FILE, "${dir}/soundcard.h")]
3832         break)
3833     done
3834   fi
3835
3836   test "$sound_found" = "yes" && with_native_sound=yes
3837 fi
3838
3839 if test "$with_native_sound" = "yes"; then
3840   AC_DEFINE(HAVE_NATIVE_SOUND)
3841   test -n "$native_sound_lib" && XE_PREPEND($native_sound_lib, LIBS)
3842 fi
3843
3844 dnl NAS Sound support
3845 if test "$with_nas_sound" != "no"; then
3846   AC_CHECK_HEADER(audio/audiolib.h, [
3847     AC_CHECK_LIB(audio, AuOpenServer, have_nas_sound=yes)])
3848   if test "$have_nas_sound" = "yes"; then
3849     with_nas_sound=yes
3850     AC_DEFINE(HAVE_NAS_SOUND)
3851     XE_ADD_OBJS(nas.o)
3852     XE_PREPEND(-laudio, libs_x)
3853     dnl If the nas library does not contain the error jump point,
3854     dnl then we force safer behavior.
3855     AC_EGREP_HEADER(AuXtErrorJump,audio/Xtutil.h,,[old_nas=yes; AC_DEFINE(NAS_NO_ERROR_JUMP)])
3856   else
3857     test "$with_nas_sound" = "yes" && \
3858       XE_DIE("Required NAS sound support cannot be provided.")
3859     with_nas_sound=no
3860   fi
3861 fi
3862
3863 dnl ESD Sound support
3864 if test "$with_esd_sound" != "no"; then
3865   AC_CHECK_PROG(have_esd_config, esd-config, yes, no)
3866   if test "$have_esd_config" = "yes"; then
3867     save_c_switch_site="$c_switch_site" save_LIBS="$LIBS"
3868     XE_APPEND(`esd-config --cflags`, c_switch_site)
3869     XE_PREPEND(`esd-config --libs`, LIBS)
3870     AC_CHECK_FUNC(esd_play_stream,
3871       have_esd_sound=yes,
3872       c_switch_site="$save_c_switch_site" LIBS="$save_LIBS")
3873   fi
3874
3875   if test "$have_esd_sound" = "yes"; then
3876     with_esd_sound=yes
3877     need_miscplay=yes
3878     XE_ADD_OBJS(esd.o)
3879     AC_DEFINE(HAVE_ESD_SOUND)
3880   else
3881     test "$with_esd_sound" = "yes" && \
3882       XE_DIE("Required ESD sound support cannot be provided.")
3883     with_esd_sound=no
3884   fi
3885 fi
3886
3887 test "$need_miscplay" = "yes" && XE_ADD_OBJS(miscplay.o)
3888
3889 dnl ---------------------
3890 dnl TTY-dependent options
3891 dnl ---------------------
3892
3893 test -z "$with_tty" && with_tty=yes
3894
3895 if test "$with_tty" = "yes"  ; then
3896   AC_CHECKING(for TTY-related features)
3897   AC_DEFINE(HAVE_TTY)
3898   XE_ADD_OBJS(console-tty.o device-tty.o event-tty.o frame-tty.o objects-tty.o redisplay-tty.o cm.o)
3899
3900   dnl Autodetect ncurses.
3901   if test -z "$with_ncurses"; then
3902     AC_CHECK_LIB(ncurses, tgetent, with_ncurses=yes, with_ncurses=no)
3903   fi
3904   if test "$with_ncurses" = "yes"; then
3905     AC_DEFINE(HAVE_NCURSES)
3906     AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
3907     AC_CHECK_HEADER(ncurses/term.h, term_h_file=ncurses/term.h)
3908     XE_ADD_OBJS(terminfo.o)
3909     XE_PREPEND(-lncurses, LIBS)
3910
3911     if test "$ac_cv_header_ncurses_curses_h" != "yes" ; then
3912       dnl Try again, and check for the bogus ncurses/ include bug.
3913       dnl (i.e. ncurses/curses.h bogusly includes <unctrl.h> instead of
3914       dnl <ncurses/unctrl.h>)
3915       save_c_switch_site="$c_switch_site"
3916       c_switch_site="$c_switch_site -I/usr/include/ncurses"
3917       AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
3918       if test "$ac_cv_header_ncurses_curses_h" = "yes"
3919         then AC_MSG_WARN("Your system has the bogus ncurses include bug.")
3920         else c_switch_site="$save_c_switch_site"
3921       fi
3922     fi
3923   else dnl "$with_ncurses" = "no"
3924     dnl Autodetect terminfo/-lcurses/-ltermlib/-ltermcap
3925     if test "$have_terminfo" = "yes"; then
3926       XE_ADD_OBJS(terminfo.o)
3927       if test -n "$libs_termcap"; then
3928         XE_PREPEND($libs_termcap, LIBS)
3929       else
3930         for lib in curses termlib termcap; do
3931           AC_CHECK_LIB($lib, tgetent, XE_PREPEND(-l${lib}, LIBS); break)
3932         done
3933       fi
3934     else dnl "$have_terminfo" = "no" && "with_ncurses" = "no"
3935       XE_ADD_OBJS(tparam.o)
3936       dnl The HP-UX curses library seems to have a badly broken version of select(2)
3937       dnl that makes "poll: interrupted system call" messages to appear and
3938       dnl Emacs suprocesses to hang (e.g. TeX compilation w/ AUCTeX) */
3939       case "$opsys" in *-hp-hpux* ) libs_termcap="-ltermcap" ;; esac
3940       if test -n "$libs_termcap"; then
3941         XE_PREPEND($libs_termcap, LIBS)
3942       else
3943         AC_CHECK_LIB(curses, tgetent, XE_PREPEND(-lcurses, LIBS),
3944           AC_CHECK_LIB(termcap, tgetent, XE_PREPEND(-ltermcap, LIBS),
3945             XE_ADD_OBJS(termcap.o)))
3946       fi
3947     fi
3948   fi
3949   AC_DEFINE_UNQUOTED(CURSES_H_FILE, "${curses_h_file-curses.h}")
3950   AC_DEFINE_UNQUOTED(TERM_H_FILE, "${term_h_file-term.h}")
3951
3952   dnl Autodetect gpm
3953   test -z "$with_gpm" && { AC_CHECK_HEADER(gpm.h, , with_gpm=no) }
3954   test -z "$with_gpm" && { AC_CHECK_LIB(gpm, Gpm_Open, with_gpm=yes, with_gpm=no) }
3955   if test "$with_gpm" = "yes"; then
3956     AC_DEFINE(HAVE_GPM)
3957     XE_ADD_OBJS(gpmevent.o)
3958     XE_PREPEND(-lgpm, LIBS)
3959   fi
3960
3961 else dnl "$with_tty" = "no"
3962   for feature in ncurses gpm; do
3963     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3964       AC_MSG_WARN("--with-${feature} ignored:  Not valid without TTY support")
3965     fi
3966     eval "with_${feature}=no"
3967   done
3968 fi dnl with_tty
3969
3970 dnl Do we need event-unixoid.o ?
3971 test "$with_x11" = "yes" -o "$with_tty" = "yes" && XE_ADD_OBJS(event-unixoid.o)
3972
3973 dnl Database support
3974 dnl We do not necessarily have to have libdb/lib(g)dbm for DB/(G)DBM support.
3975 dnl On FreeBSD, both DB and DBM are part of libc.
3976 dnl By default, we check for DBM support in libgdbm, then libc, then libdbm.
3977
3978 test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
3979   != "no no no" && AC_CHECKING(for database support)
3980
3981 dnl Check for ndbm.h, required for either kind of DBM support.
3982 if test "$with_database_gdbm $with_database_dbm" != "no no"; then
3983   AC_CHECK_HEADER(ndbm.h, [:], [
3984     test "$with_database_gdbm" = "yes" -o \
3985          "$with_database_dbm"  = "yes" && \
3986       XE_DIE("Required DBM support cannot be provided.")
3987     with_database_gdbm=no with_database_dbm=no])
3988 fi
3989
3990 dnl Check for DBM support in libgdbm.
3991 if test "$with_database_gdbm" != "no"; then
3992   AC_CHECK_LIB(gdbm, dbm_open, [
3993    with_database_gdbm=yes with_database_dbm=no libdbm=-lgdbm], [
3994    if test "$with_database_gdbm" = "yes"; then
3995      XE_DIE("Required GNU DBM support cannot be provided.")
3996    fi
3997    with_database_gdbm=no])
3998 fi
3999
4000 dnl Check for DBM support in libc and libdbm.
4001 if test "$with_database_dbm" != "no"; then
4002   AC_CHECK_FUNC(dbm_open, [with_database_dbm=yes libdbm=], [
4003     AC_CHECK_LIB(dbm, dbm_open, [with_database_dbm=yes libdbm=-ldbm], [
4004       test "$with_database_dbm" = "yes" && \
4005         XE_DIE("Required DBM support cannot be provided.")
4006       with_database_dbm=no])])
4007 fi
4008
4009 dnl Tell make about the DBM support we detected.
4010 test -n "$libdbm" && XE_PREPEND("$libdbm", LIBS)
4011 test "$with_database_gdbm" = "yes" -o \
4012      "$with_database_dbm"  = "yes" && \
4013   AC_DEFINE(HAVE_DBM)
4014
4015 dnl Check for Berkeley DB.
4016 if test "$with_database_berkdb" != "no"; then
4017   AC_MSG_CHECKING(for Berkeley db.h)
4018   for header in "db/db.h" "db.h"; do
4019     AC_TRY_COMPILE([
4020 #include <stdlib.h>
4021 #if !(defined __GLIBC__ && __GLIBC_MINOR__ >= 1)
4022 #ifdef HAVE_INTTYPES_H
4023 #define __BIT_TYPES_DEFINED__
4024 #include <inttypes.h>
4025 typedef uint8_t  u_int8_t;
4026 typedef uint16_t u_int16_t;
4027 typedef uint32_t u_int32_t;
4028 #ifdef WE_DONT_NEED_QUADS
4029 typedef uint64_t u_int64_t;
4030 #endif
4031 #endif
4032 #endif
4033 #include <$header>
4034 ],[], db_h_file="$header"; break)
4035   done
4036   if test -z "$db_h_file"
4037   then AC_MSG_RESULT(no); with_database_berkdb=no
4038   else AC_MSG_RESULT($db_h_file)
4039   fi
4040
4041   if test "$with_database_berkdb" != "no"; then
4042     AC_MSG_CHECKING(for Berkeley DB version)
4043     AC_EGREP_CPP(yes,
4044 [#include <$db_h_file>
4045 #if DB_VERSION_MAJOR > 1
4046 yes
4047 #endif
4048 ], [AC_MSG_RESULT(2); dbfunc=db_open], [AC_MSG_RESULT(1); dbfunc=dbopen])
4049     AC_CHECK_FUNC($dbfunc,     with_database_berkdb=yes need_libdb=no, [
4050     AC_CHECK_LIB(db, $dbfunc,  with_database_berkdb=yes need_libdb=yes)])
4051   fi
4052
4053   if test "$with_database_berkdb" = "yes"; then
4054     AC_DEFINE_UNQUOTED(DB_H_FILE, "$db_h_file")
4055     AC_DEFINE(HAVE_BERKELEY_DB)
4056     test "$need_libdb" = "yes" && XE_PREPEND(-ldb, LIBS)
4057   else with_database_berkdb=no
4058   fi
4059 fi
4060
4061 if test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4062      != "no no no"; then
4063   AC_DEFINE(HAVE_DATABASE)
4064   XE_ADD_OBJS(database.o)
4065 fi
4066
4067 dnl Socks support
4068 if test "$with_socks" = "yes"; then
4069   AC_CHECK_LIB(socks, SOCKSinit)
4070   test -n "$ac_cv_lib_socks_SOCKSinit" && AC_DEFINE(HAVE_SOCKS)
4071 fi
4072
4073 dnl Usage tracking (undocumented and likely unused option)
4074 if test "$usage_tracking" = "yes"; then
4075   AC_DEFINE(USAGE_TRACKING)
4076   XE_PREPEND(-Bstatic -lut -Bdynamic, LIBS)
4077 fi
4078
4079 dnl autodetect dll support
4080 if test "$with_modules" != "no"; then
4081   AC_CHECKING(for module support)
4082
4083   dnl Find headers and libraries
4084   AC_CHECK_HEADER(dlfcn.h, [
4085     AC_CHECK_LIB(dl, dlopen, [ have_dl=yes libdl=dl], [
4086     AC_CHECK_LIB(c,  dlopen, [ have_dl=yes ])])])
4087   if test -n "$have_dl"; then
4088     AC_DEFINE(HAVE_DLOPEN)
4089   else
4090     AC_CHECK_LIB(dld, shl_load, [
4091       libdl=dld have_dl=yes;
4092       AC_DEFINE(HAVE_SHL_LOAD)], [
4093     AC_CHECK_LIB(dld, dld_init, [
4094       libdl=dld have_dl=yes;
4095       AC_DEFINE(HAVE_DLD_INIT)])])
4096   fi
4097
4098   if test -n "$have_dl"; then
4099     dnl XE_SHLIB_STUFF (in aclocal.m4) defines $can_build_shared
4100     XE_SHLIB_STUFF
4101   fi
4102
4103   if test "$can_build_shared" = "yes"; then
4104     AC_DEFINE(HAVE_SHLIB)
4105     XE_ADD_OBJS(sysdll.o emodules.o)
4106     XE_APPEND(src, INSTALL_ARCH_DEP_SUBDIR)
4107     test -n "$libdl" && XE_PREPEND(-l${libdl}, LIBS)
4108     AC_CHECK_FUNCS(dlerror _dlerror)
4109     with_modules=yes
4110   else
4111     if test "$with_modules" = "yes"; then
4112       XE_DIE("Required module support cannot be provided.")
4113     else
4114       AC_MSG_WARN("Module support cannot be provided.")
4115     fi
4116     with_modules=no
4117   fi
4118 fi
4119
4120 dnl Unfortunately, just because we can link doesn't mean we can run.
4121 dnl One of the above link tests may have succeeded but caused resulting
4122 dnl executables to fail to run.  Also any tests using AC_TRY_RUN will
4123 dnl have reported incorrect results.
4124 AC_TRY_RUN([int main(int c,char *v[]){return 0;}],[:],[
4125   echo ""
4126   echo "*** PANIC *** The C compiler can no longer build working executables."
4127   echo "*** PANIC *** Please examine the tail of config.log for runtime errors."
4128   echo "*** PANIC *** The most likely reason for this problem is that configure"
4129   echo "*** PANIC *** links with shared libraries, but those libraries cannot be"
4130   echo "*** PANIC *** found at run time."
4131   echo "*** PANIC ***"
4132   echo "*** PANIC *** On a Linux system, edit /etc/ld.so.conf and re-run ldconfig."
4133   echo "*** PANIC *** On other systems, try telling configure where to find the"
4134   echo "*** PANIC *** shared libraries using the --site-runtime-libraries option"
4135   echo "*** PANIC ***"
4136   echo "*** PANIC *** Another way to shoot yourself in the foot is to specify"
4137   echo "*** PANIC *** --with-FEATURE when FEATURE is not actually installed"
4138   echo "*** PANIC *** on your system.  Don't do that."
4139   exit 1])
4140
4141 dnl Process support
4142 if test "$win32_processes" = "yes"; then
4143   XE_ADD_OBJS(process-nt.o)
4144 else
4145   AC_DEFINE(HAVE_UNIX_PROCESSES)
4146   XE_ADD_OBJS(process-unix.o)
4147 fi
4148
4149 dnl --------------------------------
4150 dnl Compute SUBST-itutable variables
4151 dnl --------------------------------
4152
4153 dnl We ignore (C|LD)_SWITCH_X_(MACHINE|SYSTEM)
4154 dnl Use XE_SPACE instead of plain assignment statements to remove extraneous blanks
4155 XE_SPACE(CFLAGS, $CFLAGS)
4156 XE_SPACE(extra_objs, $extra_objs)
4157 XE_SPACE(c_switch_general, -DHAVE_CONFIG_H $c_switch_site $c_switch_machine $c_switch_system)
4158 XE_SPACE(c_switch_window_system, $c_switch_x_site $X_CFLAGS)
4159 XE_SPACE(c_switch_all, $c_switch_general $c_switch_window_system)
4160 XE_SPACE(ld_switch_general, $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_run)
4161 XE_SPACE(ld_switch_window_system, $ld_switch_x_site)
4162 XE_SPACE(ld_switch_all, $ld_switch_general $ld_switch_window_system)
4163 XE_SPACE(ld_libs_general, $LIBS $libs_machine $libs_system $libs_standard)
4164 XE_SPACE(ld_libs_window_system, $X_EXTRA_LIBS $libs_x $X_PRE_LIBS)
4165 XE_SPACE(ld_libs_all, $ld_libs_window_system $ld_libs_general)
4166
4167 dnl Compute lists of Makefiles and subdirs
4168 AC_SUBST(SRC_SUBDIR_DEPS)
4169 XE_APPEND(src, MAKE_SUBDIR)
4170 internal_makefile_list="Makefile.in"
4171 SUBDIR_MAKEFILES=''
4172 test -d lock || mkdir lock
4173 for dir in $MAKE_SUBDIR; do
4174   case "$dir" in */* ) dnl Implement mkdir -p
4175     ( for d in `echo $dir | sed 's:/: :g'` ; do
4176         test -d "$d" || mkdir "$d"; cd "$d"
4177       done ) ;;
4178    * ) test -d "$dir" || mkdir "$dir" ;;
4179   esac
4180   XE_SPACE(SUBDIR_MAKEFILES, $SUBDIR_MAKEFILES $dir/Makefile $dir/GNUmakefile)
4181   XE_SPACE(internal_makefile_list, $internal_makefile_list $dir/Makefile.in)
4182 done
4183 AC_SUBST(INSTALL_ARCH_DEP_SUBDIR)
4184 AC_SUBST(MAKE_SUBDIR)
4185 AC_SUBST(SUBDIR_MAKEFILES)
4186
4187 dnl Make s&m symlinks in the src directory, for config.h
4188 for dir in src/s src/m; do
4189   if test ! -d "$dir" ; then
4190     echo Making symbolic link to "$srcdir/$dir"
4191     ${LN_S} "$srcdir/$dir" "$dir"
4192   fi
4193 done
4194
4195 if test "$extra_verbose" = "yes"; then
4196   echo ""
4197   PRINT_VAR(extra_objs
4198    c_switch_general  c_switch_window_system  c_switch_all
4199   ld_switch_general ld_switch_window_system ld_switch_all
4200     ld_libs_general   ld_libs_window_system   ld_libs_all)
4201   echo ""
4202 fi
4203
4204 dnl ----------------------------------------------
4205 dnl Create some auxiliary files for developers.
4206 dnl ----------------------------------------------
4207
4208 dnl Create a .gdbinit useful for debugging XEmacs
4209 if test -f "$srcdir/src/.gdbinit" -a ! -f "src/.gdbinit"; then
4210   test "$extra_verbose" = "yes" && echo "creating src/.gdbinit"
4211   echo "source $srcdir/src/.gdbinit" > "src/.gdbinit"
4212 fi
4213
4214 dnl Create a .dbxrc useful for debugging XEmacs
4215 if test -f "$srcdir/src/.dbxrc" -a ! -f "src/.dbxrc"; then
4216   test "$extra_verbose" = "yes" && echo "creating src/.dbxrc"
4217   echo ". $srcdir/src/.dbxrc" > "src/.dbxrc"
4218 fi
4219
4220 dnl Create a useful TAGS file
4221 if test -f "$srcdir/TAGS" -a ! -f "TAGS"; then
4222   test "$extra_verbose" = "yes" && echo "creating TAGS"
4223   echo "\f
4224 $srcdir/TAGS,include" > "TAGS"
4225 fi
4226
4227 dnl Create top level .sbinit for Sun compilers
4228 if test "$__SUNPRO_C" = "yes"; then
4229   test "$extra_verbose" = "yes" && echo "creating .sbinit"
4230   ( echo "# For use with Sun WorkShop's Source browser."
4231     echo "# See sbquery(1) and sbinit(4) for more information"
4232     for dir in $MAKE_SUBDIR; do echo "import $dir"; done
4233   ) > .sbinit
4234 fi
4235
4236 dnl There are no more compile tests; remove the core they created.
4237 rm -f core
4238
4239 dnl ----------------------------------------------
4240 dnl Substitute into Makefile, config.h and paths.h
4241 dnl ----------------------------------------------
4242
4243 dnl what sort of things to edit into Makefile, config.h and paths.h
4244 dnl configuration here uncanonicalized to avoid exceeding size limits.
4245
4246 AC_SUBST(PROGNAME)
4247 AC_SUBST(version)
4248 AC_SUBST(configuration)
4249 AC_SUBST(canonical)
4250 AC_SUBST(inststaticdir)
4251 AC_SUBST(instvardir)
4252 AC_SUBST(srcdir)
4253 AC_SUBST(bindir)
4254 AC_SUBST(datadir)
4255 AC_SUBST(pkgdir)
4256 AC_SUBST(statedir)
4257 AC_SUBST(libdir)
4258 AC_SUBST(mandir)
4259
4260 AC_SUBST(prefix)
4261 AC_SUBST(PREFIX_USER_DEFINED)
4262 dnl Yo, Stephen Bourne!  I want to marry you!
4263 PREFIX=$prefix
4264 while true; do
4265   case "$PREFIX" in
4266     *\$* ) eval "PREFIX=$PREFIX" ;;
4267     *) break ;;
4268   esac
4269 done
4270 AC_SUBST(PREFIX)
4271
4272 AC_SUBST(exec_prefix)
4273 AC_SUBST(EXEC_PREFIX_USER_DEFINED)
4274 EXEC_PREFIX=$exec_prefix
4275 while true; do
4276   case "$EXEC_PREFIX" in
4277     *\$* ) eval "EXEC_PREFIX=$EXEC_PREFIX" ;;
4278     *) break ;;
4279   esac
4280 done
4281 AC_SUBST(EXEC_PREFIX)
4282
4283 AC_SUBST(infodir)
4284 AC_SUBST(INFODIR_USER_DEFINED)
4285 INFODIR=$infodir
4286 while true; do
4287   case "$INFODIR" in
4288     *\$* ) eval "INFODIR=$INFODIR" ;;
4289     *) break ;;
4290   esac
4291 done
4292 AC_SUBST(INFODIR)
4293
4294 AC_SUBST(infopath)
4295 AC_SUBST(INFOPATH_USER_DEFINED)
4296 INFOPATH=$infopath
4297 while true; do
4298   case "$INFOPATH" in
4299     *\$* ) eval "INFOPATH=$INFOPATH" ;;
4300     *) break ;;
4301   esac
4302 done
4303 AC_SUBST(INFOPATH)
4304
4305 AC_SUBST(package_path)
4306 AC_SUBST(PACKAGE_PATH_USER_DEFINED)
4307 PACKAGE_PATH=$package_path
4308 while true; do
4309   case "$PACKAGE_PATH" in
4310     *\$* ) eval "PACKAGE_PATH=$PACKAGE_PATH" ;;
4311     *) break ;;
4312   esac
4313 done
4314 AC_SUBST(PACKAGE_PATH)
4315
4316 AC_SUBST(lispdir)
4317 AC_SUBST(LISPDIR_USER_DEFINED)
4318 LISPDIR=$lispdir
4319 while true; do
4320   case "$LISPDIR" in
4321     *\$* ) eval "LISPDIR=$LISPDIR" ;;
4322     *) break ;;
4323   esac
4324 done
4325 AC_SUBST(LISPDIR)
4326
4327 AC_SUBST(moduledir)
4328 AC_SUBST(MODULEDIR_USER_DEFINED)
4329 MODULEDIR=$moduledir
4330 while true; do
4331   case "$MODULEDIR" in
4332     *\$* ) eval "MODULEDIR=$MODULEDIR" ;;
4333     *) break ;;
4334   esac
4335 done
4336 AC_SUBST(MODULEDIR)
4337
4338 AC_SUBST(sitelispdir)
4339 AC_SUBST(SITELISPDIR_USER_DEFINED)
4340 SITELISPDIR=$sitelispdir
4341 while true; do
4342   case "$SITELISPDIR" in
4343     *\$* ) eval "SITELISPDIR=$SITELISPDIR" ;;
4344     *) break ;;
4345   esac
4346 done
4347 AC_SUBST(SITELISPDIR)
4348
4349 AC_SUBST(sitemoduledir)
4350 AC_SUBST(SITEMODULEDIR_USER_DEFINED)
4351 SITEMODULEDIR=$sitemoduledir
4352 while true; do
4353   case "$SITEMODULEDIR" in
4354     *\$* ) eval "SITEMODULEDIR=$SITEMODULEDIR" ;;
4355     *) break ;;
4356   esac
4357 done
4358 AC_SUBST(SITEMODULEDIR)
4359
4360 AC_SUBST(etcdir)
4361 AC_SUBST(ETCDIR_USER_DEFINED)
4362 ETCDIR=$etcdir
4363 while true; do
4364   case "$ETCDIR" in
4365     *\$* ) eval "ETCDIR=$ETCDIR" ;;
4366     *) break ;;
4367   esac
4368 done
4369 AC_SUBST(ETCDIR)
4370
4371 AC_SUBST(docdir)
4372 AC_SUBST(DOCDIR_USER_DEFINED)
4373 DOCDIR=$docdir
4374 while true; do
4375   case "$DOCDIR" in
4376     *\$* ) eval "DOCDIR=$DOCDIR" ;;
4377     *) break ;;
4378   esac
4379 done
4380 AC_SUBST(DOCDIR)
4381
4382 AC_SUBST(archlibdir)
4383 AC_SUBST(ARCHLIBDIR_USER_DEFINED)
4384 ARCHLIBDIR=$archlibdir
4385 while true; do
4386   case "$ARCHLIBDIR" in
4387     *\$* ) eval "ARCHLIBDIR=$ARCHLIBDIR" ;;
4388     *) break ;;
4389   esac
4390 done
4391 AC_SUBST(ARCHLIBDIR)
4392
4393 AC_SUBST(docdir)
4394 AC_SUBST(bitmapdir)
4395 AC_SUBST(extra_objs)
4396
4397 dnl The following flags combine all the information from:
4398 dnl - command line options (user always gets priority)
4399 dnl - user environment variables
4400 dnl - determined by configure
4401 dnl - the s&m header files (required for ellcc)
4402 AC_SUBST(machfile)
4403 AC_SUBST(opsysfile)
4404 AC_SUBST(c_switch_general)
4405 AC_SUBST(c_switch_window_system)
4406 AC_SUBST(c_switch_all)
4407 AC_SUBST(ld_switch_general)
4408 AC_SUBST(ld_switch_window_system)
4409 AC_SUBST(ld_switch_all)
4410 AC_SUBST(ld_libs_general)
4411 AC_SUBST(ld_libs_window_system)
4412 AC_SUBST(ld_libs_all)
4413 AC_SUBST(CFLAGS)
4414 AC_SUBST(CPPFLAGS)
4415 AC_SUBST(LDFLAGS)
4416 RECURSIVE_MAKE="\$(MAKE) \$(MFLAGS) CC='\$(CC)' CFLAGS='\$(CFLAGS)' LDFLAGS='\$(LDFLAGS)' CPPFLAGS='\$(CPPFLAGS)'"
4417 AC_SUBST(RECURSIVE_MAKE)
4418
4419 AC_SUBST(native_sound_lib)
4420 AC_SUBST(sound_cflags)
4421 AC_SUBST(RANLIB)
4422 AC_SUBST(dynodump_arch)
4423
4424 dnl Preliminary support for using a different compiler for xemacs itself.
4425 dnl Useful for building XEmacs with a C++ or 64-bit compiler.
4426 : ${XEMACS_CC:=$CC}
4427 AC_SUBST(XEMACS_CC)
4428
4429 dnl The default is yes
4430 if test "$with_prefix" = "yes"; then
4431   AC_DEFINE(PREFIX_USER_DEFINED)
4432 fi
4433
4434 dnl The default is no
4435 if test "$with_site_lisp" = "no"; then
4436   AC_DEFINE(INHIBIT_SITE_LISP)
4437 fi
4438 dnl The default is yes
4439 if test "$with_site_modules" = "no"; then
4440   AC_DEFINE(INHIBIT_SITE_MODULES)
4441 fi
4442
4443 XE_SPACE(ac_configure_args, $ac_configure_args)
4444 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "$configuration")
4445 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "$ac_configure_args")
4446 AC_DEFINE_UNQUOTED(config_machfile,  "$machfile")
4447 AC_DEFINE_UNQUOTED(config_opsysfile, "$opsysfile")
4448
4449 dnl Following are deprecated
4450
4451 null_string=""
4452 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE,     $null_string)
4453 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, $null_string)
4454 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,      $null_string)
4455 AC_DEFINE_UNQUOTED(LD_SWITCH_SITE,       $null_string)
4456 AC_DEFINE_UNQUOTED(C_SWITCH_SITE,        $null_string)
4457
4458 dnl Note: as a general rule, *only* define things here that are not
4459 dnl autodetected.  For things that are autodetected, define them
4460 dnl at the point where the autodetection occurs or would occur,
4461 dnl so that the user gets immediate feedback on the results of the
4462 dnl autodetection.
4463
4464 if   test "$GNU_MALLOC"         = "yes"; then AC_DEFINE(GNU_MALLOC)
4465 elif test "$with_system_malloc" = "yes"; then AC_DEFINE(USE_SYSTEM_MALLOC)
4466 elif test "$with_debug_malloc"  = "yes"; then AC_DEFINE(USE_DEBUG_MALLOC)
4467                                               AC_DEFINE(USE_SYSTEM_MALLOC)
4468 fi
4469 test "$with_i18n3"         = "yes" && AC_DEFINE(I18N3)
4470 test "$GCC"                = "yes" && AC_DEFINE(USE_GCC)
4471 test "$external_widget"    = "yes" && AC_DEFINE(EXTERNAL_WIDGET)
4472 test "$quick_build"        = "yes" && AC_DEFINE(QUICK_BUILD)
4473 test "$with_purify"        = "yes" && AC_DEFINE(PURIFY)
4474 test "$with_quantify"      = "yes" && AC_DEFINE(QUANTIFY)
4475 test "$with_pop"           = "yes" && AC_DEFINE(MAIL_USE_POP)
4476 test "$with_kerberos"      = "yes" && AC_DEFINE(KERBEROS)
4477 test "$with_hesiod"        = "yes" && AC_DEFINE(HESIOD)
4478 test "$use_union_type"     = "yes" && AC_DEFINE(USE_UNION_TYPE)
4479 test "$pdump"              = "yes" && AC_DEFINE(PDUMP)
4480
4481 dnl -------------------------------
4482 dnl Report on what we decided to do
4483 dnl -------------------------------
4484
4485 (
4486 dnl /etc/osversion is on SONY NEWS-OS
4487 if test -f /etc/osversion; then dnl SONY NEWS-OS
4488   echo "osversion: `cat /etc/osversion`"
4489 else
4490   echo "uname -a: `uname -a`"
4491 fi
4492 echo ""
4493 echo "$0 $quoted_arguments"
4494 ) > Installation
4495
4496 if test ! -z ${emacs_beta_version} ; then
4497   if test -z "${emacs_is_beta}" ; then
4498         xemacs_betaname=".${emacs_beta_version}"
4499   else
4500         xemacs_betaname="-b${emacs_beta_version}"
4501   fi
4502 else
4503   xemacs_betaname=""
4504 fi
4505
4506 dnl Start stdout redirection to '| tee -a Installation'
4507 (
4508 echo "
4509
4510 XEmacs ${emacs_major_version}.${emacs_minor_version}${xemacs_betaname} \"$xemacs_codename\" configured for \`$canonical'.
4511 "
4512 echo "
4513 Compilation / Installation:"
4514 echo "  Source code location:              $srcdir"
4515 echo "  Installation prefix:               $prefix"
4516 if test -n "$site_includes"; then
4517   echo "  Additional header files:           $site_includes"
4518 fi
4519 if test -n "$site_libraries"; then
4520   echo "  Additional libraries:              $site_libraries"
4521 fi
4522 if test -n "$site_prefixes"; then
4523   echo "  Additional prefixes:               $site_prefixes"
4524 fi
4525 if test -n "$runpath"; then
4526   echo "  Runtime library search path:       $runpath"
4527 fi
4528 echo "  Operating system description file: \`$opsysfile'"
4529 echo "  Machine description file:          \`$machfile'"
4530 echo "  Compiler:                          $CC $CFLAGS"
4531 echo "  Relocating allocator for buffers:  $rel_alloc"
4532 echo "  GNU version of malloc:             ${GNU_MALLOC}${GNU_MALLOC_reason}"
4533
4534 echo "
4535 Window System:"
4536 if test "$with_msw" = "yes"; then
4537   echo "  Compiling in support for the Microsoft window system."
4538 fi
4539 if test "$with_x11" = "yes"; then
4540   echo "  Compiling in support for the X window system:"
4541   echo "    - X Windows headers location:                 $x_includes"
4542   echo "    - X Windows libraries location:               $x_libraries"
4543   if test "$with_xauth" != yes; then
4544     echo "    - Xau (X authority) not available."
4545   fi
4546   if test "$with_xmu" != yes; then
4547     echo "    - Xmu library not available; substituting equivalent routines."
4548   fi
4549   if test "$with_wmcommand" != no; then
4550     echo "    - Handling WM_COMMAND properly."
4551   fi
4552 fi
4553 if test "$have_xaw" = "yes"; then
4554   echo "  Compiling in support for the Athena widget set:"
4555   echo "    - Athena headers location:                    $athena_h_path"
4556   echo "    - Athena library to link:                     $athena_lib"
4557 fi
4558 case "$with_menubars" in
4559   lucid ) echo "  Using Lucid menubars." ;;
4560   motif ) echo "  Using Motif menubars."
4561           echo "  *WARNING*  The Motif menubar implementation is currently buggy."
4562           echo "             We recommend using the Lucid menubar instead."
4563           echo "             Re-run configure with --with-menubars='lucid'." ;;
4564     msw ) echo "  Using MS-Windows menubars." ;;
4565 esac
4566 case "$with_scrollbars" in
4567   lucid  ) echo "  Using Lucid scrollbars."      ;;
4568   motif  ) echo "  Using Motif scrollbars."      ;;
4569   athena ) echo "  Using Athena scrollbars."     ;;
4570      msw ) echo "  Using MS-Windows scrollbars." ;;
4571 esac
4572 case "$with_dialogs" in
4573   motif  ) echo "  Using Motif dialog boxes."
4574            if test "$unexec" = "unexaix.o"; then if test "`uname -v`" = 4 -a "`uname -r`" -ge 3; then
4575              echo "  *WARNING*  The Motif dialog boxes cause problems on AIX 4.3 and higher."
4576              echo "             We recommend using the Athena dialog boxes instead."
4577              echo "             Install libXaw and re-run configure with --with-dialogs='athena'."
4578              echo "             Read the PROBLEMS file for more information."
4579            fi; fi ;;
4580   athena ) echo "  Using Athena dialog boxes."     ;;
4581      msw ) echo "  Using MS-Windows dialog boxes." ;;
4582 esac
4583 case "$with_widgets" in
4584   motif  ) echo "  Using Motif native widgets."      ;;
4585   athena ) echo "  Using Athena native widgets."     ;;
4586      msw ) echo "  Using MS-Windows native widgets." ;;
4587 esac
4588 if test "$with_dragndrop" = yes; then
4589   echo "  Compiling in support for Drag'n'Drop (EXPERIMENTAL)."
4590   echo "    -  Drag'n'Drop prototype:                             $dragndrop_proto."
4591 fi
4592
4593 echo "
4594 TTY:"
4595 test "$with_ncurses" = yes && echo "  Compiling in support for ncurses."
4596 test "$with_gpm" = yes && echo "  Compiling in support for GPM (General Purpose Mouse)."
4597
4598 echo "
4599 Images:"
4600 test "$with_gif" = yes && echo "  Compiling in support for GIF  images (builtin)."
4601 if test "$with_xpm" = yes; then
4602   echo "  Compiling in support for XPM  images."
4603 elif test "$with_x11" = yes; then
4604   echo "  WARNING: -----------------------------------------------------------"
4605   echo "  WARNING: Compiling without XPM image support."
4606   if test "$xpm_problem" != ""; then
4607     echo "  Reason: $xpm_problem"
4608   fi
4609   echo "  WARNING: You should strongly consider installing XPM."
4610   echo "  WARNING: Otherwise toolbars and other graphics will look suboptimal."
4611   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4612   echo "  WARNING: -----------------------------------------------------------"
4613 fi
4614 if test "$with_png" = yes; then
4615   echo "  Compiling in support for PNG  images."
4616 elif test "$window_system" != "none"; then
4617   echo "  WARNING: -----------------------------------------------------------"
4618   echo "  WARNING: Compiling without PNG image support."
4619   if test "$png_problem" != ""; then
4620     echo "  Reason: $png_problem"
4621   fi
4622   echo "  WARNING: You should strongly consider installing the PNG libraries."
4623   echo "  WARNING: Otherwise certain images and glyphs may not display."
4624   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4625   echo "  WARNING: -----------------------------------------------------------"
4626 fi
4627 test "$with_jpeg" = yes && echo "  Compiling in support for JPEG images."
4628 test "$with_tiff" = yes && echo "  Compiling in support for TIFF images."
4629 test "$with_xface" = yes && echo "  Compiling in support for X-Face message headers."
4630
4631 echo "
4632 Sound:"
4633 test "$with_native_sound" = yes && echo "  Compiling in support for sound (native)."
4634 test "$with_nas_sound" = yes && echo "  Compiling in support for NAS (network audio system)."
4635 test "$old_nas" = yes && echo "    - NAS library lacks error trapping; will play synchronously."
4636 test "$with_esd_sound" = yes && echo "  Compiling in support for ESD (Enlightened Sound Daemon)."
4637
4638 echo "
4639 Databases:"
4640 test "$with_database_berkdb" = yes && echo "  Compiling in support for Berkeley database."
4641 test "$with_database_dbm"    = yes && echo "  Compiling in support for DBM."
4642 test "$with_database_gdbm"   = yes && echo "  Compiling in support for GNU DBM."
4643 test "$with_ldap" = yes && echo "  Compiling in support for LDAP."
4644 if test "$with_postgresql" = yes; then
4645   echo "  Compiling in support for PostgreSQL."
4646   if test "$with_postgresqlv7" = yes; then
4647     echo "    - Using PostgreSQL V7 bindings."
4648   fi
4649   if test -n "$postgres_h_path"; then
4650     echo "    - PostgreSQL headers location:  $postgres_h_path"
4651   fi
4652 fi
4653
4654 echo "
4655 Internationalization:"
4656 test "$with_mule" = yes && echo "  Compiling in support for Mule (multi-lingual Emacs)."
4657 test "$with_utf_2000" = yes && echo "  Using UTF-2000 (UTF-8) buffer/string representation."
4658 test "$with_text_coding" = yes && echo "  Compiling in support for text coding."
4659 test "$with_file_coding" = yes && echo "  Compiling in support for file coding."
4660 test "$with_xim" != no && echo "  Compiling in support for XIM (X11R5+ I18N input method)."
4661 test "$with_xim" = motif && echo "    - Using Motif to provide XIM support."
4662 test "$with_xim" = xlib && echo "    - Using raw Xlib to provide XIM support."
4663 test "$with_xfs" = yes && echo "    - Using XFontSet to provide bilingual menubar."
4664 test "$with_canna" = yes && echo "  Compiling in support for Canna on Mule."
4665 if test "$with_wnn" = yes; then
4666   echo "  Compiling in support for the WNN input method on Mule."
4667   test "$with_wnn6" = yes && echo "    - Using WNN version 6."
4668 fi
4669 test "$with_i18n3" = yes && echo "  Compiling in support for I18N level 3 (doesn't currently work)."
4670
4671 echo "
4672 Mail:"
4673 test "$with_pop" = yes && echo "  Compiling in support for POP mail retrieval."
4674 test "$with_kerberos" = yes && echo "  Compiling in support for Kerberos POP authentication."
4675 test "$with_hesiod" = yes && echo "  Compiling in support for Hesiod POP server access."
4676 echo "  Compiling in support for \"$mail_locking\" mail spool file locking method."
4677
4678 echo "
4679 Other Features:"
4680 test "$with_tooltalk" = yes && echo "  Compiling in support for ToolTalk."
4681 test "$with_workshop" = yes && echo "  Compiling in support for Sun WorkShop."
4682 test "$with_socks" = yes && echo "  Compiling in support for SOCKS."
4683 test "$with_dnet" = yes && echo "  Compiling in support for DNET."
4684 test "$with_modules" = "yes" && echo "  Compiling in support for dynamic shared object modules."
4685 test "$use_union_type" = yes && echo "  Using the union type for Lisp_Objects."
4686 test "$pdump" = yes && echo "  Using the new portable dumper."
4687 test "$debug" = yes && echo "  Compiling in support for extra debugging code."
4688 test "$usage_tracking" = yes && echo "  Compiling in support for active usage tracking (Sun internal)."
4689 if test "$error_check_extents $error_check_typecheck $error_check_bufpos $error_check_gc $error_check_malloc $error_check_glyphs" \
4690   != "no no no no no no"; then
4691   echo "  WARNING: ---------------------------------------------------------"
4692   echo "  WARNING: Compiling in support for runtime error checking."
4693   echo "  WARNING: XEmacs will run noticeably more slowly as a result."
4694   echo "  WARNING: Error checking is on by default for XEmacs beta releases."
4695   echo "  WARNING: ---------------------------------------------------------"
4696 fi
4697 echo ""
4698 ) | tee -a Installation
4699 dnl echo "The above configure report is appended to \"Installation\" file."
4700 echo ""
4701
4702 dnl -----------------------------------
4703 dnl Now generate config.h and Makefiles
4704 dnl -----------------------------------
4705 dnl This has to be called in order for this variable to get into config.status
4706 AC_SUBST(internal_makefile_list)
4707 # Remove any trailing slashes in these variables.
4708 test -n "$prefix" &&
4709   prefix=`echo '' "$prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4710 test -n "$exec_prefix" &&
4711   exec_prefix=`echo '' "$exec_prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4712
4713 dnl Build Makefile.in's from Makefile.in.in's
4714 dnl except ./Makefile from $srcdir/Makefile.in
4715
4716 for file in $internal_makefile_list; do
4717   test "$file" = src/Makefile.in && \
4718     file="src/Makefile.in:src/Makefile.in.in:src/depend"
4719   XE_APPEND($file, ac_output_files)
4720 done
4721 ac_output_files="$ac_output_files src/paths.h lib-src/config.values"
4722 test "$with_modules" = "yes" && XE_APPEND(lib-src/ellcc.h, ac_output_files)
4723
4724 AC_OUTPUT($ac_output_files,
4725 [for dir in . $MAKE_SUBDIR; do
4726   (
4727     cd $dir
4728     rm -f junk.c
4729     < Makefile.in \
4730       sed -e '/^# Generated/d' \
4731           -e 's%/\*\*/#.*%%' \
4732           -e 's/^ *# */#/' \
4733 dnl Delete Makefile.in.in comment lines
4734           -e '/^##/d' \
4735 dnl Pass through CPP directives unchanged
4736           -e '/^#/ {
4737 p
4738 d
4739 }'        \
4740 dnl Quote other lines to protect from CPP substitution
4741           -e '/./ {
4742 s/\([[\"]]\)/\\\1/g
4743 s/^/"/
4744 s/$/"/
4745 }'  > junk.c;
4746
4747 dnl Create a GNUmakefile and Makefile from Makefile.in.
4748
4749 changequote(<<,>>)dnl
4750 dnl CPP_MAKEFILE(CPPFLAGS,filename)
4751 define(<<CPP_MAKEFILE>>,
4752 echo creating $dir/<<$2>>
4753 $CPP -I. -I${top_srcdir}/src <<$1>> junk.c \
4754 dnl Delete line directives inserted by $CPP
4755   | sed -e 's/^\#.*//'          \
4756 dnl Delete spurious blanks inserted by $CPP
4757         -e 's/^[ TAB][ TAB]*$//'\
4758         -e 's/^ /TAB/'          \
4759 dnl Delete blank lines
4760   | sed -n -e '/^..*$/p'        \
4761 dnl Restore lines quoted above to original contents.
4762   | sed '/^\"/ {
4763         s/\\\([\"]\)/\1/g
4764         s/^[ TAB]*\"//
4765         s/\"[ TAB]*$//
4766 }' > Makefile.new
4767     chmod 444 Makefile.new
4768     mv -f Makefile.new <<$2>>
4769 )dnl CPP_MAKEFILE
4770
4771     CPP_MAKEFILE(,Makefile)
4772     CPP_MAKEFILE(-DUSE_GNU_MAKE,GNUmakefile)
4773 changequote([,])dnl
4774     rm -f junk.c
4775   )
4776 done
4777
4778 dnl Append AC_DEFINE information to lib-src/config.values
4779 dnl (AC_SUBST information is already there (see config.values.sh).
4780 sed < config.status >> lib-src/config.values \
4781   -e '/{ac_dA}.*{ac_dB}.*{ac_dC}.*{ac_dD}$/!d' \
4782   -e 's/\${ac_dA}\(.*\)\${ac_dB}.*\${ac_dC}\(.*\)\${ac_dD}/\1 \2/' \
4783   -e 's/^\([[^ ]]*\) $/\1 ""/' \
4784   -e 's/ 1$/ t/'
4785
4786 ],
4787 [CPP="$CPP"
4788  top_srcdir="$srcdir"
4789  MAKE_SUBDIR="$MAKE_SUBDIR"
4790 ])dnl