elmo/elmo-multi.el

   1 ;;; elmo-multi.el --- Multiple Folder Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'elmo)
  34 (require 'luna)
  35
  36 (defvar elmo-multi-divide-number 100000
  37   "*Multi divider number.")
  38
  39 ;;; ELMO Multi folder
  40 (eval-and-compile
  41   (luna-define-class elmo-multi-folder (elmo-folder)
  42                      (children divide-number))
  43   (luna-define-internal-accessors 'elmo-multi-folder))
  44
  45 (defmacro elmo-multi-real-folder-number (folder number)
  46   "Returns a cons cell of real FOLDER and NUMBER."
  47   (` (cons (nth (-
  48                  (/ (, number)
  49                     (elmo-multi-folder-divide-number-internal (, folder)))
  50                  1) (elmo-multi-folder-children-internal (, folder)))
  51            (% (, number) (elmo-multi-folder-divide-number-internal
  52                           (, folder))))))
  53
  54 (luna-define-method elmo-folder-initialize ((folder
  55                                              elmo-multi-folder)
  56                                             name)
  57   (while (> (length (car (setq name (elmo-parse-token name ",")))) 0)
  58     (elmo-multi-folder-set-children-internal
  59      folder
  60      (nconc (elmo-multi-folder-children-internal
  61              folder)
  62             (list (elmo-make-folder (car name)))))
  63     (setq name (cdr name))
  64     (when (and (> (length name) 0)
  65                (eq (aref name 0) ?,))
  66       (setq name (substring name 1))))
  67   (elmo-multi-folder-set-divide-number-internal
  68    folder
  69    elmo-multi-divide-number)
  70   folder)
  71
  72 (luna-define-method elmo-folder-open-internal ((folder elmo-multi-folder))
  73   (dolist (fld (elmo-multi-folder-children-internal folder))
  74     (elmo-folder-open-internal fld)))
  75
  76 (luna-define-method elmo-folder-check ((folder elmo-multi-folder))
  77   (dolist (fld (elmo-multi-folder-children-internal folder))
  78     (elmo-folder-check fld)))
  79
  80 (luna-define-method elmo-folder-close-internal ((folder elmo-multi-folder))
  81   (dolist (fld (elmo-multi-folder-children-internal folder))
  82     (elmo-folder-close-internal fld)))
  83
  84 (luna-define-method elmo-folder-close :after ((folder elmo-multi-folder))
  85   (dolist (fld (elmo-multi-folder-children-internal folder))
  86     (elmo-folder-set-msgdb-internal fld nil)))
  87
  88 (luna-define-method elmo-folder-synchronize ((folder elmo-multi-folder)
  89                                              &optional
  90                                              disable-killed
  91                                              ignore-msgdb
  92                                              no-check
  93                                              mask)
  94   (if mask
  95       (dolist (element (elmo-multi-split-numbers folder mask))
  96         (when (cdr element)
  97           (elmo-folder-synchronize (car element)
  98                                    disable-killed
  99                                    ignore-msgdb
 100                                    no-check
 101                                    (cdr element))))
 102     (dolist (fld (elmo-multi-folder-children-internal folder))
 103       (elmo-folder-synchronize fld disable-killed ignore-msgdb no-check)))
 104   0)
 105
 106 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 107                                                     elmo-multi-folder))
 108   (expand-file-name (elmo-replace-string-as-filename
 109                      (elmo-folder-name-internal folder))
 110                     (expand-file-name "multi"
 111                                       elmo-msgdb-directory)))
 112
 113 (luna-define-method elmo-folder-newsgroups ((folder elmo-multi-folder))
 114   (apply  #'nconc
 115           (mapcar
 116            'elmo-folder-newsgroups
 117            (elmo-multi-folder-children-internal folder))))
 118
 119 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-multi-folder))
 120   (elmo-flatten
 121    (mapcar
 122     'elmo-folder-get-primitive-list
 123     (elmo-multi-folder-children-internal folder))))
 124
 125 (luna-define-method elmo-folder-contains-type ((folder elmo-multi-folder) type)
 126   (let ((children (elmo-multi-folder-children-internal folder))
 127         match)
 128     (while children
 129       (when (elmo-folder-contains-type (car children) type)
 130         (setq match t)
 131         (setq children nil))
 132       (setq children (cdr children)))
 133     match))
 134
 135 (luna-define-method elmo-message-folder ((folder elmo-multi-folder)
 136                                          number)
 137   (nth (- (/ number (elmo-multi-folder-divide-number-internal folder)) 1)
 138        (elmo-multi-folder-children-internal folder)))
 139
 140 (luna-define-method elmo-message-cached-p ((folder elmo-multi-folder) number)
 141   (let ((pair (elmo-multi-real-folder-number folder number)))
 142     (elmo-message-cached-p (car pair) (cdr pair))))
 143
 144 (luna-define-method elmo-message-set-cached ((folder elmo-multi-folder)
 145                                              number cached)
 146   (let ((pair (elmo-multi-real-folder-number folder number)))
 147     (elmo-message-set-cached (car pair) (cdr pair) cached))
 148   (elmo-folder-notify-event folder 'cache-changed number))
 149
 150 (luna-define-method elmo-find-fetch-strategy ((folder elmo-multi-folder)
 151                                               number
 152                                               &optional
 153                                               ignore-cache
 154                                               require-entireness)
 155   (let ((pair (elmo-multi-real-folder-number folder number)))
 156     (elmo-find-fetch-strategy (car pair)
 157                               (cdr pair)
 158                               ignore-cache
 159                               require-entireness)))
 160
 161 (luna-define-method elmo-message-number ((folder elmo-multi-folder)
 162                                          message-id)
 163   (let ((children (elmo-multi-folder-children-internal folder))
 164         match)
 165     (while children
 166       (when (setq match (elmo-message-number (car children) message-id))
 167         (setq children nil))
 168       (setq children (cdr children)))
 169     match))
 170
 171 (luna-define-method elmo-message-entity ((folder elmo-multi-folder) key)
 172   (cond
 173    ((numberp key)
 174     (let* ((pair (elmo-multi-real-folder-number folder key))
 175            (entity (elmo-message-entity (car pair) (cdr pair))))
 176       (when entity
 177         (elmo-message-entity-set-number (elmo-message-copy-entity entity)
 178                                         key))))
 179    ((stringp key)
 180     (let ((children (elmo-multi-folder-children-internal folder))
 181           (cur-number 0)
 182           match)
 183       (while children
 184         (setq cur-number (+ cur-number 1))
 185         (when (setq match (elmo-message-entity (car children) key))
 186           (setq match (elmo-message-copy-entity match))
 187           (elmo-message-entity-set-number
 188            match
 189            (+ (* (elmo-multi-folder-divide-number-internal folder)
 190                  cur-number)
 191               (elmo-message-entity-number match)))
 192           (setq children nil))
 193         (setq children (cdr children)))
 194       match))))
 195
 196 (luna-define-method elmo-message-entity-parent ((folder
 197                                                  elmo-multi-folder) entity)
 198   (elmo-message-entity
 199    folder
 200    (elmo-message-entity-field entity 'references)))
 201
 202 (luna-define-method elmo-message-field ((folder elmo-multi-folder)
 203                                         number field)
 204   (let ((pair (elmo-multi-real-folder-number folder number)))
 205     (elmo-message-field (car pair) (cdr pair) field)))
 206
 207 (luna-define-method elmo-message-flag-available-p ((folder
 208                                                     elmo-multi-folder) number
 209                                                     flag)
 210   (let ((pair (elmo-multi-real-folder-number folder number)))
 211     (elmo-message-flag-available-p (car pair) (cdr pair) flag)))
 212
 213 (luna-define-method elmo-message-flags ((folder elmo-multi-folder) number)
 214   (let ((pair (elmo-multi-real-folder-number folder number)))
 215     (elmo-message-flags (car pair) (cdr pair))))
 216
 217 (defun elmo-multi-split-numbers (folder numlist &optional as-is)
 218   (let ((numbers (sort numlist '<))
 219         (folders (elmo-multi-folder-children-internal folder))
 220         (divider (elmo-multi-folder-divide-number-internal folder))
 221         (cur-number 0)
 222         one-list numbers-list)
 223     (while numbers
 224       (setq one-list (list (nth cur-number folders)))
 225       (setq cur-number (+ cur-number 1))
 226       (while (and numbers
 227                   (eq 0
 228                       (/ (- (car numbers)
 229                             (* divider cur-number))
 230                          divider)))
 231         (setq one-list (nconc
 232                         one-list
 233                         (list
 234                          (if as-is
 235                              (car numbers)
 236                            (% (car numbers)
 237                               (* divider cur-number))))))
 238         (setq numbers (cdr numbers)))
 239       (setq numbers-list (nconc numbers-list (list one-list))))
 240     numbers-list))
 241
 242 (luna-define-method elmo-folder-process-crosspost ((folder elmo-multi-folder))
 243   (dolist (child (elmo-multi-folder-children-internal folder))
 244     (elmo-folder-process-crosspost child)))
 245
 246 (luna-define-method elmo-message-fetch ((folder elmo-multi-folder)
 247                                         number strategy
 248                                         &optional unseen section)
 249   (let ((pair (elmo-multi-real-folder-number folder number)))
 250     (when (elmo-message-fetch (car pair) (cdr pair)
 251                               strategy unseen section)
 252       (unless unseen
 253         (elmo-folder-notify-event folder 'flag-changed (list number)))
 254       t)))
 255
 256 (luna-define-method elmo-folder-delete-messages ((folder elmo-multi-folder)
 257                                                  numbers)
 258   (dolist (element (elmo-multi-split-numbers folder numbers))
 259     (when (cdr element)
 260       (elmo-folder-delete-messages (car element) (cdr element))))
 261   t)
 262
 263 (luna-define-method elmo-folder-detach-messages ((folder elmo-multi-folder)
 264                                                  numbers)
 265   (dolist (element (elmo-multi-split-numbers folder numbers))
 266     (when (cdr element)
 267       (elmo-folder-detach-messages (car element) (cdr element))))
 268   t)
 269
 270 (luna-define-method elmo-folder-diff ((folder elmo-multi-folder))
 271   (elmo-multi-folder-diff folder))
 272
 273 (defun elmo-multi-folder-diff (folder)
 274   (let ((news 0)
 275         (unreads 0)
 276         (alls 0)
 277         diff value)
 278     (dolist (child (elmo-multi-folder-children-internal folder))
 279       (setq diff (elmo-folder-diff child))
 280       (setq news    (and news
 281                          (setq value (elmo-diff-new diff))
 282                          (+ news value))
 283             unreads (and unreads
 284                          (setq value (elmo-diff-unread diff))
 285                          (+ unreads value))
 286             alls    (and alls
 287                          (setq value (elmo-diff-all diff))
 288                          (+ alls value))))
 289     (if unreads
 290         (list news unreads alls)
 291       (cons news alls))))
 292
 293 (luna-define-method elmo-folder-list-messages
 294   ((folder elmo-multi-folder) &optional visible-only in-msgdb)
 295   (let* ((flds (elmo-multi-folder-children-internal folder))
 296          (cur-number 0)
 297          list numbers)
 298     (while flds
 299       (setq cur-number (+ cur-number 1))
 300       (setq list (elmo-folder-list-messages (car flds) visible-only in-msgdb))
 301       (setq numbers
 302             (nconc
 303              numbers
 304              (mapcar
 305               (function
 306                (lambda (x)
 307                  (+
 308                   (* (elmo-multi-folder-divide-number-internal
 309                       folder) cur-number) x)))
 310               list)))
 311       (setq flds (cdr flds)))
 312     numbers))
 313
 314 (luna-define-method elmo-folder-exists-p ((folder elmo-multi-folder))
 315   (let ((flds (elmo-multi-folder-children-internal folder)))
 316     (catch 'exists
 317       (while flds
 318         (unless (elmo-folder-exists-p (car flds))
 319           (throw 'exists nil))
 320         (setq flds (cdr flds)))
 321       t)))
 322
 323 (luna-define-method elmo-folder-creatable-p ((folder elmo-multi-folder))
 324   (let ((flds (elmo-multi-folder-children-internal folder)))
 325     (catch 'creatable
 326       (while flds
 327         (when (and (elmo-folder-creatable-p (car flds))
 328                    (not (elmo-folder-exists-p (car flds))))
 329           ;; If folder already exists, don't to `creatable'.
 330           ;; Because this function is called, when folder doesn't exists.
 331           (throw 'creatable t))
 332         (setq flds (cdr flds)))
 333       nil)))
 334
 335 (luna-define-method elmo-folder-create ((folder elmo-multi-folder))
 336   (let ((flds (elmo-multi-folder-children-internal folder)))
 337     (catch 'create
 338       (while flds
 339         (unless (or (elmo-folder-exists-p (car flds))
 340                     (elmo-folder-create (car flds)))
 341           (throw 'create nil))
 342         (setq flds (cdr flds)))
 343       t)))
 344
 345 (luna-define-method elmo-folder-search ((folder elmo-multi-folder)
 346                                         condition &optional numbers)
 347   (let* ((flds (elmo-multi-folder-children-internal folder))
 348          (cur-number 0)
 349          numlist
 350          matches)
 351     (setq numbers (or numbers
 352                       (elmo-folder-list-messages folder)))
 353     (while flds
 354       (setq cur-number (+ cur-number 1))
 355       (setq matches (append matches
 356                             (mapcar
 357                              (function
 358                               (lambda (x)
 359                                 (+
 360                                  (* (elmo-multi-folder-divide-number-internal
 361                                      folder)
 362                                     cur-number)
 363                                  x)))
 364                              (elmo-folder-search
 365                               (car flds) condition))))
 366       (setq flds (cdr flds)))
 367     (elmo-list-filter numbers matches)))
 368
 369 (luna-define-method elmo-message-use-cache-p ((folder elmo-multi-folder)
 370                                               number)
 371   (let ((pair (elmo-multi-real-folder-number folder number)))
 372     (elmo-message-use-cache-p (car pair) (cdr pair))))
 373
 374 (luna-define-method elmo-message-file-p ((folder elmo-multi-folder) number)
 375   (let ((pair (elmo-multi-real-folder-number folder number)))
 376     (elmo-message-file-p (car pair) (cdr pair))))
 377
 378 (luna-define-method elmo-message-file-name ((folder elmo-multi-folder) number)
 379   (let ((pair (elmo-multi-real-folder-number folder number)))
 380     (elmo-message-file-name (car pair) (cdr pair))))
 381
 382 (luna-define-method elmo-folder-plugged-p ((folder elmo-multi-folder))
 383   (let ((flds (elmo-multi-folder-children-internal folder)))
 384     (catch 'plugged
 385       (while flds
 386         (unless (elmo-folder-plugged-p (car flds))
 387           (throw 'plugged nil))
 388         (setq flds (cdr flds)))
 389       t)))
 390
 391 (luna-define-method elmo-folder-set-plugged ((folder elmo-multi-folder)
 392                                              plugged add)
 393   (let ((flds  (elmo-multi-folder-children-internal folder)))
 394     (dolist (fld flds)
 395       (elmo-folder-set-plugged fld plugged add))))
 396
 397 (defun elmo-multi-folder-numbers-list-assoc (folder folder-numbers)
 398   (let (ent)
 399     (while folder-numbers
 400       (when (string= (elmo-folder-name-internal (car (car folder-numbers)))
 401                      (elmo-folder-name-internal folder))
 402         (setq ent (car folder-numbers)
 403               folder-numbers nil))
 404       (setq folder-numbers (cdr folder-numbers)))
 405     ent))
 406
 407 (defun elmo-multi-make-folder-numbers-list (folder msgs)
 408   (let ((msg-list msgs)
 409         pair fld-list
 410         ret-val)
 411     (while msg-list
 412       (when (and (numberp (car msg-list))
 413                  (> (car msg-list) 0))
 414         (setq pair (elmo-multi-real-folder-number folder (car msg-list)))
 415         (if (setq fld-list (elmo-multi-folder-numbers-list-assoc
 416                             (car pair)
 417                             ret-val))
 418             (setcdr fld-list (cons (cdr pair) (cdr fld-list)))
 419           (setq ret-val (cons (cons (car pair) (list (cdr pair))) ret-val))))
 420       (setq msg-list (cdr msg-list)))
 421     ret-val))
 422
 423 (luna-define-method elmo-folder-set-flag ((folder elmo-multi-folder)
 424                                           numbers
 425                                           flag
 426                                           &optional is-local)
 427   (dolist (pair (elmo-multi-make-folder-numbers-list folder numbers))
 428     (elmo-folder-set-flag (car pair) (cdr pair) flag is-local))
 429   (elmo-folder-notify-event folder 'flag-changed numbers))
 430
 431 (luna-define-method elmo-folder-unset-flag ((folder elmo-multi-folder)
 432                                             numbers
 433                                             flag
 434                                             &optional is-local)
 435   (dolist (pair (elmo-multi-make-folder-numbers-list folder numbers))
 436     (ignore-errors
 437      (elmo-folder-unset-flag (car pair) (cdr pair) flag is-local)))
 438   (elmo-folder-notify-event folder 'flag-changed numbers))
 439
 440 (luna-define-method elmo-folder-list-flagged ((folder elmo-multi-folder)
 441                                               flag
 442                                               &optional in-msgdb)
 443   (let ((cur-number 0)
 444         numbers)
 445     (dolist (child (elmo-multi-folder-children-internal folder))
 446       (setq cur-number (+ cur-number 1)
 447             numbers
 448             (nconc
 449              numbers
 450              (mapcar
 451               (function
 452                (lambda (x)
 453                  (+
 454                   (* (elmo-multi-folder-divide-number-internal folder)
 455                      cur-number) x)))
 456               (elmo-folder-list-flagged child flag in-msgdb)))))
 457     numbers))
 458
 459 (luna-define-method elmo-folder-commit ((folder elmo-multi-folder))
 460   (dolist (child (elmo-multi-folder-children-internal folder))
 461     (elmo-folder-commit child)))
 462
 463 (luna-define-method elmo-folder-length ((folder elmo-multi-folder))
 464   (let ((sum 0))
 465     (dolist (child (elmo-multi-folder-children-internal folder))
 466       (setq sum (+ sum (elmo-folder-length child))))
 467     sum))
 468
 469 (luna-define-method elmo-folder-count-flags ((folder elmo-multi-folder))
 470   (let (flag-alist element)
 471     (dolist (child (elmo-multi-folder-children-internal folder))
 472       (dolist (pair (elmo-folder-count-flags child))
 473         (if (setq element (assq (car pair) flag-alist))
 474             (setcdr element (+ (cdr element) (cdr pair)))
 475           (setq flag-alist (cons pair flag-alist)))))
 476     flag-alist))
 477
 478 (require 'product)
 479 (product-provide (provide 'elmo-multi) (require 'elmo-version))
 480
 481 ;;; elmo-multi.el ends here