elmo/elmo-spam.el

   1 ;;; elmo-spam.el --- Spam filtering interface to processor.
   2
   3 ;; Copyright (C) 2003 Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   4 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   5
   6 ;; Author: Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   7 ;; Keywords: mail, net news, spam
   8
   9 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29
  30 ;;; Code:
  31 ;;
  32
  33 (eval-when-compile (require 'cl))
  34
  35 (require 'luna)
  36 (require 'elmo-util)
  37 (require 'elmo)
  38
  39 (defgroup elmo-spam nil
  40   "Spam configuration for wanderlust."
  41   :group 'elmo)
  42
  43 (defcustom elmo-spam-scheme nil
  44   "*Scheme of spam processor implementation. "
  45   :type '(choice (const :tag "none" nil)
  46                  (const :tag "Bogofilter" bogofilter)
  47                  (const :tag "Spamfilter" spamfilter)
  48                  (const :tag "SpamAssassin" sa)
  49                  (const :tag "Header" header)
  50                  (const :tag "Bsfilter" bsfilter))
  51   :group 'elmo-spam)
  52
  53 (eval-and-compile
  54   (luna-define-class elsp-generic ()))
  55
  56 ;; required method
  57 (luna-define-generic elmo-spam-buffer-spam-p (processor buffer
  58                                                         &optional register)
  59   "Return non-nil if contents of BUFFER is spam.
  60 PROCESSOR is spam processor structure.
  61 If optional augument REGISTER is non-nil,
  62 register according to the classification.")
  63
  64 (luna-define-generic elmo-spam-register-spam-buffer (processor
  65                                                      buffer
  66                                                      &optional restore)
  67   "Register contents of BUFFER as spam.
  68 PROCESSOR is spam processor structure.
  69 If optional argument RESTORE is non-nil, unregister from non-spam list.")
  70
  71 (luna-define-generic elmo-spam-register-good-buffer (processor
  72                                                      buffer
  73                                                      &optional restore)
  74   "Register contents of BUFFER as non-spam.
  75 PROCESSOR is spam processor structure.
  76 If optional argument RESTORE is non-nil, unregister from spam list.")
  77
  78 ;; optional method
  79 (luna-define-generic elmo-spam-modified-p (processor)
  80   "Return non-nil if status of PROCESSOR is modified.")
  81
  82 (luna-define-generic elmo-spam-save-status (processor)
  83   "Save status of the PROCESSOR.")
  84
  85 (luna-define-generic elmo-spam-message-spam-p (processor folder number
  86                                                          &optional register)
  87   "Return non-nil if the message in the FOLDER with NUMBER is spam.
  88 PROCESSOR is spam processor structure.
  89 If optional augument REGISTER is non-nil,
  90 register according to the classification.")
  91
  92 (luna-define-generic elmo-spam-list-spam-messages (processor
  93                                                    folder &optional numbers)
  94   "Return a list of message numbers which is classified as spam.
  95 PROCESSOR is spam processor structure.
  96 FOLDER is the ELMO folder structure.
  97 If optional argument NUMBERS is specified and is a list of message numbers,
  98 messages are searched from the list.")
  99
 100 (luna-define-generic elmo-spam-register-spam-messages (processor
 101                                                        folder
 102                                                        &optional
 103                                                        numbers restore)
 104   "Register contents of messages as spam.
 105 PROCESSOR is spam processor structure.
 106 FOLDER is the ELMO folder structure.
 107 If optional argument NUMBERS is specified and is a list of message numbers,
 108 messages are searched from the list.
 109 If optional argument RESTORE is non-nil, unregister from non-spam list.")
 110
 111 (luna-define-generic elmo-spam-register-good-messages (processor
 112                                                        folder
 113                                                        &optional
 114                                                        numbers restore)
 115   "Register contents of messages as non spam.
 116 PROCESSOR is spam processor structure.
 117 FOLDER is the ELMO folder structure.
 118 If optional argument NUMBERS is specified and is a list of message numbers,
 119 messages are searched from the list.
 120 If optional argument RESTORE is non-nil, unregister from spam list.")
 121
 122 ;; for internal use
 123 (defun elmo-spam-message-fetch (folder number)
 124   (let (elmo-message-fetch-threshold)
 125     (when enable-multibyte-characters
 126       (set-buffer-multibyte nil))
 127     (elmo-message-fetch
 128      folder number
 129      (elmo-find-fetch-strategy folder number nil 'entire)
 130      'unread)))
 131
 132 ;; generic implement
 133 (luna-define-method elmo-spam-message-spam-p ((processor elsp-generic)
 134                                               folder number &optional register)
 135   (with-temp-buffer
 136     (elmo-spam-message-fetch folder number)
 137     (elmo-spam-buffer-spam-p processor (current-buffer) register)))
 138
 139 (luna-define-method elmo-spam-list-spam-messages ((processor elsp-generic)
 140                                                   folder &optional numbers)
 141   (let ((numbers (or numbers (elmo-folder-list-messages folder t t)))
 142         spam-list)
 143     (dolist (number numbers)
 144       (when (elmo-spam-message-spam-p processor folder number)
 145         (setq spam-list (cons number spam-list)))
 146       (elmo-progress-notify 'elmo-spam-check-spam))
 147     (nreverse spam-list)))
 148
 149 (luna-define-method elmo-spam-register-spam-messages ((processor elsp-generic)
 150                                                       folder
 151                                                       &optional
 152                                                       numbers restore)
 153   (let ((numbers (or numbers (elmo-folder-list-messages folder t t))))
 154     (with-temp-buffer
 155       (dolist (number numbers)
 156         (erase-buffer)
 157         (elmo-spam-message-fetch folder number)
 158         (elmo-spam-register-spam-buffer processor (current-buffer) restore)
 159         (elmo-progress-notify 'elmo-spam-register)))))
 160
 161 (luna-define-method elmo-spam-register-good-messages ((processor elsp-generic)
 162                                                       folder
 163                                                       &optional
 164                                                       numbers restore)
 165   (let ((numbers (or numbers (elmo-folder-list-messages folder t t))))
 166     (with-temp-buffer
 167       (dolist (number numbers)
 168         (erase-buffer)
 169         (elmo-spam-message-fetch folder number)
 170         (elmo-spam-register-good-buffer processor (current-buffer) restore)
 171         (elmo-progress-notify 'elmo-spam-register)))))
 172
 173 (provide 'elsp-generic)
 174
 175 (defvar elmo-spam-processor-internal nil)
 176
 177 (defun elmo-spam-processor (&optional if-exists)
 178   (or elmo-spam-processor-internal
 179       (unless if-exists
 180         (let* ((scheme (or elmo-spam-scheme 'generic))
 181                (class (intern (format "elsp-%s" scheme))))
 182           (require class)
 183           (setq elmo-spam-processor-internal
 184                 (luna-make-entity class))))))
 185
 186 ;; Backend for header match
 187 (eval-and-compile
 188   (luna-define-class elsp-header (elsp-generic)))
 189
 190 (defgroup elmo-spam-header nil
 191   "Spam header configuration."
 192   :group 'elmo-spam)
 193
 194 (defcustom elmo-spam-header-good-alist '(("X-Spam-Flag" . "No"))
 195   "*Regular expression for positive header good matches."
 196   :type '(repeat (cons (string :tag "Header name")
 197                        (regexp :tag "Regular expression to match good header")))
 198   :group 'elmo-spam-header)
 199
 200 (defcustom elmo-spam-header-spam-alist '(("X-Spam-Flag" . "Yes"))
 201   "*Regular expression for positive header spam matches."
 202   :type '(repeat (cons (string :tag "Header name")
 203                        (regexp :tag "Regular expression to match spam header")))
 204   :group 'elmo-spam-header)
 205
 206 (defun elmo-spam-header-check-headers (fetch-field-function)
 207   (catch 'done
 208     (dolist (pair elmo-spam-header-good-alist)
 209       (let ((field-body (funcall fetch-field-function (car pair))))
 210         (when (and field-body (string-match (cdr pair) field-body))
 211           (throw 'done nil))))
 212     (dolist (pair elmo-spam-header-spam-alist)
 213       (let ((field-body (funcall fetch-field-function (car pair))))
 214         (when (and field-body (string-match (cdr pair) field-body))
 215           (throw 'done t))))))
 216
 217 (luna-define-method elmo-spam-buffer-spam-p ((processor elsp-header)
 218                                              buffer &optional register)
 219   (with-current-buffer buffer
 220     (save-restriction
 221       (std11-narrow-to-header)
 222       (elmo-spam-header-check-headers #'elmo-decoded-field-body))))
 223
 224 (luna-define-method elmo-spam-message-spam-p ((processor elsp-header)
 225                                               folder number &optional register)
 226   (let ((entity (elmo-message-entity folder number))
 227         buffer)
 228     (unwind-protect
 229         (save-excursion
 230           (elmo-spam-header-check-headers
 231            (lambda (field-name)
 232              (or (elmo-message-entity-field entity
 233                                             (intern (downcase field-name))
 234                                             'string)
 235                  (progn
 236                    (unless buffer
 237                      (setq buffer (get-buffer-create
 238                                    (generate-new-buffer-name
 239                                     " *elmo-spam-work*")))
 240                      (set-buffer buffer)
 241                      (elmo-spam-message-fetch folder number)
 242                      (std11-narrow-to-header))
 243                    (elmo-decoded-field-body field-name))))))
 244       (and buffer (kill-buffer buffer)))))
 245
 246 (luna-define-method elmo-spam-register-spam-messages ((processor elsp-header)
 247                                                       folder
 248                                                       &optional
 249                                                       numbers restore)
 250   (elmo-progress-notify 'elmo-spam-register (length numbers)))
 251
 252 (luna-define-method elmo-spam-register-good-messages ((processor elsp-header)
 253                                                       folder
 254                                                       &optional
 255                                                       numbers restore)
 256   (elmo-progress-notify 'elmo-spam-register (length numbers)))
 257
 258 (provide 'elsp-header)
 259
 260
 261 (require 'product)
 262 (product-provide (provide 'elmo-spam) (require 'elmo-version))
 263
 264 ;;; elmo-spam.el ends here