elmo/elmo-flag.el

   1 ;;; elmo-flag.el --- global flag handling.
   2
   3 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28 (require 'elmo-util)
  29 (require 'elmo-localdir)
  30 (eval-when-compile (require 'cl))
  31
  32 ;;; Code:
  33 (defcustom elmo-global-flags '(important)
  34   "A list of flag symbol which is managed globally by the flag folder."
  35   :type '(repeat symbol)
  36   :group 'elmo)
  37
  38 (defcustom elmo-local-flags '(unread any digest)
  39   "A list of flag symbol which is not treated as global flag."
  40   :type '(repeat symbol)
  41   :group 'elmo)
  42
  43 (defvar elmo-global-flag-folder-alist nil
  44   "Internal variable to hold global-flag-folder structures.")
  45
  46 (eval-and-compile
  47   (defconst elmo-flag-char-regexp "]!#$&'+,./0-9:;<=>?@A-Z[^_`a-z|}~-"))
  48
  49 (defun elmo-flag-valid-p (flag)
  50   (string-match (eval-when-compile
  51                   (concat "^[" elmo-flag-char-regexp "]+$"))
  52                 (if (stringp flag) flag (symbol-name flag))))
  53
  54 (eval-and-compile
  55   (luna-define-class elmo-flag-folder (elmo-localdir-folder)
  56                      (flag minfo minfo-hash max-number))
  57   (luna-define-internal-accessors 'elmo-flag-folder))
  58
  59 (luna-define-method elmo-folder-initialize ((folder
  60                                              elmo-flag-folder)
  61                                             name)
  62   (unless (string-match (eval-when-compile
  63                           (concat "^flag\\(/\\(["
  64                                   elmo-flag-char-regexp
  65                                   "]+\\)\\)?$"))
  66                         name)
  67     (error "Error in folder name `%s'" (elmo-folder-name-internal folder)))
  68   (if (match-beginning 1)
  69       (setq name (match-string 2 name))
  70     (setq name (symbol-name (car elmo-global-flags)))
  71     (elmo-folder-set-name-internal
  72      folder
  73      (concat (elmo-folder-name-internal folder) "/" name)))
  74   (or (cdr (assq (intern name) elmo-global-flag-folder-alist))
  75       (let ((flag (intern name))
  76             msgdb-path)
  77         (elmo-flag-folder-set-flag-internal folder flag)
  78         (unless (elmo-global-flag-p flag)
  79           (setq elmo-global-flags
  80                 (nconc elmo-global-flags (list flag))))
  81         ;; must be AFTER set flag slot.
  82         (setq msgdb-path (elmo-folder-msgdb-path folder))
  83         (unless (file-directory-p msgdb-path)
  84           (elmo-make-directory msgdb-path))
  85         (elmo-localdir-folder-set-dir-name-internal
  86          folder
  87          msgdb-path)
  88         (elmo-localdir-folder-set-directory-internal
  89          folder
  90          msgdb-path)
  91         (if (file-exists-p (expand-file-name "max" msgdb-path))
  92             (elmo-flag-folder-set-max-number-internal
  93              folder
  94              (elmo-object-load (expand-file-name "max" msgdb-path))))
  95         (if (file-exists-p (expand-file-name ".minfo" msgdb-path))
  96             (elmo-flag-folder-set-minfo-internal
  97              folder
  98              (elmo-object-load (expand-file-name ".minfo" msgdb-path))))
  99         (elmo-flag-folder-set-minfo-hash-internal
 100          folder
 101          (elmo-make-hash (length (elmo-flag-folder-minfo-internal folder))))
 102         (dolist (elem (elmo-flag-folder-minfo-internal folder))
 103           (elmo-set-hash-val (nth 1 elem) elem
 104                              (elmo-flag-folder-minfo-hash-internal folder))
 105           (elmo-set-hash-val (concat "#" (number-to-string (nth 2 elem)))
 106                              elem
 107                              (elmo-flag-folder-minfo-hash-internal folder))
 108           (dolist (pair (car elem))
 109             (elmo-set-hash-val (concat (number-to-string (cdr pair))
 110                                        ":" (car pair))
 111                                elem
 112                                (elmo-flag-folder-minfo-hash-internal folder))))
 113         (setq elmo-global-flag-folder-alist
 114               (cons (cons flag folder) elmo-global-flag-folder-alist))
 115         folder)))
 116
 117 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-flag-folder))
 118   (expand-file-name (concat "flag/"
 119                             (elmo-replace-string-as-filename
 120                              (symbol-name
 121                               (elmo-flag-folder-flag-internal folder))))
 122                     elmo-msgdb-directory))
 123
 124 (luna-define-method elmo-folder-commit :after ((folder
 125                                                 elmo-flag-folder))
 126   (elmo-object-save
 127    (expand-file-name ".minfo" (elmo-folder-msgdb-path folder))
 128    (elmo-flag-folder-minfo-internal folder))
 129   (if (elmo-flag-folder-max-number-internal folder)
 130       (elmo-object-save
 131        (expand-file-name "max" (elmo-folder-msgdb-path folder))
 132        (elmo-flag-folder-max-number-internal folder))))
 133
 134 (luna-define-method elmo-folder-list-subfolders ((folder elmo-flag-folder)
 135                                                  &optional one-level)
 136   (mapcar (lambda (flag)
 137             (concat
 138              (elmo-folder-prefix-internal folder)
 139              (symbol-name (elmo-folder-type-internal folder))
 140              "/"
 141              (symbol-name flag)))
 142           elmo-global-flags))
 143
 144 (defun elmo-flag-folder-delete-message (folder number
 145                                                &optional keep-referrer)
 146   (let* ((elem (elmo-get-hash-val (concat "#" (number-to-string number))
 147                                   (elmo-flag-folder-minfo-hash-internal
 148                                    folder)))
 149          target-folder key)
 150     (dolist (pair (car elem))
 151       (when (and (car pair) (cdr pair))
 152         (elmo-clear-hash-val (concat (number-to-string (cdr pair)) ":"
 153                                      (car pair))
 154                              (elmo-flag-folder-minfo-hash-internal
 155                               folder))
 156         (unless keep-referrer
 157           (setq target-folder (elmo-get-folder (car pair)))
 158           (elmo-folder-open target-folder 'load-msgdb)
 159           ;; Unset the flag of the original folder.
 160           ;; (XXX Should the message-id checked?)
 161           (elmo-message-unset-flag target-folder (cdr pair)
 162                                    (elmo-flag-folder-flag-internal folder))
 163           (elmo-folder-close target-folder))))
 164     (elmo-clear-hash-val (concat "#" (number-to-string number))
 165                          (elmo-flag-folder-minfo-hash-internal
 166                           folder))
 167     (elmo-clear-hash-val (nth 1 elem) (elmo-flag-folder-minfo-hash-internal
 168                                        folder))
 169     (elmo-flag-folder-set-minfo-internal
 170      folder
 171      (delq elem (elmo-flag-folder-minfo-internal folder))))
 172   t)
 173
 174 (luna-define-method elmo-folder-delete-messages-internal ((folder
 175                                                            elmo-flag-folder)
 176                                                           numbers)
 177   (dolist (number numbers)
 178     (elmo-flag-folder-delete-message folder number)
 179     (elmo-localdir-delete-message folder number))
 180   (elmo-folder-commit folder)
 181   t)
 182
 183 ;; Same as localdir except that the flag is always the flag.
 184 (luna-define-method elmo-folder-msgdb-create ((folder elmo-flag-folder)
 185                                               numbers
 186                                               flag-table)
 187   (when numbers
 188     (let ((dir (elmo-localdir-folder-directory-internal folder))
 189           (new-msgdb (elmo-make-msgdb))
 190           entity (i 0)
 191           (len (length numbers)))
 192       (message "Creating msgdb...")
 193       (while numbers
 194         (when (setq entity (elmo-localdir-msgdb-create-entity
 195                             new-msgdb dir (car numbers)))
 196           (elmo-msgdb-append-entity new-msgdb entity
 197                                     (list (elmo-flag-folder-flag-internal
 198                                            folder))))
 199         (when (> len elmo-display-progress-threshold)
 200           (setq i (1+ i))
 201           (elmo-display-progress
 202            'elmo-flag-folder-msgdb-create "Creating msgdb..."
 203            (/ (* i 100) len)))
 204         (setq numbers (cdr numbers)))
 205       (message "Creating msgdb...done")
 206       new-msgdb)))
 207
 208 (luna-define-method elmo-folder-append-messages ((folder elmo-flag-folder)
 209                                                  src-folder
 210                                                  numbers
 211                                                  &optional same-number)
 212   (dolist (number numbers)
 213     (elmo-global-flag-set (elmo-flag-folder-flag-internal folder)
 214                           src-folder number (elmo-message-field
 215                                              src-folder
 216                                              number
 217                                              'message-id)))
 218   (elmo-folder-set-flag src-folder
 219                         numbers
 220                         (elmo-flag-folder-flag-internal folder))
 221   numbers)
 222
 223 (luna-define-method elmo-folder-append-buffer ((folder elmo-flag-folder)
 224                                                &optional flag number)
 225   (error "Cannot append to the flag folder"))
 226
 227 (luna-define-method elmo-folder-unset-flag :before ((folder elmo-flag-folder)
 228                                                     numbers
 229                                                     flag
 230                                                     &optional is-local)
 231   (when (eq flag (elmo-flag-folder-flag-internal folder))
 232     (error "Cannot unset flag `%s' in this folder" flag)))
 233
 234 ;;; Utilities
 235
 236 (defmacro elmo-flag-get-folder (flag)
 237   "Get the flag folder structure for FLAG."
 238   `(when (memq ,flag elmo-global-flags)
 239      (elmo-get-folder (concat  "'flag/" (symbol-name ,flag)))))
 240
 241 (defun elmo-flag-folder-referrer (folder number)
 242   "Return a list of referrer message information.
 243 Each element is a cons cell like following:
 244 \(FNAME . NUMBER\)
 245 FNAME is the name of the folder which the message is contained.
 246 NUMBER is the number of the message."
 247   (when (eq (elmo-folder-type-internal folder) 'flag)
 248     (car (elmo-get-hash-val (concat "#" (number-to-string number))
 249                             (elmo-flag-folder-minfo-hash-internal
 250                              folder)))))
 251
 252 ;;; Global-Flag API
 253 (defun elmo-global-flag-p (flag)
 254   "Return non-nil when FLAG is global."
 255   (memq flag elmo-global-flags))
 256
 257 (defun elmo-global-flags (fname number)
 258   "Return a list of global flags for the message.
 259 FNAME is the name string of the folder.
 260 NUMBER is the number of the message."
 261   (let ((flag-list elmo-global-flags)
 262         folder matches)
 263     (while flag-list
 264       (setq folder (elmo-flag-get-folder (car flag-list)))
 265       (when (elmo-get-hash-val
 266              (concat (number-to-string number) ":" fname)
 267              (elmo-flag-folder-minfo-hash-internal folder))
 268         (setq matches (cons (elmo-flag-folder-flag-internal folder)
 269                             matches)))
 270       (setq flag-list (cdr flag-list)))
 271     matches))
 272
 273 (defun elmo-folder-list-global-flag-messages (folder flag)
 274   "List messages which have global flag.
 275 FOLDER is the elmo folder structure.
 276 FLAG is the symbol of the flag."
 277   (when (elmo-global-flag-p flag)
 278     (let ((flag-folder (elmo-flag-get-folder flag))
 279           result number)
 280       (dolist (elem (elmo-flag-folder-minfo-internal flag-folder))
 281         (if (setq number (elmo-message-number folder (nth 1 elem)))
 282             (setq result (cons number result))))
 283       result)))
 284
 285 ;;;
 286 ;; minfo is a list of following cell.
 287 ;; ((((FNAME . NUMBER)...(FNAME . NUMBER)) MESSAGE-ID NUMBER-IN-FLAG-FOLDER)
 288 ;; minfo-index is the hash table of above with following indice;
 289 (defun elmo-global-flags-set (flags folder number message-id)
 290   "Set global flags to the message.
 291 FLAGS is a list of symbol of the flag.
 292 FOLDER is the elmo folder structure.
 293 NUMBER is the message number."
 294   (dolist (flag flags)
 295     (elmo-global-flag-set flag folder number message-id)))
 296
 297 (defun elmo-local-flag-p (flag)
 298   "Return non-nil when flag is not appropriate for global flag."
 299   (memq flag elmo-local-flags))
 300
 301 (defsubst elmo-global-flag-set-internal (flag folder number message-id)
 302   (when (elmo-local-flag-p flag)
 303     (error "Cannot treat `%s' as global flag" flag))
 304   (when message-id
 305     (let ((flag-folder (elmo-flag-get-folder flag))
 306           cache new-file new-number elem)
 307       (if (setq elem (elmo-get-hash-val
 308                       message-id
 309                       (elmo-flag-folder-minfo-hash-internal
 310                        flag-folder)))
 311           ;; Same ID already exists.
 312           (when (and folder number
 313                      (not (member (cons (elmo-folder-name-internal folder)
 314                                         number) (car elem))))
 315             (setcar elem
 316                     (cons (cons (elmo-folder-name-internal folder)
 317                                 number) (car elem)))
 318             (setq new-number (nth 2 elem))
 319             (elmo-set-hash-val (concat (number-to-string number)
 320                                        ":" (elmo-folder-name-internal
 321                                             folder))
 322                                elem
 323                                (elmo-flag-folder-minfo-hash-internal
 324                                 flag-folder)))
 325         ;; Append new element.
 326         (elmo-flag-folder-set-max-number-internal
 327          flag-folder
 328          (+ (or (elmo-flag-folder-max-number-internal flag-folder)
 329                 ;; This is the first time.
 330                 (car (elmo-folder-status flag-folder)))
 331             1))
 332         (setq new-file
 333               (expand-file-name
 334                (int-to-string
 335                 (setq new-number
 336                       (elmo-flag-folder-max-number-internal flag-folder)))
 337                (elmo-localdir-folder-directory-internal flag-folder)))
 338         (with-temp-buffer
 339           (setq cache (and message-id (elmo-file-cache-get message-id)))
 340           (if (and cache (eq (elmo-file-cache-status cache) 'entire))
 341               (elmo-copy-file (elmo-file-cache-path cache)
 342                               new-file)
 343             (when (and folder number)
 344               (elmo-message-fetch folder number
 345                                   (elmo-make-fetch-strategy 'entire))
 346               (write-region-as-binary (point-min) (point-max) new-file nil
 347                                       'no-msg))))
 348         (elmo-flag-folder-set-minfo-internal
 349          flag-folder
 350          (cons
 351           (setq elem (list
 352                       (when (and folder number)
 353                         (list (cons (elmo-folder-name-internal folder)
 354                                     number)))
 355                       message-id
 356                       new-number))
 357           (elmo-flag-folder-minfo-internal flag-folder)))
 358         (when (and folder number)
 359           (elmo-set-hash-val (concat (number-to-string number)
 360                                      ":" (elmo-folder-name-internal
 361                                           folder))
 362                              elem
 363                              (elmo-flag-folder-minfo-hash-internal
 364                               flag-folder)))
 365         (elmo-set-hash-val message-id elem
 366                            (elmo-flag-folder-minfo-hash-internal
 367                             flag-folder))
 368         (elmo-set-hash-val (concat "#" (number-to-string new-number)) elem
 369                            (elmo-flag-folder-minfo-hash-internal
 370                             flag-folder)))
 371       (elmo-folder-commit flag-folder)
 372       new-number)))
 373
 374 (defun elmo-global-flag-set (flag folder number message-id)
 375   "Set global flag to the message.
 376 FLAG is a symbol of the flag.
 377 FOLDER is the elmo folder structure.
 378 NUMBER is the message number.
 379 MESSAGE-ID is the message-id of the message."
 380   (when (elmo-global-flag-p flag)
 381     (elmo-global-flag-set-internal flag folder number message-id)))
 382
 383 (defun elmo-global-flag-detach (flag folder number &optional delete-if-none)
 384   "Detach the message from the global flag.
 385 FOLDER is the folder structure.
 386 NUMBERS is the message number.
 387 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 388 the message is not flagged in any folder.
 389 If DELETE-IF-NONE is a symbol `always',
 390 delete message without flagged in other folder."
 391   (unless (and (eq (elmo-folder-type-internal folder) 'flag)
 392                (eq (elmo-flag-folder-flag-internal folder) flag))
 393     (let ((flag-folder (elmo-flag-get-folder flag))
 394           elem key)
 395       (when flag-folder
 396         (setq key (concat (number-to-string number) ":"
 397                           (elmo-folder-name-internal folder))
 398               elem (elmo-get-hash-val
 399                     key
 400                     (elmo-flag-folder-minfo-hash-internal flag-folder)))
 401         (when elem
 402           (setcar elem (delete (cons (elmo-folder-name-internal folder)
 403                                      number) (car elem)))
 404           (elmo-clear-hash-val key (elmo-flag-folder-minfo-hash-internal
 405                                     flag-folder))
 406           ;; Does not have any referrer, remove.
 407           (when (and delete-if-none
 408                      (or (eq delete-if-none 'always)
 409                          (null (car elem))))
 410             (elmo-flag-folder-delete-message flag-folder (nth 2 elem)
 411                                              (null (car elem)))
 412             (elmo-localdir-delete-message flag-folder (nth 2 elem))
 413             (elmo-folder-commit flag-folder)))))))
 414
 415 (defun elmo-global-flag-detach-messages (folder numbers &optional
 416                                                 delete-if-none)
 417   "Detach all messages specified from all global flags.
 418 FOLDER is the folder structure.
 419 NUMBERS is the message number list.
 420 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 421 the message is not flagged in any folder."
 422   (unless (eq (elmo-folder-type-internal folder) 'flag)
 423     (dolist (flag elmo-global-flags)
 424       (dolist (number numbers)
 425         (elmo-global-flag-detach flag folder number delete-if-none)))))
 426
 427 (defun elmo-get-global-flags (&optional flags ignore-preserved)
 428   "Get global flags.
 429 Return value is a subset of optional argument FLAGS.
 430 If FLAGS is `t', all global flags becomes candidates.
 431 If optional IGNORE-PRESERVED is non-nil, preserved flags
 432 \(answered, cached, new, unread\) are not included."
 433   (let ((result (copy-sequence (if (eq flags t)
 434                                    (setq flags elmo-global-flags)
 435                                  flags))))
 436     (while flags
 437       (unless (elmo-global-flag-p (car flags))
 438         (setq result (delq (car flags) result)))
 439       (setq flags (cdr flags)))
 440     (when ignore-preserved
 441       (dolist (flag elmo-preserved-flags)
 442         (setq result (delq flag result))))
 443     result))
 444
 445 (defun elmo-global-flags-initialize (&optional additional-flags)
 446   (let ((dir (expand-file-name "flag" elmo-msgdb-directory)))
 447     (setq elmo-global-flags
 448           (elmo-list-delete
 449            elmo-local-flags
 450            (elmo-uniq-list
 451             (append
 452              elmo-global-flags
 453              additional-flags
 454              (and (file-directory-p dir)
 455                   (mapcar (lambda (x)
 456                             (intern (elmo-recover-string-from-filename x)))
 457                           (elmo-list-delete
 458                            '(".." ".")
 459                            (directory-files dir))))))
 460            #'delq))))
 461
 462 ;;; To migrate from global mark folder
 463 (defvar elmo-global-mark-filename "global-mark"
 464   "Obsolete variable. (Just for migration)")
 465
 466 (defun elmo-global-mark-migrate ()
 467   "Migrate from 'mark to 'flag. For automatic migration."
 468   (when (and (file-exists-p (expand-file-name elmo-global-mark-filename
 469                                               elmo-msgdb-directory))
 470              (elmo-global-flag-p 'important)
 471              (not (file-exists-p (elmo-folder-msgdb-path
 472                                   (elmo-flag-get-folder 'important)))))
 473     (elmo-global-mark-upgrade)))
 474
 475 (defun elmo-global-mark-upgrade ()
 476   "Upgrade old `global-mark' structure."
 477   (interactive)
 478   (when (file-exists-p (expand-file-name
 479                         elmo-global-mark-filename elmo-msgdb-directory))
 480     (message "Upgrading flag structure...")
 481     (when (elmo-global-flag-p 'important)
 482       (let ((global-marks
 483              (elmo-object-load
 484               (expand-file-name
 485                elmo-global-mark-filename elmo-msgdb-directory)))
 486             (folder (elmo-flag-get-folder 'important))
 487             file-cache)
 488         (dolist (elem global-marks)
 489           (setq file-cache (elmo-file-cache-get (car elem)))
 490           (when (eq (elmo-file-cache-status file-cache) 'entire)
 491             (elmo-global-flag-set 'important nil nil (car elem))))))
 492     (message "Upgrading flag structure...done")))
 493
 494 (luna-define-method elmo-folder-delete :around ((folder elmo-flag-folder))
 495   (let ((flag (elmo-flag-folder-flag-internal folder)))
 496     (when (luna-call-next-method)
 497       (setq elmo-global-flags (delq flag elmo-global-flags))
 498       (setq elmo-global-flag-folder-alist
 499             (delq (assq flag elmo-global-flag-folder-alist)
 500                   elmo-global-flag-folder-alist))
 501       t)))
 502
 503 (require 'product)
 504 (product-provide (provide 'elmo-flag) (require 'elmo-version))
 505
 506 ;;; elmo-flag.el ends here