elmo/elmo-filter.el

   1 ;;; elmo-filter.el --- Filtered Folder Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;;      Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   7 ;; Keywords: mail, net news
   8
   9 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29
  30 ;;; Code:
  31 ;;
  32 (require 'elmo)
  33 (require 'elmo-signal)
  34 (require 'elmo-msgdb)
  35
  36 (defvar elmo-filter-number-filename "number-list"
  37   "File name for message number database.")
  38
  39 ;;; ELMO filter folder
  40 (eval-and-compile
  41   (luna-define-class elmo-filter-folder (elmo-folder)
  42                      (condition target require-msgdb number-list flag-count))
  43   (luna-define-internal-accessors 'elmo-filter-folder))
  44
  45 (luna-define-method elmo-folder-initialize ((folder elmo-filter-folder)
  46                                             name)
  47   (let (pair)
  48     (setq pair (elmo-parse-search-condition name))
  49     (elmo-filter-folder-set-condition-internal folder (car pair))
  50     (if (string-match "^ */\\(.*\\)$" (cdr pair))
  51         (elmo-filter-folder-set-target-internal
  52          folder
  53          (elmo-get-folder (elmo-match-string 1 (cdr pair))))
  54       (error "Folder syntax error `%s'" (elmo-folder-name-internal folder)))
  55     (elmo-filter-folder-set-require-msgdb-internal
  56      folder
  57      (elmo-folder-search-requires-msgdb-p
  58       (elmo-filter-folder-target-internal folder)
  59       (elmo-filter-folder-condition-internal folder)))
  60     (elmo-filter-connect-signals
  61      folder
  62      (elmo-filter-folder-target-internal folder))
  63     folder))
  64
  65 (defun elmo-filter-connect-signals (folder target)
  66   (elmo-connect-signal
  67    target 'flag-changing folder
  68    (elmo-define-signal-handler (folder target number old-flags new-flags)
  69      (elmo-filter-add-flag-count folder old-flags -1)
  70      (elmo-filter-add-flag-count folder new-flags)
  71      (elmo-emit-signal 'flag-changing folder number old-flags new-flags))
  72    (elmo-define-signal-filter (folder target number)
  73      (memq number (elmo-folder-list-messages folder nil t))))
  74   (elmo-connect-signal
  75    target 'flag-changed folder
  76    (elmo-define-signal-handler (folder target numbers)
  77      (let ((filterd (elmo-list-filter
  78                      (elmo-folder-list-messages folder nil t)
  79                      numbers)))
  80        (when filterd
  81          (elmo-emit-signal 'flag-changed folder filterd)))))
  82   (elmo-connect-signal
  83    target 'status-changed folder
  84    (elmo-define-signal-handler (folder target numbers)
  85      (let ((filterd (elmo-list-filter
  86                      (elmo-folder-list-messages folder nil t)
  87                      numbers)))
  88        (when filterd
  89          (elmo-emit-signal 'status-changed folder filterd)))))
  90   (elmo-connect-signal
  91    target 'update-overview folder
  92    (elmo-define-signal-handler (folder target number)
  93      (elmo-emit-signal 'update-overview folder number))
  94    (elmo-define-signal-filter (folder target number)
  95      (memq number (elmo-folder-list-messages folder nil t)))))
  96
  97 (defun elmo-filter-number-list-load (dir)
  98   (elmo-object-load
  99    (expand-file-name elmo-filter-number-filename dir)))
 100
 101 (defun elmo-filter-number-list-save (dir number-list)
 102   (elmo-object-save
 103    (expand-file-name elmo-filter-number-filename dir)
 104    number-list))
 105
 106 (defun elmo-filter-folder-number-list (folder)
 107   (or (elmo-filter-folder-number-list-internal folder)
 108       (elmo-filter-folder-set-number-list-internal
 109        folder
 110        (elmo-filter-number-list-load (elmo-folder-msgdb-path folder)))))
 111
 112 (defsubst elmo-filter-folder-countup-message-flags (folder numbers
 113                                                            &optional delta)
 114   (let ((flag-count (elmo-filter-folder-flag-count-internal folder))
 115         (delta (or delta 1))
 116         elem)
 117     (dolist (number numbers)
 118       (dolist (flag (elmo-message-flags folder number))
 119         (if (setq elem (assq flag flag-count))
 120             (setcdr elem (+ (cdr elem) delta))
 121           (setq flag-count (cons (cons flag delta) flag-count)))))
 122     (elmo-filter-folder-set-flag-count-internal folder flag-count)))
 123
 124 (defun elmo-filter-add-flag-count (folder flags &optional delta)
 125   (let ((flag-count (elmo-filter-folder-flag-count-internal folder))
 126         (delta (or delta 1))
 127         elem)
 128     (dolist (flag flags)
 129       (if (setq elem (assq flag flag-count))
 130           (setcdr elem (+ (cdr elem) delta))
 131         (setq flag-count (cons (cons flag delta) flag-count))))
 132     (elmo-filter-folder-set-flag-count-internal folder flag-count)))
 133
 134 (defun elmo-filter-folder-flag-count (folder)
 135   (or (elmo-filter-folder-flag-count-internal folder)
 136       (elmo-filter-folder-countup-message-flags
 137        folder
 138        (elmo-folder-list-messages folder t t))))
 139
 140 (defun elmo-filter-folder-copy-flag-count (flag-counts)
 141   (mapcar (lambda (pair) (cons (car pair) (cdr pair))) flag-counts))
 142
 143 (luna-define-method elmo-folder-open :after ((folder elmo-filter-folder)
 144                                              &optional load-msgdb)
 145   (when load-msgdb
 146     (elmo-filter-folder-number-list folder)
 147     (elmo-filter-folder-flag-count folder)
 148     (elmo-folder-msgdb (elmo-filter-folder-target-internal folder))))
 149
 150 (luna-define-method elmo-folder-open-internal ((folder elmo-filter-folder))
 151   (elmo-folder-open-internal (elmo-filter-folder-target-internal folder)))
 152
 153 (luna-define-method elmo-folder-check ((folder elmo-filter-folder))
 154   (when (elmo-filter-folder-require-msgdb-internal folder)
 155     (elmo-folder-synchronize (elmo-filter-folder-target-internal folder))))
 156
 157 (luna-define-method elmo-folder-close-internal ((folder elmo-filter-folder))
 158   (elmo-folder-close-internal (elmo-filter-folder-target-internal folder)))
 159
 160 (luna-define-method elmo-folder-close ((folder elmo-filter-folder))
 161   (elmo-generic-folder-close folder)
 162   (elmo-filter-folder-set-number-list-internal folder nil)
 163   (elmo-filter-folder-set-flag-count-internal folder nil)
 164   (elmo-folder-close (elmo-filter-folder-target-internal folder)))
 165
 166 (luna-define-method elmo-folder-commit ((folder elmo-filter-folder))
 167   (elmo-folder-commit (elmo-filter-folder-target-internal folder))
 168   (when (elmo-folder-persistent-p folder)
 169     (elmo-folder-set-info-max-by-numdb
 170      folder
 171      (elmo-folder-list-messages folder nil 'in-msgdb))
 172     (elmo-msgdb-killed-list-save
 173      (elmo-folder-msgdb-path folder)
 174      (elmo-folder-killed-list-internal folder))
 175     (elmo-filter-number-list-save
 176      (elmo-folder-msgdb-path folder)
 177      (elmo-filter-folder-number-list-internal folder))))
 178
 179 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 180                                                     elmo-filter-folder))
 181   (expand-file-name
 182    (elmo-replace-string-as-filename (elmo-folder-name-internal folder))
 183    (expand-file-name "filter" elmo-msgdb-directory)))
 184
 185 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder
 186                                                           elmo-filter-folder)
 187                                                          condition)
 188   (elmo-folder-search-requires-msgdb-p
 189    (elmo-filter-folder-target-internal folder) condition))
 190
 191 (luna-define-method elmo-folder-newsgroups ((folder elmo-filter-folder))
 192   (elmo-folder-newsgroups (elmo-filter-folder-target-internal folder)))
 193
 194 (luna-define-method elmo-find-fetch-strategy ((folder elmo-filter-folder)
 195                                               number
 196                                               &optional
 197                                               ignore-cache
 198                                               require-entireness)
 199   (elmo-find-fetch-strategy
 200    (elmo-filter-folder-target-internal folder)
 201    number ignore-cache require-entireness))
 202
 203 (luna-define-method elmo-folder-get-primitive-list ((folder
 204                                                      elmo-filter-folder))
 205   (elmo-folder-get-primitive-list (elmo-filter-folder-target-internal folder)))
 206
 207 (luna-define-method elmo-folder-contains-type ((folder elmo-filter-folder)
 208                                                type)
 209   (elmo-folder-contains-type
 210    (elmo-filter-folder-target-internal folder)
 211    type))
 212
 213 (luna-define-method elmo-folder-append-buffer ((folder elmo-filter-folder)
 214                                                &optional flag number)
 215   (elmo-folder-append-buffer
 216    (elmo-filter-folder-target-internal folder)
 217    flag number))
 218
 219 (luna-define-method elmo-message-fetch-bodystructure ((folder
 220                                                        elmo-filter-folder)
 221                                                       number strategy)
 222   (elmo-message-fetch-bodystructure
 223    (elmo-filter-folder-target-internal folder)
 224    number strategy))
 225
 226 (luna-define-method elmo-message-fetch ((folder elmo-filter-folder)
 227                                         number strategy
 228                                         &optional unseen section)
 229   (elmo-message-fetch (elmo-filter-folder-target-internal folder)
 230                       number strategy unseen section))
 231
 232 (luna-define-method elmo-folder-delete-messages ((folder elmo-filter-folder)
 233                                                  numbers)
 234   (let ((flag-count (elmo-filter-folder-copy-flag-count
 235                      (elmo-filter-folder-flag-count-internal folder)))
 236         (messages (copy-sequence
 237                    (elmo-filter-folder-number-list-internal folder)))
 238         success)
 239     (elmo-folder-detach-messages folder numbers)
 240     (unless (setq success
 241                   (elmo-folder-delete-messages
 242                    (elmo-filter-folder-target-internal folder) numbers))
 243       (elmo-filter-folder-set-flag-count-internal folder flag-count)
 244       (elmo-filter-folder-set-number-list-internal folder messages))
 245     success))
 246
 247 (luna-define-method elmo-folder-list-messages ((folder elmo-filter-folder)
 248                                                &optional visible-only in-msgdb)
 249   (let ((list (if in-msgdb
 250                   t
 251                 (elmo-folder-list-messages-internal folder visible-only)))
 252         (killed-list (elmo-folder-killed-list-internal folder)))
 253     (unless (listp list)
 254       ;; Use current list.
 255       (setq list (elmo-filter-folder-number-list folder)))
 256     (if visible-only
 257         (elmo-living-messages list killed-list)
 258       (if (and in-msgdb killed-list list)
 259           (elmo-uniq-sorted-list
 260            (sort (nconc (elmo-number-set-to-number-list killed-list) list) #'<)
 261            #'eq)
 262         list))))
 263
 264 (luna-define-method elmo-folder-list-messages-internal
 265   ((folder elmo-filter-folder) &optional nohide)
 266   (let ((target (elmo-filter-folder-target-internal folder)))
 267     (if (or (elmo-folder-plugged-p target)
 268             (not (elmo-folder-persistent-p folder)))
 269         ;; search target folder
 270         (elmo-folder-search
 271          target
 272          (elmo-filter-folder-condition-internal folder))
 273       ;; not available
 274       t)))
 275
 276 (luna-define-method elmo-folder-list-flagged ((folder elmo-filter-folder)
 277                                               flag
 278                                               &optional in-msgdb)
 279   (elmo-list-filter
 280    (elmo-folder-list-messages folder nil t)
 281    (elmo-folder-list-flagged
 282     (elmo-filter-folder-target-internal folder) flag in-msgdb)))
 283
 284 (luna-define-method elmo-folder-list-subfolders ((folder elmo-filter-folder)
 285                                                  &optional one-level)
 286   (let* ((target (elmo-filter-folder-target-internal folder))
 287          (prefix (and (string-match
 288                        (concat "^\\(.*\\)"
 289                                (regexp-quote
 290                                 (elmo-folder-name-internal
 291                                  target))
 292                                "$")
 293                        (elmo-folder-name-internal folder))
 294                       (match-string 1 (elmo-folder-name-internal
 295                                        folder)))))
 296     (elmo-mapcar-list-of-list
 297      (lambda (x) (concat prefix x))
 298      (elmo-folder-list-subfolders target one-level))))
 299
 300 (luna-define-method elmo-folder-diff :around ((folder elmo-filter-folder))
 301   (let ((condition (elmo-filter-folder-condition-internal folder))
 302         diff)
 303     (if (vectorp condition)
 304         (cond
 305          ((and (string= (elmo-filter-key condition) "flag")
 306                (or (string= (elmo-filter-value condition) "any")
 307                    (string= (elmo-filter-value condition) "digest")
 308                    (string= (elmo-filter-value condition) "unread")))
 309           (setq diff (elmo-folder-diff (elmo-filter-folder-target-internal
 310                                         folder)))
 311           (if (consp (cdr diff))
 312               ;; new unread unread
 313               (list (car diff) (nth 1 diff) (nth 1 diff))
 314             (cons (car diff) (car diff))))
 315          ((string= "last" (elmo-filter-key condition))
 316           (luna-call-next-method))
 317          (t
 318           (cons nil (cdr (elmo-folder-diff (elmo-filter-folder-target-internal
 319                                             folder))))))
 320       (luna-call-next-method))))
 321
 322 (luna-define-method elmo-folder-status ((folder elmo-filter-folder))
 323   (elmo-folder-status
 324    (elmo-filter-folder-target-internal folder)))
 325
 326 (luna-define-method elmo-folder-exists-p ((folder elmo-filter-folder))
 327   (elmo-folder-exists-p (elmo-filter-folder-target-internal folder)))
 328
 329 (luna-define-method elmo-folder-creatable-p ((folder elmo-filter-folder))
 330   (elmo-folder-creatable-p (elmo-filter-folder-target-internal folder)))
 331
 332 (luna-define-method elmo-folder-writable-p ((folder elmo-filter-folder))
 333   (elmo-folder-writable-p (elmo-filter-folder-target-internal folder)))
 334
 335 (luna-define-method elmo-folder-create ((folder elmo-filter-folder))
 336   (elmo-folder-create (elmo-filter-folder-target-internal folder)))
 337
 338 (luna-define-method elmo-folder-search ((folder elmo-filter-folder)
 339                                         condition &optional numbers)
 340   ;; search from messages in this folder
 341   (let ((result (elmo-folder-search
 342                  (elmo-filter-folder-target-internal folder)
 343                  condition
 344                  (elmo-folder-list-messages folder))))
 345     (if numbers
 346         (elmo-list-filter numbers result)
 347       result)))
 348
 349 (luna-define-method elmo-message-use-cache-p ((folder elmo-filter-folder)
 350                                               number)
 351   (elmo-message-use-cache-p (elmo-filter-folder-target-internal folder)
 352                             number))
 353
 354 (luna-define-method elmo-folder-message-file-p ((folder elmo-filter-folder))
 355   (elmo-folder-message-file-p (elmo-filter-folder-target-internal folder)))
 356
 357 (luna-define-method elmo-folder-local-p ((folder elmo-filter-folder))
 358   (elmo-folder-local-p (elmo-filter-folder-target-internal folder)))
 359
 360 (luna-define-method elmo-folder-plugged-p ((folder elmo-filter-folder))
 361   (elmo-folder-plugged-p (elmo-filter-folder-target-internal folder)))
 362
 363 (luna-define-method elmo-folder-set-plugged ((folder elmo-filter-folder)
 364                                              plugged &optional add)
 365   (elmo-folder-set-plugged (elmo-filter-folder-target-internal folder)
 366                            plugged add))
 367
 368 (luna-define-method elmo-message-file-name ((folder elmo-filter-folder)
 369                                             number)
 370   (elmo-message-file-name (elmo-filter-folder-target-internal folder)
 371                           number))
 372
 373 (luna-define-method elmo-message-flag-available-p ((folder
 374                                                     elmo-filter-folder) number
 375                                                     flag)
 376   (elmo-message-flag-available-p
 377    (elmo-filter-folder-target-internal folder)
 378    number flag))
 379
 380 (luna-define-method elmo-message-flags ((folder elmo-filter-folder) number)
 381   (elmo-message-flags (elmo-filter-folder-target-internal folder)
 382                       number))
 383
 384 (luna-define-method elmo-message-set-cached ((folder elmo-filter-folder)
 385                                              number cached)
 386   (elmo-message-set-cached
 387    (elmo-filter-folder-target-internal folder) number cached))
 388
 389 (luna-define-method elmo-message-number ((folder elmo-filter-folder)
 390                                          message-id)
 391   (elmo-message-number (elmo-filter-folder-target-internal folder)
 392                        message-id))
 393
 394 (luna-define-method elmo-message-entity ((folder elmo-filter-folder) key)
 395   (elmo-message-entity (elmo-filter-folder-target-internal folder) key))
 396
 397 (luna-define-method elmo-message-entity-parent ((folder elmo-filter-folder)
 398                                                 entity)
 399   (let ((parent (elmo-message-entity-parent
 400                  (elmo-filter-folder-target-internal folder)
 401                  entity)))
 402     (when (memq (elmo-message-entity-number parent)
 403                 (elmo-filter-folder-number-list folder))
 404       parent)))
 405
 406 (luna-define-method elmo-folder-flag-table ((folder elmo-filter-folder)
 407                                             &optional if-exists)
 408   (elmo-folder-flag-table (elmo-filter-folder-target-internal folder)
 409                           if-exists))
 410
 411 (luna-define-method elmo-folder-close-flag-table ((folder elmo-filter-folder))
 412   (elmo-folder-close-flag-table (elmo-filter-folder-target-internal folder)))
 413
 414 (luna-define-method elmo-folder-count-flags ((folder elmo-filter-folder))
 415   (elmo-filter-folder-flag-count folder))
 416
 417 (luna-define-method elmo-folder-set-flag ((folder elmo-filter-folder)
 418                                           numbers
 419                                           flag
 420                                           &optional is-local)
 421   (elmo-folder-set-flag (elmo-filter-folder-target-internal folder)
 422                         numbers flag is-local))
 423
 424 (luna-define-method elmo-folder-unset-flag ((folder elmo-filter-folder)
 425                                             numbers
 426                                             flag
 427                                             &optional is-local)
 428   (elmo-folder-unset-flag (elmo-filter-folder-target-internal folder)
 429                           numbers flag is-local))
 430
 431 (luna-define-method elmo-message-folder ((folder elmo-filter-folder)
 432                                          number)
 433   (elmo-message-folder (elmo-filter-folder-target-internal folder) number))
 434
 435 (luna-define-method elmo-message-field ((folder elmo-filter-folder)
 436                                         number field &optional type)
 437   (elmo-message-field
 438    (elmo-filter-folder-target-internal folder) number field type))
 439
 440 (luna-define-method elmo-message-set-field ((folder elmo-filter-folder)
 441                                             number field value)
 442   (elmo-message-set-field
 443    (elmo-filter-folder-target-internal folder) number field value))
 444
 445 (luna-define-method elmo-folder-clear ((folder elmo-filter-folder)
 446                                        &optional keep-killed)
 447   (unless keep-killed
 448     (elmo-folder-set-killed-list-internal folder nil))
 449   (elmo-filter-folder-set-number-list-internal folder nil)
 450   (elmo-filter-folder-set-flag-count-internal folder nil))
 451
 452 (luna-define-method elmo-folder-synchronize ((folder elmo-filter-folder)
 453                                              &optional
 454                                              disable-killed
 455                                              ignore-msgdb
 456                                              no-check
 457                                              mask)
 458   (let ((killed-list (elmo-folder-killed-list-internal folder))
 459         numbers)
 460     (unless no-check
 461       (when (elmo-filter-folder-require-msgdb-internal folder)
 462         (elmo-folder-synchronize (elmo-filter-folder-target-internal folder)
 463                                  disable-killed
 464                                  ignore-msgdb
 465                                  no-check
 466                                  mask)))
 467     (setq numbers (elmo-folder-list-messages folder (not disable-killed)))
 468     (when (and numbers
 469                (not (elmo-filter-folder-require-msgdb-internal folder)))
 470       (elmo-folder-synchronize (elmo-filter-folder-target-internal folder)
 471                                'disable-killed
 472                                ignore-msgdb
 473                                no-check
 474                                (if mask
 475                                    (elmo-list-filter mask numbers)
 476                                  numbers)))
 477     (when (and disable-killed ignore-msgdb)
 478       (elmo-folder-set-killed-list-internal folder nil))
 479     (elmo-filter-folder-set-number-list-internal folder numbers)
 480     (elmo-filter-folder-set-flag-count-internal folder nil)
 481     0))
 482
 483 (luna-define-method elmo-folder-detach-messages ((folder elmo-filter-folder)
 484                                                  numbers)
 485   (elmo-filter-folder-countup-message-flags folder numbers -1)
 486   (elmo-filter-folder-set-number-list-internal
 487    folder
 488    (elmo-list-delete numbers (elmo-filter-folder-number-list folder) #'delq))
 489   t)
 490
 491 (luna-define-method elmo-folder-length ((folder elmo-filter-folder))
 492   (length (elmo-filter-folder-number-list-internal folder)))
 493
 494 (require 'product)
 495 (product-provide (provide 'elmo-filter) (require 'elmo-version))
 496
 497 ;;; elmo-filter.el ends here