elmo/elmo-cache.el

   1 ;;; elmo-cache.el --- Cache modules for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 2000 Kenichi OKADA <okada@opaopa.org>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Kenichi OKADA <okada@opaopa.org>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33 (require 'elmo-vars)
  34 (require 'elmo-util)
  35 (require 'elmo)
  36 (require 'elmo-map)
  37
  38 (eval-and-compile
  39   (luna-define-class elmo-cache-folder (elmo-map-folder) (dir-name directory))
  40   (luna-define-internal-accessors 'elmo-cache-folder))
  41
  42 (luna-define-method elmo-folder-initialize ((folder elmo-cache-folder)
  43                                             name)
  44   (when (string-match "\\([^/]*\\)/?\\(.*\\)$" name)
  45     (elmo-cache-folder-set-dir-name-internal
  46      folder
  47      (elmo-match-string 2 name))
  48     (elmo-cache-folder-set-directory-internal
  49      folder
  50      (expand-file-name (elmo-match-string 2 name)
  51                        elmo-cache-directory))
  52     folder))
  53
  54 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-cache-folder))
  55   (expand-file-name (elmo-cache-folder-dir-name-internal folder)
  56                     (expand-file-name "internal/cache"
  57                                       elmo-msgdb-directory)))
  58
  59 (luna-define-method elmo-map-folder-list-message-locations
  60   ((folder elmo-cache-folder))
  61   (elmo-cache-folder-list-message-locations folder))
  62
  63 (defun elmo-cache-folder-list-message-locations (folder)
  64   (mapcar 'file-name-nondirectory
  65           (elmo-delete-if
  66            'file-directory-p
  67            (directory-files (elmo-cache-folder-directory-internal folder)
  68                             t "^[^@]+@[^@]+$" t))))
  69
  70 (luna-define-method elmo-folder-list-subfolders ((folder elmo-cache-folder)
  71                                                  &optional one-level)
  72   (delq nil (mapcar
  73              (lambda (f) (if (file-directory-p f)
  74                              (concat (elmo-folder-prefix-internal folder)
  75                                      "cache/"
  76                                      (file-name-nondirectory f))))
  77              (directory-files (elmo-cache-folder-directory-internal folder)
  78                               t "^[^.].*+"))))
  79
  80 (luna-define-method elmo-folder-message-file-p ((folder elmo-cache-folder))
  81   t)
  82
  83 (luna-define-method elmo-message-file-name ((folder elmo-cache-folder)
  84                                             number)
  85   (expand-file-name
  86    (elmo-map-message-location folder number)
  87    (elmo-cache-folder-directory-internal folder)))
  88
  89 (luna-define-method elmo-folder-msgdb-create ((folder elmo-cache-folder)
  90                                               numbers seen-list)
  91   (let ((i 0)
  92         (len (length numbers))
  93         overview number-alist mark-alist entity message-id
  94         num mark)
  95     (message "Creating msgdb...")
  96     (while numbers
  97       (setq entity
  98             (elmo-msgdb-create-overview-entity-from-file
  99              (car numbers) (elmo-message-file-name folder (car numbers))))
 100       (if (null entity)
 101           ()
 102         (setq num (elmo-msgdb-overview-entity-get-number entity))
 103         (setq overview
 104               (elmo-msgdb-append-element
 105                overview entity))
 106         (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 107         (setq number-alist
 108               (elmo-msgdb-number-add number-alist
 109                                      num
 110                                      message-id))
 111         (if (setq mark (or (elmo-msgdb-global-mark-get message-id)
 112                            (if (member message-id seen-list) nil
 113                              elmo-msgdb-new-mark)))
 114             (setq mark-alist
 115                   (elmo-msgdb-mark-append
 116                    mark-alist
 117                    num mark)))
 118         (when (> len elmo-display-progress-threshold)
 119           (setq i (1+ i))
 120           (elmo-display-progress
 121            'elmo-cache-folder-msgdb-create "Creating msgdb..."
 122            (/ (* i 100) len))))
 123       (setq numbers (cdr numbers)))
 124     (message "Creating msgdb...done")
 125     (list overview number-alist mark-alist)))
 126
 127 (luna-define-method elmo-folder-append-buffer ((folder elmo-cache-folder)
 128                                                unread
 129                                                &optional number)
 130   ;; dir-name is changed according to msgid.
 131   (unless (elmo-cache-folder-dir-name-internal folder)
 132     (let* ((file (elmo-file-cache-get-path (std11-field-body "message-id")))
 133            (dir (directory-file-name (file-name-directory file))))
 134       (unless (file-exists-p dir)
 135         (elmo-make-directory dir))
 136       (when (file-writable-p file)
 137         (write-region-as-binary
 138          (point-min) (point-max) file nil 'no-msg))))
 139   t)
 140
 141 (luna-define-method elmo-map-folder-delete-messages ((folder elmo-cache-folder)
 142                                                      locations)
 143   (dolist (location locations)
 144     (elmo-file-cache-delete
 145      (expand-file-name location
 146                        (elmo-cache-folder-directory-internal folder)))))
 147
 148 (luna-define-method elmo-message-fetch-with-cache-process
 149   ((folder elmo-cache-folder) number strategy &optional section unseen)
 150   ;; disbable cache process
 151   (elmo-message-fetch-internal folder number strategy section unseen))
 152
 153 (luna-define-method elmo-map-message-fetch ((folder elmo-cache-folder)
 154                                             location strategy
 155                                             &optional section unseen)
 156   (let ((file (expand-file-name
 157                location
 158                (elmo-cache-folder-directory-internal folder))))
 159     (when (file-exists-p file)
 160       (insert-file-contents-as-binary file))))
 161
 162 (luna-define-method elmo-folder-writable-p ((folder elmo-cache-folder))
 163   t)
 164
 165 (luna-define-method elmo-folder-exists-p ((folder elmo-cache-folder))
 166   t)
 167
 168 (luna-define-method elmo-message-file-p ((folder elmo-cache-folder) number)
 169   t)
 170
 171 (require 'product)
 172 (product-provide (provide 'elmo-cache) (require 'elmo-version))
 173
 174 ;;; elmo-cache.el ends here