elmo/elmo-localdir.el

   1 ;;; elmo-localdir.el -- Localdir Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   5 ;; Copyright (C) 1999,2000      Kenichi OKADA  <okada@opaopa.org>
   6
   7 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   8 ;;      Masahiro MURATA <muse@ba2.so-net.ne.jp>
   9 ;;      Kenichi OKADA <okada@opaopa.org>
  10 ;; Keywords: mail, net news
  11
  12 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  13
  14 ;; This program is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18 ;;
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23 ;;
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28 ;;
  29
  30 ;;; Commentary:
  31 ;;
  32
  33 ;;; Code:
  34 ;;
  35 (eval-when-compile (require 'cl))
  36
  37 (require 'elmo-msgdb)
  38 (require 'elmo)
  39
  40 (defcustom elmo-localdir-folder-path "~/Mail"
  41   "*Local mail directory (MH format) path."
  42   :type 'directory
  43   :group 'elmo)
  44
  45 (defvar elmo-localdir-lockfile-list nil)
  46
  47 ;;; ELMO Local directory folder
  48 (eval-and-compile
  49   (luna-define-class elmo-localdir-folder (elmo-folder)
  50                      (dir-name directory))
  51   (luna-define-internal-accessors 'elmo-localdir-folder))
  52
  53 ;;; elmo-localdir specific methods.
  54 (luna-define-generic elmo-localdir-folder-path (folder)
  55   "Return local directory path of the FOLDER.")
  56
  57 (luna-define-generic elmo-localdir-folder-name (folder name)
  58   "Return directory NAME for FOLDER.")
  59
  60 (luna-define-method elmo-localdir-folder-path ((folder elmo-localdir-folder))
  61   elmo-localdir-folder-path)
  62
  63 (luna-define-method elmo-localdir-folder-name ((folder elmo-localdir-folder)
  64                                                name)
  65   name)
  66
  67 (luna-define-method elmo-folder-initialize ((folder
  68                                              elmo-localdir-folder)
  69                                             name)
  70   (elmo-localdir-folder-set-dir-name-internal folder name)
  71   (if (file-name-absolute-p name)
  72       (elmo-localdir-folder-set-directory-internal
  73        folder
  74        (expand-file-name name))
  75     (elmo-localdir-folder-set-directory-internal
  76      folder
  77      (expand-file-name
  78       (elmo-localdir-folder-name folder name)
  79       (elmo-localdir-folder-path folder))))
  80   folder)
  81
  82 ;; open, check, commit, and close are generic.
  83
  84 (luna-define-method elmo-folder-exists-p ((folder elmo-localdir-folder))
  85   (file-directory-p (elmo-localdir-folder-directory-internal folder)))
  86
  87 (luna-define-method elmo-folder-expand-msgdb-path ((folder
  88                                                     elmo-localdir-folder))
  89   (expand-file-name
  90    (mapconcat
  91     'identity
  92     (mapcar
  93      'elmo-replace-string-as-filename
  94      (split-string (elmo-localdir-folder-dir-name-internal folder)
  95                    "/"))
  96     "/")
  97    (expand-file-name ;;"localdir"
  98     (symbol-name (elmo-folder-type-internal folder))
  99     elmo-msgdb-dir)))
 100
 101 (luna-define-method elmo-message-file-name ((folder
 102                                              elmo-localdir-folder)
 103                                             number)
 104   (expand-file-name (int-to-string number)
 105                     (elmo-localdir-folder-directory-internal folder)))
 106
 107 (luna-define-method elmo-folder-message-file-number-p ((folder
 108                                                         elmo-localdir-folder))
 109   t)
 110
 111 (luna-define-method elmo-folder-message-file-directory ((folder
 112                                                          elmo-localdir-folder))
 113   (elmo-localdir-folder-directory-internal folder))
 114
 115 (luna-define-method elmo-folder-message-make-temp-file-p
 116   ((folder elmo-localdir-folder))
 117   t)
 118
 119 (luna-define-method elmo-folder-message-make-temp-files ((folder
 120                                                           elmo-localdir-folder)
 121                                                          numbers
 122                                                          &optional
 123                                                          start-number)
 124   (let ((temp-dir (elmo-folder-make-temp-dir folder))
 125         (cur-number (if start-number 0)))
 126     (dolist (number numbers)
 127       (elmo-add-name-to-file
 128        (expand-file-name
 129         (int-to-string number)
 130         (elmo-localdir-folder-directory-internal folder))
 131        (expand-file-name
 132         (int-to-string (if start-number (incf cur-number) number))
 133         temp-dir)))
 134     temp-dir))
 135
 136 (defun elmo-localdir-msgdb-create-entity (dir number)
 137   (elmo-msgdb-create-overview-entity-from-file
 138    number (expand-file-name (int-to-string number) dir)))
 139
 140 (luna-define-method elmo-folder-msgdb-create ((folder elmo-localdir-folder)
 141                                               numbers
 142                                               new-mark
 143                                               already-mark
 144                                               seen-mark
 145                                               important-mark
 146                                               seen-list)
 147   (when numbers
 148     (let ((dir (elmo-localdir-folder-directory-internal folder))
 149           overview number-alist mark-alist entity message-id
 150           num seen gmark
 151           (i 0)
 152           (len (length numbers)))
 153       (message "Creating msgdb...")
 154       (while numbers
 155         (setq entity
 156               (elmo-localdir-msgdb-create-entity
 157                dir (car numbers)))
 158         (if (null entity)
 159             ()
 160           (setq num (elmo-msgdb-overview-entity-get-number entity))
 161           (setq overview
 162                 (elmo-msgdb-append-element
 163                  overview entity))
 164           (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 165           (setq number-alist
 166                 (elmo-msgdb-number-add number-alist
 167                                        num
 168                                        message-id))
 169           (setq seen (member message-id seen-list))
 170           (if (setq gmark (or (elmo-msgdb-global-mark-get message-id)
 171                               (if (elmo-file-cache-exists-p message-id) ; XXX
 172                                   (if seen
 173                                       nil
 174                                     already-mark)
 175                                 (if seen
 176                                     nil ;;seen-mark
 177                                   new-mark))))
 178               (setq mark-alist
 179                     (elmo-msgdb-mark-append
 180                      mark-alist
 181                      num
 182                      gmark))))
 183         (when (> len elmo-display-progress-threshold)
 184           (setq i (1+ i))
 185           (elmo-display-progress
 186            'elmo-localdir-msgdb-create-as-numbers "Creating msgdb..."
 187            (/ (* i 100) len)))
 188         (setq numbers (cdr numbers)))
 189       (message "Creating msgdb...done")
 190       (list overview number-alist mark-alist))))
 191
 192 (luna-define-method elmo-folder-list-subfolders ((folder elmo-localdir-folder)
 193                                                  &optional one-level)
 194   (mapcar
 195    (lambda (x) (concat (elmo-folder-prefix-internal folder) x))
 196    (elmo-list-subdirectories
 197     (elmo-localdir-folder-path folder)
 198     (or (elmo-localdir-folder-dir-name-internal folder) "")
 199     one-level)))
 200
 201 (defsubst elmo-localdir-list-subr (folder &optional nonsort)
 202   (let ((flist (mapcar 'string-to-int
 203                        (directory-files
 204                         (elmo-localdir-folder-directory-internal folder)
 205                         nil "^[0-9]+$" t)))
 206         (killed (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 207     (if nonsort
 208         (cons (or (elmo-max-of-list flist) 0)
 209               (if killed
 210                   (- (length flist)
 211                      (elmo-msgdb-killed-list-length killed))
 212                 (length flist)))
 213       (sort flist '<))))
 214
 215 (luna-define-method elmo-folder-append-buffer ((folder elmo-localdir-folder)
 216                                                unread
 217                                                &optional number)
 218   (let ((filename (elmo-message-file-name
 219                    folder
 220                    (or number
 221                        (1+ (car (elmo-folder-status folder)))))))
 222     (if (file-writable-p filename)
 223         (write-region-as-binary
 224          (point-min) (point-max) filename nil 'no-msg))
 225     t))
 226
 227 (luna-define-method elmo-folder-append-messages :around ((folder elmo-localdir-folder)
 228                                                          src-folder numbers
 229                                                          unread-marks
 230                                                          &optional same-number)
 231   (if (elmo-folder-message-file-p src-folder)
 232       (let ((dir (elmo-localdir-folder-directory-internal folder))
 233             (succeeds numbers)
 234             (next-num (1+ (car (elmo-folder-status folder)))))
 235         (while numbers
 236           (elmo-copy-file
 237            (elmo-message-file-name src-folder (car numbers))
 238            (expand-file-name
 239             (int-to-string
 240              (if same-number (car numbers) next-num))
 241             dir))
 242           (if (and (setq numbers (cdr numbers))
 243                    (not same-number))
 244               (setq next-num
 245                     (if (elmo-localdir-locked-p)
 246                         ;; MDA is running.
 247                         (1+ (car (elmo-folder-status folder)))
 248                       (1+ next-num)))))
 249         succeeds)
 250     (luna-call-next-method)))
 251
 252 (luna-define-method elmo-folder-delete-messages ((folder elmo-localdir-folder)
 253                                                  numbers)
 254   (dolist (number numbers)
 255     (elmo-localdir-delete-message folder number))
 256   t)
 257
 258 (defun elmo-localdir-delete-message (folder number)
 259   "Delete message in the FOLDER with NUMBER."
 260   (let ((filename (elmo-message-file-name folder number)))
 261     (when (and (string-match "[0-9]+" filename) ; for safety.
 262                (file-exists-p filename)
 263                (file-writable-p filename)
 264                (not (file-directory-p filename)))
 265       (delete-file filename)
 266       t)))
 267
 268 (luna-define-method elmo-message-fetch ((folder elmo-localdir-folder)
 269                                         number strategy
 270                                         &optional section outbuf unseen)
 271   ;; strategy, section, unseen is ignored.
 272   (if outbuf
 273       (with-current-buffer outbuf
 274         (erase-buffer)
 275         (when (file-exists-p (elmo-message-file-name folder number))
 276           (insert-file-contents-as-binary
 277            (elmo-message-file-name folder number))
 278           (elmo-delete-cr-buffer))
 279         t)
 280     (with-temp-buffer
 281       (when (file-exists-p (elmo-message-file-name folder number))
 282         (insert-file-contents-as-binary (elmo-message-file-name folder number))
 283         (elmo-delete-cr-buffer))
 284       (buffer-string))))
 285
 286 (luna-define-method elmo-folder-list-messages-internal
 287   ((folder elmo-localdir-folder) &optional nohide)
 288   (elmo-localdir-list-subr folder))
 289
 290 (luna-define-method elmo-folder-status ((folder elmo-localdir-folder))
 291   (elmo-localdir-list-subr folder t))
 292
 293 (luna-define-method elmo-folder-creatable-p ((folder elmo-localdir-folder))
 294   t)
 295
 296 (luna-define-method elmo-folder-create ((folder elmo-localdir-folder))
 297   (let ((dir (elmo-localdir-folder-directory-internal folder)))
 298     (if (file-directory-p dir)
 299         ()
 300       (if (file-exists-p dir)
 301           (error "Create folder failed")
 302         (elmo-make-directory dir))
 303       t)))
 304
 305 (luna-define-method elmo-folder-delete ((folder elmo-localdir-folder))
 306   (let ((dir (elmo-localdir-folder-directory-internal folder)))
 307     (if (not (file-directory-p dir))
 308         (error "No such directory: %s" dir)
 309       (elmo-delete-directory dir t)
 310       t)))
 311
 312 (luna-define-method elmo-folder-rename-internal ((folder elmo-localdir-folder)
 313                                                  new-folder)
 314   (let* ((old (elmo-localdir-folder-directory-internal folder))
 315          (new (elmo-localdir-folder-directory-internal folder))
 316          (new-dir (directory-file-name (file-name-directory new))))
 317     (if (not (file-directory-p old))
 318         (error "No such directory: %s" old)
 319       (if (file-exists-p new)
 320           (error "Already exists directory: %s" new)
 321         (if (not (file-exists-p new-dir))
 322             (elmo-make-directory new-dir))
 323         (rename-file old new)
 324         t))))
 325
 326 (defsubst elmo-localdir-field-condition-match (folder condition
 327                                                       number number-list)
 328   (elmo-file-field-condition-match
 329    (expand-file-name (int-to-string number)
 330                      (elmo-localdir-folder-directory-internal folder))
 331    condition number number-list))
 332
 333 (luna-define-method elmo-folder-search ((folder elmo-localdir-folder)
 334                                         condition &optional numbers)
 335   (let* ((msgs (or numbers (elmo-folder-list-messages folder)))
 336          (num (length msgs))
 337          (i 0)
 338          number-list case-fold-search ret-val)
 339     (setq number-list msgs)
 340     (while msgs
 341       (if (elmo-localdir-field-condition-match folder condition
 342                                                (car msgs) number-list)
 343           (setq ret-val (cons (car msgs) ret-val)))
 344       (when (> num elmo-display-progress-threshold)
 345         (setq i (1+ i))
 346         (elmo-display-progress
 347          'elmo-localdir-search "Searching..."
 348          (/ (* i 100) num)))
 349       (setq msgs (cdr msgs)))
 350     (nreverse ret-val)))
 351
 352 (luna-define-method elmo-folder-pack-numbers ((folder elmo-localdir-folder))
 353   (let* ((dir (elmo-localdir-folder-directory-internal folder))
 354          (msgdb (elmo-folder-msgdb folder))
 355          (onum-alist (elmo-msgdb-get-number-alist msgdb))
 356          (omark-alist (elmo-msgdb-get-mark-alist (elmo-folder-msgdb msgdb)))
 357          (new-number 1)                 ; first ordinal position in localdir
 358          flist onum mark new-mark-alist total)
 359     (setq flist
 360           (if elmo-pack-number-check-strict
 361               (elmo-folder-list-messages folder) ; allow localnews
 362             (mapcar 'car onum-alist)))
 363     (setq total (length flist))
 364     (while flist
 365       (when (> total elmo-display-progress-threshold)
 366         (elmo-display-progress
 367          'elmo-folder-pack-numbers "Packing..."
 368          (/ (* new-number 100) total)))
 369       (setq onum (car flist))
 370       (when (not (eq onum new-number))          ; why \=() is wrong..
 371         (elmo-bind-directory
 372          dir
 373          ;; xxx  nfs,hardlink
 374          (rename-file (int-to-string onum) (int-to-string new-number) t))
 375         ;; update overview
 376         (elmo-msgdb-overview-entity-set-number
 377          (elmo-msgdb-overview-get-entity onum msgdb)
 378          new-number)
 379         ;; update number-alist
 380         (setcar (assq onum onum-alist) new-number))
 381       ;; update mark-alist
 382       (when (setq mark (cadr (assq onum omark-alist)))
 383         (setq new-mark-alist
 384               (elmo-msgdb-mark-append
 385                new-mark-alist
 386                new-number mark)))
 387       (setq new-number (1+ new-number))
 388       (setq flist (cdr flist)))
 389     (message "Packing...done")
 390     (elmo-folder-set-msgdb-internal
 391      folder
 392      (list (elmo-msgdb-get-overview msgdb)
 393            onum-alist
 394            new-mark-alist
 395            ;; remake hash table
 396            (elmo-msgdb-make-overview-hashtb
 397             (elmo-msgdb-get-overview msgdb))))))
 398
 399 (luna-define-method elmo-folder-message-file-p ((folder elmo-localdir-folder))
 400   t)
 401
 402 (luna-define-method elmo-message-file-name ((folder elmo-localdir-folder)
 403                                             number)
 404   (expand-file-name
 405    (int-to-string number)
 406    (elmo-localdir-folder-directory-internal folder)))
 407
 408 (defun elmo-localdir-locked-p ()
 409   (if elmo-localdir-lockfile-list
 410       (let ((lock elmo-localdir-lockfile-list))
 411         (catch 'found
 412           (while lock
 413             (if (file-exists-p (car lock))
 414                 (throw 'found t))
 415             (setq lock (cdr lock)))))))
 416
 417 (require 'product)
 418 (product-provide (provide 'elmo-localdir) (require 'elmo-version))
 419
 420 ;;; elmo-localdir.el ends here