configure.in

   1 dnl Define our own header notice with own copyright
   2 define([AC_INIT_NOTICE],
   3 [#### Configuration script for XEmacs.  Largely divergent from FSF.
   4 #### Guess values for system-dependent variables and create Makefiles.
   5 #### Generated automatically using autoconf version] AC_ACVERSION [
   6 #### Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000 Free Software Foundation, Inc.
   7 #### Copyright (C) 1993-1995 Board of Trustees, University of Illinois.
   8 #### Copyright (C) 1996, 1997 Sun Microsystems, Inc.
   9 #### Copyright (C) 1995, 1996 Ben Wing.
  10 #### Copyright (C) 2000, 2001 Martin Buchholz.
  11 #### Copyright (C) 1998, 1999 J. Kean Johnston.
  12
  13 ### Don't edit this script!
  14 ### This script was automatically generated by the `autoconf' program
  15 ### from the file `./configure.in'.
  16 ### To rebuild it, execute the command
  17 ###     autoconf
  18 ### in the this directory.  You must have autoconf version 2.13 or later.
  19 ### Note: this script has not yet been ported to autoconf version 2.5x.
  20
  21 ### This file is part of XEmacs.
  22
  23 ### XEmacs is free software; you can redistribute it and/or modify it
  24 ### under the terms of the GNU General Public License as published by
  25 ### the Free Software Foundation; either version 2, or (at your
  26 ### option) any later version.
  27
  28 ### XEmacs is distributed in the hope that it will be useful, but
  29 ### WITHOUT ANY WARRANTY; without even the implied warranty of
  30 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31 ### General Public License for more details.
  32
  33 ### You should have received a copy of the GNU General Public License
  34 ### along with XEmacs; see the file COPYING.  If not, write to the Free
  35 ### Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  36 ### 02111-1307, USA.
  37
  38 ### For usage, run `./configure --help'
  39 ### For more detailed information on building and installing XEmacs,
  40 ### read the file `INSTALL'.
  41 ###
  42 ### If configure succeeds, it leaves its status in config.status.
  43 ### A log of configuration tests can be found in config.log.
  44 ### If configure fails after disturbing the status quo,
  45 ###     config.status is removed.
  46 ])
  47
  48 dnl Since XEmacs has configuration requirements that autoconf cannot
  49 dnl meet, this file is an unholy marriage of custom-baked
  50 dnl configuration code and autoconf macros.
  51
  52 dnl We use the m4 quoting characters [ ] (as established by the
  53 dnl autoconf system), so quote them like this: [[foo]]
  54
  55 AC_PREREQ(2.13)dnl
  56 dnl Redefine some standard autoconf macros
  57 dnl here is how XEmacs is different:
  58 dnl - no cache file
  59 dnl - non-standard options
  60 dnl - support for extra-verbosity
  61 dnl - ordinary libs are handled separately from X libs (might be a mistake)
  62 dnl - various random kludges (e.g. -with-dnet=no)
  63
  64 dnl PRINT_VAR(var var ...)  prints values of shell variables
  65 define([PRINT_VAR],[for var in patsubst([$1],[[
  66 ]+],[ ]); do eval "echo \"$var = '\$$var'\""; done])
  67
  68 dnl Disable cache files:
  69 dnl This is controversial, but I am convinced this is the right way to go,
  70 dnl at least by default.  Otherwise there are too many surprises.
  71 define([AC_CACHE_LOAD], )dnl
  72 define([AC_CACHE_SAVE], )dnl
  73 define([AC_CACHE_VAL], [
  74 $2
  75 ])dnl
  76
  77 dnl Redefine AC_TRY_RUN_NATIVE to not throw away stderr while running
  78 dnl AC_TRY_RUN_NATIVE(PROGRAM, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
  79 define([AC_TRY_RUN_NATIVE],
  80 [cat > conftest.$ac_ext <<EOF
  81 [#]line __oline__ "configure"
  82 #include "confdefs.h"
  83 [$1]
  84 EOF
  85 if AC_TRY_EVAL(ac_link) && test -s conftest && (./conftest; exit $?) 2>&AC_FD_CC
  86 then
  87 dnl Do not remove the temporary files here, so they can be examined.
  88   ifelse([$2], , :, [$2])
  89 else
  90   conftest_rc="$?"
  91   echo "configure: failed program was:" >&AC_FD_CC
  92   cat conftest.$ac_ext >&AC_FD_CC
  93 ifelse([$3], , , [  rm -fr conftest*
  94   $3
  95 ])dnl
  96 fi
  97 rm -fr conftest*])dnl AC_TRY_RUN_NATIVE
  98
  99
 100 dnl Avoid spurious cross-compiling warnings from AC_TRY_RUN
 101 dnl XEmacs is unlikely to ever cross-compile
 102 define([AC_TRY_RUN],[AC_TRY_RUN_NATIVE([$1], [$2], [$3])])dnl
 103
 104 dnl Redefine AC_DEFINE* to provide more output if extra_verbose
 105 dnl Set VARIABLE to VALUE, verbatim, or 1.
 106 dnl AC_DEFINE(VARIABLE [, VALUE])
 107 define([AC_DEFINE],
 108 [{ test "$extra_verbose" = "yes" && cat << \EOF
 109     Defining $1[]ifelse($#, 2, [ = $2],)
 110 EOF
 111 cat >> confdefs.h <<\EOF
 112 [#define] $1 ifelse($#, 2, [$2], 1)
 113 EOF
 114 }
 115 ])dnl AC_DEFINE
 116
 117 define([AC_DEFINE_UNQUOTED],
 118 [{ test "$extra_verbose" = "yes" && cat << EOF
 119     Defining $1[]ifelse($#, 2, [ = $2],)
 120 EOF
 121 cat >> confdefs.h <<EOF
 122 [#define] $1 ifelse($#, 2, [$2], 1)
 123 EOF
 124 }
 125 ])dnl AC_DEFINE_UNQUOTED
 126
 127 dnl redefine AC_CHECK_LIB in accordance with our own value of ac_link
 128 dnl Add in extra kludgy check to support with_dnet=no
 129 dnl Add in extra LDFLAGS arg, which PRECEDES libs
 130 dnl Support --with-dnet=no
 131
 132 dnl AC_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
 133 dnl             [, OTHER-LIBRARIES] [, LDFLAGS]]]])
 134 define([AC_CHECK_LIB],
 135 [ifelse([$1],dnet, [if test "$with_dnet" = "no" ; then
 136 ac_cv_lib_dnet_dnet_ntoa=no
 137 ifelse([$4], , , [$4]
 138 )dnl
 139 else
 140 ])]
 141 AC_CHECK_LIB_ORIG_HACKED([$1],[$2],[$3],[$4],[$5], [$6])
 142 [ifelse([$1],dnet,[fi
 143 ])]dnl
 144 )dnl AC_CHECK_LIB
 145
 146 define([AC_CHECK_LIB_ORIG_HACKED],
 147 [ifelse([$5],,AC_MSG_CHECKING([for $2 in -l$1]),
 148 xe_msg_checking="for [$2] in -l[$1]"
 149 test -n "[$5]" && xe_msg_checking="$xe_msg_checking using extra libs [$5]"
 150 AC_MSG_CHECKING("$xe_msg_checking"))
 151 dnl Use a cache variable name containing both the library and function name,
 152 dnl because the test really is for library $1 defining function $2, not
 153 dnl just for library $1.  Separate tests with the same $1 and different $2s
 154 dnl may have different results.
 155 ac_lib_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
 156 AC_CACHE_VAL(ac_cv_lib_$ac_lib_var,
 157 [xe_check_libs="$6 -l$1 $5"
 158 AC_TRY_LINK(dnl
 159 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 160 [/* Override any gcc2 internal prototype to avoid an error.  */
 161 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 162 extern "C"
 163 #endif
 164 ])dnl
 165 [/* We use char because int might match the return type of a gcc2
 166     builtin and then its argument prototype would still apply.  */
 167 char $2();
 168 ]),
 169             [$2()],
 170             eval "ac_cv_lib_$ac_lib_var=yes",
 171             eval "ac_cv_lib_$ac_lib_var=no")
 172 xe_check_libs=""
 173 ])dnl
 174 if eval "test \"`echo '$ac_cv_lib_'$ac_lib_var`\" = yes" ; then
 175   AC_MSG_RESULT(yes)
 176   ifelse([$3], ,
 177 [changequote(, )dnl
 178   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 179     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 180 changequote([, ])dnl
 181   AC_DEFINE_UNQUOTED($ac_tr_lib)
 182   XE_PREPEND([-l$1], LIBS)
 183 ], [$3])
 184 else
 185   AC_MSG_RESULT(no)
 186 ifelse([$4], , , [$4
 187 ])dnl
 188 fi
 189 ])dnl AC_CHECK_LIB_ORIG_HACKED
 190
 191
 192 dnl AC_LANG_C()
 193 define([AC_LANG_C],
 194 [define([AC_LANG], [C])dnl
 195 ac_ext=c
 196 dnl CFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
 197 dnl ac_cpp='$CPP $CPPFLAGS'
 198 dnl ac_compile='${CC-cc} -c $CFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC'
 199 dnl ac_link='${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC'
 200 xe_cppflags='$CPPFLAGS $c_switch_site $c_switch_machine $c_switch_system $c_switch_x_site $X_CFLAGS'
 201 xe_ldflags='$LDFLAGS $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_x_site $ld_switch_run'
 202 xe_libs='$ld_call_shared $xe_check_libs $X_EXTRA_LIBS $libs_x $libs_gtk $X_PRE_LIBS $LIBS $libs_machine $libs_system $libs_standard'
 203 ac_cpp='$CPP '"$xe_cppflags"
 204 ac_compile='${CC-cc} -c $CFLAGS '"$xe_cppflags"' conftest.$ac_ext 1>&AC_FD_CC'
 205 ac_link='${CC-cc} -o conftest $CFLAGS '"$xe_cppflags $xe_ldflags"' conftest.$ac_ext '"$xe_libs"' 1>&AC_FD_CC'
 206 cross_compiling=no
 207 ]) dnl AC_LANG_C
 208
 209 dnl The construct foo=`echo $w1 $w2 $w3` fails on some systems if $w1 = -e or -n
 210 dnl So we use the following instead.
 211 dnl XE_SPACE(var, words)
 212 define([XE_SPACE],[
 213 T=""
 214 for W in $2; do if test -z "$T"; then T="$W"; else T="$T $W"; fi; done
 215 $1="$T"
 216 ])dnl XE_SPACE
 217
 218 dnl XE_ADD_OBJS(foo.o ...)
 219 define([XE_ADD_OBJS],
 220 [extra_objs="$extra_objs [$1]" && dnl
 221  if test "$extra_verbose" = "yes"; then
 222    echo "    xemacs will be linked with \"[$1]\""
 223  fi])dnl XE_ADD_OBJS
 224
 225 dnl XE_APPEND(value, varname)
 226 define([XE_APPEND],
 227 [[$2]="$[$2] [$1]" && dnl
 228  if test "$extra_verbose" = "yes"; then echo "    Appending \"[$1]\" to \$[$2]"; fi])
 229
 230 dnl XE_PREPEND(value, varname)
 231 define([XE_PREPEND],
 232 [[$2]="[$1] $[$2]" && dnl
 233  if test "$extra_verbose" = "yes"; then echo "    Prepending \"[$1]\" to \$[$2]"; fi])
 234
 235 dnl XE_DIE(message)
 236 define([XE_DIE], [{ echo "Error:" $1 >&2; exit 1; }])
 237
 238 dnl XE_STRIP_4TH_COMPONENT(var)
 239 dnl Changes i986-pc-linux-gnu to i986-pc-linux, as God (not RMS) intended.
 240 define([XE_STRIP_4TH_COMPONENT],
 241 [$1=`echo "$$1" | sed '[s/^\([^-][^-]*-[^-][^-]*-[^-][^-]*\)-.*$/\1/]'`])
 242
 243 dnl Initialize some variables set by options.
 244 dnl The variables have the same names as the options, with
 245 dnl dashes changed to underlines.
 246
 247 define([AC_INIT_PARSE_ARGS],[
 248
 249 dnl Get sane consistent behavior from various shells
 250 dnl Avoid losing with weird user CDPATHs
 251
 252 if test -n "$ZSH_VERSION"; then
 253   dnl zsh's Bourne shell emulation options
 254   setopt NO_BAD_PATTERN NO_BANG_HIST NO_BG_NICE NO_EQUALS NO_FUNCTION_ARGZERO
 255   setopt GLOB_SUBST NO_HUP INTERACTIVE_COMMENTS KSH_ARRAYS NO_MULTIOS NO_NOMATCH
 256   setopt RM_STAR_SILENT POSIX_BUILTINS SH_FILE_EXPANSION SH_GLOB SH_OPTION_LETTERS
 257   setopt SH_WORD_SPLIT BSD_ECHO IGNORE_BRACES
 258   dnl zsh-3.1-beta drops core on the following
 259   dnl unset CDPATH
 260   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 261 elif test -n "$BASH_VERSION"; then
 262   dnl Use Posix mode with bash
 263   set -o posix
 264   unset CDPATH
 265 else
 266   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 267 fi
 268
 269 dnl Initialize some variables set by options.
 270 dnl The variables have the same names as the options, with
 271 dnl dashes changed to underlines.
 272 exec_prefix=NONE
 273 host=NONE
 274 no_create=
 275 nonopt=NONE
 276 no_recursion=
 277 prefix=NONE
 278 program_prefix=NONE
 279 program_suffix=NONE
 280 program_transform_name=s,x,x,
 281 silent=
 282 site=
 283 srcdir=
 284 target=NONE
 285 verbose=
 286 x_includes=NONE
 287 x_libraries=NONE
 288
 289 dnl Initialize some other variables.
 290 subdirs=
 291 MFLAGS= MAKEFLAGS=
 292 SHELL=${CONFIG_SHELL-/bin/sh}
 293 dnl Maximum number of lines to put in a shell here document.
 294 ac_max_here_lines=12
 295 ])dnl AC_INIT_PARSE_ARGS
 296
 297 AC_INIT(src/lisp.h)dnl
 298 AC_CONFIG_HEADER(src/config.h lwlib/config.h)
 299 dnl Remove any more than one leading "." element from the path name.
 300 dnl If we do not remove them, then another "./" will be prepended to
 301 dnl the file name each time we use config.status, and the program name
 302 dnl will get larger and larger.  This would not be a problem, except
 303 dnl that since progname gets recorded in all the Makefiles this script
 304 dnl produces, move-if-change thinks they're different when they're
 305 dnl not.
 306 dnl
 307 dnl It would be nice if we could put the ./ in a \( \) group and then
 308 dnl apply the * operator to that, so we remove as many leading './././'s
 309 dnl as are present, but some seds (like Ultrix's sed) don't allow you to
 310 dnl apply * to a \( \) group.  Bleah.
 311 progname="`echo $0 | sed 's:^\./\./:\./:'`"
 312
 313 dnl -----------------------------
 314 dnl Establish some default values
 315 dnl -----------------------------
 316
 317 XE_APPEND(lib-src, MAKE_SUBDIR)
 318 XE_APPEND(lib-src, INSTALL_ARCH_DEP_SUBDIR)
 319
 320 prefix='/usr/local'
 321 exec_prefix='${prefix}'
 322 bindir='${exec_prefix}/bin'
 323 dnl FSF 19.29 changes to:
 324 dnl datadir='${prefix}/share'
 325 dnl sharedstatedir='${prefix}/com'
 326 dnl libexecdir='${exec_prefix}/libexec'
 327 datadir='${prefix}/lib'
 328 statedir='${prefix}/lib'
 329 libdir='${exec_prefix}/lib'
 330 mandir='${prefix}/man/man1'
 331 inststaticdir='${PROGNAME}'
 332 instvardir='${PROGNAME}-${version}'
 333 infodir='${datadir}/${instvardir}/info'
 334 infopath=''
 335 install_pp=''
 336 lispdir='${datadir}/${instvardir}/lisp'
 337 moduledir='${libdir}/${instvardir}/${configuration}/modules'
 338 sitelispdir='${datadir}/${inststaticdir}/site-lisp'
 339 sitemoduledir='${libdir}/${inststaticdir}/site-modules'
 340 pkgdir='${datadir}/${instvardir}/lisp'
 341 package_path=''
 342 etcdir='${datadir}/${instvardir}/etc'
 343 archlibdir='${libdir}/${instvardir}/${configuration}'
 344 docdir='${archlibdir}'
 345 with_netinstall="no"
 346 with_prefix='yes'
 347 with_site_lisp='no'
 348 with_site_modules='yes'
 349 with_menubars=''
 350 with_scrollbars=''
 351 with_widgets=''
 352 with_dialogs=''
 353 with_file_coding=''
 354 cpp='' cppflags='' libs='' ldflags=''
 355 extra_includes=''
 356 dynamic=''
 357 with_x11=''
 358 with_msw=''
 359 rel_alloc='default'
 360 with_system_malloc='default'
 361 with_dlmalloc='default'
 362 dnl ESD is associated with crashes and lockups due to incorrect signal use.
 363 with_esd_sound='no'
 364 native_sound_lib=''
 365 dnl These should be set to the empty string when we want gtk / gnome to
 366 dnl be auto-detected instead of manually specified.
 367 with_gtk='no'
 368 with_gnome='no'
 369 dnl use_assertions should be 'yes' by default.  Too many people in this
 370 dnl world have core dumps turned off by default or \"cannot find where the
 371 dnl core file went\".  At least we should get some useful output ...
 372 use_assertions="yes"
 373 dnl the following is set to yes or no later.
 374 with_toolbars=""
 375 with_tty=""
 376 use_union_type="no"
 377 with_dnet=""
 378 pdump="no"
 379 dnl dragndrop is still experimental.  When it is stable, comment out the following line:
 380 with_dragndrop="no"
 381 dnl Too annoying, even if mandated by IPv6 (and I'm not even sure of that)
 382 with_ipv6_cname="no"
 383
 384 dnl ------------------
 385 dnl Options Processing
 386 dnl ------------------
 387
 388 define([USAGE_ERROR],
 389 [(echo "$progname: Usage error:"
 390 echo " " $1
 391 echo "  Use \`$progname --help' to show usage.") >&2 && exit 1])
 392
 393 dnl Record all the arguments, so we can save them in config.status.
 394 arguments="$@"
 395
 396 dnl Shell Magic: Quote the quoted arguments in ARGUMENTS.  At a later date,
 397 dnl in order to get the arguments back in $@, we have to do an
 398 dnl 'eval set x "$quoted_arguments"; shift'
 399 dnl # We use sed to turn embedded ' into '"'"'.  I truly hate sh quoting.
 400 quoted_sed_magic=s/"'"/"'"'"'"'"'"'"'"/g
 401 quoted_arguments=
 402 for i in "$@"; do
 403    case "$i" in
 404    -no-create | --no-create | --no-creat | --no-crea | --no-cre \
 405    | --no-cr | --no-c) ;;
 406    -no-recursion | --no-recursion | --no-recursio | --no-recursi \
 407    | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;
 408    *)
 409    quoted_i="`echo '' $i | sed -e 's:^ ::' -e $quoted_sed_magic`"
 410    quoted_arguments="$quoted_arguments '$quoted_i'" ;;
 411    esac
 412 done
 413
 414 dnl Do not use shift -- that destroys the argument list, which autoconf needs
 415 dnl to produce config.status.  It turns out that "set - $arguments" does not
 416 dnl work portably.
 417 dnl However, it also turns out that many shells cannot expand ${10} at all.
 418 dnl So using an index variable does not work either.  It is possible to use
 419 dnl some shell magic to make 'set x "$arguments"; shift' work portably.
 420 while test $# != 0; do
 421   arg="$1"; shift
 422   case "$arg" in
 423     --no-create|--no-recursion) ;;
 424     dnl Anything starting with a hyphen we assume is an option.
 425     -* )
 426       dnl Separate the switch name from the value it is being given.
 427       case "$arg" in
 428         -*=*)
 429           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\([[^=]]*\)=.*$:\1:'`
 430           val=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*[[^=]]*=\(.*\)$:\1:'`
 431           valomitted=no
 432         ;;
 433            dnl special case these strings since echo may silently eat them:
 434            dnl --help ) opt=help val=yes valomitted=yes ;;
 435            dnl --version ) opt=version val=yes valomitted=yes ;;
 436            dnl -e ) opt=e val=yes valomitted=yes ;;
 437            dnl -E ) opt=E val=yes valomitted=yes ;;
 438            dnl -n ) opt=n val=yes valomitted=yes ;;
 439         -*)
 440            dnl If FOO is a boolean argument, --FOO is equivalent to
 441            dnl --FOO=yes.  Otherwise, the value comes from the next
 442            dnl argument - see below.
 443           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\(.*\)$:\1:'`
 444           val="yes" valomitted=yes
 445         ;;
 446       esac
 447
 448       dnl translate "-" in option string to "_"
 449       optname="$opt"
 450       opt="`echo '' $opt | sed -e 's:^ ::' | tr - _`"
 451
 452       dnl Support --without-FOO as a synonym for --with-FOO=no
 453       case "${valomitted}-${opt}" in yes-without_* )
 454         opt=`echo $opt | sed 's/without/with/'`
 455         valomitted="no" val="no" ;;
 456       esac
 457
 458       dnl Process the option.
 459       case "$opt" in
 460
 461       dnl Process (many) boolean options
 462         with_site_lisp  | \
 463         with_prefix     | \
 464         with_site_modules | \
 465         with_x          | \
 466         with_x11        | \
 467         with_gtk        | \
 468         with_gnome      | \
 469         with_msw        | \
 470         with_gcc        | \
 471         dynamic         | \
 472         with_ncurses    | \
 473         with_dnet       | \
 474         with_socks      | \
 475         with_dragndrop  | \
 476         with_cde        | \
 477         with_offix      | \
 478         with_gpm        | \
 479         with_xpm        | \
 480         with_xface      | \
 481         with_gif        | \
 482         with_jpeg       | \
 483         with_png        | \
 484         with_tiff       | \
 485         with_wmcommand  | \
 486         with_xmu        | \
 487         with_purify     | \
 488         with_quantify   | \
 489         with_toolbars   | \
 490         with_tty        | \
 491         with_xfs        | \
 492         with_i18n3      | \
 493         with_mule       | \
 494         with_utf_2000   | \
 495         with_text_coding| \
 496         with_file_coding| \
 497         with_canna      | \
 498         with_wnn        | \
 499         with_wnn6       | \
 500         with_workshop   | \
 501         with_sparcworks | \
 502         with_tooltalk   | \
 503         with_ldap       | \
 504         with_postgresql | \
 505         with_pop        | \
 506         with_kerberos   | \
 507         with_hesiod     | \
 508         with_dnet       | \
 509         with_infodock   | \
 510         with_netinstall | \
 511         with_ipv6_cname | \
 512         external_widget | \
 513         verbose         | \
 514         extra_verbose   | \
 515         usage_tracking  | \
 516         use_union_type  | \
 517         pdump           | \
 518         debug           | \
 519         use_assertions  | \
 520         memory_usage_stats | \
 521         with_clash_detection | \
 522         with_modules | \
 523         quick_build )
 524           dnl Make sure the value given was either "yes" or "no".
 525           case "$val" in
 526             y | ye | yes )      val=yes ;;
 527             n | no )            val=no  ;;
 528             * ) USAGE_ERROR("The \`--$optname' option requires a boolean value: \`yes' or \`no'.") ;;
 529           esac
 530           eval "$opt=\"$val\"" ;;
 531
 532
 533         dnl Options that take a user-supplied value, as in --x-includes=/usr/X11R6/include
 534         dnl The cache-file option is ignored (for compatibility with other configures)
 535         srcdir          | \
 536         compiler        | \
 537         cflags          | \
 538         cpp             | \
 539         cppflags        | \
 540         libs            | \
 541         ldflags         | \
 542         cache_file      | \
 543         native_sound_lib| \
 544         site_lisp       | \
 545         x_includes      | \
 546         x_libraries     | \
 547         site_includes   | \
 548         site_libraries  | \
 549         site_prefixes   | \
 550         site_runtime_libraries )
 551           dnl If the value was omitted, get it from the next argument.
 552           if test "$valomitted" = "yes" ; then
 553             dnl Get the next argument from the argument list, if there is one.
 554             if test "$#" = 0 ; then
 555               USAGE_ERROR("The \`--$optname' option requires a value.");
 556             fi
 557             val="$1"; shift
 558           fi
 559           eval "$opt=\"$val\""
 560         ;;
 561
 562         dnl Options that take "yes", "no", or "default" values
 563         rel_alloc | \
 564         with_dlmalloc | \
 565         with_debug_malloc  | use_debug_malloc | \
 566         with_system_malloc | use_system_malloc )
 567           case "$val" in
 568             y | ye | yes )      val=yes ;;
 569             n | no )            val=no  ;;
 570             d | de | def | defa | defau | defaul | default ) val=default ;;
 571             * ) USAGE_ERROR(["The \`--$optname' option requires one of these values:
 572   \`yes', \`no', or \`default'."]) ;;
 573           esac
 574           case "$opt" in use_* ) opt="`echo $opt | sed s/use/with/`" ;; esac
 575           eval "$opt=\"$val\""
 576         ;;
 577
 578         dnl Has the user requested database support?
 579         "with_database" )
 580           with_database_berkdb=no
 581           with_database_dbm=no
 582           with_database_gdbm=no
 583           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 584             case "$x" in
 585               no ) ;;
 586               b | be | ber | berk | berkd | berkdb )       with_database_berkdb=yes ;;
 587               d | db | dbm )                               with_database_dbm=yes    ;;
 588               g | gn | gnu | gnud | gnudb | gnudbm | gdbm) with_database_gdbm=yes   ;;
 589               * ) USAGE_ERROR(["The \`--$optname' option value
 590   must be either \`no' or a comma-separated list
 591   of one or more of \`berkdb' and either \`dbm' or \`gnudbm'."]) ;;
 592             esac
 593           done
 594           if test "$with_database_dbm"  = "yes" -a \
 595                   "$with_database_gdbm" = "yes"; then
 596           USAGE_ERROR("Only one of \`dbm' and \`gnudbm' may be specified
 597   with the \`--$optname' option.")
 598           fi
 599         ;;
 600
 601         dnl Has the user requested sound support?
 602         "with_sound" )
 603         dnl values is a subset of all,native,nas,esd
 604         dnl or their negatives: none,nonative,nonas,noesd
 605           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 606             case "$x" in
 607               dnl all and none are only permitted as the first in the list.
 608               n | no | non | none ) new_sdefault=no ;;
 609               a | al | all | both ) new_sdefault=yes ;;
 610
 611               native )       with_native_sound=yes ;;
 612               nonative )     with_native_sound=no ;;
 613
 614               nas )          with_nas_sound=yes ;;
 615               nonas )        with_nas_sound=no ;;
 616
 617               esd )          with_esd_sound=yes ;;
 618               noesd )        with_esd_sound=no ;;
 619
 620               * ) bogus_sound=yes ;;
 621             esac
 622             if test "$bogus_sound" -o \
 623                  \( -n "$new_sdefault" -a -n "$sound_notfirst" \) ; then
 624                 types="\`all', \`none', \`(no)native', \`no(nas)', \`(no)esd'."
 625                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 626   $types.
 627 Option \`all' or \`none' must be first in the list.
 628 The default is to autodetect native and NAS sound support."])
 629             elif test -n "$new_sdefault" ; then
 630                 with_native_sound=$new_sdefault
 631                 with_nas_sound=$new_sdefault
 632                 with_esd_sound=$new_sdefault
 633                 new_sdefault=   # reset this
 634             fi
 635             sound_notfirst=true
 636           done
 637         ;;
 638
 639         dnl Has the user specified a preferred Athena widget set?
 640         dnl This bit expands any alias names out for us...
 641         "with_athena" )
 642           case "$val" in
 643             xa | xaw )                    val=xaw    ;;
 644             3 | 3d | xaw3d )              val=3d     ;;
 645             dnl No `n' for next, someone may try `no'
 646             ne | nex | next | naxtaw)     val=next   ;;
 647             dnl Have not tested the next two...
 648             9 | 95 | xaw95 )              val=95     ;;
 649             xp | xpm | xawxpm )           val=xpm    ;;
 650             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 651   \`xaw', \`3d', \`next', \`95', or \`xpm'."]) ;;
 652           esac
 653           eval "$opt=\"$val\""
 654         ;;
 655
 656         dnl Has the user requested XIM support?
 657         "with_xim" )
 658           case "$val" in
 659             y | ye | yes )                val=yes   ;;
 660             n | no | non | none )         val=no    ;;
 661             x | xl | xli | xlib )         val=xlib  ;;
 662             m | mo | mot | moti | motif ) val=motif ;;
 663             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 664   \`motif', \`xlib', \`yes', or \`no'."]) ;;
 665           esac
 666           eval "$opt=\"$val\""
 667         ;;
 668
 669         dnl Mail locking specification
 670         "mail_locking" )
 671           case "$val" in
 672             lockf )     val=lockf ;;
 673             flock )     val=flock ;;
 674             file | dot ) val=file  ;;
 675             locking )   val=locking  ;;
 676             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 677   \`lockf', \`flock', \`file', \`locking', or \`mmdf'."]) ;;
 678           esac
 679           eval "$opt=\"$val\""
 680         ;;
 681
 682         dnl Has the user requested error-checking?
 683         "error_checking" )
 684           dnl value can be all, none, and/or a list of categories to check.
 685           dnl Example: --error-checking=all,noextents,nobufpos
 686           dnl Example: --error-checking=none,malloc,gc
 687
 688           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 689             case "$x" in
 690               dnl all and none are only permitted as the first in the list.
 691               n | no | non | none ) new_default=no ;;
 692               a | al | all )        new_default=yes ;;
 693
 694               extents )       error_check_extents=yes ;;
 695               noextents )     error_check_extents=no ;;
 696
 697               typecheck )     error_check_typecheck=yes ;;
 698               notypecheck )   error_check_typecheck=no ;;
 699
 700               bufpos )        error_check_bufpos=yes ;;
 701               nobufpos )      error_check_bufpos=no ;;
 702
 703               gc )            error_check_gc=yes ;;
 704               nogc )          error_check_gc=no ;;
 705
 706               malloc )        error_check_malloc=yes ;;
 707               nomalloc )      error_check_malloc=no ;;
 708
 709               byte_code )     error_check_byte_code=yes ;;
 710               nobyte_code )   error_check_byte_code=no ;;
 711
 712               glyphs )     error_check_glyphs=yes ;;
 713               noglyphs )   error_check_glyphs=no ;;
 714
 715               * ) bogus_error_check=yes ;;
 716             esac
 717             if test "$bogus_error_check" -o \
 718                  \( -n "$new_default" -a -n "$echeck_notfirst" \) ; then
 719                 if test "$error_check_default" = yes ; then
 720                   types="\`all' (default), \`none', \`noextents', \`notypecheck', \`nobufpos', \`nogc', \`nomalloc', \`noglyphs' and \`nobyte-code'."
 721                 else
 722                   types="\`all', \`none' (default), \`extents', \`typecheck', \`bufpos', \`gc', \`malloc', \`glyphs' and \`byte-code'."
 723                 fi
 724                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 725   $types."])
 726             elif test -n "$new_default" ; then
 727                 error_check_extents=$new_default
 728                 error_check_typecheck=$new_default
 729                 error_check_bufpos=$new_default
 730                 error_check_gc=$new_default
 731                 error_check_malloc=$new_default
 732                 error_check_byte_code=$new_default
 733                 error_check_glyphs=$new_default
 734                 new_default=    # reset this
 735             fi
 736             echeck_notfirst=true
 737           done
 738         ;;
 739
 740         dnl Has the user tried to tell us where the X files are?
 741         dnl I think these are dopey, but no less than three alpha
 742         dnl testers, at large sites, have said they have their X files
 743         dnl installed in odd places.
 744
 745         dnl Has the user specified one of the path options?
 746         prefix | exec_prefix | bindir | datadir | statedir | libdir | \
 747         mandir | infodir | infopath | lispdir | etcdir | pkgdir | \
 748         archlibdir | docdir | package_path | moduledir )
 749            dnl If the value was omitted, get it from the next argument.
 750            if test "$valomitted" = "yes"; then
 751              if test "$#" = 0; then
 752                  USAGE_ERROR("The \`--$optname' option requires a value.");
 753              fi
 754              val="$1"; shift
 755            fi
 756            eval "$opt=\"$val\""
 757
 758            dnl You need to synchronize this with the way the
 759            dnl default values are built.
 760            case "$opt" in
 761              dnl prefix is taken care of by --with-prefix
 762              exec_prefix ) AC_DEFINE(EXEC_PREFIX_USER_DEFINED) ;;
 763              lispdir ) AC_DEFINE(LISPDIR_USER_DEFINED) ;;
 764              sitelispdir ) AC_DEFINE(SITELISPDIR_USER_DEFINED) ;;
 765              moduledir ) AC_DEFINE(MODULEDIR_USER_DEFINED) ;;
 766              etcdir  )  AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 767              infodir ) AC_DEFINE(INFODIR_USER_DEFINED) ;;
 768              infopath ) AC_DEFINE(INFOPATH_USER_DEFINED) ;;
 769              package_path ) AC_DEFINE(PACKAGE_PATH_USER_DEFINED) ;;
 770              datadir )
 771                 AC_DEFINE(INFODIR_USER_DEFINED)
 772                 AC_DEFINE(LISPDIR_USER_DEFINED)
 773                 AC_DEFINE(MODULEDIR_USER_DEFINED)
 774                 AC_DEFINE(ETCDIR_USER_DEFINED)
 775                 AC_DEFINE(DOCDIR_USER_DEFINED)
 776                 AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
 777              docdir ) AC_DEFINE(DOCDIR_USER_DEFINED) ;;
 778              exec_prefix | libdir | archlibdir ) AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
 779            esac
 780         ;;
 781
 782         dnl --no-create added by autoconf for use by config.status
 783         "no_create" ) ;;
 784
 785         dnl Has the user asked for some help?
 786         "usage" | "help" ) ${PAGER-more} ${srcdir}/configure.usage; exit 0 ;;
 787
 788         dnl Has the user specified the toolkit(s) to use for GUI elements?
 789         "with_menubars"   | \
 790         "with_scrollbars" | \
 791         "with_dialogs"    | \
 792         "with_widgets" )
 793           case "$val" in
 794             l | lu | luc | luci | lucid )               val=lucid  ;;
 795             mo | mot | moti | motif )                   val=motif  ;;
 796             a | at | ath | athe | athen | athena )      val=athena ;;
 797             n | no | non | none )                       val=no     ;;
 798             y | ye | yes )                              val=yes    ;;
 799             dnl Explicit --with-widgets on command line means yes.
 800             "")                                         val=yes    ;;
 801             g | gt | gtk )                              val=gtk    ;;
 802             ms | msw )                                  val=msw    ;;
 803             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 804   \`gtk', \`lucid', \`motif', \`athena', \`yes', or \`no'."]) ;;
 805           esac
 806           eval "$opt=\"$val\""
 807         ;;
 808
 809         dnl Obsolete legacy argument?  Warn, but otherwise ignore.
 810         "use_minimal_tagbits" | \
 811         "use_indexed_lrecord_implementation" | \
 812         "run_in_place"  | \
 813         "const_is_losing" | \
 814         "with_gnu_make" )
 815           AC_MSG_WARN([Obsolete option \`--$optname' ignored.])
 816         ;;
 817
 818         dnl Unrecognized option?  No mercy for user errors.
 819         * ) USAGE_ERROR("Unrecognized option: $arg") ;;
 820
 821       esac
 822     ;;
 823
 824     dnl Assume anything with multiple hyphens is a configuration name.
 825     *-*-*) configuration="$arg" ;;
 826
 827     dnl Unrecognized argument?  No mercy for user errors.
 828     *) USAGE_ERROR("Unrecognized argument: $arg") ;;
 829
 830   esac
 831 done
 832
 833 dnl -------------------------
 834 dnl Finish options processing
 835 dnl -------------------------
 836
 837 dnl Several options are equivalent to, and override, environment variables.
 838 test -n "$cpp"      && CPP="$cpp"
 839 test -n "$cppflags" && CPPFLAGS="$cppflags"
 840 test -n "$libs"     && LIBS="$libs"
 841 test -n "$ldflags"  && LDFLAGS="$ldflags"
 842
 843 dnl Get the arguments back.  See the diatribe on Shell Magic above.
 844 eval set x "$quoted_arguments"; shift
 845
 846 dnl --extra-verbose implies --verbose
 847 test "$extra_verbose" = "yes" && verbose=yes
 848
 849 dnl with_x is an obsolete synonym for with_x11
 850 test -n "$with_x" && with_x11="$with_x"
 851
 852 dnl --with-quantify or --with-purify imply --use-system-malloc
 853 if test "$with_purify" = "yes" -o "$with_quantify" = "yes"; then
 854   test "$with_system_malloc" = "default" && with_system_malloc=yes
 855 fi
 856
 857 dnl XE_CHECK_FEATURE_DEPENDENCY(feature1, feature2)
 858 define([XE_CHECK_FEATURE_DEPENDENCY],
 859 [if test "$with_$1 $with_$2" = "yes no"; then
 860   USAGE_ERROR("--with-$1 requires --with-$2")
 861 elif test "$with_$2" = "no" ; then with_$1=no
 862 elif test "$with_$1" = "yes"; then with_$2=yes
 863 fi
 864 ])
 865
 866 dnl CDE requires tooltalk
 867 XE_CHECK_FEATURE_DEPENDENCY(cde, tooltalk)
 868
 869 dnl Find the source directory.
 870 case "$srcdir" in
 871
 872   dnl If srcdir is not specified, see if  "." or ".." might work.
 873   "" )
 874     for dir in "`echo $0 | sed 's|//|/|' | sed 's|/[[^/]]*$||'`" "." ".." ; do
 875       if test -f "$dir/src/lisp.h" -a \
 876               -f "$dir/lisp/version.el" ; then
 877         srcdir="$dir"
 878         break
 879       fi
 880     done
 881     if test -z "$srcdir" ; then
 882       USAGE_ERROR(["Neither the current directory nor its parent seem to
 883   contain the XEmacs sources.  If you do not want to build XEmacs in its
 884   source tree, you should run \`$progname' in the directory in which
 885   you wish to build XEmacs, using the \`--srcdir' option to say where the
 886   sources may be found."])
 887     fi
 888   ;;
 889
 890   dnl Otherwise, check if the directory they specified is okay.
 891   * )
 892     if test ! -f "$srcdir/src/lisp.h" -o \
 893             ! -f "$srcdir/lisp/version.el" ; then
 894       USAGE_ERROR(["The directory specified with the \`--srcdir' option,
 895   \`$srcdir', doesn't seem to contain the XEmacs sources.  You should
 896   either run the \`$progname' script at the top of the XEmacs source
 897   tree, or use the \`--srcdir' option to specify the XEmacs source directory."])
 898     fi
 899   ;;
 900 esac
 901
 902 dnl ###########################################################################
 903 if test -z "$configuration"; then
 904   dnl Guess the configuration
 905   configuration=`${CONFIG_SHELL-/bin/sh} $srcdir/config.guess`
 906   if test -z "$configuration"; then
 907     USAGE_ERROR(["XEmacs has not been ported to this host type.
 908 Try explicitly specifying the CONFIGURATION when rerunning configure."])
 909   fi
 910 fi
 911
 912 AC_PROG_LN_S
 913
 914 dnl Make symlinks for etc, lisp, and info directories while the path
 915 dnl is still relative.  We do not symlink lock because someone may
 916 dnl have stuck the source on a read-only partition.  Instead we
 917 dnl create it as an actual directory later on if it does not already
 918 dnl exist.
 919 for dir in lisp etc man info tests; do
 920   if test ! -d "$dir" ; then
 921     echo Making symbolic link to "$srcdir/$dir"
 922     ${LN_S} "$srcdir/$dir" "$dir"
 923   fi
 924 done
 925
 926 dnl Do our best to deal with automounter brokenness
 927 dnl CANONICALIZE_PATH(varname)
 928 define([CANONICALIZE_PATH],
 929 [if test -d "/net"; then
 930   if test -d "/tmp_mnt/net"; then tdir="tmp_mnt/net"; else tdir="tmp_mnt"; fi
 931   $1=`echo "[$]$1" | \
 932    sed -e "s|^${tdir}/|/net/|" -e "s|^/a/|/net/|" -e "s|^/amd/|/net/|"`
 933 fi])dnl
 934
 935 dnl Calculate canonical name for blddir (i.e. current directory).
 936 dnl PWD may already be the preferable absolute name for ".",
 937 dnl but we can't trust it - it is sometimes inaccurate.
 938 absolute_pwd="`pwd`";
 939 if test -n "$PWD" -a "`cd $PWD && pwd`" = "$absolute_pwd"
 940 then blddir="$PWD"
 941 else blddir="$absolute_pwd"; CANONICALIZE_PATH(blddir)
 942 fi
 943 AC_SUBST(blddir)
 944
 945 dnl Make srcdir absolute, if not already.  It is important to
 946 dnl avoid running the path through pwd unnecessary, since pwd can
 947 dnl give you automounter prefixes, which can go away.
 948 case "$srcdir" in
 949   /* ) ;;
 950   .  ) srcdir="$blddir" ;;
 951   *  ) srcdir="`cd $srcdir && pwd`"; CANONICALIZE_PATH(srcdir) ;;
 952 esac
 953
 954 dnl Check if the source directory already has a configured system in it.
 955 if test `pwd` != `sh -c cd $srcdir && pwd`  \
 956    && test -f "$srcdir/src/config.h"; then
 957   (echo "$progname: WARNING: The directory tree \`$srcdir' is being used"
 958    echo "   as a build directory right now; it has been configured in its own"
 959    echo "   right.  To configure in another directory as well, you MUST"
 960    echo "   use GNU make.  If you do not have GNU make, then you must"
 961    echo "   now do \`make distclean' in $srcdir,"
 962    echo "   and then run $progname again.") >&2
 963   extrasub='/^VPATH[[    ]]*=/c\
 964 vpath %.c $(srcdir)\
 965 vpath %.h $(srcdir)\
 966 vpath %.y $(srcdir)\
 967 vpath %.l $(srcdir)\
 968 vpath %.s $(srcdir)\
 969 vpath %.in $(srcdir)'
 970 fi
 971
 972 dnl ----------------------------------------
 973 dnl Find out which version of XEmacs this is
 974 dnl ----------------------------------------
 975 . "$srcdir/version.sh" || exit 1;
 976 dnl Must do the following first to determine verbosity for AC_DEFINE
 977 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
 978 : "${extra_verbose=$beta}"
 979 version="${emacs_major_version}.${emacs_minor_version}"
 980 AC_DEFINE_UNQUOTED(EMACS_MAJOR_VERSION, $emacs_major_version)
 981 AC_DEFINE_UNQUOTED(EMACS_MINOR_VERSION, $emacs_minor_version)
 982 if test -n "$emacs_beta_version" ; then
 983   if test "$beta" = "yes"; then
 984         version="${version}-b${emacs_beta_version}"
 985         AC_DEFINE_UNQUOTED(EMACS_BETA_VERSION, $emacs_beta_version)
 986   else
 987         version="${version}.${emacs_beta_version}"
 988         AC_DEFINE_UNQUOTED(EMACS_PATCH_LEVEL, $emacs_beta_version)
 989   fi
 990 fi
 991 AC_DEFINE_UNQUOTED(XEMACS_CODENAME, "$xemacs_codename")
 992 AC_DEFINE_UNQUOTED(EMACS_VERSION, "$version")
 993
 994 if test "$with_infodock" = "yes"; then
 995   if test ! -f ../../ID-INSTALL; then
 996     echo "Cannot build InfoDock without InfoDock sources"
 997     with_infodock=no
 998   fi
 999 fi
1000
1001 if test "$with_infodock" = "yes"; then
1002   dnl InfoDock version numbers.  XEmacs will use the same style of numbering
1003   dnl after the release of XEmacs 21.0.
1004   AC_DEFINE_UNQUOTED(INFODOCK_MAJOR_VERSION, $infodock_major_version)
1005   AC_DEFINE_UNQUOTED(INFODOCK_MINOR_VERSION, $infodock_minor_version)
1006   AC_DEFINE_UNQUOTED(INFODOCK_BUILD_VERSION, $infodock_build_version)
1007   version=${infodock_major_version}.${infodock_minor_version}.${infodock_build_version}
1008   PROGNAME=infodock
1009   CPPFLAGS="$CPPFLAGS -DINFODOCK"
1010 else
1011   PROGNAME=xemacs
1012 fi
1013
1014 AC_DEFINE_UNQUOTED(EMACS_PROGNAME, "$PROGNAME")
1015
1016 dnl ----------------------------------
1017 dnl Error checking and debugging flags
1018 dnl ----------------------------------
1019 dnl Error checking default to "yes" in beta versions, to "no" in releases.
1020 dnl Same goes for --debug and --extra-verbosity.
1021 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
1022 test "${error_check_extents=$beta}"   = yes && AC_DEFINE(ERROR_CHECK_EXTENTS)
1023 test "${error_check_typecheck=$beta}" = yes && AC_DEFINE(ERROR_CHECK_TYPECHECK)
1024 test "${error_check_bufpos=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_BUFPOS)
1025 test "${error_check_gc=$beta}"        = yes && AC_DEFINE(ERROR_CHECK_GC)
1026 test "${error_check_malloc=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_MALLOC)
1027 test "${error_check_byte_code=$beta}" = yes && AC_DEFINE(ERROR_CHECK_BYTE_CODE)
1028 test "${error_check_glyphs=$beta}" = yes && AC_DEFINE(ERROR_CHECK_GLYPHS)
1029 dnl debug=yes must be set when error checking is present.  This should be
1030 dnl fixed up.
1031 dnl debug implies other options
1032 if test "${debug:=$beta}" = "yes"; then
1033   use_assertions=yes memory_usage_stats=yes
1034   XE_ADD_OBJS(debug.o)
1035   XE_ADD_OBJS(tests.o)
1036   AC_DEFINE(DEBUG_XEMACS)
1037 fi
1038 test "$use_assertions"     = "yes" && AC_DEFINE(USE_ASSERTIONS)
1039 test "$memory_usage_stats" = "yes" && AC_DEFINE(MEMORY_USAGE_STATS)
1040
1041 dnl ------------------------------
1042 dnl Determine the s&m files to use
1043 dnl ------------------------------
1044 dnl Given the configuration name, set machfile and opsysfile to the
1045 dnl names of the m/*.h and s/*.h files we should use.
1046
1047 dnl Canonicalize the configuration name.
1048 AC_MSG_CHECKING("host system type")
1049 dnl allow -workshop suffix on configuration name
1050 internal_configuration=`echo $configuration | sed 's/-\(workshop\)//'`
1051 canonical=`${CONFIG_SHELL-/bin/sh} $srcdir/config.sub "$internal_configuration"`
1052 XE_STRIP_4TH_COMPONENT(configuration)
1053 XE_STRIP_4TH_COMPONENT(canonical)
1054 AC_MSG_RESULT($configuration)
1055
1056 dnl If you add support for a new configuration, add code to this
1057 dnl switch statement to recognize your configuration name and select
1058 dnl the appropriate operating system and machine description files.
1059
1060 dnl You would hope that you could choose an m/*.h file pretty much
1061 dnl based on the machine portion of the configuration name, and an s-
1062 dnl file based on the operating system portion.  However, it turns out
1063 dnl that each m/*.h file is pretty manufacturer-specific - for
1064 dnl example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
1065 dnl all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
1066 dnl machines.  So we basically have to have a special case for each
1067 dnl configuration name.
1068
1069 dnl As far as handling version numbers on operating systems is
1070 dnl concerned, make sure things will fail in a fixable way.  If
1071 dnl /etc/MACHINES says nothing about version numbers, be
1072 dnl prepared to handle anything reasonably.  If version numbers
1073 dnl matter, be sure /etc/MACHINES says something about it.
1074
1075 dnl Eric Raymond says we should accept strings like "sysvr4" to mean
1076 dnl "System V Release 4"; he writes, "The old convention encouraged"
1077 dnl "confusion between `system' and `release' levels'."
1078
1079 machine='' opsys=''
1080
1081 dnl Straightforward machine determination
1082 case "$canonical" in
1083   sparc-*-*        ) machine=sparc ;;
1084   alpha*-*-*       ) machine=alpha ;;
1085   vax-*-*          ) machine=vax ;;
1086   mips-dec-*       ) machine=pmax ;;
1087   mips-sgi-irix6*  ) machine=iris6d ;;
1088   mips-sgi-*       ) machine=iris4d ;;
1089   mips*-linux      ) machine=mips ;;
1090   romp-ibm-*       ) machine=ibmrt ;;
1091   rs6000-ibm-aix*  ) machine=ibmrs6000 ;;
1092   powerpc-ibm-aix* ) machine=ibmrs6000 ;;
1093   powerpc*-*       ) machine=powerpc ;;
1094   hppa-*-*         ) machine=hp800 ;;
1095   m88k-dg-*        ) machine=aviion ;;
1096   m68*-sony-*      ) machine=news ;;
1097   mips-sony-*      ) machine=news-risc ;;
1098   clipper-*        ) machine=clipper ;;
1099   arm*             ) machine=arm ;;
1100   ns32k-*          ) machine=ns32000 ;;
1101 esac
1102
1103 dnl Straightforward OS determination
1104 case "$canonical" in
1105   *-*-linux*    ) opsys=linux ;;
1106   *-*-netbsd*   ) opsys=netbsd ;;
1107   *-*-openbsd*  ) opsys=openbsd ;;
1108   *-*-nextstep* ) opsys=nextstep ;;
1109   *-*-vms       ) opsys=vms ;;
1110
1111   dnl DEC OSF
1112   *-dec-osf1.3 | *-dec-osf2* ) opsys=decosf1-3 ;;
1113   *-dec-osf1.2 | *-dec-osf1* ) opsys=decosf1-2 ;;
1114   *-dec-osf3.[[2-9]]         ) opsys=decosf3-2 ;;
1115   *-dec-osf3*                ) opsys=decosf3-1 ;;
1116   *-dec-osf[[4-9]]*          ) opsys=decosf4-0 ;;
1117
1118   dnl DEC Ultrix
1119   *-*-ultrix[[0-3]].* | *-*-ultrix4.0* ) opsys=bsd4-2 ;;
1120   *-*-ultrix4.[[12]]* ) opsys=bsd4-3 ;;
1121   *-*-ultrix* )         opsys=ultrix4-3 ;;
1122
1123   dnl AIX
1124   *-*-aix3.1*  ) opsys=aix3-1   ;;
1125   *-*-aix3.2.5 ) opsys=aix3-2-5 ;;
1126   *-*-aix3*    ) opsys=aix3-2   ;;
1127   *-*-aix4.0*  ) opsys=aix4     ;;
1128   *-*-aix4.1*  ) opsys=aix4-1   ;;
1129   *-*-aix4*    ) opsys=aix4-2   ;;
1130
1131   dnl Other generic OSes
1132   *-gnu* )                      opsys=gnu    ;;
1133   *-*-bsd4.[[01]] )             opsys=bsd4-1 ;;
1134   *-*-bsd4.2 )                  opsys=bsd4-2 ;;
1135   *-*-bsd4.3 )                  opsys=bsd4-3 ;;
1136   *-*-aos4.2 )                  opsys=bsd4-2 ;;
1137   *-*-aos*   )                  opsys=bsd4-3 ;;
1138   *-*-sysv0    | *-*-sysvr0 )   opsys=usg5-0 ;;
1139   *-*-sysv2    | *-*-sysvr2 )   opsys=usg5-2 ;;
1140   *-*-sysv2.2  | *-*-sysvr2.2 ) opsys=usg5-2-2 ;;
1141   *-*-sysv3*   | *-*-sysvr3* )  opsys=usg5-3 ;;
1142   *-*-sysv4.1* | *-*-sysvr4.1* )opsys=usg5-4 NON_GNU_CPP=/usr/lib/cpp ;;
1143   *-*-sysv4.[[2-9]]* | *-sysvr4.[[2-9]]* )
1144         if test -z "$NON_GNU_CPP" ; then
1145           for prog in "/usr/ccs/lib/cpp" "/lib/cpp"; do
1146             if test -f "$prog"; then NON_GNU_CPP="$prog"; break; fi
1147           done
1148         fi
1149         opsys=usg5-4-2 ;;
1150     *-sysv4* | *-sysvr4* )      opsys=usg5-4 ;;
1151     *-*-mach_bsd4.3* )          opsys=mach-bsd4-3 ;;
1152 esac
1153
1154 case "$canonical" in
1155
1156   dnl NetBSD ports
1157   *-*-netbsd* )
1158     case "$canonical" in
1159       i[[3-9]]86-*-netbsd*) machine=intel386 ;;
1160       hp300-*-netbsd* | amiga-*-netbsd* | sun3-*-netbsd* | mac68k-*-netbsd* | da30-*-netbsd* | m68k-*-netbsd* )
1161                       dnl Yes, this is somewhat bogus.
1162                       machine=hp9000s300 ;;
1163       pc532-*-netbsd* | ns32k-*-netbsd* )  machine=ns32000 ;;
1164       pmax-*-netbsd*  | mips-*-netbsd*  )  machine=pmax ;;
1165     esac
1166   ;;
1167
1168   dnl OpenBSD ports
1169   *-*-openbsd* )
1170     case "${canonical}" in
1171       i386-*-openbsd*)          machine=intel386 ;;
1172       m68k-*-openbsd*)          machine=hp9000s300 ;;
1173       mipsel-*-openbsd*)        machine=pmax ;;
1174      esac
1175    ;;
1176
1177   dnl Acorn RISCiX:
1178   arm-acorn-riscix1.1* ) machine=acorn opsys=riscix1-1 ;;
1179   arm-acorn-riscix1.2* | arm-acorn-riscix ) machine=acorn opsys=riscix1-2 ;;
1180
1181   dnl Alliant machines
1182   fx80-alliant-* ) machine=alliant4     opsys=bsd4-2 ;;
1183   i860-alliant-* ) machine=alliant-2800 opsys=bsd4-3 ;;
1184
1185   dnl Altos 3068
1186   m68*-altos-sysv* ) machine=altos opsys=usg5-2 ;;
1187
1188   dnl Amdahl UTS
1189   580-amdahl-sysv* ) machine=amdahl opsys=usg5-2-2 ;;
1190
1191   dnl Apollo, Domain/OS
1192   m68*-apollo-* ) machine=apollo opsys=bsd4-3 ;;
1193
1194   dnl AT&T 3b2, 3b5, 3b15, 3b20
1195   we32k-att-sysv* ) machine=att3b opsys=usg5-2-2 ;;
1196
1197   dnl AT&T 3b1 - The Mighty Unix PC!
1198   m68*-att-sysv* ) machine=7300 opsys=usg5-2-2 ;;
1199
1200   dnl Bull machines
1201   rs6000-bull-bosx* ) machine=ibmrs6000 opsys=aix3-2 ;; # dpx20
1202   m68*-bull-sysv3*  ) machine=dpx2      opsys=usg5-3 ;; # dpx2
1203   m68*-bull-sysv2*  ) machine=sps7      opsys=usg5-2 ;; # sps7
1204
1205   dnl CCI 5/32, 6/32 -- see "Tahoe".
1206
1207   dnl Celerity
1208   celerity-celerity-bsd* ) machine=celerity opsys=bsd4-2 ;;
1209
1210   dnl Convex
1211   *-convex-bsd* | *-convex-convexos* )
1212     machine=convex opsys=bsd4-3
1213     NON_GNU_CPP="cc -E -P"
1214   ;;
1215
1216   dnl Cubix QBx/386
1217   i[[3-9]]86-cubix-sysv* ) machine=intel386 opsys=usg5-3 ;;
1218
1219   dnl Darwin, a.k.a. MacOS X (based on Mach and Freebsd)
1220   *-*-darwin*)
1221     opsys=darwin
1222     RANLIB="ranlib -c" dnl Avoids a link error with lwlib-config.c
1223     pdump=yes          dnl No "native" working dumper available
1224     ;;
1225
1226   dnl Data General AViiON Machines
1227   i586-dg-dgux*R4*   | i586-dg-dgux5.4.4* ) machine=aviion opsys=dgux5-4r4 ;;
1228   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* ) opsys=dgux5-4r3 ;;
1229   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* ) opsys=dgux5-4r2 ;;
1230   m88k-dg-dgux*                           ) opsys=dgux     ;;
1231
1232   dnl Motorola Delta machines
1233   m68k-motorola-sysv* | m68000-motorola-sysv* ) machine=delta opsys=usg5-3 ;;
1234   m88k-motorola-sysv4* )
1235     dnl jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
1236     dnl needs POSIX_SIGNALS and therefore needs usg5-4-2.
1237     dnl I hope there are not other 4.0 versions for this machine
1238     dnl which really need usg5-4 instead.
1239     machine=delta88k opsys=usg5-4-2
1240   ;;
1241   m88k-motorola-sysv* | m88k-motorola-m88kbcs* ) machine=delta88k opsys=usg5-3 ;;
1242
1243   dnl Dual machines
1244   m68*-dual-sysv*    ) machine=dual opsys=usg5-2   ;;
1245   m68*-dual-uniplus* ) machine=dual opsys=unipl5-2 ;;
1246
1247   dnl Encore machines
1248   ns16k-encore-bsd* ) machine=ns16000 opsys=umax ;;
1249
1250   dnl Gould Power Node and NP1
1251   pn-gould-bsd4.2* ) machine=gould     opsys=bsd4-2 ;;
1252   pn-gould-bsd4.3* ) machine=gould     opsys=bsd4-3 ;;
1253   np1-gould-bsd* )   machine=gould-np1 opsys=bsd4-3 ;;
1254
1255   dnl Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
1256   dnl as far as XEmacs is concerned).
1257   m88k-harris-cxux* )
1258     dnl Build needs to be different on 7.0 and later releases
1259     case "`uname -r`" in
1260        [[56]].[[0-9]] ) machine=nh4000 opsys=cxux  ;;
1261        [[7]].[[0-9]]  ) machine=nh4000 opsys=cxux7 ;;
1262     esac
1263     NON_GNU_CPP="/lib/cpp"
1264   ;;
1265   dnl Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
1266   m68k-harris-cxux* ) machine=nh3000 opsys=cxux ;;
1267   dnl Harris power pc NightHawk running Power UNIX (Series 6000)
1268   powerpc-harris-powerunix ) machine=nh6000 opsys=powerunix NON_GNU_CPP="cc -Xo -E -P" ;;
1269
1270   dnl Honeywell XPS100
1271   xps*-honeywell-sysv* ) machine=xps100 opsys=usg5-2 ;;
1272
1273   dnl HP 9000 series 200 or 300
1274   m68*-hp-bsd* ) machine=hp9000s300 opsys=bsd4-3 ;;
1275
1276   dnl HP-UX
1277   *-hp-hpux* )
1278     dnl Figure out machine and opsys orthogonally
1279     case "$canonical" in
1280       m68*  ) machine=hp9000s300 ;;
1281       hppa* ) machine=hp800      ;;
1282     esac
1283
1284     case "$canonical" in
1285       *-hp-hpux7*  )  opsys=hpux   ;;
1286       *-hp-hpux8*  )  opsys=hpux8  ;;
1287       *-hp-hpux9*  )  opsys=hpux9  ;;
1288       *-hp-hpux10* )  opsys=hpux10 ;;
1289       *-hp-hpux11* )  opsys=hpux11 ;;
1290       *            )  opsys=hpux   ;;
1291     esac
1292
1293     dnl HP has a broken "strcat"
1294     case "$opsys" in hpux9 | hpux10 ) XE_ADD_OBJS(strcat.o) ;; esac
1295
1296     if test "$opsys" = "hpux10" -o "$opsys" = "hpux11"; then \
1297         ansi_flag="-Ae"; else ansi_flag="-Aa"; fi
1298     NON_GNU_CC="cc $ansi_flag" NON_GNU_CPP="cc $ansi_flag -E"
1299
1300     case "$canonical" in *-hp-hpux*shr* ) opsys="${opsys}-shr" ;; esac
1301   ;;
1302
1303   dnl Orion machines
1304   orion-orion-bsd*   ) machine=orion    opsys=bsd4-2 ;;
1305   clipper-orion-bsd* ) machine=orion105 opsys=bsd4-2 ;;
1306
1307   dnl IBM machines
1308   i[[3-9]]86-ibm-aix1.1* ) machine=ibmps2-aix opsys=usg5-2-2 ;;
1309   i[[3-9]]86-ibm-aix1.[[23]]* | i[[3-9]]86-ibm-aix* ) machine=ibmps2-aix opsys=usg5-3 ;;
1310   i370-ibm-aix*) machine=ibm370aix opsys=usg5-3 ;;
1311   romp-ibm-aos*    ) opsys=bsd4-3 ;;
1312   romp-ibm-bsd*    ) opsys=bsd4-3 ;;
1313   romp-ibm-mach*   ) opsys=mach-bsd4-3 ;;
1314
1315   dnl Integrated Solutions "Optimum V"
1316   m68*-isi-bsd4.2* ) machine=isi-ov opsys=bsd4-2 ;;
1317   m68*-isi-bsd4.3* ) machine=isi-ov opsys=bsd4-3 ;;
1318
1319   dnl Intel 386 machines where we do care about the manufacturer
1320   i[[3-9]]86-intsys-sysv* ) machine=is386 opsys=usg5-2-2 ;;
1321
1322   dnl Prime EXL
1323   i[[3-9]]86-prime-sysv* ) machine=i386 opsys=usg5-3 ;;
1324
1325   dnl Sequent Symmetry running Dynix
1326   i[[3-9]]86-sequent-bsd* ) machine=symmetry opsys=bsd4-3 ;;
1327
1328   dnl Sequent Symmetry running DYNIX/ptx
1329   i[[3-9]]86-sequent-ptx* ) machine=sequent-ptx opsys=ptx NON_GNU_CPP="/lib/cpp" ;;
1330
1331   dnl Unspecified sysv on an ncr machine defaults to svr4.2.
1332   dnl (Plain usg5-4 does not turn on POSIX signals, which we need.)
1333   i[[3-9]]86-ncr-sysv* ) machine=ncr386 opsys=usg5-4-2 ;;
1334
1335   dnl Intel Paragon OSF/1
1336   i860-intel-osf1* ) machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp ;;
1337
1338   dnl Intel 860
1339   i860-*-sysv4* ) machine=i860 opsys=usg5-4 NON_GNU_CC="/bin/cc" NON_GNU_CPP="/usr/ccs/lib/cpp" ;;
1340
1341   dnl Masscomp machines
1342   m68*-masscomp-rtu* ) machine=masscomp opsys=rtu ;;
1343
1344   dnl Megatest machines
1345   m68*-megatest-bsd* ) machine=mega68 opsys=bsd4-2 ;;
1346
1347   dnl Workstations sold by MIPS
1348   dnl This is not necessarily all workstations using the MIPS processor -
1349   dnl Irises are produced by SGI, and DECstations by DEC.
1350   mips-mips-usg* ) machine=mips4 ;;
1351   mips-mips-riscos4 )
1352     machine=mips4
1353     NON_GNU_CC="cc -systype bsd43"
1354     NON_GNU_CPP="cc -systype bsd43 -E"
1355     case "$canonical" in
1356       mips-mips-riscos4* ) opsys=bsd4-3  ;;
1357       mips-mips-riscos5* ) opsys=riscos5 ;;
1358     esac
1359   ;;
1360   mips-mips-bsd* ) machine=mips opsys=bsd4-3 ;;
1361   mips-mips-*    ) machine=mips opsys=usg5-2-2 ;;
1362
1363   dnl NeXT
1364   m68*-next-* | m68k-*-nextstep* ) machine=m68k opsys=nextstep ;;
1365
1366   dnl The complete machine from National Semiconductor
1367   ns32k-ns-genix* ) machine=ns32000 opsys=usg5-2 ;;
1368
1369   dnl NCR machines
1370   m68*-ncr-sysv2* | m68*-ncr-sysvr2* ) machine=tower32   opsys=usg5-2-2 ;;
1371   m68*-ncr-sysv3* | m68*-ncr-sysvr3* ) machine=tower32v3 opsys=usg5-3 ;;
1372
1373   dnl Nixdorf Targon 31
1374   m68*-nixdorf-sysv* ) machine=targon31 opsys=usg5-2-2 ;;
1375
1376   dnl Nu (TI or LMI)
1377   m68*-nu-sysv* ) machine=nu opsys=usg5-2 ;;
1378
1379   dnl Plexus
1380   m68*-plexus-sysv* ) machine=plexus opsys=usg5-2 ;;
1381
1382   dnl Pyramid machines
1383   pyramid-pyramid-bsd* ) machine=pyramid opsys=bsd4-2 ;;
1384
1385   dnl Sequent Balance
1386   ns32k-sequent-bsd4.2* ) machine=sequent opsys=bsd4-2 ;;
1387   ns32k-sequent-bsd4.3* ) machine=sequent opsys=bsd4-3 ;;
1388
1389   dnl Siemens Nixdorf
1390   mips-siemens-sysv* | mips-sni-sysv*)
1391     machine=mips-siemens opsys=usg5-4
1392     NON_GNU_CC=/usr/ccs/bin/cc
1393     NON_GNU_CPP=/usr/ccs/lib/cpp
1394   ;;
1395
1396   dnl NEC
1397   mips-nec-sysv*)
1398     machine=mips-nec
1399     NON_GNU_CC=/usr/ccs/bin/cc
1400     NON_GNU_CPP=/usr/ccs/lib/cpp
1401   ;;
1402
1403   dnl Silicon Graphics machines
1404   dnl Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
1405   m68*-sgi-iris3.5* ) machine=irist opsys=iris3-5 ;;
1406   m68*-sgi-iris3.6* | m68*-sgi-iris*) machine=irist opsys=iris3-6 ;;
1407   dnl Iris 4D
1408   mips-sgi-irix3.*    ) opsys=irix3-3 ;;
1409   mips-sgi-irix4.*    ) opsys=irix4-0 ;;
1410   mips-sgi-irix6*     ) opsys=irix6-0 ;;
1411   mips-sgi-irix5.1*   ) opsys=irix5-1 ;;
1412   mips-sgi-irix5.2*   ) opsys=irix5-2 ;;
1413   mips-sgi-irix5.*    ) opsys=irix5-3 ;;
1414   mips-sgi-irix*      ) opsys=irix5-0 ;;
1415
1416   dnl SONY machines
1417   *-sony-newsos[[34]]* | *-sony-news[[34]]* ) opsys=bsd4-3 ;;
1418   *-sony-news* ) opsys=newsos5 ;;
1419
1420   dnl Stride
1421   m68*-stride-sysv* ) machine=stride opsys=usg5-2 ;;
1422
1423   dnl Suns
1424   *-*-solaris* | *-*-sunos* | *-sun-mach* | *-sun-bsd* )
1425     dnl Hardware type
1426     case "$canonical" in
1427       m68*-sunos1* )             machine=sun1     ;;
1428       m68*-sunos2* )             machine=sun2     ;;
1429       m68* )                     machine=sun3     ;;
1430       i*86*-sun-sunos[[34]]* )   machine=sun386   ;;
1431       i*86-*-* )                 machine=intel386 ;;
1432       rs6000* )                  machine=rs6000   ;;
1433     esac
1434
1435     dnl Make $canonical even more so.
1436     case "$canonical" in *-sunos5*)
1437       canonical=`echo $canonical | sed -e s/sunos5/solaris2/`;;
1438     esac
1439
1440     dnl On SunOS 4, use /usr/lib/cpp, sans dynodump, /bin/ranlib
1441     dnl On SunOS 5, use cc -E,        need dynodump, RANLIB not needed
1442     dnl But, SunOS 5.6 no longer needs dynodump because it has a similar
1443     dnl function integrated.
1444     case "$canonical" in
1445       *-sunos4* )
1446         #test -f /usr/lib/cpp     && NON_GNU_CPP=/usr/lib/cpp ;;
1447         : ;;
1448       *-solaris2* )
1449         #test -f /usr/ccs/lib/cpp && NON_GNU_CPP=/usr/ccs/lib/cpp
1450         RANLIB=':' ;;
1451     esac
1452
1453     case "$canonical" in
1454       *-solaris*          )
1455         opsys=sol2
1456         os_release=`uname -r | sed -e 's/^\([[0-9]]\)\.\([[0-9]]\).*/\1\2/'`
1457         AC_DEFINE_UNQUOTED(OS_RELEASE, $os_release) ;;
1458
1459       dnl The last Sun386 ran 4.0.
1460       i*86-*-sunos4*      ) opsys=sunos4-0      ;;
1461       *-sunos4.0*         ) opsys=sunos4-0      ;;
1462       *-sunos4.1.2*       ) opsys=sunos4-1-2    ;;
1463       *-sunos4.1.3*       ) opsys=sunos4-1-3    ;;
1464       *-sunos4.1.[[4-9]]* ) opsys=sunos4-1-4    ;;
1465       *-sunos4* | *-sunos ) opsys=sunos4-1      ;;
1466       *-mach*             ) opsys=mach-bsd4-3   ;;
1467       *                   ) opsys=bsd4-2        ;;
1468     esac
1469
1470     case "$canonical" in *-sunos4*shr* ) opsys="${opsys}-shr" ;; esac
1471
1472     dnl Watch out for a compiler guaranteed not to work.
1473     test "$opsys $CC" = "sol2 /usr/ucb/cc" && CC=""
1474   ;;
1475
1476   dnl Tadpole 68k
1477   m68*-tadpole-sysv* ) machine=tad68k opsys=usg5-3 ;;
1478
1479   dnl Tahoe machines
1480   tahoe-tahoe-bsd4.2* ) machine=tahoe opsys=bsd4-2 ;;
1481   tahoe-tahoe-bsd4.3* ) machine=tahoe opsys=bsd4-3 ;;
1482
1483   dnl Tandem Integrity S2
1484   mips-tandem-sysv* ) machine=tandem-s2 opsys=usg5-3 ;;
1485
1486   dnl Tektronix XD88
1487   m88k-tektronix-sysv3* ) machine=tekxd88 opsys=usg5-3 ;;
1488
1489   dnl Tektronix 16000 box (6130?)
1490   ns16k-tektronix-bsd* ) machine=ns16000 opsys=bsd4-2 ;;
1491   dnl Tektronix 4300
1492   dnl src/m/tek4300.h hints that this is a m68k machine.
1493   m68*-tektronix-bsd* ) machine=tek4300 opsys=bsd4-3 ;;
1494
1495   dnl Titan P2 or P3
1496   titan-titan-sysv* ) machine=titan opsys=usg5-3 ;;
1497
1498   dnl Ustation E30 (SS5E)
1499   m68*-unisys-uniplus* ) machine=ustation opsystem=unipl5-2 ;;
1500
1501   dnl Vaxen.
1502   vax-dec-* )
1503     case "$canonical" in
1504       *-sysv[[01]]* | *-sysvr[[01]]* )  opsys=usg5-0 ;;
1505       *-sysv2* | *-sysvr2* )            opsys=usg5-2 ;;
1506       *-mach* )                         opsys=mach-bsd4-3 ;;
1507     esac
1508   ;;
1509
1510   dnl Whitechapel MG1
1511   ns16k-whitechapel-* ) machine=mg1 ;;
1512
1513   dnl Wicat
1514   m68*-wicat-sysv* ) machine=wicat opsys=usg5-2 ;;
1515
1516   dnl Intel 386 machines where we do not care about the manufacturer
1517   i[[3-9]]86-*-* )
1518     machine=intel386
1519     case "$canonical" in
1520       *-isc1.* | *-isc2.[[01]]* ) opsys=386-ix ;;
1521       *-isc2.2* )               opsys=isc2-2 ;;
1522       *-isc4.0* )               opsys=isc4-0 ;;
1523       *-isc4.* )                opsys=isc4-1
1524                                 GCC_TEST_OPTIONS=-posix
1525                                 NON_GCC_TEST_OPTIONS=-Xp
1526                                 ;;
1527       *-isc* )                  opsys=isc3-0 ;;
1528       *-esix5* )                opsys=esix5r4 NON_GNU_CPP=/usr/lib/cpp ;;
1529       *-esix* )                 opsys=esix ;;
1530       *-mach* )                 opsys=mach-bsd4-3 ;;
1531       *-xenix* )                opsys=xenix ;;
1532       *-sco3.2v4* )             opsys=sco4 NON_GNU_CPP=/lib/cpp  ;;
1533       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
1534       *-bsdi4* )                opsys=bsdos4 ;;
1535       *-bsdi3* )                opsys=bsdos3 ;;
1536       *-bsdi2.1* )              opsys=bsdos2-1 ;;
1537       *-bsdi2* )                opsys=bsdos2 ;;
1538       *-sco3.2v5* )             opsys=sco5 ;;
1539       *-sysv5* )                opsys=sco7 ;;
1540       *-386bsd* )               opsys=386bsd ;;
1541       *-freebsd* )              opsys=freebsd ;;
1542       *-nextstep* )             opsys=nextstep ;;
1543       *-pc-cygwin* )            opsys=cygwin32 ;;
1544       *-pc-mingw* )             opsys=mingw32 ;
1545                                 test -z "$with_tty" && with_tty="no";;
1546       dnl Otherwise, we fall through to the generic opsys code at the bottom.
1547     esac
1548   ;;
1549
1550   dnl Linux/68k
1551   m68k-*-linux* ) machine=m68k opsys=linux ;;
1552
1553 esac
1554
1555 dnl Initialize machine from $canonical if not in our database above.
1556 test -z "$machine" && machine=`echo $canonical | sed 's/-.*$//'`
1557
1558 dnl Initialize opsys from `uname -s` if not in our database above.
1559 test -z "$opsys"   && opsys=`uname -s | tr ABCDEFGHIJKLMNOPQRSTUVWXYZ abcdefghijklmnopqrstuvwxyz`
1560
1561 dnl Use configure-time autodetection if s&m not available
1562 if test -r "${srcdir}/src/m/${machine}.h"; then
1563   machfile="m/${machine}.h"
1564   AC_DEFINE_UNQUOTED(config_machfile, "$machfile")
1565 else
1566   echo "XEmacs has no builtin knowledge of \`$machine' machines."
1567   echo "Using configure-time autodetection only."
1568 fi
1569
1570 if test -r "${srcdir}/src/s/${opsys}.h"; then
1571   opsysfile="s/${opsys}.h"
1572   AC_DEFINE_UNQUOTED(config_opsysfile, "$opsysfile")
1573 else
1574   echo "XEmacs has no builtin knowledge of \`$opsys' operating systems."
1575   echo "Using configure-time autodetection only."
1576 fi
1577
1578
1579 if test -z "$dynamic"; then
1580   case "$opsys" in
1581     hpux* | sunos4* ) dynamic=no ;;
1582     *) dynamic=yes ;;
1583   esac
1584 fi
1585 if test "$dynamic" = "yes"; then
1586   case "$opsys" in
1587     hpux* | sunos4* | sco5 ) opsys="${opsys}-shr" ;;
1588     decosf* ) ld_call_shared="-call_shared" ;;
1589   esac
1590 else dnl "$dynamic" = "no"
1591   case "$opsys" in
1592     sol2 )
1593       echo "Static linking is not supported on Solaris 2."
1594       echo "Rerun configure without specifying --dynamic=no."
1595       exit 1 ;;
1596     linux   ) ld_call_shared="-Bstatic" ;;
1597     decosf* ) ld_call_shared="-non_shared" ;;
1598   esac
1599 fi
1600
1601 dnl Use xlc by default on AIX
1602 case "$opsys" in aix*) NON_GNU_CC=xlc ;; esac
1603
1604 stack_trace_eye_catcher=`echo ${PROGNAME}_${version}_${canonical} | sed 'y/.-/__/'`
1605 AC_DEFINE_UNQUOTED(STACK_TRACE_EYE_CATCHER, $stack_trace_eye_catcher)
1606
1607 dnl --------------------------------------------------
1608 dnl Determine the compiler, set up for feature testing
1609 dnl --------------------------------------------------
1610
1611 dnl Sun Development environment support
1612 test "$with_sparcworks" = "yes" && with_workshop=yes # compatibility alias
1613 XE_CHECK_FEATURE_DEPENDENCY(workshop, tooltalk)
1614 if test "$with_workshop" = "yes"; then
1615   AC_DEFINE(SUNPRO)
1616   XE_ADD_OBJS(sunpro.o)
1617 fi
1618
1619 if test "$with_clash_detection" != "no"; then
1620   AC_DEFINE(CLASH_DETECTION)
1621   XE_ADD_OBJS(filelock.o)
1622 fi
1623
1624 dnl Choose a compiler from (in order)
1625 dnl --compiler, env var CC, with_gcc=no && ${NON_GNU_CC:-cc}, AC_PROG_CC
1626 test -n "$compiler" && CC="$compiler"
1627 if test "$with_gcc" = "no"; then dnl Try to find a non-gcc compiler
1628   case "$CC" in "" | *gcc* ) CC="${NON_GNU_CC-cc}" ;; esac
1629 fi
1630
1631 dnl If we don't set CFLAGS here, AC_PROG_CC will set it.
1632 dnl But we know better what's good for us, so we do our own
1633 dnl computation of real CFLAGS later.
1634 dnl --cflags overrides environment variable CFLAGS
1635 test "${cflags-unset}" != unset && CFLAGS="$cflags"
1636 if test "${CFLAGS-unset}" != unset
1637   then cflags_specified=yes;
1638   else cflags_specified=no;
1639 fi
1640
1641 xe_save_CFLAGS="$CFLAGS"
1642
1643 AC_PROG_CC dnl Autoconf has its own magic for compiler autodetection
1644
1645 dnl Retry using random guesswork if AC_PROG_CC got it wrong...
1646 if   test "$with_gcc" = "no"  -a "$GCC" = "yes"; then
1647   CC=${NON_GNU_CC-cc}
1648   AC_PROG_CC
1649 elif test "$with_gcc" = "yes" -a "$GCC" != "yes" ; then
1650   CC=gcc
1651   AC_PROG_CC
1652 fi
1653 CFLAGS="$xe_save_CFLAGS"
1654
1655 dnl Figure out what C preprocessor to use.
1656
1657 dnl On Sun systems, people sometimes set up the variable CPP
1658 dnl with a value that is a directory, not an executable at all.
1659 dnl Detect that case, and ignore that value.
1660 test -n "$CPP" -a -d "$CPP" && CPP=
1661
1662 test -n "$NON_GNU_CPP" -a "$GCC" != "yes" -a -z "$CPP" && CPP="$NON_GNU_CPP"
1663
1664 AC_PROG_CPP
1665
1666 dnl --------------------------------------------------------------------
1667 dnl Compiler feature macros
1668 dnl --------------------------------------------------------------------
1669
1670 AC_AIX dnl Defines _ALL_SOURCE on AIX.
1671
1672 dnl We want feature macros defined here *and* in config.h.in, so that
1673 dnl the compilation environment at configure time and compile time agree.
1674
1675 AC_MSG_CHECKING(for GNU libc)
1676 AC_TRY_COMPILE([#include <features.h>],[
1677 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
1678 #error Not a GNU libc system :-(
1679 ******* ======= ******** &&&&&&&&
1680 #endif
1681 ], have_glibc=yes, have_glibc=no)
1682 AC_MSG_RESULT($have_glibc)
1683 dnl I'm tired of pop being broken with GLIBC -slb
1684 dnl Well. then why not fix fucking pop?
1685 test "$have_glibc" = "yes" && AC_DEFINE(_GNU_SOURCE)
1686
1687 dnl We'd like to use vendor extensions, where available.
1688 dnl We'd like to use functions from the latest Unix98 standards.
1689 dnl See http://www.opengroup.org/onlinepubs/007908799/xsh/compilation.html
1690 case "$opsys" in
1691   sol2)
1692    AC_DEFINE(__EXTENSIONS__)
1693    dnl Solaris 2 before 2.5 had some bugs with feature test macro interaction.
1694    if test "$os_release" -ge 55; then
1695      AC_DEFINE(_XOPEN_SOURCE,500)
1696      AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1697    fi ;;
1698   linux)
1699     AC_DEFINE(_POSIX_C_SOURCE,199506L)
1700     AC_DEFINE(_XOPEN_SOURCE,500)
1701     AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1702     ;;
1703 esac
1704
1705 dnl Identify compilers to enable compiler-specific hacks.
1706 dnl Add support for other compilers HERE!
1707 dnl GCC is already identified elsewhere.
1708 AC_TRY_RUN([int main () {
1709 #if defined __SUNPRO_C
1710 return 11;
1711 #elif defined __DECC
1712 return 12;
1713 #elif defined __USLC__ && defined __SCO_VERSION__
1714 return 13;
1715 #else
1716 return 0;
1717 #endif
1718 }], [],
1719 [case "$conftest_rc" in
1720   11) echo "You appear to be using the SunPro C compiler."; __SUNPRO_C=yes ;;
1721   12) echo "You appear to be using the DEC C compiler."   ; __DECC=yes ;;
1722   13) echo "You appear to be using the SCO C compiler."   ; __USLC__=yes ;;
1723 esac])
1724
1725
1726 dnl case "$canonical" in
1727 dnl   *-sun-sunos* ) test "$CPP" = "acc -E" && CPP="acc -E -Xs" ;;
1728 dnl esac
1729
1730 dnl --------------------------------------------------------------------
1731 dnl Extract some information from the operating system and machine files
1732 dnl --------------------------------------------------------------------
1733
1734 echo "Extracting information from the machine- and system-dependent headers..."
1735
1736 dnl It is not important that this name contain the PID; you cannot run
1737 dnl two configures in the same directory and have anything work
1738 dnl anyway.
1739 tempcname="conftest.c"
1740
1741 dnl CPP_to_sh(CPP_SYMBOL, SH_VAR, DEFAULT_VALUE)
1742 define([CPP_to_sh],
1743 [[#]ifndef [$1]
1744 [#]define [$1]ifelse([$3],,, [ "$3"])
1745 [#]endif
1746 configure___ [$2]=[$1]
1747 ])dnl CPP_to_sh
1748
1749 dnl CPP_boolean_to_sh(CPP_SYMBOL, SH_VAR)
1750 define([CPP_boolean_to_sh],
1751 [[#]ifdef [$1]
1752 configure___ [$2]=yes
1753 [#]else
1754 configure___ [$2]=no
1755 [#]endif
1756 ])dnl CPP_boolean_to_sh
1757
1758 cat > $tempcname < confdefs.h
1759 cat >> $tempcname <<EOF
1760 #define NOT_C_CODE
1761 #define C_SWITCH_SITE
1762 #define C_SWITCH_X_SITE
1763 #define LD_SWITCH_SITE
1764 #define LD_SWITCH_X_SITE
1765 #define LD_SWITCH_X_SITE_AUX
1766 #define OS_RELEASE $os_release
1767
1768 #ifdef config_opsysfile
1769 #include "$srcdir/src/$opsysfile"
1770 #endif
1771
1772 #ifdef config_machfile
1773 #include "$srcdir/src/$machfile"
1774 #endif
1775
1776 CPP_to_sh(LIBS_MACHINE, libs_machine)
1777 CPP_to_sh(LIBS_SYSTEM,  libs_system)
1778 CPP_to_sh(LIBS_TERMCAP, libs_termcap)
1779 CPP_to_sh(LIB_STANDARD, libs_standard)
1780
1781 CPP_to_sh(OBJECTS_MACHINE, objects_machine)
1782 CPP_to_sh(OBJECTS_SYSTEM,  objects_system)
1783
1784 CPP_to_sh(C_SWITCH_MACHINE,   c_switch_machine)
1785 CPP_to_sh(C_SWITCH_SYSTEM,    c_switch_system)
1786
1787 CPP_to_sh(LD_SWITCH_MACHINE,  ld_switch_machine)
1788 CPP_to_sh(LD_SWITCH_SYSTEM,   ld_switch_system)
1789
1790 CPP_to_sh(UNEXEC, unexec, unexec.o)
1791
1792 CPP_to_sh(LD_SWITCH_SHARED, ld_switch_shared, -c)
1793
1794 #define ORDINARY_LD "\$(CC) \$(CFLAGS)"
1795 configure___ ordinary_ld=ORDINARY_LD
1796
1797 #ifdef ORDINARY_LINK
1798 #define LD ORDINARY_LD
1799 #else /* no ORDINARY LINK */
1800 #ifdef COFF_ENCAPSULATE
1801 #define LD "\$(CC) -nostdlib"
1802 #else /* not COFF_ENCAPSULATE */
1803 #ifdef LINKER
1804 #define LD LINKER
1805 #else /* ! defined (LINKER) */
1806 #define LD "ld"
1807 #endif /* ! defined (LINKER) */
1808 #endif /* ! defined (COFF_ENCAPSULATE) */
1809 #endif /* not ORDINARY_LINK */
1810 configure___ ld=LD
1811
1812 CPP_to_sh(LIB_GCC, lib_gcc)
1813 CPP_to_sh(LD_TEXT_START_ADDR, ld_text_start_addr)
1814
1815 #if ! defined (ORDINARY_LINK) && !defined (START_FILES)
1816 #ifdef NO_REMAP
1817 #ifdef COFF_ENCAPSULATE
1818 #define START_FILES "pre-crt0.o /usr/local/lib/gcc-crt0.o"
1819 #else /* ! defined (COFF_ENCAPSULATE) */
1820 #define START_FILES "pre-crt0.o /lib/crt0.o"
1821 #endif /* ! defined (COFF_ENCAPSULATE) */
1822 #else /* ! defined (NO_REMAP) */
1823 #define START_FILES "ecrt0.o"
1824 #endif /* ! defined (NO_REMAP) */
1825 #endif /* no ORDINARY_LINK */
1826 #ifndef START_FILES
1827 #define START_FILES
1828 #endif
1829 configure___ start_files=START_FILES
1830
1831 CPP_boolean_to_sh(ORDINARY_LINK, ordinary_link)
1832 CPP_boolean_to_sh(SYSTEM_MALLOC, system_malloc)
1833 CPP_boolean_to_sh(TERMINFO, have_terminfo)
1834 dnl The MAIL_USE_xxx variables come from the s&m headers
1835 CPP_boolean_to_sh(MAIL_USE_FLOCK, mail_use_flock)
1836 CPP_boolean_to_sh(MAIL_USE_LOCKF, mail_use_lockf)
1837 CPP_boolean_to_sh(MAIL_USE_LOCKING, mail_use_locking)
1838 CPP_boolean_to_sh(HAVE_WIN32_PROCESSES, win32_processes)
1839 EOF
1840
1841 dnl The value of CPP is a quoted variable reference, so we need to do this
1842 dnl to get its actual value...
1843 CPP=`eval "echo $CPP $CPPFLAGS"`
1844 define(TAB, [   ])dnl
1845 changequote(, )dnl
1846 eval `$CPP -Isrc $tempcname \
1847         | sed -n -e "s/[ TAB]*=[ TAB\"]*/='/" -e "s/[ TAB\"]*\$/'/" -e "s/^configure___//p"`
1848 changequote([, ])dnl
1849
1850 rm $tempcname
1851
1852 if test "$pdump" = "yes"; then
1853   ordinary_link="yes"
1854   ld="${ordinary_ld}"
1855   start_files=
1856   libs_standard=
1857   unexec=
1858   lib_gcc=
1859 fi
1860
1861 dnl For debugging...
1862 test "$extra_verbose" = "yes" && \
1863   PRINT_VAR(libs_machine libs_system libs_termcap libs_standard
1864   objects_machine objects_system c_switch_machine c_switch_system
1865   ld_switch_machine ld_switch_system unexec ld_switch_shared
1866   ld lib_gcc ld_text_start_addr start_files ordinary_link
1867   have_terminfo mail_use_flock mail_use_lockf) && echo ""
1868
1869 dnl Pick up mingw include path
1870 dnl We only cope with headers in mingw, not mingw32: no previous version of
1871 dnl XEmacs supported mingw and cygnus have made this incompatible change
1872 dnl so we just go with the flow.
1873 case "$opsys" in mingw* | cygwin*)
1874   cygwin_include=`eval "gcc -print-file-name=libc.a"` ;
1875   cygwin_include=`eval "dirname $cygwin_include"` ;
1876   cygwin_include="-I$cygwin_include/../include" ;
1877   extra_includes="$cygwin_include/mingw $cygwin_include" ;
1878   case "$opsys" in mingw*)
1879     XE_APPEND($extra_includes, c_switch_system) ;;
1880   esac
1881   ;;
1882 esac
1883
1884 dnl Non-ordinary link usually requires -lc
1885 test "$ordinary_link" = "no" -a -z "$libs_standard" && libs_standard="-lc"
1886
1887 dnl -----------------------
1888 dnl Compiler-specific hacks
1889 dnl -----------------------
1890
1891 dnl DEC C `-std1' means ANSI C mode
1892 test "$__DECC" = "yes" && XE_APPEND(-std1, c_switch_site)
1893
1894 dnl Some versions of SCO native compiler need -Kalloca
1895 if test "$__USLC__" = yes; then
1896   AC_MSG_CHECKING(for whether the -Kalloca compiler flag is needed)
1897   need_kalloca=no
1898   AC_TRY_LINK([], [void *x = alloca(4);], [:], [
1899     xe_save_c_switch_system="$c_switch_system"
1900     c_switch_system="$c_switch_system -Kalloca"
1901     AC_TRY_LINK([], [void *x = alloca(4);], [ need_kalloca=yes ])
1902     c_switch_system="$xe_save_c_switch_system"])
1903   AC_MSG_RESULT($need_kalloca)
1904   test "$need_kalloca" = "yes" && XE_APPEND(-Kalloca,c_switch_system)
1905 fi
1906
1907 dnl Calculate value of CFLAGS:
1908 dnl Use either command line flag, environment var, or autodetection
1909 if test "$cflags_specified" = "no"; then
1910   dnl Following values of CFLAGS are known to work well.
1911   dnl Should we take debugging options into consideration?
1912   if   test "$GCC" = "yes"; then
1913     CFLAGS="-g -O3 -Wall -Wno-switch -Winline -Wmissing-prototypes"
1914     dnl Yuck, bad compares have been worth at least 3 crashes!
1915     CFLAGS="$CFLAGS -Wsign-compare"
1916     dnl You get five zillion shadowing warnings with g++.
1917     dnl Even with gcc, -Wshadow is questionable because of its complaints
1918     dnl about parameters with the same names as global functions.
1919     if test "$xemacs_compiler" != "g++"; then
1920       CFLAGS="$CFLAGS -Wshadow"
1921     fi
1922     dnl glibc is intentionally not `-Wpointer-arith'-clean.
1923     dnl Ulrich Drepper has rejected patches to fix the glibc header files.
1924     test "$have_glibc" != "yes" && CFLAGS="$CFLAGS -Wpointer-arith"
1925     dnl I'm not convinced this is a good idea any more. -sb
1926     dnl test "$opsys $machine" = "linux intel386" && \
1927     dnl CFLAGS="$CFLAGS -fno-strength-reduce -malign-loops=2 -malign-jumps=2 -malign-functions=2"
1928   elif test "$__SUNPRO_C" = "yes"; then
1929     case "$opsys" in
1930       sol2    ) CFLAGS="-v -xO4" ;;
1931       sunos4* ) CFLAGS="-xO2";;
1932     esac
1933   elif test "$__DECC" = "yes"; then
1934     CFLAGS="-O3"
1935   elif test "$CC" = "xlc"; then
1936     CFLAGS="-g -O3 -qstrict -qnoansialias -qlibansi -qinfo -qro -qmaxmem=20000"
1937   dnl ### Add optimal CFLAGS support for other compilers HERE!
1938   else
1939     CFLAGS="-O" ;dnl The only POSIX-approved flag
1940   fi
1941 fi
1942
1943 dnl Search for GCC specific build problems we know about
1944 if test "$GCC" = "yes"; then
1945 AC_MSG_CHECKING(for buggy gcc versions)
1946 GCC_VERSION=`$CC --version`
1947 case `uname -s`:`uname -m`:$GCC_VERSION in
1948         dnl egcs 2.90.21 (egcs-1.00 release)
1949         dnl egcs 2.90.29 (egcs-1.0.3 release)
1950     *:sun4*:2.8.1|*:sun4*:egcs-2.90.*)
1951         dnl Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures
1952         dnl without also using `-fno-schedule-insns'.
1953         case "$CFLAGS" in
1954             *-O2*|*-O3*)
1955                 case "$CFLAGS" in
1956                     *-fno-schedule-insns*) ;;
1957                     *)
1958                         AC_MSG_RESULT(yes)
1959                         AC_MSG_WARN(Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures)
1960                         AC_MSG_WARN(without also using -fno-schedule-insns.)
1961                         AC_MSG_ERROR(Aborting due to known problem)
1962                         ;;
1963                 esac
1964                 ;;
1965         esac
1966         ;;
1967         dnl egcs-2.91.57 (egcs-1.1 release)
1968         dnl egcs-2.91.66 (egcs-1.1.2 release)
1969     Linux:alpha:egcs-2.91.*)
1970         AC_MSG_RESULT(yes)
1971         AC_MSG_WARN(There have been reports of egcs-1.1 not compiling XEmacs correctly on)
1972         AC_MSG_WARN(Alpha Linux.  There have also been reports that egcs-1.0.3a is O.K.)
1973         AC_MSG_ERROR(Aborting due to known problem)
1974         ;;
1975     *:i*86*:2.7.2*)
1976         case "$CFLAGS" in
1977             *-O2*|*-O3*)
1978                 case "$GCC_VERSION" in
1979                     2.7.2)
1980                         case "$CFLAGS" in
1981                             *-fno-strength-reduce*) ;;
1982                             *)
1983                                 AC_MSG_RESULT(yes)
1984                                 AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1985                                 AC_MSG_WARN(-fno-strength-reduce.)
1986                                 AC_MSG_ERROR(Aborting due to known problem)
1987                                 ;;
1988                         esac
1989                         ;;
1990                 esac
1991                 case "$CFLAGS" in
1992                  *-fno-caller-saves*) ;;
1993                  *)
1994                     AC_MSG_RESULT(yes)
1995                     AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1996                     AC_MSG_WARN(-fno-caller-saves.)
1997                     AC_MSG_ERROR(Aborting due to known problem)
1998                     ;;
1999                 esac
2000                 ;;
2001         esac
2002         ;;
2003 esac
2004 AC_MSG_RESULT(no)
2005 fi
2006
2007 dnl Inform compiler that certain flags are meant for the linker
2008 dnl XE_PROTECT_LINKER_FLAGS(shell_var)
2009 define([XE_PROTECT_LINKER_FLAGS], [
2010 if test "$GCC" = "yes"; then
2011   set x $[$1]; shift; [$1]=""
2012   while test -n "[$]1"; do
2013     case [$]1 in
2014       -L  | -l  | -u               ) [$1]="$[$1] [$]1 [$]2"; shift ;;
2015       -L* | -l* | -u* | -Wl* | -pg ) [$1]="$[$1] [$]1" ;;
2016       -Xlinker* ) ;;
2017       * ) [$1]="$[$1] -Xlinker [$]1" ;;
2018     esac
2019     shift
2020   done
2021 fi])dnl
2022 XE_PROTECT_LINKER_FLAGS(ld_switch_system)
2023 XE_PROTECT_LINKER_FLAGS(ld_switch_machine)
2024 XE_PROTECT_LINKER_FLAGS(LDFLAGS)
2025 XE_PROTECT_LINKER_FLAGS(ld_call_shared)
2026
2027 dnl Add s&m-determined objects (including unexec) to link line
2028 test -n "$objects_machine" && XE_ADD_OBJS($objects_machine)
2029 test -n "$objects_system"  && XE_ADD_OBJS($objects_system)
2030 test -n "$unexec"          && test ! "$pdump" = "yes" && XE_ADD_OBJS($unexec)
2031 test "$pdump" = "yes" && XE_ADD_OBJS(dumper.o)
2032
2033 dnl Dynodump (Solaris 2.x, x<6)
2034 AC_MSG_CHECKING(for dynodump)
2035 if test "$unexec" != "unexsol2.o"; then
2036   AC_MSG_RESULT(no)
2037 else
2038   AC_MSG_RESULT(yes)
2039   AC_DEFINE(DYNODUMP)
2040   XE_APPEND(dynodump, MAKE_SUBDIR)
2041   XE_APPEND(dynodump, SRC_SUBDIR_DEPS)
2042   case "$machine" in
2043     sparc   ) dynodump_arch=sparc ;;
2044     *86*    ) dynodump_arch=i386  ;;
2045     powerpc ) dynodump_arch=ppc   ;;
2046   esac
2047   dnl Dynodump requires the system linker
2048   test "$GCC" = "yes" && XE_APPEND(-fno-gnu-linker, ld_switch_site)
2049 fi
2050
2051 dnl Feed s&m crud to src/Makefile
2052
2053 dnl Linux/powerpc needs the following magic for some reason
2054 test "$machine$opsys" = "powerpclinux" && start_flags="-T $srcdir/src/ppc.ldscript"
2055
2056 if test "$unexec" = "unexaix.o"; then
2057 dnl AIX needs various hacks to make static linking work.
2058   if   test "$dynamic" = "no"; then
2059   start_flags="-Wl,-bnso,-bnodelcsect"
2060   test "$GCC" = "yes" && start_flags="-B/bin/ ${start_flags}"
2061   for f in "/lib/syscalls.exp" "/lib/threads.exp"; do
2062     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; fi
2063   done
2064   for f in "/usr/lpp/X11/bin/smt.exp" "/usr/bin/X11/smt.exp"; do
2065     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; break; fi
2066   done
2067   AC_CHECK_LIB(C, terminateAndUnload, XE_APPEND(-lC, libs_system))
2068   fi
2069 elif test -n "$ld_text_start_addr"; then
2070   start_flags="-T $ld_text_start_addr -e __start"
2071 fi
2072 AC_SUBST(start_flags)
2073
2074 AC_SUBST(ld_switch_shared)
2075 AC_SUBST(start_files)
2076 if test "$ordinary_link" = "no" -a "$GCC" = "yes"; then
2077  test -z "$linker" &&  linker='$(CC) -nostdlib'
2078  test -z "$lib_gcc" && lib_gcc='`$(CC) -print-libgcc-file-name`'
2079 fi
2080 test "$GCC" != "yes" && lib_gcc=
2081 AC_SUBST(ld)
2082 AC_SUBST(lib_gcc)
2083
2084 dnl ---------------------------------------------------------------
2085 dnl Add site and system specific flags to compile and link commands
2086 dnl ---------------------------------------------------------------
2087
2088 dnl Allow use of either ":" or spaces for lists of directories
2089 define(COLON_TO_SPACE,
2090   [case "$[$1]" in *:* [)] [$1]="`echo '' $[$1] | sed -e 's/^ //' -e 's/:/ /g'`";; esac])dnl
2091
2092 dnl --site-libraries (multiple dirs)
2093 COLON_TO_SPACE(site_libraries)
2094 if test -n "$site_libraries"; then
2095   for arg in $site_libraries; do
2096     case "$arg" in
2097      -* ) ;;
2098      * ) test -d "$arg" || \
2099            XE_DIE("Invalid site library \`$arg': no such directory")
2100        arg="-L${arg}" ;;
2101     esac
2102     XE_APPEND($arg, ld_switch_site)
2103   done
2104 fi
2105
2106 dnl --site-includes (multiple dirs)
2107 COLON_TO_SPACE(site_includes)
2108 if test -n "$site_includes"; then
2109   for arg in $site_includes; do
2110     case "$arg" in
2111       -* ) ;;
2112       * ) test -d "$arg" || \
2113            XE_DIE("Invalid site include \`$arg': no such directory")
2114       arg="-I${arg}" ;;
2115     esac
2116     XE_APPEND($arg, c_switch_site)
2117   done
2118 fi
2119
2120 dnl --site-prefixes (multiple dirs)
2121 dnl --site-prefixes=dir1:dir2 is a convenient shorthand for
2122 dnl --site-libraries=dir1/lib:dir2/lib --site-includes=dir1/include:dir2/include
2123 dnl Site prefixes take precedence over the standard places, but not over
2124 dnl site-includes and site-libraries.
2125 COLON_TO_SPACE(site_prefixes)
2126 if test -n "$site_prefixes"; then
2127   for dir in $site_prefixes; do
2128     lib_dir="${dir}/lib"
2129     inc_dir="${dir}/include"
2130     if test ! -d "$dir"; then
2131       XE_DIE("Invalid site prefix \`$dir': no such directory")
2132     elif test ! -d "$lib_dir"; then
2133       XE_DIE("Invalid site prefix \`$dir': no such directory \`$lib_dir'")
2134     else
2135       if test -d "$inc_dir"; then
2136         XE_APPEND("-I$inc_dir", c_switch_site)
2137       fi
2138       XE_APPEND("-L$lib_dir", ld_switch_site)
2139     fi
2140   done
2141 fi
2142
2143 dnl GNU software installs by default into /usr/local/{include,lib}
2144 dnl if test -d "/usr/local/include" -a -d "/usr/local/lib"; then
2145 dnl   XE_APPEND("-L/usr/local/lib",    ld_switch_site)
2146 dnl   XE_APPEND("-I/usr/local/include", c_switch_site)
2147 dnl fi
2148
2149 dnl Extra system-specific library directories - please add to list
2150 for dir in "/usr/ccs/lib"; do
2151   test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2152 done
2153
2154 dnl --site-runtime-libraries (multiple dirs)
2155 COLON_TO_SPACE(site_runtime_libraries)
2156 if test -n "$site_runtime_libraries"; then
2157   LD_RUN_PATH="`echo $site_runtime_libraries | sed -e 's/  */:/g'`"
2158   export LD_RUN_PATH
2159 fi
2160
2161 dnl Linux systems have dynamic runtime library directories listed in
2162 dnl /etc/ld.so.conf.  Since those are used at run time, it seems pretty
2163 dnl safe to use them at link time, and less controversial than forcing
2164 dnl the run-time to use the link-time libraries.  This also helps avoid
2165 dnl mismatches between the link-time and run-time libraries.
2166
2167 dnl #### Unfortunately, there are horrible libc4 and libc5 libraries
2168 dnl listed in /etc/ld.so.conf on some systems, and including them on
2169 dnl the link path leads to linking in utterly broken libc's.
2170 dnl There are many clever ways of approaching this problem,
2171 dnl but finding one that actually works...
2172
2173 dnl if test -z "$LD_RUN_PATH" -a -r "/etc/ld.so.conf"; then
2174 dnl   for dir in `cat /etc/ld.so.conf`; do
2175 dnl     test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2176 dnl   done
2177 dnl   add_runtime_path=no
2178 dnl fi
2179
2180 dnl -------------------------------------
2181 dnl Compute runtime library path
2182 dnl -------------------------------------
2183
2184 if test -n "$add_runtime_path"; then :;
2185 elif test "$dynamic" = "no"; then add_runtime_path=no
2186 elif test -n "$LD_RUN_PATH"; then add_runtime_path=yes
2187 else case "$opsys" in
2188        sol2 | irix* | *bsd* | decosf* ) add_runtime_path=yes ;;
2189        * ) add_runtime_path=no ;;
2190      esac
2191 fi
2192
2193 if test "$add_runtime_path" = "yes"; then
2194   dnl Try to autodetect runtime library flag (usually -R),
2195   dnl and whether it works (or at least does no harm)
2196   AC_MSG_CHECKING("for runtime libraries flag")
2197   case "$opsys" in
2198     sol2 ) dash_r="-R" ;;
2199     decosf* | linux* | irix*) dash_r="-rpath " ;;
2200     *)
2201       dash_r=""
2202       for try_dash_r in "-R" "-R " "-rpath "; do
2203         xe_check_libs="${try_dash_r}/no/such/file-or-directory"
2204         XE_PROTECT_LINKER_FLAGS(xe_check_libs)
2205         AC_TRY_LINK(, , dash_r="$try_dash_r")
2206         xe_check_libs=""
2207         test -n "$dash_r" && break
2208       done ;;
2209   esac
2210   if test -n "$dash_r";
2211     then AC_MSG_RESULT("\"${dash_r}\"")
2212     else AC_MSG_RESULT(NONE)
2213   fi
2214 fi
2215
2216 xe_add_unique_runpath_dir='
2217   xe_add_p=yes
2218   for xe_dir in $runpath_dirs; do   dnl Uniquify
2219     test "$xe_dir" = "$xe_runpath_dir" && xe_add_p=no
2220   done
2221   if test "$xe_add_p" = "yes"; then
2222     test -n "$runpath" && runpath="${runpath}:"
2223     runpath="${runpath}${xe_runpath_dir}"
2224     runpath_dirs="$runpath_dirs $xe_runpath_dir"
2225   fi'
2226
2227
2228 dnl XE_ADD_RUNPATH_DIR(directory)
2229 define([XE_ADD_RUNPATH_DIR],[{
2230 xe_runpath_dir=$1
2231 dnl PRINT_VAR(ld_switch_site ld_switch_x_site runpath xe_runpath_dir LD_RUN_PATH xe_ldflags)
2232   test "$xe_runpath_dir" != "/lib"     -a \
2233         "$xe_runpath_dir" != "/usr/lib" -a \
2234         -n "`ls ${xe_runpath_dir}/*.s[[ol]] 2>/dev/null`" && \
2235   eval "$xe_add_unique_runpath_dir"
2236 }])dnl
2237
2238 dnl XE_COMPUTE_RUNPATH()
2239 define([XE_COMPUTE_RUNPATH],[
2240 if test "$add_runtime_path" = "yes" -a -n "$dash_r"; then
2241   dnl Remove runtime paths from current ld switches
2242   ld_switch_site=`echo   '' $ld_switch_site   | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2243   ld_switch_x_site=`echo '' $ld_switch_x_site | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2244   dnl PRINT_VAR(ld_switch_site ld_switch_x_site)
2245
2246   dnl Fix up Runtime path
2247   dnl If LD_RUN_PATH is set in environment, use that.
2248   dnl In this case, assume user has set the right value.
2249   runpath="" runpath_dirs=""
2250   if test -n "$LD_RUN_PATH"; then
2251     runpath="$LD_RUN_PATH"
2252   elif test "$GCC" = "yes"; then
2253     dnl Compute runpath from gcc's -v output
2254     ld_switch_run_save="$ld_switch_run"; ld_switch_run=""
2255     echo "int main(int argc, char *argv[[]]) {return 0;}" > conftest.c
2256     xe_runpath_link='${CC-cc} -o conftest -v $CFLAGS '"$xe_ldflags"' conftest.$ac_ext 2>&1 1>/dev/null'
2257     for arg in `eval "$xe_runpath_link" | grep ' -L'`; do
2258       case "$arg" in P,* | -L* | -R* )
2259         for dir in `echo '' "$arg" | sed -e 's:^ ::' -e 's/^..//' -e 'y/:/ /'`; do
2260           XE_ADD_RUNPATH_DIR("$dir")
2261         done ;;
2262       esac
2263     done
2264     ld_switch_run="$ld_switch_run_save"
2265     rm -f conftest*
2266   else
2267     dnl Add all directories with .so files to runpath
2268     for arg in $ld_switch_site $ld_switch_x_site; do
2269       case "$arg" in -L*) XE_ADD_RUNPATH_DIR(`echo '' "$arg" | sed -e 's:^ ::' -e 's/^-L//'`);; esac
2270     done
2271     dnl Sometimes /opt/SUNWdt/lib is the only installed Motif available
2272     if test "$opsys $need_motif" = "sol2 yes"; then
2273       xe_runpath_dir="/opt/SUNWdt/lib";
2274       eval "$xe_add_unique_runpath_dir";
2275     fi
2276   fi dnl Compute $runpath
2277
2278   if test -n "$runpath"; then
2279     ld_switch_run="${dash_r}${runpath}"
2280     XE_PROTECT_LINKER_FLAGS(ld_switch_run)
2281     test "$extra_verbose" = "yes" && echo "Setting runpath to $runpath"
2282   fi
2283 fi
2284 ])dnl
2285 XE_COMPUTE_RUNPATH()
2286
2287 dnl -----------------------------------
2288 dnl Do some misc autoconf-special tests
2289 dnl -----------------------------------
2290
2291 dnl Do the opsystem or machine files prohibit the use of the GNU malloc?
2292 dnl Assume not, until told otherwise.
2293 GNU_MALLOC=yes
2294 if test "$with_dlmalloc" != "no"; then
2295         doug_lea_malloc=yes
2296 else
2297         doug_lea_malloc=no
2298 fi
2299 after_morecore_hook_exists=yes
2300 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
2301 AC_MSG_CHECKING(whether __after_morecore_hook exists)
2302 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
2303   [AC_MSG_RESULT(yes)],
2304   [AC_MSG_RESULT(no)
2305    after_morecore_hook_exists=no])
2306 if test "$system_malloc" = "yes" ; then
2307   GNU_MALLOC=no
2308   GNU_MALLOC_reason="
2309     - The GNU allocators don't work with this system configuration."
2310 elif test "$with_system_malloc" = "yes" ; then
2311   GNU_MALLOC=no
2312   GNU_MALLOC_reason="
2313     - User chose not to use GNU allocators."
2314 elif test "$with_debug_malloc" = "yes" ; then
2315   GNU_MALLOC=no
2316   GNU_MALLOC_reason="
2317     - User chose to use Debugging Malloc."
2318 fi
2319
2320 if test "$doug_lea_malloc" = "yes" -a "$GNU_MALLOC" = "yes" ; then
2321   GNU_MALLOC_reason="
2322     - Using Doug Lea's new malloc from the GNU C Library."
2323   AC_DEFINE(DOUG_LEA_MALLOC)
2324   if test "$after_morecore_hook_exists" = "no" ; then
2325     GNU_MALLOC_reason="
2326     - Using Doug Lea's new malloc from the Linux C Library."
2327     AC_DEFINE(_NO_MALLOC_WARNING_)
2328   fi
2329 fi
2330
2331 dnl #### mcheck is broken in all versions of Linux libc and glibc.
2332 dnl Try this again when 2.1 hits the streets.
2333 dnl Avoid using free-hook.c if support exists for malloc debugging in libc
2334 dnl have_libmcheck=no
2335 dnl if test "$error_check_malloc" = "yes" -a \
2336 dnl    "$have_glibc" = "yes" -a \
2337 dnl    "$doug_lea_malloc" = "yes"; then
2338 dnl   AC_CHECK_HEADERS(mcheck.h)
2339 dnl   AC_CHECK_LIB(mcheck, mcheck, have_libmcheck=yes, have_libmcheck=no)
2340 dnl fi
2341
2342 dnl if test "$have_libmcheck" = "yes"; then
2343 dnl   AC_DEFINE(HAVE_LIBMCHECK)
2344 dnl   libmcheck=-lmcheck
2345 dnl   AC_SUBST(libmcheck)
2346 dnl fi
2347
2348 dnl Some other nice autoconf tests.  If you add a test here which
2349 dnl should make an entry in src/config.h, do not forget to add an
2350 dnl #undef clause to src/config.h.in for autoconf to modify.
2351
2352 AC_PROG_RANLIB
2353 AC_PROG_INSTALL
2354 AC_PROG_YACC
2355
2356 dnl checks for header files
2357 AC_CHECK_HEADERS(dnl
2358   a.out.h dnl
2359   elf.h dnl
2360   cygwin/version.h dnl
2361   fcntl.h dnl
2362   inttypes.h dnl
2363   libgen.h dnl
2364   locale.h dnl
2365   mach/mach.h dnl
2366   sys/param.h dnl
2367   sys/pstat.h dnl
2368   sys/time.h dnl
2369   sys/timeb.h dnl
2370   sys/un.h dnl
2371   ulimit.h dnl
2372   unistd.h dnl
2373 )
2374 AC_HEADER_SYS_WAIT
2375 AC_HEADER_STDC
2376 AC_HEADER_TIME
2377 AC_DECL_SYS_SIGLIST
2378
2379
2380 dnl ----------------------------------------------------------------
2381 dnl Checking for utime() or utimes().
2382 dnl We prefer utime, since it is more standard.
2383 dnl Some systems have utime.h but do not declare the struct anyplace,
2384 dnl so we use a more sophisticated test for utime than AC_CHECK_FUNCS.
2385 dnl ----------------------------------------------------------------
2386 AC_MSG_CHECKING(for utime)
2387 AC_TRY_COMPILE([#include <sys/types.h>
2388 #include <utime.h>],
2389 [struct utimbuf x; x.actime = x.modtime = 0; utime ("/", &x);],
2390   [AC_MSG_RESULT(yes)
2391    AC_DEFINE(HAVE_UTIME)],
2392   [AC_MSG_RESULT(no)
2393    dnl We don't have utime(); how about utimes()?
2394    AC_CHECK_FUNCS(utimes)])
2395
2396
2397 dnl checks for typedefs
2398 AC_TYPE_SIGNAL
2399 AC_TYPE_SIZE_T
2400 AC_TYPE_PID_T
2401 AC_TYPE_UID_T
2402 AC_TYPE_MODE_T
2403 AC_TYPE_OFF_T
2404 AC_CHECK_TYPE(ssize_t, int)
2405
2406 dnl check for Unix98 socklen_t
2407 AC_MSG_CHECKING(for socklen_t)
2408 AC_TRY_COMPILE([#include <sys/socket.h>
2409 socklen_t x;
2410 ],[],[AC_MSG_RESULT(yes)],[
2411 AC_TRY_COMPILE([#include <sys/socket.h>
2412 int accept (int, struct sockaddr *, size_t *);
2413 ],[],[
2414 AC_MSG_RESULT(size_t)
2415 AC_DEFINE(socklen_t,size_t)], [
2416 AC_MSG_RESULT(int)
2417 AC_DEFINE(socklen_t,int)])])
2418
2419 AC_MSG_CHECKING(for struct timeval)
2420 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2421 #include <sys/time.h>
2422 #include <time.h>
2423 #else
2424 #ifdef HAVE_SYS_TIME_H
2425 #include <sys/time.h>
2426 #else
2427 #include <time.h>
2428 #endif
2429 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
2430   [AC_MSG_RESULT(yes)
2431   HAVE_TIMEVAL=yes
2432   AC_DEFINE(HAVE_TIMEVAL)],
2433   [AC_MSG_RESULT(no)
2434    HAVE_TIMEVAL=no])
2435
2436 dnl checks for structure members
2437 AC_STRUCT_TM
2438 AC_STRUCT_TIMEZONE
2439
2440 dnl checks for compiler characteristics
2441 AC_C_CONST
2442
2443 dnl check for Make feature
2444 AC_PROG_MAKE_SET
2445
2446 dnl check byte order
2447 AC_C_BIGENDIAN
2448
2449 dnl define SIZEOF_TYPE
2450 AC_CHECK_SIZEOF(short)
2451 if test "$ac_cv_sizeof_short" = 0; then
2452   echo ""
2453   echo "*** PANIC *** Configure tests are not working - compiler is broken."
2454   echo "*** PANIC *** Please examine config.log for compilation errors."
2455   exit 1
2456 fi
2457 AC_CHECK_SIZEOF(int)
2458 AC_CHECK_SIZEOF(long)
2459 AC_CHECK_SIZEOF(long long)
2460 AC_CHECK_SIZEOF(void *)
2461
2462 dnl check for long file names
2463 AC_SYS_LONG_FILE_NAMES
2464
2465 dnl -lm is required by LISP_FLOAT_TYPE, among other things
2466 AC_CHECK_FUNC(sin, ,AC_CHECK_LIB(m, sin))
2467
2468 dnl Floating operation support is now unconditional
2469 AC_DEFINE(LISP_FLOAT_TYPE)
2470
2471 AC_TRY_LINK([#include <math.h>],
2472   [return atanh(1.0) + asinh(1.0) + acosh(1.0); ],
2473   AC_DEFINE(HAVE_INVERSE_HYPERBOLIC))
2474
2475 dnl Determine type of mail locking from configure args and s&m headers
2476 AC_CHECKING(type of mail spool file locking)
2477 AC_CHECK_FUNCS(lockf flock)
2478 dnl The mail_use_xxx variables are set according to the s&m headers.
2479 test -z "$mail_locking" -a "$mail_use_flock" = "yes" && mail_locking=flock
2480 test -z "$mail_locking" -a "$mail_use_lockf" = "yes" && mail_locking=lockf
2481 test -z "$mail_locking" -a "$mail_use_locking" = "yes" && mail_locking=locking
2482 if   test -z "$mail_locking"; then
2483   case "$opsys" in cygwin* | mingw*)
2484     mail_locking=pop ;;
2485   esac
2486 fi
2487
2488 if   test "$mail_locking" = "lockf"; then AC_DEFINE(MAIL_LOCK_LOCKF)
2489 elif test "$mail_locking" = "flock"; then AC_DEFINE(MAIL_LOCK_FLOCK)
2490 elif test "$mail_locking" = "locking"; then AC_DEFINE(MAIL_LOCK_LOCKING)
2491 elif test "$mail_locking" = "pop"; then
2492   with_pop=yes
2493   mail_locking=
2494 else mail_locking="dot-locking"; AC_DEFINE(MAIL_LOCK_DOT)
2495 fi
2496 test "$mail_locking" = "lockf" -a "$ac_cv_func_lockf" != "yes" && \
2497   XE_DIE("lockf mail locking requested but not available.")
2498 test "$mail_locking" = "flock" -a "$ac_cv_func_flock" != "yes" && \
2499   XE_DIE("flock mail locking requested but not available.")
2500 test "$mail_locking" = "locking" -a "$ac_cv_func_locking" != "yes" && \
2501   XE_DIE("locking mail locking requested but not available.")
2502
2503 case "$opsys" in decosf*)
2504   AC_CHECK_LIB(pthreads, cma_open)
2505   test "$ac_cv_lib_pthreads_cma_open" = "yes" && \
2506     c_switch_site="$c_switch_site -threads" ;;
2507 esac
2508
2509 dnl ----------------------------------------------------------------
2510 dnl Miscellaneous flags
2511 dnl ----------------------------------------------------------------
2512
2513 AC_MSG_CHECKING(whether the -xildoff compiler flag is required)
2514 if   ${CC-cc} '-###' -xildon  no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ; then
2515   if ${CC-cc} '-###' -xildoff no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ;
2516     then AC_MSG_RESULT(no);
2517     else AC_MSG_RESULT(yes); XE_APPEND(-xildoff, ld_switch_site)
2518   fi
2519   else AC_MSG_RESULT(no)
2520 fi
2521
2522 dnl Link with "-z ignore" on Solaris if supported
2523 if test "$opsys" = "sol2"; then
2524   if test "$os_release" -ge 56; then
2525     AC_MSG_CHECKING(for \"-z ignore\" linker flag)
2526     case "`ld -h 2>&1`" in
2527       *-z\ ignore\|record* ) AC_MSG_RESULT(yes)
2528         XE_PREPEND(-z ignore, ld_switch_site) ;;
2529       *) AC_MSG_RESULT(no) ;;
2530     esac
2531   fi
2532 fi
2533
2534 dnl GNU ld now defaults to combreloc, which screws up unexec, but not pdump.
2535 dnl Note that it's OK if the GNU style long option causes non-GNU ld to barf
2536 dnl a usage message, that's often good enough.  Please report it, though.
2537 dnl #### Should make this Solaris-friendly.
2538 dnl Link with -z nocombreloc for now.
2539 if test "$pdump" != "yes"; then
2540   AC_MSG_CHECKING(for \"-z nocombreloc\" linker flag)
2541   case "`ld --help 2>&1`" in
2542     *-z\ nocombreloc* ) AC_MSG_RESULT(yes)
2543       XE_PREPEND(-z nocombreloc, ld_switch_site) ;;
2544     *) AC_MSG_RESULT(no) ;;
2545   esac
2546 fi
2547
2548 dnl ----------------------
2549 dnl Choose a window system
2550 dnl ----------------------
2551
2552 AC_CHECKING("for specified window system")
2553
2554 dnl Autodetection of Gdk libraries and includes
2555 dnl -------------------------------------------
2556 dnl On some systems (FreeBSD springs to mind), they use
2557 dnl versions on the utility routines, so instead of gtk-config
2558 dnl you must use gtk12-config, etc, etc.
2559
2560 GNOME_CONFIG=no
2561 GTK_CONFIG=no
2562
2563 if test "$with_gnome" != "no"; then
2564    AC_MSG_CHECKING(for GNOME configuration script)
2565    for possible in gnome-config
2566    do
2567       possible_version=`${possible} --version 2> /dev/null`
2568       if test "x${possible_version}" != "x"; then
2569               GNOME_CONFIG="${possible}"
2570               with_gnome=yes
2571               with_gtk=yes
2572               break
2573       fi
2574    done
2575    AC_MSG_RESULT([${GNOME_CONFIG}])
2576 fi
2577
2578 if test "${GNOME_CONFIG}" != "no"; then
2579       GNOME_LIBS=`${GNOME_CONFIG} --libs gnomeui`
2580       GNOME_CFLAGS=`${GNOME_CONFIG} --cflags gnomeui`
2581       AC_DEFINE(HAVE_GNOME)
2582       XE_APPEND(${GNOME_LIBS}, libs_gtk)
2583       XE_APPEND(${GNOME_CFLAGS}, c_switch_gtk)
2584 fi
2585
2586 if test "$with_gtk" != "no";then
2587    AC_MSG_CHECKING(for GTK configuration script)
2588    for possible in gtk12-config gtk14-config gtk-config
2589    do
2590       possible_version=`${possible} --version 2> /dev/null`
2591       if test "x${possible_version}" != "x"; then
2592               GTK_CONFIG="${possible}"
2593       fi
2594       case "${possible_version}" in
2595         1.0.*) AC_MSG_WARN([GTK 1.2 is required, please upgrade your version of GTK.]); with_gtk=no;;
2596         1.3.*) AC_MSG_WARN([GTK 1.3 is not supported right now]); with_gtk=no;;
2597         1.2.*)
2598                 with_gtk=yes
2599                 break
2600                 ;;
2601         *)     AC_MSG_WARN([Found unsupported version of GTK: $possible_version]);;
2602       esac
2603    done
2604    AC_MSG_RESULT([${GTK_CONFIG}])
2605 fi
2606
2607 if test "${GTK_CONFIG}" != "no"; then
2608       AC_MSG_CHECKING(gtk version)
2609       GTK_VERSION=`${GTK_CONFIG} --version`
2610       AC_MSG_RESULT(${GTK_VERSION})
2611
2612       AC_MSG_CHECKING(gtk libs)
2613       GTK_LIBS=`${GTK_CONFIG} --libs`
2614       XE_APPEND(${GTK_LIBS}, libs_gtk)
2615       AC_MSG_RESULT(${GTK_LIBS})
2616
2617       AC_MSG_CHECKING(gtk cflags)
2618       GTK_CFLAGS=`${GTK_CONFIG} --cflags`
2619       if test "$GCC" = "yes"; then
2620         GTK_CFLAGS="${GTK_CFLAGS} -Wno-shadow"
2621       fi
2622       XE_APPEND(${GTK_CFLAGS}, c_switch_gtk)
2623       AC_MSG_RESULT(${GTK_CFLAGS})
2624
2625       AC_CHECK_LIB(gdk_imlib, main, XE_PREPEND(-lgdk_imlib, libs_gtk))
2626       AC_CHECK_LIB(Imlib, Imlib_init, XE_APPEND(-lImlib, libs_gtk))
2627       AC_CHECK_FUNCS(gdk_imlib_init)
2628
2629       AC_DEFINE(HAVE_XPM)
2630       AC_DEFINE(HAVE_GTK)
2631       AC_SUBST(GTK_CONFIG)
2632
2633       window_system=gtk
2634       with_gtk=yes
2635       with_x11=no
2636
2637       test "${with_scrollbars}" != "no" && with_scrollbars=gtk
2638       test "${with_toolbars}" != no && with_toolbars=gtk
2639       test "${with_menubars}" != "no" && with_menubars=gtk
2640       test "${with_dialogs}" != "no" && with_dialogs=gtk
2641       test "${with_widgets}" != "no" && with_widgets=gtk
2642
2643       XE_ADD_OBJS(console-gtk.o device-gtk.o event-gtk.o frame-gtk.o)
2644       XE_ADD_OBJS(objects-gtk.o redisplay-gtk.o glyphs-gtk.o)
2645       XE_ADD_OBJS(select-gtk.o gccache-gtk.o)
2646       XE_ADD_OBJS(gtk-xemacs.o ui-gtk.o)
2647
2648       dnl Check for libglade support (it rocks)
2649       OLD_CFLAGS="${CFLAGS}"
2650       OLD_CPPFLAGS="${CPPFLAGS}"
2651       OLD_LDFLAGS="${LDFLAGS}"
2652       CFLAGS="${GTK_CFLAGS} ${CFLAGS}"
2653       CPPFLAGS="${GTK_CFLAGS} ${CFLAGS}"
2654       LDFLAGS="${LDFLAGS} ${GTK_LIBS}"
2655       AC_CHECK_HEADERS(glade/glade.h glade.h)
2656       AC_CHECK_LIB(xml, main, XE_PREPEND(-lxml, libs_gtk))
2657       AC_CHECK_LIB(glade, main, XE_PREPEND(-lglade, libs_gtk))
2658       AC_CHECK_LIB(glade-gnome, main, XE_PREPEND(-lglade-gnome, libs_gtk))
2659       AC_EGREP_HEADER([char \*txtdomain;], [glade/glade-xml.h],
2660                       [AC_MSG_RESULT(yes)
2661                        AC_DEFINE(LIBGLADE_XML_TXTDOMAIN,1)],
2662                       [AC_MSG_RESULT(no)])
2663       CFLAGS="${OLD_CFLAGS}"
2664       CPPFLAGS="${OLD_CPPFLAGS}"
2665       LDFLAGS="${OLD_LDFLAGS}"
2666 fi
2667
2668 dnl We may eventually prefer gtk/gdk over vanilla X11...
2669
2670 if test "$with_x11" != "no"; then
2671   dnl User-specified --x-includes or --x-libraries implies --with-x11.
2672   test "$x_includes $x_libraries" != "NONE NONE" && \
2673    window_system=x11 with_x11=yes
2674
2675   dnl Autodetection of X11 libraries and includes
2676   dnl -------------------------------------------
2677   dnl AC_PATH_XTRA thinks it can find our X headers and includes, but
2678   dnl it often gets it wrong, so we only use it as a last resort.
2679
2680   dnl $OPENWINHOME implies --x-includes and --x-libraries
2681   dnl Not (yet) handled by autoconf2
2682   if test "$x_includes $x_libraries" = "NONE NONE" \
2683     -a -n "$OPENWINHOME" \
2684     -a "$OPENWINHOME" != "/usr/openwin" \
2685     -a -d "$OPENWINHOME"; then
2686       test -d "$OPENWINHOME/lib"           && x_libraries="$OPENWINHOME/lib"
2687       test -d "$OPENWINHOME/include"       && x_includes="$OPENWINHOME/include"
2688       test -d "$OPENWINHOME/share/include" && x_includes="$OPENWINHOME/share/include"
2689   fi
2690
2691   if test "$x_includes" = "NONE"; then
2692     dnl AC_PATH_XTRA often guesses /usr/include, when some other
2693     dnl include directory is a MUCH better guess (Linux, HP-UX 10.20).
2694     dnl This is a workaround for idiot (esp. HP) system vendors, who
2695     dnl provide a /usr/include/X11, but DON'T FULLY POPULATE IT.
2696     for dir in "/usr/X11" "/usr/X11R6"; do
2697       if test -d "$dir/include/X11"; then x_includes="$dir/include"; break; fi
2698     done
2699   fi
2700
2701   if test "$x_libraries" = "NONE"; then
2702     for dir in "/usr/X11/lib" "/usr/X11R6/lib" "/usr/lib/X11R6"; do
2703       if test -r "$dir/libX11.a"; then x_libraries="$dir"; break; fi
2704     done
2705   fi
2706
2707   AC_PATH_XTRA # Autoconf claims to find X library and include dirs for us.
2708   if test "$no_x" = "yes"
2709   then with_x11=no  window_system=none HAVE_X_WINDOWS=no
2710   else with_x11=yes window_system=x11  HAVE_X_WINDOWS=yes
2711   fi
2712 fi
2713
2714 dnl #### wmperry:: !x11 != NONE
2715 dnl case "$with_x11" in
2716 dnl  yes ) window_system=x11  HAVE_X_WINDOWS=yes ;;
2717 dnl  no  ) window_system=none HAVE_X_WINDOWS=no  ;;
2718 dnl esac
2719
2720 if test "$with_x11" = "yes"; then
2721   AC_DEFINE(HAVE_X_WINDOWS)
2722   XE_APPEND(lwlib, MAKE_SUBDIR)
2723   XE_APPEND(lwlib, SRC_SUBDIR_DEPS)
2724
2725   dnl Try to find Motif/CDE/Tooltalk dirs
2726   dnl These take precedence over other X libs/includes, so PRE-pend
2727   for lib_dir in "/usr/dt/lib" "/usr/lib/Motif2.1" "/usr/lib/Motif1.2" "/usr/lib/Motif1.1"; do
2728     inc_dir=`echo $lib_dir | sed -e 's/lib/include/'`
2729     if test -d "$lib_dir" -a -d "$inc_dir"; then
2730       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2731         x_libraries="$lib_dir $x_libraries"
2732         XE_PREPEND(-L${lib_dir}, X_LIBS) ;;
2733       esac
2734       case "$x_includes" in "$inc_dir"* ) ;; *)
2735         x_includes="$inc_dir $x_includes"
2736         XE_PREPEND(-I${inc_dir}, X_CFLAGS) ;;
2737       esac
2738       break; dnl only need ONE Motif implementation!
2739       fi
2740   done
2741
2742   dnl Contrib X libs/includes do NOT take precedence, so AP-pend
2743   for rel in "X11R6" "X11R5" "X11R4"; do
2744     lib_dir="/usr/contrib/$rel/lib" inc_dir="/usr/contrib/$rel/include"
2745     if test -d "$lib_dir" -a -d "$inc_dir"; then
2746       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2747         x_libraries="$x_libraries $lib_dir"
2748         XE_APPEND(-L${lib_dir}, X_LIBS)
2749       esac
2750       case "$x_includes" in "$inc_dir"* ) ;; *)
2751         x_includes="$x_includes $inc_dir"
2752         XE_APPEND(-I${inc_dir}, X_CFLAGS)
2753       esac
2754       break; dnl Only need ONE X11 implementation !
2755     fi
2756   done
2757
2758   dnl Avoid version mismatch for shared library libXm.so on osf4
2759   case "$opsys" in
2760   decosf*) if test "$GCC" = yes -a -d /usr/shlib; then XE_APPEND(-L/usr/shlib, X_LIBS); fi ;;
2761   esac
2762
2763   ld_switch_x_site="$X_LIBS"
2764
2765   XE_COMPUTE_RUNPATH()
2766
2767   if test "$extra_verbose" = "yes"; then
2768     echo; echo "X11 compilation variables:"
2769     PRINT_VAR(x_libraries x_includes X_CFLAGS X_LIBS X_PRE_LIBS X_EXTRA_LIBS)
2770     echo
2771   fi
2772
2773   dnl Set up bitmaps search path.
2774   dnl The original suggestion was to unconditionally to append X11/bitmaps
2775   dnl to each element of $x_includes, I'm pretty sure this is the wrong
2776   dnl thing to do.  We test for bitmaps and X11/bitmaps directories on each
2777   dnl element and add them to BITMAPDIR if they exist.
2778   bitmapdirs=
2779   if test "$x_includes" != NONE; then
2780     for i in $x_includes; do
2781       if test -d "$i/bitmaps"; then
2782         bitmapdirs="$i/bitmaps:$bitmapdirs"
2783       fi
2784       if test -d "$i/X11/bitmaps"; then
2785         bitmapdirs="$i/X11/bitmaps:$bitmapdirs"
2786       fi
2787     done
2788     bitmapdirs=`echo "$bitmapdirs" | sed s/.$//`
2789   fi
2790   test ! -z "$bitmapdirs" && AC_DEFINE_UNQUOTED(BITMAPDIR, "$bitmapdirs")
2791
2792   dnl Autodetect defines extracted from X config by xmkmf, e.g. NARROWPROTO
2793   AC_CHECKING(for X defines extracted by xmkmf)
2794   rm -fr conftestdir
2795   if mkdir conftestdir; then
2796     cd conftestdir
2797     cat > Imakefile <<'EOF'
2798 xetest:
2799         @echo ${PROTO_DEFINES} ${STD_DEFINES}
2800 EOF
2801     if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
2802       # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
2803       xmkmf_defines=`${MAKE-make} xetest 2>/dev/null | grep -v make`
2804     fi
2805     cd ..
2806     rm -fr conftestdir
2807     for word in $xmkmf_defines; do
2808       case "$word" in
2809       -D__STDC__*) ;;
2810       -D* )
2811         sym=`echo '' $word | sed -e 's:^ *-D::' -e 's:=.*::'`
2812         case "$word" in
2813           -D*=* ) val=`echo '' $word | sed -e 's:^.*=::'` ;;
2814           *     ) val=1 ;;
2815         esac
2816 dnl Avoid re-AC_DEFINE-ing xmkmf symbols we've already defined above.
2817         if grep "^#define $sym " confdefs.h >/dev/null; then :; else
2818           if test "$val" = "1"
2819             then AC_DEFINE_UNQUOTED($sym)
2820             else AC_DEFINE_UNQUOTED($sym,$val)
2821           fi
2822         fi  ;;
2823       esac
2824     done
2825   fi
2826
2827   dnl make sure we can find Intrinsic.h
2828   AC_CHECK_HEADER(X11/Intrinsic.h, ,
2829    [AC_MSG_ERROR("Unable to find X11 header files.")])
2830
2831   dnl -lXt and -lX11 are required
2832   dnl Some broken systems require the magic "-b i486-linuxaout" flag
2833   AC_CHECK_LIB(X11, XOpenDisplay, have_lib_x11=yes)
2834   if test "$have_lib_x11" != "yes"; then
2835     AC_CHECK_LIB(X11, XGetFontProperty,
2836       ld_switch_x_site="-b i486-linuxaout $ld_switch_x_site",
2837       [AC_MSG_ERROR("Unable to find X11 libraries.")],
2838       -b i486-linuxaout)
2839   fi
2840   libs_x="-lX11"
2841   test "$extra_verbose" = "yes" && echo "    Setting libs_x to \"-lX11\""
2842
2843   dnl Autodetect -lXext
2844   AC_CHECK_LIB(Xext, XShapeSelectInput, XE_PREPEND(-lXext, libs_x))
2845
2846   dnl Require -lXt
2847   AC_CHECK_LIB(Xt, XtOpenDisplay, XE_PREPEND(-lXt, libs_x),
2848     AC_MSG_ERROR("Unable to find X11 libraries."))
2849
2850   AC_MSG_CHECKING(the version of X11 being used)
2851   AC_TRY_RUN([#include <X11/Intrinsic.h>
2852     int main(int c, char *v[]) { return c>1 ? XlibSpecificationRelease : 0; }],
2853     [./conftest foobar; x11_release=$?],[x11_release=4],[x11_release=4])
2854   AC_MSG_RESULT(R${x11_release})
2855   AC_DEFINE_UNQUOTED(THIS_IS_X11R${x11_release})
2856
2857   if test "${x11_release}" = "4"; then
2858     case "$with_widgets" in
2859       "" | "no") with_widgets=no ;;
2860       *) XE_DIE("Widget support requires X11R5 or greater") ;;
2861     esac
2862   fi
2863
2864   AC_CHECK_FUNCS(XConvertCase)
2865
2866   AC_CHECK_HEADERS(X11/Xlocale.h)
2867
2868   dnl XFree86 has a non-standard prototype for this X11R6 function
2869   AC_CHECK_FUNCS(XRegisterIMInstantiateCallback)
2870   AC_MSG_CHECKING(for standard XRegisterIMInstantiateCallback prototype)
2871   AC_TRY_COMPILE([
2872 #define NeedFunctionPrototypes 1
2873 #include <X11/Xlib.h>
2874 extern Bool XRegisterIMInstantiateCallback(
2875    Display*, struct _XrmHashBucketRec*, char*, char*, XIMProc, XPointer*);
2876 ], [],
2877   [AC_MSG_RESULT(yes)],
2878   [AC_MSG_RESULT(no)
2879    AC_DEFINE(XREGISTERIMINSTANTIATECALLBACK_NONSTANDARD_PROTOTYPE)])
2880
2881   dnl autodetect -lXmu
2882   test -z "$with_xmu" && { AC_CHECK_LIB(Xmu, XmuReadBitmapDataFromFile,
2883                            with_xmu=yes, with_xmu=no) }
2884   if test "$with_xmu" = "no"; then
2885     XE_ADD_OBJS(xmu.o)
2886   else
2887     XE_PREPEND(-lXmu, libs_x)
2888     AC_DEFINE(HAVE_XMU)
2889   fi
2890
2891   dnl Autodetect -lXbsd
2892   dnl #### Someone, please add a better function than main
2893   AC_CHECK_LIB(Xbsd, main, XE_PREPEND(-lXbsd, libs_x))
2894
2895   dnl Problem with the MIT distribution of X on AIX
2896   if test "$unexec" = "unexaix.o" -a "$x11_release" = "6"; then
2897     dnl X11R6 requires thread-safe code on AIX for some reason
2898     if test "$GCC" = "yes"; then
2899       XE_PREPEND(-mthreads, X_CFLAGS)
2900       XE_PREPEND(-mthreads, libs_x)
2901     else
2902       case "$CC" in
2903         "xlc" ) CC="xlc_r" ;;
2904         "xlC" ) CC="xlC_r" ;;
2905         "cc"  ) CC="cc_r" ;;
2906       esac
2907     fi
2908   fi
2909
2910 fi dnl $with_x11 = yes
2911
2912 if test "$with_msw" != "no"; then
2913   AC_CHECKING(for MS-Windows)
2914   AC_CHECK_LIB(gdi32,main,with_msw=yes)
2915   if test "$with_msw" = "yes"; then
2916     AC_DEFINE(HAVE_MS_WINDOWS)
2917
2918     dnl The net installer only works with MS-Windows currently
2919     if test "$with_netinstall" = "yes"; then
2920       XE_APPEND(netinstall, MAKE_SUBDIR)
2921       XE_APPEND(netinstall, SRC_SUBDIR_DEPS)
2922       XE_APPEND(netinstall, INSTALL_ARCH_DEP_SUBDIR)
2923     fi
2924
2925     install_pp="$blddir/lib-src/installexe.sh"
2926     XE_APPEND(-lshell32 -lgdi32 -luser32 -lcomdlg32 -lcomctl32 -lwinspool, libs_system)
2927     test "$with_dragndrop" != no && XE_APPEND(msw, dragndrop_proto)
2928     if test "$window_system" != x11; then
2929         window_system=msw
2930         test "$with_scrollbars" != "no" && with_scrollbars=msw \
2931             && XE_ADD_OBJS(scrollbar-msw.o)
2932         test "$with_menubars"   != "no" && with_menubars=msw \
2933             && XE_ADD_OBJS(menubar-msw.o)
2934         test "$with_toolbars"   != "no" && with_toolbars=msw \
2935             && XE_ADD_OBJS(toolbar-msw.o)
2936         test "$with_dialogs"   != "no" && with_dialogs=msw \
2937             && XE_ADD_OBJS(dialog-msw.o)
2938         test "$with_widgets"   != "no" && with_widgets=msw
2939     else
2940         test "$with_scrollbars" != "no" && XE_ADD_OBJS(scrollbar-msw.o)
2941         test "$with_menubars"   != "no" && XE_ADD_OBJS(menubar-msw.o)
2942         test "$with_toolbars"   != "no" && XE_ADD_OBJS(toolbar-msw.o)
2943         test "$with_dialogs"    != "no" && XE_ADD_OBJS(dialog-msw.o)
2944     fi
2945     dnl check for our special version of select
2946     AC_TRY_RUN([#include <fcntl.h>
2947     int main() { return (open("/dev/windows", O_RDONLY, 0) > 0)? 0 : 1; }],
2948     [need_event_unixoid=yes; AC_DEFINE(HAVE_MSG_SELECT)])
2949     with_file_coding=yes
2950     XE_ADD_OBJS(console-msw.o device-msw.o event-msw.o frame-msw.o objects-msw.o select-msw.o redisplay-msw.o glyphs-msw.o gui-msw.o)
2951   fi
2952 fi
2953
2954 AC_SUBST(install_pp)
2955
2956 test -z "$window_system" && window_system="none"
2957
2958 dnl Test for features that require a window system - ANY window system
2959 if test "$window_system" = "none"; then
2960   for feature in menubars scrollbars toolbars dialogs dragndrop xface
2961   do
2962     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2963        AC_MSG_WARN([--with-$feature ignored:  Not valid without window system support])
2964     fi
2965     eval "with_${feature}=no"
2966   done
2967 else
2968   test -z "$with_toolbars" && with_toolbars=yes
2969 fi
2970
2971 dnl ### Test for features that require mswindows support - currently none
2972 dnl ### MS-Windows folks: add code here..... (martin)
2973 if test "$with_msw" != "yes"; then
2974   for feature in   MARTIN_IS_CLUELESS_ABOUT_MSW_FEATURES
2975   do
2976     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2977        AC_MSG_WARN([--with-$feature ignored:  Not valid without MS-Windows support])
2978     fi
2979     eval "with_${feature}=no"
2980   done
2981 else
2982   :
2983 fi
2984
2985 dnl Test for features that require X11 support
2986 if test "$with_x11" != "yes"; then
2987   dnl It ought to be reasonable to have no output device at all, and only use
2988   dnl XEmacs in --batch mode.
2989   dnl if test "$with_tty" = "no" ; then
2990   dnl   AC_MSG_ERROR([No window system support and no TTY support - Unable to proceed.])
2991   dnl fi
2992   for feature in tooltalk cde offix wmcommand xim xmu nas_sound
2993   do
2994     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2995        AC_MSG_WARN([--with-$feature ignored:  Not valid without X support])
2996     fi
2997     eval "with_${feature}=no"
2998   done
2999 fi
3000
3001 dnl Balloon Help requires the Shape extension, not available everywhere,
3002 dnl for example not on AIX 4.3.
3003 if test "$with_x11" = "yes"; then
3004   AC_CHECK_HEADER(X11/extensions/shape.h, [
3005    AC_DEFINE(HAVE_BALLOON_HELP)
3006    XE_ADD_OBJS(balloon_help.o balloon-x.o)])
3007 fi
3008
3009 dnl FSF 19.29 has some bitmapdir stuff here.
3010 bitmapdir=
3011
3012 case "$window_system" in
3013   x11  ) HAVE_X_WINDOWS=yes; echo "  Using X11." ;;
3014   msw  ) HAVE_X_WINDOWS=no ; echo "  Using MS-Windows." ;;
3015   gtk  )
3016        HAVE_X_WINDOWS=no
3017        test "$with_gnome" = "yes" && echo "  Using GNOME."
3018        test "$with_gnome" = "no" && echo "  Using GTK."
3019        ;;
3020   none ) HAVE_X_WINDOWS=no ; echo "  Using no window system." ;;
3021 esac
3022
3023 case "$x_libraries" in *X11R4* )
3024   test "$opsys" = "hpux9"     && opsysfile="s/hpux9-x11r4.h"
3025   test "$opsys" = "hpux9-shr" && opsysfile="s/hpux9shxr4.h"
3026 esac
3027
3028 dnl Enable or disable proper handling of WM_COMMAND
3029 AC_CHECKING(for WM_COMMAND option);
3030 dnl if test "$with_wmcommand" = "yes"; then
3031 if test "$with_wmcommand" != "no"; then
3032   AC_DEFINE(HAVE_WMCOMMAND)
3033 fi
3034
3035 dnl Autodetect Xauth
3036 dnl -lXau is only used by gnuclient, so use a special variable for Xauth X libs
3037 test -z "$with_xauth" && test "$window_system" = "none" && with_xauth=no
3038 test -z "$with_xauth" && { AC_CHECK_HEADER(X11/Xauth.h,          ,with_xauth=no) }
3039 test -z "$with_xauth" && { AC_CHECK_LIB(Xau, XauGetAuthByAddr,[:],with_xauth=no) }
3040 test -z "$with_xauth" && with_xauth=yes
3041 if test "$with_xauth" = "yes"; then
3042   AC_DEFINE(HAVE_XAUTH)
3043   XE_SPACE(libs_xauth, $GTK_LIBS $X_EXTRA_LIBS -lXau $libs_x $X_PRE_LIBS)
3044 fi
3045 AC_SUBST(libs_xauth)
3046
3047 dnl This one is for the static initializeds variables in
3048 dnl offix.c, so that the thing is dumped after lastfile.o
3049 AC_SUBST(dnd_objs)
3050
3051 dnl Autodetect tooltalk
3052 if test "$with_tooltalk" != "no" ; then
3053   dnl autodetect the location of tt_c.h
3054   dnl tt_c.h might be in Tt or desktop include directories
3055   for dir in "" "Tt/" "desktop/" ; do
3056     AC_CHECK_HEADER(${dir}tt_c.h, tt_c_h_file="${dir}tt_c.h"; break)
3057   done
3058   if test -z "$tt_c_h_file"; then
3059     if test "$with_tooltalk" = "yes"; then
3060       USAGE_ERROR("Unable to find required tooltalk header files.")
3061     fi
3062     with_tooltalk=no
3063   fi
3064 fi
3065 if test "$with_tooltalk" != "no" ; then
3066   for extra_libs in "" "-lI18N -lce" "-lcxx"; do
3067     AC_CHECK_LIB(tt, tt_message_create,
3068       tt_libs="-ltt $extra_libs"; break, [:],$extra_libs)
3069   done
3070   if test -z "$tt_libs"; then
3071     if test "$with_tooltalk" = "yes"; then
3072       USAGE_ERROR("Unable to find required tooltalk libraries.")
3073     fi
3074     with_tooltalk=no
3075   fi
3076 fi
3077 test -z "$with_tooltalk" && with_tooltalk=yes
3078 if test "$with_tooltalk" = "yes"; then
3079   AC_DEFINE(TOOLTALK)
3080   AC_DEFINE_UNQUOTED(TT_C_H_FILE, "$tt_c_h_file")
3081   XE_PREPEND($tt_libs, libs_x)
3082   XE_ADD_OBJS(tooltalk.o)
3083 fi
3084
3085 dnl Autodetect CDE
3086 test -z "$with_cde" && { AC_CHECK_HEADER(Dt/Dt.h,               , with_cde=no) }
3087 test -z "$with_cde" && { AC_CHECK_LIB(DtSvc, DtDndDragStart, [:], with_cde=no) }
3088 test -z "$with_cde" && with_cde=yes
3089 if test "$with_dragndrop" = no; then
3090   AC_MSG_WARN([No CDE without generic Drag'n'Drop support])
3091   with_cde=no
3092 fi
3093 if test "$with_cde" = "yes" ; then
3094   AC_DEFINE(HAVE_CDE)
3095   XE_PREPEND(-lDtSvc, libs_x)
3096   XE_APPEND(CDE, dragndrop_proto)
3097   with_tooltalk=yes # CDE requires Tooltalk
3098   need_motif=yes    # CDE requires Motif
3099 fi
3100
3101 dnl Always compile OffiX unless --without-offix is given, no
3102 dnl X11 support is compiled in, no standard Xmu is available,
3103 dnl or dragndrop support is disabled
3104 dnl Because OffiX support currently loses when more than one display
3105 dnl is in use, we now disable it by default -slb 07/10/1998.
3106 test "$window_system" != "x11" && with_offix=no
3107 if test "$with_xmu" != yes -a "$with_x11" = yes; then
3108   AC_MSG_WARN([No OffiX without real Xmu support])
3109   with_offix=no
3110 fi
3111 if test "$with_dragndrop" = no; then
3112   AC_MSG_WARN([No OffiX without generic Drag'n'Drop support])
3113   with_offix=no
3114 fi
3115 if test "$with_cde" = yes; then
3116   AC_MSG_WARN([CDE already found, disabling OffiX support])
3117   with_offix=no
3118 fi
3119 test -z "$with_offix" && with_offix=no
3120 if test "$with_offix" = "yes"; then
3121   AC_DEFINE(HAVE_OFFIX_DND)
3122   XE_APPEND(offix.o, dnd_objs)
3123   XE_APPEND(OffiX, dragndrop_proto)
3124 fi
3125 if test "$with_gtk" = "yes"; then
3126    XE_APPEND(GTK, dragndrop_proto)
3127 fi
3128
3129 dnl Autodetect Drag'n'Drop support
3130 dnl always included if CDE, Offix, or MSWindows are defined
3131 if test "$with_dragndrop" != "no" ; then
3132   AC_MSG_CHECKING(if drag and drop API is needed)
3133   if test -n "$dragndrop_proto" ; then
3134     with_dragndrop=yes
3135     AC_MSG_RESULT([yes (${dragndrop_proto} )])
3136     AC_DEFINE(HAVE_DRAGNDROP)
3137     XE_APPEND(dragdrop.o, extra_objs)
3138   else
3139     with_dragndrop=no
3140     AC_MSG_RESULT(no)
3141   fi
3142 fi
3143
3144 dnl Autodetect LDAP
3145 AC_CHECKING(for LDAP)
3146 test -z "$with_ldap" && { AC_CHECK_HEADER(ldap.h, ,with_ldap=no) }
3147 test -z "$with_ldap" && { AC_CHECK_HEADER(lber.h, ,with_ldap=no) }
3148 if test "$with_ldap" != "no"; then
3149   AC_CHECK_LIB(ldap, ldap_search, with_ldap_nolber=yes, with_ldap_nolber=no)
3150   test "$with_ldap_nolber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_lber=yes, with_ldap_lber=no, -llber) }
3151   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krb=yes, with_ldap_krb=no, -llber -lkrb) }
3152   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" -a "$with_ldap_krb" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krbdes=yes, with_ldap_krbdes=no, -llber -lkrb -ldes) }
3153   test -z "$with_ldap" -a \( "$with_ldap_lber" = "yes" -o "$with_ldap_nolber" = "yes" -o "$with_ldap_krb" = "yes" -o "$with_ldap_krbdes" = "yes" \) && with_ldap=yes
3154 fi
3155 if test "$with_ldap" = "yes"; then
3156   AC_DEFINE(HAVE_LDAP)
3157   XE_ADD_OBJS(eldap.o)
3158   if test "$with_ldap_nolber" = "yes" ; then
3159     XE_PREPEND(-lldap, LIBS)
3160   else
3161     if test "$with_ldap_krb" = "yes" ; then
3162       XE_PREPEND(-lkrb, LIBS)
3163     fi
3164     if test "$with_ldap_krbdes" = "yes" ; then
3165       XE_PREPEND(-ldes, LIBS)
3166       XE_PREPEND(-lkrb, LIBS)
3167     fi
3168     XE_PREPEND(-llber, LIBS)
3169     XE_PREPEND(-lldap, LIBS)
3170   fi
3171   AC_CHECK_FUNCS(ldap_set_option ldap_get_lderrno ldap_result2error ldap_parse_result)
3172 fi
3173
3174 dnl Autodetect PostgreSQL
3175 dnl On many Linux systems, PostgreSQL is packaged to be installed in /usr;
3176 dnl in this case, configure will easily detect it there.
3177 dnl
3178 dnl If PostgreSQL is installed into a different prefix,
3179 dnl (such as the default /usr/local/pgsql when building from source),
3180 dnl that prefix must be specified using the --site-prefixes flag.
3181 if test "$with_postgresql" != "no"; then
3182   AC_CHECKING(for PostgreSQL)
3183
3184 dnl Look for these standard header file locations, known to be used on Linux
3185   for header_dir in "" "pgsql/" "postgresql/"; do
3186     AC_CHECK_HEADER(${header_dir}libpq-fe.h,
3187                     libpq_fe_h_file=${header_dir}libpq-fe.h; break)
3188   done
3189
3190   test -n "$libpq_fe_h_file" && { AC_CHECK_LIB(pq,PQconnectdb,have_libpq=yes) }
3191
3192   if test -n "$libpq_fe_h_file" -a "$have_libpq" = "yes"; then
3193     with_postgresql=yes
3194     AC_DEFINE(HAVE_POSTGRESQL)
3195     AC_CHECK_LIB(pq,PQconnectStart, [
3196                  with_postgresqlv7=yes;
3197                  AC_DEFINE(HAVE_POSTGRESQLV7)])
3198     AC_DEFINE_UNQUOTED(LIBPQ_FE_H_FILE, "$libpq_fe_h_file")
3199     XE_PREPEND(-lpq, LIBS)
3200     XE_ADD_OBJS(postgresql.o)
3201   elif test "$with_postgresql" = "yes"; then
3202     XE_DIE("Required PostgreSQL support cannot be provided.  Check --site-prefixes.")
3203   fi
3204 fi
3205
3206 dnl ----------------------
3207 dnl Graphics libraries
3208 dnl ----------------------
3209
3210 if test "$window_system" != "none"; then
3211   AC_CHECKING(for graphics libraries)
3212
3213   dnl add special code to handle xpm-nox on Cygwin (csw)
3214   dnl   -- should only happen if CYGWIN && WITH_XPM && WITH_MSW && !WITH_X
3215   libpath_xpm=
3216   incpath_xpm=
3217   case "$opsys" in
3218     cygwin*)
3219       cygwin_top=`eval "gcc -print-file-name=libc.a"` ;
3220       cygwin_top=`eval "dirname ${cygwin_top}"`;
3221       cygwin_top="${cygwin_top}/..";
3222       case "$window_system" in
3223         dnl use "standard" search pattern
3224         x11)  ;;
3225         dnl hardcode "standard" non-X11 xpm lib/inc dirs
3226         msw) libpath_xpm="-L${cygwin_top}/lib/noX"
3227              incpath_xpm="-I${cygwin_top}/include/noX"
3228               ;;
3229         dnl not supported on cygwin (yet?)
3230         gtk)  ;;
3231         dnl probably not reached...
3232         none) ;;
3233         dnl ditto
3234         *)    ;;
3235       esac
3236       ;;
3237     dnl use "standard" search pattern for all other OS's
3238     *) ;;
3239   esac
3240   dnl Autodetect Xpm
3241   xpm_problem=""
3242   if test -z "$with_xpm"; then
3243     XE_PREPEND("$incpath_xpm", CFLAGS)
3244     XE_PREPEND("$libpath_xpm", LDFLAGS)
3245     AC_MSG_CHECKING(for Xpm - no older than 3.4f)
3246     xe_check_libs=-lXpm
3247     AC_TRY_RUN([#define XPM_NUMBERS
3248 #include <X11/xpm.h>
3249     int main(int c, char **v) {
3250     return c == 1 ? 0 :
3251       XpmIncludeVersion != XpmLibraryVersion() ? 1 :
3252       XpmIncludeVersion < 30406 ? 2 : 0 ;}],
3253     [./conftest dummy_arg; xpm_status=$?;
3254       if test "$xpm_status" = "0"; then
3255         with_xpm=yes;
3256       else
3257         with_xpm=no;
3258         if test "$xpm_status" = "1"; then
3259           xpm_problem="Xpm library version and header file version don't match!"
3260         elif test "$xpm_status" = "2"; then
3261           xpm_problem="Xpm library version is too old!"
3262         else
3263           xpm_problem="Internal xpm detection logic error!"
3264         fi
3265         echo "
3266 *** WARNING *** $xpm_problem
3267   I'm not touching that with a 10-foot pole!
3268   If you really want to use the installed version of Xpm, rerun
3269   configure and add '--with-xpm=yes', but don't blame me if XEmacs crashes!"
3270     fi],
3271     [with_xpm=no])
3272     xe_check_libs=
3273     AC_MSG_RESULT($with_xpm)
3274   fi
3275   if test "$with_xpm" = "yes"; then
3276     dnl #### This code assumes that if AC_CHECK_LIB fails,
3277     dnl #### then it will succeed if FOR_MSW is defined,
3278     dnl #### but doesn't actually verify this assumption.
3279     AC_DEFINE(HAVE_XPM)
3280     XE_PREPEND("$libpath_xpm", LDFLAGS)
3281     XE_PREPEND(-lXpm, libs_x)
3282     XE_PREPEND("$incpath_xpm", CFLAGS)
3283     AC_MSG_CHECKING(for \"FOR_MSW\" xpm)
3284     xe_check_libs=-lXpm
3285     AC_TRY_LINK(, [XpmCreatePixmapFromData()],
3286     [xpm_for_msw=no],
3287     [xpm_for_msw=yes])
3288     xe_check_libs=
3289     AC_MSG_RESULT($xpm_for_msw)
3290     if test "$xpm_for_msw" = "yes"; then
3291       AC_DEFINE(FOR_MSW)
3292     fi
3293   fi
3294
3295   dnl Autodetect XFACE
3296   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
3297   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
3298   test -z "$with_xface" && with_xface=yes
3299   if test "$with_xface" = "yes"; then
3300     AC_DEFINE(HAVE_XFACE)
3301     XE_PREPEND(-lcompface, libs_x)
3302   fi
3303
3304   dnl For a brief period we had the GIF code split out into a separate library,
3305   dnl but patent problems, etc. sort of squashed that idea.
3306   dnl We default to building with builtin GIF decoding
3307   if test "$with_gif" != "no"; then
3308     with_gif="yes"
3309     AC_DEFINE(HAVE_GIF)
3310     XE_ADD_OBJS(dgif_lib.o gif_io.o)
3311   fi
3312
3313   dnl Too many stupid linkers can't detect cascaded lib dependencies until runtime
3314   dnl So we always search for libz compression support.
3315   if test "$with_png $with_tiff" != "no no"; then
3316     AC_CHECK_LIB(c,  inflate, [:], [
3317     AC_CHECK_LIB(z,  inflate, [XE_PREPEND(-lz,  libs_x)],[
3318     AC_CHECK_LIB(gz, inflate, [XE_PREPEND(-lgz, libs_x)])])])
3319   fi
3320
3321   dnl autodetect JPEG
3322   test -z "$with_jpeg" && { AC_CHECK_HEADER(jpeglib.h,                    ,with_jpeg=no) }
3323   test -z "$with_jpeg" && { AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,[:],with_jpeg=no) }
3324   test -z "$with_jpeg" && with_jpeg=yes
3325   if test "$with_jpeg" = "yes"; then
3326     AC_DEFINE(HAVE_JPEG)
3327     XE_PREPEND(-ljpeg, libs_x)
3328   fi
3329
3330   dnl autodetect PNG
3331   png_problem=""
3332   test -z "$with_png" && { AC_CHECK_FUNC(pow,                  ,with_png=no) }
3333   test -z "$with_png" && { AC_CHECK_HEADER(png.h,              ,with_png=no) }
3334   test -z "$with_png" && { AC_CHECK_LIB(png, png_read_image,[:],with_png=no) }
3335   if test -z "$with_png"; then
3336     AC_MSG_CHECKING(for workable png version information)
3337     xe_check_libs="-lpng -lz"
3338     AC_TRY_RUN([#include <png.h>
3339     int main(int c, char **v) {
3340     if (c == 1) return 0;
3341     if (strcmp(png_libpng_ver, PNG_LIBPNG_VER_STRING) != 0) return 1;
3342     return (PNG_LIBPNG_VER < 10002) ? 2 : 0 ;}],
3343     [./conftest dummy_arg; png_status=$?;
3344       if test "$png_status" = "0"; then
3345         with_png=yes;
3346       else
3347         with_png=no;
3348         if test "$png_status" = "1"; then
3349           png_problem="PNG library version and header file don't match!"
3350         elif test "$png_status" = "2"; then
3351           png_problem="PNG library version too old (pre 1.0.2)!"
3352         fi
3353         echo "
3354 *** WARNING *** $png_problem
3355   I'm not touching that with a 10-foot pole!
3356   If you really want to use the installed version of libPNG, rerun
3357   configure and add '--with-png=yes', but don't blame me if XEmacs crashes!"
3358     fi],
3359     [with_png=no])
3360     xe_check_libs=
3361     AC_MSG_RESULT($with_png)
3362   fi
3363   if test "$with_png" = "yes"; then
3364     AC_DEFINE(HAVE_PNG)
3365     XE_PREPEND(-lpng, libs_x)
3366   fi
3367
3368   dnl autodetect TIFF
3369   test -z "$with_tiff" && { AC_CHECK_HEADER(tiffio.h,            ,with_tiff=no) }
3370   test -z "$with_tiff" && { AC_CHECK_LIB(tiff, TIFFClientOpen,[:],with_tiff=no) }
3371   test -z "$with_tiff" && with_tiff=yes
3372   if test "$with_tiff" = "yes"; then
3373     AC_DEFINE(HAVE_TIFF)
3374     XE_PREPEND(-ltiff, libs_x)
3375   fi
3376 fi
3377
3378 dnl ----------------------
3379 dnl GTK-Specific Graphics libraries
3380 dnl ----------------------
3381
3382 if test "$with_gtk" = "yes"; then
3383   dnl Autodetect XFACE
3384   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
3385   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
3386   test -z "$with_xface" && with_xface=yes
3387   if test "$with_xface" = "yes"; then
3388     AC_DEFINE(HAVE_XFACE)
3389     XE_PREPEND(-lcompface, libs_gtk)
3390   fi
3391 fi
3392
3393
3394 dnl ----------------------
3395 dnl X-Specific Graphics libraries
3396 dnl ----------------------
3397
3398 if test "$with_x11" = "yes"; then
3399   AC_CHECKING(for X11 graphics libraries)
3400 fi
3401
3402 dnl We don't automatically trigger widgets if athena is present
3403 dnl because of stability concerns.
3404 dnl But if the user wants widgets, still offer him autodetections
3405 case "$with_widgets" in
3406   "yes" | "athena")             detect_athena=yes ;;
3407    *)                           detect_athena=no ;;
3408 esac
3409
3410 if test "$with_x11" = "yes" -a "$detect_athena" = "yes" ; then
3411   AC_CHECKING(for the Athena widgets)
3412
3413   dnl What in heck did the user actually want?
3414   case "$with_athena" in
3415     dnl This is the default, old fashioned flat Athena.
3416     "xaw" | "") athena_variant=Xaw      athena_3d=no  ;;
3417     "3d")       athena_variant=Xaw3d    athena_3d=yes ;;
3418     "next")     athena_variant=neXtaw   athena_3d=yes ;;
3419     "95")       athena_variant=Xaw95    athena_3d=yes ;;
3420     "xpm")      athena_variant=XawXpm   athena_3d=yes ;;
3421     *)          XE_DIE("Unknown Athena widget set \`$with_athena'. This should not happen.") ;;
3422   esac
3423
3424   dnl Search for the Athena library...
3425   if test "$athena_3d" = "no"; then
3426     AC_CHECK_LIB($athena_variant, XawScrollbarSetThumb,
3427       [
3428         dnl Must not be a 3d library...
3429         AC_CHECK_LIB($athena_variant, threeDClassRec,
3430           AC_MSG_WARN("Could not find a non-3d Athena widget library."),
3431           athena_lib=$athena_variant)
3432       ],
3433       AC_MSG_WARN("Could not find an Athena widget library."))
3434   else
3435     dnl The real configuration, need 3d library
3436     AC_CHECK_LIB($athena_variant, threeDClassRec, athena_lib=$athena_variant,
3437       dnl OK, couldn't find it with a proper name, try the standard Athena lib
3438       dnl If that is 3d, presume the user asked for what they have installed.
3439       AC_CHECK_LIB(Xaw, threeDClassRec,
3440         [
3441           athena_lib=Xaw;
3442           AC_MSG_WARN("Assuming that libXaw is actually $athena_variant.");
3443         ],
3444         AC_MSG_WARN("Could not find a 3d Athena widget library that looked like $athena_variant.")))
3445   fi
3446
3447   dnl Now we locate the Athena headers that we need.
3448   if test "$athena_3d" = "no"; then
3449     AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3450       AC_MSG_WARN("Could not find a non-3d Athena header set."),
3451       AC_CHECK_HEADER(X11/Xaw/XawInit.h,
3452         athena_h_path=X11/Xaw,
3453         AC_MSG_WARN("Could not find a non-3d Athena header set.")))
3454   else
3455     dnl The three-d Athena headers are so much more slippery.
3456     dnl Curse this `Lets replace standard libraries' thing that they did. :/
3457     AC_CHECK_HEADER(X11/$athena_variant/XawInit.h,
3458       AC_CHECK_HEADER(X11/$athena_variant/ThreeD.h,
3459         athena_h_path=X11/$athena_variant,))
3460
3461     dnl Is the variant specific header directory directly under include?
3462     if test -z "$athena_h_path"; then
3463       AC_CHECK_HEADER($athena_variant/XawInit.h,
3464         AC_CHECK_HEADER($athena_variant/ThreeD.h,
3465           athena_h_path=$athena_variant,))
3466     fi
3467
3468     dnl If we couldn't find the specific variant, try the generic Athena 3d headers
3469     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3470       AC_CHECK_HEADER(X11/Xaw3d/XawInit.h,
3471         AC_CHECK_HEADER(X11/Xaw3d/ThreeD.h,
3472           [
3473             AC_MSG_WARN("Assuming that X11/Xaw3d headers are suitable for $athena_variant.")
3474             athena_h_path=X11/Xaw3d
3475           ],))
3476     fi
3477
3478     dnl Also generic 3d headers directly under include dir
3479     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3480       AC_CHECK_HEADER(Xaw3d/XawInit.h,
3481         AC_CHECK_HEADER(Xaw3d/ThreeD.h,
3482           [
3483             AC_MSG_WARN("Assuming that Xaw3d headers are suitable for $athena_variant.")
3484             athena_h_path=Xaw3d
3485           ],))
3486     fi
3487
3488     dnl If nothing yet found, see if Xaw is a 3d header set...
3489     dnl We AC_MSG_WARN if we fail because I am all out of ideas...
3490     if test -z "$athena_h_path"; then
3491       AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3492         [
3493           AC_MSG_WARN("Assuming that X11/Xaw headers are suitable for $athena_variant.")
3494           athena_h_path=X11/Xaw
3495         ],
3496         AC_MSG_WARN("Could not find a suitable 3d Athena header set."))
3497     fi
3498   fi
3499
3500   dnl Do we actually have a usable Athena widget set? Please?
3501   if test -n "$athena_lib" -a -n "$athena_h_path"; then
3502     have_xaw=yes
3503   else
3504     have_xaw=no
3505   fi
3506
3507 else
3508   have_xaw=no
3509 fi dnl "$with_x11" = "yes" -a "detect_athena" = "yes"
3510
3511 if test "$with_x11" = "yes"; then
3512   dnl autodetect Motif - but only add to libs_x later (if necessary)
3513   AC_CHECK_HEADER(Xm/Xm.h,
3514    [AC_CHECK_LIB(Xm, XmStringFree, have_motif=yes, have_motif=no)],
3515    have_motif=no)
3516
3517   if test "$have_motif" = "yes"; then
3518     dnl autodetect lesstif
3519     AC_MSG_CHECKING(for Lesstif)
3520     AC_EGREP_CPP(yes,
3521 [#include <Xm/Xm.h>
3522 #ifdef LESSTIF_VERSION
3523 yes
3524 #endif
3525 ], have_lesstif=yes, have_lesstif=no)
3526   AC_MSG_RESULT($have_lesstif)
3527   fi
3528
3529 fi dnl "$with_x11" = "yes"
3530
3531 dnl Finish ensuring that we have values for the various toolkit items.
3532 dnl Not all toolkits support all widgets
3533 dnl if Motif is available we use it for the dialog boxes.
3534
3535 case "$with_menubars" in "" | "yes" | "athena" )
3536   with_menubars="lucid" ;;
3537 esac
3538 case "$with_dialogs" in "" | "yes" | "lucid" )
3539   if   test "$have_motif"     = "yes"; then with_dialogs="motif"
3540   elif test "$have_xaw"       = "yes"; then with_dialogs="athena"
3541   else with_dialogs=no
3542   fi ;;
3543 esac
3544 case "$with_scrollbars" in "" | "yes" )
3545   with_scrollbars="lucid" ;;
3546 esac
3547 case "$with_widgets" in "" | "yes" | "lucid")
3548   if   test "$have_motif" = "yes"; then with_widgets="motif"
3549   elif test "$have_xaw"   = "yes"; then with_widgets="athena"
3550   else with_widgets=no
3551   fi ;;
3552 esac
3553
3554 all_widgets="$with_menubars $with_scrollbars $with_dialogs $with_toolbars $with_widgets"
3555
3556 case "$all_widgets" in
3557   *athena* )
3558     if test "$have_xaw" != "yes"; then
3559       XE_DIE("Could not find a suitable Athena library to build with.")
3560     fi
3561
3562     dnl Add the Lucid widget Athena code
3563     XE_APPEND(lwlib-Xaw.o, lwlib_objs)
3564
3565     dnl Add the Athena widget library we located earlier
3566     XE_PREPEND(-l$athena_lib, libs_x)
3567
3568     dnl Tell lwlib where to find the Athena header files.
3569     dnl Many people have tried to create a `smart' way of doing this,
3570     dnl but all have failed.  Before changing the following ugly definitions,
3571     dnl consult the veterans of many a battle.
3572     AC_DEFINE_UNQUOTED(ATHENA_Scrollbar_h_,"$athena_h_path/Scrollbar.h")
3573     AC_DEFINE_UNQUOTED(ATHENA_Dialog_h_,"$athena_h_path/Dialog.h")
3574     AC_DEFINE_UNQUOTED(ATHENA_Form_h_,"$athena_h_path/Form.h")
3575     AC_DEFINE_UNQUOTED(ATHENA_Command_h_,"$athena_h_path/Command.h")
3576     AC_DEFINE_UNQUOTED(ATHENA_Label_h_,"$athena_h_path/Label.h")
3577     AC_DEFINE_UNQUOTED(ATHENA_LabelP_h_,"$athena_h_path/LabelP.h")
3578     AC_DEFINE_UNQUOTED(ATHENA_Toggle_h_,"$athena_h_path/Toggle.h")
3579     AC_DEFINE_UNQUOTED(ATHENA_ToggleP_h_,"$athena_h_path/ToggleP.h")
3580     AC_DEFINE_UNQUOTED(ATHENA_AsciiText_h_,"$athena_h_path/AsciiText.h")
3581     AC_DEFINE_UNQUOTED(ATHENA_XawInit_h_,"$athena_h_path/XawInit.h")
3582
3583     AC_DEFINE(LWLIB_USES_ATHENA)
3584     AC_DEFINE(NEED_ATHENA)
3585     need_athena="yes"
3586
3587     if test "$athena_3d" = "yes"; then
3588       AC_DEFINE(HAVE_ATHENA_3D)
3589     fi
3590   ;;
3591 esac
3592
3593 case "$all_widgets" in *motif* )
3594   AC_DEFINE(LWLIB_USES_MOTIF)
3595   AC_DEFINE(NEED_MOTIF)
3596   XE_APPEND(lwlib-Xm.o, lwlib_objs)
3597   need_motif=yes ;;
3598 esac
3599
3600 test "$with_menubars"   = "lucid" && XE_APPEND(xlwmenu.o, lwlib_objs)
3601 test "$with_menubars"   = "motif" && XE_APPEND(xlwmenu.o, lwlib_objs)
3602 test "$with_scrollbars" = "lucid" && XE_APPEND(xlwscrollbar.o, lwlib_objs)
3603 test "$with_widgets"   != "no" && test "$with_widgets" != "msw" && \
3604         XE_APPEND(xlwtabs.o xlwgcs.o, lwlib_objs)
3605 case "$with_widgets" in athena* )
3606         XE_APPEND(xlwradio.o xlwcheckbox.o xlwgauge.o, lwlib_objs);;
3607 esac
3608 case "$all_widgets" in *lucid* )
3609   AC_DEFINE(NEED_LUCID)
3610   XE_APPEND(lwlib-Xlw.o, lwlib_objs) ;;
3611 esac
3612
3613 AC_SUBST(lwlib_objs)
3614
3615 test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA)
3616 test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA)
3617
3618 if test "$athena_3d" = "yes"; then
3619   test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA3D)
3620   test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA3D)
3621 fi
3622
3623 case "$with_widgets" in athena* ) AC_DEFINE(LWLIB_WIDGETS_ATHENA);; esac
3624 test "$with_widgets" != "no" && test "$with_widgets" != "msw" && \
3625         AC_DEFINE(LWLIB_TABS_LUCID)
3626
3627 test "$with_menubars"   != "no"    && AC_DEFINE(HAVE_MENUBARS)
3628 test "$with_scrollbars" != "no"    && AC_DEFINE(HAVE_SCROLLBARS)
3629 test "$with_dialogs"    != "no"    && AC_DEFINE(HAVE_DIALOGS)
3630 test "$with_toolbars"   != "no"    && AC_DEFINE(HAVE_TOOLBARS)
3631 test "$with_widgets"    != "no"    && AC_DEFINE(HAVE_WIDGETS)
3632
3633 test "$with_menubars"   = "lucid"  && AC_DEFINE(LWLIB_MENUBARS_LUCID)
3634 test "$with_scrollbars" = "lucid"  && AC_DEFINE(LWLIB_SCROLLBARS_LUCID)
3635
3636 test "$with_menubars"   = "motif"  && AC_DEFINE(LWLIB_MENUBARS_MOTIF)
3637 test "$with_scrollbars" = "motif"  && AC_DEFINE(LWLIB_SCROLLBARS_MOTIF)
3638 test "$with_dialogs"    = "motif"  && AC_DEFINE(LWLIB_DIALOGS_MOTIF)
3639 test "$with_widgets"    = "motif"  && AC_DEFINE(LWLIB_WIDGETS_MOTIF)
3640
3641 test "$with_menubars"   != "no"    && XE_ADD_OBJS(menubar.o)
3642 test "$with_scrollbars" != "no"    && XE_ADD_OBJS(scrollbar.o)
3643 test "$with_dialogs"    != "no"    && XE_ADD_OBJS(dialog.o)
3644 test "$with_toolbars"   != "no"    && XE_ADD_OBJS(toolbar.o)
3645
3646 if test "$with_gtk" = "yes"; then
3647   test "$with_menubars"   != "no"      && XE_ADD_OBJS(menubar-gtk.o)
3648   test "$with_scrollbars" != "no"      && XE_ADD_OBJS(scrollbar-gtk.o)
3649   test "$with_dialogs"    != "no"      && XE_ADD_OBJS(dialog-gtk.o)
3650   test "$with_toolbars"   != "no"      && XE_ADD_OBJS(toolbar-gtk.o)
3651   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-gtk.o)
3652 fi
3653
3654 if test "$with_x11" = "yes"; then
3655   test "$with_menubars"   != "no"  && XE_ADD_OBJS(menubar-x.o)
3656   test "$with_scrollbars" != "no"  && XE_ADD_OBJS(scrollbar-x.o)
3657   test "$with_dialogs"    != "no"  && XE_ADD_OBJS(dialog-x.o)
3658   test "$with_toolbars"   != "no"  && XE_ADD_OBJS(toolbar-x.o)
3659   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-x.o)
3660 fi
3661
3662 dnl ----------------------
3663 dnl Mule-dependent options
3664 dnl ----------------------
3665
3666 test -z "$with_mule" && with_mule=no
3667 test -z "$with_file_coding" && with_file_coding=no
3668
3669 dnl if test "$with_mule" = "yes" && test ! -d "$srcdir/lisp/mule"; then
3670 dnl     echo "Attempt to Build with Mule without Mule/Lisp"
3671 dnl     echo "Please install the XEmacs/Mule tarball or"
3672 dnl     echo "rerun configure with --with-mule=no"
3673 dnl     exit 1
3674 dnl fi
3675
3676 if test "$with_file_coding" = "yes" && test "$with_mule" = "no"; then
3677   AC_DEFINE(FILE_CODING)
3678   XE_ADD_OBJS(file-coding.o)
3679 fi
3680
3681 if test "$with_mule" = "yes" ; then
3682   AC_CHECKING(for Mule-related features)
3683   AC_DEFINE(MULE)
3684   AC_DEFINE(FILE_CODING)
3685   XE_ADD_OBJS(mule.o mule-ccl.o mule-charset.o)
3686   if test "$with_utf_2000" = "yes" && test "$with_text_coding" = "yes"; then
3687     AC_DEFINE(TEXT_CODING)
3688     XE_ADD_OBJS(text-coding.o)
3689   else
3690     XE_ADD_OBJS(file-coding.o)
3691   fi
3692   dnl Use -lintl to get internationalized strerror for Mule
3693   AC_CHECK_HEADERS(libintl.h)
3694   AC_CHECK_LIB(intl, strerror)
3695
3696   if test "$with_utf_2000" = "yes" ; then
3697     AC_DEFINE(CHAR_IS_UCS4)
3698     AC_DEFINE(UTF2000)
3699   fi
3700
3701   AC_CHECKING(for Mule input methods)
3702   dnl Do we have the XmIm* routines?  And if so, do we want to use them?
3703   dnl XIM seems to be flaky except on Solaris...
3704   dnl test -z "$with_xim" -a "$opsys" != "sol2" && with_xim=no
3705   case "$with_xim" in "" | "yes" )
3706     AC_CHECKING(for XIM)
3707     AC_CHECK_LIB(X11, XOpenIM, with_xim=xlib, with_xim=no)
3708     dnl XIM + Lesstif is not (yet?) usable
3709     if test "$have_motif $have_lesstif" = "yes no"; then
3710       AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif)
3711     fi ;;
3712   esac
3713   if test "$with_xim" != "no"; then
3714     AC_DEFINE(HAVE_XIM)
3715     if test "$with_xim" = "xlib"; then
3716       AC_DEFINE(XIM_XLIB)
3717       XE_ADD_OBJS(input-method-xlib.o)
3718     fi
3719     if test "$with_xim" = "motif"; then
3720       AC_DEFINE(XIM_MOTIF)
3721       need_motif=yes
3722       XE_ADD_OBJS(input-method-motif.o)
3723     fi
3724     if test "$with_xim" = "motif"; then
3725       with_xfs=no
3726     fi
3727   fi
3728
3729   dnl "with_xfs" = "yes"
3730   if test "$with_xfs" = "yes" ; then
3731     AC_CHECKING(for XFontSet)
3732     AC_CHECK_LIB(X11, XmbDrawString, [:], with_xfs=no)
3733     if test "$with_xfs" = "yes" && test "$with_menubars" = "lucid"; then
3734       AC_DEFINE(USE_XFONTSET)
3735       if test "$with_xim" = "no" ; then
3736         XE_ADD_OBJS(input-method-xlib.o)
3737       fi
3738     fi
3739   fi dnl with_xfs
3740
3741   dnl Autodetect WNN
3742   test "$with_wnn6" = "yes" && with_wnn=yes # wnn6 implies wnn support
3743   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/jllib.h, ,with_wnn=no) }
3744   dnl gcc 2.97 fixincludes breaks inclusion of wnn/commonhd.h
3745   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/commonhd.h, ,with_wnn=no) }
3746   dnl Detour to find crypt
3747   if test "$with_wnn" != "no"; then
3748     AC_CHECK_FUNCS(crypt)
3749     test "$ac_cv_func_crypt" != "yes" && { AC_CHECK_LIB(crypt, crypt) }
3750   fi
3751   dnl Back to our regularly scheduled wnn hunting
3752   if test -z "$with_wnn" -o "$with_wnn" = "yes"; then
3753     AC_CHECK_LIB(wnn,jl_dic_list_e,libwnn=wnn,
3754       AC_CHECK_LIB(wnn4,jl_dic_list_e,libwnn=wnn4,
3755         AC_CHECK_LIB(wnn6,jl_dic_list_e,libwnn=wnn6,
3756           AC_CHECK_LIB(wnn6_fromsrc,dic_list_e,libwnn=wnn6_fromsrc,with_wnn=no))))
3757   fi
3758   test -z "$with_wnn" && with_wnn=yes
3759   if test "$with_wnn" = "yes"; then
3760     AC_DEFINE(HAVE_WNN)
3761     XE_PREPEND(-l$libwnn, libs_x)
3762     XE_ADD_OBJS(mule-wnnfns.o)
3763     if test "$with_wnn6" != "no"; then
3764       AC_CHECK_LIB($libwnn, jl_fi_dic_list, with_wnn6=yes)
3765       test "$with_wnn6" = "yes" && AC_DEFINE(WNN6)
3766     fi
3767   fi
3768
3769   dnl Autodetect canna
3770   canna_includes_found=no
3771   if test "$with_canna" != "no"; then
3772     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3773   fi
3774   if test "$canna_includes_found" = "no" -a "$with_canna" != "no" -a \
3775       -d "/usr/local/canna/include"; then
3776     save_c_switch_site="$c_switch_site"
3777     c_switch_site="$c_switch_site -I/usr/local/canna/include"
3778     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3779     if test "$canna_includes_found" != "yes"; then
3780       c_switch_site="$save_c_switch_site"
3781       with_canna="no"
3782     fi
3783   fi
3784
3785   test -z "$with_canna" && { AC_CHECK_HEADER(canna/RK.h,         , with_canna=no) }
3786   test -z "$with_canna" && { AC_CHECK_LIB(RKC, RkBgnBun,       [:],with_canna=no) }
3787   test -z "$with_canna" && { AC_CHECK_LIB(canna,jrKanjiControl,[:],with_canna=no) }
3788   test -z "$with_canna" && with_canna=yes
3789   if test "$with_canna" = "yes"; then
3790     AC_DEFINE(HAVE_CANNA)
3791     XE_PREPEND(-lcanna -lRKC, libs_x)
3792     XE_ADD_OBJS(mule-canna.o)
3793   fi
3794
3795 else dnl "$with_mule" = "no"
3796   for feature in xim canna wnn; do
3797     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3798       AC_MSG_WARN("--with-${feature} ignored:  Not valid without Mule support")
3799     fi
3800     eval "with_${feature}=no"
3801   done
3802 fi dnl with_mule
3803
3804
3805 dnl At this point, we know whether we need the motif lib or not.
3806 if test "$need_motif" = "yes" ; then
3807   XE_PREPEND(-lXm, libs_x)
3808   dnl AIX needs the following library for use with Motif
3809   AC_CHECK_LIB(i18n, layout_object_getvalue, [XE_PREPEND(-li18n, libs_x)])
3810   XE_COMPUTE_RUNPATH()
3811 fi
3812
3813 AC_CHECK_FUNCS(cbrt closedir dup2 eaccess fmod fpathconf frexp ftime getaddrinfo gethostname getnameinfo getpagesize gettimeofday getcwd getwd logb lrand48 matherr mkdir mktime perror poll random rename res_init rint rmdir select setitimer setpgid setlocale setsid sigblock sighold sigprocmask snprintf stpcpy strerror tzset ulimit usleep waitpid vsnprintf fsync ftruncate umask)
3814
3815 dnl ----------------------------------------------------------------
3816 dnl Check for PTY support functions.
3817 dnl ----------------------------------------------------------------
3818
3819 dnl There is no "standard" pty allocation method.  Every system is different.
3820 dnl  getpt()  is the preferred pty allocation method on glibc systems.
3821 dnl _getpty() is the preferred pty allocation method on SGI systems.
3822 dnl grantpt(), unlockpt(), ptsname() are defined by Unix98.
3823 AC_CHECK_FUNCS(getpt _getpty grantpt unlockpt ptsname killpg tcgetpgrp)
3824
3825 dnl openpty() is the preferred pty allocation method on BSD and Tru64 systems.
3826 dnl openpty() might be declared in:
3827 dnl - pty.h (Tru64 or Linux)
3828 dnl - libutil.h (FreeBSD)
3829 dnl - util.h (NetBSD)
3830 AC_CHECK_FUNC(openpty, have_openpty=yes, [
3831   AC_CHECK_LIB(util, openpty, have_openpty=yes need_libutil=yes)])
3832 if test "$have_openpty" = "yes"; then
3833   AC_DEFINE(HAVE_OPENPTY)
3834   AC_CHECK_HEADERS(pty.h libutil.h util.h, break)
3835   test "$need_libutil" = "yes" && XE_APPEND(-lutil, libs_system)
3836 fi
3837
3838 dnl Check for STREAM support functions.
3839 dnl Confusingly, "str" means both "string" and "SysV Streams".
3840 AC_CHECK_HEADERS(stropts.h)
3841 if test "$ac_cv_header_stropts_h" = "yes"; then
3842   AC_CHECK_FUNCS(isastream)
3843   AC_CHECK_HEADERS(strtio.h) dnl TIOCSIGNAL
3844 fi
3845
3846 dnl Use our own realpath always.
3847 XE_ADD_OBJS(realpath.o)
3848
3849 dnl Check whether the system provides getloadavg().
3850 AC_CHECK_FUNCS(getloadavg)
3851
3852 if test "$ac_cv_func_getloadavg" = "yes"; then
3853   dnl Solaris 8 declares getloadavg() in <sys/loadavg.h>.
3854   dnl glibc 2.2 declares getloadavg() in <stdlib.h>...
3855   dnl   ...if we #define _GNU_SOURCE, which we do.
3856   AC_CHECK_HEADERS(sys/loadavg.h)
3857 else
3858   dnl We define our own getloadavg() using lower level functions.
3859   XE_ADD_OBJS(getloadavg.o)
3860
3861   dnl Used by getloadavg() - does not require root priveleges
3862   AC_CHECK_LIB(kstat, kstat_open)
3863   AC_CHECK_HEADERS(kstat.h)
3864
3865   dnl Another way to get the load average
3866   AC_CHECK_LIB(kvm, kvm_read)
3867 fi
3868
3869 dnl If netdb.h does not declare h_errno, we must declare it by hand.
3870 AC_MSG_CHECKING(whether netdb declares h_errno)
3871 AC_TRY_LINK([#include <netdb.h>],
3872   [return h_errno;],
3873   [AC_MSG_RESULT(yes)
3874    AC_DEFINE(HAVE_H_ERRNO)],
3875   [AC_MSG_RESULT(no)])
3876
3877 AC_MSG_CHECKING(for sigsetjmp)
3878 AC_TRY_COMPILE([#include <setjmp.h>],
3879         [sigjmp_buf bar; sigsetjmp (bar, 0);],
3880   [AC_MSG_RESULT(yes)
3881    AC_DEFINE(HAVE_SIGSETJMP)],
3882   [AC_MSG_RESULT(no)])
3883
3884 AC_MSG_CHECKING(whether localtime caches TZ)
3885 AC_CACHE_VAL(emacs_cv_localtime_cache,
3886 [if test "$ac_cv_func_tzset" = "yes"; then
3887 AC_TRY_RUN([#include <time.h>
3888 #if STDC_HEADERS
3889 # include <stdlib.h>
3890 #endif
3891 extern char **environ;
3892 unset_TZ ()
3893 {
3894   char **from, **to;
3895   for (to = from = environ; (*to = *from); from++)
3896     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
3897       to++;
3898 }
3899 char TZ_GMT0[] = "TZ=GMT0";
3900 char TZ_PST8[] = "TZ=PST8";
3901 main()
3902 {
3903   time_t now = time ((time_t *) 0);
3904   int hour_GMT0, hour_unset;
3905   if (putenv (TZ_GMT0) != 0)
3906     exit (1);
3907   hour_GMT0 = localtime (&now)->tm_hour;
3908   unset_TZ ();
3909   hour_unset = localtime (&now)->tm_hour;
3910   if (putenv (TZ_PST8) != 0)
3911     exit (1);
3912   if (localtime (&now)->tm_hour == hour_GMT0)
3913     exit (1);
3914   unset_TZ ();
3915   if (localtime (&now)->tm_hour != hour_unset)
3916     exit (1);
3917   exit (0);
3918 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3919 [# If we have tzset, assume the worst when cross-compiling.
3920 emacs_cv_localtime_cache=yes])
3921 else
3922         # If we lack tzset, report that localtime does not cache TZ,
3923         # since we can't invalidate the cache if we don't have tzset.
3924         emacs_cv_localtime_cache=no
3925 fi],[:])dnl
3926 AC_MSG_RESULT($emacs_cv_localtime_cache)
3927 if test $emacs_cv_localtime_cache = yes; then
3928   AC_DEFINE(LOCALTIME_CACHE)
3929 fi
3930
3931 if test "$HAVE_TIMEVAL" = "yes"; then
3932 AC_MSG_CHECKING(whether gettimeofday accepts one or two arguments)
3933 AC_TRY_LINK([
3934 #ifdef TIME_WITH_SYS_TIME
3935 #include <sys/time.h>
3936 #include <time.h>
3937 #else
3938 #ifdef HAVE_SYS_TIME_H
3939 #include <sys/time.h>
3940 #else
3941 #include <time.h>
3942 #endif
3943 #endif
3944   ],
3945   [
3946   struct timeval time;
3947   gettimeofday (&time, 0);
3948 ],
3949   [AC_MSG_RESULT(two)],
3950   [AC_MSG_RESULT(one)
3951    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
3952 fi
3953
3954
3955 AC_C_INLINE
3956 test "$ac_cv_c_inline" != "no" -a "$GCC" = "yes" && XE_ADD_OBJS(inline.o)
3957
3958 dnl HP-UX has a working alloca in libPW.
3959 dnl case "${GCC}${opsys}" in hpux* )
3960 dnl  AC_CHECK_FUNC(alloca, [:], [AC_CHECK_LIB(PW, alloca)])
3961 dnl esac
3962
3963 dnl AC_FUNC_ALLOCA doesn't know about DEC C's #pragma intrinsic(alloca)
3964 if test "$__DECC" != "yes"; then
3965   AC_FUNC_ALLOCA
3966   test -n "$ALLOCA" && XE_ADD_OBJS($ALLOCA)
3967 fi
3968
3969 dnl Check whether vfork exists and works correctly. (This does more
3970 dnl than just check for its existence.) If so, it defines HAVE_VFORK_H.
3971 dnl If not, it defines vfork to be fork.
3972 AC_FUNC_VFORK
3973
3974 dnl Check whether strcoll exists and works correctly. (This does more
3975 dnl than just check for its existence.) If so, it defines HAVE_STRCOLL.
3976 AC_FUNC_STRCOLL
3977
3978 dnl If `getpgrp' takes no argument (the POSIX.1 version), define
3979 dnl `GETPGRP_VOID'.  Otherwise, it is the BSD version, which takes a
3980 dnl process ID as an argument.
3981 AC_CHECK_FUNCS(getpgrp)
3982 AC_FUNC_GETPGRP
3983
3984 dnl We used to call AC_FUNC_MMAP here
3985 dnl Instead we now use following, suggested by Neal Becker
3986 AC_MSG_CHECKING(for working mmap)
3987 case "$opsys" in ultrix* ) have_mmap=no ;; *)
3988 AC_TRY_RUN([#include <stdio.h>
3989 #include <unistd.h>
3990 #include <fcntl.h>
3991 #include <sys/mman.h>
3992
3993 #ifndef MAP_VARIABLE
3994 #define MAP_VARIABLE 0
3995 #endif
3996
3997 #ifndef MAP_FAILED
3998 #define MAP_FAILED -1
3999 #endif
4000
4001 int main (int argc, char *argv[])
4002 {
4003   int fd = -1;
4004   caddr_t p;
4005 #ifndef MAP_ANONYMOUS
4006   fd = open ("/dev/zero", O_RDWR);
4007   if (fd < 0)
4008     return 1;
4009 #define MAP_ANONYMOUS 0
4010 #endif
4011   if (mmap(0, 1024, PROT_READ | PROT_WRITE,
4012            MAP_PRIVATE | MAP_VARIABLE | MAP_ANONYMOUS,
4013            fd, 0) != (void *) MAP_FAILED)
4014     return 0;
4015   perror ("conftest: mmap failed");
4016   return 1;
4017 }], have_mmap=yes, have_mmap=no) ;;
4018 esac
4019 AC_MSG_RESULT($have_mmap)
4020 test "$have_mmap" = "yes" && AC_DEFINE(HAVE_MMAP)
4021
4022 dnl By default we switch off rel-alloc on cygwin as it generally causes us grief
4023 case "$opsys" in cygwin*)
4024         test "$rel_alloc" = "default" && rel_alloc=no ;;
4025 esac
4026 dnl rel_alloc requires either GNU malloc or system malloc with mmap
4027 dnl We only turn rel_alloc on by default if mmap is available.
4028 test "$GNU_MALLOC" != "yes" -a "$have_mmap" != "yes" && rel_alloc=no
4029 if test "$rel_alloc $have_mmap" = "default yes"; then
4030   if test "$doug_lea_malloc" = "yes"; then
4031     dnl Check if malloc() calls mmap(), making rel_alloc pointless.
4032     AC_MSG_CHECKING(for M_MMAP_THRESHOLD)
4033     AC_TRY_COMPILE([#include <malloc.h>],[
4034 #ifndef M_MMAP_THRESHOLD
4035 #error No M_MMAP_THRESHOLD :-(
4036 !@+$%^&*_)(_ - unlikely to compile...
4037 #endif
4038 ], [rel_alloc=no; AC_MSG_RESULT(yes);], [rel_alloc=yes; AC_MSG_RESULT(no);])
4039   else
4040     rel_alloc=yes
4041   fi
4042 fi
4043 test "$rel_alloc" = "yes" && AC_DEFINE(REL_ALLOC)
4044
4045 dnl Check for terminal I/O variants
4046 dnl TERMIOS systems may have termio.h, but not vice-versa, I think.
4047 AC_CHECK_HEADER(termios.h,
4048   AC_DEFINE(HAVE_TERMIOS)
4049   AC_DEFINE(SIGNALS_VIA_CHARACTERS)
4050   AC_DEFINE(NO_TERMIO),
4051   [AC_CHECK_HEADER(termio.h, [AC_DEFINE(HAVE_TERMIO)])])
4052
4053
4054 dnl Check for Internet sockets.
4055 AC_CHECK_FUNC(socket,
4056  [AC_CHECK_HEADER(netinet/in.h,
4057    [AC_CHECK_HEADER(arpa/inet.h, [
4058   AC_DEFINE(HAVE_SOCKETS)
4059       AC_MSG_CHECKING("for sun_len member in struct sockaddr_un")
4060       AC_TRY_LINK([
4061 #include <sys/types.h>
4062 #include <sys/socket.h>
4063 #include <sys/un.h>
4064       ],
4065       [static struct sockaddr_un x; x.sun_len = 1;],
4066       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)],
4067       [AC_MSG_RESULT(no)])
4068       AC_MSG_CHECKING("for ip_mreq struct in netinet/in.h")
4069       AC_TRY_LINK([
4070 #include <sys/types.h>
4071 #include <netinet/in.h>
4072       ],
4073       [static struct ip_mreq x;],
4074       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MULTICAST)],
4075       [AC_MSG_RESULT(no)])])])])
4076
4077 dnl Check for SYS V IPC. (Inferior to sockets.)
4078 AC_CHECK_FUNC(msgget,
4079   [AC_CHECK_HEADER(sys/ipc.h,
4080     [AC_CHECK_HEADER(sys/msg.h,
4081       [AC_DEFINE(HAVE_SYSVIPC)])])])
4082
4083 dnl Check for directory variants
4084 AC_CHECK_HEADER(dirent.h, [AC_DEFINE(SYSV_SYSTEM_DIR)],
4085   [AC_CHECK_HEADER(sys/dir.h, , [AC_DEFINE(NONSYSTEM_DIR_LIBRARY)])])
4086
4087 dnl Check for nlist.h
4088 AC_CHECK_HEADER(nlist.h, AC_DEFINE(NLIST_STRUCT), )
4089
4090 dnl Check for sound of various sorts.
4091
4092 dnl Autodetect native sound
4093 AC_CHECKING("for sound support")
4094 test -z "$with_native_sound" -a -n "$native_sound_lib" && with_native_sound=yes
4095
4096 if test "$with_native_sound" != "no"; then
4097   dnl Maybe sound is already on include path...
4098   if test -n "$native_sound_lib"; then
4099     AC_CHECK_HEADER(multimedia/audio_device.h,
4100       [sound_found=yes sound_cflags=""
4101       XE_ADD_OBJS(sunplay.o)])
4102   fi
4103
4104   dnl Autodetect Sun native sound from SUNWaudmo package
4105   if test -z "$sound_found" -a -d "/usr/demo/SOUND"; then
4106     sound_found=yes
4107     XE_ADD_OBJS(sunplay.o)
4108     if test -d "/usr/demo/SOUND/include"
4109       then sound_cflags="-I/usr/demo/SOUND/include"
4110       else sound_cflags="-I/usr/demo/SOUND"
4111     fi
4112     if test -z "$native_sound_lib" ; then
4113       if test -r "/usr/demo/SOUND/lib/libaudio.a"
4114         then native_sound_lib="/usr/demo/SOUND/lib/libaudio.a"
4115         else native_sound_lib="/usr/demo/SOUND/libaudio.a"
4116       fi
4117     fi
4118   fi
4119
4120   dnl Check for SGI and HP native sound libs
4121   if test -z "$sound_found"; then
4122     case "$canonical" in
4123     *-sgi-* )
4124       if test -z "$native_sound_lib"; then
4125         AC_CHECK_LIB(audio, ALopenport, native_sound_lib="-laudio")
4126       fi
4127       if test -n "$native_sound_lib"; then
4128         sound_found=yes sound_cflags=""
4129         XE_ADD_OBJS(sgiplay.o)
4130       fi ;;
4131     hppa*-hp-hpux* )
4132       if test -z "$native_sound_lib"; then
4133         AC_CHECK_LIB(Alib, AOpenAudio, native_sound_lib="-lAlib")
4134       fi
4135       if test -n "$native_sound_lib"; then
4136         sound_found=yes
4137         XE_ADD_OBJS(hpplay.o)
4138         if test "$GCC" = "yes" # Kludge city
4139           then sound_cflags="-Dconst= -Dvolatile= -I/usr/audio/examples"
4140           else sound_cflags="+e -I/usr/audio/examples"
4141         fi
4142       fi ;;
4143     esac
4144   fi
4145
4146   dnl Win32 Native uses native sound
4147   if test -z "$sound_found"; then
4148     if test "$with_msw" = "yes"; then
4149     sound_found=yes
4150     native_sound_lib=
4151     fi
4152   fi
4153
4154   dnl Check for Linux/BSD native sound
4155   if test -z "$sound_found"; then
4156     for dir in "machine" "sys" "linux"; do
4157       AC_CHECK_HEADER(${dir}/soundcard.h,
4158         sound_found=yes
4159        need_miscplay=yes
4160         XE_ADD_OBJS(linuxplay.o)
4161         [AC_DEFINE_UNQUOTED(SOUNDCARD_H_FILE, "${dir}/soundcard.h")]
4162         break)
4163     done
4164   fi
4165
4166   test "$sound_found" = "yes" && with_native_sound=yes
4167 fi
4168
4169 if test "$with_native_sound" = "yes"; then
4170   AC_DEFINE(HAVE_NATIVE_SOUND)
4171   test -n "$native_sound_lib" && XE_PREPEND($native_sound_lib, LIBS)
4172 fi
4173
4174 dnl NAS Sound support
4175 if test "$with_nas_sound" != "no"; then
4176   AC_CHECK_HEADER(audio/audiolib.h, [
4177     AC_CHECK_LIB(audio, AuOpenServer, have_nas_sound=yes)])
4178   if test "$have_nas_sound" = "yes"; then
4179     with_nas_sound=yes
4180     AC_DEFINE(HAVE_NAS_SOUND)
4181     XE_ADD_OBJS(nas.o)
4182     XE_PREPEND(-laudio, libs_x)
4183     dnl If the nas library does not contain the error jump point,
4184     dnl then we force safer behavior.
4185     AC_EGREP_HEADER(AuXtErrorJump,audio/Xtutil.h,,[old_nas=yes; AC_DEFINE(NAS_NO_ERROR_JUMP)])
4186   else
4187     test "$with_nas_sound" = "yes" && \
4188       XE_DIE("Required NAS sound support cannot be provided.")
4189     with_nas_sound=no
4190   fi
4191 fi
4192
4193 dnl ESD Sound support
4194 if test "$with_esd_sound" != "no"; then
4195   AC_CHECK_PROG(have_esd_config, esd-config, yes, no)
4196   if test "$have_esd_config" = "yes"; then
4197     save_c_switch_site="$c_switch_site" save_LIBS="$LIBS"
4198     XE_APPEND(`esd-config --cflags`, c_switch_site)
4199     XE_PREPEND(`esd-config --libs`, LIBS)
4200     AC_CHECK_FUNC(esd_play_stream,
4201       have_esd_sound=yes,
4202       c_switch_site="$save_c_switch_site" LIBS="$save_LIBS")
4203   fi
4204
4205   if test "$have_esd_sound" = "yes"; then
4206     with_esd_sound=yes
4207     need_miscplay=yes
4208     XE_ADD_OBJS(esd.o)
4209     AC_DEFINE(HAVE_ESD_SOUND)
4210   else
4211     test "$with_esd_sound" = "yes" && \
4212       XE_DIE("Required ESD sound support cannot be provided.")
4213     with_esd_sound=no
4214   fi
4215 fi
4216
4217 test "$need_miscplay" = "yes" && XE_ADD_OBJS(miscplay.o)
4218
4219 dnl ---------------------
4220 dnl TTY-dependent options
4221 dnl ---------------------
4222
4223 test -z "$with_tty" && with_tty=yes
4224
4225 if test "$with_tty" = "yes"  ; then
4226   AC_CHECKING(for TTY-related features)
4227   AC_DEFINE(HAVE_TTY)
4228   XE_ADD_OBJS(console-tty.o device-tty.o event-tty.o frame-tty.o objects-tty.o redisplay-tty.o cm.o)
4229
4230   dnl Autodetect ncurses.
4231   if test -z "$with_ncurses"; then
4232     AC_CHECK_LIB(ncurses, tgetent, with_ncurses=yes, with_ncurses=no)
4233   fi
4234   if test "$with_ncurses" = "yes"; then
4235     AC_DEFINE(HAVE_NCURSES)
4236     AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
4237     AC_CHECK_HEADER(ncurses/term.h, term_h_file=ncurses/term.h)
4238     XE_ADD_OBJS(terminfo.o)
4239     XE_PREPEND(-lncurses, LIBS)
4240
4241     if test "$ac_cv_header_ncurses_curses_h" != "yes" ; then
4242       dnl Try again, and check for the bogus ncurses/ include bug.
4243       dnl (i.e. ncurses/curses.h bogusly includes <unctrl.h> instead of
4244       dnl <ncurses/unctrl.h>)
4245       save_c_switch_site="$c_switch_site"
4246       c_switch_site="$c_switch_site -I/usr/include/ncurses"
4247       AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
4248       if test "$ac_cv_header_ncurses_curses_h" = "yes"
4249         then AC_MSG_WARN("Your system has the bogus ncurses include bug.")
4250         else c_switch_site="$save_c_switch_site"
4251       fi
4252     fi
4253   else dnl "$with_ncurses" = "no"
4254     dnl Autodetect terminfo/-lcurses/-ltermlib/-ltermcap
4255     if test "$have_terminfo" = "yes"; then
4256       XE_ADD_OBJS(terminfo.o)
4257       if test -n "$libs_termcap"; then
4258         XE_PREPEND($libs_termcap, LIBS)
4259       else
4260         for lib in curses termlib termcap; do
4261           AC_CHECK_LIB($lib, tgetent, XE_PREPEND(-l${lib}, LIBS); break)
4262         done
4263       fi
4264     else dnl "$have_terminfo" = "no" && "with_ncurses" = "no"
4265       XE_ADD_OBJS(tparam.o)
4266       dnl The HP-UX curses library seems to have a badly broken version of select(2)
4267       dnl that makes "poll: interrupted system call" messages to appear and
4268       dnl Emacs subprocesses to hang (e.g. TeX compilation w/ AUCTeX) */
4269       case "$opsys" in *-hp-hpux* ) libs_termcap="-ltermcap" ;; esac
4270       if test -n "$libs_termcap"; then
4271         XE_PREPEND($libs_termcap, LIBS)
4272       else
4273         AC_CHECK_LIB(curses, tgetent, XE_PREPEND(-lcurses, LIBS),
4274           AC_CHECK_LIB(termcap, tgetent, XE_PREPEND(-ltermcap, LIBS),
4275             XE_ADD_OBJS(termcap.o)))
4276       fi
4277     fi
4278   fi
4279   AC_DEFINE_UNQUOTED(CURSES_H_FILE, "${curses_h_file-curses.h}")
4280   AC_DEFINE_UNQUOTED(TERM_H_FILE, "${term_h_file-term.h}")
4281
4282   dnl Autodetect gpm
4283   test -z "$with_gpm" && { AC_CHECK_HEADER(gpm.h, , with_gpm=no) }
4284   test -z "$with_gpm" && { AC_CHECK_LIB(gpm, Gpm_Open, with_gpm=yes, with_gpm=no) }
4285   if test "$with_gpm" = "yes"; then
4286     AC_DEFINE(HAVE_GPM)
4287     XE_ADD_OBJS(gpmevent.o)
4288     XE_PREPEND(-lgpm, LIBS)
4289   fi
4290
4291 else dnl "$with_tty" = "no"
4292   for feature in ncurses gpm; do
4293     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
4294       AC_MSG_WARN("--with-${feature} ignored:  Not valid without TTY support")
4295     fi
4296     eval "with_${feature}=no"
4297   done
4298 fi dnl with_tty
4299
4300 dnl Do we need event-unixoid.o ?
4301 dnl This is needed for X, or for TTY, or for MSWIN w/Cygwin select()
4302 dnl [but not Mingw MSWIN]
4303 test "$with_x11" = "yes" -o "$with_tty" = "yes" -o "$need_event_unixoid" = "yes" && XE_ADD_OBJS(event-unixoid.o)
4304
4305 dnl Database support
4306 dnl We do not necessarily have to have libdb/lib(g)dbm for DB/(G)DBM support.
4307 dnl On FreeBSD, both DB and DBM are part of libc.
4308 dnl By default, we check for DBM support in libgdbm, then libc, then libdbm.
4309
4310 test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4311   != "no no no" && AC_CHECKING(for database support)
4312
4313 dnl Check for ndbm.h, required for either kind of DBM support.
4314 if test "$with_database_gdbm $with_database_dbm" != "no no"; then
4315   AC_CHECK_HEADER(ndbm.h, [:], [
4316     test "$with_database_gdbm" = "yes" -o \
4317          "$with_database_dbm"  = "yes" && \
4318       XE_DIE("Required DBM support cannot be provided.")
4319     with_database_gdbm=no with_database_dbm=no])
4320 fi
4321
4322 dnl Check for DBM support in libgdbm.
4323 if test "$with_database_gdbm" != "no"; then
4324   AC_CHECK_LIB(gdbm, dbm_open, [
4325    with_database_gdbm=yes with_database_dbm=no libdbm=-lgdbm], [
4326    if test "$with_database_gdbm" = "yes"; then
4327      XE_DIE("Required GNU DBM support cannot be provided.")
4328    fi
4329    with_database_gdbm=no])
4330 fi
4331
4332 dnl Check for DBM support in libc and libdbm.
4333 if test "$with_database_dbm" != "no"; then
4334   AC_CHECK_FUNC(dbm_open, [with_database_dbm=yes libdbm=], [
4335     AC_CHECK_LIB(dbm, dbm_open, [with_database_dbm=yes libdbm=-ldbm], [
4336       test "$with_database_dbm" = "yes" && \
4337         XE_DIE("Required DBM support cannot be provided.")
4338       with_database_dbm=no])])
4339 fi
4340
4341 dnl Tell make about the DBM support we detected.
4342 test -n "$libdbm" && XE_PREPEND("$libdbm", LIBS)
4343 test "$with_database_gdbm" = "yes" -o \
4344      "$with_database_dbm"  = "yes" && \
4345   AC_DEFINE(HAVE_DBM)
4346
4347 dnl Check for Berkeley DB.
4348 if test "$with_database_berkdb" != "no"; then
4349   AC_MSG_CHECKING(for Berkeley db.h)
4350   for header in "db/db.h" "db.h"; do
4351     AC_TRY_COMPILE([
4352 #include <stdlib.h>
4353 #if !(defined __GLIBC__ && __GLIBC_MINOR__ >= 1)
4354 #ifdef HAVE_INTTYPES_H
4355 #define __BIT_TYPES_DEFINED__
4356 #include <inttypes.h>
4357 typedef uint8_t  u_int8_t;
4358 typedef uint16_t u_int16_t;
4359 typedef uint32_t u_int32_t;
4360 #ifdef WE_DONT_NEED_QUADS
4361 typedef uint64_t u_int64_t;
4362 #endif
4363 #endif
4364 #endif
4365 #include <$header>
4366 ],[], db_h_file="$header"; break)
4367   done
4368   if test -z "$db_h_file"
4369   then AC_MSG_RESULT(no); with_database_berkdb=no
4370   else AC_MSG_RESULT($db_h_file)
4371   fi
4372
4373   if test "$with_database_berkdb" != "no"; then
4374     AC_MSG_CHECKING(for Berkeley DB version)
4375     AC_EGREP_CPP(yes,
4376 [#include <$db_h_file>
4377 #if DB_VERSION_MAJOR > 1
4378 yes
4379 #endif
4380 ], [AC_EGREP_CPP(yes,
4381 [#include <$db_h_file>
4382 #if DB_VERSION_MAJOR > 2
4383 yes
4384 #endif
4385 ], [AC_MSG_RESULT(3); dbfunc=db_create],[
4386     AC_MSG_RESULT(2); dbfunc=db_open])],[
4387     AC_MSG_RESULT(1); dbfunc=dbopen])
4388     AC_CHECK_FUNC($dbfunc,     with_database_berkdb=yes need_libdb=no, [
4389     AC_CHECK_LIB(db, $dbfunc,  with_database_berkdb=yes need_libdb=yes)])
4390   fi
4391
4392   if test "$with_database_berkdb" = "yes"; then
4393     AC_DEFINE_UNQUOTED(DB_H_FILE, "$db_h_file")
4394     AC_DEFINE(HAVE_BERKELEY_DB)
4395     test "$need_libdb" = "yes" && XE_PREPEND(-ldb, LIBS)
4396   else with_database_berkdb=no
4397   fi
4398 fi
4399
4400 if test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4401      != "no no no"; then
4402   AC_DEFINE(HAVE_DATABASE)
4403   XE_ADD_OBJS(database.o)
4404   if test "$with_utf_2000" = "yes"; then
4405     AC_DEFINE(HAVE_CHISE_CLIENT)
4406   fi
4407 fi
4408
4409 dnl Socks support
4410 if test "$with_socks" = "yes"; then
4411   AC_CHECK_LIB(socks, SOCKSinit)
4412   test -n "$ac_cv_lib_socks_SOCKSinit" && AC_DEFINE(HAVE_SOCKS)
4413 fi
4414
4415 dnl Usage tracking (undocumented and likely unused option)
4416 if test "$usage_tracking" = "yes"; then
4417   AC_DEFINE(USAGE_TRACKING)
4418   XE_PREPEND(-Bstatic -lut -Bdynamic, LIBS)
4419 fi
4420
4421 dnl autodetect dll support
4422 if test "$with_modules" != "no"; then
4423   AC_CHECKING(for module support)
4424
4425   dnl Check for MS-Windows
4426   if test "$with_msw" = "yes"; then
4427     have_dl=yes;
4428   else
4429     dnl Find headers and libraries
4430     AC_CHECK_HEADER(dlfcn.h, [
4431       AC_MSG_CHECKING([for dlopen in -lc])
4432       AC_TRY_LINK([#include <dlfcn.h>],dnl
4433         [dlopen ("", 0);], [ have_dl=yes ], [
4434       AC_MSG_CHECKING([for dlopen in -ldl])
4435       ac_save_LIBS="$LIBS"
4436       LIBS="-ldl $LIBS"
4437       AC_TRY_LINK([#include <dlfcn.h>],dnl
4438         [dlopen ("", 0);], [ have_dl=yes ],
4439         [LIBS="$ac_save_LIBS"])
4440       ac_save_LIBS=])])
4441     if test -n "$have_dl"; then
4442       AC_DEFINE(HAVE_DLOPEN)
4443     else
4444       AC_CHECK_LIB(dld, shl_load, [
4445         libdl=dld have_dl=yes;
4446         AC_DEFINE(HAVE_SHL_LOAD)], [
4447         AC_CHECK_LIB(dld, dld_init, [
4448         libdl=dld have_dl=yes;
4449         AC_DEFINE(HAVE_DLD_INIT)])])
4450     fi
4451   fi dnl end !MS-Windows
4452
4453   if test -n "$have_dl"; then
4454     dnl XE_SHLIB_STUFF (in aclocal.m4) defines $can_build_shared
4455     XE_SHLIB_STUFF
4456   fi
4457
4458   if test "$can_build_shared" = "yes"; then
4459     AC_DEFINE(HAVE_SHLIB)
4460     XE_ADD_OBJS(sysdll.o emodules.o)
4461     XE_APPEND(src, INSTALL_ARCH_DEP_SUBDIR)
4462     test -n "$libdl" && XE_PREPEND(-l${libdl}, LIBS)
4463     AC_CHECK_FUNCS(dlerror _dlerror)
4464     with_modules=yes
4465   else
4466     if test "$with_modules" = "yes"; then
4467       XE_DIE("Required module support cannot be provided.")
4468     else
4469       AC_MSG_WARN("Module support cannot be provided.")
4470     fi
4471     with_modules=no
4472   fi
4473 fi
4474
4475 dnl Unfortunately, just because we can link doesn't mean we can run.
4476 dnl One of the above link tests may have succeeded but caused resulting
4477 dnl executables to fail to run.  Also any tests using AC_TRY_RUN will
4478 dnl have reported incorrect results.
4479 AC_TRY_RUN([int main(int c,char *v[]){return 0;}],[:],[
4480   echo ""
4481   echo "*** PANIC *** The C compiler can no longer build working executables."
4482   echo "*** PANIC *** Please examine the tail of config.log for runtime errors."
4483   echo "*** PANIC *** The most likely reason for this problem is that configure"
4484   echo "*** PANIC *** links with shared libraries, but those libraries cannot be"
4485   echo "*** PANIC *** found at run time."
4486   echo "*** PANIC ***"
4487   echo "*** PANIC *** On a Linux system, edit /etc/ld.so.conf and re-run ldconfig."
4488   echo "*** PANIC *** On other systems, try telling configure where to find the"
4489   echo "*** PANIC *** shared libraries using the --site-runtime-libraries option"
4490   echo "*** PANIC ***"
4491   echo "*** PANIC *** Another way to shoot yourself in the foot is to specify"
4492   echo "*** PANIC *** --with-FEATURE when FEATURE is not actually installed"
4493   echo "*** PANIC *** on your system.  Don't do that."
4494   exit 1])
4495
4496 dnl Process support
4497 if test "$win32_processes" = "yes"; then
4498   XE_ADD_OBJS(process-nt.o)
4499 else
4500   AC_DEFINE(HAVE_UNIX_PROCESSES)
4501   XE_ADD_OBJS(process-unix.o)
4502 fi
4503
4504 dnl --------------------------------
4505 dnl Compute SUBST-itutable variables
4506 dnl --------------------------------
4507
4508 dnl We ignore (C|LD)_SWITCH_X_(MACHINE|SYSTEM)
4509 dnl Use XE_SPACE instead of plain assignment statements to remove extraneous blanks
4510 XE_SPACE(CFLAGS, $CFLAGS)
4511 XE_SPACE(extra_objs, $extra_objs)
4512 XE_SPACE(c_switch_general, -DHAVE_CONFIG_H $c_switch_site $c_switch_machine $c_switch_system)
4513 XE_SPACE(c_switch_window_system, $c_switch_x_site $c_switch_gtk $X_CFLAGS)
4514 XE_SPACE(c_switch_all, $c_switch_general $c_switch_window_system)
4515 XE_SPACE(ld_switch_general, $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_run)
4516 XE_SPACE(ld_switch_window_system, $ld_switch_x_site)
4517 XE_SPACE(ld_switch_all, $ld_switch_general $ld_switch_window_system)
4518 XE_SPACE(ld_libs_general, $LIBS $libs_machine $libs_system $libs_standard)
4519 XE_SPACE(ld_libs_window_system, $X_EXTRA_LIBS $libs_x $libs_gtk $X_PRE_LIBS)
4520 XE_SPACE(ld_libs_all, $ld_libs_window_system $ld_libs_general)
4521
4522 dnl Compute lists of Makefiles and subdirs
4523 AC_SUBST(SRC_SUBDIR_DEPS)
4524 XE_APPEND(src, MAKE_SUBDIR)
4525 internal_makefile_list="Makefile.in"
4526 SUBDIR_MAKEFILES=''
4527 test -d lock || mkdir lock
4528 for dir in $MAKE_SUBDIR; do
4529   case "$dir" in */* ) dnl Implement mkdir -p
4530     ( for d in `echo $dir | sed 's:/: :g'` ; do
4531         test -d "$d" || mkdir "$d"; cd "$d"
4532       done ) ;;
4533    * ) test -d "$dir" || mkdir "$dir" ;;
4534   esac
4535   XE_SPACE(SUBDIR_MAKEFILES, $SUBDIR_MAKEFILES $dir/Makefile $dir/GNUmakefile)
4536   XE_SPACE(internal_makefile_list, $internal_makefile_list $dir/Makefile.in)
4537 done
4538 AC_SUBST(INSTALL_ARCH_DEP_SUBDIR)
4539 AC_SUBST(MAKE_SUBDIR)
4540 AC_SUBST(SUBDIR_MAKEFILES)
4541
4542 dnl Make s&m symlinks in the src directory, for config.h
4543 for dir in src/s src/m; do
4544   if test ! -d "$dir" ; then
4545     echo Making symbolic link to "$srcdir/$dir"
4546     ${LN_S} "$srcdir/$dir" "$dir"
4547   fi
4548 done
4549
4550 if test "$extra_verbose" = "yes"; then
4551   echo ""
4552   PRINT_VAR(extra_objs
4553    c_switch_general  c_switch_window_system  c_switch_all
4554   ld_switch_general ld_switch_window_system ld_switch_all
4555     ld_libs_general   ld_libs_window_system   ld_libs_all)
4556   echo ""
4557 fi
4558
4559 dnl ----------------------------------------------
4560 dnl Create some auxiliary files for developers.
4561 dnl ----------------------------------------------
4562
4563 dnl Create a .gdbinit useful for debugging XEmacs
4564 if test -f "$srcdir/src/.gdbinit" -a ! -f "src/.gdbinit"; then
4565   test "$extra_verbose" = "yes" && echo "creating src/.gdbinit"
4566   echo "source $srcdir/src/.gdbinit" > "src/.gdbinit"
4567 fi
4568
4569 dnl Create a .dbxrc useful for debugging XEmacs
4570 if test -f "$srcdir/src/.dbxrc" -a ! -f "src/.dbxrc"; then
4571   test "$extra_verbose" = "yes" && echo "creating src/.dbxrc"
4572   echo ". $srcdir/src/.dbxrc" > "src/.dbxrc"
4573 fi
4574
4575 dnl Create a useful TAGS file
4576 if test -f "$srcdir/TAGS" -a ! -f "TAGS"; then
4577   test "$extra_verbose" = "yes" && echo "creating TAGS"
4578   echo "\f
4579 $srcdir/TAGS,include" > "TAGS"
4580 fi
4581
4582 dnl Create top level .sbinit for Sun compilers
4583 if test "$__SUNPRO_C" = "yes"; then
4584   test "$extra_verbose" = "yes" && echo "creating .sbinit"
4585   ( echo "# For use with Sun WorkShop's Source browser."
4586     echo "# See sbquery(1) and sbinit(4) for more information"
4587     for dir in $MAKE_SUBDIR; do echo "import $dir"; done
4588   ) > .sbinit
4589 fi
4590
4591 dnl There are no more compile tests; remove the core they created.
4592 rm -f core
4593
4594 dnl ----------------------------------------------
4595 dnl Substitute into Makefile, config.h and paths.h
4596 dnl ----------------------------------------------
4597
4598 dnl what sort of things to edit into Makefile, config.h and paths.h
4599 dnl configuration here uncanonicalized to avoid exceeding size limits.
4600
4601 AC_SUBST(PROGNAME)
4602 AC_SUBST(version)
4603 AC_SUBST(configuration)
4604 AC_SUBST(canonical)
4605 AC_SUBST(inststaticdir)
4606 AC_SUBST(instvardir)
4607 AC_SUBST(srcdir)
4608 AC_SUBST(bindir)
4609 AC_SUBST(datadir)
4610 AC_SUBST(pkgdir)
4611 AC_SUBST(statedir)
4612 AC_SUBST(libdir)
4613 AC_SUBST(mandir)
4614 AC_SUBST(extra_includes)
4615
4616 AC_SUBST(prefix)
4617 AC_SUBST(PREFIX_USER_DEFINED)
4618 dnl Yo, Stephen Bourne!  I want to marry you!
4619 PREFIX=$prefix
4620 while true; do
4621   case "$PREFIX" in
4622     *\$* ) eval "PREFIX=$PREFIX" ;;
4623     *) break ;;
4624   esac
4625 done
4626 AC_SUBST(PREFIX)
4627
4628 AC_SUBST(exec_prefix)
4629 AC_SUBST(EXEC_PREFIX_USER_DEFINED)
4630 EXEC_PREFIX=$exec_prefix
4631 while true; do
4632   case "$EXEC_PREFIX" in
4633     *\$* ) eval "EXEC_PREFIX=$EXEC_PREFIX" ;;
4634     *) break ;;
4635   esac
4636 done
4637 AC_SUBST(EXEC_PREFIX)
4638
4639 AC_SUBST(infodir)
4640 AC_SUBST(INFODIR_USER_DEFINED)
4641 INFODIR=$infodir
4642 while true; do
4643   case "$INFODIR" in
4644     *\$* ) eval "INFODIR=$INFODIR" ;;
4645     *) break ;;
4646   esac
4647 done
4648 AC_SUBST(INFODIR)
4649
4650 AC_SUBST(infopath)
4651 AC_SUBST(INFOPATH_USER_DEFINED)
4652 INFOPATH=$infopath
4653 while true; do
4654   case "$INFOPATH" in
4655     *\$* ) eval "INFOPATH=$INFOPATH" ;;
4656     *) break ;;
4657   esac
4658 done
4659 AC_SUBST(INFOPATH)
4660
4661 AC_SUBST(package_path)
4662 AC_SUBST(PACKAGE_PATH_USER_DEFINED)
4663 PACKAGE_PATH=$package_path
4664 while true; do
4665   case "$PACKAGE_PATH" in
4666     *\$* ) eval "PACKAGE_PATH=$PACKAGE_PATH" ;;
4667     *) break ;;
4668   esac
4669 done
4670 AC_SUBST(PACKAGE_PATH)
4671
4672 AC_SUBST(lispdir)
4673 AC_SUBST(LISPDIR_USER_DEFINED)
4674 LISPDIR=$lispdir
4675 while true; do
4676   case "$LISPDIR" in
4677     *\$* ) eval "LISPDIR=$LISPDIR" ;;
4678     *) break ;;
4679   esac
4680 done
4681 AC_SUBST(LISPDIR)
4682
4683 AC_SUBST(moduledir)
4684 AC_SUBST(MODULEDIR_USER_DEFINED)
4685 MODULEDIR=$moduledir
4686 while true; do
4687   case "$MODULEDIR" in
4688     *\$* ) eval "MODULEDIR=$MODULEDIR" ;;
4689     *) break ;;
4690   esac
4691 done
4692 AC_SUBST(MODULEDIR)
4693
4694 AC_SUBST(sitelispdir)
4695 AC_SUBST(SITELISPDIR_USER_DEFINED)
4696 SITELISPDIR=$sitelispdir
4697 while true; do
4698   case "$SITELISPDIR" in
4699     *\$* ) eval "SITELISPDIR=$SITELISPDIR" ;;
4700     *) break ;;
4701   esac
4702 done
4703 AC_SUBST(SITELISPDIR)
4704
4705 AC_SUBST(sitemoduledir)
4706 AC_SUBST(SITEMODULEDIR_USER_DEFINED)
4707 SITEMODULEDIR=$sitemoduledir
4708 while true; do
4709   case "$SITEMODULEDIR" in
4710     *\$* ) eval "SITEMODULEDIR=$SITEMODULEDIR" ;;
4711     *) break ;;
4712   esac
4713 done
4714 AC_SUBST(SITEMODULEDIR)
4715
4716 AC_SUBST(etcdir)
4717 AC_SUBST(ETCDIR_USER_DEFINED)
4718 ETCDIR=$etcdir
4719 while true; do
4720   case "$ETCDIR" in
4721     *\$* ) eval "ETCDIR=$ETCDIR" ;;
4722     *) break ;;
4723   esac
4724 done
4725 AC_SUBST(ETCDIR)
4726
4727 AC_SUBST(docdir)
4728 AC_SUBST(DOCDIR_USER_DEFINED)
4729 DOCDIR=$docdir
4730 while true; do
4731   case "$DOCDIR" in
4732     *\$* ) eval "DOCDIR=$DOCDIR" ;;
4733     *) break ;;
4734   esac
4735 done
4736 AC_SUBST(DOCDIR)
4737
4738 AC_SUBST(archlibdir)
4739 AC_SUBST(ARCHLIBDIR_USER_DEFINED)
4740 ARCHLIBDIR=$archlibdir
4741 while true; do
4742   case "$ARCHLIBDIR" in
4743     *\$* ) eval "ARCHLIBDIR=$ARCHLIBDIR" ;;
4744     *) break ;;
4745   esac
4746 done
4747 AC_SUBST(ARCHLIBDIR)
4748
4749 AC_SUBST(docdir)
4750 AC_SUBST(bitmapdir)
4751 AC_SUBST(extra_objs)
4752
4753 dnl The following flags combine all the information from:
4754 dnl - command line options (user always gets priority)
4755 dnl - user environment variables
4756 dnl - determined by configure
4757 dnl - the s&m header files (required for ellcc)
4758 AC_SUBST(machfile)
4759 AC_SUBST(opsysfile)
4760 AC_SUBST(c_switch_general)
4761 AC_SUBST(c_switch_window_system)
4762 AC_SUBST(c_switch_all)
4763 AC_SUBST(ld_switch_general)
4764 AC_SUBST(ld_switch_window_system)
4765 AC_SUBST(ld_switch_all)
4766 AC_SUBST(ld_libs_general)
4767 AC_SUBST(ld_libs_window_system)
4768 AC_SUBST(ld_libs_all)
4769 AC_SUBST(CFLAGS)
4770 AC_SUBST(CPPFLAGS)
4771 AC_SUBST(LDFLAGS)
4772 RECURSIVE_MAKE="\$(MAKE) \$(MFLAGS) CC='\$(CC)' CFLAGS='\$(CFLAGS)' LDFLAGS='\$(LDFLAGS)' CPPFLAGS='\$(CPPFLAGS)'"
4773 AC_SUBST(RECURSIVE_MAKE)
4774
4775 AC_SUBST(native_sound_lib)
4776 AC_SUBST(sound_cflags)
4777 AC_SUBST(RANLIB)
4778 AC_SUBST(dynodump_arch)
4779
4780 dnl Preliminary support for using a different compiler for xemacs itself.
4781 dnl Useful for building XEmacs with a C++ or 64-bit compiler.
4782 : ${XEMACS_CC:=$CC}
4783 AC_SUBST(XEMACS_CC)
4784
4785 dnl The default is yes
4786 if test "$with_prefix" = "yes"; then
4787   AC_DEFINE(PREFIX_USER_DEFINED)
4788 fi
4789
4790 dnl The default is no
4791 if test "$with_site_lisp" = "no"; then
4792   AC_DEFINE(INHIBIT_SITE_LISP)
4793 fi
4794 dnl The default is yes
4795 if test "$with_site_modules" = "no"; then
4796   AC_DEFINE(INHIBIT_SITE_MODULES)
4797 fi
4798
4799 XE_SPACE(ac_configure_args, $ac_configure_args)
4800 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "$configuration")
4801 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "$ac_configure_args")
4802
4803 dnl Following are deprecated
4804
4805 null_string=""
4806 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE,     $null_string)
4807 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, $null_string)
4808 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,      $null_string)
4809 AC_DEFINE_UNQUOTED(LD_SWITCH_SITE,       $null_string)
4810 AC_DEFINE_UNQUOTED(C_SWITCH_SITE,        $null_string)
4811
4812 dnl Note: as a general rule, *only* define things here that are not
4813 dnl autodetected.  For things that are autodetected, define them
4814 dnl at the point where the autodetection occurs or would occur,
4815 dnl so that the user gets immediate feedback on the results of the
4816 dnl autodetection.
4817
4818 if   test "$GNU_MALLOC"         = "yes"; then AC_DEFINE(GNU_MALLOC)
4819 elif test "$with_system_malloc" = "yes"; then AC_DEFINE(USE_SYSTEM_MALLOC)
4820 elif test "$with_debug_malloc"  = "yes"; then AC_DEFINE(USE_DEBUG_MALLOC)
4821                                               AC_DEFINE(USE_SYSTEM_MALLOC)
4822 fi
4823 test "$with_i18n3"         = "yes" && AC_DEFINE(I18N3)
4824 test "$GCC"                = "yes" && AC_DEFINE(USE_GCC)
4825 test "$external_widget"    = "yes" && AC_DEFINE(EXTERNAL_WIDGET)
4826 test "$quick_build"        = "yes" && AC_DEFINE(QUICK_BUILD)
4827 test "$with_purify"        = "yes" && AC_DEFINE(PURIFY)
4828 test "$with_quantify"      = "yes" && AC_DEFINE(QUANTIFY)
4829 test "$with_pop"           = "yes" && AC_DEFINE(MAIL_USE_POP)
4830 test "$with_kerberos"      = "yes" && AC_DEFINE(KERBEROS)
4831 test "$with_hesiod"        = "yes" && AC_DEFINE(HESIOD)
4832 test "$use_union_type"     = "yes" && AC_DEFINE(USE_UNION_TYPE)
4833 test "$pdump"              = "yes" && AC_DEFINE(PDUMP)
4834 test "$with_ipv6_cname"    = "yes" && AC_DEFINE(IPV6_CANONICALIZE)
4835
4836 dnl -------------------------------
4837 dnl Report on what we decided to do
4838 dnl -------------------------------
4839
4840 (
4841 dnl /etc/osversion is on SONY NEWS-OS
4842 if test -f /etc/osversion; then dnl SONY NEWS-OS
4843   echo "osversion: `cat /etc/osversion`"
4844 else
4845   echo "uname -a: `uname -a`"
4846 fi
4847 echo ""
4848 echo "$0 $quoted_arguments"
4849 ) > Installation
4850
4851 if test ! -z ${emacs_beta_version} ; then
4852   if test -z "${emacs_is_beta}" ; then
4853         xemacs_betaname=".${emacs_beta_version}"
4854   else
4855         xemacs_betaname="-b${emacs_beta_version}"
4856   fi
4857 else
4858   xemacs_betaname=""
4859 fi
4860
4861 dnl Start stdout redirection to '| tee -a Installation'
4862 (
4863 echo "
4864
4865 XEmacs ${emacs_major_version}.${emacs_minor_version}${xemacs_betaname} \"$xemacs_codename\" configured for \`$canonical'.
4866 "
4867 echo "
4868 Compilation / Installation:"
4869 echo "  Source code location:              $srcdir"
4870 echo "  Installation prefix:               $prefix"
4871 if test -n "$site_includes"; then
4872   echo "  Additional header files:           $site_includes"
4873 fi
4874 if test -n "$site_libraries"; then
4875   echo "  Additional libraries:              $site_libraries"
4876 fi
4877 if test -n "$site_prefixes"; then
4878   echo "  Additional prefixes:               $site_prefixes"
4879 fi
4880 if test -n "$runpath"; then
4881   echo "  Runtime library search path:       $runpath"
4882 fi
4883
4884 if test -n "$opsysfile"
4885 then echo "  Operating system description file: \`$opsysfile'"
4886 else echo "  Not using any operating system description file"
4887 fi
4888 if test -n "$machfile"
4889 then echo "  Machine description file:          \`$machfile'"
4890 else echo "  Not using any machine description file"
4891 fi
4892
4893 echo "  Compiler:                          $CC $CFLAGS"
4894 echo "  Relocating allocator for buffers:  $rel_alloc"
4895 echo "  GNU version of malloc:             ${GNU_MALLOC}${GNU_MALLOC_reason}"
4896 case "$ld_switch_site" in
4897   *nocombreloc*) echo "  Linking with \`-z nocombreloc'.
4898     - Consider configuring with --pdump." ;;
4899 esac
4900
4901 echo "
4902 Window System:"
4903 if test "$with_msw" = "yes"; then
4904   echo "  Compiling in support for the Microsoft window system."
4905 fi
4906 if test "$with_x11" = "yes"; then
4907   echo "  Compiling in support for the X window system:"
4908   echo "    - X Windows headers location:                 $x_includes"
4909   echo "    - X Windows libraries location:               $x_libraries"
4910   if test "$with_xauth" != yes; then
4911     echo "    - Xau (X authority) not available."
4912   fi
4913   if test "$with_xmu" != yes; then
4914     echo "    - Xmu library not available; substituting equivalent routines."
4915   fi
4916   if test "$with_wmcommand" != no; then
4917     echo "    - Handling WM_COMMAND properly."
4918   fi
4919 fi
4920 if test "$need_athena" = "yes"; then
4921   echo "  Compiling in support for the Athena widget set:"
4922   echo "    - Athena headers location:                    $athena_h_path"
4923   echo "    - Athena library to link:                     $athena_lib"
4924 fi
4925 case "$with_menubars" in
4926   gtk   ) echo "  Using GTK menubars."   ;;
4927   lucid ) echo "  Using Lucid menubars." ;;
4928   motif ) echo "  Using Motif menubars."
4929           echo "  *WARNING*  The Motif menubar implementation is currently buggy."
4930           echo "             We recommend using the Lucid menubar instead."
4931           echo "             Re-run configure with --with-menubars='lucid'." ;;
4932     msw ) echo "  Using MS-Windows menubars." ;;
4933 esac
4934 case "$with_scrollbars" in
4935   gtk    ) echo "  Using GTK scrollbars."        ;;
4936   lucid  ) echo "  Using Lucid scrollbars."      ;;
4937   motif  ) echo "  Using Motif scrollbars."      ;;
4938   athena ) echo "  Using Athena scrollbars."     ;;
4939      msw ) echo "  Using MS-Windows scrollbars." ;;
4940 esac
4941 case "$with_dialogs" in
4942   gtk    ) echo "  Using GTK dialog boxes." ;;
4943   motif  ) echo "  Using Motif dialog boxes."
4944            if test "$unexec" = "unexaix.o"; then if test "`uname -v`" = 4 -a "`uname -r`" -ge 3; then
4945              echo "  *WARNING*  The Motif dialog boxes cause problems on AIX 4.3 and higher."
4946              echo "             We recommend using the Athena dialog boxes instead."
4947              echo "             Install libXaw and re-run configure with --with-dialogs='athena'."
4948              echo "             Read the PROBLEMS file for more information."
4949            fi; fi ;;
4950   athena ) echo "  Using Athena dialog boxes."     ;;
4951      msw ) echo "  Using MS-Windows dialog boxes." ;;
4952 esac
4953 case "$with_widgets" in
4954   gtk    ) echo "  Using GTK native widgets."        ;;
4955   motif  ) echo "  Using Motif native widgets."      ;;
4956   athena ) echo "  Using Athena native widgets."     ;;
4957      msw ) echo "  Using MS-Windows native widgets." ;;
4958 esac
4959 if test "$with_dragndrop" = yes; then
4960   echo "  Compiling in support for Drag'n'Drop (EXPERIMENTAL)."
4961   echo "    -  Drag'n'Drop prototype:                             $dragndrop_proto."
4962 fi
4963
4964 echo "
4965 TTY:"
4966 test "$with_ncurses" = yes && echo "  Compiling in support for ncurses."
4967 test "$with_gpm" = yes && echo "  Compiling in support for GPM (General Purpose Mouse)."
4968
4969 echo "
4970 Images:"
4971 test "$with_gif" = yes && echo "  Compiling in support for GIF  images (builtin)."
4972 if test "$with_xpm" = yes; then
4973   echo "  Compiling in support for XPM  images."
4974 elif test "$with_x11" = yes; then
4975   echo "  WARNING: -----------------------------------------------------------"
4976   echo "  WARNING: Compiling without XPM image support."
4977   if test "$xpm_problem" != ""; then
4978     echo "  Reason: $xpm_problem"
4979   fi
4980   echo "  WARNING: You should strongly consider installing XPM."
4981   echo "  WARNING: Otherwise toolbars and other graphics will look suboptimal."
4982   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4983   echo "  WARNING: -----------------------------------------------------------"
4984 fi
4985 if test "$with_png" = yes; then
4986   echo "  Compiling in support for PNG  images."
4987 elif test "$window_system" != "none"; then
4988   echo "  WARNING: -----------------------------------------------------------"
4989   echo "  WARNING: Compiling without PNG image support."
4990   if test "$png_problem" != ""; then
4991     echo "  Reason: $png_problem"
4992   fi
4993   echo "  WARNING: You should strongly consider installing the PNG libraries."
4994   echo "  WARNING: Otherwise certain images and glyphs may not display."
4995   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4996   echo "  WARNING: -----------------------------------------------------------"
4997 fi
4998 test "$with_jpeg" = yes && echo "  Compiling in support for JPEG images."
4999 test "$with_tiff" = yes && echo "  Compiling in support for TIFF images."
5000 test "$with_xface" = yes && echo "  Compiling in support for X-Face message headers."
5001
5002 echo "
5003 Sound:"
5004 test "$with_native_sound" = yes && echo "  Compiling in support for sound (native)."
5005 test "$with_nas_sound" = yes && echo "  Compiling in support for NAS (network audio system)."
5006 test "$old_nas" = yes && echo "    - NAS library lacks error trapping; will play synchronously."
5007 test "$with_esd_sound" = yes && echo "  Compiling in support for ESD (Enlightened Sound Daemon)."
5008
5009 echo "
5010 Databases:"
5011 test "$with_database_berkdb" = yes && echo "  Compiling in support for Berkeley database."
5012 test "$with_database_dbm"    = yes && echo "  Compiling in support for DBM."
5013 test "$with_database_gdbm"   = yes && echo "  Compiling in support for GNU DBM."
5014 test "$with_ldap" = yes && echo "  Compiling in support for LDAP."
5015 if test "$with_postgresql" = yes; then
5016   echo "  Compiling in support for PostgreSQL."
5017   echo "    - Using PostgreSQL header file:  $libpq_fe_h_file"
5018   test "$with_postgresqlv7" = yes && echo "    - Using PostgreSQL V7 bindings."
5019 fi
5020
5021 echo "
5022 Internationalization:"
5023 test "$with_mule" = yes && echo "  Compiling in support for Mule (multi-lingual Emacs)."
5024 test "$with_utf_2000" = yes && echo "  Using UTF-2000 (UTF-8) buffer/string representation."
5025 test "$with_text_coding" = yes && echo "  Compiling in support for text coding."
5026 test "$with_file_coding" = yes && echo "  Compiling in support for file coding."
5027 test "$with_xim" != no && echo "  Compiling in support for XIM (X11R5+ I18N input method)."
5028 test "$with_xim" = motif && echo "    - Using Motif to provide XIM support."
5029 test "$with_xim" = xlib && echo "    - Using raw Xlib to provide XIM support."
5030 test "$with_xfs" = yes && echo "    - Using XFontSet to provide bilingual menubar."
5031 test "$with_canna" = yes && echo "  Compiling in support for Canna on Mule."
5032 if test "$with_wnn" = yes; then
5033   echo "  Compiling in support for the WNN input method on Mule."
5034   test "$with_wnn6" = yes && echo "    - Using WNN version 6."
5035 fi
5036 test "$with_i18n3" = yes && echo "  Compiling in support for I18N level 3 (doesn't currently work)."
5037
5038 echo "
5039 Mail:"
5040 test "$with_pop" = yes && echo "  Compiling in support for POP mail retrieval."
5041 test "$with_kerberos" = yes && echo "  Compiling in support for Kerberos POP authentication."
5042 test "$with_hesiod" = yes && echo "  Compiling in support for Hesiod POP server access."
5043 test -n "$mail_locking" && echo "  Compiling in support for \"$mail_locking\" mail spool file locking method."
5044
5045 echo "
5046 Other Features:"
5047 test "$with_ipv6_cname" = no && echo "  Inhibiting IPv6 canonicalization at startup."
5048 test "$with_tooltalk" = yes && echo "  Compiling in support for ToolTalk."
5049 test "$with_workshop" = yes && echo "  Compiling in support for Sun WorkShop."
5050 test "$with_socks" = yes && echo "  Compiling in support for SOCKS."
5051 test "$with_dnet" = yes && echo "  Compiling in support for DNET."
5052 test "$with_modules" = "yes" && echo "  Compiling in support for dynamic shared object modules."
5053 test "$use_union_type" = yes && echo "  Using the union type for Lisp_Objects."
5054 test "$pdump" = yes && echo "  Using the new portable dumper."
5055 test "$debug" = yes && echo "  Compiling in support for extra debugging code."
5056 test "$usage_tracking" = yes && echo "  Compiling in support for active usage tracking (Sun internal)."
5057 if test "$error_check_extents $error_check_typecheck $error_check_bufpos $error_check_gc $error_check_malloc $error_check_glyphs" \
5058   != "no no no no no no"; then
5059   echo "  WARNING: ---------------------------------------------------------"
5060   echo "  WARNING: Compiling in support for runtime error checking."
5061   echo "  WARNING: XEmacs will run noticeably more slowly as a result."
5062   echo "  WARNING: Error checking is on by default for XEmacs beta releases."
5063   echo "  WARNING: ---------------------------------------------------------"
5064 fi
5065 echo ""
5066 ) | tee -a Installation
5067 dnl echo "The above configure report is appended to \"Installation\" file."
5068 echo ""
5069
5070 dnl -----------------------------------
5071 dnl Now generate config.h and Makefiles
5072 dnl -----------------------------------
5073 dnl This has to be called in order for this variable to get into config.status
5074 AC_SUBST(internal_makefile_list)
5075 # Remove any trailing slashes in these variables.
5076 test -n "$prefix" &&
5077   prefix=`echo '' "$prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
5078 test -n "$exec_prefix" &&
5079   exec_prefix=`echo '' "$exec_prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
5080
5081 dnl Build Makefile.in's from Makefile.in.in's
5082 dnl except ./Makefile from $srcdir/Makefile.in
5083
5084 for file in $internal_makefile_list; do
5085   test "$file" = src/Makefile.in && \
5086     file="src/Makefile.in:src/Makefile.in.in:src/depend"
5087   XE_APPEND($file, ac_output_files)
5088 done
5089 ac_output_files="$ac_output_files src/paths.h lib-src/config.values"
5090 test "$with_modules" = "yes" && XE_APPEND(lib-src/ellcc.h, ac_output_files)
5091
5092 AC_OUTPUT($ac_output_files,
5093 [for dir in . $MAKE_SUBDIR; do
5094   (
5095     cd $dir
5096     rm -f junk.c
5097     < Makefile.in \
5098       sed -e '/^# Generated/d' \
5099           -e 's%/\*\*/#.*%%' \
5100           -e 's/^ *# */#/' \
5101 dnl Delete Makefile.in.in comment lines
5102           -e '/^##/d' \
5103 dnl Pass through CPP directives unchanged
5104           -e '/^#/ {
5105 p
5106 d
5107 }'        \
5108 dnl Quote other lines to protect from CPP substitution
5109           -e '/./ {
5110 s/\([[\"]]\)/\\\1/g
5111 s/^/"/
5112 s/$/"/
5113 }'  > junk.c;
5114
5115 dnl Create a GNUmakefile and Makefile from Makefile.in.
5116
5117 changequote(<<,>>)dnl
5118 dnl CPP_MAKEFILE(CPPFLAGS,filename)
5119 define(<<CPP_MAKEFILE>>,
5120 echo creating $dir/<<$2>>
5121 $CPP -I. -I${top_srcdir}/src <<$1>> junk.c \
5122 dnl Delete line directives inserted by $CPP
5123   | sed -e 's/^\#.*//'          \
5124 dnl Delete spurious blanks inserted by $CPP
5125         -e 's/^[ TAB][ TAB]*$//'\
5126         -e 's/^ /TAB/'          \
5127 dnl Delete blank lines
5128         -e '/^[ \f]*$/d' \
5129 dnl Restore lines quoted above to original contents.
5130         -e '/^\"/ {
5131         s/\\\([\"]\)/\1/g
5132         s/^[ TAB]*\"//
5133         s/\"[ TAB]*$//
5134 }' > Makefile.new
5135     chmod 444 Makefile.new
5136     mv -f Makefile.new <<$2>>
5137 )dnl CPP_MAKEFILE
5138
5139     CPP_MAKEFILE(,Makefile)
5140     CPP_MAKEFILE(-DUSE_GNU_MAKE,GNUmakefile)
5141 changequote([,])dnl
5142     rm -f junk.c
5143   )
5144 done
5145
5146 dnl Append AC_DEFINE information to lib-src/config.values
5147 dnl (AC_SUBST information is already there (see config.values.sh).
5148 sed < config.status >> lib-src/config.values \
5149   -e '/{ac_dA}.*{ac_dB}.*{ac_dC}.*{ac_dD}$/!d' \
5150   -e 's/\${ac_dA}\(.*\)\${ac_dB}.*\${ac_dC}\(.*\)\${ac_dD}/\1 \2/' \
5151   -e 's/^\([[^ ]]*\) $/\1 ""/' \
5152   -e 's/ 1$/ t/'
5153
5154 ],
5155 [CPP="$CPP"
5156  top_srcdir="$srcdir"
5157  MAKE_SUBDIR="$MAKE_SUBDIR"
5158 ])dnl