elmo/elmo-dop.el

   1 ;;; elmo-dop.el --- Modules for Disconnected Operations on ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'elmo)
  34 (require 'elmo-vars)
  35 (require 'elmo-msgdb)
  36 (require 'elmo-util)
  37 (require 'elmo-localdir)
  38
  39 ;; global variable.
  40 (defvar elmo-dop-queue nil
  41   "A list of (folder-name function-to-be-called argument-list).
  42 Automatically loaded/saved.")
  43
  44 (defmacro elmo-make-dop-queue (fname method arguments)
  45   "Make a dop queue."
  46   (` (vector (, fname) (, method) (, arguments))))
  47
  48 (defmacro elmo-dop-queue-fname (queue)
  49   "Return the folder name string of the QUEUE."
  50   (` (aref (, queue) 0)))
  51
  52 (defmacro elmo-dop-queue-method (queue)
  53   "Return the method symbol of the QUEUE."
  54   (` (aref (, queue) 1)))
  55
  56 (defmacro elmo-dop-queue-arguments (queue)
  57   "Return the arguments of the QUEUE."
  58   (` (aref (, queue) 2)))
  59
  60 (defun elmo-dop-queue-append (folder method arguments)
  61   "Append to disconnected operation queue."
  62   (let ((queue (elmo-make-dop-queue (elmo-folder-name-internal folder)
  63                                     method arguments)))
  64     (setq elmo-dop-queue (nconc elmo-dop-queue (list queue)))))
  65
  66 (defvar elmo-dop-queue-merge-method-list
  67   '(elmo-folder-set-read-delayed
  68     elmo-folder-unset-read-delayed
  69     elmo-folder-set-important-delayed
  70     elmo-folder-unset-important-delayed
  71     elmo-folder-set-answered-delayed
  72     elmo-folder-unset-answered-delayed))
  73
  74 (defvar elmo-dop-queue-method-name-alist
  75   '((elmo-folder-append-buffer-dop-delayed . "Append")
  76     (elmo-folder-delete-messages-dop-delayed . "Delete")
  77     (elmo-message-encache . "Encache")
  78     (elmo-folder-create-dop-delayed . "Create")
  79     (elmo-folder-set-read-delayed . "Read")
  80     (elmo-folder-unset-read-delayed . "Unread")
  81     (elmo-folder-set-answered-delayed . "Answered")
  82     (elmo-folder-unset-answered-delayed . "Unanswered")
  83     (elmo-folder-set-important-delayed . "Important")
  84     (elmo-folder-unset-important-delayed . "Unimportant")
  85     (elmo-folder-set-flag . "Set flag")
  86     (elmo-folder-unset-flag . "Unset flag")))
  87
  88 (defmacro elmo-dop-queue-method-name (queue)
  89   `(cdr (assq (elmo-dop-queue-method ,queue)
  90               elmo-dop-queue-method-name-alist)))
  91
  92 (defun elmo-dop-queue-flush ()
  93   "Flush disconnected operations that consern plugged folders."
  94   ;; obsolete
  95   (unless (or (null elmo-dop-queue)
  96               (vectorp (car elmo-dop-queue)))
  97     (if (y-or-n-p "\
  98 Saved queue is old version(2.6).  Clear all pending operations? ")
  99         (progn
 100           (setq elmo-dop-queue nil)
 101           (message "All pending operations are cleared.")
 102           (elmo-dop-queue-save))
 103       (error "Please use 2.6 or earlier")))
 104   (elmo-dop-queue-merge)
 105   (let ((queue-all elmo-dop-queue)
 106         queue
 107         (count 0)
 108         len)
 109     (while queue-all
 110       (if (elmo-folder-plugged-p
 111            (elmo-make-folder (elmo-dop-queue-fname (car queue-all))))
 112           (setq queue (append queue (list (car queue-all)))))
 113       (setq queue-all (cdr queue-all)))
 114     (setq count (length queue))
 115     (when (> count 0)
 116       (if (elmo-y-or-n-p
 117            (format "%d pending operation(s) exists.  Perform now? " count)
 118            (not elmo-dop-flush-confirm) t)
 119           (progn
 120             (message "")
 121             (sit-for 0)
 122             (let ((queue elmo-dop-queue)
 123                   (performed 0)
 124                   (i 0)
 125                   (num (length elmo-dop-queue))
 126                   folder func failure)
 127               (while queue
 128                 ;; now perform pending processes.
 129                 (setq failure nil)
 130                 (setq i (+ 1 i))
 131                 (message "Flushing queue....%d/%d." i num)
 132                 (condition-case err
 133                     (progn
 134                       (apply (elmo-dop-queue-method (car queue))
 135                              (prog1
 136                                  (setq folder
 137                                        (elmo-make-folder
 138                                         (elmo-dop-queue-fname (car queue))))
 139                                (elmo-folder-open folder)
 140                                (unless (elmo-folder-plugged-p folder)
 141                                  (error "Unplugged")))
 142                              (elmo-dop-queue-arguments (car queue)))
 143                       (elmo-folder-close folder))
 144                   (quit  (setq failure t))
 145                   (error (setq failure err)))
 146                 (if failure
 147                     ();
 148                   (setq elmo-dop-queue (delq (car queue) elmo-dop-queue))
 149                   (setq performed (+ 1 performed)))
 150                 (setq queue (cdr queue)))
 151               (message "%d/%d operation(s) are performed successfully."
 152                        performed num)
 153               (sit-for 0) ;
 154               (elmo-dop-queue-save)))
 155         ;; when answer=NO against performing dop
 156         (if (elmo-y-or-n-p "Clear these pending operations? "
 157                            (not elmo-dop-flush-confirm) t)
 158             (progn
 159               (while queue
 160                 (setq elmo-dop-queue (delq (car queue) elmo-dop-queue))
 161                 (setq queue (cdr queue)))
 162               (message "Pending operations are cleared.")
 163               (elmo-dop-queue-save))
 164           (message "")))
 165       count)))
 166
 167 (defun elmo-dop-queue-merge ()
 168   (let ((queue elmo-dop-queue)
 169         new-queue match-queue que)
 170     (while (setq que (car queue))
 171       (if (and
 172            (memq (elmo-dop-queue-method que)
 173                  elmo-dop-queue-merge-method-list)
 174            (setq match-queue
 175                  (car (delete
 176                        nil
 177                        (mapcar
 178                         (lambda (nqueue)
 179                           (if (and
 180                                (string= (elmo-dop-queue-fname que)
 181                                         (elmo-dop-queue-fname nqueue))
 182                                (string= (elmo-dop-queue-method que)
 183                                         (elmo-dop-queue-method nqueue)))
 184                               nqueue))
 185                         new-queue)))))
 186           (setcar (elmo-dop-queue-arguments match-queue)
 187                   (append (car (elmo-dop-queue-arguments match-queue))
 188                           (car (elmo-dop-queue-arguments que))))
 189         (setq new-queue (nconc new-queue (list que))))
 190       (setq queue (cdr queue)) )
 191     (setq elmo-dop-queue new-queue)))
 192
 193 ;;; dop spool folder
 194 (defmacro elmo-dop-spool-folder (folder)
 195   "Return a spool folder for disconnected operations
 196 which is corresponded to the FOLDER."
 197   (` (elmo-make-folder
 198       (concat "+" (expand-file-name "spool" (elmo-folder-msgdb-path
 199                                              (, folder)))))))
 200
 201 (defun elmo-dop-spool-folder-append-buffer (folder flags)
 202   "Append current buffer content to the dop spool folder.
 203 FOLDER is the folder structure.
 204 Return a message number."
 205   (let ((spool (elmo-dop-spool-folder folder)))
 206     (unless (elmo-folder-exists-p spool)
 207       (elmo-folder-create spool))
 208     (let ((new-number (1+ (car (elmo-folder-status spool)))))
 209       (elmo-folder-append-buffer spool flags new-number)
 210       new-number)))
 211
 212
 213 (defun elmo-dop-spool-folder-list-messages (folder)
 214   "List messages in the dop spool folder.
 215 FOLDER is the folder structure."
 216   (setq folder (elmo-dop-spool-folder folder))
 217   (if (elmo-folder-exists-p folder)
 218       (elmo-folder-list-messages folder)))
 219
 220 (defun elmo-dop-list-deleting-messages (folder)
 221   "List messages which are on the deleting queue for the folder.
 222 FOLDER is the folder structure."
 223   (let (messages)
 224     (dolist (queue elmo-dop-queue)
 225       (if (and (string= (elmo-dop-queue-fname queue)
 226                         (elmo-folder-name-internal folder))
 227                (eq (elmo-dop-queue-method queue)
 228                    'elmo-folder-delete-messages-dop-delayed))
 229           (setq messages (nconc messages
 230                                 (mapcar
 231                                  'car
 232                                  (car (elmo-dop-queue-arguments queue)))))))))
 233
 234 (defun elmo-dop-filter-pending-messages (numbers)
 235   (elmo-delete-if (lambda (number) (< number 0)) numbers))
 236
 237 ;;; DOP operations.
 238 (defsubst elmo-folder-append-buffer-dop (folder &optional flag number)
 239   (elmo-dop-queue-append
 240    folder 'elmo-folder-append-buffer-dop-delayed
 241    (list flag
 242          (elmo-dop-spool-folder-append-buffer folder flag)
 243          number)))
 244
 245 (defsubst elmo-folder-delete-messages-dop (folder numbers)
 246   (let ((spool-folder (elmo-dop-spool-folder folder))
 247         queue)
 248     (dolist (number numbers)
 249       (if (< number 0)
 250           (elmo-folder-delete-messages spool-folder
 251                                        (list (abs number))) ; delete from queue
 252         (setq queue (cons number queue))))
 253     (when queue
 254       (elmo-dop-queue-append folder 'elmo-folder-delete-messages-dop-delayed
 255                              (list
 256                               (mapcar
 257                                (lambda (number)
 258                                  (cons number (elmo-message-field
 259                                                folder number 'message-id)))
 260                                queue))))
 261     t))
 262
 263 (defsubst elmo-message-encache-dop (folder number &optional read)
 264   (elmo-dop-queue-append folder 'elmo-message-encache (list number read)))
 265
 266 (defsubst elmo-folder-create-dop (folder)
 267   (elmo-dop-queue-append folder 'elmo-folder-create-dop-delayed nil))
 268
 269 (defsubst elmo-folder-set-flag-dop (folder numbers flag)
 270   (when (setq numbers (elmo-dop-filter-pending-messages numbers))
 271     (let ((method (case flag
 272                     (unread
 273                      'elmo-folder-unset-read-delayed)
 274                     (read
 275                      'elmo-folder-set-read-delayed)
 276                     (important
 277                      'elmo-folder-set-important-delayed)
 278                     (answered
 279                      'elmo-folder-set-answered-delayed))))
 280       (if method
 281           (elmo-dop-queue-append folder method (list numbers))
 282         (elmo-dop-queue-append folder 'elmo-folder-set-flag
 283                                (list numbers flag))))))
 284
 285 (defsubst elmo-folder-unset-flag-dop (folder numbers flag)
 286   (when (setq numbers (elmo-dop-filter-pending-messages numbers))
 287     (let ((method (case flag
 288                     (unread
 289                      'elmo-folder-set-read-delayed)
 290                     (read
 291                      'elmo-folder-unset-read-delayed)
 292                     (important
 293                      'elmo-folder-unset-important-delayed)
 294                     (answered
 295                      'elmo-folder-unset-answered-delayed))))
 296       (if method
 297           (elmo-dop-queue-append folder method (list numbers))
 298         (elmo-dop-queue-append folder 'elmo-folder-unset-flag
 299                                (list numbers flag))))))
 300
 301 ;;; Execute as subsutitute for plugged operation.
 302 (defun elmo-folder-status-dop (folder)
 303   (let ((number-list (elmo-folder-list-messages folder nil 'in-msgdb))
 304         (spool-folder (elmo-dop-spool-folder folder))
 305         spool-length
 306         max-num)
 307     (setq spool-length (or (if (elmo-folder-exists-p spool-folder)
 308                                (car (elmo-folder-status spool-folder)))
 309                            0))
 310     (setq max-num (if number-list (apply #'max number-list) 0))
 311     (cons (+ max-num spool-length) (+ (length number-list) spool-length))))
 312
 313 (defun elmo-folder-next-message-number-dop (folder)
 314   (let ((number-list (elmo-folder-list-messages folder nil 'in-msgdb))
 315         (spool-folder (elmo-dop-spool-folder folder))
 316         spool-length
 317         max-num)
 318     (setq spool-length (or (if (elmo-folder-exists-p spool-folder)
 319                                (car (elmo-folder-status spool-folder)))
 320                            0))
 321     (setq max-num (if number-list (apply #'max number-list) 0))
 322     (+ max-num spool-length)))
 323
 324 ;;; Delayed operation (executed at online status).
 325 (defun elmo-folder-append-buffer-dop-delayed (folder flag number set-number)
 326   (let ((spool-folder (elmo-dop-spool-folder folder))
 327         flags)
 328     (with-temp-buffer
 329       (when (elmo-message-fetch spool-folder number
 330                                 (elmo-make-fetch-strategy 'entire)
 331                                 'unread)
 332         (setq flags (or (elmo-message-flags-for-append folder (* -1 number))
 333                         (cond ((listp flag)
 334                                flag)
 335                               ;; for compatibility with 2.11.12 or earlier
 336                               ((eq flag t)
 337                                nil)
 338                               (t
 339                                (list flag)))))
 340         (when (or (condition-case nil
 341                       (elmo-folder-append-buffer folder flags set-number)
 342                     (error))
 343                   ;; Append failed...
 344                   (elmo-folder-append-buffer
 345                    (elmo-make-folder elmo-lost+found-folder)
 346                    flags))
 347           (elmo-folder-delete-messages spool-folder (list number)))))
 348     ;; ignore failure (already dequed)
 349     t))
 350
 351 (defun elmo-folder-delete-messages-dop-delayed (folder number-alist)
 352   (ignore-errors
 353     (elmo-folder-delete-messages
 354      folder
 355      ;; messages are deleted only if message-id is not changed.
 356      (mapcar 'car
 357              (elmo-delete-if
 358               (lambda (pair)
 359                 (not (string=
 360                       (cdr pair)
 361                       (elmo-message-fetch-field folder (car pair)
 362                                                 'message-id))))
 363               number-alist)))
 364     t)) ; Always success (If failure, just remain)
 365
 366 (defun elmo-folder-create-dop-delayed (folder)
 367   (unless (elmo-folder-exists-p folder)
 368     (elmo-folder-create folder)))
 369
 370 (defun elmo-folder-set-important-delayed (folder numbers)
 371   (elmo-folder-set-flag folder numbers 'important))
 372
 373 (defun elmo-folder-unset-important-delayed (folder numbers)
 374   (elmo-folder-unset-flag folder numbers 'important))
 375
 376 (defun elmo-folder-set-read-delayed (folder numbers)
 377   (elmo-folder-unset-flag folder numbers 'unread))
 378
 379 (defun elmo-folder-unset-read-delayed (folder numbers)
 380   (elmo-folder-set-flag folder numbers 'unread))
 381
 382 (defun elmo-folder-set-answered-delayed (folder numbers)
 383   (elmo-folder-set-flag folder numbers 'answered))
 384
 385 (defun elmo-folder-unset-answered-delayed (folder numbers)
 386   (elmo-folder-unset-flag folder numbers 'answered))
 387
 388 ;;; Util
 389 (defun elmo-dop-msgdb (msgdb)
 390   (let ((new-db (elmo-make-msgdb))
 391         entity)
 392     (dolist (dop-entity (mapcar
 393                          (lambda (number)
 394                            (setq entity (elmo-msgdb-message-entity
 395                                          msgdb number))
 396                            (elmo-message-entity-set-number
 397                             entity
 398                             (* -1 (elmo-message-entity-number entity)))
 399                            entity)
 400                          (elmo-msgdb-list-messages msgdb)))
 401       (elmo-msgdb-append-entity new-db
 402                                 dop-entity
 403                                 (elmo-msgdb-flags
 404                                  msgdb
 405                                  (abs (elmo-message-entity-number
 406                                        dop-entity)))))
 407     new-db))
 408
 409 (require 'product)
 410 (product-provide (provide 'elmo-dop) (require 'elmo-version))
 411
 412 ;;; elmo-dop.el ends here