elmo/elmo-shimbun.el

   1 ;;; elmo-shimbun.el --- Shimbun interface for ELMO.
   2
   3 ;; Copyright (C) 2001 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'elmo)
  32 (require 'elmo-map)
  33 (require 'elmo-dop)
  34 (require 'shimbun)
  35
  36 (eval-when-compile
  37   (require 'cl)
  38   (defun-maybe shimbun-servers-list ()))
  39
  40 (defcustom elmo-shimbun-check-interval 60
  41   "*Check interval for shimbun."
  42   :type 'integer
  43   :group 'elmo)
  44
  45 (defcustom elmo-shimbun-default-index-range 2
  46   "*Default value for the range of header indices."
  47   :type '(choice (const :tag "all" all)
  48                  (const :tag "last" last)
  49                  (integer :tag "number"))
  50   :group 'elmo)
  51
  52 (defcustom elmo-shimbun-use-cache t
  53   "*If non-nil, use cache for each article."
  54   :type 'boolean
  55   :group 'elmo)
  56
  57 (defcustom elmo-shimbun-index-range-alist nil
  58   "*Alist of FOLDER-REGEXP and RANGE.
  59 FOLDER-REGEXP is the regexp for shimbun folder name.
  60 RANGE is the range of the header indices .
  61 See `shimbun-headers' for more detail about RANGE."
  62   :type '(repeat (cons (regexp :tag "Folder Regexp")
  63                        (choice (const :tag "all" all)
  64                                (const :tag "last" last)
  65                                (integer :tag "number"))))
  66   :group 'elmo)
  67
  68 (defcustom elmo-shimbun-update-overview-folder-list 'all
  69   "*List of FOLDER-REGEXP.
  70 FOLDER-REGEXP is the regexp of shimbun folder name which should be
  71 update overview when message is fetched.
  72 If it is the symbol `all', update overview for all shimbun folders."
  73   :type '(choice (const :tag "All shimbun folders" all)
  74                  (repeat (regexp :tag "Folder Regexp")))
  75   :group 'elmo)
  76
  77 ;; Shimbun header.
  78 (defsubst elmo-shimbun-header-extra-field (header field-name)
  79   (let ((extra (and header (shimbun-header-extra header))))
  80     (and extra
  81          (cdr (assoc field-name extra)))))
  82
  83 (defsubst elmo-shimbun-header-set-extra-field (header field-name value)
  84   (let ((extras (and header (shimbun-header-extra header)))
  85         extra)
  86     (if (setq extra (assoc field-name extras))
  87         (setcdr extra value)
  88       (shimbun-header-set-extra
  89        header
  90        (cons (cons field-name value) extras)))))
  91
  92 ;; Shimbun mua.
  93 (eval-and-compile
  94   (luna-define-class shimbun-elmo-mua (shimbun-mua) (folder))
  95   (luna-define-internal-accessors 'shimbun-elmo-mua))
  96
  97 (luna-define-method shimbun-mua-search-id ((mua shimbun-elmo-mua) id)
  98   (elmo-message-entity (shimbun-elmo-mua-folder-internal mua) id))
  99
 100 (eval-and-compile
 101   (luna-define-class elmo-shimbun-folder
 102                      (elmo-map-folder) (shimbun headers header-hash
 103                                                 entity-hash
 104                                                 group range last-check))
 105   (luna-define-internal-accessors 'elmo-shimbun-folder))
 106
 107 (defun elmo-shimbun-folder-entity-hash (folder)
 108   (or (elmo-shimbun-folder-entity-hash-internal folder)
 109       (let ((overviews (elmo-folder-list-message-entities folder))
 110             hash id)
 111         (when overviews
 112           (setq hash (elmo-make-hash (length overviews)))
 113           (dolist (entity overviews)
 114             (elmo-set-hash-val (elmo-message-entity-field entity 'message-id)
 115                                entity hash)
 116             (when (setq id (elmo-message-entity-field entity 'x-original-id))
 117               (elmo-set-hash-val id entity hash)))
 118           (elmo-shimbun-folder-set-entity-hash-internal folder hash)))))
 119
 120 (defsubst elmo-shimbun-folder-shimbun-header (folder location)
 121   (let ((hash (elmo-shimbun-folder-header-hash-internal folder)))
 122     (or (and hash (elmo-get-hash-val location hash))
 123         (let ((entity (elmo-message-entity folder location))
 124               (elmo-hash-minimum-size 63)
 125               header)
 126           (when entity
 127             (setq header (elmo-shimbun-entity-to-header entity))
 128             (unless hash
 129               (elmo-shimbun-folder-set-header-hash-internal
 130                folder
 131                (setq hash (elmo-make-hash))))
 132             (elmo-set-hash-val (elmo-message-entity-field entity
 133                                                           'message-id)
 134                                header
 135                                hash)
 136             header)))))
 137
 138 (defsubst elmo-shimbun-lapse-seconds (time)
 139   (let ((now (current-time)))
 140     (+ (* (- (car now) (car time)) 65536)
 141        (- (nth 1 now) (nth 1 time)))))
 142
 143 (defun elmo-shimbun-parse-time-string (string)
 144   "Parse the time-string STRING and return its time as Emacs style."
 145   (ignore-errors
 146     (let ((x (timezone-fix-time string nil nil)))
 147       (encode-time (aref x 5) (aref x 4) (aref x 3)
 148                    (aref x 2) (aref x 1) (aref x 0)
 149                    (aref x 6)))))
 150
 151 (defsubst elmo-shimbun-headers-check-p (folder)
 152   (or (null (elmo-shimbun-folder-last-check-internal folder))
 153       (and (elmo-shimbun-folder-last-check-internal folder)
 154            (> (elmo-shimbun-lapse-seconds
 155                (elmo-shimbun-folder-last-check-internal folder))
 156               elmo-shimbun-check-interval))))
 157
 158 (defun elmo-shimbun-entity-to-header (entity)
 159   (let (message-id shimbun-id)
 160     (if (setq message-id (elmo-message-entity-field
 161                           entity 'x-original-id))
 162         (setq shimbun-id (elmo-message-entity-field entity 'message-id))
 163       (setq message-id (elmo-message-entity-field entity 'message-id)
 164             shimbun-id nil))
 165     (elmo-with-enable-multibyte
 166       (shimbun-make-header
 167        (elmo-message-entity-number entity)
 168        (shimbun-mime-encode-string
 169         (elmo-message-entity-field entity 'subject 'decode))
 170        (shimbun-mime-encode-string
 171         (elmo-message-entity-field entity 'from 'decode))
 172        (elmo-message-entity-field entity 'date)
 173        message-id
 174        (elmo-message-entity-field entity 'references)
 175        0
 176        0
 177        (elmo-message-entity-field entity 'xref)
 178        (and shimbun-id
 179             (list (cons "x-shimbun-id" shimbun-id)))))))
 180
 181 (defsubst elmo-shimbun-folder-header-hash-setup (folder headers)
 182   (let ((hash (or (elmo-shimbun-folder-header-hash-internal folder)
 183                   (elmo-make-hash (length headers)))))
 184     (dolist (header headers)
 185       (elmo-set-hash-val (shimbun-header-id header) header hash))
 186     (elmo-shimbun-folder-set-header-hash-internal folder hash)))
 187
 188 (defun elmo-shimbun-get-headers (folder)
 189   (let* ((shimbun (elmo-shimbun-folder-shimbun-internal folder))
 190          (key (concat (shimbun-server shimbun)
 191                       "." (shimbun-current-group shimbun)))
 192          (elmo-hash-minimum-size 63)
 193          headers)
 194     ;; new headers.
 195     (setq headers
 196           (delq nil
 197                 (mapcar
 198                  (lambda (x)
 199                    (unless (elmo-message-entity folder (shimbun-header-id x))
 200                      x))
 201                  ;; This takes much time.
 202                  (shimbun-headers
 203                   (elmo-shimbun-folder-shimbun-internal folder)
 204                   (elmo-shimbun-folder-range-internal folder)))))
 205     (elmo-shimbun-folder-set-headers-internal folder headers)
 206     (when headers
 207       (elmo-shimbun-folder-header-hash-setup folder headers))
 208     (elmo-shimbun-folder-set-last-check-internal folder (current-time))))
 209
 210 (luna-define-method elmo-folder-initialize ((folder
 211                                              elmo-shimbun-folder)
 212                                             name)
 213   (if (string= name "")
 214       folder
 215     (let ((server-group (if (string-match "\\([^.]+\\)\\." name)
 216                             (list (elmo-match-string 1 name)
 217                                   (substring name (match-end 0)))
 218                           (list name))))
 219       (when (nth 0 server-group) ; server
 220         (elmo-shimbun-folder-set-shimbun-internal
 221          folder
 222          (condition-case nil
 223              (shimbun-open (nth 0 server-group)
 224                            (luna-make-entity 'shimbun-elmo-mua :folder folder))
 225            (file-error
 226             (luna-make-entity 'shimbun :server (nth 0 server-group))))))
 227       (when (nth 1 server-group)
 228         (elmo-shimbun-folder-set-group-internal
 229          folder
 230          (nth 1 server-group)))
 231       (elmo-shimbun-folder-set-range-internal
 232        folder
 233        (or (cdr (elmo-string-matched-assoc (elmo-folder-name-internal folder)
 234                                            elmo-shimbun-index-range-alist))
 235            elmo-shimbun-default-index-range))
 236       folder)))
 237
 238 (luna-define-method elmo-folder-open-internal ((folder elmo-shimbun-folder))
 239   (when (elmo-shimbun-folder-shimbun-internal folder)
 240     (shimbun-open-group
 241      (elmo-shimbun-folder-shimbun-internal folder)
 242      (elmo-shimbun-folder-group-internal folder))
 243     (let ((inhibit-quit t))
 244       (unless (elmo-map-folder-location-alist-internal folder)
 245         (elmo-map-folder-location-setup
 246          folder
 247          (elmo-msgdb-location-load (elmo-folder-msgdb-path folder))))
 248       (when (and (elmo-folder-plugged-p folder)
 249                  (elmo-shimbun-headers-check-p folder))
 250         (elmo-shimbun-get-headers folder)
 251         (elmo-map-folder-update-locations
 252          folder
 253          (elmo-map-folder-list-message-locations folder))))))
 254
 255 (luna-define-method elmo-folder-reserve-status-p ((folder elmo-shimbun-folder))
 256   t)
 257
 258 (luna-define-method elmo-folder-local-p ((folder elmo-shimbun-folder))
 259   nil)
 260
 261 (luna-define-method elmo-message-use-cache-p ((folder elmo-shimbun-folder)
 262                                               number)
 263   elmo-shimbun-use-cache)
 264
 265 (luna-define-method elmo-folder-close-internal :after ((folder
 266                                                         elmo-shimbun-folder))
 267   (shimbun-close-group
 268    (elmo-shimbun-folder-shimbun-internal folder))
 269   (elmo-shimbun-folder-set-headers-internal
 270    folder nil)
 271   (elmo-shimbun-folder-set-header-hash-internal
 272    folder nil)
 273   (elmo-shimbun-folder-set-entity-hash-internal
 274    folder nil)
 275   (elmo-shimbun-folder-set-last-check-internal
 276    folder nil))
 277
 278 (luna-define-method elmo-folder-plugged-p ((folder elmo-shimbun-folder))
 279   (if (elmo-shimbun-folder-shimbun-internal folder)
 280       (elmo-plugged-p
 281        "shimbun"
 282        (shimbun-server (elmo-shimbun-folder-shimbun-internal folder))
 283        nil nil
 284        (shimbun-server (elmo-shimbun-folder-shimbun-internal folder)))
 285     t))
 286
 287 (luna-define-method elmo-folder-set-plugged ((folder elmo-shimbun-folder)
 288                                              plugged &optional add)
 289   (elmo-set-plugged plugged
 290                     "shimbun"
 291                     (shimbun-server
 292                      (elmo-shimbun-folder-shimbun-internal folder))
 293                     nil nil nil
 294                     (shimbun-server
 295                      (elmo-shimbun-folder-shimbun-internal folder))
 296                     add))
 297
 298 (luna-define-method elmo-net-port-info ((folder elmo-shimbun-folder))
 299   (list "shimbun"
 300         (shimbun-server
 301          (elmo-shimbun-folder-shimbun-internal folder))
 302         nil))
 303
 304 (luna-define-method elmo-folder-check :around ((folder elmo-shimbun-folder))
 305   (when (shimbun-current-group
 306          (elmo-shimbun-folder-shimbun-internal folder))
 307     (when (and (elmo-folder-plugged-p folder)
 308                (elmo-shimbun-headers-check-p folder))
 309       (elmo-shimbun-get-headers folder)
 310       (luna-call-next-method))))
 311
 312 (luna-define-method elmo-folder-clear :around ((folder elmo-shimbun-folder)
 313                                                &optional keep-killed)
 314   (elmo-shimbun-folder-set-headers-internal folder nil)
 315   (elmo-shimbun-folder-set-header-hash-internal folder nil)
 316   (elmo-shimbun-folder-set-entity-hash-internal folder nil)
 317   (elmo-shimbun-folder-set-last-check-internal folder nil)
 318   (luna-call-next-method))
 319
 320 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 321                                                     elmo-shimbun-folder))
 322   (expand-file-name
 323    (concat (shimbun-server
 324             (elmo-shimbun-folder-shimbun-internal folder))
 325            "/"
 326            (elmo-shimbun-folder-group-internal folder))
 327    (expand-file-name "shimbun" elmo-msgdb-directory)))
 328
 329 (defun elmo-shimbun-msgdb-create-entity (folder number)
 330   (let ((header (elmo-shimbun-folder-shimbun-header
 331                  folder
 332                  (elmo-map-message-location folder number)))
 333         ov)
 334     (when header
 335       (with-temp-buffer
 336         (shimbun-header-insert
 337          (elmo-shimbun-folder-shimbun-internal folder)
 338          header)
 339         (setq ov (elmo-msgdb-create-message-entity-from-buffer
 340                   (elmo-msgdb-message-entity-handler
 341                    (elmo-folder-msgdb-internal folder)) number))
 342         (elmo-message-entity-set-field
 343          ov
 344          'xref (shimbun-header-xref header)))
 345       ov)))
 346
 347 (luna-define-method elmo-folder-msgdb-create ((folder elmo-shimbun-folder)
 348                                               numlist flag-table)
 349   (let ((new-msgdb (elmo-make-msgdb))
 350         entity i percent length msgid flags)
 351     (setq length (length numlist))
 352     (setq i 0)
 353     (message "Creating msgdb...")
 354     (while numlist
 355       (setq entity
 356             (elmo-shimbun-msgdb-create-entity
 357              folder (car numlist)))
 358       (when entity
 359         (setq msgid (elmo-message-entity-field entity 'message-id)
 360               flags (elmo-flag-table-get flag-table msgid))
 361         (elmo-global-flags-set flags folder (car numlist) msgid)
 362         (elmo-msgdb-append-entity new-msgdb entity flags))
 363       (when (> length elmo-display-progress-threshold)
 364         (setq i (1+ i))
 365         (setq percent (/ (* i 100) length))
 366         (elmo-display-progress
 367          'elmo-folder-msgdb-create "Creating msgdb..."
 368          percent))
 369       (setq numlist (cdr numlist)))
 370     (message "Creating msgdb...done")
 371     (elmo-msgdb-sort-by-date new-msgdb)))
 372
 373 (luna-define-method elmo-folder-message-file-p ((folder elmo-shimbun-folder))
 374   nil)
 375
 376 (defsubst elmo-shimbun-update-overview (folder shimbun-id header)
 377   (let ((entity (elmo-message-entity folder shimbun-id))
 378         (message-id (shimbun-header-id header))
 379         references)
 380     (when (elmo-msgdb-update-entity
 381            (elmo-folder-msgdb folder)
 382            entity
 383            (nconc
 384             (unless (string= shimbun-id message-id)
 385               (elmo-shimbun-header-set-extra-field
 386                header "x-shimbun-id" shimbun-id)
 387               (elmo-set-hash-val message-id
 388                                  entity
 389                                  (elmo-shimbun-folder-entity-hash folder))
 390               (elmo-set-hash-val shimbun-id
 391                                  entity
 392                                  (elmo-shimbun-folder-entity-hash folder))
 393               (list (cons 'x-original-id message-id)))
 394             (list
 395              (cons 'from
 396                    (elmo-mime-string (shimbun-header-from header)))
 397              (cons 'subject
 398                    (elmo-mime-string (shimbun-header-subject header)))
 399              (cons 'date
 400                    (shimbun-header-date header))
 401              (cons 'references
 402                    (or (elmo-msgdb-get-last-message-id
 403                         (elmo-field-body "in-reply-to"))
 404                        (elmo-msgdb-get-last-message-id
 405                         (elmo-field-body "references")))))))
 406       (elmo-emit-signal 'update-overview folder
 407                         (elmo-message-entity-number entity)))))
 408
 409 (luna-define-method elmo-map-message-fetch ((folder elmo-shimbun-folder)
 410                                             location strategy
 411                                             &optional section unseen)
 412   (if (elmo-folder-plugged-p folder)
 413       (let ((header (elmo-shimbun-folder-shimbun-header
 414                      folder
 415                      location))
 416             shimbun-id)
 417         (shimbun-article (elmo-shimbun-folder-shimbun-internal folder)
 418                          header)
 419         (when (or (eq elmo-shimbun-update-overview-folder-list 'all)
 420                   (elmo-string-match-member
 421                    (elmo-folder-name-internal folder)
 422                    elmo-shimbun-update-overview-folder-list))
 423           (elmo-shimbun-update-overview folder location header))
 424         (when (setq shimbun-id
 425                     (elmo-shimbun-header-extra-field header "x-shimbun-id"))
 426           (goto-char (point-min))
 427           (insert (format "X-Shimbun-Id: %s\n" shimbun-id)))
 428         t)
 429     (error "Unplugged")))
 430
 431 (luna-define-method elmo-message-encache :around ((folder
 432                                                    elmo-shimbun-folder)
 433                                                   number &optional read)
 434   (if (elmo-folder-plugged-p folder)
 435       (luna-call-next-method)
 436     (if elmo-enable-disconnected-operation
 437         (elmo-message-encache-dop folder number read)
 438       (error "Unplugged"))))
 439
 440 (luna-define-method elmo-folder-list-messages-internal :around
 441   ((folder elmo-shimbun-folder) &optional nohide)
 442   (if (elmo-folder-plugged-p folder)
 443       (luna-call-next-method)
 444     t))
 445
 446 (luna-define-method elmo-map-folder-list-message-locations
 447   ((folder elmo-shimbun-folder))
 448   (let ((expire-days (shimbun-article-expiration-days
 449                       (elmo-shimbun-folder-shimbun-internal folder))))
 450     (elmo-uniq-list
 451      (nconc
 452       (delq nil
 453             (mapcar
 454              (lambda (ov)
 455                (when (and (elmo-message-entity-field ov 'xref)
 456                           (if expire-days
 457                               (< (elmo-shimbun-lapse-seconds
 458                                   (elmo-shimbun-parse-time-string
 459                                    (elmo-message-entity-field ov 'date)))
 460                                  (* expire-days 86400 ; seconds per day
 461                                     ))
 462                             t))
 463                  (elmo-message-entity-field ov 'message-id)))
 464              (elmo-folder-list-message-entities folder)))
 465       (mapcar
 466        (lambda (header)
 467          (or (elmo-shimbun-header-extra-field header "x-shimbun-id")
 468              (shimbun-header-id header)))
 469        (elmo-shimbun-folder-headers-internal folder))))))
 470
 471 (luna-define-method elmo-folder-list-subfolders ((folder elmo-shimbun-folder)
 472                                                  &optional one-level)
 473   (let ((prefix (elmo-folder-prefix-internal folder)))
 474     (cond ((elmo-shimbun-folder-shimbun-internal folder)
 475            (unless (elmo-shimbun-folder-group-internal folder)
 476              (mapcar
 477               (lambda (fld)
 478                 (concat prefix
 479                         (shimbun-server
 480                          (elmo-shimbun-folder-shimbun-internal folder))
 481                         "." fld))
 482               (shimbun-groups (elmo-shimbun-folder-shimbun-internal folder)))))
 483           ;; the rest are for "@/" group
 484           (one-level
 485            (mapcar
 486             (lambda (server) (list (concat prefix server)))
 487             (shimbun-servers-list)))
 488           (t
 489            (let (folders)
 490              (dolist (server (shimbun-servers-list))
 491                (setq folders
 492                      (append folders
 493                              (mapcar
 494                               (lambda (fld) (concat prefix server "." fld))
 495                               (shimbun-groups
 496                                (shimbun-open server
 497                                              (let ((fld
 498                                                     (elmo-make-folder
 499                                                      (concat prefix server))))
 500                                                (luna-make-entity
 501                                                 'shimbun-elmo-mua
 502                                                 :folder fld))))))))
 503              folders)))))
 504
 505 (luna-define-method elmo-folder-exists-p ((folder elmo-shimbun-folder))
 506   (if (elmo-shimbun-folder-group-internal folder)
 507       (if (fboundp 'shimbun-group-p)
 508           (shimbun-group-p (elmo-shimbun-folder-shimbun-internal folder)
 509                            (elmo-shimbun-folder-group-internal folder))
 510         (member
 511          (elmo-shimbun-folder-group-internal folder)
 512          (shimbun-groups (elmo-shimbun-folder-shimbun-internal folder))))
 513     t))
 514
 515 (luna-define-method elmo-folder-delete-messages ((folder elmo-shimbun-folder)
 516                                                  numbers)
 517   (elmo-folder-kill-messages folder numbers)
 518   t)
 519
 520 (luna-define-method elmo-message-entity-parent ((folder elmo-shimbun-folder)
 521                                                 entity)
 522   (let ((references (elmo-message-entity-field entity 'references)))
 523     (and references
 524          (elmo-get-hash-val references
 525                             (elmo-shimbun-folder-entity-hash folder)))))
 526
 527 (require 'product)
 528 (product-provide (provide 'elmo-shimbun) (require 'elmo-version))
 529
 530 ;;; elmo-shimbun.el ends here