elmo/elmo-pop3.el

   1 ;;; elmo-pop3.el -- POP3 Interface for ELMO.
   2
   3 ;; Copyright 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'elmo-msgdb)
  33 (require 'elmo-net)
  34 (eval-when-compile
  35   (require 'elmo-util)
  36   (condition-case nil
  37       (progn
  38         (require 'starttls)
  39         (require 'sasl))
  40     (error))
  41   (defun-maybe md5 (a))
  42   (defun-maybe sasl-digest-md5-digest-response
  43     (digest-challenge username passwd serv-type host &optional realm))
  44   (defun-maybe sasl-scram-md5-client-msg-1
  45     (authenticate-id &optional authorize-id))
  46   (defun-maybe sasl-scram-md5-client-msg-2
  47     (server-msg-1 client-msg-1 salted-pass))
  48   (defun-maybe sasl-scram-md5-make-salted-pass
  49     (server-msg-1 passphrase))
  50   (defun-maybe sasl-cram-md5 (username passphrase challenge))
  51   (defun-maybe sasl-scram-md5-authenticate-server
  52     (server-msg-1 server-msg-2 client-msg-1 salted-pass))
  53   (defun-maybe starttls-negotiate (a)))
  54 (condition-case nil
  55     (progn
  56       (require 'sasl))
  57   (error))
  58
  59 (defvar elmo-pop3-use-uidl t
  60   "*If non-nil, use UIDL.")
  61
  62 (defvar elmo-pop3-exists-exactly t)
  63
  64 (defvar elmo-pop3-authenticator-alist
  65   '((user        elmo-pop3-auth-user)
  66     (apop        elmo-pop3-auth-apop)
  67     (cram-md5    elmo-pop3-auth-cram-md5)
  68     (scram-md5   elmo-pop3-auth-scram-md5)
  69     (digest-md5  elmo-pop3-auth-digest-md5))
  70   "Definition of authenticators.")
  71
  72 (eval-and-compile
  73   (luna-define-class elmo-pop3-session (elmo-network-session) ()))
  74
  75 ;; buffer-local
  76 (defvar elmo-pop3-read-point nil)
  77 (defvar elmo-pop3-number-uidl-hash nil) ; number -> uidl
  78 (defvar elmo-pop3-uidl-number-hash nil) ; uidl -> number
  79 (defvar elmo-pop3-size-hash nil) ; number -> size
  80 (defvar elmo-pop3-uidl-done nil)
  81 (defvar elmo-pop3-list-done nil)
  82
  83 (defvar elmo-pop3-local-variables '(elmo-pop3-read-point
  84                                     elmo-pop3-uidl-number-hash
  85                                     elmo-pop3-number-uidl-hash
  86                                     elmo-pop3-uidl-done
  87                                     elmo-pop3-size-hash
  88                                     elmo-pop3-list-done))
  89
  90 (luna-define-method elmo-network-close-session ((session elmo-pop3-session))
  91   (unless (memq (process-status
  92                  (elmo-network-session-process-internal session))
  93                 '(closed exit))
  94     (elmo-pop3-send-command (elmo-network-session-process-internal session)
  95                             "quit")
  96     (or (elmo-pop3-read-response
  97          (elmo-network-session-process-internal session) t)
  98         (error "POP error: QUIT failed")))
  99   (kill-buffer (process-buffer
 100                 (elmo-network-session-process-internal session)))
 101   (delete-process (elmo-network-session-process-internal session)))
 102
 103 (defun elmo-pop3-get-session (spec &optional if-exists)
 104   (elmo-network-get-session
 105    'elmo-pop3-session
 106    "POP3"
 107    (elmo-pop3-spec-hostname spec)
 108    (elmo-pop3-spec-port spec)
 109    (elmo-pop3-spec-username spec)
 110    (elmo-pop3-spec-auth spec)
 111    (elmo-pop3-spec-stream-type spec)
 112    if-exists))
 113
 114 (defun elmo-pop3-send-command (process command &optional no-erase)
 115   (with-current-buffer (process-buffer process)
 116     (unless no-erase
 117       (erase-buffer))
 118     (goto-char (point-min))
 119     (setq elmo-pop3-read-point (point))
 120     (process-send-string process command)
 121     (process-send-string process "\r\n")))
 122
 123 (defun elmo-pop3-read-response (process &optional not-command)
 124   (with-current-buffer (process-buffer process)
 125     (let ((case-fold-search nil)
 126           (response-string nil)
 127           (response-continue t)
 128           (return-value nil)
 129           match-end)
 130       (while response-continue
 131         (goto-char elmo-pop3-read-point)
 132         (while (not (re-search-forward "\r?\n" nil t))
 133           (accept-process-output process)
 134           (goto-char elmo-pop3-read-point))
 135         (setq match-end (point))
 136         (setq response-string
 137               (buffer-substring elmo-pop3-read-point (- match-end 2)))
 138         (goto-char elmo-pop3-read-point)
 139         (if (looking-at "\\+.*$")
 140             (progn
 141               (setq response-continue nil)
 142               (setq elmo-pop3-read-point match-end)
 143               (setq return-value
 144                     (if return-value
 145                         (concat return-value "\n" response-string)
 146                       response-string)))
 147           (if (looking-at "\\-.*$")
 148               (progn
 149                 (setq response-continue nil)
 150                 (setq elmo-pop3-read-point match-end)
 151                 (setq return-value nil))
 152             (setq elmo-pop3-read-point match-end)
 153             (if not-command
 154                 (setq response-continue nil))
 155             (setq return-value
 156                   (if return-value
 157                       (concat return-value "\n" response-string)
 158                     response-string)))
 159           (setq elmo-pop3-read-point match-end)))
 160       return-value)))
 161
 162 (defun elmo-pop3-process-filter (process output)
 163   (save-excursion
 164     (set-buffer (process-buffer process))
 165     (goto-char (point-max))
 166     (insert output)))
 167
 168 (defun elmo-pop3-auth-user (session)
 169   (let ((process (elmo-network-session-process-internal session)))
 170     ;; try USER/PASS
 171     (elmo-pop3-send-command
 172      process
 173      (format "user %s" (elmo-network-session-user-internal session)))
 174     (or (elmo-pop3-read-response process t)
 175         (signal 'elmo-authenticate-error
 176                 '(elmo-pop-auth-user)))
 177     (elmo-pop3-send-command  process
 178                              (format
 179                               "pass %s"
 180                               (elmo-get-passwd
 181                                (elmo-network-session-password-key session))))
 182     (or (elmo-pop3-read-response process t)
 183         (signal 'elmo-authenticate-error
 184                 '(elmo-pop-auth-user)))))
 185
 186 (defun elmo-pop3-auth-apop (session)
 187   (if (string-match "^\+OK .*\\(<[^\>]+>\\)"
 188                     (elmo-network-session-greeting-internal session))
 189       ;; good, APOP ready server
 190       (progn
 191         (require 'md5)
 192         (elmo-pop3-send-command
 193          (elmo-network-session-process-internal session)
 194          (format "apop %s %s"
 195                  (elmo-network-session-user-internal session)
 196                  (md5
 197                   (concat (match-string
 198                            1
 199                            (elmo-network-session-greeting-internal session))
 200                           (elmo-get-passwd
 201                            (elmo-network-session-password-key session))))))
 202         (or (elmo-pop3-read-response
 203              (elmo-network-session-process-internal session)
 204              t)
 205             (signal 'elmo-authenticate-error
 206                     '(elmo-pop3-auth-apop))))
 207     (signal 'elmo-open-error '(elmo-pop-auth-user))))
 208
 209 (defun elmo-pop3-auth-cram-md5 (session)
 210   (let ((process (elmo-network-session-process-internal session))
 211         response)
 212     (elmo-pop3-send-command  process "auth cram-md5")
 213     (or (setq response
 214               (elmo-pop3-read-response process t))
 215         (signal 'elmo-open-error '(elmo-pop-auth-cram-md5)))
 216     (elmo-pop3-send-command
 217      process
 218      (elmo-base64-encode-string
 219       (sasl-cram-md5 (elmo-network-session-user-internal session)
 220                      (elmo-get-passwd
 221                       (elmo-network-session-password-key session))
 222                      (elmo-base64-decode-string
 223                       (cadr (split-string response " "))))))
 224     (or (elmo-pop3-read-response process t)
 225         (signal 'elmo-authenticate-error
 226                 '(elmo-pop-auth-cram-md5)))))
 227
 228 (defun elmo-pop3-auth-scram-md5 (session)
 229   (let ((process (elmo-network-session-process-internal session))
 230         server-msg-1 server-msg-2 client-msg-1 client-msg-2
 231         salted-pass response)
 232     (elmo-pop3-send-command
 233      process
 234      (format "auth scram-md5 %s"
 235              (elmo-base64-encode-string
 236               (setq client-msg-1
 237                     (sasl-scram-md5-client-msg-1
 238                      (elmo-network-session-user-internal session))))))
 239     (or (elmo-pop3-read-response process t)
 240         (signal 'elmo-open-error '(elmo-pop-auth-scram-md5)))
 241     (setq server-msg-1
 242           (elmo-base64-decode-string (cadr (split-string response " "))))
 243     (elmo-pop3-send-command
 244      process
 245      (elmo-base64-encode-string
 246       (sasl-scram-md5-client-msg-2
 247        server-msg-1
 248        client-msg-1
 249        (setq salted-pass
 250              (sasl-scram-md5-make-salted-pass
 251               server-msg-1
 252               (elmo-get-passwd
 253                (elmo-network-session-password-key session)))))))
 254     (or (setq response (elmo-pop3-read-response process t))
 255         (signal 'elmo-authenticate-error
 256                 '(elmo-pop-auth-scram-md5)))
 257     (setq server-msg-2 (elmo-base64-decode-string
 258                         (cadr (split-string response " "))))
 259     (or (sasl-scram-md5-authenticate-server server-msg-1
 260                                             server-msg-2
 261                                             client-msg-1
 262                                             salted-pass)
 263         (signal 'elmo-authenticate-error
 264                 '(elmo-pop-auth-scram-md5)))
 265     (elmo-pop3-send-command process "")
 266     (or (setq response (elmo-pop3-read-response process t))
 267         (signal 'elmo-authenticate-error
 268                 '(elmo-pop-auth-scram-md5)))))
 269
 270 (defun elmo-pop3-auth-digest-md5 (session)
 271   (let ((process (elmo-network-session-process-internal session))
 272         response)
 273     (elmo-pop3-send-command process "auth digest-md5")
 274     (or (setq response
 275               (elmo-pop3-read-response process t))
 276         (signal 'elmo-open-error
 277                 '(elmo-pop-auth-digest-md5)))
 278     (elmo-pop3-send-command
 279      process
 280      (elmo-base64-encode-string
 281       (sasl-digest-md5-digest-response
 282        (elmo-base64-decode-string
 283         (cadr (split-string response " ")))
 284        (elmo-network-session-user-internal session)
 285        (elmo-get-passwd
 286         (elmo-network-session-password-key session))
 287        "pop"
 288        (elmo-network-session-host-internal session))
 289       'no-line-break))
 290     (or (elmo-pop3-read-response process t)
 291         (signal 'elmo-authenticate-error
 292                 '(elmo-pop-auth-digest-md5)))
 293     (elmo-pop3-send-command process "")
 294     (or (elmo-pop3-read-response process t)
 295         (signal 'elmo-open-error
 296                 '(elmo-pop-auth-digest-md5)))))
 297
 298 (luna-define-method elmo-network-initialize-session-buffer :after
 299   ((session elmo-pop3-session) buffer)
 300   (with-current-buffer buffer
 301     (mapcar 'make-variable-buffer-local elmo-pop3-local-variables)))
 302
 303 (luna-define-method elmo-network-initialize-session ((session
 304                                                       elmo-pop3-session))
 305   (let ((process (elmo-network-session-process-internal session))
 306         response capability mechanism)
 307     (with-current-buffer (process-buffer process)
 308       (set-process-filter process 'elmo-pop3-process-filter)
 309       (setq elmo-pop3-read-point (point-min))
 310       (or (elmo-network-session-set-greeting-internal
 311            session
 312            (elmo-pop3-read-response process t))
 313           (signal 'elmo-open-error
 314                   '(elmo-network-intialize-session)))
 315       (when (eq (elmo-network-stream-type-symbol
 316                  (elmo-network-session-stream-type-internal session))
 317                 'starttls)
 318         (elmo-pop3-send-command process "stls")
 319         (if (string-match "^\+OK"
 320                           (elmo-pop3-read-response process))
 321             (starttls-negotiate process)
 322           (signal 'elmo-open-error
 323                   '(elmo-network-intialize-session)))))))
 324
 325 (luna-define-method elmo-network-authenticate-session ((session
 326                                                         elmo-pop3-session))
 327   (let (authenticator)
 328     ;; defaults to 'user.
 329     (unless (elmo-network-session-auth-internal session)
 330       (elmo-network-session-set-auth-internal session 'user))
 331     (setq authenticator
 332           (nth 1 (assq (elmo-network-session-auth-internal session)
 333                        elmo-pop3-authenticator-alist)))
 334     (unless authenticator (error "There's no authenticator for %s"
 335                                  (elmo-network-session-auth-internal session)))
 336     (funcall authenticator session)))
 337
 338 (luna-define-method elmo-network-setup-session ((session
 339                                                  elmo-pop3-session))
 340   (let ((process (elmo-network-session-process-internal session))
 341         response)
 342     (with-current-buffer (process-buffer process)
 343       (setq elmo-pop3-size-hash (make-vector 31 0))
 344       ;; To get obarray of uidl and size
 345       (elmo-pop3-send-command process "list")
 346       (if (null (elmo-pop3-read-response process))
 347           (error "POP List folder failed"))
 348       (if (null (setq response
 349                       (elmo-pop3-read-contents
 350                        (current-buffer) process)))
 351           (error "POP List folder failed"))
 352       ;; POP server always returns a sequence of serial numbers.
 353       (elmo-pop3-parse-list-response response)
 354       ;; UIDL
 355       (when elmo-pop3-use-uidl
 356         (setq elmo-pop3-uidl-number-hash (make-vector 31 0))
 357         (setq elmo-pop3-number-uidl-hash (make-vector 31 0))
 358         ;; UIDL
 359         (elmo-pop3-send-command process "uidl")
 360         (unless (elmo-pop3-read-response process)
 361           (error "UIDL failed."))
 362         (unless (setq response (elmo-pop3-read-contents
 363                                 (current-buffer) process))
 364           (error "UIDL failed."))
 365         (elmo-pop3-parse-uidl-response response)))))
 366
 367 (defun elmo-pop3-read-contents (buffer process)
 368   (save-excursion
 369     (set-buffer buffer)
 370     (let ((case-fold-search nil)
 371           match-end)
 372       (goto-char elmo-pop3-read-point)
 373       (while (not (re-search-forward "^\\.\r\n" nil t))
 374         (accept-process-output process)
 375         (goto-char elmo-pop3-read-point))
 376       (setq match-end (point))
 377       (elmo-delete-cr
 378        (buffer-substring elmo-pop3-read-point
 379                          (- match-end 3))))))
 380
 381 ;; dummy functions
 382 (defun elmo-pop3-list-folders (spec &optional hierarchy) nil)
 383 (defun elmo-pop3-append-msg (spec string) nil nil)
 384 (defun elmo-pop3-folder-creatable-p (spec) nil)
 385 (defun elmo-pop3-create-folder (spec) nil)
 386
 387 (defun elmo-pop3-folder-exists-p (spec)
 388   (if (and elmo-pop3-exists-exactly
 389            (elmo-pop3-plugged-p spec))
 390       (save-excursion
 391         (let (elmo-auto-change-plugged ; don't change plug status.
 392               session)
 393           (condition-case nil
 394               (prog1
 395                   (setq session (elmo-pop3-get-session spec))
 396                 (if session
 397                     (elmo-network-close-session session)))
 398             (error nil))))
 399     t))
 400
 401 (defun elmo-pop3-parse-uidl-response (string)
 402   (let ((buffer (current-buffer))
 403         number list size)
 404     (with-temp-buffer
 405       (let (number uid list)
 406         (insert string)
 407         (goto-char (point-min))
 408         (while (re-search-forward "^\\([0-9]+\\)[\t ]\\([^ \n]+\\)$" nil t)
 409           (setq number  (elmo-match-buffer 1))
 410           (setq uid (elmo-match-buffer 2))
 411           (with-current-buffer buffer
 412             (elmo-set-hash-val uid number elmo-pop3-uidl-number-hash)
 413             (elmo-set-hash-val (concat "#" number) uid
 414                                elmo-pop3-number-uidl-hash))
 415           (setq list (cons uid list)))
 416         (with-current-buffer buffer (setq elmo-pop3-uidl-done t))
 417         (nreverse list)))))
 418
 419 (defun elmo-pop3-parse-list-response (string)
 420   (let ((buffer (current-buffer))
 421         number list size)
 422     (with-temp-buffer
 423       (insert string)
 424       (goto-char (point-min))
 425       (while (re-search-forward "^\\([0-9]+\\)[\t ]\\([0-9]+\\)$" nil t)
 426         (setq list
 427               (cons
 428                (string-to-int (setq number (elmo-match-buffer 1)))
 429                list))
 430         (setq size (elmo-match-buffer 2))
 431         (with-current-buffer buffer
 432           (elmo-set-hash-val (concat "#" number)
 433                              size
 434                              elmo-pop3-size-hash)))
 435       (with-current-buffer buffer (setq elmo-pop3-list-done t))
 436       (nreverse list))))
 437
 438 (defun elmo-pop3-list-location (spec)
 439   (with-current-buffer (process-buffer
 440                         (elmo-network-session-process-internal
 441                          (elmo-pop3-get-session spec)))
 442     (let (list)
 443       (if elmo-pop3-uidl-done
 444           (progn
 445             (mapatoms
 446              (lambda (atom)
 447                (setq list (cons (symbol-name atom) list)))
 448              elmo-pop3-uidl-number-hash)
 449             (nreverse list))
 450         (error "POP3: Error in UIDL")))))
 451
 452 (defun elmo-pop3-list-by-uidl-subr (spec &optional nonsort)
 453   (let ((flist (elmo-list-folder-by-location
 454                 spec
 455                 (elmo-pop3-list-location spec))))
 456     (if nonsort
 457         (cons (elmo-max-of-list flist) (length flist))
 458       (sort flist '<))))
 459
 460 (defun elmo-pop3-list-by-list (spec)
 461   (with-current-buffer (process-buffer
 462                         (elmo-network-session-process-internal
 463                          (elmo-pop3-get-session spec)))
 464     (let (list)
 465       (if elmo-pop3-list-done
 466           (progn
 467             (mapatoms (lambda (atom)
 468                         (setq list (cons (string-to-int
 469                                           (substring (symbol-name atom) 1))
 470                                          list)))
 471                       elmo-pop3-size-hash)
 472             (sort list '<))
 473         (error "POP3: Error in list")))))
 474
 475 (defun elmo-pop3-list-folder (spec)
 476   (let ((killed (and elmo-use-killed-list
 477                      (elmo-msgdb-killed-list-load
 478                       (elmo-msgdb-expand-path nil spec))))
 479         numbers)
 480     (elmo-pop3-commit spec)
 481     (setq numbers (if elmo-pop3-use-uidl
 482                       (progn
 483                         (elmo-pop3-list-by-uidl-subr spec))
 484                     (elmo-pop3-list-by-list spec)))
 485     (if killed
 486         (delq nil
 487               (mapcar (lambda (number)
 488                         (unless (memq number killed) number))
 489                       numbers))
 490       numbers)))
 491
 492 (defun elmo-pop3-max-of-folder (spec)
 493   (elmo-pop3-commit spec)
 494   (if elmo-pop3-use-uidl
 495       (elmo-pop3-list-by-uidl-subr spec 'nonsort)
 496     (let* ((process
 497             (elmo-network-session-process-internal
 498              (elmo-pop3-get-session spec)))
 499            (total 0)
 500            response)
 501       (with-current-buffer (process-buffer process)
 502         (elmo-pop3-send-command process "STAT")
 503         (setq response (elmo-pop3-read-response process))
 504         ;; response: "^\+OK 2 7570$"
 505         (if (not (string-match "^\+OK[ \t]*\\([0-9]*\\)" response))
 506             (error "POP STAT command failed")
 507           (setq total
 508                 (string-to-int
 509                  (substring response (match-beginning 1)(match-end 1 ))))
 510           (cons total total))))))
 511
 512 (defvar elmo-pop3-header-fetch-chop-length 200)
 513
 514 (defsubst elmo-pop3-next-result-arrived-p ()
 515   (cond
 516    ((eq (following-char) ?+)
 517     (if (re-search-forward "\n\\.\r?\n" nil t)
 518         t
 519       nil))
 520    ((looking-at "-")
 521     (if (search-forward "\n" nil t)
 522         t
 523       nil))
 524    (t
 525     nil)))
 526
 527 (defun elmo-pop3-retrieve-headers (buffer tobuffer process articles)
 528   (save-excursion
 529     (set-buffer buffer)
 530     (erase-buffer)
 531     (let ((number (length articles))
 532           (count 0)
 533           (received 0)
 534           (last-point (point-min)))
 535       ;; Send HEAD commands.
 536       (while articles
 537         (elmo-pop3-send-command process (format
 538                                          "top %s 0" (car articles))
 539                                 'no-erase)
 540         ;; (accept-process-output process 1)
 541         (setq articles (cdr articles))
 542         (setq count (1+ count))
 543         ;; Every 200 requests we have to read the stream in
 544         ;; order to avoid deadlocks.
 545         (when (or elmo-pop3-send-command-synchronously
 546                   (null articles)       ;All requests have been sent.
 547                   (zerop (% count elmo-pop3-header-fetch-chop-length)))
 548           (unless elmo-pop3-send-command-synchronously
 549             (accept-process-output process 1))
 550           (discard-input)
 551           (while (progn
 552                    (set-buffer buffer)
 553                    (goto-char last-point)
 554                    ;; Count replies.
 555                    (while (elmo-pop3-next-result-arrived-p)
 556                      (setq last-point (point))
 557                      (setq received (1+ received)))
 558                    (< received count))
 559             (when (> number elmo-display-progress-threshold)
 560               (if (or (zerop (% received 5)) (= received number))
 561                   (elmo-display-progress
 562                    'elmo-pop3-retrieve-headers "Getting headers..."
 563                    (/ (* received 100) number))))
 564             (accept-process-output process 1)
 565             ;(accept-process-output process)
 566             (discard-input))))
 567       ;; Remove all "\r"'s.
 568       (goto-char (point-min))
 569       (while (search-forward "\r\n" nil t)
 570         (replace-match "\n"))
 571       (copy-to-buffer tobuffer (point-min) (point-max)))))
 572
 573 (defalias 'elmo-pop3-msgdb-create 'elmo-pop3-msgdb-create-as-numlist)
 574
 575 (defun elmo-pop3-msgdb-create-as-numlist (spec numlist new-mark
 576                                                already-mark seen-mark
 577                                                important-mark seen-list
 578                                                &optional msgdb)
 579   (when numlist
 580     (let ((process (elmo-network-session-process-internal
 581                     (elmo-pop3-get-session spec)))
 582           loc-alist)
 583       (if elmo-pop3-use-uidl
 584           (setq loc-alist (if msgdb (elmo-msgdb-get-location msgdb)
 585                             (elmo-msgdb-location-load
 586                              (elmo-msgdb-expand-path nil spec)))))
 587       (elmo-pop3-msgdb-create-by-header process numlist
 588                                         new-mark already-mark
 589                                         seen-mark seen-list
 590                                         loc-alist))))
 591
 592 (defun elmo-pop3-uidl-to-number (uidl)
 593   (string-to-number (elmo-get-hash-val uidl
 594                                        elmo-pop3-uidl-number-hash)))
 595
 596 (defun elmo-pop3-number-to-uidl (number)
 597   (elmo-get-hash-val (format "#%d" number)
 598                      elmo-pop3-number-uidl-hash))
 599
 600 (defun elmo-pop3-number-to-size (number)
 601   (elmo-get-hash-val (format "#%d" number)
 602                      elmo-pop3-size-hash))
 603
 604 (defun elmo-pop3-msgdb-create-by-header (process numlist
 605                                                  new-mark already-mark
 606                                                  seen-mark
 607                                                  seen-list
 608                                                  loc-alist)
 609   (let ((tmp-buffer (get-buffer-create " *ELMO Overview TMP*")))
 610     (with-current-buffer (process-buffer process)
 611       (if loc-alist ; use uidl.
 612           (setq numlist
 613                 (delq
 614                  nil
 615                  (mapcar
 616                   (lambda (number)
 617                     (elmo-pop3-uidl-to-number (cdr (assq number loc-alist))))
 618                   numlist))))
 619       (elmo-pop3-retrieve-headers (process-buffer process)
 620                                   tmp-buffer process numlist)
 621       (prog1
 622           (elmo-pop3-msgdb-create-message
 623            tmp-buffer
 624            process
 625            (length numlist)
 626            numlist
 627            new-mark already-mark seen-mark seen-list loc-alist)
 628         (kill-buffer tmp-buffer)))))
 629
 630 (defun elmo-pop3-msgdb-create-message (buffer
 631                                        process
 632                                        num
 633                                        numlist new-mark already-mark
 634                                        seen-mark
 635                                        seen-list
 636                                        loc-alist)
 637   (save-excursion
 638     (let (beg overview number-alist mark-alist
 639               entity i number message-id gmark seen size)
 640       (set-buffer buffer)
 641       (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 642       (goto-char (point-min))
 643       (setq i 0)
 644       (message "Creating msgdb...")
 645       (while (not (eobp))
 646         (setq beg (save-excursion (forward-line 1) (point)))
 647         (elmo-pop3-next-result-arrived-p)
 648         (save-excursion
 649           (forward-line -1)
 650           (save-restriction
 651             (narrow-to-region beg (point))
 652             (setq entity
 653                   (elmo-msgdb-create-overview-from-buffer
 654                    (car numlist)))
 655             (setq numlist (cdr numlist))
 656             (when entity
 657               (setq overview
 658                     (elmo-msgdb-append-element
 659                      overview entity))
 660               (with-current-buffer (process-buffer process)
 661                 (elmo-msgdb-overview-entity-set-size
 662                  entity
 663                  (string-to-number
 664                   (elmo-pop3-number-to-size
 665                    (elmo-msgdb-overview-entity-get-number entity))))
 666                 (if (setq number
 667                           (car
 668                            (rassoc
 669                             (elmo-pop3-number-to-uidl
 670                              (elmo-msgdb-overview-entity-get-number entity))
 671                             loc-alist)))
 672                     (elmo-msgdb-overview-entity-set-number entity number)))
 673               (setq number-alist
 674                     (elmo-msgdb-number-add
 675                      number-alist
 676                      (elmo-msgdb-overview-entity-get-number entity)
 677                      (car entity)))
 678               (setq message-id (car entity))
 679               (setq seen (member message-id seen-list))
 680               (if (setq gmark (or (elmo-msgdb-global-mark-get message-id)
 681                                   (if (elmo-cache-exists-p
 682                                        message-id) ; XXX
 683                                       (if seen
 684                                           nil
 685                                         already-mark)
 686                                     (if seen
 687                                         (if elmo-pop3-use-cache
 688                                             seen-mark)
 689                                       new-mark))))
 690                   (setq mark-alist
 691                         (elmo-msgdb-mark-append
 692                          mark-alist
 693                          (elmo-msgdb-overview-entity-get-number entity)
 694                          gmark))))))
 695         (when (> num elmo-display-progress-threshold)
 696           (setq i (1+ i))
 697           (if (or (zerop (% i 5)) (= i num))
 698               (elmo-display-progress
 699                'elmo-pop3-msgdb-create-message "Creating msgdb..."
 700                (/ (* i 100) num)))))
 701       (list overview number-alist mark-alist loc-alist))))
 702
 703 (defun elmo-pop3-read-body (process outbuf)
 704   (with-current-buffer (process-buffer process)
 705     (let ((start elmo-pop3-read-point)
 706           end)
 707       (goto-char start)
 708       (while (not (re-search-forward "^\\.\r?\n" nil t))
 709         (accept-process-output process)
 710         (goto-char start))
 711       (setq end (point))
 712       (with-current-buffer outbuf
 713         (erase-buffer)
 714         (insert-buffer-substring (process-buffer process) start (- end 3))
 715         (elmo-delete-cr-get-content-type)))))
 716
 717 (defun elmo-pop3-read-msg (spec number outbuf &optional msgdb)
 718   (let* ((loc-alist (if elmo-pop3-use-uidl
 719                         (if msgdb
 720                             (elmo-msgdb-get-location msgdb)
 721                           (elmo-msgdb-location-load
 722                            (elmo-msgdb-expand-path nil spec)))))
 723          (process (elmo-network-session-process-internal
 724                    (elmo-pop3-get-session spec)))
 725          response errmsg msg)
 726     (with-current-buffer (process-buffer process)
 727       (if loc-alist
 728           (setq number (elmo-pop3-uidl-to-number
 729                         (cdr (assq number loc-alist)))))
 730       (when number
 731         (elmo-pop3-send-command process
 732                                 (format "retr %s" number))
 733         (when (null (setq response (elmo-pop3-read-response
 734                                     process t)))
 735           (error "Fetching message failed"))
 736         (setq response (elmo-pop3-read-body process outbuf))
 737         (set-buffer outbuf)
 738         (goto-char (point-min))
 739         (while (re-search-forward "^\\." nil t)
 740           (replace-match "")
 741           (forward-line))
 742         response))))
 743
 744 (defun elmo-pop3-delete-msg (process number loc-alist)
 745   (with-current-buffer (process-buffer process)
 746     (let (response errmsg msg)
 747       (if loc-alist
 748           (setq number (elmo-pop3-uidl-to-number
 749                         (cdr (assq number loc-alist)))))
 750       (if number
 751           (progn
 752             (elmo-pop3-send-command process
 753                                     (format "dele %s" number))
 754             (when (null (setq response (elmo-pop3-read-response
 755                                         process t)))
 756               (error "Deleting message failed")))
 757         (error "Deleting message failed")))))
 758
 759 (defun elmo-pop3-delete-msgs (spec msgs &optional msgdb)
 760   (let ((loc-alist (if elmo-pop3-use-uidl
 761                        (if msgdb
 762                            (elmo-msgdb-get-location msgdb)
 763                          (elmo-msgdb-location-load
 764                           (elmo-msgdb-expand-path nil spec)))))
 765         (process (elmo-network-session-process-internal
 766                   (elmo-pop3-get-session spec))))
 767     (mapcar '(lambda (msg) (elmo-pop3-delete-msg
 768                             process msg loc-alist))
 769             msgs)))
 770
 771 (defun elmo-pop3-search (spec condition &optional numlist)
 772   (error "Searching in pop3 folder is not implemented yet"))
 773
 774 (defun elmo-pop3-use-cache-p (spec number)
 775   elmo-pop3-use-cache)
 776
 777 (defun elmo-pop3-local-file-p (spec number)
 778   nil)
 779
 780 (defun elmo-pop3-port-label (spec)
 781   (concat "pop3"
 782           (if (elmo-pop3-spec-stream-type spec)
 783               (concat "!" (symbol-name
 784                            (elmo-network-stream-type-symbol
 785                             (elmo-pop3-spec-stream-type spec)))))))
 786
 787 (defsubst elmo-pop3-portinfo (spec)
 788   (list (elmo-pop3-spec-hostname spec)
 789         (elmo-pop3-spec-port spec)))
 790
 791 (defun elmo-pop3-plugged-p (spec)
 792   (apply 'elmo-plugged-p
 793          (append (elmo-pop3-portinfo spec)
 794                  (list nil (quote (elmo-pop3-port-label spec))))))
 795
 796 (defun elmo-pop3-set-plugged (spec plugged add)
 797   (apply 'elmo-set-plugged plugged
 798          (append (elmo-pop3-portinfo spec)
 799                  (list nil nil (quote (elmo-pop3-port-label spec)) add))))
 800
 801 (defalias 'elmo-pop3-sync-number-alist
 802   'elmo-generic-sync-number-alist)
 803 (defalias 'elmo-pop3-list-folder-unread
 804   'elmo-generic-list-folder-unread)
 805 (defalias 'elmo-pop3-list-folder-important
 806   'elmo-generic-list-folder-important)
 807
 808 (defun elmo-pop3-commit (spec)
 809   (if (elmo-pop3-plugged-p spec)
 810       (let ((session (elmo-pop3-get-session spec 'if-exists)))
 811         (and session
 812              (elmo-network-close-session session)))))
 813
 814
 815 (provide 'elmo-pop3)
 816
 817 ;;; elmo-pop3.el ends here