elmo/elmo-msgdb.el

   1 ;;; elmo-msgdb.el --- Message Database for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 2000           Masahiro MURATA <muse@ba2.so-net.ne.jp>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Masahiro MURATA <muse@ba2.so-net.ne.jp>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33
  34 (eval-when-compile (require 'cl))
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'emu)
  38 (require 'std11)
  39
  40 (defsubst elmo-msgdb-append-element (list element)
  41   (if list
  42 ;;;   (append list (list element))
  43       (nconc list (list element))
  44     ;; list is nil
  45     (list element)))
  46
  47 (defsubst elmo-msgdb-get-overview (msgdb)
  48   (car msgdb))
  49 (defsubst elmo-msgdb-get-number-alist (msgdb)
  50   (cadr msgdb))
  51 (defsubst elmo-msgdb-get-mark-alist (msgdb)
  52   (caddr msgdb))
  53 ;(defsubst elmo-msgdb-get-location (msgdb)
  54 ;  (cadddr msgdb))
  55 (defsubst elmo-msgdb-get-overviewht (msgdb)
  56   (nth 3 msgdb))
  57
  58 ;;
  59 ;; number <-> Message-ID handling
  60 ;;
  61 (defsubst elmo-msgdb-number-add (alist number id)
  62   (let ((ret-val alist))
  63     (setq ret-val
  64           (elmo-msgdb-append-element ret-val (cons number id)))
  65     ret-val))
  66
  67 ;;;
  68 ;; parsistent mark handling
  69 ;; (for global!)
  70
  71 (defvar elmo-msgdb-global-mark-alist nil)
  72
  73 (defun elmo-msgdb-global-mark-delete (msgid)
  74   (let* ((path (expand-file-name
  75                 elmo-msgdb-global-mark-filename
  76                 elmo-msgdb-directory))
  77          (malist (or elmo-msgdb-global-mark-alist
  78                      (setq elmo-msgdb-global-mark-alist
  79                            (elmo-object-load path))))
  80          match)
  81     (when (setq match (assoc msgid malist))
  82       (setq elmo-msgdb-global-mark-alist
  83             (delete match elmo-msgdb-global-mark-alist))
  84       (elmo-object-save path elmo-msgdb-global-mark-alist))))
  85
  86 (defun elmo-msgdb-global-mark-set (msgid mark)
  87   (let* ((path (expand-file-name
  88                 elmo-msgdb-global-mark-filename
  89                 elmo-msgdb-directory))
  90          (malist (or elmo-msgdb-global-mark-alist
  91                      (setq elmo-msgdb-global-mark-alist
  92                            (elmo-object-load path))))
  93          match)
  94     (if (setq match (assoc msgid malist))
  95         (setcdr match mark)
  96       (setq elmo-msgdb-global-mark-alist
  97             (nconc elmo-msgdb-global-mark-alist
  98                    (list (cons msgid mark)))))
  99     (elmo-object-save path elmo-msgdb-global-mark-alist)))
 100
 101 (defun elmo-msgdb-global-mark-get (msgid)
 102   (cdr (assoc msgid (or elmo-msgdb-global-mark-alist
 103                         (setq elmo-msgdb-global-mark-alist
 104                               (elmo-object-load
 105                                (expand-file-name
 106                                 elmo-msgdb-global-mark-filename
 107                                 elmo-msgdb-directory)))))))
 108
 109 ;;;
 110 ;; persistent mark handling
 111 ;; (for each folder)
 112 (defun elmo-msgdb-mark-set (alist id mark)
 113   (let ((ret-val alist)
 114         entity)
 115     (setq entity (assq id alist))
 116     (if entity
 117         (if (eq mark nil)
 118             ;; delete this entity
 119             (setq ret-val (delq entity alist))
 120           ;; set mark
 121           (setcar (cdr entity) mark))
 122       (if mark
 123           (setq ret-val (elmo-msgdb-append-element ret-val
 124                                                    (list id mark)))))
 125     ret-val))
 126
 127 (defun elmo-msgdb-mark-append (alist id mark)
 128   "Append mark."
 129   (setq alist (elmo-msgdb-append-element alist
 130                                          (list id mark))))
 131
 132 (defun elmo-msgdb-mark-alist-to-seen-list (number-alist mark-alist seen-marks)
 133   "Make seen-list from MARK-ALIST."
 134   (let ((seen-mark-list (string-to-char-list seen-marks))
 135         ret-val ent)
 136     (while number-alist
 137       (if (setq ent (assq (car (car number-alist)) mark-alist))
 138           (if (and (cadr ent)
 139                    (memq (string-to-char (cadr ent)) seen-mark-list))
 140               (setq ret-val (cons (cdr (car number-alist)) ret-val)))
 141         (setq ret-val (cons (cdr (car number-alist)) ret-val)))
 142       (setq number-alist (cdr number-alist)))
 143     ret-val))
 144
 145 ;;
 146 ;; mime decode cache
 147
 148 (defvar elmo-msgdb-decoded-cache-hashtb nil)
 149 (make-variable-buffer-local 'elmo-msgdb-decoded-cache-hashtb)
 150
 151 (defsubst elmo-msgdb-get-decoded-cache (string)
 152   (if elmo-use-decoded-cache
 153       (let ((hashtb (or elmo-msgdb-decoded-cache-hashtb
 154                         (setq elmo-msgdb-decoded-cache-hashtb
 155                               (elmo-make-hash 2048))))
 156             decoded)
 157         (or (elmo-get-hash-val string hashtb)
 158             (progn
 159               (elmo-set-hash-val
 160                string
 161                (setq decoded
 162                      (decode-mime-charset-string string elmo-mime-charset))
 163                hashtb)
 164               decoded)))
 165     (decode-mime-charset-string string elmo-mime-charset)))
 166
 167 ;;
 168 ;; overview handling
 169 ;;
 170
 171 (defsubst elmo-msgdb-get-field-value (field-name beg end buffer)
 172   (save-excursion
 173     (save-restriction
 174       (set-buffer buffer)
 175       (narrow-to-region beg end)
 176       (elmo-field-body field-name))))
 177
 178 (defun elmo-multiple-field-body (name &optional boundary)
 179   (save-excursion
 180     (save-restriction
 181       (std11-narrow-to-header boundary)
 182       (goto-char (point-min))
 183       (let ((case-fold-search t)
 184             (field-body nil))
 185         (while (re-search-forward (concat "^" name ":[ \t]*") nil t)
 186           (setq field-body
 187                 (nconc field-body
 188                        (list (buffer-substring-no-properties
 189                               (match-end 0) (std11-field-end))))))
 190         field-body))))
 191
 192 (defun elmo-multiple-fields-body-list (field-names &optional boundary)
 193   "Return list of each field-bodies of FIELD-NAMES of the message header
 194 in current buffer. If BOUNDARY is not nil, it is used as message
 195 header separator."
 196   (save-excursion
 197     (save-restriction
 198       (std11-narrow-to-header boundary)
 199       (let* ((case-fold-search t)
 200              (s-rest field-names)
 201              field-name field-body)
 202         (while (setq field-name (car s-rest))
 203           (goto-char (point-min))
 204           (while (re-search-forward (concat "^" field-name ":[ \t]*") nil t)
 205             (setq field-body
 206                   (nconc field-body
 207                          (list (buffer-substring-no-properties
 208                                 (match-end 0) (std11-field-end))))))
 209           (setq s-rest (cdr s-rest)))
 210         field-body))))
 211
 212 (defsubst elmo-msgdb-remove-field-string (string)
 213   (if (string-match (concat std11-field-head-regexp "[ \t]*") string)
 214       (substring string (match-end 0))
 215     string))
 216
 217 (defsubst elmo-msgdb-get-last-message-id (string)
 218   (if string
 219       (save-match-data
 220         (let (beg)
 221           (elmo-set-work-buf
 222            (insert string)
 223            (goto-char (point-max))
 224            (when (search-backward "<" nil t)
 225              (setq beg (point))
 226              (if (search-forward ">" nil t)
 227                  (elmo-replace-in-string
 228                   (buffer-substring beg (point)) "\n[ \t]*" ""))))))))
 229
 230 (defun elmo-msgdb-number-load (dir)
 231   (elmo-object-load
 232    (expand-file-name elmo-msgdb-number-filename dir)))
 233
 234 (defun elmo-msgdb-overview-load (dir)
 235   (elmo-object-load
 236    (expand-file-name elmo-msgdb-overview-filename dir)))
 237
 238 (defun elmo-msgdb-mark-load (dir)
 239   (elmo-object-load
 240    (expand-file-name elmo-msgdb-mark-filename dir)))
 241
 242 (defsubst elmo-msgdb-seen-load (dir)
 243   (elmo-object-load (expand-file-name
 244                      elmo-msgdb-seen-filename
 245                      dir)))
 246
 247 (defun elmo-msgdb-number-save (dir obj)
 248   (elmo-object-save
 249    (expand-file-name elmo-msgdb-number-filename dir)
 250    obj))
 251
 252 (defun elmo-msgdb-mark-save (dir obj)
 253   (elmo-object-save
 254    (expand-file-name elmo-msgdb-mark-filename dir)
 255    obj))
 256
 257 (defun elmo-msgdb-change-mark (msgdb before after)
 258   "Set the BEFORE marks to AFTER."
 259   (let ((mark-alist (elmo-msgdb-get-mark-alist msgdb))
 260         entity)
 261     (while mark-alist
 262       (setq entity (car mark-alist))
 263       (when (string= (cadr entity) before)
 264         (setcar (cdr entity) after))
 265       (setq mark-alist (cdr mark-alist)))))
 266
 267 (defsubst elmo-msgdb-seen-save (dir obj)
 268   (elmo-object-save
 269    (expand-file-name elmo-msgdb-seen-filename dir)
 270    obj))
 271
 272 (defsubst elmo-msgdb-overview-save (dir overview)
 273   (elmo-object-save
 274    (expand-file-name elmo-msgdb-overview-filename dir)
 275    overview))
 276
 277 (defun elmo-msgdb-search-internal-primitive (condition entity number-list)
 278   (let ((key (elmo-filter-key condition))
 279         (case-fold-search t)
 280         result)
 281     (cond
 282      ((string= key "last")
 283       (setq result (<= (length (memq
 284                                 (elmo-msgdb-overview-entity-get-number entity)
 285                                 number-list))
 286                        (string-to-int (elmo-filter-value condition)))))
 287      ((string= key "first")
 288       (setq result (< (-
 289                        (length number-list)
 290                        (length (memq
 291                                 (elmo-msgdb-overview-entity-get-number entity)
 292                                 number-list)))
 293                       (string-to-int (elmo-filter-value condition)))))
 294      ((string= key "from")
 295       (setq result (string-match
 296                     (elmo-filter-value condition)
 297                     (elmo-msgdb-overview-entity-get-from entity))))
 298      ((string= key "subject")
 299       (setq result (string-match
 300                     (elmo-filter-value condition)
 301                     (elmo-msgdb-overview-entity-get-subject entity))))
 302      ((string= key "to")
 303       (setq result (string-match
 304                     (elmo-filter-value condition)
 305                     (elmo-msgdb-overview-entity-get-to entity))))
 306      ((string= key "cc")
 307       (setq result (string-match
 308                     (elmo-filter-value condition)
 309                     (elmo-msgdb-overview-entity-get-cc entity))))
 310      ((or (string= key "since")
 311           (string= key "before"))
 312       (let ((field-date (elmo-date-make-sortable-string
 313                          (timezone-fix-time
 314                           (elmo-msgdb-overview-entity-get-date entity)
 315                           (current-time-zone) nil)))
 316             (specified-date
 317              (elmo-date-make-sortable-string
 318               (elmo-date-get-datevec
 319                (elmo-filter-value condition)))))
 320         (setq result (if (string= key "since")
 321                          (or (string= specified-date field-date)
 322                              (string< specified-date field-date))
 323                        (string< field-date specified-date)))))
 324      ((member key elmo-msgdb-extra-fields)
 325       (let ((extval (elmo-msgdb-overview-entity-get-extra-field entity key)))
 326         (if (stringp extval)
 327             (setq result (string-match
 328                           (elmo-filter-value condition)
 329                           extval))))))
 330     (if (eq (elmo-filter-type condition) 'unmatch)
 331         (setq result (not result)))
 332     result))
 333
 334 (defun elmo-msgdb-search-internal (condition entity number-list)
 335   (cond
 336    ((vectorp condition)
 337     (elmo-msgdb-search-internal-primitive condition entity number-list))
 338    ((eq (car condition) 'and)
 339     (and (elmo-msgdb-search-internal
 340           (nth 1 condition) entity number-list)
 341          (elmo-msgdb-search-internal
 342           (nth 2 condition) entity number-list)))
 343    ((eq (car condition) 'or)
 344     (or (elmo-msgdb-search-internal
 345          (nth 1 condition) entity number-list)
 346         (elmo-msgdb-search-internal
 347          (nth 2 condition) entity number-list)))))
 348
 349 (defun elmo-msgdb-delete-msgs (msgdb msgs)
 350   "Delete MSGS from MSGDB
 351 content of MSGDB is changed."
 352   (save-excursion
 353     (let* (;(msgdb (elmo-folder-msgdb folder))
 354            (overview (car msgdb))
 355            (number-alist (cadr msgdb))
 356            (mark-alist (caddr msgdb))
 357            (hashtb (elmo-msgdb-get-overviewht msgdb))
 358            (newmsgdb (list overview number-alist mark-alist hashtb))
 359            ov-entity)
 360       ;; remove from current database.
 361       (while msgs
 362         (setq overview
 363               (delq
 364                (setq ov-entity
 365                      (elmo-msgdb-overview-get-entity (car msgs) newmsgdb))
 366                overview))
 367         (when (and elmo-use-overview-hashtb hashtb)
 368           (elmo-msgdb-clear-overview-hashtb ov-entity hashtb))
 369         (setq number-alist
 370               (delq (assq (car msgs) number-alist) number-alist))
 371         (setq mark-alist (delq (assq (car msgs) mark-alist) mark-alist))
 372         (setq msgs (cdr msgs)))
 373       ;(elmo-folder-set-message-modified-internal folder t)
 374       (setcar msgdb overview)
 375       (setcar (cdr msgdb) number-alist)
 376       (setcar (cddr msgdb) mark-alist)
 377       (setcar (nthcdr 3 msgdb) hashtb))
 378     t)) ;return value
 379
 380 (defsubst elmo-msgdb-set-overview (msgdb overview)
 381   (setcar msgdb overview))
 382
 383 (defsubst elmo-msgdb-set-number-alist (msgdb number-alist)
 384   (setcar (cdr msgdb) number-alist))
 385
 386 (defsubst elmo-msgdb-set-mark-alist (msgdb mark-alist)
 387   (setcar (cddr msgdb) mark-alist))
 388
 389 (defsubst elmo-msgdb-overview-entity-get-references (entity)
 390   (and entity (aref (cdr entity) 1)))
 391
 392 (defsubst elmo-msgdb-overview-entity-set-references (entity references)
 393   (and entity (aset (cdr entity) 1 references))
 394   entity)
 395
 396 ;; entity -> parent-entity
 397 (defsubst elmo-msgdb-overview-get-parent-entity (entity database)
 398   (setq entity (elmo-msgdb-overview-entity-get-references entity))
 399   ;; entity is parent-id.
 400   (and entity (assoc entity database)))
 401
 402 (defsubst elmo-msgdb-overview-entity-get-number (entity)
 403   (and entity (aref (cdr entity) 0)))
 404
 405 (defsubst elmo-msgdb-overview-entity-get-from-no-decode (entity)
 406   (and entity (aref (cdr entity) 2)))
 407
 408 (defsubst elmo-msgdb-overview-entity-get-from (entity)
 409   (and entity
 410        (aref (cdr entity) 2)
 411        (elmo-msgdb-get-decoded-cache (aref (cdr entity) 2))))
 412
 413 (defsubst elmo-msgdb-overview-entity-set-number (entity number)
 414   (and entity (aset (cdr entity) 0 number))
 415   entity)
 416 ;;;(setcar (cadr entity) number) entity)
 417
 418 (defsubst elmo-msgdb-overview-entity-set-from (entity from)
 419   (and entity (aset (cdr entity) 2 from))
 420   entity)
 421
 422 (defsubst elmo-msgdb-overview-entity-get-subject (entity)
 423   (and entity
 424        (aref (cdr entity) 3)
 425        (elmo-msgdb-get-decoded-cache (aref (cdr entity) 3))))
 426
 427 (defsubst elmo-msgdb-overview-entity-get-subject-no-decode (entity)
 428   (and entity (aref (cdr entity) 3)))
 429
 430 (defsubst elmo-msgdb-overview-entity-set-subject (entity subject)
 431   (and entity (aset (cdr entity) 3 subject))
 432   entity)
 433
 434 (defsubst elmo-msgdb-overview-entity-get-date (entity)
 435   (and entity (aref (cdr entity) 4)))
 436
 437 (defsubst elmo-msgdb-overview-entity-set-date (entity date)
 438   (and entity (aset (cdr entity) 4 date))
 439   entity)
 440
 441 (defsubst elmo-msgdb-overview-entity-get-to (entity)
 442   (and entity (aref (cdr entity) 5)))
 443
 444 (defsubst elmo-msgdb-overview-entity-get-cc (entity)
 445   (and entity (aref (cdr entity) 6)))
 446
 447 (defsubst elmo-msgdb-overview-entity-get-size (entity)
 448   (and entity (aref (cdr entity) 7)))
 449
 450 (defsubst elmo-msgdb-overview-entity-set-size (entity size)
 451   (and entity (aset (cdr entity) 7 size))
 452   entity)
 453
 454 (defsubst elmo-msgdb-overview-entity-get-id (entity)
 455   (and entity (car entity)))
 456
 457 (defsubst elmo-msgdb-overview-entity-get-extra-field (entity field-name)
 458   (let ((extra (and entity (aref (cdr entity) 8))))
 459     (and extra
 460          (cdr (assoc field-name extra)))))
 461
 462 (defsubst elmo-msgdb-overview-entity-set-extra-field (entity field-name value)
 463   (let ((extras (and entity (aref (cdr entity) 8)))
 464         extra)
 465     (if (setq extra (assoc field-name extras))
 466         (setcdr extra value)
 467       (elmo-msgdb-overview-entity-set-extra
 468        entity
 469        (cons (cons field-name value) extras)))))
 470
 471 (defsubst elmo-msgdb-overview-entity-get-extra (entity)
 472   (and entity (aref (cdr entity) 8)))
 473
 474 (defsubst elmo-msgdb-overview-entity-set-extra (entity extra)
 475   (and entity (aset (cdr entity) 8 extra))
 476   entity)
 477
 478 (defun elmo-msgdb-overview-get-entity-by-number (database number)
 479   (when number
 480     (let ((db database)
 481           entity)
 482       (while db
 483         (if (eq (elmo-msgdb-overview-entity-get-number (car db)) number)
 484             (setq entity (car db)
 485                   db nil) ; exit loop
 486           (setq db (cdr db))))
 487       entity)))
 488
 489 (defun elmo-msgdb-overview-get-entity (id msgdb)
 490   (when id
 491     (let ((ovht (elmo-msgdb-get-overviewht msgdb)))
 492       (if ovht ; use overview hash
 493           (if (stringp id) ;; ID is message-id
 494               (elmo-get-hash-val id ovht)
 495             (elmo-get-hash-val (format "#%d" id) ovht))
 496         (let* ((overview (elmo-msgdb-get-overview msgdb))
 497                (number-alist (elmo-msgdb-get-number-alist msgdb))
 498                (message-id (if (stringp id)
 499                                id ;; ID is message-id
 500                              (cdr (assq id number-alist))))
 501                entity)
 502           (if message-id
 503               (assoc message-id overview)
 504             ;; ID is number. message-id is nil or no exists in number-alist.
 505             (elmo-msgdb-overview-get-entity-by-number overview id)))))))
 506
 507 ;;
 508 ;; deleted message handling
 509 ;;
 510 (defun elmo-msgdb-killed-list-load (dir)
 511   (elmo-object-load
 512    (expand-file-name elmo-msgdb-killed-filename dir)
 513    nil t))
 514
 515 (defun elmo-msgdb-killed-list-save (dir killed-list)
 516   (elmo-object-save
 517    (expand-file-name elmo-msgdb-killed-filename dir)
 518    killed-list))
 519
 520 (defun elmo-msgdb-killed-message-p (killed-list msg)
 521   (elmo-number-set-member msg killed-list))
 522
 523 (defun elmo-msgdb-set-as-killed (killed-list msg)
 524   (elmo-number-set-append killed-list msg))
 525
 526 (defun elmo-msgdb-append-to-killed-list (folder msgs)
 527   (elmo-folder-set-killed-list-internal
 528    folder
 529    (elmo-number-set-append-list
 530     (elmo-folder-killed-list-internal folder)
 531     msgs)))
 532
 533 (defun elmo-msgdb-killed-list-length (killed-list)
 534   (let ((killed killed-list)
 535         (ret-val 0))
 536     (while (car killed)
 537       (if (consp (car killed))
 538           (setq ret-val (+ ret-val 1 (- (cdar killed) (caar killed))))
 539         (setq ret-val (+ ret-val 1)))
 540       (setq killed (cdr killed)))
 541     ret-val))
 542
 543 (defun elmo-msgdb-max-of-killed (killed-list)
 544   (let ((klist killed-list)
 545         (max 0)
 546         k)
 547     (while (car klist)
 548       (if (< max
 549              (setq k
 550                    (if (consp (car klist))
 551                        (cdar klist)
 552                      (car klist))))
 553           (setq max k))
 554       (setq klist (cdr klist)))
 555     max))
 556
 557 (defun elmo-living-messages (messages killed-list)
 558   (if killed-list
 559       (delq nil
 560             (mapcar (lambda (number)
 561                       (unless (elmo-number-set-member number killed-list)
 562                         number))
 563                     messages))
 564     messages))
 565
 566 (defun elmo-msgdb-finfo-load ()
 567   (elmo-object-load (expand-file-name
 568                      elmo-msgdb-finfo-filename
 569                      elmo-msgdb-directory)
 570                     elmo-mime-charset t))
 571
 572 (defun elmo-msgdb-finfo-save (finfo)
 573   (elmo-object-save (expand-file-name
 574                      elmo-msgdb-finfo-filename
 575                      elmo-msgdb-directory)
 576                     finfo elmo-mime-charset))
 577
 578 (defun elmo-msgdb-flist-load (fname)
 579   (let ((flist-file (expand-file-name
 580                      elmo-msgdb-flist-filename
 581                      (expand-file-name
 582                       (elmo-safe-filename fname)
 583                       (expand-file-name "folder" elmo-msgdb-directory)))))
 584     (elmo-object-load flist-file elmo-mime-charset t)))
 585
 586 (defun elmo-msgdb-flist-save (fname flist)
 587   (let ((flist-file (expand-file-name
 588                      elmo-msgdb-flist-filename
 589                      (expand-file-name
 590                       (elmo-safe-filename fname)
 591                       (expand-file-name "folder" elmo-msgdb-directory)))))
 592     (elmo-object-save flist-file flist elmo-mime-charset)))
 593
 594 (defun elmo-crosspost-alist-load ()
 595   (elmo-object-load (expand-file-name
 596                      elmo-crosspost-alist-filename
 597                      elmo-msgdb-directory)
 598                     nil t))
 599
 600 (defun elmo-crosspost-alist-save (alist)
 601   (elmo-object-save (expand-file-name
 602                      elmo-crosspost-alist-filename
 603                      elmo-msgdb-directory)
 604                     alist))
 605
 606 (defun elmo-msgdb-add-msgs-to-seen-list (msgs msgdb unread-marks seen-list)
 607   ;; Add to seen list.
 608   (let* ((number-alist (elmo-msgdb-get-number-alist msgdb))
 609          (mark-alist   (elmo-msgdb-get-mark-alist msgdb))
 610          ent)
 611     (while msgs
 612       (if (setq ent (assq (car msgs) mark-alist))
 613           (unless (member (cadr ent) unread-marks) ;; not unread mark
 614             (setq seen-list
 615                   (cons (cdr (assq (car msgs) number-alist)) seen-list)))
 616         ;; no mark ... seen...
 617         (setq seen-list
 618               (cons (cdr (assq (car msgs) number-alist)) seen-list)))
 619       (setq msgs (cdr msgs)))
 620     seen-list))
 621
 622 (defun elmo-msgdb-get-message-id-from-buffer ()
 623   (or (elmo-field-body "message-id")
 624       ;; no message-id, so put dummy msgid.
 625       (concat (timezone-make-date-sortable
 626                (elmo-field-body "date"))
 627               (nth 1 (eword-extract-address-components
 628                       (or (elmo-field-body "from") "nobody"))))))
 629
 630 (defsubst elmo-msgdb-create-overview-from-buffer (number &optional size time)
 631   "Create overview entity from current buffer.
 632 Header region is supposed to be narrowed."
 633   (save-excursion
 634     (let ((extras elmo-msgdb-extra-fields)
 635           message-id references from subject to cc date
 636           extra field-body)
 637       (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 638       (setq message-id (elmo-msgdb-get-message-id-from-buffer))
 639       (setq references
 640             (or (elmo-msgdb-get-last-message-id
 641                  (elmo-field-body "in-reply-to"))
 642                 (elmo-msgdb-get-last-message-id
 643                  (elmo-field-body "references"))))
 644       (setq from (elmo-mime-string (elmo-delete-char
 645                                     ?\"
 646                                     (or
 647                                      (elmo-field-body "from")
 648                                      elmo-no-from))))
 649       (setq subject (elmo-mime-string (or (elmo-field-body "subject")
 650                                           elmo-no-subject)))
 651       (setq date (or (elmo-field-body "date") time))
 652       (setq to   (mapconcat 'identity (elmo-multiple-field-body "to") ","))
 653       (setq cc   (mapconcat 'identity (elmo-multiple-field-body "cc") ","))
 654       (or size
 655           (if (setq size (elmo-field-body "content-length"))
 656               (setq size (string-to-int size))
 657             (setq size 0)));; No mean...
 658       (while extras
 659         (if (setq field-body (elmo-field-body (car extras)))
 660             (setq extra (cons (cons (downcase (car extras))
 661                                     field-body) extra)))
 662         (setq extras (cdr extras)))
 663       (cons message-id (vector number references
 664                                from subject date to cc
 665                                size extra))
 666       )))
 667
 668 (defun elmo-msgdb-copy-overview-entity (entity)
 669   (cons (car entity)
 670         (copy-sequence (cdr entity))))
 671
 672 (defsubst elmo-msgdb-insert-file-header (file)
 673   "Insert the header of the article."
 674   (let ((beg 0)
 675         insert-file-contents-pre-hook   ; To avoid autoconv-xmas...
 676         insert-file-contents-post-hook
 677         format-alist)
 678     (when (file-exists-p file)
 679       ;; Read until header separator is found.
 680       (while (and (eq elmo-msgdb-file-header-chop-length
 681                       (nth 1
 682                            (insert-file-contents-as-binary
 683                             file nil beg
 684                             (incf beg elmo-msgdb-file-header-chop-length))))
 685                   (prog1 (not (search-forward "\n\n" nil t))
 686                     (goto-char (point-max))))))))
 687
 688 (defsubst elmo-msgdb-create-overview-entity-from-file (number file)
 689   (let (insert-file-contents-pre-hook   ; To avoid autoconv-xmas...
 690         insert-file-contents-post-hook header-end
 691         (attrib (file-attributes file))
 692         ret-val size mtime)
 693     (with-temp-buffer
 694       (if (not (file-exists-p file))
 695           ()
 696         (setq size (nth 7 attrib))
 697         (setq mtime (timezone-make-date-arpa-standard
 698                      (current-time-string (nth 5 attrib)) (current-time-zone)))
 699         ;; insert header from file.
 700         (catch 'done
 701           (condition-case nil
 702               (elmo-msgdb-insert-file-header file)
 703             (error (throw 'done nil)))
 704           (goto-char (point-min))
 705           (setq header-end
 706                 (if (re-search-forward "\\(^--.*$\\)\\|\\(\n\n\\)" nil t)
 707                     (point)
 708                   (point-max)))
 709           (narrow-to-region (point-min) header-end)
 710           (elmo-msgdb-create-overview-from-buffer number size mtime))))))
 711
 712 (defun elmo-msgdb-overview-sort-by-date (overview)
 713   (sort overview
 714         (function
 715          (lambda (x y)
 716            (condition-case nil
 717                (string<
 718                 (timezone-make-date-sortable
 719                  (elmo-msgdb-overview-entity-get-date x))
 720                 (timezone-make-date-sortable
 721                  (elmo-msgdb-overview-entity-get-date y)))
 722              (error))))))
 723
 724 (defun elmo-msgdb-sort-by-date (msgdb)
 725   (message "Sorting...")
 726   (let ((overview (elmo-msgdb-get-overview msgdb)))
 727     (setq overview (elmo-msgdb-overview-sort-by-date overview))
 728     (message "Sorting...done")
 729     (list overview (nth 1 msgdb)(nth 2 msgdb))))
 730
 731 (defun elmo-msgdb-clear-overview-hashtb (entity hashtb)
 732   (let (number)
 733     (when (and entity
 734                elmo-use-overview-hashtb
 735                hashtb)
 736       (and (setq number (elmo-msgdb-overview-entity-get-number entity))
 737            (elmo-clear-hash-val (format "#%d" number) hashtb))
 738       (and (car entity) ;; message-id
 739            (elmo-clear-hash-val (car entity) hashtb)))))
 740
 741 (defun elmo-msgdb-make-overview-hashtb (overview &optional hashtb)
 742   (if (and elmo-use-overview-hashtb
 743            overview)
 744       (let ((hashtb (or hashtb ;; append
 745                         (elmo-make-hash (length overview)))))
 746         (while overview
 747           ;; key is message-id
 748           (if (caar overview)
 749               (elmo-set-hash-val (caar overview) (car overview) hashtb))
 750           ;; key is number
 751           (elmo-set-hash-val
 752            (format "#%d" (elmo-msgdb-overview-entity-get-number (car overview)))
 753            (car overview) hashtb)
 754           (setq overview (cdr overview)))
 755         hashtb)
 756     nil))
 757
 758 (defsubst elmo-msgdb-append (msgdb msgdb-append &optional set-hash)
 759   (list
 760    (nconc (car msgdb) (car msgdb-append))
 761    (nconc (cadr msgdb) (cadr msgdb-append))
 762    (nconc (caddr msgdb) (caddr msgdb-append))
 763    (and set-hash
 764         (elmo-msgdb-make-overview-hashtb (car msgdb-append) (nth 3 msgdb)))))
 765
 766 (defsubst elmo-msgdb-clear (&optional msgdb)
 767   (if msgdb
 768       (list
 769        (setcar msgdb nil)
 770        (setcar (cdr msgdb) nil)
 771        (setcar (cddr msgdb) nil)
 772        (setcar (nthcdr 3 msgdb) (elmo-msgdb-make-overview-hashtb nil)))
 773     (list nil nil nil (elmo-msgdb-make-overview-hashtb nil))))
 774
 775 (defsubst elmo-folder-get-info (folder &optional hashtb)
 776   (elmo-get-hash-val folder
 777                      (or hashtb elmo-folder-info-hashtb)))
 778
 779 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 780   (let ((info (elmo-folder-get-info folder)))
 781     (when info
 782       (or new     (setq new     (nth 0 info)))
 783       (or unread  (setq unread  (nth 1 info)))
 784       (or numbers (setq numbers (nth 2 info)))
 785       (or max     (setq max     (nth 3 info))))
 786     (elmo-set-hash-val folder
 787                        (list new unread numbers max)
 788                        elmo-folder-info-hashtb)))
 789
 790 (defun elmo-folder-set-info-max-by-numdb (folder msgdb-number)
 791   (let ((num-db (sort (mapcar 'car msgdb-number) '<)))
 792     (elmo-folder-set-info-hashtb
 793      folder
 794      (or (nth (max 0 (1- (length num-db))) num-db) 0)
 795      nil ;;(length num-db)
 796      )))
 797
 798 (defun elmo-folder-get-info-max (folder)
 799   "Get folder info from cache."
 800   (nth 3 (elmo-folder-get-info folder)))
 801
 802 (defun elmo-folder-get-info-length (folder)
 803   (nth 2 (elmo-folder-get-info folder)))
 804
 805 (defun elmo-folder-get-info-unread (folder)
 806   (nth 1 (elmo-folder-get-info folder)))
 807
 808 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 809   (let* ((hashtb (or hashtb
 810                      (elmo-make-hash (length info-alist)))))
 811     (mapcar
 812      '(lambda (x)
 813         (let ((info (cadr x)))
 814           (and (intern-soft (car x) hashtb)
 815                (elmo-set-hash-val (car x)
 816                                   (list (nth 2 info)   ;; new
 817                                         (nth 3 info)   ;; unread
 818                                         (nth 1 info)   ;; length
 819                                         (nth 0 info))  ;; max
 820                                   hashtb))))
 821      info-alist)
 822     (setq elmo-folder-info-hashtb hashtb)))
 823
 824 (defsubst elmo-msgdb-location-load (dir)
 825   (elmo-object-load
 826    (expand-file-name
 827     elmo-msgdb-location-filename
 828     dir)))
 829
 830 (defsubst elmo-msgdb-location-add (alist number location)
 831   (let ((ret-val alist))
 832     (setq ret-val
 833           (elmo-msgdb-append-element ret-val (cons number location)))
 834     ret-val))
 835
 836 (defsubst elmo-msgdb-location-save (dir alist)
 837   (elmo-object-save
 838    (expand-file-name
 839     elmo-msgdb-location-filename
 840     dir) alist))
 841
 842 (require 'product)
 843 (product-provide (provide 'elmo-msgdb) (require 'elmo-version))
 844
 845 ;;; elmo-msgdb.el ends here