elmo/elmo-pop3.el

   1 ;;; elmo-pop3.el -- POP3 Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1999,2000      Kenichi OKADA <okada@opaopa.org>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Kenichi OKADA <okada@opaopa.org>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33
  34 (require 'elmo-msgdb)
  35 (require 'elmo-net)
  36 (eval-when-compile
  37   (require 'elmo-util)
  38   (condition-case nil
  39       (progn
  40         (require 'starttls)
  41         (require 'sasl))
  42     (error))
  43   (defun-maybe md5 (a))
  44   (defun-maybe sasl-digest-md5-digest-response
  45     (digest-challenge username passwd serv-type host &optional realm))
  46   (defun-maybe sasl-scram-md5-client-msg-1
  47     (authenticate-id &optional authorize-id))
  48   (defun-maybe sasl-scram-md5-client-msg-2
  49     (server-msg-1 client-msg-1 salted-pass))
  50   (defun-maybe sasl-scram-md5-make-salted-pass
  51     (server-msg-1 passphrase))
  52   (defun-maybe sasl-cram-md5 (username passphrase challenge))
  53   (defun-maybe sasl-scram-md5-authenticate-server
  54     (server-msg-1 server-msg-2 client-msg-1 salted-pass))
  55   (defun-maybe starttls-negotiate (a)))
  56 (condition-case nil
  57     (progn
  58       (require 'sasl))
  59   (error))
  60
  61 (defvar elmo-pop3-use-uidl t
  62   "*If non-nil, use UIDL.")
  63
  64 (defvar elmo-pop3-exists-exactly t)
  65
  66 (defvar elmo-pop3-authenticator-alist
  67   '((user        elmo-pop3-auth-user)
  68     (apop        elmo-pop3-auth-apop)
  69     (cram-md5    elmo-pop3-auth-cram-md5)
  70     (scram-md5   elmo-pop3-auth-scram-md5)
  71     (digest-md5  elmo-pop3-auth-digest-md5))
  72   "Definition of authenticators.")
  73
  74 (eval-and-compile
  75   (luna-define-class elmo-pop3-session (elmo-network-session) ()))
  76
  77 ;; buffer-local
  78 (defvar elmo-pop3-read-point nil)
  79 (defvar elmo-pop3-number-uidl-hash nil) ; number -> uidl
  80 (defvar elmo-pop3-uidl-number-hash nil) ; uidl -> number
  81 (defvar elmo-pop3-size-hash nil) ; number -> size
  82 (defvar elmo-pop3-uidl-done nil)
  83 (defvar elmo-pop3-list-done nil)
  84
  85 (defvar elmo-pop3-local-variables '(elmo-pop3-read-point
  86                                     elmo-pop3-uidl-number-hash
  87                                     elmo-pop3-number-uidl-hash
  88                                     elmo-pop3-uidl-done
  89                                     elmo-pop3-size-hash
  90                                     elmo-pop3-list-done))
  91
  92 (luna-define-method elmo-network-close-session ((session elmo-pop3-session))
  93   (unless (memq (process-status
  94                  (elmo-network-session-process-internal session))
  95                 '(closed exit))
  96     (elmo-pop3-send-command (elmo-network-session-process-internal session)
  97                             "quit")
  98     (or (elmo-pop3-read-response
  99          (elmo-network-session-process-internal session) t)
 100         (error "POP error: QUIT failed")))
 101   (kill-buffer (process-buffer
 102                 (elmo-network-session-process-internal session)))
 103   (delete-process (elmo-network-session-process-internal session)))
 104
 105 (defun elmo-pop3-get-session (spec &optional if-exists)
 106   (elmo-network-get-session
 107    'elmo-pop3-session
 108    "POP3"
 109    (elmo-pop3-spec-hostname spec)
 110    (elmo-pop3-spec-port spec)
 111    (elmo-pop3-spec-username spec)
 112    (elmo-pop3-spec-auth spec)
 113    (elmo-pop3-spec-stream-type spec)
 114    if-exists))
 115
 116 (defun elmo-pop3-send-command (process command &optional no-erase)
 117   (with-current-buffer (process-buffer process)
 118     (unless no-erase
 119       (erase-buffer))
 120     (goto-char (point-min))
 121     (setq elmo-pop3-read-point (point))
 122     (process-send-string process command)
 123     (process-send-string process "\r\n")))
 124
 125 (defun elmo-pop3-read-response (process &optional not-command)
 126   (with-current-buffer (process-buffer process)
 127     (let ((case-fold-search nil)
 128           (response-string nil)
 129           (response-continue t)
 130           (return-value nil)
 131           match-end)
 132       (while response-continue
 133         (goto-char elmo-pop3-read-point)
 134         (while (not (re-search-forward "\r?\n" nil t))
 135           (accept-process-output process)
 136           (goto-char elmo-pop3-read-point))
 137         (setq match-end (point))
 138         (setq response-string
 139               (buffer-substring elmo-pop3-read-point (- match-end 2)))
 140         (goto-char elmo-pop3-read-point)
 141         (if (looking-at "\\+.*$")
 142             (progn
 143               (setq response-continue nil)
 144               (setq elmo-pop3-read-point match-end)
 145               (setq return-value
 146                     (if return-value
 147                         (concat return-value "\n" response-string)
 148                       response-string)))
 149           (if (looking-at "\\-.*$")
 150               (progn
 151                 (setq response-continue nil)
 152                 (setq elmo-pop3-read-point match-end)
 153                 (setq return-value nil))
 154             (setq elmo-pop3-read-point match-end)
 155             (if not-command
 156                 (setq response-continue nil))
 157             (setq return-value
 158                   (if return-value
 159                       (concat return-value "\n" response-string)
 160                     response-string)))
 161           (setq elmo-pop3-read-point match-end)))
 162       return-value)))
 163
 164 (defun elmo-pop3-process-filter (process output)
 165   (save-excursion
 166     (set-buffer (process-buffer process))
 167     (goto-char (point-max))
 168     (insert output)))
 169
 170 (defun elmo-pop3-auth-user (session)
 171   (let ((process (elmo-network-session-process-internal session)))
 172     ;; try USER/PASS
 173     (elmo-pop3-send-command
 174      process
 175      (format "user %s" (elmo-network-session-user-internal session)))
 176     (or (elmo-pop3-read-response process t)
 177         (signal 'elmo-authenticate-error
 178                 '(elmo-pop-auth-user)))
 179     (elmo-pop3-send-command  process
 180                              (format
 181                               "pass %s"
 182                               (elmo-get-passwd
 183                                (elmo-network-session-password-key session))))
 184     (or (elmo-pop3-read-response process t)
 185         (signal 'elmo-authenticate-error
 186                 '(elmo-pop-auth-user)))))
 187
 188 (defun elmo-pop3-auth-apop (session)
 189   (if (string-match "^\+OK .*\\(<[^\>]+>\\)"
 190                     (elmo-network-session-greeting-internal session))
 191       ;; good, APOP ready server
 192       (progn
 193         (require 'md5)
 194         (elmo-pop3-send-command
 195          (elmo-network-session-process-internal session)
 196          (format "apop %s %s"
 197                  (elmo-network-session-user-internal session)
 198                  (md5
 199                   (concat (match-string
 200                            1
 201                            (elmo-network-session-greeting-internal session))
 202                           (elmo-get-passwd
 203                            (elmo-network-session-password-key session))))))
 204         (or (elmo-pop3-read-response
 205              (elmo-network-session-process-internal session)
 206              t)
 207             (signal 'elmo-authenticate-error
 208                     '(elmo-pop3-auth-apop))))
 209     (signal 'elmo-open-error '(elmo-pop-auth-user))))
 210
 211 (defun elmo-pop3-auth-cram-md5 (session)
 212   (let ((process (elmo-network-session-process-internal session))
 213         response)
 214     (elmo-pop3-send-command  process "auth cram-md5")
 215     (or (setq response
 216               (elmo-pop3-read-response process t))
 217         (signal 'elmo-open-error '(elmo-pop-auth-cram-md5)))
 218     (elmo-pop3-send-command
 219      process
 220      (elmo-base64-encode-string
 221       (sasl-cram-md5 (elmo-network-session-user-internal session)
 222                      (elmo-get-passwd
 223                       (elmo-network-session-password-key session))
 224                      (elmo-base64-decode-string
 225                       (cadr (split-string response " "))))))
 226     (or (elmo-pop3-read-response process t)
 227         (signal 'elmo-authenticate-error
 228                 '(elmo-pop-auth-cram-md5)))))
 229
 230 (defun elmo-pop3-auth-scram-md5 (session)
 231   (let ((process (elmo-network-session-process-internal session))
 232         server-msg-1 server-msg-2 client-msg-1 client-msg-2
 233         salted-pass response)
 234     (elmo-pop3-send-command
 235      process
 236      (format "auth scram-md5 %s"
 237              (elmo-base64-encode-string
 238               (setq client-msg-1
 239                     (sasl-scram-md5-client-msg-1
 240                      (elmo-network-session-user-internal session))))))
 241     (or (elmo-pop3-read-response process t)
 242         (signal 'elmo-open-error '(elmo-pop-auth-scram-md5)))
 243     (setq server-msg-1
 244           (elmo-base64-decode-string (cadr (split-string response " "))))
 245     (elmo-pop3-send-command
 246      process
 247      (elmo-base64-encode-string
 248       (sasl-scram-md5-client-msg-2
 249        server-msg-1
 250        client-msg-1
 251        (setq salted-pass
 252              (sasl-scram-md5-make-salted-pass
 253               server-msg-1
 254               (elmo-get-passwd
 255                (elmo-network-session-password-key session)))))))
 256     (or (setq response (elmo-pop3-read-response process t))
 257         (signal 'elmo-authenticate-error
 258                 '(elmo-pop-auth-scram-md5)))
 259     (setq server-msg-2 (elmo-base64-decode-string
 260                         (cadr (split-string response " "))))
 261     (or (sasl-scram-md5-authenticate-server server-msg-1
 262                                             server-msg-2
 263                                             client-msg-1
 264                                             salted-pass)
 265         (signal 'elmo-authenticate-error
 266                 '(elmo-pop-auth-scram-md5)))
 267     (elmo-pop3-send-command process "")
 268     (or (setq response (elmo-pop3-read-response process t))
 269         (signal 'elmo-authenticate-error
 270                 '(elmo-pop-auth-scram-md5)))))
 271
 272 (defun elmo-pop3-auth-digest-md5 (session)
 273   (let ((process (elmo-network-session-process-internal session))
 274         response)
 275     (elmo-pop3-send-command process "auth digest-md5")
 276     (or (setq response
 277               (elmo-pop3-read-response process t))
 278         (signal 'elmo-open-error
 279                 '(elmo-pop-auth-digest-md5)))
 280     (elmo-pop3-send-command
 281      process
 282      (elmo-base64-encode-string
 283       (sasl-digest-md5-digest-response
 284        (elmo-base64-decode-string
 285         (cadr (split-string response " ")))
 286        (elmo-network-session-user-internal session)
 287        (elmo-get-passwd
 288         (elmo-network-session-password-key session))
 289        "pop"
 290        (elmo-network-session-host-internal session))
 291       'no-line-break))
 292     (or (elmo-pop3-read-response process t)
 293         (signal 'elmo-authenticate-error
 294                 '(elmo-pop-auth-digest-md5)))
 295     (elmo-pop3-send-command process "")
 296     (or (elmo-pop3-read-response process t)
 297         (signal 'elmo-open-error
 298                 '(elmo-pop-auth-digest-md5)))))
 299
 300 (luna-define-method elmo-network-initialize-session-buffer :after
 301   ((session elmo-pop3-session) buffer)
 302   (with-current-buffer buffer
 303     (mapcar 'make-variable-buffer-local elmo-pop3-local-variables)))
 304
 305 (luna-define-method elmo-network-initialize-session ((session
 306                                                       elmo-pop3-session))
 307   (let ((process (elmo-network-session-process-internal session))
 308         response mechanism)
 309     (with-current-buffer (process-buffer process)
 310       (set-process-filter process 'elmo-pop3-process-filter)
 311       (setq elmo-pop3-read-point (point-min))
 312       (or (elmo-network-session-set-greeting-internal
 313            session
 314            (elmo-pop3-read-response process t))
 315           (signal 'elmo-open-error
 316                   '(elmo-network-intialize-session)))
 317       (when (eq (elmo-network-stream-type-symbol
 318                  (elmo-network-session-stream-type-internal session))
 319                 'starttls)
 320         (elmo-pop3-send-command process "stls")
 321         (if (string-match "^\+OK"
 322                           (elmo-pop3-read-response process))
 323             (starttls-negotiate process)
 324           (signal 'elmo-open-error
 325                   '(elmo-pop3-starttls-error)))))))
 326
 327 (luna-define-method elmo-network-authenticate-session ((session
 328                                                         elmo-pop3-session))
 329   (let (authenticator)
 330     ;; defaults to 'user.
 331     (unless (elmo-network-session-auth-internal session)
 332       (elmo-network-session-set-auth-internal session 'user))
 333     (setq authenticator
 334           (nth 1 (assq (elmo-network-session-auth-internal session)
 335                        elmo-pop3-authenticator-alist)))
 336     (unless authenticator (error "There's no authenticator for %s"
 337                                  (elmo-network-session-auth-internal session)))
 338     (funcall authenticator session)))
 339
 340 (luna-define-method elmo-network-setup-session ((session
 341                                                  elmo-pop3-session))
 342   (let ((process (elmo-network-session-process-internal session))
 343         response)
 344     (with-current-buffer (process-buffer process)
 345       (setq elmo-pop3-size-hash (make-vector 31 0))
 346       ;; To get obarray of uidl and size
 347       (elmo-pop3-send-command process "list")
 348       (if (null (elmo-pop3-read-response process))
 349           (error "POP List folder failed"))
 350       (if (null (setq response
 351                       (elmo-pop3-read-contents
 352                        (current-buffer) process)))
 353           (error "POP List folder failed"))
 354       ;; POP server always returns a sequence of serial numbers.
 355       (elmo-pop3-parse-list-response response)
 356       ;; UIDL
 357       (when elmo-pop3-use-uidl
 358         (setq elmo-pop3-uidl-number-hash (make-vector 31 0))
 359         (setq elmo-pop3-number-uidl-hash (make-vector 31 0))
 360         ;; UIDL
 361         (elmo-pop3-send-command process "uidl")
 362         (unless (elmo-pop3-read-response process)
 363           (error "UIDL failed"))
 364         (unless (setq response (elmo-pop3-read-contents
 365                                 (current-buffer) process))
 366           (error "UIDL failed"))
 367         (elmo-pop3-parse-uidl-response response)))))
 368
 369 (defun elmo-pop3-read-contents (buffer process)
 370   (save-excursion
 371     (set-buffer buffer)
 372     (let ((case-fold-search nil)
 373           match-end)
 374       (goto-char elmo-pop3-read-point)
 375       (while (not (re-search-forward "^\\.\r\n" nil t))
 376         (accept-process-output process)
 377         (goto-char elmo-pop3-read-point))
 378       (setq match-end (point))
 379       (elmo-delete-cr
 380        (buffer-substring elmo-pop3-read-point
 381                          (- match-end 3))))))
 382
 383 ;; dummy functions
 384 (defun elmo-pop3-list-folders (spec &optional hierarchy) nil)
 385 (defun elmo-pop3-append-msg (spec string) nil nil)
 386 (defun elmo-pop3-folder-creatable-p (spec) nil)
 387 (defun elmo-pop3-create-folder (spec) nil)
 388
 389 (defun elmo-pop3-folder-exists-p (spec)
 390   (if (and elmo-pop3-exists-exactly
 391            (elmo-pop3-plugged-p spec))
 392       (save-excursion
 393         (let (elmo-auto-change-plugged ; don't change plug status.
 394               elmo-pop3-use-uidl       ; No need to use uidl.
 395               session)
 396           (prog1
 397               (setq session (elmo-pop3-get-session spec))
 398             (if session
 399                 (elmo-network-close-session session)))))
 400     t))
 401
 402 (defun elmo-pop3-parse-uidl-response (string)
 403   (let ((buffer (current-buffer))
 404         number list size)
 405     (with-temp-buffer
 406       (let (number uid list)
 407         (insert string)
 408         (goto-char (point-min))
 409         (while (re-search-forward "^\\([0-9]+\\)[\t ]\\([^ \n]+\\)$" nil t)
 410           (setq number  (elmo-match-buffer 1))
 411           (setq uid (elmo-match-buffer 2))
 412           (with-current-buffer buffer
 413             (elmo-set-hash-val uid number elmo-pop3-uidl-number-hash)
 414             (elmo-set-hash-val (concat "#" number) uid
 415                                elmo-pop3-number-uidl-hash))
 416           (setq list (cons uid list)))
 417         (with-current-buffer buffer (setq elmo-pop3-uidl-done t))
 418         (nreverse list)))))
 419
 420 (defun elmo-pop3-parse-list-response (string)
 421   (let ((buffer (current-buffer))
 422         number list size)
 423     (with-temp-buffer
 424       (insert string)
 425       (goto-char (point-min))
 426       (while (re-search-forward "^\\([0-9]+\\)[\t ]\\([0-9]+\\)$" nil t)
 427         (setq list
 428               (cons
 429                (string-to-int (setq number (elmo-match-buffer 1)))
 430                list))
 431         (setq size (elmo-match-buffer 2))
 432         (with-current-buffer buffer
 433           (elmo-set-hash-val (concat "#" number)
 434                              size
 435                              elmo-pop3-size-hash)))
 436       (with-current-buffer buffer (setq elmo-pop3-list-done t))
 437       (nreverse list))))
 438
 439 (defun elmo-pop3-list-location (spec)
 440   (with-current-buffer (process-buffer
 441                         (elmo-network-session-process-internal
 442                          (elmo-pop3-get-session spec)))
 443     (let (list)
 444       (if elmo-pop3-uidl-done
 445           (progn
 446             (mapatoms
 447              (lambda (atom)
 448                (setq list (cons (symbol-name atom) list)))
 449              elmo-pop3-uidl-number-hash)
 450             (nreverse list))
 451         (error "POP3: Error in UIDL")))))
 452
 453 (defun elmo-pop3-list-by-uidl-subr (spec &optional nonsort)
 454   (let ((flist (elmo-list-folder-by-location
 455                 spec
 456                 (elmo-pop3-list-location spec))))
 457     (if nonsort
 458         (cons (elmo-max-of-list flist) (length flist))
 459       (sort flist '<))))
 460
 461 (defun elmo-pop3-list-by-list (spec)
 462   (with-current-buffer (process-buffer
 463                         (elmo-network-session-process-internal
 464                          (elmo-pop3-get-session spec)))
 465     (let (list)
 466       (if elmo-pop3-list-done
 467           (progn
 468             (mapatoms (lambda (atom)
 469                         (setq list (cons (string-to-int
 470                                           (substring (symbol-name atom) 1))
 471                                          list)))
 472                       elmo-pop3-size-hash)
 473             (sort list '<))
 474         (error "POP3: Error in list")))))
 475
 476 (defun elmo-pop3-list-folder (spec)
 477   (let ((killed (and elmo-use-killed-list
 478                      (elmo-msgdb-killed-list-load
 479                       (elmo-msgdb-expand-path spec))))
 480         numbers)
 481     (elmo-pop3-commit spec)
 482     (setq numbers (if elmo-pop3-use-uidl
 483                       (progn
 484                         (elmo-pop3-list-by-uidl-subr spec))
 485                     (elmo-pop3-list-by-list spec)))
 486     (elmo-living-messages numbers killed)))
 487
 488 (defun elmo-pop3-max-of-folder (spec)
 489   (elmo-pop3-commit spec)
 490   (if elmo-pop3-use-uidl
 491       (elmo-pop3-list-by-uidl-subr spec 'nonsort)
 492     (let* ((process
 493             (elmo-network-session-process-internal
 494              (elmo-pop3-get-session spec)))
 495            (total 0)
 496            response)
 497       (with-current-buffer (process-buffer process)
 498         (elmo-pop3-send-command process "STAT")
 499         (setq response (elmo-pop3-read-response process))
 500         ;; response: "^\+OK 2 7570$"
 501         (if (not (string-match "^\+OK[ \t]*\\([0-9]*\\)" response))
 502             (error "POP STAT command failed")
 503           (setq total
 504                 (string-to-int
 505                  (substring response (match-beginning 1)(match-end 1 ))))
 506           (cons total total))))))
 507
 508 (defvar elmo-pop3-header-fetch-chop-length 200)
 509
 510 (defsubst elmo-pop3-next-result-arrived-p ()
 511   (cond
 512    ((eq (following-char) ?+)
 513     (if (re-search-forward "\n\\.\r?\n" nil t)
 514         t
 515       nil))
 516    ((looking-at "-")
 517     (if (search-forward "\n" nil t)
 518         t
 519       nil))
 520    (t
 521     nil)))
 522
 523 (defun elmo-pop3-retrieve-headers (buffer tobuffer process articles)
 524   (save-excursion
 525     (set-buffer buffer)
 526     (erase-buffer)
 527     (let ((number (length articles))
 528           (count 0)
 529           (received 0)
 530           (last-point (point-min)))
 531       ;; Send HEAD commands.
 532       (while articles
 533         (elmo-pop3-send-command process (format
 534                                          "top %s 0" (car articles))
 535                                 'no-erase)
 536 ;;;     (accept-process-output process 1)
 537         (setq articles (cdr articles))
 538         (setq count (1+ count))
 539         ;; Every 200 requests we have to read the stream in
 540         ;; order to avoid deadlocks.
 541         (when (or elmo-pop3-send-command-synchronously
 542                   (null articles)       ;All requests have been sent.
 543                   (zerop (% count elmo-pop3-header-fetch-chop-length)))
 544           (unless elmo-pop3-send-command-synchronously
 545             (accept-process-output process 1))
 546           (discard-input)
 547           (while (progn
 548                    (set-buffer buffer)
 549                    (goto-char last-point)
 550                    ;; Count replies.
 551                    (while (elmo-pop3-next-result-arrived-p)
 552                      (setq last-point (point))
 553                      (setq received (1+ received)))
 554                    (< received count))
 555             (when (> number elmo-display-progress-threshold)
 556               (if (or (zerop (% received 5)) (= received number))
 557                   (elmo-display-progress
 558                    'elmo-pop3-retrieve-headers "Getting headers..."
 559                    (/ (* received 100) number))))
 560             (accept-process-output process 1)
 561 ;;;         (accept-process-output process)
 562             (discard-input))))
 563       ;; Remove all "\r"'s.
 564       (goto-char (point-min))
 565       (while (search-forward "\r\n" nil t)
 566         (replace-match "\n"))
 567       (copy-to-buffer tobuffer (point-min) (point-max)))))
 568
 569 (defalias 'elmo-pop3-msgdb-create 'elmo-pop3-msgdb-create-as-numlist)
 570
 571 (defun elmo-pop3-msgdb-create-as-numlist (spec numlist new-mark
 572                                                already-mark seen-mark
 573                                                important-mark seen-list
 574                                                &optional msgdb)
 575   (when numlist
 576     (let ((process (elmo-network-session-process-internal
 577                     (elmo-pop3-get-session spec)))
 578           loc-alist)
 579       (if elmo-pop3-use-uidl
 580           (setq loc-alist (if msgdb (elmo-msgdb-get-location msgdb)
 581                             (elmo-msgdb-location-load
 582                              (elmo-msgdb-expand-path spec)))))
 583       (elmo-pop3-msgdb-create-by-header process numlist
 584                                         new-mark already-mark
 585                                         seen-mark seen-list
 586                                         loc-alist))))
 587
 588 (defun elmo-pop3-uidl-to-number (uidl)
 589   (string-to-number (elmo-get-hash-val uidl
 590                                        elmo-pop3-uidl-number-hash)))
 591
 592 (defun elmo-pop3-number-to-uidl (number)
 593   (elmo-get-hash-val (format "#%d" number)
 594                      elmo-pop3-number-uidl-hash))
 595
 596 (defun elmo-pop3-number-to-size (number)
 597   (elmo-get-hash-val (format "#%d" number)
 598                      elmo-pop3-size-hash))
 599
 600 (defun elmo-pop3-msgdb-create-by-header (process numlist
 601                                                  new-mark already-mark
 602                                                  seen-mark
 603                                                  seen-list
 604                                                  loc-alist)
 605   (let ((tmp-buffer (get-buffer-create " *ELMO Overview TMP*")))
 606     (with-current-buffer (process-buffer process)
 607       (if loc-alist ; use uidl.
 608           (setq numlist
 609                 (delq
 610                  nil
 611                  (mapcar
 612                   (lambda (number)
 613                     (elmo-pop3-uidl-to-number (cdr (assq number loc-alist))))
 614                   numlist))))
 615       (elmo-pop3-retrieve-headers (process-buffer process)
 616                                   tmp-buffer process numlist)
 617       (prog1
 618           (elmo-pop3-msgdb-create-message
 619            tmp-buffer
 620            process
 621            (length numlist)
 622            numlist
 623            new-mark already-mark seen-mark seen-list loc-alist)
 624         (kill-buffer tmp-buffer)))))
 625
 626 (defun elmo-pop3-msgdb-create-message (buffer
 627                                        process
 628                                        num
 629                                        numlist new-mark already-mark
 630                                        seen-mark
 631                                        seen-list
 632                                        loc-alist)
 633   (save-excursion
 634     (let (beg overview number-alist mark-alist
 635               entity i number message-id gmark seen size)
 636       (set-buffer buffer)
 637       (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 638       (goto-char (point-min))
 639       (setq i 0)
 640       (message "Creating msgdb...")
 641       (while (not (eobp))
 642         (setq beg (save-excursion (forward-line 1) (point)))
 643         (elmo-pop3-next-result-arrived-p)
 644         (save-excursion
 645           (forward-line -1)
 646           (save-restriction
 647             (narrow-to-region beg (point))
 648             (setq entity
 649                   (elmo-msgdb-create-overview-from-buffer
 650                    (car numlist)))
 651             (setq numlist (cdr numlist))
 652             (when entity
 653               (setq overview
 654                     (elmo-msgdb-append-element
 655                      overview entity))
 656               (with-current-buffer (process-buffer process)
 657                 (elmo-msgdb-overview-entity-set-size
 658                  entity
 659                  (string-to-number
 660                   (elmo-pop3-number-to-size
 661                    (elmo-msgdb-overview-entity-get-number entity))))
 662                 (if (setq number
 663                           (car
 664                            (rassoc
 665                             (elmo-pop3-number-to-uidl
 666                              (elmo-msgdb-overview-entity-get-number entity))
 667                             loc-alist)))
 668                     (elmo-msgdb-overview-entity-set-number entity number)))
 669               (setq number-alist
 670                     (elmo-msgdb-number-add
 671                      number-alist
 672                      (elmo-msgdb-overview-entity-get-number entity)
 673                      (car entity)))
 674               (setq message-id (car entity))
 675               (setq seen (member message-id seen-list))
 676               (if (setq gmark (or (elmo-msgdb-global-mark-get message-id)
 677                                   (if (elmo-cache-exists-p
 678                                        message-id) ; XXX
 679                                       (if seen
 680                                           nil
 681                                         already-mark)
 682                                     (if seen
 683                                         (if elmo-pop3-use-cache
 684                                             seen-mark)
 685                                       new-mark))))
 686                   (setq mark-alist
 687                         (elmo-msgdb-mark-append
 688                          mark-alist
 689                          (elmo-msgdb-overview-entity-get-number entity)
 690                          gmark))))))
 691         (when (> num elmo-display-progress-threshold)
 692           (setq i (1+ i))
 693           (if (or (zerop (% i 5)) (= i num))
 694               (elmo-display-progress
 695                'elmo-pop3-msgdb-create-message "Creating msgdb..."
 696                (/ (* i 100) num)))))
 697       (list overview number-alist mark-alist loc-alist))))
 698
 699 (defun elmo-pop3-read-body (process outbuf)
 700   (with-current-buffer (process-buffer process)
 701     (let ((start elmo-pop3-read-point)
 702           end)
 703       (goto-char start)
 704       (while (not (re-search-forward "^\\.\r?\n" nil t))
 705         (accept-process-output process)
 706         (goto-char start))
 707       (setq end (point))
 708       (with-current-buffer outbuf
 709         (erase-buffer)
 710         (insert-buffer-substring (process-buffer process) start (- end 3))
 711         (elmo-delete-cr-get-content-type)))))
 712
 713 (defun elmo-pop3-read-msg (spec number outbuf &optional msgdb)
 714   (let* ((loc-alist (if elmo-pop3-use-uidl
 715                         (if msgdb
 716                             (elmo-msgdb-get-location msgdb)
 717                           (elmo-msgdb-location-load
 718                            (elmo-msgdb-expand-path spec)))))
 719          (process (elmo-network-session-process-internal
 720                    (elmo-pop3-get-session spec)))
 721          response errmsg msg)
 722     (with-current-buffer (process-buffer process)
 723       (if loc-alist
 724           (setq number (elmo-pop3-uidl-to-number
 725                         (cdr (assq number loc-alist)))))
 726       (when number
 727         (elmo-pop3-send-command process
 728                                 (format "retr %s" number))
 729         (when (null (setq response (elmo-pop3-read-response
 730                                     process t)))
 731           (error "Fetching message failed"))
 732         (setq response (elmo-pop3-read-body process outbuf))
 733         (set-buffer outbuf)
 734         (goto-char (point-min))
 735         (while (re-search-forward "^\\." nil t)
 736           (replace-match "")
 737           (forward-line))
 738         response))))
 739
 740 (defun elmo-pop3-delete-msg (process number loc-alist)
 741   (with-current-buffer (process-buffer process)
 742     (let (response errmsg msg)
 743       (if loc-alist
 744           (setq number (elmo-pop3-uidl-to-number
 745                         (cdr (assq number loc-alist)))))
 746       (if number
 747           (progn
 748             (elmo-pop3-send-command process
 749                                     (format "dele %s" number))
 750             (when (null (setq response (elmo-pop3-read-response
 751                                         process t)))
 752               (error "Deleting message failed")))
 753         (error "Deleting message failed")))))
 754
 755 (defun elmo-pop3-delete-msgs (spec msgs &optional msgdb)
 756   (let ((loc-alist (if elmo-pop3-use-uidl
 757                        (if msgdb
 758                            (elmo-msgdb-get-location msgdb)
 759                          (elmo-msgdb-location-load
 760                           (elmo-msgdb-expand-path spec)))))
 761         (process (elmo-network-session-process-internal
 762                   (elmo-pop3-get-session spec))))
 763     (mapcar '(lambda (msg) (elmo-pop3-delete-msg
 764                             process msg loc-alist))
 765             msgs)))
 766
 767 (defun elmo-pop3-search (spec condition &optional numlist)
 768   (error "Searching in pop3 folder is not implemented yet"))
 769
 770 (defun elmo-pop3-use-cache-p (spec number)
 771   elmo-pop3-use-cache)
 772
 773 (defun elmo-pop3-local-file-p (spec number)
 774   nil)
 775
 776 (defun elmo-pop3-port-label (spec)
 777   (concat "pop3"
 778           (if (elmo-pop3-spec-stream-type spec)
 779               (concat "!" (symbol-name
 780                            (elmo-network-stream-type-symbol
 781                             (elmo-pop3-spec-stream-type spec)))))))
 782
 783 (defsubst elmo-pop3-portinfo (spec)
 784   (list (elmo-pop3-spec-hostname spec)
 785         (elmo-pop3-spec-port spec)))
 786
 787 (defun elmo-pop3-plugged-p (spec)
 788   (apply 'elmo-plugged-p
 789          (append (elmo-pop3-portinfo spec)
 790                  (list nil (quote (elmo-pop3-port-label spec))))))
 791
 792 (defun elmo-pop3-set-plugged (spec plugged add)
 793   (apply 'elmo-set-plugged plugged
 794          (append (elmo-pop3-portinfo spec)
 795                  (list nil nil (quote (elmo-pop3-port-label spec)) add))))
 796
 797 (defalias 'elmo-pop3-sync-number-alist
 798   'elmo-generic-sync-number-alist)
 799 (defalias 'elmo-pop3-list-folder-unread
 800   'elmo-generic-list-folder-unread)
 801 (defalias 'elmo-pop3-list-folder-important
 802   'elmo-generic-list-folder-important)
 803 (defalias 'elmo-pop3-folder-diff 'elmo-generic-folder-diff)
 804
 805 (defun elmo-pop3-commit (spec)
 806   (if (elmo-pop3-plugged-p spec)
 807       (let ((session (elmo-pop3-get-session spec 'if-exists)))
 808         (and session
 809              (elmo-network-close-session session)))))
 810
 811
 812 (require 'product)
 813 (product-provide (provide 'elmo-pop3) (require 'elmo-version))
 814
 815 ;;; elmo-pop3.el ends here