elmo/elmo-spam.el

   1 ;;; elmo-spam.el --- Spam filtering interface to processor.
   2
   3 ;; Copyright (C) 2003 Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   4 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   5
   6 ;; Author: Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   7 ;; Keywords: mail, net news, spam
   8
   9 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29
  30 ;;; Code:
  31 ;;
  32
  33 (eval-when-compile (require 'cl))
  34
  35 (require 'luna)
  36 (require 'elmo-util)
  37 (require 'elmo)
  38
  39 (defgroup elmo-spam nil
  40   "Spam configuration for wanderlust."
  41   :group 'elmo)
  42
  43 (defcustom elmo-spam-scheme nil
  44   "*Scheme of spam processor implementation. "
  45   :type '(choice (const :tag "none" nil)
  46                  (const :tag "Bogofilter" bogofilter)
  47                  (const :tag "Spamfilter" spamfilter)
  48                  (const :tag "SpamAssassin" sa)
  49                  (const :tag "Header" header)
  50                  (const :tag "Bsfilter" bsfilter))
  51   :group 'elmo-spam)
  52
  53 (eval-and-compile
  54   (luna-define-class elsp-generic ()))
  55
  56 ;; required method
  57 (luna-define-generic elmo-spam-buffer-spam-p (processor buffer
  58                                                         &optional register)
  59   "Return non-nil if contents of BUFFER is spam.
  60 PROCESSOR is spam processor structure.
  61 If optional augument REGISTER is non-nil,
  62 register according to the classification.")
  63
  64 (luna-define-generic elmo-spam-register-spam-buffer (processor
  65                                                      buffer
  66                                                      &optional restore)
  67   "Register contents of BUFFER as spam.
  68 PROCESSOR is spam processor structure.
  69 If optional argument RESTORE is non-nil, unregister from non-spam list.")
  70
  71 (luna-define-generic elmo-spam-register-good-buffer (processor
  72                                                      buffer
  73                                                      &optional restore)
  74   "Register contents of BUFFER as non-spam.
  75 PROCESSOR is spam processor structure.
  76 If optional argument RESTORE is non-nil, unregister from spam list.")
  77
  78 ;; optional method
  79 (luna-define-generic elmo-spam-modified-p (processor)
  80   "Return non-nil if status of PROCESSOR is modified.")
  81
  82 (luna-define-generic elmo-spam-save-status (processor)
  83   "Save status of the PROCESSOR.")
  84
  85 (luna-define-generic elmo-spam-message-spam-p (processor folder number
  86                                                          &optional register)
  87   "Return non-nil if the message in the FOLDER with NUMBER is spam.
  88 PROCESSOR is spam processor structure.
  89 If optional augument REGISTER is non-nil,
  90 register according to the classification.")
  91
  92 (luna-define-generic elmo-spam-list-spam-messages (processor
  93                                                    folder &optional numbers)
  94   "Return a list of message numbers which is classified as spam.
  95 PROCESSOR is spam processor structure.
  96 FOLDER is the ELMO folder structure.
  97 If optional argument NUMBERS is specified and is a list of message numbers,
  98 messages are searched from the list.")
  99
 100 (luna-define-generic elmo-spam-register-spam-messages (processor
 101                                                        folder
 102                                                        &optional
 103                                                        numbers restore)
 104   "Register contents of messages as spam.
 105 PROCESSOR is spam processor structure.
 106 FOLDER is the ELMO folder structure.
 107 If optional argument NUMBERS is specified and is a list of message numbers,
 108 messages are searched from the list.
 109 If optional argument RESTORE is non-nil, unregister from non-spam list.")
 110
 111 (luna-define-generic elmo-spam-register-good-messages (processor
 112                                                        folder
 113                                                        &optional
 114                                                        numbers restore)
 115   "Register contents of messages as non spam.
 116 PROCESSOR is spam processor structure.
 117 FOLDER is the ELMO folder structure.
 118 If optional argument NUMBERS is specified and is a list of message numbers,
 119 messages are searched from the list.
 120 If optional argument RESTORE is non-nil, unregister from spam list.")
 121
 122 ;; for internal use
 123 (defun elmo-spam-message-fetch (folder number)
 124   (let (elmo-message-fetch-threshold)
 125     (elmo-message-fetch
 126      folder number
 127      (elmo-find-fetch-strategy folder number nil 'entire)
 128      'unread)))
 129
 130 ;; generic implement
 131 (luna-define-method elmo-spam-message-spam-p ((processor elsp-generic)
 132                                               folder number &optional register)
 133   (with-temp-buffer
 134     (elmo-spam-message-fetch folder number)
 135     (elmo-spam-buffer-spam-p processor (current-buffer) register)))
 136
 137 (luna-define-method elmo-spam-list-spam-messages ((processor elsp-generic)
 138                                                   folder &optional numbers)
 139   (let ((numbers (or numbers (elmo-folder-list-messages folder t t)))
 140         spam-list)
 141     (dolist (number numbers)
 142       (when (elmo-spam-message-spam-p processor folder number)
 143         (setq spam-list (cons number spam-list)))
 144       (elmo-progress-notify 'elmo-spam-check-spam))
 145     (nreverse spam-list)))
 146
 147 (luna-define-method elmo-spam-register-spam-messages ((processor elsp-generic)
 148                                                       folder
 149                                                       &optional
 150                                                       numbers restore)
 151   (let ((numbers (or numbers (elmo-folder-list-messages folder t t))))
 152     (with-temp-buffer
 153       (dolist (number numbers)
 154         (erase-buffer)
 155         (elmo-spam-message-fetch folder number)
 156         (elmo-spam-register-spam-buffer processor (current-buffer) restore)
 157         (elmo-progress-notify 'elmo-spam-register)))))
 158
 159 (luna-define-method elmo-spam-register-good-messages ((processor elsp-generic)
 160                                                       folder
 161                                                       &optional
 162                                                       numbers restore)
 163   (let ((numbers (or numbers (elmo-folder-list-messages folder t t))))
 164     (with-temp-buffer
 165       (dolist (number numbers)
 166         (erase-buffer)
 167         (elmo-spam-message-fetch folder number)
 168         (elmo-spam-register-good-buffer processor (current-buffer) restore)
 169         (elmo-progress-notify 'elmo-spam-register)))))
 170
 171 (provide 'elsp-generic)
 172
 173 (defvar elmo-spam-processor-internal nil)
 174
 175 (defun elmo-spam-processor (&optional if-exists)
 176   (or elmo-spam-processor-internal
 177       (unless if-exists
 178         (let* ((scheme (or elmo-spam-scheme 'generic))
 179                (class (intern (format "elsp-%s" scheme))))
 180           (require class)
 181           (setq elmo-spam-processor-internal
 182                 (luna-make-entity class))))))
 183
 184 ;; Backend for header match
 185 (eval-and-compile
 186   (luna-define-class elsp-header (elsp-generic)))
 187
 188 (defgroup elmo-spam-header nil
 189   "Spam header configuration."
 190   :group 'elmo-spam)
 191
 192 (defcustom elmo-spam-header-good-alist '(("X-Spam-Flag" . "No"))
 193   "*Regular expression for positive header good matches."
 194   :type '(repeat (cons (string :tag "Header name")
 195                        (regexp :tag "Regular expression to match good header")))
 196   :group 'elmo-spam-header)
 197
 198 (defcustom elmo-spam-header-spam-alist '(("X-Spam-Flag" . "Yes"))
 199   "*Regular expression for positive header spam matches."
 200   :type '(repeat (cons (string :tag "Header name")
 201                        (regexp :tag "Regular expression to match spam header")))
 202   :group 'elmo-spam-header)
 203
 204 (defun elmo-spam-header-check-headers (fetch-field-function)
 205   (catch 'done
 206     (dolist (pair elmo-spam-header-good-alist)
 207       (let ((field-body (funcall fetch-field-function (car pair))))
 208         (when (and field-body (string-match (cdr pair) field-body))
 209           (throw 'done nil))))
 210     (dolist (pair elmo-spam-header-spam-alist)
 211       (let ((field-body (funcall fetch-field-function (car pair))))
 212         (when (and field-body (string-match (cdr pair) field-body))
 213           (throw 'done t))))))
 214
 215 (luna-define-method elmo-spam-buffer-spam-p ((processor elsp-header)
 216                                              buffer &optional register)
 217   (with-current-buffer buffer
 218     (save-restriction
 219       (std11-narrow-to-header)
 220       (elmo-spam-header-check-headers #'elmo-decoded-field-body))))
 221
 222 (luna-define-method elmo-spam-message-spam-p ((processor elsp-header)
 223                                               folder number &optional register)
 224   (let ((entity (elmo-message-entity folder number))
 225         buffer)
 226     (unwind-protect
 227         (save-excursion
 228           (elmo-spam-header-check-headers
 229            (lambda (field-name)
 230              (or (elmo-message-entity-field entity
 231                                             (intern (downcase field-name))
 232                                             'string)
 233                  (progn
 234                    (unless buffer
 235                      (setq buffer (get-buffer-create
 236                                    (generate-new-buffer-name
 237                                     " *elmo-spam-work*")))
 238                      (set-buffer buffer)
 239                      (elmo-spam-message-fetch folder number)
 240                      (std11-narrow-to-header))
 241                    (elmo-decoded-field-body field-name))))))
 242       (and buffer (kill-buffer buffer)))))
 243
 244 (luna-define-method elmo-spam-register-spam-messages ((processor elsp-header)
 245                                                       folder
 246                                                       &optional
 247                                                       numbers restore)
 248   (elmo-progress-notify 'elmo-spam-register (length numbers)))
 249
 250 (luna-define-method elmo-spam-register-good-messages ((processor elsp-header)
 251                                                       folder
 252                                                       &optional
 253                                                       numbers restore)
 254   (elmo-progress-notify 'elmo-spam-register (length numbers)))
 255
 256 (provide 'elsp-header)
 257
 258
 259 (require 'product)
 260 (product-provide (provide 'elmo-spam) (require 'elmo-version))
 261
 262 ;;; elmo-spam.el ends here