elmo/elmo-dop.el

   1 ;;; elmo-dop.el --- Modules for Disconnected Operations on ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'elmo)
  33 (require 'elmo-vars)
  34 (require 'elmo-msgdb)
  35 (require 'elmo-util)
  36 (require 'elmo-localdir)
  37
  38 ;; global variable.
  39 (defvar elmo-dop-queue nil
  40   "A list of (folder-name function-to-be-called argument-list).
  41 Automatically loaded/saved.")
  42
  43 (defmacro elmo-make-dop-queue (fname method arguments)
  44   "Make a dop queue."
  45   (` (vector (, fname) (, method) (, arguments))))
  46
  47 (defmacro elmo-dop-queue-fname (queue)
  48   "Return the folder name string of the QUEUE."
  49   (` (aref (, queue) 0)))
  50
  51 (defmacro elmo-dop-queue-method (queue)
  52   "Return the method symbol of the QUEUE."
  53   (` (aref (, queue) 1)))
  54
  55 (defmacro elmo-dop-queue-arguments (queue)
  56   "Return the arguments of the QUEUE."
  57   (` (aref (, queue) 2)))
  58
  59 (defun elmo-dop-queue-append (folder method arguments)
  60   "Append to disconnected operation queue."
  61   (let ((queue (elmo-make-dop-queue (elmo-folder-name-internal folder)
  62                                     method arguments)))
  63     (setq elmo-dop-queue (nconc elmo-dop-queue (list queue)))))
  64
  65 (defvar elmo-dop-queue-merge-method-list
  66   '(elmo-folder-set-read-delayed
  67     elmo-folder-unset-read-delayed
  68     elmo-folder-set-important-delayed
  69     elmo-folder-unset-important-delayed
  70     elmo-folder-set-answered-delayed
  71     elmo-folder-unset-answered-delayed))
  72
  73 (defvar elmo-dop-queue-method-name-alist
  74   '((elmo-folder-append-buffer-dop-delayed . "Append")
  75     (elmo-folder-delete-messages-dop-delayed . "Delete")
  76     (elmo-message-encache . "Encache")
  77     (elmo-folder-create-dop-delayed . "Create")
  78     (elmo-folder-set-read-delayed . "Read")
  79     (elmo-folder-unset-read-delayed . "Unread")
  80     (elmo-folder-set-answered-delayed . "Answered")
  81     (elmo-folder-unset-answered-delayed . "Unanswered")
  82     (elmo-folder-set-important-delayed . "Important")
  83     (elmo-folder-unset-important-delayed . "Unimportant")
  84     (elmo-folder-set-flag . "Set flag")
  85     (elmo-folder-unset-flag . "Unset flag")))
  86
  87 (defmacro elmo-dop-queue-method-name (queue)
  88   `(cdr (assq (elmo-dop-queue-method ,queue)
  89               elmo-dop-queue-method-name-alist)))
  90
  91 (defun elmo-dop-queue-flush ()
  92   "Flush disconnected operations that consern plugged folders."
  93   ;; obsolete
  94   (unless (or (null elmo-dop-queue)
  95               (vectorp (car elmo-dop-queue)))
  96     (if (y-or-n-p "\
  97 Saved queue is old version(2.6).  Clear all pending operations? ")
  98         (progn
  99           (setq elmo-dop-queue nil)
 100           (message "All pending operations are cleared.")
 101           (elmo-dop-queue-save))
 102       (error "Please use 2.6 or earlier")))
 103   (elmo-dop-queue-merge)
 104   (let ((queue-all elmo-dop-queue)
 105         queue
 106         (count 0)
 107         len)
 108     (while queue-all
 109       (if (elmo-folder-plugged-p
 110            (elmo-make-folder (elmo-dop-queue-fname (car queue-all))))
 111           (setq queue (append queue (list (car queue-all)))))
 112       (setq queue-all (cdr queue-all)))
 113     (setq count (length queue))
 114     (when (> count 0)
 115       (if (elmo-y-or-n-p
 116            (format "%d pending operation(s) exists.  Perform now? " count)
 117            (not elmo-dop-flush-confirm) t)
 118           (progn
 119             (message "")
 120             (sit-for 0)
 121             (let ((queue elmo-dop-queue)
 122                   (performed 0)
 123                   (i 0)
 124                   (num (length elmo-dop-queue))
 125                   folder func failure)
 126               (while queue
 127                 ;; now perform pending processes.
 128                 (setq failure nil)
 129                 (setq i (+ 1 i))
 130                 (message "Flushing queue....%d/%d." i num)
 131                 (condition-case err
 132                     (progn
 133                       (apply (elmo-dop-queue-method (car queue))
 134                              (prog1
 135                                  (setq folder
 136                                        (elmo-make-folder
 137                                         (elmo-dop-queue-fname (car queue))))
 138                                (elmo-folder-open folder)
 139                                (unless (elmo-folder-plugged-p folder)
 140                                  (error "Unplugged")))
 141                              (elmo-dop-queue-arguments (car queue)))
 142                       (elmo-folder-close folder))
 143                   (quit  (setq failure t))
 144                   (error (setq failure err)))
 145                 (if failure
 146                     ();
 147                   (setq elmo-dop-queue (delq (car queue) elmo-dop-queue))
 148                   (setq performed (+ 1 performed)))
 149                 (setq queue (cdr queue)))
 150               (message "%d/%d operation(s) are performed successfully."
 151                        performed num)
 152               (sit-for 0) ;
 153               (elmo-dop-queue-save)))
 154         ;; when answer=NO against performing dop
 155         (if (elmo-y-or-n-p "Clear these pending operations? "
 156                            (not elmo-dop-flush-confirm) t)
 157             (progn
 158               (while queue
 159                 (setq elmo-dop-queue (delq (car queue) elmo-dop-queue))
 160                 (setq queue (cdr queue)))
 161               (message "Pending operations are cleared.")
 162               (elmo-dop-queue-save))
 163           (message "")))
 164       count)))
 165
 166 (defun elmo-dop-queue-merge ()
 167   (let ((queue elmo-dop-queue)
 168         new-queue match-queue que)
 169     (while (setq que (car queue))
 170       (if (and
 171            (memq (elmo-dop-queue-method que)
 172                  elmo-dop-queue-merge-method-list)
 173            (setq match-queue
 174                  (car (delete
 175                        nil
 176                        (mapcar
 177                         (lambda (nqueue)
 178                           (if (and
 179                                (string= (elmo-dop-queue-fname que)
 180                                         (elmo-dop-queue-fname nqueue))
 181                                (string= (elmo-dop-queue-method que)
 182                                         (elmo-dop-queue-method nqueue)))
 183                               nqueue))
 184                         new-queue)))))
 185           (setcar (elmo-dop-queue-arguments match-queue)
 186                   (append (car (elmo-dop-queue-arguments match-queue))
 187                           (car (elmo-dop-queue-arguments que))))
 188         (setq new-queue (nconc new-queue (list que))))
 189       (setq queue (cdr queue)) )
 190     (setq elmo-dop-queue new-queue)))
 191
 192 ;;; dop spool folder
 193 (defmacro elmo-dop-spool-folder (folder)
 194   "Return a spool folder for disconnected operations
 195 which is corresponded to the FOLDER."
 196   (` (elmo-make-folder
 197       (concat "+" (expand-file-name "spool" (elmo-folder-msgdb-path
 198                                              (, folder)))))))
 199
 200 (defun elmo-dop-spool-folder-append-buffer (folder flags)
 201   "Append current buffer content to the dop spool folder.
 202 FOLDER is the folder structure.
 203 Return a message number."
 204   (let ((spool (elmo-dop-spool-folder folder)))
 205     (unless (elmo-folder-exists-p spool)
 206       (elmo-folder-create spool))
 207     (let ((new-number (1+ (car (elmo-folder-status spool)))))
 208       (elmo-folder-append-buffer spool flags new-number)
 209       new-number)))
 210
 211
 212 (defun elmo-dop-spool-folder-list-messages (folder)
 213   "List messages in the dop spool folder.
 214 FOLDER is the folder structure."
 215   (setq folder (elmo-dop-spool-folder folder))
 216   (if (elmo-folder-exists-p folder)
 217       (elmo-folder-list-messages folder)))
 218
 219 (defun elmo-dop-list-deleting-messages (folder)
 220   "List messages which are on the deleting queue for the folder.
 221 FOLDER is the folder structure."
 222   (let (messages)
 223     (dolist (queue elmo-dop-queue)
 224       (if (and (string= (elmo-dop-queue-fname queue)
 225                         (elmo-folder-name-internal folder))
 226                (eq (elmo-dop-queue-method queue)
 227                    'elmo-folder-delete-messages-dop-delayed))
 228           (setq messages (nconc messages
 229                                 (mapcar
 230                                  'car
 231                                  (car (elmo-dop-queue-arguments queue)))))))))
 232
 233 (defun elmo-dop-filter-pending-messages (numbers)
 234   (elmo-delete-if (lambda (number) (< number 0)) numbers))
 235
 236 ;;; DOP operations.
 237 (defsubst elmo-folder-append-buffer-dop (folder &optional flag number)
 238   (elmo-dop-queue-append
 239    folder 'elmo-folder-append-buffer-dop-delayed
 240    (list flag
 241          (elmo-dop-spool-folder-append-buffer folder flag)
 242          number)))
 243
 244 (defsubst elmo-folder-delete-messages-dop (folder numbers)
 245   (let ((spool-folder (elmo-dop-spool-folder folder))
 246         queue)
 247     (dolist (number numbers)
 248       (if (< number 0)
 249           (elmo-folder-delete-messages spool-folder
 250                                        (list (abs number))) ; delete from queue
 251         (setq queue (cons number queue))))
 252     (when queue
 253       (elmo-dop-queue-append folder 'elmo-folder-delete-messages-dop-delayed
 254                              (list
 255                               (mapcar
 256                                (lambda (number)
 257                                  (cons number (elmo-message-field
 258                                                folder number 'message-id)))
 259                                queue))))
 260     t))
 261
 262 (defsubst elmo-message-encache-dop (folder number &optional read)
 263   (elmo-dop-queue-append folder 'elmo-message-encache (list number read)))
 264
 265 (defsubst elmo-folder-create-dop (folder)
 266   (elmo-dop-queue-append folder 'elmo-folder-create-dop-delayed nil))
 267
 268 (defsubst elmo-folder-set-flag-dop (folder numbers flag)
 269   (when (setq numbers (elmo-dop-filter-pending-messages numbers))
 270     (let ((method (case flag
 271                     (unread
 272                      'elmo-folder-unset-read-delayed)
 273                     (read
 274                      'elmo-folder-set-read-delayed)
 275                     (important
 276                      'elmo-folder-set-important-delayed)
 277                     (answered
 278                      'elmo-folder-set-answered-delayed))))
 279       (if method
 280           (elmo-dop-queue-append folder method (list numbers))
 281         (elmo-dop-queue-append folder 'elmo-folder-set-flag
 282                                (list numbers flag))))))
 283
 284 (defsubst elmo-folder-unset-flag-dop (folder numbers flag)
 285   (when (setq numbers (elmo-dop-filter-pending-messages numbers))
 286     (let ((method (case flag
 287                     (unread
 288                      'elmo-folder-set-read-delayed)
 289                     (read
 290                      'elmo-folder-unset-read-delayed)
 291                     (important
 292                      'elmo-folder-unset-important-delayed)
 293                     (answered
 294                      'elmo-folder-unset-answered-delayed))))
 295       (if method
 296           (elmo-dop-queue-append folder method (list numbers))
 297         (elmo-dop-queue-append folder 'elmo-folder-unset-flag
 298                                (list numbers flag))))))
 299
 300 ;;; Execute as subsutitute for plugged operation.
 301 (defun elmo-folder-status-dop (folder)
 302   (let ((number-list (elmo-folder-list-messages folder nil 'in-msgdb))
 303         (spool-folder (elmo-dop-spool-folder folder))
 304         spool-length
 305         max-num)
 306     (setq spool-length (or (if (elmo-folder-exists-p spool-folder)
 307                                (car (elmo-folder-status spool-folder)))
 308                            0))
 309     (setq max-num (if number-list (apply #'max number-list) 0))
 310     (cons (+ max-num spool-length) (+ (length number-list) spool-length))))
 311
 312 (defun elmo-folder-next-message-number-dop (folder)
 313   (let ((number-list (elmo-folder-list-messages folder nil 'in-msgdb))
 314         (spool-folder (elmo-dop-spool-folder folder))
 315         spool-length
 316         max-num)
 317     (setq spool-length (or (if (elmo-folder-exists-p spool-folder)
 318                                (car (elmo-folder-status spool-folder)))
 319                            0))
 320     (setq max-num (if number-list (apply #'max number-list) 0))
 321     (+ max-num spool-length)))
 322
 323 ;;; Delayed operation (executed at online status).
 324 (defun elmo-folder-append-buffer-dop-delayed (folder flag number set-number)
 325   (let ((spool-folder (elmo-dop-spool-folder folder))
 326         flags)
 327     (with-temp-buffer
 328       (when (elmo-message-fetch spool-folder number
 329                                 (elmo-make-fetch-strategy 'entire)
 330                                 nil (current-buffer) 'unread)
 331         (setq flags (or (elmo-message-flags-for-append folder (* -1 number))
 332                         (cond ((listp flag)
 333                                flag)
 334                               ;; for compatibility with 2.11.12 or earlier
 335                               ((eq flag t)
 336                                nil)
 337                               (t
 338                                (list flag)))))
 339         (when (or (condition-case nil
 340                       (elmo-folder-append-buffer folder flags set-number)
 341                     (error))
 342                   ;; Append failed...
 343                   (elmo-folder-append-buffer
 344                    (elmo-make-folder elmo-lost+found-folder)
 345                    flags))
 346           (elmo-folder-delete-messages spool-folder (list number)))))
 347     ;; ignore failure (already dequed)
 348     t))
 349
 350 (defun elmo-folder-delete-messages-dop-delayed (folder number-alist)
 351   (ignore-errors
 352     (elmo-folder-delete-messages
 353      folder
 354      ;; messages are deleted only if message-id is not changed.
 355      (mapcar 'car
 356              (elmo-delete-if
 357               (lambda (pair)
 358                 (not (string=
 359                       (cdr pair)
 360                       (elmo-message-fetch-field folder (car pair)
 361                                                 'message-id))))
 362               number-alist)))
 363     t)) ; Always success (If failure, just remain)
 364
 365 (defun elmo-folder-create-dop-delayed (folder)
 366   (unless (elmo-folder-exists-p folder)
 367     (elmo-folder-create folder)))
 368
 369 (defun elmo-folder-set-important-delayed (folder numbers)
 370   (elmo-folder-set-flag folder numbers 'important))
 371
 372 (defun elmo-folder-unset-important-delayed (folder numbers)
 373   (elmo-folder-unset-flag folder numbers 'important))
 374
 375 (defun elmo-folder-set-read-delayed (folder numbers)
 376   (elmo-folder-unset-flag folder numbers 'unread))
 377
 378 (defun elmo-folder-unset-read-delayed (folder numbers)
 379   (elmo-folder-set-flag folder numbers 'unread))
 380
 381 (defun elmo-folder-set-answered-delayed (folder numbers)
 382   (elmo-folder-set-flag folder numbers 'answered))
 383
 384 (defun elmo-folder-unset-answered-delayed (folder numbers)
 385   (elmo-folder-unset-flag folder numbers 'answered))
 386
 387 ;;; Util
 388 (defun elmo-dop-msgdb (msgdb)
 389   (let ((new-db (elmo-make-msgdb))
 390         entity)
 391     (dolist (dop-entity (mapcar
 392                          (lambda (number)
 393                            (setq entity (elmo-msgdb-message-entity
 394                                          msgdb number))
 395                            (elmo-message-entity-set-number
 396                             entity
 397                             (* -1 (elmo-message-entity-number entity)))
 398                            entity)
 399                          (elmo-msgdb-list-messages msgdb)))
 400       (elmo-msgdb-append-entity new-db
 401                                 dop-entity
 402                                 (elmo-msgdb-flags
 403                                  msgdb
 404                                  (abs (elmo-message-entity-number
 405                                        dop-entity)))))
 406     new-db))
 407
 408 (require 'product)
 409 (product-provide (provide 'elmo-dop) (require 'elmo-version))
 410
 411 ;;; elmo-dop.el ends here