elmo/elmo-flag.el

   1 ;;; elmo-flag.el --- global flag handling.
   2
   3 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28 (require 'elmo-util)
  29 (require 'elmo-localdir)
  30 (eval-when-compile (require 'cl))
  31
  32 ;;; Code:
  33 (defcustom elmo-global-flag-list '(important)
  34   "A list of flag symbol which is managed globally by the flag folder."
  35   :type '(repeat symbol)
  36   :group 'elmo)
  37
  38 (defvar elmo-global-flag-folder-alist nil
  39   "Internal variable to hold global-flag-folder structures.")
  40
  41 (eval-and-compile
  42   (luna-define-class elmo-flag-folder (elmo-localdir-folder)
  43                      (flag minfo minfo-hash))
  44   (luna-define-internal-accessors 'elmo-flag-folder))
  45
  46 (luna-define-method elmo-folder-initialize ((folder
  47                                              elmo-flag-folder)
  48                                             name)
  49   (if (string-match "flag/\\([a-z]+\\)" name)
  50       (setq name (match-string 1 name))
  51     (setq name (symbol-name (car elmo-global-flag-list))))
  52   (or (cdr (assq (intern name) elmo-global-flag-folder-alist))
  53       (let (msgdb-path)
  54         (elmo-flag-folder-set-flag-internal folder (intern name))
  55         ;; must be AFTER set flag slot.
  56         (setq msgdb-path (elmo-folder-msgdb-path folder))
  57         (unless (file-directory-p msgdb-path)
  58           (elmo-make-directory msgdb-path))
  59         (elmo-localdir-folder-set-dir-name-internal
  60          folder
  61          msgdb-path)
  62         (elmo-localdir-folder-set-directory-internal
  63          folder
  64          msgdb-path)
  65         (if (file-exists-p (expand-file-name "/.minfo" msgdb-path))
  66             (elmo-flag-folder-set-minfo-internal
  67              folder
  68              (elmo-object-load (expand-file-name "/.minfo" msgdb-path))))
  69         (elmo-flag-folder-set-minfo-hash-internal
  70          folder
  71          (elmo-make-hash (length (elmo-flag-folder-minfo-internal folder))))
  72         (dolist (elem (elmo-flag-folder-minfo-internal folder))
  73           (elmo-set-hash-val (nth 1 elem) elem
  74                              (elmo-flag-folder-minfo-hash-internal folder))
  75           (elmo-set-hash-val (concat "#" (number-to-string (nth 2 elem)))
  76                              elem
  77                              (elmo-flag-folder-minfo-hash-internal folder))
  78           (dolist (pair (car elem))
  79             (elmo-set-hash-val (concat (number-to-string (cdr pair))
  80                                        ":" (car pair))
  81                                elem
  82                                (elmo-flag-folder-minfo-hash-internal folder))))
  83         (setq elmo-global-flag-folder-alist
  84               (cons (cons (intern name) folder) elmo-global-flag-folder-alist))
  85         folder)))
  86
  87 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-flag-folder))
  88   (expand-file-name (concat "flag/"
  89                             (symbol-name
  90                              (elmo-flag-folder-flag-internal folder)))
  91                     elmo-msgdb-directory))
  92
  93 (luna-define-method elmo-folder-commit :after ((folder
  94                                                 elmo-flag-folder))
  95   (elmo-object-save
  96    (expand-file-name ".minfo" (elmo-folder-msgdb-path folder))
  97    (elmo-flag-folder-minfo-internal folder)))
  98
  99 (defun elmo-flag-folder-delete-message (folder number
 100                                                &optional keep-referrer)
 101   (let* ((elem (elmo-get-hash-val (concat "#" (number-to-string number))
 102                                   (elmo-flag-folder-minfo-hash-internal
 103                                    folder)))
 104          target-folder key)
 105     (dolist (pair (car elem))
 106       (when (and (car pair) (cdr pair))
 107         (unless keep-referrer
 108           (setq target-folder (elmo-make-folder (car pair)))
 109           (elmo-folder-open target-folder 'load-msgdb)
 110           ;; Unset the flag of the original folder.
 111           ;; (XXX Should the message-id checked?)
 112           (elmo-message-unset-flag target-folder (cdr pair)
 113                                    (elmo-flag-folder-flag-internal folder))
 114           (elmo-folder-close target-folder))
 115         (elmo-clear-hash-val (concat (number-to-string (cdr pair)) ":"
 116                                      (car pair))
 117                              (elmo-flag-folder-minfo-hash-internal
 118                               folder))))
 119     (elmo-clear-hash-val (concat "#" (number-to-string number))
 120                          (elmo-flag-folder-minfo-hash-internal
 121                           folder))
 122     (elmo-clear-hash-val (nth 1 elem) (elmo-flag-folder-minfo-hash-internal
 123                                        folder))
 124     (elmo-flag-folder-set-minfo-internal
 125      folder
 126      (delq elem (elmo-flag-folder-minfo-internal folder))))
 127   t)
 128
 129 (luna-define-method elmo-folder-delete-messages ((folder
 130                                                   elmo-flag-folder)
 131                                                  numbers)
 132   (dolist (number numbers)
 133     (elmo-flag-folder-delete-message folder number)
 134     (elmo-localdir-delete-message folder number))
 135   (elmo-folder-commit folder)
 136   t)
 137
 138 ;; Same as localdir except that the flag is always the flag.
 139 (luna-define-method elmo-folder-msgdb-create ((folder elmo-flag-folder)
 140                                               numbers
 141                                               flag-table)
 142   (when numbers
 143     (let ((dir (elmo-localdir-folder-directory-internal folder))
 144           (new-msgdb (elmo-make-msgdb))
 145           entity (i 0)
 146           (len (length numbers)))
 147       (message "Creating msgdb...")
 148       (while numbers
 149         (when (setq entity (elmo-localdir-msgdb-create-entity
 150                             dir (car numbers)))
 151           (elmo-msgdb-append-entity new-msgdb entity
 152                                     (list (elmo-flag-folder-flag-internal
 153                                            folder))))
 154         (when (> len elmo-display-progress-threshold)
 155           (setq i (1+ i))
 156           (elmo-display-progress
 157            'elmo-flag-folder-msgdb-create "Creating msgdb..."
 158            (/ (* i 100) len)))
 159         (setq numbers (cdr numbers)))
 160       (message "Creating msgdb...done")
 161       new-msgdb)))
 162
 163 (luna-define-method elmo-folder-append-buffer ((folder elmo-flag-folder)
 164                                                unread
 165                                                &optional number)
 166   (error "Cannot append to the flag folder"))
 167
 168 ;;; Utilities
 169
 170 (defmacro elmo-flag-get-folder (flag)
 171   "Get the flag folder structure for FLAG."
 172   `(when (memq ,flag elmo-global-flag-list)
 173      (elmo-make-folder (concat  "'flag/" (symbol-name ,flag)))))
 174
 175 (defun elmo-flag-folder-referrer (folder number)
 176   "Return a list of referrer message information.
 177 Each element is a cons cell like following:
 178 \(FNAME . NUMBER\)
 179 FNAME is the name of the folder which the message is contained.
 180 NUMBER is the number of the message."
 181   (when (eq (elmo-folder-type-internal folder) 'flag)
 182     (car (elmo-get-hash-val (concat "#" (number-to-string number))
 183                             (elmo-flag-folder-minfo-hash-internal
 184                              folder)))))
 185
 186 ;;; Global-Flag API
 187 (defun elmo-global-flag-initialize ()
 188   "Initialize flag folders.
 189 This function is necessary to be called before using `elmo-flag-folder'."
 190   (unless elmo-global-flag-folder-alist
 191     (dolist (flag elmo-global-flag-list)
 192       (setq elmo-global-flag-folder-alist
 193             (cons (elmo-make-folder
 194                    (concat "'flag/" (symbol-name flag)))
 195                   elmo-global-flag-folder-alist)))))
 196
 197 (defun elmo-global-flag-p (flag)
 198   "Return non-nil when FLAG is global."
 199   (memq flag elmo-global-flag-list))
 200
 201 (defun elmo-global-flags (fname number)
 202   "Return a list of global flags for the message.
 203 FNAME is the name string of the folder.
 204 NUMBER is the number of the message."
 205   (let ((flag-list elmo-global-flag-list)
 206         folder matches)
 207     (while flag-list
 208       (setq folder (elmo-flag-get-folder (car flag-list)))
 209       (when (elmo-get-hash-val
 210              (concat (number-to-string number) ":" fname)
 211              (elmo-flag-folder-minfo-hash-internal folder))
 212         (setq matches (cons (elmo-flag-folder-flag-internal folder)
 213                             matches)))
 214       (setq flag-list (cdr flag-list)))
 215     matches))
 216
 217 ;;;
 218 ;; minfo is a list of following cell.
 219 ;; ((((FNAME . NUMBER)...(FNAME . NUMBER)) MESSAGE-ID NUMBER-IN-FLAG-FOLDER)
 220 ;; minfo-index is the hash table of above with following indice;
 221 (defun elmo-global-flags-set (flags folder number message-id)
 222   "Set global flags to the message.
 223 FLAGS is a list of symbol of the flag.
 224 FOLDER is the elmo folder structure.
 225 NUMBER is the message number."
 226   (dolist (flag flags)
 227     (elmo-global-flag-set flag folder number message-id)))
 228
 229 (defsubst elmo-global-flag-set-internal (flag folder number message-id)
 230   (when message-id
 231     (let ((flag-folder (elmo-flag-get-folder flag))
 232           cache new-file new-number elem)
 233       (if (setq elem (elmo-get-hash-val
 234                       message-id
 235                       (elmo-flag-folder-minfo-hash-internal
 236                        flag-folder)))
 237           ;; Same ID already exists.
 238           (when (and folder number
 239                      (not (member (cons (elmo-folder-name-internal folder)
 240                                         number) (car elem))))
 241             (setcar elem
 242                     (cons (cons (elmo-folder-name-internal folder)
 243                                 number) (car elem)))
 244             (setq new-number (nth 2 elem))
 245             (elmo-set-hash-val (concat (number-to-string number)
 246                                        ":" (elmo-folder-name-internal
 247                                             folder))
 248                                elem
 249                                (elmo-flag-folder-minfo-hash-internal
 250                                 flag-folder)))
 251         ;; Append new element.
 252         (setq new-file
 253               (expand-file-name
 254                (int-to-string
 255                 (setq new-number (1+ (car (elmo-folder-status flag-folder)))))
 256                (elmo-localdir-folder-directory-internal flag-folder)))
 257         (with-temp-buffer
 258           (setq cache (and message-id (elmo-file-cache-get message-id)))
 259           (if (and cache (eq (elmo-file-cache-status cache) 'entire))
 260               (elmo-copy-file (elmo-file-cache-path cache)
 261                               new-file)
 262             (when (and folder number)
 263               (elmo-message-fetch folder number (elmo-make-fetch-strategy
 264                                                  'entire)
 265                                   nil (current-buffer))
 266               (write-region-as-binary (point-min) (point-max) new-file nil
 267                                       'no-msg))))
 268         (elmo-flag-folder-set-minfo-internal
 269          flag-folder
 270          (cons
 271           (setq elem (list
 272                       (when (and folder number)
 273                         (list (cons (elmo-folder-name-internal folder)
 274                                     number)))
 275                       message-id
 276                       new-number))
 277           (elmo-flag-folder-minfo-internal flag-folder)))
 278         (when (and folder number)
 279           (elmo-set-hash-val (concat (number-to-string number)
 280                                      ":" (elmo-folder-name-internal
 281                                           folder))
 282                              elem
 283                              (elmo-flag-folder-minfo-hash-internal
 284                               flag-folder)))
 285         (elmo-set-hash-val message-id elem
 286                            (elmo-flag-folder-minfo-hash-internal
 287                             flag-folder))
 288         (elmo-set-hash-val (concat "#" (number-to-string new-number)) elem
 289                            (elmo-flag-folder-minfo-hash-internal
 290                             flag-folder)))
 291       (elmo-folder-commit flag-folder)
 292       new-number)))
 293
 294 (defun elmo-global-flag-set (flag folder number message-id)
 295   "Set global flag to the message.
 296 FLAG is a symbol of the flag.
 297 FOLDER is the elmo folder structure.
 298 NUMBER is the message number.
 299 MESSAGE-ID is the message-id of the message."
 300   (when (elmo-global-flag-p flag)
 301     (elmo-global-flag-set-internal flag folder number message-id)))
 302
 303 (defun elmo-global-flag-detach (flag folder number &optional delete-if-none)
 304   "Detach the message from the global flag.
 305 FOLDER is the folder structure.
 306 NUMBERS is the message number.
 307 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 308 the message is not flagged in any folder."
 309   (unless (eq (elmo-folder-type-internal folder) 'flag)
 310     (let ((flag-folder (elmo-flag-get-folder flag))
 311           elem key)
 312       (when flag-folder
 313         (setq key (concat (number-to-string number) ":"
 314                           (elmo-folder-name-internal folder))
 315               elem (elmo-get-hash-val
 316                     key
 317                     (elmo-flag-folder-minfo-hash-internal flag-folder)))
 318         (when elem
 319           (setcar elem (delete (cons (elmo-folder-name-internal folder)
 320                                      number) (car elem)))
 321           (elmo-clear-hash-val key (elmo-flag-folder-minfo-hash-internal
 322                                     flag-folder))
 323           ;; Does not have any referrer, remove.
 324           (when (and delete-if-none (null (car elem)))
 325             (elmo-flag-folder-delete-message flag-folder (nth 2 elem) 'keep)
 326             (elmo-localdir-delete-message flag-folder (nth 2 elem))
 327             (elmo-folder-commit flag-folder)))))))
 328
 329 (defun elmo-global-flag-detach-messages (folder numbers)
 330   "Detach all messages specified from all global flags.
 331 FOLDER is the folder structure.
 332 NUMBERS is the message number list."
 333   (unless (eq (elmo-folder-type-internal folder) 'flag)
 334     (dolist (flag elmo-global-flag-list)
 335       (dolist (number numbers)
 336         (elmo-global-flag-detach flag folder number)))))
 337
 338 ;;; To migrate from global mark folder
 339 (defvar elmo-global-mark-filename "global-mark"
 340   "Obsolete variable. (Just for migration)")
 341
 342 (defun elmo-global-mark-upgrade ()
 343   "Upgrade old `global-mark' structure."
 344   (interactive)
 345   (when (file-exists-p (expand-file-name
 346                         elmo-global-mark-filename elmo-msgdb-directory))
 347     (message "Upgrading flag structure...")
 348     (elmo-global-flag-initialize)
 349     (when (elmo-global-flag-p 'important)
 350       (let ((global-marks
 351              (elmo-object-load
 352               (expand-file-name
 353                elmo-global-mark-filename elmo-msgdb-directory)))
 354             (folder (elmo-flag-get-folder 'important))
 355             file-cache)
 356         (dolist (elem global-marks)
 357           (setq file-cache (elmo-file-cache-get (car elem)))
 358           (when (eq (elmo-file-cache-status file-cache) 'entire)
 359             (elmo-global-flag-set 'important nil nil (car elem))))))
 360     (message "Upgrading flag structure...done")))
 361
 362 (require 'product)
 363 (product-provide (provide 'elmo-flag) (require 'elmo-version))
 364
 365 ;;; elmo-flag.el ends here