elmo/elmo-spam.el

   1 ;;; elmo-spam.el --- Spam filtering interface to processor.
   2
   3 ;; Copyright (C) 2003 Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   4 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   5
   6 ;; Author: Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   7 ;; Keywords: mail, net news, spam
   8
   9 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29
  30 ;;; Code:
  31 ;;
  32
  33 (eval-when-compile (require 'cl))
  34
  35 (require 'luna)
  36 (require 'elmo-util)
  37 (require 'elmo)
  38
  39 (defgroup elmo-spam nil
  40   "Spam configuration for wanderlust."
  41   :group 'elmo)
  42
  43 (defcustom elmo-spam-scheme nil
  44   "*Scheme of spam processor implementation. "
  45   :type '(choice (const :tag "none" nil)
  46                  (const :tag "Bogofilter" bogofilter))
  47   :group 'elmo-spam)
  48
  49 (eval-and-compile
  50   (luna-define-class elsp-generic ()))
  51
  52 ;; required method
  53 (luna-define-generic elmo-spam-buffer-spam-p (processor buffer)
  54   "Return non-nil if contents of BUFFER is spam.
  55 PROCESSOR is spam processor structure.")
  56
  57 (luna-define-generic elmo-spam-register-spam-buffer (processor buffer)
  58   "Register contents of BUFFER as spam.
  59 PROCESSOR is spam processor structure.")
  60
  61 (luna-define-generic elmo-spam-register-good-buffer (processor buffer)
  62   "Register contents of BUFFER as non spam.
  63 PROCESSOR is spam processor structure.")
  64
  65 ;; optional method
  66 (luna-define-generic elmo-spam-message-spam-p (processor folder number)
  67   "Return non-nil if the message in the FOLDER with NUMBER is spam.
  68 PROCESSOR is spam processor structure.")
  69
  70 (luna-define-generic elmo-spam-list-spam-messages (processor
  71                                                    folder &optional numbers)
  72   "Return a list of message numbers which is gussed spam.
  73 PROCESSOR is spam processor structure.
  74 FOLDER is the ELMO folder structure.
  75 If optional argument NUMBERS is specified and is a list of message numbers,
  76 messages are searched from the list.")
  77
  78 (luna-define-generic elmo-spam-register-spam-messages (processor
  79                                                        folder &optional numbers)
  80   "Register contents of messages as spam.
  81 PROCESSOR is spam processor structure.
  82 FOLDER is the ELMO folder structure.
  83 If optional argument NUMBERS is specified and is a list of message numbers,
  84 messages are searched from the list.")
  85
  86 (luna-define-generic elmo-spam-register-good-messages (processor
  87                                                        folder &optional numbers)
  88   "Register contents of messages as non spam.
  89 PROCESSOR is spam processor structure.
  90 FOLDER is the ELMO folder structure.
  91 If optional argument NUMBERS is specified and is a list of message numbers,
  92 messages are searched from the list.")
  93
  94 ;; for internal use
  95 (defun elmo-spam-message-fetch (folder number)
  96   (let (elmo-message-fetch-threshold)
  97     (elmo-message-fetch
  98      folder number
  99      (elmo-find-fetch-strategy folder
 100                                (elmo-message-entity folder number))
 101      nil (current-buffer) 'unread)))
 102
 103 ;; generic implement
 104 (luna-define-method elmo-spam-message-spam-p ((processor elsp-generic)
 105                                               folder number)
 106   (with-temp-buffer
 107     (elmo-spam-message-fetch folder number)
 108     (elmo-spam-buffer-spam-p processor (current-buffer))))
 109
 110 (luna-define-method elmo-spam-list-spam-messages ((processor elsp-generic)
 111                                                   folder &optional numbers)
 112   (let ((numbers (or numbers (elmo-folder-list-messages folder t t)))
 113         spam-list)
 114     (dolist (number numbers)
 115       (when (elmo-spam-message-spam-p processor folder number)
 116         (setq spam-list (cons number spam-list)))
 117       (elmo-progress-notify 'elmo-spam-check-spam))
 118     (nreverse spam-list)))
 119
 120 (luna-define-method elmo-spam-register-spam-messages ((processor elsp-generic)
 121                                                       folder &optional numbers)
 122   (let ((numbers (or numbers (elmo-folder-list-messages folder t t))))
 123     (with-temp-buffer
 124       (buffer-disable-undo (current-buffer))
 125       (dolist (number numbers)
 126         (erase-buffer)
 127         (elmo-spam-message-fetch folder number)
 128         (elmo-spam-register-spam-buffer processor (current-buffer))
 129         (elmo-progress-notify 'elmo-spam-register)))))
 130
 131 (luna-define-method elmo-spam-register-good-messages ((processor elsp-generic)
 132                                                       folder &optional numbers)
 133   (let ((numbers (or numbers (elmo-folder-list-messages folder t t))))
 134     (with-temp-buffer
 135       (buffer-disable-undo (current-buffer))
 136       (dolist (number numbers)
 137         (erase-buffer)
 138         (elmo-spam-message-fetch folder number)
 139         (elmo-spam-register-good-buffer processor (current-buffer))
 140         (elmo-progress-notify 'elmo-spam-register)))))
 141
 142 (provide 'elsp-generic)
 143
 144 (defvar elmo-spam-processor-internal nil)
 145
 146 (defun elmo-spam-processor ()
 147   (or elmo-spam-processor-internal
 148       (let* ((scheme (or elmo-spam-scheme 'generic))
 149              (class (intern (format "elsp-%s" scheme))))
 150         (require class)
 151         (setq elmo-spam-processor-internal
 152               (luna-make-entity class)))))
 153
 154 (require 'product)
 155 (product-provide (provide 'elmo-spam) (require 'elmo-version))
 156
 157 ;;; elmo-sapm.el ends here