elmo/elmo-multi.el

   1 ;;; elmo-multi.el --- Multiple Folder Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'elmo)
  33 (require 'luna)
  34
  35 (defvar elmo-multi-divide-number 100000
  36   "*Multi divider number.")
  37
  38 ;;; ELMO Multi folder
  39 (eval-and-compile
  40   (luna-define-class elmo-multi-folder (elmo-folder)
  41                      (children divide-number))
  42   (luna-define-internal-accessors 'elmo-multi-folder))
  43
  44 (defmacro elmo-multi-real-folder-number (folder number)
  45   "Returns a cons cell of real FOLDER and NUMBER."
  46   (` (cons (nth (-
  47                  (/ (, number)
  48                     (elmo-multi-folder-divide-number-internal (, folder)))
  49                  1) (elmo-multi-folder-children-internal (, folder)))
  50            (% (, number) (elmo-multi-folder-divide-number-internal
  51                           (, folder))))))
  52
  53 (luna-define-method elmo-folder-initialize ((folder
  54                                              elmo-multi-folder)
  55                                             name)
  56   (while (> (length (car (setq name (elmo-parse-token name ",")))) 0)
  57     (elmo-multi-folder-set-children-internal
  58      folder
  59      (nconc (elmo-multi-folder-children-internal
  60              folder)
  61             (list (elmo-make-folder (car name)))))
  62     (setq name (cdr name))
  63     (when (and (> (length name) 0)
  64                (eq (aref name 0) ?,))
  65       (setq name (substring name 1))))
  66   (elmo-multi-folder-set-divide-number-internal
  67    folder
  68    elmo-multi-divide-number)
  69   folder)
  70
  71 (luna-define-method elmo-folder-open-internal ((folder elmo-multi-folder))
  72   (dolist (fld (elmo-multi-folder-children-internal folder))
  73     (elmo-folder-open-internal fld)))
  74
  75 (luna-define-method elmo-folder-check ((folder elmo-multi-folder))
  76   (dolist (fld (elmo-multi-folder-children-internal folder))
  77     (elmo-folder-check fld)))
  78
  79 (luna-define-method elmo-folder-close-internal ((folder elmo-multi-folder))
  80   (dolist (fld (elmo-multi-folder-children-internal folder))
  81     (elmo-folder-close-internal fld)))
  82
  83 (luna-define-method elmo-folder-close :after ((folder elmo-multi-folder))
  84   (dolist (fld (elmo-multi-folder-children-internal folder))
  85     (elmo-folder-set-msgdb-internal fld nil)))
  86
  87 (luna-define-method elmo-folder-synchronize ((folder elmo-multi-folder)
  88                                              &optional
  89                                              disable-killed
  90                                              ignore-msgdb
  91                                              no-check
  92                                              mask)
  93   (if mask
  94       (dolist (element (elmo-multi-split-numbers folder mask))
  95         (when (cdr element)
  96           (elmo-folder-synchronize (car element)
  97                                    disable-killed
  98                                    ignore-msgdb
  99                                    no-check
 100                                    (cdr element))))
 101     (dolist (fld (elmo-multi-folder-children-internal folder))
 102       (elmo-folder-synchronize fld disable-killed ignore-msgdb no-check)))
 103   0)
 104
 105 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 106                                                     elmo-multi-folder))
 107   (expand-file-name (elmo-replace-string-as-filename
 108                      (elmo-folder-name-internal folder))
 109                     (expand-file-name "multi"
 110                                       elmo-msgdb-directory)))
 111
 112 (luna-define-method elmo-folder-newsgroups ((folder elmo-multi-folder))
 113   (apply  #'nconc
 114           (mapcar
 115            'elmo-folder-newsgroups
 116            (elmo-multi-folder-children-internal folder))))
 117
 118 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-multi-folder))
 119   (elmo-flatten
 120    (mapcar
 121     'elmo-folder-get-primitive-list
 122     (elmo-multi-folder-children-internal folder))))
 123
 124 (luna-define-method elmo-folder-contains-type ((folder elmo-multi-folder) type)
 125   (let ((children (elmo-multi-folder-children-internal folder))
 126         match)
 127     (while children
 128       (when (elmo-folder-contains-type (car children) type)
 129         (setq match t)
 130         (setq children nil))
 131       (setq children (cdr children)))
 132     match))
 133
 134 (luna-define-method elmo-message-folder ((folder elmo-multi-folder)
 135                                          number)
 136   (nth (- (/ number (elmo-multi-folder-divide-number-internal folder)) 1)
 137        (elmo-multi-folder-children-internal folder)))
 138
 139 (luna-define-method elmo-message-cached-p ((folder elmo-multi-folder) number)
 140   (let ((pair (elmo-multi-real-folder-number folder number)))
 141     (elmo-message-cached-p (car pair) (cdr pair))))
 142
 143 (luna-define-method elmo-message-set-cached ((folder elmo-multi-folder)
 144                                              number cached)
 145   (let ((pair (elmo-multi-real-folder-number folder number)))
 146     (elmo-message-set-cached (car pair) (cdr pair) cached)))
 147
 148 (luna-define-method elmo-find-fetch-strategy
 149   ((folder elmo-multi-folder) entity &optional ignore-cache)
 150   (let ((pair (elmo-multi-real-folder-number
 151                folder
 152                (elmo-message-entity-number entity))))
 153     (elmo-find-fetch-strategy
 154      (car pair)
 155      (elmo-message-entity (car pair) (cdr pair)) ignore-cache)))
 156
 157 (luna-define-method elmo-message-entity ((folder elmo-multi-folder) key)
 158   (cond
 159    ((numberp key)
 160     (let* ((pair (elmo-multi-real-folder-number folder key))
 161            (entity (elmo-message-entity (car pair) (cdr pair))))
 162       (when entity
 163         (elmo-message-entity-set-number (elmo-message-copy-entity entity)
 164                                         key))))
 165    ((stringp key)
 166     (let ((children (elmo-multi-folder-children-internal folder))
 167           (cur-number 0)
 168           match)
 169       (while children
 170         (setq cur-number (+ cur-number 1))
 171         (when (setq match (elmo-message-entity (car children) key))
 172           (setq match (elmo-message-copy-entity match))
 173           (elmo-message-entity-set-number
 174            match
 175            (+ (* (elmo-multi-folder-divide-number-internal folder)
 176                  cur-number)
 177               (elmo-message-entity-number match)))
 178           (setq children nil))
 179         (setq children (cdr children)))
 180       match))))
 181
 182 (luna-define-method elmo-message-entity-parent ((folder
 183                                                  elmo-multi-folder) entity)
 184   (elmo-message-entity
 185    folder
 186    (elmo-message-entity-field entity 'references)))
 187
 188 (luna-define-method elmo-message-field ((folder elmo-multi-folder)
 189                                         number field)
 190   (let ((pair (elmo-multi-real-folder-number folder number)))
 191     (elmo-message-field (car pair) (cdr pair) field)))
 192
 193 (luna-define-method elmo-message-flags ((folder elmo-multi-folder) number
 194                                         &optional msgid)
 195   (let ((pair (elmo-multi-real-folder-number folder number)))
 196     (elmo-message-flags (car pair) (cdr pair) msgid)))
 197
 198 (defun elmo-multi-split-numbers (folder numlist &optional as-is)
 199   (let ((numbers (sort numlist '<))
 200         (folders (elmo-multi-folder-children-internal folder))
 201         (divider (elmo-multi-folder-divide-number-internal folder))
 202         (cur-number 0)
 203         one-list numbers-list)
 204     (while numbers
 205       (setq one-list (list (nth cur-number folders)))
 206       (setq cur-number (+ cur-number 1))
 207       (while (and numbers
 208                   (eq 0
 209                       (/ (- (car numbers)
 210                             (* divider cur-number))
 211                          divider)))
 212         (setq one-list (nconc
 213                         one-list
 214                         (list
 215                          (if as-is
 216                              (car numbers)
 217                            (% (car numbers)
 218                               (* divider cur-number))))))
 219         (setq numbers (cdr numbers)))
 220       (setq numbers-list (nconc numbers-list (list one-list))))
 221     numbers-list))
 222
 223 (luna-define-method elmo-folder-process-crosspost ((folder elmo-multi-folder))
 224   (dolist (child (elmo-multi-folder-children-internal folder))
 225     (elmo-folder-process-crosspost child)))
 226
 227 (luna-define-method elmo-message-fetch ((folder elmo-multi-folder)
 228                                         number strategy
 229                                         &optional section outbuf unseen)
 230   (let ((pair (elmo-multi-real-folder-number folder number)))
 231     (elmo-message-fetch (car pair) (cdr pair) strategy section outbuf unseen)))
 232
 233 (luna-define-method elmo-folder-delete-messages ((folder elmo-multi-folder)
 234                                                  numbers)
 235   (dolist (element (elmo-multi-split-numbers folder numbers))
 236     (when (cdr element)
 237       (elmo-folder-delete-messages (car element) (cdr element))))
 238   t)
 239
 240 (luna-define-method elmo-folder-detach-messages ((folder elmo-multi-folder)
 241                                                  numbers)
 242   (dolist (element (elmo-multi-split-numbers folder numbers))
 243     (when (cdr element)
 244       (elmo-folder-detach-messages (car element) (cdr element))))
 245   t)
 246
 247 (luna-define-method elmo-folder-diff ((folder elmo-multi-folder))
 248   (elmo-multi-folder-diff folder))
 249
 250 (defun elmo-multi-folder-diff (folder)
 251   (let ((flds (elmo-multi-folder-children-internal folder))
 252         (news 0)
 253         (unreads 0)
 254         (alls 0)
 255         no-unreads diff)
 256     (while flds
 257       (setq diff (elmo-folder-diff (car flds)))
 258       (cond
 259        ((consp (cdr diff)) ; (new unread all)
 260         (setq news    (+ news (nth 0 diff))
 261               unreads (+ unreads (nth 1 diff))
 262               alls    (+ alls (nth 2 diff))))
 263        (t
 264         (setq no-unreads t)
 265         (setq news    (+ news (car diff))
 266               alls    (+ alls (cdr diff)))))
 267       (setq flds (cdr flds)))
 268     (if no-unreads
 269         (cons news alls)
 270       (list news unreads alls))))
 271
 272 (luna-define-method elmo-folder-list-messages
 273   ((folder elmo-multi-folder) &optional visible-only in-msgdb)
 274   (let* ((flds (elmo-multi-folder-children-internal folder))
 275          (cur-number 0)
 276          list numbers)
 277     (while flds
 278       (setq cur-number (+ cur-number 1))
 279       (setq list (elmo-folder-list-messages (car flds) visible-only in-msgdb))
 280       (setq numbers
 281             (nconc
 282              numbers
 283              (mapcar
 284               (function
 285                (lambda (x)
 286                  (+
 287                   (* (elmo-multi-folder-divide-number-internal
 288                       folder) cur-number) x)))
 289               list)))
 290       (setq flds (cdr flds)))
 291     numbers))
 292
 293 (luna-define-method elmo-folder-exists-p ((folder elmo-multi-folder))
 294   (let ((flds (elmo-multi-folder-children-internal folder)))
 295     (catch 'exists
 296       (while flds
 297         (unless (elmo-folder-exists-p (car flds))
 298           (throw 'exists nil))
 299         (setq flds (cdr flds)))
 300       t)))
 301
 302 (luna-define-method elmo-folder-creatable-p ((folder elmo-multi-folder))
 303   (let ((flds (elmo-multi-folder-children-internal folder)))
 304     (catch 'creatable
 305       (while flds
 306         (when (and (elmo-folder-creatable-p (car flds))
 307                    (not (elmo-folder-exists-p (car flds))))
 308           ;; If folder already exists, don't to `creatable'.
 309           ;; Because this function is called, when folder doesn't exists.
 310           (throw 'creatable t))
 311         (setq flds (cdr flds)))
 312       nil)))
 313
 314 (luna-define-method elmo-folder-create ((folder elmo-multi-folder))
 315   (let ((flds (elmo-multi-folder-children-internal folder)))
 316     (catch 'create
 317       (while flds
 318         (unless (or (elmo-folder-exists-p (car flds))
 319                     (elmo-folder-create (car flds)))
 320           (throw 'create nil))
 321         (setq flds (cdr flds)))
 322       t)))
 323
 324 (luna-define-method elmo-folder-search ((folder elmo-multi-folder)
 325                                         condition &optional numbers)
 326   (let* ((flds (elmo-multi-folder-children-internal folder))
 327          (cur-number 0)
 328          numlist
 329          matches)
 330     (setq numbers (or numbers
 331                       (elmo-folder-list-messages folder)))
 332     (while flds
 333       (setq cur-number (+ cur-number 1))
 334       (setq matches (append matches
 335                             (mapcar
 336                              (function
 337                               (lambda (x)
 338                                 (+
 339                                  (* (elmo-multi-folder-divide-number-internal
 340                                      folder)
 341                                     cur-number)
 342                                  x)))
 343                              (elmo-folder-search
 344                               (car flds) condition))))
 345       (setq flds (cdr flds)))
 346     (elmo-list-filter numbers matches)))
 347
 348 (luna-define-method elmo-message-use-cache-p ((folder elmo-multi-folder)
 349                                               number)
 350   (let ((pair (elmo-multi-real-folder-number folder number)))
 351     (elmo-message-use-cache-p (car pair) (cdr pair))))
 352
 353 (luna-define-method elmo-message-file-p ((folder elmo-multi-folder) number)
 354   (let ((pair (elmo-multi-real-folder-number folder number)))
 355     (elmo-message-file-p (car pair) (cdr pair))))
 356
 357 (luna-define-method elmo-message-file-name ((folder elmo-multi-folder) number)
 358   (let ((pair (elmo-multi-real-folder-number folder number)))
 359     (elmo-message-file-name (car pair) (cdr pair))))
 360
 361 (luna-define-method elmo-folder-plugged-p ((folder elmo-multi-folder))
 362   (let ((flds (elmo-multi-folder-children-internal folder)))
 363     (catch 'plugged
 364       (while flds
 365         (unless (elmo-folder-plugged-p (car flds))
 366           (throw 'plugged nil))
 367         (setq flds (cdr flds)))
 368       t)))
 369
 370 (luna-define-method elmo-folder-set-plugged ((folder elmo-multi-folder)
 371                                              plugged add)
 372   (let ((flds  (elmo-multi-folder-children-internal folder)))
 373     (dolist (fld flds)
 374       (elmo-folder-set-plugged fld plugged add))))
 375
 376 (defun elmo-multi-folder-numbers-list-assoc (folder folder-numbers)
 377   (let (ent)
 378     (while folder-numbers
 379       (when (string= (elmo-folder-name-internal (car (car folder-numbers)))
 380                      (elmo-folder-name-internal folder))
 381         (setq ent (car folder-numbers)
 382               folder-numbers nil))
 383       (setq folder-numbers (cdr folder-numbers)))
 384     ent))
 385
 386 (defun elmo-multi-make-folder-numbers-list (folder msgs)
 387   (let ((msg-list msgs)
 388         pair fld-list
 389         ret-val)
 390     (while msg-list
 391       (when (and (numberp (car msg-list))
 392                  (> (car msg-list) 0))
 393         (setq pair (elmo-multi-real-folder-number folder (car msg-list)))
 394         (if (setq fld-list (elmo-multi-folder-numbers-list-assoc
 395                             (car pair)
 396                             ret-val))
 397             (setcdr fld-list (cons (cdr pair) (cdr fld-list)))
 398           (setq ret-val (cons (cons (car pair) (list (cdr pair))) ret-val))))
 399       (setq msg-list (cdr msg-list)))
 400     ret-val))
 401
 402 (luna-define-method elmo-folder-set-flag ((folder elmo-multi-folder)
 403                                           numbers
 404                                           flag
 405                                           &optional is-local)
 406   (dolist (pair (elmo-multi-make-folder-numbers-list folder numbers))
 407     (elmo-folder-set-flag (car pair) (cdr pair) flag is-local)))
 408
 409 (luna-define-method elmo-folder-unset-flag ((folder elmo-multi-folder)
 410                                             numbers
 411                                             flag
 412                                             &optional is-local)
 413   (dolist (pair (elmo-multi-make-folder-numbers-list folder numbers))
 414     (elmo-folder-unset-flag (car pair) (cdr pair) flag is-local)))
 415
 416 (luna-define-method elmo-folder-list-flagged ((folder elmo-multi-folder)
 417                                               flag
 418                                               &optional in-msgdb)
 419   (let ((cur-number 0)
 420         numbers)
 421     (dolist (child (elmo-multi-folder-children-internal folder))
 422       (setq cur-number (+ cur-number 1)
 423             numbers
 424             (nconc
 425              numbers
 426              (mapcar
 427               (function
 428                (lambda (x)
 429                  (+
 430                   (* (elmo-multi-folder-divide-number-internal folder)
 431                      cur-number) x)))
 432               (elmo-folder-list-flagged child flag in-msgdb)))))
 433     numbers))
 434
 435 (luna-define-method elmo-folder-commit ((folder elmo-multi-folder))
 436   (dolist (child (elmo-multi-folder-children-internal folder))
 437     (elmo-folder-commit child)))
 438
 439 (luna-define-method elmo-folder-length ((folder elmo-multi-folder))
 440   (let ((sum 0))
 441     (dolist (child (elmo-multi-folder-children-internal folder))
 442       (setq sum (+ sum (elmo-folder-length child))))
 443     sum))
 444
 445 (luna-define-method elmo-folder-count-flags ((folder elmo-multi-folder))
 446   (let (flag-alist element)
 447     (dolist (child (elmo-multi-folder-children-internal folder))
 448       (dolist (pair (elmo-folder-count-flags child))
 449         (if (setq element (assq (car pair) flag-alist))
 450             (setcdr element (+ (cdr element) (cdr pair)))
 451           (setq flag-alist (cons pair flag-alist)))))
 452     flag-alist))
 453
 454 (require 'product)
 455 (product-provide (provide 'elmo-multi) (require 'elmo-version))
 456
 457 ;;; elmo-multi.el ends here