elmo/elmo-cache.el

   1 ;;; elmo-cache.el --- Cache modules for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 2000 Kenichi OKADA <okada@opaopa.org>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Kenichi OKADA <okada@opaopa.org>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33 (require 'elmo-vars)
  34 (require 'elmo-util)
  35 (require 'elmo)
  36 (require 'elmo-map)
  37
  38 (eval-and-compile
  39   (luna-define-class elmo-cache-folder (elmo-map-folder elmo-file-tag)
  40                      (dir-name directory))
  41   (luna-define-internal-accessors 'elmo-cache-folder))
  42
  43 (luna-define-method elmo-folder-initialize ((folder elmo-cache-folder)
  44                                             name)
  45   (when (string-match "\\([^/]*\\)/?\\(.*\\)$" name)
  46     (elmo-cache-folder-set-dir-name-internal
  47      folder
  48      (elmo-match-string 2 name))
  49     (elmo-cache-folder-set-directory-internal
  50      folder
  51      (expand-file-name (elmo-match-string 2 name)
  52                        elmo-cache-directory))
  53     folder))
  54
  55 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-cache-folder))
  56   (expand-file-name (elmo-cache-folder-dir-name-internal folder)
  57                     (expand-file-name "internal/cache"
  58                                       elmo-msgdb-directory)))
  59
  60 (luna-define-method elmo-map-folder-list-message-locations
  61   ((folder elmo-cache-folder))
  62   (elmo-cache-folder-list-message-locations folder))
  63
  64 (defun elmo-cache-folder-list-message-locations (folder)
  65   (mapcar 'file-name-nondirectory
  66           (elmo-delete-if
  67            'file-directory-p
  68            (directory-files (elmo-cache-folder-directory-internal folder)
  69                             t "^[^@]+@[^@]+$" t))))
  70
  71 (luna-define-method elmo-folder-list-subfolders ((folder elmo-cache-folder)
  72                                                  &optional one-level)
  73   (delq nil (mapcar
  74              (lambda (f) (if (file-directory-p f)
  75                              (concat (elmo-folder-prefix-internal folder)
  76                                      "cache/"
  77                                      (file-name-nondirectory f))))
  78              (directory-files (elmo-cache-folder-directory-internal folder)
  79                               t "^[01][0-9A-F]$"))))
  80
  81 (luna-define-method elmo-folder-message-file-p ((folder elmo-cache-folder))
  82   t)
  83
  84 (luna-define-method elmo-message-file-name ((folder elmo-cache-folder)
  85                                             number)
  86   (expand-file-name
  87    (elmo-map-message-location folder number)
  88    (elmo-cache-folder-directory-internal folder)))
  89
  90 (luna-define-method elmo-folder-msgdb-create ((folder elmo-cache-folder)
  91                                               numbers flag-table)
  92   (let ((i 0)
  93         (len (length numbers))
  94         (new-msgdb (elmo-make-msgdb))
  95         entity message-id flags)
  96     (message "Creating msgdb...")
  97     (while numbers
  98       (setq entity
  99             (elmo-msgdb-create-message-entity-from-file
 100              (elmo-msgdb-message-entity-handler new-msgdb)
 101              (car numbers) (elmo-message-file-name folder (car numbers))))
 102       (when entity
 103         (setq message-id (elmo-message-entity-field entity 'message-id)
 104               flags (elmo-flag-table-get flag-table message-id))
 105         (elmo-global-flags-set flags folder (car numbers) message-id)
 106         (elmo-msgdb-append-entity new-msgdb entity flags))
 107       (when (> len elmo-display-progress-threshold)
 108         (setq i (1+ i))
 109         (elmo-display-progress
 110          'elmo-cache-folder-msgdb-create "Creating msgdb..."
 111          (/ (* i 100) len)))
 112       (setq numbers (cdr numbers)))
 113     (message "Creating msgdb...done")
 114     new-msgdb))
 115
 116 (luna-define-method elmo-folder-append-buffer ((folder elmo-cache-folder)
 117                                                &optional flags number)
 118   ;; dir-name is changed according to msgid.
 119   (unless (elmo-cache-folder-dir-name-internal folder)
 120     (let ((msgid (std11-field-body "message-id"))
 121           file dir)
 122       (when msgid
 123         (setq file (elmo-file-cache-get-path msgid))
 124         (setq dir (directory-file-name (file-name-directory file)))
 125         (unless (file-exists-p dir)
 126           (elmo-make-directory dir))
 127         (when (and (file-writable-p file)
 128                    (not (file-exists-p file)))
 129           (write-region-as-binary
 130            (point-min) (point-max) file nil 'no-msg)
 131           (elmo-folder-preserve-flags folder msgid flags)
 132           t)))))
 133
 134 (luna-define-method elmo-map-folder-delete-messages ((folder elmo-cache-folder)
 135                                                      locations)
 136   (dolist (location locations)
 137     (elmo-file-cache-delete
 138      (expand-file-name location
 139                        (elmo-cache-folder-directory-internal folder))))
 140   t)
 141
 142 (luna-define-method elmo-message-fetch
 143   ((folder elmo-cache-folder) number strategy &optional unseen section)
 144   ;; disable cache process
 145   (erase-buffer)
 146   (when (elmo-message-fetch-internal folder number strategy section unseen)
 147     (when (and (not unseen)
 148                (elmo-message-flagged-p folder number 'unread))
 149       (elmo-message-unset-flag folder number 'unread))
 150     t))
 151
 152 (luna-define-method elmo-map-message-fetch ((folder elmo-cache-folder)
 153                                             location strategy
 154                                             &optional section unseen)
 155   (let ((file (expand-file-name
 156                location
 157                (elmo-cache-folder-directory-internal folder))))
 158     (when (file-exists-p file)
 159       (insert-file-contents-as-binary file))))
 160
 161 (luna-define-method elmo-folder-writable-p ((folder elmo-cache-folder))
 162   t)
 163
 164 (luna-define-method elmo-folder-exists-p ((folder elmo-cache-folder))
 165   t)
 166
 167 (luna-define-method elmo-message-file-p ((folder elmo-cache-folder) number)
 168   t)
 169
 170 (require 'product)
 171 (product-provide (provide 'elmo-cache) (require 'elmo-version))
 172
 173 ;;; elmo-cache.el ends here