elmo/elmo-localdir.el

   1 ;;; elmo-localdir.el --- Localdir Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   5 ;; Copyright (C) 1999,2000      Kenichi OKADA  <okada@opaopa.org>
   6
   7 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   8 ;;      Masahiro MURATA <muse@ba2.so-net.ne.jp>
   9 ;;      Kenichi OKADA <okada@opaopa.org>
  10 ;; Keywords: mail, net news
  11
  12 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  13
  14 ;; This program is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18 ;;
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23 ;;
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28 ;;
  29
  30 ;;; Commentary:
  31 ;;
  32
  33 ;;; Code:
  34 ;;
  35 (eval-when-compile (require 'cl))
  36
  37 (require 'elmo-msgdb)
  38 (require 'elmo)
  39
  40 (defcustom elmo-localdir-folder-path "~/Mail"
  41   "*Local mail directory (MH format) path."
  42   :type 'directory
  43   :group 'elmo)
  44
  45 (defvar elmo-localdir-lockfile-list nil)
  46
  47 ;;; ELMO Local directory folder
  48 (eval-and-compile
  49   (luna-define-class elmo-localdir-folder (elmo-folder)
  50                      (dir-name directory))
  51   (luna-define-internal-accessors 'elmo-localdir-folder))
  52
  53 ;;; elmo-localdir specific methods.
  54 (luna-define-generic elmo-localdir-folder-path (folder)
  55   "Return local directory path of the FOLDER.")
  56
  57 (luna-define-generic elmo-localdir-folder-name (folder name)
  58   "Return directory NAME for FOLDER.")
  59
  60 (luna-define-method elmo-localdir-folder-path ((folder elmo-localdir-folder))
  61   elmo-localdir-folder-path)
  62
  63 (luna-define-method elmo-localdir-folder-name ((folder elmo-localdir-folder)
  64                                                name)
  65   name)
  66
  67 (luna-define-method elmo-folder-initialize ((folder
  68                                              elmo-localdir-folder)
  69                                             name)
  70   (elmo-localdir-folder-set-dir-name-internal folder name)
  71   (if (file-name-absolute-p name)
  72       (elmo-localdir-folder-set-directory-internal
  73        folder
  74        (expand-file-name name))
  75     (elmo-localdir-folder-set-directory-internal
  76      folder
  77      (expand-file-name
  78       (elmo-localdir-folder-name folder name)
  79       (elmo-localdir-folder-path folder))))
  80   folder)
  81
  82 ;; open, check, commit, and close are generic.
  83
  84 (luna-define-method elmo-folder-exists-p ((folder elmo-localdir-folder))
  85   (file-directory-p (elmo-localdir-folder-directory-internal folder)))
  86
  87 (luna-define-method elmo-folder-expand-msgdb-path ((folder
  88                                                     elmo-localdir-folder))
  89   (expand-file-name
  90    (mapconcat
  91     'identity
  92     (delete ""
  93             (mapcar
  94              'elmo-replace-string-as-filename
  95              (split-string
  96               (let ((dir-name (elmo-localdir-folder-dir-name-internal folder)))
  97                 (if (file-name-absolute-p dir-name)
  98                     (expand-file-name dir-name)
  99                   dir-name))
 100               "/")))
 101     "/")
 102    (expand-file-name ;;"localdir"
 103     (symbol-name (elmo-folder-type-internal folder))
 104     elmo-msgdb-directory)))
 105
 106 (luna-define-method elmo-message-file-name ((folder
 107                                              elmo-localdir-folder)
 108                                             number)
 109   (expand-file-name (int-to-string number)
 110                     (elmo-localdir-folder-directory-internal folder)))
 111
 112 (luna-define-method elmo-folder-message-file-number-p ((folder
 113                                                         elmo-localdir-folder))
 114   t)
 115
 116 (luna-define-method elmo-folder-message-file-directory ((folder
 117                                                          elmo-localdir-folder))
 118   (elmo-localdir-folder-directory-internal folder))
 119
 120 (luna-define-method elmo-folder-message-make-temp-file-p
 121   ((folder elmo-localdir-folder))
 122   t)
 123
 124 (luna-define-method elmo-folder-message-make-temp-files ((folder
 125                                                           elmo-localdir-folder)
 126                                                          numbers
 127                                                          &optional
 128                                                          start-number)
 129   (let ((temp-dir (elmo-folder-make-temporary-directory folder))
 130         (cur-number (or start-number 0)))
 131     (dolist (number numbers)
 132       (elmo-copy-file
 133        (expand-file-name
 134         (int-to-string number)
 135         (elmo-localdir-folder-directory-internal folder))
 136        (expand-file-name
 137         (int-to-string (if start-number cur-number number))
 138         temp-dir))
 139       (incf cur-number))
 140     temp-dir))
 141
 142 (defun elmo-localdir-msgdb-create-entity (msgdb dir number)
 143   (elmo-msgdb-create-message-entity-from-file
 144    (elmo-msgdb-message-entity-handler msgdb)
 145    number (expand-file-name (int-to-string number) dir)))
 146
 147 (luna-define-method elmo-folder-msgdb-create ((folder elmo-localdir-folder)
 148                                               numbers
 149                                               flag-table)
 150   (when numbers
 151     (let ((dir (elmo-localdir-folder-directory-internal folder))
 152           (new-msgdb (elmo-make-msgdb))
 153           entity message-id
 154           flags
 155           (i 0)
 156           (len (length numbers)))
 157       (message "Creating msgdb...")
 158       (while numbers
 159         (setq entity
 160               (elmo-localdir-msgdb-create-entity
 161                new-msgdb dir (car numbers)))
 162         (when entity
 163           (setq message-id (elmo-message-entity-field entity 'message-id)
 164                 flags (elmo-flag-table-get flag-table message-id))
 165           (elmo-global-flags-set flags folder (car numbers) message-id)
 166           (elmo-msgdb-append-entity new-msgdb entity flags))
 167         (when (> len elmo-display-progress-threshold)
 168           (setq i (1+ i))
 169           (elmo-display-progress
 170            'elmo-localdir-msgdb-create-as-numbers "Creating msgdb..."
 171            (/ (* i 100) len)))
 172         (setq numbers (cdr numbers)))
 173       (message "Creating msgdb...done")
 174       new-msgdb)))
 175
 176 (luna-define-method elmo-folder-list-subfolders ((folder elmo-localdir-folder)
 177                                                  &optional one-level)
 178   (elmo-mapcar-list-of-list
 179    (lambda (x) (concat (elmo-folder-prefix-internal folder) x))
 180    (elmo-list-subdirectories
 181     (elmo-localdir-folder-path folder)
 182     (or (elmo-localdir-folder-dir-name-internal folder) "")
 183     one-level)))
 184
 185 (defsubst elmo-localdir-list-subr (folder &optional nonsort)
 186   (let ((flist (mapcar 'string-to-int
 187                        (directory-files
 188                         (elmo-localdir-folder-directory-internal folder)
 189                         nil "^[0-9]+$" t)))
 190         (killed (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 191     (if nonsort
 192         (cons (or (elmo-max-of-list flist) 0)
 193               (if killed
 194                   (- (length flist)
 195                      (elmo-msgdb-killed-list-length killed))
 196                 (length flist)))
 197       (sort flist '<))))
 198
 199 (luna-define-method elmo-folder-append-buffer ((folder elmo-localdir-folder)
 200                                                &optional flags number)
 201   (let ((filename (elmo-message-file-name
 202                    folder
 203                    (or number
 204                        (1+ (car (elmo-folder-status folder)))))))
 205     (when (and (file-writable-p filename)
 206                (not (file-exists-p filename)))
 207       (write-region-as-binary
 208        (point-min) (point-max) filename nil 'no-msg)
 209       (elmo-folder-preserve-falgs
 210        folder (elmo-msgdb-get-message-id-from-buffer) flags)
 211       t)))
 212
 213 (luna-define-method elmo-folder-append-messages :around
 214   ((folder elmo-localdir-folder)
 215    src-folder numbers &optional same-number)
 216   (if (elmo-folder-message-file-p src-folder)
 217       (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
 218             (dir (elmo-localdir-folder-directory-internal folder))
 219             (table (elmo-folder-flag-table folder))
 220             (succeeds numbers)
 221             (next-num (1+ (car (elmo-folder-status folder))))
 222             flags id)
 223         (while numbers
 224           (setq flags (elmo-message-flags src-folder (car numbers)))
 225           (elmo-copy-file
 226            (elmo-message-file-name src-folder (car numbers))
 227            (expand-file-name
 228             (int-to-string
 229              (if same-number (car numbers) next-num))
 230             dir))
 231           ;; save flag-table only when src folder's msgdb is loaded.
 232           (when (setq id (and src-msgdb-exists
 233                               (elmo-message-field src-folder (car numbers)
 234                                                   'message-id)))
 235             (elmo-flag-table-set table id flags))
 236           (elmo-progress-notify 'elmo-folder-move-messages)
 237           (if (and (setq numbers (cdr numbers))
 238                    (not same-number))
 239               (setq next-num
 240                     (if (elmo-localdir-locked-p)
 241                         ;; MDA is running.
 242                         (1+ (car (elmo-folder-status folder)))
 243                       (1+ next-num)))))
 244         (when (elmo-folder-persistent-p folder)
 245           (elmo-folder-close-flag-table folder))
 246         succeeds)
 247     (luna-call-next-method)))
 248
 249 (luna-define-method elmo-folder-delete-messages ((folder elmo-localdir-folder)
 250                                                  numbers)
 251   (dolist (number numbers)
 252     (elmo-localdir-delete-message folder number))
 253   t)
 254
 255 (defun elmo-localdir-delete-message (folder number)
 256   "Delete message in the FOLDER with NUMBER."
 257   (let ((filename (elmo-message-file-name folder number)))
 258     (when (and (string-match "[0-9]+" filename) ; for safety.
 259                (file-exists-p filename)
 260                (file-writable-p filename)
 261                (not (file-directory-p filename)))
 262       (delete-file filename)
 263       t)))
 264
 265 (luna-define-method elmo-message-fetch-internal ((folder elmo-localdir-folder)
 266                                                  number strategy
 267                                                  &optional section unread)
 268   (when (file-exists-p (elmo-message-file-name folder number))
 269     (insert-file-contents-as-binary
 270      (elmo-message-file-name folder number))))
 271
 272 (luna-define-method elmo-folder-list-messages-internal
 273   ((folder elmo-localdir-folder) &optional nohide)
 274   (elmo-localdir-list-subr folder))
 275
 276 (luna-define-method elmo-folder-status ((folder elmo-localdir-folder))
 277   (elmo-localdir-list-subr folder t))
 278
 279 (luna-define-method elmo-folder-creatable-p ((folder elmo-localdir-folder))
 280   t)
 281
 282 (luna-define-method elmo-folder-writable-p ((folder elmo-localdir-folder))
 283   t)
 284
 285 (luna-define-method elmo-folder-create ((folder elmo-localdir-folder))
 286   (let ((dir (elmo-localdir-folder-directory-internal folder)))
 287     (if (file-directory-p dir)
 288         ()
 289       (if (file-exists-p dir)
 290           (error "Create folder failed")
 291         (elmo-make-directory dir))
 292       t)))
 293
 294 (luna-define-method elmo-folder-delete ((folder elmo-localdir-folder))
 295   (let ((msgs (and (elmo-folder-exists-p folder)
 296                    (elmo-folder-list-messages folder))))
 297     (when (yes-or-no-p (format "%sDelete msgdb and substance of \"%s\"? "
 298                                (if (> (length msgs) 0)
 299                                    (format "%d msg(s) exists. " (length msgs))
 300                                  "")
 301                                (elmo-folder-name-internal folder)))
 302       (let ((dir (elmo-localdir-folder-directory-internal folder)))
 303         (if (not (file-directory-p dir))
 304             (error "No such directory: %s" dir)
 305           (elmo-delete-match-files dir "[0-9]+" t)))
 306       (elmo-msgdb-delete-path folder)
 307       t)))
 308
 309 (luna-define-method elmo-folder-rename-internal ((folder elmo-localdir-folder)
 310                                                  new-folder)
 311   (let* ((old (elmo-localdir-folder-directory-internal folder))
 312          (new (elmo-localdir-folder-directory-internal new-folder))
 313          (new-dir (directory-file-name (file-name-directory new))))
 314     (unless (file-directory-p old)
 315       (error "No such directory: %s" old))
 316     (when (file-exists-p new)
 317       (error "Already exists directory: %s" new))
 318     (unless (file-directory-p new-dir)
 319       (elmo-make-directory new-dir))
 320     (rename-file old new)
 321     t))
 322
 323 (defsubst elmo-localdir-field-condition-match (folder condition
 324                                                       number number-list)
 325   (elmo-file-field-condition-match
 326    (expand-file-name (int-to-string number)
 327                      (elmo-localdir-folder-directory-internal folder))
 328    condition number number-list))
 329
 330 (luna-define-method elmo-folder-pack-numbers ((folder elmo-localdir-folder))
 331   (let* ((dir (elmo-localdir-folder-directory-internal folder))
 332          (msgdb (elmo-folder-msgdb folder))
 333          (new-msgdb (elmo-make-msgdb (elmo-folder-msgdb-path folder)))
 334          (numbers (sort (elmo-folder-list-messages
 335                          folder
 336                          nil
 337                          (not elmo-pack-number-check-strict))
 338                         '<))
 339          (new-number 1)           ; first ordinal position in localdir
 340          total entity)
 341     (setq total (length numbers))
 342     (elmo-with-progress-display (> total elmo-display-progress-threshold)
 343         (elmo-folder-pack-numbers total "Packing...")
 344       (dolist (old-number numbers)
 345         (setq entity (elmo-msgdb-message-entity msgdb old-number))
 346         (when (not (eq old-number new-number)) ; why \=() is wrong..
 347           (elmo-bind-directory
 348            dir
 349            ;; xxx  nfs,hardlink
 350            (rename-file (int-to-string old-number)
 351                         (int-to-string new-number) t))
 352           (elmo-message-entity-set-number entity new-number))
 353         (elmo-msgdb-append-entity new-msgdb entity
 354                                   (elmo-msgdb-flags msgdb old-number))
 355         (setq new-number (1+ new-number))))
 356     (message "Packing...done")
 357     (elmo-folder-set-msgdb-internal folder new-msgdb)))
 358
 359 (luna-define-method elmo-folder-message-file-p ((folder elmo-localdir-folder))
 360   t)
 361
 362 (luna-define-method elmo-message-file-name ((folder elmo-localdir-folder)
 363                                             number)
 364   (expand-file-name
 365    (int-to-string number)
 366    (elmo-localdir-folder-directory-internal folder)))
 367
 368 (defun elmo-localdir-locked-p ()
 369   (if elmo-localdir-lockfile-list
 370       (let ((lock elmo-localdir-lockfile-list))
 371         (catch 'found
 372           (while lock
 373             (if (file-exists-p (car lock))
 374                 (throw 'found t))
 375             (setq lock (cdr lock)))))))
 376
 377 (autoload 'elmo-global-flags-set "elmo-flag")
 378
 379 (require 'product)
 380 (product-provide (provide 'elmo-localdir) (require 'elmo-version))
 381
 382 ;;; elmo-localdir.el ends here