elmo/elmo-dop.el

   1 ;;; elmo-dop.el --- Modules for Disconnected Operations on ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'elmo)
  33 (require 'elmo-vars)
  34 (require 'elmo-msgdb)
  35 (require 'elmo-util)
  36 (require 'elmo-localdir)
  37
  38 ;; global variable.
  39 (defvar elmo-dop-queue nil
  40   "A list of (folder-name function-to-be-called argument-list).
  41 Automatically loaded/saved.")
  42
  43 (defmacro elmo-make-dop-queue (fname method arguments)
  44   "Make a dop queue."
  45   (` (vector (, fname) (, method) (, arguments))))
  46
  47 (defmacro elmo-dop-queue-fname (queue)
  48   "Return the folder name string of the QUEUE."
  49   (` (aref (, queue) 0)))
  50
  51 (defmacro elmo-dop-queue-method (queue)
  52   "Return the method symbol of the QUEUE."
  53   (` (aref (, queue) 1)))
  54
  55 (defmacro elmo-dop-queue-arguments (queue)
  56   "Return the arguments of the QUEUE."
  57   (` (aref (, queue) 2)))
  58
  59 (defun elmo-dop-queue-append (folder method arguments)
  60   "Append to disconnected operation queue."
  61   (let ((queue (elmo-make-dop-queue (elmo-folder-name-internal folder)
  62                                     method arguments)))
  63     (setq elmo-dop-queue (nconc elmo-dop-queue (list queue)))))
  64
  65 (defvar elmo-dop-queue-method-name-alist
  66   '((elmo-folder-append-buffer-dop-delayed . "Append")
  67     (elmo-folder-delete-messages-dop-delayed . "Delete")
  68     (elmo-message-encache . "Encache")
  69     (elmo-create-folder . "Create")
  70     (elmo-folder-mark-as-read . "Read")
  71     (elmo-folder-unmark-read . "Unread")
  72     (elmo-folder-mark-as-important . "Important")
  73     (elmo-folder-unmark-important . "Unimportant")))
  74
  75 (defmacro elmo-dop-queue-method-name (queue)
  76   `(cdr (assq (elmo-dop-queue-method ,queue)
  77               elmo-dop-queue-method-name-alist)))
  78
  79 (defun elmo-dop-queue-flush (&optional force)
  80   "Flush disconnected operations.
  81 If optional argument FORCE is non-nil, try flushing all operation queues
  82 even an operation concerns the unplugged folder."
  83   (elmo-dop-queue-merge)
  84   (let ((queue elmo-dop-queue)
  85         (count 0)
  86         folder
  87         len)
  88     ;; obsolete
  89     (unless (or (null queue)
  90                 (vectorp (car queue)))
  91       (if (y-or-n-p "Saved queue is old version(2.6). Clear all pending operations? ")
  92           (progn
  93             (setq elmo-dop-queue nil)
  94             (message "All pending operations are cleared.")
  95             (elmo-dop-queue-save))
  96         (error "Please use 2.6 or earlier.")))
  97     (setq count (length queue))
  98     (when (> count 0)
  99       (if (elmo-y-or-n-p
 100            (format "%d pending operation(s) exists.  Perform now? " count)
 101            (not elmo-dop-flush-confirm) t)
 102           (progn
 103             (message "")
 104             (sit-for 0)
 105             (let ((queue elmo-dop-queue)
 106                   (performed 0)
 107                   (i 0)
 108                   (num (length elmo-dop-queue))
 109                   folder func failure)
 110               (while queue
 111                 ;; now perform pending processes.
 112                 (setq failure nil)
 113                 (setq i (+ 1 i))
 114                 (message "Flushing queue....%d/%d." i num)
 115                 (condition-case err
 116                     (progn
 117                       (apply (elmo-dop-queue-method (car queue))
 118                              (prog1
 119                                  (setq folder
 120                                        (elmo-make-folder
 121                                         (elmo-dop-queue-fname (car queue))))
 122                                (elmo-folder-open folder)
 123                                (unless (elmo-folder-plugged-p folder)
 124                                  (error "Unplugged.")))
 125                              (elmo-dop-queue-arguments (car queue)))
 126                       (elmo-folder-close folder))
 127                   (quit  (setq failure t))
 128                   (error (setq failure err)))
 129                 (if failure
 130                     ();
 131                   (setq elmo-dop-queue (delq (car queue) elmo-dop-queue))
 132                   (setq performed (+ 1 performed)))
 133                 (setq queue (cdr queue)))
 134               (message "%d/%d operation(s) are performed successfully."
 135                        performed num)
 136               (sit-for 0) ;
 137               (elmo-dop-queue-save)))
 138         (if (elmo-y-or-n-p "Clear all pending operations? "
 139                            (not elmo-dop-flush-confirm) t)
 140             (progn
 141               (setq elmo-dop-queue nil)
 142               (message "All pending operations are cleared.")
 143               (elmo-dop-queue-save))
 144           (message "")))
 145       count)))
 146
 147 (defun elmo-dop-queue-merge ()
 148   (let ((queue elmo-dop-queue)
 149         new-queue match-queue que)
 150     (while (setq que (car queue))
 151       (if (and
 152            (assq (elmo-dop-queue-method que)
 153                  elmo-dop-queue-method-name-alist)
 154            (setq match-queue
 155                  (car (delete nil
 156                               (mapcar '(lambda (nqueue)
 157                                          (if (and
 158                                               (string= (elmo-dop-queue-fname que)
 159                                                        (elmo-dop-queue-fname nqueue))
 160                                               (string= (elmo-dop-queue-method que)
 161                                                        (elmo-dop-queue-method nqueue)))
 162                                              nqueue))
 163                                       new-queue)))))
 164             (setcar (elmo-dop-queue-arguments match-queue)
 165                     (append (car (elmo-dop-queue-arguments match-queue))
 166                             (car (elmo-dop-queue-arguments que))))
 167         (setq new-queue (nconc new-queue (list que))))
 168       (setq queue (cdr queue)) )
 169     (setq elmo-dop-queue new-queue)))
 170
 171 ;;; dop spool folder
 172 (defmacro elmo-dop-spool-folder (folder)
 173   "Return a spool folder for disconnected operations
 174 which is corresponded to the FOLDER."
 175   (` (elmo-make-folder
 176       (concat "+" (expand-file-name "spool" (elmo-folder-msgdb-path
 177                                              (, folder)))))))
 178
 179 (defun elmo-dop-spool-folder-append-buffer (folder)
 180   "Append current buffer content to the dop spool folder.
 181 FOLDER is the folder structure.
 182 Return a message number."
 183   (setq folder (elmo-dop-spool-folder folder))
 184   (unless (elmo-folder-exists-p folder)
 185     (elmo-folder-create folder))
 186   (let ((new-number (1+ (car (elmo-folder-status folder)))))
 187     ;; dop folder is a localdir folder.
 188     (write-region-as-binary (point-min) (point-max)
 189                           (expand-file-name
 190                            (int-to-string new-number)
 191                            (elmo-localdir-folder-directory-internal folder))
 192                           nil 'no-msg)
 193     new-number))
 194
 195
 196 (defun elmo-dop-spool-folder-list-messages (folder)
 197   "List messages in the dop spool folder.
 198 FOLDER is the folder structure."
 199   (setq folder (elmo-dop-spool-folder folder))
 200   (if (elmo-folder-exists-p folder)
 201       (elmo-folder-list-messages folder)))
 202
 203 (defun elmo-dop-list-deleting-messages (folder)
 204   "List messages which are on the deleting queue for the folder.
 205 FOLDER is the folder structure."
 206   (let (messages)
 207     (dolist (queue elmo-dop-queue)
 208       (if (and (string= (elmo-dop-queue-fname queue)
 209                         (elmo-folder-name-internal folder))
 210                (eq (elmo-dop-queue-method queue)
 211                    'elmo-folder-delete-messages-dop-delayed))
 212           (setq messages (nconc messages
 213                                 (mapcar
 214                                  'car
 215                                  (car (elmo-dop-queue-arguments queue)))))))))
 216
 217 ;;; DOP operations.
 218 (defsubst elmo-folder-append-buffer-dop (folder unread &optional number)
 219   (elmo-dop-queue-append
 220    folder 'elmo-folder-append-buffer-dop-delayed
 221    (list unread
 222          (elmo-dop-spool-folder-append-buffer
 223           folder)
 224          number)))
 225
 226 (defsubst elmo-folder-delete-messages-dop (folder numbers)
 227   (elmo-dop-queue-append folder 'elmo-folder-delete-messages-dop-delayed
 228                          (list
 229                           (mapcar
 230                            (lambda (number)
 231                              (cons number (elmo-message-field
 232                                            folder number 'message-id)))
 233                            numbers)))
 234   t)
 235
 236 (defsubst elmo-message-encache-dop (folder number &optional read)
 237   (elmo-dop-queue-append folder 'elmo-message-encache (list number read)))
 238
 239 (defsubst elmo-create-folder-dop (folder)
 240   (elmo-dop-queue-append folder 'elmo-folder-create nil))
 241
 242 (defsubst elmo-folder-mark-as-read-dop (folder numbers)
 243   (elmo-dop-queue-append folder 'elmo-folder-mark-as-read (list numbers)))
 244
 245 (defsubst elmo-folder-unmark-read-dop (folder numbers)
 246   (elmo-dop-queue-append folder 'elmo-folder-unmark-read (list numbers)))
 247
 248 (defsubst elmo-folder-mark-as-important-dop (folder numbers)
 249   (elmo-dop-queue-append folder 'elmo-folder-mark-as-important (list numbers)))
 250
 251 (defsubst elmo-folder-unmark-important-dop (folder numbers)
 252   (elmo-dop-queue-append folder 'elmo-folder-unmark-important (list numbers)))
 253
 254 ;;; Execute as subsutitute for plugged operation.
 255 (defun elmo-folder-status-dop (folder)
 256   (let* ((number-alist (elmo-msgdb-number-load
 257                         (elmo-folder-msgdb-path folder)))
 258          (number-list (mapcar 'car number-alist))
 259          (spool-folder (elmo-dop-spool-folder folder))
 260          spool-length
 261          (i 0)
 262          max-num)
 263     (setq spool-length (length (car (if (elmo-folder-exists-p spool-folder)
 264                                         (elmo-folder-status spool-folder)))))
 265     (setq max-num
 266           (or (nth (max (- (length number-list) 1) 0) number-list)
 267               0))
 268     (cons (+ max-num spool-length) (+ (length number-list) spool-length))))
 269
 270 ;;; Delayed operation (executed at online status).
 271 (defun elmo-folder-append-buffer-dop-delayed (folder unread number set-number)
 272   (let ((spool-folder (elmo-dop-spool-folder folder))
 273         failure saved)
 274     (with-temp-buffer
 275       (elmo-message-fetch spool-folder number
 276                           (elmo-make-fetch-strategy 'entire)
 277                           nil (current-buffer) 'unread)
 278       (condition-case nil
 279           (setq failure (not
 280                          (elmo-folder-append-buffer folder unread set-number)))
 281         (error (setq failure t)))
 282       (when failure
 283         ;; Append failed...
 284         (setq saved (elmo-folder-append-buffer
 285                      (elmo-make-folder elmo-lost+found-folder)
 286                      unread set-number)))
 287       (if (or (not failure)
 288               saved)
 289           (elmo-folder-delete-messages spool-folder (list number)))
 290       t)))
 291
 292 (defun elmo-folder-delete-messages-dop-delayed (folder number-alist)
 293   (elmo-folder-delete-messages
 294    folder
 295    ;; messages are deleted only if message-id is not changed.
 296    (mapcar 'car
 297            (elmo-delete-if
 298             (lambda (pair)
 299               (not (string=
 300                     (cdr pair)
 301                     (elmo-message-fetch-field folder (car pair)
 302                                               'message-id))))
 303             number-alist))))
 304
 305 ;;; Util
 306 (defun elmo-dop-msgdb (msgdb)
 307   (list (mapcar (function
 308                  (lambda (x)
 309                    (elmo-msgdb-overview-entity-set-number
 310                     x
 311                     (* -1
 312                        (elmo-msgdb-overview-entity-get-number x)))))
 313                 (nth 0 msgdb))
 314         (mapcar (function
 315                  (lambda (x) (cons
 316                               (* -1 (car x))
 317                               (cdr x))))
 318                 (nth 1 msgdb))
 319         (mapcar (function
 320                  (lambda (x) (cons
 321                               (* -1 (car x))
 322                               (cdr x)))) (nth 2 msgdb))))
 323
 324 (require 'product)
 325 (product-provide (provide 'elmo-dop) (require 'elmo-version))
 326
 327 ;;; elmo-dop.el ends here