configure.in

   1 dnl Define our own header notice with own copyright
   2 define([AC_INIT_NOTICE],
   3 [#### Configuration script for XEmacs.  Largely divergent from FSF.
   4 #### Guess values for system-dependent variables and create Makefiles.
   5 #### Generated automatically using autoconf version] AC_ACVERSION [
   6 #### Copyright (C) 1992, 93, 94, 95, 96 Free Software Foundation, Inc.
   7 #### Copyright (C) 1993-1995 Board of Trustees, University of Illinois.
   8 #### Copyright (C) 1996, 1997 Sun Microsystems, Inc.
   9 #### Copyright (C) 1995, 1996 Ben Wing.
  10 #### Copyright (C) 1998, 1999 J. Kean Johnston.
  11
  12 ### Don't edit this script!
  13 ### This script was automatically generated by the `autoconf' program
  14 ### from the file `./configure.in'.
  15 ### To rebuild it, execute the command
  16 ###     autoconf
  17 ### in the this directory.  You must have autoconf version 2.13 or later.
  18
  19 ### This file is part of XEmacs.
  20
  21 ### XEmacs is free software; you can redistribute it and/or modify it
  22 ### under the terms of the GNU General Public License as published by
  23 ### the Free Software Foundation; either version 2, or (at your
  24 ### option) any later version.
  25
  26 ### XEmacs is distributed in the hope that it will be useful, but
  27 ### WITHOUT ANY WARRANTY; without even the implied warranty of
  28 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  29 ### General Public License for more details.
  30
  31 ### You should have received a copy of the GNU General Public License
  32 ### along with XEmacs; see the file COPYING.  If not, write to the Free
  33 ### Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  34 ### 02111-1307, USA.
  35
  36 ### For usage, run `./configure --help'
  37 ### For more detailed information on building and installing XEmacs,
  38 ### read the file `INSTALL'.
  39 ###
  40 ### If configure succeeds, it leaves its status in config.status.
  41 ### A log of configuration tests can be found in config.log.
  42 ### If configure fails after disturbing the status quo,
  43 ###     config.status is removed.
  44 ])
  45
  46 dnl Since XEmacs has configuration requirements that autoconf cannot
  47 dnl meet, this file is an unholy marriage of custom-baked
  48 dnl configuration code and autoconf macros.
  49
  50 dnl We use the m4 quoting characters [ ] (as established by the
  51 dnl autoconf system), so quote them like this: [[foo]]
  52
  53 AC_PREREQ(2.13)dnl
  54 dnl Redefine some standard autoconf macros
  55 dnl here is how XEmacs is different:
  56 dnl - no cache file
  57 dnl - non-standard options
  58 dnl - suport for extra-verbosity
  59 dnl - ordinary libs are handled separately from X libs (might be a mistake)
  60 dnl - various random kludges (e.g. -with-dnet=no
  61
  62 dnl PRINT_VAR(var var ...)  prints values of shell variables
  63 define([PRINT_VAR],[for var in patsubst([$1],[[
  64 ]+],[ ]); do eval "echo \"$var = '\$$var'\""; done])
  65
  66 dnl Disable cache files:
  67 dnl This is controversial, but I am convinced this is the right way to go,
  68 dnl at least by default.  Otherwise there are too many surprises.
  69 define([AC_CACHE_LOAD], )dnl
  70 define([AC_CACHE_SAVE], )dnl
  71 define([AC_CACHE_VAL], [
  72 $2
  73 ])dnl
  74
  75 dnl Redefine AC_TRY_RUN_NATIVE to not throw away stderr while running
  76 dnl AC_TRY_RUN_NATIVE(PROGRAM, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
  77 define([AC_TRY_RUN_NATIVE],
  78 [cat > conftest.$ac_ext <<EOF
  79 [#]line __oline__ "configure"
  80 #include "confdefs.h"
  81 [$1]
  82 EOF
  83 if AC_TRY_EVAL(ac_link) && test -s conftest && (./conftest; exit $?) 2>&AC_FD_CC
  84 then
  85 dnl Do not remove the temporary files here, so they can be examined.
  86   ifelse([$2], , :, [$2])
  87 else
  88   conftest_rc="$?"
  89   echo "configure: failed program was:" >&AC_FD_CC
  90   cat conftest.$ac_ext >&AC_FD_CC
  91 ifelse([$3], , , [  rm -fr conftest*
  92   $3
  93 ])dnl
  94 fi
  95 rm -fr conftest*])dnl AC_TRY_RUN_NATIVE
  96
  97
  98 dnl Avoid spurious cross-compiling warnings from AC_TRY_RUN
  99 dnl XEmacs is unlikely to ever cross-compile
 100 define([AC_TRY_RUN],[AC_TRY_RUN_NATIVE([$1], [$2], [$3])])dnl
 101
 102 dnl Redefine AC_DEFINE* to provide more output if extra_verbose
 103 dnl Set VARIABLE to VALUE, verbatim, or 1.
 104 dnl AC_DEFINE(VARIABLE [, VALUE])
 105 define([AC_DEFINE],
 106 [{ test "$extra_verbose" = "yes" && cat << \EOF
 107     Defining $1[]ifelse($#, 2, [ = $2],)
 108 EOF
 109 cat >> confdefs.h <<\EOF
 110 [#define] $1 ifelse($#, 2, [$2], 1)
 111 EOF
 112 }
 113 ])dnl AC_DEFINE
 114
 115 define([AC_DEFINE_UNQUOTED],
 116 [{ test "$extra_verbose" = "yes" && cat << EOF
 117     Defining $1[]ifelse($#, 2, [ = $2],)
 118 EOF
 119 cat >> confdefs.h <<EOF
 120 [#define] $1 ifelse($#, 2, [$2], 1)
 121 EOF
 122 }
 123 ])dnl AC_DEFINE_UNQUOTED
 124
 125 dnl redefine AC_CHECK_LIB in accordance with our own value of ac_link
 126 dnl Add in extra kludgy check to support with_dnet=no
 127 dnl Add in extra LDFLAGS arg, which PRECEDE libs
 128 dnl Support --with-dnet=no
 129
 130 dnl AC_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
 131 dnl             [, OTHER-LIBRARIES] [, LDFLAGS]]]])
 132 define([AC_CHECK_LIB],
 133 [ifelse([$1],dnet, [if test "$with_dnet" = "no" ; then
 134 ac_cv_lib_dnet_dnet_ntoa=no
 135 ifelse([$4], , , [$4]
 136 )dnl
 137 else
 138 ])]
 139 AC_CHECK_LIB_ORIG_HACKED([$1],[$2],[$3],[$4],[$5], [$6])
 140 [ifelse([$1],dnet,[fi
 141 ])]dnl
 142 )dnl AC_CHECK_LIB
 143
 144 define([AC_CHECK_LIB_ORIG_HACKED],
 145 [ifelse([$5],,AC_MSG_CHECKING([for $2 in -l$1]),
 146 xe_msg_checking="for [$2] in -l[$1]"
 147 test -n "[$5]" && xe_msg_checking="$xe_msg_checking using extra libs [$5]"
 148 AC_MSG_CHECKING("$xe_msg_checking"))
 149 dnl Use a cache variable name containing both the library and function name,
 150 dnl because the test really is for library $1 defining function $2, not
 151 dnl just for library $1.  Separate tests with the same $1 and different $2s
 152 dnl may have different results.
 153 ac_lib_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
 154 AC_CACHE_VAL(ac_cv_lib_$ac_lib_var,
 155 [xe_check_libs="$6 -l$1 $5"
 156 AC_TRY_LINK(dnl
 157 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 158 [/* Override any gcc2 internal prototype to avoid an error.  */
 159 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 160 extern "C"
 161 #endif
 162 ])dnl
 163 [/* We use char because int might match the return type of a gcc2
 164     builtin and then its argument prototype would still apply.  */
 165 char $2();
 166 ]),
 167             [$2()],
 168             eval "ac_cv_lib_$ac_lib_var=yes",
 169             eval "ac_cv_lib_$ac_lib_var=no")
 170 xe_check_libs=""
 171 ])dnl
 172 if eval "test \"`echo '$ac_cv_lib_'$ac_lib_var`\" = yes" ; then
 173   AC_MSG_RESULT(yes)
 174   ifelse([$3], ,
 175 [changequote(, )dnl
 176   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 177     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 178 changequote([, ])dnl
 179   AC_DEFINE_UNQUOTED($ac_tr_lib)
 180   XE_PREPEND([-l$1], LIBS)
 181 ], [$3])
 182 else
 183   AC_MSG_RESULT(no)
 184 ifelse([$4], , , [$4
 185 ])dnl
 186 fi
 187 ])dnl AC_CHECK_LIB_ORIG_HACKED
 188
 189
 190 dnl AC_LANG_C()
 191 define([AC_LANG_C],
 192 [define([AC_LANG], [C])dnl
 193 ac_ext=c
 194 dnl CFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
 195 dnl ac_cpp='$CPP $CPPFLAGS'
 196 dnl ac_compile='${CC-cc} -c $CFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC'
 197 dnl ac_link='${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC'
 198 xe_cppflags='$CPPFLAGS $c_switch_site $c_switch_machine $c_switch_system $c_switch_x_site $X_CFLAGS'
 199 xe_ldflags='$LDFLAGS $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_x_site $ld_switch_run'
 200 xe_libs='$ld_call_shared $xe_check_libs $X_EXTRA_LIBS $libs_x $X_PRE_LIBS $LIBS $libs_machine $libs_system $libs_standard'
 201 ac_cpp='$CPP '"$xe_cppflags"
 202 ac_compile='${CC-cc} -c $CFLAGS '"$xe_cppflags"' conftest.$ac_ext 1>&AC_FD_CC'
 203 ac_link='${CC-cc} -o conftest $CFLAGS '"$xe_cppflags $xe_ldflags"' conftest.$ac_ext '"$xe_libs"' 1>&AC_FD_CC'
 204 cross_compiling=no
 205 ]) dnl AC_LANG_C
 206
 207 dnl The construct foo=`echo $w1 $w2 $w3` fails on some systems if $w1 = -e or -n
 208 dnl So we use the following instead.
 209 dnl XE_SPACE(var, words)
 210 define([XE_SPACE],[
 211 T=""
 212 for W in $2; do if test -z "$T"; then T="$W"; else T="$T $W"; fi; done
 213 $1="$T"
 214 ])dnl XE_SPACE
 215
 216 dnl XE_ADD_OBJS(foo.o ...)
 217 define([XE_ADD_OBJS],
 218 [extra_objs="$extra_objs [$1]" && dnl
 219  if test "$extra_verbose" = "yes"; then
 220    echo "    xemacs will be linked with \"[$1]\""
 221  fi])dnl XE_ADD_OBJS
 222
 223 dnl XE_APPEND(value, varname)
 224 define([XE_APPEND],
 225 [[$2]="$[$2] [$1]" && dnl
 226  if test "$extra_verbose" = "yes"; then echo "    Appending \"[$1]\" to \$[$2]"; fi])
 227
 228 dnl XE_PREPEND(value, varname)
 229 define([XE_PREPEND],
 230 [[$2]="[$1] $[$2]" && dnl
 231  if test "$extra_verbose" = "yes"; then echo "    Prepending \"[$1]\" to \$[$2]"; fi])
 232
 233 dnl XE_DIE(message)
 234 define([XE_DIE], [{ echo "Error:" $1 >&2; exit 1; }])
 235
 236 dnl XE_STRIP_4TH_COMPONENT(var)
 237 dnl Changes i986-pc-linux-gnu to i986-pc-linux, as God (not RMS) intended.
 238 define([XE_STRIP_4TH_COMPONENT],
 239 [$1=`echo "$$1" | sed '[s/^\([^-][^-]*-[^-][^-]*-[^-][^-]*\)-.*$/\1/]'`])
 240
 241 dnl Initialize some variables set by options.
 242 dnl The variables have the same names as the options, with
 243 dnl dashes changed to underlines.
 244
 245 define([AC_INIT_PARSE_ARGS],[
 246
 247 dnl Get sane consistent behavior from various shells
 248 dnl Avoid losing with weird user CDPATHs
 249
 250 if test -n "$ZSH_VERSION"; then
 251   dnl zsh's Bourne shell emulation options
 252   setopt NO_BAD_PATTERN NO_BANG_HIST NO_BG_NICE NO_EQUALS NO_FUNCTION_ARGZERO
 253   setopt GLOB_SUBST NO_HUP INTERACTIVE_COMMENTS KSH_ARRAYS NO_MULTIOS NO_NOMATCH
 254   setopt RM_STAR_SILENT POSIX_BUILTINS SH_FILE_EXPANSION SH_GLOB SH_OPTION_LETTERS
 255   setopt SH_WORD_SPLIT BSD_ECHO IGNORE_BRACES
 256   dnl zsh-3.1-beta drops core on the following
 257   dnl unset CDPATH
 258   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 259 elif test -n "$BASH_VERSION"; then
 260   dnl Use Posix mode with bash
 261   set -o posix
 262   unset CDPATH
 263 else
 264   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 265 fi
 266
 267 dnl Initialize some variables set by options.
 268 dnl The variables have the same names as the options, with
 269 dnl dashes changed to underlines.
 270 exec_prefix=NONE
 271 host=NONE
 272 no_create=
 273 nonopt=NONE
 274 no_recursion=
 275 prefix=NONE
 276 program_prefix=NONE
 277 program_suffix=NONE
 278 program_transform_name=s,x,x,
 279 silent=
 280 site=
 281 srcdir=
 282 target=NONE
 283 verbose=
 284 x_includes=NONE
 285 x_libraries=NONE
 286
 287 dnl Installation directory options.
 288 dnl These are left unexpanded so users can "make install exec_prefix=/foo"
 289 dnl and all the variables that are supposed to be based on exec_prefix
 290 dnl by default will actually change.
 291 dnl Use braces instead of parens because sh, perl, etc. also accept them.
 292 dnl If you change these, you need to synchronize with the settings of the
 293 dnl various ..._USER_DEFINED variables further down.
 294 bindir='${exec_prefix}/bin'
 295 sbindir='${exec_prefix}/sbin'
 296 libexecdir='${exec_prefix}/libexec'
 297 datadir='${prefix}/share'
 298 sysconfdir='${prefix}/etc'
 299 sharedstatedir='${prefix}/com'
 300 localstatedir='${prefix}/var'
 301 libdir='${{exec_prefix}}/lib'
 302 includedir='${prefix}/include'
 303 oldincludedir='/usr/include'
 304 infodir='${prefix}/info'
 305 mandir='${prefix}/man'
 306
 307 dnl Initialize some other variables.
 308 subdirs=
 309 MFLAGS= MAKEFLAGS=
 310 SHELL=${CONFIG_SHELL-/bin/sh}
 311 dnl Maximum number of lines to put in a shell here document.
 312 ac_max_here_lines=12
 313 ])dnl AC_INIT_PARSE_ARGS
 314
 315 AC_INIT(src/lisp.h)dnl
 316 AC_CONFIG_HEADER(src/config.h lwlib/config.h)
 317 dnl Remove any more than one leading "." element from the path name.
 318 dnl If we do not remove them, then another "./" will be prepended to
 319 dnl the file name each time we use config.status, and the program name
 320 dnl will get larger and larger.  This would not be a problem, except
 321 dnl that since progname gets recorded in all the Makefiles this script
 322 dnl produces, move-if-change thinks they're different when they're
 323 dnl not.
 324 dnl
 325 dnl It would be nice if we could put the ./ in a \( \) group and then
 326 dnl apply the * operator to that, so we remove as many leading './././'s
 327 dnl as are present, but some seds (like Ultrix's sed) don't allow you to
 328 dnl apply * to a \( \) group.  Bleah.
 329 progname="`echo $0 | sed 's:^\./\./:\./:'`"
 330
 331 dnl -----------------------------
 332 dnl Establish some default values
 333 dnl -----------------------------
 334
 335 XE_APPEND(lib-src, MAKE_SUBDIR)
 336 XE_APPEND(lib-src, INSTALL_ARCH_DEP_SUBDIR)
 337
 338 prefix='/usr/local'
 339 exec_prefix='${prefix}'
 340 bindir='${exec_prefix}/bin'
 341 dnl FSF 19.29 changes to:
 342 dnl datadir='${prefix}/share'
 343 dnl sharedstatedir='${prefix}/com'
 344 dnl libexecdir='${exec_prefix}/libexec'
 345 datadir='${prefix}/lib'
 346 statedir='${prefix}/lib'
 347 libdir='${exec_prefix}/lib'
 348 mandir='${prefix}/man/man1'
 349 inststaticdir='${PROGNAME}'
 350 instvardir='${PROGNAME}-${version}'
 351 infodir='${datadir}/${instvardir}/info'
 352 infopath=''
 353 install_pp=''
 354 lispdir='${datadir}/${instvardir}/lisp'
 355 moduledir='${datadir}/${instvardir}/${configuration}/modules'
 356 sitelispdir='${datadir}/${inststaticdir}/site-lisp'
 357 sitemoduledir='${datadir}/${inststaticdir}/site-modules'
 358 pkgdir='${datadir}/${instvardir}/lisp'
 359 package_path=''
 360 etcdir='${datadir}/${instvardir}/etc'
 361 archlibdir='${datadir}/${instvardir}/${configuration}'
 362 docdir='${archlibdir}'
 363 with_prefix='yes'
 364 with_site_lisp='no'
 365 with_site_modules='yes'
 366 with_menubars=''
 367 with_scrollbars=''
 368 with_widgets=''
 369 with_dialogs=''
 370 with_file_coding=''
 371 cpp='' cppflags='' libs='' ldflags=''
 372 dynamic=''
 373 with_x11=''
 374 with_msw=''
 375 rel_alloc='default'
 376 with_system_malloc='default'
 377 with_dlmalloc='default'
 378 native_sound_lib=''
 379 dnl use_assertions should be 'yes' by default.  Too many people in this
 380 dnl world have core dumps turned off by default or \"cannot find where the
 381 dnl core file went\".  At least we should get some useful output ...
 382 use_assertions="yes"
 383 dnl the following is set to yes or no later.
 384 with_toolbars=""
 385 with_tty=""
 386 use_union_type="no"
 387 with_dnet=""
 388 pdump="no"
 389 dnl dragndrop is still experimental.  When it is stable, comment out the following line:
 390 with_dragndrop="no"
 391
 392 dnl ------------------
 393 dnl Options Processing
 394 dnl ------------------
 395
 396 define([USAGE_ERROR],
 397 [(echo "$progname: Usage error:"
 398 echo " " $1
 399 echo "  Use \`$progname --help' to show usage.") >&2 && exit 1])
 400
 401 dnl Record all the arguments, so we can save them in config.status.
 402 arguments="$@"
 403
 404 dnl Shell Magic: Quote the quoted arguments in ARGUMENTS.  At a later date,
 405 dnl in order to get the arguments back in $@, we have to do an
 406 dnl 'eval set x "$quoted_arguments"; shift'
 407 dnl # We use sed to turn embedded ' into '"'"'.  I truly hate sh quoting.
 408 quoted_sed_magic=s/"'"/"'"'"'"'"'"'"'"/g
 409 quoted_arguments=
 410 for i in "$@"; do
 411    case "$i" in
 412    -no-create | --no-create | --no-creat | --no-crea | --no-cre \
 413    | --no-cr | --no-c) ;;
 414    -no-recursion | --no-recursion | --no-recursio | --no-recursi \
 415    | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;
 416    *)
 417    quoted_i="`echo '' $i | sed -e 's:^ ::' -e $quoted_sed_magic`"
 418    quoted_arguments="$quoted_arguments '$quoted_i'" ;;
 419    esac
 420 done
 421
 422 dnl Do not use shift -- that destroys the argument list, which autoconf needs
 423 dnl to produce config.status.  It turns out that "set - $arguments" does not
 424 dnl work portably.
 425 dnl However, it also turns out that many shells cannot expand ${10} at all.
 426 dnl So using an index variable does not work either.  It is possible to use
 427 dnl some shell magic to make 'set x "$arguments"; shift' work portably.
 428 while test $# != 0; do
 429   arg="$1"; shift
 430   case "$arg" in
 431     --no-create|--no-recursion) ;;
 432     dnl Anything starting with a hyphen we assume is an option.
 433     -* )
 434       dnl Separate the switch name from the value it is being given.
 435       case "$arg" in
 436         -*=*)
 437           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\([[^=]]*\)=.*$:\1:'`
 438           val=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*[[^=]]*=\(.*\)$:\1:'`
 439           valomitted=no
 440         ;;
 441            dnl special case these strings since echo may silently eat them:
 442            dnl --help ) opt=help val=yes valomitted=yes ;;
 443            dnl --version ) opt=version val=yes valomitted=yes ;;
 444            dnl -e ) opt=e val=yes valomitted=yes ;;
 445            dnl -E ) opt=E val=yes valomitted=yes ;;
 446            dnl -n ) opt=n val=yes valomitted=yes ;;
 447         -*)
 448            dnl If FOO is a boolean argument, --FOO is equivalent to
 449            dnl --FOO=yes.  Otherwise, the value comes from the next
 450            dnl argument - see below.
 451           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\(.*\)$:\1:'`
 452           val="yes" valomitted=yes
 453         ;;
 454       esac
 455
 456       dnl translate "-" in option string to "_"
 457       optname="$opt"
 458       opt="`echo '' $opt | sed -e 's:^ ::' | tr - _`"
 459
 460       dnl Support --without-FOO as a synonym for --with-FOO=no
 461       case "${valomitted}-${opt}" in yes-without_* )
 462         opt=`echo $opt | sed 's/without/with/'`
 463         valomitted="no" val="no" ;;
 464       esac
 465
 466       dnl Process the option.
 467       case "$opt" in
 468
 469       dnl Process (many) boolean options
 470         with_site_lisp  | \
 471         with_prefix     | \
 472         with_site_modules | \
 473         with_x          | \
 474         with_x11        | \
 475         with_msw        | \
 476         with_gcc        | \
 477         dynamic         | \
 478         with_ncurses    | \
 479         with_dnet       | \
 480         with_socks      | \
 481         with_dragndrop  | \
 482         with_cde        | \
 483         with_offix      | \
 484         with_gpm        | \
 485         with_xpm        | \
 486         with_xface      | \
 487         with_gif        | \
 488         with_jpeg       | \
 489         with_png        | \
 490         with_tiff       | \
 491         with_wmcommand  | \
 492         with_xmu        | \
 493         with_purify     | \
 494         with_quantify   | \
 495         with_toolbars   | \
 496         with_tty        | \
 497         with_xfs        | \
 498         with_i18n3      | \
 499         with_mule       | \
 500         with_utf_2000   | \
 501         with_text_coding| \
 502         with_file_coding| \
 503         with_canna      | \
 504         with_wnn        | \
 505         with_wnn6       | \
 506         with_workshop   | \
 507         with_sparcworks | \
 508         with_tooltalk   | \
 509         with_ldap       | \
 510         with_postgresql | \
 511         with_pop        | \
 512         with_kerberos   | \
 513         with_hesiod     | \
 514         with_dnet       | \
 515         with_infodock   | \
 516         external_widget | \
 517         verbose         | \
 518         extra_verbose   | \
 519         usage_tracking  | \
 520         use_union_type  | \
 521         pdump           | \
 522         debug           | \
 523         use_assertions  | \
 524         memory_usage_stats | \
 525         with_clash_detection | \
 526         with_modules | \
 527         quick_build )
 528           dnl Make sure the value given was either "yes" or "no".
 529           case "$val" in
 530             y | ye | yes )      val=yes ;;
 531             n | no )            val=no  ;;
 532             * ) USAGE_ERROR("The \`--$optname' option requires a boolean value: \`yes' or \`no'.") ;;
 533           esac
 534           eval "$opt=\"$val\"" ;;
 535
 536
 537         dnl Options that take a user-supplied value, as in --x-includes=/usr/X11R6/include
 538         dnl The cache-file option is ignored (for compatibility with other configures)
 539         srcdir          | \
 540         compiler        | \
 541         cflags          | \
 542         cpp             | \
 543         cppflags        | \
 544         libs            | \
 545         ldflags         | \
 546         cache_file      | \
 547         native_sound_lib| \
 548         site_lisp       | \
 549         x_includes      | \
 550         x_libraries     | \
 551         site_includes   | \
 552         site_libraries  | \
 553         site_prefixes   | \
 554         site_runtime_libraries )
 555           dnl If the value was omitted, get it from the next argument.
 556           if test "$valomitted" = "yes" ; then
 557             dnl Get the next argument from the argument list, if there is one.
 558             if test "$#" = 0 ; then
 559               USAGE_ERROR("The \`--$optname' option requires a value.");
 560             fi
 561             val="$1"; shift
 562           fi
 563           eval "$opt=\"$val\""
 564         ;;
 565
 566         dnl Options that take "yes", "no", or "default" values
 567         rel_alloc | \
 568         with_dlmalloc | \
 569         with_debug_malloc  | use_debug_malloc | \
 570         with_system_malloc | use_system_malloc )
 571           case "$val" in
 572             y | ye | yes )      val=yes ;;
 573             n | no )            val=no  ;;
 574             d | de | def | defa | defau | defaul | default ) val=default ;;
 575             * ) USAGE_ERROR(["The \`--$optname' option requires one of these values:
 576   \`yes', \`no', or \`default'."]) ;;
 577           esac
 578           case "$opt" in use_* ) opt="`echo $opt | sed s/use/with/`" ;; esac
 579           eval "$opt=\"$val\""
 580         ;;
 581
 582         dnl Has the user requested database support?
 583         "with_database" )
 584           with_database_berkdb=no
 585           with_database_dbm=no
 586           with_database_gdbm=no
 587           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 588             case "$x" in
 589               no ) ;;
 590               b | be | ber | berk | berkd | berkdb )       with_database_berkdb=yes ;;
 591               d | db | dbm )                               with_database_dbm=yes    ;;
 592               g | gn | gnu | gnud | gnudb | gnudbm | gdbm) with_database_gdbm=yes   ;;
 593               * ) USAGE_ERROR(["The \`--$optname' option value
 594   must be either \`no' or a comma-separated list
 595   of one or more of \`berkdb' and either \`dbm' or \`gnudbm'."]) ;;
 596             esac
 597           done
 598           if test "$with_database_dbm"  = "yes" -a \
 599                   "$with_database_gdbm" = "yes"; then
 600           USAGE_ERROR("Only one of \`dbm' and \`gnudbm' may be specified
 601   with the \`--$optname' option.")
 602           fi
 603         ;;
 604
 605         dnl Has the user requested sound support?
 606         "with_sound" )
 607         dnl values is a subset of all,native,nas,esd
 608         dnl or their negatives: none,nonative,nonas,noesd
 609           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 610             case "$x" in
 611               dnl all and none are only permitted as the first in the list.
 612               n | no | non | none ) new_sdefault=no ;;
 613               a | al | all | both ) new_sdefault=yes ;;
 614
 615               native )       with_native_sound=yes ;;
 616               nonative )     with_native_sound=no ;;
 617
 618               nas )          with_nas_sound=yes ;;
 619               nonas )        with_nas_sound=no ;;
 620
 621               esd )          with_esd_sound=yes ;;
 622               noesd )        with_esd_sound=no ;;
 623
 624               * ) bogus_sound=yes ;;
 625             esac
 626             if test "$bogus_sound" -o \
 627                  \( -n "$new_sdefault" -a -n "$sound_notfirst" \) ; then
 628                 types="\`all', \`none', \`(no)native', \`no(nas)', \`(no)esd'."
 629                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 630   $types.
 631 The default is to autodetect all sound support."])
 632             elif test -n "$new_sdefault" ; then
 633                 with_native_sound=$new_sdefault
 634                 with_nas_sound=$new_sdefault
 635                 with_esd_sound=$new_sdefault
 636                 new_sdefault=   # reset this
 637             fi
 638             sound_notfirst=true
 639           done
 640         ;;
 641
 642         dnl Has the user specified a prefered Athena widget set?
 643         dnl This bit expands any alias names out for us...
 644         "with_athena" )
 645           case "$val" in
 646             xa | xaw )                    val=xaw    ;;
 647             3 | 3d | xaw3d )              val=3d     ;;
 648             dnl No `n' for next, someone may try `no'
 649             ne | nex | next | naxtaw)     val=next   ;;
 650             dnl Have not tested the next two...
 651             9 | 95 | xaw95 )              val=95     ;;
 652             xp | xpm | xawxpm )           val=xpm    ;;
 653             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 654   \`xaw', \`3d', \`next', \`95', or \`xpm'."]) ;;
 655           esac
 656           eval "$opt=\"$val\""
 657         ;;
 658
 659         dnl Has the user requested XIM support?
 660         "with_xim" )
 661           case "$val" in
 662             y | ye | yes )                val=yes   ;;
 663             n | no | non | none )         val=no    ;;
 664             x | xl | xli | xlib )         val=xlib  ;;
 665             m | mo | mot | moti | motif ) val=motif ;;
 666             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 667   \`motif', \`xlib', \`yes', or \`no'."]) ;;
 668           esac
 669           eval "$opt=\"$val\""
 670         ;;
 671
 672         dnl Mail locking specification
 673         "mail_locking" )
 674           case "$val" in
 675             lockf )     val=lockf ;;
 676             flock )     val=flock ;;
 677             file | dot ) val=file  ;;
 678             locking )   val=locking  ;;
 679             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 680   \`lockf', \`flock', \`file', \`locking', or \`mmdf'."]) ;;
 681           esac
 682           eval "$opt=\"$val\""
 683         ;;
 684
 685         dnl Has the user requested error-checking?
 686         "error_checking" )
 687           dnl value can be all, none, and/or a list of categories to check.
 688           dnl Example: --error-checking=all,noextents,nobufpos
 689           dnl Example: --error-checking=none,malloc,gc
 690
 691           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 692             case "$x" in
 693               dnl all and none are only permitted as the first in the list.
 694               n | no | non | none ) new_default=no ;;
 695               a | al | all )        new_default=yes ;;
 696
 697               extents )       error_check_extents=yes ;;
 698               noextents )     error_check_extents=no ;;
 699
 700               typecheck )     error_check_typecheck=yes ;;
 701               notypecheck )   error_check_typecheck=no ;;
 702
 703               bufpos )        error_check_bufpos=yes ;;
 704               nobufpos )      error_check_bufpos=no ;;
 705
 706               gc )            error_check_gc=yes ;;
 707               nogc )          error_check_gc=no ;;
 708
 709               malloc )        error_check_malloc=yes ;;
 710               nomalloc )      error_check_malloc=no ;;
 711
 712               byte_code )     error_check_byte_code=yes ;;
 713               nobyte_code )   error_check_byte_code=no ;;
 714
 715               glyphs )     error_check_glyphs=yes ;;
 716               noglyphs )   error_check_glyphs=no ;;
 717
 718               * ) bogus_error_check=yes ;;
 719             esac
 720             if test "$bogus_error_check" -o \
 721                  \( -n "$new_default" -a -n "$echeck_notfirst" \) ; then
 722                 if test "$error_check_default" = yes ; then
 723                   types="\`all' (default), \`none', \`noextents', \`notypecheck', \`nobufpos', \`nogc', \`nomalloc', \`noglyphs' and \`nobyte-code'."
 724                 else
 725                   types="\`all', \`none' (default), \`extents', \`typecheck', \`bufpos', \`gc', \`malloc', \`glyphs' and \`byte-code'."
 726                 fi
 727                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 728   $types."])
 729             elif test -n "$new_default" ; then
 730                 error_check_extents=$new_default
 731                 error_check_typecheck=$new_default
 732                 error_check_bufpos=$new_default
 733                 error_check_gc=$new_default
 734                 error_check_malloc=$new_default
 735                 error_check_byte_code=$new_default
 736                 error_check_glyphs=$new_default
 737                 new_default=    # reset this
 738             fi
 739             echeck_notfirst=true
 740           done
 741         ;;
 742
 743         dnl Has the user tried to tell us where the X files are?
 744         dnl I think these are dopey, but no less than three alpha
 745         dnl testers, at large sites, have said they have their X files
 746         dnl installed in odd places.
 747
 748         dnl Has the user specified one of the path options?
 749         prefix | exec_prefix | bindir | datadir | statedir | libdir | \
 750         mandir | infodir | infopath | lispdir | etcdir | pkgdir | \
 751         archlibdir | docdir | package_path )
 752            dnl If the value was omitted, get it from the next argument.
 753            if test "$valomitted" = "yes"; then
 754              if test "$#" = 0; then
 755                  USAGE_ERROR("The \`--$optname' option requires a value.");
 756              fi
 757              val="$1"; shift
 758            fi
 759            eval "$opt=\"$val\""
 760
 761            dnl You need to synchronize this with the way the
 762            dnl default values are built.
 763            case "$opt" in
 764              dnl prefix is taken care of by --with-prefix
 765              exec_prefix ) AC_DEFINE(EXEC_PREFIX_USER_DEFINED) ;;
 766              lispdir ) AC_DEFINE(LISPDIR_USER_DEFINED) ;;
 767              sitelispdir ) AC_DEFINE(SITELISPDIR_USER_DEFINED) ;;
 768              moduledir ) AC_DEFINE(MODULEDIR_USER_DEFINED) ;;
 769              etcdir  )  AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 770              infodir ) AC_DEFINE(INFODIR_USER_DEFINED) ;;
 771              infopath ) AC_DEFINE(INFOPATH_USER_DEFINED) ;;
 772              package_path ) AC_DEFINE(PACKAGE_PATH_USER_DEFINED) ;;
 773              datadir )
 774                 AC_DEFINE(INFODIR_USER_DEFINED)
 775                 AC_DEFINE(LISPDIR_USER_DEFINED)
 776             AC_DEFINE(MODULEDIR_USER_DEFINED)
 777                 AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 778              docdir ) AC_DEFINE(DOCDIR_USER_DEFINED) ;;
 779              exec_prefix | libdir | archlibdir ) AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
 780            esac
 781         ;;
 782
 783         dnl --no-create added by autoconf for use by config.status
 784         "no_create" ) ;;
 785
 786         dnl Has the user asked for some help?
 787         "usage" | "help" ) ${PAGER-more} ${srcdir}/configure.usage; exit 0 ;;
 788
 789         dnl Has the user specified the toolkit(s) to use for GUI elements?
 790         "with_menubars"   | \
 791         "with_scrollbars" | \
 792         "with_dialogs"    | \
 793         "with_widgets" )
 794           case "$val" in
 795             l | lu | luc | luci | lucid )               val=lucid  ;;
 796             m | mo | mot | moti | motif )               val=motif  ;;
 797             a | at | ath | athe | athen | athena )      val=athena ;;
 798             n | no | non | none )                       val=no     ;;
 799             y | ye | yes )                              val=yes    ;;
 800             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 801   \`lucid', \`motif', \`athena', \`yes', or \`no'."]) ;;
 802           esac
 803           eval "$opt=\"$val\""
 804         ;;
 805
 806         dnl Obsolete legacy argument?  Warn, but otherwise ignore.
 807         "use_minimal_tagbits" | \
 808         "use_indexed_lrecord_implementation" | \
 809         "run_in_place"  | \
 810         "const_is_losing" | \
 811         "with_gnu_make" )
 812           AC_MSG_WARN([Obsolete option \`--$optname' ignored.])
 813         ;;
 814
 815         dnl Unrecognized option?  No mercy for user errors.
 816         * ) USAGE_ERROR("Unrecognized option: $arg") ;;
 817
 818       esac
 819     ;;
 820
 821     dnl Assume anything with multiple hyphens is a configuration name.
 822     *-*-*) configuration="$arg" ;;
 823
 824     dnl Unrecognized argument?  No mercy for user errors.
 825     *) USAGE_ERROR("Unrecognized argument: $arg") ;;
 826
 827   esac
 828 done
 829
 830 dnl -------------------------
 831 dnl Finish options processing
 832 dnl -------------------------
 833
 834 dnl Several options are equivalent to, and override, environment variables.
 835 test -n "$cpp"      && CPP="$cpp"
 836 test -n "$cppflags" && CPPFLAGS="$cppflags"
 837 test -n "$libs"     && LIBS="$libs"
 838 test -n "$ldflags"  && LDFLAGS="$ldflags"
 839
 840 dnl Get the arguments back.  See the diatribe on Shell Magic above.
 841 eval set x "$quoted_arguments"; shift
 842
 843 dnl --extra-verbose implies --verbose
 844 test "$extra_verbose" = "yes" && verbose=yes
 845
 846 dnl with_x is an obsolete synonym for with_x11
 847 test -n "$with_x" && with_x11="$with_x"
 848
 849 dnl --with-quantify or --with-purify imply --use-system-malloc
 850 if test "$with_purify" = "yes" -o "$with_quantify" = "yes"; then
 851   test "$with_system_malloc" = "default" && with_system_malloc=yes
 852 fi
 853
 854 dnl XE_CHECK_FEATURE_DEPENDENCY(feature1, feature2)
 855 define([XE_CHECK_FEATURE_DEPENDENCY],
 856 [if test "$with_$1 $with_$2" = "yes no"; then
 857   USAGE_ERROR("--with-$1 requires --with-$2")
 858 elif test "$with_$2" = "no" ; then with_$1=no
 859 elif test "$with_$1" = "yes"; then with_$2=yes
 860 fi
 861 ])
 862
 863 dnl CDE requires tooltalk
 864 XE_CHECK_FEATURE_DEPENDENCY(cde, tooltalk)
 865
 866 dnl Find the source directory.
 867 case "$srcdir" in
 868
 869   dnl If srcdir is not specified, see if  "." or ".." might work.
 870   "" )
 871     for dir in "`echo $0 | sed 's|//|/|' | sed 's|/[[^/]]*$||'`" "." ".." ; do
 872       if test -f "$dir/src/lisp.h" -a \
 873               -f "$dir/lisp/version.el" ; then
 874         srcdir="$dir"
 875         break
 876       fi
 877     done
 878     if test -z "$srcdir" ; then
 879       USAGE_ERROR(["Neither the current directory nor its parent seem to
 880   contain the XEmacs sources.  If you do not want to build XEmacs in its
 881   source tree, you should run \`$progname' in the directory in which
 882   you wish to build XEmacs, using the \`--srcdir' option to say where the
 883   sources may be found."])
 884     fi
 885   ;;
 886
 887   dnl Otherwise, check if the directory they specified is okay.
 888   * )
 889     if test ! -f "$srcdir/src/lisp.h" -o \
 890             ! -f "$srcdir/lisp/version.el" ; then
 891       USAGE_ERROR(["The directory specified with the \`--srcdir' option,
 892   \`$srcdir', doesn't seem to contain the XEmacs sources.  You should
 893   either run the \`$progname' script at the top of the XEmacs source
 894   tree, or use the \`--srcdir' option to specify the XEmacs source directory."])
 895     fi
 896   ;;
 897 esac
 898
 899 dnl ###########################################################################
 900 if test -z "$configuration"; then
 901   dnl Guess the configuration
 902   configuration=`${CONFIG_SHELL-/bin/sh} $srcdir/config.guess`
 903   if test -z "$configuration"; then
 904     USAGE_ERROR(["XEmacs has not been ported to this host type.
 905 Try explicitly specifying the CONFIGURATION when rerunning configure."])
 906   fi
 907 fi
 908
 909 AC_PROG_LN_S
 910
 911 dnl Make symlinks for etc, lisp, and info directories while the path
 912 dnl is still relative.  We do not symlink lock because someone may
 913 dnl have stuck the source on a read-only partition.  Instead we
 914 dnl create it as an actual directory later on if it does not already
 915 dnl exist.
 916 for dir in lisp etc man info tests; do
 917   if test ! -d "$dir" ; then
 918     echo Making symbolic link to "$srcdir/$dir"
 919     ${LN_S} "$srcdir/$dir" "$dir"
 920   fi
 921 done
 922
 923 dnl Do our best to deal with automounter brokenness
 924 dnl CANONICALIZE_PATH(varname)
 925 define([CANONICALIZE_PATH],
 926 [if test -d "/net"; then
 927   if test -d "/tmp_mnt/net"; then tdir="tmp_mnt/net"; else tdir="tmp_mnt"; fi
 928   $1=`echo "[$]$1" | \
 929    sed -e "s|^${tdir}/|/net/|" -e "s|^/a/|/net/|" -e "s|^/amd/|/net/|"`
 930 fi])dnl
 931
 932 dnl Calculate canonical name for blddir (i.e. current directory).
 933 dnl PWD may already be the preferable absolute name for ".",
 934 dnl but we can't trust it - it is sometimes inaccurate.
 935 absolute_pwd="`pwd`";
 936 if test -n "$PWD" -a "`cd $PWD && pwd`" = "$absolute_pwd"
 937 then blddir="$PWD"
 938 else blddir="$absolute_pwd"; CANONICALIZE_PATH(blddir)
 939 fi
 940 AC_SUBST(blddir)
 941
 942 dnl Make srcdir absolute, if not already.  It is important to
 943 dnl avoid running the path through pwd unnecessary, since pwd can
 944 dnl give you automounter prefixes, which can go away.
 945 case "$srcdir" in
 946   /* ) ;;
 947   .  ) srcdir="$blddir" ;;
 948   *  ) srcdir="`cd $srcdir && pwd`"; CANONICALIZE_PATH(srcdir) ;;
 949 esac
 950
 951 dnl Check if the source directory already has a configured system in it.
 952 if test `pwd` != `sh -c cd $srcdir && pwd`  \
 953    && test -f "$srcdir/src/config.h"; then
 954   (echo "$progname: WARNING: The directory tree \`$srcdir' is being used"
 955    echo "   as a build directory right now; it has been configured in its own"
 956    echo "   right.  To configure in another directory as well, you MUST"
 957    echo "   use GNU make.  If you do not have GNU make, then you must"
 958    echo "   now do \`make distclean' in $srcdir,"
 959    echo "   and then run $progname again.") >&2
 960   extrasub='/^VPATH[[    ]]*=/c\
 961 vpath %.c $(srcdir)\
 962 vpath %.h $(srcdir)\
 963 vpath %.y $(srcdir)\
 964 vpath %.l $(srcdir)\
 965 vpath %.s $(srcdir)\
 966 vpath %.in $(srcdir)'
 967 fi
 968
 969 dnl ----------------------------------------
 970 dnl Find out which version of XEmacs this is
 971 dnl ----------------------------------------
 972 . "$srcdir/version.sh" || exit 1;
 973 dnl Must do the following first to determine verbosity for AC_DEFINE
 974 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
 975 : "${extra_verbose=$beta}"
 976 version="${emacs_major_version}.${emacs_minor_version}"
 977 AC_DEFINE_UNQUOTED(EMACS_MAJOR_VERSION, $emacs_major_version)
 978 AC_DEFINE_UNQUOTED(EMACS_MINOR_VERSION, $emacs_minor_version)
 979 if test -n "$emacs_beta_version" ; then
 980   if test "$beta" = "yes"; then
 981         version="${version}-b${emacs_beta_version}"
 982         AC_DEFINE_UNQUOTED(EMACS_BETA_VERSION, $emacs_beta_version)
 983   else
 984         version="${version}.${emacs_beta_version}"
 985         AC_DEFINE_UNQUOTED(EMACS_PATCH_LEVEL, $emacs_beta_version)
 986   fi
 987 fi
 988 AC_DEFINE_UNQUOTED(XEMACS_CODENAME, "$xemacs_codename")
 989 AC_DEFINE_UNQUOTED(EMACS_VERSION, "$version")
 990
 991 if test "$with_infodock" = "yes"; then
 992   if test ! -f ../../ID-INSTALL; then
 993     echo "Cannot build InfoDock without InfoDock sources"
 994     with_infodock=no
 995   fi
 996 fi
 997
 998 if test "$with_infodock" = "yes"; then
 999   dnl InfoDock version numbers.  XEmacs will use the same style of numbering
1000   dnl after the release of XEmacs 21.0.
1001   AC_DEFINE_UNQUOTED(INFODOCK_MAJOR_VERSION, $infodock_major_version)
1002   AC_DEFINE_UNQUOTED(INFODOCK_MINOR_VERSION, $infodock_minor_version)
1003   AC_DEFINE_UNQUOTED(INFODOCK_BUILD_VERSION, $infodock_build_version)
1004   version=${infodock_major_version}.${infodock_minor_version}.${infodock_build_version}
1005   PROGNAME=infodock
1006   CPPFLAGS="$CPPFLAGS -DINFODOCK"
1007 else
1008   PROGNAME=xemacs
1009 fi
1010
1011 AC_DEFINE_UNQUOTED(EMACS_PROGNAME, "$PROGNAME")
1012
1013 dnl ----------------------------------
1014 dnl Error checking and debugging flags
1015 dnl ----------------------------------
1016 dnl Error checking default to "yes" in beta versions, to "no" in releases.
1017 dnl Same goes for --debug and --extra-verbosity.
1018 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
1019 test "${error_check_extents=$beta}"   = yes && AC_DEFINE(ERROR_CHECK_EXTENTS)
1020 test "${error_check_typecheck=$beta}" = yes && AC_DEFINE(ERROR_CHECK_TYPECHECK)
1021 test "${error_check_bufpos=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_BUFPOS)
1022 test "${error_check_gc=$beta}"        = yes && AC_DEFINE(ERROR_CHECK_GC)
1023 test "${error_check_malloc=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_MALLOC)
1024 test "${error_check_byte_code=$beta}" = yes && AC_DEFINE(ERROR_CHECK_BYTE_CODE)
1025 test "${error_check_glyphs=$beta}" = yes && AC_DEFINE(ERROR_CHECK_GLYPHS)
1026 dnl debug=yes must be set when error checking is present.  This should be
1027 dnl fixed up.
1028 dnl debug implies other options
1029 if test "${debug:=$beta}" = "yes"; then
1030   use_assertions=yes memory_usage_stats=yes
1031   XE_ADD_OBJS(debug.o)
1032   XE_ADD_OBJS(tests.o)
1033   AC_DEFINE(DEBUG_XEMACS)
1034 fi
1035 test "$use_assertions"     = "yes" && AC_DEFINE(USE_ASSERTIONS)
1036 test "$memory_usage_stats" = "yes" && AC_DEFINE(MEMORY_USAGE_STATS)
1037
1038 dnl ------------------------------
1039 dnl Determine the s&m files to use
1040 dnl ------------------------------
1041 dnl Given the configuration name, set machfile and opsysfile to the
1042 dnl names of the m/*.h and s/*.h files we should use.
1043
1044 dnl Canonicalize the configuration name.
1045 AC_MSG_CHECKING("host system type")
1046 dnl allow -workshop suffix on configuration name
1047 internal_configuration=`echo $configuration | sed 's/-\(workshop\)//'`
1048 canonical=`${CONFIG_SHELL-/bin/sh} $srcdir/config.sub "$internal_configuration"`
1049 XE_STRIP_4TH_COMPONENT(configuration)
1050 XE_STRIP_4TH_COMPONENT(canonical)
1051 AC_MSG_RESULT($configuration)
1052
1053 dnl If you add support for a new configuration, add code to this
1054 dnl switch statement to recognize your configuration name and select
1055 dnl the appropriate operating system and machine description files.
1056
1057 dnl You would hope that you could choose an m/*.h file pretty much
1058 dnl based on the machine portion of the configuration name, and an s-
1059 dnl file based on the operating system portion.  However, it turns out
1060 dnl that each m/*.h file is pretty manufacturer-specific - for
1061 dnl example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
1062 dnl all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
1063 dnl machines.  So we basically have to have a special case for each
1064 dnl configuration name.
1065
1066 dnl As far as handling version numbers on operating systems is
1067 dnl concerned, make sure things will fail in a fixable way.  If
1068 dnl /etc/MACHINES says nothing about version numbers, be
1069 dnl prepared to handle anything reasonably.  If version numbers
1070 dnl matter, be sure /etc/MACHINES says something about it.
1071
1072 dnl Eric Raymond says we should accept strings like "sysvr4" to mean
1073 dnl "System V Release 4"; he writes, "The old convention encouraged"
1074 dnl "confusion between `system' and `release' levels'."
1075
1076 machine='' opsys=''
1077
1078 dnl Straightforward machine determination
1079 case "$canonical" in
1080   sparc-*-*        ) machine=sparc ;;
1081   alpha*-*-*       ) machine=alpha ;;
1082   vax-*-*          ) machine=vax ;;
1083   mips-dec-*       ) machine=pmax ;;
1084   mips-sgi-irix6*  ) machine=iris6d ;;
1085   mips-sgi-*       ) machine=iris4d ;;
1086   mips*-linux      ) machine=mips ;;
1087   romp-ibm-*       ) machine=ibmrt ;;
1088   rs6000-ibm-aix*  ) machine=ibmrs6000 ;;
1089   powerpc-ibm-aix* ) machine=ibmrs6000 ;;
1090   powerpc*-*       ) machine=powerpc ;;
1091   hppa-*-*         ) machine=hp800 ;;
1092   m88k-dg-*        ) machine=aviion ;;
1093   m68*-sony-*      ) machine=news ;;
1094   mips-sony-*      ) machine=news-risc ;;
1095   clipper-*        ) machine=clipper ;;
1096   arm*             ) machine=arm ;;
1097   ns32k-*          ) machine=ns32000 ;;
1098   s390-*           ) machine=s390 ;;
1099 esac
1100
1101 dnl Straightforward OS determination
1102 case "$canonical" in
1103   *-*-linux*    ) opsys=linux ;;
1104   *-*-netbsd*   ) opsys=netbsd ;;
1105   *-*-openbsd*  ) opsys=openbsd ;;
1106   *-*-nextstep* ) opsys=nextstep ;;
1107   *-*-vms       ) opsys=vms ;;
1108
1109   dnl DEC OSF
1110   *-dec-osf1.3 | *-dec-osf2* ) opsys=decosf1-3 ;;
1111   *-dec-osf1.2 | *-dec-osf1* ) opsys=decosf1-2 ;;
1112   *-dec-osf3.[[2-9]]         ) opsys=decosf3-2 ;;
1113   *-dec-osf3*                ) opsys=decosf3-1 ;;
1114   *-dec-osf4*                ) opsys=decosf4-0 ;;
1115
1116   dnl DEC Ultrix
1117   *-*-ultrix[[0-3]].* | *-*-ultrix4.0* ) opsys=bsd4-2 ;;
1118   *-*-ultrix4.[[12]]* ) opsys=bsd4-3 ;;
1119   *-*-ultrix* )         opsys=ultrix4-3 ;;
1120
1121   dnl AIX
1122   *-*-aix3.1*  ) opsys=aix3-1   ;;
1123   *-*-aix3.2.5 ) opsys=aix3-2-5 ;;
1124   *-*-aix3*    ) opsys=aix3-2   ;;
1125   *-*-aix4.0*  ) opsys=aix4     ;;
1126   *-*-aix4.1*  ) opsys=aix4-1   ;;
1127   *-*-aix4*    ) opsys=aix4-2   ;;
1128
1129   dnl Other generic OSes
1130   *-gnu* )                      opsys=gnu    ;;
1131   *-*-bsd4.[[01]] )             opsys=bsd4-1 ;;
1132   *-*-bsd4.2 )                  opsys=bsd4-2 ;;
1133   *-*-bsd4.3 )                  opsys=bsd4-3 ;;
1134   *-*-aos4.2 )                  opsys=bsd4-2 ;;
1135   *-*-aos*   )                  opsys=bsd4-3 ;;
1136   *-*-sysv0    | *-*-sysvr0 )   opsys=usg5-0 ;;
1137   *-*-sysv2    | *-*-sysvr2 )   opsys=usg5-2 ;;
1138   *-*-sysv2.2  | *-*-sysvr2.2 ) opsys=usg5-2-2 ;;
1139   *-*-sysv3*   | *-*-sysvr3* )  opsys=usg5-3 ;;
1140   *-*-sysv4.1* | *-*-sysvr4.1* )opsys=usg5-4 NON_GNU_CPP=/usr/lib/cpp ;;
1141   *-*-sysv4.[[2-9]]* | *-sysvr4.[[2-9]]* )
1142         if test -z "$NON_GNU_CPP" ; then
1143           for prog in "/usr/ccs/lib/cpp" "/lib/cpp"; do
1144             if test -f "$prog"; then NON_GNU_CPP="$prog"; break; fi
1145           done
1146         fi
1147         opsys=usg5-4-2 ;;
1148     *-sysv4* | *-sysvr4* )      opsys=usg5-4 ;;
1149     *-*-mach_bsd4.3* )          opsys=mach-bsd4-3 ;;
1150 esac
1151
1152 case "$canonical" in
1153
1154   dnl NetBSD ports
1155   *-*-netbsd* )
1156     case "$canonical" in
1157       i[[3-9]]86-*-netbsd*) machine=intel386 ;;
1158       hp300-*-netbsd* | amiga-*-netbsd* | sun3-*-netbsd* | mac68k-*-netbsd* | da30-*-netbsd* | m68k-*-netbsd* )
1159                       dnl Yes, this is somewhat bogus.
1160                       machine=hp9000s300 ;;
1161       pc532-*-netbsd* | ns32k-*-netbsd* )  machine=ns32000 ;;
1162       pmax-*-netbsd*  | mips-*-netbsd*  )  machine=pmax ;;
1163     esac
1164   ;;
1165
1166   dnl OpenBSD ports
1167   *-*-openbsd* )
1168     case "${canonical}" in
1169       i386-*-openbsd*)          machine=intel386 ;;
1170       m68k-*-openbsd*)          machine=hp9000s300 ;;
1171       mipsel-*-openbsd*)        machine=pmax ;;
1172      esac
1173    ;;
1174
1175   dnl Acorn RISCiX:
1176   arm-acorn-riscix1.1* ) machine=acorn opsys=riscix1-1 ;;
1177   arm-acorn-riscix1.2* | arm-acorn-riscix ) machine=acorn opsys=riscix1-2 ;;
1178
1179   dnl Alliant machines
1180   fx80-alliant-* ) machine=alliant4     opsys=bsd4-2 ;;
1181   i860-alliant-* ) machine=alliant-2800 opsys=bsd4-3 ;;
1182
1183   dnl Altos 3068
1184   m68*-altos-sysv* ) machine=altos opsys=usg5-2 ;;
1185
1186   dnl Amdahl UTS
1187   580-amdahl-sysv* ) machine=amdahl opsys=usg5-2-2 ;;
1188
1189   dnl Apollo, Domain/OS
1190   m68*-apollo-* ) machine=apollo opsys=bsd4-3 ;;
1191
1192   dnl AT&T 3b2, 3b5, 3b15, 3b20
1193   we32k-att-sysv* ) machine=att3b opsys=usg5-2-2 ;;
1194
1195   dnl AT&T 3b1 - The Mighty Unix PC!
1196   m68*-att-sysv* ) machine=7300 opsys=usg5-2-2 ;;
1197
1198   dnl Bull machines
1199   rs6000-bull-bosx* ) machine=ibmrs6000 opsys=aix3-2 ;; # dpx20
1200   m68*-bull-sysv3*  ) machine=dpx2      opsys=usg5-3 ;; # dpx2
1201   m68*-bull-sysv2*  ) machine=sps7      opsys=usg5-2 ;; # sps7
1202
1203   dnl CCI 5/32, 6/32 -- see "Tahoe".
1204
1205   dnl Celerity
1206   celerity-celerity-bsd* ) machine=celerity opsys=bsd4-2 ;;
1207
1208   dnl Convex
1209   *-convex-bsd* | *-convex-convexos* )
1210     machine=convex opsys=bsd4-3
1211     NON_GNU_CPP="cc -E -P"
1212   ;;
1213
1214   dnl Cubix QBx/386
1215   i[[3-9]]86-cubix-sysv* ) machine=intel386 opsys=usg5-3 ;;
1216
1217   dnl Data General AViiON Machines
1218   i586-dg-dgux*R4*   | i586-dg-dgux5.4.4* ) machine=aviion opsys=dgux5-4r4 ;;
1219   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* ) opsys=dgux5-4r3 ;;
1220   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* ) opsys=dgux5-4r2 ;;
1221   m88k-dg-dgux*                           ) opsys=dgux     ;;
1222
1223   dnl Motorola Delta machines
1224   m68k-motorola-sysv* | m68000-motorola-sysv* ) machine=delta opsys=usg5-3 ;;
1225   m88k-motorola-sysv4* )
1226     dnl jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
1227     dnl needs POSIX_SIGNALS and therefore needs usg5-4-2.
1228     dnl I hope there are not other 4.0 versions for this machine
1229     dnl which really need usg5-4 instead.
1230     machine=delta88k opsys=usg5-4-2
1231   ;;
1232   m88k-motorola-sysv* | m88k-motorola-m88kbcs* ) machine=delta88k opsys=usg5-3 ;;
1233
1234   dnl Dual machines
1235   m68*-dual-sysv*    ) machine=dual opsys=usg5-2   ;;
1236   m68*-dual-uniplus* ) machine=dual opsys=unipl5-2 ;;
1237
1238   dnl Encore machines
1239   ns16k-encore-bsd* ) machine=ns16000 opsys=umax ;;
1240
1241   dnl Gould Power Node and NP1
1242   pn-gould-bsd4.2* ) machine=gould     opsys=bsd4-2 ;;
1243   pn-gould-bsd4.3* ) machine=gould     opsys=bsd4-3 ;;
1244   np1-gould-bsd* )   machine=gould-np1 opsys=bsd4-3 ;;
1245
1246   dnl Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
1247   dnl as far as XEmacs is concerned).
1248   m88k-harris-cxux* )
1249     dnl Build needs to be different on 7.0 and later releases
1250     case "`uname -r`" in
1251        [[56]].[[0-9]] ) machine=nh4000 opsys=cxux  ;;
1252        [[7]].[[0-9]]  ) machine=nh4000 opsys=cxux7 ;;
1253     esac
1254     NON_GNU_CPP="/lib/cpp"
1255   ;;
1256   dnl Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
1257   m68k-harris-cxux* ) machine=nh3000 opsys=cxux ;;
1258   dnl Harris power pc NightHawk running Power UNIX (Series 6000)
1259   powerpc-harris-powerunix ) machine=nh6000 opsys=powerunix NON_GNU_CPP="cc -Xo -E -P" ;;
1260
1261   dnl Honeywell XPS100
1262   xps*-honeywell-sysv* ) machine=xps100 opsys=usg5-2 ;;
1263
1264   dnl HP 9000 series 200 or 300
1265   m68*-hp-bsd* ) machine=hp9000s300 opsys=bsd4-3 ;;
1266
1267   dnl HP-UX
1268   *-hp-hpux* )
1269     dnl Figure out machine and opsys orthogonally
1270     case "$canonical" in
1271       m68*  ) machine=hp9000s300 ;;
1272       hppa* ) machine=hp800      ;;
1273     esac
1274
1275     case "$canonical" in
1276       *-hp-hpux7*  )  opsys=hpux   ;;
1277       *-hp-hpux8*  )  opsys=hpux8  ;;
1278       *-hp-hpux9*  )  opsys=hpux9  ;;
1279       *-hp-hpux10* )  opsys=hpux10 ;;
1280       *-hp-hpux11* )  opsys=hpux11 ;;
1281       *            )  opsys=hpux   ;;
1282     esac
1283
1284     dnl HP has a broken "strcat"
1285     case "$opsys" in hpux9 | hpux10 ) XE_ADD_OBJS(strcat.o) ;; esac
1286
1287     if test "$opsys" = "hpux10" -o "$opsys" = "hpux11"; then \
1288         ansi_flag="-Ae"; else ansi_flag="-Aa"; fi
1289     NON_GNU_CC="cc $ansi_flag" NON_GNU_CPP="cc $ansi_flag -E"
1290
1291     case "$canonical" in *-hp-hpux*shr* ) opsys="${opsys}-shr" ;; esac
1292   ;;
1293
1294   dnl Orion machines
1295   orion-orion-bsd*   ) machine=orion    opsys=bsd4-2 ;;
1296   clipper-orion-bsd* ) machine=orion105 opsys=bsd4-2 ;;
1297
1298   dnl IBM machines
1299   i[[3-9]]86-ibm-aix1.1* ) machine=ibmps2-aix opsys=usg5-2-2 ;;
1300   i[[3-9]]86-ibm-aix1.[[23]]* | i[[3-9]]86-ibm-aix* ) machine=ibmps2-aix opsys=usg5-3 ;;
1301   i370-ibm-aix*) machine=ibm370aix opsys=usg5-3 ;;
1302   romp-ibm-aos*    ) opsys=bsd4-3 ;;
1303   romp-ibm-bsd*    ) opsys=bsd4-3 ;;
1304   romp-ibm-mach*   ) opsys=mach-bsd4-3 ;;
1305
1306   dnl Integrated Solutions "Optimum V"
1307   m68*-isi-bsd4.2* ) machine=isi-ov opsys=bsd4-2 ;;
1308   m68*-isi-bsd4.3* ) machine=isi-ov opsys=bsd4-3 ;;
1309
1310   dnl Intel 386 machines where we do care about the manufacturer
1311   i[[3-9]]86-intsys-sysv* ) machine=is386 opsys=usg5-2-2 ;;
1312
1313   dnl Prime EXL
1314   i[[3-9]]86-prime-sysv* ) machine=i386 opsys=usg5-3 ;;
1315
1316   dnl Sequent Symmetry running Dynix
1317   i[[3-9]]86-sequent-bsd* ) machine=symmetry opsys=bsd4-3 ;;
1318
1319   dnl Sequent Symmetry running DYNIX/ptx
1320   i[[3-9]]86-sequent-ptx* ) machine=sequent-ptx opsys=ptx NON_GNU_CPP="/lib/cpp" ;;
1321
1322   dnl Unspecified sysv on an ncr machine defaults to svr4.2.
1323   dnl (Plain usg5-4 does not turn on POSIX signals, which we need.)
1324   i[[3-9]]86-ncr-sysv* ) machine=ncr386 opsys=usg5-4-2 ;;
1325
1326   dnl Intel Paragon OSF/1
1327   i860-intel-osf1* ) machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp ;;
1328
1329   dnl Intel 860
1330   i860-*-sysv4* ) machine=i860 opsys=usg5-4 NON_GNU_CC="/bin/cc" NON_GNU_CPP="/usr/ccs/lib/cpp" ;;
1331
1332   dnl Masscomp machines
1333   m68*-masscomp-rtu* ) machine=masscomp opsys=rtu ;;
1334
1335   dnl Megatest machines
1336   m68*-megatest-bsd* ) machine=mega68 opsys=bsd4-2 ;;
1337
1338   dnl Workstations sold by MIPS
1339   dnl This is not necessarily all workstations using the MIPS processor -
1340   dnl Irises are produced by SGI, and DECstations by DEC.
1341   mips-mips-usg* ) machine=mips4 ;;
1342   mips-mips-riscos4 )
1343     machine=mips4
1344     NON_GNU_CC="cc -systype bsd43"
1345     NON_GNU_CPP="cc -systype bsd43 -E"
1346     case "$canonical" in
1347       mips-mips-riscos4* ) opsys=bsd4-3  ;;
1348       mips-mips-riscos5* ) opsys=riscos5 ;;
1349     esac
1350   ;;
1351   mips-mips-bsd* ) machine=mips opsys=bsd4-3 ;;
1352   mips-mips-*    ) machine=mips opsys=usg5-2-2 ;;
1353
1354   dnl NeXT
1355   m68*-next-* | m68k-*-nextstep* ) machine=m68k opsys=nextstep ;;
1356
1357   dnl The complete machine from National Semiconductor
1358   ns32k-ns-genix* ) machine=ns32000 opsys=usg5-2 ;;
1359
1360   dnl NCR machines
1361   m68*-ncr-sysv2* | m68*-ncr-sysvr2* ) machine=tower32   opsys=usg5-2-2 ;;
1362   m68*-ncr-sysv3* | m68*-ncr-sysvr3* ) machine=tower32v3 opsys=usg5-3 ;;
1363
1364   dnl Nixdorf Targon 31
1365   m68*-nixdorf-sysv* ) machine=targon31 opsys=usg5-2-2 ;;
1366
1367   dnl Nu (TI or LMI)
1368   m68*-nu-sysv* ) machine=nu opsys=usg5-2 ;;
1369
1370   dnl Plexus
1371   m68*-plexus-sysv* ) machine=plexus opsys=usg5-2 ;;
1372
1373   dnl Pyramid machines
1374   pyramid-pyramid-bsd* ) machine=pyramid opsys=bsd4-2 ;;
1375
1376   dnl Sequent Balance
1377   ns32k-sequent-bsd4.2* ) machine=sequent opsys=bsd4-2 ;;
1378   ns32k-sequent-bsd4.3* ) machine=sequent opsys=bsd4-3 ;;
1379
1380   dnl Siemens Nixdorf
1381   mips-siemens-sysv* | mips-sni-sysv*)
1382     machine=mips-siemens opsys=usg5-4
1383     NON_GNU_CC=/usr/ccs/bin/cc
1384     NON_GNU_CPP=/usr/ccs/lib/cpp
1385   ;;
1386
1387   dnl NEC
1388   mips-nec-sysv*)
1389     machine=mips-nec
1390     NON_GNU_CC=/usr/ccs/bin/cc
1391     NON_GNU_CPP=/usr/ccs/lib/cpp
1392   ;;
1393
1394   dnl Silicon Graphics machines
1395   dnl Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
1396   m68*-sgi-iris3.5* ) machine=irist opsys=iris3-5 ;;
1397   m68*-sgi-iris3.6* | m68*-sgi-iris*) machine=irist opsys=iris3-6 ;;
1398   dnl Iris 4D
1399   mips-sgi-irix3.*    ) opsys=irix3-3 ;;
1400   mips-sgi-irix4.*    ) opsys=irix4-0 ;;
1401   mips-sgi-irix6*     ) opsys=irix6-0 ;;
1402   mips-sgi-irix5.1*   ) opsys=irix5-1 ;;
1403   mips-sgi-irix5.2*   ) opsys=irix5-2 ;;
1404   mips-sgi-irix5.*    ) opsys=irix5-3 ;;
1405   mips-sgi-irix*      ) opsys=irix5-0 ;;
1406
1407   dnl SONY machines
1408   *-sony-newsos[[34]]* | *-sony-news[[34]]* ) opsys=bsd4-3 ;;
1409   *-sony-news* ) opsys=newsos5 ;;
1410
1411   dnl Stride
1412   m68*-stride-sysv* ) machine=stride opsys=usg5-2 ;;
1413
1414   dnl Suns
1415   *-*-solaris* | *-*-sunos* | *-sun-mach* | *-sun-bsd* )
1416     dnl Hardware type
1417     case "$canonical" in
1418       m68*-sunos1* )             machine=sun1     ;;
1419       m68*-sunos2* )             machine=sun2     ;;
1420       m68* )                     machine=sun3     ;;
1421       i*86*-sun-sunos[[34]]* )   machine=sun386   ;;
1422       i*86-*-* )                 machine=intel386 ;;
1423       rs6000* )                  machine=rs6000   ;;
1424     esac
1425
1426     dnl Make $canonical even more so.
1427     case "$canonical" in *-sunos5*)
1428       canonical=`echo $canonical | sed -e s/sunos5/solaris2/`;;
1429     esac
1430
1431     dnl On SunOS 4, use /usr/lib/cpp, sans dynodump, /bin/ranlib
1432     dnl On SunOS 5, use cc -E,        need dynodump, RANLIB not needed
1433     dnl But, SunOS 5.6 no longer needs dynodump because it has a similar
1434     dnl function integrated.
1435     case "$canonical" in
1436       *-sunos4* )
1437         #test -f /usr/lib/cpp     && NON_GNU_CPP=/usr/lib/cpp ;;
1438         : ;;
1439       *-solaris2* )
1440         #test -f /usr/ccs/lib/cpp && NON_GNU_CPP=/usr/ccs/lib/cpp
1441         RANLIB=':' ;;
1442     esac
1443
1444     case "$canonical" in
1445       *-solaris*          )
1446         opsys=sol2
1447         os_release=`uname -r | sed -e 's/^\([[0-9]]\)\.\([[0-9]]\).*/\1\2/'`
1448         AC_DEFINE_UNQUOTED(OS_RELEASE, $os_release) ;;
1449
1450       dnl The last Sun386 ran 4.0.
1451       i*86-*-sunos4*      ) opsys=sunos4-0      ;;
1452       *-sunos4.0*         ) opsys=sunos4-0      ;;
1453       *-sunos4.1.2*       ) opsys=sunos4-1-2    ;;
1454       *-sunos4.1.3*       ) opsys=sunos4-1-3    ;;
1455       *-sunos4.1.[[4-9]]* ) opsys=sunos4-1-4    ;;
1456       *-sunos4* | *-sunos ) opsys=sunos4-1      ;;
1457       *-mach*             ) opsys=mach-bsd4-3   ;;
1458       *                   ) opsys=bsd4-2        ;;
1459     esac
1460
1461     case "$canonical" in *-sunos4*shr* ) opsys="${opsys}-shr" ;; esac
1462
1463     dnl Watch out for a compiler guaranteed not to work.
1464     test "$opsys $CC" = "sol2 /usr/ucb/cc" && CC=""
1465   ;;
1466
1467   dnl Tadpole 68k
1468   m68*-tadpole-sysv* ) machine=tad68k opsys=usg5-3 ;;
1469
1470   dnl Tahoe machines
1471   tahoe-tahoe-bsd4.2* ) machine=tahoe opsys=bsd4-2 ;;
1472   tahoe-tahoe-bsd4.3* ) machine=tahoe opsys=bsd4-3 ;;
1473
1474   dnl Tandem Integrity S2
1475   mips-tandem-sysv* ) machine=tandem-s2 opsys=usg5-3 ;;
1476
1477   dnl Tektronix XD88
1478   m88k-tektronix-sysv3* ) machine=tekxd88 opsys=usg5-3 ;;
1479
1480   dnl Tektronix 16000 box (6130?)
1481   ns16k-tektronix-bsd* ) machine=ns16000 opsys=bsd4-2 ;;
1482   dnl Tektronix 4300
1483   dnl src/m/tek4300.h hints that this is a m68k machine.
1484   m68*-tektronix-bsd* ) machine=tek4300 opsys=bsd4-3 ;;
1485
1486   dnl Titan P2 or P3
1487   titan-titan-sysv* ) machine=titan opsys=usg5-3 ;;
1488
1489   dnl Ustation E30 (SS5E)
1490   m68*-unisys-uniplus* ) machine=ustation opsystem=unipl5-2 ;;
1491
1492   dnl Vaxen.
1493   vax-dec-* )
1494     case "$canonical" in
1495       *-sysv[[01]]* | *-sysvr[[01]]* )  opsys=usg5-0 ;;
1496       *-sysv2* | *-sysvr2* )            opsys=usg5-2 ;;
1497       *-mach* )                         opsys=mach-bsd4-3 ;;
1498     esac
1499   ;;
1500
1501   dnl Whitechapel MG1
1502   ns16k-whitechapel-* ) machine=mg1 ;;
1503
1504   dnl Wicat
1505   m68*-wicat-sysv* ) machine=wicat opsys=usg5-2 ;;
1506
1507   dnl Intel 386 machines where we do not care about the manufacturer
1508   i[[3-9]]86-*-* )
1509     machine=intel386
1510     case "$canonical" in
1511       *-isc1.* | *-isc2.[[01]]* ) opsys=386-ix ;;
1512       *-isc2.2* )               opsys=isc2-2 ;;
1513       *-isc4.0* )               opsys=isc4-0 ;;
1514       *-isc4.* )                opsys=isc4-1
1515                                 GCC_TEST_OPTIONS=-posix
1516                                 NON_GCC_TEST_OPTIONS=-Xp
1517                                 ;;
1518       *-isc* )                  opsys=isc3-0 ;;
1519       *-esix5* )                opsys=esix5r4 NON_GNU_CPP=/usr/lib/cpp ;;
1520       *-esix* )                 opsys=esix ;;
1521       *-mach* )                 opsys=mach-bsd4-3 ;;
1522       *-xenix* )                opsys=xenix ;;
1523       *-sco3.2v4* )             opsys=sco4 NON_GNU_CPP=/lib/cpp  ;;
1524       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
1525       *-bsdi4* )                opsys=bsdos4 ;;
1526       *-bsdi3* )                opsys=bsdos3 ;;
1527       *-bsdi2.1* )              opsys=bsdos2-1 ;;
1528       *-bsdi2* )                opsys=bsdos2 ;;
1529       *-sco3.2v5* )             opsys=sco5 ;
1530         dnl This is a pain.  Like the current USL cc, SCO cc -E
1531         dnl tokenizes as it preprocesses, making configure very
1532         dnl unhappy.  Unfortunately, /lib/cpp does not understand
1533         dnl flags like "-b elf", so we have to cheat in order to
1534         dnl pick up the right defines for UNEXEC from the s-file.
1535         dnl 01/05/95 robertl@dgii.com
1536         if test "$dynamic" = "yes" ; then
1537                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE -D_SCO_ELF"  ;
1538         else
1539                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE"  ;
1540         fi ;;
1541       *-sysv5* )                opsys=sco7 ;;
1542       *-386bsd* )               opsys=386bsd ;;
1543       *-freebsd* )              opsys=freebsd ;;
1544       *-nextstep* )             opsys=nextstep ;;
1545       *-pc-cygwin* )            opsys=cygwin32 ;;
1546       *-pc-mingw* )             opsys=mingw32 ;
1547                                 test -z "$with_tty" && with_tty="no";;
1548       dnl Otherwise, we fall through to the generic opsys code at the bottom.
1549     esac
1550   ;;
1551
1552   dnl Linux/68k
1553   m68k-*-linux* ) machine=m68k opsys=linux ;;
1554
1555 esac
1556
1557 if test -z "$machine" -o -z "$opsys"; then
1558   (echo "$progname: XEmacs hasn't been ported to \`$canonical' systems."
1559    echo "$progname: Check \`etc/MACHINES' for recognized configuration names."
1560   ) >&2
1561   exit 1
1562 fi
1563
1564 if test -z "$dynamic"; then
1565   case "$opsys" in
1566     hpux* | sunos4* ) dynamic=no ;;
1567     *) dynamic=yes ;;
1568   esac
1569 fi
1570 if test "$dynamic" = "yes"; then
1571   case "$opsys" in
1572     hpux* | sunos4* | sco5 ) opsys="${opsys}-shr" ;;
1573     decosf* ) ld_call_shared="-call_shared" ;;
1574   esac
1575 else dnl "$dynamic" = "no"
1576   case "$opsys" in
1577     sol2 )
1578       echo "Static linking is not supported on Solaris 2."
1579       echo "Rerun configure without specifying --dynamic=no."
1580       exit 1 ;;
1581     linux   ) ld_call_shared="-Bstatic" ;;
1582     decosf* ) ld_call_shared="-non_shared" ;;
1583   esac
1584 fi
1585
1586 dnl Use xlc by default on AIX
1587 case "$opsys" in aix*) NON_GNU_CC=xlc ;; esac
1588
1589 stack_trace_eye_catcher=`echo ${PROGNAME}_${version}_${canonical} | sed 'y/.-/__/'`
1590 AC_DEFINE_UNQUOTED(STACK_TRACE_EYE_CATCHER, $stack_trace_eye_catcher)
1591
1592 machfile="m/${machine}.h"
1593 opsysfile="s/${opsys}.h"
1594
1595 dnl --------------------------------------------------
1596 dnl Determine the compiler, set up for feature testing
1597 dnl --------------------------------------------------
1598
1599 dnl Sun Development environment support
1600 test "$with_sparcworks" = "yes" && with_workshop=yes # compatibility alias
1601 XE_CHECK_FEATURE_DEPENDENCY(workshop, tooltalk)
1602 if test "$with_workshop" = "yes"; then
1603   AC_DEFINE(SUNPRO)
1604   XE_ADD_OBJS(sunpro.o)
1605 fi
1606
1607 if test "$with_clash_detection" != "no"; then
1608   AC_DEFINE(CLASH_DETECTION)
1609   XE_ADD_OBJS(filelock.o)
1610 fi
1611
1612 dnl Choose a compiler from (in order)
1613 dnl --compiler, env var CC, with_gcc=no && ${NON_GNU_CC:-cc}, AC_PROG_CC
1614 test -n "$compiler" && CC="$compiler"
1615 if test "$with_gcc" = "no"; then dnl Try to find a non-gcc compiler
1616   case "$CC" in "" | *gcc* ) CC="${NON_GNU_CC-cc}" ;; esac
1617 fi
1618
1619 dnl If we don't set CFLAGS here, AC_PROG_CC will set it.
1620 dnl But we know better what's good for us, so we do our own
1621 dnl computation of real CFLAGS later.
1622 dnl --cflags overrides environment variable CFLAGS
1623 test "${cflags-unset}" != unset && CFLAGS="$cflags"
1624 if test "${CFLAGS-unset}" != unset
1625   then cflags_specified=yes;
1626   else cflags_specified=no;
1627 fi
1628
1629 xe_save_CFLAGS="$CFLAGS"
1630
1631 AC_PROG_CC dnl Autoconf has its own magic for compiler autodetection
1632
1633 dnl Retry using random guesswork if AC_PROG_CC got it wrong...
1634 if   test "$with_gcc" = "no"  -a "$GCC" = "yes"; then
1635   CC=${NON_GNU_CC-cc}
1636   AC_PROG_CC
1637 elif test "$with_gcc" = "yes" -a "$GCC" != "yes" ; then
1638   CC=gcc
1639   AC_PROG_CC
1640 fi
1641 CFLAGS="$xe_save_CFLAGS"
1642
1643 dnl Figure out what C preprocessor to use.
1644
1645 dnl On Sun systems, people sometimes set up the variable CPP
1646 dnl with a value that is a directory, not an executable at all.
1647 dnl Detect that case, and ignore that value.
1648 test -n "$CPP" -a -d "$CPP" && CPP=
1649
1650 test -n "$NON_GNU_CPP" -a "$GCC" != "yes" -a -z "$CPP" && CPP="$NON_GNU_CPP"
1651
1652 AC_PROG_CPP
1653
1654 dnl --------------------------------------------------------------------
1655 dnl Compiler feature macros
1656 dnl --------------------------------------------------------------------
1657
1658 AC_AIX dnl Defines _ALL_SOURCE on AIX.
1659
1660 dnl We want feature macros defined here *and* in config.h.in, so that
1661 dnl the compilation environment at configure time and compile time agree.
1662
1663 AC_MSG_CHECKING(for GNU libc)
1664 AC_TRY_COMPILE([#include <features.h>],[
1665 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
1666 #error Not a GNU libc system :-(
1667 ******* ======= ******** &&&&&&&&
1668 #endif
1669 ], have_glibc=yes, have_glibc=no)
1670 AC_MSG_RESULT($have_glibc)
1671 dnl I'm tired of pop being broken with GLIBC -slb
1672 dnl Well. then why not fix fucking pop?
1673 test "$have_glibc" = "yes" && AC_DEFINE(_GNU_SOURCE)
1674
1675 dnl We'd like to use vendor extensions, where available.
1676 dnl We'd like to use functions from the latest Unix98 standards.
1677 dnl See http://www.opengroup.org/onlinepubs/007908799/xsh/compilation.html
1678 case "$opsys" in
1679   sol2)
1680    AC_DEFINE(__EXTENSIONS__)
1681    dnl Solaris 2 before 2.5 had some bugs with feature test macro interaction.
1682    if test "$os_release" -ge 55; then
1683      AC_DEFINE(_XOPEN_SOURCE,500)
1684      AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1685    fi ;;
1686   linux)
1687     AC_DEFINE(_POSIX_C_SOURCE,199506L)
1688     AC_DEFINE(_XOPEN_SOURCE,500)
1689     AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1690     ;;
1691 esac
1692
1693 dnl Identify compilers to enable compiler-specific hacks.
1694 dnl Add support for other compilers HERE!
1695 dnl GCC is already identified elsewhere.
1696 AC_TRY_RUN([int main () {
1697 #if defined __SUNPRO_C
1698 return 11;
1699 #elif defined __DECC
1700 return 12;
1701 #else
1702 return 0;
1703 #endif
1704 }], [],
1705 [case "$conftest_rc" in
1706   11) echo "You appear to be using the SunPro C compiler."; __SUNPRO_C=yes ;;
1707   12) echo "You appear to be using the DEC C compiler."   ; __DECC=yes ;;
1708 esac])
1709
1710
1711 dnl case "$canonical" in
1712 dnl   *-sun-sunos* ) test "$CPP" = "acc -E" && CPP="acc -E -Xs" ;;
1713 dnl esac
1714
1715 dnl --------------------------------------------------------------------
1716 dnl Extract some information from the operating system and machine files
1717 dnl --------------------------------------------------------------------
1718
1719 echo "Extracting information from the machine- and system-dependent headers..."
1720
1721 dnl It is not important that this name contain the PID; you cannot run
1722 dnl two configures in the same directory and have anything work
1723 dnl anyway.
1724 tempcname="conftest.c"
1725
1726 dnl CPP_to_sh(CPP_SYMBOL, SH_VAR, DEFAULT_VALUE)
1727 define([CPP_to_sh],
1728 [[#]ifndef [$1]
1729 [#]define [$1]ifelse([$3],,, [ "$3"])
1730 [#]endif
1731 configure___ [$2]=[$1]
1732 ])dnl CPP_to_sh
1733
1734 dnl CPP_boolean_to_sh(CPP_SYMBOL, SH_VAR)
1735 define([CPP_boolean_to_sh],
1736 [[#]ifdef [$1]
1737 configure___ [$2]=yes
1738 [#]else
1739 configure___ [$2]=no
1740 [#]endif
1741 ])dnl CPP_boolean_to_sh
1742
1743 cat > $tempcname <<EOF
1744 #define NOT_C_CODE
1745 #define C_SWITCH_SITE
1746 #define C_SWITCH_X_SITE
1747 #define LD_SWITCH_SITE
1748 #define LD_SWITCH_X_SITE
1749 #define LD_SWITCH_X_SITE_AUX
1750 #define OS_RELEASE $os_release
1751 #include "$srcdir/src/$opsysfile"
1752 #include "$srcdir/src/$machfile"
1753
1754 CPP_to_sh(LIBS_MACHINE, libs_machine)
1755 CPP_to_sh(LIBS_SYSTEM,  libs_system)
1756 CPP_to_sh(LIBS_TERMCAP, libs_termcap)
1757 CPP_to_sh(LIB_STANDARD, libs_standard)
1758
1759 CPP_to_sh(OBJECTS_MACHINE, objects_machine)
1760 CPP_to_sh(OBJECTS_SYSTEM,  objects_system)
1761
1762 CPP_to_sh(C_SWITCH_MACHINE,   c_switch_machine)
1763 CPP_to_sh(C_SWITCH_SYSTEM,    c_switch_system)
1764
1765 CPP_to_sh(LD_SWITCH_MACHINE,  ld_switch_machine)
1766 CPP_to_sh(LD_SWITCH_SYSTEM,   ld_switch_system)
1767
1768 CPP_to_sh(UNEXEC, unexec, unexec.o)
1769
1770 CPP_to_sh(LD_SWITCH_SHARED, ld_switch_shared, -c)
1771
1772 #define ORDINARY_LD "\$(CC) \$(CFLAGS)"
1773 configure___ ordinary_ld=ORDINARY_LD
1774
1775 #ifdef ORDINARY_LINK
1776 #define LD ORDINARY_LD
1777 #else /* no ORDINARY LINK */
1778 #ifdef COFF_ENCAPSULATE
1779 #define LD "\$(CC) -nostdlib"
1780 #else /* not COFF_ENCAPSULATE */
1781 #ifdef LINKER
1782 #define LD LINKER
1783 #else /* ! defined (LINKER) */
1784 #define LD "ld"
1785 #endif /* ! defined (LINKER) */
1786 #endif /* ! defined (COFF_ENCAPSULATE) */
1787 #endif /* not ORDINARY_LINK */
1788 configure___ ld=LD
1789
1790 CPP_to_sh(LIB_GCC, lib_gcc)
1791 CPP_to_sh(LD_TEXT_START_ADDR, ld_text_start_addr)
1792
1793 #if ! defined (ORDINARY_LINK) && !defined (START_FILES)
1794 #ifdef NO_REMAP
1795 #ifdef COFF_ENCAPSULATE
1796 #define START_FILES "pre-crt0.o /usr/local/lib/gcc-crt0.o"
1797 #else /* ! defined (COFF_ENCAPSULATE) */
1798 #define START_FILES "pre-crt0.o /lib/crt0.o"
1799 #endif /* ! defined (COFF_ENCAPSULATE) */
1800 #else /* ! defined (NO_REMAP) */
1801 #define START_FILES "ecrt0.o"
1802 #endif /* ! defined (NO_REMAP) */
1803 #endif /* no ORDINARY_LINK */
1804 #ifndef START_FILES
1805 #define START_FILES
1806 #endif
1807 configure___ start_files=START_FILES
1808
1809 CPP_boolean_to_sh(ORDINARY_LINK, ordinary_link)
1810 CPP_boolean_to_sh(SYSTEM_MALLOC, system_malloc)
1811 CPP_boolean_to_sh(TERMINFO, have_terminfo)
1812 dnl The MAIL_USE_xxx variables come from the s&m headers
1813 CPP_boolean_to_sh(MAIL_USE_FLOCK, mail_use_flock)
1814 CPP_boolean_to_sh(MAIL_USE_LOCKF, mail_use_lockf)
1815 CPP_boolean_to_sh(MAIL_USE_LOCKING, mail_use_locking)
1816 CPP_boolean_to_sh(HAVE_WIN32_PROCESSES, win32_processes)
1817 EOF
1818
1819 dnl The value of CPP is a quoted variable reference, so we need to do this
1820 dnl to get its actual value...
1821 CPP=`eval "echo $CPP $CPPFLAGS"`
1822 define(TAB, [   ])dnl
1823 changequote(, )dnl
1824 eval `$CPP -Isrc $tempcname \
1825         | sed -n -e "s/[ TAB]*=[ TAB\"]*/='/" -e "s/[ TAB\"]*\$/'/" -e "s/^configure___//p"`
1826 changequote([, ])dnl
1827
1828 rm $tempcname
1829
1830 if test "$pdump" = "yes"; then
1831   ordinary_link="yes"
1832   ld="${ordinary_ld}"
1833   start_files=
1834   libs_standard=
1835   unexec=
1836   lib_gcc=
1837 fi
1838
1839 dnl For debugging...
1840 test "$extra_verbose" = "yes" && \
1841   PRINT_VAR(libs_machine libs_system libs_termcap libs_standard
1842   objects_machine objects_system c_switch_machine c_switch_system
1843   ld_switch_machine ld_switch_system unexec ld_switch_shared
1844   ld lib_gcc ld_text_start_addr start_files ordinary_link
1845   have_terminfo mail_use_flock mail_use_lockf) && echo ""
1846
1847 dnl Pick up mingw32 include path
1848 case "$opsys" in mingw*) mingw_include=`eval "gcc -print-file-name=libc.a"` ;
1849         mingw_include=`eval "dirname $mingw_include"` ;
1850         mingw_include="-I$mingw_include/../include/mingw32" ;
1851         XE_APPEND($mingw_include, c_switch_system) ;;
1852 esac
1853
1854 dnl Non-ordinary link usually requires -lc
1855 test "$ordinary_link" = "no" -a -z "$libs_standard" && libs_standard="-lc"
1856
1857 dnl Compiler-specific hacks
1858 dnl DEC C `-std1' means ANSI C mode
1859 test "$__DECC" = "yes" && XE_APPEND(-std1, c_switch_site)
1860
1861 dnl Calculalate value of CFLAGS:
1862 dnl Use either command line flag, environment var, or autodetection
1863 if test "$cflags_specified" = "no"; then
1864   dnl Following values of CFLAGS are known to work well.
1865   dnl Should we take debugging options into consideration?
1866   if   test "$GCC" = "yes"; then
1867     CFLAGS="-g -O3 -Wall -Wno-switch -Wpointer-arith -Winline -Wmissing-prototypes -Wshadow"
1868     dnl I'm not convinced this is a good idea any more. -sb
1869     dnl test "$opsys $machine" = "linux intel386" && \
1870     dnl CFLAGS="$CFLAGS -fno-strength-reduce -malign-loops=2 -malign-jumps=2 -malign-functions=2"
1871   elif test "$__SUNPRO_C" = "yes"; then
1872     case "$opsys" in
1873       sol2    ) CFLAGS="-v -xO4" ;;
1874       sunos4* ) CFLAGS="-xO2";;
1875     esac
1876   elif test "$__DECC" = "yes"; then
1877     CFLAGS="-O3"
1878   elif test "$CC" = "xlc"; then
1879     CFLAGS="-g -O3 -qstrict -qnoansialias -qlibansi -qinfo -qro -qmaxmem=20000"
1880   dnl ### Add optimal CFLAGS support for other compilers HERE!
1881   else
1882     CFLAGS="-O" ;dnl The only POSIX-approved flag
1883   fi
1884 fi
1885
1886 dnl Search for GCC specific build problems we know about
1887 if test "$GCC" = "yes"; then
1888 AC_MSG_CHECKING(for buggy gcc versions)
1889 GCC_VERSION=`$CC --version`
1890 case `uname -s`:`uname -m`:$GCC_VERSION in
1891         dnl egcs 2.90.21 (egcs-1.00 release)
1892         dnl egcs 2.90.29 (egcs-1.0.3 release)
1893     *:sun4*:2.8.1|*:sun4*:egcs-2.90.*)
1894         dnl Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures
1895         dnl without also using `-fno-schedule-insns'.
1896         case "$CFLAGS" in
1897             *-O2*|*-O3*)
1898                 case "$CFLAGS" in
1899                     *-fno-schedule-insns*) ;;
1900                     *)
1901                         AC_MSG_RESULT(Yes)
1902                         AC_MSG_WARN(Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures)
1903                         AC_MSG_WARN(without also using -fno-schedule-insns.)
1904                         AC_MSG_ERROR(Aborting due to known problem)
1905                         ;;
1906                 esac
1907                 ;;
1908         esac
1909         ;;
1910         dnl egcs-2.91.57 (egcs-1.1 release)
1911         dnl egcs-2.91.66 (egcs-1.1.2 release)
1912     Linux:alpha:egcs-2.91.*)
1913         AC_MSG_RESULT(Yes)
1914         AC_MSG_WARN(There have been reports of egcs-1.1 not compiling XEmacs correctly on)
1915         AC_MSG_WARN(Alpha Linux.  There have also been reports that egcs-1.0.3a is O.K.)
1916         AC_MSG_ERROR(Aborting due to known problem)
1917         ;;
1918     *:i*86*:2.7.2*)
1919         case "$GCC_VERSION" in
1920             2.7.2)
1921                 case "$CFLAGS" in
1922                     *-O2*|*-O3*)
1923                         case "$CFLAGS" in
1924                             *-fno-strength-reduce*) ;;
1925                             *)
1926                                 AC_MSG_RESULT(Yes)
1927                                 AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1928                                 AC_MSG_WARN(-fno-strength-reduce.)
1929                                 AC_MSG_ERROR(Aborting due to known problem)
1930                                 ;;
1931                         esac
1932                         ;;
1933                 esac
1934                 ;;
1935         esac
1936         case "$CFLAGS" in
1937          *-fno-caller-saves*) ;;
1938          *)
1939             AC_MSG_RESULT(Yes)
1940             AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1941             AC_MSG_WARN(-fno-caller-saves.)
1942             AC_MSG_ERROR(Aborting due to known problem)
1943             ;;
1944         esac
1945         ;;
1946 esac
1947 fi
1948 AC_MSG_RESULT(No)
1949
1950 dnl Inform compiler that certain flags are meant for the linker
1951 dnl XE_PROTECT_LINKER_FLAGS(shell_var)
1952 define([XE_PROTECT_LINKER_FLAGS], [
1953 if test "$GCC" = "yes"; then
1954   set x $[$1]; shift; [$1]=""
1955   while test -n "[$]1"; do
1956     case [$]1 in
1957       -L  | -l  | -u               ) [$1]="$[$1] [$]1 [$]2"; shift ;;
1958       -L* | -l* | -u* | -Wl* | -pg ) [$1]="$[$1] [$]1" ;;
1959       -Xlinker* ) ;;
1960       * ) [$1]="$[$1] -Xlinker [$]1" ;;
1961     esac
1962     shift
1963   done
1964 fi])dnl
1965 XE_PROTECT_LINKER_FLAGS(ld_switch_system)
1966 XE_PROTECT_LINKER_FLAGS(ld_switch_machine)
1967 XE_PROTECT_LINKER_FLAGS(LDFLAGS)
1968 XE_PROTECT_LINKER_FLAGS(ld_call_shared)
1969
1970 dnl Add s&m-determined objects (including unexec) to link line
1971 test -n "$objects_machine" && XE_ADD_OBJS($objects_machine)
1972 test -n "$objects_system"  && XE_ADD_OBJS($objects_system)
1973 test -n "$unexec"          && test ! "$pdump" = "yes" && XE_ADD_OBJS($unexec)
1974 test "$pdump" = "yes" && XE_ADD_OBJS(dumper.o)
1975
1976 dnl Dynodump (Solaris 2.x, x<6)
1977 AC_MSG_CHECKING(for dynodump)
1978 if test "$unexec" != "unexsol2.o"; then
1979   AC_MSG_RESULT(no)
1980 else
1981   AC_MSG_RESULT(yes)
1982   AC_DEFINE(DYNODUMP)
1983   XE_APPEND(dynodump, MAKE_SUBDIR)
1984   XE_APPEND(dynodump, SRC_SUBDIR_DEPS)
1985   case "$machine" in
1986     sparc   ) dynodump_arch=sparc ;;
1987     *86*    ) dynodump_arch=i386  ;;
1988     powerpc ) dynodump_arch=ppc   ;;
1989   esac
1990   dnl Dynodump requires the system linker
1991   test "$GCC" = "yes" && XE_APPEND(-fno-gnu-linker, ld_switch_site)
1992 fi
1993
1994 dnl Feed s&m crud to src/Makefile
1995
1996 dnl Linux/powerpc needs the following magic for some reason
1997 test "$machine$opsys" = "powerpclinux" && start_flags="-T $srcdir/src/ppc.ldscript"
1998
1999 if test "$unexec" = "unexaix.o"; then
2000 dnl AIX needs various hacks to make static linking work.
2001   if   test "$dynamic" = "no"; then
2002   start_flags="-Wl,-bnso,-bnodelcsect"
2003   test "$GCC" = "yes" && start_flags="-B/bin/ ${start_flags}"
2004   for f in "/lib/syscalls.exp" "/lib/threads.exp"; do
2005     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; fi
2006   done
2007   for f in "/usr/lpp/X11/bin/smt.exp" "/usr/bin/X11/smt.exp"; do
2008     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; break; fi
2009   done
2010   AC_CHECK_LIB(C, terminateAndUnload, XE_APPEND(-lC, libs_system))
2011   fi
2012 elif test -n "$ld_text_start_addr"; then
2013   start_flags="-T $ld_text_start_addr -e __start"
2014 fi
2015 AC_SUBST(start_flags)
2016
2017 AC_SUBST(ld_switch_shared)
2018 AC_SUBST(start_files)
2019 if test "$ordinary_link" = "no" -a "$GCC" = "yes"; then
2020  test -z "$linker" &&  linker='$(CC) -nostdlib'
2021  test -z "$lib_gcc" && lib_gcc='`$(CC) -print-libgcc-file-name`'
2022 fi
2023 test "$GCC" != "yes" && lib_gcc=
2024 AC_SUBST(ld)
2025 AC_SUBST(lib_gcc)
2026
2027 dnl ---------------------------------------------------------------
2028 dnl Add site and system specific flags to compile and link commands
2029 dnl ---------------------------------------------------------------
2030
2031 dnl Allow use of either ":" or spaces for lists of directories
2032 define(COLON_TO_SPACE,
2033   [case "$[$1]" in *:* [)] [$1]="`echo '' $[$1] | sed -e 's/^ //' -e 's/:/ /g'`";; esac])dnl
2034
2035 dnl --site-libraries (multiple dirs)
2036 COLON_TO_SPACE(site_libraries)
2037 if test -n "$site_libraries"; then
2038   for arg in $site_libraries; do
2039     case "$arg" in
2040      -* ) ;;
2041      * ) test -d "$arg" || \
2042            XE_DIE("Invalid site library \`$arg': no such directory")
2043        arg="-L${arg}" ;;
2044     esac
2045     XE_APPEND($arg, ld_switch_site)
2046   done
2047 fi
2048
2049 dnl --site-includes (multiple dirs)
2050 COLON_TO_SPACE(site_includes)
2051 if test -n "$site_includes"; then
2052   for arg in $site_includes; do
2053     case "$arg" in
2054       -* ) ;;
2055       * ) test -d "$arg" || \
2056            XE_DIE("Invalid site include \`$arg': no such directory")
2057       arg="-I${arg}" ;;
2058     esac
2059     XE_APPEND($arg, c_switch_site)
2060   done
2061 fi
2062
2063 dnl --site-prefixes (multiple dirs)
2064 dnl --site-prefixes=dir1:dir2 is a convenient shorthand for
2065 dnl --site-libraries=dir1/lib:dir2/lib --site-includes=dir1/include:dir2/include
2066 dnl Site prefixes take precedence over the standard places, but not over
2067 dnl site-includes and site-libraries.
2068 COLON_TO_SPACE(site_prefixes)
2069 if test -n "$site_prefixes"; then
2070   for dir in $site_prefixes; do
2071     lib_dir="${dir}/lib"
2072     inc_dir="${dir}/include"
2073     if test ! -d "$dir"; then
2074       XE_DIE("Invalid site prefix \`$dir': no such directory")
2075     elif test ! -d "$lib_dir"; then
2076       XE_DIE("Invalid site prefix \`$dir': no such directory \`$lib_dir'")
2077     else
2078       if test -d "$inc_dir"; then
2079         XE_APPEND("-I$inc_dir", c_switch_site)
2080       fi
2081       XE_APPEND("-L$lib_dir", ld_switch_site)
2082     fi
2083   done
2084 fi
2085
2086 dnl GNU software installs by default into /usr/local/{include,lib}
2087 dnl if test -d "/usr/local/include" -a -d "/usr/local/lib"; then
2088 dnl   XE_APPEND("-L/usr/local/lib",    ld_switch_site)
2089 dnl   XE_APPEND("-I/usr/local/include", c_switch_site)
2090 dnl fi
2091
2092 dnl Extra system-specific library directories - please add to list
2093 for dir in "/usr/ccs/lib"; do
2094   test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2095 done
2096
2097 dnl --site-runtime-libraries (multiple dirs)
2098 COLON_TO_SPACE(site_runtime_libraries)
2099 if test -n "$site_runtime_libraries"; then
2100   LD_RUN_PATH="`echo $site_runtime_libraries | sed -e 's/  */:/g'`"
2101   export LD_RUN_PATH
2102 fi
2103
2104 dnl Linux systems have dynamic runtime library directories listed in
2105 dnl /etc/ld.so.conf.  Since those are used at run time, it seems pretty
2106 dnl safe to use them at link time, and less controversial than forcing
2107 dnl the run-time to use the link-time libraries.  This also helps avoid
2108 dnl mismatches between the link-time and run-time libraries.
2109
2110 dnl #### Unfortunately, there are horrible libc4 and libc5 libraries
2111 dnl listed in /etc/ld.so.conf on some systems, and including them on
2112 dnl the link path leads to linking in utterly broken libc's.
2113 dnl There are many clever ways of approaching this problem,
2114 dnl but finding out that actually works...
2115
2116 dnl if test -z "$LD_RUN_PATH" -a -r "/etc/ld.so.conf"; then
2117 dnl   for dir in `cat /etc/ld.so.conf`; do
2118 dnl     test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2119 dnl   done
2120 dnl   add_runtime_path=no
2121 dnl fi
2122
2123 dnl -------------------------------------
2124 dnl Compute runtime library path
2125 dnl -------------------------------------
2126
2127 if test -n "$add_runtime_path"; then :;
2128 elif test "$dynamic" = "no"; then add_runtime_path=no
2129 elif test -n "$LD_RUN_PATH"; then add_runtime_path=yes
2130 else case "$opsys" in
2131        sol2 | irix* | *bsd* | decosf* ) add_runtime_path=yes ;;
2132        * ) add_runtime_path=no ;;
2133      esac
2134 fi
2135
2136 if test "$add_runtime_path" = "yes"; then
2137   dnl Try to autodetect runtime library flag (usually -R),
2138   dnl and whether it works (or at least does no harm)
2139   AC_MSG_CHECKING("for runtime libraries flag")
2140   case "$opsys" in
2141     sol2 ) dash_r="-R" ;;
2142     decosf* | linux* | irix*) dash_r="-rpath " ;;
2143     *)
2144       dash_r=""
2145       for try_dash_r in "-R" "-R " "-rpath "; do
2146         xe_check_libs="${try_dash_r}/no/such/file-or-directory"
2147         XE_PROTECT_LINKER_FLAGS(xe_check_libs)
2148         AC_TRY_LINK(, , dash_r="$try_dash_r")
2149         xe_check_libs=""
2150         test -n "$dash_r" && break
2151       done ;;
2152   esac
2153   if test -n "$dash_r";
2154     then AC_MSG_RESULT("\"${dash_r}\"")
2155     else AC_MSG_RESULT(NONE)
2156   fi
2157 fi
2158
2159 xe_add_unique_runpath_dir='
2160   xe_add_p=yes
2161   for xe_dir in $runpath_dirs; do   dnl Uniquify
2162     test "$xe_dir" = "$xe_runpath_dir" && xe_add_p=no
2163   done
2164   if test "$xe_add_p" = "yes"; then
2165     test -n "$runpath" && runpath="${runpath}:"
2166     runpath="${runpath}${xe_runpath_dir}"
2167     runpath_dirs="$runpath_dirs $xe_runpath_dir"
2168   fi'
2169
2170
2171 dnl XE_ADD_RUNPATH_DIR(directory)
2172 define([XE_ADD_RUNPATH_DIR],[{
2173 xe_runpath_dir=$1
2174 dnl PRINT_VAR(ld_switch_site ld_switch_x_site runpath xe_runpath_dir LD_RUN_PATH xe_ldflags)
2175   test "$xe_runpath_dir" != "/lib"     -a \
2176         "$xe_runpath_dir" != "/usr/lib" -a \
2177         -n "`ls ${xe_runpath_dir}/*.s[[ol]] 2>/dev/null`" && \
2178   eval "$xe_add_unique_runpath_dir"
2179 }])dnl
2180
2181 dnl XE_COMPUTE_RUNPATH()
2182 define([XE_COMPUTE_RUNPATH],[
2183 if test "$add_runtime_path" = "yes" -a -n "$dash_r"; then
2184   dnl Remove runtime paths from current ld switches
2185   ld_switch_site=`echo   '' $ld_switch_site   | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2186   ld_switch_x_site=`echo '' $ld_switch_x_site | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2187   dnl PRINT_VAR(ld_switch_site ld_switch_x_site)
2188
2189   dnl Fix up Runtime path
2190   dnl If LD_RUN_PATH is set in environment, use that.
2191   dnl In this case, assume user has set the right value.
2192   runpath="" runpath_dirs=""
2193   if test -n "$LD_RUN_PATH"; then
2194     runpath="$LD_RUN_PATH"
2195   elif test "$GCC" = "yes"; then
2196     dnl Compute runpath from gcc's -v output
2197     ld_switch_run_save="$ld_switch_run"; ld_switch_run=""
2198     echo "int main(int argc, char *argv[[]]) {return 0;}" > conftest.c
2199     xe_runpath_link='${CC-cc} -o conftest -v $CFLAGS '"$xe_ldflags"' conftest.$ac_ext 2>&1 1>/dev/null'
2200     for arg in `eval "$xe_runpath_link" | grep ' -L'`; do
2201       case "$arg" in P,* | -L* | -R* )
2202         for dir in `echo '' "$arg" | sed -e 's:^ ::' -e 's/^..//' -e 'y/:/ /'`; do
2203           XE_ADD_RUNPATH_DIR("$dir")
2204         done ;;
2205       esac
2206     done
2207     ld_switch_run="$ld_switch_run_save"
2208     rm -f conftest*
2209   else
2210     dnl Add all directories with .so files to runpath
2211     for arg in $ld_switch_site $ld_switch_x_site; do
2212       case "$arg" in -L*) XE_ADD_RUNPATH_DIR(`echo '' "$arg" | sed -e 's:^ ::' -e 's/^-L//'`);; esac
2213     done
2214     dnl Sometimes /opt/SUNWdt/lib is the only installed Motif available
2215     if test "$opsys $need_motif" = "sol2 yes"; then
2216       xe_runpath_dir="/opt/SUNWdt/lib";
2217       eval "$xe_add_unique_runpath_dir";
2218     fi
2219   fi dnl Compute $runpath
2220
2221   if test -n "$runpath"; then
2222     ld_switch_run="${dash_r}${runpath}"
2223     XE_PROTECT_LINKER_FLAGS(ld_switch_run)
2224     test "$extra_verbose" = "yes" && echo "Setting runpath to $runpath"
2225   fi
2226 fi
2227 ])dnl
2228 XE_COMPUTE_RUNPATH()
2229
2230 dnl JKJ REMOVEME
2231 dnl XE_SHLIB_STUFF
2232
2233 dnl -----------------------------------
2234 dnl Do some misc autoconf-special tests
2235 dnl -----------------------------------
2236
2237 dnl Do the opsystem or machine files prohibit the use of the GNU malloc?
2238 dnl Assume not, until told otherwise.
2239 GNU_MALLOC=yes
2240 if test "$with_dlmalloc" != "no"; then
2241         doug_lea_malloc=yes
2242 else
2243         doug_lea_malloc=no
2244 fi
2245 after_morecore_hook_exists=yes
2246 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
2247 AC_MSG_CHECKING(whether __after_morecore_hook exists)
2248 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
2249   [AC_MSG_RESULT(yes)],
2250   [AC_MSG_RESULT(no)
2251    after_morecore_hook_exists=no])
2252 if test "$system_malloc" = "yes" ; then
2253   GNU_MALLOC=no
2254   GNU_MALLOC_reason="
2255     - The GNU allocators don't work with this system configuration."
2256 elif test "$with_system_malloc" = "yes" ; then
2257   GNU_MALLOC=no
2258   GNU_MALLOC_reason="
2259     - User chose not to use GNU allocators."
2260 elif test "$with_debug_malloc" = "yes" ; then
2261   GNU_MALLOC=no
2262   GNU_MALLOC_reason="
2263     - User chose to use Debugging Malloc."
2264 fi
2265
2266 if test "$doug_lea_malloc" = "yes" -a "$GNU_MALLOC" = "yes" ; then
2267   GNU_MALLOC_reason="
2268     - Using Doug Lea's new malloc from the GNU C Library."
2269   AC_DEFINE(DOUG_LEA_MALLOC)
2270   if test "$after_morecore_hook_exists" = "no" ; then
2271     GNU_MALLOC_reason="
2272     - Using Doug Lea's new malloc from the Linux C Library."
2273     AC_DEFINE(_NO_MALLOC_WARNING_)
2274   fi
2275 fi
2276
2277 dnl #### mcheck is broken in all versions of Linux libc and glibc.
2278 dnl Try this again when 2.1 hits the streets.
2279 dnl Avoid using free-hook.c if support exists for malloc debugging in libc
2280 dnl have_libmcheck=no
2281 dnl if test "$error_check_malloc" = "yes" -a \
2282 dnl    "$have_glibc" = "yes" -a \
2283 dnl    "$doug_lea_malloc" = "yes"; then
2284 dnl   AC_CHECK_HEADERS(mcheck.h)
2285 dnl   AC_CHECK_LIB(mcheck, mcheck, have_libmcheck=yes, have_libmcheck=no)
2286 dnl fi
2287
2288 dnl if test "$have_libmcheck" = "yes"; then
2289 dnl   AC_DEFINE(HAVE_LIBMCHECK)
2290 dnl   libmcheck=-lmcheck
2291 dnl   AC_SUBST(libmcheck)
2292 dnl fi
2293
2294 dnl Some other nice autoconf tests.  If you add a test here which
2295 dnl should make an entry in src/config.h, do not forget to add an
2296 dnl #undef clause to src/config.h.in for autoconf to modify.
2297
2298 AC_PROG_RANLIB
2299 AC_PROG_INSTALL
2300 AC_PROG_YACC
2301
2302 dnl checks for header files
2303 AC_CHECK_HEADERS(dnl
2304   a.out.h dnl
2305   cygwin/version.h dnl
2306   fcntl.h dnl
2307   inttypes.h dnl
2308   libgen.h dnl
2309   locale.h dnl
2310   mach/mach.h dnl
2311   sys/param.h dnl
2312   sys/pstat.h dnl
2313   sys/stropts.h dnl
2314   sys/time.h dnl
2315   sys/timeb.h dnl
2316   sys/un.h dnl
2317   kstat.h dnl
2318   ulimit.h dnl
2319   unistd.h dnl
2320   utime.h dnl
2321 )
2322 AC_HEADER_SYS_WAIT
2323 AC_HEADER_STDC
2324 AC_HEADER_TIME
2325 AC_DECL_SYS_SIGLIST
2326
2327 dnl Some systems have utime.h but do not declare the struct anyplace.
2328 AC_MSG_CHECKING(for struct utimbuf)
2329 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2330 #include <sys/time.h>
2331 #include <time.h>
2332 #else
2333 #ifdef HAVE_SYS_TIME_H
2334 #include <sys/time.h>
2335 #else
2336 #include <time.h>
2337 #endif
2338 #endif
2339 #ifdef HAVE_UTIME_H
2340 #include <utime.h>
2341 #endif], [static struct utimbuf x; x.actime = x.modtime;],
2342   [AC_MSG_RESULT(yes)
2343    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
2344   AC_MSG_RESULT(no))
2345
2346 dnl checks for typedefs
2347 AC_TYPE_SIGNAL
2348 AC_TYPE_SIZE_T
2349 AC_TYPE_PID_T
2350 AC_TYPE_UID_T
2351 AC_TYPE_MODE_T
2352 AC_TYPE_OFF_T
2353 AC_CHECK_TYPE(ssize_t, int)
2354
2355 dnl check for Unix98 socklen_t
2356 AC_MSG_CHECKING(for socklen_t)
2357 AC_TRY_COMPILE([#include <sys/socket.h>
2358 socklen_t x;
2359 ],[],[AC_MSG_RESULT(yes)],[
2360 AC_TRY_COMPILE([#include <sys/socket.h>
2361 int accept (int, struct sockaddr *, size_t *);
2362 ],[],[
2363 AC_MSG_RESULT(size_t)
2364 AC_DEFINE(socklen_t,size_t)], [
2365 AC_MSG_RESULT(int)
2366 AC_DEFINE(socklen_t,int)])])
2367
2368 AC_MSG_CHECKING(for struct timeval)
2369 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2370 #include <sys/time.h>
2371 #include <time.h>
2372 #else
2373 #ifdef HAVE_SYS_TIME_H
2374 #include <sys/time.h>
2375 #else
2376 #include <time.h>
2377 #endif
2378 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
2379   [AC_MSG_RESULT(yes)
2380   HAVE_TIMEVAL=yes
2381   AC_DEFINE(HAVE_TIMEVAL)],
2382   [AC_MSG_RESULT(no)
2383    HAVE_TIMEVAL=no])
2384
2385 dnl checks for structure members
2386 AC_STRUCT_TM
2387 AC_STRUCT_TIMEZONE
2388
2389 dnl checks for compiler characteristics
2390 AC_C_CONST
2391
2392 dnl check for Make feature
2393 AC_PROG_MAKE_SET
2394
2395 dnl check byte order
2396 AC_C_BIGENDIAN
2397
2398 dnl define SIZEOF_TYPE
2399 AC_CHECK_SIZEOF(short)
2400 if test "$ac_cv_sizeof_short" = 0; then
2401   echo ""
2402   echo "*** PANIC *** Configure tests are not working - compiler is broken."
2403   echo "*** PANIC *** Please examine config.log for compilation errors."
2404   exit 1
2405 fi
2406 AC_CHECK_SIZEOF(int)
2407 AC_CHECK_SIZEOF(long)
2408 AC_CHECK_SIZEOF(long long)
2409 AC_CHECK_SIZEOF(void *)
2410
2411 dnl check for long file names
2412 AC_SYS_LONG_FILE_NAMES
2413
2414 dnl -lm is required by LISP_FLOAT_TYPE, among other things
2415 AC_CHECK_FUNC(sin, ,AC_CHECK_LIB(m, sin))
2416
2417 dnl Floating operation support is now unconditional
2418 AC_DEFINE(LISP_FLOAT_TYPE)
2419
2420 AC_TRY_LINK([#include <math.h>],
2421   [return atanh(1.0) + asinh(1.0) + acosh(1.0); ],
2422   AC_DEFINE(HAVE_INVERSE_HYPERBOLIC))
2423
2424 dnl Determine type of mail locking from configure args and s&m headers
2425 AC_CHECKING(type of mail spool file locking)
2426 AC_CHECK_FUNCS(lockf flock)
2427 dnl The mail_use_xxx variables are set according to the s&m headers.
2428 test -z "$mail_locking" -a "$mail_use_flock" = "yes" && mail_locking=flock
2429 test -z "$mail_locking" -a "$mail_use_lockf" = "yes" && mail_locking=lockf
2430 test -z "$mail_locking" -a "$mail_use_locking" = "yes" && mail_locking=locking
2431 if   test -z "$mail_locking"; then
2432   case "$opsys" in cygwin* | mingw*)
2433     mail_locking=pop ;;
2434   esac
2435 fi
2436
2437 if   test "$mail_locking" = "lockf"; then AC_DEFINE(MAIL_LOCK_LOCKF)
2438 elif test "$mail_locking" = "flock"; then AC_DEFINE(MAIL_LOCK_FLOCK)
2439 elif test "$mail_locking" = "locking"; then AC_DEFINE(MAIL_LOCK_LOCKING)
2440 elif test "$mail_locking" = "pop"; then
2441   with_pop=yes
2442   mail_locking=
2443 else mail_locking="dot-locking"; AC_DEFINE(MAIL_LOCK_DOT)
2444 fi
2445 test "$mail_locking" = "lockf" -a "$ac_cv_func_lockf" != "yes" && \
2446   XE_DIE("lockf mail locking requested but not available.")
2447 test "$mail_locking" = "flock" -a "$ac_cv_func_flock" != "yes" && \
2448   XE_DIE("flock mail locking requested but not available.")
2449 test "$mail_locking" = "locking" -a "$ac_cv_func_locking" != "yes" && \
2450   XE_DIE("locking mail locking requested but not available.")
2451
2452 case "$opsys" in decosf*)
2453   AC_CHECK_LIB(pthreads, cma_open)
2454   test "$ac_cv_lib_pthreads_cma_open" = "yes" && \
2455     c_switch_site="$c_switch_site -threads" ;;
2456 esac
2457
2458 AC_MSG_CHECKING(whether the -xildoff compiler flag is required)
2459 if   ${CC-cc} '-###' -xildon  no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ; then
2460   if ${CC-cc} '-###' -xildoff no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ;
2461     then AC_MSG_RESULT(no);
2462     else AC_MSG_RESULT(yes); XE_APPEND(-xildoff, ld_switch_site)
2463   fi
2464   else AC_MSG_RESULT(no)
2465 fi
2466
2467 dnl Link with "-z ignore" on Solaris if supported
2468 if test "$opsys" = "sol2"; then
2469   if test "$os_release" -ge 56; then
2470     AC_MSG_CHECKING(for \"-z ignore\" linker flag)
2471     case "`ld -h 2>&1`" in
2472       *-z\ ignore\|record* ) AC_MSG_RESULT(yes)
2473         XE_PREPEND(-z ignore, ld_switch_site) ;;
2474       *) AC_MSG_RESULT(no) ;;
2475     esac
2476   fi
2477 fi
2478
2479 dnl ----------------------
2480 dnl Choose a window system
2481 dnl ----------------------
2482
2483 AC_CHECKING("for specified window system")
2484
2485 if test "$with_x11" != "no"; then
2486   dnl User-specified --x-includes or --x-libraries implies --with-x11.
2487   test "$x_includes $x_libraries" != "NONE NONE" && \
2488    window_system=x11 with_x11=yes
2489
2490   dnl Autodetection of X11 libraries and includes
2491   dnl -------------------------------------------
2492   dnl AC_PATH_XTRA thinks it can find our X headers and includes, but
2493   dnl it often gets it wrong, so we only use it as a last resort.
2494
2495   dnl $OPENWINHOME implies --x-includes and --x-libraries
2496   dnl Not (yet) handled by autoconf2
2497   if test "$x_includes $x_libraries" = "NONE NONE" \
2498     -a -n "$OPENWINHOME" \
2499     -a "$OPENWINHOME" != "/usr/openwin" \
2500     -a -d "$OPENWINHOME"; then
2501       test -d "$OPENWINHOME/lib"           && x_libraries="$OPENWINHOME/lib"
2502       test -d "$OPENWINHOME/include"       && x_includes="$OPENWINHOME/include"
2503       test -d "$OPENWINHOME/share/include" && x_includes="$OPENWINHOME/share/include"
2504   fi
2505
2506   if test "$x_includes" = "NONE"; then
2507     dnl AC_PATH_XTRA often guesses /usr/include, when some other
2508     dnl include directory is a MUCH better guess (Linux, HP-UX 10.20).
2509     dnl This is a workaround for idiot (esp. HP) system vendors, who
2510     dnl provide a /usr/include/X11, but DON'T FULLY POPULATE IT.
2511     for dir in "/usr/X11" "/usr/X11R6"; do
2512       if test -d "$dir/include/X11"; then x_includes="$dir/include"; break; fi
2513     done
2514   fi
2515
2516   if test "$x_libraries" = "NONE"; then
2517     for dir in "/usr/X11/lib" "/usr/X11R6/lib" "/usr/lib/X11R6"; do
2518       if test -r "$dir/libX11.a"; then x_libraries="$dir"; break; fi
2519     done
2520   fi
2521
2522   AC_PATH_XTRA # Autoconf claims to find X library and include dirs for us.
2523   if test "$no_x" = "yes"
2524   then with_x11=no  window_system=none HAVE_X_WINDOWS=no
2525   else with_x11=yes window_system=x11  HAVE_X_WINDOWS=yes
2526   fi
2527 fi
2528
2529 case "$with_x11" in
2530   yes ) window_system=x11  HAVE_X_WINDOWS=yes ;;
2531   no  ) window_system=none HAVE_X_WINDOWS=no  ;;
2532 esac
2533
2534 if test "$with_x11" = "yes"; then
2535   AC_DEFINE(HAVE_X_WINDOWS)
2536   XE_APPEND(lwlib, MAKE_SUBDIR)
2537   XE_APPEND(lwlib, SRC_SUBDIR_DEPS)
2538
2539   dnl Try to find Motif/CDE/Tooltalk dirs
2540   dnl These take precedence over other X libs/includes, so PRE-pend
2541   for lib_dir in "/usr/dt/lib" "/usr/lib/Motif2.1" "/usr/lib/Motif1.2" "/usr/lib/Motif1.1"; do
2542     inc_dir=`echo $lib_dir | sed -e 's/lib/include/'`
2543     if test -d "$lib_dir" -a -d "$inc_dir"; then
2544       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2545         x_libraries="$lib_dir $x_libraries"
2546         XE_PREPEND(-L${lib_dir}, X_LIBS) ;;
2547       esac
2548       case "$x_includes" in "$inc_dir"* ) ;; *)
2549         x_includes="$inc_dir $x_includes"
2550         XE_PREPEND(-I${inc_dir}, X_CFLAGS) ;;
2551       esac
2552       break; dnl only need ONE Motif implementation!
2553       fi
2554   done
2555
2556   dnl Contrib X libs/includes do NOT take precedence, so AP-pend
2557   for rel in "X11R6" "X11R5" "X11R4"; do
2558     lib_dir="/usr/contrib/$rel/lib" inc_dir="/usr/contrib/$rel/include"
2559     if test -d "$lib_dir" -a -d "$inc_dir"; then
2560       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2561         x_libraries="$x_libraries $lib_dir"
2562         XE_APPEND(-L${lib_dir}, X_LIBS)
2563       esac
2564       case "$x_includes" in "$inc_dir"* ) ;; *)
2565         x_includes="$x_includes $inc_dir"
2566         XE_APPEND(-I${inc_dir}, X_CFLAGS)
2567       esac
2568       break; dnl Only need ONE X11 implementation !
2569     fi
2570   done
2571
2572   dnl Avoid version mismatch for shared library libXm.so on osf4
2573   if test "$GCC" = yes -a -d /usr/shlib; then XE_APPEND(-L/usr/shlib, X_LIBS); fi
2574
2575   ld_switch_x_site="$X_LIBS"
2576
2577   XE_COMPUTE_RUNPATH()
2578
2579   if test "$extra_verbose" = "yes"; then
2580     echo; echo "X11 compilation variables:"
2581     PRINT_VAR(x_libraries x_includes X_CFLAGS X_LIBS X_PRE_LIBS X_EXTRA_LIBS)
2582     echo
2583   fi
2584
2585   dnl Set up bitmaps search path.
2586   dnl The original suggestion was to unconditionally to append X11/bitmaps
2587   dnl to each element of $x_includes, I'm pretty sure this is the wrong
2588   dnl thing to do.  We test for bitmaps and X11/bitmaps directories on each
2589   dnl element and add them to BITMAPDIR if they exist.
2590   bitmapdirs=
2591   if test "$x_includes" != NONE; then
2592     for i in $x_includes; do
2593       if test -d "$i/bitmaps"; then
2594         bitmapdirs="$i/bitmaps:$bitmapdirs"
2595       fi
2596       if test -d "$i/X11/bitmaps"; then
2597         bitmapdirs="$i/X11/bitmaps:$bitmapdirs"
2598       fi
2599     done
2600     bitmapdirs=`echo "$bitmapdirs" | sed s/.$//`
2601   fi
2602   test ! -z "$bitmapdirs" && AC_DEFINE_UNQUOTED(BITMAPDIR, "$bitmapdirs")
2603
2604   dnl Autodetect defines extracted from X config by xmkmf, e.g. NARROWPROTO
2605   AC_CHECKING(for X defines extracted by xmkmf)
2606   rm -fr conftestdir
2607   if mkdir conftestdir; then
2608     cd conftestdir
2609     cat > Imakefile <<'EOF'
2610 xetest:
2611         @echo ${PROTO_DEFINES} ${STD_DEFINES}
2612 EOF
2613     if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
2614       # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
2615       xmkmf_defines=`${MAKE-make} xetest 2>/dev/null | grep -v make`
2616     fi
2617     cd ..
2618     rm -fr conftestdir
2619     for word in $xmkmf_defines; do
2620       case "$word" in -D* )
2621         sym=`echo '' $word | sed -e 's:^ *-D::' -e 's:=.*::'`
2622         case "$word" in
2623           -D*=* ) val=`echo '' $word | sed -e 's:^.*=::'` ;;
2624           *     ) val=1 ;;
2625         esac
2626 dnl Avoid re-AC_DEFINE-ing xmkmf symbols we've already defined above.
2627         if grep "^#define $sym " confdefs.h >/dev/null; then :; else
2628           if test "$val" = "1"
2629             then AC_DEFINE_UNQUOTED($sym)
2630             else AC_DEFINE_UNQUOTED($sym,$val)
2631           fi
2632         fi  ;;
2633       esac
2634     done
2635   fi
2636
2637   dnl make sure we can find Intrinsic.h
2638   AC_CHECK_HEADER(X11/Intrinsic.h, ,
2639    [AC_MSG_ERROR("Unable to find X11 header files.")])
2640
2641   dnl -lXt and -lX11 are required
2642   dnl Some broken systems require the magic "-b i486-linuxaout" flag
2643   AC_CHECK_LIB(X11, XOpenDisplay, have_lib_x11=yes)
2644   if test "$have_lib_x11" != "yes"; then
2645     AC_CHECK_LIB(X11, XGetFontProperty,
2646       ld_switch_x_site="-b i486-linuxaout $ld_switch_x_site",
2647       [AC_MSG_ERROR("Unable to find X11 libraries.")],
2648       -b i486-linuxaout)
2649   fi
2650   libs_x="-lX11"
2651   test "$extra_verbose" = "yes" && echo "    Setting libs_x to \"-lX11\""
2652
2653   dnl Autodetect -lXext
2654   AC_CHECK_LIB(Xext, XShapeSelectInput, XE_PREPEND(-lXext, libs_x))
2655
2656   dnl Require -lXt
2657   AC_CHECK_LIB(Xt, XtOpenDisplay, XE_PREPEND(-lXt, libs_x),
2658     AC_MSG_ERROR("Unable to find X11 libraries."))
2659
2660   AC_MSG_CHECKING(the version of X11 being used)
2661   AC_TRY_RUN([#include <X11/Intrinsic.h>
2662     int main(int c, char *v[]) { return c>1 ? XlibSpecificationRelease : 0; }],
2663     [./conftest foobar; x11_release=$?],[x11_release=4],[x11_release=4])
2664   AC_MSG_RESULT(R${x11_release})
2665   AC_DEFINE_UNQUOTED(THIS_IS_X11R${x11_release})
2666
2667   AC_CHECK_FUNCS(XConvertCase)
2668
2669   AC_CHECK_HEADERS(X11/Xlocale.h)
2670
2671   dnl remove this - we should avoid checking for specific OS
2672   AC_MSG_CHECKING(for XFree86)
2673   if test -d "/usr/X386/include" -o \
2674           -f "/etc/XF86Config"    -o \
2675           -f "/etc/X11/XF86Config" -o \
2676           -f "/usr/X11R6/lib/X11/XF86Config"; then
2677     AC_MSG_RESULT(yes)
2678     AC_DEFINE(HAVE_XFREE386)
2679   else
2680     AC_MSG_RESULT(no)
2681   fi
2682
2683   dnl autodetect -lXmu
2684   test -z "$with_xmu" && { AC_CHECK_LIB(Xmu, XmuReadBitmapDataFromFile,
2685                            with_xmu=yes, with_xmu=no) }
2686   if test "$with_xmu" = "no"; then
2687     XE_ADD_OBJS(xmu.o)
2688   else
2689     XE_PREPEND(-lXmu, libs_x)
2690     AC_DEFINE(HAVE_XMU)
2691   fi
2692
2693   dnl Autodetect -lXbsd
2694   dnl #### Someone, please add a better function than main
2695   AC_CHECK_LIB(Xbsd, main, XE_PREPEND(-lXbsd, libs_x))
2696
2697   dnl Problem with the MIT distribution of X on AIX
2698   if test "$unexec" = "unexaix.o" -a "$x11_release" = "6"; then
2699     dnl X11R6 requires thread-safe code on AIX for some reason
2700     if test "$GCC" = "yes"; then
2701       XE_PREPEND(-mthreads, X_CFLAGS)
2702       XE_PREPEND(-mthreads, libs_x)
2703     else
2704       case "$CC" in
2705         "xlc" ) CC="xlc_r" ;;
2706         "xlC" ) CC="xlC_r" ;;
2707         "cc"  ) CC="cc_r" ;;
2708       esac
2709     fi
2710   fi
2711
2712 fi dnl $with_x11 = yes
2713
2714 if test "$with_msw" != "no"; then
2715   AC_CHECKING(for MS-Windows)
2716   AC_CHECK_LIB(gdi32,main,with_msw=yes)
2717   if test "$with_msw" = "yes"; then
2718     AC_DEFINE(HAVE_MS_WINDOWS)
2719     install_pp="$blddir/lib-src/installexe.sh"
2720     XE_APPEND(-lshell32 -lgdi32 -luser32 -lcomdlg32 -lcomctl32 -lwinspool, libs_system)
2721     test "$with_dragndrop" != no && XE_APPEND(msw, dragndrop_proto)
2722     if test "$window_system" != x11; then
2723         window_system=msw
2724         test "$with_scrollbars" != "no" && with_scrollbars=msw \
2725             && XE_ADD_OBJS(scrollbar-msw.o)
2726         test "$with_menubars"   != "no" && with_menubars=msw \
2727             && XE_ADD_OBJS(menubar-msw.o)
2728         test "$with_toolbars"   != "no" && with_toolbars=msw \
2729             && XE_ADD_OBJS(toolbar-msw.o)
2730         test "$with_dialogs"   != "no" && with_dialogs=msw \
2731             && XE_ADD_OBJS(dialog-msw.o)
2732         test "$with_widgets"   != "no" && with_widgets=msw
2733     else
2734         test "$with_scrollbars" != "no" && XE_ADD_OBJS(scrollbar-msw.o)
2735         test "$with_menubars"   != "no" && XE_ADD_OBJS(menubar-msw.o)
2736         test "$with_toolbars"   != "no" && XE_ADD_OBJS(toolbar-msw.o)
2737         test "$with_dialogs"    != "no" && XE_ADD_OBJS(dialog-msw.o)
2738     fi
2739     dnl check for our special version of select
2740     AC_TRY_RUN([#include <fcntl.h>
2741     int main() { return (open("/dev/windows", O_RDONLY, 0) > 0)? 0 : 1; }],
2742     [AC_DEFINE(HAVE_MSG_SELECT)])
2743     with_file_coding=yes
2744     XE_ADD_OBJS(console-msw.o device-msw.o event-msw.o frame-msw.o objects-msw.o select-msw.o redisplay-msw.o glyphs-msw.o gui-msw.o)
2745   fi
2746 fi
2747
2748 AC_SUBST(install_pp)
2749
2750 test -z "$window_system" && window_system="none"
2751
2752 dnl Test for features that require a window system - ANY window system
2753 if test "$window_system" = "none"; then
2754   for feature in menubars scrollbars toolbars dialogs dragndrop xface
2755   do
2756     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2757        AC_MSG_WARN([--with-$feature ignored:  Not valid without window system support])
2758     fi
2759     eval "with_${feature}=no"
2760   done
2761 else
2762   test -z "$with_toolbars" && with_toolbars=yes
2763 fi
2764
2765 dnl ### Test for features that require mswindows support - currently none
2766 dnl ### MS-Windows folks: add code here..... (martin)
2767 if test "$with_msw" != "yes"; then
2768   for feature in   MARTIN_IS_CLUELESS_ABOUT_MSW_FEATURES
2769   do
2770     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2771        AC_MSG_WARN([--with-$feature ignored:  Not valid without MS-Windows support])
2772     fi
2773     eval "with_${feature}=no"
2774   done
2775 else
2776   :
2777 fi
2778
2779 dnl Test for features that require X11 support
2780 if test "$with_x11" != "yes"; then
2781   dnl It ought to be reasonable to have no output device at all, and only use
2782   dnl XEmacs in --batch mode.
2783   dnl if test "$with_tty" = "no" ; then
2784   dnl   AC_MSG_ERROR([No window system support and no TTY support - Unable to proceed.])
2785   dnl fi
2786   for feature in tooltalk cde offix wmcommand xim xmu nas_sound
2787   do
2788     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2789        AC_MSG_WARN([--with-$feature ignored:  Not valid without X support])
2790     fi
2791     eval "with_${feature}=no"
2792   done
2793 fi
2794
2795 dnl FSF 19.29 has some bitmapdir stuff here.
2796 bitmapdir=
2797
2798 case "$window_system" in
2799   x11  ) HAVE_X_WINDOWS=yes; echo "  Using X11." ;;
2800   msw  ) HAVE_X_WINDOWS=no ; echo "  Using MS-Windows." ;;
2801   none ) HAVE_X_WINDOWS=no ; echo "  Using no window system." ;;
2802 esac
2803
2804 case "$x_libraries" in *X11R4* )
2805   test "$opsys" = "hpux9"     && opsysfile="s/hpux9-x11r4.h"
2806   test "$opsys" = "hpux9-shr" && opsysfile="s/hpux9shxr4.h"
2807 esac
2808
2809 dnl Enable or disable proper handling of WM_COMMAND
2810 AC_CHECKING(for WM_COMMAND option);
2811 dnl if test "$with_wmcommand" = "yes"; then
2812 if test "$with_wmcommand" != "no"; then
2813   AC_DEFINE(HAVE_WMCOMMAND)
2814 fi
2815
2816 dnl Autodetect Xauth
2817 dnl -lXau is only used by gnuclient, so use a special variable for Xauth X libs
2818 test -z "$with_xauth" && test "$window_system" = "none" && with_xauth=no
2819 test -z "$with_xauth" && { AC_CHECK_HEADER(X11/Xauth.h,          ,with_xauth=no) }
2820 test -z "$with_xauth" && { AC_CHECK_LIB(Xau, XauGetAuthByAddr,[:],with_xauth=no) }
2821 test -z "$with_xauth" && with_xauth=yes
2822 if test "$with_xauth" = "yes"; then
2823   AC_DEFINE(HAVE_XAUTH)
2824   XE_SPACE(libs_xauth, $X_EXTRA_LIBS -lXau $libs_x $X_PRE_LIBS)
2825 fi
2826 AC_SUBST(libs_xauth)
2827
2828 dnl This one is for the static initializeds variables in
2829 dnl offix.c, so that the thing is dumped after lastfile.o
2830 AC_SUBST(dnd_objs)
2831
2832 dnl Autodetect tooltalk
2833 if test "$with_tooltalk" != "no" ; then
2834   dnl autodetect the location of tt_c.h
2835   dnl tt_c.h might be in Tt or desktop include directories
2836   for dir in "" "Tt/" "desktop/" ; do
2837     AC_CHECK_HEADER(${dir}tt_c.h, tt_c_h_file="${dir}tt_c.h"; break)
2838   done
2839   if test -z "$tt_c_h_file"; then
2840     if test "$with_tooltalk" = "yes"; then
2841       USAGE_ERROR("Unable to find required tooltalk header files.")
2842     fi
2843     with_tooltalk=no
2844   fi
2845 fi
2846 if test "$with_tooltalk" != "no" ; then
2847   for extra_libs in "" "-lI18N -lce" "-lcxx"; do
2848     AC_CHECK_LIB(tt, tt_message_create,
2849       tt_libs="-ltt $extra_libs"; break, [:],$extra_libs)
2850   done
2851   if test -z "$tt_libs"; then
2852     if test "$with_tooltalk" = "yes"; then
2853       USAGE_ERROR("Unable to find required tooltalk libraries.")
2854     fi
2855     with_tooltalk=no
2856   fi
2857 fi
2858 test -z "$with_tooltalk" && with_tooltalk=yes
2859 if test "$with_tooltalk" = "yes"; then
2860   AC_DEFINE(TOOLTALK)
2861   AC_DEFINE_UNQUOTED(TT_C_H_FILE, "$tt_c_h_file")
2862   XE_PREPEND($tt_libs, libs_x)
2863   XE_ADD_OBJS(tooltalk.o)
2864 fi
2865
2866 dnl Autodetect CDE
2867 test -z "$with_cde" && { AC_CHECK_HEADER(Dt/Dt.h,               , with_cde=no) }
2868 test -z "$with_cde" && { AC_CHECK_LIB(DtSvc, DtDndDragStart, [:], with_cde=no) }
2869 test -z "$with_cde" && with_cde=yes
2870 if test "$with_dragndrop" = no; then
2871   AC_MSG_WARN([No CDE without generic Drag'n'Drop support])
2872   with_cde=no
2873 fi
2874 if test "$with_cde" = "yes" ; then
2875   AC_DEFINE(HAVE_CDE)
2876   XE_PREPEND(-lDtSvc, libs_x)
2877   XE_APPEND(CDE, dragndrop_proto)
2878   with_tooltalk=yes # CDE requires Tooltalk
2879   need_motif=yes    # CDE requires Motif
2880 fi
2881
2882 dnl Always compile OffiX unless --without-offix is given, no
2883 dnl X11 support is compiled in, no standard Xmu is available,
2884 dnl or dragndrop support is disabled
2885 dnl Because OffiX support currently loses when more than one display
2886 dnl is in use, we now disable it by default -slb 07/10/1998.
2887 test "$window_system" != "x11" && with_offix=no
2888 if test "$with_xmu" != yes -a "$with_x11" = yes; then
2889   AC_MSG_WARN([No OffiX without real Xmu support])
2890   with_offix=no
2891 fi
2892 if test "$with_dragndrop" = no; then
2893   AC_MSG_WARN([No OffiX without generic Drag'n'Drop support])
2894   with_offix=no
2895 fi
2896 if test "$with_cde" = yes; then
2897   AC_MSG_WARN([CDE already found, disabling OffiX support])
2898   with_offix=no
2899 fi
2900 test -z "$with_offix" && with_offix=no
2901 if test "$with_offix" = "yes"; then
2902   AC_DEFINE(HAVE_OFFIX_DND)
2903   XE_APPEND(offix.o, dnd_objs)
2904   XE_APPEND(OffiX, dragndrop_proto)
2905 fi
2906
2907 dnl Autodetect Drag'n'Drop support
2908 dnl always included if CDE, Offix, or MSWindows are defined
2909 AC_MSG_CHECKING(if drag and drop API is needed)
2910 if test "$with_dragndrop" != "no" ; then
2911   if test -n "$dragndrop_proto" ; then
2912     with_dragndrop=yes
2913     AC_MSG_RESULT([yes (${dragndrop_proto} )])
2914     AC_DEFINE(HAVE_DRAGNDROP)
2915     XE_APPEND(dragdrop.o, extra_objs)
2916   else
2917     with_dragndrop=no
2918     AC_MSG_RESULT(no)
2919   fi
2920 fi
2921
2922 dnl Autodetect LDAP
2923 AC_CHECKING(for LDAP)
2924 test -z "$with_ldap" && { AC_CHECK_HEADER(ldap.h, ,with_ldap=no) }
2925 test -z "$with_ldap" && { AC_CHECK_HEADER(lber.h, ,with_ldap=no) }
2926 if test "$with_ldap" != "no"; then
2927   AC_CHECK_LIB(ldap, ldap_search, with_ldap_nolber=yes, with_ldap_nolber=no)
2928   test "$with_ldap_nolber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_lber=yes, with_ldap_lber=no, -llber) }
2929   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krb=yes, with_ldap_krb=no, -llber -lkrb) }
2930   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" -a "$with_ldap_krb" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krbdes=yes, with_ldap_krbdes=no, -llber -lkrb -ldes) }
2931   test -z "$with_ldap" -a \( "$with_ldap_lber" = "yes" -o "$with_ldap_nolber" = "yes" -o "$with_ldap_krb" = "yes" -o "$with_ldap_krbdes" = "yes" \) && with_ldap=yes
2932 fi
2933 if test "$with_ldap" = "yes"; then
2934   AC_DEFINE(HAVE_LDAP)
2935   XE_ADD_OBJS(eldap.o)
2936   if test "$with_ldap_nolber" = "yes" ; then
2937     XE_PREPEND(-lldap, LIBS)
2938   else
2939     if test "$with_ldap_krb" = "yes" ; then
2940       XE_PREPEND(-lkrb, LIBS)
2941     fi
2942     if test "$with_ldap_krbdes" = "yes" ; then
2943       XE_PREPEND(-ldes, LIBS)
2944       XE_PREPEND(-lkrb, LIBS)
2945     fi
2946     XE_PREPEND(-llber, LIBS)
2947     XE_PREPEND(-lldap, LIBS)
2948   fi
2949   AC_CHECK_FUNCS(ldap_set_option ldap_get_lderrno ldap_result2error ldap_parse_result)
2950 fi
2951
2952 dnl Autodetect PostgreSQL
2953 dnl On many Linux systems, PostgreSQL is packaged to be installed in /usr;
2954 dnl in this case, configure will easily detect it there.
2955 dnl
2956 dnl If PostgreSQL is installed into a different prefix,
2957 dnl (such as the default /usr/local/pgsql when building from source),
2958 dnl that prefix must be specified using the --site-prefixes flag.
2959 if test "$with_postgresql" != "no"; then
2960   AC_CHECKING(for PostgreSQL)
2961
2962 dnl Look for these standard header file locations, known to be used on Linux
2963   for header_dir in "" "pgsql/" "postgresql/"; do
2964     AC_CHECK_HEADER(${header_dir}libpq-fe.h,
2965                     libpq_fe_h_file=${header_dir}libpq-fe.h; break)
2966   done
2967
2968   test -n "$libpq_fe_h_file" && { AC_CHECK_LIB(pq,PQconnectdb,have_libpq=yes) }
2969
2970   if test -n "$libpq_fe_h_file" -a "$have_libpq" = "yes"; then
2971     with_postgresql=yes
2972     AC_DEFINE(HAVE_POSTGRESQL)
2973     AC_CHECK_LIB(pq,PQconnectStart, [
2974                  with_postgresqlv7=yes;
2975                  AC_DEFINE(HAVE_POSTGRESQLV7)])
2976     AC_DEFINE_UNQUOTED(LIBPQ_FE_H_FILE, "$libpq_fe_h_file")
2977     XE_PREPEND(-lpq, LIBS)
2978     XE_ADD_OBJS(postgresql.o)
2979   elif test "$with_postgresql" = "yes"; then
2980     XE_DIE("Required PostgreSQL support cannot be provided.  Check --site-prefixes.")
2981   fi
2982 fi
2983
2984 dnl ----------------------
2985 dnl Graphics libraries
2986 dnl ----------------------
2987
2988 if test "$window_system" != "none"; then
2989   AC_CHECKING(for graphics libraries)
2990
2991   dnl Autodetect Xpm
2992   xpm_problem=""
2993   if test -z "$with_xpm"; then
2994     AC_MSG_CHECKING(for Xpm - no older than 3.4f)
2995     xe_check_libs=-lXpm
2996     AC_TRY_RUN([#define XPM_NUMBERS
2997 #include <X11/xpm.h>
2998     int main(int c, char **v) {
2999     return c == 1 ? 0 :
3000       XpmIncludeVersion != XpmLibraryVersion() ? 1 :
3001       XpmIncludeVersion < 30406 ? 2 : 0 ;}],
3002     [./conftest dummy_arg; xpm_status=$?;
3003       if test "$xpm_status" = "0"; then
3004         with_xpm=yes;
3005       else
3006         with_xpm=no;
3007         if test "$xpm_status" = "1"; then
3008           xpm_problem="Xpm library version and header file version don't match!"
3009         elif test "$xpm_status" = "2"; then
3010           xpm_problem="Xpm library version is too old!"
3011         else
3012           xpm_problem="Internal xpm detection logic error!"
3013         fi
3014         echo "
3015 *** WARNING *** $xpm_problem
3016   I'm not touching that with a 10-foot pole!
3017   If you really want to use the installed version of Xpm, rerun
3018   configure and add '--with-xpm=yes', but don't blame me if XEmacs crashes!"
3019     fi],
3020     [with_xpm=no])
3021     xe_check_libs=
3022     AC_MSG_RESULT($with_xpm)
3023   fi
3024   if test "$with_xpm" = "yes"; then
3025     AC_DEFINE(HAVE_XPM)
3026     XE_PREPEND(-lXpm, libs_x)
3027     AC_MSG_CHECKING(for \"FOR_MSW\" xpm)
3028     xe_check_libs=-lXpm
3029     AC_TRY_LINK(, [XpmCreatePixmapFromData()],
3030     [xpm_for_msw=no],
3031     [xpm_for_msw=yes])
3032     xe_check_libs=
3033     AC_MSG_RESULT($xpm_for_msw)
3034     if test "$xpm_for_msw" = "yes"; then
3035       AC_DEFINE(FOR_MSW)
3036     fi
3037   fi
3038
3039   dnl Autodetect XFACE
3040   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
3041   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
3042   test -z "$with_xface" && with_xface=yes
3043   if test "$with_xface" = "yes"; then
3044     AC_DEFINE(HAVE_XFACE)
3045     XE_PREPEND(-lcompface, libs_x)
3046   fi
3047
3048   dnl For a brief period we had the GIF code split out into a separate library,
3049   dnl but patent problems, etc. sort of squashed that idea.
3050   dnl We default to building with builtin GIF decoding
3051   if test "$with_gif" != "no"; then
3052     with_gif="yes"
3053     AC_DEFINE(HAVE_GIF)
3054     XE_ADD_OBJS(dgif_lib.o gif_io.o)
3055   fi
3056
3057   dnl Too many stupid linkers can't detect cascaded lib dependencies until runtime
3058   dnl So we always search for libz compression support.
3059   if test "$with_png $with_tiff" != "no no"; then
3060     AC_CHECK_LIB(c,  inflate, [:], [
3061     AC_CHECK_LIB(z,  inflate, [XE_PREPEND(-lz,  libs_x)],[
3062     AC_CHECK_LIB(gz, inflate, [XE_PREPEND(-lgz, libs_x)])])])
3063   fi
3064
3065   dnl autodetect JPEG
3066   test -z "$with_jpeg" && { AC_CHECK_HEADER(jpeglib.h,                    ,with_jpeg=no) }
3067   test -z "$with_jpeg" && { AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,[:],with_jpeg=no) }
3068   test -z "$with_jpeg" && with_jpeg=yes
3069   if test "$with_jpeg" = "yes"; then
3070     AC_DEFINE(HAVE_JPEG)
3071     XE_PREPEND(-ljpeg, libs_x)
3072   fi
3073
3074   dnl autodetect PNG
3075   png_problem=""
3076   test -z "$with_png" && { AC_CHECK_FUNC(pow,                  ,with_png=no) }
3077   test -z "$with_png" && { AC_CHECK_HEADER(png.h,              ,with_png=no) }
3078   test -z "$with_png" && { AC_CHECK_LIB(png, png_read_image,[:],with_png=no) }
3079   if test -z "$with_png"; then
3080     AC_MSG_CHECKING(for workable png version information)
3081     xe_check_libs="-lpng -lz"
3082     AC_TRY_RUN([#include <png.h>
3083     int main(int c, char **v) {
3084     if (c == 1) return 0;
3085     if (strcmp(png_libpng_ver, PNG_LIBPNG_VER_STRING) != 0) return 1;
3086     return (PNG_LIBPNG_VER < 10002) ? 2 : 0 ;}],
3087     [./conftest dummy_arg; png_status=$?;
3088       if test "$png_status" = "0"; then
3089         with_png=yes;
3090       else
3091         with_png=no;
3092         if test "$png_status" = "1"; then
3093           png_problem="PNG library version and header file don't match!"
3094         elif test "$png_status" = "2"; then
3095           png_problem="PNG library version too old (pre 1.0.2)!"
3096         fi
3097         echo "
3098 *** WARNING *** $png_problem
3099   I'm not touching that with a 10-foot pole!
3100   If you really want to use the installed version of libPNG, rerun
3101   configure and add '--with-png=yes', but don't blame me if XEmacs crashes!"
3102     fi],
3103     [with_png=no])
3104     xe_check_libs=
3105     AC_MSG_RESULT($with_png)
3106   fi
3107   if test "$with_png" = "yes"; then
3108     AC_DEFINE(HAVE_PNG)
3109     XE_PREPEND(-lpng, libs_x)
3110   fi
3111
3112   dnl autodetect TIFF
3113   test -z "$with_tiff" && { AC_CHECK_HEADER(tiffio.h,            ,with_tiff=no) }
3114   test -z "$with_tiff" && { AC_CHECK_LIB(tiff, TIFFClientOpen,[:],with_tiff=no) }
3115   test -z "$with_tiff" && with_tiff=yes
3116   if test "$with_tiff" = "yes"; then
3117     AC_DEFINE(HAVE_TIFF)
3118     XE_PREPEND(-ltiff, libs_x)
3119   fi
3120 fi
3121
3122 dnl ----------------------
3123 dnl X-Specific Graphics libraries
3124 dnl ----------------------
3125
3126 if test "$with_x11" = "yes"; then
3127
3128   AC_CHECKING(for X11 graphics libraries)
3129
3130   AC_CHECKING(for the Athena widgets)
3131
3132   dnl What in heck did the user actually want?
3133   case "$with_athena" in
3134     dnl This is the default, old fashioned flat Athena.
3135     "xaw" | "") athena_variant=Xaw      athena_3d=no  ;;
3136     "3d")       athena_variant=Xaw3d    athena_3d=yes ;;
3137     "next")     athena_variant=neXtaw   athena_3d=yes ;;
3138     "95")       athena_variant=Xaw95    athena_3d=yes ;;
3139     "xpm")      athena_variant=XawXpm   athena_3d=yes ;;
3140     *)          XE_DIE("Unknown Athena widget set \`$with_athena'. This should not happen.") ;;
3141   esac
3142
3143   dnl Search for the Athena library...
3144   if test "$athena_3d" = "no"; then
3145     AC_CHECK_LIB($athena_variant, XawScrollbarSetThumb,
3146       [
3147         dnl Must not be a 3d library...
3148         AC_CHECK_LIB($athena_variant, threeDClassRec,
3149           AC_MSG_WARN("Could not find a non-3d Athena widget library."),
3150           athena_lib=$athena_variant)
3151       ],
3152       AC_MSG_WARN("Could not find an Athena widget library."))
3153   else
3154     dnl The real configuration, need 3d library
3155     AC_CHECK_LIB($athena_variant, threeDClassRec, athena_lib=$athena_variant,
3156       dnl OK, couldn't find it with a proper name, try the standard Athena lib
3157       dnl If that is 3d, presume the user asked for what they have installed.
3158       AC_CHECK_LIB(Xaw, threeDClassRec,
3159         [
3160           athena_lib=Xaw;
3161           AC_MSG_WARN("Assuming that libXaw is actually $athena_variant.");
3162         ],
3163         AC_MSG_WARN("Could not find a 3d Athena widget library that looked like $athena_variant.")))
3164   fi
3165
3166   dnl Now we locate the Athena headers that we need.
3167   if test "$athena_3d" = "no"; then
3168     AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3169       AC_MSG_WARN("Could not find a non-3d Athena header set."),
3170       AC_CHECK_HEADER(X11/Xaw/XawInit.h,
3171         athena_h_path=X11/Xaw,
3172         AC_MSG_WARN("Could not find a non-3d Athena header set.")))
3173   else
3174     dnl The three-d Athena headers are so much more slippery.
3175     dnl Curse this `Lets replace standard libraries' thing that they did. :/
3176     AC_CHECK_HEADER(X11/$athena_variant/XawInit.h,
3177       AC_CHECK_HEADER(X11/$athena_variant/ThreeD.h,
3178         athena_h_path=X11/$athena_variant,))
3179
3180     dnl Is the variant specific header directory directly under include?
3181     if test -z "$athena_h_path"; then
3182       AC_CHECK_HEADER($athena_variant/XawInit.h,
3183         AC_CHECK_HEADER($athena_variant/ThreeD.h,
3184           athena_h_path=$athena_variant,))
3185     fi
3186
3187     dnl If we couldn't find the specific variant, try the generic Athena 3d headers
3188     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3189       AC_CHECK_HEADER(X11/Xaw3d/XawInit.h,
3190         AC_CHECK_HEADER(X11/Xaw3d/ThreeD.h,
3191           [
3192             AC_MSG_WARN("Assuming that X11/Xaw3d headers are suitable for $athena_variant.")
3193             athena_h_path=X11/Xaw3d
3194           ],))
3195     fi
3196
3197     dnl Also generic 3d headers directly under include dir
3198     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3199       AC_CHECK_HEADER(Xaw3d/XawInit.h,
3200         AC_CHECK_HEADER(Xaw3d/ThreeD.h,
3201           [
3202             AC_MSG_WARN("Assuming that Xaw3d headers are suitable for $athena_variant.")
3203             athena_h_path=Xaw3d
3204           ],))
3205     fi
3206
3207     dnl If nothing yet found, see if Xaw is a 3d header set...
3208     dnl We AC_MSG_WARN if we fail because I am all out of ideas...
3209     if test -z "$athena_h_path"; then
3210       AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3211         [
3212           AC_MSG_WARN("Assuming that X11/Xaw headers are suitable for $athena_variant.")
3213           athena_h_path=X11/Xaw
3214         ],
3215         AC_MSG_WARN("Could not find a suitable 3d Athena header set."))
3216     fi
3217   fi
3218
3219   dnl Do we actually have a usable Athena widget set? Please?
3220   if test -n "$athena_lib" -a -n "$athena_h_path"; then
3221     have_xaw=yes
3222   else
3223     have_xaw=no
3224   fi
3225
3226   dnl autodetect Motif - but only add to libs_x later (if necessary)
3227   AC_CHECK_HEADER(Xm/Xm.h,
3228    [AC_CHECK_LIB(Xm, XmStringFree, have_motif=yes, have_motif=no)],
3229    have_motif=no)
3230
3231   if test "$have_motif" = "yes"; then
3232     dnl autodetect lesstif
3233     AC_MSG_CHECKING(for Lesstif)
3234     AC_EGREP_CPP(yes,
3235 [#include <Xm/Xm.h>
3236 #ifdef LESSTIF_VERSION
3237 yes
3238 #endif
3239 ], have_lesstif=yes, have_lesstif=no)
3240   AC_MSG_RESULT($have_lesstif)
3241   fi
3242
3243 fi dnl "$with_x11" = "yes"
3244
3245 dnl Finish ensuring that we have values for the various toolkit items.
3246 dnl Not all toolkits support all widgets
3247 dnl if Motif is available we use it for the dialog boxes.
3248
3249 case "$with_menubars" in "" | "yes" | "athena" )
3250   with_menubars="lucid" ;;
3251 esac
3252 case "$with_dialogs" in "" | "yes" | "lucid" )
3253   if   test "$have_motif"     = "yes"; then with_dialogs="motif"
3254   elif test "$have_xaw"       = "yes"; then with_dialogs="athena"
3255   else with_dialogs=no
3256   fi ;;
3257 esac
3258 case "$with_scrollbars" in "" | "yes" )
3259   with_scrollbars="lucid" ;;
3260 esac
3261 case "$with_widgets" in "" | "yes" | "lucid")
3262   if   test "$have_motif" = "yes"; then with_widgets="motif"
3263   elif test "$have_xaw"   = "yes"; then with_widgets="athena"
3264   else with_widgets=no
3265   fi ;;
3266 esac
3267
3268 all_widgets="$with_menubars $with_scrollbars $with_dialogs $with_toolbars $with_widgets"
3269
3270 case "$all_widgets" in
3271   *athena* )
3272     if test "$have_xaw" != "yes"; then
3273       XE_DIE("Could not find a suitable Athena library to build with.")
3274     fi
3275
3276     dnl Add the Lucid widget Athena code
3277     XE_APPEND(lwlib-Xaw.o, lwlib_objs)
3278
3279     dnl Add the Athena widget library we located earlier
3280     XE_PREPEND(-l$athena_lib, libs_x)
3281
3282     dnl Tell lwlib where to find the Athena header files.
3283     dnl Many people have tried to create a `smart' way of doing this,
3284     dnl but all have failed.  Before changing the following ugly definitions,
3285     dnl consult the veterans of many a battle.
3286     AC_DEFINE_UNQUOTED(ATHENA_Scrollbar_h_,"$athena_h_path/Scrollbar.h")
3287     AC_DEFINE_UNQUOTED(ATHENA_Dialog_h_,"$athena_h_path/Dialog.h")
3288     AC_DEFINE_UNQUOTED(ATHENA_Form_h_,"$athena_h_path/Form.h")
3289     AC_DEFINE_UNQUOTED(ATHENA_Command_h_,"$athena_h_path/Command.h")
3290     AC_DEFINE_UNQUOTED(ATHENA_Label_h_,"$athena_h_path/Label.h")
3291     AC_DEFINE_UNQUOTED(ATHENA_LabelP_h_,"$athena_h_path/LabelP.h")
3292     AC_DEFINE_UNQUOTED(ATHENA_Toggle_h_,"$athena_h_path/Toggle.h")
3293     AC_DEFINE_UNQUOTED(ATHENA_ToggleP_h_,"$athena_h_path/ToggleP.h")
3294     AC_DEFINE_UNQUOTED(ATHENA_AsciiText_h_,"$athena_h_path/AsciiText.h")
3295     AC_DEFINE_UNQUOTED(ATHENA_XawInit_h_,"$athena_h_path/XawInit.h")
3296
3297     AC_DEFINE(LWLIB_USES_ATHENA)
3298     AC_DEFINE(NEED_ATHENA)
3299     need_athena="yes"
3300
3301     if test "$athena_3d" = "yes"; then
3302       AC_DEFINE(HAVE_ATHENA_3D)
3303     fi
3304   ;;
3305 esac
3306
3307 case "$all_widgets" in *motif* )
3308   AC_DEFINE(LWLIB_USES_MOTIF)
3309   AC_DEFINE(NEED_MOTIF)
3310   XE_APPEND(lwlib-Xm.o, lwlib_objs)
3311   need_motif=yes ;;
3312 esac
3313
3314 test "$with_menubars"   = "lucid" && XE_APPEND(xlwmenu.o, lwlib_objs)
3315 test "$with_menubars"   = "motif" && XE_APPEND(xlwmenu.o, lwlib_objs)
3316 test "$with_scrollbars" = "lucid" && XE_APPEND(xlwscrollbar.o, lwlib_objs)
3317 test "$with_widgets"   != "no" && test "$with_widgets" != "msw" && \
3318         XE_APPEND(xlwtabs.o xlwgcs.o, lwlib_objs)
3319 case "$with_widgets" in athena* )
3320         XE_APPEND(xlwradio.o xlwcheckbox.o xlwgauge.o, lwlib_objs);;
3321 esac
3322 case "$all_widgets" in *lucid* )
3323   AC_DEFINE(NEED_LUCID)
3324   XE_APPEND(lwlib-Xlw.o, lwlib_objs) ;;
3325 esac
3326
3327 AC_SUBST(lwlib_objs)
3328
3329 test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA)
3330 test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA)
3331
3332 if test "$athena_3d" = "yes"; then
3333   test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA3D)
3334   test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA3D)
3335 fi
3336
3337 case "$with_widgets" in athena* ) AC_DEFINE(LWLIB_WIDGETS_ATHENA);; esac
3338 test "$with_widgets" != "no" && test "$with_widgets" != "msw" && \
3339         AC_DEFINE(LWLIB_TABS_LUCID)
3340
3341 test "$with_menubars"   != "no"    && AC_DEFINE(HAVE_MENUBARS)
3342 test "$with_scrollbars" != "no"    && AC_DEFINE(HAVE_SCROLLBARS)
3343 test "$with_dialogs"    != "no"    && AC_DEFINE(HAVE_DIALOGS)
3344 test "$with_toolbars"   != "no"    && AC_DEFINE(HAVE_TOOLBARS)
3345 test "$with_widgets"    != "no"    && AC_DEFINE(HAVE_WIDGETS)
3346
3347 test "$with_menubars"   = "lucid"  && AC_DEFINE(LWLIB_MENUBARS_LUCID)
3348 test "$with_scrollbars" = "lucid"  && AC_DEFINE(LWLIB_SCROLLBARS_LUCID)
3349
3350 test "$with_menubars"   = "motif"  && AC_DEFINE(LWLIB_MENUBARS_MOTIF)
3351 test "$with_scrollbars" = "motif"  && AC_DEFINE(LWLIB_SCROLLBARS_MOTIF)
3352 test "$with_dialogs"    = "motif"  && AC_DEFINE(LWLIB_DIALOGS_MOTIF)
3353 test "$with_widgets"    = "motif"  && AC_DEFINE(LWLIB_WIDGETS_MOTIF)
3354
3355 test "$with_menubars"   != "no"    && XE_ADD_OBJS(menubar.o)
3356 test "$with_scrollbars" != "no"    && XE_ADD_OBJS(scrollbar.o)
3357 test "$with_dialogs"    != "no"    && XE_ADD_OBJS(dialog.o)
3358 test "$with_toolbars"   != "no"    && XE_ADD_OBJS(toolbar.o)
3359
3360 if test "$with_x11" = "yes"; then
3361   test "$with_menubars"   != "no"  && XE_ADD_OBJS(menubar-x.o)
3362   test "$with_scrollbars" != "no"  && XE_ADD_OBJS(scrollbar-x.o)
3363   test "$with_dialogs"    != "no"  && XE_ADD_OBJS(dialog-x.o)
3364   test "$with_toolbars"   != "no"  && XE_ADD_OBJS(toolbar-x.o)
3365   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-x.o)
3366 fi
3367
3368 dnl ----------------------
3369 dnl Mule-dependent options
3370 dnl ----------------------
3371
3372 test -z "$with_mule" && with_mule=no
3373 test -z "$with_file_coding" && with_file_coding=no
3374
3375 dnl if test "$with_mule" = "yes" && test ! -d "$srcdir/lisp/mule"; then
3376 dnl     echo "Attempt to Build with Mule without Mule/Lisp"
3377 dnl     echo "Please install the XEmacs/Mule tarball or"
3378 dnl     echo "rerun configure with --with-mule=no"
3379 dnl     exit 1
3380 dnl fi
3381
3382 if test "$with_file_coding" = "yes" && test "$with_mule" = "no"; then
3383   AC_DEFINE(FILE_CODING)
3384   XE_ADD_OBJS(file-coding.o)
3385 fi
3386
3387 if test "$with_mule" = "yes" ; then
3388   AC_CHECKING(for Mule-related features)
3389   AC_DEFINE(MULE)
3390   AC_DEFINE(FILE_CODING)
3391   XE_ADD_OBJS(mule.o mule-ccl.o mule-charset.o)
3392   if test "$with_utf_2000" = "yes" && test "$with_text_coding" = "yes"; then
3393     AC_DEFINE(TEXT_CODING)
3394     XE_ADD_OBJS(text-coding.o)
3395   else
3396     XE_ADD_OBJS(file-coding.o)
3397   fi
3398   dnl Use -lintl to get internationalized strerror for Mule
3399   AC_CHECK_HEADERS(libintl.h)
3400   AC_CHECK_LIB(intl, strerror)
3401
3402   if test "$with_utf_2000" = "yes" ; then
3403     AC_DEFINE(CHAR_IS_UCS4)
3404     AC_DEFINE(UTF2000)
3405     AC_DEFINE(HAVE_GGC)
3406   fi
3407
3408   AC_CHECKING(for Mule input methods)
3409   dnl Do we have the XmIm* routines?  And if so, do we want to use them?
3410   dnl XIM seems to be flaky except on Solaris...
3411   dnl test -z "$with_xim" -a "$opsys" != "sol2" && with_xim=no
3412   case "$with_xim" in "" | "yes" )
3413     AC_CHECKING(for XIM)
3414     AC_CHECK_LIB(X11, XOpenIM, with_xim=xlib, with_xim=no)
3415     dnl XIM + Lesstif is not (yet?) usable
3416     if test "$have_motif $have_lesstif" = "yes no"; then
3417       AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif)
3418     fi ;;
3419   esac
3420   if test "$with_xim" != "no"; then
3421     AC_DEFINE(HAVE_XIM)
3422     if test "$with_xim" = "xlib"; then
3423       AC_DEFINE(XIM_XLIB)
3424       XE_ADD_OBJS(input-method-xlib.o)
3425     fi
3426     if test "$with_xim" = "motif"; then
3427       AC_DEFINE(XIM_MOTIF)
3428       need_motif=yes
3429       XE_ADD_OBJS(input-method-motif.o)
3430     fi
3431     if test "$with_xim" = "motif"; then
3432       with_xfs=no
3433     fi
3434   fi
3435
3436   dnl "with_xfs" = "yes"
3437   if test "$with_xfs" = "yes" ; then
3438     AC_CHECKING(for XFontSet)
3439     AC_CHECK_LIB(X11, XmbDrawString, [:], with_xfs=no)
3440     if test "$with_xfs" = "yes" && test "$with_menubars" = "lucid"; then
3441       AC_DEFINE(USE_XFONTSET)
3442       if test "$with_xim" = "no" ; then
3443         XE_ADD_OBJS(input-method-xfs.o)
3444       fi
3445     fi
3446   fi dnl with_xfs
3447
3448   dnl Autodetect WNN
3449   test "$with_wnn6" = "yes" && with_wnn=yes # wnn6 implies wnn support
3450   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/jllib.h, ,with_wnn=no) }
3451   dnl Detour to find crypt
3452   if test "$with_wnn" != "no"; then
3453     AC_CHECK_FUNCS(crypt)
3454     test "$ac_cv_func_crypt" != "yes" && { AC_CHECK_LIB(crypt, crypt) }
3455   fi
3456   dnl Back to our regularly scheduled wnn hunting
3457   if test -z "$with_wnn" -o "$with_wnn" = "yes"; then
3458     AC_CHECK_LIB(wnn,jl_dic_list_e,libwnn=wnn,
3459       AC_CHECK_LIB(wnn4,jl_dic_list_e,libwnn=wnn4,
3460         AC_CHECK_LIB(wnn6,jl_dic_list_e,libwnn=wnn6,
3461           AC_CHECK_LIB(wnn6_fromsrc,dic_list_e,libwnn=wnn6_fromsrc,with_wnn=no))))
3462   fi
3463   test -z "$with_wnn" && with_wnn=yes
3464   if test "$with_wnn" = "yes"; then
3465     AC_DEFINE(HAVE_WNN)
3466     XE_PREPEND(-l$libwnn, libs_x)
3467     XE_ADD_OBJS(mule-wnnfns.o)
3468     if test "$with_wnn6" != "no"; then
3469       AC_CHECK_LIB($libwnn, jl_fi_dic_list, with_wnn6=yes)
3470       test "$with_wnn6" = "yes" && AC_DEFINE(WNN6)
3471     fi
3472   fi
3473
3474   dnl Autodetect canna
3475   canna_includes_found=no
3476   if test "$with_canna" != "no"; then
3477     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3478   fi
3479   if test "$canna_includes_found" = "no" -a "$with_canna" != "no" -a \
3480       -d "/usr/local/canna/include"; then
3481     save_c_switch_site="$c_switch_site"
3482     c_switch_site="$c_switch_site -I/usr/local/canna/include"
3483     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3484     if test "$canna_includes_found" != "yes"; then
3485       c_switch_site="$save_c_switch_site"
3486       with_canna="no"
3487     fi
3488   fi
3489
3490   test -z "$with_canna" && { AC_CHECK_HEADER(canna/RK.h,         , with_canna=no) }
3491   test -z "$with_canna" && { AC_CHECK_LIB(RKC, RkBgnBun,       [:],with_canna=no) }
3492   test -z "$with_canna" && { AC_CHECK_LIB(canna,jrKanjiControl,[:],with_canna=no) }
3493   test -z "$with_canna" && with_canna=yes
3494   if test "$with_canna" = "yes"; then
3495     AC_DEFINE(HAVE_CANNA)
3496     XE_PREPEND(-lcanna -lRKC, libs_x)
3497     XE_ADD_OBJS(mule-canna.o)
3498   fi
3499
3500 else dnl "$with_mule" = "no"
3501   for feature in xim canna wnn; do
3502     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3503       AC_MSG_WARN("--with-${feature} ignored:  Not valid without Mule support")
3504     fi
3505     eval "with_${feature}=no"
3506   done
3507 fi dnl with_mule
3508
3509
3510 dnl At this point, we know whether we need the motif lib or not.
3511 if test "$need_motif" = "yes" ; then
3512   XE_PREPEND(-lXm, libs_x)
3513   dnl AIX needs the following library for use with Motif
3514   AC_CHECK_LIB(i18n, layout_object_getvalue, [XE_PREPEND(-li18n, libs_x)])
3515   XE_COMPUTE_RUNPATH()
3516 fi
3517
3518 AC_CHECK_FUNCS(cbrt closedir dup2 eaccess fmod fpathconf frexp ftime getaddrinfo gethostname getnameinfo getpagesize gettimeofday getcwd getpt getwd logb lrand48 matherr mkdir mktime perror poll random rename res_init rint rmdir select setitimer setpgid setlocale setsid sigblock sighold sigprocmask snprintf stpcpy strcasecmp strerror tzset ulimit usleep utimes waitpid vsnprintf fsync ftruncate umask)
3519
3520 dnl Use our own realpath always.
3521 XE_ADD_OBJS(realpath.o)
3522
3523 dnl Check whether the system provides getloadavg (Solaris 7 has it)
3524 AC_CHECK_FUNCS(getloadavg)
3525
3526 if test "$ac_cv_func_getloadavg" != "yes"
3527 then
3528   XE_ADD_OBJS(getloadavg.o)
3529
3530   dnl Used by getloadavg() - does not require root priveleges
3531   AC_CHECK_LIB(kstat, kstat_open)
3532
3533   dnl Another way to get the load average
3534   AC_CHECK_LIB(kvm, kvm_read)
3535 fi
3536
3537 dnl If netdb.h does not declare h_errno, we must declare it by hand.
3538 AC_MSG_CHECKING(whether netdb declares h_errno)
3539 AC_TRY_LINK([#include <netdb.h>],
3540   [return h_errno;],
3541   [AC_MSG_RESULT(yes)
3542    AC_DEFINE(HAVE_H_ERRNO)],
3543   [AC_MSG_RESULT(no)])
3544
3545 AC_MSG_CHECKING(for sigsetjmp)
3546 AC_TRY_COMPILE([#include <setjmp.h>],
3547         [sigjmp_buf bar; sigsetjmp (bar, 0);],
3548   [AC_MSG_RESULT(yes)
3549    AC_DEFINE(HAVE_SIGSETJMP)],
3550   [AC_MSG_RESULT(no)])
3551
3552 AC_MSG_CHECKING(whether localtime caches TZ)
3553 AC_CACHE_VAL(emacs_cv_localtime_cache,
3554 [if test "$ac_cv_func_tzset" = "yes"; then
3555 AC_TRY_RUN([#include <time.h>
3556 #if STDC_HEADERS
3557 # include <stdlib.h>
3558 #endif
3559 extern char **environ;
3560 unset_TZ ()
3561 {
3562   char **from, **to;
3563   for (to = from = environ; (*to = *from); from++)
3564     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
3565       to++;
3566 }
3567 char TZ_GMT0[] = "TZ=GMT0";
3568 char TZ_PST8[] = "TZ=PST8";
3569 main()
3570 {
3571   time_t now = time ((time_t *) 0);
3572   int hour_GMT0, hour_unset;
3573   if (putenv (TZ_GMT0) != 0)
3574     exit (1);
3575   hour_GMT0 = localtime (&now)->tm_hour;
3576   unset_TZ ();
3577   hour_unset = localtime (&now)->tm_hour;
3578   if (putenv (TZ_PST8) != 0)
3579     exit (1);
3580   if (localtime (&now)->tm_hour == hour_GMT0)
3581     exit (1);
3582   unset_TZ ();
3583   if (localtime (&now)->tm_hour != hour_unset)
3584     exit (1);
3585   exit (0);
3586 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3587 [# If we have tzset, assume the worst when cross-compiling.
3588 emacs_cv_localtime_cache=yes])
3589 else
3590         # If we lack tzset, report that localtime does not cache TZ,
3591         # since we can't invalidate the cache if we don't have tzset.
3592         emacs_cv_localtime_cache=no
3593 fi],[:])dnl
3594 AC_MSG_RESULT($emacs_cv_localtime_cache)
3595 if test $emacs_cv_localtime_cache = yes; then
3596   AC_DEFINE(LOCALTIME_CACHE)
3597 fi
3598
3599 if test "$HAVE_TIMEVAL" = "yes"; then
3600 AC_MSG_CHECKING(whether gettimeofday accepts one or two arguments)
3601 AC_TRY_LINK([
3602 #ifdef TIME_WITH_SYS_TIME
3603 #include <sys/time.h>
3604 #include <time.h>
3605 #else
3606 #ifdef HAVE_SYS_TIME_H
3607 #include <sys/time.h>
3608 #else
3609 #include <time.h>
3610 #endif
3611 #endif
3612   ],
3613   [
3614   struct timeval time;
3615   gettimeofday (&time, 0);
3616 ],
3617   [AC_MSG_RESULT(two)],
3618   [AC_MSG_RESULT(one)
3619    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
3620 fi
3621
3622
3623 AC_C_INLINE
3624 test "$ac_cv_c_inline" != "no" -a "$GCC" = "yes" && XE_ADD_OBJS(inline.o)
3625
3626 dnl HP-UX has a working alloca in libPW.
3627 dnl case "${GCC}${opsys}" in hpux* )
3628 dnl  AC_CHECK_FUNC(alloca, [:], [AC_CHECK_LIB(PW, alloca)])
3629 dnl esac
3630
3631 AC_FUNC_ALLOCA
3632 test -n "$ALLOCA" && XE_ADD_OBJS($ALLOCA)
3633
3634 dnl Check whether vfork exists and works correctly. (This does more
3635 dnl than just check for its existence.) If so, it defines HAVE_VFORK_H.
3636 dnl If not, it defines vfork to be fork.
3637 AC_FUNC_VFORK
3638
3639 dnl Check whether strcoll exists and works correctly. (This does more
3640 dnl than just check for its existence.) If so, it defines HAVE_STRCOLL.
3641 AC_FUNC_STRCOLL
3642
3643 dnl If `getpgrp' takes no argument (the POSIX.1 version), define
3644 dnl `GETPGRP_VOID'.  Otherwise, it is the BSD version, which takes a
3645 dnl process ID as an argument.
3646 AC_CHECK_FUNCS(getpgrp)
3647 AC_FUNC_GETPGRP
3648
3649 dnl We used to call AC_FUNC_MMAP here
3650 dnl Instead we now use following, suggested by Neal Becker
3651 AC_MSG_CHECKING(for working mmap)
3652 case "$opsys" in ultrix* ) have_mmap=no ;; *)
3653 AC_TRY_RUN([#include <stdio.h>
3654 #include <unistd.h>
3655 #include <fcntl.h>
3656 #include <sys/mman.h>
3657
3658 #ifndef MAP_VARIABLE
3659 #define MAP_VARIABLE 0
3660 #endif
3661
3662 #ifndef MAP_FAILED
3663 #define MAP_FAILED -1
3664 #endif
3665
3666 int main (int argc, char *argv[])
3667 {
3668   int fd = -1;
3669   caddr_t p;
3670 #ifndef MAP_ANONYMOUS
3671   fd = open ("/dev/zero", O_RDWR);
3672   if (fd < 0)
3673     return 1;
3674 #define MAP_ANONYMOUS 0
3675 #endif
3676   if (mmap(0, 1024, PROT_READ | PROT_WRITE,
3677            MAP_PRIVATE | MAP_VARIABLE | MAP_ANONYMOUS,
3678            fd, 0) != (void *) MAP_FAILED)
3679     return 0;
3680   perror ("conftest: mmap failed");
3681   return 1;
3682 }], have_mmap=yes, have_mmap=no) ;;
3683 esac
3684 AC_MSG_RESULT($have_mmap)
3685 test "$have_mmap" = "yes" && AC_DEFINE(HAVE_MMAP)
3686
3687 dnl rel_alloc requires either GNU malloc or system malloc with mmap
3688 dnl We only turn rel_alloc on by default if mmap is available.
3689 test "$GNU_MALLOC" != "yes" -a "$have_mmap" != "yes" && rel_alloc=no
3690 if test "$rel_alloc $have_mmap" = "default yes"; then
3691   if test "$doug_lea_malloc" = "yes"; then
3692     dnl Check if malloc() calls mmap(), making rel_alloc pointless.
3693     AC_MSG_CHECKING(for M_MMAP_THRESHOLD)
3694     AC_TRY_COMPILE([#include <malloc.h>],[
3695 #ifndef M_MMAP_THRESHOLD
3696 #error No M_MMAP_THRESHOLD :-(
3697 !@+$%^&*_)(_ - unlikely to compile...
3698 #endif
3699 ], [rel_alloc=no; AC_MSG_RESULT(yes);], [rel_alloc=yes; AC_MSG_RESULT(no);])
3700   else
3701     rel_alloc=yes
3702   fi
3703 fi
3704 test "$rel_alloc" = "yes" && AC_DEFINE(REL_ALLOC)
3705
3706 dnl Check for terminal I/O variants
3707 dnl TERMIOS systems may have termio.h, but not vice-versa, I think.
3708 AC_CHECK_HEADER(termios.h,
3709   AC_DEFINE(HAVE_TERMIOS)
3710   AC_DEFINE(SIGNALS_VIA_CHARACTERS)
3711   AC_DEFINE(NO_TERMIO),
3712   [AC_CHECK_HEADER(termio.h, [AC_DEFINE(HAVE_TERMIO)])])
3713
3714
3715 dnl Check for Internet sockets.
3716 AC_CHECK_FUNC(socket,
3717  [AC_CHECK_HEADER(netinet/in.h,
3718    [AC_CHECK_HEADER(arpa/inet.h, [
3719   AC_DEFINE(HAVE_SOCKETS)
3720       AC_MSG_CHECKING("for sun_len member in struct sockaddr_un")
3721       AC_TRY_LINK([
3722 #include <sys/types.h>
3723 #include <sys/socket.h>
3724 #include <sys/un.h>
3725       ],
3726       [static struct sockaddr_un x; x.sun_len = 1;],
3727       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)],
3728       [AC_MSG_RESULT(no)])
3729       AC_MSG_CHECKING("for ip_mreq struct in netinet/in.h")
3730       AC_TRY_LINK([
3731 #include <sys/types.h>
3732 #include <netinet/in.h>
3733       ],
3734       [static struct ip_mreq x;],
3735       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MULTICAST)],
3736       [AC_MSG_RESULT(no)])])])])
3737
3738 dnl Check for SYS V IPC. (Inferior to sockets.)
3739 AC_CHECK_FUNC(msgget,
3740   [AC_CHECK_HEADER(sys/ipc.h,
3741     [AC_CHECK_HEADER(sys/msg.h,
3742       [AC_DEFINE(HAVE_SYSVIPC)])])])
3743
3744 dnl Check for directory variants
3745 AC_CHECK_HEADER(dirent.h, [AC_DEFINE(SYSV_SYSTEM_DIR)],
3746   [AC_CHECK_HEADER(sys/dir.h, , [AC_DEFINE(NONSYSTEM_DIR_LIBRARY)])])
3747
3748 dnl Check for nlist.h
3749 AC_CHECK_HEADER(nlist.h, AC_DEFINE(NLIST_STRUCT), )
3750
3751 dnl Check for sound of various sorts.
3752
3753 dnl Autodetect native sound
3754 AC_CHECKING("for sound support")
3755 test -z "$with_native_sound" -a -n "$native_sound_lib" && with_native_sound=yes
3756
3757 if test "$with_native_sound" != "no"; then
3758   dnl Maybe sound is already on include path...
3759   if test -n "$native_sound_lib"; then
3760     AC_CHECK_HEADER(multimedia/audio_device.h,
3761       [sound_found=yes sound_cflags=""
3762       XE_ADD_OBJS(sunplay.o)])
3763   fi
3764
3765   dnl Autodetect Sun native sound from SUNWaudmo package
3766   if test -z "$sound_found" -a -d "/usr/demo/SOUND"; then
3767     sound_found=yes
3768     XE_ADD_OBJS(sunplay.o)
3769     if test -d "/usr/demo/SOUND/include"
3770       then sound_cflags="-I/usr/demo/SOUND/include"
3771       else sound_cflags="-I/usr/demo/SOUND"
3772     fi
3773     if test -z "$native_sound_lib" ; then
3774       if test -r "/usr/demo/SOUND/lib/libaudio.a"
3775         then native_sound_lib="/usr/demo/SOUND/lib/libaudio.a"
3776         else native_sound_lib="/usr/demo/SOUND/libaudio.a"
3777       fi
3778     fi
3779   fi
3780
3781   dnl Check for SGI and HP native sound libs
3782   if test -z "$sound_found"; then
3783     case "$canonical" in
3784     *-sgi-* )
3785       if test -z "$native_sound_lib"; then
3786         AC_CHECK_LIB(audio, ALopenport, native_sound_lib="-laudio")
3787       fi
3788       if test -n "$native_sound_lib"; then
3789         sound_found=yes sound_cflags=""
3790         XE_ADD_OBJS(sgiplay.o)
3791       fi ;;
3792     hppa*-hp-hpux* )
3793       if test -z "$native_sound_lib"; then
3794         AC_CHECK_LIB(Alib, AOpenAudio, native_sound_lib="-lAlib")
3795       fi
3796       if test -n "$native_sound_lib"; then
3797         sound_found=yes
3798         XE_ADD_OBJS(hpplay.o)
3799         if test "$GCC" = "yes" # Kludge city
3800           then sound_cflags="-Dconst= -Dvolatile= -I/usr/audio/examples"
3801           else sound_cflags="+e -I/usr/audio/examples"
3802         fi
3803       fi ;;
3804     esac
3805   fi
3806
3807   dnl Check for Linux/BSD native sound
3808   if test -z "$sound_found"; then
3809     for dir in "machine" "sys" "linux"; do
3810       AC_CHECK_HEADER(${dir}/soundcard.h,
3811         sound_found=yes
3812        need_miscplay=yes
3813         XE_ADD_OBJS(linuxplay.o)
3814         [AC_DEFINE_UNQUOTED(SOUNDCARD_H_FILE, "${dir}/soundcard.h")]
3815         break)
3816     done
3817   fi
3818
3819   dnl Win32 Native uses native sound
3820   if test -z "$sound_found"; then
3821     if test "$with_msw" = "yes"; then
3822     sound_found=yes
3823     native_sound_lib=
3824     fi
3825   fi
3826
3827   test "$sound_found" = "yes" && with_native_sound=yes
3828 fi
3829
3830 if test "$with_native_sound" = "yes"; then
3831   AC_DEFINE(HAVE_NATIVE_SOUND)
3832   test -n "$native_sound_lib" && XE_PREPEND($native_sound_lib, LIBS)
3833 fi
3834
3835 dnl NAS Sound support
3836 if test "$with_nas_sound" != "no"; then
3837   AC_CHECK_HEADER(audio/audiolib.h, [
3838     AC_CHECK_LIB(audio, AuOpenServer, have_nas_sound=yes)])
3839   if test "$have_nas_sound" = "yes"; then
3840     with_nas_sound=yes
3841     AC_DEFINE(HAVE_NAS_SOUND)
3842     XE_ADD_OBJS(nas.o)
3843     XE_PREPEND(-laudio, libs_x)
3844     dnl If the nas library does not contain the error jump point,
3845     dnl then we force safer behavior.
3846     AC_EGREP_HEADER(AuXtErrorJump,audio/Xtutil.h,,[old_nas=yes; AC_DEFINE(NAS_NO_ERROR_JUMP)])
3847   else
3848     test "$with_nas_sound" = "yes" && \
3849       XE_DIE("Required NAS sound support cannot be provided.")
3850     with_nas_sound=no
3851   fi
3852 fi
3853
3854 dnl ESD Sound support
3855 if test "$with_esd_sound" != "no"; then
3856   AC_CHECK_PROG(have_esd_config, esd-config, yes, no)
3857   if test "$have_esd_config" = "yes"; then
3858     save_c_switch_site="$c_switch_site" save_LIBS="$LIBS"
3859     XE_APPEND(`esd-config --cflags`, c_switch_site)
3860     XE_PREPEND(`esd-config --libs`, LIBS)
3861     AC_CHECK_FUNC(esd_play_stream,
3862       have_esd_sound=yes,
3863       c_switch_site="$save_c_switch_site" LIBS="$save_LIBS")
3864   fi
3865
3866   if test "$have_esd_sound" = "yes"; then
3867     with_esd_sound=yes
3868     need_miscplay=yes
3869     XE_ADD_OBJS(esd.o)
3870     AC_DEFINE(HAVE_ESD_SOUND)
3871   else
3872     test "$with_esd_sound" = "yes" && \
3873       XE_DIE("Required ESD sound support cannot be provided.")
3874     with_esd_sound=no
3875   fi
3876 fi
3877
3878 test "$need_miscplay" = "yes" && XE_ADD_OBJS(miscplay.o)
3879
3880 dnl ---------------------
3881 dnl TTY-dependent options
3882 dnl ---------------------
3883
3884 test -z "$with_tty" && with_tty=yes
3885
3886 if test "$with_tty" = "yes"  ; then
3887   AC_CHECKING(for TTY-related features)
3888   AC_DEFINE(HAVE_TTY)
3889   XE_ADD_OBJS(console-tty.o device-tty.o event-tty.o frame-tty.o objects-tty.o redisplay-tty.o cm.o)
3890
3891   dnl Autodetect ncurses.
3892   if test -z "$with_ncurses"; then
3893     AC_CHECK_LIB(ncurses, tgetent, with_ncurses=yes, with_ncurses=no)
3894   fi
3895   if test "$with_ncurses" = "yes"; then
3896     AC_DEFINE(HAVE_NCURSES)
3897     AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
3898     AC_CHECK_HEADER(ncurses/term.h, term_h_file=ncurses/term.h)
3899     XE_ADD_OBJS(terminfo.o)
3900     XE_PREPEND(-lncurses, LIBS)
3901
3902     if test "$ac_cv_header_ncurses_curses_h" != "yes" ; then
3903       dnl Try again, and check for the bogus ncurses/ include bug.
3904       dnl (i.e. ncurses/curses.h bogusly includes <unctrl.h> instead of
3905       dnl <ncurses/unctrl.h>)
3906       save_c_switch_site="$c_switch_site"
3907       c_switch_site="$c_switch_site -I/usr/include/ncurses"
3908       AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
3909       if test "$ac_cv_header_ncurses_curses_h" = "yes"
3910         then AC_MSG_WARN("Your system has the bogus ncurses include bug.")
3911         else c_switch_site="$save_c_switch_site"
3912       fi
3913     fi
3914   else dnl "$with_ncurses" = "no"
3915     dnl Autodetect terminfo/-lcurses/-ltermlib/-ltermcap
3916     if test "$have_terminfo" = "yes"; then
3917       XE_ADD_OBJS(terminfo.o)
3918       if test -n "$libs_termcap"; then
3919         XE_PREPEND($libs_termcap, LIBS)
3920       else
3921         for lib in curses termlib termcap; do
3922           AC_CHECK_LIB($lib, tgetent, XE_PREPEND(-l${lib}, LIBS); break)
3923         done
3924       fi
3925     else dnl "$have_terminfo" = "no" && "with_ncurses" = "no"
3926       XE_ADD_OBJS(tparam.o)
3927       dnl The HP-UX curses library seems to have a badly broken version of select(2)
3928       dnl that makes "poll: interrupted system call" messages to appear and
3929       dnl Emacs suprocesses to hang (e.g. TeX compilation w/ AUCTeX) */
3930       case "$opsys" in *-hp-hpux* ) libs_termcap="-ltermcap" ;; esac
3931       if test -n "$libs_termcap"; then
3932         XE_PREPEND($libs_termcap, LIBS)
3933       else
3934         AC_CHECK_LIB(curses, tgetent, XE_PREPEND(-lcurses, LIBS),
3935           AC_CHECK_LIB(termcap, tgetent, XE_PREPEND(-ltermcap, LIBS),
3936             XE_ADD_OBJS(termcap.o)))
3937       fi
3938     fi
3939   fi
3940   AC_DEFINE_UNQUOTED(CURSES_H_FILE, "${curses_h_file-curses.h}")
3941   AC_DEFINE_UNQUOTED(TERM_H_FILE, "${term_h_file-term.h}")
3942
3943   dnl Autodetect gpm
3944   test -z "$with_gpm" && { AC_CHECK_HEADER(gpm.h, , with_gpm=no) }
3945   test -z "$with_gpm" && { AC_CHECK_LIB(gpm, Gpm_Open, with_gpm=yes, with_gpm=no) }
3946   if test "$with_gpm" = "yes"; then
3947     AC_DEFINE(HAVE_GPM)
3948     XE_ADD_OBJS(gpmevent.o)
3949     XE_PREPEND(-lgpm, LIBS)
3950   fi
3951
3952 else dnl "$with_tty" = "no"
3953   for feature in ncurses gpm; do
3954     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3955       AC_MSG_WARN("--with-${feature} ignored:  Not valid without TTY support")
3956     fi
3957     eval "with_${feature}=no"
3958   done
3959 fi dnl with_tty
3960
3961 dnl Do we need event-unixoid.o ?
3962 test "$with_x11" = "yes" -o "$with_tty" = "yes" && XE_ADD_OBJS(event-unixoid.o)
3963
3964 dnl Database support
3965 dnl We do not necessarily have to have libdb/lib(g)dbm for DB/(G)DBM support.
3966 dnl On FreeBSD, both DB and DBM are part of libc.
3967 dnl By default, we check for DBM support in libgdbm, then libc, then libdbm.
3968
3969 test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
3970   != "no no no" && AC_CHECKING(for database support)
3971
3972 dnl Check for ndbm.h, required for either kind of DBM support.
3973 if test "$with_database_gdbm $with_database_dbm" != "no no"; then
3974   AC_CHECK_HEADER(ndbm.h, [:], [
3975     test "$with_database_gdbm" = "yes" -o \
3976          "$with_database_dbm"  = "yes" && \
3977       XE_DIE("Required DBM support cannot be provided.")
3978     with_database_gdbm=no with_database_dbm=no])
3979 fi
3980
3981 dnl Check for DBM support in libgdbm.
3982 if test "$with_database_gdbm" != "no"; then
3983   AC_CHECK_LIB(gdbm, dbm_open, [
3984    with_database_gdbm=yes with_database_dbm=no libdbm=-lgdbm], [
3985    if test "$with_database_gdbm" = "yes"; then
3986      XE_DIE("Required GNU DBM support cannot be provided.")
3987    fi
3988    with_database_gdbm=no])
3989 fi
3990
3991 dnl Check for DBM support in libc and libdbm.
3992 if test "$with_database_dbm" != "no"; then
3993   AC_CHECK_FUNC(dbm_open, [with_database_dbm=yes libdbm=], [
3994     AC_CHECK_LIB(dbm, dbm_open, [with_database_dbm=yes libdbm=-ldbm], [
3995       test "$with_database_dbm" = "yes" && \
3996         XE_DIE("Required DBM support cannot be provided.")
3997       with_database_dbm=no])])
3998 fi
3999
4000 dnl Tell make about the DBM support we detected.
4001 test -n "$libdbm" && XE_PREPEND("$libdbm", LIBS)
4002 test "$with_database_gdbm" = "yes" -o \
4003      "$with_database_dbm"  = "yes" && \
4004   AC_DEFINE(HAVE_DBM)
4005
4006 dnl Check for Berkeley DB.
4007 if test "$with_database_berkdb" != "no"; then
4008   AC_MSG_CHECKING(for Berkeley db.h)
4009   for header in "db/db.h" "db.h"; do
4010     AC_TRY_COMPILE([
4011 #include <stdlib.h>
4012 #if !(defined __GLIBC__ && __GLIBC_MINOR__ >= 1)
4013 #ifdef HAVE_INTTYPES_H
4014 #define __BIT_TYPES_DEFINED__
4015 #include <inttypes.h>
4016 typedef uint8_t  u_int8_t;
4017 typedef uint16_t u_int16_t;
4018 typedef uint32_t u_int32_t;
4019 #ifdef WE_DONT_NEED_QUADS
4020 typedef uint64_t u_int64_t;
4021 #endif
4022 #endif
4023 #endif
4024 #include <$header>
4025 ],[], db_h_file="$header"; break)
4026   done
4027   if test -z "$db_h_file"
4028   then AC_MSG_RESULT(no); with_database_berkdb=no
4029   else AC_MSG_RESULT($db_h_file)
4030   fi
4031
4032   if test "$with_database_berkdb" != "no"; then
4033     AC_MSG_CHECKING(for Berkeley DB version)
4034     AC_EGREP_CPP(yes,
4035 [#include <$db_h_file>
4036 #if DB_VERSION_MAJOR > 1
4037 yes
4038 #endif
4039 ], [AC_MSG_RESULT(2); dbfunc=db_open], [AC_MSG_RESULT(1); dbfunc=dbopen])
4040     AC_CHECK_FUNC($dbfunc,     with_database_berkdb=yes need_libdb=no, [
4041     AC_CHECK_LIB(db, $dbfunc,  with_database_berkdb=yes need_libdb=yes)])
4042   fi
4043
4044   if test "$with_database_berkdb" = "yes"; then
4045     AC_DEFINE_UNQUOTED(DB_H_FILE, "$db_h_file")
4046     AC_DEFINE(HAVE_BERKELEY_DB)
4047     test "$need_libdb" = "yes" && XE_PREPEND(-ldb, LIBS)
4048   else with_database_berkdb=no
4049   fi
4050 fi
4051
4052 if test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4053      != "no no no"; then
4054   AC_DEFINE(HAVE_DATABASE)
4055   XE_ADD_OBJS(database.o)
4056 fi
4057
4058 dnl Socks support
4059 if test "$with_socks" = "yes"; then
4060   AC_CHECK_LIB(socks, SOCKSinit)
4061   test -n "$ac_cv_lib_socks_SOCKSinit" && AC_DEFINE(HAVE_SOCKS)
4062 fi
4063
4064 dnl Usage tracking (undocumented and likely unused option)
4065 if test "$usage_tracking" = "yes"; then
4066   AC_DEFINE(USAGE_TRACKING)
4067   XE_PREPEND(-Bstatic -lut -Bdynamic, LIBS)
4068 fi
4069
4070 dnl autodetect dll support
4071 if test "$with_modules" != "no"; then
4072   AC_CHECKING(for module support)
4073
4074   dnl Check for MS-Windows
4075   if test "$with_msw" = "yes"; then
4076     have_dl=yes;
4077   else
4078     dnl Find headers and libraries
4079     AC_CHECK_HEADER(dlfcn.h, [
4080       AC_CHECK_LIB(dl, dlopen, [ have_dl=yes libdl=dl], [
4081       AC_CHECK_LIB(c,  dlopen, [ have_dl=yes ])])])
4082     if test -n "$have_dl"; then
4083       AC_DEFINE(HAVE_DLOPEN)
4084     else
4085       AC_CHECK_LIB(dld, shl_load, [
4086         libdl=dld have_dl=yes;
4087         AC_DEFINE(HAVE_SHL_LOAD)], [
4088         AC_CHECK_LIB(dld, dld_init, [
4089         libdl=dld have_dl=yes;
4090         AC_DEFINE(HAVE_DLD_INIT)])])
4091     fi
4092   fi dnl end !MS-Windows
4093
4094   if test -n "$have_dl"; then
4095     dnl XE_SHLIB_STUFF (in aclocal.m4) defines $can_build_shared
4096     XE_SHLIB_STUFF
4097   fi
4098
4099   if test "$can_build_shared" = "yes"; then
4100     AC_DEFINE(HAVE_SHLIB)
4101     XE_ADD_OBJS(sysdll.o emodules.o)
4102     XE_APPEND(src, INSTALL_ARCH_DEP_SUBDIR)
4103     test -n "$libdl" && XE_PREPEND(-l${libdl}, LIBS)
4104     AC_CHECK_FUNCS(dlerror _dlerror)
4105     with_modules=yes
4106   else
4107     if test "$with_modules" = "yes"; then
4108       XE_DIE("Required module support cannot be provided.")
4109     else
4110       AC_MSG_WARN("Module support cannot be provided.")
4111     fi
4112     with_modules=no
4113   fi
4114 fi
4115
4116 dnl Unfortunately, just because we can link doesn't mean we can run.
4117 dnl One of the above link tests may have succeeded but caused resulting
4118 dnl executables to fail to run.  Also any tests using AC_TRY_RUN will
4119 dnl have reported incorrect results.
4120 AC_TRY_RUN([int main(int c,char *v[]){return 0;}],[:],[
4121   echo ""
4122   echo "*** PANIC *** The C compiler can no longer build working executables."
4123   echo "*** PANIC *** Please examine the tail of config.log for runtime errors."
4124   echo "*** PANIC *** The most likely reason for this problem is that configure"
4125   echo "*** PANIC *** links with shared libraries, but those libraries cannot be"
4126   echo "*** PANIC *** found at run time."
4127   echo "*** PANIC ***"
4128   echo "*** PANIC *** On a Linux system, edit /etc/ld.so.conf and re-run ldconfig."
4129   echo "*** PANIC *** On other systems, try telling configure where to find the"
4130   echo "*** PANIC *** shared libraries using the --site-runtime-libraries option"
4131   echo "*** PANIC ***"
4132   echo "*** PANIC *** Another way to shoot yourself in the foot is to specify"
4133   echo "*** PANIC *** --with-FEATURE when FEATURE is not actually installed"
4134   echo "*** PANIC *** on your system.  Don't do that."
4135   exit 1])
4136
4137 dnl Process support
4138 if test "$win32_processes" = "yes"; then
4139   XE_ADD_OBJS(process-nt.o)
4140 else
4141   AC_DEFINE(HAVE_UNIX_PROCESSES)
4142   XE_ADD_OBJS(process-unix.o)
4143 fi
4144
4145 dnl --------------------------------
4146 dnl Compute SUBST-itutable variables
4147 dnl --------------------------------
4148
4149 dnl We ignore (C|LD)_SWITCH_X_(MACHINE|SYSTEM)
4150 dnl Use XE_SPACE instead of plain assignment statements to remove extraneous blanks
4151 XE_SPACE(CFLAGS, $CFLAGS)
4152 XE_SPACE(extra_objs, $extra_objs)
4153 XE_SPACE(c_switch_general, -DHAVE_CONFIG_H $c_switch_site $c_switch_machine $c_switch_system)
4154 XE_SPACE(c_switch_window_system, $c_switch_x_site $X_CFLAGS)
4155 XE_SPACE(c_switch_all, $c_switch_general $c_switch_window_system)
4156 XE_SPACE(ld_switch_general, $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_run)
4157 XE_SPACE(ld_switch_window_system, $ld_switch_x_site)
4158 XE_SPACE(ld_switch_all, $ld_switch_general $ld_switch_window_system)
4159 XE_SPACE(ld_libs_general, $LIBS $libs_machine $libs_system $libs_standard)
4160 XE_SPACE(ld_libs_window_system, $X_EXTRA_LIBS $libs_x $X_PRE_LIBS)
4161 XE_SPACE(ld_libs_all, $ld_libs_window_system $ld_libs_general)
4162
4163 dnl Compute lists of Makefiles and subdirs
4164 AC_SUBST(SRC_SUBDIR_DEPS)
4165 XE_APPEND(src, MAKE_SUBDIR)
4166 internal_makefile_list="Makefile.in"
4167 SUBDIR_MAKEFILES=''
4168 test -d lock || mkdir lock
4169 for dir in $MAKE_SUBDIR; do
4170   case "$dir" in */* ) dnl Implement mkdir -p
4171     ( for d in `echo $dir | sed 's:/: :g'` ; do
4172         test -d "$d" || mkdir "$d"; cd "$d"
4173       done ) ;;
4174    * ) test -d "$dir" || mkdir "$dir" ;;
4175   esac
4176   XE_SPACE(SUBDIR_MAKEFILES, $SUBDIR_MAKEFILES $dir/Makefile $dir/GNUmakefile)
4177   XE_SPACE(internal_makefile_list, $internal_makefile_list $dir/Makefile.in)
4178 done
4179 AC_SUBST(INSTALL_ARCH_DEP_SUBDIR)
4180 AC_SUBST(MAKE_SUBDIR)
4181 AC_SUBST(SUBDIR_MAKEFILES)
4182
4183 dnl Make s&m symlinks in the src directory, for config.h
4184 for dir in src/s src/m; do
4185   if test ! -d "$dir" ; then
4186     echo Making symbolic link to "$srcdir/$dir"
4187     ${LN_S} "$srcdir/$dir" "$dir"
4188   fi
4189 done
4190
4191 if test "$extra_verbose" = "yes"; then
4192   echo ""
4193   PRINT_VAR(extra_objs
4194    c_switch_general  c_switch_window_system  c_switch_all
4195   ld_switch_general ld_switch_window_system ld_switch_all
4196     ld_libs_general   ld_libs_window_system   ld_libs_all)
4197   echo ""
4198 fi
4199
4200 dnl ----------------------------------------------
4201 dnl Create some auxiliary files for developers.
4202 dnl ----------------------------------------------
4203
4204 dnl Create a .gdbinit useful for debugging XEmacs
4205 if test -f "$srcdir/src/.gdbinit" -a ! -f "src/.gdbinit"; then
4206   test "$extra_verbose" = "yes" && echo "creating src/.gdbinit"
4207   echo "source $srcdir/src/.gdbinit" > "src/.gdbinit"
4208 fi
4209
4210 dnl Create a .dbxrc useful for debugging XEmacs
4211 if test -f "$srcdir/src/.dbxrc" -a ! -f "src/.dbxrc"; then
4212   test "$extra_verbose" = "yes" && echo "creating src/.dbxrc"
4213   echo ". $srcdir/src/.dbxrc" > "src/.dbxrc"
4214 fi
4215
4216 dnl Create a useful TAGS file
4217 if test -f "$srcdir/TAGS" -a ! -f "TAGS"; then
4218   test "$extra_verbose" = "yes" && echo "creating TAGS"
4219   echo "\f
4220 $srcdir/TAGS,include" > "TAGS"
4221 fi
4222
4223 dnl Create top level .sbinit for Sun compilers
4224 if test "$__SUNPRO_C" = "yes"; then
4225   test "$extra_verbose" = "yes" && echo "creating .sbinit"
4226   ( echo "# For use with Sun WorkShop's Source browser."
4227     echo "# See sbquery(1) and sbinit(4) for more information"
4228     for dir in $MAKE_SUBDIR; do echo "import $dir"; done
4229   ) > .sbinit
4230 fi
4231
4232 dnl There are no more compile tests; remove the core they created.
4233 rm -f core
4234
4235 dnl ----------------------------------------------
4236 dnl Substitute into Makefile, config.h and paths.h
4237 dnl ----------------------------------------------
4238
4239 dnl what sort of things to edit into Makefile, config.h and paths.h
4240 dnl configuration here uncanonicalized to avoid exceeding size limits.
4241
4242 AC_SUBST(PROGNAME)
4243 AC_SUBST(version)
4244 AC_SUBST(configuration)
4245 AC_SUBST(canonical)
4246 AC_SUBST(inststaticdir)
4247 AC_SUBST(instvardir)
4248 AC_SUBST(srcdir)
4249 AC_SUBST(bindir)
4250 AC_SUBST(datadir)
4251 AC_SUBST(pkgdir)
4252 AC_SUBST(statedir)
4253 AC_SUBST(libdir)
4254 AC_SUBST(mandir)
4255
4256 AC_SUBST(prefix)
4257 AC_SUBST(PREFIX_USER_DEFINED)
4258 dnl Yo, Stephen Bourne!  I want to marry you!
4259 PREFIX=$prefix
4260 while true; do
4261   case "$PREFIX" in
4262     *\$* ) eval "PREFIX=$PREFIX" ;;
4263     *) break ;;
4264   esac
4265 done
4266 AC_SUBST(PREFIX)
4267
4268 AC_SUBST(exec_prefix)
4269 AC_SUBST(EXEC_PREFIX_USER_DEFINED)
4270 EXEC_PREFIX=$exec_prefix
4271 while true; do
4272   case "$EXEC_PREFIX" in
4273     *\$* ) eval "EXEC_PREFIX=$EXEC_PREFIX" ;;
4274     *) break ;;
4275   esac
4276 done
4277 AC_SUBST(EXEC_PREFIX)
4278
4279 AC_SUBST(infodir)
4280 AC_SUBST(INFODIR_USER_DEFINED)
4281 INFODIR=$infodir
4282 while true; do
4283   case "$INFODIR" in
4284     *\$* ) eval "INFODIR=$INFODIR" ;;
4285     *) break ;;
4286   esac
4287 done
4288 AC_SUBST(INFODIR)
4289
4290 AC_SUBST(infopath)
4291 AC_SUBST(INFOPATH_USER_DEFINED)
4292 INFOPATH=$infopath
4293 while true; do
4294   case "$INFOPATH" in
4295     *\$* ) eval "INFOPATH=$INFOPATH" ;;
4296     *) break ;;
4297   esac
4298 done
4299 AC_SUBST(INFOPATH)
4300
4301 AC_SUBST(package_path)
4302 AC_SUBST(PACKAGE_PATH_USER_DEFINED)
4303 PACKAGE_PATH=$package_path
4304 while true; do
4305   case "$PACKAGE_PATH" in
4306     *\$* ) eval "PACKAGE_PATH=$PACKAGE_PATH" ;;
4307     *) break ;;
4308   esac
4309 done
4310 AC_SUBST(PACKAGE_PATH)
4311
4312 AC_SUBST(lispdir)
4313 AC_SUBST(LISPDIR_USER_DEFINED)
4314 LISPDIR=$lispdir
4315 while true; do
4316   case "$LISPDIR" in
4317     *\$* ) eval "LISPDIR=$LISPDIR" ;;
4318     *) break ;;
4319   esac
4320 done
4321 AC_SUBST(LISPDIR)
4322
4323 AC_SUBST(moduledir)
4324 AC_SUBST(MODULEDIR_USER_DEFINED)
4325 MODULEDIR=$moduledir
4326 while true; do
4327   case "$MODULEDIR" in
4328     *\$* ) eval "MODULEDIR=$MODULEDIR" ;;
4329     *) break ;;
4330   esac
4331 done
4332 AC_SUBST(MODULEDIR)
4333
4334 AC_SUBST(sitelispdir)
4335 AC_SUBST(SITELISPDIR_USER_DEFINED)
4336 SITELISPDIR=$sitelispdir
4337 while true; do
4338   case "$SITELISPDIR" in
4339     *\$* ) eval "SITELISPDIR=$SITELISPDIR" ;;
4340     *) break ;;
4341   esac
4342 done
4343 AC_SUBST(SITELISPDIR)
4344
4345 AC_SUBST(sitemoduledir)
4346 AC_SUBST(SITEMODULEDIR_USER_DEFINED)
4347 SITEMODULEDIR=$sitemoduledir
4348 while true; do
4349   case "$SITEMODULEDIR" in
4350     *\$* ) eval "SITEMODULEDIR=$SITEMODULEDIR" ;;
4351     *) break ;;
4352   esac
4353 done
4354 AC_SUBST(SITEMODULEDIR)
4355
4356 AC_SUBST(etcdir)
4357 AC_SUBST(ETCDIR_USER_DEFINED)
4358 ETCDIR=$etcdir
4359 while true; do
4360   case "$ETCDIR" in
4361     *\$* ) eval "ETCDIR=$ETCDIR" ;;
4362     *) break ;;
4363   esac
4364 done
4365 AC_SUBST(ETCDIR)
4366
4367 AC_SUBST(docdir)
4368 AC_SUBST(DOCDIR_USER_DEFINED)
4369 DOCDIR=$docdir
4370 while true; do
4371   case "$DOCDIR" in
4372     *\$* ) eval "DOCDIR=$DOCDIR" ;;
4373     *) break ;;
4374   esac
4375 done
4376 AC_SUBST(DOCDIR)
4377
4378 AC_SUBST(archlibdir)
4379 AC_SUBST(ARCHLIBDIR_USER_DEFINED)
4380 ARCHLIBDIR=$archlibdir
4381 while true; do
4382   case "$ARCHLIBDIR" in
4383     *\$* ) eval "ARCHLIBDIR=$ARCHLIBDIR" ;;
4384     *) break ;;
4385   esac
4386 done
4387 AC_SUBST(ARCHLIBDIR)
4388
4389 AC_SUBST(docdir)
4390 AC_SUBST(bitmapdir)
4391 AC_SUBST(extra_objs)
4392
4393 dnl The following flags combine all the information from:
4394 dnl - command line options (user always gets priority)
4395 dnl - user environment variables
4396 dnl - determined by configure
4397 dnl - the s&m header files (required for ellcc)
4398 AC_SUBST(machfile)
4399 AC_SUBST(opsysfile)
4400 AC_SUBST(c_switch_general)
4401 AC_SUBST(c_switch_window_system)
4402 AC_SUBST(c_switch_all)
4403 AC_SUBST(ld_switch_general)
4404 AC_SUBST(ld_switch_window_system)
4405 AC_SUBST(ld_switch_all)
4406 AC_SUBST(ld_libs_general)
4407 AC_SUBST(ld_libs_window_system)
4408 AC_SUBST(ld_libs_all)
4409 AC_SUBST(CFLAGS)
4410 AC_SUBST(CPPFLAGS)
4411 AC_SUBST(LDFLAGS)
4412 RECURSIVE_MAKE="\$(MAKE) \$(MFLAGS) CC='\$(CC)' CFLAGS='\$(CFLAGS)' LDFLAGS='\$(LDFLAGS)' CPPFLAGS='\$(CPPFLAGS)'"
4413 AC_SUBST(RECURSIVE_MAKE)
4414
4415 AC_SUBST(native_sound_lib)
4416 AC_SUBST(sound_cflags)
4417 AC_SUBST(RANLIB)
4418 AC_SUBST(dynodump_arch)
4419
4420 dnl Preliminary support for using a different compiler for xemacs itself.
4421 dnl Useful for building XEmacs with a C++ or 64-bit compiler.
4422 : ${XEMACS_CC:=$CC}
4423 AC_SUBST(XEMACS_CC)
4424
4425 dnl The default is yes
4426 if test "$with_prefix" = "yes"; then
4427   AC_DEFINE(PREFIX_USER_DEFINED)
4428 fi
4429
4430 dnl The default is no
4431 if test "$with_site_lisp" = "no"; then
4432   AC_DEFINE(INHIBIT_SITE_LISP)
4433 fi
4434 dnl The default is yes
4435 if test "$with_site_modules" = "no"; then
4436   AC_DEFINE(INHIBIT_SITE_MODULES)
4437 fi
4438
4439 XE_SPACE(ac_configure_args, $ac_configure_args)
4440 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "$configuration")
4441 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "$ac_configure_args")
4442 AC_DEFINE_UNQUOTED(config_machfile,  "$machfile")
4443 AC_DEFINE_UNQUOTED(config_opsysfile, "$opsysfile")
4444
4445 dnl Following are deprecated
4446
4447 null_string=""
4448 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE,     $null_string)
4449 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, $null_string)
4450 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,      $null_string)
4451 AC_DEFINE_UNQUOTED(LD_SWITCH_SITE,       $null_string)
4452 AC_DEFINE_UNQUOTED(C_SWITCH_SITE,        $null_string)
4453
4454 dnl Note: as a general rule, *only* define things here that are not
4455 dnl autodetected.  For things that are autodetected, define them
4456 dnl at the point where the autodetection occurs or would occur,
4457 dnl so that the user gets immediate feedback on the results of the
4458 dnl autodetection.
4459
4460 if   test "$GNU_MALLOC"         = "yes"; then AC_DEFINE(GNU_MALLOC)
4461 elif test "$with_system_malloc" = "yes"; then AC_DEFINE(USE_SYSTEM_MALLOC)
4462 elif test "$with_debug_malloc"  = "yes"; then AC_DEFINE(USE_DEBUG_MALLOC)
4463                                               AC_DEFINE(USE_SYSTEM_MALLOC)
4464 fi
4465 test "$with_i18n3"         = "yes" && AC_DEFINE(I18N3)
4466 test "$GCC"                = "yes" && AC_DEFINE(USE_GCC)
4467 test "$external_widget"    = "yes" && AC_DEFINE(EXTERNAL_WIDGET)
4468 test "$quick_build"        = "yes" && AC_DEFINE(QUICK_BUILD)
4469 test "$with_purify"        = "yes" && AC_DEFINE(PURIFY)
4470 test "$with_quantify"      = "yes" && AC_DEFINE(QUANTIFY)
4471 test "$with_pop"           = "yes" && AC_DEFINE(MAIL_USE_POP)
4472 test "$with_kerberos"      = "yes" && AC_DEFINE(KERBEROS)
4473 test "$with_hesiod"        = "yes" && AC_DEFINE(HESIOD)
4474 test "$use_union_type"     = "yes" && AC_DEFINE(USE_UNION_TYPE)
4475 test "$pdump"              = "yes" && AC_DEFINE(PDUMP)
4476
4477 dnl -------------------------------
4478 dnl Report on what we decided to do
4479 dnl -------------------------------
4480
4481 (
4482 dnl /etc/osversion is on SONY NEWS-OS
4483 if test -f /etc/osversion; then dnl SONY NEWS-OS
4484   echo "osversion: `cat /etc/osversion`"
4485 else
4486   echo "uname -a: `uname -a`"
4487 fi
4488 echo ""
4489 echo "$0 $quoted_arguments"
4490 ) > Installation
4491
4492 if test ! -z ${emacs_beta_version} ; then
4493   if test -z "${emacs_is_beta}" ; then
4494         xemacs_betaname=".${emacs_beta_version}"
4495   else
4496         xemacs_betaname="-b${emacs_beta_version}"
4497   fi
4498 else
4499   xemacs_betaname=""
4500 fi
4501
4502 dnl Start stdout redirection to '| tee -a Installation'
4503 (
4504 echo "
4505
4506 XEmacs ${emacs_major_version}.${emacs_minor_version}${xemacs_betaname} \"$xemacs_codename\" configured for \`$canonical'.
4507 "
4508 echo "
4509 Compilation / Installation:"
4510 echo "  Source code location:              $srcdir"
4511 echo "  Installation prefix:               $prefix"
4512 if test -n "$site_includes"; then
4513   echo "  Additional header files:           $site_includes"
4514 fi
4515 if test -n "$site_libraries"; then
4516   echo "  Additional libraries:              $site_libraries"
4517 fi
4518 if test -n "$site_prefixes"; then
4519   echo "  Additional prefixes:               $site_prefixes"
4520 fi
4521 if test -n "$runpath"; then
4522   echo "  Runtime library search path:       $runpath"
4523 fi
4524 echo "  Operating system description file: \`$opsysfile'"
4525 echo "  Machine description file:          \`$machfile'"
4526 echo "  Compiler:                          $CC $CFLAGS"
4527 echo "  Relocating allocator for buffers:  $rel_alloc"
4528 echo "  GNU version of malloc:             ${GNU_MALLOC}${GNU_MALLOC_reason}"
4529
4530 echo "
4531 Window System:"
4532 if test "$with_msw" = "yes"; then
4533   echo "  Compiling in support for the Microsoft window system."
4534 fi
4535 if test "$with_x11" = "yes"; then
4536   echo "  Compiling in support for the X window system:"
4537   echo "    - X Windows headers location:                 $x_includes"
4538   echo "    - X Windows libraries location:               $x_libraries"
4539   if test "$with_xauth" != yes; then
4540     echo "    - Xau (X authority) not available."
4541   fi
4542   if test "$with_xmu" != yes; then
4543     echo "    - Xmu library not available; substituting equivalent routines."
4544   fi
4545   if test "$with_wmcommand" != no; then
4546     echo "    - Handling WM_COMMAND properly."
4547   fi
4548 fi
4549 if test "$need_athena" = "yes"; then
4550   echo "  Compiling in support for the Athena widget set:"
4551   echo "    - Athena headers location:                    $athena_h_path"
4552   echo "    - Athena library to link:                     $athena_lib"
4553 fi
4554 case "$with_menubars" in
4555   lucid ) echo "  Using Lucid menubars." ;;
4556   motif ) echo "  Using Motif menubars."
4557           echo "  *WARNING*  The Motif menubar implementation is currently buggy."
4558           echo "             We recommend using the Lucid menubar instead."
4559           echo "             Re-run configure with --with-menubars='lucid'." ;;
4560     msw ) echo "  Using MS-Windows menubars." ;;
4561 esac
4562 case "$with_scrollbars" in
4563   lucid  ) echo "  Using Lucid scrollbars."      ;;
4564   motif  ) echo "  Using Motif scrollbars."      ;;
4565   athena ) echo "  Using Athena scrollbars."     ;;
4566      msw ) echo "  Using MS-Windows scrollbars." ;;
4567 esac
4568 case "$with_dialogs" in
4569   motif  ) echo "  Using Motif dialog boxes."
4570            if test "$unexec" = "unexaix.o"; then if test "`uname -v`" = 4 -a "`uname -r`" -ge 3; then
4571              echo "  *WARNING*  The Motif dialog boxes cause problems on AIX 4.3 and higher."
4572              echo "             We recommend using the Athena dialog boxes instead."
4573              echo "             Install libXaw and re-run configure with --with-dialogs='athena'."
4574              echo "             Read the PROBLEMS file for more information."
4575            fi; fi ;;
4576   athena ) echo "  Using Athena dialog boxes."     ;;
4577      msw ) echo "  Using MS-Windows dialog boxes." ;;
4578 esac
4579 case "$with_widgets" in
4580   motif  ) echo "  Using Motif native widgets."      ;;
4581   athena ) echo "  Using Athena native widgets."     ;;
4582      msw ) echo "  Using MS-Windows native widgets." ;;
4583 esac
4584 if test "$with_dragndrop" = yes; then
4585   echo "  Compiling in support for Drag'n'Drop (EXPERIMENTAL)."
4586   echo "    -  Drag'n'Drop prototype:                             $dragndrop_proto."
4587 fi
4588
4589 echo "
4590 TTY:"
4591 test "$with_ncurses" = yes && echo "  Compiling in support for ncurses."
4592 test "$with_gpm" = yes && echo "  Compiling in support for GPM (General Purpose Mouse)."
4593
4594 echo "
4595 Images:"
4596 test "$with_gif" = yes && echo "  Compiling in support for GIF  images (builtin)."
4597 if test "$with_xpm" = yes; then
4598   echo "  Compiling in support for XPM  images."
4599 elif test "$with_x11" = yes; then
4600   echo "  WARNING: -----------------------------------------------------------"
4601   echo "  WARNING: Compiling without XPM image support."
4602   if test "$xpm_problem" != ""; then
4603     echo "  Reason: $xpm_problem"
4604   fi
4605   echo "  WARNING: You should strongly consider installing XPM."
4606   echo "  WARNING: Otherwise toolbars and other graphics will look suboptimal."
4607   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4608   echo "  WARNING: -----------------------------------------------------------"
4609 fi
4610 if test "$with_png" = yes; then
4611   echo "  Compiling in support for PNG  images."
4612 elif test "$window_system" != "none"; then
4613   echo "  WARNING: -----------------------------------------------------------"
4614   echo "  WARNING: Compiling without PNG image support."
4615   if test "$png_problem" != ""; then
4616     echo "  Reason: $png_problem"
4617   fi
4618   echo "  WARNING: You should strongly consider installing the PNG libraries."
4619   echo "  WARNING: Otherwise certain images and glyphs may not display."
4620   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4621   echo "  WARNING: -----------------------------------------------------------"
4622 fi
4623 test "$with_jpeg" = yes && echo "  Compiling in support for JPEG images."
4624 test "$with_tiff" = yes && echo "  Compiling in support for TIFF images."
4625 test "$with_xface" = yes && echo "  Compiling in support for X-Face message headers."
4626
4627 echo "
4628 Sound:"
4629 test "$with_native_sound" = yes && echo "  Compiling in support for sound (native)."
4630 test "$with_nas_sound" = yes && echo "  Compiling in support for NAS (network audio system)."
4631 test "$old_nas" = yes && echo "    - NAS library lacks error trapping; will play synchronously."
4632 test "$with_esd_sound" = yes && echo "  Compiling in support for ESD (Enlightened Sound Daemon)."
4633
4634 echo "
4635 Databases:"
4636 test "$with_database_berkdb" = yes && echo "  Compiling in support for Berkeley database."
4637 test "$with_database_dbm"    = yes && echo "  Compiling in support for DBM."
4638 test "$with_database_gdbm"   = yes && echo "  Compiling in support for GNU DBM."
4639 test "$with_ldap" = yes && echo "  Compiling in support for LDAP."
4640 if test "$with_postgresql" = yes; then
4641   echo "  Compiling in support for PostgreSQL."
4642   echo "    - Using PostgreSQL header file:  $libpq_fe_h_file"
4643   test "$with_postgresqlv7" = yes && echo "    - Using PostgreSQL V7 bindings."
4644 fi
4645
4646 echo "
4647 Internationalization:"
4648 test "$with_mule" = yes && echo "  Compiling in support for Mule (multi-lingual Emacs)."
4649 test "$with_utf_2000" = yes && echo "  Using UTF-2000 (UTF-8) buffer/string representation."
4650 test "$with_text_coding" = yes && echo "  Compiling in support for text coding."
4651 test "$with_file_coding" = yes && echo "  Compiling in support for file coding."
4652 test "$with_xim" != no && echo "  Compiling in support for XIM (X11R5+ I18N input method)."
4653 test "$with_xim" = motif && echo "    - Using Motif to provide XIM support."
4654 test "$with_xim" = xlib && echo "    - Using raw Xlib to provide XIM support."
4655 test "$with_xfs" = yes && echo "    - Using XFontSet to provide bilingual menubar."
4656 test "$with_canna" = yes && echo "  Compiling in support for Canna on Mule."
4657 if test "$with_wnn" = yes; then
4658   echo "  Compiling in support for the WNN input method on Mule."
4659   test "$with_wnn6" = yes && echo "    - Using WNN version 6."
4660 fi
4661 test "$with_i18n3" = yes && echo "  Compiling in support for I18N level 3 (doesn't currently work)."
4662
4663 echo "
4664 Mail:"
4665 test "$with_pop" = yes && echo "  Compiling in support for POP mail retrieval."
4666 test "$with_kerberos" = yes && echo "  Compiling in support for Kerberos POP authentication."
4667 test "$with_hesiod" = yes && echo "  Compiling in support for Hesiod POP server access."
4668 test -n "$mail_locking" && echo "  Compiling in support for \"$mail_locking\" mail spool file locking method."
4669
4670 echo "
4671 Other Features:"
4672 test "$with_tooltalk" = yes && echo "  Compiling in support for ToolTalk."
4673 test "$with_workshop" = yes && echo "  Compiling in support for Sun WorkShop."
4674 test "$with_socks" = yes && echo "  Compiling in support for SOCKS."
4675 test "$with_dnet" = yes && echo "  Compiling in support for DNET."
4676 test "$with_modules" = "yes" && echo "  Compiling in support for dynamic shared object modules."
4677 test "$use_union_type" = yes && echo "  Using the union type for Lisp_Objects."
4678 test "$pdump" = yes && echo "  Using the new portable dumper."
4679 test "$debug" = yes && echo "  Compiling in support for extra debugging code."
4680 test "$usage_tracking" = yes && echo "  Compiling in support for active usage tracking (Sun internal)."
4681 if test "$error_check_extents $error_check_typecheck $error_check_bufpos $error_check_gc $error_check_malloc $error_check_glyphs" \
4682   != "no no no no no no"; then
4683   echo "  WARNING: ---------------------------------------------------------"
4684   echo "  WARNING: Compiling in support for runtime error checking."
4685   echo "  WARNING: XEmacs will run noticeably more slowly as a result."
4686   echo "  WARNING: Error checking is on by default for XEmacs beta releases."
4687   echo "  WARNING: ---------------------------------------------------------"
4688 fi
4689 echo ""
4690 ) | tee -a Installation
4691 dnl echo "The above configure report is appended to \"Installation\" file."
4692 echo ""
4693
4694 dnl -----------------------------------
4695 dnl Now generate config.h and Makefiles
4696 dnl -----------------------------------
4697 dnl This has to be called in order for this variable to get into config.status
4698 AC_SUBST(internal_makefile_list)
4699 # Remove any trailing slashes in these variables.
4700 test -n "$prefix" &&
4701   prefix=`echo '' "$prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4702 test -n "$exec_prefix" &&
4703   exec_prefix=`echo '' "$exec_prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4704
4705 dnl Build Makefile.in's from Makefile.in.in's
4706 dnl except ./Makefile from $srcdir/Makefile.in
4707
4708 for file in $internal_makefile_list; do
4709   test "$file" = src/Makefile.in && \
4710     file="src/Makefile.in:src/Makefile.in.in:src/depend"
4711   XE_APPEND($file, ac_output_files)
4712 done
4713 ac_output_files="$ac_output_files src/paths.h lib-src/config.values"
4714 test "$with_modules" = "yes" && XE_APPEND(lib-src/ellcc.h, ac_output_files)
4715
4716 AC_OUTPUT($ac_output_files,
4717 [for dir in . $MAKE_SUBDIR; do
4718   (
4719     cd $dir
4720     rm -f junk.c
4721     < Makefile.in \
4722       sed -e '/^# Generated/d' \
4723           -e 's%/\*\*/#.*%%' \
4724           -e 's/^ *# */#/' \
4725 dnl Delete Makefile.in.in comment lines
4726           -e '/^##/d' \
4727 dnl Pass through CPP directives unchanged
4728           -e '/^#/ {
4729 p
4730 d
4731 }'        \
4732 dnl Quote other lines to protect from CPP substitution
4733           -e '/./ {
4734 s/\([[\"]]\)/\\\1/g
4735 s/^/"/
4736 s/$/"/
4737 }'  > junk.c;
4738
4739 dnl Create a GNUmakefile and Makefile from Makefile.in.
4740
4741 changequote(<<,>>)dnl
4742 dnl CPP_MAKEFILE(CPPFLAGS,filename)
4743 define(<<CPP_MAKEFILE>>,
4744 echo creating $dir/<<$2>>
4745 $CPP -I. -I${top_srcdir}/src <<$1>> junk.c \
4746 dnl Delete line directives inserted by $CPP
4747   | sed -e 's/^\#.*//'          \
4748 dnl Delete spurious blanks inserted by $CPP
4749         -e 's/^[ TAB][ TAB]*$//'\
4750         -e 's/^ /TAB/'          \
4751 dnl Delete blank lines
4752   | sed -n -e '/^..*$/p'        \
4753 dnl Restore lines quoted above to original contents.
4754   | sed '/^\"/ {
4755         s/\\\([\"]\)/\1/g
4756         s/^[ TAB]*\"//
4757         s/\"[ TAB]*$//
4758 }' > Makefile.new
4759     chmod 444 Makefile.new
4760     mv -f Makefile.new <<$2>>
4761 )dnl CPP_MAKEFILE
4762
4763     CPP_MAKEFILE(,Makefile)
4764     CPP_MAKEFILE(-DUSE_GNU_MAKE,GNUmakefile)
4765 changequote([,])dnl
4766     rm -f junk.c
4767   )
4768 done
4769
4770 dnl Append AC_DEFINE information to lib-src/config.values
4771 dnl (AC_SUBST information is already there (see config.values.sh).
4772 sed < config.status >> lib-src/config.values \
4773   -e '/{ac_dA}.*{ac_dB}.*{ac_dC}.*{ac_dD}$/!d' \
4774   -e 's/\${ac_dA}\(.*\)\${ac_dB}.*\${ac_dC}\(.*\)\${ac_dD}/\1 \2/' \
4775   -e 's/^\([[^ ]]*\) $/\1 ""/' \
4776   -e 's/ 1$/ t/'
4777
4778 ],
4779 [CPP="$CPP"
4780  top_srcdir="$srcdir"
4781  MAKE_SUBDIR="$MAKE_SUBDIR"
4782 ])dnl