elmo/elmo-mime.el

   1 ;;; elmo-mime.el -- MIME module for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'elmo-vars)
  32 (require 'mmbuffer)
  33 (require 'mmimap)
  34 (require 'mime-view)
  35
  36 (eval-and-compile
  37   (luna-define-class mime-elmo-buffer-entity (mime-buffer-entity) ())
  38   (luna-define-class mime-elmo-imap-entity (mime-imap-entity) ()))
  39
  40 ;; Provide backend
  41 (provide 'mmelmo-imap)
  42 (provide 'mmelmo-buffer)
  43
  44 (defvar elmo-message-ignored-field-list mime-view-ignored-field-list)
  45 (defvar elmo-message-visible-field-list mime-view-visible-field-list)
  46 (defvar elmo-message-sorted-field-list nil)
  47
  48 (defcustom elmo-mime-header-max-column fill-column
  49   "*Header max column number. Default is `fill-colmn'.
  50 If a symbol of function is specified, the function is called and its return
  51 value is used."
  52   :type '(choice (integer :tag "Column Number")
  53                  (function :tag "Function"))
  54   :group 'elmo)
  55
  56 (luna-define-method initialize-instance :after ((entity mime-elmo-buffer-entity)
  57                                                 &rest init-args)
  58   entity)
  59
  60 (luna-define-method initialize-instance :around ((entity mime-elmo-imap-entity)
  61                                                  &rest init-args)
  62   (luna-call-next-method))
  63
  64 ;;; Insert sorted header.
  65 (defsubst elmo-mime-insert-header-from-buffer (buffer
  66                                                start end
  67                                                &optional invisible-fields
  68                                                visible-fields
  69                                                sort-fields)
  70   (let ((the-buf (current-buffer))
  71         (mode-obj (mime-find-field-presentation-method 'wide))
  72         field-decoder
  73         f-b p f-e field-name field field-body
  74         vf-alist (sl sort-fields))
  75     (save-excursion
  76       (set-buffer buffer)
  77       (save-restriction
  78         (narrow-to-region start end)
  79         (goto-char start)
  80         (while (re-search-forward std11-field-head-regexp nil t)
  81           (setq f-b (match-beginning 0)
  82                 p (match-end 0)
  83                 field-name (buffer-substring f-b p)
  84                 f-e (std11-field-end))
  85           (when (mime-visible-field-p field-name
  86                                       visible-fields invisible-fields)
  87             (setq field (intern
  88                          (capitalize (buffer-substring f-b (1- p))))
  89                   field-body (buffer-substring p f-e)
  90                   field-decoder (inline (mime-find-field-decoder-internal
  91                                          field mode-obj)))
  92             (setq vf-alist (append (list
  93                                     (cons field-name
  94                                           (list field-body field-decoder)))
  95                                    vf-alist))))
  96         (and vf-alist
  97              (setq vf-alist
  98                    (sort vf-alist
  99                          (function (lambda (s d)
 100                                      (let ((n 0) re
 101                                            (sf (car s))
 102                                            (df (car d)))
 103                                        (catch 'done
 104                                          (while (setq re (nth n sl))
 105                                            (setq n (1+ n))
 106                                            (and (string-match re sf)
 107                                                 (throw 'done t))
 108                                            (and (string-match re df)
 109                                                 (throw 'done nil)))
 110                                          t)))))))
 111         (with-current-buffer the-buf
 112           (while vf-alist
 113             (let* ((vf (car vf-alist))
 114                    (field-name (car vf))
 115                    (field-body (car (cdr vf)))
 116                    (field-decoder (car (cdr (cdr vf)))))
 117               (insert field-name)
 118               (insert (if field-decoder
 119                           (funcall field-decoder field-body
 120                                    (string-width field-name)
 121                                    (if (functionp elmo-mime-header-max-column)
 122                                        (funcall elmo-mime-header-max-column)
 123                                      elmo-mime-header-max-column))
 124                         ;; Don't decode
 125                         field-body))
 126               (insert "\n"))
 127             (setq vf-alist (cdr vf-alist)))
 128           (run-hooks 'mmelmo-header-inserted-hook))))))
 129
 130 (luna-define-generic elmo-mime-insert-sorted-header (entity
 131                                                      &optional invisible-fields
 132                                                      visible-fields
 133                                                      sorted-fields)
 134   "Insert sorted header fields of the ENTITY.")
 135
 136 (luna-define-method elmo-mime-insert-sorted-header ((entity
 137                                                      mime-elmo-buffer-entity)
 138                                                     &optional invisible-fields
 139                                                     visible-fields
 140                                                     sorted-fields)
 141   (elmo-mime-insert-header-from-buffer
 142    (mime-buffer-entity-buffer-internal entity)
 143    (mime-buffer-entity-header-start-internal entity)
 144    (mime-buffer-entity-header-end-internal entity)
 145    invisible-fields visible-fields sorted-fields))
 146
 147 (luna-define-method elmo-mime-insert-sorted-header ((entity
 148                                                      mime-elmo-imap-entity)
 149                                                     &optional invisible-fields
 150                                                     visible-fields
 151                                                     sorted-fields)
 152   (let ((the-buf (current-buffer))
 153         buf p-min p-max)
 154     (with-temp-buffer
 155       (insert (mime-imap-entity-header-string entity))
 156       (setq buf (current-buffer)
 157             p-min (point-min)
 158             p-max (point-max))
 159       (set-buffer the-buf)
 160       (elmo-mime-insert-header-from-buffer buf p-min p-max
 161                                            invisible-fields visible-fields))))
 162
 163 (luna-define-method mime-insert-text-content :around
 164   ((entity mime-elmo-buffer-entity))
 165   (luna-call-next-method)
 166   (run-hooks 'elmo-message-text-content-inserted-hook))
 167
 168 (luna-define-method mime-insert-text-content :around
 169   ((entity mime-elmo-imap-entity))
 170   (luna-call-next-method)
 171   (run-hooks 'elmo-message-text-content-inserted-hook))
 172
 173 (defun elmo-mime-insert-header (entity situation)
 174   (elmo-mime-insert-sorted-header
 175    entity
 176    elmo-message-ignored-field-list
 177    elmo-message-visible-field-list
 178    elmo-message-sorted-field-list)
 179   (run-hooks 'elmo-message-header-inserted-hook))
 180
 181 (defun elmo-make-mime-message-location (folder number strategy rawbuf unread)
 182 ;; Return the MIME message location structure.
 183 ;; FOLDER is the ELMO folder structure.
 184 ;; NUMBER is the number of the message in the FOLDER.
 185 ;; STRATEGY is the message fetching strategy.
 186 ;; RAWBUF is the output buffer for original message.
 187 ;; If second optional argument UNREAD is non-nil, message is not marked
 188 ;; as read.
 189   (if (and strategy
 190            (eq (elmo-fetch-strategy-entireness strategy) 'section))
 191       (luna-make-entity
 192        'mime-elmo-imap-location
 193        :folder folder
 194        :number number
 195        :rawbuf rawbuf
 196        :strategy strategy)
 197     (with-current-buffer rawbuf
 198       (let (buffer-read-only)
 199         (erase-buffer)
 200         (if strategy
 201             (elmo-message-fetch folder number strategy
 202                                 nil (current-buffer)
 203                                 unread))))
 204     rawbuf))
 205
 206 (defun elmo-mime-message-display (folder number viewbuf rawbuf original-mode
 207                                          &optional ignore-cache unread)
 208   "Display MIME message.
 209 A message in the FOLDER with NUMBER is displayed on the VIEWBUF using RAWBUF.
 210 VIEWBUF is a view buffer and RAWBUF is a raw buffer.
 211 ORIGINAL is the major mode of RAWBUF.
 212 If optional argument IGNORE-CACHE is specified, existing cache is ignored.
 213 If second optional argument UNREAD is specified, message is displayed but
 214 keep it as unread.
 215 Return non-nil if not entire message was fetched."
 216   (let (mime-display-header-hook ; Do nothing.
 217         entity strategy)
 218     (setq entity (elmo-msgdb-overview-get-entity number
 219                                                  (elmo-folder-msgdb
 220                                                   folder)))
 221     (setq strategy (elmo-find-fetch-strategy folder entity
 222                                              ignore-cache))
 223     (mime-display-message
 224      (mime-open-entity
 225       (if (and strategy
 226                (eq (elmo-fetch-strategy-entireness strategy) 'section))
 227           'elmo-imap
 228         'elmo-buffer)
 229       (elmo-make-mime-message-location
 230        folder number strategy rawbuf unread))
 231      viewbuf nil nil original-mode)
 232     (if strategy
 233         (or (elmo-fetch-strategy-use-cache strategy)
 234             (eq (elmo-fetch-strategy-entireness strategy)
 235                 'section)))))
 236
 237 (defun elmo-mime-display-as-is (folder number viewbuf rawbuf original-mode
 238                                        &optional ignore-cache unread)
 239   "Display MIME message.
 240 A message in the FOLDER with NUMBER is displayed on the VIEWBUF using RAWBUF.
 241 VIEWBUF is a view buffer and RAWBUF is a raw buffer.
 242 ORIGINAL is the major mode of RAWBUF.
 243 If optional argument IGNORE-CACHE is specified, existing cache is ignored.
 244 If second optional argument UNREAD is specified, message is displayed but
 245 keep it as unread.
 246 Return non-nil if cache is used."
 247   (let ((entity (elmo-msgdb-overview-get-entity number
 248                                                 (elmo-folder-msgdb folder)))
 249         mime-display-header-hook ; Do nothing.
 250         cache-file strategy use-cache)
 251     (setq cache-file (elmo-file-cache-get
 252                       (elmo-msgdb-overview-entity-get-id entity)))
 253     (setq use-cache (eq (elmo-file-cache-status cache-file) 'entire))
 254     (setq strategy (elmo-make-fetch-strategy
 255                     'entire use-cache (elmo-message-use-cache-p folder number)
 256                     (elmo-file-cache-path
 257                      cache-file)))
 258     (elmo-mime-display-as-is-internal
 259      (mime-open-entity
 260       'elmo-buffer
 261       (elmo-make-mime-message-location
 262        folder number strategy rawbuf unread))
 263      viewbuf nil nil original-mode)
 264     (elmo-fetch-strategy-use-cache strategy)))
 265
 266 ;; Replacement of mime-display-message.
 267 (defun elmo-mime-display-as-is-internal (message
 268                                          &optional preview-buffer
 269                                          mother default-keymap-or-function
 270                                          original-major-mode keymap)
 271   (mime-maybe-hide-echo-buffer)
 272   (let ((win-conf (current-window-configuration)))
 273     (or preview-buffer
 274         (setq preview-buffer
 275               (concat "*Preview-" (mime-entity-name message) "*")))
 276     (or original-major-mode
 277         (setq original-major-mode major-mode))
 278     (let ((inhibit-read-only t))
 279       (set-buffer (get-buffer-create preview-buffer))
 280       (widen)
 281       (erase-buffer)
 282       (if mother
 283           (setq mime-mother-buffer mother))
 284       (setq mime-preview-original-window-configuration win-conf)
 285       (setq major-mode 'mime-view-mode)
 286       (setq mode-name "MIME-View")
 287
 288       (mime-insert-entity message)
 289       ;(insert (mime-entity-body message))
 290       ;(insert (mime-entity-body message))
 291
 292       (decode-coding-region (point-min) (point-max) 'undecided)
 293
 294       (save-restriction
 295         (std11-narrow-to-header)
 296         (run-hooks 'elmo-message-header-inserted-hook))
 297 ;      (mime-display-entity message nil
 298 ;                          `((entity-button . invisible)
 299 ;                            (header . visible)
 300 ;                            (major-mode . ,original-major-mode))
 301 ;                          preview-buffer)
 302
 303       (use-local-map
 304        (or keymap
 305            (if default-keymap-or-function
 306                (mime-view-define-keymap default-keymap-or-function)
 307              mime-view-mode-default-map)))
 308       (let ((point
 309              (next-single-property-change (point-min) 'mime-view-entity)))
 310         (if point
 311             (goto-char point)
 312           (goto-char (point-min))
 313           (search-forward "\n\n" nil t)))
 314       (run-hooks 'mime-view-mode-hook)
 315       (set-buffer-modified-p nil)
 316       (setq buffer-read-only t)
 317       preview-buffer)))
 318
 319 (require 'product)
 320 (product-provide (provide 'elmo-mime) (require 'elmo-version))
 321
 322 ;; elmo-mime.el ends here