elmo/elmo-shimbun.el

   1 ;;; elmo-shimbun.el --- Shimbun interface for ELMO.
   2
   3 ;; Copyright (C) 2001 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'elmo)
  32 (require 'elmo-map)
  33 (require 'elmo-dop)
  34 (require 'shimbun)
  35
  36 (eval-when-compile
  37   (defun-maybe shimbun-servers-list ()))
  38
  39 (defcustom elmo-shimbun-check-interval 60
  40   "*Check interval for shimbun."
  41   :type 'integer
  42   :group 'elmo)
  43
  44 (defcustom elmo-shimbun-default-index-range 2
  45   "*Default value for the range of header indices."
  46   :type '(choice (const :tag "all" all)
  47                  (const :tag "last" last)
  48                  (integer :tag "number"))
  49   :group 'elmo)
  50
  51 (defcustom elmo-shimbun-use-cache t
  52   "*If non-nil, use cache for each article."
  53   :type 'boolean
  54   :group 'elmo)
  55
  56 (defcustom elmo-shimbun-index-range-alist nil
  57   "*Alist of FOLDER-REGEXP and RANGE.
  58 FOLDER-REGEXP is the regexp for shimbun folder name.
  59 RANGE is the range of the header indices .
  60 See `shimbun-headers' for more detail about RANGE."
  61   :type '(repeat (cons (regexp :tag "Folder Regexp")
  62                        (choice (const :tag "all" all)
  63                                (const :tag "last" last)
  64                                (integer :tag "number"))))
  65   :group 'elmo)
  66
  67 (defcustom elmo-shimbun-update-overview-folder-list nil
  68   "*List of FOLDER-REGEXP.
  69 FOLDER-REGEXP is the regexp of shimbun folder name which should be
  70 update overview when message is fetched."
  71   :type '(repeat (regexp :tag "Folder Regexp"))
  72   :group 'elmo)
  73
  74 ;; Shimbun header.
  75 (defsubst elmo-shimbun-header-extra-field (header field-name)
  76   (let ((extra (and header (shimbun-header-extra header))))
  77     (and extra
  78          (cdr (assoc field-name extra)))))
  79
  80 (defsubst elmo-shimbun-header-set-extra-field (header field-name value)
  81   (let ((extras (and header (shimbun-header-extra header)))
  82         extra)
  83     (if (setq extra (assoc field-name extras))
  84         (setcdr extra value)
  85       (shimbun-header-set-extra
  86        header
  87        (cons (cons field-name value) extras)))))
  88
  89 ;; Shimbun mua.
  90 (eval-and-compile
  91   (luna-define-class shimbun-elmo-mua (shimbun-mua) (folder))
  92   (luna-define-internal-accessors 'shimbun-elmo-mua))
  93
  94 (luna-define-method shimbun-mua-search-id ((mua shimbun-elmo-mua) id)
  95   (elmo-msgdb-overview-get-entity id
  96                                   (elmo-folder-msgdb
  97                                    (shimbun-elmo-mua-folder-internal mua))))
  98
  99 (eval-and-compile
 100   (luna-define-class elmo-shimbun-folder
 101                      (elmo-map-folder) (shimbun headers header-hash
 102                                                 entity-hash
 103                                                 group range last-check))
 104   (luna-define-internal-accessors 'elmo-shimbun-folder))
 105
 106 (defun elmo-shimbun-folder-entity-hash (folder)
 107   (or (elmo-shimbun-folder-entity-hash-internal folder)
 108       (let ((overviews (elmo-msgdb-get-overview (elmo-folder-msgdb folder)))
 109             hash id)
 110         (when overviews
 111           (setq hash (elmo-make-hash (length overviews)))
 112           (dolist (entity overviews)
 113             (elmo-set-hash-val (elmo-msgdb-overview-entity-get-id entity)
 114                                entity hash)
 115             (when (setq id (elmo-msgdb-overview-entity-get-extra-field
 116                             entity "x-original-id"))
 117               (elmo-set-hash-val id entity hash)))
 118           (elmo-shimbun-folder-set-entity-hash-internal folder hash)))))
 119
 120 (defsubst elmo-shimbun-folder-shimbun-header (folder location)
 121   (let ((hash (elmo-shimbun-folder-header-hash-internal folder)))
 122     (or (and hash (elmo-get-hash-val location hash))
 123         (let ((entity (elmo-msgdb-overview-get-entity
 124                        location
 125                        (elmo-folder-msgdb folder)))
 126               (elmo-hash-minimum-size 63)
 127               header)
 128           (when entity
 129             (setq header (elmo-shimbun-entity-to-header entity))
 130             (unless hash
 131               (elmo-shimbun-folder-set-header-hash-internal
 132                folder
 133                (setq hash (elmo-make-hash))))
 134             (elmo-set-hash-val (elmo-msgdb-overview-entity-get-id entity)
 135                                header
 136                                hash)
 137             header)))))
 138
 139 (defsubst elmo-shimbun-lapse-seconds (time)
 140   (let ((now (current-time)))
 141     (+ (* (- (car now) (car time)) 65536)
 142        (- (nth 1 now) (nth 1 time)))))
 143
 144 (defun elmo-shimbun-parse-time-string (string)
 145   "Parse the time-string STRING and return its time as Emacs style."
 146   (ignore-errors
 147     (let ((x (timezone-fix-time string nil nil)))
 148       (encode-time (aref x 5) (aref x 4) (aref x 3)
 149                    (aref x 2) (aref x 1) (aref x 0)
 150                    (aref x 6)))))
 151
 152 (defsubst elmo-shimbun-headers-check-p (folder)
 153   (or (null (elmo-shimbun-folder-last-check-internal folder))
 154       (and (elmo-shimbun-folder-last-check-internal folder)
 155            (> (elmo-shimbun-lapse-seconds
 156                (elmo-shimbun-folder-last-check-internal folder))
 157               elmo-shimbun-check-interval))))
 158
 159 (defun elmo-shimbun-entity-to-header (entity)
 160   (let (message-id shimbun-id)
 161     (if (setq message-id (elmo-msgdb-overview-entity-get-extra-field
 162                           entity "x-original-id"))
 163         (setq shimbun-id (elmo-msgdb-overview-entity-get-id entity))
 164       (setq message-id (elmo-msgdb-overview-entity-get-id entity)
 165             shimbun-id nil))
 166     (elmo-set-work-buf
 167      (set-buffer-multibyte t)
 168      (shimbun-make-header
 169       (elmo-msgdb-overview-entity-get-number entity)
 170       (shimbun-mime-encode-string
 171        (decode-mime-charset-string
 172         (elmo-msgdb-overview-entity-get-subject-no-decode entity)
 173         elmo-mime-charset))
 174       (shimbun-mime-encode-string
 175        (decode-mime-charset-string
 176         (elmo-msgdb-overview-entity-get-from-no-decode entity)
 177         elmo-mime-charset))
 178       (elmo-msgdb-overview-entity-get-date entity)
 179       message-id
 180       (elmo-msgdb-overview-entity-get-references entity)
 181       0
 182       0
 183       (elmo-msgdb-overview-entity-get-extra-field entity "xref")
 184       (and shimbun-id
 185            (list (cons "x-shimbun-id" shimbun-id)))))))
 186
 187 (defsubst elmo-shimbun-folder-header-hash-setup (folder headers)
 188   (let ((hash (or (elmo-shimbun-folder-header-hash-internal folder)
 189                   (elmo-make-hash (length headers)))))
 190     (dolist (header headers)
 191       (elmo-set-hash-val (shimbun-header-id header) header hash))
 192     (elmo-shimbun-folder-set-header-hash-internal folder hash)))
 193
 194 (defun elmo-shimbun-get-headers (folder)
 195   (let* ((shimbun (elmo-shimbun-folder-shimbun-internal folder))
 196          (key (concat (shimbun-server shimbun)
 197                       "." (shimbun-current-group shimbun)))
 198          (elmo-hash-minimum-size 63)
 199          headers)
 200     ;; new headers.
 201     (setq headers
 202           (delq nil
 203                 (mapcar
 204                  (lambda (x)
 205                    (unless (elmo-msgdb-overview-get-entity
 206                             (shimbun-header-id x)
 207                             (elmo-folder-msgdb folder))
 208                      x))
 209                  ;; This takes much time.
 210                  (shimbun-headers
 211                   (elmo-shimbun-folder-shimbun-internal folder)
 212                   (elmo-shimbun-folder-range-internal folder)))))
 213     (elmo-shimbun-folder-set-headers-internal folder headers)
 214     (when headers
 215       (elmo-shimbun-folder-header-hash-setup folder headers))
 216     (elmo-shimbun-folder-set-last-check-internal folder (current-time))))
 217
 218 (luna-define-method elmo-folder-initialize ((folder
 219                                              elmo-shimbun-folder)
 220                                             name)
 221   (if (string= name "")
 222       folder
 223     (let ((server-group (if (string-match "\\([^.]+\\)\\." name)
 224                             (list (elmo-match-string 1 name)
 225                                   (substring name (match-end 0)))
 226                           (list name))))
 227       (when (nth 0 server-group) ; server
 228         (elmo-shimbun-folder-set-shimbun-internal
 229          folder
 230          (shimbun-open (nth 0 server-group)
 231                        (luna-make-entity 'shimbun-elmo-mua :folder folder))))
 232       (when (nth 1 server-group)
 233         (elmo-shimbun-folder-set-group-internal
 234          folder
 235          (nth 1 server-group)))
 236       (elmo-shimbun-folder-set-range-internal
 237        folder
 238        (or (cdr (elmo-string-matched-assoc (elmo-folder-name-internal folder)
 239                                            elmo-shimbun-index-range-alist))
 240            elmo-shimbun-default-index-range))
 241       folder)))
 242
 243 (luna-define-method elmo-folder-open-internal ((folder elmo-shimbun-folder))
 244   (when (elmo-shimbun-folder-shimbun-internal folder)
 245     (shimbun-open-group
 246      (elmo-shimbun-folder-shimbun-internal folder)
 247      (elmo-shimbun-folder-group-internal folder))
 248     (let ((inhibit-quit t))
 249       (unless (elmo-map-folder-location-alist-internal folder)
 250         (elmo-map-folder-location-setup
 251          folder
 252          (elmo-msgdb-location-load (elmo-folder-msgdb-path folder))))
 253       (when (and (elmo-folder-plugged-p folder)
 254                  (elmo-shimbun-headers-check-p folder))
 255         (elmo-shimbun-get-headers folder)
 256         (elmo-map-folder-update-locations
 257          folder
 258          (elmo-map-folder-list-message-locations folder))))))
 259
 260 (luna-define-method elmo-folder-reserve-status-p ((folder elmo-shimbun-folder))
 261   t)
 262
 263 (luna-define-method elmo-folder-local-p ((folder elmo-shimbun-folder))
 264   nil)
 265
 266 (luna-define-method elmo-message-use-cache-p ((folder elmo-shimbun-folder)
 267                                               number)
 268   elmo-shimbun-use-cache)
 269
 270 (luna-define-method elmo-folder-close-internal :after ((folder
 271                                                         elmo-shimbun-folder))
 272   (shimbun-close-group
 273    (elmo-shimbun-folder-shimbun-internal folder))
 274   (elmo-shimbun-folder-set-headers-internal
 275    folder nil)
 276   (elmo-shimbun-folder-set-header-hash-internal
 277    folder nil)
 278   (elmo-shimbun-folder-set-entity-hash-internal
 279    folder nil)
 280   (elmo-shimbun-folder-set-last-check-internal
 281    folder nil))
 282
 283 (luna-define-method elmo-folder-plugged-p ((folder elmo-shimbun-folder))
 284   (elmo-plugged-p
 285    "shimbun"
 286    (and (elmo-shimbun-folder-shimbun-internal folder)
 287         (shimbun-server (elmo-shimbun-folder-shimbun-internal folder)))
 288    nil nil
 289    (and (elmo-shimbun-folder-shimbun-internal folder)
 290         (shimbun-server (elmo-shimbun-folder-shimbun-internal folder)))))
 291
 292 (luna-define-method elmo-folder-set-plugged ((folder elmo-shimbun-folder)
 293                                              plugged &optional add)
 294   (elmo-set-plugged plugged
 295                     "shimbun"
 296                     (shimbun-server
 297                      (elmo-shimbun-folder-shimbun-internal folder))
 298                     nil nil nil
 299                     (shimbun-server
 300                      (elmo-shimbun-folder-shimbun-internal folder))
 301                     add))
 302
 303 (luna-define-method elmo-net-port-info ((folder elmo-shimbun-folder))
 304   (list "shimbun"
 305         (shimbun-server
 306          (elmo-shimbun-folder-shimbun-internal folder))
 307         nil))
 308
 309 (luna-define-method elmo-folder-check :around ((folder elmo-shimbun-folder))
 310   (when (shimbun-current-group
 311          (elmo-shimbun-folder-shimbun-internal folder))
 312     (when (and (elmo-folder-plugged-p folder)
 313                (elmo-shimbun-headers-check-p folder))
 314       (elmo-shimbun-get-headers folder)
 315       (luna-call-next-method))))
 316
 317 (luna-define-method elmo-folder-clear :around ((folder elmo-shimbun-folder)
 318                                                &optional keep-killed)
 319   (elmo-shimbun-folder-set-headers-internal folder nil)
 320   (elmo-shimbun-folder-set-header-hash-internal folder nil)
 321   (elmo-shimbun-folder-set-entity-hash-internal folder nil)
 322   (elmo-shimbun-folder-set-last-check-internal folder nil)
 323   (luna-call-next-method))
 324
 325 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 326                                                     elmo-shimbun-folder))
 327   (expand-file-name
 328    (concat (shimbun-server
 329             (elmo-shimbun-folder-shimbun-internal folder))
 330            "/"
 331            (elmo-shimbun-folder-group-internal folder))
 332    (expand-file-name "shimbun" elmo-msgdb-directory)))
 333
 334 (defun elmo-shimbun-msgdb-create-entity (folder number)
 335   (let ((header (elmo-shimbun-folder-shimbun-header
 336                  folder
 337                  (elmo-map-message-location folder number)))
 338         ov)
 339     (when header
 340       (with-temp-buffer
 341         (shimbun-header-insert
 342          (elmo-shimbun-folder-shimbun-internal folder)
 343          header)
 344         (setq ov (elmo-msgdb-create-overview-from-buffer number))
 345         (elmo-msgdb-overview-entity-set-extra
 346          ov
 347          (nconc
 348           (elmo-msgdb-overview-entity-get-extra ov)
 349           (list (cons "xref" (shimbun-header-xref header)))))))))
 350
 351 (luna-define-method elmo-folder-msgdb-create ((folder elmo-shimbun-folder)
 352                                               numlist flag-table)
 353   (let* (overview number-alist mark-alist entity
 354                   i percent number length pair msgid gmark seen)
 355     (setq length (length numlist))
 356     (setq i 0)
 357     (message "Creating msgdb...")
 358     (while numlist
 359       (setq entity
 360             (elmo-shimbun-msgdb-create-entity
 361              folder (car numlist)))
 362       (when entity
 363         (setq overview
 364               (elmo-msgdb-append-element
 365                overview entity))
 366         (setq number (elmo-msgdb-overview-entity-get-number entity))
 367         (setq msgid (elmo-msgdb-overview-entity-get-id entity))
 368         (setq number-alist
 369               (elmo-msgdb-number-add number-alist
 370                                      number msgid))
 371         (if (setq gmark (or (elmo-msgdb-global-mark-get msgid)
 372                             (elmo-msgdb-mark
 373                              (elmo-flag-table-get flag-table msgid)
 374                              (elmo-file-cache-status
 375                               (elmo-file-cache-get msgid))
 376                              'new)))
 377             (setq mark-alist
 378                   (elmo-msgdb-mark-append mark-alist
 379                                           number gmark))))
 380       (when (> length elmo-display-progress-threshold)
 381         (setq i (1+ i))
 382         (setq percent (/ (* i 100) length))
 383         (elmo-display-progress
 384          'elmo-folder-msgdb-create "Creating msgdb..."
 385          percent))
 386       (setq numlist (cdr numlist)))
 387     (message "Creating msgdb...done")
 388     (elmo-msgdb-sort-by-date
 389      (list overview number-alist mark-alist))))
 390
 391 (luna-define-method elmo-folder-message-file-p ((folder elmo-shimbun-folder))
 392   nil)
 393
 394 (defsubst elmo-shimbun-update-overview (folder shimbun-id header)
 395   (let ((entity (elmo-msgdb-overview-get-entity shimbun-id
 396                                                 (elmo-folder-msgdb folder)))
 397         (message-id (shimbun-header-id header))
 398         references)
 399     (unless (string= shimbun-id message-id)
 400       (elmo-msgdb-overview-entity-set-extra-field
 401        entity "x-original-id" message-id)
 402       (elmo-shimbun-header-set-extra-field
 403        header "x-shimbun-id" shimbun-id)
 404       (elmo-set-hash-val message-id
 405                          entity
 406                          (elmo-shimbun-folder-entity-hash folder))
 407       (elmo-set-hash-val shimbun-id
 408                          entity
 409                          (elmo-shimbun-folder-entity-hash folder)))
 410     (elmo-msgdb-overview-entity-set-from
 411      entity
 412      (elmo-mime-string (shimbun-header-from header)))
 413     (elmo-msgdb-overview-entity-set-subject
 414      entity
 415      (elmo-mime-string (shimbun-header-subject header)))
 416     (elmo-msgdb-overview-entity-set-date
 417      entity (shimbun-header-date header))
 418     (when (setq references
 419                 (or (elmo-msgdb-get-last-message-id
 420                      (elmo-field-body "in-reply-to"))
 421                     (elmo-msgdb-get-last-message-id
 422                      (elmo-field-body "references"))))
 423       (elmo-msgdb-overview-entity-set-references
 424        entity
 425        (or (elmo-msgdb-overview-entity-get-id
 426             (elmo-get-hash-val
 427              references
 428              (elmo-shimbun-folder-entity-hash folder)))
 429            references)))))
 430
 431 (luna-define-method elmo-map-message-fetch ((folder elmo-shimbun-folder)
 432                                             location strategy
 433                                             &optional section unseen)
 434   (if (elmo-folder-plugged-p folder)
 435       (let ((header (elmo-shimbun-folder-shimbun-header
 436                      folder
 437                      location))
 438             shimbun-id)
 439         (shimbun-article (elmo-shimbun-folder-shimbun-internal folder)
 440                          header)
 441         (when (elmo-string-match-member
 442                (elmo-folder-name-internal folder)
 443                elmo-shimbun-update-overview-folder-list)
 444           (elmo-shimbun-update-overview folder location header))
 445         (when (setq shimbun-id
 446                     (elmo-shimbun-header-extra-field header "x-shimbun-id"))
 447           (goto-char (point-min))
 448           (insert (format "X-Shimbun-Id: %s\n" shimbun-id)))
 449         t)
 450     (error "Unplugged")))
 451
 452 (luna-define-method elmo-message-encache :around ((folder
 453                                                    elmo-shimbun-folder)
 454                                                   number &optional read)
 455   (if (elmo-folder-plugged-p folder)
 456       (luna-call-next-method)
 457     (if elmo-enable-disconnected-operation
 458         (elmo-message-encache-dop folder number read)
 459       (error "Unplugged"))))
 460
 461 (luna-define-method elmo-folder-list-messages-internal :around
 462   ((folder elmo-shimbun-folder) &optional nohide)
 463   (if (elmo-folder-plugged-p folder)
 464       (luna-call-next-method)
 465     t))
 466
 467 (luna-define-method elmo-map-folder-list-message-locations
 468   ((folder elmo-shimbun-folder))
 469   (let ((expire-days (shimbun-article-expiration-days
 470                       (elmo-shimbun-folder-shimbun-internal folder))))
 471     (elmo-uniq-list
 472      (nconc
 473       (delq nil
 474             (mapcar
 475              (lambda (ov)
 476                (when (and (elmo-msgdb-overview-entity-get-extra-field
 477                            ov "xref")
 478                           (if expire-days
 479                               (< (elmo-shimbun-lapse-seconds
 480                                   (elmo-shimbun-parse-time-string
 481                                    (elmo-msgdb-overview-entity-get-date ov)))
 482                                  (* expire-days 86400 ; seconds per day
 483                                     ))
 484                             t))
 485                  (elmo-msgdb-overview-entity-get-id ov)))
 486              (elmo-msgdb-get-overview (elmo-folder-msgdb folder))))
 487       (mapcar
 488        (lambda (header)
 489          (or (elmo-shimbun-header-extra-field header "x-shimbun-id")
 490              (shimbun-header-id header)))
 491        (elmo-shimbun-folder-headers-internal folder))))))
 492
 493 (luna-define-method elmo-folder-list-subfolders ((folder elmo-shimbun-folder)
 494                                                  &optional one-level)
 495   (let ((prefix (elmo-folder-prefix-internal folder)))
 496     (cond ((elmo-shimbun-folder-shimbun-internal folder)
 497            (unless (elmo-shimbun-folder-group-internal folder)
 498              (mapcar
 499               (lambda (fld)
 500                 (concat prefix
 501                         (shimbun-server
 502                          (elmo-shimbun-folder-shimbun-internal folder))
 503                         "." fld))
 504               (shimbun-groups (elmo-shimbun-folder-shimbun-internal folder)))))
 505           ;; the rest are for "@/" group
 506           (one-level
 507            (mapcar
 508             (lambda (server) (list (concat prefix server)))
 509             (shimbun-servers-list)))
 510           (t
 511            (let (folders)
 512              (dolist (server (shimbun-servers-list))
 513                (setq folders
 514                      (append folders
 515                              (mapcar
 516                               (lambda (fld) (concat prefix server "." fld))
 517                               (shimbun-groups
 518                                (shimbun-open server
 519                                              (let ((fld
 520                                                     (elmo-make-folder
 521                                                      (concat prefix server))))
 522                                                (luna-make-entity
 523                                                 'shimbun-elmo-mua
 524                                                 :folder fld))))))))
 525              folders)))))
 526
 527 (luna-define-method elmo-folder-exists-p ((folder elmo-shimbun-folder))
 528   (if (elmo-shimbun-folder-group-internal folder)
 529       (progn
 530         (member
 531          (elmo-shimbun-folder-group-internal folder)
 532          (shimbun-groups (elmo-shimbun-folder-shimbun-internal
 533                           folder))))
 534     t))
 535
 536 (require 'product)
 537 (product-provide (provide 'elmo-shimbun) (require 'elmo-version))
 538
 539 ;;; elmo-shimbun.el ends here