elmo/elmo-localdir.el

   1 ;;; elmo-localdir.el --- Localdir Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   5 ;; Copyright (C) 1999,2000      Kenichi OKADA  <okada@opaopa.org>
   6
   7 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   8 ;;      Masahiro MURATA <muse@ba2.so-net.ne.jp>
   9 ;;      Kenichi OKADA <okada@opaopa.org>
  10 ;; Keywords: mail, net news
  11
  12 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  13
  14 ;; This program is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18 ;;
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23 ;;
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28 ;;
  29
  30 ;;; Commentary:
  31 ;;
  32
  33 ;;; Code:
  34 ;;
  35 (eval-when-compile (require 'cl))
  36
  37 (require 'elmo-msgdb)
  38 (require 'elmo)
  39
  40 (defcustom elmo-localdir-folder-path "~/Mail"
  41   "*Local mail directory (MH format) path."
  42   :type 'directory
  43   :group 'elmo)
  44
  45 (defvar elmo-localdir-lockfile-list nil)
  46
  47 ;;; ELMO Local directory folder
  48 (eval-and-compile
  49   (luna-define-class elmo-localdir-folder (elmo-folder)
  50                      (dir-name directory))
  51   (luna-define-internal-accessors 'elmo-localdir-folder))
  52
  53 ;;; elmo-localdir specific methods.
  54 (luna-define-generic elmo-localdir-folder-path (folder)
  55   "Return local directory path of the FOLDER.")
  56
  57 (luna-define-generic elmo-localdir-folder-name (folder name)
  58   "Return directory NAME for FOLDER.")
  59
  60 (luna-define-method elmo-localdir-folder-path ((folder elmo-localdir-folder))
  61   elmo-localdir-folder-path)
  62
  63 (luna-define-method elmo-localdir-folder-name ((folder elmo-localdir-folder)
  64                                                name)
  65   name)
  66
  67 (luna-define-method elmo-folder-initialize ((folder
  68                                              elmo-localdir-folder)
  69                                             name)
  70   (elmo-localdir-folder-set-dir-name-internal folder name)
  71   (if (file-name-absolute-p name)
  72       (elmo-localdir-folder-set-directory-internal
  73        folder
  74        (expand-file-name name))
  75     (elmo-localdir-folder-set-directory-internal
  76      folder
  77      (expand-file-name
  78       (elmo-localdir-folder-name folder name)
  79       (elmo-localdir-folder-path folder))))
  80   folder)
  81
  82 ;; open, check, commit, and close are generic.
  83
  84 (luna-define-method elmo-folder-exists-p ((folder elmo-localdir-folder))
  85   (file-directory-p (elmo-localdir-folder-directory-internal folder)))
  86
  87 (luna-define-method elmo-folder-expand-msgdb-path ((folder
  88                                                     elmo-localdir-folder))
  89   (expand-file-name
  90    (mapconcat
  91     'identity
  92     (mapcar
  93      'elmo-replace-string-as-filename
  94      (split-string
  95       (let ((dir-name (elmo-localdir-folder-dir-name-internal folder)))
  96         (if (file-name-absolute-p dir-name)
  97             (expand-file-name dir-name)
  98           dir-name))
  99       "/"))
 100     "/")
 101    (expand-file-name ;;"localdir"
 102     (symbol-name (elmo-folder-type-internal folder))
 103     elmo-msgdb-directory)))
 104
 105 (luna-define-method elmo-message-file-name ((folder
 106                                              elmo-localdir-folder)
 107                                             number)
 108   (expand-file-name (int-to-string number)
 109                     (elmo-localdir-folder-directory-internal folder)))
 110
 111 (luna-define-method elmo-folder-message-file-number-p ((folder
 112                                                         elmo-localdir-folder))
 113   t)
 114
 115 (luna-define-method elmo-folder-message-file-directory ((folder
 116                                                          elmo-localdir-folder))
 117   (elmo-localdir-folder-directory-internal folder))
 118
 119 (luna-define-method elmo-folder-message-make-temp-file-p
 120   ((folder elmo-localdir-folder))
 121   t)
 122
 123 (luna-define-method elmo-folder-message-make-temp-files ((folder
 124                                                           elmo-localdir-folder)
 125                                                          numbers
 126                                                          &optional
 127                                                          start-number)
 128   (let ((temp-dir (elmo-folder-make-temporary-directory folder))
 129         (cur-number (or start-number 0)))
 130     (dolist (number numbers)
 131       (elmo-copy-file
 132        (expand-file-name
 133         (int-to-string number)
 134         (elmo-localdir-folder-directory-internal folder))
 135        (expand-file-name
 136         (int-to-string (if start-number cur-number number))
 137         temp-dir))
 138       (incf cur-number))
 139     temp-dir))
 140
 141 (defun elmo-localdir-msgdb-create-entity (dir number)
 142   (elmo-msgdb-create-overview-entity-from-file
 143    number (expand-file-name (int-to-string number) dir)))
 144
 145 (luna-define-method elmo-folder-msgdb-create ((folder elmo-localdir-folder)
 146                                               numbers
 147                                               flag-table)
 148   (when numbers
 149     (let ((dir (elmo-localdir-folder-directory-internal folder))
 150           overview number-alist mark-alist entity message-id
 151           num gmark
 152           (i 0)
 153           (len (length numbers)))
 154       (message "Creating msgdb...")
 155       (while numbers
 156         (setq entity
 157               (elmo-localdir-msgdb-create-entity
 158                dir (car numbers)))
 159         (if (null entity)
 160             ()
 161           (setq num (elmo-msgdb-overview-entity-get-number entity))
 162           (setq overview
 163                 (elmo-msgdb-append-element
 164                  overview entity))
 165           (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 166           (setq number-alist
 167                 (elmo-msgdb-number-add number-alist
 168                                        num
 169                                        message-id))
 170           (if (setq gmark (or (elmo-msgdb-global-mark-get message-id)
 171                               (unless (eq 'read (elmo-flag-table-get
 172                                                  flag-table message-id))
 173                                 (elmo-msgdb-mark
 174                                  (elmo-flag-table-get flag-table message-id)
 175                                  (elmo-file-cache-status
 176                                   (elmo-file-cache-get message-id))
 177                                  'new))))
 178               (setq mark-alist
 179                     (elmo-msgdb-mark-append
 180                      mark-alist
 181                      num
 182                      gmark))))
 183         (when (> len elmo-display-progress-threshold)
 184           (setq i (1+ i))
 185           (elmo-display-progress
 186            'elmo-localdir-msgdb-create-as-numbers "Creating msgdb..."
 187            (/ (* i 100) len)))
 188         (setq numbers (cdr numbers)))
 189       (message "Creating msgdb...done")
 190       (list overview number-alist mark-alist))))
 191
 192 (luna-define-method elmo-folder-list-subfolders ((folder elmo-localdir-folder)
 193                                                  &optional one-level)
 194   (elmo-mapcar-list-of-list
 195    (lambda (x) (concat (elmo-folder-prefix-internal folder) x))
 196    (elmo-list-subdirectories
 197     (elmo-localdir-folder-path folder)
 198     (or (elmo-localdir-folder-dir-name-internal folder) "")
 199     one-level)))
 200
 201 (defsubst elmo-localdir-list-subr (folder &optional nonsort)
 202   (let ((flist (mapcar 'string-to-int
 203                        (directory-files
 204                         (elmo-localdir-folder-directory-internal folder)
 205                         nil "^[0-9]+$" t)))
 206         (killed (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 207     (if nonsort
 208         (cons (or (elmo-max-of-list flist) 0)
 209               (if killed
 210                   (- (length flist)
 211                      (elmo-msgdb-killed-list-length killed))
 212                 (length flist)))
 213       (sort flist '<))))
 214
 215 (luna-define-method elmo-folder-append-buffer ((folder elmo-localdir-folder)
 216                                                unread
 217                                                &optional number)
 218   (let ((filename (elmo-message-file-name
 219                    folder
 220                    (or number
 221                        (1+ (car (elmo-folder-status folder)))))))
 222     (when (file-writable-p filename)
 223       (write-region-as-binary
 224        (point-min) (point-max) filename nil 'no-msg)
 225       t)))
 226
 227 (luna-define-method elmo-folder-append-messages :around
 228   ((folder elmo-localdir-folder)
 229    src-folder numbers &optional same-number)
 230   (if (elmo-folder-message-file-p src-folder)
 231       (let ((dir (elmo-localdir-folder-directory-internal folder))
 232             (table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
 233             (succeeds numbers)
 234             (next-num (1+ (car (elmo-folder-status folder))))
 235             mark flag)
 236         (while numbers
 237           (setq mark (elmo-message-mark src-folder (car numbers))
 238                 flag (cond
 239                       ((null mark) nil)
 240                       ((member mark (elmo-msgdb-answered-marks))
 241                        'answered)
 242                       ;;
 243                       ((not (member mark (elmo-msgdb-unread-marks)))
 244                        'read)))
 245           (elmo-copy-file
 246            (elmo-message-file-name src-folder (car numbers))
 247            (expand-file-name
 248             (int-to-string
 249              (if same-number (car numbers) next-num))
 250             dir))
 251           (elmo-flag-table-set table
 252                                (elmo-message-field
 253                                 src-folder (car numbers)
 254                                 'message-id)
 255                                flag)
 256           (elmo-progress-notify 'elmo-folder-move-messages)
 257           (if (and (setq numbers (cdr numbers))
 258                    (not same-number))
 259               (setq next-num
 260                     (if (elmo-localdir-locked-p)
 261                         ;; MDA is running.
 262                         (1+ (car (elmo-folder-status folder)))
 263                       (1+ next-num)))))
 264         (when (elmo-folder-persistent-p folder)
 265           (elmo-flag-table-save (elmo-folder-msgdb-path folder) table))
 266         succeeds)
 267     (luna-call-next-method)))
 268
 269 (luna-define-method elmo-folder-delete-messages ((folder elmo-localdir-folder)
 270                                                  numbers)
 271   (dolist (number numbers)
 272     (elmo-localdir-delete-message folder number))
 273   t)
 274
 275 (defun elmo-localdir-delete-message (folder number)
 276   "Delete message in the FOLDER with NUMBER."
 277   (let ((filename (elmo-message-file-name folder number)))
 278     (when (and (string-match "[0-9]+" filename) ; for safety.
 279                (file-exists-p filename)
 280                (file-writable-p filename)
 281                (not (file-directory-p filename)))
 282       (delete-file filename)
 283       t)))
 284
 285 (luna-define-method elmo-message-fetch-internal ((folder elmo-localdir-folder)
 286                                                  number strategy
 287                                                  &optional section unread)
 288   (when (file-exists-p (elmo-message-file-name folder number))
 289     (insert-file-contents-as-binary
 290      (elmo-message-file-name folder number))))
 291
 292 (luna-define-method elmo-folder-list-messages-internal
 293   ((folder elmo-localdir-folder) &optional nohide)
 294   (elmo-localdir-list-subr folder))
 295
 296 (luna-define-method elmo-folder-status ((folder elmo-localdir-folder))
 297   (elmo-localdir-list-subr folder t))
 298
 299 (luna-define-method elmo-folder-creatable-p ((folder elmo-localdir-folder))
 300   t)
 301
 302 (luna-define-method elmo-folder-writable-p ((folder elmo-localdir-folder))
 303   t)
 304
 305 (luna-define-method elmo-folder-create ((folder elmo-localdir-folder))
 306   (let ((dir (elmo-localdir-folder-directory-internal folder)))
 307     (if (file-directory-p dir)
 308         ()
 309       (if (file-exists-p dir)
 310           (error "Create folder failed")
 311         (elmo-make-directory dir))
 312       t)))
 313
 314 (luna-define-method elmo-folder-delete ((folder elmo-localdir-folder))
 315   (let ((msgs (and (elmo-folder-exists-p folder)
 316                    (elmo-folder-list-messages folder))))
 317     (when (yes-or-no-p (format "%sDelete msgdb and substance of \"%s\"? "
 318                                (if (> (length msgs) 0)
 319                                    (format "%d msg(s) exists. " (length msgs))
 320                                  "")
 321                                (elmo-folder-name-internal folder)))
 322       (let ((dir (elmo-localdir-folder-directory-internal folder)))
 323         (if (not (file-directory-p dir))
 324             (error "No such directory: %s" dir)
 325           (elmo-delete-match-files dir "[0-9]+" t)))
 326       (elmo-msgdb-delete-path folder)
 327       t)))
 328
 329 (luna-define-method elmo-folder-rename-internal ((folder elmo-localdir-folder)
 330                                                  new-folder)
 331   (let* ((old (elmo-localdir-folder-directory-internal folder))
 332          (new (elmo-localdir-folder-directory-internal new-folder))
 333          (new-dir (directory-file-name (file-name-directory new))))
 334     (unless (file-directory-p old)
 335       (error "No such directory: %s" old))
 336     (when (file-exists-p new)
 337       (error "Already exists directory: %s" new))
 338     (unless (file-directory-p new-dir)
 339       (elmo-make-directory new-dir))
 340     (rename-file old new)
 341     t))
 342
 343 (defsubst elmo-localdir-field-condition-match (folder condition
 344                                                       number number-list)
 345   (elmo-file-field-condition-match
 346    (expand-file-name (int-to-string number)
 347                      (elmo-localdir-folder-directory-internal folder))
 348    condition number number-list))
 349
 350 (luna-define-method elmo-folder-pack-numbers ((folder elmo-localdir-folder))
 351   (let* ((dir (elmo-localdir-folder-directory-internal folder))
 352          (msgdb (elmo-folder-msgdb folder))
 353          (onum-alist (elmo-msgdb-get-number-alist msgdb))
 354          (omark-alist (elmo-msgdb-get-mark-alist msgdb))
 355          (new-number 1)                 ; first ordinal position in localdir
 356          flist onum mark new-mark-alist total)
 357     (setq flist
 358           (if elmo-pack-number-check-strict
 359               (elmo-folder-list-messages folder) ; allow localnews
 360             (mapcar 'car onum-alist)))
 361     (setq total (length flist))
 362     (while flist
 363       (when (> total elmo-display-progress-threshold)
 364         (elmo-display-progress
 365          'elmo-folder-pack-numbers "Packing..."
 366          (/ (* new-number 100) total)))
 367       (setq onum (car flist))
 368       (when (not (eq onum new-number))          ; why \=() is wrong..
 369         (elmo-bind-directory
 370          dir
 371          ;; xxx  nfs,hardlink
 372          (rename-file (int-to-string onum) (int-to-string new-number) t))
 373         ;; update overview
 374         (elmo-msgdb-overview-entity-set-number
 375          (elmo-msgdb-overview-get-entity onum msgdb)
 376          new-number)
 377         ;; update number-alist
 378         (and (assq onum onum-alist)
 379              (setcar (assq onum onum-alist) new-number)))
 380       ;; update mark-alist
 381       (when (setq mark (cadr (assq onum omark-alist)))
 382         (setq new-mark-alist
 383               (elmo-msgdb-mark-append
 384                new-mark-alist
 385                new-number mark)))
 386       (setq new-number (1+ new-number))
 387       (setq flist (cdr flist)))
 388     (message "Packing...done")
 389     (elmo-folder-set-msgdb-internal
 390      folder
 391      (elmo-make-msgdb
 392       (elmo-msgdb-get-overview msgdb)
 393       onum-alist
 394       new-mark-alist))))
 395
 396 (luna-define-method elmo-folder-message-file-p ((folder elmo-localdir-folder))
 397   t)
 398
 399 (luna-define-method elmo-message-file-name ((folder elmo-localdir-folder)
 400                                             number)
 401   (expand-file-name
 402    (int-to-string number)
 403    (elmo-localdir-folder-directory-internal folder)))
 404
 405 (defun elmo-localdir-locked-p ()
 406   (if elmo-localdir-lockfile-list
 407       (let ((lock elmo-localdir-lockfile-list))
 408         (catch 'found
 409           (while lock
 410             (if (file-exists-p (car lock))
 411                 (throw 'found t))
 412             (setq lock (cdr lock)))))))
 413
 414 (require 'product)
 415 (product-provide (provide 'elmo-localdir) (require 'elmo-version))
 416
 417 ;;; elmo-localdir.el ends here