elmo/elmo-nntp.el

   1 ;;; elmo-nntp.el --- NNTP Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   5 ;; Copyright (C) 1999,2000      Kenichi OKADA <okada@opaopa.org>
   6
   7 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   8 ;;      Masahiro MURATA <muse@ba2.so-net.ne.jp>
   9 ;;      Kenichi OKADA <okada@opaopa.org>
  10 ;; Keywords: mail, net news
  11
  12 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  13
  14 ;; This program is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18 ;;
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23 ;;
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28 ;;
  29
  30 ;;; Commentary:
  31 ;;
  32
  33 ;;; Code:
  34 ;;
  35
  36 (require 'elmo-vars)
  37 (require 'elmo-util)
  38 (require 'elmo-date)
  39 (require 'elmo-msgdb)
  40 (require 'elmo-cache)
  41 (require 'elmo)
  42 (require 'elmo-net)
  43
  44 (defvar elmo-nntp-overview-fetch-chop-length 200
  45  "*Number of overviews to fetch in one request in nntp.")
  46
  47 (defvar elmo-nntp-use-cache t
  48   "Use cache in nntp folder.")
  49
  50 (defvar elmo-nntp-max-number-precedes-list-active nil
  51   "Non-nil means max number of msgdb is set as the max number of `list active'.
  52 \(Needed for inn 2.3 or later?\).")
  53
  54 (defvar elmo-nntp-group-coding-system nil
  55   "A coding system for newsgroup string.")
  56
  57 (defsubst elmo-nntp-encode-group-string (string)
  58   (if elmo-nntp-group-coding-system
  59       (encode-coding-string string elmo-nntp-group-coding-system)
  60     string))
  61
  62 (defsubst elmo-nntp-decode-group-string (string)
  63   (if elmo-nntp-group-coding-system
  64       (decode-coding-string string elmo-nntp-group-coding-system)
  65     string))
  66
  67 ;; For debugging.
  68 (defvar elmo-nntp-debug nil
  69   "Non-nil forces NNTP folder as debug mode.
  70 Debug information is inserted in the buffer \"*NNTP DEBUG*\"")
  71
  72 ;;; Debug
  73 (defsubst elmo-nntp-debug (message &rest args)
  74   (if elmo-nntp-debug
  75       (let ((biff (string-match "BIFF-" (buffer-name)))
  76             pos)
  77         (with-current-buffer (get-buffer-create (concat "*NNTP DEBUG*"
  78                                                         (if biff "BIFF")))
  79           (goto-char (point-max))
  80           (setq pos (point))
  81           (insert (apply 'format message args) "\n")))))
  82
  83 ;;; ELMO NNTP folder
  84 (eval-and-compile
  85   (luna-define-class elmo-nntp-folder (elmo-net-folder)
  86                      (group temp-crosses reads))
  87   (luna-define-internal-accessors 'elmo-nntp-folder))
  88
  89 (luna-define-method elmo-folder-initialize :around ((folder
  90                                                      elmo-nntp-folder)
  91                                                     name)
  92   (let ((elmo-network-stream-type-alist
  93          (if elmo-nntp-stream-type-alist
  94              (setq elmo-network-stream-type-alist
  95                    (append elmo-nntp-stream-type-alist
  96                            elmo-network-stream-type-alist))
  97            elmo-network-stream-type-alist))
  98         explicit-user parse)
  99     (setq name (luna-call-next-method))
 100     (setq parse (elmo-parse-token name ":"))
 101     (elmo-nntp-folder-set-group-internal folder
 102                                          (elmo-nntp-encode-group-string
 103                                           (car parse)))
 104     (setq explicit-user (eq ?: (string-to-char (cdr parse))))
 105     (setq parse (elmo-parse-prefixed-element ?: (cdr parse)))
 106     (elmo-net-folder-set-user-internal folder
 107                                        (if (eq (length (car parse)) 0)
 108                                            (unless explicit-user
 109                                              elmo-nntp-default-user)
 110                                          (car parse)))
 111     (unless (elmo-net-folder-server-internal folder)
 112       (elmo-net-folder-set-server-internal folder
 113                                            elmo-nntp-default-server))
 114     (unless (elmo-net-folder-port-internal folder)
 115       (elmo-net-folder-set-port-internal folder
 116                                          elmo-nntp-default-port))
 117     (unless (elmo-net-folder-stream-type-internal folder)
 118       (elmo-net-folder-set-stream-type-internal
 119        folder
 120        (elmo-get-network-stream-type
 121         elmo-nntp-default-stream-type)))
 122     folder))
 123
 124 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-nntp-folder))
 125   (convert-standard-filename
 126    (expand-file-name
 127     (elmo-nntp-folder-group-internal folder)
 128     (expand-file-name (or (elmo-net-folder-server-internal folder) "nowhere")
 129                       (expand-file-name "nntp"
 130                                         elmo-msgdb-directory)))))
 131
 132 (luna-define-method elmo-folder-newsgroups ((folder elmo-nntp-folder))
 133   (list (elmo-nntp-folder-group-internal folder)))
 134
 135 ;;; NNTP Session
 136 (eval-and-compile
 137   (luna-define-class elmo-nntp-session (elmo-network-session)
 138                      (current-group))
 139   (luna-define-internal-accessors 'elmo-nntp-session))
 140
 141 ;;
 142 ;; internal variables
 143 ;;
 144
 145 (defvar elmo-nntp-connection-cache nil
 146   "Cache of NNTP connection.")
 147 ;; buffer local variable
 148
 149 (defvar elmo-nntp-list-folders-use-cache 600
 150   "*Time to cache of list folders, as the number of seconds.
 151 Don't cache if nil.")
 152
 153 (defvar elmo-nntp-list-folders-cache nil)
 154
 155 (defvar elmo-nntp-groups-async nil)
 156 (defvar elmo-nntp-header-fetch-chop-length 200)
 157
 158 (defvar elmo-nntp-read-point 0)
 159
 160 (defvar elmo-nntp-send-mode-reader t)
 161
 162 (defvar elmo-nntp-opened-hook nil)
 163
 164 (defvar elmo-nntp-get-folders-securely nil)
 165
 166 (defvar elmo-nntp-default-use-xover t)
 167
 168 (defvar elmo-nntp-default-use-listgroup t)
 169
 170 (defvar elmo-nntp-default-use-list-active t)
 171
 172 (defvar elmo-nntp-default-use-xhdr t)
 173
 174 (defvar elmo-nntp-server-command-alist nil)
 175
 176
 177 (defconst elmo-nntp-server-command-index '((xover . 0)
 178                                            (listgroup . 1)
 179                                            (list-active . 2)))
 180
 181 (defmacro elmo-nntp-get-server-command (session)
 182   (` (assoc (cons (elmo-network-session-server-internal (, session))
 183                   (elmo-network-session-port-internal (, session)))
 184             elmo-nntp-server-command-alist)))
 185
 186 (defmacro elmo-nntp-set-server-command (session com value)
 187   (` (let (entry)
 188        (unless (setq entry (cdr (elmo-nntp-get-server-command
 189                                  (, session))))
 190          (setq elmo-nntp-server-command-alist
 191                (nconc elmo-nntp-server-command-alist
 192                       (list (cons
 193                              (cons
 194                               (elmo-network-session-server-internal (, session))
 195                               (elmo-network-session-port-internal (, session)))
 196                              (setq entry
 197                                    (vector
 198                                     elmo-nntp-default-use-xover
 199                                     elmo-nntp-default-use-listgroup
 200                                     elmo-nntp-default-use-list-active
 201                                     elmo-nntp-default-use-xhdr)))))))
 202        (aset entry
 203              (cdr (assq (, com) elmo-nntp-server-command-index))
 204              (, value)))))
 205
 206 (defmacro elmo-nntp-xover-p (session)
 207   (` (let ((entry (elmo-nntp-get-server-command (, session))))
 208        (if entry
 209            (aref (cdr entry)
 210                  (cdr (assq 'xover elmo-nntp-server-command-index)))
 211          elmo-nntp-default-use-xover))))
 212
 213 (defmacro elmo-nntp-set-xover (session value)
 214   (` (elmo-nntp-set-server-command (, session) 'xover (, value))))
 215
 216 (defmacro elmo-nntp-listgroup-p (session)
 217   (` (let ((entry (elmo-nntp-get-server-command (, session))))
 218        (if entry
 219            (aref (cdr entry)
 220                  (cdr (assq 'listgroup elmo-nntp-server-command-index)))
 221          elmo-nntp-default-use-listgroup))))
 222
 223 (defmacro elmo-nntp-set-listgroup (session value)
 224   (` (elmo-nntp-set-server-command (, session) 'listgroup (, value))))
 225
 226 (defmacro elmo-nntp-list-active-p (session)
 227   (` (let ((entry (elmo-nntp-get-server-command (, session))))
 228        (if entry
 229            (aref (cdr entry)
 230                  (cdr (assq 'list-active elmo-nntp-server-command-index)))
 231          elmo-nntp-default-use-list-active))))
 232
 233 (defmacro elmo-nntp-set-list-active (session value)
 234   (` (elmo-nntp-set-server-command (, session) 'list-active (, value))))
 235
 236 (defmacro elmo-nntp-xhdr-p (session)
 237   (` (let ((entry (elmo-nntp-get-server-command (, session))))
 238        (if entry
 239            (aref (cdr entry)
 240                  (cdr (assq 'xhdr elmo-nntp-server-command-index)))
 241          elmo-nntp-default-use-xhdr))))
 242
 243 (defmacro elmo-nntp-set-xhdr (session value)
 244   (` (elmo-nntp-set-server-command (, session) 'xhdr (, value))))
 245
 246 (defsubst elmo-nntp-max-number-precedes-list-active-p ()
 247   elmo-nntp-max-number-precedes-list-active)
 248
 249 (defsubst elmo-nntp-folder-postfix (user server port type)
 250   (concat
 251    (and user (concat ":" user))
 252    (if (and server
 253             (null (string= server elmo-nntp-default-server)))
 254        (concat "@" server))
 255    (if (and port
 256             (null (eq port elmo-nntp-default-port)))
 257        (concat ":" (if (numberp port)
 258                        (int-to-string port) port)))
 259    (unless (eq (elmo-network-stream-type-symbol type)
 260                elmo-nntp-default-stream-type)
 261      (elmo-network-stream-type-spec-string type))))
 262
 263 (defun elmo-nntp-get-session (folder &optional if-exists)
 264   (elmo-network-get-session
 265    'elmo-nntp-session
 266    (concat
 267     (if (elmo-folder-biff-internal folder)
 268         "BIFF-")
 269     "NNTP")
 270    folder
 271    if-exists))
 272
 273 (luna-define-method elmo-network-initialize-session ((session
 274                                                       elmo-nntp-session))
 275   (let ((process (elmo-network-session-process-internal session))
 276         response)
 277     (set-process-filter (elmo-network-session-process-internal session)
 278                         'elmo-nntp-process-filter)
 279     (with-current-buffer (elmo-network-session-buffer session)
 280       (setq elmo-nntp-read-point (point-min))
 281       ;; Skip garbage output from process before greeting.
 282       (while (and (memq (process-status process) '(open run))
 283                   (goto-char (point-max))
 284                   (forward-line -1)
 285                   (not (looking-at "^[2-5][0-9][0-9]")))
 286         (accept-process-output process 1))
 287       (setq elmo-nntp-read-point (point))
 288       (setq response (elmo-nntp-read-response session t t))
 289       (unless (car response)
 290           (signal 'elmo-open-error (list (cdr response))))
 291       (if elmo-nntp-send-mode-reader
 292           (elmo-nntp-send-mode-reader session))
 293       (when (eq (elmo-network-stream-type-symbol
 294                  (elmo-network-session-stream-type-internal session))
 295                 'starttls)
 296         (elmo-nntp-send-command session "starttls")
 297         (or (elmo-nntp-read-response session)
 298             (error "Cannot open starttls session"))
 299         (starttls-negotiate process)))))
 300
 301 (luna-define-method elmo-network-authenticate-session ((session
 302                                                         elmo-nntp-session))
 303   (with-current-buffer (elmo-network-session-buffer session)
 304     (when (elmo-network-session-user-internal session)
 305       (elmo-nntp-send-command session
 306                               (format "authinfo user %s"
 307                                       (elmo-network-session-user-internal
 308                                        session))
 309                               nil
 310                               'no-log)
 311       (or (elmo-nntp-read-response session)
 312           (signal 'elmo-authenticate-error '(authinfo)))
 313       (elmo-nntp-send-command
 314        session
 315        (format "authinfo pass %s"
 316                (elmo-get-passwd (elmo-network-session-password-key session)))
 317        nil
 318        'no-log)
 319       (or (elmo-nntp-read-response session)
 320           (signal 'elmo-authenticate-error '(authinfo))))))
 321
 322 (luna-define-method elmo-network-setup-session ((session
 323                                                  elmo-nntp-session))
 324   (run-hooks 'elmo-nntp-opened-hook))
 325
 326 (defun elmo-nntp-process-filter (process output)
 327   (when (buffer-live-p (process-buffer process))
 328     (with-current-buffer (process-buffer process)
 329       (goto-char (point-max))
 330       (insert output)
 331       (elmo-nntp-debug "RECEIVED: %s\n" output))))
 332
 333 (defun elmo-nntp-send-mode-reader (session)
 334   (elmo-nntp-send-command session "mode reader")
 335   (if (null (elmo-nntp-read-response session t))
 336       (message "Mode reader failed")))
 337
 338 (defun elmo-nntp-send-command (session command &optional noerase no-log)
 339   (with-current-buffer (elmo-network-session-buffer session)
 340     (unless noerase
 341       (erase-buffer)
 342       (goto-char (point-min)))
 343     (setq elmo-nntp-read-point (point))
 344     (elmo-nntp-debug "SEND: %s\n" (if no-log "<NO LOGGING>" command))
 345     (process-send-string (elmo-network-session-process-internal
 346                           session) command)
 347     (process-send-string (elmo-network-session-process-internal
 348                           session) "\r\n")))
 349
 350 (defun elmo-nntp-read-response (session &optional not-command error-msg)
 351   (with-current-buffer (elmo-network-session-buffer session)
 352     (let ((process (elmo-network-session-process-internal session))
 353           (case-fold-search nil)
 354           (response-string nil)
 355           (response-continue t)
 356           response match-end)
 357       (while response-continue
 358         (goto-char elmo-nntp-read-point)
 359         (while (not (search-forward "\r\n" nil t))
 360           (accept-process-output process)
 361           (goto-char elmo-nntp-read-point))
 362         (setq match-end (point))
 363         (setq response-string
 364               (buffer-substring elmo-nntp-read-point (- match-end 2)))
 365         (goto-char elmo-nntp-read-point)
 366         (if (looking-at "[23][0-9]+ .*$")
 367             (progn (setq response-continue nil)
 368                    (setq elmo-nntp-read-point match-end)
 369                    (setq response
 370                          (if response
 371                              (concat response "\n" response-string)
 372                            response-string)))
 373           (if (looking-at "[^23][0-9]+ .*$")
 374               (progn (setq response-continue nil)
 375                      (setq elmo-nntp-read-point match-end)
 376                      (setq response nil))
 377             (setq elmo-nntp-read-point match-end)
 378             (if not-command
 379                 (setq response-continue nil))
 380             (setq response
 381                   (if response
 382                       (concat response "\n" response-string)
 383                     response-string)))
 384           (setq elmo-nntp-read-point match-end)))
 385       (if error-msg
 386           (cons response response-string)
 387         response))))
 388
 389 (defun elmo-nntp-read-raw-response (session)
 390   (with-current-buffer (elmo-network-session-buffer session)
 391     (goto-char elmo-nntp-read-point)
 392     (while (not (search-forward "\r\n" nil t))
 393       (accept-process-output (elmo-network-session-process-internal
 394                               session))
 395       (goto-char elmo-nntp-read-point))
 396     (buffer-substring elmo-nntp-read-point (- (point) 2))))
 397
 398 (defun elmo-nntp-read-contents (session)
 399   (with-current-buffer (elmo-network-session-buffer session)
 400     (goto-char elmo-nntp-read-point)
 401     (while (not (re-search-forward "^\\.\r\n" nil t))
 402       (accept-process-output (elmo-network-session-process-internal
 403                               session))
 404       (goto-char elmo-nntp-read-point))
 405     (elmo-delete-cr
 406      (buffer-substring elmo-nntp-read-point
 407                        (- (point) 3)))))
 408
 409 (defun elmo-nntp-read-body (session outbuf)
 410   (with-current-buffer (elmo-network-session-buffer session)
 411     (goto-char elmo-nntp-read-point)
 412     (while (not (re-search-forward "^\\.\r\n" nil t))
 413       (accept-process-output (elmo-network-session-process-internal session))
 414       (goto-char elmo-nntp-read-point))
 415     (let ((start elmo-nntp-read-point)
 416           (end  (point)))
 417       (with-current-buffer outbuf
 418         (erase-buffer)
 419         (insert-buffer-substring (elmo-network-session-buffer session)
 420                                  start (- end 3))))
 421     t))
 422
 423 (defun elmo-nntp-select-group (session group &optional force)
 424   (let (response)
 425     (when (or force
 426               (not (string= (elmo-nntp-session-current-group-internal session)
 427                             group)))
 428       (unwind-protect
 429           (progn
 430             (elmo-nntp-send-command session (format "group %s" group))
 431             (setq response (elmo-nntp-read-response session)))
 432         (elmo-nntp-session-set-current-group-internal session
 433                                                       (and response group))
 434         response))))
 435
 436 (defun elmo-nntp-list-folders-get-cache (group server buf)
 437   (when (and elmo-nntp-list-folders-use-cache
 438              elmo-nntp-list-folders-cache
 439              (string-match (concat "^"
 440                                    (regexp-quote
 441                                     (or
 442                                      (nth 1 elmo-nntp-list-folders-cache)
 443                                      "")))
 444                            (or group ""))
 445              (string-match (concat "^"
 446                                    (regexp-quote
 447                                     (or
 448                                      (nth 2 elmo-nntp-list-folders-cache)
 449                                      "")))
 450                            (or server "")))
 451     (let* ((cache-time (car elmo-nntp-list-folders-cache)))
 452       (unless (elmo-time-expire cache-time
 453                                 elmo-nntp-list-folders-use-cache)
 454         (save-excursion
 455           (set-buffer buf)
 456           (erase-buffer)
 457           (insert (nth 3 elmo-nntp-list-folders-cache))
 458           (goto-char (point-min))
 459           (or (string= group "")
 460               (and group
 461                    (keep-lines (concat "^" (regexp-quote group) "\\."))))
 462           t
 463           )))))
 464
 465 (defsubst elmo-nntp-catchup-msgdb (msgdb max-number)
 466   (let (msgdb-max number-alist)
 467     (setq number-alist (elmo-msgdb-get-number-alist msgdb))
 468     (setq msgdb-max (car (nth (max (- (length number-alist) 1) 0)
 469                               number-alist)))
 470     (if (or (not msgdb-max)
 471             (and msgdb-max max-number
 472                  (< msgdb-max max-number)))
 473         (elmo-msgdb-set-number-alist
 474          msgdb
 475          (nconc number-alist (list (cons max-number nil)))))))
 476
 477 (luna-define-method elmo-folder-list-subfolders ((folder elmo-nntp-folder)
 478                                                  &optional one-level)
 479   (elmo-nntp-folder-list-subfolders folder one-level))
 480
 481 (defun elmo-nntp-folder-list-subfolders (folder one-level)
 482   (let ((session (elmo-nntp-get-session folder))
 483         (case-fold-search nil)
 484         response ret-val top-ng username append-serv use-list-active start)
 485     (with-temp-buffer
 486       (set-buffer-multibyte nil)
 487       (if (and (elmo-nntp-folder-group-internal folder)
 488                (elmo-nntp-select-group
 489                 session
 490                 (elmo-nntp-folder-group-internal folder)))
 491           ;; add top newsgroups
 492           (setq ret-val (list (elmo-nntp-folder-group-internal folder))))
 493       (unless (setq response (elmo-nntp-list-folders-get-cache
 494                               (elmo-nntp-folder-group-internal folder)
 495                               (elmo-net-folder-server-internal folder)
 496                               (current-buffer)))
 497         (when (setq use-list-active (elmo-nntp-list-active-p session))
 498           (elmo-nntp-send-command
 499            session
 500            (concat "list"
 501                    (if (and (elmo-nntp-folder-group-internal folder)
 502                             (not (string= (elmo-nntp-folder-group-internal
 503                                            folder) "")))
 504                        (concat " active"
 505                                (format " %s.*"
 506                                        (elmo-nntp-folder-group-internal folder)
 507                                        "")))))
 508           (if (elmo-nntp-read-response session t)
 509               (if (null (setq response (elmo-nntp-read-contents session)))
 510                   (error "NNTP List folders failed")
 511                 (when elmo-nntp-list-folders-use-cache
 512                   (setq elmo-nntp-list-folders-cache
 513                         (list (current-time)
 514                               (elmo-nntp-folder-group-internal folder)
 515                               (elmo-net-folder-server-internal folder)
 516                               response)))
 517                 (erase-buffer)
 518                 (insert response))
 519             (elmo-nntp-set-list-active session nil)
 520             (setq use-list-active nil)))
 521         (when (null use-list-active)
 522           (elmo-nntp-send-command session "list")
 523           (if (null (and (elmo-nntp-read-response session t)
 524                          (setq response (elmo-nntp-read-contents session))))
 525               (error "NNTP List folders failed"))
 526           (when elmo-nntp-list-folders-use-cache
 527             (setq elmo-nntp-list-folders-cache
 528                   (list (current-time) nil nil response)))
 529           (erase-buffer)
 530           (setq start nil)
 531           (while (string-match (concat "^"
 532                                        (regexp-quote
 533                                         (or
 534                                          (elmo-nntp-folder-group-internal
 535                                           folder)
 536                                          "")) ".*$")
 537                                response start)
 538             (insert (match-string 0 response) "\n")
 539             (setq start (match-end 0)))))
 540       (goto-char (point-min))
 541       (let ((len (count-lines (point-min) (point-max)))
 542             (i 0) regexp)
 543         (if one-level
 544             (progn
 545               (setq regexp
 546                     (format "^\\(%s[^. ]+\\)\\([. ]\\).*\n"
 547                             (if (and
 548                                  (elmo-nntp-folder-group-internal folder)
 549                                  (null (string=
 550                                         (elmo-nntp-folder-group-internal
 551                                          folder) "")))
 552                                 (concat (elmo-nntp-folder-group-internal
 553                                          folder)
 554                                         "\\.") "")))
 555               (while (looking-at regexp)
 556                 (setq top-ng (elmo-match-buffer 1))
 557                 (if (string= (elmo-match-buffer 2) " ")
 558                     (if (not (or (member top-ng ret-val)
 559                                  (assoc top-ng ret-val)))
 560                         (setq ret-val (nconc ret-val (list top-ng))))
 561                   (if (member top-ng ret-val)
 562                       (setq ret-val (delete top-ng ret-val)))
 563                   (if (not (assoc top-ng ret-val))
 564                       (setq ret-val (nconc ret-val (list (list top-ng))))))
 565                 (when (> len elmo-display-progress-threshold)
 566                   (setq i (1+ i))
 567                   (if (or (zerop (% i 10)) (= i len))
 568                       (elmo-display-progress
 569                        'elmo-nntp-list-folders "Parsing active..."
 570                        (/ (* i 100) len))))
 571                 (forward-line 1)))
 572           (while (re-search-forward "\\([^ ]+\\) .*\n" nil t)
 573             (setq ret-val (nconc ret-val
 574                                  (list (elmo-match-buffer 1))))
 575             (when (> len elmo-display-progress-threshold)
 576               (setq i (1+ i))
 577               (if (or (zerop (% i 10)) (= i len))
 578                   (elmo-display-progress
 579                    'elmo-nntp-list-folders "Parsing active..."
 580                    (/ (* i 100) len))))))
 581         (when (> len elmo-display-progress-threshold)
 582           (elmo-display-progress
 583            'elmo-nntp-list-folders "Parsing active..." 100))))
 584
 585     (setq username (elmo-net-folder-user-internal folder))
 586     (when (and username
 587                elmo-nntp-default-user
 588                (string= username elmo-nntp-default-user))
 589       (setq username nil))
 590
 591     (when (or username ; XXX: ad-hoc fix against username includes "@"
 592               (not (string= (elmo-net-folder-server-internal folder)
 593                             elmo-nntp-default-server)))
 594       (setq append-serv (concat "@" (elmo-net-folder-server-internal
 595                                      folder))))
 596     (unless (eq (elmo-net-folder-port-internal folder) elmo-nntp-default-port)
 597       (setq append-serv (concat append-serv
 598                                 ":" (int-to-string
 599                                      (elmo-net-folder-port-internal folder)))))
 600     (unless (eq (elmo-network-stream-type-symbol
 601                  (elmo-net-folder-stream-type-internal folder))
 602                 elmo-nntp-default-stream-type)
 603       (setq append-serv
 604             (concat append-serv
 605                     (elmo-network-stream-type-spec-string
 606                      (elmo-net-folder-stream-type-internal folder)))))
 607     (mapcar '(lambda (fld)
 608                (if (consp fld)
 609                    (list (concat "-" (elmo-nntp-decode-group-string (car fld))
 610                                  (and username
 611                                       (concat
 612                                        ":"
 613                                        username))
 614                                  (and append-serv
 615                                       (concat append-serv))))
 616                  (concat "-" (elmo-nntp-decode-group-string fld)
 617                          (and username
 618                               (concat ":" username))
 619                          (and append-serv
 620                               (concat append-serv)))))
 621             ret-val)))
 622
 623 (defun elmo-nntp-make-msglist (beg-str end-str)
 624   (elmo-set-work-buf
 625    (let ((beg-num (string-to-int beg-str))
 626          (end-num (string-to-int end-str))
 627          i)
 628      (setq i beg-num)
 629      (insert "(")
 630      (while (<= i end-num)
 631        (insert (format "%s " i))
 632        (setq i (1+ i)))
 633      (insert ")")
 634      (goto-char (point-min))
 635      (read (current-buffer)))))
 636
 637 (luna-define-method elmo-folder-list-messages-plugged ((folder
 638                                                         elmo-nntp-folder)
 639                                                        &optional nohide)
 640   (let ((session (elmo-nntp-get-session folder))
 641         (group   (elmo-nntp-folder-group-internal folder))
 642         response numbers use-listgroup)
 643     (save-excursion
 644       (when (setq use-listgroup (elmo-nntp-listgroup-p session))
 645         (elmo-nntp-send-command session
 646                                 (format "listgroup %s" group))
 647         (if (not (elmo-nntp-read-response session t))
 648             (progn
 649               (elmo-nntp-set-listgroup session nil)
 650               (setq use-listgroup nil))
 651           (if (null (setq response (elmo-nntp-read-contents session)))
 652               (error "Fetching listgroup failed"))
 653           (setq numbers (elmo-string-to-list response))
 654           (elmo-nntp-session-set-current-group-internal session
 655                                                         group)))
 656       (unless use-listgroup
 657         (elmo-nntp-send-command session (format "group %s" group))
 658         (if (null (setq response (elmo-nntp-read-response session)))
 659             (error "Select group failed"))
 660         (when (and
 661                (string-match
 662                 "211 \\([0-9]+\\) \\([0-9]+\\) \\([0-9]+\\) [^.].+$"
 663                 response)
 664                (> (string-to-int (elmo-match-string 1 response)) 0))
 665           (setq numbers (elmo-nntp-make-msglist
 666                          (elmo-match-string 2 response)
 667                          (elmo-match-string 3 response)))))
 668       numbers)))
 669
 670 (luna-define-method elmo-folder-status ((folder elmo-nntp-folder))
 671   (elmo-nntp-folder-status folder))
 672
 673 (defun elmo-nntp-folder-status (folder)
 674   (let ((killed-list (elmo-msgdb-killed-list-load
 675                       (elmo-folder-msgdb-path folder)))
 676         end-num entry)
 677     (if elmo-nntp-groups-async
 678         (if (setq entry
 679                   (elmo-get-hash-val
 680                    (concat (elmo-nntp-folder-group-internal folder)
 681                            (elmo-nntp-folder-postfix
 682                             (elmo-net-folder-user-internal folder)
 683                             (elmo-net-folder-server-internal folder)
 684                             (elmo-net-folder-port-internal folder)
 685                             (elmo-net-folder-stream-type-internal folder)))
 686                    elmo-newsgroups-hashtb))
 687             (progn
 688               (setq end-num (nth 2 entry))
 689               (when (and killed-list
 690                          (elmo-number-set-member end-num killed-list))
 691                 ;; Max is killed.
 692                 (setq end-num nil))
 693               (cons end-num (car entry)))
 694           (error "No such newsgroup \"%s\""
 695                  (elmo-nntp-folder-group-internal folder)))
 696       (let ((session (elmo-nntp-get-session folder))
 697             response e-num)
 698         (if (null session)
 699             (error "Connection failed"))
 700         (save-excursion
 701           (elmo-nntp-send-command session
 702                                   (format
 703                                    "group %s"
 704                                    (elmo-nntp-folder-group-internal folder)))
 705           (setq response (elmo-nntp-read-response session))
 706           (if (and response
 707                    (string-match
 708                     "211 \\([0-9]+\\) \\([0-9]+\\) \\([0-9]+\\) [^.].+$"
 709                     response))
 710               (progn
 711                 (setq end-num (string-to-int
 712                                (elmo-match-string 3 response)))
 713                 (setq e-num (string-to-int
 714                              (elmo-match-string 1 response)))
 715                 (when (and killed-list
 716                            (elmo-number-set-member end-num killed-list))
 717                   ;; Max is killed.
 718                   (setq end-num nil))
 719                 (cons end-num e-num))
 720             (if (null response)
 721                 (error "Selecting newsgroup \"%s\" failed"
 722                        (elmo-nntp-folder-group-internal folder))
 723               nil)))))))
 724
 725 (defconst elmo-nntp-overview-index
 726   '(("number" . 0)
 727     ("subject" . 1)
 728     ("from" . 2)
 729     ("date" . 3)
 730     ("message-id" . 4)
 731     ("references" . 5)
 732     ("size" . 6)
 733     ("lines" . 7)
 734     ("xref" . 8)))
 735
 736 (defun elmo-nntp-create-msgdb-from-overview-string (str
 737                                                     flag-table
 738                                                     &optional numlist)
 739   (let ((new-msgdb (elmo-make-msgdb))
 740         ov-list gmark message-id entity
 741         ov-entity num
 742         extras extra ext field field-index)
 743     (setq ov-list (elmo-nntp-parse-overview-string str))
 744     (while ov-list
 745       (setq ov-entity (car ov-list))
 746 ;;; INN bug??
 747 ;;;   (if (or (> (setq num (string-to-int (aref ov-entity 0)))
 748 ;;;              99999)
 749 ;;;           (<= num 0))
 750 ;;;       (setq num 0))
 751 ;;;  (setq num (int-to-string num))
 752       (setq num (string-to-int (aref ov-entity 0)))
 753       (when (or (null numlist)
 754                 (memq num numlist))
 755         (setq extras elmo-msgdb-extra-fields
 756               extra nil)
 757         (while extras
 758           (setq ext (downcase (car extras)))
 759           (when (setq field-index (cdr (assoc ext elmo-nntp-overview-index)))
 760             (when (> (length ov-entity) field-index)
 761               (setq field (aref ov-entity field-index))
 762               (when (eq field-index 8) ;; xref
 763                 (setq field (elmo-msgdb-remove-field-string field)))
 764               (setq extra (cons (cons ext field) extra))))
 765           (setq extras (cdr extras)))
 766         (setq entity (elmo-msgdb-make-message-entity
 767                       :message-id (aref ov-entity 4)
 768                       :number     num
 769                       :references (elmo-msgdb-get-last-message-id
 770                                     (aref ov-entity 5))
 771                       :from       (elmo-mime-string (elmo-delete-char
 772                                                      ?\"
 773                                                      (or
 774                                                       (aref ov-entity 2)
 775                                                       elmo-no-from) 'uni))
 776                       :subject    (elmo-mime-string (or (aref ov-entity 1)
 777                                                         elmo-no-subject))
 778                       :date       (aref ov-entity 3)
 779                       :size       (string-to-int (aref ov-entity 6))
 780                       :extra      extra))
 781         (setq message-id (elmo-message-entity-field entity 'message-id))
 782         (setq gmark (or (elmo-msgdb-global-mark-get message-id)
 783                         (elmo-msgdb-mark
 784                          (elmo-flag-table-get flag-table message-id)
 785                          (elmo-file-cache-status
 786                           (elmo-file-cache-get message-id))
 787                          'new)))
 788         (elmo-msgdb-append-entity new-msgdb entity gmark))
 789       (setq ov-list (cdr ov-list)))
 790     new-msgdb))
 791
 792 (luna-define-method elmo-folder-msgdb-create ((folder elmo-nntp-folder)
 793                                               numbers flag-table)
 794   (elmo-nntp-folder-msgdb-create folder numbers flag-table))
 795
 796 (defun elmo-nntp-folder-msgdb-create (folder numbers flag-table)
 797   (let ((filter numbers)
 798         (session (elmo-nntp-get-session folder))
 799         beg-num end-num cur length
 800         ret-val ov-str use-xover dir)
 801     (elmo-nntp-select-group session (elmo-nntp-folder-group-internal
 802                                      folder))
 803     (when (setq use-xover (elmo-nntp-xover-p session))
 804       (setq beg-num (car numbers)
 805             cur beg-num
 806             end-num (nth (1- (length numbers)) numbers)
 807             length  (+ (- end-num beg-num) 1))
 808       (message "Getting overview...")
 809       (while (<= cur end-num)
 810         (elmo-nntp-send-command
 811          session
 812          (format
 813           "xover %s-%s"
 814           (int-to-string cur)
 815           (int-to-string
 816            (+ cur
 817               elmo-nntp-overview-fetch-chop-length))))
 818         (with-current-buffer (elmo-network-session-buffer session)
 819           (if ov-str
 820               (setq ret-val
 821                     (elmo-msgdb-append
 822                      ret-val
 823                      (elmo-nntp-create-msgdb-from-overview-string
 824                       ov-str
 825                       flag-table
 826                       filter
 827                       )))))
 828         (if (null (elmo-nntp-read-response session t))
 829             (progn
 830               (setq cur end-num);; exit while loop
 831               (elmo-nntp-set-xover session nil)
 832               (setq use-xover nil))
 833           (if (null (setq ov-str (elmo-nntp-read-contents session)))
 834               (error "Fetching overview failed")))
 835         (setq cur (+ elmo-nntp-overview-fetch-chop-length cur 1))
 836         (when (> length elmo-display-progress-threshold)
 837           (elmo-display-progress
 838            'elmo-nntp-msgdb-create "Getting overview..."
 839            (/ (* (+ (- (min cur end-num)
 840                        beg-num) 1) 100) length))))
 841       (when (> length elmo-display-progress-threshold)
 842         (elmo-display-progress
 843          'elmo-nntp-msgdb-create "Getting overview..." 100)))
 844     (if (not use-xover)
 845         (setq ret-val (elmo-nntp-msgdb-create-by-header
 846                        session numbers flag-table))
 847       (with-current-buffer (elmo-network-session-buffer session)
 848         (if ov-str
 849             (setq ret-val
 850                   (elmo-msgdb-append
 851                    ret-val
 852                    (elmo-nntp-create-msgdb-from-overview-string
 853                     ov-str
 854                     flag-table
 855                     filter))))))
 856     (elmo-folder-set-killed-list-internal
 857      folder
 858      (nconc
 859       (elmo-folder-killed-list-internal folder)
 860       (car (elmo-list-diff
 861             numbers
 862             (elmo-msgdb-list-messages ret-val)))))
 863     ;; If there are canceled messages, overviews are not obtained
 864     ;; to max-number(inn 2.3?).
 865     (when (and (elmo-nntp-max-number-precedes-list-active-p)
 866                (elmo-nntp-list-active-p session))
 867       (elmo-nntp-send-command session
 868                               (format "list active %s"
 869                                       (elmo-nntp-folder-group-internal
 870                                        folder)))
 871       (if (null (elmo-nntp-read-response session))
 872           (progn
 873             (elmo-nntp-set-list-active session nil)
 874             (error "NNTP list command failed")))
 875       (elmo-nntp-catchup-msgdb
 876        ret-val
 877        (nth 1 (read (concat "(" (elmo-nntp-read-contents
 878                                  session) ")")))))
 879     ret-val))
 880
 881 (luna-define-method elmo-folder-update-number ((folder elmo-nntp-folder))
 882   (if (elmo-nntp-max-number-precedes-list-active-p)
 883       (let ((session (elmo-nntp-get-session folder))
 884             (number-alist (elmo-msgdb-get-number-alist
 885                            (elmo-folder-msgdb folder))))
 886         (if (elmo-nntp-list-active-p session)
 887             (let (msgdb-max max-number)
 888               ;; If there are canceled messages, overviews are not obtained
 889               ;; to max-number(inn 2.3?).
 890               (elmo-nntp-select-group session
 891                                       (elmo-nntp-folder-group-internal folder))
 892               (elmo-nntp-send-command session
 893                                       (format "list active %s"
 894                                               (elmo-nntp-folder-group-internal
 895                                                folder)))
 896               (if (null (elmo-nntp-read-response session))
 897                   (error "NNTP list command failed"))
 898               (setq max-number
 899                     (nth 1 (read (concat "(" (elmo-nntp-read-contents
 900                                               session) ")"))))
 901               (setq msgdb-max
 902                     (car (nth (max (- (length number-alist) 1) 0)
 903                               number-alist)))
 904               (if (or (and number-alist (not msgdb-max))
 905                       (and msgdb-max max-number
 906                            (< msgdb-max max-number)))
 907                   (elmo-msgdb-set-number-alist
 908                    (elmo-folder-msgdb folder)
 909                    (nconc number-alist
 910                           (list (cons max-number nil))))))))))
 911
 912 (defun elmo-nntp-msgdb-create-by-header (session numbers flag-table)
 913   (with-temp-buffer
 914     (elmo-nntp-retrieve-headers session (current-buffer) numbers)
 915     (elmo-nntp-msgdb-create-message
 916      (length numbers) flag-table)))
 917
 918 (defun elmo-nntp-parse-xhdr-response (string)
 919   (let (response)
 920     (with-temp-buffer
 921       (insert string)
 922       (goto-char (point-min))
 923       (while (not (eobp))
 924         (if (looking-at "^\\([0-9]+\\) \\(.*\\)$")
 925             (setq response (cons (cons (string-to-int (elmo-match-buffer 1))
 926                                        (elmo-match-buffer 2))
 927                                  response)))
 928         (forward-line 1)))
 929     (nreverse response)))
 930
 931 (defun elmo-nntp-parse-overview-string (string)
 932   (save-excursion
 933     (let ((tmp-buffer (get-buffer-create " *ELMO Overview TMP*"))
 934           ret-list ret-val beg)
 935       (set-buffer tmp-buffer)
 936       (erase-buffer)
 937       (elmo-set-buffer-multibyte nil)
 938       (insert string)
 939       (goto-char (point-min))
 940       (setq beg (point))
 941       (while (not (eobp))
 942         (end-of-line)
 943         (setq ret-list (save-match-data
 944                          (apply 'vector (split-string
 945                                          (buffer-substring beg (point))
 946                                          "\t"))))
 947         (beginning-of-line)
 948         (forward-line 1)
 949         (setq beg (point))
 950         (setq ret-val (nconc ret-val (list ret-list))))
 951 ;;;   (kill-buffer tmp-buffer)
 952       ret-val)))
 953
 954 (defun elmo-nntp-get-newsgroup-by-msgid (msgid server user port type)
 955   "Get nntp header string."
 956   (save-excursion
 957     (let ((session (elmo-nntp-get-session
 958                     (luna-make-entity
 959                      'elmo-nntp-folder
 960                      :user user
 961                      :server server
 962                      :port port
 963                      :stream-type type))))
 964       (elmo-nntp-send-command session
 965                               (format "head %s" msgid))
 966       (if (elmo-nntp-read-response session)
 967           (elmo-nntp-read-contents session))
 968       (with-current-buffer (elmo-network-session-buffer session)
 969         (std11-field-body "Newsgroups")))))
 970
 971 (luna-define-method elmo-message-fetch-with-cache-process :around
 972   ((folder elmo-nntp-folder) number strategy &optional section unread)
 973   (when (luna-call-next-method)
 974     (elmo-nntp-setup-crosspost-buffer folder number)
 975     (unless unread
 976       (elmo-nntp-folder-update-crosspost-message-alist
 977        folder (list number)))
 978     t))
 979
 980 (luna-define-method elmo-message-fetch-plugged ((folder elmo-nntp-folder)
 981                                                 number strategy
 982                                                 &optional section outbuf
 983                                                 unread)
 984   (elmo-nntp-message-fetch folder number strategy section outbuf unread))
 985
 986 (defun elmo-nntp-message-fetch (folder number strategy section outbuf unread)
 987   (let ((session (elmo-nntp-get-session folder))
 988         newsgroups)
 989     (with-current-buffer (elmo-network-session-buffer session)
 990       (elmo-nntp-select-group session (elmo-nntp-folder-group-internal folder))
 991       (elmo-nntp-send-command session (format "article %s" number))
 992       (if (null (elmo-nntp-read-response session t))
 993           (progn
 994             (with-current-buffer outbuf (erase-buffer))
 995             (message "Fetching message failed")
 996             nil)
 997         (prog1 (elmo-nntp-read-body session outbuf)
 998           (with-current-buffer outbuf
 999             (goto-char (point-min))
1000             (while (re-search-forward "^\\." nil t)
1001               (replace-match "")
1002               (forward-line))
1003             (elmo-nntp-setup-crosspost-buffer folder number)
1004             (unless unread
1005               (elmo-nntp-folder-update-crosspost-message-alist
1006                folder (list number)))))))))
1007
1008 (defun elmo-nntp-post (hostname content-buf)
1009   (let ((session (elmo-nntp-get-session
1010                   (luna-make-entity
1011                    'elmo-nntp-folder
1012                    :user elmo-nntp-default-user
1013                    :server hostname
1014                    :port elmo-nntp-default-port
1015                    :stream-type
1016                    (elmo-get-network-stream-type
1017                     elmo-nntp-default-stream-type))))
1018         response has-message-id)
1019     (save-excursion
1020       (set-buffer content-buf)
1021       (goto-char (point-min))
1022       (if (search-forward mail-header-separator nil t)
1023           (delete-region (match-beginning 0)(match-end 0)))
1024       (setq has-message-id (std11-field-body "message-id"))
1025       (elmo-nntp-send-command session "post")
1026       (if (string-match "^340" (setq response
1027                                      (elmo-nntp-read-raw-response session)))
1028           (if (string-match "recommended ID \\(<[^@]+@[^>]+>\\)" response)
1029               (unless has-message-id
1030                 (goto-char (point-min))
1031                 (insert (concat "Message-ID: "
1032                                 (elmo-match-string 1 response)
1033                                 "\n"))))
1034         (error "POST failed"))
1035       (run-hooks 'elmo-nntp-post-pre-hook)
1036       (elmo-nntp-send-buffer session content-buf)
1037       (elmo-nntp-send-command session ".")
1038 ;;;   (elmo-nntp-read-response buffer process t)
1039       (if (not (string-match
1040                 "^2" (setq response (elmo-nntp-read-raw-response
1041                                      session))))
1042           (error "NNTP error: %s" response)))))
1043
1044 (defsubst elmo-nntp-send-data-line (session line)
1045   "Send LINE to SESSION."
1046   ;; Escape "." at start of a line
1047   (if (eq (string-to-char line) ?.)
1048       (process-send-string (elmo-network-session-process-internal
1049                             session) "."))
1050   (process-send-string (elmo-network-session-process-internal
1051                         session) line)
1052   (process-send-string (elmo-network-session-process-internal
1053                         session) "\r\n"))
1054
1055 (defun elmo-nntp-send-buffer (session databuf)
1056   "Send data content of DATABUF to SESSION."
1057   (let ((data-continue t)
1058         line bol)
1059     (with-current-buffer databuf
1060       (goto-char (point-min))
1061       (while data-continue
1062         (beginning-of-line)
1063         (setq bol (point))
1064         (end-of-line)
1065         (setq line (buffer-substring bol (point)))
1066         (unless (eq (forward-line 1) 0) (setq data-continue nil))
1067         (elmo-nntp-send-data-line session line)))))
1068
1069 (luna-define-method elmo-folder-delete-messages ((folder elmo-nntp-folder)
1070                                                  numbers)
1071   (elmo-nntp-folder-delete-messages folder numbers))
1072
1073 (defun elmo-nntp-folder-delete-messages (folder numbers)
1074   (let ((killed-list (elmo-folder-killed-list-internal folder)))
1075     (dolist (number numbers)
1076       (setq killed-list
1077             (elmo-msgdb-set-as-killed killed-list number)))
1078     (elmo-folder-set-killed-list-internal folder killed-list))
1079   t)
1080
1081 (luna-define-method elmo-folder-exists-p-plugged ((folder elmo-nntp-folder))
1082   (let ((session (elmo-nntp-get-session folder)))
1083           (elmo-nntp-send-command
1084            session
1085            (format "group %s"
1086                    (elmo-nntp-folder-group-internal folder)))
1087     (elmo-nntp-read-response session)))
1088
1089 (defun elmo-nntp-retrieve-field (spec field from-msgs)
1090   "Retrieve FIELD values from FROM-MSGS.
1091 Returns a list of cons cells like (NUMBER . VALUE)"
1092   (let ((session (elmo-nntp-get-session spec)))
1093     (if (elmo-nntp-xhdr-p session)
1094         (progn
1095           (elmo-nntp-select-group session (elmo-nntp-folder-group-internal spec))
1096           (elmo-nntp-send-command session
1097                                   (format "xhdr %s %s"
1098                                           field
1099                                           (if from-msgs
1100                                               (format
1101                                                "%d-%d"
1102                                                (car from-msgs)
1103                                                (nth
1104                                                 (max
1105                                                  (- (length from-msgs) 1) 0)
1106                                                 from-msgs))
1107                                             "0-")))
1108           (if (elmo-nntp-read-response session t)
1109               (elmo-nntp-parse-xhdr-response
1110                (elmo-nntp-read-contents session))
1111             (elmo-nntp-set-xhdr session nil)
1112             (error "NNTP XHDR command failed"))))))
1113
1114 (defun elmo-nntp-search-primitive (spec condition &optional from-msgs)
1115   (let ((search-key (elmo-filter-key condition)))
1116     (cond
1117      ((string= "last" search-key)
1118       (let ((numbers (or from-msgs (elmo-folder-list-messages spec))))
1119         (nthcdr (max (- (length numbers)
1120                         (string-to-int (elmo-filter-value condition)))
1121                      0)
1122                 numbers)))
1123      ((string= "first" search-key)
1124       (let* ((numbers (or from-msgs (elmo-folder-list-messages spec)))
1125              (rest (nthcdr (string-to-int (elmo-filter-value condition) )
1126                            numbers)))
1127         (mapcar '(lambda (x) (delete x numbers)) rest)
1128         numbers))
1129      ((or (string= "since" search-key)
1130           (string= "before" search-key))
1131       (let* ((specified-date (elmo-date-make-sortable-string
1132                               (elmo-date-get-datevec (elmo-filter-value
1133                                                       condition))))
1134              (since (string= "since" search-key))
1135              field-date  result)
1136         (if (eq (elmo-filter-type condition) 'unmatch)
1137             (setq since (not since)))
1138         (setq result
1139               (delq nil
1140                     (mapcar
1141                      (lambda (pair)
1142                        (setq field-date
1143                              (elmo-date-make-sortable-string
1144                               (timezone-fix-time
1145                                (cdr pair)
1146                                (current-time-zone) nil)))
1147                        (if (if since
1148                                (or (string= specified-date field-date)
1149                                    (string< specified-date field-date))
1150                              (string< field-date
1151                                       specified-date))
1152                            (car pair)))
1153                      (elmo-nntp-retrieve-field spec "date" from-msgs))))
1154         (if from-msgs
1155             (elmo-list-filter from-msgs result)
1156           result)))
1157      ((string= "body" search-key)
1158       nil)
1159      (t
1160       (let ((val (elmo-filter-value condition))
1161             (negative (eq (elmo-filter-type condition) 'unmatch))
1162             (case-fold-search t)
1163             result)
1164         (setq result
1165               (delq nil
1166                     (mapcar
1167                      (lambda (pair)
1168                        (if (string-match val
1169                                          (eword-decode-string
1170                                           (decode-mime-charset-string
1171                                            (cdr pair) elmo-mime-charset)))
1172                            (unless negative (car pair))
1173                          (if negative (car pair))))
1174                      (elmo-nntp-retrieve-field spec search-key
1175                                                from-msgs))))
1176         (if from-msgs
1177             (elmo-list-filter from-msgs result)
1178           result))))))
1179
1180 (defun elmo-nntp-search-internal (folder condition from-msgs)
1181   (let (result)
1182     (cond
1183      ((vectorp condition)
1184       (setq result (elmo-nntp-search-primitive
1185                     folder condition from-msgs)))
1186      ((eq (car condition) 'and)
1187       (setq result (elmo-nntp-search-internal folder
1188                                               (nth 1 condition)
1189                                               from-msgs)
1190             result (elmo-list-filter result
1191                                      (elmo-nntp-search-internal
1192                                       folder (nth 2 condition)
1193                                       from-msgs))))
1194      ((eq (car condition) 'or)
1195       (setq result (elmo-nntp-search-internal folder
1196                                               (nth 1 condition)
1197                                               from-msgs)
1198             result (elmo-uniq-list
1199                     (nconc result
1200                            (elmo-nntp-search-internal folder
1201                                                       (nth 2 condition)
1202                                                       from-msgs)))
1203             result (sort result '<))))))
1204
1205 (luna-define-method elmo-folder-search :around ((folder elmo-nntp-folder)
1206                                                 condition &optional from-msgs)
1207   (if (and (elmo-folder-plugged-p folder)
1208            (not (string= "body" (elmo-filter-key condition))))
1209       (elmo-nntp-search-internal folder condition from-msgs)
1210     (luna-call-next-method)))
1211
1212 (defun elmo-nntp-get-folders-info-prepare (folder session-keys)
1213   (condition-case ()
1214       (let ((session (elmo-nntp-get-session folder))
1215             key count)
1216         (with-current-buffer (elmo-network-session-buffer session)
1217           (unless (setq key (assoc session session-keys))
1218             (erase-buffer)
1219             (setq key (cons session
1220                             (vector 0
1221                                     (elmo-net-folder-server-internal folder)
1222                                     (elmo-net-folder-user-internal folder)
1223                                     (elmo-net-folder-port-internal folder)
1224                                     (elmo-net-folder-stream-type-internal
1225                                      folder))))
1226             (setq session-keys (nconc session-keys (list key))))
1227           (elmo-nntp-send-command session
1228                                   (format "group %s"
1229                                           (elmo-nntp-folder-group-internal
1230                                            folder))
1231                                   'noerase)
1232           (if elmo-nntp-get-folders-securely
1233               (accept-process-output
1234                (elmo-network-session-process-internal session)
1235                1))
1236           (setq count (aref (cdr key) 0))
1237           (aset (cdr key) 0 (1+ count))))
1238     (error
1239      (when elmo-auto-change-plugged
1240        (sit-for 1))
1241      nil))
1242   session-keys)
1243
1244 (defun elmo-nntp-get-folders-info (session-keys)
1245   (let ((sessions session-keys)
1246         (cur (get-buffer-create " *ELMO NNTP Temp*")))
1247     (while sessions
1248       (let* ((session (caar sessions))
1249              (key     (cdar sessions))
1250              (count   (aref key 0))
1251              (server  (aref key 1))
1252              (user    (aref key 2))
1253              (port    (aref key 3))
1254              (type    (aref key 4))
1255              (hashtb (or elmo-newsgroups-hashtb
1256                          (setq elmo-newsgroups-hashtb
1257                                (elmo-make-hash count)))))
1258         (save-excursion
1259           (elmo-nntp-groups-read-response session cur count)
1260           (set-buffer cur)
1261           (goto-char (point-min))
1262           (let ((case-replace nil)
1263                 (postfix (elmo-nntp-folder-postfix user server port type)))
1264             (if (not (string= postfix ""))
1265                 (save-excursion
1266                   (while (re-search-forward "^\\(211 [0-9]+ [0-9]+ [0-9]+ [^ \n]+\\)\\(.*\\)$" nil t)
1267                     (replace-match (concat (match-string 1)
1268                                            (elmo-replace-in-string
1269                                             postfix
1270                                             "\\\\" "\\\\\\\\\\\\\\\\")))))))
1271           (let (len min max group)
1272             (while (not (eobp))
1273               (condition-case ()
1274                   (when (= (following-char) ?2)
1275                     (read cur)
1276                     (setq len (read cur)
1277                           min (read cur)
1278                           max (read cur))
1279                     (set (setq group (let ((obarray hashtb)) (read cur)))
1280                          (list len min max)))
1281                 (error (and group (symbolp group) (set group nil))))
1282               (forward-line 1))))
1283         (setq sessions (cdr sessions))))
1284     (kill-buffer cur)))
1285
1286 ;; original is 'nntp-retrieve-groups [Gnus]
1287 (defun elmo-nntp-groups-read-response (session outbuf count)
1288   (let* ((received 0)
1289          (last-point (point-min)))
1290     (with-current-buffer (elmo-network-session-buffer session)
1291       (accept-process-output
1292        (elmo-network-session-process-internal session) 1)
1293       (discard-input)
1294       ;; Wait for all replies.
1295       (message "Getting folders info...")
1296       (while (progn
1297                (goto-char last-point)
1298                ;; Count replies.
1299                (while (re-search-forward "^[0-9]" nil t)
1300                  (setq received
1301                        (1+ received)))
1302                (setq last-point (point))
1303                (< received count))
1304         (accept-process-output (elmo-network-session-process-internal session)
1305                                1)
1306         (discard-input)
1307         (when (> count elmo-display-progress-threshold)
1308           (if (or (zerop (% received 10)) (= received count))
1309               (elmo-display-progress
1310                'elmo-nntp-groups-read-response "Getting folders info..."
1311                (/ (* received 100) count)))))
1312       (when (> count elmo-display-progress-threshold)
1313         (elmo-display-progress
1314          'elmo-nntp-groups-read-response "Getting folders info..." 100))
1315       ;; Wait for the reply from the final command.
1316       (goto-char (point-max))
1317       (re-search-backward "^[0-9]" nil t)
1318       (when (looking-at "^[23]")
1319         (while (progn
1320                  (goto-char (point-max))
1321                  (not (re-search-backward "\r?\n" (- (point) 3) t)))
1322           (accept-process-output
1323            (elmo-network-session-process-internal session) 1)
1324           (discard-input)))
1325       ;; Now all replies are received.  We remove CRs.
1326       (goto-char (point-min))
1327       (while (search-forward "\r" nil t)
1328         (replace-match "" t t))
1329       (copy-to-buffer outbuf (point-min) (point-max)))))
1330
1331 ;; from nntp.el [Gnus]
1332
1333 (defsubst elmo-nntp-next-result-arrived-p ()
1334   (cond
1335    ((eq (following-char) ?2)
1336     (if (re-search-forward "\n\\.\r?\n" nil t)
1337         t
1338       nil))
1339    ((looking-at "[34]")
1340     (if (search-forward "\n" nil t)
1341         t
1342       nil))
1343    (t
1344     nil)))
1345
1346 (defun elmo-nntp-retrieve-headers (session outbuf articles)
1347   "Retrieve the headers of ARTICLES."
1348   (with-current-buffer (elmo-network-session-buffer session)
1349     (erase-buffer)
1350     (let ((number (length articles))
1351           (count 0)
1352           (received 0)
1353           (last-point (point-min))
1354           article)
1355       ;; Send HEAD commands.
1356       (while (setq article (pop articles))
1357         (elmo-nntp-send-command session
1358                                 (format "head %s" article)
1359                                 'noerase)
1360         (setq count (1+ count))
1361         ;; Every 200 requests we have to read the stream in
1362         ;; order to avoid deadlocks.
1363         (when (or (null articles)       ;All requests have been sent.
1364                   (zerop (% count elmo-nntp-header-fetch-chop-length)))
1365           (accept-process-output
1366            (elmo-network-session-process-internal session) 1)
1367           (discard-input)
1368           (while (progn
1369                    (goto-char last-point)
1370                    ;; Count replies.
1371                    (while (elmo-nntp-next-result-arrived-p)
1372                      (setq last-point (point))
1373                      (setq received (1+ received)))
1374                    (< received count))
1375             (when (> number elmo-display-progress-threshold)
1376               (if (or (zerop (% received 20)) (= received number))
1377                   (elmo-display-progress
1378                    'elmo-nntp-retrieve-headers "Getting headers..."
1379                    (/ (* received 100) number))))
1380             (accept-process-output
1381              (elmo-network-session-process-internal session) 1)
1382             (discard-input))))
1383       (when (> number elmo-display-progress-threshold)
1384         (elmo-display-progress
1385          'elmo-nntp-retrieve-headers "Getting headers..." 100))
1386       (message "Getting headers...done")
1387       ;; Remove all "\r"'s.
1388       (goto-char (point-min))
1389       (while (search-forward "\r\n" nil t)
1390         (replace-match "\n"))
1391       (copy-to-buffer outbuf (point-min) (point-max)))))
1392
1393 ;; end of from Gnus
1394
1395 (defun elmo-nntp-msgdb-create-message (len flag-table)
1396   (save-excursion
1397     (let ((new-msgdb (elmo-make-msgdb))
1398           beg overview number-alist mark-alist
1399           entity i num gmark seen message-id)
1400       (elmo-set-buffer-multibyte nil)
1401       (goto-char (point-min))
1402       (setq i 0)
1403       (message "Creating msgdb...")
1404       (while (not (eobp))
1405         (setq beg (save-excursion (forward-line 1) (point)))
1406         (setq num
1407               (and (looking-at "^2[0-9]*[ ]+\\([0-9]+\\)")
1408                    (string-to-int
1409                     (elmo-match-buffer 1))))
1410         (elmo-nntp-next-result-arrived-p)
1411         (when num
1412           (save-excursion
1413             (forward-line -1)
1414             (save-restriction
1415               (narrow-to-region beg (point))
1416               (setq entity
1417                     (elmo-msgdb-create-overview-from-buffer num))
1418               (when entity
1419                 (setq message-id
1420                       (elmo-message-entity-field entity 'message-id)
1421                       gmark
1422                       (or (elmo-msgdb-global-mark-get message-id)
1423                           (elmo-msgdb-mark
1424                            (elmo-flag-table-get flag-table message-id)
1425                            (elmo-file-cache-status
1426                             (elmo-file-cache-get message-id))
1427                            'new)))
1428                 (elmo-msgdb-append-entity new-msgdb entity gmark)))))
1429         (when (> len elmo-display-progress-threshold)
1430           (setq i (1+ i))
1431           (if (or (zerop (% i 20)) (= i len))
1432               (elmo-display-progress
1433                'elmo-nntp-msgdb-create-message "Creating msgdb..."
1434                (/ (* i 100) len)))))
1435       (when (> len elmo-display-progress-threshold)
1436         (elmo-display-progress
1437          'elmo-nntp-msgdb-create-message "Creating msgdb..." 100))
1438       new-msgdb)))
1439
1440 (luna-define-method elmo-message-use-cache-p ((folder elmo-nntp-folder) number)
1441   elmo-nntp-use-cache)
1442
1443 (defun elmo-nntp-parse-newsgroups (string &optional subscribe-only)
1444   (let ((nglist (elmo-parse string "[ \t\f\r\n,]*\\([^ \t\f\r\n,]+\\)"))
1445         ngs)
1446     (if (not subscribe-only)
1447         nglist
1448       (dolist (ng nglist)
1449         (if (intern-soft ng elmo-newsgroups-hashtb)
1450             (setq ngs (cons ng ngs))))
1451       ngs)))
1452
1453 ;;; Crosspost processing.
1454
1455 ;; 1. setup crosspost alist.
1456 ;;    1.1. When message is fetched and is crossposted message,
1457 ;;         it is remembered in `temp-crosses' slot.
1458 ;;         temp-crosses slot is a list of cons cell:
1459 ;;         (NUMBER . (MESSAGE-ID (LIST-OF-NEWSGROUPS) 'ng))
1460 ;;    1.2. In elmo-folder-close, `temp-crosses' slot is cleared,
1461 ;;    1.3. In elmo-folder-mark-as-read, move crosspost entry
1462 ;;         from `temp-crosses' slot to `elmo-crosspost-message-alist'.
1463
1464 ;; 2. process crosspost alist.
1465 ;;    2.1. At elmo-folder-process-crosspost, setup `reads' slot from
1466 ;;         `elmo-crosspost-message-alist'.
1467 ;;    2.2. remove crosspost entry for current newsgroup from
1468 ;;         `elmo-crosspost-message-alist'.
1469 ;;    2.3. elmo-folder-list-unreads return unread message list according to
1470 ;;         `reads' slot.
1471 ;;         (There's a problem that if `elmo-folder-list-unreads'
1472 ;;           never executed, crosspost information is thrown away.)
1473 ;;    2.4. In elmo-folder-close, `read' slot is cleared,
1474
1475 (defun elmo-nntp-setup-crosspost-buffer (folder number)
1476 ;;    1.1. When message is fetched and is crossposted message,
1477 ;;         it is remembered in `temp-crosses' slot.
1478 ;;         temp-crosses slot is a list of cons cell:
1479 ;;         (NUMBER . (MESSAGE-ID (LIST-OF-NEWSGROUPS) 'ng))
1480   (let (newsgroups crosspost-newsgroups message-id)
1481     (save-restriction
1482       (std11-narrow-to-header)
1483       (setq newsgroups (std11-fetch-field "newsgroups")
1484             message-id (std11-msg-id-string
1485                         (car (std11-parse-msg-id-string
1486                               (std11-fetch-field "message-id"))))))
1487     (when newsgroups
1488       (when (setq crosspost-newsgroups
1489                   (delete
1490                    (elmo-nntp-folder-group-internal folder)
1491                    (elmo-nntp-parse-newsgroups newsgroups t)))
1492         (unless (assq number
1493                       (elmo-nntp-folder-temp-crosses-internal folder))
1494           (elmo-nntp-folder-set-temp-crosses-internal
1495            folder
1496            (cons (cons number (list message-id crosspost-newsgroups 'ng))
1497                  (elmo-nntp-folder-temp-crosses-internal folder))))))))
1498
1499 (luna-define-method elmo-folder-close-internal ((folder elmo-nntp-folder))
1500 ;;    1.2. In elmo-folder-close, `temp-crosses' slot is cleared,
1501   (elmo-nntp-folder-set-temp-crosses-internal folder nil)
1502   (elmo-nntp-folder-set-reads-internal folder nil)
1503   )
1504
1505 (defun elmo-nntp-folder-update-crosspost-message-alist (folder numbers)
1506 ;;    1.3. In elmo-folder-mark-as-read, move crosspost entry
1507 ;;         from `temp-crosses' slot to `elmo-crosspost-message-alist'.
1508   (let (elem)
1509     (dolist (number numbers)
1510       (when (setq elem (assq number
1511                              (elmo-nntp-folder-temp-crosses-internal folder)))
1512         (unless (assoc (cdr (cdr elem)) elmo-crosspost-message-alist)
1513           (setq elmo-crosspost-message-alist
1514                 (cons (cdr elem) elmo-crosspost-message-alist)))
1515         (elmo-nntp-folder-set-temp-crosses-internal
1516          folder
1517          (delq elem (elmo-nntp-folder-temp-crosses-internal folder)))))))
1518
1519 (luna-define-method elmo-folder-mark-as-read :before ((folder
1520                                                        elmo-nntp-folder)
1521                                                       numbers
1522                                                       &optional ignore-flags)
1523   (elmo-nntp-folder-update-crosspost-message-alist folder numbers))
1524
1525 (defsubst elmo-nntp-folder-process-crosspost (folder)
1526 ;;    2.1. At elmo-folder-process-crosspost, setup `reads' slot from
1527 ;;         `elmo-crosspost-message-alist'.
1528 ;;    2.2. remove crosspost entry for current newsgroup from
1529 ;;         `elmo-crosspost-message-alist'.
1530   (let (cross-deletes reads entity ngs)
1531     (dolist (cross elmo-crosspost-message-alist)
1532       (when (setq entity (elmo-message-entity folder (nth 0 cross)))
1533         (setq reads (cons (elmo-message-entity-number entity) reads)))
1534       (when entity
1535         (if (setq ngs (delete (elmo-nntp-folder-group-internal folder)
1536                               (nth 1 cross)))
1537             (setcar (cdr cross) ngs)
1538           (setq cross-deletes (cons cross cross-deletes)))
1539         (setq elmo-crosspost-message-alist-modified t)))
1540     (dolist (dele cross-deletes)
1541       (setq elmo-crosspost-message-alist (delq
1542                                           dele
1543                                           elmo-crosspost-message-alist)))
1544     (elmo-nntp-folder-set-reads-internal folder reads)))
1545
1546 (luna-define-method elmo-folder-process-crosspost ((folder elmo-nntp-folder))
1547   (elmo-nntp-folder-process-crosspost folder))
1548
1549 (luna-define-method elmo-folder-list-unreads :around ((folder
1550                                                        elmo-nntp-folder))
1551   ;;    2.3. elmo-folder-list-unreads return unread message list according to
1552   ;;         `reads' slot.
1553   (elmo-living-messages (luna-call-next-method)
1554                         (elmo-nntp-folder-reads-internal folder)))
1555
1556 (require 'product)
1557 (product-provide (provide 'elmo-nntp) (require 'elmo-version))
1558
1559 ;;; elmo-nntp.el ends here