elmo/elmo-shimbun.el

   1 ;;; elmo-shimbun.el --- Shimbun interface for ELMO.
   2
   3 ;; Copyright (C) 2001 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'elmo)
  32 (require 'elmo-map)
  33 (require 'elmo-dop)
  34 (require 'shimbun)
  35
  36 (eval-when-compile
  37   (defun-maybe shimbun-servers-list ()))
  38
  39 (defcustom elmo-shimbun-check-interval 60
  40   "*Check interval for shimbun."
  41   :type 'integer
  42   :group 'elmo)
  43
  44 (defcustom elmo-shimbun-default-index-range 2
  45   "*Default value for the range of header indices."
  46   :type '(choice (const :tag "all" all)
  47                  (const :tag "last" last)
  48                  (integer :tag "number"))
  49   :group 'elmo)
  50
  51 (defcustom elmo-shimbun-use-cache t
  52   "*If non-nil, use cache for each article."
  53   :type 'boolean
  54   :group 'elmo)
  55
  56 (defcustom elmo-shimbun-index-range-alist nil
  57   "*Alist of FOLDER-REGEXP and RANGE.
  58 FOLDER-REGEXP is the regexp for shimbun folder name.
  59 RANGE is the range of the header indices .
  60 See `shimbun-headers' for more detail about RANGE."
  61   :type '(repeat (cons (regexp :tag "Folder Regexp")
  62                        (choice (const :tag "all" all)
  63                                (const :tag "last" last)
  64                                (integer :tag "number"))))
  65   :group 'elmo)
  66
  67 (defcustom elmo-shimbun-update-overview-folder-list nil
  68   "*List of FOLDER-REGEXP.
  69 FOLDER-REGEXP is the regexp of shimbun folder name which should be
  70 update overview when message is fetched."
  71   :type '(repeat (regexp :tag "Folder Regexp"))
  72   :group 'elmo)
  73
  74 ;; Shimbun header.
  75 (defsubst elmo-shimbun-header-extra-field (header field-name)
  76   (let ((extra (and header (shimbun-header-extra header))))
  77     (and extra
  78          (cdr (assoc field-name extra)))))
  79
  80 (defsubst elmo-shimbun-header-set-extra-field (header field-name value)
  81   (let ((extras (and header (shimbun-header-extra header)))
  82         extra)
  83     (if (setq extra (assoc field-name extras))
  84         (setcdr extra value)
  85       (shimbun-header-set-extra
  86        header
  87        (cons (cons field-name value) extras)))))
  88
  89 ;; Shimbun mua.
  90 (eval-and-compile
  91   (luna-define-class shimbun-elmo-mua (shimbun-mua) (folder))
  92   (luna-define-internal-accessors 'shimbun-elmo-mua))
  93
  94 (luna-define-method shimbun-mua-search-id ((mua shimbun-elmo-mua) id)
  95   (elmo-msgdb-message-entity (elmo-folder-msgdb
  96                               (shimbun-elmo-mua-folder-internal mua))
  97                              id))
  98
  99 (eval-and-compile
 100   (luna-define-class elmo-shimbun-folder
 101                      (elmo-map-folder) (shimbun headers header-hash
 102                                                 entity-hash
 103                                                 group range last-check))
 104   (luna-define-internal-accessors 'elmo-shimbun-folder))
 105
 106 (defun elmo-shimbun-folder-entity-hash (folder)
 107   (or (elmo-shimbun-folder-entity-hash-internal folder)
 108       (let ((overviews (elmo-folder-list-message-entities folder))
 109             hash id)
 110         (when overviews
 111           (setq hash (elmo-make-hash (length overviews)))
 112           (dolist (entity overviews)
 113             (elmo-set-hash-val (elmo-message-entity-field entity 'message-id)
 114                                entity hash)
 115             (when (setq id (elmo-message-entity-field entity 'x-original-id))
 116               (elmo-set-hash-val id entity hash)))
 117           (elmo-shimbun-folder-set-entity-hash-internal folder hash)))))
 118
 119 (defsubst elmo-shimbun-folder-shimbun-header (folder location)
 120   (let ((hash (elmo-shimbun-folder-header-hash-internal folder)))
 121     (or (and hash (elmo-get-hash-val location hash))
 122         (let ((entity (elmo-msgdb-message-entity
 123                        (elmo-folder-msgdb folder)
 124                        location))
 125               (elmo-hash-minimum-size 63)
 126               header)
 127           (when entity
 128             (setq header (elmo-shimbun-entity-to-header entity))
 129             (unless hash
 130               (elmo-shimbun-folder-set-header-hash-internal
 131                folder
 132                (setq hash (elmo-make-hash))))
 133             (elmo-set-hash-val (elmo-message-entity-field entity
 134                                                           'message-id)
 135                                header
 136                                hash)
 137             header)))))
 138
 139 (defsubst elmo-shimbun-lapse-seconds (time)
 140   (let ((now (current-time)))
 141     (+ (* (- (car now) (car time)) 65536)
 142        (- (nth 1 now) (nth 1 time)))))
 143
 144 (defun elmo-shimbun-parse-time-string (string)
 145   "Parse the time-string STRING and return its time as Emacs style."
 146   (ignore-errors
 147     (let ((x (timezone-fix-time string nil nil)))
 148       (encode-time (aref x 5) (aref x 4) (aref x 3)
 149                    (aref x 2) (aref x 1) (aref x 0)
 150                    (aref x 6)))))
 151
 152 (defsubst elmo-shimbun-headers-check-p (folder)
 153   (or (null (elmo-shimbun-folder-last-check-internal folder))
 154       (and (elmo-shimbun-folder-last-check-internal folder)
 155            (> (elmo-shimbun-lapse-seconds
 156                (elmo-shimbun-folder-last-check-internal folder))
 157               elmo-shimbun-check-interval))))
 158
 159 (defun elmo-shimbun-entity-to-header (entity)
 160   (let (message-id shimbun-id)
 161     (if (setq message-id (elmo-message-entity-field
 162                           entity 'x-original-id))
 163         (setq shimbun-id (elmo-message-entity-field entity 'message-id))
 164       (setq message-id (elmo-message-entity-field entity 'message-id)
 165             shimbun-id nil))
 166     (elmo-set-work-buf
 167      (set-buffer-multibyte t)
 168      (shimbun-make-header
 169       (elmo-message-entity-number entity)
 170       (shimbun-mime-encode-string
 171        (elmo-message-entity-field entity 'subject 'decode))
 172       (shimbun-mime-encode-string
 173        (elmo-message-entity-field entity 'from 'decode))
 174       (elmo-message-entity-field entity 'date)
 175       message-id
 176       (elmo-message-entity-field entity 'references)
 177       0
 178       0
 179       (elmo-message-entity-field entity 'xref)
 180       (and shimbun-id
 181            (list (cons "x-shimbun-id" shimbun-id)))))))
 182
 183 (defsubst elmo-shimbun-folder-header-hash-setup (folder headers)
 184   (let ((hash (or (elmo-shimbun-folder-header-hash-internal folder)
 185                   (elmo-make-hash (length headers)))))
 186     (dolist (header headers)
 187       (elmo-set-hash-val (shimbun-header-id header) header hash))
 188     (elmo-shimbun-folder-set-header-hash-internal folder hash)))
 189
 190 (defun elmo-shimbun-get-headers (folder)
 191   (let* ((shimbun (elmo-shimbun-folder-shimbun-internal folder))
 192          (key (concat (shimbun-server shimbun)
 193                       "." (shimbun-current-group shimbun)))
 194          (elmo-hash-minimum-size 63)
 195          headers)
 196     ;; new headers.
 197     (setq headers
 198           (delq nil
 199                 (mapcar
 200                  (lambda (x)
 201                    (unless (elmo-msgdb-message-entity
 202                             (elmo-folder-msgdb folder)
 203                             (shimbun-header-id x))
 204                      x))
 205                  ;; This takes much time.
 206                  (shimbun-headers
 207                   (elmo-shimbun-folder-shimbun-internal folder)
 208                   (elmo-shimbun-folder-range-internal folder)))))
 209     (elmo-shimbun-folder-set-headers-internal folder headers)
 210     (when headers
 211       (elmo-shimbun-folder-header-hash-setup folder headers))
 212     (elmo-shimbun-folder-set-last-check-internal folder (current-time))))
 213
 214 (luna-define-method elmo-folder-initialize ((folder
 215                                              elmo-shimbun-folder)
 216                                             name)
 217   (if (string= name "")
 218       folder
 219     (let ((server-group (if (string-match "\\([^.]+\\)\\." name)
 220                             (list (elmo-match-string 1 name)
 221                                   (substring name (match-end 0)))
 222                           (list name))))
 223       (when (nth 0 server-group) ; server
 224         (elmo-shimbun-folder-set-shimbun-internal
 225          folder
 226          (shimbun-open (nth 0 server-group)
 227                        (luna-make-entity 'shimbun-elmo-mua :folder folder))))
 228       (when (nth 1 server-group)
 229         (elmo-shimbun-folder-set-group-internal
 230          folder
 231          (nth 1 server-group)))
 232       (elmo-shimbun-folder-set-range-internal
 233        folder
 234        (or (cdr (elmo-string-matched-assoc (elmo-folder-name-internal folder)
 235                                            elmo-shimbun-index-range-alist))
 236            elmo-shimbun-default-index-range))
 237       folder)))
 238
 239 (luna-define-method elmo-folder-open-internal ((folder elmo-shimbun-folder))
 240   (when (elmo-shimbun-folder-shimbun-internal folder)
 241     (shimbun-open-group
 242      (elmo-shimbun-folder-shimbun-internal folder)
 243      (elmo-shimbun-folder-group-internal folder))
 244     (let ((inhibit-quit t))
 245       (unless (elmo-map-folder-location-alist-internal folder)
 246         (elmo-map-folder-location-setup
 247          folder
 248          (elmo-msgdb-location-load (elmo-folder-msgdb-path folder))))
 249       (when (and (elmo-folder-plugged-p folder)
 250                  (elmo-shimbun-headers-check-p folder))
 251         (elmo-shimbun-get-headers folder)
 252         (elmo-map-folder-update-locations
 253          folder
 254          (elmo-map-folder-list-message-locations folder))))))
 255
 256 (luna-define-method elmo-folder-reserve-status-p ((folder elmo-shimbun-folder))
 257   t)
 258
 259 (luna-define-method elmo-folder-local-p ((folder elmo-shimbun-folder))
 260   nil)
 261
 262 (luna-define-method elmo-message-use-cache-p ((folder elmo-shimbun-folder)
 263                                               number)
 264   elmo-shimbun-use-cache)
 265
 266 (luna-define-method elmo-folder-close-internal :after ((folder
 267                                                         elmo-shimbun-folder))
 268   (shimbun-close-group
 269    (elmo-shimbun-folder-shimbun-internal folder))
 270   (elmo-shimbun-folder-set-headers-internal
 271    folder nil)
 272   (elmo-shimbun-folder-set-header-hash-internal
 273    folder nil)
 274   (elmo-shimbun-folder-set-entity-hash-internal
 275    folder nil)
 276   (elmo-shimbun-folder-set-last-check-internal
 277    folder nil))
 278
 279 (luna-define-method elmo-folder-plugged-p ((folder elmo-shimbun-folder))
 280   (elmo-plugged-p
 281    "shimbun"
 282    (and (elmo-shimbun-folder-shimbun-internal folder)
 283         (shimbun-server (elmo-shimbun-folder-shimbun-internal folder)))
 284    nil nil
 285    (and (elmo-shimbun-folder-shimbun-internal folder)
 286         (shimbun-server (elmo-shimbun-folder-shimbun-internal folder)))))
 287
 288 (luna-define-method elmo-folder-set-plugged ((folder elmo-shimbun-folder)
 289                                              plugged &optional add)
 290   (elmo-set-plugged plugged
 291                     "shimbun"
 292                     (shimbun-server
 293                      (elmo-shimbun-folder-shimbun-internal folder))
 294                     nil nil nil
 295                     (shimbun-server
 296                      (elmo-shimbun-folder-shimbun-internal folder))
 297                     add))
 298
 299 (luna-define-method elmo-net-port-info ((folder elmo-shimbun-folder))
 300   (list "shimbun"
 301         (shimbun-server
 302          (elmo-shimbun-folder-shimbun-internal folder))
 303         nil))
 304
 305 (luna-define-method elmo-folder-check :around ((folder elmo-shimbun-folder))
 306   (when (shimbun-current-group
 307          (elmo-shimbun-folder-shimbun-internal folder))
 308     (when (and (elmo-folder-plugged-p folder)
 309                (elmo-shimbun-headers-check-p folder))
 310       (elmo-shimbun-get-headers folder)
 311       (luna-call-next-method))))
 312
 313 (luna-define-method elmo-folder-clear :around ((folder elmo-shimbun-folder)
 314                                                &optional keep-killed)
 315   (elmo-shimbun-folder-set-headers-internal folder nil)
 316   (elmo-shimbun-folder-set-header-hash-internal folder nil)
 317   (elmo-shimbun-folder-set-entity-hash-internal folder nil)
 318   (elmo-shimbun-folder-set-last-check-internal folder nil)
 319   (luna-call-next-method))
 320
 321 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 322                                                     elmo-shimbun-folder))
 323   (expand-file-name
 324    (concat (shimbun-server
 325             (elmo-shimbun-folder-shimbun-internal folder))
 326            "/"
 327            (elmo-shimbun-folder-group-internal folder))
 328    (expand-file-name "shimbun" elmo-msgdb-directory)))
 329
 330 (defun elmo-shimbun-msgdb-create-entity (folder number)
 331   (let ((header (elmo-shimbun-folder-shimbun-header
 332                  folder
 333                  (elmo-map-message-location folder number)))
 334         ov)
 335     (when header
 336       (with-temp-buffer
 337         (shimbun-header-insert
 338          (elmo-shimbun-folder-shimbun-internal folder)
 339          header)
 340         (setq ov (elmo-msgdb-create-message-entity-from-buffer
 341                   (elmo-folder-msgdb-internal folder) number))
 342         (elmo-message-entity-set-field
 343          ov
 344          'xref (shimbun-header-xref header)))
 345       ov)))
 346
 347 (luna-define-method elmo-folder-msgdb-create ((folder elmo-shimbun-folder)
 348                                               numlist flag-table)
 349   (let ((new-msgdb (elmo-make-msgdb))
 350         entity i percent length msgid flags)
 351     (setq length (length numlist))
 352     (setq i 0)
 353     (message "Creating msgdb...")
 354     (while numlist
 355       (setq entity
 356             (elmo-shimbun-msgdb-create-entity
 357              folder (car numlist)))
 358       (when entity
 359         (setq msgid (elmo-message-entity-field entity 'message-id)
 360               flags (elmo-flag-table-get flag-table msgid))
 361         (elmo-global-flags-set flags folder (car numlist) msgid)
 362         (elmo-msgdb-append-entity new-msgdb entity flags))
 363       (when (> length elmo-display-progress-threshold)
 364         (setq i (1+ i))
 365         (setq percent (/ (* i 100) length))
 366         (elmo-display-progress
 367          'elmo-folder-msgdb-create "Creating msgdb..."
 368          percent))
 369       (setq numlist (cdr numlist)))
 370     (message "Creating msgdb...done")
 371     (elmo-msgdb-sort-by-date new-msgdb)))
 372
 373 (luna-define-method elmo-folder-message-file-p ((folder elmo-shimbun-folder))
 374   nil)
 375
 376 (defsubst elmo-shimbun-update-overview (folder shimbun-id header)
 377   (let ((entity (elmo-msgdb-message-entity (elmo-folder-msgdb folder)
 378                                            shimbun-id))
 379         (message-id (shimbun-header-id header))
 380         references)
 381     (unless (string= shimbun-id message-id)
 382       (elmo-message-entity-set-field
 383        entity 'x-original-id message-id)
 384       (elmo-shimbun-header-set-extra-field
 385        header "x-shimbun-id" shimbun-id)
 386       (elmo-set-hash-val message-id
 387                          entity
 388                          (elmo-shimbun-folder-entity-hash folder))
 389       (elmo-set-hash-val shimbun-id
 390                          entity
 391                          (elmo-shimbun-folder-entity-hash folder)))
 392     (elmo-message-entity-set-field
 393      entity
 394      'from
 395      (elmo-mime-string (shimbun-header-from header)))
 396     (elmo-message-entity-set-field
 397      entity
 398      'subject
 399      (elmo-mime-string (shimbun-header-subject header)))
 400     (elmo-message-entity-set-field
 401      entity
 402      'date
 403      (shimbun-header-date header))
 404     (when (setq references
 405                 (or (elmo-msgdb-get-last-message-id
 406                      (elmo-field-body "in-reply-to"))
 407                     (elmo-msgdb-get-last-message-id
 408                      (elmo-field-body "references"))))
 409       (elmo-message-entity-set-field
 410        entity
 411        'references
 412        (or (elmo-message-entity-field
 413             (elmo-get-hash-val
 414              references
 415              (elmo-shimbun-folder-entity-hash folder))
 416             'message-id)
 417            references)))))
 418
 419 (luna-define-method elmo-map-message-fetch ((folder elmo-shimbun-folder)
 420                                             location strategy
 421                                             &optional section unseen)
 422   (if (elmo-folder-plugged-p folder)
 423       (let ((header (elmo-shimbun-folder-shimbun-header
 424                      folder
 425                      location))
 426             shimbun-id)
 427         (shimbun-article (elmo-shimbun-folder-shimbun-internal folder)
 428                          header)
 429         (when (elmo-string-match-member
 430                (elmo-folder-name-internal folder)
 431                elmo-shimbun-update-overview-folder-list)
 432           (elmo-shimbun-update-overview folder location header))
 433         (when (setq shimbun-id
 434                     (elmo-shimbun-header-extra-field header "x-shimbun-id"))
 435           (goto-char (point-min))
 436           (insert (format "X-Shimbun-Id: %s\n" shimbun-id)))
 437         t)
 438     (error "Unplugged")))
 439
 440 (luna-define-method elmo-message-encache :around ((folder
 441                                                    elmo-shimbun-folder)
 442                                                   number &optional read)
 443   (if (elmo-folder-plugged-p folder)
 444       (luna-call-next-method)
 445     (if elmo-enable-disconnected-operation
 446         (elmo-message-encache-dop folder number read)
 447       (error "Unplugged"))))
 448
 449 (luna-define-method elmo-folder-list-messages-internal :around
 450   ((folder elmo-shimbun-folder) &optional nohide)
 451   (if (elmo-folder-plugged-p folder)
 452       (luna-call-next-method)
 453     t))
 454
 455 (luna-define-method elmo-map-folder-list-message-locations
 456   ((folder elmo-shimbun-folder))
 457   (let ((expire-days (shimbun-article-expiration-days
 458                       (elmo-shimbun-folder-shimbun-internal folder))))
 459     (elmo-uniq-list
 460      (nconc
 461       (delq nil
 462             (mapcar
 463              (lambda (ov)
 464                (when (and (elmo-message-entity-field ov 'xref)
 465                           (if expire-days
 466                               (< (elmo-shimbun-lapse-seconds
 467                                   (elmo-shimbun-parse-time-string
 468                                    (elmo-message-entity-field ov 'date)))
 469                                  (* expire-days 86400 ; seconds per day
 470                                     ))
 471                             t))
 472                  (elmo-message-entity-field ov 'message-id)))
 473              (elmo-folder-list-message-entities folder)))
 474       (mapcar
 475        (lambda (header)
 476          (or (elmo-shimbun-header-extra-field header "x-shimbun-id")
 477              (shimbun-header-id header)))
 478        (elmo-shimbun-folder-headers-internal folder))))))
 479
 480 (luna-define-method elmo-folder-list-subfolders ((folder elmo-shimbun-folder)
 481                                                  &optional one-level)
 482   (let ((prefix (elmo-folder-prefix-internal folder)))
 483     (cond ((elmo-shimbun-folder-shimbun-internal folder)
 484            (unless (elmo-shimbun-folder-group-internal folder)
 485              (mapcar
 486               (lambda (fld)
 487                 (concat prefix
 488                         (shimbun-server
 489                          (elmo-shimbun-folder-shimbun-internal folder))
 490                         "." fld))
 491               (shimbun-groups (elmo-shimbun-folder-shimbun-internal folder)))))
 492           ;; the rest are for "@/" group
 493           (one-level
 494            (mapcar
 495             (lambda (server) (list (concat prefix server)))
 496             (shimbun-servers-list)))
 497           (t
 498            (let (folders)
 499              (dolist (server (shimbun-servers-list))
 500                (setq folders
 501                      (append folders
 502                              (mapcar
 503                               (lambda (fld) (concat prefix server "." fld))
 504                               (shimbun-groups
 505                                (shimbun-open server
 506                                              (let ((fld
 507                                                     (elmo-make-folder
 508                                                      (concat prefix server))))
 509                                                (luna-make-entity
 510                                                 'shimbun-elmo-mua
 511                                                 :folder fld))))))))
 512              folders)))))
 513
 514 (luna-define-method elmo-folder-exists-p ((folder elmo-shimbun-folder))
 515   (if (elmo-shimbun-folder-group-internal folder)
 516       (progn
 517         (member
 518          (elmo-shimbun-folder-group-internal folder)
 519          (shimbun-groups (elmo-shimbun-folder-shimbun-internal
 520                           folder))))
 521     t))
 522
 523 (require 'product)
 524 (product-provide (provide 'elmo-shimbun) (require 'elmo-version))
 525
 526 ;;; elmo-shimbun.el ends here