elmo/elmo-flag.el

   1 ;;; elmo-flag.el --- global flag handling.
   2
   3 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28 (require 'elmo-util)
  29 (require 'elmo-localdir)
  30 (eval-when-compile (require 'cl))
  31
  32 ;;; Code:
  33 (defcustom elmo-global-flags '(important)
  34   "A list of flag symbol which is managed globally by the flag folder."
  35   :type '(repeat symbol)
  36   :group 'elmo)
  37
  38 (defcustom elmo-local-flags '(unread any digest)
  39   "A list of flag symbol which is not treated as global flag."
  40   :type '(repeat symbol)
  41   :group 'elmo)
  42
  43 (defvar elmo-global-flag-folder-alist nil
  44   "Internal variable to hold global-flag-folder structures.")
  45
  46 (eval-and-compile
  47   (defconst elmo-flag-char-regexp "]!#$&'+,./0-9:;<=>?@A-Z[^_`a-z|}~-"))
  48
  49 (defun elmo-flag-valid-p (flag)
  50   (string-match (eval-when-compile
  51                   (concat "^[" elmo-flag-char-regexp "]+$"))
  52                 (if (stringp flag) flag (symbol-name flag))))
  53
  54 (eval-and-compile
  55   (luna-define-class elmo-flag-folder (elmo-localdir-folder)
  56                      (flag minfo minfo-hash max-number))
  57   (luna-define-internal-accessors 'elmo-flag-folder))
  58
  59 (luna-define-method elmo-folder-initialize ((folder
  60                                              elmo-flag-folder)
  61                                             name)
  62   (unless (string-match (eval-when-compile
  63                           (concat "^flag\\(/\\(["
  64                                   elmo-flag-char-regexp
  65                                   "]+\\)\\)?$"))
  66                         name)
  67     (error "Error in folder name `%s'" (elmo-folder-name-internal folder)))
  68   (if (match-beginning 1)
  69       (setq name (match-string 2 name))
  70     (setq name (symbol-name (car elmo-global-flags)))
  71     (elmo-folder-set-name-internal
  72      folder
  73      (concat (elmo-folder-name-internal folder) "/" name)))
  74   (or (cdr (assq (intern name) elmo-global-flag-folder-alist))
  75       (let ((flag (intern name))
  76             msgdb-path)
  77         (elmo-flag-folder-set-flag-internal folder flag)
  78         (unless (elmo-global-flag-p flag)
  79           (setq elmo-global-flags
  80                 (nconc elmo-global-flags (list flag))))
  81         ;; must be AFTER set flag slot.
  82         (setq msgdb-path (elmo-folder-msgdb-path folder))
  83         (unless (file-directory-p msgdb-path)
  84           (elmo-make-directory msgdb-path))
  85         (elmo-localdir-folder-set-dir-name-internal
  86          folder
  87          msgdb-path)
  88         (elmo-localdir-folder-set-directory-internal
  89          folder
  90          msgdb-path)
  91         (if (file-exists-p (expand-file-name "max" msgdb-path))
  92             (elmo-flag-folder-set-max-number-internal
  93              folder
  94              (elmo-object-load (expand-file-name "max" msgdb-path))))
  95         (elmo-flag-folder-set-minfo
  96          folder
  97          (and (file-exists-p (expand-file-name ".minfo" msgdb-path))
  98               (elmo-object-load (expand-file-name ".minfo" msgdb-path))))
  99         (setq elmo-global-flag-folder-alist
 100               (cons (cons flag folder) elmo-global-flag-folder-alist))
 101         folder)))
 102
 103 (defun elmo-flag-folder-set-minfo (folder minfo)
 104   (let ((hash (elmo-make-hash (length minfo))))
 105     (dolist (elem minfo)
 106       (elmo-set-hash-val (nth 1 elem) elem hash)
 107       (elmo-set-hash-val (concat "#" (number-to-string (nth 2 elem)))
 108                          elem hash)
 109       (dolist (pair (car elem))
 110         (elmo-set-hash-val (concat (number-to-string (cdr pair))
 111                                    ":" (car pair))
 112                            elem hash)))
 113     (elmo-flag-folder-set-minfo-internal folder minfo)
 114     (elmo-flag-folder-set-minfo-hash-internal folder hash)))
 115
 116 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-flag-folder))
 117   (expand-file-name (concat "flag/"
 118                             (elmo-replace-string-as-filename
 119                              (symbol-name
 120                               (elmo-flag-folder-flag-internal folder))))
 121                     elmo-msgdb-directory))
 122
 123 (luna-define-method elmo-folder-commit :after ((folder
 124                                                 elmo-flag-folder))
 125   (elmo-object-save
 126    (expand-file-name ".minfo" (elmo-folder-msgdb-path folder))
 127    (elmo-flag-folder-minfo-internal folder))
 128   (if (elmo-flag-folder-max-number-internal folder)
 129       (elmo-object-save
 130        (expand-file-name "max" (elmo-folder-msgdb-path folder))
 131        (elmo-flag-folder-max-number-internal folder))))
 132
 133 (luna-define-method elmo-folder-list-subfolders ((folder elmo-flag-folder)
 134                                                  &optional one-level)
 135   (mapcar (lambda (flag)
 136             (concat
 137              (elmo-folder-prefix-internal folder)
 138              (symbol-name (elmo-folder-type-internal folder))
 139              "/"
 140              (symbol-name flag)))
 141           elmo-global-flags))
 142
 143 (defun elmo-flag-folder-delete-message (folder number
 144                                                &optional keep-referrer)
 145   (let* ((elem (elmo-get-hash-val (concat "#" (number-to-string number))
 146                                   (elmo-flag-folder-minfo-hash-internal
 147                                    folder)))
 148          target-folder key)
 149     (dolist (pair (car elem))
 150       (when (and (car pair) (cdr pair))
 151         (elmo-clear-hash-val (concat (number-to-string (cdr pair)) ":"
 152                                      (car pair))
 153                              (elmo-flag-folder-minfo-hash-internal
 154                               folder))
 155         (unless keep-referrer
 156           (setq target-folder (elmo-get-folder (car pair)))
 157           (elmo-folder-open target-folder 'load-msgdb)
 158           ;; Unset the flag of the original folder.
 159           ;; (XXX Should the message-id checked?)
 160           (elmo-message-unset-flag target-folder (cdr pair)
 161                                    (elmo-flag-folder-flag-internal folder))
 162           (elmo-folder-close target-folder))))
 163     (elmo-clear-hash-val (concat "#" (number-to-string number))
 164                          (elmo-flag-folder-minfo-hash-internal
 165                           folder))
 166     (elmo-clear-hash-val (nth 1 elem) (elmo-flag-folder-minfo-hash-internal
 167                                        folder))
 168     (elmo-flag-folder-set-minfo-internal
 169      folder
 170      (delq elem (elmo-flag-folder-minfo-internal folder))))
 171   t)
 172
 173 (luna-define-method elmo-folder-delete-messages-internal ((folder
 174                                                            elmo-flag-folder)
 175                                                           numbers)
 176   (dolist (number numbers)
 177     (elmo-flag-folder-delete-message folder number)
 178     (elmo-localdir-delete-message folder number))
 179   (elmo-folder-commit folder)
 180   t)
 181
 182 ;; Same as localdir except that the flag is always the flag.
 183 (luna-define-method elmo-folder-msgdb-create ((folder elmo-flag-folder)
 184                                               numbers
 185                                               flag-table)
 186   (when numbers
 187     (let ((dir (elmo-localdir-folder-directory-internal folder))
 188           (new-msgdb (elmo-make-msgdb))
 189           (flags (list (elmo-flag-folder-flag-internal folder)))
 190           entity)
 191       (elmo-with-progress-display (elmo-folder-msgdb-create (length numbers))
 192           "Creating msgdb"
 193         (dolist (number numbers)
 194           (when (setq entity (elmo-localdir-msgdb-create-entity
 195                               new-msgdb dir number))
 196             (elmo-msgdb-append-entity new-msgdb entity flags))
 197           (elmo-progress-notify 'elmo-folder-msgdb-create)))
 198       new-msgdb)))
 199
 200 (defun elmo-folder-append-messages-*-flag (dst-folder
 201                                            src-folder
 202                                            numbers
 203                                            same-number)
 204   (let ((flag (elmo-flag-folder-flag-internal dst-folder)))
 205     (dolist (number numbers)
 206       (elmo-global-flag-set flag src-folder number
 207                             (elmo-message-field
 208                              src-folder number 'message-id)))
 209     (elmo-folder-set-flag src-folder numbers flag))
 210   numbers)
 211
 212 (luna-define-method elmo-folder-append-buffer ((folder elmo-flag-folder)
 213                                                &optional flag number)
 214   (error "Cannot append to the flag folder"))
 215
 216 (luna-define-method elmo-folder-unset-flag :before ((folder elmo-flag-folder)
 217                                                     numbers
 218                                                     flag
 219                                                     &optional is-local)
 220   (when (eq flag (elmo-flag-folder-flag-internal folder))
 221     (error "Cannot unset flag `%s' in this folder" flag)))
 222
 223 ;;; Utilities
 224
 225 (defmacro elmo-flag-get-folder (flag)
 226   "Get the flag folder structure for FLAG."
 227   `(when (memq ,flag elmo-global-flags)
 228      (elmo-get-folder (concat  "'flag/" (symbol-name ,flag)))))
 229
 230 (defun elmo-flag-folder-referrer (folder number)
 231   "Return a list of referrer message information.
 232 Each element is a cons cell like following:
 233 \(FNAME . NUMBER\)
 234 FNAME is the name of the folder which the message is contained.
 235 NUMBER is the number of the message."
 236   (when (eq (elmo-folder-type-internal folder) 'flag)
 237     (car (elmo-get-hash-val (concat "#" (number-to-string number))
 238                             (elmo-flag-folder-minfo-hash-internal
 239                              folder)))))
 240
 241 ;;; Global-Flag API
 242 (defun elmo-global-flag-p (flag)
 243   "Return non-nil when FLAG is global."
 244   (memq flag elmo-global-flags))
 245
 246 (defun elmo-global-flags (fname number)
 247   "Return a list of global flags for the message.
 248 FNAME is the name string of the folder.
 249 NUMBER is the number of the message."
 250   (let ((flag-list elmo-global-flags)
 251         folder matches)
 252     (while flag-list
 253       (setq folder (elmo-flag-get-folder (car flag-list)))
 254       (when (elmo-get-hash-val
 255              (concat (number-to-string number) ":" fname)
 256              (elmo-flag-folder-minfo-hash-internal folder))
 257         (setq matches (cons (elmo-flag-folder-flag-internal folder)
 258                             matches)))
 259       (setq flag-list (cdr flag-list)))
 260     matches))
 261
 262 (defun elmo-folder-list-global-flag-messages (folder flag)
 263   "List messages which have global flag.
 264 FOLDER is the elmo folder structure.
 265 FLAG is the symbol of the flag."
 266   (when (elmo-global-flag-p flag)
 267     (let ((flag-folder (elmo-flag-get-folder flag))
 268           result number)
 269       (dolist (elem (elmo-flag-folder-minfo-internal flag-folder))
 270         (if (setq number (elmo-message-number folder (nth 1 elem)))
 271             (setq result (cons number result))))
 272       result)))
 273
 274 ;;;
 275 ;; minfo is a list of following cell.
 276 ;; ((((FNAME . NUMBER)...(FNAME . NUMBER)) MESSAGE-ID NUMBER-IN-FLAG-FOLDER)
 277 ;; minfo-index is the hash table of above with following indice;
 278 (defun elmo-global-flags-set (flags folder number message-id)
 279   "Set global flags to the message.
 280 FLAGS is a list of symbol of the flag.
 281 FOLDER is the elmo folder structure.
 282 NUMBER is the message number."
 283   (dolist (flag flags)
 284     (elmo-global-flag-set flag folder number message-id)))
 285
 286 (defun elmo-local-flag-p (flag)
 287   "Return non-nil when flag is not appropriate for global flag."
 288   (memq flag elmo-local-flags))
 289
 290 (defsubst elmo-global-flag-set-internal (flag folder number message-id)
 291   (when (elmo-local-flag-p flag)
 292     (error "Cannot treat `%s' as global flag" flag))
 293   (when message-id
 294     (let ((flag-folder (elmo-flag-get-folder flag))
 295           filename cache new-file new-number elem)
 296       (if (setq elem (elmo-get-hash-val
 297                       message-id
 298                       (elmo-flag-folder-minfo-hash-internal
 299                        flag-folder)))
 300           ;; Same ID already exists.
 301           (when (and folder number
 302                      (not (member (cons (elmo-folder-name-internal folder)
 303                                         number) (car elem))))
 304             (setcar elem
 305                     (cons (cons (elmo-folder-name-internal folder)
 306                                 number) (car elem)))
 307             (setq new-number (nth 2 elem))
 308             (elmo-set-hash-val (concat (number-to-string number)
 309                                        ":" (elmo-folder-name-internal
 310                                             folder))
 311                                elem
 312                                (elmo-flag-folder-minfo-hash-internal
 313                                 flag-folder)))
 314         ;; Append new element.
 315         (elmo-flag-folder-set-max-number-internal
 316          flag-folder
 317          (+ (or (elmo-flag-folder-max-number-internal flag-folder)
 318                 ;; This is the first time.
 319                 (car (elmo-folder-status flag-folder)))
 320             1))
 321         (setq new-file
 322               (expand-file-name
 323                (int-to-string
 324                 (setq new-number
 325                       (elmo-flag-folder-max-number-internal flag-folder)))
 326                (elmo-localdir-folder-directory-internal flag-folder)))
 327         (cond
 328          ((setq filename (elmo-message-file-name folder number))
 329           (elmo-copy-file filename new-file))
 330          ((and (setq cache (elmo-file-cache-get message-id))
 331                (eq (elmo-file-cache-status cache) 'entire))
 332           (elmo-copy-file (elmo-file-cache-path cache) new-file))
 333          (t
 334           (with-temp-buffer
 335             (elmo-message-fetch folder number
 336                                 (elmo-make-fetch-strategy 'entire))
 337             (write-region-as-binary (point-min) (point-max) new-file nil
 338                                     'no-msg))))
 339         (elmo-flag-folder-set-minfo-internal
 340          flag-folder
 341          (cons
 342           (setq elem (list
 343                       (when (and folder number)
 344                         (list (cons (elmo-folder-name-internal folder)
 345                                     number)))
 346                       message-id
 347                       new-number))
 348           (elmo-flag-folder-minfo-internal flag-folder)))
 349         (when (and folder number)
 350           (elmo-set-hash-val (concat (number-to-string number)
 351                                      ":" (elmo-folder-name-internal
 352                                           folder))
 353                              elem
 354                              (elmo-flag-folder-minfo-hash-internal
 355                               flag-folder)))
 356         (elmo-set-hash-val message-id elem
 357                            (elmo-flag-folder-minfo-hash-internal
 358                             flag-folder))
 359         (elmo-set-hash-val (concat "#" (number-to-string new-number)) elem
 360                            (elmo-flag-folder-minfo-hash-internal
 361                             flag-folder)))
 362       (elmo-folder-commit flag-folder)
 363       new-number)))
 364
 365 (defun elmo-global-flag-set (flag folder number message-id)
 366   "Set global flag to the message.
 367 FLAG is a symbol of the flag.
 368 FOLDER is the elmo folder structure.
 369 NUMBER is the message number.
 370 MESSAGE-ID is the message-id of the message."
 371   (when (elmo-global-flag-p flag)
 372     (elmo-global-flag-set-internal flag folder number message-id)))
 373
 374 (defun elmo-global-flag-detach (flag folder number &optional delete-if-none)
 375   "Detach the message from the global flag.
 376 FOLDER is the folder structure.
 377 NUMBERS is the message number.
 378 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 379 the message is not flagged in any folder.
 380 If DELETE-IF-NONE is a symbol `always',
 381 delete message without flagged in other folder."
 382   (unless (and (eq (elmo-folder-type-internal folder) 'flag)
 383                (eq (elmo-flag-folder-flag-internal folder) flag))
 384     (let ((flag-folder (elmo-flag-get-folder flag))
 385           elem key)
 386       (when flag-folder
 387         (setq key (concat (number-to-string number) ":"
 388                           (elmo-folder-name-internal folder))
 389               elem (elmo-get-hash-val
 390                     key
 391                     (elmo-flag-folder-minfo-hash-internal flag-folder)))
 392         (when elem
 393           (setcar elem (delete (cons (elmo-folder-name-internal folder)
 394                                      number) (car elem)))
 395           (elmo-clear-hash-val key (elmo-flag-folder-minfo-hash-internal
 396                                     flag-folder))
 397           ;; Does not have any referrer, remove.
 398           (when (and delete-if-none
 399                      (or (eq delete-if-none 'always)
 400                          (null (car elem))))
 401             (elmo-flag-folder-delete-message flag-folder (nth 2 elem)
 402                                              (null (car elem)))
 403             (elmo-localdir-delete-message flag-folder (nth 2 elem))
 404             (elmo-folder-commit flag-folder)))))))
 405
 406 (defun elmo-global-flag-detach-messages (folder numbers &optional
 407                                                 delete-if-none)
 408   "Detach all messages specified from all global flags.
 409 FOLDER is the folder structure.
 410 NUMBERS is the message number list.
 411 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 412 the message is not flagged in any folder."
 413   (unless (eq (elmo-folder-type-internal folder) 'flag)
 414     (dolist (flag elmo-global-flags)
 415       (dolist (number numbers)
 416         (elmo-global-flag-detach flag folder number delete-if-none)))))
 417
 418 (defun elmo-global-flag-replace-referrer (old-folder new-folder)
 419   (dolist (flag elmo-global-flags)
 420     (let* ((folder (elmo-flag-get-folder flag))
 421            (minfo (elmo-flag-folder-minfo-internal folder))
 422            modified)
 423       (dolist (entry minfo)
 424         (let ((pair (assoc old-folder (nth 0 entry))))
 425           (when pair
 426             (setcar pair new-folder)
 427             (setq modified t))))
 428       (when modified
 429         (elmo-flag-folder-set-minfo folder minfo)
 430         (elmo-folder-commit folder)))))
 431
 432 (defun elmo-get-global-flags (&optional flags ignore-preserved)
 433   "Get global flags.
 434 Return value is a subset of optional argument FLAGS.
 435 If FLAGS is `t', all global flags becomes candidates.
 436 If optional IGNORE-PRESERVED is non-nil, preserved flags
 437 \(answered, cached, new, unread\) are not included."
 438   (let ((result (copy-sequence (if (eq flags t)
 439                                    (setq flags elmo-global-flags)
 440                                  flags))))
 441     (while flags
 442       (unless (elmo-global-flag-p (car flags))
 443         (setq result (delq (car flags) result)))
 444       (setq flags (cdr flags)))
 445     (when ignore-preserved
 446       (dolist (flag elmo-preserved-flags)
 447         (setq result (delq flag result))))
 448     result))
 449
 450 (defun elmo-global-flags-initialize (&optional additional-flags)
 451   (let ((dir (expand-file-name "flag" elmo-msgdb-directory)))
 452     (setq elmo-global-flags
 453           (elmo-list-delete
 454            elmo-local-flags
 455            (elmo-uniq-list
 456             (append
 457              elmo-global-flags
 458              additional-flags
 459              (and (file-directory-p dir)
 460                   (mapcar (lambda (x)
 461                             (intern (elmo-recover-string-from-filename x)))
 462                           (elmo-list-delete
 463                            '(".." ".")
 464                            (directory-files dir))))))
 465            #'delq))))
 466
 467 ;;; To migrate from global mark folder
 468 (defvar elmo-global-mark-filename "global-mark"
 469   "Obsolete variable. (Just for migration)")
 470
 471 (defun elmo-global-mark-migrate ()
 472   "Migrate from 'mark to 'flag. For automatic migration."
 473   (when (and (file-exists-p (expand-file-name elmo-global-mark-filename
 474                                               elmo-msgdb-directory))
 475              (elmo-global-flag-p 'important)
 476              (not (file-exists-p (elmo-folder-msgdb-path
 477                                   (elmo-flag-get-folder 'important)))))
 478     (elmo-global-mark-upgrade)))
 479
 480 (defun elmo-global-mark-upgrade ()
 481   "Upgrade old `global-mark' structure."
 482   (interactive)
 483   (when (file-exists-p (expand-file-name
 484                         elmo-global-mark-filename elmo-msgdb-directory))
 485     (message "Upgrading flag structure...")
 486     (when (elmo-global-flag-p 'important)
 487       (let ((global-marks
 488              (elmo-object-load
 489               (expand-file-name
 490                elmo-global-mark-filename elmo-msgdb-directory)))
 491             (folder (elmo-flag-get-folder 'important))
 492             file-cache)
 493         (dolist (elem global-marks)
 494           (setq file-cache (elmo-file-cache-get (car elem)))
 495           (when (eq (elmo-file-cache-status file-cache) 'entire)
 496             (elmo-global-flag-set 'important nil nil (car elem))))))
 497     (message "Upgrading flag structure...done")))
 498
 499 (luna-define-method elmo-folder-delete :around ((folder elmo-flag-folder))
 500   (let ((flag (elmo-flag-folder-flag-internal folder)))
 501     (when (luna-call-next-method)
 502       (setq elmo-global-flags (delq flag elmo-global-flags))
 503       (setq elmo-global-flag-folder-alist
 504             (delq (assq flag elmo-global-flag-folder-alist)
 505                   elmo-global-flag-folder-alist))
 506       t)))
 507
 508 (require 'product)
 509 (product-provide (provide 'elmo-flag) (require 'elmo-version))
 510
 511 ;;; elmo-flag.el ends here