elmo/elmo-pop3.el

   1 ;;; elmo-pop3.el -- POP3 Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1999,2000      Kenichi OKADA <okada@opaopa.org>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Kenichi OKADA <okada@opaopa.org>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33
  34 (require 'elmo-msgdb)
  35 (require 'elmo-net)
  36
  37 (eval-when-compile
  38   (require 'elmo-util))
  39
  40 (eval-and-compile
  41   (autoload 'md5 "md5"))
  42
  43 ;; POP3
  44 (defcustom elmo-pop3-default-user (or (getenv "USER")
  45                                       (getenv "LOGNAME")
  46                                       (user-login-name))
  47   "*Default username for POP3."
  48   :type 'string
  49   :group 'elmo)
  50
  51 (defcustom elmo-pop3-default-server  "localhost"
  52   "*Default POP3 server."
  53   :type 'string
  54   :group 'elmo)
  55
  56 (defcustom elmo-pop3-default-authenticate-type 'user
  57   "*Default Authentication type for POP3."
  58   :type 'symbol
  59   :group 'elmo)
  60
  61 (defcustom elmo-pop3-default-port 110
  62   "*Default POP3 port."
  63   :type 'integer
  64   :group 'elmo)
  65
  66 (defcustom elmo-pop3-default-stream-type nil
  67   "*Default stream type for POP3.
  68 Any symbol value of `elmo-network-stream-type-alist' or
  69 `elmo-pop3-stream-type-alist'."
  70   :type 'symbol
  71   :group 'elmo)
  72
  73 (defcustom elmo-pop3-default-use-uidl t
  74   "If non-nil, use UIDL on POP3."
  75   :type 'boolean
  76   :group 'elmo)
  77
  78 (defvar elmo-pop3-stream-type-alist nil
  79   "*Stream bindings for POP3.
  80 This is taken precedence over `elmo-network-stream-type-alist'.")
  81
  82 (defvar elmo-pop3-use-uidl-internal t
  83   "(Internal switch for using UIDL on POP3).")
  84
  85 (defvar elmo-pop3-use-cache t
  86   "Use cache in pop3 folder.")
  87
  88 (defvar elmo-pop3-send-command-synchronously nil
  89   "If non-nil, commands are send synchronously.
  90 If server doesn't accept asynchronous commands, this variable should be
  91 set as non-nil.")
  92
  93 (defvar elmo-pop3-exists-exactly t)
  94 (defvar sasl-mechanism-alist)
  95
  96 ;;; ELMO POP3 folder
  97 (eval-and-compile
  98   (luna-define-class elmo-pop3-folder (elmo-net-folder)
  99                      (use-uidl location-alist))
 100   (luna-define-internal-accessors 'elmo-pop3-folder))
 101
 102 (luna-define-method elmo-folder-initialize :around ((folder
 103                                                      elmo-pop3-folder)
 104                                                     name)
 105   (let ((elmo-network-stream-type-alist
 106          (if elmo-pop3-stream-type-alist
 107              (append elmo-pop3-stream-type-alist
 108                      elmo-network-stream-type-alist)
 109            elmo-network-stream-type-alist)))
 110     (setq name (luna-call-next-method))
 111     ;; Setup slots for elmo-net-folder
 112     (when (string-match "^\\([^:/!]*\\)\\(/[^/:@!]+\\)?\\(:[^/:@!]+\\)?" name)
 113       (elmo-net-folder-set-user-internal folder
 114                                          (if (match-beginning 1)
 115                                              (elmo-match-string 1 name)))
 116       (if (eq (length (elmo-net-folder-user-internal folder)) 0)
 117           (elmo-net-folder-set-user-internal folder
 118                                              elmo-pop3-default-user))
 119       (elmo-net-folder-set-auth-internal
 120        folder
 121        (if (match-beginning 2)
 122            (intern (elmo-match-substring 2 name 1))
 123          elmo-pop3-default-authenticate-type))
 124       (elmo-pop3-folder-set-use-uidl-internal
 125        folder
 126        (if (match-beginning 3)
 127            (string= (elmo-match-substring 3 name 1) "uidl")
 128          elmo-pop3-default-use-uidl)))
 129     (unless (elmo-net-folder-server-internal folder)
 130       (elmo-net-folder-set-server-internal folder
 131                                            elmo-pop3-default-server))
 132     (unless (elmo-net-folder-port-internal folder)
 133       (elmo-net-folder-set-port-internal folder
 134                                          elmo-pop3-default-port))
 135     (unless (elmo-net-folder-stream-type-internal folder)
 136       (elmo-net-folder-set-stream-type-internal
 137        folder
 138        elmo-pop3-default-stream-type))
 139     folder))
 140
 141 ;;; POP3 session
 142 (luna-define-class elmo-pop3-session (elmo-network-session) ())
 143
 144 ;; buffer-local
 145 (defvar elmo-pop3-read-point nil)
 146 (defvar elmo-pop3-number-uidl-hash nil) ; number -> uidl
 147 (defvar elmo-pop3-uidl-number-hash nil) ; uidl -> number
 148 (defvar elmo-pop3-size-hash nil) ; number -> size
 149 (defvar elmo-pop3-uidl-done nil)
 150 (defvar elmo-pop3-list-done nil)
 151
 152 (defvar elmo-pop3-local-variables '(elmo-pop3-read-point
 153                                     elmo-pop3-uidl-number-hash
 154                                     elmo-pop3-number-uidl-hash
 155                                     elmo-pop3-uidl-done
 156                                     elmo-pop3-size-hash
 157                                     elmo-pop3-list-done))
 158
 159 (luna-define-method elmo-network-close-session ((session elmo-pop3-session))
 160   (when (elmo-network-session-process-internal session)
 161     (when (memq (process-status
 162                  (elmo-network-session-process-internal session))
 163                 '(open run))
 164       (let ((buffer (process-buffer
 165                      (elmo-network-session-process-internal session))))
 166         (elmo-pop3-send-command (elmo-network-session-process-internal session)
 167                                 "quit")
 168         ;; process is dead.
 169         (or (elmo-pop3-read-response
 170              (elmo-network-session-process-internal session)
 171              t buffer)
 172             (error "POP error: QUIT failed"))))
 173     (kill-buffer (process-buffer
 174                   (elmo-network-session-process-internal session)))
 175     (delete-process (elmo-network-session-process-internal session))))
 176
 177 (defun elmo-pop3-get-session (folder &optional if-exists)
 178   (let ((elmo-pop3-use-uidl-internal (if elmo-inhibit-number-mapping
 179                                          nil
 180                                        (elmo-pop3-folder-use-uidl-internal
 181                                         folder))))
 182     (elmo-network-get-session 'elmo-pop3-session "POP3" folder if-exists)))
 183
 184 (defun elmo-pop3-send-command (process command &optional no-erase)
 185   (with-current-buffer (process-buffer process)
 186     (unless no-erase
 187       (erase-buffer))
 188     (goto-char (point-min))
 189     (setq elmo-pop3-read-point (point))
 190     (process-send-string process command)
 191     (process-send-string process "\r\n")))
 192
 193 (defun elmo-pop3-read-response (process &optional not-command buffer)
 194   ;; buffer is in case for process is dead.
 195   (with-current-buffer (or buffer (process-buffer process))
 196     (let ((case-fold-search nil)
 197           (response-string nil)
 198           (response-continue t)
 199           (return-value nil)
 200           match-end)
 201       (while response-continue
 202         (goto-char elmo-pop3-read-point)
 203         (while (not (re-search-forward "\r?\n" nil t))
 204           (accept-process-output process)
 205           (goto-char elmo-pop3-read-point))
 206         (setq match-end (point))
 207         (setq response-string
 208               (buffer-substring elmo-pop3-read-point (- match-end 2)))
 209         (goto-char elmo-pop3-read-point)
 210         (if (looking-at "\\+.*$")
 211             (progn
 212               (setq response-continue nil)
 213               (setq elmo-pop3-read-point match-end)
 214               (setq return-value
 215                     (if return-value
 216                         (concat return-value "\n" response-string)
 217                       response-string)))
 218           (if (looking-at "\\-.*$")
 219               (progn
 220                 (setq response-continue nil)
 221                 (setq elmo-pop3-read-point match-end)
 222                 (setq return-value nil))
 223             (setq elmo-pop3-read-point match-end)
 224             (if not-command
 225                 (setq response-continue nil))
 226             (setq return-value
 227                   (if return-value
 228                       (concat return-value "\n" response-string)
 229                     response-string)))
 230           (setq elmo-pop3-read-point match-end)))
 231       return-value)))
 232
 233 (defun elmo-pop3-process-filter (process output)
 234   (save-excursion
 235     (set-buffer (process-buffer process))
 236     (goto-char (point-max))
 237     (insert output)
 238     (message "Retrieving...(%d bytes)." (buffer-size))))
 239
 240 (defun elmo-pop3-auth-user (session)
 241   (let ((process (elmo-network-session-process-internal session)))
 242     ;; try USER/PASS
 243     (elmo-pop3-send-command
 244      process
 245      (format "user %s" (elmo-network-session-user-internal session)))
 246     (or (elmo-pop3-read-response process t)
 247         (signal 'elmo-authenticate-error
 248                 '(elmo-pop-auth-user)))
 249     (elmo-pop3-send-command  process
 250                              (format
 251                               "pass %s"
 252                               (elmo-get-passwd
 253                                (elmo-network-session-password-key session))))
 254     (or (elmo-pop3-read-response process t)
 255         (signal 'elmo-authenticate-error
 256                 '(elmo-pop-auth-user)))))
 257
 258 (defun elmo-pop3-auth-apop (session)
 259   (if (string-match "^\+OK .*\\(<[^\>]+>\\)"
 260                     (elmo-network-session-greeting-internal session))
 261       ;; good, APOP ready server
 262       (progn
 263         (elmo-pop3-send-command
 264          (elmo-network-session-process-internal session)
 265          (format "apop %s %s"
 266                  (elmo-network-session-user-internal session)
 267                  (md5
 268                   (concat (match-string
 269                            1
 270                            (elmo-network-session-greeting-internal session))
 271                           (elmo-get-passwd
 272                            (elmo-network-session-password-key session))))))
 273         (or (elmo-pop3-read-response
 274              (elmo-network-session-process-internal session)
 275              t)
 276             (signal 'elmo-authenticate-error
 277                     '(elmo-pop3-auth-apop))))
 278     (signal 'elmo-open-error '(elmo-pop3-auth-apop))))
 279
 280 (luna-define-method elmo-network-initialize-session-buffer :after
 281   ((session elmo-pop3-session) buffer)
 282   (with-current-buffer buffer
 283     (mapcar 'make-variable-buffer-local elmo-pop3-local-variables)))
 284
 285 (luna-define-method elmo-network-initialize-session ((session
 286                                                       elmo-pop3-session))
 287   (let ((process (elmo-network-session-process-internal session))
 288         response mechanism)
 289     (with-current-buffer (process-buffer process)
 290       (set-process-filter process 'elmo-pop3-process-filter)
 291       (setq elmo-pop3-read-point (point-min))
 292       ;; Skip garbage output from process before greeting.
 293       (while (and (memq (process-status process) '(open run))
 294                   (goto-char (point-max))
 295                   (forward-line -1)
 296                   (not (looking-at "+OK")))
 297         (accept-process-output process 1))
 298       (setq elmo-pop3-read-point (point))
 299       (or (elmo-network-session-set-greeting-internal
 300            session
 301            (elmo-pop3-read-response process t))
 302           (signal 'elmo-open-error
 303                   '(elmo-network-intialize-session)))
 304       (when (eq (elmo-network-stream-type-symbol
 305                  (elmo-network-session-stream-type-internal session))
 306                 'starttls)
 307         (elmo-pop3-send-command process "stls")
 308         (if (string-match "^\+OK"
 309                           (elmo-pop3-read-response process))
 310             (starttls-negotiate process)
 311           (signal 'elmo-open-error
 312                   '(elmo-pop3-starttls-error)))))))
 313
 314 (luna-define-method elmo-network-authenticate-session ((session
 315                                                         elmo-pop3-session))
 316   (with-current-buffer (process-buffer
 317                         (elmo-network-session-process-internal session))
 318     (let* ((process (elmo-network-session-process-internal session))
 319            (auth (elmo-network-session-auth-internal session))
 320            (auth (mapcar '(lambda (mechanism) (upcase (symbol-name mechanism)))
 321                          (if (listp auth) auth (list auth))))
 322            sasl-mechanisms
 323            client name step response mechanism
 324            sasl-read-passphrase)
 325       (or (and (string= "USER" (car auth))
 326                (elmo-pop3-auth-user session))
 327           (and (string= "APOP" (car auth))
 328                (elmo-pop3-auth-apop session))
 329           (progn
 330             (require 'sasl)
 331             (setq sasl-mechanisms (mapcar 'car sasl-mechanism-alist))
 332             (setq mechanism (sasl-find-mechanism auth))
 333             (unless mechanism
 334               (signal 'elmo-authenticate-error '(elmo-pop3-auth-no-mechanisms)))
 335             (setq client
 336                   (sasl-make-client
 337                    mechanism
 338                    (elmo-network-session-user-internal session)
 339                    "pop"
 340                    (elmo-network-session-server-internal session)))
 341 ;;;         (if elmo-pop3-auth-user-realm
 342 ;;;             (sasl-client-set-property client 'realm elmo-pop3-auth-user-realm))
 343             (setq name (sasl-mechanism-name mechanism))
 344             (elmo-network-session-set-auth-internal session
 345                                                     (intern (downcase name)))
 346             (setq sasl-read-passphrase
 347                   (function
 348                    (lambda (prompt)
 349                      (elmo-get-passwd
 350                       (elmo-network-session-password-key session)))))
 351             (setq step (sasl-next-step client nil))
 352             (elmo-pop3-send-command
 353              process
 354              (concat "AUTH " name
 355                      (and (sasl-step-data step)
 356                           (concat
 357                            " "
 358                            (elmo-base64-encode-string
 359                             (sasl-step-data step) 'no-line-break))))) ;)
 360             (catch 'done
 361               (while t
 362                 (unless (setq response (elmo-pop3-read-response process t))
 363                   ;; response is NO or BAD.
 364                   (signal 'elmo-authenticate-error
 365                           (list (intern
 366                                  (concat "elmo-pop3-auth-"
 367                                          (downcase name))))))
 368                 (if (string-match "^\+OK" response)
 369                     (if (sasl-next-step client step)
 370                         ;; Bogus server?
 371                         (signal 'elmo-authenticate-error
 372                                 (list (intern
 373                                        (concat "elmo-pop3-auth-"
 374                                                (downcase name)))))
 375                       ;; The authentication process is finished.
 376                       (throw 'done nil)))
 377                 (sasl-step-set-data
 378                  step
 379                  (elmo-base64-decode-string
 380                   (cadr (split-string response " "))))
 381                 (setq step (sasl-next-step client step))
 382                 (elmo-pop3-send-command
 383                  process
 384                  (if (sasl-step-data step)
 385                      (elmo-base64-encode-string (sasl-step-data step)
 386                                                 'no-line-break)
 387                    "")))))))))
 388
 389 (luna-define-method elmo-network-setup-session ((session
 390                                                  elmo-pop3-session))
 391   (let ((process (elmo-network-session-process-internal session))
 392         count response)
 393     (with-current-buffer (process-buffer process)
 394       (setq elmo-pop3-size-hash (elmo-make-hash 31))
 395       ;; To get obarray of uidl and size
 396       (elmo-pop3-send-command process "list")
 397       (if (null (elmo-pop3-read-response process))
 398           (error "POP LIST command failed"))
 399       (if (null (setq response
 400                       (elmo-pop3-read-contents
 401                        (current-buffer) process)))
 402           (error "POP LIST command failed"))
 403       ;; POP server always returns a sequence of serial numbers.
 404       (setq count (elmo-pop3-parse-list-response response))
 405       ;; UIDL
 406       (when elmo-pop3-use-uidl-internal
 407         (setq elmo-pop3-uidl-number-hash (elmo-make-hash (* count 2)))
 408         (setq elmo-pop3-number-uidl-hash (elmo-make-hash (* count 2)))
 409         ;; UIDL
 410         (elmo-pop3-send-command process "uidl")
 411         (unless (elmo-pop3-read-response process)
 412           (error "POP UIDL failed"))
 413         (unless (setq response (elmo-pop3-read-contents
 414                                 (current-buffer) process))
 415           (error "POP UIDL failed"))
 416         (elmo-pop3-parse-uidl-response response)))))
 417
 418 (defun elmo-pop3-read-contents (buffer process)
 419   (save-excursion
 420     (set-buffer buffer)
 421     (let ((case-fold-search nil)
 422           match-end)
 423       (goto-char elmo-pop3-read-point)
 424       (while (not (re-search-forward "^\\.\r\n" nil t))
 425         (accept-process-output process)
 426         (goto-char elmo-pop3-read-point))
 427       (setq match-end (point))
 428       (elmo-delete-cr
 429        (buffer-substring elmo-pop3-read-point
 430                          (- match-end 3))))))
 431
 432 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-pop3-folder))
 433   (convert-standard-filename
 434    (expand-file-name
 435     (elmo-safe-filename (elmo-net-folder-user-internal folder))
 436     (expand-file-name (elmo-net-folder-server-internal folder)
 437                       (expand-file-name
 438                        "pop"
 439                        elmo-msgdb-dir)))))
 440
 441 (luna-define-method elmo-folder-exists-p ((folder elmo-pop3-folder))
 442   (if (and elmo-pop3-exists-exactly
 443            (elmo-folder-plugged-p folder))
 444       (save-excursion
 445         (let (elmo-auto-change-plugged  ; don't change plug status.
 446               (elmo-inhibit-number-mapping t) ; No need to use uidl.
 447               session)
 448           (prog1
 449               (setq session (elmo-pop3-get-session folder))
 450             (if session
 451                 (elmo-network-close-session session)))))
 452     t))
 453
 454 (defun elmo-pop3-parse-uidl-response (string)
 455   (let ((buffer (current-buffer))
 456         number list size)
 457     (with-temp-buffer
 458       (let (number uid list)
 459         (insert string)
 460         (goto-char (point-min))
 461         (while (re-search-forward "^\\([0-9]+\\)[\t ]\\([^ \n]+\\)$" nil t)
 462           (setq number  (elmo-match-buffer 1))
 463           (setq uid (elmo-match-buffer 2))
 464           (with-current-buffer buffer
 465             (elmo-set-hash-val uid number elmo-pop3-uidl-number-hash)
 466             (elmo-set-hash-val (concat "#" number) uid
 467                                elmo-pop3-number-uidl-hash))
 468           (setq list (cons uid list)))
 469         (with-current-buffer buffer (setq elmo-pop3-uidl-done t))
 470         (nreverse list)))))
 471
 472 (defun elmo-pop3-parse-list-response (string)
 473   (let ((buffer (current-buffer))
 474         (count 0)
 475         alist)
 476     (with-temp-buffer
 477       (insert string)
 478       (goto-char (point-min))
 479       (while (re-search-forward "^\\([0-9]+\\)[\t ]\\([0-9]+\\)$" nil t)
 480         (setq alist
 481               (cons
 482                (cons (elmo-match-buffer 1)
 483                      (elmo-match-buffer 2))
 484                alist))
 485         (setq count (1+ count)))
 486       (with-current-buffer buffer
 487         (setq elmo-pop3-size-hash (elmo-make-hash (* (length alist) 2)))
 488         (while alist
 489           (elmo-set-hash-val (concat "#" (car (car alist)))
 490                              (cdr (car alist))
 491                              elmo-pop3-size-hash)
 492           (setq alist (cdr alist)))
 493         (setq elmo-pop3-list-done t))
 494       count)))
 495
 496 (defun elmo-pop3-list-location (folder)
 497   (with-current-buffer (process-buffer
 498                         (elmo-network-session-process-internal
 499                          (elmo-pop3-get-session folder)))
 500     (let (list)
 501       (if elmo-pop3-uidl-done
 502           (progn
 503             (mapatoms
 504              (lambda (atom)
 505                (setq list (cons (symbol-name atom) list)))
 506              elmo-pop3-uidl-number-hash)
 507             (nreverse list))
 508         (error "POP3: Error in UIDL")))))
 509
 510 (defun elmo-pop3-list-folder-by-location (folder locations)
 511   (let* ((location-alist (elmo-pop3-folder-location-alist-internal folder))
 512          (locations-in-db (mapcar 'cdr location-alist))
 513          result new-locs new-alist deleted-locs i)
 514     (setq new-locs
 515           (elmo-delete-if (function
 516                            (lambda (x) (member x locations-in-db)))
 517                           locations))
 518     (setq deleted-locs
 519           (elmo-delete-if (function
 520                            (lambda (x) (member x locations)))
 521                           locations-in-db))
 522     (setq i (or (elmo-max-of-list (mapcar 'car location-alist)) 0))
 523     (mapcar
 524      (function
 525       (lambda (x)
 526         (setq location-alist
 527               (delq (rassoc x location-alist) location-alist))))
 528      deleted-locs)
 529     (while new-locs
 530       (setq i (1+ i))
 531       (setq new-alist (cons (cons i (car new-locs)) new-alist))
 532       (setq new-locs (cdr new-locs)))
 533     (setq result (nconc location-alist new-alist))
 534     (setq result (sort result (lambda (x y) (< (car x)(car y)))))
 535     (elmo-pop3-folder-set-location-alist-internal folder result)
 536     (mapcar 'car result)))
 537
 538 (defun elmo-pop3-list-by-uidl-subr (folder &optional nonsort)
 539   (let ((flist (elmo-pop3-list-folder-by-location
 540                 folder
 541                 (elmo-pop3-list-location folder))))
 542     (if nonsort
 543         (cons (elmo-max-of-list flist) (length flist))
 544       (sort flist '<))))
 545
 546 (defun elmo-pop3-list-by-list (folder)
 547   (with-current-buffer (process-buffer
 548                         (elmo-network-session-process-internal
 549                          (elmo-pop3-get-session folder)))
 550     (let (list)
 551       (if elmo-pop3-list-done
 552           (progn
 553             (mapatoms (lambda (atom)
 554                         (setq list (cons (string-to-int
 555                                           (substring (symbol-name atom) 1))
 556                                          list)))
 557                       elmo-pop3-size-hash)
 558             (sort list '<))
 559         (error "POP3: Error in list")))))
 560
 561 (defsubst elmo-pop3-folder-list-messages (folder)
 562   (if (and (not elmo-inhibit-number-mapping)
 563            (elmo-pop3-folder-use-uidl-internal folder))
 564       (elmo-pop3-list-by-uidl-subr folder)
 565     (elmo-pop3-list-by-list folder)))
 566
 567 (luna-define-method elmo-folder-list-messages-internal
 568   ((folder elmo-pop3-folder) &optional nohide)
 569   (elmo-pop3-folder-list-messages folder))
 570
 571 (luna-define-method elmo-folder-status ((folder elmo-pop3-folder))
 572   (elmo-folder-check folder)
 573   (if (elmo-pop3-folder-use-uidl-internal folder)
 574       (elmo-pop3-list-by-uidl-subr folder 'nonsort)
 575     (let* ((process
 576             (elmo-network-session-process-internal
 577              (elmo-pop3-get-session folder)))
 578            (total 0)
 579            response)
 580       (with-current-buffer (process-buffer process)
 581         (elmo-pop3-send-command process "STAT")
 582         (setq response (elmo-pop3-read-response process))
 583         ;; response: "^\+OK 2 7570$"
 584         (if (not (string-match "^\+OK[ \t]*\\([0-9]*\\)" response))
 585             (error "POP STAT command failed")
 586           (setq total
 587                 (string-to-int
 588                  (substring response (match-beginning 1)(match-end 1 ))))
 589           (cons total total))))))
 590
 591 (defvar elmo-pop3-header-fetch-chop-length 200)
 592
 593 (defsubst elmo-pop3-next-result-arrived-p ()
 594   (cond
 595    ((eq (following-char) ?+)
 596     (if (re-search-forward "\n\\.\r?\n" nil t)
 597         t
 598       nil))
 599    ((looking-at "-")
 600     (if (search-forward "\n" nil t)
 601         t
 602       nil))
 603    (t
 604     nil)))
 605
 606 (defun elmo-pop3-retrieve-headers (buffer tobuffer process articles)
 607   (save-excursion
 608     (set-buffer buffer)
 609     (erase-buffer)
 610     (let ((number (length articles))
 611           (count 0)
 612           (received 0)
 613           (last-point (point-min)))
 614       ;; Send HEAD commands.
 615       (while articles
 616         (elmo-pop3-send-command process (format
 617                                          "top %s 0" (car articles))
 618                                 'no-erase)
 619 ;;;     (accept-process-output process 1)
 620         (setq articles (cdr articles))
 621         (setq count (1+ count))
 622         ;; Every 200 requests we have to read the stream in
 623         ;; order to avoid deadlocks.
 624         (when (or elmo-pop3-send-command-synchronously
 625                   (null articles)       ;All requests have been sent.
 626                   (zerop (% count elmo-pop3-header-fetch-chop-length)))
 627           (unless elmo-pop3-send-command-synchronously
 628             (accept-process-output process 1))
 629           (discard-input)
 630           (while (progn
 631                    (set-buffer buffer)
 632                    (goto-char last-point)
 633                    ;; Count replies.
 634                    (while (elmo-pop3-next-result-arrived-p)
 635                      (setq last-point (point))
 636                      (setq received (1+ received)))
 637                    (< received count))
 638             (when (> number elmo-display-progress-threshold)
 639               (if (or (zerop (% received 5)) (= received number))
 640                   (elmo-display-progress
 641                    'elmo-pop3-retrieve-headers "Getting headers..."
 642                    (/ (* received 100) number))))
 643             (accept-process-output process 1)
 644 ;;;         (accept-process-output process)
 645             (discard-input))))
 646       ;; Remove all "\r"'s.
 647       (goto-char (point-min))
 648       (while (search-forward "\r\n" nil t)
 649         (replace-match "\n"))
 650       (copy-to-buffer tobuffer (point-min) (point-max)))))
 651
 652 (luna-define-method elmo-folder-msgdb-create ((folder elmo-pop3-folder)
 653                                               numlist new-mark
 654                                               already-mark seen-mark
 655                                               important-mark seen-list)
 656   (let ((process (elmo-network-session-process-internal
 657                   (elmo-pop3-get-session folder))))
 658     (with-current-buffer (process-buffer process)
 659       (elmo-pop3-sort-msgdb-by-original-number
 660        folder
 661        (elmo-pop3-msgdb-create-by-header
 662         process
 663         numlist
 664         new-mark already-mark
 665         seen-mark seen-list
 666         (if (elmo-pop3-folder-use-uidl-internal folder)
 667             (elmo-pop3-folder-location-alist-internal folder)))))))
 668
 669 (defun elmo-pop3-sort-overview-by-original-number (overview loc-alist)
 670   (if loc-alist
 671       (sort overview
 672             (lambda (ent1 ent2)
 673               (< (elmo-pop3-uidl-to-number
 674                   (cdr (assq (elmo-msgdb-overview-entity-get-number ent1)
 675                              loc-alist)))
 676                  (elmo-pop3-uidl-to-number
 677                   (cdr (assq (elmo-msgdb-overview-entity-get-number ent2)
 678                              loc-alist))))))
 679     overview))
 680
 681 (defun elmo-pop3-sort-msgdb-by-original-number (folder msgdb)
 682   (message "Sorting...")
 683   (let ((overview (elmo-msgdb-get-overview msgdb)))
 684     (current-buffer)
 685     (setq overview (elmo-pop3-sort-overview-by-original-number
 686                     overview
 687                     (elmo-pop3-folder-location-alist-internal folder)))
 688     (message "Sorting...done")
 689     (list overview (nth 1 msgdb)(nth 2 msgdb)(nth 3 msgdb))))
 690
 691 (defun elmo-pop3-uidl-to-number (uidl)
 692   (string-to-number (elmo-get-hash-val uidl
 693                                        elmo-pop3-uidl-number-hash)))
 694
 695 (defun elmo-pop3-number-to-uidl (number)
 696   (elmo-get-hash-val (format "#%d" number)
 697                      elmo-pop3-number-uidl-hash))
 698
 699 (defun elmo-pop3-number-to-size (number)
 700   (elmo-get-hash-val (format "#%d" number)
 701                      elmo-pop3-size-hash))
 702
 703 (defun elmo-pop3-msgdb-create-by-header (process numlist
 704                                                  new-mark already-mark
 705                                                  seen-mark
 706                                                  seen-list
 707                                                  loc-alist)
 708   (let ((tmp-buffer (get-buffer-create " *ELMO Overview TMP*")))
 709     (with-current-buffer (process-buffer process)
 710       (if loc-alist ; use uidl.
 711           (setq numlist
 712                 (delq
 713                  nil
 714                  (mapcar
 715                   (lambda (number)
 716                     (elmo-pop3-uidl-to-number (cdr (assq number loc-alist))))
 717                   numlist))))
 718       (elmo-pop3-retrieve-headers (process-buffer process)
 719                                   tmp-buffer process numlist)
 720       (prog1
 721           (elmo-pop3-msgdb-create-message
 722            tmp-buffer
 723            process
 724            (length numlist)
 725            numlist
 726            new-mark already-mark seen-mark seen-list loc-alist)
 727         (kill-buffer tmp-buffer)))))
 728
 729 (defun elmo-pop3-msgdb-create-message (buffer
 730                                        process
 731                                        num
 732                                        numlist new-mark already-mark
 733                                        seen-mark
 734                                        seen-list
 735                                        loc-alist)
 736   (save-excursion
 737     (let (beg overview number-alist mark-alist
 738               entity i number message-id gmark seen size)
 739       (set-buffer buffer)
 740       (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 741       (goto-char (point-min))
 742       (setq i 0)
 743       (message "Creating msgdb...")
 744       (while (not (eobp))
 745         (setq beg (save-excursion (forward-line 1) (point)))
 746         (elmo-pop3-next-result-arrived-p)
 747         (save-excursion
 748           (forward-line -1)
 749           (save-restriction
 750             (narrow-to-region beg (point))
 751             (setq entity
 752                   (elmo-msgdb-create-overview-from-buffer
 753                    (car numlist)))
 754             (setq numlist (cdr numlist))
 755             (when entity
 756               (setq overview
 757                     (elmo-msgdb-append-element
 758                      overview entity))
 759               (with-current-buffer (process-buffer process)
 760                 (elmo-msgdb-overview-entity-set-size
 761                  entity
 762                  (string-to-number
 763                   (elmo-pop3-number-to-size
 764                    (elmo-msgdb-overview-entity-get-number entity))))
 765                 (if (setq number
 766                           (car
 767                            (rassoc
 768                             (elmo-pop3-number-to-uidl
 769                              (elmo-msgdb-overview-entity-get-number entity))
 770                             loc-alist)))
 771                     (elmo-msgdb-overview-entity-set-number entity number)))
 772               (setq number-alist
 773                     (elmo-msgdb-number-add
 774                      number-alist
 775                      (elmo-msgdb-overview-entity-get-number entity)
 776                      (car entity)))
 777               (setq message-id (car entity))
 778               (setq seen (member message-id seen-list))
 779               (if (setq gmark (or (elmo-msgdb-global-mark-get message-id)
 780                                   (if (elmo-file-cache-status
 781                                        (elmo-file-cache-get message-id))
 782                                       (if seen
 783                                           nil
 784                                         already-mark)
 785                                     (if seen
 786                                         (if elmo-pop3-use-cache
 787                                             seen-mark)
 788                                       new-mark))))
 789                   (setq mark-alist
 790                         (elmo-msgdb-mark-append
 791                          mark-alist
 792                          (elmo-msgdb-overview-entity-get-number entity)
 793                          gmark))))))
 794         (when (> num elmo-display-progress-threshold)
 795           (setq i (1+ i))
 796           (if (or (zerop (% i 5)) (= i num))
 797               (elmo-display-progress
 798                'elmo-pop3-msgdb-create-message "Creating msgdb..."
 799                (/ (* i 100) num)))))
 800       (list overview number-alist mark-alist))))
 801
 802 (defun elmo-pop3-read-body (process outbuf)
 803   (with-current-buffer (process-buffer process)
 804     (let ((start elmo-pop3-read-point)
 805           end)
 806       (goto-char start)
 807       (while (not (re-search-forward "^\\.\r?\n" nil t))
 808         (accept-process-output process)
 809         (goto-char start))
 810       (setq end (point))
 811       (with-current-buffer outbuf
 812         (erase-buffer)
 813         (insert-buffer-substring (process-buffer process) start (- end 3))))))
 814
 815 (luna-define-method elmo-folder-open-internal ((folder elmo-pop3-folder))
 816   (if (and (not elmo-inhibit-number-mapping)
 817            (elmo-pop3-folder-use-uidl-internal folder))
 818       (elmo-pop3-folder-set-location-alist-internal
 819        folder (elmo-msgdb-location-load (elmo-folder-msgdb-path folder)))))
 820
 821 (luna-define-method elmo-folder-commit :after ((folder elmo-pop3-folder))
 822   (when (elmo-folder-persistent-p folder)
 823     (elmo-msgdb-location-save (elmo-folder-msgdb-path folder)
 824                               (elmo-pop3-folder-location-alist-internal
 825                                folder))))
 826
 827 (luna-define-method elmo-folder-close-internal ((folder elmo-pop3-folder))
 828   (elmo-pop3-folder-set-location-alist-internal folder nil)
 829   (elmo-folder-check folder))
 830
 831 (luna-define-method elmo-message-fetch-plugged ((folder elmo-pop3-folder)
 832                                                 number strategy
 833                                                 &optional section
 834                                                 outbuf unseen)
 835   (let* ((loc-alist (elmo-pop3-folder-location-alist-internal folder))
 836          (process (elmo-network-session-process-internal
 837                    (elmo-pop3-get-session folder)))
 838          response errmsg msg)
 839     (with-current-buffer (process-buffer process)
 840       (if loc-alist
 841           (setq number (elmo-pop3-uidl-to-number
 842                         (cdr (assq number loc-alist)))))
 843       (when number
 844         (elmo-pop3-send-command process
 845                                 (format "retr %s" number))
 846         (when (null (setq response (elmo-pop3-read-response
 847                                     process t)))
 848           (error "Fetching message failed"))
 849         (setq response (elmo-pop3-read-body process outbuf))
 850         (set-buffer outbuf)
 851         (goto-char (point-min))
 852         (while (re-search-forward "^\\." nil t)
 853           (replace-match "")
 854           (forward-line))
 855         response))))
 856
 857 (defun elmo-pop3-delete-msg (process number loc-alist)
 858   (with-current-buffer (process-buffer process)
 859     (let (response errmsg msg)
 860       (if loc-alist
 861           (setq number (elmo-pop3-uidl-to-number
 862                         (cdr (assq number loc-alist)))))
 863       (if number
 864           (progn
 865             (elmo-pop3-send-command process
 866                                     (format "dele %s" number))
 867             (when (null (setq response (elmo-pop3-read-response
 868                                         process t)))
 869               (error "Deleting message failed")))
 870         (error "Deleting message failed")))))
 871
 872 (luna-define-method elmo-folder-delete-messages ((folder elmo-pop3-folder)
 873                                                       msgs)
 874   (let ((loc-alist (elmo-pop3-folder-location-alist-internal folder))
 875         (process (elmo-network-session-process-internal
 876                   (elmo-pop3-get-session folder))))
 877     (mapcar '(lambda (msg) (elmo-pop3-delete-msg
 878                             process msg loc-alist))
 879             msgs)))
 880
 881 (luna-define-method elmo-message-use-cache-p ((folder elmo-pop3-folder) number)
 882   elmo-pop3-use-cache)
 883
 884 (luna-define-method elmo-folder-persistent-p ((folder elmo-pop3-folder))
 885   (and (elmo-folder-persistent-internal folder)
 886        (elmo-pop3-folder-use-uidl-internal folder)))
 887
 888
 889 (luna-define-method elmo-folder-check ((folder elmo-pop3-folder))
 890   (if (elmo-folder-plugged-p folder)
 891       (let ((session (elmo-pop3-get-session folder 'if-exists)))
 892         (and session
 893              (elmo-network-close-session session)))))
 894
 895 (require 'product)
 896 (product-provide (provide 'elmo-pop3) (require 'elmo-version))
 897
 898 ;;; elmo-pop3.el ends here