configure.in

   1 dnl Define our own header notice with own copyright
   2 define([AC_INIT_NOTICE],
   3 [#### Configuration script for XEmacs.  Largely divergent from FSF.
   4 #### Guess values for system-dependent variables and create Makefiles.
   5 #### Generated automatically using autoconf version] AC_ACVERSION [
   6 #### Copyright (C) 1992, 93, 94, 95, 96 Free Software Foundation, Inc.
   7 #### Copyright (C) 1993-1995 Board of Trustees, University of Illinois.
   8 #### Copyright (C) 1996, 1997 Sun Microsystems, Inc.
   9 #### Copyright (C) 1995, 1996 Ben Wing.
  10 #### Copyright (C) 1998, 1999 J. Kean Johnston.
  11
  12 ### Don't edit this script!
  13 ### This script was automatically generated by the `autoconf' program
  14 ### from the file `./configure.in'.
  15 ### To rebuild it, execute the command
  16 ###     autoconf
  17 ### in the this directory.  You must have autoconf version 2.13 or later.
  18
  19 ### This file is part of XEmacs.
  20
  21 ### XEmacs is free software; you can redistribute it and/or modify it
  22 ### under the terms of the GNU General Public License as published by
  23 ### the Free Software Foundation; either version 2, or (at your
  24 ### option) any later version.
  25
  26 ### XEmacs is distributed in the hope that it will be useful, but
  27 ### WITHOUT ANY WARRANTY; without even the implied warranty of
  28 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  29 ### General Public License for more details.
  30
  31 ### You should have received a copy of the GNU General Public License
  32 ### along with XEmacs; see the file COPYING.  If not, write to the Free
  33 ### Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  34 ### 02111-1307, USA.
  35
  36 ### For usage, run `./configure --help'
  37 ### For more detailed information on building and installing XEmacs,
  38 ### read the file `INSTALL'.
  39 ###
  40 ### If configure succeeds, it leaves its status in config.status.
  41 ### A log of configuration tests can be found in config.log.
  42 ### If configure fails after disturbing the status quo,
  43 ###     config.status is removed.
  44 ])
  45
  46 dnl Since XEmacs has configuration requirements that autoconf cannot
  47 dnl meet, this file is an unholy marriage of custom-baked
  48 dnl configuration code and autoconf macros.
  49
  50 dnl We use the m4 quoting characters [ ] (as established by the
  51 dnl autoconf system), so quote them like this: [[foo]]
  52
  53 AC_PREREQ(2.13)dnl
  54 dnl Redefine some standard autoconf macros
  55 dnl here is how XEmacs is different:
  56 dnl - no cache file
  57 dnl - non-standard options
  58 dnl - suport for extra-verbosity
  59 dnl - ordinary libs are handled separately from X libs (might be a mistake)
  60 dnl - various random kludges (e.g. -with-dnet=no)
  61
  62 dnl PRINT_VAR(var var ...)  prints values of shell variables
  63 define([PRINT_VAR],[for var in patsubst([$1],[[
  64 ]+],[ ]); do eval "echo \"$var = '\$$var'\""; done])
  65
  66 dnl Disable cache files:
  67 dnl This is controversial, but I am convinced this is the right way to go,
  68 dnl at least by default.  Otherwise there are too many surprises.
  69 define([AC_CACHE_LOAD], )dnl
  70 define([AC_CACHE_SAVE], )dnl
  71 define([AC_CACHE_VAL], [
  72 $2
  73 ])dnl
  74
  75 dnl Redefine AC_TRY_RUN_NATIVE to not throw away stderr while running
  76 dnl AC_TRY_RUN_NATIVE(PROGRAM, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
  77 define([AC_TRY_RUN_NATIVE],
  78 [cat > conftest.$ac_ext <<EOF
  79 [#]line __oline__ "configure"
  80 #include "confdefs.h"
  81 [$1]
  82 EOF
  83 if AC_TRY_EVAL(ac_link) && test -s conftest && (./conftest; exit $?) 2>&AC_FD_CC
  84 then
  85 dnl Do not remove the temporary files here, so they can be examined.
  86   ifelse([$2], , :, [$2])
  87 else
  88   conftest_rc="$?"
  89   echo "configure: failed program was:" >&AC_FD_CC
  90   cat conftest.$ac_ext >&AC_FD_CC
  91 ifelse([$3], , , [  rm -fr conftest*
  92   $3
  93 ])dnl
  94 fi
  95 rm -fr conftest*])dnl AC_TRY_RUN_NATIVE
  96
  97
  98 dnl Avoid spurious cross-compiling warnings from AC_TRY_RUN
  99 dnl XEmacs is unlikely to ever cross-compile
 100 define([AC_TRY_RUN],[AC_TRY_RUN_NATIVE([$1], [$2], [$3])])dnl
 101
 102 dnl Redefine AC_DEFINE* to provide more output if extra_verbose
 103 dnl Set VARIABLE to VALUE, verbatim, or 1.
 104 dnl AC_DEFINE(VARIABLE [, VALUE])
 105 define([AC_DEFINE],
 106 [{ test "$extra_verbose" = "yes" && cat << \EOF
 107     Defining $1[]ifelse($#, 2, [ = $2],)
 108 EOF
 109 cat >> confdefs.h <<\EOF
 110 [#define] $1 ifelse($#, 2, [$2], 1)
 111 EOF
 112 }
 113 ])dnl AC_DEFINE
 114
 115 define([AC_DEFINE_UNQUOTED],
 116 [{ test "$extra_verbose" = "yes" && cat << EOF
 117     Defining $1[]ifelse($#, 2, [ = $2],)
 118 EOF
 119 cat >> confdefs.h <<EOF
 120 [#define] $1 ifelse($#, 2, [$2], 1)
 121 EOF
 122 }
 123 ])dnl AC_DEFINE_UNQUOTED
 124
 125 dnl redefine AC_CHECK_LIB in accordance with our own value of ac_link
 126 dnl Add in extra kludgy check to support with_dnet=no
 127 dnl Add in extra LDFLAGS arg, which PRECEDE libs
 128 dnl Support --with-dnet=no
 129
 130 dnl AC_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
 131 dnl             [, OTHER-LIBRARIES] [, LDFLAGS]]]])
 132 define([AC_CHECK_LIB],
 133 [ifelse([$1],dnet, [if test "$with_dnet" = "no" ; then
 134 ac_cv_lib_dnet_dnet_ntoa=no
 135 ifelse([$4], , , [$4]
 136 )dnl
 137 else
 138 ])]
 139 AC_CHECK_LIB_ORIG_HACKED([$1],[$2],[$3],[$4],[$5], [$6])
 140 [ifelse([$1],dnet,[fi
 141 ])]dnl
 142 )dnl AC_CHECK_LIB
 143
 144 define([AC_CHECK_LIB_ORIG_HACKED],
 145 [ifelse([$5],,AC_MSG_CHECKING([for $2 in -l$1]),
 146 xe_msg_checking="for [$2] in -l[$1]"
 147 test -n "[$5]" && xe_msg_checking="$xe_msg_checking using extra libs [$5]"
 148 AC_MSG_CHECKING("$xe_msg_checking"))
 149 dnl Use a cache variable name containing both the library and function name,
 150 dnl because the test really is for library $1 defining function $2, not
 151 dnl just for library $1.  Separate tests with the same $1 and different $2s
 152 dnl may have different results.
 153 ac_lib_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
 154 AC_CACHE_VAL(ac_cv_lib_$ac_lib_var,
 155 [xe_check_libs="$6 -l$1 $5"
 156 AC_TRY_LINK(dnl
 157 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 158 [/* Override any gcc2 internal prototype to avoid an error.  */
 159 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 160 extern "C"
 161 #endif
 162 ])dnl
 163 [/* We use char because int might match the return type of a gcc2
 164     builtin and then its argument prototype would still apply.  */
 165 char $2();
 166 ]),
 167             [$2()],
 168             eval "ac_cv_lib_$ac_lib_var=yes",
 169             eval "ac_cv_lib_$ac_lib_var=no")
 170 xe_check_libs=""
 171 ])dnl
 172 if eval "test \"`echo '$ac_cv_lib_'$ac_lib_var`\" = yes" ; then
 173   AC_MSG_RESULT(yes)
 174   ifelse([$3], ,
 175 [changequote(, )dnl
 176   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 177     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 178 changequote([, ])dnl
 179   AC_DEFINE_UNQUOTED($ac_tr_lib)
 180   XE_PREPEND([-l$1], LIBS)
 181 ], [$3])
 182 else
 183   AC_MSG_RESULT(no)
 184 ifelse([$4], , , [$4
 185 ])dnl
 186 fi
 187 ])dnl AC_CHECK_LIB_ORIG_HACKED
 188
 189
 190 dnl AC_LANG_C()
 191 define([AC_LANG_C],
 192 [define([AC_LANG], [C])dnl
 193 ac_ext=c
 194 dnl CFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
 195 dnl ac_cpp='$CPP $CPPFLAGS'
 196 dnl ac_compile='${CC-cc} -c $CFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC'
 197 dnl ac_link='${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC'
 198 xe_cppflags='$CPPFLAGS $c_switch_site $c_switch_machine $c_switch_system $c_switch_x_site $X_CFLAGS'
 199 xe_ldflags='$LDFLAGS $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_x_site $ld_switch_run'
 200 xe_libs='$ld_call_shared $xe_check_libs $X_EXTRA_LIBS $libs_x $X_PRE_LIBS $LIBS $libs_machine $libs_system $libs_standard'
 201 ac_cpp='$CPP '"$xe_cppflags"
 202 ac_compile='${CC-cc} -c $CFLAGS '"$xe_cppflags"' conftest.$ac_ext 1>&AC_FD_CC'
 203 ac_link='${CC-cc} -o conftest $CFLAGS '"$xe_cppflags $xe_ldflags"' conftest.$ac_ext '"$xe_libs"' 1>&AC_FD_CC'
 204 cross_compiling=no
 205 ]) dnl AC_LANG_C
 206
 207 dnl The construct foo=`echo $w1 $w2 $w3` fails on some systems if $w1 = -e or -n
 208 dnl So we use the following instead.
 209 dnl XE_SPACE(var, words)
 210 define([XE_SPACE],[
 211 T=""
 212 for W in $2; do if test -z "$T"; then T="$W"; else T="$T $W"; fi; done
 213 $1="$T"
 214 ])dnl XE_SPACE
 215
 216 dnl XE_ADD_OBJS(foo.o ...)
 217 define([XE_ADD_OBJS],
 218 [extra_objs="$extra_objs [$1]" && dnl
 219  if test "$extra_verbose" = "yes"; then
 220    echo "    xemacs will be linked with \"[$1]\""
 221  fi])dnl XE_ADD_OBJS
 222
 223 dnl XE_APPEND(value, varname)
 224 define([XE_APPEND],
 225 [[$2]="$[$2] [$1]" && dnl
 226  if test "$extra_verbose" = "yes"; then echo "    Appending \"[$1]\" to \$[$2]"; fi])
 227
 228 dnl XE_PREPEND(value, varname)
 229 define([XE_PREPEND],
 230 [[$2]="[$1] $[$2]" && dnl
 231  if test "$extra_verbose" = "yes"; then echo "    Prepending \"[$1]\" to \$[$2]"; fi])
 232
 233 dnl XE_DIE(message)
 234 define([XE_DIE], [{ echo "Error:" $1 >&2; exit 1; }])
 235
 236 dnl XE_STRIP_4TH_COMPONENT(var)
 237 dnl Changes i986-pc-linux-gnu to i986-pc-linux, as God (not RMS) intended.
 238 define([XE_STRIP_4TH_COMPONENT],
 239 [$1=`echo "$$1" | sed '[s/^\([^-][^-]*-[^-][^-]*-[^-][^-]*\)-.*$/\1/]'`])
 240
 241 dnl Initialize some variables set by options.
 242 dnl The variables have the same names as the options, with
 243 dnl dashes changed to underlines.
 244
 245 define([AC_INIT_PARSE_ARGS],[
 246
 247 dnl Get sane consistent behavior from various shells
 248 dnl Avoid losing with weird user CDPATHs
 249
 250 if test -n "$ZSH_VERSION"; then
 251   dnl zsh's Bourne shell emulation options
 252   setopt NO_BAD_PATTERN NO_BANG_HIST NO_BG_NICE NO_EQUALS NO_FUNCTION_ARGZERO
 253   setopt GLOB_SUBST NO_HUP INTERACTIVE_COMMENTS KSH_ARRAYS NO_MULTIOS NO_NOMATCH
 254   setopt RM_STAR_SILENT POSIX_BUILTINS SH_FILE_EXPANSION SH_GLOB SH_OPTION_LETTERS
 255   setopt SH_WORD_SPLIT BSD_ECHO IGNORE_BRACES
 256   dnl zsh-3.1-beta drops core on the following
 257   dnl unset CDPATH
 258   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 259 elif test -n "$BASH_VERSION"; then
 260   dnl Use Posix mode with bash
 261   set -o posix
 262   unset CDPATH
 263 else
 264   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 265 fi
 266
 267 dnl Initialize some variables set by options.
 268 dnl The variables have the same names as the options, with
 269 dnl dashes changed to underlines.
 270 exec_prefix=NONE
 271 host=NONE
 272 no_create=
 273 nonopt=NONE
 274 no_recursion=
 275 prefix=NONE
 276 program_prefix=NONE
 277 program_suffix=NONE
 278 program_transform_name=s,x,x,
 279 silent=
 280 site=
 281 srcdir=
 282 target=NONE
 283 verbose=
 284 x_includes=NONE
 285 x_libraries=NONE
 286
 287 dnl Installation directory options.
 288 dnl These are left unexpanded so users can "make install exec_prefix=/foo"
 289 dnl and all the variables that are supposed to be based on exec_prefix
 290 dnl by default will actually change.
 291 dnl Use braces instead of parens because sh, perl, etc. also accept them.
 292 dnl If you change these, you need to synchronize with the settings of the
 293 dnl various ..._USER_DEFINED variables further down.
 294 bindir='${exec_prefix}/bin'
 295 sbindir='${exec_prefix}/sbin'
 296 libexecdir='${exec_prefix}/libexec'
 297 datadir='${prefix}/share'
 298 sysconfdir='${prefix}/etc'
 299 sharedstatedir='${prefix}/com'
 300 localstatedir='${prefix}/var'
 301 libdir='${{exec_prefix}}/lib'
 302 includedir='${prefix}/include'
 303 oldincludedir='/usr/include'
 304 infodir='${prefix}/info'
 305 mandir='${prefix}/man'
 306
 307 dnl Initialize some other variables.
 308 subdirs=
 309 MFLAGS= MAKEFLAGS=
 310 SHELL=${CONFIG_SHELL-/bin/sh}
 311 dnl Maximum number of lines to put in a shell here document.
 312 ac_max_here_lines=12
 313 ])dnl AC_INIT_PARSE_ARGS
 314
 315 AC_INIT(src/lisp.h)dnl
 316 AC_CONFIG_HEADER(src/config.h lwlib/config.h)
 317 dnl Remove any more than one leading "." element from the path name.
 318 dnl If we do not remove them, then another "./" will be prepended to
 319 dnl the file name each time we use config.status, and the program name
 320 dnl will get larger and larger.  This would not be a problem, except
 321 dnl that since progname gets recorded in all the Makefiles this script
 322 dnl produces, move-if-change thinks they're different when they're
 323 dnl not.
 324 dnl
 325 dnl It would be nice if we could put the ./ in a \( \) group and then
 326 dnl apply the * operator to that, so we remove as many leading './././'s
 327 dnl as are present, but some seds (like Ultrix's sed) don't allow you to
 328 dnl apply * to a \( \) group.  Bleah.
 329 progname="`echo $0 | sed 's:^\./\./:\./:'`"
 330
 331 dnl -----------------------------
 332 dnl Establish some default values
 333 dnl -----------------------------
 334
 335 XE_APPEND(lib-src, MAKE_SUBDIR)
 336 XE_APPEND(lib-src, INSTALL_ARCH_DEP_SUBDIR)
 337
 338 prefix='/usr/local'
 339 exec_prefix='${prefix}'
 340 bindir='${exec_prefix}/bin'
 341 dnl FSF 19.29 changes to:
 342 dnl datadir='${prefix}/share'
 343 dnl sharedstatedir='${prefix}/com'
 344 dnl libexecdir='${exec_prefix}/libexec'
 345 datadir='${prefix}/lib'
 346 statedir='${prefix}/lib'
 347 libdir='${exec_prefix}/lib'
 348 mandir='${prefix}/man/man1'
 349 inststaticdir='${PROGNAME}'
 350 instvardir='${PROGNAME}-${version}'
 351 infodir='${datadir}/${instvardir}/info'
 352 infopath=''
 353 install_pp=''
 354 lispdir='${datadir}/${instvardir}/lisp'
 355 moduledir='${datadir}/${instvardir}/${configuration}/modules'
 356 sitelispdir='${datadir}/${inststaticdir}/site-lisp'
 357 sitemoduledir='${datadir}/${inststaticdir}/site-modules'
 358 pkgdir='${datadir}/${instvardir}/lisp'
 359 package_path=''
 360 etcdir='${datadir}/${instvardir}/etc'
 361 archlibdir='${datadir}/${instvardir}/${configuration}'
 362 docdir='${archlibdir}'
 363 with_prefix='yes'
 364 with_site_lisp='no'
 365 with_site_modules='yes'
 366 with_menubars=''
 367 with_scrollbars=''
 368 with_widgets=''
 369 with_dialogs=''
 370 with_file_coding=''
 371 cpp='' cppflags='' libs='' ldflags=''
 372 extra_includes=''
 373 dynamic=''
 374 with_x11=''
 375 with_msw=''
 376 rel_alloc='default'
 377 with_system_malloc='default'
 378 with_dlmalloc='default'
 379 native_sound_lib=''
 380 dnl use_assertions should be 'yes' by default.  Too many people in this
 381 dnl world have core dumps turned off by default or \"cannot find where the
 382 dnl core file went\".  At least we should get some useful output ...
 383 use_assertions="yes"
 384 dnl the following is set to yes or no later.
 385 with_toolbars=""
 386 with_tty=""
 387 use_union_type="no"
 388 with_dnet=""
 389 pdump="no"
 390 dnl dragndrop is still experimental.  When it is stable, comment out the following line:
 391 with_dragndrop="no"
 392
 393 dnl ------------------
 394 dnl Options Processing
 395 dnl ------------------
 396
 397 define([USAGE_ERROR],
 398 [(echo "$progname: Usage error:"
 399 echo " " $1
 400 echo "  Use \`$progname --help' to show usage.") >&2 && exit 1])
 401
 402 dnl Record all the arguments, so we can save them in config.status.
 403 arguments="$@"
 404
 405 dnl Shell Magic: Quote the quoted arguments in ARGUMENTS.  At a later date,
 406 dnl in order to get the arguments back in $@, we have to do an
 407 dnl 'eval set x "$quoted_arguments"; shift'
 408 dnl # We use sed to turn embedded ' into '"'"'.  I truly hate sh quoting.
 409 quoted_sed_magic=s/"'"/"'"'"'"'"'"'"'"/g
 410 quoted_arguments=
 411 for i in "$@"; do
 412    case "$i" in
 413    -no-create | --no-create | --no-creat | --no-crea | --no-cre \
 414    | --no-cr | --no-c) ;;
 415    -no-recursion | --no-recursion | --no-recursio | --no-recursi \
 416    | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;
 417    *)
 418    quoted_i="`echo '' $i | sed -e 's:^ ::' -e $quoted_sed_magic`"
 419    quoted_arguments="$quoted_arguments '$quoted_i'" ;;
 420    esac
 421 done
 422
 423 dnl Do not use shift -- that destroys the argument list, which autoconf needs
 424 dnl to produce config.status.  It turns out that "set - $arguments" does not
 425 dnl work portably.
 426 dnl However, it also turns out that many shells cannot expand ${10} at all.
 427 dnl So using an index variable does not work either.  It is possible to use
 428 dnl some shell magic to make 'set x "$arguments"; shift' work portably.
 429 while test $# != 0; do
 430   arg="$1"; shift
 431   case "$arg" in
 432     --no-create|--no-recursion) ;;
 433     dnl Anything starting with a hyphen we assume is an option.
 434     -* )
 435       dnl Separate the switch name from the value it is being given.
 436       case "$arg" in
 437         -*=*)
 438           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\([[^=]]*\)=.*$:\1:'`
 439           val=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*[[^=]]*=\(.*\)$:\1:'`
 440           valomitted=no
 441         ;;
 442            dnl special case these strings since echo may silently eat them:
 443            dnl --help ) opt=help val=yes valomitted=yes ;;
 444            dnl --version ) opt=version val=yes valomitted=yes ;;
 445            dnl -e ) opt=e val=yes valomitted=yes ;;
 446            dnl -E ) opt=E val=yes valomitted=yes ;;
 447            dnl -n ) opt=n val=yes valomitted=yes ;;
 448         -*)
 449            dnl If FOO is a boolean argument, --FOO is equivalent to
 450            dnl --FOO=yes.  Otherwise, the value comes from the next
 451            dnl argument - see below.
 452           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\(.*\)$:\1:'`
 453           val="yes" valomitted=yes
 454         ;;
 455       esac
 456
 457       dnl translate "-" in option string to "_"
 458       optname="$opt"
 459       opt="`echo '' $opt | sed -e 's:^ ::' | tr - _`"
 460
 461       dnl Support --without-FOO as a synonym for --with-FOO=no
 462       case "${valomitted}-${opt}" in yes-without_* )
 463         opt=`echo $opt | sed 's/without/with/'`
 464         valomitted="no" val="no" ;;
 465       esac
 466
 467       dnl Process the option.
 468       case "$opt" in
 469
 470       dnl Process (many) boolean options
 471         with_site_lisp  | \
 472         with_prefix     | \
 473         with_site_modules | \
 474         with_x          | \
 475         with_x11        | \
 476         with_msw        | \
 477         with_gcc        | \
 478         dynamic         | \
 479         with_ncurses    | \
 480         with_dnet       | \
 481         with_socks      | \
 482         with_dragndrop  | \
 483         with_cde        | \
 484         with_offix      | \
 485         with_gpm        | \
 486         with_xpm        | \
 487         with_xface      | \
 488         with_gif        | \
 489         with_jpeg       | \
 490         with_png        | \
 491         with_tiff       | \
 492         with_wmcommand  | \
 493         with_xmu        | \
 494         with_purify     | \
 495         with_quantify   | \
 496         with_toolbars   | \
 497         with_tty        | \
 498         with_xfs        | \
 499         with_i18n3      | \
 500         with_mule       | \
 501         with_utf_2000   | \
 502         with_text_coding| \
 503         with_file_coding| \
 504         with_canna      | \
 505         with_wnn        | \
 506         with_wnn6       | \
 507         with_workshop   | \
 508         with_sparcworks | \
 509         with_tooltalk   | \
 510         with_ldap       | \
 511         with_postgresql | \
 512         with_pop        | \
 513         with_kerberos   | \
 514         with_hesiod     | \
 515         with_dnet       | \
 516         with_infodock   | \
 517         external_widget | \
 518         verbose         | \
 519         extra_verbose   | \
 520         usage_tracking  | \
 521         use_union_type  | \
 522         pdump           | \
 523         debug           | \
 524         use_assertions  | \
 525         memory_usage_stats | \
 526         with_clash_detection | \
 527         with_modules | \
 528         quick_build )
 529           dnl Make sure the value given was either "yes" or "no".
 530           case "$val" in
 531             y | ye | yes )      val=yes ;;
 532             n | no )            val=no  ;;
 533             * ) USAGE_ERROR("The \`--$optname' option requires a boolean value: \`yes' or \`no'.") ;;
 534           esac
 535           eval "$opt=\"$val\"" ;;
 536
 537
 538         dnl Options that take a user-supplied value, as in --x-includes=/usr/X11R6/include
 539         dnl The cache-file option is ignored (for compatibility with other configures)
 540         srcdir          | \
 541         compiler        | \
 542         cflags          | \
 543         cpp             | \
 544         cppflags        | \
 545         libs            | \
 546         ldflags         | \
 547         cache_file      | \
 548         native_sound_lib| \
 549         site_lisp       | \
 550         x_includes      | \
 551         x_libraries     | \
 552         site_includes   | \
 553         site_libraries  | \
 554         site_prefixes   | \
 555         site_runtime_libraries )
 556           dnl If the value was omitted, get it from the next argument.
 557           if test "$valomitted" = "yes" ; then
 558             dnl Get the next argument from the argument list, if there is one.
 559             if test "$#" = 0 ; then
 560               USAGE_ERROR("The \`--$optname' option requires a value.");
 561             fi
 562             val="$1"; shift
 563           fi
 564           eval "$opt=\"$val\""
 565         ;;
 566
 567         dnl Options that take "yes", "no", or "default" values
 568         rel_alloc | \
 569         with_dlmalloc | \
 570         with_debug_malloc  | use_debug_malloc | \
 571         with_system_malloc | use_system_malloc )
 572           case "$val" in
 573             y | ye | yes )      val=yes ;;
 574             n | no )            val=no  ;;
 575             d | de | def | defa | defau | defaul | default ) val=default ;;
 576             * ) USAGE_ERROR(["The \`--$optname' option requires one of these values:
 577   \`yes', \`no', or \`default'."]) ;;
 578           esac
 579           case "$opt" in use_* ) opt="`echo $opt | sed s/use/with/`" ;; esac
 580           eval "$opt=\"$val\""
 581         ;;
 582
 583         dnl Has the user requested database support?
 584         "with_database" )
 585           with_database_berkdb=no
 586           with_database_dbm=no
 587           with_database_gdbm=no
 588           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 589             case "$x" in
 590               no ) ;;
 591               b | be | ber | berk | berkd | berkdb )       with_database_berkdb=yes ;;
 592               d | db | dbm )                               with_database_dbm=yes    ;;
 593               g | gn | gnu | gnud | gnudb | gnudbm | gdbm) with_database_gdbm=yes   ;;
 594               * ) USAGE_ERROR(["The \`--$optname' option value
 595   must be either \`no' or a comma-separated list
 596   of one or more of \`berkdb' and either \`dbm' or \`gnudbm'."]) ;;
 597             esac
 598           done
 599           if test "$with_database_dbm"  = "yes" -a \
 600                   "$with_database_gdbm" = "yes"; then
 601           USAGE_ERROR("Only one of \`dbm' and \`gnudbm' may be specified
 602   with the \`--$optname' option.")
 603           fi
 604         ;;
 605
 606         dnl Has the user requested sound support?
 607         "with_sound" )
 608         dnl values is a subset of all,native,nas,esd
 609         dnl or their negatives: none,nonative,nonas,noesd
 610           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 611             case "$x" in
 612               dnl all and none are only permitted as the first in the list.
 613               n | no | non | none ) new_sdefault=no ;;
 614               a | al | all | both ) new_sdefault=yes ;;
 615
 616               native )       with_native_sound=yes ;;
 617               nonative )     with_native_sound=no ;;
 618
 619               nas )          with_nas_sound=yes ;;
 620               nonas )        with_nas_sound=no ;;
 621
 622               esd )          with_esd_sound=yes ;;
 623               noesd )        with_esd_sound=no ;;
 624
 625               * ) bogus_sound=yes ;;
 626             esac
 627             if test "$bogus_sound" -o \
 628                  \( -n "$new_sdefault" -a -n "$sound_notfirst" \) ; then
 629                 types="\`all', \`none', \`(no)native', \`no(nas)', \`(no)esd'."
 630                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 631   $types.
 632 The default is to autodetect all sound support."])
 633             elif test -n "$new_sdefault" ; then
 634                 with_native_sound=$new_sdefault
 635                 with_nas_sound=$new_sdefault
 636                 with_esd_sound=$new_sdefault
 637                 new_sdefault=   # reset this
 638             fi
 639             sound_notfirst=true
 640           done
 641         ;;
 642
 643         dnl Has the user specified a preferred Athena widget set?
 644         dnl This bit expands any alias names out for us...
 645         "with_athena" )
 646           case "$val" in
 647             xa | xaw )                    val=xaw    ;;
 648             3 | 3d | xaw3d )              val=3d     ;;
 649             dnl No `n' for next, someone may try `no'
 650             ne | nex | next | naxtaw)     val=next   ;;
 651             dnl Have not tested the next two...
 652             9 | 95 | xaw95 )              val=95     ;;
 653             xp | xpm | xawxpm )           val=xpm    ;;
 654             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 655   \`xaw', \`3d', \`next', \`95', or \`xpm'."]) ;;
 656           esac
 657           eval "$opt=\"$val\""
 658         ;;
 659
 660         dnl Has the user requested XIM support?
 661         "with_xim" )
 662           case "$val" in
 663             y | ye | yes )                val=yes   ;;
 664             n | no | non | none )         val=no    ;;
 665             x | xl | xli | xlib )         val=xlib  ;;
 666             m | mo | mot | moti | motif ) val=motif ;;
 667             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 668   \`motif', \`xlib', \`yes', or \`no'."]) ;;
 669           esac
 670           eval "$opt=\"$val\""
 671         ;;
 672
 673         dnl Mail locking specification
 674         "mail_locking" )
 675           case "$val" in
 676             lockf )     val=lockf ;;
 677             flock )     val=flock ;;
 678             file | dot ) val=file  ;;
 679             locking )   val=locking  ;;
 680             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 681   \`lockf', \`flock', \`file', \`locking', or \`mmdf'."]) ;;
 682           esac
 683           eval "$opt=\"$val\""
 684         ;;
 685
 686         dnl Has the user requested error-checking?
 687         "error_checking" )
 688           dnl value can be all, none, and/or a list of categories to check.
 689           dnl Example: --error-checking=all,noextents,nobufpos
 690           dnl Example: --error-checking=none,malloc,gc
 691
 692           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 693             case "$x" in
 694               dnl all and none are only permitted as the first in the list.
 695               n | no | non | none ) new_default=no ;;
 696               a | al | all )        new_default=yes ;;
 697
 698               extents )       error_check_extents=yes ;;
 699               noextents )     error_check_extents=no ;;
 700
 701               typecheck )     error_check_typecheck=yes ;;
 702               notypecheck )   error_check_typecheck=no ;;
 703
 704               bufpos )        error_check_bufpos=yes ;;
 705               nobufpos )      error_check_bufpos=no ;;
 706
 707               gc )            error_check_gc=yes ;;
 708               nogc )          error_check_gc=no ;;
 709
 710               malloc )        error_check_malloc=yes ;;
 711               nomalloc )      error_check_malloc=no ;;
 712
 713               byte_code )     error_check_byte_code=yes ;;
 714               nobyte_code )   error_check_byte_code=no ;;
 715
 716               glyphs )     error_check_glyphs=yes ;;
 717               noglyphs )   error_check_glyphs=no ;;
 718
 719               * ) bogus_error_check=yes ;;
 720             esac
 721             if test "$bogus_error_check" -o \
 722                  \( -n "$new_default" -a -n "$echeck_notfirst" \) ; then
 723                 if test "$error_check_default" = yes ; then
 724                   types="\`all' (default), \`none', \`noextents', \`notypecheck', \`nobufpos', \`nogc', \`nomalloc', \`noglyphs' and \`nobyte-code'."
 725                 else
 726                   types="\`all', \`none' (default), \`extents', \`typecheck', \`bufpos', \`gc', \`malloc', \`glyphs' and \`byte-code'."
 727                 fi
 728                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 729   $types."])
 730             elif test -n "$new_default" ; then
 731                 error_check_extents=$new_default
 732                 error_check_typecheck=$new_default
 733                 error_check_bufpos=$new_default
 734                 error_check_gc=$new_default
 735                 error_check_malloc=$new_default
 736                 error_check_byte_code=$new_default
 737                 error_check_glyphs=$new_default
 738                 new_default=    # reset this
 739             fi
 740             echeck_notfirst=true
 741           done
 742         ;;
 743
 744         dnl Has the user tried to tell us where the X files are?
 745         dnl I think these are dopey, but no less than three alpha
 746         dnl testers, at large sites, have said they have their X files
 747         dnl installed in odd places.
 748
 749         dnl Has the user specified one of the path options?
 750         prefix | exec_prefix | bindir | datadir | statedir | libdir | \
 751         mandir | infodir | infopath | lispdir | etcdir | pkgdir | \
 752         archlibdir | docdir | package_path )
 753            dnl If the value was omitted, get it from the next argument.
 754            if test "$valomitted" = "yes"; then
 755              if test "$#" = 0; then
 756                  USAGE_ERROR("The \`--$optname' option requires a value.");
 757              fi
 758              val="$1"; shift
 759            fi
 760            eval "$opt=\"$val\""
 761
 762            dnl You need to synchronize this with the way the
 763            dnl default values are built.
 764            case "$opt" in
 765              dnl prefix is taken care of by --with-prefix
 766              exec_prefix ) AC_DEFINE(EXEC_PREFIX_USER_DEFINED) ;;
 767              lispdir ) AC_DEFINE(LISPDIR_USER_DEFINED) ;;
 768              sitelispdir ) AC_DEFINE(SITELISPDIR_USER_DEFINED) ;;
 769              moduledir ) AC_DEFINE(MODULEDIR_USER_DEFINED) ;;
 770              etcdir  )  AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 771              infodir ) AC_DEFINE(INFODIR_USER_DEFINED) ;;
 772              infopath ) AC_DEFINE(INFOPATH_USER_DEFINED) ;;
 773              package_path ) AC_DEFINE(PACKAGE_PATH_USER_DEFINED) ;;
 774              datadir )
 775                 AC_DEFINE(INFODIR_USER_DEFINED)
 776                 AC_DEFINE(LISPDIR_USER_DEFINED)
 777             AC_DEFINE(MODULEDIR_USER_DEFINED)
 778                 AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 779              docdir ) AC_DEFINE(DOCDIR_USER_DEFINED) ;;
 780              exec_prefix | libdir | archlibdir ) AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
 781            esac
 782         ;;
 783
 784         dnl --no-create added by autoconf for use by config.status
 785         "no_create" ) ;;
 786
 787         dnl Has the user asked for some help?
 788         "usage" | "help" ) ${PAGER-more} ${srcdir}/configure.usage; exit 0 ;;
 789
 790         dnl Has the user specified the toolkit(s) to use for GUI elements?
 791         "with_menubars"   | \
 792         "with_scrollbars" | \
 793         "with_dialogs"    | \
 794         "with_widgets" )
 795           case "$val" in
 796             l | lu | luc | luci | lucid )               val=lucid  ;;
 797             m | mo | mot | moti | motif )               val=motif  ;;
 798             a | at | ath | athe | athen | athena )      val=athena ;;
 799             n | no | non | none )                       val=no     ;;
 800             y | ye | yes )                              val=yes    ;;
 801             m | ms | msw )                      val=msw    ;;
 802             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 803   \`lucid', \`motif', \`athena', \`yes', or \`no'."]) ;;
 804           esac
 805           eval "$opt=\"$val\""
 806         ;;
 807
 808         dnl Obsolete legacy argument?  Warn, but otherwise ignore.
 809         "use_minimal_tagbits" | \
 810         "use_indexed_lrecord_implementation" | \
 811         "run_in_place"  | \
 812         "const_is_losing" | \
 813         "with_gnu_make" )
 814           AC_MSG_WARN([Obsolete option \`--$optname' ignored.])
 815         ;;
 816
 817         dnl Unrecognized option?  No mercy for user errors.
 818         * ) USAGE_ERROR("Unrecognized option: $arg") ;;
 819
 820       esac
 821     ;;
 822
 823     dnl Assume anything with multiple hyphens is a configuration name.
 824     *-*-*) configuration="$arg" ;;
 825
 826     dnl Unrecognized argument?  No mercy for user errors.
 827     *) USAGE_ERROR("Unrecognized argument: $arg") ;;
 828
 829   esac
 830 done
 831
 832 dnl -------------------------
 833 dnl Finish options processing
 834 dnl -------------------------
 835
 836 dnl Several options are equivalent to, and override, environment variables.
 837 test -n "$cpp"      && CPP="$cpp"
 838 test -n "$cppflags" && CPPFLAGS="$cppflags"
 839 test -n "$libs"     && LIBS="$libs"
 840 test -n "$ldflags"  && LDFLAGS="$ldflags"
 841
 842 dnl Get the arguments back.  See the diatribe on Shell Magic above.
 843 eval set x "$quoted_arguments"; shift
 844
 845 dnl --extra-verbose implies --verbose
 846 test "$extra_verbose" = "yes" && verbose=yes
 847
 848 dnl with_x is an obsolete synonym for with_x11
 849 test -n "$with_x" && with_x11="$with_x"
 850
 851 dnl --with-quantify or --with-purify imply --use-system-malloc
 852 if test "$with_purify" = "yes" -o "$with_quantify" = "yes"; then
 853   test "$with_system_malloc" = "default" && with_system_malloc=yes
 854 fi
 855
 856 dnl XE_CHECK_FEATURE_DEPENDENCY(feature1, feature2)
 857 define([XE_CHECK_FEATURE_DEPENDENCY],
 858 [if test "$with_$1 $with_$2" = "yes no"; then
 859   USAGE_ERROR("--with-$1 requires --with-$2")
 860 elif test "$with_$2" = "no" ; then with_$1=no
 861 elif test "$with_$1" = "yes"; then with_$2=yes
 862 fi
 863 ])
 864
 865 dnl CDE requires tooltalk
 866 XE_CHECK_FEATURE_DEPENDENCY(cde, tooltalk)
 867
 868 dnl Find the source directory.
 869 case "$srcdir" in
 870
 871   dnl If srcdir is not specified, see if  "." or ".." might work.
 872   "" )
 873     for dir in "`echo $0 | sed 's|//|/|' | sed 's|/[[^/]]*$||'`" "." ".." ; do
 874       if test -f "$dir/src/lisp.h" -a \
 875               -f "$dir/lisp/version.el" ; then
 876         srcdir="$dir"
 877         break
 878       fi
 879     done
 880     if test -z "$srcdir" ; then
 881       USAGE_ERROR(["Neither the current directory nor its parent seem to
 882   contain the XEmacs sources.  If you do not want to build XEmacs in its
 883   source tree, you should run \`$progname' in the directory in which
 884   you wish to build XEmacs, using the \`--srcdir' option to say where the
 885   sources may be found."])
 886     fi
 887   ;;
 888
 889   dnl Otherwise, check if the directory they specified is okay.
 890   * )
 891     if test ! -f "$srcdir/src/lisp.h" -o \
 892             ! -f "$srcdir/lisp/version.el" ; then
 893       USAGE_ERROR(["The directory specified with the \`--srcdir' option,
 894   \`$srcdir', doesn't seem to contain the XEmacs sources.  You should
 895   either run the \`$progname' script at the top of the XEmacs source
 896   tree, or use the \`--srcdir' option to specify the XEmacs source directory."])
 897     fi
 898   ;;
 899 esac
 900
 901 dnl ###########################################################################
 902 if test -z "$configuration"; then
 903   dnl Guess the configuration
 904   configuration=`${CONFIG_SHELL-/bin/sh} $srcdir/config.guess`
 905   if test -z "$configuration"; then
 906     USAGE_ERROR(["XEmacs has not been ported to this host type.
 907 Try explicitly specifying the CONFIGURATION when rerunning configure."])
 908   fi
 909 fi
 910
 911 AC_PROG_LN_S
 912
 913 dnl Make symlinks for etc, lisp, and info directories while the path
 914 dnl is still relative.  We do not symlink lock because someone may
 915 dnl have stuck the source on a read-only partition.  Instead we
 916 dnl create it as an actual directory later on if it does not already
 917 dnl exist.
 918 for dir in lisp etc man info tests; do
 919   if test ! -d "$dir" ; then
 920     echo Making symbolic link to "$srcdir/$dir"
 921     ${LN_S} "$srcdir/$dir" "$dir"
 922   fi
 923 done
 924
 925 dnl Do our best to deal with automounter brokenness
 926 dnl CANONICALIZE_PATH(varname)
 927 define([CANONICALIZE_PATH],
 928 [if test -d "/net"; then
 929   if test -d "/tmp_mnt/net"; then tdir="tmp_mnt/net"; else tdir="tmp_mnt"; fi
 930   $1=`echo "[$]$1" | \
 931    sed -e "s|^${tdir}/|/net/|" -e "s|^/a/|/net/|" -e "s|^/amd/|/net/|"`
 932 fi])dnl
 933
 934 dnl Calculate canonical name for blddir (i.e. current directory).
 935 dnl PWD may already be the preferable absolute name for ".",
 936 dnl but we can't trust it - it is sometimes inaccurate.
 937 absolute_pwd="`pwd`";
 938 if test -n "$PWD" -a "`cd $PWD && pwd`" = "$absolute_pwd"
 939 then blddir="$PWD"
 940 else blddir="$absolute_pwd"; CANONICALIZE_PATH(blddir)
 941 fi
 942 AC_SUBST(blddir)
 943
 944 dnl Make srcdir absolute, if not already.  It is important to
 945 dnl avoid running the path through pwd unnecessary, since pwd can
 946 dnl give you automounter prefixes, which can go away.
 947 case "$srcdir" in
 948   /* ) ;;
 949   .  ) srcdir="$blddir" ;;
 950   *  ) srcdir="`cd $srcdir && pwd`"; CANONICALIZE_PATH(srcdir) ;;
 951 esac
 952
 953 dnl Check if the source directory already has a configured system in it.
 954 if test `pwd` != `sh -c cd $srcdir && pwd`  \
 955    && test -f "$srcdir/src/config.h"; then
 956   (echo "$progname: WARNING: The directory tree \`$srcdir' is being used"
 957    echo "   as a build directory right now; it has been configured in its own"
 958    echo "   right.  To configure in another directory as well, you MUST"
 959    echo "   use GNU make.  If you do not have GNU make, then you must"
 960    echo "   now do \`make distclean' in $srcdir,"
 961    echo "   and then run $progname again.") >&2
 962   extrasub='/^VPATH[[    ]]*=/c\
 963 vpath %.c $(srcdir)\
 964 vpath %.h $(srcdir)\
 965 vpath %.y $(srcdir)\
 966 vpath %.l $(srcdir)\
 967 vpath %.s $(srcdir)\
 968 vpath %.in $(srcdir)'
 969 fi
 970
 971 dnl ----------------------------------------
 972 dnl Find out which version of XEmacs this is
 973 dnl ----------------------------------------
 974 . "$srcdir/version.sh" || exit 1;
 975 dnl Must do the following first to determine verbosity for AC_DEFINE
 976 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
 977 : "${extra_verbose=$beta}"
 978 version="${emacs_major_version}.${emacs_minor_version}"
 979 AC_DEFINE_UNQUOTED(EMACS_MAJOR_VERSION, $emacs_major_version)
 980 AC_DEFINE_UNQUOTED(EMACS_MINOR_VERSION, $emacs_minor_version)
 981 if test -n "$emacs_beta_version" ; then
 982   if test "$beta" = "yes"; then
 983         version="${version}-b${emacs_beta_version}"
 984         AC_DEFINE_UNQUOTED(EMACS_BETA_VERSION, $emacs_beta_version)
 985   else
 986         version="${version}.${emacs_beta_version}"
 987         AC_DEFINE_UNQUOTED(EMACS_PATCH_LEVEL, $emacs_beta_version)
 988   fi
 989 fi
 990 AC_DEFINE_UNQUOTED(XEMACS_CODENAME, "$xemacs_codename")
 991 AC_DEFINE_UNQUOTED(EMACS_VERSION, "$version")
 992
 993 if test "$with_infodock" = "yes"; then
 994   if test ! -f ../../ID-INSTALL; then
 995     echo "Cannot build InfoDock without InfoDock sources"
 996     with_infodock=no
 997   fi
 998 fi
 999
1000 if test "$with_infodock" = "yes"; then
1001   dnl InfoDock version numbers.  XEmacs will use the same style of numbering
1002   dnl after the release of XEmacs 21.0.
1003   AC_DEFINE_UNQUOTED(INFODOCK_MAJOR_VERSION, $infodock_major_version)
1004   AC_DEFINE_UNQUOTED(INFODOCK_MINOR_VERSION, $infodock_minor_version)
1005   AC_DEFINE_UNQUOTED(INFODOCK_BUILD_VERSION, $infodock_build_version)
1006   version=${infodock_major_version}.${infodock_minor_version}.${infodock_build_version}
1007   PROGNAME=infodock
1008   CPPFLAGS="$CPPFLAGS -DINFODOCK"
1009 else
1010   PROGNAME=xemacs
1011 fi
1012
1013 AC_DEFINE_UNQUOTED(EMACS_PROGNAME, "$PROGNAME")
1014
1015 dnl ----------------------------------
1016 dnl Error checking and debugging flags
1017 dnl ----------------------------------
1018 dnl Error checking default to "yes" in beta versions, to "no" in releases.
1019 dnl Same goes for --debug and --extra-verbosity.
1020 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
1021 test "${error_check_extents=$beta}"   = yes && AC_DEFINE(ERROR_CHECK_EXTENTS)
1022 test "${error_check_typecheck=$beta}" = yes && AC_DEFINE(ERROR_CHECK_TYPECHECK)
1023 test "${error_check_bufpos=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_BUFPOS)
1024 test "${error_check_gc=$beta}"        = yes && AC_DEFINE(ERROR_CHECK_GC)
1025 test "${error_check_malloc=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_MALLOC)
1026 test "${error_check_byte_code=$beta}" = yes && AC_DEFINE(ERROR_CHECK_BYTE_CODE)
1027 test "${error_check_glyphs=$beta}" = yes && AC_DEFINE(ERROR_CHECK_GLYPHS)
1028 dnl debug=yes must be set when error checking is present.  This should be
1029 dnl fixed up.
1030 dnl debug implies other options
1031 if test "${debug:=$beta}" = "yes"; then
1032   use_assertions=yes memory_usage_stats=yes
1033   XE_ADD_OBJS(debug.o)
1034   XE_ADD_OBJS(tests.o)
1035   AC_DEFINE(DEBUG_XEMACS)
1036 fi
1037 test "$use_assertions"     = "yes" && AC_DEFINE(USE_ASSERTIONS)
1038 test "$memory_usage_stats" = "yes" && AC_DEFINE(MEMORY_USAGE_STATS)
1039
1040 dnl ------------------------------
1041 dnl Determine the s&m files to use
1042 dnl ------------------------------
1043 dnl Given the configuration name, set machfile and opsysfile to the
1044 dnl names of the m/*.h and s/*.h files we should use.
1045
1046 dnl Canonicalize the configuration name.
1047 AC_MSG_CHECKING("host system type")
1048 dnl allow -workshop suffix on configuration name
1049 internal_configuration=`echo $configuration | sed 's/-\(workshop\)//'`
1050 canonical=`${CONFIG_SHELL-/bin/sh} $srcdir/config.sub "$internal_configuration"`
1051 XE_STRIP_4TH_COMPONENT(configuration)
1052 XE_STRIP_4TH_COMPONENT(canonical)
1053 AC_MSG_RESULT($configuration)
1054
1055 dnl If you add support for a new configuration, add code to this
1056 dnl switch statement to recognize your configuration name and select
1057 dnl the appropriate operating system and machine description files.
1058
1059 dnl You would hope that you could choose an m/*.h file pretty much
1060 dnl based on the machine portion of the configuration name, and an s-
1061 dnl file based on the operating system portion.  However, it turns out
1062 dnl that each m/*.h file is pretty manufacturer-specific - for
1063 dnl example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
1064 dnl all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
1065 dnl machines.  So we basically have to have a special case for each
1066 dnl configuration name.
1067
1068 dnl As far as handling version numbers on operating systems is
1069 dnl concerned, make sure things will fail in a fixable way.  If
1070 dnl /etc/MACHINES says nothing about version numbers, be
1071 dnl prepared to handle anything reasonably.  If version numbers
1072 dnl matter, be sure /etc/MACHINES says something about it.
1073
1074 dnl Eric Raymond says we should accept strings like "sysvr4" to mean
1075 dnl "System V Release 4"; he writes, "The old convention encouraged"
1076 dnl "confusion between `system' and `release' levels'."
1077
1078 machine='' opsys=''
1079
1080 dnl Straightforward machine determination
1081 case "$canonical" in
1082   sparc-*-*        ) machine=sparc ;;
1083   alpha*-*-*       ) machine=alpha ;;
1084   vax-*-*          ) machine=vax ;;
1085   mips-dec-*       ) machine=pmax ;;
1086   mips-sgi-irix6*  ) machine=iris6d ;;
1087   mips-sgi-*       ) machine=iris4d ;;
1088   mips*-linux      ) machine=mips ;;
1089   romp-ibm-*       ) machine=ibmrt ;;
1090   rs6000-ibm-aix*  ) machine=ibmrs6000 ;;
1091   powerpc-ibm-aix* ) machine=ibmrs6000 ;;
1092   powerpc*-*       ) machine=powerpc ;;
1093   hppa-*-*         ) machine=hp800 ;;
1094   m88k-dg-*        ) machine=aviion ;;
1095   m68*-sony-*      ) machine=news ;;
1096   mips-sony-*      ) machine=news-risc ;;
1097   clipper-*        ) machine=clipper ;;
1098   arm*             ) machine=arm ;;
1099   ns32k-*          ) machine=ns32000 ;;
1100 esac
1101
1102 dnl Straightforward OS determination
1103 case "$canonical" in
1104   *-*-linux*    ) opsys=linux ;;
1105   *-*-netbsd*   ) opsys=netbsd ;;
1106   *-*-openbsd*  ) opsys=openbsd ;;
1107   *-*-nextstep* ) opsys=nextstep ;;
1108   *-*-vms       ) opsys=vms ;;
1109
1110   dnl DEC OSF
1111   *-dec-osf1.3 | *-dec-osf2* ) opsys=decosf1-3 ;;
1112   *-dec-osf1.2 | *-dec-osf1* ) opsys=decosf1-2 ;;
1113   *-dec-osf3.[[2-9]]         ) opsys=decosf3-2 ;;
1114   *-dec-osf3*                ) opsys=decosf3-1 ;;
1115   *-dec-osf[[4-9]]*          ) opsys=decosf4-0 ;;
1116
1117   dnl DEC Ultrix
1118   *-*-ultrix[[0-3]].* | *-*-ultrix4.0* ) opsys=bsd4-2 ;;
1119   *-*-ultrix4.[[12]]* ) opsys=bsd4-3 ;;
1120   *-*-ultrix* )         opsys=ultrix4-3 ;;
1121
1122   dnl AIX
1123   *-*-aix3.1*  ) opsys=aix3-1   ;;
1124   *-*-aix3.2.5 ) opsys=aix3-2-5 ;;
1125   *-*-aix3*    ) opsys=aix3-2   ;;
1126   *-*-aix4.0*  ) opsys=aix4     ;;
1127   *-*-aix4.1*  ) opsys=aix4-1   ;;
1128   *-*-aix4*    ) opsys=aix4-2   ;;
1129
1130   dnl Other generic OSes
1131   *-gnu* )                      opsys=gnu    ;;
1132   *-*-bsd4.[[01]] )             opsys=bsd4-1 ;;
1133   *-*-bsd4.2 )                  opsys=bsd4-2 ;;
1134   *-*-bsd4.3 )                  opsys=bsd4-3 ;;
1135   *-*-aos4.2 )                  opsys=bsd4-2 ;;
1136   *-*-aos*   )                  opsys=bsd4-3 ;;
1137   *-*-sysv0    | *-*-sysvr0 )   opsys=usg5-0 ;;
1138   *-*-sysv2    | *-*-sysvr2 )   opsys=usg5-2 ;;
1139   *-*-sysv2.2  | *-*-sysvr2.2 ) opsys=usg5-2-2 ;;
1140   *-*-sysv3*   | *-*-sysvr3* )  opsys=usg5-3 ;;
1141   *-*-sysv4.1* | *-*-sysvr4.1* )opsys=usg5-4 NON_GNU_CPP=/usr/lib/cpp ;;
1142   *-*-sysv4.[[2-9]]* | *-sysvr4.[[2-9]]* )
1143         if test -z "$NON_GNU_CPP" ; then
1144           for prog in "/usr/ccs/lib/cpp" "/lib/cpp"; do
1145             if test -f "$prog"; then NON_GNU_CPP="$prog"; break; fi
1146           done
1147         fi
1148         opsys=usg5-4-2 ;;
1149     *-sysv4* | *-sysvr4* )      opsys=usg5-4 ;;
1150     *-*-mach_bsd4.3* )          opsys=mach-bsd4-3 ;;
1151 esac
1152
1153 case "$canonical" in
1154
1155   dnl NetBSD ports
1156   *-*-netbsd* )
1157     case "$canonical" in
1158       i[[3-9]]86-*-netbsd*) machine=intel386 ;;
1159       hp300-*-netbsd* | amiga-*-netbsd* | sun3-*-netbsd* | mac68k-*-netbsd* | da30-*-netbsd* | m68k-*-netbsd* )
1160                       dnl Yes, this is somewhat bogus.
1161                       machine=hp9000s300 ;;
1162       pc532-*-netbsd* | ns32k-*-netbsd* )  machine=ns32000 ;;
1163       pmax-*-netbsd*  | mips-*-netbsd*  )  machine=pmax ;;
1164     esac
1165   ;;
1166
1167   dnl OpenBSD ports
1168   *-*-openbsd* )
1169     case "${canonical}" in
1170       i386-*-openbsd*)          machine=intel386 ;;
1171       m68k-*-openbsd*)          machine=hp9000s300 ;;
1172       mipsel-*-openbsd*)        machine=pmax ;;
1173      esac
1174    ;;
1175
1176   dnl Acorn RISCiX:
1177   arm-acorn-riscix1.1* ) machine=acorn opsys=riscix1-1 ;;
1178   arm-acorn-riscix1.2* | arm-acorn-riscix ) machine=acorn opsys=riscix1-2 ;;
1179
1180   dnl Alliant machines
1181   fx80-alliant-* ) machine=alliant4     opsys=bsd4-2 ;;
1182   i860-alliant-* ) machine=alliant-2800 opsys=bsd4-3 ;;
1183
1184   dnl Altos 3068
1185   m68*-altos-sysv* ) machine=altos opsys=usg5-2 ;;
1186
1187   dnl Amdahl UTS
1188   580-amdahl-sysv* ) machine=amdahl opsys=usg5-2-2 ;;
1189
1190   dnl Apollo, Domain/OS
1191   m68*-apollo-* ) machine=apollo opsys=bsd4-3 ;;
1192
1193   dnl AT&T 3b2, 3b5, 3b15, 3b20
1194   we32k-att-sysv* ) machine=att3b opsys=usg5-2-2 ;;
1195
1196   dnl AT&T 3b1 - The Mighty Unix PC!
1197   m68*-att-sysv* ) machine=7300 opsys=usg5-2-2 ;;
1198
1199   dnl Bull machines
1200   rs6000-bull-bosx* ) machine=ibmrs6000 opsys=aix3-2 ;; # dpx20
1201   m68*-bull-sysv3*  ) machine=dpx2      opsys=usg5-3 ;; # dpx2
1202   m68*-bull-sysv2*  ) machine=sps7      opsys=usg5-2 ;; # sps7
1203
1204   dnl CCI 5/32, 6/32 -- see "Tahoe".
1205
1206   dnl Celerity
1207   celerity-celerity-bsd* ) machine=celerity opsys=bsd4-2 ;;
1208
1209   dnl Convex
1210   *-convex-bsd* | *-convex-convexos* )
1211     machine=convex opsys=bsd4-3
1212     NON_GNU_CPP="cc -E -P"
1213   ;;
1214
1215   dnl Cubix QBx/386
1216   i[[3-9]]86-cubix-sysv* ) machine=intel386 opsys=usg5-3 ;;
1217
1218   dnl Data General AViiON Machines
1219   i586-dg-dgux*R4*   | i586-dg-dgux5.4.4* ) machine=aviion opsys=dgux5-4r4 ;;
1220   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* ) opsys=dgux5-4r3 ;;
1221   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* ) opsys=dgux5-4r2 ;;
1222   m88k-dg-dgux*                           ) opsys=dgux     ;;
1223
1224   dnl Motorola Delta machines
1225   m68k-motorola-sysv* | m68000-motorola-sysv* ) machine=delta opsys=usg5-3 ;;
1226   m88k-motorola-sysv4* )
1227     dnl jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
1228     dnl needs POSIX_SIGNALS and therefore needs usg5-4-2.
1229     dnl I hope there are not other 4.0 versions for this machine
1230     dnl which really need usg5-4 instead.
1231     machine=delta88k opsys=usg5-4-2
1232   ;;
1233   m88k-motorola-sysv* | m88k-motorola-m88kbcs* ) machine=delta88k opsys=usg5-3 ;;
1234
1235   dnl Dual machines
1236   m68*-dual-sysv*    ) machine=dual opsys=usg5-2   ;;
1237   m68*-dual-uniplus* ) machine=dual opsys=unipl5-2 ;;
1238
1239   dnl Encore machines
1240   ns16k-encore-bsd* ) machine=ns16000 opsys=umax ;;
1241
1242   dnl Gould Power Node and NP1
1243   pn-gould-bsd4.2* ) machine=gould     opsys=bsd4-2 ;;
1244   pn-gould-bsd4.3* ) machine=gould     opsys=bsd4-3 ;;
1245   np1-gould-bsd* )   machine=gould-np1 opsys=bsd4-3 ;;
1246
1247   dnl Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
1248   dnl as far as XEmacs is concerned).
1249   m88k-harris-cxux* )
1250     dnl Build needs to be different on 7.0 and later releases
1251     case "`uname -r`" in
1252        [[56]].[[0-9]] ) machine=nh4000 opsys=cxux  ;;
1253        [[7]].[[0-9]]  ) machine=nh4000 opsys=cxux7 ;;
1254     esac
1255     NON_GNU_CPP="/lib/cpp"
1256   ;;
1257   dnl Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
1258   m68k-harris-cxux* ) machine=nh3000 opsys=cxux ;;
1259   dnl Harris power pc NightHawk running Power UNIX (Series 6000)
1260   powerpc-harris-powerunix ) machine=nh6000 opsys=powerunix NON_GNU_CPP="cc -Xo -E -P" ;;
1261
1262   dnl Honeywell XPS100
1263   xps*-honeywell-sysv* ) machine=xps100 opsys=usg5-2 ;;
1264
1265   dnl HP 9000 series 200 or 300
1266   m68*-hp-bsd* ) machine=hp9000s300 opsys=bsd4-3 ;;
1267
1268   dnl HP-UX
1269   *-hp-hpux* )
1270     dnl Figure out machine and opsys orthogonally
1271     case "$canonical" in
1272       m68*  ) machine=hp9000s300 ;;
1273       hppa* ) machine=hp800      ;;
1274     esac
1275
1276     case "$canonical" in
1277       *-hp-hpux7*  )  opsys=hpux   ;;
1278       *-hp-hpux8*  )  opsys=hpux8  ;;
1279       *-hp-hpux9*  )  opsys=hpux9  ;;
1280       *-hp-hpux10* )  opsys=hpux10 ;;
1281       *-hp-hpux11* )  opsys=hpux11 ;;
1282       *            )  opsys=hpux   ;;
1283     esac
1284
1285     dnl HP has a broken "strcat"
1286     case "$opsys" in hpux9 | hpux10 ) XE_ADD_OBJS(strcat.o) ;; esac
1287
1288     if test "$opsys" = "hpux10" -o "$opsys" = "hpux11"; then \
1289         ansi_flag="-Ae"; else ansi_flag="-Aa"; fi
1290     NON_GNU_CC="cc $ansi_flag" NON_GNU_CPP="cc $ansi_flag -E"
1291
1292     case "$canonical" in *-hp-hpux*shr* ) opsys="${opsys}-shr" ;; esac
1293   ;;
1294
1295   dnl Orion machines
1296   orion-orion-bsd*   ) machine=orion    opsys=bsd4-2 ;;
1297   clipper-orion-bsd* ) machine=orion105 opsys=bsd4-2 ;;
1298
1299   dnl IBM machines
1300   i[[3-9]]86-ibm-aix1.1* ) machine=ibmps2-aix opsys=usg5-2-2 ;;
1301   i[[3-9]]86-ibm-aix1.[[23]]* | i[[3-9]]86-ibm-aix* ) machine=ibmps2-aix opsys=usg5-3 ;;
1302   i370-ibm-aix*) machine=ibm370aix opsys=usg5-3 ;;
1303   romp-ibm-aos*    ) opsys=bsd4-3 ;;
1304   romp-ibm-bsd*    ) opsys=bsd4-3 ;;
1305   romp-ibm-mach*   ) opsys=mach-bsd4-3 ;;
1306
1307   dnl Integrated Solutions "Optimum V"
1308   m68*-isi-bsd4.2* ) machine=isi-ov opsys=bsd4-2 ;;
1309   m68*-isi-bsd4.3* ) machine=isi-ov opsys=bsd4-3 ;;
1310
1311   dnl Intel 386 machines where we do care about the manufacturer
1312   i[[3-9]]86-intsys-sysv* ) machine=is386 opsys=usg5-2-2 ;;
1313
1314   dnl Prime EXL
1315   i[[3-9]]86-prime-sysv* ) machine=i386 opsys=usg5-3 ;;
1316
1317   dnl Sequent Symmetry running Dynix
1318   i[[3-9]]86-sequent-bsd* ) machine=symmetry opsys=bsd4-3 ;;
1319
1320   dnl Sequent Symmetry running DYNIX/ptx
1321   i[[3-9]]86-sequent-ptx* ) machine=sequent-ptx opsys=ptx NON_GNU_CPP="/lib/cpp" ;;
1322
1323   dnl Unspecified sysv on an ncr machine defaults to svr4.2.
1324   dnl (Plain usg5-4 does not turn on POSIX signals, which we need.)
1325   i[[3-9]]86-ncr-sysv* ) machine=ncr386 opsys=usg5-4-2 ;;
1326
1327   dnl Intel Paragon OSF/1
1328   i860-intel-osf1* ) machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp ;;
1329
1330   dnl Intel 860
1331   i860-*-sysv4* ) machine=i860 opsys=usg5-4 NON_GNU_CC="/bin/cc" NON_GNU_CPP="/usr/ccs/lib/cpp" ;;
1332
1333   dnl Masscomp machines
1334   m68*-masscomp-rtu* ) machine=masscomp opsys=rtu ;;
1335
1336   dnl Megatest machines
1337   m68*-megatest-bsd* ) machine=mega68 opsys=bsd4-2 ;;
1338
1339   dnl Workstations sold by MIPS
1340   dnl This is not necessarily all workstations using the MIPS processor -
1341   dnl Irises are produced by SGI, and DECstations by DEC.
1342   mips-mips-usg* ) machine=mips4 ;;
1343   mips-mips-riscos4 )
1344     machine=mips4
1345     NON_GNU_CC="cc -systype bsd43"
1346     NON_GNU_CPP="cc -systype bsd43 -E"
1347     case "$canonical" in
1348       mips-mips-riscos4* ) opsys=bsd4-3  ;;
1349       mips-mips-riscos5* ) opsys=riscos5 ;;
1350     esac
1351   ;;
1352   mips-mips-bsd* ) machine=mips opsys=bsd4-3 ;;
1353   mips-mips-*    ) machine=mips opsys=usg5-2-2 ;;
1354
1355   dnl NeXT
1356   m68*-next-* | m68k-*-nextstep* ) machine=m68k opsys=nextstep ;;
1357
1358   dnl The complete machine from National Semiconductor
1359   ns32k-ns-genix* ) machine=ns32000 opsys=usg5-2 ;;
1360
1361   dnl NCR machines
1362   m68*-ncr-sysv2* | m68*-ncr-sysvr2* ) machine=tower32   opsys=usg5-2-2 ;;
1363   m68*-ncr-sysv3* | m68*-ncr-sysvr3* ) machine=tower32v3 opsys=usg5-3 ;;
1364
1365   dnl Nixdorf Targon 31
1366   m68*-nixdorf-sysv* ) machine=targon31 opsys=usg5-2-2 ;;
1367
1368   dnl Nu (TI or LMI)
1369   m68*-nu-sysv* ) machine=nu opsys=usg5-2 ;;
1370
1371   dnl Plexus
1372   m68*-plexus-sysv* ) machine=plexus opsys=usg5-2 ;;
1373
1374   dnl Pyramid machines
1375   pyramid-pyramid-bsd* ) machine=pyramid opsys=bsd4-2 ;;
1376
1377   dnl Sequent Balance
1378   ns32k-sequent-bsd4.2* ) machine=sequent opsys=bsd4-2 ;;
1379   ns32k-sequent-bsd4.3* ) machine=sequent opsys=bsd4-3 ;;
1380
1381   dnl Siemens Nixdorf
1382   mips-siemens-sysv* | mips-sni-sysv*)
1383     machine=mips-siemens opsys=usg5-4
1384     NON_GNU_CC=/usr/ccs/bin/cc
1385     NON_GNU_CPP=/usr/ccs/lib/cpp
1386   ;;
1387
1388   dnl NEC
1389   mips-nec-sysv*)
1390     machine=mips-nec
1391     NON_GNU_CC=/usr/ccs/bin/cc
1392     NON_GNU_CPP=/usr/ccs/lib/cpp
1393   ;;
1394
1395   dnl Silicon Graphics machines
1396   dnl Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
1397   m68*-sgi-iris3.5* ) machine=irist opsys=iris3-5 ;;
1398   m68*-sgi-iris3.6* | m68*-sgi-iris*) machine=irist opsys=iris3-6 ;;
1399   dnl Iris 4D
1400   mips-sgi-irix3.*    ) opsys=irix3-3 ;;
1401   mips-sgi-irix4.*    ) opsys=irix4-0 ;;
1402   mips-sgi-irix6*     ) opsys=irix6-0 ;;
1403   mips-sgi-irix5.1*   ) opsys=irix5-1 ;;
1404   mips-sgi-irix5.2*   ) opsys=irix5-2 ;;
1405   mips-sgi-irix5.*    ) opsys=irix5-3 ;;
1406   mips-sgi-irix*      ) opsys=irix5-0 ;;
1407
1408   dnl SONY machines
1409   *-sony-newsos[[34]]* | *-sony-news[[34]]* ) opsys=bsd4-3 ;;
1410   *-sony-news* ) opsys=newsos5 ;;
1411
1412   dnl Stride
1413   m68*-stride-sysv* ) machine=stride opsys=usg5-2 ;;
1414
1415   dnl Suns
1416   *-*-solaris* | *-*-sunos* | *-sun-mach* | *-sun-bsd* )
1417     dnl Hardware type
1418     case "$canonical" in
1419       m68*-sunos1* )             machine=sun1     ;;
1420       m68*-sunos2* )             machine=sun2     ;;
1421       m68* )                     machine=sun3     ;;
1422       i*86*-sun-sunos[[34]]* )   machine=sun386   ;;
1423       i*86-*-* )                 machine=intel386 ;;
1424       rs6000* )                  machine=rs6000   ;;
1425     esac
1426
1427     dnl Make $canonical even more so.
1428     case "$canonical" in *-sunos5*)
1429       canonical=`echo $canonical | sed -e s/sunos5/solaris2/`;;
1430     esac
1431
1432     dnl On SunOS 4, use /usr/lib/cpp, sans dynodump, /bin/ranlib
1433     dnl On SunOS 5, use cc -E,        need dynodump, RANLIB not needed
1434     dnl But, SunOS 5.6 no longer needs dynodump because it has a similar
1435     dnl function integrated.
1436     case "$canonical" in
1437       *-sunos4* )
1438         #test -f /usr/lib/cpp     && NON_GNU_CPP=/usr/lib/cpp ;;
1439         : ;;
1440       *-solaris2* )
1441         #test -f /usr/ccs/lib/cpp && NON_GNU_CPP=/usr/ccs/lib/cpp
1442         RANLIB=':' ;;
1443     esac
1444
1445     case "$canonical" in
1446       *-solaris*          )
1447         opsys=sol2
1448         os_release=`uname -r | sed -e 's/^\([[0-9]]\)\.\([[0-9]]\).*/\1\2/'`
1449         AC_DEFINE_UNQUOTED(OS_RELEASE, $os_release) ;;
1450
1451       dnl The last Sun386 ran 4.0.
1452       i*86-*-sunos4*      ) opsys=sunos4-0      ;;
1453       *-sunos4.0*         ) opsys=sunos4-0      ;;
1454       *-sunos4.1.2*       ) opsys=sunos4-1-2    ;;
1455       *-sunos4.1.3*       ) opsys=sunos4-1-3    ;;
1456       *-sunos4.1.[[4-9]]* ) opsys=sunos4-1-4    ;;
1457       *-sunos4* | *-sunos ) opsys=sunos4-1      ;;
1458       *-mach*             ) opsys=mach-bsd4-3   ;;
1459       *                   ) opsys=bsd4-2        ;;
1460     esac
1461
1462     case "$canonical" in *-sunos4*shr* ) opsys="${opsys}-shr" ;; esac
1463
1464     dnl Watch out for a compiler guaranteed not to work.
1465     test "$opsys $CC" = "sol2 /usr/ucb/cc" && CC=""
1466   ;;
1467
1468   dnl Tadpole 68k
1469   m68*-tadpole-sysv* ) machine=tad68k opsys=usg5-3 ;;
1470
1471   dnl Tahoe machines
1472   tahoe-tahoe-bsd4.2* ) machine=tahoe opsys=bsd4-2 ;;
1473   tahoe-tahoe-bsd4.3* ) machine=tahoe opsys=bsd4-3 ;;
1474
1475   dnl Tandem Integrity S2
1476   mips-tandem-sysv* ) machine=tandem-s2 opsys=usg5-3 ;;
1477
1478   dnl Tektronix XD88
1479   m88k-tektronix-sysv3* ) machine=tekxd88 opsys=usg5-3 ;;
1480
1481   dnl Tektronix 16000 box (6130?)
1482   ns16k-tektronix-bsd* ) machine=ns16000 opsys=bsd4-2 ;;
1483   dnl Tektronix 4300
1484   dnl src/m/tek4300.h hints that this is a m68k machine.
1485   m68*-tektronix-bsd* ) machine=tek4300 opsys=bsd4-3 ;;
1486
1487   dnl Titan P2 or P3
1488   titan-titan-sysv* ) machine=titan opsys=usg5-3 ;;
1489
1490   dnl Ustation E30 (SS5E)
1491   m68*-unisys-uniplus* ) machine=ustation opsystem=unipl5-2 ;;
1492
1493   dnl Vaxen.
1494   vax-dec-* )
1495     case "$canonical" in
1496       *-sysv[[01]]* | *-sysvr[[01]]* )  opsys=usg5-0 ;;
1497       *-sysv2* | *-sysvr2* )            opsys=usg5-2 ;;
1498       *-mach* )                         opsys=mach-bsd4-3 ;;
1499     esac
1500   ;;
1501
1502   dnl Whitechapel MG1
1503   ns16k-whitechapel-* ) machine=mg1 ;;
1504
1505   dnl Wicat
1506   m68*-wicat-sysv* ) machine=wicat opsys=usg5-2 ;;
1507
1508   dnl Intel 386 machines where we do not care about the manufacturer
1509   i[[3-9]]86-*-* )
1510     machine=intel386
1511     case "$canonical" in
1512       *-isc1.* | *-isc2.[[01]]* ) opsys=386-ix ;;
1513       *-isc2.2* )               opsys=isc2-2 ;;
1514       *-isc4.0* )               opsys=isc4-0 ;;
1515       *-isc4.* )                opsys=isc4-1
1516                                 GCC_TEST_OPTIONS=-posix
1517                                 NON_GCC_TEST_OPTIONS=-Xp
1518                                 ;;
1519       *-isc* )                  opsys=isc3-0 ;;
1520       *-esix5* )                opsys=esix5r4 NON_GNU_CPP=/usr/lib/cpp ;;
1521       *-esix* )                 opsys=esix ;;
1522       *-mach* )                 opsys=mach-bsd4-3 ;;
1523       *-xenix* )                opsys=xenix ;;
1524       *-sco3.2v4* )             opsys=sco4 NON_GNU_CPP=/lib/cpp  ;;
1525       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
1526       *-bsdi4* )                opsys=bsdos4 ;;
1527       *-bsdi3* )                opsys=bsdos3 ;;
1528       *-bsdi2.1* )              opsys=bsdos2-1 ;;
1529       *-bsdi2* )                opsys=bsdos2 ;;
1530       *-sco3.2v5* )             opsys=sco5 ;
1531         dnl This is a pain.  Like the current USL cc, SCO cc -E
1532         dnl tokenizes as it preprocesses, making configure very
1533         dnl unhappy.  Unfortunately, /lib/cpp does not understand
1534         dnl flags like "-b elf", so we have to cheat in order to
1535         dnl pick up the right defines for UNEXEC from the s-file.
1536         dnl 01/05/95 robertl@dgii.com
1537         if test "$dynamic" = "yes" ; then
1538                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE -D_SCO_ELF"  ;
1539         else
1540                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE"  ;
1541         fi ;;
1542       *-sysv5* )                opsys=sco7 ;;
1543       *-386bsd* )               opsys=386bsd ;;
1544       *-freebsd* )              opsys=freebsd ;;
1545       *-nextstep* )             opsys=nextstep ;;
1546       *-pc-cygwin* )            opsys=cygwin32 ;;
1547       *-pc-mingw* )             opsys=mingw32 ;
1548                                 test -z "$with_tty" && with_tty="no";;
1549       dnl Otherwise, we fall through to the generic opsys code at the bottom.
1550     esac
1551   ;;
1552
1553   dnl Linux/68k
1554   m68k-*-linux* ) machine=m68k opsys=linux ;;
1555
1556 esac
1557
1558 dnl Initialize machine and opsys from $canonical if not in our database above.
1559 test -z "$machine" && machine=`echo $canonical | sed 's/-.*$//'`
1560 test -z "$opsys"   && opsys=`echo $canonical | sed 's/^[^-]*-[^-]*-//'`
1561
1562 dnl Use configure-time autodetection if s&m not available
1563 if test -r "${srcdir}/src/m/${machine}.h"; then
1564   machfile="m/${machine}.h"
1565   AC_DEFINE_UNQUOTED(config_machfile, "$machfile")
1566 else
1567   echo "XEmacs has no builtin knowledge of \`$machine' machines."
1568   echo "Using configure-time autodetection only."
1569 fi
1570
1571 if test -r "${srcdir}/src/s/${opsys}.h"; then
1572   opsysfile="s/${opsys}.h"
1573   AC_DEFINE_UNQUOTED(config_opsysfile, "$opsysfile")
1574 else
1575   echo "XEmacs has no builtin knowledge of \`$opsys' operating systems."
1576   echo "Using configure-time autodetection only."
1577 fi
1578
1579
1580 if test -z "$dynamic"; then
1581   case "$opsys" in
1582     hpux* | sunos4* ) dynamic=no ;;
1583     *) dynamic=yes ;;
1584   esac
1585 fi
1586 if test "$dynamic" = "yes"; then
1587   case "$opsys" in
1588     hpux* | sunos4* | sco5 ) opsys="${opsys}-shr" ;;
1589     decosf* ) ld_call_shared="-call_shared" ;;
1590   esac
1591 else dnl "$dynamic" = "no"
1592   case "$opsys" in
1593     sol2 )
1594       echo "Static linking is not supported on Solaris 2."
1595       echo "Rerun configure without specifying --dynamic=no."
1596       exit 1 ;;
1597     linux   ) ld_call_shared="-Bstatic" ;;
1598     decosf* ) ld_call_shared="-non_shared" ;;
1599   esac
1600 fi
1601
1602 dnl Use xlc by default on AIX
1603 case "$opsys" in aix*) NON_GNU_CC=xlc ;; esac
1604
1605 stack_trace_eye_catcher=`echo ${PROGNAME}_${version}_${canonical} | sed 'y/.-/__/'`
1606 AC_DEFINE_UNQUOTED(STACK_TRACE_EYE_CATCHER, $stack_trace_eye_catcher)
1607
1608 dnl --------------------------------------------------
1609 dnl Determine the compiler, set up for feature testing
1610 dnl --------------------------------------------------
1611
1612 dnl Sun Development environment support
1613 test "$with_sparcworks" = "yes" && with_workshop=yes # compatibility alias
1614 XE_CHECK_FEATURE_DEPENDENCY(workshop, tooltalk)
1615 if test "$with_workshop" = "yes"; then
1616   AC_DEFINE(SUNPRO)
1617   XE_ADD_OBJS(sunpro.o)
1618 fi
1619
1620 if test "$with_clash_detection" != "no"; then
1621   AC_DEFINE(CLASH_DETECTION)
1622   XE_ADD_OBJS(filelock.o)
1623 fi
1624
1625 dnl Choose a compiler from (in order)
1626 dnl --compiler, env var CC, with_gcc=no && ${NON_GNU_CC:-cc}, AC_PROG_CC
1627 test -n "$compiler" && CC="$compiler"
1628 if test "$with_gcc" = "no"; then dnl Try to find a non-gcc compiler
1629   case "$CC" in "" | *gcc* ) CC="${NON_GNU_CC-cc}" ;; esac
1630 fi
1631
1632 dnl If we don't set CFLAGS here, AC_PROG_CC will set it.
1633 dnl But we know better what's good for us, so we do our own
1634 dnl computation of real CFLAGS later.
1635 dnl --cflags overrides environment variable CFLAGS
1636 test "${cflags-unset}" != unset && CFLAGS="$cflags"
1637 if test "${CFLAGS-unset}" != unset
1638   then cflags_specified=yes;
1639   else cflags_specified=no;
1640 fi
1641
1642 xe_save_CFLAGS="$CFLAGS"
1643
1644 AC_PROG_CC dnl Autoconf has its own magic for compiler autodetection
1645
1646 dnl Retry using random guesswork if AC_PROG_CC got it wrong...
1647 if   test "$with_gcc" = "no"  -a "$GCC" = "yes"; then
1648   CC=${NON_GNU_CC-cc}
1649   AC_PROG_CC
1650 elif test "$with_gcc" = "yes" -a "$GCC" != "yes" ; then
1651   CC=gcc
1652   AC_PROG_CC
1653 fi
1654 CFLAGS="$xe_save_CFLAGS"
1655
1656 dnl Figure out what C preprocessor to use.
1657
1658 dnl On Sun systems, people sometimes set up the variable CPP
1659 dnl with a value that is a directory, not an executable at all.
1660 dnl Detect that case, and ignore that value.
1661 test -n "$CPP" -a -d "$CPP" && CPP=
1662
1663 test -n "$NON_GNU_CPP" -a "$GCC" != "yes" -a -z "$CPP" && CPP="$NON_GNU_CPP"
1664
1665 AC_PROG_CPP
1666
1667 dnl --------------------------------------------------------------------
1668 dnl Compiler feature macros
1669 dnl --------------------------------------------------------------------
1670
1671 AC_AIX dnl Defines _ALL_SOURCE on AIX.
1672
1673 dnl We want feature macros defined here *and* in config.h.in, so that
1674 dnl the compilation environment at configure time and compile time agree.
1675
1676 AC_MSG_CHECKING(for GNU libc)
1677 AC_TRY_COMPILE([#include <features.h>],[
1678 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
1679 #error Not a GNU libc system :-(
1680 ******* ======= ******** &&&&&&&&
1681 #endif
1682 ], have_glibc=yes, have_glibc=no)
1683 AC_MSG_RESULT($have_glibc)
1684 dnl I'm tired of pop being broken with GLIBC -slb
1685 dnl Well. then why not fix fucking pop?
1686 test "$have_glibc" = "yes" && AC_DEFINE(_GNU_SOURCE)
1687
1688 dnl We'd like to use vendor extensions, where available.
1689 dnl We'd like to use functions from the latest Unix98 standards.
1690 dnl See http://www.opengroup.org/onlinepubs/007908799/xsh/compilation.html
1691 case "$opsys" in
1692   sol2)
1693    AC_DEFINE(__EXTENSIONS__)
1694    dnl Solaris 2 before 2.5 had some bugs with feature test macro interaction.
1695    if test "$os_release" -ge 55; then
1696      AC_DEFINE(_XOPEN_SOURCE,500)
1697      AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1698    fi ;;
1699   linux)
1700     AC_DEFINE(_POSIX_C_SOURCE,199506L)
1701     AC_DEFINE(_XOPEN_SOURCE,500)
1702     AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1703     ;;
1704 esac
1705
1706 dnl Identify compilers to enable compiler-specific hacks.
1707 dnl Add support for other compilers HERE!
1708 dnl GCC is already identified elsewhere.
1709 AC_TRY_RUN([int main () {
1710 #if defined __SUNPRO_C
1711 return 11;
1712 #elif defined __DECC
1713 return 12;
1714 #elif defined __USLC__ && defined __SCO_VERSION__
1715 return 13;
1716 #else
1717 return 0;
1718 #endif
1719 }], [],
1720 [case "$conftest_rc" in
1721   11) echo "You appear to be using the SunPro C compiler."; __SUNPRO_C=yes ;;
1722   12) echo "You appear to be using the DEC C compiler."   ; __DECC=yes ;;
1723   13) echo "You appear to be using the SCO C compiler."   ; __USLC__=yes ;;
1724 esac])
1725
1726
1727 dnl case "$canonical" in
1728 dnl   *-sun-sunos* ) test "$CPP" = "acc -E" && CPP="acc -E -Xs" ;;
1729 dnl esac
1730
1731 dnl --------------------------------------------------------------------
1732 dnl Extract some information from the operating system and machine files
1733 dnl --------------------------------------------------------------------
1734
1735 echo "Extracting information from the machine- and system-dependent headers..."
1736
1737 dnl It is not important that this name contain the PID; you cannot run
1738 dnl two configures in the same directory and have anything work
1739 dnl anyway.
1740 tempcname="conftest.c"
1741
1742 dnl CPP_to_sh(CPP_SYMBOL, SH_VAR, DEFAULT_VALUE)
1743 define([CPP_to_sh],
1744 [[#]ifndef [$1]
1745 [#]define [$1]ifelse([$3],,, [ "$3"])
1746 [#]endif
1747 configure___ [$2]=[$1]
1748 ])dnl CPP_to_sh
1749
1750 dnl CPP_boolean_to_sh(CPP_SYMBOL, SH_VAR)
1751 define([CPP_boolean_to_sh],
1752 [[#]ifdef [$1]
1753 configure___ [$2]=yes
1754 [#]else
1755 configure___ [$2]=no
1756 [#]endif
1757 ])dnl CPP_boolean_to_sh
1758
1759 cat > $tempcname < confdefs.h
1760 cat >> $tempcname <<EOF
1761 #define NOT_C_CODE
1762 #define C_SWITCH_SITE
1763 #define C_SWITCH_X_SITE
1764 #define LD_SWITCH_SITE
1765 #define LD_SWITCH_X_SITE
1766 #define LD_SWITCH_X_SITE_AUX
1767 #define OS_RELEASE $os_release
1768
1769 #ifdef config_opsysfile
1770 #include "$srcdir/src/$opsysfile"
1771 #endif
1772
1773 #ifdef config_machfile
1774 #include "$srcdir/src/$machfile"
1775 #endif
1776
1777 CPP_to_sh(LIBS_MACHINE, libs_machine)
1778 CPP_to_sh(LIBS_SYSTEM,  libs_system)
1779 CPP_to_sh(LIBS_TERMCAP, libs_termcap)
1780 CPP_to_sh(LIB_STANDARD, libs_standard)
1781
1782 CPP_to_sh(OBJECTS_MACHINE, objects_machine)
1783 CPP_to_sh(OBJECTS_SYSTEM,  objects_system)
1784
1785 CPP_to_sh(C_SWITCH_MACHINE,   c_switch_machine)
1786 CPP_to_sh(C_SWITCH_SYSTEM,    c_switch_system)
1787
1788 CPP_to_sh(LD_SWITCH_MACHINE,  ld_switch_machine)
1789 CPP_to_sh(LD_SWITCH_SYSTEM,   ld_switch_system)
1790
1791 CPP_to_sh(UNEXEC, unexec, unexec.o)
1792
1793 CPP_to_sh(LD_SWITCH_SHARED, ld_switch_shared, -c)
1794
1795 #define ORDINARY_LD "\$(CC) \$(CFLAGS)"
1796 configure___ ordinary_ld=ORDINARY_LD
1797
1798 #ifdef ORDINARY_LINK
1799 #define LD ORDINARY_LD
1800 #else /* no ORDINARY LINK */
1801 #ifdef COFF_ENCAPSULATE
1802 #define LD "\$(CC) -nostdlib"
1803 #else /* not COFF_ENCAPSULATE */
1804 #ifdef LINKER
1805 #define LD LINKER
1806 #else /* ! defined (LINKER) */
1807 #define LD "ld"
1808 #endif /* ! defined (LINKER) */
1809 #endif /* ! defined (COFF_ENCAPSULATE) */
1810 #endif /* not ORDINARY_LINK */
1811 configure___ ld=LD
1812
1813 CPP_to_sh(LIB_GCC, lib_gcc)
1814 CPP_to_sh(LD_TEXT_START_ADDR, ld_text_start_addr)
1815
1816 #if ! defined (ORDINARY_LINK) && !defined (START_FILES)
1817 #ifdef NO_REMAP
1818 #ifdef COFF_ENCAPSULATE
1819 #define START_FILES "pre-crt0.o /usr/local/lib/gcc-crt0.o"
1820 #else /* ! defined (COFF_ENCAPSULATE) */
1821 #define START_FILES "pre-crt0.o /lib/crt0.o"
1822 #endif /* ! defined (COFF_ENCAPSULATE) */
1823 #else /* ! defined (NO_REMAP) */
1824 #define START_FILES "ecrt0.o"
1825 #endif /* ! defined (NO_REMAP) */
1826 #endif /* no ORDINARY_LINK */
1827 #ifndef START_FILES
1828 #define START_FILES
1829 #endif
1830 configure___ start_files=START_FILES
1831
1832 CPP_boolean_to_sh(ORDINARY_LINK, ordinary_link)
1833 CPP_boolean_to_sh(SYSTEM_MALLOC, system_malloc)
1834 CPP_boolean_to_sh(TERMINFO, have_terminfo)
1835 dnl The MAIL_USE_xxx variables come from the s&m headers
1836 CPP_boolean_to_sh(MAIL_USE_FLOCK, mail_use_flock)
1837 CPP_boolean_to_sh(MAIL_USE_LOCKF, mail_use_lockf)
1838 CPP_boolean_to_sh(MAIL_USE_LOCKING, mail_use_locking)
1839 CPP_boolean_to_sh(HAVE_WIN32_PROCESSES, win32_processes)
1840 EOF
1841
1842 dnl The value of CPP is a quoted variable reference, so we need to do this
1843 dnl to get its actual value...
1844 CPP=`eval "echo $CPP $CPPFLAGS"`
1845 define(TAB, [   ])dnl
1846 changequote(, )dnl
1847 eval `$CPP -Isrc $tempcname \
1848         | sed -n -e "s/[ TAB]*=[ TAB\"]*/='/" -e "s/[ TAB\"]*\$/'/" -e "s/^configure___//p"`
1849 changequote([, ])dnl
1850
1851 rm $tempcname
1852
1853 if test "$pdump" = "yes"; then
1854   ordinary_link="yes"
1855   ld="${ordinary_ld}"
1856   start_files=
1857   libs_standard=
1858   unexec=
1859   lib_gcc=
1860 fi
1861
1862 dnl For debugging...
1863 test "$extra_verbose" = "yes" && \
1864   PRINT_VAR(libs_machine libs_system libs_termcap libs_standard
1865   objects_machine objects_system c_switch_machine c_switch_system
1866   ld_switch_machine ld_switch_system unexec ld_switch_shared
1867   ld lib_gcc ld_text_start_addr start_files ordinary_link
1868   have_terminfo mail_use_flock mail_use_lockf) && echo ""
1869
1870 dnl Pick up mingw32 include path
1871 case "$opsys" in mingw* | cygwin*)
1872   cygwin_include=`eval "gcc -print-file-name=libc.a"` ;
1873   cygwin_include=`eval "dirname $cygwin_include"` ;
1874   cygwin_include="-I$cygwin_include/../include" ;
1875   extra_includes="$cygwin_include/mingw32 $cygwin_include/mingw $cygwin_include" ;
1876   case "$opsys" in mingw*)
1877     XE_APPEND($extra_includes, c_switch_system) ;;
1878   esac
1879   ;;
1880 esac
1881
1882 dnl Non-ordinary link usually requires -lc
1883 test "$ordinary_link" = "no" -a -z "$libs_standard" && libs_standard="-lc"
1884
1885 dnl -----------------------
1886 dnl Compiler-specific hacks
1887 dnl -----------------------
1888
1889 dnl DEC C `-std1' means ANSI C mode
1890 test "$__DECC" = "yes" && XE_APPEND(-std1, c_switch_site)
1891
1892 dnl Some versions of SCO native compiler need -Kalloca
1893 if test "$__USLC__" = yes; then
1894   AC_MSG_CHECKING(for whether the -Kalloca compiler flag is needed)
1895   need_kalloca=no
1896   AC_TRY_LINK([], [void *x = alloca(4);], [:], [
1897     xe_save_c_switch_system="$c_switch_system"
1898     c_switch_system="$c_switch_system -Kalloca"
1899     AC_TRY_LINK([], [void *x = alloca(4);], [ need_kalloca=yes ])
1900     c_switch_system="$xe_save_c_switch_system"])
1901   AC_MSG_RESULT($need_kalloca)
1902   test "$need_kalloca" = "yes" && XE_APPEND(-Kalloca,c_switch_system)
1903 fi
1904
1905 dnl Calculalate value of CFLAGS:
1906 dnl Use either command line flag, environment var, or autodetection
1907 if test "$cflags_specified" = "no"; then
1908   dnl Following values of CFLAGS are known to work well.
1909   dnl Should we take debugging options into consideration?
1910   if   test "$GCC" = "yes"; then
1911     CFLAGS="-g -O3 -Wall -Wno-switch -Wpointer-arith -Winline -Wmissing-prototypes -Wshadow"
1912     dnl I'm not convinced this is a good idea any more. -sb
1913     dnl test "$opsys $machine" = "linux intel386" && \
1914     dnl CFLAGS="$CFLAGS -fno-strength-reduce -malign-loops=2 -malign-jumps=2 -malign-functions=2"
1915   elif test "$__SUNPRO_C" = "yes"; then
1916     case "$opsys" in
1917       sol2    ) CFLAGS="-v -xO4" ;;
1918       sunos4* ) CFLAGS="-xO2";;
1919     esac
1920   elif test "$__DECC" = "yes"; then
1921     CFLAGS="-O3"
1922   elif test "$CC" = "xlc"; then
1923     CFLAGS="-g -O3 -qstrict -qnoansialias -qlibansi -qinfo -qro -qmaxmem=20000"
1924   dnl ### Add optimal CFLAGS support for other compilers HERE!
1925   else
1926     CFLAGS="-O" ;dnl The only POSIX-approved flag
1927   fi
1928 fi
1929
1930 dnl Search for GCC specific build problems we know about
1931 if test "$GCC" = "yes"; then
1932 AC_MSG_CHECKING(for buggy gcc versions)
1933 GCC_VERSION=`$CC --version`
1934 case `uname -s`:`uname -m`:$GCC_VERSION in
1935         dnl egcs 2.90.21 (egcs-1.00 release)
1936         dnl egcs 2.90.29 (egcs-1.0.3 release)
1937     *:sun4*:2.8.1|*:sun4*:egcs-2.90.*)
1938         dnl Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures
1939         dnl without also using `-fno-schedule-insns'.
1940         case "$CFLAGS" in
1941             *-O2*|*-O3*)
1942                 case "$CFLAGS" in
1943                     *-fno-schedule-insns*) ;;
1944                     *)
1945                         AC_MSG_RESULT(yes)
1946                         AC_MSG_WARN(Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures)
1947                         AC_MSG_WARN(without also using -fno-schedule-insns.)
1948                         AC_MSG_ERROR(Aborting due to known problem)
1949                         ;;
1950                 esac
1951                 ;;
1952         esac
1953         ;;
1954         dnl egcs-2.91.57 (egcs-1.1 release)
1955         dnl egcs-2.91.66 (egcs-1.1.2 release)
1956     Linux:alpha:egcs-2.91.*)
1957         AC_MSG_RESULT(yes)
1958         AC_MSG_WARN(There have been reports of egcs-1.1 not compiling XEmacs correctly on)
1959         AC_MSG_WARN(Alpha Linux.  There have also been reports that egcs-1.0.3a is O.K.)
1960         AC_MSG_ERROR(Aborting due to known problem)
1961         ;;
1962     *:i*86*:2.7.2*)
1963         case "$CFLAGS" in
1964             *-O2*|*-O3*)
1965                 case "$GCC_VERSION" in
1966                     2.7.2)
1967                         case "$CFLAGS" in
1968                             *-fno-strength-reduce*) ;;
1969                             *)
1970                                 AC_MSG_RESULT(yes)
1971                                 AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1972                                 AC_MSG_WARN(-fno-strength-reduce.)
1973                                 AC_MSG_ERROR(Aborting due to known problem)
1974                                 ;;
1975                         esac
1976                         ;;
1977                 esac
1978                 case "$CFLAGS" in
1979                  *-fno-caller-saves*) ;;
1980                  *)
1981                     AC_MSG_RESULT(yes)
1982                     AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1983                     AC_MSG_WARN(-fno-caller-saves.)
1984                     AC_MSG_ERROR(Aborting due to known problem)
1985                     ;;
1986                 esac
1987                 ;;
1988         esac
1989         ;;
1990 esac
1991 AC_MSG_RESULT(no)
1992 fi
1993
1994 dnl Inform compiler that certain flags are meant for the linker
1995 dnl XE_PROTECT_LINKER_FLAGS(shell_var)
1996 define([XE_PROTECT_LINKER_FLAGS], [
1997 if test "$GCC" = "yes"; then
1998   set x $[$1]; shift; [$1]=""
1999   while test -n "[$]1"; do
2000     case [$]1 in
2001       -L  | -l  | -u               ) [$1]="$[$1] [$]1 [$]2"; shift ;;
2002       -L* | -l* | -u* | -Wl* | -pg ) [$1]="$[$1] [$]1" ;;
2003       -Xlinker* ) ;;
2004       * ) [$1]="$[$1] -Xlinker [$]1" ;;
2005     esac
2006     shift
2007   done
2008 fi])dnl
2009 XE_PROTECT_LINKER_FLAGS(ld_switch_system)
2010 XE_PROTECT_LINKER_FLAGS(ld_switch_machine)
2011 XE_PROTECT_LINKER_FLAGS(LDFLAGS)
2012 XE_PROTECT_LINKER_FLAGS(ld_call_shared)
2013
2014 dnl Add s&m-determined objects (including unexec) to link line
2015 test -n "$objects_machine" && XE_ADD_OBJS($objects_machine)
2016 test -n "$objects_system"  && XE_ADD_OBJS($objects_system)
2017 test -n "$unexec"          && test ! "$pdump" = "yes" && XE_ADD_OBJS($unexec)
2018 test "$pdump" = "yes" && XE_ADD_OBJS(dumper.o)
2019
2020 dnl Dynodump (Solaris 2.x, x<6)
2021 AC_MSG_CHECKING(for dynodump)
2022 if test "$unexec" != "unexsol2.o"; then
2023   AC_MSG_RESULT(no)
2024 else
2025   AC_MSG_RESULT(yes)
2026   AC_DEFINE(DYNODUMP)
2027   XE_APPEND(dynodump, MAKE_SUBDIR)
2028   XE_APPEND(dynodump, SRC_SUBDIR_DEPS)
2029   case "$machine" in
2030     sparc   ) dynodump_arch=sparc ;;
2031     *86*    ) dynodump_arch=i386  ;;
2032     powerpc ) dynodump_arch=ppc   ;;
2033   esac
2034   dnl Dynodump requires the system linker
2035   test "$GCC" = "yes" && XE_APPEND(-fno-gnu-linker, ld_switch_site)
2036 fi
2037
2038 dnl Feed s&m crud to src/Makefile
2039
2040 dnl Linux/powerpc needs the following magic for some reason
2041 test "$machine$opsys" = "powerpclinux" && start_flags="-T $srcdir/src/ppc.ldscript"
2042
2043 if test "$unexec" = "unexaix.o"; then
2044 dnl AIX needs various hacks to make static linking work.
2045   if   test "$dynamic" = "no"; then
2046   start_flags="-Wl,-bnso,-bnodelcsect"
2047   test "$GCC" = "yes" && start_flags="-B/bin/ ${start_flags}"
2048   for f in "/lib/syscalls.exp" "/lib/threads.exp"; do
2049     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; fi
2050   done
2051   for f in "/usr/lpp/X11/bin/smt.exp" "/usr/bin/X11/smt.exp"; do
2052     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; break; fi
2053   done
2054   AC_CHECK_LIB(C, terminateAndUnload, XE_APPEND(-lC, libs_system))
2055   fi
2056 elif test -n "$ld_text_start_addr"; then
2057   start_flags="-T $ld_text_start_addr -e __start"
2058 fi
2059 AC_SUBST(start_flags)
2060
2061 AC_SUBST(ld_switch_shared)
2062 AC_SUBST(start_files)
2063 if test "$ordinary_link" = "no" -a "$GCC" = "yes"; then
2064  test -z "$linker" &&  linker='$(CC) -nostdlib'
2065  test -z "$lib_gcc" && lib_gcc='`$(CC) -print-libgcc-file-name`'
2066 fi
2067 test "$GCC" != "yes" && lib_gcc=
2068 AC_SUBST(ld)
2069 AC_SUBST(lib_gcc)
2070
2071 dnl ---------------------------------------------------------------
2072 dnl Add site and system specific flags to compile and link commands
2073 dnl ---------------------------------------------------------------
2074
2075 dnl Allow use of either ":" or spaces for lists of directories
2076 define(COLON_TO_SPACE,
2077   [case "$[$1]" in *:* [)] [$1]="`echo '' $[$1] | sed -e 's/^ //' -e 's/:/ /g'`";; esac])dnl
2078
2079 dnl --site-libraries (multiple dirs)
2080 COLON_TO_SPACE(site_libraries)
2081 if test -n "$site_libraries"; then
2082   for arg in $site_libraries; do
2083     case "$arg" in
2084      -* ) ;;
2085      * ) test -d "$arg" || \
2086            XE_DIE("Invalid site library \`$arg': no such directory")
2087        arg="-L${arg}" ;;
2088     esac
2089     XE_APPEND($arg, ld_switch_site)
2090   done
2091 fi
2092
2093 dnl --site-includes (multiple dirs)
2094 COLON_TO_SPACE(site_includes)
2095 if test -n "$site_includes"; then
2096   for arg in $site_includes; do
2097     case "$arg" in
2098       -* ) ;;
2099       * ) test -d "$arg" || \
2100            XE_DIE("Invalid site include \`$arg': no such directory")
2101       arg="-I${arg}" ;;
2102     esac
2103     XE_APPEND($arg, c_switch_site)
2104   done
2105 fi
2106
2107 dnl --site-prefixes (multiple dirs)
2108 dnl --site-prefixes=dir1:dir2 is a convenient shorthand for
2109 dnl --site-libraries=dir1/lib:dir2/lib --site-includes=dir1/include:dir2/include
2110 dnl Site prefixes take precedence over the standard places, but not over
2111 dnl site-includes and site-libraries.
2112 COLON_TO_SPACE(site_prefixes)
2113 if test -n "$site_prefixes"; then
2114   for dir in $site_prefixes; do
2115     lib_dir="${dir}/lib"
2116     inc_dir="${dir}/include"
2117     if test ! -d "$dir"; then
2118       XE_DIE("Invalid site prefix \`$dir': no such directory")
2119     elif test ! -d "$lib_dir"; then
2120       XE_DIE("Invalid site prefix \`$dir': no such directory \`$lib_dir'")
2121     else
2122       if test -d "$inc_dir"; then
2123         XE_APPEND("-I$inc_dir", c_switch_site)
2124       fi
2125       XE_APPEND("-L$lib_dir", ld_switch_site)
2126     fi
2127   done
2128 fi
2129
2130 dnl GNU software installs by default into /usr/local/{include,lib}
2131 dnl if test -d "/usr/local/include" -a -d "/usr/local/lib"; then
2132 dnl   XE_APPEND("-L/usr/local/lib",    ld_switch_site)
2133 dnl   XE_APPEND("-I/usr/local/include", c_switch_site)
2134 dnl fi
2135
2136 dnl Extra system-specific library directories - please add to list
2137 for dir in "/usr/ccs/lib"; do
2138   test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2139 done
2140
2141 dnl --site-runtime-libraries (multiple dirs)
2142 COLON_TO_SPACE(site_runtime_libraries)
2143 if test -n "$site_runtime_libraries"; then
2144   LD_RUN_PATH="`echo $site_runtime_libraries | sed -e 's/  */:/g'`"
2145   export LD_RUN_PATH
2146 fi
2147
2148 dnl Linux systems have dynamic runtime library directories listed in
2149 dnl /etc/ld.so.conf.  Since those are used at run time, it seems pretty
2150 dnl safe to use them at link time, and less controversial than forcing
2151 dnl the run-time to use the link-time libraries.  This also helps avoid
2152 dnl mismatches between the link-time and run-time libraries.
2153
2154 dnl #### Unfortunately, there are horrible libc4 and libc5 libraries
2155 dnl listed in /etc/ld.so.conf on some systems, and including them on
2156 dnl the link path leads to linking in utterly broken libc's.
2157 dnl There are many clever ways of approaching this problem,
2158 dnl but finding out that actually works...
2159
2160 dnl if test -z "$LD_RUN_PATH" -a -r "/etc/ld.so.conf"; then
2161 dnl   for dir in `cat /etc/ld.so.conf`; do
2162 dnl     test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2163 dnl   done
2164 dnl   add_runtime_path=no
2165 dnl fi
2166
2167 dnl -------------------------------------
2168 dnl Compute runtime library path
2169 dnl -------------------------------------
2170
2171 if test -n "$add_runtime_path"; then :;
2172 elif test "$dynamic" = "no"; then add_runtime_path=no
2173 elif test -n "$LD_RUN_PATH"; then add_runtime_path=yes
2174 else case "$opsys" in
2175        sol2 | irix* | *bsd* | decosf* ) add_runtime_path=yes ;;
2176        * ) add_runtime_path=no ;;
2177      esac
2178 fi
2179
2180 if test "$add_runtime_path" = "yes"; then
2181   dnl Try to autodetect runtime library flag (usually -R),
2182   dnl and whether it works (or at least does no harm)
2183   AC_MSG_CHECKING("for runtime libraries flag")
2184   case "$opsys" in
2185     sol2 ) dash_r="-R" ;;
2186     decosf* | linux* | irix*) dash_r="-rpath " ;;
2187     *)
2188       dash_r=""
2189       for try_dash_r in "-R" "-R " "-rpath "; do
2190         xe_check_libs="${try_dash_r}/no/such/file-or-directory"
2191         XE_PROTECT_LINKER_FLAGS(xe_check_libs)
2192         AC_TRY_LINK(, , dash_r="$try_dash_r")
2193         xe_check_libs=""
2194         test -n "$dash_r" && break
2195       done ;;
2196   esac
2197   if test -n "$dash_r";
2198     then AC_MSG_RESULT("\"${dash_r}\"")
2199     else AC_MSG_RESULT(NONE)
2200   fi
2201 fi
2202
2203 xe_add_unique_runpath_dir='
2204   xe_add_p=yes
2205   for xe_dir in $runpath_dirs; do   dnl Uniquify
2206     test "$xe_dir" = "$xe_runpath_dir" && xe_add_p=no
2207   done
2208   if test "$xe_add_p" = "yes"; then
2209     test -n "$runpath" && runpath="${runpath}:"
2210     runpath="${runpath}${xe_runpath_dir}"
2211     runpath_dirs="$runpath_dirs $xe_runpath_dir"
2212   fi'
2213
2214
2215 dnl XE_ADD_RUNPATH_DIR(directory)
2216 define([XE_ADD_RUNPATH_DIR],[{
2217 xe_runpath_dir=$1
2218 dnl PRINT_VAR(ld_switch_site ld_switch_x_site runpath xe_runpath_dir LD_RUN_PATH xe_ldflags)
2219   test "$xe_runpath_dir" != "/lib"     -a \
2220         "$xe_runpath_dir" != "/usr/lib" -a \
2221         -n "`ls ${xe_runpath_dir}/*.s[[ol]] 2>/dev/null`" && \
2222   eval "$xe_add_unique_runpath_dir"
2223 }])dnl
2224
2225 dnl XE_COMPUTE_RUNPATH()
2226 define([XE_COMPUTE_RUNPATH],[
2227 if test "$add_runtime_path" = "yes" -a -n "$dash_r"; then
2228   dnl Remove runtime paths from current ld switches
2229   ld_switch_site=`echo   '' $ld_switch_site   | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2230   ld_switch_x_site=`echo '' $ld_switch_x_site | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2231   dnl PRINT_VAR(ld_switch_site ld_switch_x_site)
2232
2233   dnl Fix up Runtime path
2234   dnl If LD_RUN_PATH is set in environment, use that.
2235   dnl In this case, assume user has set the right value.
2236   runpath="" runpath_dirs=""
2237   if test -n "$LD_RUN_PATH"; then
2238     runpath="$LD_RUN_PATH"
2239   elif test "$GCC" = "yes"; then
2240     dnl Compute runpath from gcc's -v output
2241     ld_switch_run_save="$ld_switch_run"; ld_switch_run=""
2242     echo "int main(int argc, char *argv[[]]) {return 0;}" > conftest.c
2243     xe_runpath_link='${CC-cc} -o conftest -v $CFLAGS '"$xe_ldflags"' conftest.$ac_ext 2>&1 1>/dev/null'
2244     for arg in `eval "$xe_runpath_link" | grep ' -L'`; do
2245       case "$arg" in P,* | -L* | -R* )
2246         for dir in `echo '' "$arg" | sed -e 's:^ ::' -e 's/^..//' -e 'y/:/ /'`; do
2247           XE_ADD_RUNPATH_DIR("$dir")
2248         done ;;
2249       esac
2250     done
2251     ld_switch_run="$ld_switch_run_save"
2252     rm -f conftest*
2253   else
2254     dnl Add all directories with .so files to runpath
2255     for arg in $ld_switch_site $ld_switch_x_site; do
2256       case "$arg" in -L*) XE_ADD_RUNPATH_DIR(`echo '' "$arg" | sed -e 's:^ ::' -e 's/^-L//'`);; esac
2257     done
2258     dnl Sometimes /opt/SUNWdt/lib is the only installed Motif available
2259     if test "$opsys $need_motif" = "sol2 yes"; then
2260       xe_runpath_dir="/opt/SUNWdt/lib";
2261       eval "$xe_add_unique_runpath_dir";
2262     fi
2263   fi dnl Compute $runpath
2264
2265   if test -n "$runpath"; then
2266     ld_switch_run="${dash_r}${runpath}"
2267     XE_PROTECT_LINKER_FLAGS(ld_switch_run)
2268     test "$extra_verbose" = "yes" && echo "Setting runpath to $runpath"
2269   fi
2270 fi
2271 ])dnl
2272 XE_COMPUTE_RUNPATH()
2273
2274 dnl JKJ REMOVEME
2275 dnl XE_SHLIB_STUFF
2276
2277 dnl -----------------------------------
2278 dnl Do some misc autoconf-special tests
2279 dnl -----------------------------------
2280
2281 dnl Do the opsystem or machine files prohibit the use of the GNU malloc?
2282 dnl Assume not, until told otherwise.
2283 GNU_MALLOC=yes
2284 if test "$with_dlmalloc" != "no"; then
2285         doug_lea_malloc=yes
2286 else
2287         doug_lea_malloc=no
2288 fi
2289 after_morecore_hook_exists=yes
2290 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
2291 AC_MSG_CHECKING(whether __after_morecore_hook exists)
2292 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
2293   [AC_MSG_RESULT(yes)],
2294   [AC_MSG_RESULT(no)
2295    after_morecore_hook_exists=no])
2296 if test "$system_malloc" = "yes" ; then
2297   GNU_MALLOC=no
2298   GNU_MALLOC_reason="
2299     - The GNU allocators don't work with this system configuration."
2300 elif test "$with_system_malloc" = "yes" ; then
2301   GNU_MALLOC=no
2302   GNU_MALLOC_reason="
2303     - User chose not to use GNU allocators."
2304 elif test "$with_debug_malloc" = "yes" ; then
2305   GNU_MALLOC=no
2306   GNU_MALLOC_reason="
2307     - User chose to use Debugging Malloc."
2308 fi
2309
2310 if test "$doug_lea_malloc" = "yes" -a "$GNU_MALLOC" = "yes" ; then
2311   GNU_MALLOC_reason="
2312     - Using Doug Lea's new malloc from the GNU C Library."
2313   AC_DEFINE(DOUG_LEA_MALLOC)
2314   if test "$after_morecore_hook_exists" = "no" ; then
2315     GNU_MALLOC_reason="
2316     - Using Doug Lea's new malloc from the Linux C Library."
2317     AC_DEFINE(_NO_MALLOC_WARNING_)
2318   fi
2319 fi
2320
2321 dnl #### mcheck is broken in all versions of Linux libc and glibc.
2322 dnl Try this again when 2.1 hits the streets.
2323 dnl Avoid using free-hook.c if support exists for malloc debugging in libc
2324 dnl have_libmcheck=no
2325 dnl if test "$error_check_malloc" = "yes" -a \
2326 dnl    "$have_glibc" = "yes" -a \
2327 dnl    "$doug_lea_malloc" = "yes"; then
2328 dnl   AC_CHECK_HEADERS(mcheck.h)
2329 dnl   AC_CHECK_LIB(mcheck, mcheck, have_libmcheck=yes, have_libmcheck=no)
2330 dnl fi
2331
2332 dnl if test "$have_libmcheck" = "yes"; then
2333 dnl   AC_DEFINE(HAVE_LIBMCHECK)
2334 dnl   libmcheck=-lmcheck
2335 dnl   AC_SUBST(libmcheck)
2336 dnl fi
2337
2338 dnl Some other nice autoconf tests.  If you add a test here which
2339 dnl should make an entry in src/config.h, do not forget to add an
2340 dnl #undef clause to src/config.h.in for autoconf to modify.
2341
2342 AC_PROG_RANLIB
2343 AC_PROG_INSTALL
2344 AC_PROG_YACC
2345
2346 dnl checks for header files
2347 AC_CHECK_HEADERS(dnl
2348   a.out.h dnl
2349   elf.h dnl
2350   cygwin/version.h dnl
2351   fcntl.h dnl
2352   inttypes.h dnl
2353   libgen.h dnl
2354   locale.h dnl
2355   mach/mach.h dnl
2356   sys/param.h dnl
2357   sys/pstat.h dnl
2358   sys/time.h dnl
2359   sys/timeb.h dnl
2360   sys/un.h dnl
2361   ulimit.h dnl
2362   unistd.h dnl
2363   utime.h dnl
2364 )
2365 AC_HEADER_SYS_WAIT
2366 AC_HEADER_STDC
2367 AC_HEADER_TIME
2368 AC_DECL_SYS_SIGLIST
2369
2370 dnl Some systems have utime.h but do not declare the struct anyplace.
2371 AC_MSG_CHECKING(for struct utimbuf)
2372 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2373 #include <sys/time.h>
2374 #include <time.h>
2375 #else
2376 #ifdef HAVE_SYS_TIME_H
2377 #include <sys/time.h>
2378 #else
2379 #include <time.h>
2380 #endif
2381 #endif
2382 #ifdef HAVE_UTIME_H
2383 #include <utime.h>
2384 #endif], [static struct utimbuf x; x.actime = x.modtime;],
2385   [AC_MSG_RESULT(yes)
2386    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
2387   AC_MSG_RESULT(no))
2388
2389 dnl checks for typedefs
2390 AC_TYPE_SIGNAL
2391 AC_TYPE_SIZE_T
2392 AC_TYPE_PID_T
2393 AC_TYPE_UID_T
2394 AC_TYPE_MODE_T
2395 AC_TYPE_OFF_T
2396 AC_CHECK_TYPE(ssize_t, int)
2397
2398 dnl check for Unix98 socklen_t
2399 AC_MSG_CHECKING(for socklen_t)
2400 AC_TRY_COMPILE([#include <sys/socket.h>
2401 socklen_t x;
2402 ],[],[AC_MSG_RESULT(yes)],[
2403 AC_TRY_COMPILE([#include <sys/socket.h>
2404 int accept (int, struct sockaddr *, size_t *);
2405 ],[],[
2406 AC_MSG_RESULT(size_t)
2407 AC_DEFINE(socklen_t,size_t)], [
2408 AC_MSG_RESULT(int)
2409 AC_DEFINE(socklen_t,int)])])
2410
2411 AC_MSG_CHECKING(for struct timeval)
2412 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2413 #include <sys/time.h>
2414 #include <time.h>
2415 #else
2416 #ifdef HAVE_SYS_TIME_H
2417 #include <sys/time.h>
2418 #else
2419 #include <time.h>
2420 #endif
2421 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
2422   [AC_MSG_RESULT(yes)
2423   HAVE_TIMEVAL=yes
2424   AC_DEFINE(HAVE_TIMEVAL)],
2425   [AC_MSG_RESULT(no)
2426    HAVE_TIMEVAL=no])
2427
2428 dnl checks for structure members
2429 AC_STRUCT_TM
2430 AC_STRUCT_TIMEZONE
2431
2432 dnl checks for compiler characteristics
2433 AC_C_CONST
2434
2435 dnl check for Make feature
2436 AC_PROG_MAKE_SET
2437
2438 dnl check byte order
2439 AC_C_BIGENDIAN
2440
2441 dnl define SIZEOF_TYPE
2442 AC_CHECK_SIZEOF(short)
2443 if test "$ac_cv_sizeof_short" = 0; then
2444   echo ""
2445   echo "*** PANIC *** Configure tests are not working - compiler is broken."
2446   echo "*** PANIC *** Please examine config.log for compilation errors."
2447   exit 1
2448 fi
2449 AC_CHECK_SIZEOF(int)
2450 AC_CHECK_SIZEOF(long)
2451 AC_CHECK_SIZEOF(long long)
2452 AC_CHECK_SIZEOF(void *)
2453
2454 dnl check for long file names
2455 AC_SYS_LONG_FILE_NAMES
2456
2457 dnl -lm is required by LISP_FLOAT_TYPE, among other things
2458 AC_CHECK_FUNC(sin, ,AC_CHECK_LIB(m, sin))
2459
2460 dnl Floating operation support is now unconditional
2461 AC_DEFINE(LISP_FLOAT_TYPE)
2462
2463 AC_TRY_LINK([#include <math.h>],
2464   [return atanh(1.0) + asinh(1.0) + acosh(1.0); ],
2465   AC_DEFINE(HAVE_INVERSE_HYPERBOLIC))
2466
2467 dnl Determine type of mail locking from configure args and s&m headers
2468 AC_CHECKING(type of mail spool file locking)
2469 AC_CHECK_FUNCS(lockf flock)
2470 dnl The mail_use_xxx variables are set according to the s&m headers.
2471 test -z "$mail_locking" -a "$mail_use_flock" = "yes" && mail_locking=flock
2472 test -z "$mail_locking" -a "$mail_use_lockf" = "yes" && mail_locking=lockf
2473 test -z "$mail_locking" -a "$mail_use_locking" = "yes" && mail_locking=locking
2474 if   test -z "$mail_locking"; then
2475   case "$opsys" in cygwin* | mingw*)
2476     mail_locking=pop ;;
2477   esac
2478 fi
2479
2480 if   test "$mail_locking" = "lockf"; then AC_DEFINE(MAIL_LOCK_LOCKF)
2481 elif test "$mail_locking" = "flock"; then AC_DEFINE(MAIL_LOCK_FLOCK)
2482 elif test "$mail_locking" = "locking"; then AC_DEFINE(MAIL_LOCK_LOCKING)
2483 elif test "$mail_locking" = "pop"; then
2484   with_pop=yes
2485   mail_locking=
2486 else mail_locking="dot-locking"; AC_DEFINE(MAIL_LOCK_DOT)
2487 fi
2488 test "$mail_locking" = "lockf" -a "$ac_cv_func_lockf" != "yes" && \
2489   XE_DIE("lockf mail locking requested but not available.")
2490 test "$mail_locking" = "flock" -a "$ac_cv_func_flock" != "yes" && \
2491   XE_DIE("flock mail locking requested but not available.")
2492 test "$mail_locking" = "locking" -a "$ac_cv_func_locking" != "yes" && \
2493   XE_DIE("locking mail locking requested but not available.")
2494
2495 case "$opsys" in decosf*)
2496   AC_CHECK_LIB(pthreads, cma_open)
2497   test "$ac_cv_lib_pthreads_cma_open" = "yes" && \
2498     c_switch_site="$c_switch_site -threads" ;;
2499 esac
2500
2501 AC_MSG_CHECKING(whether the -xildoff compiler flag is required)
2502 if   ${CC-cc} '-###' -xildon  no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ; then
2503   if ${CC-cc} '-###' -xildoff no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ;
2504     then AC_MSG_RESULT(no);
2505     else AC_MSG_RESULT(yes); XE_APPEND(-xildoff, ld_switch_site)
2506   fi
2507   else AC_MSG_RESULT(no)
2508 fi
2509
2510 dnl Link with "-z ignore" on Solaris if supported
2511 if test "$opsys" = "sol2"; then
2512   if test "$os_release" -ge 56; then
2513     AC_MSG_CHECKING(for \"-z ignore\" linker flag)
2514     case "`ld -h 2>&1`" in
2515       *-z\ ignore\|record* ) AC_MSG_RESULT(yes)
2516         XE_PREPEND(-z ignore, ld_switch_site) ;;
2517       *) AC_MSG_RESULT(no) ;;
2518     esac
2519   fi
2520 fi
2521
2522 dnl ----------------------
2523 dnl Choose a window system
2524 dnl ----------------------
2525
2526 AC_CHECKING("for specified window system")
2527
2528 if test "$with_x11" != "no"; then
2529   dnl User-specified --x-includes or --x-libraries implies --with-x11.
2530   test "$x_includes $x_libraries" != "NONE NONE" && \
2531    window_system=x11 with_x11=yes
2532
2533   dnl Autodetection of X11 libraries and includes
2534   dnl -------------------------------------------
2535   dnl AC_PATH_XTRA thinks it can find our X headers and includes, but
2536   dnl it often gets it wrong, so we only use it as a last resort.
2537
2538   dnl $OPENWINHOME implies --x-includes and --x-libraries
2539   dnl Not (yet) handled by autoconf2
2540   if test "$x_includes $x_libraries" = "NONE NONE" \
2541     -a -n "$OPENWINHOME" \
2542     -a "$OPENWINHOME" != "/usr/openwin" \
2543     -a -d "$OPENWINHOME"; then
2544       test -d "$OPENWINHOME/lib"           && x_libraries="$OPENWINHOME/lib"
2545       test -d "$OPENWINHOME/include"       && x_includes="$OPENWINHOME/include"
2546       test -d "$OPENWINHOME/share/include" && x_includes="$OPENWINHOME/share/include"
2547   fi
2548
2549   if test "$x_includes" = "NONE"; then
2550     dnl AC_PATH_XTRA often guesses /usr/include, when some other
2551     dnl include directory is a MUCH better guess (Linux, HP-UX 10.20).
2552     dnl This is a workaround for idiot (esp. HP) system vendors, who
2553     dnl provide a /usr/include/X11, but DON'T FULLY POPULATE IT.
2554     for dir in "/usr/X11" "/usr/X11R6"; do
2555       if test -d "$dir/include/X11"; then x_includes="$dir/include"; break; fi
2556     done
2557   fi
2558
2559   if test "$x_libraries" = "NONE"; then
2560     for dir in "/usr/X11/lib" "/usr/X11R6/lib" "/usr/lib/X11R6"; do
2561       if test -r "$dir/libX11.a"; then x_libraries="$dir"; break; fi
2562     done
2563   fi
2564
2565   AC_PATH_XTRA # Autoconf claims to find X library and include dirs for us.
2566   if test "$no_x" = "yes"
2567   then with_x11=no  window_system=none HAVE_X_WINDOWS=no
2568   else with_x11=yes window_system=x11  HAVE_X_WINDOWS=yes
2569   fi
2570 fi
2571
2572 case "$with_x11" in
2573   yes ) window_system=x11  HAVE_X_WINDOWS=yes ;;
2574   no  ) window_system=none HAVE_X_WINDOWS=no  ;;
2575 esac
2576
2577 if test "$with_x11" = "yes"; then
2578   AC_DEFINE(HAVE_X_WINDOWS)
2579   XE_APPEND(lwlib, MAKE_SUBDIR)
2580   XE_APPEND(lwlib, SRC_SUBDIR_DEPS)
2581
2582   dnl Try to find Motif/CDE/Tooltalk dirs
2583   dnl These take precedence over other X libs/includes, so PRE-pend
2584   for lib_dir in "/usr/dt/lib" "/usr/lib/Motif2.1" "/usr/lib/Motif1.2" "/usr/lib/Motif1.1"; do
2585     inc_dir=`echo $lib_dir | sed -e 's/lib/include/'`
2586     if test -d "$lib_dir" -a -d "$inc_dir"; then
2587       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2588         x_libraries="$lib_dir $x_libraries"
2589         XE_PREPEND(-L${lib_dir}, X_LIBS) ;;
2590       esac
2591       case "$x_includes" in "$inc_dir"* ) ;; *)
2592         x_includes="$inc_dir $x_includes"
2593         XE_PREPEND(-I${inc_dir}, X_CFLAGS) ;;
2594       esac
2595       break; dnl only need ONE Motif implementation!
2596       fi
2597   done
2598
2599   dnl Contrib X libs/includes do NOT take precedence, so AP-pend
2600   for rel in "X11R6" "X11R5" "X11R4"; do
2601     lib_dir="/usr/contrib/$rel/lib" inc_dir="/usr/contrib/$rel/include"
2602     if test -d "$lib_dir" -a -d "$inc_dir"; then
2603       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2604         x_libraries="$x_libraries $lib_dir"
2605         XE_APPEND(-L${lib_dir}, X_LIBS)
2606       esac
2607       case "$x_includes" in "$inc_dir"* ) ;; *)
2608         x_includes="$x_includes $inc_dir"
2609         XE_APPEND(-I${inc_dir}, X_CFLAGS)
2610       esac
2611       break; dnl Only need ONE X11 implementation !
2612     fi
2613   done
2614
2615   dnl Avoid version mismatch for shared library libXm.so on osf4
2616   case "$opsys" in
2617   decosf*) if test "$GCC" = yes -a -d /usr/shlib; then XE_APPEND(-L/usr/shlib, X_LIBS); fi ;;
2618   esac
2619
2620   ld_switch_x_site="$X_LIBS"
2621
2622   XE_COMPUTE_RUNPATH()
2623
2624   if test "$extra_verbose" = "yes"; then
2625     echo; echo "X11 compilation variables:"
2626     PRINT_VAR(x_libraries x_includes X_CFLAGS X_LIBS X_PRE_LIBS X_EXTRA_LIBS)
2627     echo
2628   fi
2629
2630   dnl Set up bitmaps search path.
2631   dnl The original suggestion was to unconditionally to append X11/bitmaps
2632   dnl to each element of $x_includes, I'm pretty sure this is the wrong
2633   dnl thing to do.  We test for bitmaps and X11/bitmaps directories on each
2634   dnl element and add them to BITMAPDIR if they exist.
2635   bitmapdirs=
2636   if test "$x_includes" != NONE; then
2637     for i in $x_includes; do
2638       if test -d "$i/bitmaps"; then
2639         bitmapdirs="$i/bitmaps:$bitmapdirs"
2640       fi
2641       if test -d "$i/X11/bitmaps"; then
2642         bitmapdirs="$i/X11/bitmaps:$bitmapdirs"
2643       fi
2644     done
2645     bitmapdirs=`echo "$bitmapdirs" | sed s/.$//`
2646   fi
2647   test ! -z "$bitmapdirs" && AC_DEFINE_UNQUOTED(BITMAPDIR, "$bitmapdirs")
2648
2649   dnl Autodetect defines extracted from X config by xmkmf, e.g. NARROWPROTO
2650   AC_CHECKING(for X defines extracted by xmkmf)
2651   rm -fr conftestdir
2652   if mkdir conftestdir; then
2653     cd conftestdir
2654     cat > Imakefile <<'EOF'
2655 xetest:
2656         @echo ${PROTO_DEFINES} ${STD_DEFINES}
2657 EOF
2658     if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
2659       # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
2660       xmkmf_defines=`${MAKE-make} xetest 2>/dev/null | grep -v make`
2661     fi
2662     cd ..
2663     rm -fr conftestdir
2664     for word in $xmkmf_defines; do
2665       case "$word" in -D* )
2666         sym=`echo '' $word | sed -e 's:^ *-D::' -e 's:=.*::'`
2667         case "$word" in
2668           -D*=* ) val=`echo '' $word | sed -e 's:^.*=::'` ;;
2669           *     ) val=1 ;;
2670         esac
2671 dnl Avoid re-AC_DEFINE-ing xmkmf symbols we've already defined above.
2672         if grep "^#define $sym " confdefs.h >/dev/null; then :; else
2673           if test "$val" = "1"
2674             then AC_DEFINE_UNQUOTED($sym)
2675             else AC_DEFINE_UNQUOTED($sym,$val)
2676           fi
2677         fi  ;;
2678       esac
2679     done
2680   fi
2681
2682   dnl make sure we can find Intrinsic.h
2683   AC_CHECK_HEADER(X11/Intrinsic.h, ,
2684    [AC_MSG_ERROR("Unable to find X11 header files.")])
2685
2686   dnl -lXt and -lX11 are required
2687   dnl Some broken systems require the magic "-b i486-linuxaout" flag
2688   AC_CHECK_LIB(X11, XOpenDisplay, have_lib_x11=yes)
2689   if test "$have_lib_x11" != "yes"; then
2690     AC_CHECK_LIB(X11, XGetFontProperty,
2691       ld_switch_x_site="-b i486-linuxaout $ld_switch_x_site",
2692       [AC_MSG_ERROR("Unable to find X11 libraries.")],
2693       -b i486-linuxaout)
2694   fi
2695   libs_x="-lX11"
2696   test "$extra_verbose" = "yes" && echo "    Setting libs_x to \"-lX11\""
2697
2698   dnl Autodetect -lXext
2699   AC_CHECK_LIB(Xext, XShapeSelectInput, XE_PREPEND(-lXext, libs_x))
2700
2701   dnl Require -lXt
2702   AC_CHECK_LIB(Xt, XtOpenDisplay, XE_PREPEND(-lXt, libs_x),
2703     AC_MSG_ERROR("Unable to find X11 libraries."))
2704
2705   AC_MSG_CHECKING(the version of X11 being used)
2706   AC_TRY_RUN([#include <X11/Intrinsic.h>
2707     int main(int c, char *v[]) { return c>1 ? XlibSpecificationRelease : 0; }],
2708     [./conftest foobar; x11_release=$?],[x11_release=4],[x11_release=4])
2709   AC_MSG_RESULT(R${x11_release})
2710   AC_DEFINE_UNQUOTED(THIS_IS_X11R${x11_release})
2711
2712   if test "${x11_release}" = "4"; then
2713     case "$with_widgets" in
2714       "" | "no") with_widgets=no ;;
2715       *) XE_DIE("Widget support requires X11R5 or greater") ;;
2716     esac
2717   fi
2718
2719   AC_CHECK_FUNCS(XConvertCase)
2720
2721   AC_CHECK_HEADERS(X11/Xlocale.h)
2722
2723   dnl XFree86 has a non-standard prototype for this X11R6 function
2724   AC_CHECK_FUNCS(XRegisterIMInstantiateCallback)
2725   AC_MSG_CHECKING(for standard XRegisterIMInstantiateCallback prototype)
2726   AC_TRY_COMPILE([
2727 #define NeedFunctionPrototypes 1
2728 #include <X11/Xlib.h>
2729 extern Bool XRegisterIMInstantiateCallback(
2730    Display*, struct _XrmHashBucketRec*, char*, char*, XIMProc, XPointer*);
2731 ], [],
2732   [AC_MSG_RESULT(yes)],
2733   [AC_MSG_RESULT(no)
2734    AC_DEFINE(XREGISTERIMINSTANTIATECALLBACK_NONSTANDARD_PROTOTYPE)])
2735
2736   dnl autodetect -lXmu
2737   test -z "$with_xmu" && { AC_CHECK_LIB(Xmu, XmuReadBitmapDataFromFile,
2738                            with_xmu=yes, with_xmu=no) }
2739   if test "$with_xmu" = "no"; then
2740     XE_ADD_OBJS(xmu.o)
2741   else
2742     XE_PREPEND(-lXmu, libs_x)
2743     AC_DEFINE(HAVE_XMU)
2744   fi
2745
2746   dnl Autodetect -lXbsd
2747   dnl #### Someone, please add a better function than main
2748   AC_CHECK_LIB(Xbsd, main, XE_PREPEND(-lXbsd, libs_x))
2749
2750   dnl Problem with the MIT distribution of X on AIX
2751   if test "$unexec" = "unexaix.o" -a "$x11_release" = "6"; then
2752     dnl X11R6 requires thread-safe code on AIX for some reason
2753     if test "$GCC" = "yes"; then
2754       XE_PREPEND(-mthreads, X_CFLAGS)
2755       XE_PREPEND(-mthreads, libs_x)
2756     else
2757       case "$CC" in
2758         "xlc" ) CC="xlc_r" ;;
2759         "xlC" ) CC="xlC_r" ;;
2760         "cc"  ) CC="cc_r" ;;
2761       esac
2762     fi
2763   fi
2764
2765 fi dnl $with_x11 = yes
2766
2767 if test "$with_msw" != "no"; then
2768   AC_CHECKING(for MS-Windows)
2769   AC_CHECK_LIB(gdi32,main,with_msw=yes)
2770   if test "$with_msw" = "yes"; then
2771     AC_DEFINE(HAVE_MS_WINDOWS)
2772
2773     dnl The net installer only works with MS-Windows currently
2774     XE_APPEND(netinstall, MAKE_SUBDIR)
2775     XE_APPEND(netinstall, SRC_SUBDIR_DEPS)
2776     XE_APPEND(netinstall, INSTALL_ARCH_DEP_SUBDIR)
2777
2778     install_pp="$blddir/lib-src/installexe.sh"
2779     XE_APPEND(-lshell32 -lgdi32 -luser32 -lcomdlg32 -lcomctl32 -lwinspool, libs_system)
2780     test "$with_dragndrop" != no && XE_APPEND(msw, dragndrop_proto)
2781     if test "$window_system" != x11; then
2782         window_system=msw
2783         test "$with_scrollbars" != "no" && with_scrollbars=msw \
2784             && XE_ADD_OBJS(scrollbar-msw.o)
2785         test "$with_menubars"   != "no" && with_menubars=msw \
2786             && XE_ADD_OBJS(menubar-msw.o)
2787         test "$with_toolbars"   != "no" && with_toolbars=msw \
2788             && XE_ADD_OBJS(toolbar-msw.o)
2789         test "$with_dialogs"   != "no" && with_dialogs=msw \
2790             && XE_ADD_OBJS(dialog-msw.o)
2791         test "$with_widgets"   != "no" && with_widgets=msw
2792     else
2793         test "$with_scrollbars" != "no" && XE_ADD_OBJS(scrollbar-msw.o)
2794         test "$with_menubars"   != "no" && XE_ADD_OBJS(menubar-msw.o)
2795         test "$with_toolbars"   != "no" && XE_ADD_OBJS(toolbar-msw.o)
2796         test "$with_dialogs"    != "no" && XE_ADD_OBJS(dialog-msw.o)
2797     fi
2798     dnl check for our special version of select
2799     AC_TRY_RUN([#include <fcntl.h>
2800     int main() { return (open("/dev/windows", O_RDONLY, 0) > 0)? 0 : 1; }],
2801     [AC_DEFINE(HAVE_MSG_SELECT)])
2802     with_file_coding=yes
2803     XE_ADD_OBJS(console-msw.o device-msw.o event-msw.o frame-msw.o objects-msw.o select-msw.o redisplay-msw.o glyphs-msw.o gui-msw.o)
2804   fi
2805 fi
2806
2807 AC_SUBST(install_pp)
2808
2809 test -z "$window_system" && window_system="none"
2810
2811 dnl Test for features that require a window system - ANY window system
2812 if test "$window_system" = "none"; then
2813   for feature in menubars scrollbars toolbars dialogs dragndrop xface
2814   do
2815     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2816        AC_MSG_WARN([--with-$feature ignored:  Not valid without window system support])
2817     fi
2818     eval "with_${feature}=no"
2819   done
2820 else
2821   test -z "$with_toolbars" && with_toolbars=yes
2822 fi
2823
2824 dnl ### Test for features that require mswindows support - currently none
2825 dnl ### MS-Windows folks: add code here..... (martin)
2826 if test "$with_msw" != "yes"; then
2827   for feature in   MARTIN_IS_CLUELESS_ABOUT_MSW_FEATURES
2828   do
2829     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2830        AC_MSG_WARN([--with-$feature ignored:  Not valid without MS-Windows support])
2831     fi
2832     eval "with_${feature}=no"
2833   done
2834 else
2835   :
2836 fi
2837
2838 dnl Test for features that require X11 support
2839 if test "$with_x11" != "yes"; then
2840   dnl It ought to be reasonable to have no output device at all, and only use
2841   dnl XEmacs in --batch mode.
2842   dnl if test "$with_tty" = "no" ; then
2843   dnl   AC_MSG_ERROR([No window system support and no TTY support - Unable to proceed.])
2844   dnl fi
2845   for feature in tooltalk cde offix wmcommand xim xmu nas_sound
2846   do
2847     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2848        AC_MSG_WARN([--with-$feature ignored:  Not valid without X support])
2849     fi
2850     eval "with_${feature}=no"
2851   done
2852 fi
2853
2854 dnl Balloon Help requires the Shape extension, not available everywhere,
2855 dnl for example not on AIX 4.3.
2856 if test "$with_x11" = "yes"; then
2857   AC_CHECK_HEADER(X11/extensions/shape.h, [
2858    AC_DEFINE(HAVE_BALLOON_HELP)
2859    XE_ADD_OBJS(balloon_help.o balloon-x.o)])
2860 fi
2861
2862 dnl FSF 19.29 has some bitmapdir stuff here.
2863 bitmapdir=
2864
2865 case "$window_system" in
2866   x11  ) HAVE_X_WINDOWS=yes; echo "  Using X11." ;;
2867   msw  ) HAVE_X_WINDOWS=no ; echo "  Using MS-Windows." ;;
2868   none ) HAVE_X_WINDOWS=no ; echo "  Using no window system." ;;
2869 esac
2870
2871 case "$x_libraries" in *X11R4* )
2872   test "$opsys" = "hpux9"     && opsysfile="s/hpux9-x11r4.h"
2873   test "$opsys" = "hpux9-shr" && opsysfile="s/hpux9shxr4.h"
2874 esac
2875
2876 dnl Enable or disable proper handling of WM_COMMAND
2877 AC_CHECKING(for WM_COMMAND option);
2878 dnl if test "$with_wmcommand" = "yes"; then
2879 if test "$with_wmcommand" != "no"; then
2880   AC_DEFINE(HAVE_WMCOMMAND)
2881 fi
2882
2883 dnl Autodetect Xauth
2884 dnl -lXau is only used by gnuclient, so use a special variable for Xauth X libs
2885 test -z "$with_xauth" && test "$window_system" = "none" && with_xauth=no
2886 test -z "$with_xauth" && { AC_CHECK_HEADER(X11/Xauth.h,          ,with_xauth=no) }
2887 test -z "$with_xauth" && { AC_CHECK_LIB(Xau, XauGetAuthByAddr,[:],with_xauth=no) }
2888 test -z "$with_xauth" && with_xauth=yes
2889 if test "$with_xauth" = "yes"; then
2890   AC_DEFINE(HAVE_XAUTH)
2891   XE_SPACE(libs_xauth, $X_EXTRA_LIBS -lXau $libs_x $X_PRE_LIBS)
2892 fi
2893 AC_SUBST(libs_xauth)
2894
2895 dnl This one is for the static initializeds variables in
2896 dnl offix.c, so that the thing is dumped after lastfile.o
2897 AC_SUBST(dnd_objs)
2898
2899 dnl Autodetect tooltalk
2900 if test "$with_tooltalk" != "no" ; then
2901   dnl autodetect the location of tt_c.h
2902   dnl tt_c.h might be in Tt or desktop include directories
2903   for dir in "" "Tt/" "desktop/" ; do
2904     AC_CHECK_HEADER(${dir}tt_c.h, tt_c_h_file="${dir}tt_c.h"; break)
2905   done
2906   if test -z "$tt_c_h_file"; then
2907     if test "$with_tooltalk" = "yes"; then
2908       USAGE_ERROR("Unable to find required tooltalk header files.")
2909     fi
2910     with_tooltalk=no
2911   fi
2912 fi
2913 if test "$with_tooltalk" != "no" ; then
2914   for extra_libs in "" "-lI18N -lce" "-lcxx"; do
2915     AC_CHECK_LIB(tt, tt_message_create,
2916       tt_libs="-ltt $extra_libs"; break, [:],$extra_libs)
2917   done
2918   if test -z "$tt_libs"; then
2919     if test "$with_tooltalk" = "yes"; then
2920       USAGE_ERROR("Unable to find required tooltalk libraries.")
2921     fi
2922     with_tooltalk=no
2923   fi
2924 fi
2925 test -z "$with_tooltalk" && with_tooltalk=yes
2926 if test "$with_tooltalk" = "yes"; then
2927   AC_DEFINE(TOOLTALK)
2928   AC_DEFINE_UNQUOTED(TT_C_H_FILE, "$tt_c_h_file")
2929   XE_PREPEND($tt_libs, libs_x)
2930   XE_ADD_OBJS(tooltalk.o)
2931 fi
2932
2933 dnl Autodetect CDE
2934 test -z "$with_cde" && { AC_CHECK_HEADER(Dt/Dt.h,               , with_cde=no) }
2935 test -z "$with_cde" && { AC_CHECK_LIB(DtSvc, DtDndDragStart, [:], with_cde=no) }
2936 test -z "$with_cde" && with_cde=yes
2937 if test "$with_dragndrop" = no; then
2938   AC_MSG_WARN([No CDE without generic Drag'n'Drop support])
2939   with_cde=no
2940 fi
2941 if test "$with_cde" = "yes" ; then
2942   AC_DEFINE(HAVE_CDE)
2943   XE_PREPEND(-lDtSvc, libs_x)
2944   XE_APPEND(CDE, dragndrop_proto)
2945   with_tooltalk=yes # CDE requires Tooltalk
2946   need_motif=yes    # CDE requires Motif
2947 fi
2948
2949 dnl Always compile OffiX unless --without-offix is given, no
2950 dnl X11 support is compiled in, no standard Xmu is available,
2951 dnl or dragndrop support is disabled
2952 dnl Because OffiX support currently loses when more than one display
2953 dnl is in use, we now disable it by default -slb 07/10/1998.
2954 test "$window_system" != "x11" && with_offix=no
2955 if test "$with_xmu" != yes -a "$with_x11" = yes; then
2956   AC_MSG_WARN([No OffiX without real Xmu support])
2957   with_offix=no
2958 fi
2959 if test "$with_dragndrop" = no; then
2960   AC_MSG_WARN([No OffiX without generic Drag'n'Drop support])
2961   with_offix=no
2962 fi
2963 if test "$with_cde" = yes; then
2964   AC_MSG_WARN([CDE already found, disabling OffiX support])
2965   with_offix=no
2966 fi
2967 test -z "$with_offix" && with_offix=no
2968 if test "$with_offix" = "yes"; then
2969   AC_DEFINE(HAVE_OFFIX_DND)
2970   XE_APPEND(offix.o, dnd_objs)
2971   XE_APPEND(OffiX, dragndrop_proto)
2972 fi
2973
2974 dnl Autodetect Drag'n'Drop support
2975 dnl always included if CDE, Offix, or MSWindows are defined
2976 if test "$with_dragndrop" != "no" ; then
2977   AC_MSG_CHECKING(if drag and drop API is needed)
2978   if test -n "$dragndrop_proto" ; then
2979     with_dragndrop=yes
2980     AC_MSG_RESULT([yes (${dragndrop_proto} )])
2981     AC_DEFINE(HAVE_DRAGNDROP)
2982     XE_APPEND(dragdrop.o, extra_objs)
2983   else
2984     with_dragndrop=no
2985     AC_MSG_RESULT(no)
2986   fi
2987 fi
2988
2989 dnl Autodetect LDAP
2990 AC_CHECKING(for LDAP)
2991 test -z "$with_ldap" && { AC_CHECK_HEADER(ldap.h, ,with_ldap=no) }
2992 test -z "$with_ldap" && { AC_CHECK_HEADER(lber.h, ,with_ldap=no) }
2993 if test "$with_ldap" != "no"; then
2994   AC_CHECK_LIB(ldap, ldap_search, with_ldap_nolber=yes, with_ldap_nolber=no)
2995   test "$with_ldap_nolber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_lber=yes, with_ldap_lber=no, -llber) }
2996   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krb=yes, with_ldap_krb=no, -llber -lkrb) }
2997   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" -a "$with_ldap_krb" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krbdes=yes, with_ldap_krbdes=no, -llber -lkrb -ldes) }
2998   test -z "$with_ldap" -a \( "$with_ldap_lber" = "yes" -o "$with_ldap_nolber" = "yes" -o "$with_ldap_krb" = "yes" -o "$with_ldap_krbdes" = "yes" \) && with_ldap=yes
2999 fi
3000 if test "$with_ldap" = "yes"; then
3001   AC_DEFINE(HAVE_LDAP)
3002   XE_ADD_OBJS(eldap.o)
3003   if test "$with_ldap_nolber" = "yes" ; then
3004     XE_PREPEND(-lldap, LIBS)
3005   else
3006     if test "$with_ldap_krb" = "yes" ; then
3007       XE_PREPEND(-lkrb, LIBS)
3008     fi
3009     if test "$with_ldap_krbdes" = "yes" ; then
3010       XE_PREPEND(-ldes, LIBS)
3011       XE_PREPEND(-lkrb, LIBS)
3012     fi
3013     XE_PREPEND(-llber, LIBS)
3014     XE_PREPEND(-lldap, LIBS)
3015   fi
3016   AC_CHECK_FUNCS(ldap_set_option ldap_get_lderrno ldap_result2error ldap_parse_result)
3017 fi
3018
3019 dnl Autodetect PostgreSQL
3020 dnl On many Linux systems, PostgreSQL is packaged to be installed in /usr;
3021 dnl in this case, configure will easily detect it there.
3022 dnl
3023 dnl If PostgreSQL is installed into a different prefix,
3024 dnl (such as the default /usr/local/pgsql when building from source),
3025 dnl that prefix must be specified using the --site-prefixes flag.
3026 if test "$with_postgresql" != "no"; then
3027   AC_CHECKING(for PostgreSQL)
3028
3029 dnl Look for these standard header file locations, known to be used on Linux
3030   for header_dir in "" "pgsql/" "postgresql/"; do
3031     AC_CHECK_HEADER(${header_dir}libpq-fe.h,
3032                     libpq_fe_h_file=${header_dir}libpq-fe.h; break)
3033   done
3034
3035   test -n "$libpq_fe_h_file" && { AC_CHECK_LIB(pq,PQconnectdb,have_libpq=yes) }
3036
3037   if test -n "$libpq_fe_h_file" -a "$have_libpq" = "yes"; then
3038     with_postgresql=yes
3039     AC_DEFINE(HAVE_POSTGRESQL)
3040     AC_CHECK_LIB(pq,PQconnectStart, [
3041                  with_postgresqlv7=yes;
3042                  AC_DEFINE(HAVE_POSTGRESQLV7)])
3043     AC_DEFINE_UNQUOTED(LIBPQ_FE_H_FILE, "$libpq_fe_h_file")
3044     XE_PREPEND(-lpq, LIBS)
3045     XE_ADD_OBJS(postgresql.o)
3046   elif test "$with_postgresql" = "yes"; then
3047     XE_DIE("Required PostgreSQL support cannot be provided.  Check --site-prefixes.")
3048   fi
3049 fi
3050
3051 dnl ----------------------
3052 dnl Graphics libraries
3053 dnl ----------------------
3054
3055 if test "$window_system" != "none"; then
3056   AC_CHECKING(for graphics libraries)
3057
3058   dnl Autodetect Xpm
3059   xpm_problem=""
3060   if test -z "$with_xpm"; then
3061     AC_MSG_CHECKING(for Xpm - no older than 3.4f)
3062     xe_check_libs=-lXpm
3063     AC_TRY_RUN([#define XPM_NUMBERS
3064 #include <X11/xpm.h>
3065     int main(int c, char **v) {
3066     return c == 1 ? 0 :
3067       XpmIncludeVersion != XpmLibraryVersion() ? 1 :
3068       XpmIncludeVersion < 30406 ? 2 : 0 ;}],
3069     [./conftest dummy_arg; xpm_status=$?;
3070       if test "$xpm_status" = "0"; then
3071         with_xpm=yes;
3072       else
3073         with_xpm=no;
3074         if test "$xpm_status" = "1"; then
3075           xpm_problem="Xpm library version and header file version don't match!"
3076         elif test "$xpm_status" = "2"; then
3077           xpm_problem="Xpm library version is too old!"
3078         else
3079           xpm_problem="Internal xpm detection logic error!"
3080         fi
3081         echo "
3082 *** WARNING *** $xpm_problem
3083   I'm not touching that with a 10-foot pole!
3084   If you really want to use the installed version of Xpm, rerun
3085   configure and add '--with-xpm=yes', but don't blame me if XEmacs crashes!"
3086     fi],
3087     [with_xpm=no])
3088     xe_check_libs=
3089     AC_MSG_RESULT($with_xpm)
3090   fi
3091   if test "$with_xpm" = "yes"; then
3092     AC_DEFINE(HAVE_XPM)
3093     XE_PREPEND(-lXpm, libs_x)
3094     AC_MSG_CHECKING(for \"FOR_MSW\" xpm)
3095     xe_check_libs=-lXpm
3096     AC_TRY_LINK(, [XpmCreatePixmapFromData()],
3097     [xpm_for_msw=no],
3098     [xpm_for_msw=yes])
3099     xe_check_libs=
3100     AC_MSG_RESULT($xpm_for_msw)
3101     if test "$xpm_for_msw" = "yes"; then
3102       AC_DEFINE(FOR_MSW)
3103     fi
3104   fi
3105
3106   dnl Autodetect XFACE
3107   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
3108   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
3109   test -z "$with_xface" && with_xface=yes
3110   if test "$with_xface" = "yes"; then
3111     AC_DEFINE(HAVE_XFACE)
3112     XE_PREPEND(-lcompface, libs_x)
3113   fi
3114
3115   dnl For a brief period we had the GIF code split out into a separate library,
3116   dnl but patent problems, etc. sort of squashed that idea.
3117   dnl We default to building with builtin GIF decoding
3118   if test "$with_gif" != "no"; then
3119     with_gif="yes"
3120     AC_DEFINE(HAVE_GIF)
3121     XE_ADD_OBJS(dgif_lib.o gif_io.o)
3122   fi
3123
3124   dnl Too many stupid linkers can't detect cascaded lib dependencies until runtime
3125   dnl So we always search for libz compression support.
3126   if test "$with_png $with_tiff" != "no no"; then
3127     AC_CHECK_LIB(c,  inflate, [:], [
3128     AC_CHECK_LIB(z,  inflate, [XE_PREPEND(-lz,  libs_x)],[
3129     AC_CHECK_LIB(gz, inflate, [XE_PREPEND(-lgz, libs_x)])])])
3130   fi
3131
3132   dnl autodetect JPEG
3133   test -z "$with_jpeg" && { AC_CHECK_HEADER(jpeglib.h,                    ,with_jpeg=no) }
3134   test -z "$with_jpeg" && { AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,[:],with_jpeg=no) }
3135   test -z "$with_jpeg" && with_jpeg=yes
3136   if test "$with_jpeg" = "yes"; then
3137     AC_DEFINE(HAVE_JPEG)
3138     XE_PREPEND(-ljpeg, libs_x)
3139   fi
3140
3141   dnl autodetect PNG
3142   png_problem=""
3143   test -z "$with_png" && { AC_CHECK_FUNC(pow,                  ,with_png=no) }
3144   test -z "$with_png" && { AC_CHECK_HEADER(png.h,              ,with_png=no) }
3145   test -z "$with_png" && { AC_CHECK_LIB(png, png_read_image,[:],with_png=no) }
3146   if test -z "$with_png"; then
3147     AC_MSG_CHECKING(for workable png version information)
3148     xe_check_libs="-lpng -lz"
3149     AC_TRY_RUN([#include <png.h>
3150     int main(int c, char **v) {
3151     if (c == 1) return 0;
3152     if (strcmp(png_libpng_ver, PNG_LIBPNG_VER_STRING) != 0) return 1;
3153     return (PNG_LIBPNG_VER < 10002) ? 2 : 0 ;}],
3154     [./conftest dummy_arg; png_status=$?;
3155       if test "$png_status" = "0"; then
3156         with_png=yes;
3157       else
3158         with_png=no;
3159         if test "$png_status" = "1"; then
3160           png_problem="PNG library version and header file don't match!"
3161         elif test "$png_status" = "2"; then
3162           png_problem="PNG library version too old (pre 1.0.2)!"
3163         fi
3164         echo "
3165 *** WARNING *** $png_problem
3166   I'm not touching that with a 10-foot pole!
3167   If you really want to use the installed version of libPNG, rerun
3168   configure and add '--with-png=yes', but don't blame me if XEmacs crashes!"
3169     fi],
3170     [with_png=no])
3171     xe_check_libs=
3172     AC_MSG_RESULT($with_png)
3173   fi
3174   if test "$with_png" = "yes"; then
3175     AC_DEFINE(HAVE_PNG)
3176     XE_PREPEND(-lpng, libs_x)
3177   fi
3178
3179   dnl autodetect TIFF
3180   test -z "$with_tiff" && { AC_CHECK_HEADER(tiffio.h,            ,with_tiff=no) }
3181   test -z "$with_tiff" && { AC_CHECK_LIB(tiff, TIFFClientOpen,[:],with_tiff=no) }
3182   test -z "$with_tiff" && with_tiff=yes
3183   if test "$with_tiff" = "yes"; then
3184     AC_DEFINE(HAVE_TIFF)
3185     XE_PREPEND(-ltiff, libs_x)
3186   fi
3187 fi
3188
3189 dnl ----------------------
3190 dnl X-Specific Graphics libraries
3191 dnl ----------------------
3192
3193 if test "$with_x11" = "yes"; then
3194
3195   AC_CHECKING(for X11 graphics libraries)
3196
3197   AC_CHECKING(for the Athena widgets)
3198
3199   dnl What in heck did the user actually want?
3200   case "$with_athena" in
3201     dnl This is the default, old fashioned flat Athena.
3202     "xaw" | "") athena_variant=Xaw      athena_3d=no  ;;
3203     "3d")       athena_variant=Xaw3d    athena_3d=yes ;;
3204     "next")     athena_variant=neXtaw   athena_3d=yes ;;
3205     "95")       athena_variant=Xaw95    athena_3d=yes ;;
3206     "xpm")      athena_variant=XawXpm   athena_3d=yes ;;
3207     *)          XE_DIE("Unknown Athena widget set \`$with_athena'. This should not happen.") ;;
3208   esac
3209
3210   dnl Search for the Athena library...
3211   if test "$athena_3d" = "no"; then
3212     AC_CHECK_LIB($athena_variant, XawScrollbarSetThumb,
3213       [
3214         dnl Must not be a 3d library...
3215         AC_CHECK_LIB($athena_variant, threeDClassRec,
3216           AC_MSG_WARN("Could not find a non-3d Athena widget library."),
3217           athena_lib=$athena_variant)
3218       ],
3219       AC_MSG_WARN("Could not find an Athena widget library."))
3220   else
3221     dnl The real configuration, need 3d library
3222     AC_CHECK_LIB($athena_variant, threeDClassRec, athena_lib=$athena_variant,
3223       dnl OK, couldn't find it with a proper name, try the standard Athena lib
3224       dnl If that is 3d, presume the user asked for what they have installed.
3225       AC_CHECK_LIB(Xaw, threeDClassRec,
3226         [
3227           athena_lib=Xaw;
3228           AC_MSG_WARN("Assuming that libXaw is actually $athena_variant.");
3229         ],
3230         AC_MSG_WARN("Could not find a 3d Athena widget library that looked like $athena_variant.")))
3231   fi
3232
3233   dnl Now we locate the Athena headers that we need.
3234   if test "$athena_3d" = "no"; then
3235     AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3236       AC_MSG_WARN("Could not find a non-3d Athena header set."),
3237       AC_CHECK_HEADER(X11/Xaw/XawInit.h,
3238         athena_h_path=X11/Xaw,
3239         AC_MSG_WARN("Could not find a non-3d Athena header set.")))
3240   else
3241     dnl The three-d Athena headers are so much more slippery.
3242     dnl Curse this `Lets replace standard libraries' thing that they did. :/
3243     AC_CHECK_HEADER(X11/$athena_variant/XawInit.h,
3244       AC_CHECK_HEADER(X11/$athena_variant/ThreeD.h,
3245         athena_h_path=X11/$athena_variant,))
3246
3247     dnl Is the variant specific header directory directly under include?
3248     if test -z "$athena_h_path"; then
3249       AC_CHECK_HEADER($athena_variant/XawInit.h,
3250         AC_CHECK_HEADER($athena_variant/ThreeD.h,
3251           athena_h_path=$athena_variant,))
3252     fi
3253
3254     dnl If we couldn't find the specific variant, try the generic Athena 3d headers
3255     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3256       AC_CHECK_HEADER(X11/Xaw3d/XawInit.h,
3257         AC_CHECK_HEADER(X11/Xaw3d/ThreeD.h,
3258           [
3259             AC_MSG_WARN("Assuming that X11/Xaw3d headers are suitable for $athena_variant.")
3260             athena_h_path=X11/Xaw3d
3261           ],))
3262     fi
3263
3264     dnl Also generic 3d headers directly under include dir
3265     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3266       AC_CHECK_HEADER(Xaw3d/XawInit.h,
3267         AC_CHECK_HEADER(Xaw3d/ThreeD.h,
3268           [
3269             AC_MSG_WARN("Assuming that Xaw3d headers are suitable for $athena_variant.")
3270             athena_h_path=Xaw3d
3271           ],))
3272     fi
3273
3274     dnl If nothing yet found, see if Xaw is a 3d header set...
3275     dnl We AC_MSG_WARN if we fail because I am all out of ideas...
3276     if test -z "$athena_h_path"; then
3277       AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3278         [
3279           AC_MSG_WARN("Assuming that X11/Xaw headers are suitable for $athena_variant.")
3280           athena_h_path=X11/Xaw
3281         ],
3282         AC_MSG_WARN("Could not find a suitable 3d Athena header set."))
3283     fi
3284   fi
3285
3286   dnl Do we actually have a usable Athena widget set? Please?
3287   if test -n "$athena_lib" -a -n "$athena_h_path"; then
3288     have_xaw=yes
3289   else
3290     have_xaw=no
3291   fi
3292
3293   dnl autodetect Motif - but only add to libs_x later (if necessary)
3294   AC_CHECK_HEADER(Xm/Xm.h,
3295    [AC_CHECK_LIB(Xm, XmStringFree, have_motif=yes, have_motif=no)],
3296    have_motif=no)
3297
3298   if test "$have_motif" = "yes"; then
3299     dnl autodetect lesstif
3300     AC_MSG_CHECKING(for Lesstif)
3301     AC_EGREP_CPP(yes,
3302 [#include <Xm/Xm.h>
3303 #ifdef LESSTIF_VERSION
3304 yes
3305 #endif
3306 ], have_lesstif=yes, have_lesstif=no)
3307   AC_MSG_RESULT($have_lesstif)
3308   fi
3309
3310 fi dnl "$with_x11" = "yes"
3311
3312 dnl Finish ensuring that we have values for the various toolkit items.
3313 dnl Not all toolkits support all widgets
3314 dnl if Motif is available we use it for the dialog boxes.
3315
3316 case "$with_menubars" in "" | "yes" | "athena" )
3317   with_menubars="lucid" ;;
3318 esac
3319 case "$with_dialogs" in "" | "yes" | "lucid" )
3320   if   test "$have_motif"     = "yes"; then with_dialogs="motif"
3321   elif test "$have_xaw"       = "yes"; then with_dialogs="athena"
3322   else with_dialogs=no
3323   fi ;;
3324 esac
3325 case "$with_scrollbars" in "" | "yes" )
3326   with_scrollbars="lucid" ;;
3327 esac
3328 case "$with_widgets" in "" | "yes" | "lucid")
3329   if   test "$have_motif" = "yes"; then with_widgets="motif"
3330   elif test "$have_xaw"   = "yes"; then with_widgets="athena"
3331   else with_widgets=no
3332   fi ;;
3333 esac
3334
3335 all_widgets="$with_menubars $with_scrollbars $with_dialogs $with_toolbars $with_widgets"
3336
3337 case "$all_widgets" in
3338   *athena* )
3339     if test "$have_xaw" != "yes"; then
3340       XE_DIE("Could not find a suitable Athena library to build with.")
3341     fi
3342
3343     dnl Add the Lucid widget Athena code
3344     XE_APPEND(lwlib-Xaw.o, lwlib_objs)
3345
3346     dnl Add the Athena widget library we located earlier
3347     XE_PREPEND(-l$athena_lib, libs_x)
3348
3349     dnl Tell lwlib where to find the Athena header files.
3350     dnl Many people have tried to create a `smart' way of doing this,
3351     dnl but all have failed.  Before changing the following ugly definitions,
3352     dnl consult the veterans of many a battle.
3353     AC_DEFINE_UNQUOTED(ATHENA_Scrollbar_h_,"$athena_h_path/Scrollbar.h")
3354     AC_DEFINE_UNQUOTED(ATHENA_Dialog_h_,"$athena_h_path/Dialog.h")
3355     AC_DEFINE_UNQUOTED(ATHENA_Form_h_,"$athena_h_path/Form.h")
3356     AC_DEFINE_UNQUOTED(ATHENA_Command_h_,"$athena_h_path/Command.h")
3357     AC_DEFINE_UNQUOTED(ATHENA_Label_h_,"$athena_h_path/Label.h")
3358     AC_DEFINE_UNQUOTED(ATHENA_LabelP_h_,"$athena_h_path/LabelP.h")
3359     AC_DEFINE_UNQUOTED(ATHENA_Toggle_h_,"$athena_h_path/Toggle.h")
3360     AC_DEFINE_UNQUOTED(ATHENA_ToggleP_h_,"$athena_h_path/ToggleP.h")
3361     AC_DEFINE_UNQUOTED(ATHENA_AsciiText_h_,"$athena_h_path/AsciiText.h")
3362     AC_DEFINE_UNQUOTED(ATHENA_XawInit_h_,"$athena_h_path/XawInit.h")
3363
3364     AC_DEFINE(LWLIB_USES_ATHENA)
3365     AC_DEFINE(NEED_ATHENA)
3366     need_athena="yes"
3367
3368     if test "$athena_3d" = "yes"; then
3369       AC_DEFINE(HAVE_ATHENA_3D)
3370     fi
3371   ;;
3372 esac
3373
3374 case "$all_widgets" in *motif* )
3375   AC_DEFINE(LWLIB_USES_MOTIF)
3376   AC_DEFINE(NEED_MOTIF)
3377   XE_APPEND(lwlib-Xm.o, lwlib_objs)
3378   need_motif=yes ;;
3379 esac
3380
3381 test "$with_menubars"   = "lucid" && XE_APPEND(xlwmenu.o, lwlib_objs)
3382 test "$with_menubars"   = "motif" && XE_APPEND(xlwmenu.o, lwlib_objs)
3383 test "$with_scrollbars" = "lucid" && XE_APPEND(xlwscrollbar.o, lwlib_objs)
3384 test "$with_widgets"   != "no" && test "$with_widgets" != "msw" && \
3385         XE_APPEND(xlwtabs.o xlwgcs.o, lwlib_objs)
3386 case "$with_widgets" in athena* )
3387         XE_APPEND(xlwradio.o xlwcheckbox.o xlwgauge.o, lwlib_objs);;
3388 esac
3389 case "$all_widgets" in *lucid* )
3390   AC_DEFINE(NEED_LUCID)
3391   XE_APPEND(lwlib-Xlw.o, lwlib_objs) ;;
3392 esac
3393
3394 AC_SUBST(lwlib_objs)
3395
3396 test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA)
3397 test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA)
3398
3399 if test "$athena_3d" = "yes"; then
3400   test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA3D)
3401   test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA3D)
3402 fi
3403
3404 case "$with_widgets" in athena* ) AC_DEFINE(LWLIB_WIDGETS_ATHENA);; esac
3405 test "$with_widgets" != "no" && test "$with_widgets" != "msw" && \
3406         AC_DEFINE(LWLIB_TABS_LUCID)
3407
3408 test "$with_menubars"   != "no"    && AC_DEFINE(HAVE_MENUBARS)
3409 test "$with_scrollbars" != "no"    && AC_DEFINE(HAVE_SCROLLBARS)
3410 test "$with_dialogs"    != "no"    && AC_DEFINE(HAVE_DIALOGS)
3411 test "$with_toolbars"   != "no"    && AC_DEFINE(HAVE_TOOLBARS)
3412 test "$with_widgets"    != "no"    && AC_DEFINE(HAVE_WIDGETS)
3413
3414 test "$with_menubars"   = "lucid"  && AC_DEFINE(LWLIB_MENUBARS_LUCID)
3415 test "$with_scrollbars" = "lucid"  && AC_DEFINE(LWLIB_SCROLLBARS_LUCID)
3416
3417 test "$with_menubars"   = "motif"  && AC_DEFINE(LWLIB_MENUBARS_MOTIF)
3418 test "$with_scrollbars" = "motif"  && AC_DEFINE(LWLIB_SCROLLBARS_MOTIF)
3419 test "$with_dialogs"    = "motif"  && AC_DEFINE(LWLIB_DIALOGS_MOTIF)
3420 test "$with_widgets"    = "motif"  && AC_DEFINE(LWLIB_WIDGETS_MOTIF)
3421
3422 test "$with_menubars"   != "no"    && XE_ADD_OBJS(menubar.o)
3423 test "$with_scrollbars" != "no"    && XE_ADD_OBJS(scrollbar.o)
3424 test "$with_dialogs"    != "no"    && XE_ADD_OBJS(dialog.o)
3425 test "$with_toolbars"   != "no"    && XE_ADD_OBJS(toolbar.o)
3426
3427 if test "$with_x11" = "yes"; then
3428   test "$with_menubars"   != "no"  && XE_ADD_OBJS(menubar-x.o)
3429   test "$with_scrollbars" != "no"  && XE_ADD_OBJS(scrollbar-x.o)
3430   test "$with_dialogs"    != "no"  && XE_ADD_OBJS(dialog-x.o)
3431   test "$with_toolbars"   != "no"  && XE_ADD_OBJS(toolbar-x.o)
3432   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-x.o)
3433 fi
3434
3435 dnl ----------------------
3436 dnl Mule-dependent options
3437 dnl ----------------------
3438
3439 test -z "$with_mule" && with_mule=no
3440 test -z "$with_file_coding" && with_file_coding=no
3441
3442 dnl if test "$with_mule" = "yes" && test ! -d "$srcdir/lisp/mule"; then
3443 dnl     echo "Attempt to Build with Mule without Mule/Lisp"
3444 dnl     echo "Please install the XEmacs/Mule tarball or"
3445 dnl     echo "rerun configure with --with-mule=no"
3446 dnl     exit 1
3447 dnl fi
3448
3449 if test "$with_file_coding" = "yes" && test "$with_mule" = "no"; then
3450   AC_DEFINE(FILE_CODING)
3451   XE_ADD_OBJS(file-coding.o)
3452 fi
3453
3454 if test "$with_mule" = "yes" ; then
3455   AC_CHECKING(for Mule-related features)
3456   AC_DEFINE(MULE)
3457   AC_DEFINE(FILE_CODING)
3458   XE_ADD_OBJS(mule.o mule-ccl.o mule-charset.o)
3459   if test "$with_utf_2000" = "yes" && test "$with_text_coding" = "yes"; then
3460     AC_DEFINE(TEXT_CODING)
3461     XE_ADD_OBJS(text-coding.o)
3462   else
3463     XE_ADD_OBJS(file-coding.o)
3464   fi
3465   dnl Use -lintl to get internationalized strerror for Mule
3466   AC_CHECK_HEADERS(libintl.h)
3467   AC_CHECK_LIB(intl, strerror)
3468
3469   if test "$with_utf_2000" = "yes" ; then
3470     AC_DEFINE(CHAR_IS_UCS4)
3471     AC_DEFINE(UTF2000)
3472   fi
3473
3474   AC_CHECKING(for Mule input methods)
3475   dnl Do we have the XmIm* routines?  And if so, do we want to use them?
3476   dnl XIM seems to be flaky except on Solaris...
3477   dnl test -z "$with_xim" -a "$opsys" != "sol2" && with_xim=no
3478   case "$with_xim" in "" | "yes" )
3479     AC_CHECKING(for XIM)
3480     AC_CHECK_LIB(X11, XOpenIM, with_xim=xlib, with_xim=no)
3481     dnl XIM + Lesstif is not (yet?) usable
3482     if test "$have_motif $have_lesstif" = "yes no"; then
3483       AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif)
3484     fi ;;
3485   esac
3486   if test "$with_xim" != "no"; then
3487     AC_DEFINE(HAVE_XIM)
3488     if test "$with_xim" = "xlib"; then
3489       AC_DEFINE(XIM_XLIB)
3490       XE_ADD_OBJS(input-method-xlib.o)
3491     fi
3492     if test "$with_xim" = "motif"; then
3493       AC_DEFINE(XIM_MOTIF)
3494       need_motif=yes
3495       XE_ADD_OBJS(input-method-motif.o)
3496     fi
3497     if test "$with_xim" = "motif"; then
3498       with_xfs=no
3499     fi
3500   fi
3501
3502   dnl "with_xfs" = "yes"
3503   if test "$with_xfs" = "yes" ; then
3504     AC_CHECKING(for XFontSet)
3505     AC_CHECK_LIB(X11, XmbDrawString, [:], with_xfs=no)
3506     if test "$with_xfs" = "yes" && test "$with_menubars" = "lucid"; then
3507       AC_DEFINE(USE_XFONTSET)
3508       if test "$with_xim" = "no" ; then
3509         XE_ADD_OBJS(input-method-xlib.o)
3510       fi
3511     fi
3512   fi dnl with_xfs
3513
3514   dnl Autodetect WNN
3515   test "$with_wnn6" = "yes" && with_wnn=yes # wnn6 implies wnn support
3516   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/jllib.h, ,with_wnn=no) }
3517   dnl Detour to find crypt
3518   if test "$with_wnn" != "no"; then
3519     AC_CHECK_FUNCS(crypt)
3520     test "$ac_cv_func_crypt" != "yes" && { AC_CHECK_LIB(crypt, crypt) }
3521   fi
3522   dnl Back to our regularly scheduled wnn hunting
3523   if test -z "$with_wnn" -o "$with_wnn" = "yes"; then
3524     AC_CHECK_LIB(wnn,jl_dic_list_e,libwnn=wnn,
3525       AC_CHECK_LIB(wnn4,jl_dic_list_e,libwnn=wnn4,
3526         AC_CHECK_LIB(wnn6,jl_dic_list_e,libwnn=wnn6,
3527           AC_CHECK_LIB(wnn6_fromsrc,dic_list_e,libwnn=wnn6_fromsrc,with_wnn=no))))
3528   fi
3529   test -z "$with_wnn" && with_wnn=yes
3530   if test "$with_wnn" = "yes"; then
3531     AC_DEFINE(HAVE_WNN)
3532     XE_PREPEND(-l$libwnn, libs_x)
3533     XE_ADD_OBJS(mule-wnnfns.o)
3534     if test "$with_wnn6" != "no"; then
3535       AC_CHECK_LIB($libwnn, jl_fi_dic_list, with_wnn6=yes)
3536       test "$with_wnn6" = "yes" && AC_DEFINE(WNN6)
3537     fi
3538   fi
3539
3540   dnl Autodetect canna
3541   canna_includes_found=no
3542   if test "$with_canna" != "no"; then
3543     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3544   fi
3545   if test "$canna_includes_found" = "no" -a "$with_canna" != "no" -a \
3546       -d "/usr/local/canna/include"; then
3547     save_c_switch_site="$c_switch_site"
3548     c_switch_site="$c_switch_site -I/usr/local/canna/include"
3549     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3550     if test "$canna_includes_found" != "yes"; then
3551       c_switch_site="$save_c_switch_site"
3552       with_canna="no"
3553     fi
3554   fi
3555
3556   test -z "$with_canna" && { AC_CHECK_HEADER(canna/RK.h,         , with_canna=no) }
3557   test -z "$with_canna" && { AC_CHECK_LIB(RKC, RkBgnBun,       [:],with_canna=no) }
3558   test -z "$with_canna" && { AC_CHECK_LIB(canna,jrKanjiControl,[:],with_canna=no) }
3559   test -z "$with_canna" && with_canna=yes
3560   if test "$with_canna" = "yes"; then
3561     AC_DEFINE(HAVE_CANNA)
3562     XE_PREPEND(-lcanna -lRKC, libs_x)
3563     XE_ADD_OBJS(mule-canna.o)
3564   fi
3565
3566 else dnl "$with_mule" = "no"
3567   for feature in xim canna wnn; do
3568     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3569       AC_MSG_WARN("--with-${feature} ignored:  Not valid without Mule support")
3570     fi
3571     eval "with_${feature}=no"
3572   done
3573 fi dnl with_mule
3574
3575
3576 dnl At this point, we know whether we need the motif lib or not.
3577 if test "$need_motif" = "yes" ; then
3578   XE_PREPEND(-lXm, libs_x)
3579   dnl AIX needs the following library for use with Motif
3580   AC_CHECK_LIB(i18n, layout_object_getvalue, [XE_PREPEND(-li18n, libs_x)])
3581   XE_COMPUTE_RUNPATH()
3582 fi
3583
3584 AC_CHECK_FUNCS(cbrt closedir dup2 eaccess fmod fpathconf frexp ftime getaddrinfo gethostname getnameinfo getpagesize gettimeofday getcwd getwd logb lrand48 matherr mkdir mktime perror poll random rename res_init rint rmdir select setitimer setpgid setlocale setsid sigblock sighold sigprocmask snprintf stpcpy strerror tzset ulimit usleep utimes waitpid vsnprintf fsync ftruncate umask)
3585
3586 dnl Check for PTY support functions.
3587 dnl  getpt  is the preferred pty allocation method on glibc systems.
3588 dnl _getpty is the preferred pty allocation method on SGI systems.
3589 dnl grantpt, unlockpt, ptsname are defined by Unix98.
3590 AC_CHECK_FUNCS(getpt _getpty grantpt unlockpt ptsname killpg tcgetpgrp)
3591
3592 dnl openpty is the preferred pty allocation method on BSD and Tru64 systems.
3593 dnl openpty might be declared in pty.h or in libutil.h.
3594 AC_CHECK_FUNC(openpty, have_openpty=yes, [
3595   AC_CHECK_LIB(util, openpty, have_openpty=yes need_libutil=yes)])
3596 if test "$have_openpty" = "yes"; then
3597   AC_DEFINE(HAVE_OPENPTY)
3598   AC_CHECK_HEADERS(pty.h libutil.h)
3599   test "$need_libutil" = "yes" && XE_APPEND(-lutil, libs_system)
3600 fi
3601
3602 dnl Check for STREAM support functions.
3603 dnl Confusingly, "str" means both "string" and "SysV Streams".
3604 AC_CHECK_HEADERS(stropts.h)
3605 if test "$ac_cv_header_stropts_h" = "yes"; then
3606   AC_CHECK_FUNCS(isastream)
3607   AC_CHECK_HEADERS(strtio.h) dnl TIOCSIGNAL
3608 fi
3609
3610 dnl Use our own realpath always.
3611 XE_ADD_OBJS(realpath.o)
3612
3613 dnl Check whether the system provides getloadavg().
3614 AC_CHECK_FUNCS(getloadavg)
3615
3616 if test "$ac_cv_func_getloadavg" = "yes"; then
3617   dnl Solaris 8 declares getloadavg() in <sys/loadavg.h>.
3618   dnl glibc 2.2 declares getloadavg() in <stdlib.h>...
3619   dnl   ...if we #define _GNU_SOURCE, which we do.
3620   AC_CHECK_HEADERS(sys/loadavg.h)
3621 else
3622   dnl We define our own getloadavg() using lower level functions.
3623   XE_ADD_OBJS(getloadavg.o)
3624
3625   dnl Used by getloadavg() - does not require root priveleges
3626   AC_CHECK_LIB(kstat, kstat_open)
3627   AC_CHECK_HEADERS(kstat.h)
3628
3629   dnl Another way to get the load average
3630   AC_CHECK_LIB(kvm, kvm_read)
3631 fi
3632
3633 dnl If netdb.h does not declare h_errno, we must declare it by hand.
3634 AC_MSG_CHECKING(whether netdb declares h_errno)
3635 AC_TRY_LINK([#include <netdb.h>],
3636   [return h_errno;],
3637   [AC_MSG_RESULT(yes)
3638    AC_DEFINE(HAVE_H_ERRNO)],
3639   [AC_MSG_RESULT(no)])
3640
3641 AC_MSG_CHECKING(for sigsetjmp)
3642 AC_TRY_COMPILE([#include <setjmp.h>],
3643         [sigjmp_buf bar; sigsetjmp (bar, 0);],
3644   [AC_MSG_RESULT(yes)
3645    AC_DEFINE(HAVE_SIGSETJMP)],
3646   [AC_MSG_RESULT(no)])
3647
3648 AC_MSG_CHECKING(whether localtime caches TZ)
3649 AC_CACHE_VAL(emacs_cv_localtime_cache,
3650 [if test "$ac_cv_func_tzset" = "yes"; then
3651 AC_TRY_RUN([#include <time.h>
3652 #if STDC_HEADERS
3653 # include <stdlib.h>
3654 #endif
3655 extern char **environ;
3656 unset_TZ ()
3657 {
3658   char **from, **to;
3659   for (to = from = environ; (*to = *from); from++)
3660     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
3661       to++;
3662 }
3663 char TZ_GMT0[] = "TZ=GMT0";
3664 char TZ_PST8[] = "TZ=PST8";
3665 main()
3666 {
3667   time_t now = time ((time_t *) 0);
3668   int hour_GMT0, hour_unset;
3669   if (putenv (TZ_GMT0) != 0)
3670     exit (1);
3671   hour_GMT0 = localtime (&now)->tm_hour;
3672   unset_TZ ();
3673   hour_unset = localtime (&now)->tm_hour;
3674   if (putenv (TZ_PST8) != 0)
3675     exit (1);
3676   if (localtime (&now)->tm_hour == hour_GMT0)
3677     exit (1);
3678   unset_TZ ();
3679   if (localtime (&now)->tm_hour != hour_unset)
3680     exit (1);
3681   exit (0);
3682 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3683 [# If we have tzset, assume the worst when cross-compiling.
3684 emacs_cv_localtime_cache=yes])
3685 else
3686         # If we lack tzset, report that localtime does not cache TZ,
3687         # since we can't invalidate the cache if we don't have tzset.
3688         emacs_cv_localtime_cache=no
3689 fi],[:])dnl
3690 AC_MSG_RESULT($emacs_cv_localtime_cache)
3691 if test $emacs_cv_localtime_cache = yes; then
3692   AC_DEFINE(LOCALTIME_CACHE)
3693 fi
3694
3695 if test "$HAVE_TIMEVAL" = "yes"; then
3696 AC_MSG_CHECKING(whether gettimeofday accepts one or two arguments)
3697 AC_TRY_LINK([
3698 #ifdef TIME_WITH_SYS_TIME
3699 #include <sys/time.h>
3700 #include <time.h>
3701 #else
3702 #ifdef HAVE_SYS_TIME_H
3703 #include <sys/time.h>
3704 #else
3705 #include <time.h>
3706 #endif
3707 #endif
3708   ],
3709   [
3710   struct timeval time;
3711   gettimeofday (&time, 0);
3712 ],
3713   [AC_MSG_RESULT(two)],
3714   [AC_MSG_RESULT(one)
3715    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
3716 fi
3717
3718
3719 AC_C_INLINE
3720 test "$ac_cv_c_inline" != "no" -a "$GCC" = "yes" && XE_ADD_OBJS(inline.o)
3721
3722 dnl HP-UX has a working alloca in libPW.
3723 dnl case "${GCC}${opsys}" in hpux* )
3724 dnl  AC_CHECK_FUNC(alloca, [:], [AC_CHECK_LIB(PW, alloca)])
3725 dnl esac
3726
3727 dnl AC_FUNC_ALLOCA doesn't know about DEC C's #pragma intrinsic(alloca)
3728 if test "$__DECC" != "yes"; then
3729   AC_FUNC_ALLOCA
3730   test -n "$ALLOCA" && XE_ADD_OBJS($ALLOCA)
3731 fi
3732
3733 dnl Check whether vfork exists and works correctly. (This does more
3734 dnl than just check for its existence.) If so, it defines HAVE_VFORK_H.
3735 dnl If not, it defines vfork to be fork.
3736 AC_FUNC_VFORK
3737
3738 dnl Check whether strcoll exists and works correctly. (This does more
3739 dnl than just check for its existence.) If so, it defines HAVE_STRCOLL.
3740 AC_FUNC_STRCOLL
3741
3742 dnl If `getpgrp' takes no argument (the POSIX.1 version), define
3743 dnl `GETPGRP_VOID'.  Otherwise, it is the BSD version, which takes a
3744 dnl process ID as an argument.
3745 AC_CHECK_FUNCS(getpgrp)
3746 AC_FUNC_GETPGRP
3747
3748 dnl We used to call AC_FUNC_MMAP here
3749 dnl Instead we now use following, suggested by Neal Becker
3750 AC_MSG_CHECKING(for working mmap)
3751 case "$opsys" in ultrix* ) have_mmap=no ;; *)
3752 AC_TRY_RUN([#include <stdio.h>
3753 #include <unistd.h>
3754 #include <fcntl.h>
3755 #include <sys/mman.h>
3756
3757 #ifndef MAP_VARIABLE
3758 #define MAP_VARIABLE 0
3759 #endif
3760
3761 #ifndef MAP_FAILED
3762 #define MAP_FAILED -1
3763 #endif
3764
3765 int main (int argc, char *argv[])
3766 {
3767   int fd = -1;
3768   caddr_t p;
3769 #ifndef MAP_ANONYMOUS
3770   fd = open ("/dev/zero", O_RDWR);
3771   if (fd < 0)
3772     return 1;
3773 #define MAP_ANONYMOUS 0
3774 #endif
3775   if (mmap(0, 1024, PROT_READ | PROT_WRITE,
3776            MAP_PRIVATE | MAP_VARIABLE | MAP_ANONYMOUS,
3777            fd, 0) != (void *) MAP_FAILED)
3778     return 0;
3779   perror ("conftest: mmap failed");
3780   return 1;
3781 }], have_mmap=yes, have_mmap=no) ;;
3782 esac
3783 AC_MSG_RESULT($have_mmap)
3784 test "$have_mmap" = "yes" && AC_DEFINE(HAVE_MMAP)
3785
3786 dnl rel_alloc requires either GNU malloc or system malloc with mmap
3787 dnl We only turn rel_alloc on by default if mmap is available.
3788 test "$GNU_MALLOC" != "yes" -a "$have_mmap" != "yes" && rel_alloc=no
3789 if test "$rel_alloc $have_mmap" = "default yes"; then
3790   if test "$doug_lea_malloc" = "yes"; then
3791     dnl Check if malloc() calls mmap(), making rel_alloc pointless.
3792     AC_MSG_CHECKING(for M_MMAP_THRESHOLD)
3793     AC_TRY_COMPILE([#include <malloc.h>],[
3794 #ifndef M_MMAP_THRESHOLD
3795 #error No M_MMAP_THRESHOLD :-(
3796 !@+$%^&*_)(_ - unlikely to compile...
3797 #endif
3798 ], [rel_alloc=no; AC_MSG_RESULT(yes);], [rel_alloc=yes; AC_MSG_RESULT(no);])
3799   else
3800     rel_alloc=yes
3801   fi
3802 fi
3803 test "$rel_alloc" = "yes" && AC_DEFINE(REL_ALLOC)
3804
3805 dnl Check for terminal I/O variants
3806 dnl TERMIOS systems may have termio.h, but not vice-versa, I think.
3807 AC_CHECK_HEADER(termios.h,
3808   AC_DEFINE(HAVE_TERMIOS)
3809   AC_DEFINE(SIGNALS_VIA_CHARACTERS)
3810   AC_DEFINE(NO_TERMIO),
3811   [AC_CHECK_HEADER(termio.h, [AC_DEFINE(HAVE_TERMIO)])])
3812
3813
3814 dnl Check for Internet sockets.
3815 AC_CHECK_FUNC(socket,
3816  [AC_CHECK_HEADER(netinet/in.h,
3817    [AC_CHECK_HEADER(arpa/inet.h, [
3818   AC_DEFINE(HAVE_SOCKETS)
3819       AC_MSG_CHECKING("for sun_len member in struct sockaddr_un")
3820       AC_TRY_LINK([
3821 #include <sys/types.h>
3822 #include <sys/socket.h>
3823 #include <sys/un.h>
3824       ],
3825       [static struct sockaddr_un x; x.sun_len = 1;],
3826       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)],
3827       [AC_MSG_RESULT(no)])
3828       AC_MSG_CHECKING("for ip_mreq struct in netinet/in.h")
3829       AC_TRY_LINK([
3830 #include <sys/types.h>
3831 #include <netinet/in.h>
3832       ],
3833       [static struct ip_mreq x;],
3834       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MULTICAST)],
3835       [AC_MSG_RESULT(no)])])])])
3836
3837 dnl Check for SYS V IPC. (Inferior to sockets.)
3838 AC_CHECK_FUNC(msgget,
3839   [AC_CHECK_HEADER(sys/ipc.h,
3840     [AC_CHECK_HEADER(sys/msg.h,
3841       [AC_DEFINE(HAVE_SYSVIPC)])])])
3842
3843 dnl Check for directory variants
3844 AC_CHECK_HEADER(dirent.h, [AC_DEFINE(SYSV_SYSTEM_DIR)],
3845   [AC_CHECK_HEADER(sys/dir.h, , [AC_DEFINE(NONSYSTEM_DIR_LIBRARY)])])
3846
3847 dnl Check for nlist.h
3848 AC_CHECK_HEADER(nlist.h, AC_DEFINE(NLIST_STRUCT), )
3849
3850 dnl Check for sound of various sorts.
3851
3852 dnl Autodetect native sound
3853 AC_CHECKING("for sound support")
3854 test -z "$with_native_sound" -a -n "$native_sound_lib" && with_native_sound=yes
3855
3856 if test "$with_native_sound" != "no"; then
3857   dnl Maybe sound is already on include path...
3858   if test -n "$native_sound_lib"; then
3859     AC_CHECK_HEADER(multimedia/audio_device.h,
3860       [sound_found=yes sound_cflags=""
3861       XE_ADD_OBJS(sunplay.o)])
3862   fi
3863
3864   dnl Autodetect Sun native sound from SUNWaudmo package
3865   if test -z "$sound_found" -a -d "/usr/demo/SOUND"; then
3866     sound_found=yes
3867     XE_ADD_OBJS(sunplay.o)
3868     if test -d "/usr/demo/SOUND/include"
3869       then sound_cflags="-I/usr/demo/SOUND/include"
3870       else sound_cflags="-I/usr/demo/SOUND"
3871     fi
3872     if test -z "$native_sound_lib" ; then
3873       if test -r "/usr/demo/SOUND/lib/libaudio.a"
3874         then native_sound_lib="/usr/demo/SOUND/lib/libaudio.a"
3875         else native_sound_lib="/usr/demo/SOUND/libaudio.a"
3876       fi
3877     fi
3878   fi
3879
3880   dnl Check for SGI and HP native sound libs
3881   if test -z "$sound_found"; then
3882     case "$canonical" in
3883     *-sgi-* )
3884       if test -z "$native_sound_lib"; then
3885         AC_CHECK_LIB(audio, ALopenport, native_sound_lib="-laudio")
3886       fi
3887       if test -n "$native_sound_lib"; then
3888         sound_found=yes sound_cflags=""
3889         XE_ADD_OBJS(sgiplay.o)
3890       fi ;;
3891     hppa*-hp-hpux* )
3892       if test -z "$native_sound_lib"; then
3893         AC_CHECK_LIB(Alib, AOpenAudio, native_sound_lib="-lAlib")
3894       fi
3895       if test -n "$native_sound_lib"; then
3896         sound_found=yes
3897         XE_ADD_OBJS(hpplay.o)
3898         if test "$GCC" = "yes" # Kludge city
3899           then sound_cflags="-Dconst= -Dvolatile= -I/usr/audio/examples"
3900           else sound_cflags="+e -I/usr/audio/examples"
3901         fi
3902       fi ;;
3903     esac
3904   fi
3905
3906   dnl Check for Linux/BSD native sound
3907   if test -z "$sound_found"; then
3908     for dir in "machine" "sys" "linux"; do
3909       AC_CHECK_HEADER(${dir}/soundcard.h,
3910         sound_found=yes
3911        need_miscplay=yes
3912         XE_ADD_OBJS(linuxplay.o)
3913         [AC_DEFINE_UNQUOTED(SOUNDCARD_H_FILE, "${dir}/soundcard.h")]
3914         break)
3915     done
3916   fi
3917
3918   dnl Win32 Native uses native sound
3919   if test -z "$sound_found"; then
3920     if test "$with_msw" = "yes"; then
3921     sound_found=yes
3922     native_sound_lib=
3923     fi
3924   fi
3925
3926   test "$sound_found" = "yes" && with_native_sound=yes
3927 fi
3928
3929 if test "$with_native_sound" = "yes"; then
3930   AC_DEFINE(HAVE_NATIVE_SOUND)
3931   test -n "$native_sound_lib" && XE_PREPEND($native_sound_lib, LIBS)
3932 fi
3933
3934 dnl NAS Sound support
3935 if test "$with_nas_sound" != "no"; then
3936   AC_CHECK_HEADER(audio/audiolib.h, [
3937     AC_CHECK_LIB(audio, AuOpenServer, have_nas_sound=yes)])
3938   if test "$have_nas_sound" = "yes"; then
3939     with_nas_sound=yes
3940     AC_DEFINE(HAVE_NAS_SOUND)
3941     XE_ADD_OBJS(nas.o)
3942     XE_PREPEND(-laudio, libs_x)
3943     dnl If the nas library does not contain the error jump point,
3944     dnl then we force safer behavior.
3945     AC_EGREP_HEADER(AuXtErrorJump,audio/Xtutil.h,,[old_nas=yes; AC_DEFINE(NAS_NO_ERROR_JUMP)])
3946   else
3947     test "$with_nas_sound" = "yes" && \
3948       XE_DIE("Required NAS sound support cannot be provided.")
3949     with_nas_sound=no
3950   fi
3951 fi
3952
3953 dnl ESD Sound support
3954 if test "$with_esd_sound" != "no"; then
3955   AC_CHECK_PROG(have_esd_config, esd-config, yes, no)
3956   if test "$have_esd_config" = "yes"; then
3957     save_c_switch_site="$c_switch_site" save_LIBS="$LIBS"
3958     XE_APPEND(`esd-config --cflags`, c_switch_site)
3959     XE_PREPEND(`esd-config --libs`, LIBS)
3960     AC_CHECK_FUNC(esd_play_stream,
3961       have_esd_sound=yes,
3962       c_switch_site="$save_c_switch_site" LIBS="$save_LIBS")
3963   fi
3964
3965   if test "$have_esd_sound" = "yes"; then
3966     with_esd_sound=yes
3967     need_miscplay=yes
3968     XE_ADD_OBJS(esd.o)
3969     AC_DEFINE(HAVE_ESD_SOUND)
3970   else
3971     test "$with_esd_sound" = "yes" && \
3972       XE_DIE("Required ESD sound support cannot be provided.")
3973     with_esd_sound=no
3974   fi
3975 fi
3976
3977 test "$need_miscplay" = "yes" && XE_ADD_OBJS(miscplay.o)
3978
3979 dnl ---------------------
3980 dnl TTY-dependent options
3981 dnl ---------------------
3982
3983 test -z "$with_tty" && with_tty=yes
3984
3985 if test "$with_tty" = "yes"  ; then
3986   AC_CHECKING(for TTY-related features)
3987   AC_DEFINE(HAVE_TTY)
3988   XE_ADD_OBJS(console-tty.o device-tty.o event-tty.o frame-tty.o objects-tty.o redisplay-tty.o cm.o)
3989
3990   dnl Autodetect ncurses.
3991   if test -z "$with_ncurses"; then
3992     AC_CHECK_LIB(ncurses, tgetent, with_ncurses=yes, with_ncurses=no)
3993   fi
3994   if test "$with_ncurses" = "yes"; then
3995     AC_DEFINE(HAVE_NCURSES)
3996     AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
3997     AC_CHECK_HEADER(ncurses/term.h, term_h_file=ncurses/term.h)
3998     XE_ADD_OBJS(terminfo.o)
3999     XE_PREPEND(-lncurses, LIBS)
4000
4001     if test "$ac_cv_header_ncurses_curses_h" != "yes" ; then
4002       dnl Try again, and check for the bogus ncurses/ include bug.
4003       dnl (i.e. ncurses/curses.h bogusly includes <unctrl.h> instead of
4004       dnl <ncurses/unctrl.h>)
4005       save_c_switch_site="$c_switch_site"
4006       c_switch_site="$c_switch_site -I/usr/include/ncurses"
4007       AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
4008       if test "$ac_cv_header_ncurses_curses_h" = "yes"
4009         then AC_MSG_WARN("Your system has the bogus ncurses include bug.")
4010         else c_switch_site="$save_c_switch_site"
4011       fi
4012     fi
4013   else dnl "$with_ncurses" = "no"
4014     dnl Autodetect terminfo/-lcurses/-ltermlib/-ltermcap
4015     if test "$have_terminfo" = "yes"; then
4016       XE_ADD_OBJS(terminfo.o)
4017       if test -n "$libs_termcap"; then
4018         XE_PREPEND($libs_termcap, LIBS)
4019       else
4020         for lib in curses termlib termcap; do
4021           AC_CHECK_LIB($lib, tgetent, XE_PREPEND(-l${lib}, LIBS); break)
4022         done
4023       fi
4024     else dnl "$have_terminfo" = "no" && "with_ncurses" = "no"
4025       XE_ADD_OBJS(tparam.o)
4026       dnl The HP-UX curses library seems to have a badly broken version of select(2)
4027       dnl that makes "poll: interrupted system call" messages to appear and
4028       dnl Emacs suprocesses to hang (e.g. TeX compilation w/ AUCTeX) */
4029       case "$opsys" in *-hp-hpux* ) libs_termcap="-ltermcap" ;; esac
4030       if test -n "$libs_termcap"; then
4031         XE_PREPEND($libs_termcap, LIBS)
4032       else
4033         AC_CHECK_LIB(curses, tgetent, XE_PREPEND(-lcurses, LIBS),
4034           AC_CHECK_LIB(termcap, tgetent, XE_PREPEND(-ltermcap, LIBS),
4035             XE_ADD_OBJS(termcap.o)))
4036       fi
4037     fi
4038   fi
4039   AC_DEFINE_UNQUOTED(CURSES_H_FILE, "${curses_h_file-curses.h}")
4040   AC_DEFINE_UNQUOTED(TERM_H_FILE, "${term_h_file-term.h}")
4041
4042   dnl Autodetect gpm
4043   test -z "$with_gpm" && { AC_CHECK_HEADER(gpm.h, , with_gpm=no) }
4044   test -z "$with_gpm" && { AC_CHECK_LIB(gpm, Gpm_Open, with_gpm=yes, with_gpm=no) }
4045   if test "$with_gpm" = "yes"; then
4046     AC_DEFINE(HAVE_GPM)
4047     XE_ADD_OBJS(gpmevent.o)
4048     XE_PREPEND(-lgpm, LIBS)
4049   fi
4050
4051 else dnl "$with_tty" = "no"
4052   for feature in ncurses gpm; do
4053     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
4054       AC_MSG_WARN("--with-${feature} ignored:  Not valid without TTY support")
4055     fi
4056     eval "with_${feature}=no"
4057   done
4058 fi dnl with_tty
4059
4060 dnl Do we need event-unixoid.o ?
4061 test "$with_x11" = "yes" -o "$with_tty" = "yes" && XE_ADD_OBJS(event-unixoid.o)
4062
4063 dnl Database support
4064 dnl We do not necessarily have to have libdb/lib(g)dbm for DB/(G)DBM support.
4065 dnl On FreeBSD, both DB and DBM are part of libc.
4066 dnl By default, we check for DBM support in libgdbm, then libc, then libdbm.
4067
4068 test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4069   != "no no no" && AC_CHECKING(for database support)
4070
4071 dnl Check for ndbm.h, required for either kind of DBM support.
4072 if test "$with_database_gdbm $with_database_dbm" != "no no"; then
4073   AC_CHECK_HEADER(ndbm.h, [:], [
4074     test "$with_database_gdbm" = "yes" -o \
4075          "$with_database_dbm"  = "yes" && \
4076       XE_DIE("Required DBM support cannot be provided.")
4077     with_database_gdbm=no with_database_dbm=no])
4078 fi
4079
4080 dnl Check for DBM support in libgdbm.
4081 if test "$with_database_gdbm" != "no"; then
4082   AC_CHECK_LIB(gdbm, dbm_open, [
4083    with_database_gdbm=yes with_database_dbm=no libdbm=-lgdbm], [
4084    if test "$with_database_gdbm" = "yes"; then
4085      XE_DIE("Required GNU DBM support cannot be provided.")
4086    fi
4087    with_database_gdbm=no])
4088 fi
4089
4090 dnl Check for DBM support in libc and libdbm.
4091 if test "$with_database_dbm" != "no"; then
4092   AC_CHECK_FUNC(dbm_open, [with_database_dbm=yes libdbm=], [
4093     AC_CHECK_LIB(dbm, dbm_open, [with_database_dbm=yes libdbm=-ldbm], [
4094       test "$with_database_dbm" = "yes" && \
4095         XE_DIE("Required DBM support cannot be provided.")
4096       with_database_dbm=no])])
4097 fi
4098
4099 dnl Tell make about the DBM support we detected.
4100 test -n "$libdbm" && XE_PREPEND("$libdbm", LIBS)
4101 test "$with_database_gdbm" = "yes" -o \
4102      "$with_database_dbm"  = "yes" && \
4103   AC_DEFINE(HAVE_DBM)
4104
4105 dnl Check for Berkeley DB.
4106 if test "$with_database_berkdb" != "no"; then
4107   AC_MSG_CHECKING(for Berkeley db.h)
4108   for header in "db/db.h" "db.h"; do
4109     AC_TRY_COMPILE([
4110 #include <stdlib.h>
4111 #if !(defined __GLIBC__ && __GLIBC_MINOR__ >= 1)
4112 #ifdef HAVE_INTTYPES_H
4113 #define __BIT_TYPES_DEFINED__
4114 #include <inttypes.h>
4115 typedef uint8_t  u_int8_t;
4116 typedef uint16_t u_int16_t;
4117 typedef uint32_t u_int32_t;
4118 #ifdef WE_DONT_NEED_QUADS
4119 typedef uint64_t u_int64_t;
4120 #endif
4121 #endif
4122 #endif
4123 #include <$header>
4124 ],[], db_h_file="$header"; break)
4125   done
4126   if test -z "$db_h_file"
4127   then AC_MSG_RESULT(no); with_database_berkdb=no
4128   else AC_MSG_RESULT($db_h_file)
4129   fi
4130
4131   if test "$with_database_berkdb" != "no"; then
4132     AC_MSG_CHECKING(for Berkeley DB version)
4133     AC_EGREP_CPP(yes,
4134 [#include <$db_h_file>
4135 #if DB_VERSION_MAJOR > 1
4136 yes
4137 #endif
4138 ], [AC_EGREP_CPP(yes,
4139 [#include <$db_h_file>
4140 #if DB_VERSION_MAJOR > 2
4141 yes
4142 #endif
4143 ], [AC_MSG_RESULT(3); dbfunc=db_create],[
4144     AC_MSG_RESULT(2); dbfunc=db_open])],[
4145     AC_MSG_RESULT(1); dbfunc=dbopen])
4146     AC_CHECK_FUNC($dbfunc,     with_database_berkdb=yes need_libdb=no, [
4147     AC_CHECK_LIB(db, $dbfunc,  with_database_berkdb=yes need_libdb=yes)])
4148   fi
4149
4150   if test "$with_database_berkdb" = "yes"; then
4151     AC_DEFINE_UNQUOTED(DB_H_FILE, "$db_h_file")
4152     AC_DEFINE(HAVE_BERKELEY_DB)
4153     test "$need_libdb" = "yes" && XE_PREPEND(-ldb, LIBS)
4154   else with_database_berkdb=no
4155   fi
4156 fi
4157
4158 if test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4159      != "no no no"; then
4160   AC_DEFINE(HAVE_DATABASE)
4161   XE_ADD_OBJS(database.o)
4162 fi
4163
4164 dnl Socks support
4165 if test "$with_socks" = "yes"; then
4166   AC_CHECK_LIB(socks, SOCKSinit)
4167   test -n "$ac_cv_lib_socks_SOCKSinit" && AC_DEFINE(HAVE_SOCKS)
4168 fi
4169
4170 dnl Usage tracking (undocumented and likely unused option)
4171 if test "$usage_tracking" = "yes"; then
4172   AC_DEFINE(USAGE_TRACKING)
4173   XE_PREPEND(-Bstatic -lut -Bdynamic, LIBS)
4174 fi
4175
4176 dnl autodetect dll support
4177 if test "$with_modules" != "no"; then
4178   AC_CHECKING(for module support)
4179
4180   dnl Check for MS-Windows
4181   if test "$with_msw" = "yes"; then
4182     have_dl=yes;
4183   else
4184     dnl Find headers and libraries
4185     AC_CHECK_HEADER(dlfcn.h, [
4186       AC_MSG_CHECKING([for dlopen in -lc])
4187       AC_TRY_LINK([#include <dlfcn.h>],dnl
4188         [dlopen ("", 0);], [ have_dl=yes ], [
4189       AC_MSG_CHECKING([for dlopen in -ldl])
4190       ac_save_LIBS="$LIBS"
4191       LIBS="-ldl $LIBS"
4192       AC_TRY_LINK([#include <dlfcn.h>],dnl
4193         [dlopen ("", 0);], [ have_dl=yes ],
4194         [LIBS="$ac_save_LIBS"])
4195       ac_save_LIBS=])])
4196     if test -n "$have_dl"; then
4197       AC_DEFINE(HAVE_DLOPEN)
4198     else
4199       AC_CHECK_LIB(dld, shl_load, [
4200         libdl=dld have_dl=yes;
4201         AC_DEFINE(HAVE_SHL_LOAD)], [
4202         AC_CHECK_LIB(dld, dld_init, [
4203         libdl=dld have_dl=yes;
4204         AC_DEFINE(HAVE_DLD_INIT)])])
4205     fi
4206   fi dnl end !MS-Windows
4207
4208   if test -n "$have_dl"; then
4209     dnl XE_SHLIB_STUFF (in aclocal.m4) defines $can_build_shared
4210     XE_SHLIB_STUFF
4211   fi
4212
4213   if test "$can_build_shared" = "yes"; then
4214     AC_DEFINE(HAVE_SHLIB)
4215     XE_ADD_OBJS(sysdll.o emodules.o)
4216     XE_APPEND(src, INSTALL_ARCH_DEP_SUBDIR)
4217     test -n "$libdl" && XE_PREPEND(-l${libdl}, LIBS)
4218     AC_CHECK_FUNCS(dlerror _dlerror)
4219     with_modules=yes
4220   else
4221     if test "$with_modules" = "yes"; then
4222       XE_DIE("Required module support cannot be provided.")
4223     else
4224       AC_MSG_WARN("Module support cannot be provided.")
4225     fi
4226     with_modules=no
4227   fi
4228 fi
4229
4230 dnl Unfortunately, just because we can link doesn't mean we can run.
4231 dnl One of the above link tests may have succeeded but caused resulting
4232 dnl executables to fail to run.  Also any tests using AC_TRY_RUN will
4233 dnl have reported incorrect results.
4234 AC_TRY_RUN([int main(int c,char *v[]){return 0;}],[:],[
4235   echo ""
4236   echo "*** PANIC *** The C compiler can no longer build working executables."
4237   echo "*** PANIC *** Please examine the tail of config.log for runtime errors."
4238   echo "*** PANIC *** The most likely reason for this problem is that configure"
4239   echo "*** PANIC *** links with shared libraries, but those libraries cannot be"
4240   echo "*** PANIC *** found at run time."
4241   echo "*** PANIC ***"
4242   echo "*** PANIC *** On a Linux system, edit /etc/ld.so.conf and re-run ldconfig."
4243   echo "*** PANIC *** On other systems, try telling configure where to find the"
4244   echo "*** PANIC *** shared libraries using the --site-runtime-libraries option"
4245   echo "*** PANIC ***"
4246   echo "*** PANIC *** Another way to shoot yourself in the foot is to specify"
4247   echo "*** PANIC *** --with-FEATURE when FEATURE is not actually installed"
4248   echo "*** PANIC *** on your system.  Don't do that."
4249   exit 1])
4250
4251 dnl Process support
4252 if test "$win32_processes" = "yes"; then
4253   XE_ADD_OBJS(process-nt.o)
4254 else
4255   AC_DEFINE(HAVE_UNIX_PROCESSES)
4256   XE_ADD_OBJS(process-unix.o)
4257 fi
4258
4259 dnl --------------------------------
4260 dnl Compute SUBST-itutable variables
4261 dnl --------------------------------
4262
4263 dnl We ignore (C|LD)_SWITCH_X_(MACHINE|SYSTEM)
4264 dnl Use XE_SPACE instead of plain assignment statements to remove extraneous blanks
4265 XE_SPACE(CFLAGS, $CFLAGS)
4266 XE_SPACE(extra_objs, $extra_objs)
4267 XE_SPACE(c_switch_general, -DHAVE_CONFIG_H $c_switch_site $c_switch_machine $c_switch_system)
4268 XE_SPACE(c_switch_window_system, $c_switch_x_site $X_CFLAGS)
4269 XE_SPACE(c_switch_all, $c_switch_general $c_switch_window_system)
4270 XE_SPACE(ld_switch_general, $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_run)
4271 XE_SPACE(ld_switch_window_system, $ld_switch_x_site)
4272 XE_SPACE(ld_switch_all, $ld_switch_general $ld_switch_window_system)
4273 XE_SPACE(ld_libs_general, $LIBS $libs_machine $libs_system $libs_standard)
4274 XE_SPACE(ld_libs_window_system, $X_EXTRA_LIBS $libs_x $X_PRE_LIBS)
4275 XE_SPACE(ld_libs_all, $ld_libs_window_system $ld_libs_general)
4276
4277 dnl Compute lists of Makefiles and subdirs
4278 AC_SUBST(SRC_SUBDIR_DEPS)
4279 XE_APPEND(src, MAKE_SUBDIR)
4280 internal_makefile_list="Makefile.in"
4281 SUBDIR_MAKEFILES=''
4282 test -d lock || mkdir lock
4283 for dir in $MAKE_SUBDIR; do
4284   case "$dir" in */* ) dnl Implement mkdir -p
4285     ( for d in `echo $dir | sed 's:/: :g'` ; do
4286         test -d "$d" || mkdir "$d"; cd "$d"
4287       done ) ;;
4288    * ) test -d "$dir" || mkdir "$dir" ;;
4289   esac
4290   XE_SPACE(SUBDIR_MAKEFILES, $SUBDIR_MAKEFILES $dir/Makefile $dir/GNUmakefile)
4291   XE_SPACE(internal_makefile_list, $internal_makefile_list $dir/Makefile.in)
4292 done
4293 AC_SUBST(INSTALL_ARCH_DEP_SUBDIR)
4294 AC_SUBST(MAKE_SUBDIR)
4295 AC_SUBST(SUBDIR_MAKEFILES)
4296
4297 dnl Make s&m symlinks in the src directory, for config.h
4298 for dir in src/s src/m; do
4299   if test ! -d "$dir" ; then
4300     echo Making symbolic link to "$srcdir/$dir"
4301     ${LN_S} "$srcdir/$dir" "$dir"
4302   fi
4303 done
4304
4305 if test "$extra_verbose" = "yes"; then
4306   echo ""
4307   PRINT_VAR(extra_objs
4308    c_switch_general  c_switch_window_system  c_switch_all
4309   ld_switch_general ld_switch_window_system ld_switch_all
4310     ld_libs_general   ld_libs_window_system   ld_libs_all)
4311   echo ""
4312 fi
4313
4314 dnl ----------------------------------------------
4315 dnl Create some auxiliary files for developers.
4316 dnl ----------------------------------------------
4317
4318 dnl Create a .gdbinit useful for debugging XEmacs
4319 if test -f "$srcdir/src/.gdbinit" -a ! -f "src/.gdbinit"; then
4320   test "$extra_verbose" = "yes" && echo "creating src/.gdbinit"
4321   echo "source $srcdir/src/.gdbinit" > "src/.gdbinit"
4322 fi
4323
4324 dnl Create a .dbxrc useful for debugging XEmacs
4325 if test -f "$srcdir/src/.dbxrc" -a ! -f "src/.dbxrc"; then
4326   test "$extra_verbose" = "yes" && echo "creating src/.dbxrc"
4327   echo ". $srcdir/src/.dbxrc" > "src/.dbxrc"
4328 fi
4329
4330 dnl Create a useful TAGS file
4331 if test -f "$srcdir/TAGS" -a ! -f "TAGS"; then
4332   test "$extra_verbose" = "yes" && echo "creating TAGS"
4333   echo "\f
4334 $srcdir/TAGS,include" > "TAGS"
4335 fi
4336
4337 dnl Create top level .sbinit for Sun compilers
4338 if test "$__SUNPRO_C" = "yes"; then
4339   test "$extra_verbose" = "yes" && echo "creating .sbinit"
4340   ( echo "# For use with Sun WorkShop's Source browser."
4341     echo "# See sbquery(1) and sbinit(4) for more information"
4342     for dir in $MAKE_SUBDIR; do echo "import $dir"; done
4343   ) > .sbinit
4344 fi
4345
4346 dnl There are no more compile tests; remove the core they created.
4347 rm -f core
4348
4349 dnl ----------------------------------------------
4350 dnl Substitute into Makefile, config.h and paths.h
4351 dnl ----------------------------------------------
4352
4353 dnl what sort of things to edit into Makefile, config.h and paths.h
4354 dnl configuration here uncanonicalized to avoid exceeding size limits.
4355
4356 AC_SUBST(PROGNAME)
4357 AC_SUBST(version)
4358 AC_SUBST(configuration)
4359 AC_SUBST(canonical)
4360 AC_SUBST(inststaticdir)
4361 AC_SUBST(instvardir)
4362 AC_SUBST(srcdir)
4363 AC_SUBST(bindir)
4364 AC_SUBST(datadir)
4365 AC_SUBST(pkgdir)
4366 AC_SUBST(statedir)
4367 AC_SUBST(libdir)
4368 AC_SUBST(mandir)
4369 AC_SUBST(extra_includes)
4370
4371 AC_SUBST(prefix)
4372 AC_SUBST(PREFIX_USER_DEFINED)
4373 dnl Yo, Stephen Bourne!  I want to marry you!
4374 PREFIX=$prefix
4375 while true; do
4376   case "$PREFIX" in
4377     *\$* ) eval "PREFIX=$PREFIX" ;;
4378     *) break ;;
4379   esac
4380 done
4381 AC_SUBST(PREFIX)
4382
4383 AC_SUBST(exec_prefix)
4384 AC_SUBST(EXEC_PREFIX_USER_DEFINED)
4385 EXEC_PREFIX=$exec_prefix
4386 while true; do
4387   case "$EXEC_PREFIX" in
4388     *\$* ) eval "EXEC_PREFIX=$EXEC_PREFIX" ;;
4389     *) break ;;
4390   esac
4391 done
4392 AC_SUBST(EXEC_PREFIX)
4393
4394 AC_SUBST(infodir)
4395 AC_SUBST(INFODIR_USER_DEFINED)
4396 INFODIR=$infodir
4397 while true; do
4398   case "$INFODIR" in
4399     *\$* ) eval "INFODIR=$INFODIR" ;;
4400     *) break ;;
4401   esac
4402 done
4403 AC_SUBST(INFODIR)
4404
4405 AC_SUBST(infopath)
4406 AC_SUBST(INFOPATH_USER_DEFINED)
4407 INFOPATH=$infopath
4408 while true; do
4409   case "$INFOPATH" in
4410     *\$* ) eval "INFOPATH=$INFOPATH" ;;
4411     *) break ;;
4412   esac
4413 done
4414 AC_SUBST(INFOPATH)
4415
4416 AC_SUBST(package_path)
4417 AC_SUBST(PACKAGE_PATH_USER_DEFINED)
4418 PACKAGE_PATH=$package_path
4419 while true; do
4420   case "$PACKAGE_PATH" in
4421     *\$* ) eval "PACKAGE_PATH=$PACKAGE_PATH" ;;
4422     *) break ;;
4423   esac
4424 done
4425 AC_SUBST(PACKAGE_PATH)
4426
4427 AC_SUBST(lispdir)
4428 AC_SUBST(LISPDIR_USER_DEFINED)
4429 LISPDIR=$lispdir
4430 while true; do
4431   case "$LISPDIR" in
4432     *\$* ) eval "LISPDIR=$LISPDIR" ;;
4433     *) break ;;
4434   esac
4435 done
4436 AC_SUBST(LISPDIR)
4437
4438 AC_SUBST(moduledir)
4439 AC_SUBST(MODULEDIR_USER_DEFINED)
4440 MODULEDIR=$moduledir
4441 while true; do
4442   case "$MODULEDIR" in
4443     *\$* ) eval "MODULEDIR=$MODULEDIR" ;;
4444     *) break ;;
4445   esac
4446 done
4447 AC_SUBST(MODULEDIR)
4448
4449 AC_SUBST(sitelispdir)
4450 AC_SUBST(SITELISPDIR_USER_DEFINED)
4451 SITELISPDIR=$sitelispdir
4452 while true; do
4453   case "$SITELISPDIR" in
4454     *\$* ) eval "SITELISPDIR=$SITELISPDIR" ;;
4455     *) break ;;
4456   esac
4457 done
4458 AC_SUBST(SITELISPDIR)
4459
4460 AC_SUBST(sitemoduledir)
4461 AC_SUBST(SITEMODULEDIR_USER_DEFINED)
4462 SITEMODULEDIR=$sitemoduledir
4463 while true; do
4464   case "$SITEMODULEDIR" in
4465     *\$* ) eval "SITEMODULEDIR=$SITEMODULEDIR" ;;
4466     *) break ;;
4467   esac
4468 done
4469 AC_SUBST(SITEMODULEDIR)
4470
4471 AC_SUBST(etcdir)
4472 AC_SUBST(ETCDIR_USER_DEFINED)
4473 ETCDIR=$etcdir
4474 while true; do
4475   case "$ETCDIR" in
4476     *\$* ) eval "ETCDIR=$ETCDIR" ;;
4477     *) break ;;
4478   esac
4479 done
4480 AC_SUBST(ETCDIR)
4481
4482 AC_SUBST(docdir)
4483 AC_SUBST(DOCDIR_USER_DEFINED)
4484 DOCDIR=$docdir
4485 while true; do
4486   case "$DOCDIR" in
4487     *\$* ) eval "DOCDIR=$DOCDIR" ;;
4488     *) break ;;
4489   esac
4490 done
4491 AC_SUBST(DOCDIR)
4492
4493 AC_SUBST(archlibdir)
4494 AC_SUBST(ARCHLIBDIR_USER_DEFINED)
4495 ARCHLIBDIR=$archlibdir
4496 while true; do
4497   case "$ARCHLIBDIR" in
4498     *\$* ) eval "ARCHLIBDIR=$ARCHLIBDIR" ;;
4499     *) break ;;
4500   esac
4501 done
4502 AC_SUBST(ARCHLIBDIR)
4503
4504 AC_SUBST(docdir)
4505 AC_SUBST(bitmapdir)
4506 AC_SUBST(extra_objs)
4507
4508 dnl The following flags combine all the information from:
4509 dnl - command line options (user always gets priority)
4510 dnl - user environment variables
4511 dnl - determined by configure
4512 dnl - the s&m header files (required for ellcc)
4513 AC_SUBST(machfile)
4514 AC_SUBST(opsysfile)
4515 AC_SUBST(c_switch_general)
4516 AC_SUBST(c_switch_window_system)
4517 AC_SUBST(c_switch_all)
4518 AC_SUBST(ld_switch_general)
4519 AC_SUBST(ld_switch_window_system)
4520 AC_SUBST(ld_switch_all)
4521 AC_SUBST(ld_libs_general)
4522 AC_SUBST(ld_libs_window_system)
4523 AC_SUBST(ld_libs_all)
4524 AC_SUBST(CFLAGS)
4525 AC_SUBST(CPPFLAGS)
4526 AC_SUBST(LDFLAGS)
4527 RECURSIVE_MAKE="\$(MAKE) \$(MFLAGS) CC='\$(CC)' CFLAGS='\$(CFLAGS)' LDFLAGS='\$(LDFLAGS)' CPPFLAGS='\$(CPPFLAGS)'"
4528 AC_SUBST(RECURSIVE_MAKE)
4529
4530 AC_SUBST(native_sound_lib)
4531 AC_SUBST(sound_cflags)
4532 AC_SUBST(RANLIB)
4533 AC_SUBST(dynodump_arch)
4534
4535 dnl Preliminary support for using a different compiler for xemacs itself.
4536 dnl Useful for building XEmacs with a C++ or 64-bit compiler.
4537 : ${XEMACS_CC:=$CC}
4538 AC_SUBST(XEMACS_CC)
4539
4540 dnl The default is yes
4541 if test "$with_prefix" = "yes"; then
4542   AC_DEFINE(PREFIX_USER_DEFINED)
4543 fi
4544
4545 dnl The default is no
4546 if test "$with_site_lisp" = "no"; then
4547   AC_DEFINE(INHIBIT_SITE_LISP)
4548 fi
4549 dnl The default is yes
4550 if test "$with_site_modules" = "no"; then
4551   AC_DEFINE(INHIBIT_SITE_MODULES)
4552 fi
4553
4554 XE_SPACE(ac_configure_args, $ac_configure_args)
4555 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "$configuration")
4556 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "$ac_configure_args")
4557
4558 dnl Following are deprecated
4559
4560 null_string=""
4561 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE,     $null_string)
4562 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, $null_string)
4563 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,      $null_string)
4564 AC_DEFINE_UNQUOTED(LD_SWITCH_SITE,       $null_string)
4565 AC_DEFINE_UNQUOTED(C_SWITCH_SITE,        $null_string)
4566
4567 dnl Note: as a general rule, *only* define things here that are not
4568 dnl autodetected.  For things that are autodetected, define them
4569 dnl at the point where the autodetection occurs or would occur,
4570 dnl so that the user gets immediate feedback on the results of the
4571 dnl autodetection.
4572
4573 if   test "$GNU_MALLOC"         = "yes"; then AC_DEFINE(GNU_MALLOC)
4574 elif test "$with_system_malloc" = "yes"; then AC_DEFINE(USE_SYSTEM_MALLOC)
4575 elif test "$with_debug_malloc"  = "yes"; then AC_DEFINE(USE_DEBUG_MALLOC)
4576                                               AC_DEFINE(USE_SYSTEM_MALLOC)
4577 fi
4578 test "$with_i18n3"         = "yes" && AC_DEFINE(I18N3)
4579 test "$GCC"                = "yes" && AC_DEFINE(USE_GCC)
4580 test "$external_widget"    = "yes" && AC_DEFINE(EXTERNAL_WIDGET)
4581 test "$quick_build"        = "yes" && AC_DEFINE(QUICK_BUILD)
4582 test "$with_purify"        = "yes" && AC_DEFINE(PURIFY)
4583 test "$with_quantify"      = "yes" && AC_DEFINE(QUANTIFY)
4584 test "$with_pop"           = "yes" && AC_DEFINE(MAIL_USE_POP)
4585 test "$with_kerberos"      = "yes" && AC_DEFINE(KERBEROS)
4586 test "$with_hesiod"        = "yes" && AC_DEFINE(HESIOD)
4587 test "$use_union_type"     = "yes" && AC_DEFINE(USE_UNION_TYPE)
4588 test "$pdump"              = "yes" && AC_DEFINE(PDUMP)
4589
4590 dnl -------------------------------
4591 dnl Report on what we decided to do
4592 dnl -------------------------------
4593
4594 (
4595 dnl /etc/osversion is on SONY NEWS-OS
4596 if test -f /etc/osversion; then dnl SONY NEWS-OS
4597   echo "osversion: `cat /etc/osversion`"
4598 else
4599   echo "uname -a: `uname -a`"
4600 fi
4601 echo ""
4602 echo "$0 $quoted_arguments"
4603 ) > Installation
4604
4605 if test ! -z ${emacs_beta_version} ; then
4606   if test -z "${emacs_is_beta}" ; then
4607         xemacs_betaname=".${emacs_beta_version}"
4608   else
4609         xemacs_betaname="-b${emacs_beta_version}"
4610   fi
4611 else
4612   xemacs_betaname=""
4613 fi
4614
4615 dnl Start stdout redirection to '| tee -a Installation'
4616 (
4617 echo "
4618
4619 XEmacs ${emacs_major_version}.${emacs_minor_version}${xemacs_betaname} \"$xemacs_codename\" configured for \`$canonical'.
4620 "
4621 echo "
4622 Compilation / Installation:"
4623 echo "  Source code location:              $srcdir"
4624 echo "  Installation prefix:               $prefix"
4625 if test -n "$site_includes"; then
4626   echo "  Additional header files:           $site_includes"
4627 fi
4628 if test -n "$site_libraries"; then
4629   echo "  Additional libraries:              $site_libraries"
4630 fi
4631 if test -n "$site_prefixes"; then
4632   echo "  Additional prefixes:               $site_prefixes"
4633 fi
4634 if test -n "$runpath"; then
4635   echo "  Runtime library search path:       $runpath"
4636 fi
4637
4638 if test -n "$opsysfile"
4639 then echo "  Operating system description file: \`$opsysfile'"
4640 else echo "  Not using any operating system description file"
4641 fi
4642 if test -n "$machfile"
4643 then echo "  Machine description file:          \`$machfile'"
4644 else echo "  Not using any machine description file"
4645 fi
4646
4647 echo "  Compiler:                          $CC $CFLAGS"
4648 echo "  Relocating allocator for buffers:  $rel_alloc"
4649 echo "  GNU version of malloc:             ${GNU_MALLOC}${GNU_MALLOC_reason}"
4650
4651 echo "
4652 Window System:"
4653 if test "$with_msw" = "yes"; then
4654   echo "  Compiling in support for the Microsoft window system."
4655 fi
4656 if test "$with_x11" = "yes"; then
4657   echo "  Compiling in support for the X window system:"
4658   echo "    - X Windows headers location:                 $x_includes"
4659   echo "    - X Windows libraries location:               $x_libraries"
4660   if test "$with_xauth" != yes; then
4661     echo "    - Xau (X authority) not available."
4662   fi
4663   if test "$with_xmu" != yes; then
4664     echo "    - Xmu library not available; substituting equivalent routines."
4665   fi
4666   if test "$with_wmcommand" != no; then
4667     echo "    - Handling WM_COMMAND properly."
4668   fi
4669 fi
4670 if test "$need_athena" = "yes"; then
4671   echo "  Compiling in support for the Athena widget set:"
4672   echo "    - Athena headers location:                    $athena_h_path"
4673   echo "    - Athena library to link:                     $athena_lib"
4674 fi
4675 case "$with_menubars" in
4676   lucid ) echo "  Using Lucid menubars." ;;
4677   motif ) echo "  Using Motif menubars."
4678           echo "  *WARNING*  The Motif menubar implementation is currently buggy."
4679           echo "             We recommend using the Lucid menubar instead."
4680           echo "             Re-run configure with --with-menubars='lucid'." ;;
4681     msw ) echo "  Using MS-Windows menubars." ;;
4682 esac
4683 case "$with_scrollbars" in
4684   lucid  ) echo "  Using Lucid scrollbars."      ;;
4685   motif  ) echo "  Using Motif scrollbars."      ;;
4686   athena ) echo "  Using Athena scrollbars."     ;;
4687      msw ) echo "  Using MS-Windows scrollbars." ;;
4688 esac
4689 case "$with_dialogs" in
4690   motif  ) echo "  Using Motif dialog boxes."
4691            if test "$unexec" = "unexaix.o"; then if test "`uname -v`" = 4 -a "`uname -r`" -ge 3; then
4692              echo "  *WARNING*  The Motif dialog boxes cause problems on AIX 4.3 and higher."
4693              echo "             We recommend using the Athena dialog boxes instead."
4694              echo "             Install libXaw and re-run configure with --with-dialogs='athena'."
4695              echo "             Read the PROBLEMS file for more information."
4696            fi; fi ;;
4697   athena ) echo "  Using Athena dialog boxes."     ;;
4698      msw ) echo "  Using MS-Windows dialog boxes." ;;
4699 esac
4700 case "$with_widgets" in
4701   motif  ) echo "  Using Motif native widgets."      ;;
4702   athena ) echo "  Using Athena native widgets."     ;;
4703      msw ) echo "  Using MS-Windows native widgets." ;;
4704 esac
4705 if test "$with_dragndrop" = yes; then
4706   echo "  Compiling in support for Drag'n'Drop (EXPERIMENTAL)."
4707   echo "    -  Drag'n'Drop prototype:                             $dragndrop_proto."
4708 fi
4709
4710 echo "
4711 TTY:"
4712 test "$with_ncurses" = yes && echo "  Compiling in support for ncurses."
4713 test "$with_gpm" = yes && echo "  Compiling in support for GPM (General Purpose Mouse)."
4714
4715 echo "
4716 Images:"
4717 test "$with_gif" = yes && echo "  Compiling in support for GIF  images (builtin)."
4718 if test "$with_xpm" = yes; then
4719   echo "  Compiling in support for XPM  images."
4720 elif test "$with_x11" = yes; then
4721   echo "  WARNING: -----------------------------------------------------------"
4722   echo "  WARNING: Compiling without XPM image support."
4723   if test "$xpm_problem" != ""; then
4724     echo "  Reason: $xpm_problem"
4725   fi
4726   echo "  WARNING: You should strongly consider installing XPM."
4727   echo "  WARNING: Otherwise toolbars and other graphics will look suboptimal."
4728   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4729   echo "  WARNING: -----------------------------------------------------------"
4730 fi
4731 if test "$with_png" = yes; then
4732   echo "  Compiling in support for PNG  images."
4733 elif test "$window_system" != "none"; then
4734   echo "  WARNING: -----------------------------------------------------------"
4735   echo "  WARNING: Compiling without PNG image support."
4736   if test "$png_problem" != ""; then
4737     echo "  Reason: $png_problem"
4738   fi
4739   echo "  WARNING: You should strongly consider installing the PNG libraries."
4740   echo "  WARNING: Otherwise certain images and glyphs may not display."
4741   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4742   echo "  WARNING: -----------------------------------------------------------"
4743 fi
4744 test "$with_jpeg" = yes && echo "  Compiling in support for JPEG images."
4745 test "$with_tiff" = yes && echo "  Compiling in support for TIFF images."
4746 test "$with_xface" = yes && echo "  Compiling in support for X-Face message headers."
4747
4748 echo "
4749 Sound:"
4750 test "$with_native_sound" = yes && echo "  Compiling in support for sound (native)."
4751 test "$with_nas_sound" = yes && echo "  Compiling in support for NAS (network audio system)."
4752 test "$old_nas" = yes && echo "    - NAS library lacks error trapping; will play synchronously."
4753 test "$with_esd_sound" = yes && echo "  Compiling in support for ESD (Enlightened Sound Daemon)."
4754
4755 echo "
4756 Databases:"
4757 test "$with_database_berkdb" = yes && echo "  Compiling in support for Berkeley database."
4758 test "$with_database_dbm"    = yes && echo "  Compiling in support for DBM."
4759 test "$with_database_gdbm"   = yes && echo "  Compiling in support for GNU DBM."
4760 test "$with_ldap" = yes && echo "  Compiling in support for LDAP."
4761 if test "$with_postgresql" = yes; then
4762   echo "  Compiling in support for PostgreSQL."
4763   echo "    - Using PostgreSQL header file:  $libpq_fe_h_file"
4764   test "$with_postgresqlv7" = yes && echo "    - Using PostgreSQL V7 bindings."
4765 fi
4766
4767 echo "
4768 Internationalization:"
4769 test "$with_mule" = yes && echo "  Compiling in support for Mule (multi-lingual Emacs)."
4770 test "$with_utf_2000" = yes && echo "  Using UTF-2000 (UTF-8) buffer/string representation."
4771 test "$with_text_coding" = yes && echo "  Compiling in support for text coding."
4772 test "$with_file_coding" = yes && echo "  Compiling in support for file coding."
4773 test "$with_xim" != no && echo "  Compiling in support for XIM (X11R5+ I18N input method)."
4774 test "$with_xim" = motif && echo "    - Using Motif to provide XIM support."
4775 test "$with_xim" = xlib && echo "    - Using raw Xlib to provide XIM support."
4776 test "$with_xfs" = yes && echo "    - Using XFontSet to provide bilingual menubar."
4777 test "$with_canna" = yes && echo "  Compiling in support for Canna on Mule."
4778 if test "$with_wnn" = yes; then
4779   echo "  Compiling in support for the WNN input method on Mule."
4780   test "$with_wnn6" = yes && echo "    - Using WNN version 6."
4781 fi
4782 test "$with_i18n3" = yes && echo "  Compiling in support for I18N level 3 (doesn't currently work)."
4783
4784 echo "
4785 Mail:"
4786 test "$with_pop" = yes && echo "  Compiling in support for POP mail retrieval."
4787 test "$with_kerberos" = yes && echo "  Compiling in support for Kerberos POP authentication."
4788 test "$with_hesiod" = yes && echo "  Compiling in support for Hesiod POP server access."
4789 test -n "$mail_locking" && echo "  Compiling in support for \"$mail_locking\" mail spool file locking method."
4790
4791 echo "
4792 Other Features:"
4793 test "$with_tooltalk" = yes && echo "  Compiling in support for ToolTalk."
4794 test "$with_workshop" = yes && echo "  Compiling in support for Sun WorkShop."
4795 test "$with_socks" = yes && echo "  Compiling in support for SOCKS."
4796 test "$with_dnet" = yes && echo "  Compiling in support for DNET."
4797 test "$with_modules" = "yes" && echo "  Compiling in support for dynamic shared object modules."
4798 test "$use_union_type" = yes && echo "  Using the union type for Lisp_Objects."
4799 test "$pdump" = yes && echo "  Using the new portable dumper."
4800 test "$debug" = yes && echo "  Compiling in support for extra debugging code."
4801 test "$usage_tracking" = yes && echo "  Compiling in support for active usage tracking (Sun internal)."
4802 if test "$error_check_extents $error_check_typecheck $error_check_bufpos $error_check_gc $error_check_malloc $error_check_glyphs" \
4803   != "no no no no no no"; then
4804   echo "  WARNING: ---------------------------------------------------------"
4805   echo "  WARNING: Compiling in support for runtime error checking."
4806   echo "  WARNING: XEmacs will run noticeably more slowly as a result."
4807   echo "  WARNING: Error checking is on by default for XEmacs beta releases."
4808   echo "  WARNING: ---------------------------------------------------------"
4809 fi
4810 echo ""
4811 ) | tee -a Installation
4812 dnl echo "The above configure report is appended to \"Installation\" file."
4813 echo ""
4814
4815 dnl -----------------------------------
4816 dnl Now generate config.h and Makefiles
4817 dnl -----------------------------------
4818 dnl This has to be called in order for this variable to get into config.status
4819 AC_SUBST(internal_makefile_list)
4820 # Remove any trailing slashes in these variables.
4821 test -n "$prefix" &&
4822   prefix=`echo '' "$prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4823 test -n "$exec_prefix" &&
4824   exec_prefix=`echo '' "$exec_prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4825
4826 dnl Build Makefile.in's from Makefile.in.in's
4827 dnl except ./Makefile from $srcdir/Makefile.in
4828
4829 for file in $internal_makefile_list; do
4830   test "$file" = src/Makefile.in && \
4831     file="src/Makefile.in:src/Makefile.in.in:src/depend"
4832   XE_APPEND($file, ac_output_files)
4833 done
4834 ac_output_files="$ac_output_files src/paths.h lib-src/config.values"
4835 test "$with_modules" = "yes" && XE_APPEND(lib-src/ellcc.h, ac_output_files)
4836
4837 AC_OUTPUT($ac_output_files,
4838 [for dir in . $MAKE_SUBDIR; do
4839   (
4840     cd $dir
4841     rm -f junk.c
4842     < Makefile.in \
4843       sed -e '/^# Generated/d' \
4844           -e 's%/\*\*/#.*%%' \
4845           -e 's/^ *# */#/' \
4846 dnl Delete Makefile.in.in comment lines
4847           -e '/^##/d' \
4848 dnl Pass through CPP directives unchanged
4849           -e '/^#/ {
4850 p
4851 d
4852 }'        \
4853 dnl Quote other lines to protect from CPP substitution
4854           -e '/./ {
4855 s/\([[\"]]\)/\\\1/g
4856 s/^/"/
4857 s/$/"/
4858 }'  > junk.c;
4859
4860 dnl Create a GNUmakefile and Makefile from Makefile.in.
4861
4862 changequote(<<,>>)dnl
4863 dnl CPP_MAKEFILE(CPPFLAGS,filename)
4864 define(<<CPP_MAKEFILE>>,
4865 echo creating $dir/<<$2>>
4866 $CPP -I. -I${top_srcdir}/src <<$1>> junk.c \
4867 dnl Delete line directives inserted by $CPP
4868   | sed -e 's/^\#.*//'          \
4869 dnl Delete spurious blanks inserted by $CPP
4870         -e 's/^[ TAB][ TAB]*$//'\
4871         -e 's/^ /TAB/'          \
4872 dnl Delete blank lines
4873         -e '/^[ \f]*$/d' \
4874 dnl Restore lines quoted above to original contents.
4875         -e '/^\"/ {
4876         s/\\\([\"]\)/\1/g
4877         s/^[ TAB]*\"//
4878         s/\"[ TAB]*$//
4879 }' > Makefile.new
4880     chmod 444 Makefile.new
4881     mv -f Makefile.new <<$2>>
4882 )dnl CPP_MAKEFILE
4883
4884     CPP_MAKEFILE(,Makefile)
4885     CPP_MAKEFILE(-DUSE_GNU_MAKE,GNUmakefile)
4886 changequote([,])dnl
4887     rm -f junk.c
4888   )
4889 done
4890
4891 dnl Append AC_DEFINE information to lib-src/config.values
4892 dnl (AC_SUBST information is already there (see config.values.sh).
4893 sed < config.status >> lib-src/config.values \
4894   -e '/{ac_dA}.*{ac_dB}.*{ac_dC}.*{ac_dD}$/!d' \
4895   -e 's/\${ac_dA}\(.*\)\${ac_dB}.*\${ac_dC}\(.*\)\${ac_dD}/\1 \2/' \
4896   -e 's/^\([[^ ]]*\) $/\1 ""/' \
4897   -e 's/ 1$/ t/'
4898
4899 ],
4900 [CPP="$CPP"
4901  top_srcdir="$srcdir"
4902  MAKE_SUBDIR="$MAKE_SUBDIR"
4903 ])dnl