elmo/elmo-flag.el

   1 ;;; elmo-flag.el --- global flag handling.
   2
   3 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28 (require 'elmo-util)
  29 (require 'elmo-localdir)
  30 (eval-when-compile (require 'cl))
  31
  32 ;;; Code:
  33 (defcustom elmo-global-flag-list '(important)
  34   "A list of flag symbol which is managed globally by the flag folder."
  35   :type '(repeat symbol)
  36   :group 'elmo)
  37
  38 (defvar elmo-global-flag-folder-alist nil
  39   "Internal variable to hold global-flag-folder structures.")
  40
  41 (eval-and-compile
  42   (luna-define-class elmo-flag-folder (elmo-localdir-folder)
  43                      (flag minfo minfo-hash))
  44   (luna-define-internal-accessors 'elmo-flag-folder))
  45
  46 (luna-define-method elmo-folder-initialize ((folder
  47                                              elmo-flag-folder)
  48                                             name)
  49   (if (string-match "flag/\\([a-z]+\\)" name)
  50       (setq name (match-string 1 name))
  51     (setq name (symbol-name (car elmo-global-flag-list))))
  52   (or (cdr (assq (intern name) elmo-global-flag-folder-alist))
  53       (let (msgdb-path)
  54         (elmo-flag-folder-set-flag-internal folder (intern name))
  55         ;; must be AFTER set flag slot.
  56         (setq msgdb-path (elmo-folder-msgdb-path folder))
  57         (unless (file-directory-p msgdb-path)
  58           (elmo-make-directory msgdb-path))
  59         (elmo-localdir-folder-set-dir-name-internal
  60          folder
  61          msgdb-path)
  62         (elmo-localdir-folder-set-directory-internal
  63          folder
  64          msgdb-path)
  65         (if (file-exists-p (expand-file-name ".minfo" msgdb-path))
  66             (elmo-flag-folder-set-minfo-internal
  67              folder
  68              (elmo-object-load (expand-file-name ".minfo" msgdb-path))))
  69         (elmo-flag-folder-set-minfo-hash-internal
  70          folder
  71          (elmo-make-hash (length (elmo-flag-folder-minfo-internal folder))))
  72         (dolist (elem (elmo-flag-folder-minfo-internal folder))
  73           (elmo-set-hash-val (nth 1 elem) elem
  74                              (elmo-flag-folder-minfo-hash-internal folder))
  75           (elmo-set-hash-val (concat "#" (number-to-string (nth 2 elem)))
  76                              elem
  77                              (elmo-flag-folder-minfo-hash-internal folder))
  78           (dolist (pair (car elem))
  79             (elmo-set-hash-val (concat (number-to-string (cdr pair))
  80                                        ":" (car pair))
  81                                elem
  82                                (elmo-flag-folder-minfo-hash-internal folder))))
  83         (setq elmo-global-flag-folder-alist
  84               (cons (cons (intern name) folder) elmo-global-flag-folder-alist))
  85         folder)))
  86
  87 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-flag-folder))
  88   (expand-file-name (concat "flag/"
  89                             (symbol-name
  90                              (elmo-flag-folder-flag-internal folder)))
  91                     elmo-msgdb-directory))
  92
  93 (luna-define-method elmo-folder-commit :after ((folder
  94                                                 elmo-flag-folder))
  95   (elmo-object-save
  96    (expand-file-name ".minfo" (elmo-folder-msgdb-path folder))
  97    (elmo-flag-folder-minfo-internal folder)))
  98
  99 (defun elmo-flag-folder-delete-message (folder number
 100                                                &optional keep-referrer)
 101   (let* ((elem (elmo-get-hash-val (concat "#" (number-to-string number))
 102                                   (elmo-flag-folder-minfo-hash-internal
 103                                    folder)))
 104          target-folder key)
 105     (dolist (pair (car elem))
 106       (when (and (car pair) (cdr pair))
 107         (unless keep-referrer
 108           (setq target-folder (elmo-make-folder (car pair)))
 109           (elmo-folder-open target-folder 'load-msgdb)
 110           ;; Unset the flag of the original folder.
 111           ;; (XXX Should the message-id checked?)
 112           (elmo-message-unset-flag target-folder (cdr pair)
 113                                    (elmo-flag-folder-flag-internal folder))
 114           (elmo-folder-close target-folder))
 115         (elmo-clear-hash-val (concat (number-to-string (cdr pair)) ":"
 116                                      (car pair))
 117                              (elmo-flag-folder-minfo-hash-internal
 118                               folder))))
 119     (elmo-clear-hash-val (concat "#" (number-to-string number))
 120                          (elmo-flag-folder-minfo-hash-internal
 121                           folder))
 122     (elmo-clear-hash-val (nth 1 elem) (elmo-flag-folder-minfo-hash-internal
 123                                        folder))
 124     (elmo-flag-folder-set-minfo-internal
 125      folder
 126      (delq elem (elmo-flag-folder-minfo-internal folder))))
 127   t)
 128
 129 (luna-define-method elmo-folder-delete-messages ((folder
 130                                                   elmo-flag-folder)
 131                                                  numbers)
 132   (dolist (number numbers)
 133     (elmo-flag-folder-delete-message folder number)
 134     (elmo-localdir-delete-message folder number))
 135   (elmo-folder-commit folder)
 136   t)
 137
 138 ;; Same as localdir except that the flag is always the flag.
 139 (luna-define-method elmo-folder-msgdb-create ((folder elmo-flag-folder)
 140                                               numbers
 141                                               flag-table)
 142   (when numbers
 143     (let ((dir (elmo-localdir-folder-directory-internal folder))
 144           (new-msgdb (elmo-make-msgdb))
 145           entity (i 0)
 146           (len (length numbers)))
 147       (message "Creating msgdb...")
 148       (while numbers
 149         (when (setq entity (elmo-localdir-msgdb-create-entity
 150                             dir (car numbers)))
 151           (elmo-msgdb-append-entity new-msgdb entity
 152                                     (list (elmo-flag-folder-flag-internal
 153                                            folder))))
 154         (when (> len elmo-display-progress-threshold)
 155           (setq i (1+ i))
 156           (elmo-display-progress
 157            'elmo-flag-folder-msgdb-create "Creating msgdb..."
 158            (/ (* i 100) len)))
 159         (setq numbers (cdr numbers)))
 160       (message "Creating msgdb...done")
 161       new-msgdb)))
 162
 163 (luna-define-method elmo-folder-append-messages ((folder elmo-flag-folder)
 164                                                  src-folder
 165                                                  numbers
 166                                                  &optional same-number)
 167   (dolist (number numbers)
 168     (elmo-global-flag-set (elmo-flag-folder-flag-internal folder)
 169                           src-folder number (elmo-message-field
 170                                              src-folder
 171                                              number
 172                                              'message-id)))
 173   numbers)
 174
 175 (luna-define-method elmo-folder-append-buffer ((folder elmo-flag-folder)
 176                                                unread
 177                                                &optional number)
 178   (error "Cannot append to the flag folder"))
 179
 180 ;;; Utilities
 181
 182 (defmacro elmo-flag-get-folder (flag)
 183   "Get the flag folder structure for FLAG."
 184   `(when (memq ,flag elmo-global-flag-list)
 185      (elmo-make-folder (concat  "'flag/" (symbol-name ,flag)))))
 186
 187 (defun elmo-flag-folder-referrer (folder number)
 188   "Return a list of referrer message information.
 189 Each element is a cons cell like following:
 190 \(FNAME . NUMBER\)
 191 FNAME is the name of the folder which the message is contained.
 192 NUMBER is the number of the message."
 193   (when (eq (elmo-folder-type-internal folder) 'flag)
 194     (car (elmo-get-hash-val (concat "#" (number-to-string number))
 195                             (elmo-flag-folder-minfo-hash-internal
 196                              folder)))))
 197
 198 ;;; Global-Flag API
 199 (defun elmo-global-flag-initialize ()
 200   "Initialize flag folders.
 201 This function is necessary to be called before using `elmo-flag-folder'."
 202   (unless elmo-global-flag-folder-alist
 203     (dolist (flag elmo-global-flag-list)
 204       (setq elmo-global-flag-folder-alist
 205             (cons (elmo-make-folder
 206                    (concat "'flag/" (symbol-name flag)))
 207                   elmo-global-flag-folder-alist)))))
 208
 209 (defun elmo-global-flag-p (flag)
 210   "Return non-nil when FLAG is global."
 211   (memq flag elmo-global-flag-list))
 212
 213 (defun elmo-global-flags (fname number)
 214   "Return a list of global flags for the message.
 215 FNAME is the name string of the folder.
 216 NUMBER is the number of the message."
 217   (let ((flag-list elmo-global-flag-list)
 218         folder matches)
 219     (while flag-list
 220       (setq folder (elmo-flag-get-folder (car flag-list)))
 221       (when (elmo-get-hash-val
 222              (concat (number-to-string number) ":" fname)
 223              (elmo-flag-folder-minfo-hash-internal folder))
 224         (setq matches (cons (elmo-flag-folder-flag-internal folder)
 225                             matches)))
 226       (setq flag-list (cdr flag-list)))
 227     matches))
 228
 229 ;;;
 230 ;; minfo is a list of following cell.
 231 ;; ((((FNAME . NUMBER)...(FNAME . NUMBER)) MESSAGE-ID NUMBER-IN-FLAG-FOLDER)
 232 ;; minfo-index is the hash table of above with following indice;
 233 (defun elmo-global-flags-set (flags folder number message-id)
 234   "Set global flags to the message.
 235 FLAGS is a list of symbol of the flag.
 236 FOLDER is the elmo folder structure.
 237 NUMBER is the message number."
 238   (dolist (flag flags)
 239     (elmo-global-flag-set flag folder number message-id)))
 240
 241 (defsubst elmo-global-flag-set-internal (flag folder number message-id)
 242   (when message-id
 243     (let ((flag-folder (elmo-flag-get-folder flag))
 244           cache new-file new-number elem)
 245       (if (setq elem (elmo-get-hash-val
 246                       message-id
 247                       (elmo-flag-folder-minfo-hash-internal
 248                        flag-folder)))
 249           ;; Same ID already exists.
 250           (when (and folder number
 251                      (not (member (cons (elmo-folder-name-internal folder)
 252                                         number) (car elem))))
 253             (setcar elem
 254                     (cons (cons (elmo-folder-name-internal folder)
 255                                 number) (car elem)))
 256             (setq new-number (nth 2 elem))
 257             (elmo-set-hash-val (concat (number-to-string number)
 258                                        ":" (elmo-folder-name-internal
 259                                             folder))
 260                                elem
 261                                (elmo-flag-folder-minfo-hash-internal
 262                                 flag-folder)))
 263         ;; Append new element.
 264         (setq new-file
 265               (expand-file-name
 266                (int-to-string
 267                 (setq new-number (1+ (car (elmo-folder-status flag-folder)))))
 268                (elmo-localdir-folder-directory-internal flag-folder)))
 269         (with-temp-buffer
 270           (setq cache (and message-id (elmo-file-cache-get message-id)))
 271           (if (and cache (eq (elmo-file-cache-status cache) 'entire))
 272               (elmo-copy-file (elmo-file-cache-path cache)
 273                               new-file)
 274             (when (and folder number)
 275               (elmo-message-fetch folder number (elmo-make-fetch-strategy
 276                                                  'entire)
 277                                   nil (current-buffer))
 278               (write-region-as-binary (point-min) (point-max) new-file nil
 279                                       'no-msg))))
 280         (elmo-flag-folder-set-minfo-internal
 281          flag-folder
 282          (cons
 283           (setq elem (list
 284                       (when (and folder number)
 285                         (list (cons (elmo-folder-name-internal folder)
 286                                     number)))
 287                       message-id
 288                       new-number))
 289           (elmo-flag-folder-minfo-internal flag-folder)))
 290         (when (and folder number)
 291           (elmo-set-hash-val (concat (number-to-string number)
 292                                      ":" (elmo-folder-name-internal
 293                                           folder))
 294                              elem
 295                              (elmo-flag-folder-minfo-hash-internal
 296                               flag-folder)))
 297         (elmo-set-hash-val message-id elem
 298                            (elmo-flag-folder-minfo-hash-internal
 299                             flag-folder))
 300         (elmo-set-hash-val (concat "#" (number-to-string new-number)) elem
 301                            (elmo-flag-folder-minfo-hash-internal
 302                             flag-folder)))
 303       (elmo-folder-commit flag-folder)
 304       new-number)))
 305
 306 (defun elmo-global-flag-set (flag folder number message-id)
 307   "Set global flag to the message.
 308 FLAG is a symbol of the flag.
 309 FOLDER is the elmo folder structure.
 310 NUMBER is the message number.
 311 MESSAGE-ID is the message-id of the message."
 312   (when (elmo-global-flag-p flag)
 313     (elmo-global-flag-set-internal flag folder number message-id)))
 314
 315 (defun elmo-global-flag-detach (flag folder number &optional delete-if-none)
 316   "Detach the message from the global flag.
 317 FOLDER is the folder structure.
 318 NUMBERS is the message number.
 319 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 320 the message is not flagged in any folder."
 321   (unless (eq (elmo-folder-type-internal folder) 'flag)
 322     (let ((flag-folder (elmo-flag-get-folder flag))
 323           elem key)
 324       (when flag-folder
 325         (setq key (concat (number-to-string number) ":"
 326                           (elmo-folder-name-internal folder))
 327               elem (elmo-get-hash-val
 328                     key
 329                     (elmo-flag-folder-minfo-hash-internal flag-folder)))
 330         (when elem
 331           (setcar elem (delete (cons (elmo-folder-name-internal folder)
 332                                      number) (car elem)))
 333           (elmo-clear-hash-val key (elmo-flag-folder-minfo-hash-internal
 334                                     flag-folder))
 335           ;; Does not have any referrer, remove.
 336           (when (and delete-if-none (null (car elem)))
 337             (elmo-flag-folder-delete-message flag-folder (nth 2 elem) 'keep)
 338             (elmo-localdir-delete-message flag-folder (nth 2 elem))
 339             (elmo-folder-commit flag-folder)))))))
 340
 341 (defun elmo-global-flag-detach-messages (folder numbers &optional
 342                                                 delete-if-none)
 343   "Detach all messages specified from all global flags.
 344 FOLDER is the folder structure.
 345 NUMBERS is the message number list.
 346 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 347 the message is not flagged in any folder."
 348   (unless (eq (elmo-folder-type-internal folder) 'flag)
 349     (dolist (flag elmo-global-flag-list)
 350       (dolist (number numbers)
 351         (elmo-global-flag-detach flag folder number delete-if-none)))))
 352
 353 ;;; To migrate from global mark folder
 354 (defvar elmo-global-mark-filename "global-mark"
 355   "Obsolete variable. (Just for migration)")
 356
 357 (defun elmo-global-mark-upgrade ()
 358   "Upgrade old `global-mark' structure."
 359   (interactive)
 360   (when (file-exists-p (expand-file-name
 361                         elmo-global-mark-filename elmo-msgdb-directory))
 362     (message "Upgrading flag structure...")
 363     (elmo-global-flag-initialize)
 364     (when (elmo-global-flag-p 'important)
 365       (let ((global-marks
 366              (elmo-object-load
 367               (expand-file-name
 368                elmo-global-mark-filename elmo-msgdb-directory)))
 369             (folder (elmo-flag-get-folder 'important))
 370             file-cache)
 371         (dolist (elem global-marks)
 372           (setq file-cache (elmo-file-cache-get (car elem)))
 373           (when (eq (elmo-file-cache-status file-cache) 'entire)
 374             (elmo-global-flag-set 'important nil nil (car elem))))))
 375     (message "Upgrading flag structure...done")))
 376
 377 (require 'product)
 378 (product-provide (provide 'elmo-flag) (require 'elmo-version))
 379
 380 ;;; elmo-flag.el ends here