elmo/elmo-flag.el

   1 ;;; elmo-flag.el --- global flag handling.
   2
   3 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28 (require 'elmo-util)
  29 (require 'elmo-localdir)
  30 (eval-when-compile (require 'cl))
  31
  32 ;;; Code:
  33 (defcustom elmo-global-flag-list '(important)
  34   "A list of flag symbol which is managed globally by the flag folder."
  35   :type '(repeat symbol)
  36   :group 'elmo)
  37
  38 (defvar elmo-global-flag-folder-alist nil
  39   "Internal variable to hold global-flag-folder structures.")
  40
  41 (eval-and-compile
  42   (luna-define-class elmo-flag-folder (elmo-localdir-folder)
  43                      (flag minfo minfo-hash))
  44   (luna-define-internal-accessors 'elmo-flag-folder))
  45
  46 (luna-define-method elmo-folder-initialize ((folder
  47                                              elmo-flag-folder)
  48                                             name)
  49   (if (string-match "flag/\\([a-z]+\\)" name)
  50       (setq name (match-string 1 name))
  51     (setq name (symbol-name (car elmo-global-flag-list)))
  52     (elmo-folder-set-name-internal
  53      folder
  54      (concat (elmo-folder-name-internal folder) "/" name)))
  55   (or (cdr (assq (intern name) elmo-global-flag-folder-alist))
  56       (let ((flag (intern name))
  57             msgdb-path)
  58         (elmo-flag-folder-set-flag-internal folder flag)
  59         (unless (elmo-global-flag-p flag)
  60           (setq elmo-global-flag-list
  61                 (nconc elmo-global-flag-list (list flag))))
  62         ;; must be AFTER set flag slot.
  63         (setq msgdb-path (elmo-folder-msgdb-path folder))
  64         (unless (file-directory-p msgdb-path)
  65           (elmo-make-directory msgdb-path))
  66         (elmo-localdir-folder-set-dir-name-internal
  67          folder
  68          msgdb-path)
  69         (elmo-localdir-folder-set-directory-internal
  70          folder
  71          msgdb-path)
  72         (if (file-exists-p (expand-file-name ".minfo" msgdb-path))
  73             (elmo-flag-folder-set-minfo-internal
  74              folder
  75              (elmo-object-load (expand-file-name ".minfo" msgdb-path))))
  76         (elmo-flag-folder-set-minfo-hash-internal
  77          folder
  78          (elmo-make-hash (length (elmo-flag-folder-minfo-internal folder))))
  79         (dolist (elem (elmo-flag-folder-minfo-internal folder))
  80           (elmo-set-hash-val (nth 1 elem) elem
  81                              (elmo-flag-folder-minfo-hash-internal folder))
  82           (elmo-set-hash-val (concat "#" (number-to-string (nth 2 elem)))
  83                              elem
  84                              (elmo-flag-folder-minfo-hash-internal folder))
  85           (dolist (pair (car elem))
  86             (elmo-set-hash-val (concat (number-to-string (cdr pair))
  87                                        ":" (car pair))
  88                                elem
  89                                (elmo-flag-folder-minfo-hash-internal folder))))
  90         (setq elmo-global-flag-folder-alist
  91               (cons (cons flag folder) elmo-global-flag-folder-alist))
  92         folder)))
  93
  94 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-flag-folder))
  95   (expand-file-name (concat "flag/"
  96                             (symbol-name
  97                              (elmo-flag-folder-flag-internal folder)))
  98                     elmo-msgdb-directory))
  99
 100 (luna-define-method elmo-folder-commit :after ((folder
 101                                                 elmo-flag-folder))
 102   (elmo-object-save
 103    (expand-file-name ".minfo" (elmo-folder-msgdb-path folder))
 104    (elmo-flag-folder-minfo-internal folder)))
 105
 106 (luna-define-method elmo-folder-list-subfolders ((folder elmo-flag-folder)
 107                                                  &optional one-level)
 108   (mapcar (lambda (flag)
 109             (concat
 110              (elmo-folder-prefix-internal folder)
 111              (symbol-name (elmo-folder-type-internal folder))
 112              "/"
 113              (symbol-name flag)))
 114           elmo-global-flag-list))
 115
 116 (defun elmo-flag-folder-delete-message (folder number
 117                                                &optional keep-referrer)
 118   (let* ((elem (elmo-get-hash-val (concat "#" (number-to-string number))
 119                                   (elmo-flag-folder-minfo-hash-internal
 120                                    folder)))
 121          target-folder key)
 122     (dolist (pair (car elem))
 123       (when (and (car pair) (cdr pair))
 124         (elmo-clear-hash-val (concat (number-to-string (cdr pair)) ":"
 125                                      (car pair))
 126                              (elmo-flag-folder-minfo-hash-internal
 127                               folder))
 128         (unless keep-referrer
 129           (setq target-folder (elmo-make-folder (car pair)))
 130           (elmo-folder-open target-folder 'load-msgdb)
 131           ;; Unset the flag of the original folder.
 132           ;; (XXX Should the message-id checked?)
 133           (elmo-message-unset-flag target-folder (cdr pair)
 134                                    (elmo-flag-folder-flag-internal folder))
 135           (elmo-folder-close target-folder))))
 136     (elmo-clear-hash-val (concat "#" (number-to-string number))
 137                          (elmo-flag-folder-minfo-hash-internal
 138                           folder))
 139     (elmo-clear-hash-val (nth 1 elem) (elmo-flag-folder-minfo-hash-internal
 140                                        folder))
 141     (elmo-flag-folder-set-minfo-internal
 142      folder
 143      (delq elem (elmo-flag-folder-minfo-internal folder))))
 144   t)
 145
 146 (luna-define-method elmo-folder-delete-messages ((folder
 147                                                   elmo-flag-folder)
 148                                                  numbers)
 149   (dolist (number numbers)
 150     (elmo-flag-folder-delete-message folder number)
 151     (elmo-localdir-delete-message folder number))
 152   (elmo-folder-commit folder)
 153   t)
 154
 155 ;; Same as localdir except that the flag is always the flag.
 156 (luna-define-method elmo-folder-msgdb-create ((folder elmo-flag-folder)
 157                                               numbers
 158                                               flag-table)
 159   (when numbers
 160     (let ((dir (elmo-localdir-folder-directory-internal folder))
 161           (new-msgdb (elmo-make-msgdb))
 162           entity (i 0)
 163           (len (length numbers)))
 164       (message "Creating msgdb...")
 165       (while numbers
 166         (when (setq entity (elmo-localdir-msgdb-create-entity
 167                             new-msgdb dir (car numbers)))
 168           (elmo-msgdb-append-entity new-msgdb entity
 169                                     (list (elmo-flag-folder-flag-internal
 170                                            folder))))
 171         (when (> len elmo-display-progress-threshold)
 172           (setq i (1+ i))
 173           (elmo-display-progress
 174            'elmo-flag-folder-msgdb-create "Creating msgdb..."
 175            (/ (* i 100) len)))
 176         (setq numbers (cdr numbers)))
 177       (message "Creating msgdb...done")
 178       new-msgdb)))
 179
 180 (luna-define-method elmo-folder-append-messages ((folder elmo-flag-folder)
 181                                                  src-folder
 182                                                  numbers
 183                                                  &optional same-number)
 184   (dolist (number numbers)
 185     (elmo-global-flag-set (elmo-flag-folder-flag-internal folder)
 186                           src-folder number (elmo-message-field
 187                                              src-folder
 188                                              number
 189                                              'message-id)))
 190   (elmo-folder-set-flag src-folder
 191                         numbers
 192                         (elmo-flag-folder-flag-internal folder))
 193   numbers)
 194
 195 (luna-define-method elmo-folder-append-buffer ((folder elmo-flag-folder)
 196                                                &optional flag number)
 197   (error "Cannot append to the flag folder"))
 198
 199 ;;; Utilities
 200
 201 (defmacro elmo-flag-get-folder (flag)
 202   "Get the flag folder structure for FLAG."
 203   `(when (memq ,flag elmo-global-flag-list)
 204      (elmo-make-folder (concat  "'flag/" (symbol-name ,flag)))))
 205
 206 (defun elmo-flag-folder-referrer (folder number)
 207   "Return a list of referrer message information.
 208 Each element is a cons cell like following:
 209 \(FNAME . NUMBER\)
 210 FNAME is the name of the folder which the message is contained.
 211 NUMBER is the number of the message."
 212   (when (eq (elmo-folder-type-internal folder) 'flag)
 213     (car (elmo-get-hash-val (concat "#" (number-to-string number))
 214                             (elmo-flag-folder-minfo-hash-internal
 215                              folder)))))
 216
 217 ;;; Global-Flag API
 218 (defun elmo-global-flag-p (flag)
 219   "Return non-nil when FLAG is global."
 220   (memq flag elmo-global-flag-list))
 221
 222 (defun elmo-global-flags (fname number)
 223   "Return a list of global flags for the message.
 224 FNAME is the name string of the folder.
 225 NUMBER is the number of the message."
 226   (let ((flag-list elmo-global-flag-list)
 227         folder matches)
 228     (while flag-list
 229       (setq folder (elmo-flag-get-folder (car flag-list)))
 230       (when (elmo-get-hash-val
 231              (concat (number-to-string number) ":" fname)
 232              (elmo-flag-folder-minfo-hash-internal folder))
 233         (setq matches (cons (elmo-flag-folder-flag-internal folder)
 234                             matches)))
 235       (setq flag-list (cdr flag-list)))
 236     matches))
 237
 238 (defun elmo-folder-list-global-flag-messages (folder flag)
 239   "List messages which have global flag.
 240 FOLDER is the elmo folder structure.
 241 FLAG is the symbol of the flag."
 242   (when (elmo-global-flag-p flag)
 243     (let ((flag-folder (elmo-flag-get-folder flag))
 244           result entity)
 245       (dolist (elem (elmo-flag-folder-minfo-internal flag-folder))
 246         (if (setq entity (elmo-message-entity folder (nth 1 elem)))
 247             (setq result (cons (elmo-message-entity-number entity)
 248                                result))))
 249       result)))
 250
 251 ;;;
 252 ;; minfo is a list of following cell.
 253 ;; ((((FNAME . NUMBER)...(FNAME . NUMBER)) MESSAGE-ID NUMBER-IN-FLAG-FOLDER)
 254 ;; minfo-index is the hash table of above with following indice;
 255 (defun elmo-global-flags-set (flags folder number message-id)
 256   "Set global flags to the message.
 257 FLAGS is a list of symbol of the flag.
 258 FOLDER is the elmo folder structure.
 259 NUMBER is the message number."
 260   (dolist (flag flags)
 261     (elmo-global-flag-set flag folder number message-id)))
 262
 263 (defsubst elmo-global-flag-set-internal (flag folder number message-id)
 264   (when message-id
 265     (let ((flag-folder (elmo-flag-get-folder flag))
 266           cache new-file new-number elem)
 267       (if (setq elem (elmo-get-hash-val
 268                       message-id
 269                       (elmo-flag-folder-minfo-hash-internal
 270                        flag-folder)))
 271           ;; Same ID already exists.
 272           (when (and folder number
 273                      (not (member (cons (elmo-folder-name-internal folder)
 274                                         number) (car elem))))
 275             (setcar elem
 276                     (cons (cons (elmo-folder-name-internal folder)
 277                                 number) (car elem)))
 278             (setq new-number (nth 2 elem))
 279             (elmo-set-hash-val (concat (number-to-string number)
 280                                        ":" (elmo-folder-name-internal
 281                                             folder))
 282                                elem
 283                                (elmo-flag-folder-minfo-hash-internal
 284                                 flag-folder)))
 285         ;; Append new element.
 286         (setq new-file
 287               (expand-file-name
 288                (int-to-string
 289                 (setq new-number (1+ (car (elmo-folder-status flag-folder)))))
 290                (elmo-localdir-folder-directory-internal flag-folder)))
 291         (with-temp-buffer
 292           (setq cache (and message-id (elmo-file-cache-get message-id)))
 293           (if (and cache (eq (elmo-file-cache-status cache) 'entire))
 294               (elmo-copy-file (elmo-file-cache-path cache)
 295                               new-file)
 296             (when (and folder number)
 297               (elmo-message-fetch folder number (elmo-make-fetch-strategy
 298                                                  'entire)
 299                                   nil (current-buffer))
 300               (write-region-as-binary (point-min) (point-max) new-file nil
 301                                       'no-msg))))
 302         (elmo-flag-folder-set-minfo-internal
 303          flag-folder
 304          (cons
 305           (setq elem (list
 306                       (when (and folder number)
 307                         (list (cons (elmo-folder-name-internal folder)
 308                                     number)))
 309                       message-id
 310                       new-number))
 311           (elmo-flag-folder-minfo-internal flag-folder)))
 312         (when (and folder number)
 313           (elmo-set-hash-val (concat (number-to-string number)
 314                                      ":" (elmo-folder-name-internal
 315                                           folder))
 316                              elem
 317                              (elmo-flag-folder-minfo-hash-internal
 318                               flag-folder)))
 319         (elmo-set-hash-val message-id elem
 320                            (elmo-flag-folder-minfo-hash-internal
 321                             flag-folder))
 322         (elmo-set-hash-val (concat "#" (number-to-string new-number)) elem
 323                            (elmo-flag-folder-minfo-hash-internal
 324                             flag-folder)))
 325       (elmo-folder-commit flag-folder)
 326       new-number)))
 327
 328 (defun elmo-global-flag-set (flag folder number message-id)
 329   "Set global flag to the message.
 330 FLAG is a symbol of the flag.
 331 FOLDER is the elmo folder structure.
 332 NUMBER is the message number.
 333 MESSAGE-ID is the message-id of the message."
 334   (when (elmo-global-flag-p flag)
 335     (elmo-global-flag-set-internal flag folder number message-id)))
 336
 337 (defun elmo-global-flag-detach (flag folder number &optional delete-if-none)
 338   "Detach the message from the global flag.
 339 FOLDER is the folder structure.
 340 NUMBERS is the message number.
 341 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 342 the message is not flagged in any folder.
 343 If DELETE-IF-NONE is a symbol `always',
 344 delete message without flagged in other folder."
 345   (unless (eq (elmo-folder-type-internal folder) 'flag)
 346     (let ((flag-folder (elmo-flag-get-folder flag))
 347           elem key)
 348       (when flag-folder
 349         (setq key (concat (number-to-string number) ":"
 350                           (elmo-folder-name-internal folder))
 351               elem (elmo-get-hash-val
 352                     key
 353                     (elmo-flag-folder-minfo-hash-internal flag-folder)))
 354         (when elem
 355           (setcar elem (delete (cons (elmo-folder-name-internal folder)
 356                                      number) (car elem)))
 357           (elmo-clear-hash-val key (elmo-flag-folder-minfo-hash-internal
 358                                     flag-folder))
 359           ;; Does not have any referrer, remove.
 360           (when (and delete-if-none
 361                      (or (eq delete-if-none 'always)
 362                          (null (car elem))))
 363             (elmo-flag-folder-delete-message flag-folder (nth 2 elem)
 364                                              (null (car elem)))
 365             (elmo-localdir-delete-message flag-folder (nth 2 elem))
 366             (elmo-folder-commit flag-folder)))))))
 367
 368 (defun elmo-global-flag-detach-messages (folder numbers &optional
 369                                                 delete-if-none)
 370   "Detach all messages specified from all global flags.
 371 FOLDER is the folder structure.
 372 NUMBERS is the message number list.
 373 If optional DELETE-IF-NONE is non-nil, delete message from flag folder when
 374 the message is not flagged in any folder."
 375   (unless (eq (elmo-folder-type-internal folder) 'flag)
 376     (dolist (flag elmo-global-flag-list)
 377       (dolist (number numbers)
 378         (elmo-global-flag-detach flag folder number delete-if-none)))))
 379
 380 (defun elmo-get-global-flags (&optional flags ignore-preserved)
 381   "Get global flags.
 382 Return value is a subset of optional argument FLAGS.
 383 If FLAGS is `t', all global flags becomes candidates.
 384 If optional IGNORE-PRESERVED is non-nil, preserved flags
 385 \(answered, cached, new, unread\) are not included."
 386   (let ((result (copy-sequence (if (eq flags t)
 387                                    (setq flags elmo-global-flag-list)
 388                                  flags))))
 389     (while flags
 390       (unless (elmo-global-flag-p (car flags))
 391         (setq result (delq (car flags) result)))
 392       (setq flags (cdr flags)))
 393     (when ignore-preserved
 394       (dolist (flag '(answered cached new unread))
 395         (setq result (delq flag result))))
 396     result))
 397
 398 ;;; To migrate from global mark folder
 399 (defvar elmo-global-mark-filename "global-mark"
 400   "Obsolete variable. (Just for migration)")
 401
 402 (defun elmo-global-mark-migrate ()
 403   "Migrate from 'mark to 'flag. For automatic migration."
 404   (when (and (file-exists-p (expand-file-name elmo-global-mark-filename
 405                                               elmo-msgdb-directory))
 406              (elmo-global-flag-p 'important)
 407              (not (file-exists-p (elmo-folder-expand-msgdb-path
 408                                   (elmo-flag-get-folder 'important)))))
 409     (elmo-global-mark-upgrade)))
 410
 411 (defun elmo-global-mark-upgrade ()
 412   "Upgrade old `global-mark' structure."
 413   (interactive)
 414   (when (file-exists-p (expand-file-name
 415                         elmo-global-mark-filename elmo-msgdb-directory))
 416     (message "Upgrading flag structure...")
 417     (when (elmo-global-flag-p 'important)
 418       (let ((global-marks
 419              (elmo-object-load
 420               (expand-file-name
 421                elmo-global-mark-filename elmo-msgdb-directory)))
 422             (folder (elmo-flag-get-folder 'important))
 423             file-cache)
 424         (dolist (elem global-marks)
 425           (setq file-cache (elmo-file-cache-get (car elem)))
 426           (when (eq (elmo-file-cache-status file-cache) 'entire)
 427             (elmo-global-flag-set 'important nil nil (car elem))))))
 428     (message "Upgrading flag structure...done")))
 429
 430 (require 'product)
 431 (product-provide (provide 'elmo-flag) (require 'elmo-version))
 432
 433 ;;; elmo-flag.el ends here