elmo/elmo-pop3.el

   1 ;;; elmo-pop3.el --- POP3 Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1999,2000      Kenichi OKADA <okada@opaopa.org>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Kenichi OKADA <okada@opaopa.org>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33
  34 (require 'elmo-msgdb)
  35 (require 'elmo-net)
  36
  37 (eval-when-compile
  38   (require 'elmo-util))
  39
  40 (eval-and-compile
  41   (autoload 'md5 "md5"))
  42
  43 (defcustom elmo-pop3-default-use-uidl t
  44   "If non-nil, use UIDL on POP3."
  45   :type 'boolean
  46   :group 'elmo)
  47
  48 (defvar elmo-pop3-use-uidl-internal t
  49   "(Internal switch for using UIDL on POP3).")
  50
  51 (defvar elmo-pop3-use-cache t
  52   "Use cache in pop3 folder.")
  53
  54 (defvar elmo-pop3-send-command-synchronously nil
  55   "If non-nil, commands are send synchronously.
  56 If server doesn't accept asynchronous commands, this variable should be
  57 set as non-nil.")
  58
  59 (defcustom elmo-pop3-exists-exactly nil
  60   "If non-nil, POP3 folder existence is checked everytime before the session."
  61   :type 'boolean
  62   :group 'elmo)
  63
  64 (defvar sasl-mechanism-alist)
  65
  66 (defvar elmo-pop3-total-size nil)
  67
  68 ;; For debugging.
  69 (defvar elmo-pop3-debug nil
  70   "Non-nil forces POP3 folder as debug mode.
  71 Debug information is inserted in the buffer \"*POP3 DEBUG*\"")
  72
  73 ;;; Debug
  74 (defsubst elmo-pop3-debug (message &rest args)
  75   (if elmo-pop3-debug
  76       (let ((biff (string-match "BIFF-" (buffer-name)))
  77             pos)
  78         (with-current-buffer (get-buffer-create (concat "*POP3 DEBUG*"
  79                                                         (if biff "BIFF")))
  80           (goto-char (point-max))
  81           (setq pos (point))
  82           (insert (apply 'format message args) "\n")))))
  83
  84 ;;; ELMO POP3 folder
  85 (eval-and-compile
  86   (luna-define-class elmo-pop3-folder (elmo-net-folder)
  87                      (use-uidl location-alist))
  88   (luna-define-internal-accessors 'elmo-pop3-folder))
  89
  90 (luna-define-method elmo-folder-initialize :around ((folder
  91                                                      elmo-pop3-folder)
  92                                                     name)
  93   (let ((elmo-network-stream-type-alist
  94          (if elmo-pop3-stream-type-alist
  95              (append elmo-pop3-stream-type-alist
  96                      elmo-network-stream-type-alist)
  97            elmo-network-stream-type-alist))
  98         parse)
  99     (setq name (luna-call-next-method))
 100     ;; user
 101     (setq parse (elmo-parse-token name "/:"))
 102     (elmo-net-folder-set-user-internal folder
 103                                        (if (eq (length (car parse)) 0)
 104                                            elmo-pop3-default-user
 105                                          (car parse)))
 106     ;; auth
 107     (setq parse (elmo-parse-prefixed-element ?/ (cdr parse) ":"))
 108     (elmo-net-folder-set-auth-internal folder
 109                                        (if (eq (length (car parse)) 0)
 110                                            elmo-pop3-default-authenticate-type
 111                                          (intern (downcase (car parse)))))
 112     ;; uidl
 113     (setq parse (elmo-parse-prefixed-element ?: (cdr parse)))
 114     (elmo-pop3-folder-set-use-uidl-internal folder
 115                                             (if (eq (length (car parse)) 0)
 116                                                 elmo-pop3-default-use-uidl
 117                                               (string= (car parse) "uidl")))
 118     (unless (elmo-net-folder-server-internal folder)
 119       (elmo-net-folder-set-server-internal folder
 120                                            elmo-pop3-default-server))
 121     (unless (elmo-net-folder-port-internal folder)
 122       (elmo-net-folder-set-port-internal folder
 123                                          elmo-pop3-default-port))
 124     (unless (elmo-net-folder-stream-type-internal folder)
 125       (elmo-net-folder-set-stream-type-internal
 126        folder
 127        (elmo-get-network-stream-type
 128         elmo-pop3-default-stream-type)))
 129     folder))
 130
 131 ;;; POP3 session
 132 (luna-define-class elmo-pop3-session (elmo-network-session) ())
 133
 134 ;; buffer-local
 135 (defvar elmo-pop3-read-point nil)
 136 (defvar elmo-pop3-number-uidl-hash nil) ; number -> uidl
 137 (defvar elmo-pop3-uidl-number-hash nil) ; uidl -> number
 138 (defvar elmo-pop3-size-hash nil) ; number -> size
 139 (defvar elmo-pop3-uidl-done nil)
 140 (defvar elmo-pop3-list-done nil)
 141 (defvar elmo-pop3-lock nil)
 142
 143 (defvar elmo-pop3-local-variables '(elmo-pop3-read-point
 144                                     elmo-pop3-uidl-number-hash
 145                                     elmo-pop3-number-uidl-hash
 146                                     elmo-pop3-uidl-done
 147                                     elmo-pop3-size-hash
 148                                     elmo-pop3-list-done
 149                                     elmo-pop3-lock))
 150
 151 (luna-define-method elmo-network-close-session ((session elmo-pop3-session))
 152   (when (elmo-network-session-process-internal session)
 153     (when (memq (process-status
 154                  (elmo-network-session-process-internal session))
 155                 '(open run))
 156       (elmo-pop3-send-command (elmo-network-session-process-internal session)
 157                               "quit")
 158       ;; process is dead.
 159       (or (cdr (elmo-pop3-read-response
 160                 (elmo-network-session-process-internal session)
 161                 t))
 162           (error "POP error: QUIT failed")))
 163     (kill-buffer (process-buffer
 164                   (elmo-network-session-process-internal session)))
 165     (delete-process (elmo-network-session-process-internal session))))
 166
 167 (defun elmo-pop3-get-session (folder &optional if-exists)
 168   "Get POP3 session for FOLDER.
 169 If IF-EXISTS is non-nil, don't get new session.
 170 If IF-EXISTS is `any-exists', get BIFF session or normal session if exists."
 171   (let ((elmo-pop3-use-uidl-internal (if elmo-inhibit-number-mapping
 172                                          nil
 173                                        (elmo-pop3-folder-use-uidl-internal
 174                                         folder))))
 175     (prog1
 176         (if (eq if-exists 'any-exists)
 177             (or (elmo-network-get-session 'elmo-pop3-session
 178                                           "POP3"
 179                                           folder if-exists)
 180                 (elmo-network-get-session 'elmo-pop3-session
 181                                           "BIFF-POP3"
 182                                           folder if-exists))
 183           (elmo-network-get-session 'elmo-pop3-session
 184                                     (concat
 185                                      (if (elmo-folder-biff-internal folder)
 186                                          "BIFF-")
 187                                      "POP3")
 188                                     folder if-exists))
 189       ;; For saving existency.
 190       (unless (file-exists-p (elmo-folder-msgdb-path folder))
 191         (elmo-make-directory (elmo-folder-msgdb-path folder))))))
 192
 193 (defun elmo-pop3-send-command (process command &optional no-erase no-log)
 194   (with-current-buffer (process-buffer process)
 195     (unless no-erase
 196       (erase-buffer))
 197     (goto-char (point-min))
 198     (setq elmo-pop3-read-point (point))
 199     (elmo-pop3-debug "SEND: %s\n" (if no-log "<NO LOGGING>" command))
 200     (process-send-string process (concat command "\r\n"))))
 201
 202 (defun elmo-pop3-read-response (process &optional not-command)
 203   "Read response and return a cons cell of \(CODE . BODY\).
 204 PROCESS is the process to read response from.
 205 If optional NOT-COMMAND is non-nil, read only the first line.
 206 CODE is one of the following:
 207 'ok          ... response is OK.
 208 'err         ... response is ERROR.
 209 'login-delay ... user is not allowed to login until the login delay
 210                  period has expired.
 211 'in-use      ... authentication was successful but the mailbox is in use."
 212   ;; buffer is in case for process is dead.
 213   (with-current-buffer (process-buffer process)
 214     (let ((case-fold-search nil)
 215           (response-string nil)
 216           (response-continue t)
 217           (return-value nil)
 218           (err nil)
 219           match-end)
 220       (while response-continue
 221         (goto-char elmo-pop3-read-point)
 222         (while (not (re-search-forward "\r?\n" nil t))
 223           (accept-process-output process 1)
 224           (goto-char elmo-pop3-read-point))
 225         (setq match-end (point))
 226         (setq response-string
 227               (buffer-substring elmo-pop3-read-point (- match-end 2)))
 228         (goto-char elmo-pop3-read-point)
 229         (if (looking-at "\\+.*$")
 230             (progn
 231               (setq response-continue nil)
 232               (setq elmo-pop3-read-point match-end)
 233               (setq return-value
 234                     (if return-value
 235                         (concat return-value "\n" response-string)
 236                       response-string)))
 237           (if (looking-at "\\-.*$")
 238               (progn
 239                 (when (looking-at "[^ ]+ \\[\\([^]]+\\)\\]")
 240                   (setq return-value
 241                         (intern
 242                          (downcase
 243                           (buffer-substring (match-beginning 1)
 244                                             (match-end 1))))))
 245                 (setq err t
 246                       response-continue nil
 247                       elmo-pop3-read-point match-end
 248                       return-value (cons (or return-value 'err) nil)))
 249             (setq elmo-pop3-read-point match-end)
 250             (if not-command
 251                 (setq response-continue nil))
 252             (setq return-value
 253                   (if return-value
 254                       (concat return-value "\n" response-string)
 255                     response-string)))
 256           (setq elmo-pop3-read-point match-end)))
 257       (if err
 258           return-value
 259         (cons 'ok return-value)))))
 260
 261 (defun elmo-pop3-process-filter (process output)
 262   (when (buffer-live-p (process-buffer process))
 263     (with-current-buffer (process-buffer process)
 264       (goto-char (point-max))
 265       (insert output)
 266       (elmo-pop3-debug "RECEIVED: %s\n" output)
 267       (if (and elmo-pop3-total-size
 268                (> elmo-pop3-total-size
 269                   (min elmo-display-retrieval-progress-threshold 100)))
 270           (elmo-display-progress
 271            'elmo-display-retrieval-progress
 272            (format "Retrieving (%d/%d bytes)..."
 273                    (buffer-size)
 274                    elmo-pop3-total-size)
 275            (/ (buffer-size) (/ elmo-pop3-total-size 100)))))))
 276
 277 (defun elmo-pop3-auth-user (session)
 278   (let ((process (elmo-network-session-process-internal session))
 279         response)
 280     ;; try USER/PASS
 281     (elmo-pop3-send-command
 282      process
 283      (format "user %s" (elmo-network-session-user-internal session))
 284      nil 'no-log)
 285     (setq response (elmo-pop3-read-response process t))
 286     (unless (eq (car response) 'ok)
 287       (delete-process process)
 288       (signal 'elmo-open-error '(elmo-pop-auth-user)))
 289     (elmo-pop3-send-command  process
 290                              (format
 291                               "pass %s"
 292                               (elmo-get-passwd
 293                                (elmo-network-session-password-key session)))
 294                              nil 'no-log)
 295     (setq response (elmo-pop3-read-response process t))
 296     (unless (eq (car response) 'ok)
 297       (delete-process process)
 298       (unless (eq 'ok (car response))
 299         (if (or (eq (car response) 'in-use)
 300                 (eq (car response) 'login-delay))
 301             (error (cond ((eq (car response) 'in-use)
 302                           "Maildrop is currently in use")
 303                          ((eq (car response) 'login-delay)
 304                           "Not allowed to login \
 305 until the login delay period has expired")))
 306           (signal 'elmo-authenticate-error
 307                   '(elmo-pop-auth-user)))))
 308     (car response)))
 309
 310 (defun elmo-pop3-auth-apop (session)
 311   (if (string-match "^\+OK .*\\(<[^\>]+>\\)"
 312                     (elmo-network-session-greeting-internal session))
 313       ;; good, APOP ready server
 314       (progn
 315         (elmo-pop3-send-command
 316          (elmo-network-session-process-internal session)
 317          (format "apop %s %s"
 318                  (elmo-network-session-user-internal session)
 319                  (md5
 320                   (concat (match-string
 321                            1
 322                            (elmo-network-session-greeting-internal session))
 323                           (elmo-get-passwd
 324                            (elmo-network-session-password-key session)))))
 325          nil 'no-log)
 326         (let ((response (elmo-pop3-read-response
 327                          (elmo-network-session-process-internal session)
 328                          t)))
 329           (unless (eq (car response) 'ok)
 330             (delete-process (elmo-network-session-process-internal session))
 331             (unless (eq 'ok (car response))
 332               (if (or (eq (car response) 'in-use)
 333                       (eq (car response) 'login-delay))
 334                   (error (cond ((eq (car response) 'in-use)
 335                                 "Maildrop is currently in use")
 336                                ((eq (car response) 'login-delay)
 337                                 "Not allowed to login \
 338 until the login delay period has expired")))
 339                 (signal 'elmo-authenticate-error
 340                         '(elmo-pop-auth-apop)))))
 341           (car response)))
 342     (signal 'elmo-open-error '(elmo-pop3-auth-apop))))
 343
 344 (luna-define-method elmo-network-initialize-session-buffer :after
 345   ((session elmo-pop3-session) buffer)
 346   (with-current-buffer buffer
 347     (mapcar 'make-variable-buffer-local elmo-pop3-local-variables)))
 348
 349 (luna-define-method elmo-network-initialize-session ((session
 350                                                       elmo-pop3-session))
 351   (let ((process (elmo-network-session-process-internal session))
 352         response mechanism)
 353     (with-current-buffer (process-buffer process)
 354       (set-process-filter process 'elmo-pop3-process-filter)
 355       (setq elmo-pop3-read-point (point-min))
 356       ;; Skip garbage output from process before greeting.
 357       (while (and (memq (process-status process) '(open run))
 358                   (goto-char (point-max))
 359                   (forward-line -1)
 360                   (not (looking-at "+OK")))
 361         (accept-process-output process 1))
 362       (setq elmo-pop3-read-point (point))
 363       (or (elmo-network-session-set-greeting-internal
 364            session
 365            (cdr (elmo-pop3-read-response process t))) ; if ok, cdr is non-nil.
 366           (signal 'elmo-open-error
 367                   '(elmo-network-intialize-session)))
 368       (when (eq (elmo-network-stream-type-symbol
 369                  (elmo-network-session-stream-type-internal session))
 370                 'starttls)
 371         (elmo-pop3-send-command process "stls")
 372         (if (eq 'ok (car (elmo-pop3-read-response process)))
 373             (starttls-negotiate process)
 374           (signal 'elmo-open-error '(elmo-pop3-starttls-error)))))))
 375
 376 (luna-define-method elmo-network-authenticate-session ((session
 377                                                         elmo-pop3-session))
 378   (with-current-buffer (process-buffer
 379                         (elmo-network-session-process-internal session))
 380     (let* ((process (elmo-network-session-process-internal session))
 381            (auth (elmo-network-session-auth-internal session))
 382            (auth (mapcar '(lambda (mechanism) (upcase (symbol-name mechanism)))
 383                          (if (listp auth) auth (list auth))))
 384            sasl-mechanisms
 385            client name step response mechanism
 386            sasl-read-passphrase)
 387       (or (and (string= "USER" (car auth))
 388                (elmo-pop3-auth-user session))
 389           (and (string= "APOP" (car auth))
 390                (elmo-pop3-auth-apop session))
 391           (progn
 392             (require 'sasl)
 393             (setq sasl-mechanisms (mapcar 'car sasl-mechanism-alist))
 394             (setq mechanism (sasl-find-mechanism auth))
 395             (unless mechanism
 396               (signal 'elmo-authenticate-error '(elmo-pop3-auth-no-mechanisms)))
 397             (setq client
 398                   (sasl-make-client
 399                    mechanism
 400                    (elmo-network-session-user-internal session)
 401                    "pop"
 402                    (elmo-network-session-server-internal session)))
 403 ;;;         (if elmo-pop3-auth-user-realm
 404 ;;;             (sasl-client-set-property client 'realm elmo-pop3-auth-user-realm))
 405             (setq name (sasl-mechanism-name mechanism))
 406             (elmo-network-session-set-auth-internal session
 407                                                     (intern (downcase name)))
 408             (setq sasl-read-passphrase
 409                   (function
 410                    (lambda (prompt)
 411                      (elmo-get-passwd
 412                       (elmo-network-session-password-key session)))))
 413             (setq step (sasl-next-step client nil))
 414             (elmo-pop3-send-command
 415              process
 416              (concat "AUTH " name
 417                      (and (sasl-step-data step)
 418                           (concat
 419                            " "
 420                            (elmo-base64-encode-string
 421                             (sasl-step-data step) 'no-line-break))))
 422              nil 'no-log)
 423             (catch 'done
 424               (while t
 425                 (setq response (elmo-pop3-read-response process t))
 426                 (unless (eq 'ok (car response))
 427                   (if (or (eq (car response) 'in-use)
 428                           (eq (car response) 'login-delay))
 429                       (error (cond ((eq (car response) 'in-use)
 430                                     "Maildrop is currently in use")
 431                                    ((eq (car response) 'login-delay)
 432                                     "Not allowed to login \
 433 until the login delay period has expired")))
 434                     (signal 'elmo-authenticate-error
 435                             (list (intern (concat "elmo-pop3-auth-"
 436                                                   (downcase name)))))))
 437                 (if (sasl-next-step client step)
 438                     ;; Bogus server?
 439                     (signal 'elmo-authenticate-error
 440                             (list (intern
 441                                    (concat "elmo-pop3-auth-"
 442                                            (downcase name)))))
 443                   ;; The authentication process is finished.
 444                   (throw 'done nil))
 445                 (sasl-step-set-data
 446                  step
 447                  (elmo-base64-decode-string
 448                   (cadr (split-string response " "))))
 449                 (setq step (sasl-next-step client step))
 450                 (elmo-pop3-send-command
 451                  process
 452                  (if (sasl-step-data step)
 453                      (elmo-base64-encode-string (sasl-step-data step)
 454                                                 'no-line-break)
 455                    "") nil 'no-log))))))))
 456
 457 (luna-define-method elmo-network-setup-session ((session
 458                                                  elmo-pop3-session))
 459   (let ((process (elmo-network-session-process-internal session))
 460         count response)
 461     (with-current-buffer (process-buffer process)
 462       (setq elmo-pop3-size-hash (elmo-make-hash 31))
 463       ;; To get obarray of uidl and size
 464       (elmo-pop3-send-command process "list")
 465       (if (null (cdr (elmo-pop3-read-response process)))
 466           (error "POP LIST command failed"))
 467       (if (null (setq response
 468                       (elmo-pop3-read-contents process)))
 469           (error "POP LIST command failed"))
 470       ;; POP server always returns a sequence of serial numbers.
 471       (setq count (elmo-pop3-parse-list-response response))
 472       ;; UIDL
 473       (when elmo-pop3-use-uidl-internal
 474         (setq elmo-pop3-uidl-number-hash (elmo-make-hash (* count 2)))
 475         (setq elmo-pop3-number-uidl-hash (elmo-make-hash (* count 2)))
 476         ;; UIDL
 477         (elmo-pop3-send-command process "uidl")
 478         (unless (cdr (elmo-pop3-read-response process))
 479           (error "POP UIDL failed"))
 480         (unless (setq response (elmo-pop3-read-contents process))
 481           (error "POP UIDL failed"))
 482         (elmo-pop3-parse-uidl-response response)))))
 483
 484 (defun elmo-pop3-read-contents (process)
 485   (with-current-buffer (process-buffer process)
 486     (let ((case-fold-search nil)
 487           match-end)
 488       (goto-char elmo-pop3-read-point)
 489       (while (not (re-search-forward "^\\.\r\n" nil t))
 490         (accept-process-output process 1)
 491         (goto-char elmo-pop3-read-point))
 492       (setq match-end (point))
 493       (elmo-delete-cr
 494        (buffer-substring elmo-pop3-read-point
 495                          (- match-end 3))))))
 496
 497 (luna-define-method elmo-folder-expand-msgdb-path ((folder elmo-pop3-folder))
 498   (convert-standard-filename
 499    (expand-file-name
 500     (elmo-safe-filename (elmo-net-folder-user-internal folder))
 501     (expand-file-name (elmo-net-folder-server-internal folder)
 502                       (expand-file-name
 503                        "pop"
 504                        elmo-msgdb-directory)))))
 505
 506 (luna-define-method elmo-folder-exists-p ((folder elmo-pop3-folder))
 507   (if (and elmo-pop3-exists-exactly
 508            (elmo-folder-plugged-p folder))
 509       (save-excursion
 510         (let (elmo-auto-change-plugged  ; don't change plug status.
 511               (elmo-inhibit-number-mapping t) ; No need to use uidl.
 512               session)
 513           (prog1
 514               (setq session (elmo-pop3-get-session folder))
 515             (if session
 516                 (elmo-network-close-session session)))))
 517     (or (file-directory-p (elmo-folder-msgdb-path folder))
 518         ;; First time.
 519         (when (elmo-folder-plugged-p folder)
 520           (let ((elmo-pop3-exists-exactly t))
 521             (elmo-folder-exists-p folder))))))
 522
 523 (defun elmo-pop3-parse-uidl-response (string)
 524   (let ((buffer (current-buffer))
 525         number list size)
 526     (with-temp-buffer
 527       (let (number uid list)
 528         (insert string)
 529         (goto-char (point-min))
 530         (while (re-search-forward "^\\([0-9]+\\)[\t ]+\\([^ \n]+\\)$" nil t)
 531           (setq number  (elmo-match-buffer 1))
 532           (setq uid (elmo-match-buffer 2))
 533           (with-current-buffer buffer
 534             (elmo-set-hash-val uid number elmo-pop3-uidl-number-hash)
 535             (elmo-set-hash-val (concat "#" number) uid
 536                                elmo-pop3-number-uidl-hash))
 537           (setq list (cons uid list)))
 538         (with-current-buffer buffer (setq elmo-pop3-uidl-done t))
 539         (nreverse list)))))
 540
 541 (defun elmo-pop3-parse-list-response (string)
 542   (let ((buffer (current-buffer))
 543         (count 0)
 544         alist)
 545     (with-temp-buffer
 546       (insert string)
 547       (goto-char (point-min))
 548       (while (re-search-forward "^\\([0-9]+\\)[\t ]+\\([0-9]+\\)$" nil t)
 549         (setq alist
 550               (cons
 551                (cons (elmo-match-buffer 1)
 552                      (elmo-match-buffer 2))
 553                alist))
 554         (setq count (1+ count)))
 555       (with-current-buffer buffer
 556         (setq elmo-pop3-size-hash (elmo-make-hash (* (length alist) 2)))
 557         (while alist
 558           (elmo-set-hash-val (concat "#" (car (car alist)))
 559                              (cdr (car alist))
 560                              elmo-pop3-size-hash)
 561           (setq alist (cdr alist)))
 562         (setq elmo-pop3-list-done t))
 563       count)))
 564
 565 (defun elmo-pop3-list-location (folder)
 566   (with-current-buffer (process-buffer
 567                         (elmo-network-session-process-internal
 568                          (elmo-pop3-get-session folder)))
 569     (let (locations)
 570       (if elmo-pop3-uidl-done
 571           (progn
 572             (mapatoms
 573              (lambda (atom)
 574                (setq locations (cons (symbol-name atom) locations)))
 575              elmo-pop3-uidl-number-hash)
 576             (sort locations
 577                   (lambda (loc1 loc2)
 578                     (< (elmo-pop3-uidl-to-number loc1)
 579                        (elmo-pop3-uidl-to-number loc2)))))
 580         (error "POP3: Error in UIDL")))))
 581
 582 (defun elmo-pop3-list-folder-by-location (folder locations)
 583   (let* ((location-alist (elmo-pop3-folder-location-alist-internal folder))
 584          (locations-in-db (mapcar 'cdr location-alist))
 585          result new-locs new-alist deleted-locs i)
 586     (setq new-locs
 587           (elmo-delete-if (function
 588                            (lambda (x) (member x locations-in-db)))
 589                           locations))
 590     (setq deleted-locs
 591           (elmo-delete-if (function
 592                            (lambda (x) (member x locations)))
 593                           locations-in-db))
 594     (setq i (or (elmo-max-of-list (mapcar 'car location-alist)) 0))
 595     (mapcar
 596      (function
 597       (lambda (x)
 598         (setq location-alist
 599               (delq (rassoc x location-alist) location-alist))))
 600      deleted-locs)
 601     (while new-locs
 602       (setq i (1+ i))
 603       (setq new-alist (cons (cons i (car new-locs)) new-alist))
 604       (setq new-locs (cdr new-locs)))
 605     (setq result (nconc location-alist new-alist))
 606     (setq result (sort result (lambda (x y) (< (car x)(car y)))))
 607     (elmo-pop3-folder-set-location-alist-internal folder result)
 608     (mapcar 'car result)))
 609
 610 (defun elmo-pop3-list-by-uidl-subr (folder &optional nonsort)
 611   (let ((flist (elmo-pop3-list-folder-by-location
 612                 folder
 613                 (elmo-pop3-list-location folder))))
 614     (if nonsort
 615         (cons (elmo-max-of-list flist) (length flist))
 616       (sort flist '<))))
 617
 618 (defun elmo-pop3-list-by-list (folder)
 619   (with-current-buffer (process-buffer
 620                         (elmo-network-session-process-internal
 621                          (elmo-pop3-get-session folder)))
 622     (let (list)
 623       (if elmo-pop3-list-done
 624           (progn
 625             (mapatoms (lambda (atom)
 626                         (setq list (cons (string-to-int
 627                                           (substring (symbol-name atom) 1))
 628                                          list)))
 629                       elmo-pop3-size-hash)
 630             (sort list '<))
 631         (error "POP3: Error in list")))))
 632
 633 (defsubst elmo-pop3-folder-list-messages (folder)
 634   (if (and (not elmo-inhibit-number-mapping)
 635            (elmo-pop3-folder-use-uidl-internal folder))
 636       (elmo-pop3-list-by-uidl-subr folder)
 637     (elmo-pop3-list-by-list folder)))
 638
 639 (luna-define-method elmo-folder-list-messages-plugged
 640   ((folder elmo-pop3-folder) &optional nohide)
 641   (elmo-pop3-folder-list-messages folder))
 642
 643 (luna-define-method elmo-folder-status ((folder elmo-pop3-folder))
 644   (elmo-folder-open-internal folder)
 645   (elmo-folder-check folder)
 646   (if (elmo-pop3-folder-use-uidl-internal folder)
 647       (prog1
 648           (elmo-pop3-list-by-uidl-subr folder 'nonsort)
 649         (elmo-folder-close-internal folder))
 650     (let* ((process
 651             (elmo-network-session-process-internal
 652              (elmo-pop3-get-session folder)))
 653            (total 0)
 654            response)
 655       (with-current-buffer (process-buffer process)
 656         (elmo-pop3-send-command process "STAT")
 657         (setq response (cdr (elmo-pop3-read-response process)))
 658         ;; response: "^\+OK 2 7570$"
 659         (if (not (string-match "^\+OK[ \t]*\\([0-9]*\\)" response))
 660             (error "POP STAT command failed")
 661           (setq total
 662                 (string-to-int
 663                  (substring response (match-beginning 1)(match-end 1 ))))
 664           (elmo-folder-close-internal folder)
 665           (cons total total))))))
 666
 667 (defvar elmo-pop3-header-fetch-chop-length 200)
 668
 669 (defsubst elmo-pop3-next-result-arrived-p ()
 670   (cond
 671    ((eq (following-char) ?+)
 672     (if (re-search-forward "\n\\.\r?\n" nil t)
 673         t
 674       nil))
 675    ((looking-at "-")
 676     (if (search-forward "\n" nil t)
 677         t
 678       nil))
 679    (t
 680     nil)))
 681
 682 (defun elmo-pop3-retrieve-headers (process tobuffer articles)
 683   (save-excursion
 684     (set-buffer (process-buffer process))
 685     (erase-buffer)
 686     (let ((number (length articles))
 687           (count 0)
 688           (received 0)
 689           (last-point (point-min)))
 690       ;; Send HEAD commands.
 691       (while articles
 692         (elmo-pop3-send-command process (format
 693                                          "top %s 0" (car articles))
 694                                 'no-erase)
 695 ;;;     (accept-process-output process 1)
 696         (setq articles (cdr articles))
 697         (setq count (1+ count))
 698         ;; Every 200 requests we have to read the stream in
 699         ;; order to avoid deadlocks.
 700         (when (or elmo-pop3-send-command-synchronously
 701                   (null articles)       ;All requests have been sent.
 702                   (zerop (% count elmo-pop3-header-fetch-chop-length)))
 703           (unless elmo-pop3-send-command-synchronously
 704             (accept-process-output process 1))
 705           (discard-input)
 706           (while (progn
 707                    (goto-char last-point)
 708                    ;; Count replies.
 709                    (while (elmo-pop3-next-result-arrived-p)
 710                      (setq last-point (point))
 711                      (setq received (1+ received)))
 712                    (< received count))
 713             (when (> number elmo-display-progress-threshold)
 714               (if (or (zerop (% received 5)) (= received number))
 715                   (elmo-display-progress
 716                    'elmo-pop3-retrieve-headers "Getting headers..."
 717                    (/ (* received 100) number))))
 718             (accept-process-output process 1)
 719 ;;;         (accept-process-output process)
 720             (discard-input))))
 721       ;; Replace all CRLF with LF.
 722       (elmo-delete-cr-buffer)
 723       (copy-to-buffer tobuffer (point-min) (point-max)))))
 724
 725 (luna-define-method elmo-folder-msgdb-create ((folder elmo-pop3-folder)
 726                                               numlist flag-table)
 727   (let ((process (elmo-network-session-process-internal
 728                   (elmo-pop3-get-session folder))))
 729     (with-current-buffer (process-buffer process)
 730       (elmo-pop3-sort-msgdb-by-original-number
 731        folder
 732        (elmo-pop3-msgdb-create-by-header
 733         folder
 734         process
 735         numlist
 736         flag-table
 737         (if (elmo-pop3-folder-use-uidl-internal folder)
 738             (elmo-pop3-folder-location-alist-internal folder)))))))
 739
 740 (defun elmo-pop3-sort-msgdb-by-original-number (folder msgdb)
 741   (let ((location-alist (elmo-pop3-folder-location-alist-internal folder)))
 742     (when location-alist
 743       (elmo-msgdb-sort-entities
 744        msgdb
 745        (lambda (ent1 ent2 loc-alist)
 746          (< (elmo-pop3-uidl-to-number
 747              (cdr (assq (elmo-message-entity-number ent1)
 748                         loc-alist)))
 749             (elmo-pop3-uidl-to-number
 750              (cdr (assq (elmo-message-entity-number ent2)
 751                         loc-alist)))))
 752        location-alist))
 753     msgdb))
 754
 755 (defun elmo-pop3-uidl-to-number (uidl)
 756   (string-to-number (elmo-get-hash-val uidl
 757                                        elmo-pop3-uidl-number-hash)))
 758
 759 (defun elmo-pop3-number-to-uidl (number)
 760   (elmo-get-hash-val (format "#%d" number)
 761                      elmo-pop3-number-uidl-hash))
 762
 763 (defun elmo-pop3-number-to-size (number)
 764   (elmo-get-hash-val (format "#%d" number)
 765                      elmo-pop3-size-hash))
 766
 767 (defun elmo-pop3-msgdb-create-by-header (folder process numlist
 768                                                 flag-table
 769                                                 loc-alist)
 770   (let ((tmp-buffer (get-buffer-create " *ELMO Overview TMP*")))
 771     (with-current-buffer (process-buffer process)
 772       (if loc-alist ; use uidl.
 773           (setq numlist
 774                 (delq
 775                  nil
 776                  (mapcar
 777                   (lambda (number)
 778                     (elmo-pop3-uidl-to-number (cdr (assq number loc-alist))))
 779                   numlist))))
 780       (elmo-pop3-retrieve-headers process tmp-buffer numlist)
 781       (prog1
 782           (elmo-pop3-msgdb-create-message
 783            folder
 784            tmp-buffer
 785            process
 786            (length numlist)
 787            numlist
 788            flag-table loc-alist)
 789         (kill-buffer tmp-buffer)))))
 790
 791 (defun elmo-pop3-msgdb-create-message (folder
 792                                        buffer
 793                                        process
 794                                        num
 795                                        numlist
 796                                        flag-table
 797                                        loc-alist)
 798   (save-excursion
 799     (let ((new-msgdb (elmo-make-msgdb))
 800           beg entity i number message-id flags)
 801       (set-buffer buffer)
 802       (set-buffer-multibyte default-enable-multibyte-characters)
 803       (goto-char (point-min))
 804       (setq i 0)
 805       (message "Creating msgdb...")
 806       (while (not (eobp))
 807         (setq beg (save-excursion (forward-line 1) (point)))
 808         (elmo-pop3-next-result-arrived-p)
 809         (save-excursion
 810           (forward-line -1)
 811           (save-restriction
 812             (narrow-to-region beg (point))
 813             (setq entity
 814                   (elmo-msgdb-create-message-entity-from-buffer
 815                    (elmo-msgdb-message-entity-handler new-msgdb)
 816                    (car numlist)))
 817             (setq numlist (cdr numlist))
 818             (when entity
 819               (with-current-buffer (process-buffer process)
 820                 (elmo-message-entity-set-field
 821                  entity
 822                  'size
 823                  (string-to-number
 824                   (elmo-pop3-number-to-size
 825                    (elmo-message-entity-number entity))))
 826                 (if (setq number
 827                           (car
 828                            (rassoc
 829                             (elmo-pop3-number-to-uidl
 830                              (elmo-message-entity-number entity))
 831                             loc-alist)))
 832                     (elmo-message-entity-set-number entity number)))
 833               (setq message-id (elmo-message-entity-field entity 'message-id)
 834                     flags (elmo-flag-table-get flag-table message-id))
 835               (elmo-global-flags-set flags folder number message-id)
 836               (elmo-msgdb-append-entity new-msgdb entity flags))))
 837         (when (> num elmo-display-progress-threshold)
 838           (setq i (1+ i))
 839           (if (or (zerop (% i 5)) (= i num))
 840               (elmo-display-progress
 841                'elmo-pop3-msgdb-create-message "Creating msgdb..."
 842                (/ (* i 100) num)))))
 843       new-msgdb)))
 844
 845 (defun elmo-pop3-read-body (process outbuf)
 846   (with-current-buffer (process-buffer process)
 847     (let ((start elmo-pop3-read-point)
 848           end)
 849       (goto-char start)
 850       (while (not (re-search-forward "^\\.\r?\n" nil t))
 851         (accept-process-output process 1)
 852         (goto-char start))
 853       (setq end (point))
 854       (with-current-buffer outbuf
 855         (erase-buffer)
 856         (insert-buffer-substring (process-buffer process) start (- end 3)))
 857       t)))
 858
 859 (luna-define-method elmo-folder-open-internal ((folder elmo-pop3-folder))
 860   (if (and (not elmo-inhibit-number-mapping)
 861            (elmo-pop3-folder-use-uidl-internal folder))
 862       (elmo-pop3-folder-set-location-alist-internal
 863        folder (elmo-msgdb-location-load (elmo-folder-msgdb-path folder)))))
 864
 865 (luna-define-method elmo-folder-commit :after ((folder elmo-pop3-folder))
 866   (when (elmo-folder-persistent-p folder)
 867     (elmo-msgdb-location-save (elmo-folder-msgdb-path folder)
 868                               (elmo-pop3-folder-location-alist-internal
 869                                folder))))
 870
 871 (luna-define-method elmo-folder-close-internal ((folder elmo-pop3-folder))
 872   (elmo-pop3-folder-set-location-alist-internal folder nil)
 873   ;; Just close connection
 874   (elmo-folder-check folder))
 875
 876 (luna-define-method elmo-message-fetch-plugged ((folder elmo-pop3-folder)
 877                                                 number strategy
 878                                                 &optional section
 879                                                 outbuf unseen)
 880   (let* ((loc-alist (elmo-pop3-folder-location-alist-internal folder))
 881          (process (elmo-network-session-process-internal
 882                    (elmo-pop3-get-session folder)))
 883         size  response errmsg msg)
 884     (with-current-buffer (process-buffer process)
 885       (if loc-alist
 886           (setq number (elmo-pop3-uidl-to-number
 887                         (cdr (assq number loc-alist)))))
 888       (setq size (string-to-number
 889                   (elmo-pop3-number-to-size number)))
 890       (when number
 891         (elmo-pop3-send-command process
 892                                 (format "retr %s" number))
 893         (unless elmo-inhibit-display-retrieval-progress
 894           (setq elmo-pop3-total-size size)
 895           (elmo-display-progress
 896            'elmo-display-retrieval-progress
 897            (format "Retrieving (0/%d bytes)..." elmo-pop3-total-size)
 898            0))
 899         (unwind-protect
 900             (progn
 901               (when (null (setq response (cdr (elmo-pop3-read-response
 902                                                process t))))
 903                 (error "Fetching message failed"))
 904               (setq response  (elmo-pop3-read-body process outbuf)))
 905           (setq elmo-pop3-total-size nil))
 906         (unless elmo-inhibit-display-retrieval-progress
 907           (elmo-display-progress
 908            'elmo-display-retrieval-progress
 909            "Retrieving..." 100)  ; remove progress bar.
 910           (message "Retrieving...done"))
 911         (set-buffer outbuf)
 912         (goto-char (point-min))
 913         (while (re-search-forward "^\\." nil t)
 914           (replace-match "")
 915           (forward-line))
 916         (elmo-delete-cr-buffer)
 917         response))))
 918
 919 (defun elmo-pop3-delete-msg (process number loc-alist)
 920   (with-current-buffer (process-buffer process)
 921     (let (response errmsg msg)
 922       (if loc-alist
 923           (setq number (elmo-pop3-uidl-to-number
 924                         (cdr (assq number loc-alist)))))
 925       (if number
 926           (progn
 927             (elmo-pop3-send-command process
 928                                     (format "dele %s" number))
 929             (when (null (setq response (cdr (elmo-pop3-read-response
 930                                              process t))))
 931               (error "Deleting message failed")))
 932         (error "Deleting message failed")))))
 933
 934 (luna-define-method elmo-folder-delete-messages-plugged ((folder
 935                                                           elmo-pop3-folder)
 936                                                          msgs)
 937   (let ((loc-alist (elmo-pop3-folder-location-alist-internal folder))
 938         (process (elmo-network-session-process-internal
 939                   (elmo-pop3-get-session folder))))
 940     (mapcar '(lambda (msg) (elmo-pop3-delete-msg process msg loc-alist))
 941             msgs)))
 942
 943 (luna-define-method elmo-message-use-cache-p ((folder elmo-pop3-folder) number)
 944   elmo-pop3-use-cache)
 945
 946 (luna-define-method elmo-folder-persistent-p ((folder elmo-pop3-folder))
 947   (and (elmo-folder-persistent-internal folder)
 948        (elmo-pop3-folder-use-uidl-internal folder)))
 949
 950 (luna-define-method elmo-folder-clear :around ((folder elmo-pop3-folder)
 951                                                &optional keep-killed)
 952   (unless keep-killed
 953     (elmo-pop3-folder-set-location-alist-internal folder nil))
 954   (luna-call-next-method))
 955
 956 (luna-define-method elmo-folder-check ((folder elmo-pop3-folder))
 957   (if (elmo-folder-plugged-p folder)
 958       (let ((session (elmo-pop3-get-session folder 'if-exists)))
 959         (when session
 960           (elmo-network-close-session session)))))
 961
 962 (require 'product)
 963 (product-provide (provide 'elmo-pop3) (require 'elmo-version))
 964
 965 ;;; elmo-pop3.el ends here