elmo/elmo-shimbun.el

   1 ;;; elmo-shimbun.el --- Shimbun interface for ELMO.
   2
   3 ;; Copyright (C) 2001 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'elmo)
  32 (require 'elmo-map)
  33 (require 'elmo-dop)
  34 (require 'shimbun)
  35
  36 (eval-when-compile
  37   (defun-maybe shimbun-servers-list ()))
  38
  39 (defcustom elmo-shimbun-check-interval 60
  40   "*Check interval for shimbun."
  41   :type 'integer
  42   :group 'elmo)
  43
  44 (defcustom elmo-shimbun-default-index-range 2
  45   "*Default value for the range of header indices."
  46   :type '(choice (const :tag "all" all)
  47                  (const :tag "last" last)
  48                  (integer :tag "number"))
  49   :group 'elmo)
  50
  51 (defcustom elmo-shimbun-use-cache t
  52   "*If non-nil, use cache for each article."
  53   :type 'boolean
  54   :group 'elmo)
  55
  56 (defcustom elmo-shimbun-index-range-alist nil
  57   "*Alist of FOLDER-REGEXP and RANGE.
  58 FOLDER-REGEXP is the regexp for shimbun folder name.
  59 RANGE is the range of the header indices .
  60 See `shimbun-headers' for more detail about RANGE."
  61   :type '(repeat (cons (regexp :tag "Folder Regexp")
  62                        (choice (const :tag "all" all)
  63                                (const :tag "last" last)
  64                                (integer :tag "number"))))
  65   :group 'elmo)
  66
  67 (defcustom elmo-shimbun-update-overview-folder-list nil
  68   "*List of FOLDER-REGEXP.
  69 FOLDER-REGEXP is the regexp of shimbun folder name which should be
  70 update overview when message is fetched."
  71   :type '(repeat (regexp :tag "Folder Regexp"))
  72   :group 'elmo)
  73
  74 ;; Shimbun header.
  75 (defsubst elmo-shimbun-header-extra-field (header field-name)
  76   (let ((extra (and header (shimbun-header-extra header))))
  77     (and extra
  78          (cdr (assoc field-name extra)))))
  79
  80 (defsubst elmo-shimbun-header-set-extra-field (header field-name value)
  81   (let ((extras (and header (shimbun-header-extra header)))
  82         extra)
  83     (if (setq extra (assoc field-name extras))
  84         (setcdr extra value)
  85       (shimbun-header-set-extra
  86        header
  87        (cons (cons field-name value) extras)))))
  88
  89 ;; Shimbun mua.
  90 (eval-and-compile
  91   (luna-define-class shimbun-elmo-mua (shimbun-mua) (folder))
  92   (luna-define-internal-accessors 'shimbun-elmo-mua))
  93
  94 (luna-define-method shimbun-mua-search-id ((mua shimbun-elmo-mua) id)
  95   (elmo-msgdb-message-entity (elmo-folder-msgdb
  96                               (shimbun-elmo-mua-folder-internal mua))
  97                              id))
  98
  99 (eval-and-compile
 100   (luna-define-class elmo-shimbun-folder
 101                      (elmo-map-folder) (shimbun headers header-hash
 102                                                 entity-hash
 103                                                 group range last-check))
 104   (luna-define-internal-accessors 'elmo-shimbun-folder))
 105
 106 (defun elmo-shimbun-folder-entity-hash (folder)
 107   (or (elmo-shimbun-folder-entity-hash-internal folder)
 108       (let ((overviews (elmo-folder-list-message-entities folder))
 109             hash id)
 110         (when overviews
 111           (setq hash (elmo-make-hash (length overviews)))
 112           (dolist (entity overviews)
 113             (elmo-set-hash-val (elmo-message-entity-field entity 'message-id)
 114                                entity hash)
 115             (when (setq id (elmo-message-entity-field entity 'x-original-id))
 116               (elmo-set-hash-val id entity hash)))
 117           (elmo-shimbun-folder-set-entity-hash-internal folder hash)))))
 118
 119 (defsubst elmo-shimbun-folder-shimbun-header (folder location)
 120   (let ((hash (elmo-shimbun-folder-header-hash-internal folder)))
 121     (or (and hash (elmo-get-hash-val location hash))
 122         (let ((entity (elmo-msgdb-message-entity
 123                        (elmo-folder-msgdb folder)
 124                        location))
 125               (elmo-hash-minimum-size 63)
 126               header)
 127           (when entity
 128             (setq header (elmo-shimbun-entity-to-header entity))
 129             (unless hash
 130               (elmo-shimbun-folder-set-header-hash-internal
 131                folder
 132                (setq hash (elmo-make-hash))))
 133             (elmo-set-hash-val (elmo-message-entity-field entity
 134                                                           'message-id)
 135                                header
 136                                hash)
 137             header)))))
 138
 139 (defsubst elmo-shimbun-lapse-seconds (time)
 140   (let ((now (current-time)))
 141     (+ (* (- (car now) (car time)) 65536)
 142        (- (nth 1 now) (nth 1 time)))))
 143
 144 (defun elmo-shimbun-parse-time-string (string)
 145   "Parse the time-string STRING and return its time as Emacs style."
 146   (ignore-errors
 147     (let ((x (timezone-fix-time string nil nil)))
 148       (encode-time (aref x 5) (aref x 4) (aref x 3)
 149                    (aref x 2) (aref x 1) (aref x 0)
 150                    (aref x 6)))))
 151
 152 (defsubst elmo-shimbun-headers-check-p (folder)
 153   (or (null (elmo-shimbun-folder-last-check-internal folder))
 154       (and (elmo-shimbun-folder-last-check-internal folder)
 155            (> (elmo-shimbun-lapse-seconds
 156                (elmo-shimbun-folder-last-check-internal folder))
 157               elmo-shimbun-check-interval))))
 158
 159 (defun elmo-shimbun-entity-to-header (entity)
 160   (let (message-id shimbun-id)
 161     (if (setq message-id (elmo-message-entity-field
 162                           entity 'x-original-id))
 163         (setq shimbun-id (elmo-message-entity-field entity 'message-id))
 164       (setq message-id (elmo-message-entity-field entity 'message-id)
 165             shimbun-id nil))
 166     (elmo-set-work-buf
 167      (set-buffer-multibyte t)
 168      (shimbun-make-header
 169       (elmo-message-entity-number entity)
 170       (shimbun-mime-encode-string
 171        (elmo-message-entity-field entity 'subject 'decode))
 172       (shimbun-mime-encode-string
 173        (elmo-message-entity-field entity 'from 'decode))
 174       (elmo-message-entity-field entity 'date)
 175       message-id
 176       (elmo-message-entity-field entity 'references)
 177       0
 178       0
 179       (elmo-message-entity-field entity 'xref)
 180       (and shimbun-id
 181            (list (cons "x-shimbun-id" shimbun-id)))))))
 182
 183 (defsubst elmo-shimbun-folder-header-hash-setup (folder headers)
 184   (let ((hash (or (elmo-shimbun-folder-header-hash-internal folder)
 185                   (elmo-make-hash (length headers)))))
 186     (dolist (header headers)
 187       (elmo-set-hash-val (shimbun-header-id header) header hash))
 188     (elmo-shimbun-folder-set-header-hash-internal folder hash)))
 189
 190 (defun elmo-shimbun-get-headers (folder)
 191   (let* ((shimbun (elmo-shimbun-folder-shimbun-internal folder))
 192          (key (concat (shimbun-server shimbun)
 193                       "." (shimbun-current-group shimbun)))
 194          (elmo-hash-minimum-size 63)
 195          headers)
 196     ;; new headers.
 197     (setq headers
 198           (delq nil
 199                 (mapcar
 200                  (lambda (x)
 201                    (unless (elmo-msgdb-message-entity
 202                             (elmo-folder-msgdb folder)
 203                             (shimbun-header-id x))
 204                      x))
 205                  ;; This takes much time.
 206                  (shimbun-headers
 207                   (elmo-shimbun-folder-shimbun-internal folder)
 208                   (elmo-shimbun-folder-range-internal folder)))))
 209     (elmo-shimbun-folder-set-headers-internal folder headers)
 210     (when headers
 211       (elmo-shimbun-folder-header-hash-setup folder headers))
 212     (elmo-shimbun-folder-set-last-check-internal folder (current-time))))
 213
 214 (luna-define-method elmo-folder-initialize ((folder
 215                                              elmo-shimbun-folder)
 216                                             name)
 217   (if (string= name "")
 218       folder
 219     (let ((server-group (if (string-match "\\([^.]+\\)\\." name)
 220                             (list (elmo-match-string 1 name)
 221                                   (substring name (match-end 0)))
 222                           (list name))))
 223       (when (nth 0 server-group) ; server
 224         (elmo-shimbun-folder-set-shimbun-internal
 225          folder
 226          (shimbun-open (nth 0 server-group)
 227                        (luna-make-entity 'shimbun-elmo-mua :folder folder))))
 228       (when (nth 1 server-group)
 229         (elmo-shimbun-folder-set-group-internal
 230          folder
 231          (nth 1 server-group)))
 232       (elmo-shimbun-folder-set-range-internal
 233        folder
 234        (or (cdr (elmo-string-matched-assoc (elmo-folder-name-internal folder)
 235                                            elmo-shimbun-index-range-alist))
 236            elmo-shimbun-default-index-range))
 237       folder)))
 238
 239 (luna-define-method elmo-folder-open-internal ((folder elmo-shimbun-folder))
 240   (when (elmo-shimbun-folder-shimbun-internal folder)
 241     (shimbun-open-group
 242      (elmo-shimbun-folder-shimbun-internal folder)
 243      (elmo-shimbun-folder-group-internal folder))
 244     (let ((inhibit-quit t))
 245       (unless (elmo-map-folder-location-alist-internal folder)
 246         (elmo-map-folder-location-setup
 247          folder
 248          (elmo-msgdb-location-load (elmo-folder-msgdb-path folder))))
 249       (when (and (elmo-folder-plugged-p folder)
 250                  (elmo-shimbun-headers-check-p folder))
 251         (elmo-shimbun-get-headers folder)
 252         (elmo-map-folder-update-locations
 253          folder
 254          (elmo-map-folder-list-message-locations folder))))))
 255
 256 (luna-define-method elmo-folder-reserve-status-p ((folder elmo-shimbun-folder))
 257   t)
 258
 259 (luna-define-method elmo-folder-local-p ((folder elmo-shimbun-folder))
 260   nil)
 261
 262 (luna-define-method elmo-message-use-cache-p ((folder elmo-shimbun-folder)
 263                                               number)
 264   elmo-shimbun-use-cache)
 265
 266 (luna-define-method elmo-folder-close-internal :after ((folder
 267                                                         elmo-shimbun-folder))
 268   (shimbun-close-group
 269    (elmo-shimbun-folder-shimbun-internal folder))
 270   (elmo-shimbun-folder-set-headers-internal
 271    folder nil)
 272   (elmo-shimbun-folder-set-header-hash-internal
 273    folder nil)
 274   (elmo-shimbun-folder-set-entity-hash-internal
 275    folder nil)
 276   (elmo-shimbun-folder-set-last-check-internal
 277    folder nil))
 278
 279 (luna-define-method elmo-folder-plugged-p ((folder elmo-shimbun-folder))
 280   (elmo-plugged-p
 281    "shimbun"
 282    (and (elmo-shimbun-folder-shimbun-internal folder)
 283         (shimbun-server (elmo-shimbun-folder-shimbun-internal folder)))
 284    nil nil
 285    (and (elmo-shimbun-folder-shimbun-internal folder)
 286         (shimbun-server (elmo-shimbun-folder-shimbun-internal folder)))))
 287
 288 (luna-define-method elmo-folder-set-plugged ((folder elmo-shimbun-folder)
 289                                              plugged &optional add)
 290   (elmo-set-plugged plugged
 291                     "shimbun"
 292                     (shimbun-server
 293                      (elmo-shimbun-folder-shimbun-internal folder))
 294                     nil nil nil
 295                     (shimbun-server
 296                      (elmo-shimbun-folder-shimbun-internal folder))
 297                     add))
 298
 299 (luna-define-method elmo-net-port-info ((folder elmo-shimbun-folder))
 300   (list "shimbun"
 301         (shimbun-server
 302          (elmo-shimbun-folder-shimbun-internal folder))
 303         nil))
 304
 305 (luna-define-method elmo-folder-check :around ((folder elmo-shimbun-folder))
 306   (when (shimbun-current-group
 307          (elmo-shimbun-folder-shimbun-internal folder))
 308     (when (and (elmo-folder-plugged-p folder)
 309                (elmo-shimbun-headers-check-p folder))
 310       (elmo-shimbun-get-headers folder)
 311       (luna-call-next-method))))
 312
 313 (luna-define-method elmo-folder-clear :around ((folder elmo-shimbun-folder)
 314                                                &optional keep-killed)
 315   (elmo-shimbun-folder-set-headers-internal folder nil)
 316   (elmo-shimbun-folder-set-header-hash-internal folder nil)
 317   (elmo-shimbun-folder-set-entity-hash-internal folder nil)
 318   (elmo-shimbun-folder-set-last-check-internal folder nil)
 319   (luna-call-next-method))
 320
 321 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 322                                                     elmo-shimbun-folder))
 323   (expand-file-name
 324    (concat (shimbun-server
 325             (elmo-shimbun-folder-shimbun-internal folder))
 326            "/"
 327            (elmo-shimbun-folder-group-internal folder))
 328    (expand-file-name "shimbun" elmo-msgdb-directory)))
 329
 330 (defun elmo-shimbun-msgdb-create-entity (folder number)
 331   (let ((header (elmo-shimbun-folder-shimbun-header
 332                  folder
 333                  (elmo-map-message-location folder number)))
 334         ov)
 335     (when header
 336       (with-temp-buffer
 337         (shimbun-header-insert
 338          (elmo-shimbun-folder-shimbun-internal folder)
 339          header)
 340         (setq ov (elmo-msgdb-create-message-entity-from-buffer
 341                   (elmo-msgdb-message-entity-handler
 342                    (elmo-folder-msgdb-internal folder)) number))
 343         (elmo-message-entity-set-field
 344          ov
 345          'xref (shimbun-header-xref header)))
 346       ov)))
 347
 348 (luna-define-method elmo-folder-msgdb-create ((folder elmo-shimbun-folder)
 349                                               numlist flag-table)
 350   (let ((new-msgdb (elmo-make-msgdb))
 351         entity i percent length msgid flags)
 352     (setq length (length numlist))
 353     (setq i 0)
 354     (message "Creating msgdb...")
 355     (while numlist
 356       (setq entity
 357             (elmo-shimbun-msgdb-create-entity
 358              folder (car numlist)))
 359       (when entity
 360         (setq msgid (elmo-message-entity-field entity 'message-id)
 361               flags (elmo-flag-table-get flag-table msgid))
 362         (elmo-global-flags-set flags folder (car numlist) msgid)
 363         (elmo-msgdb-append-entity new-msgdb entity flags))
 364       (when (> length elmo-display-progress-threshold)
 365         (setq i (1+ i))
 366         (setq percent (/ (* i 100) length))
 367         (elmo-display-progress
 368          'elmo-folder-msgdb-create "Creating msgdb..."
 369          percent))
 370       (setq numlist (cdr numlist)))
 371     (message "Creating msgdb...done")
 372     (elmo-msgdb-sort-by-date new-msgdb)))
 373
 374 (luna-define-method elmo-folder-message-file-p ((folder elmo-shimbun-folder))
 375   nil)
 376
 377 (defsubst elmo-shimbun-update-overview (folder shimbun-id header)
 378   (let ((entity (elmo-msgdb-message-entity (elmo-folder-msgdb folder)
 379                                            shimbun-id))
 380         (message-id (shimbun-header-id header))
 381         references)
 382     (unless (string= shimbun-id message-id)
 383       (elmo-message-entity-set-field
 384        entity 'x-original-id message-id)
 385       (elmo-shimbun-header-set-extra-field
 386        header "x-shimbun-id" shimbun-id)
 387       (elmo-set-hash-val message-id
 388                          entity
 389                          (elmo-shimbun-folder-entity-hash folder))
 390       (elmo-set-hash-val shimbun-id
 391                          entity
 392                          (elmo-shimbun-folder-entity-hash folder)))
 393     (elmo-message-entity-set-field
 394      entity
 395      'from
 396      (elmo-mime-string (shimbun-header-from header)))
 397     (elmo-message-entity-set-field
 398      entity
 399      'subject
 400      (elmo-mime-string (shimbun-header-subject header)))
 401     (elmo-message-entity-set-field
 402      entity
 403      'date
 404      (shimbun-header-date header))
 405     (when (setq references
 406                 (or (elmo-msgdb-get-last-message-id
 407                      (elmo-field-body "in-reply-to"))
 408                     (elmo-msgdb-get-last-message-id
 409                      (elmo-field-body "references"))))
 410       (elmo-message-entity-set-field
 411        entity
 412        'references
 413        (or (elmo-message-entity-field
 414             (elmo-get-hash-val
 415              references
 416              (elmo-shimbun-folder-entity-hash folder))
 417             'message-id)
 418            references)))))
 419
 420 (luna-define-method elmo-map-message-fetch ((folder elmo-shimbun-folder)
 421                                             location strategy
 422                                             &optional section unseen)
 423   (if (elmo-folder-plugged-p folder)
 424       (let ((header (elmo-shimbun-folder-shimbun-header
 425                      folder
 426                      location))
 427             shimbun-id)
 428         (shimbun-article (elmo-shimbun-folder-shimbun-internal folder)
 429                          header)
 430         (when (elmo-string-match-member
 431                (elmo-folder-name-internal folder)
 432                elmo-shimbun-update-overview-folder-list)
 433           (elmo-shimbun-update-overview folder location header))
 434         (when (setq shimbun-id
 435                     (elmo-shimbun-header-extra-field header "x-shimbun-id"))
 436           (goto-char (point-min))
 437           (insert (format "X-Shimbun-Id: %s\n" shimbun-id)))
 438         t)
 439     (error "Unplugged")))
 440
 441 (luna-define-method elmo-message-encache :around ((folder
 442                                                    elmo-shimbun-folder)
 443                                                   number &optional read)
 444   (if (elmo-folder-plugged-p folder)
 445       (luna-call-next-method)
 446     (if elmo-enable-disconnected-operation
 447         (elmo-message-encache-dop folder number read)
 448       (error "Unplugged"))))
 449
 450 (luna-define-method elmo-folder-list-messages-internal :around
 451   ((folder elmo-shimbun-folder) &optional nohide)
 452   (if (elmo-folder-plugged-p folder)
 453       (luna-call-next-method)
 454     t))
 455
 456 (luna-define-method elmo-map-folder-list-message-locations
 457   ((folder elmo-shimbun-folder))
 458   (let ((expire-days (shimbun-article-expiration-days
 459                       (elmo-shimbun-folder-shimbun-internal folder))))
 460     (elmo-uniq-list
 461      (nconc
 462       (delq nil
 463             (mapcar
 464              (lambda (ov)
 465                (when (and (elmo-message-entity-field ov 'xref)
 466                           (if expire-days
 467                               (< (elmo-shimbun-lapse-seconds
 468                                   (elmo-shimbun-parse-time-string
 469                                    (elmo-message-entity-field ov 'date)))
 470                                  (* expire-days 86400 ; seconds per day
 471                                     ))
 472                             t))
 473                  (elmo-message-entity-field ov 'message-id)))
 474              (elmo-folder-list-message-entities folder)))
 475       (mapcar
 476        (lambda (header)
 477          (or (elmo-shimbun-header-extra-field header "x-shimbun-id")
 478              (shimbun-header-id header)))
 479        (elmo-shimbun-folder-headers-internal folder))))))
 480
 481 (luna-define-method elmo-folder-list-subfolders ((folder elmo-shimbun-folder)
 482                                                  &optional one-level)
 483   (let ((prefix (elmo-folder-prefix-internal folder)))
 484     (cond ((elmo-shimbun-folder-shimbun-internal folder)
 485            (unless (elmo-shimbun-folder-group-internal folder)
 486              (mapcar
 487               (lambda (fld)
 488                 (concat prefix
 489                         (shimbun-server
 490                          (elmo-shimbun-folder-shimbun-internal folder))
 491                         "." fld))
 492               (shimbun-groups (elmo-shimbun-folder-shimbun-internal folder)))))
 493           ;; the rest are for "@/" group
 494           (one-level
 495            (mapcar
 496             (lambda (server) (list (concat prefix server)))
 497             (shimbun-servers-list)))
 498           (t
 499            (let (folders)
 500              (dolist (server (shimbun-servers-list))
 501                (setq folders
 502                      (append folders
 503                              (mapcar
 504                               (lambda (fld) (concat prefix server "." fld))
 505                               (shimbun-groups
 506                                (shimbun-open server
 507                                              (let ((fld
 508                                                     (elmo-make-folder
 509                                                      (concat prefix server))))
 510                                                (luna-make-entity
 511                                                 'shimbun-elmo-mua
 512                                                 :folder fld))))))))
 513              folders)))))
 514
 515 (luna-define-method elmo-folder-exists-p ((folder elmo-shimbun-folder))
 516   (if (elmo-shimbun-folder-group-internal folder)
 517       (progn
 518         (member
 519          (elmo-shimbun-folder-group-internal folder)
 520          (shimbun-groups (elmo-shimbun-folder-shimbun-internal
 521                           folder))))
 522     t))
 523
 524 (require 'product)
 525 (product-provide (provide 'elmo-shimbun) (require 'elmo-version))
 526
 527 ;;; elmo-shimbun.el ends here