elmo/elmo-localdir.el

   1 ;;; elmo-localdir.el --- Localdir Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   5 ;; Copyright (C) 1999,2000      Kenichi OKADA  <okada@opaopa.org>
   6
   7 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   8 ;;      Masahiro MURATA <muse@ba2.so-net.ne.jp>
   9 ;;      Kenichi OKADA <okada@opaopa.org>
  10 ;; Keywords: mail, net news
  11
  12 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  13
  14 ;; This program is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18 ;;
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23 ;;
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28 ;;
  29
  30 ;;; Commentary:
  31 ;;
  32
  33 ;;; Code:
  34 ;;
  35 (eval-when-compile (require 'cl))
  36
  37 (require 'elmo-msgdb)
  38 (require 'elmo)
  39
  40 (defcustom elmo-localdir-folder-path "~/Mail"
  41   "*Local mail directory (MH format) path."
  42   :type 'directory
  43   :group 'elmo)
  44
  45 (defvar elmo-localdir-lockfile-list nil)
  46
  47 ;;; ELMO Local directory folder
  48 (eval-and-compile
  49   (luna-define-class elmo-localdir-folder (elmo-folder)
  50                      (dir-name directory))
  51   (luna-define-internal-accessors 'elmo-localdir-folder))
  52
  53 ;;; elmo-localdir specific methods.
  54 (luna-define-generic elmo-localdir-folder-path (folder)
  55   "Return local directory path of the FOLDER.")
  56
  57 (luna-define-generic elmo-localdir-folder-name (folder name)
  58   "Return directory NAME for FOLDER.")
  59
  60 (luna-define-method elmo-localdir-folder-path ((folder elmo-localdir-folder))
  61   elmo-localdir-folder-path)
  62
  63 (luna-define-method elmo-localdir-folder-name ((folder elmo-localdir-folder)
  64                                                name)
  65   name)
  66
  67 (luna-define-method elmo-folder-initialize ((folder
  68                                              elmo-localdir-folder)
  69                                             name)
  70   (elmo-localdir-folder-set-dir-name-internal folder name)
  71   (if (file-name-absolute-p name)
  72       (elmo-localdir-folder-set-directory-internal
  73        folder
  74        (expand-file-name name))
  75     (elmo-localdir-folder-set-directory-internal
  76      folder
  77      (expand-file-name
  78       (elmo-localdir-folder-name folder name)
  79       (elmo-localdir-folder-path folder))))
  80   folder)
  81
  82 ;; open, check, commit, and close are generic.
  83
  84 (luna-define-method elmo-folder-exists-p ((folder elmo-localdir-folder))
  85   (file-directory-p (elmo-localdir-folder-directory-internal folder)))
  86
  87 (luna-define-method elmo-folder-expand-msgdb-path ((folder
  88                                                     elmo-localdir-folder))
  89   (expand-file-name
  90    (mapconcat
  91     'identity
  92     (mapcar
  93      'elmo-replace-string-as-filename
  94      (split-string
  95       (let ((dir-name (elmo-localdir-folder-dir-name-internal folder)))
  96         (if (file-name-absolute-p dir-name)
  97             (expand-file-name dir-name)
  98           dir-name))
  99       "/"))
 100     "/")
 101    (expand-file-name ;;"localdir"
 102     (symbol-name (elmo-folder-type-internal folder))
 103     elmo-msgdb-directory)))
 104
 105 (luna-define-method elmo-message-file-name ((folder
 106                                              elmo-localdir-folder)
 107                                             number)
 108   (expand-file-name (int-to-string number)
 109                     (elmo-localdir-folder-directory-internal folder)))
 110
 111 (luna-define-method elmo-folder-message-file-number-p ((folder
 112                                                         elmo-localdir-folder))
 113   t)
 114
 115 (luna-define-method elmo-folder-message-file-directory ((folder
 116                                                          elmo-localdir-folder))
 117   (elmo-localdir-folder-directory-internal folder))
 118
 119 (luna-define-method elmo-folder-message-make-temp-file-p
 120   ((folder elmo-localdir-folder))
 121   t)
 122
 123 (luna-define-method elmo-folder-message-make-temp-files ((folder
 124                                                           elmo-localdir-folder)
 125                                                          numbers
 126                                                          &optional
 127                                                          start-number)
 128   (let ((temp-dir (elmo-folder-make-temporary-directory folder))
 129         (cur-number (or start-number 0)))
 130     (dolist (number numbers)
 131       (elmo-copy-file
 132        (expand-file-name
 133         (int-to-string number)
 134         (elmo-localdir-folder-directory-internal folder))
 135        (expand-file-name
 136         (int-to-string (if start-number cur-number number))
 137         temp-dir))
 138       (incf cur-number))
 139     temp-dir))
 140
 141 (defun elmo-localdir-msgdb-create-entity (dir number)
 142   (elmo-msgdb-create-overview-entity-from-file
 143    number (expand-file-name (int-to-string number) dir)))
 144
 145 (luna-define-method elmo-folder-msgdb-create ((folder elmo-localdir-folder)
 146                                               numbers
 147                                               flag-table)
 148   (when numbers
 149     (let ((dir (elmo-localdir-folder-directory-internal folder))
 150           (new-msgdb (elmo-make-msgdb))
 151           entity message-id
 152           (i 0)
 153           (len (length numbers)))
 154       (message "Creating msgdb...")
 155       (while numbers
 156         (setq entity
 157               (elmo-localdir-msgdb-create-entity
 158                dir (car numbers)))
 159         (when entity
 160           (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 161           (elmo-msgdb-append-entity
 162            new-msgdb
 163            entity
 164            (elmo-flag-table-get flag-table message-id)))
 165         (when (> len elmo-display-progress-threshold)
 166           (setq i (1+ i))
 167           (elmo-display-progress
 168            'elmo-localdir-msgdb-create-as-numbers "Creating msgdb..."
 169            (/ (* i 100) len)))
 170         (setq numbers (cdr numbers)))
 171       (message "Creating msgdb...done")
 172       new-msgdb)))
 173
 174 (luna-define-method elmo-folder-list-subfolders ((folder elmo-localdir-folder)
 175                                                  &optional one-level)
 176   (elmo-mapcar-list-of-list
 177    (lambda (x) (concat (elmo-folder-prefix-internal folder) x))
 178    (elmo-list-subdirectories
 179     (elmo-localdir-folder-path folder)
 180     (or (elmo-localdir-folder-dir-name-internal folder) "")
 181     one-level)))
 182
 183 (defsubst elmo-localdir-list-subr (folder &optional nonsort)
 184   (let ((flist (mapcar 'string-to-int
 185                        (directory-files
 186                         (elmo-localdir-folder-directory-internal folder)
 187                         nil "^[0-9]+$" t)))
 188         (killed (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 189     (if nonsort
 190         (cons (or (elmo-max-of-list flist) 0)
 191               (if killed
 192                   (- (length flist)
 193                      (elmo-msgdb-killed-list-length killed))
 194                 (length flist)))
 195       (sort flist '<))))
 196
 197 (luna-define-method elmo-folder-append-buffer ((folder elmo-localdir-folder)
 198                                                unread
 199                                                &optional number)
 200   (let ((filename (elmo-message-file-name
 201                    folder
 202                    (or number
 203                        (1+ (car (elmo-folder-status folder)))))))
 204     (when (file-writable-p filename)
 205       (write-region-as-binary
 206        (point-min) (point-max) filename nil 'no-msg)
 207       t)))
 208
 209 (luna-define-method elmo-folder-append-messages :around
 210   ((folder elmo-localdir-folder)
 211    src-folder numbers &optional same-number)
 212   (if (elmo-folder-message-file-p src-folder)
 213       (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
 214             (dir (elmo-localdir-folder-directory-internal folder))
 215             (table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
 216             (succeeds numbers)
 217             (next-num (1+ (car (elmo-folder-status folder))))
 218             flags id)
 219         (while numbers
 220           (setq flags (elmo-message-flags src-folder (car numbers)))
 221           (elmo-copy-file
 222            (elmo-message-file-name src-folder (car numbers))
 223            (expand-file-name
 224             (int-to-string
 225              (if same-number (car numbers) next-num))
 226             dir))
 227           ;; save flag-table only when src folder's msgdb is loaded.
 228           (when (setq id (and src-msgdb-exists
 229                               (elmo-message-field src-folder (car numbers)
 230                                                   'message-id)))
 231             (elmo-flag-table-set table id flags))
 232           (elmo-progress-notify 'elmo-folder-move-messages)
 233           (if (and (setq numbers (cdr numbers))
 234                    (not same-number))
 235               (setq next-num
 236                     (if (elmo-localdir-locked-p)
 237                         ;; MDA is running.
 238                         (1+ (car (elmo-folder-status folder)))
 239                       (1+ next-num)))))
 240         (when (elmo-folder-persistent-p folder)
 241           (elmo-flag-table-save (elmo-folder-msgdb-path folder) table))
 242         succeeds)
 243     (luna-call-next-method)))
 244
 245 (luna-define-method elmo-folder-delete-messages ((folder elmo-localdir-folder)
 246                                                  numbers)
 247   (dolist (number numbers)
 248     (elmo-localdir-delete-message folder number))
 249   t)
 250
 251 (defun elmo-localdir-delete-message (folder number)
 252   "Delete message in the FOLDER with NUMBER."
 253   (let ((filename (elmo-message-file-name folder number)))
 254     (when (and (string-match "[0-9]+" filename) ; for safety.
 255                (file-exists-p filename)
 256                (file-writable-p filename)
 257                (not (file-directory-p filename)))
 258       (delete-file filename)
 259       t)))
 260
 261 (luna-define-method elmo-message-fetch-internal ((folder elmo-localdir-folder)
 262                                                  number strategy
 263                                                  &optional section unread)
 264   (when (file-exists-p (elmo-message-file-name folder number))
 265     (insert-file-contents-as-binary
 266      (elmo-message-file-name folder number))))
 267
 268 (luna-define-method elmo-folder-list-messages-internal
 269   ((folder elmo-localdir-folder) &optional nohide)
 270   (elmo-localdir-list-subr folder))
 271
 272 (luna-define-method elmo-folder-status ((folder elmo-localdir-folder))
 273   (elmo-localdir-list-subr folder t))
 274
 275 (luna-define-method elmo-folder-creatable-p ((folder elmo-localdir-folder))
 276   t)
 277
 278 (luna-define-method elmo-folder-writable-p ((folder elmo-localdir-folder))
 279   t)
 280
 281 (luna-define-method elmo-folder-create ((folder elmo-localdir-folder))
 282   (let ((dir (elmo-localdir-folder-directory-internal folder)))
 283     (if (file-directory-p dir)
 284         ()
 285       (if (file-exists-p dir)
 286           (error "Create folder failed")
 287         (elmo-make-directory dir))
 288       t)))
 289
 290 (luna-define-method elmo-folder-delete ((folder elmo-localdir-folder))
 291   (let ((msgs (and (elmo-folder-exists-p folder)
 292                    (elmo-folder-list-messages folder))))
 293     (when (yes-or-no-p (format "%sDelete msgdb and substance of \"%s\"? "
 294                                (if (> (length msgs) 0)
 295                                    (format "%d msg(s) exists. " (length msgs))
 296                                  "")
 297                                (elmo-folder-name-internal folder)))
 298       (let ((dir (elmo-localdir-folder-directory-internal folder)))
 299         (if (not (file-directory-p dir))
 300             (error "No such directory: %s" dir)
 301           (elmo-delete-match-files dir "[0-9]+" t)))
 302       (elmo-msgdb-delete-path folder)
 303       t)))
 304
 305 (luna-define-method elmo-folder-rename-internal ((folder elmo-localdir-folder)
 306                                                  new-folder)
 307   (let* ((old (elmo-localdir-folder-directory-internal folder))
 308          (new (elmo-localdir-folder-directory-internal new-folder))
 309          (new-dir (directory-file-name (file-name-directory new))))
 310     (unless (file-directory-p old)
 311       (error "No such directory: %s" old))
 312     (when (file-exists-p new)
 313       (error "Already exists directory: %s" new))
 314     (unless (file-directory-p new-dir)
 315       (elmo-make-directory new-dir))
 316     (rename-file old new)
 317     t))
 318
 319 (defsubst elmo-localdir-field-condition-match (folder condition
 320                                                       number number-list)
 321   (elmo-file-field-condition-match
 322    (expand-file-name (int-to-string number)
 323                      (elmo-localdir-folder-directory-internal folder))
 324    condition number number-list))
 325
 326 (luna-define-method elmo-folder-pack-numbers ((folder elmo-localdir-folder))
 327   (let* ((dir (elmo-localdir-folder-directory-internal folder))
 328          (msgdb (elmo-folder-msgdb folder))
 329          (new-msgdb (elmo-make-msgdb))
 330          (numbers (sort (elmo-folder-list-messages
 331                          folder
 332                          nil
 333                          (not elmo-pack-number-check-strict))
 334                         '<))
 335          (new-number 1)           ; first ordinal position in localdir
 336          total entity)
 337     (elmo-msgdb-set-path new-msgdb (elmo-folder-msgdb-path folder))
 338     (setq total (length numbers))
 339     (elmo-with-progress-display (> total elmo-display-progress-threshold)
 340         (elmo-folder-pack-numbers total "Packing...")
 341       (dolist (old-number numbers)
 342         (setq entity (elmo-msgdb-message-entity msgdb old-number))
 343         (when (not (eq old-number new-number)) ; why \=() is wrong..
 344           (elmo-bind-directory
 345            dir
 346            ;; xxx  nfs,hardlink
 347            (rename-file (int-to-string old-number)
 348                         (int-to-string new-number) t))
 349           (elmo-msgdb-overview-entity-set-number entity new-number))
 350         (elmo-msgdb-append-entity new-msgdb entity
 351                                   (elmo-msgdb-flags msgdb old-number))
 352         (setq new-number (1+ new-number))))
 353     (message "Packing...done")
 354     (elmo-folder-set-msgdb-internal folder new-msgdb)))
 355
 356 (luna-define-method elmo-folder-message-file-p ((folder elmo-localdir-folder))
 357   t)
 358
 359 (luna-define-method elmo-message-file-name ((folder elmo-localdir-folder)
 360                                             number)
 361   (expand-file-name
 362    (int-to-string number)
 363    (elmo-localdir-folder-directory-internal folder)))
 364
 365 (defun elmo-localdir-locked-p ()
 366   (if elmo-localdir-lockfile-list
 367       (let ((lock elmo-localdir-lockfile-list))
 368         (catch 'found
 369           (while lock
 370             (if (file-exists-p (car lock))
 371                 (throw 'found t))
 372             (setq lock (cdr lock)))))))
 373
 374 (require 'product)
 375 (product-provide (provide 'elmo-localdir) (require 'elmo-version))
 376
 377 ;;; elmo-localdir.el ends here