elmo/elmo-flag.el

   1 ;;; elmo-flag.el --- global flag handling.
   2
   3 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28 (require 'elmo-util)
  29 (require 'elmo-localdir)
  30 (eval-when-compile (require 'cl))
  31
  32 ;;; Code:
  33 (defcustom elmo-global-flags '(important)
  34   "A list of flag symbol which is managed globally by the flag folder."
  35   :type '(repeat symbol)
  36   :group 'elmo)
  37
  38 (defcustom elmo-local-flags '(unread any digest)
  39   "A list of flag symbol which is not treated as global flag."
  40   :type '(repeat symbol)
  41   :group 'elmo)
  42
  43 (defvar elmo-global-flag-folder-alist nil
  44   "Internal variable to hold global-flag-folder structures.")
  45
  46 (eval-and-compile
  47   (defconst elmo-flag-char-regexp "]!#$&'+,./0-9:;<=>?@A-Z[^_`a-z|}~-"))
  48
  49 (defun elmo-flag-valid-p (flag)
  50   (string-match (eval-when-compile
  51                   (concat "^[" elmo-flag-char-regexp "]+$"))
  52                 (if (stringp flag) flag (symbol-name flag))))
  53
  54 (eval-and-compile
  55   (luna-define-class elmo-flag-folder (elmo-localdir-folder)
  56                      (flag minfo minfo-hash max-number))
  57   (luna-define-internal-accessors 'elmo-flag-folder))
  58
  59 (luna-define-method elmo-folder-initialize ((folder
  60                                              elmo-flag-folder)
  61                                             name)
  62   (unless (string-match (eval-when-compile
  63                           (concat "^flag\\(/\\(["
  64                                   elmo-flag-char-regexp
  65                                   "]+\\)\\)?$"))
  66                         name)
  67     (error "Error in folder name `%s'" (elmo-folder-name-internal folder)))
  68   (if (match-beginning 1)
  69       (setq name (match-string 2 name))
  70     (setq name (symbol-name (car elmo-global-flags)))
  71     (elmo-folder-set-name-internal
  72      folder
  73      (concat (elmo-folder-name-internal folder) "/" name)))
  74   (or (cdr (assq (intern name) elmo-global-flag-folder-alist))
  75       (let ((flag (intern name))
  76             msgdb-path)
  77         (elmo-flag-folder-set-flag-internal folder flag)
  78         (unless (elmo-global-flag-p flag)
  79           (setq elmo-global-flags
  80                 (nconc elmo-global-flags (list flag))))
  81         ;; must be AFTER set flag slot.
  82         (setq msgdb-path (elmo-folder-msgdb-path folder))
  83         (unless (file-directory-p msgdb-path)
  84           (elmo-make-directory msgdb-path))
  85         (elmo-localdir-folder-set-dir-name-internal
  86          folder
  87          msgdb-path)
  88         (elmo-localdir-folder-set-directory-internal
  89          folder
  90          msgdb-path)
  91         (if (file-exists-p (expand-file-name "max" msgdb-path))
  92             (elmo-flag-folder-set-max-number-internal
  93              folder
  94              (elmo-object-load (expand-file-name "max" msgdb-path))))
  95         (elmo-flag-folder-set-minfo
  96          folder
  97          (and (file-exists-p (expand-file-name ".minfo" msgdb-path))
  98               (elmo-object-load (expand-file-name ".minfo" msgdb-path))))
  99         (setq elmo-global-flag-folder-alist
 100               (cons (cons flag folder) elmo-global-flag-folder-alist))
 101         folder)))
 102
 103 (defun elmo-flag-folder-set-minfo (folder minfo)
 104   (let ((hash (elmo-make-hash (length minfo))))
 105     (dolist (elem minfo)
 106       (elmo-set-hash-val (nth 1 elem) elem hash)
 107       (elmo-set-hash-val (concat "#" (number-to-string (nth 2 elem)))
 108                          elem hash)
 109       (dolist (pair (car elem))
 110         (elmo-set-hash-val (concat (number-to-string (cdr pair))
 111                                    ":" (car pair))
 112                            elem hash)))
 113     (elmo-flag-folder-set-minfo-internal folder minfo)
 114     (elmo-flag-folder-set-minfo-hash-internal folder hash)))
 115
 116 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-flag-folder))
 117   (expand-file-name (concat "flag/"
 118                             (elmo-replace-string-as-filename
 119                              (symbol-name
 120                               (elmo-flag-folder-flag-internal folder))))
 121                     elmo-msgdb-directory))
 122
 123 (luna-define-method elmo-folder-commit :after ((folder
 124                                                 elmo-flag-folder))
 125   (elmo-object-save
 126    (expand-file-name ".minfo" (elmo-folder-msgdb-path folder))
 127    (elmo-flag-folder-minfo-internal folder))
 128   (if (elmo-flag-folder-max-number-internal folder)
 129       (elmo-object-save
 130        (expand-file-name "max" (elmo-folder-msgdb-path folder))
 131        (elmo-flag-folder-max-number-internal folder))))
 132
 133 (luna-define-method elmo-folder-list-subfolders ((folder elmo-flag-folder)
 134                                                  &optional one-level)
 135   (mapcar (lambda (flag)
 136             (concat
 137              (elmo-folder-prefix-internal folder)
 138              (symbol-name (elmo-folder-type-internal folder))
 139              "/"
 140              (symbol-name flag)))
 141           elmo-global-flags))
 142
 143 (defun elmo-flag-folder-delete-message (folder number
 144                                                &optional keep-referrer)
 145   (let* ((elem (elmo-get-hash-val (concat "#" (number-to-string number))
 146                                   (elmo-flag-folder-minfo-hash-internal
 147                                    folder)))
 148          target-folder key)
 149     (dolist (pair (car elem))
 150       (when (and (car pair) (cdr pair))
 151         (elmo-clear-hash-val (concat (number-to-string (cdr pair)) ":"
 152                                      (car pair))
 153                              (elmo-flag-folder-minfo-hash-internal
 154                               folder))
 155         (unless keep-referrer
 156           (setq target-folder (elmo-get-folder (car pair)))
 157           (elmo-folder-open target-folder 'load-msgdb)
 158           ;; Unset the flag of the original folder.
 159           ;; (XXX Should the message-id checked?)
 160           (elmo-message-unset-flag target-folder (cdr pair)
 161                                    (elmo-flag-folder-flag-internal folder))
 162           (elmo-folder-close target-folder))))
 163     (elmo-clear-hash-val (concat "#" (number-to-string number))
 164                          (elmo-flag-folder-minfo-hash-internal
 165                           folder))
 166     (elmo-clear-hash-val (nth 1 elem) (elmo-flag-folder-minfo-hash-internal
 167                                        folder))
 168     (elmo-flag-folder-set-minfo-internal
 169      folder
 170      (delq elem (elmo-flag-folder-minfo-internal folder))))
 171   t)
 172
 173 (luna-define-method elmo-folder-delete-messages-internal ((folder
 174                                                            elmo-flag-folder)
 175                                                           numbers)
 176   (dolist (number numbers)
 177     (elmo-flag-folder-delete-message folder number)
 178     (elmo-localdir-delete-message folder number))
 179   (elmo-folder-commit folder)
 180   t)
 181
 182 ;; Same as localdir except that the flag is always the flag.
 183 (luna-define-method elmo-folder-msgdb-create ((folder elmo-flag-folder)
 184                                               numbers
 185                                               flag-table)
 186   (when numbers
 187     (let ((dir (elmo-localdir-folder-directory-internal folder))
 188           (new-msgdb (elmo-make-msgdb))
 189           entity (i 0)
 190           (len (length numbers)))
 191       (message "Creating msgdb...")
 192       (while numbers
 193         (when (setq entity (elmo-localdir-msgdb-create-entity
 194                             new-msgdb dir (car numbers)))
 195           (elmo-msgdb-append-entity new-msgdb entity
 196                                     (list (elmo-flag-folder-flag-internal
 197                                            folder))))
 198         (when (> len elmo-display-progress-threshold)
 199           (setq i (1+ i))
 200           (elmo-display-progress
 201            'elmo-flag-folder-msgdb-create "Creating msgdb..."
 202            (/ (* i 100) len)))
 203         (setq numbers (cdr numbers)))
 204       (message "Creating msgdb...done")
 205       new-msgdb)))
 206
 207 (defun elmo-folder-append-messages-*-flag (dst-folder
 208                                            src-folder
 209                                            numbers
 210                                            same-number)
 211   (let ((flag (elmo-flag-folder-flag-internal dst-folder)))
 212     (dolist (number numbers)
 213       (elmo-global-flag-set flag src-folder number
 214                             (elmo-message-field
 215                              src-folder number 'message-id)))
 216     (elmo-folder-set-flag src-folder numbers flag))
 217   numbers)
 218
 219 (luna-define-method elmo-folder-append-buffer ((folder elmo-flag-folder)
 220                                                &optional flag number)
 221   (error "Cannot append to the flag folder"))
 222
 223 (luna-define-method elmo-folder-unset-flag :before ((folder elmo-flag-folder)
 224                                                     numbers
 225                                                     flag
 226                                                     &optional is-local)
 227   (when (eq flag (elmo-flag-folder-flag-internal folder))
 228     (error "Cannot unset flag `%s' in this folder" flag)))
 229
 230 ;;; Utilities
 231
 232 (defmacro elmo-flag-get-folder (flag)
 233   "Get the flag folder structure for FLAG."
 234   `(when (memq ,flag elmo-global-flags)
 235      (elmo-get-folder (concat  "'flag/" (symbol-name ,flag)))))
 236
 237 (defun elmo-flag-folder-referrer (folder number)
 238   "Return a list of referrer message information.
 239 Each element is a cons cell like following:
 240 \(FNAME . NUMBER\)
 241 FNAME is the name of the folder which the message is contained.
 242 NUMBER is the number of the message."
 243   (when (eq (elmo-folder-type-internal folder) 'flag)
 244     (car (elmo-get-hash-val (concat "#" (number-to-string number))
 245                             (elmo-flag-folder-minfo-hash-internal
 246                              folder)))))
 247
 248 ;;; Global-Flag API
 249 (defun elmo-global-flag-p (flag)
 250   "Return non-nil when FLAG is global."
 251   (memq flag elmo-global-flags))
 252
 253 (defun elmo-global-flags (fname number)
 254   "Return a list of global flags for the message.
 255 FNAME is the name string of the folder.
 256 NUMBER is the number of the message."
 257   (let ((flag-list elmo-global-flags)
 258         folder matches)
 259     (while flag-list
 260       (setq folder (elmo-flag-get-folder (car flag-list)))
 261       (when (elmo-get-hash-val
 262              (concat (number-to-string number) ":" fname)
 263              (elmo-flag-folder-minfo-hash-internal folder))
 264         (setq matches (cons (elmo-flag-folder-flag-internal folder)
 265                             matches)))
 266       (setq flag-list (cdr flag-list)))
 267     matches))
 268
 269 (defun elmo-folder-list-global-flag-messages (folder flag)
 270   "List messages which have global flag.
 271 FOLDER is the elmo folder structure.
 272 FLAG is the symbol of the flag."
 273   (when (elmo-global-flag-p flag)
 274     (let ((flag-folder (elmo-flag-get-folder flag))
 275           result number)
 276       (dolist (elem (elmo-flag-folder-minfo-internal flag-folder))
 277         (if (setq number (elmo-message-number folder (nth 1 elem)))
 278             (setq result (cons number result))))
 279       result)))
 280
 281 ;;;
 282 ;; minfo is a list of following cell.
 283 ;; ((((FNAME . NUMBER)...(FNAME . NUMBER)) MESSAGE-ID NUMBER-IN-FLAG-FOLDER)
 284 ;; minfo-index is the hash table of above with following indice;
 285 (defun elmo-global-flags-set (flags folder number message-id)
 286   "Set global flags to the message.
 287 FLAGS is a list of symbol of the flag.
 288 FOLDER is the elmo folder structure.
 289 NUMBER is the message number."
 290   (dolist (flag flags)
 291     (elmo-global-flag-set flag folder number message-id)))
 292
 293 (defun elmo-local-flag-p (flag)
 294   "Return non-nil when flag is not appropriate for global flag."
 295   (memq flag elmo-local-flags))
 296
 297 (defsubst elmo-global-flag-set-internal (flag folder number message-id)
 298   (when (elmo-local-flag-p flag)
 299     (error "Cannot treat `%s' as global flag" flag))
 300   (when message-id
 301     (let ((flag-folder (elmo-flag-get-folder flag))
 302           cache new-file new-number elem)
 303       (if (setq elem (elmo-get-hash-val
 304                       message-id
 305                       (elmo-flag-folder-minfo-hash-internal
 306                        flag-folder)))
 307           ;; Same ID already exists.
 308           (when (and folder number
 309                      (not (member (cons (elmo-folder-name-internal folder)
 310                                         number) (car elem))))
 311             (setcar elem
 312                     (cons (cons (elmo-folder-name-internal folder)
 313                                 number) (car elem)))
 314             (setq new-number (nth 2 elem))
 315             (elmo-set-hash-val (concat (number-to-string number)
 316                                        ":" (elmo-folder-name-internal
 317                                             folder))
 318                                elem
 319                                (elmo-flag-folder-minfo-hash-internal
 320                                 flag-folder)))
 321         ;; Append new element.
 322         (elmo-flag-folder-set-max-number-internal
 323          flag-folder
 324          (+ (or (elmo-flag-folder-max-number-internal flag-folder)
 325                 ;; This is the first time.
 326                 (car (elmo-folder-status flag-folder)))
 327             1))
 328         (setq new-file
 329               (expand-file-name
 330                (int-to-string
 331                 (setq new-number
 332                       (elmo-flag-folder-max-number-internal flag-folder)))
 333                (elmo-localdir-folder-directory-internal flag-folder)))
 334         (with-temp-buffer
 335           (setq cache (and message-id (elmo-file-cache-get message-id)))
 336           (if (and cache (eq (elmo-file-cache-status cache) 'entire))
 337               (elmo-copy-file (elmo-file-cache-path cache)
 338                               new-file)
 339             (when (and folder number)
 340               (elmo-message-fetch folder number
 341                                   (elmo-make-fetch-strategy 'entire))
 342               (write-region-as-binary (point-min) (point-max) new-file nil
 343                                       'no-msg))))
 344         (elmo-flag-folder-set-minfo-internal
 345          flag-folder
 346          (cons
 347           (setq elem (list
 348                       (when (and folder number)
 349                         (list (cons (elmo-folder-name-internal folder)
 350                                     number)))
 351                       message-id
 352                       new-number))
 353           (elmo-flag-folder-minfo-internal flag-folder)))
 354         (when (and folder number)
 355           (elmo-set-hash-val (concat (number-to-string number)
 356                                      ":" (elmo-folder-name-internal
 357                                           folder))
 358                              elem
 359                              (elmo-flag-folder-minfo-hash-internal
 360                               flag-folder)))
 361         (elmo-set-hash-val message-id elem
 362                            (elmo-flag-folder-minfo-hash-internal
 363                             flag-folder))
 364         (elmo-set-hash-val (concat "#" (number-to-string new-number)) elem
 365                            (elmo-flag-folder-minfo-hash-internal
 366                             flag-folder)))
 367       (elmo-folder-commit flag-folder)
 368       new-number)))
 369
 370 (defun elmo-global-flag-set (flag folder number message-id)
 371   "Set global flag to the message.
 372 FLAG is a symbol of the flag.
 373 FOLDER is the elmo folder structure.
 374 NUMBER is the message number.
 375 MESSAGE-ID is the message-id of the message."
 376   (when (elmo-global-flag-p flag)
 377     (elmo-global-flag-set-internal flag folder number message-id)))
 378
 379 (defun elmo-global-flag-detach (flag folder number &optional delete-if-none)
 380   "Detach the message from the global flag.
 381 FOLDER is the folder structure.
 382 NUMBERS is the message number.
 383 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 384 the message is not flagged in any folder.
 385 If DELETE-IF-NONE is a symbol `always',
 386 delete message without flagged in other folder."
 387   (unless (and (eq (elmo-folder-type-internal folder) 'flag)
 388                (eq (elmo-flag-folder-flag-internal folder) flag))
 389     (let ((flag-folder (elmo-flag-get-folder flag))
 390           elem key)
 391       (when flag-folder
 392         (setq key (concat (number-to-string number) ":"
 393                           (elmo-folder-name-internal folder))
 394               elem (elmo-get-hash-val
 395                     key
 396                     (elmo-flag-folder-minfo-hash-internal flag-folder)))
 397         (when elem
 398           (setcar elem (delete (cons (elmo-folder-name-internal folder)
 399                                      number) (car elem)))
 400           (elmo-clear-hash-val key (elmo-flag-folder-minfo-hash-internal
 401                                     flag-folder))
 402           ;; Does not have any referrer, remove.
 403           (when (and delete-if-none
 404                      (or (eq delete-if-none 'always)
 405                          (null (car elem))))
 406             (elmo-flag-folder-delete-message flag-folder (nth 2 elem)
 407                                              (null (car elem)))
 408             (elmo-localdir-delete-message flag-folder (nth 2 elem))
 409             (elmo-folder-commit flag-folder)))))))
 410
 411 (defun elmo-global-flag-detach-messages (folder numbers &optional
 412                                                 delete-if-none)
 413   "Detach all messages specified from all global flags.
 414 FOLDER is the folder structure.
 415 NUMBERS is the message number list.
 416 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 417 the message is not flagged in any folder."
 418   (unless (eq (elmo-folder-type-internal folder) 'flag)
 419     (dolist (flag elmo-global-flags)
 420       (dolist (number numbers)
 421         (elmo-global-flag-detach flag folder number delete-if-none)))))
 422
 423 (defun elmo-global-flag-replace-referrer (old-folder new-folder)
 424   (dolist (flag elmo-global-flags)
 425     (let* ((folder (elmo-flag-get-folder flag))
 426            (minfo (elmo-flag-folder-minfo-internal folder))
 427            modified)
 428       (dolist (entry minfo)
 429         (let ((pair (assoc old-folder (nth 0 entry))))
 430           (when pair
 431             (setcar pair new-folder)
 432             (setq modified t))))
 433       (when modified
 434         (elmo-flag-folder-set-minfo folder minfo)
 435         (elmo-folder-commit folder)))))
 436
 437 (defun elmo-get-global-flags (&optional flags ignore-preserved)
 438   "Get global flags.
 439 Return value is a subset of optional argument FLAGS.
 440 If FLAGS is `t', all global flags becomes candidates.
 441 If optional IGNORE-PRESERVED is non-nil, preserved flags
 442 \(answered, cached, new, unread\) are not included."
 443   (let ((result (copy-sequence (if (eq flags t)
 444                                    (setq flags elmo-global-flags)
 445                                  flags))))
 446     (while flags
 447       (unless (elmo-global-flag-p (car flags))
 448         (setq result (delq (car flags) result)))
 449       (setq flags (cdr flags)))
 450     (when ignore-preserved
 451       (dolist (flag elmo-preserved-flags)
 452         (setq result (delq flag result))))
 453     result))
 454
 455 (defun elmo-global-flags-initialize (&optional additional-flags)
 456   (let ((dir (expand-file-name "flag" elmo-msgdb-directory)))
 457     (setq elmo-global-flags
 458           (elmo-list-delete
 459            elmo-local-flags
 460            (elmo-uniq-list
 461             (append
 462              elmo-global-flags
 463              additional-flags
 464              (and (file-directory-p dir)
 465                   (mapcar (lambda (x)
 466                             (intern (elmo-recover-string-from-filename x)))
 467                           (elmo-list-delete
 468                            '(".." ".")
 469                            (directory-files dir))))))
 470            #'delq))))
 471
 472 ;;; To migrate from global mark folder
 473 (defvar elmo-global-mark-filename "global-mark"
 474   "Obsolete variable. (Just for migration)")
 475
 476 (defun elmo-global-mark-migrate ()
 477   "Migrate from 'mark to 'flag. For automatic migration."
 478   (when (and (file-exists-p (expand-file-name elmo-global-mark-filename
 479                                               elmo-msgdb-directory))
 480              (elmo-global-flag-p 'important)
 481              (not (file-exists-p (elmo-folder-msgdb-path
 482                                   (elmo-flag-get-folder 'important)))))
 483     (elmo-global-mark-upgrade)))
 484
 485 (defun elmo-global-mark-upgrade ()
 486   "Upgrade old `global-mark' structure."
 487   (interactive)
 488   (when (file-exists-p (expand-file-name
 489                         elmo-global-mark-filename elmo-msgdb-directory))
 490     (message "Upgrading flag structure...")
 491     (when (elmo-global-flag-p 'important)
 492       (let ((global-marks
 493              (elmo-object-load
 494               (expand-file-name
 495                elmo-global-mark-filename elmo-msgdb-directory)))
 496             (folder (elmo-flag-get-folder 'important))
 497             file-cache)
 498         (dolist (elem global-marks)
 499           (setq file-cache (elmo-file-cache-get (car elem)))
 500           (when (eq (elmo-file-cache-status file-cache) 'entire)
 501             (elmo-global-flag-set 'important nil nil (car elem))))))
 502     (message "Upgrading flag structure...done")))
 503
 504 (luna-define-method elmo-folder-delete :around ((folder elmo-flag-folder))
 505   (let ((flag (elmo-flag-folder-flag-internal folder)))
 506     (when (luna-call-next-method)
 507       (setq elmo-global-flags (delq flag elmo-global-flags))
 508       (setq elmo-global-flag-folder-alist
 509             (delq (assq flag elmo-global-flag-folder-alist)
 510                   elmo-global-flag-folder-alist))
 511       t)))
 512
 513 (require 'product)
 514 (product-provide (provide 'elmo-flag) (require 'elmo-version))
 515
 516 ;;; elmo-flag.el ends here