elmo/elmo-shimbun.el

   1 ;;; elmo-shimbun.el --- Shimbun interface for ELMO.
   2
   3 ;; Copyright (C) 2001 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'elmo)
  32 (require 'elmo-map)
  33 (require 'elmo-dop)
  34 (require 'shimbun)
  35
  36 (eval-when-compile
  37   (defun-maybe shimbun-servers-list ()))
  38
  39 (defcustom elmo-shimbun-check-interval 60
  40   "*Check interval for shimbun."
  41   :type 'integer
  42   :group 'elmo)
  43
  44 (defcustom elmo-shimbun-default-index-range 2
  45   "*Default value for the range of header indices."
  46   :type '(choice (const :tag "all" all)
  47                  (const :tag "last" last)
  48                  (integer :tag "number"))
  49   :group 'elmo)
  50
  51 (defcustom elmo-shimbun-use-cache t
  52   "*If non-nil, use cache for each article."
  53   :type 'boolean
  54   :group 'elmo)
  55
  56 (defcustom elmo-shimbun-index-range-alist nil
  57   "*Alist of FOLDER-REGEXP and RANGE.
  58 FOLDER-REGEXP is the regexp for shimbun folder name.
  59 RANGE is the range of the header indices .
  60 See `shimbun-headers' for more detail about RANGE."
  61   :type '(repeat (cons (regexp :tag "Folder Regexp")
  62                        (choice (const :tag "all" all)
  63                                (const :tag "last" last)
  64                                (integer :tag "number"))))
  65   :group 'elmo)
  66
  67 (defcustom elmo-shimbun-update-overview-folder-list nil
  68   "*List of FOLDER-REGEXP.
  69 FOLDER-REGEXP is the regexp of shimbun folder name which should be
  70 update overview when message is fetched.
  71 If it is nil, update overview for all shimbun folders."
  72   :type '(repeat (regexp :tag "Folder Regexp"))
  73   :group 'elmo)
  74
  75 ;; Shimbun header.
  76 (defsubst elmo-shimbun-header-extra-field (header field-name)
  77   (let ((extra (and header (shimbun-header-extra header))))
  78     (and extra
  79          (cdr (assoc field-name extra)))))
  80
  81 (defsubst elmo-shimbun-header-set-extra-field (header field-name value)
  82   (let ((extras (and header (shimbun-header-extra header)))
  83         extra)
  84     (if (setq extra (assoc field-name extras))
  85         (setcdr extra value)
  86       (shimbun-header-set-extra
  87        header
  88        (cons (cons field-name value) extras)))))
  89
  90 ;; Shimbun mua.
  91 (eval-and-compile
  92   (luna-define-class shimbun-elmo-mua (shimbun-mua) (folder))
  93   (luna-define-internal-accessors 'shimbun-elmo-mua))
  94
  95 (luna-define-method shimbun-mua-search-id ((mua shimbun-elmo-mua) id)
  96   (elmo-msgdb-message-entity (elmo-folder-msgdb
  97                               (shimbun-elmo-mua-folder-internal mua))
  98                              id))
  99
 100 (eval-and-compile
 101   (luna-define-class elmo-shimbun-folder
 102                      (elmo-map-folder) (shimbun headers header-hash
 103                                                 entity-hash
 104                                                 group range last-check))
 105   (luna-define-internal-accessors 'elmo-shimbun-folder))
 106
 107 (defun elmo-shimbun-folder-entity-hash (folder)
 108   (or (elmo-shimbun-folder-entity-hash-internal folder)
 109       (let ((overviews (elmo-folder-list-message-entities folder))
 110             hash id)
 111         (when overviews
 112           (setq hash (elmo-make-hash (length overviews)))
 113           (dolist (entity overviews)
 114             (elmo-set-hash-val (elmo-message-entity-field entity 'message-id)
 115                                entity hash)
 116             (when (setq id (elmo-message-entity-field entity 'x-original-id))
 117               (elmo-set-hash-val id entity hash)))
 118           (elmo-shimbun-folder-set-entity-hash-internal folder hash)))))
 119
 120 (defsubst elmo-shimbun-folder-shimbun-header (folder location)
 121   (let ((hash (elmo-shimbun-folder-header-hash-internal folder)))
 122     (or (and hash (elmo-get-hash-val location hash))
 123         (let ((entity (elmo-msgdb-message-entity
 124                        (elmo-folder-msgdb folder)
 125                        location))
 126               (elmo-hash-minimum-size 63)
 127               header)
 128           (when entity
 129             (setq header (elmo-shimbun-entity-to-header entity))
 130             (unless hash
 131               (elmo-shimbun-folder-set-header-hash-internal
 132                folder
 133                (setq hash (elmo-make-hash))))
 134             (elmo-set-hash-val (elmo-message-entity-field entity
 135                                                           'message-id)
 136                                header
 137                                hash)
 138             header)))))
 139
 140 (defsubst elmo-shimbun-lapse-seconds (time)
 141   (let ((now (current-time)))
 142     (+ (* (- (car now) (car time)) 65536)
 143        (- (nth 1 now) (nth 1 time)))))
 144
 145 (defun elmo-shimbun-parse-time-string (string)
 146   "Parse the time-string STRING and return its time as Emacs style."
 147   (ignore-errors
 148     (let ((x (timezone-fix-time string nil nil)))
 149       (encode-time (aref x 5) (aref x 4) (aref x 3)
 150                    (aref x 2) (aref x 1) (aref x 0)
 151                    (aref x 6)))))
 152
 153 (defsubst elmo-shimbun-headers-check-p (folder)
 154   (or (null (elmo-shimbun-folder-last-check-internal folder))
 155       (and (elmo-shimbun-folder-last-check-internal folder)
 156            (> (elmo-shimbun-lapse-seconds
 157                (elmo-shimbun-folder-last-check-internal folder))
 158               elmo-shimbun-check-interval))))
 159
 160 (defun elmo-shimbun-entity-to-header (entity)
 161   (let (message-id shimbun-id)
 162     (if (setq message-id (elmo-message-entity-field
 163                           entity 'x-original-id))
 164         (setq shimbun-id (elmo-message-entity-field entity 'message-id))
 165       (setq message-id (elmo-message-entity-field entity 'message-id)
 166             shimbun-id nil))
 167     (elmo-set-work-buf
 168      (set-buffer-multibyte t)
 169      (shimbun-make-header
 170       (elmo-message-entity-number entity)
 171       (shimbun-mime-encode-string
 172        (elmo-message-entity-field entity 'subject 'decode))
 173       (shimbun-mime-encode-string
 174        (elmo-message-entity-field entity 'from 'decode))
 175       (elmo-message-entity-field entity 'date)
 176       message-id
 177       (elmo-message-entity-field entity 'references)
 178       0
 179       0
 180       (elmo-message-entity-field entity 'xref)
 181       (and shimbun-id
 182            (list (cons "x-shimbun-id" shimbun-id)))))))
 183
 184 (defsubst elmo-shimbun-folder-header-hash-setup (folder headers)
 185   (let ((hash (or (elmo-shimbun-folder-header-hash-internal folder)
 186                   (elmo-make-hash (length headers)))))
 187     (dolist (header headers)
 188       (elmo-set-hash-val (shimbun-header-id header) header hash))
 189     (elmo-shimbun-folder-set-header-hash-internal folder hash)))
 190
 191 (defun elmo-shimbun-get-headers (folder)
 192   (let* ((shimbun (elmo-shimbun-folder-shimbun-internal folder))
 193          (key (concat (shimbun-server shimbun)
 194                       "." (shimbun-current-group shimbun)))
 195          (elmo-hash-minimum-size 63)
 196          headers)
 197     ;; new headers.
 198     (setq headers
 199           (delq nil
 200                 (mapcar
 201                  (lambda (x)
 202                    (unless (elmo-msgdb-message-entity
 203                             (elmo-folder-msgdb folder)
 204                             (shimbun-header-id x))
 205                      x))
 206                  ;; This takes much time.
 207                  (shimbun-headers
 208                   (elmo-shimbun-folder-shimbun-internal folder)
 209                   (elmo-shimbun-folder-range-internal folder)))))
 210     (elmo-shimbun-folder-set-headers-internal folder headers)
 211     (when headers
 212       (elmo-shimbun-folder-header-hash-setup folder headers))
 213     (elmo-shimbun-folder-set-last-check-internal folder (current-time))))
 214
 215 (luna-define-method elmo-folder-initialize ((folder
 216                                              elmo-shimbun-folder)
 217                                             name)
 218   (if (string= name "")
 219       folder
 220     (let ((server-group (if (string-match "\\([^.]+\\)\\." name)
 221                             (list (elmo-match-string 1 name)
 222                                   (substring name (match-end 0)))
 223                           (list name))))
 224       (when (nth 0 server-group) ; server
 225         (elmo-shimbun-folder-set-shimbun-internal
 226          folder
 227          (condition-case nil
 228              (shimbun-open (nth 0 server-group)
 229                            (luna-make-entity 'shimbun-elmo-mua :folder folder))
 230            (file-error
 231             (luna-make-entity 'shimbun :server (nth 0 server-group))))))
 232       (when (nth 1 server-group)
 233         (elmo-shimbun-folder-set-group-internal
 234          folder
 235          (nth 1 server-group)))
 236       (elmo-shimbun-folder-set-range-internal
 237        folder
 238        (or (cdr (elmo-string-matched-assoc (elmo-folder-name-internal folder)
 239                                            elmo-shimbun-index-range-alist))
 240            elmo-shimbun-default-index-range))
 241       folder)))
 242
 243 (luna-define-method elmo-folder-open-internal ((folder elmo-shimbun-folder))
 244   (when (elmo-shimbun-folder-shimbun-internal folder)
 245     (shimbun-open-group
 246      (elmo-shimbun-folder-shimbun-internal folder)
 247      (elmo-shimbun-folder-group-internal folder))
 248     (let ((inhibit-quit t))
 249       (unless (elmo-map-folder-location-alist-internal folder)
 250         (elmo-map-folder-location-setup
 251          folder
 252          (elmo-msgdb-location-load (elmo-folder-msgdb-path folder))))
 253       (when (and (elmo-folder-plugged-p folder)
 254                  (elmo-shimbun-headers-check-p folder))
 255         (elmo-shimbun-get-headers folder)
 256         (elmo-map-folder-update-locations
 257          folder
 258          (elmo-map-folder-list-message-locations folder))))))
 259
 260 (luna-define-method elmo-folder-reserve-status-p ((folder elmo-shimbun-folder))
 261   t)
 262
 263 (luna-define-method elmo-folder-local-p ((folder elmo-shimbun-folder))
 264   nil)
 265
 266 (luna-define-method elmo-message-use-cache-p ((folder elmo-shimbun-folder)
 267                                               number)
 268   elmo-shimbun-use-cache)
 269
 270 (luna-define-method elmo-folder-close-internal :after ((folder
 271                                                         elmo-shimbun-folder))
 272   (shimbun-close-group
 273    (elmo-shimbun-folder-shimbun-internal folder))
 274   (elmo-shimbun-folder-set-headers-internal
 275    folder nil)
 276   (elmo-shimbun-folder-set-header-hash-internal
 277    folder nil)
 278   (elmo-shimbun-folder-set-entity-hash-internal
 279    folder nil)
 280   (elmo-shimbun-folder-set-last-check-internal
 281    folder nil))
 282
 283 (luna-define-method elmo-folder-plugged-p ((folder elmo-shimbun-folder))
 284   (elmo-plugged-p
 285    "shimbun"
 286    (and (elmo-shimbun-folder-shimbun-internal folder)
 287         (shimbun-server (elmo-shimbun-folder-shimbun-internal folder)))
 288    nil nil
 289    (and (elmo-shimbun-folder-shimbun-internal folder)
 290         (shimbun-server (elmo-shimbun-folder-shimbun-internal folder)))))
 291
 292 (luna-define-method elmo-folder-set-plugged ((folder elmo-shimbun-folder)
 293                                              plugged &optional add)
 294   (elmo-set-plugged plugged
 295                     "shimbun"
 296                     (shimbun-server
 297                      (elmo-shimbun-folder-shimbun-internal folder))
 298                     nil nil nil
 299                     (shimbun-server
 300                      (elmo-shimbun-folder-shimbun-internal folder))
 301                     add))
 302
 303 (luna-define-method elmo-net-port-info ((folder elmo-shimbun-folder))
 304   (list "shimbun"
 305         (shimbun-server
 306          (elmo-shimbun-folder-shimbun-internal folder))
 307         nil))
 308
 309 (luna-define-method elmo-folder-check :around ((folder elmo-shimbun-folder))
 310   (when (shimbun-current-group
 311          (elmo-shimbun-folder-shimbun-internal folder))
 312     (when (and (elmo-folder-plugged-p folder)
 313                (elmo-shimbun-headers-check-p folder))
 314       (elmo-shimbun-get-headers folder)
 315       (luna-call-next-method))))
 316
 317 (luna-define-method elmo-folder-clear :around ((folder elmo-shimbun-folder)
 318                                                &optional keep-killed)
 319   (elmo-shimbun-folder-set-headers-internal folder nil)
 320   (elmo-shimbun-folder-set-header-hash-internal folder nil)
 321   (elmo-shimbun-folder-set-entity-hash-internal folder nil)
 322   (elmo-shimbun-folder-set-last-check-internal folder nil)
 323   (luna-call-next-method))
 324
 325 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 326                                                     elmo-shimbun-folder))
 327   (expand-file-name
 328    (concat (shimbun-server
 329             (elmo-shimbun-folder-shimbun-internal folder))
 330            "/"
 331            (elmo-shimbun-folder-group-internal folder))
 332    (expand-file-name "shimbun" elmo-msgdb-directory)))
 333
 334 (defun elmo-shimbun-msgdb-create-entity (folder number)
 335   (let ((header (elmo-shimbun-folder-shimbun-header
 336                  folder
 337                  (elmo-map-message-location folder number)))
 338         ov)
 339     (when header
 340       (with-temp-buffer
 341         (shimbun-header-insert
 342          (elmo-shimbun-folder-shimbun-internal folder)
 343          header)
 344         (setq ov (elmo-msgdb-create-message-entity-from-buffer
 345                   (elmo-msgdb-message-entity-handler
 346                    (elmo-folder-msgdb-internal folder)) number))
 347         (elmo-message-entity-set-field
 348          ov
 349          'xref (shimbun-header-xref header)))
 350       ov)))
 351
 352 (luna-define-method elmo-folder-msgdb-create ((folder elmo-shimbun-folder)
 353                                               numlist flag-table)
 354   (let ((new-msgdb (elmo-make-msgdb))
 355         entity i percent length msgid flags)
 356     (setq length (length numlist))
 357     (setq i 0)
 358     (message "Creating msgdb...")
 359     (while numlist
 360       (setq entity
 361             (elmo-shimbun-msgdb-create-entity
 362              folder (car numlist)))
 363       (when entity
 364         (setq msgid (elmo-message-entity-field entity 'message-id)
 365               flags (elmo-flag-table-get flag-table msgid))
 366         (elmo-global-flags-set flags folder (car numlist) msgid)
 367         (elmo-msgdb-append-entity new-msgdb entity flags))
 368       (when (> length elmo-display-progress-threshold)
 369         (setq i (1+ i))
 370         (setq percent (/ (* i 100) length))
 371         (elmo-display-progress
 372          'elmo-folder-msgdb-create "Creating msgdb..."
 373          percent))
 374       (setq numlist (cdr numlist)))
 375     (message "Creating msgdb...done")
 376     (elmo-msgdb-sort-by-date new-msgdb)))
 377
 378 (luna-define-method elmo-folder-message-file-p ((folder elmo-shimbun-folder))
 379   nil)
 380
 381 (defsubst elmo-shimbun-update-overview (folder shimbun-id header)
 382   (let ((entity (elmo-msgdb-message-entity (elmo-folder-msgdb folder)
 383                                            shimbun-id))
 384         (message-id (shimbun-header-id header))
 385         references)
 386     (unless (string= shimbun-id message-id)
 387       (elmo-message-entity-set-field
 388        entity 'x-original-id message-id)
 389       (elmo-shimbun-header-set-extra-field
 390        header "x-shimbun-id" shimbun-id)
 391       (elmo-set-hash-val message-id
 392                          entity
 393                          (elmo-shimbun-folder-entity-hash folder))
 394       (elmo-set-hash-val shimbun-id
 395                          entity
 396                          (elmo-shimbun-folder-entity-hash folder)))
 397     (elmo-message-entity-set-field
 398      entity
 399      'from
 400      (elmo-mime-string (shimbun-header-from header)))
 401     (elmo-message-entity-set-field
 402      entity
 403      'subject
 404      (elmo-mime-string (shimbun-header-subject header)))
 405     (elmo-message-entity-set-field
 406      entity
 407      'date
 408      (shimbun-header-date header))
 409     (when (setq references
 410                 (or (elmo-msgdb-get-last-message-id
 411                      (elmo-field-body "in-reply-to"))
 412                     (elmo-msgdb-get-last-message-id
 413                      (elmo-field-body "references"))))
 414       (elmo-message-entity-set-field
 415        entity
 416        'references
 417        (or (elmo-message-entity-field
 418             (elmo-get-hash-val
 419              references
 420              (elmo-shimbun-folder-entity-hash folder))
 421             'message-id)
 422            references)))))
 423
 424 (luna-define-method elmo-map-message-fetch ((folder elmo-shimbun-folder)
 425                                             location strategy
 426                                             &optional section unseen)
 427   (if (elmo-folder-plugged-p folder)
 428       (let ((header (elmo-shimbun-folder-shimbun-header
 429                      folder
 430                      location))
 431             shimbun-id)
 432         (shimbun-article (elmo-shimbun-folder-shimbun-internal folder)
 433                          header)
 434         (when (or (null elmo-shimbun-update-overview-folder-list)
 435                   (elmo-string-match-member
 436                    (elmo-folder-name-internal folder)
 437                    elmo-shimbun-update-overview-folder-list))
 438           (elmo-shimbun-update-overview folder location header))
 439         (when (setq shimbun-id
 440                     (elmo-shimbun-header-extra-field header "x-shimbun-id"))
 441           (goto-char (point-min))
 442           (insert (format "X-Shimbun-Id: %s\n" shimbun-id)))
 443         t)
 444     (error "Unplugged")))
 445
 446 (luna-define-method elmo-message-encache :around ((folder
 447                                                    elmo-shimbun-folder)
 448                                                   number &optional read)
 449   (if (elmo-folder-plugged-p folder)
 450       (luna-call-next-method)
 451     (if elmo-enable-disconnected-operation
 452         (elmo-message-encache-dop folder number read)
 453       (error "Unplugged"))))
 454
 455 (luna-define-method elmo-folder-list-messages-internal :around
 456   ((folder elmo-shimbun-folder) &optional nohide)
 457   (if (elmo-folder-plugged-p folder)
 458       (luna-call-next-method)
 459     t))
 460
 461 (luna-define-method elmo-map-folder-list-message-locations
 462   ((folder elmo-shimbun-folder))
 463   (let ((expire-days (shimbun-article-expiration-days
 464                       (elmo-shimbun-folder-shimbun-internal folder))))
 465     (elmo-uniq-list
 466      (nconc
 467       (delq nil
 468             (mapcar
 469              (lambda (ov)
 470                (when (and (elmo-message-entity-field ov 'xref)
 471                           (if expire-days
 472                               (< (elmo-shimbun-lapse-seconds
 473                                   (elmo-shimbun-parse-time-string
 474                                    (elmo-message-entity-field ov 'date)))
 475                                  (* expire-days 86400 ; seconds per day
 476                                     ))
 477                             t))
 478                  (elmo-message-entity-field ov 'message-id)))
 479              (elmo-folder-list-message-entities folder)))
 480       (mapcar
 481        (lambda (header)
 482          (or (elmo-shimbun-header-extra-field header "x-shimbun-id")
 483              (shimbun-header-id header)))
 484        (elmo-shimbun-folder-headers-internal folder))))))
 485
 486 (luna-define-method elmo-folder-list-subfolders ((folder elmo-shimbun-folder)
 487                                                  &optional one-level)
 488   (let ((prefix (elmo-folder-prefix-internal folder)))
 489     (cond ((elmo-shimbun-folder-shimbun-internal folder)
 490            (unless (elmo-shimbun-folder-group-internal folder)
 491              (mapcar
 492               (lambda (fld)
 493                 (concat prefix
 494                         (shimbun-server
 495                          (elmo-shimbun-folder-shimbun-internal folder))
 496                         "." fld))
 497               (shimbun-groups (elmo-shimbun-folder-shimbun-internal folder)))))
 498           ;; the rest are for "@/" group
 499           (one-level
 500            (mapcar
 501             (lambda (server) (list (concat prefix server)))
 502             (shimbun-servers-list)))
 503           (t
 504            (let (folders)
 505              (dolist (server (shimbun-servers-list))
 506                (setq folders
 507                      (append folders
 508                              (mapcar
 509                               (lambda (fld) (concat prefix server "." fld))
 510                               (shimbun-groups
 511                                (shimbun-open server
 512                                              (let ((fld
 513                                                     (elmo-make-folder
 514                                                      (concat prefix server))))
 515                                                (luna-make-entity
 516                                                 'shimbun-elmo-mua
 517                                                 :folder fld))))))))
 518              folders)))))
 519
 520 (luna-define-method elmo-folder-exists-p ((folder elmo-shimbun-folder))
 521   (if (elmo-shimbun-folder-group-internal folder)
 522       (progn
 523         (member
 524          (elmo-shimbun-folder-group-internal folder)
 525          (shimbun-groups (elmo-shimbun-folder-shimbun-internal
 526                           folder))))
 527     t))
 528
 529 (require 'product)
 530 (product-provide (provide 'elmo-shimbun) (require 'elmo-version))
 531
 532 ;;; elmo-shimbun.el ends here