elmo/elmo-util.el

   1 ;;; elmo-util.el --- Utilities for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (eval-when-compile (require 'cl))
  33 (require 'elmo-vars)
  34 (require 'elmo-date)
  35 (require 'mcharset)
  36 (require 'pces)
  37 (require 'std11)
  38 (require 'eword-decode)
  39 (require 'utf7)
  40 (require 'poem)
  41 (require 'emu)
  42
  43 (eval-and-compile
  44   (autoload 'md5 "md5"))
  45
  46 (defvar elmo-work-buf-name " *elmo work*")
  47 (defvar elmo-temp-buf-name " *elmo temp*")
  48
  49 (or (boundp 'default-enable-multibyte-characters)
  50     (defvar default-enable-multibyte-characters (featurep 'mule)
  51       "The mock variable except for Emacs 20."))
  52
  53 (defun elmo-base64-encode-string (string &optional no-line-break))
  54 (defun elmo-base64-decode-string (string))
  55
  56 ;; base64 encoding/decoding
  57 (require 'mel)
  58 (fset 'elmo-base64-encode-string
  59       (mel-find-function 'mime-encode-string "base64"))
  60 (fset 'elmo-base64-decode-string
  61       (mel-find-function 'mime-decode-string "base64"))
  62
  63 ;; Any Emacsen may have add-name-to-file(), because loadup.el requires it. :-p
  64 ;; Check make-symbolic-link() instead.  -- 981002 by Fuji
  65 (if (fboundp 'make-symbolic-link)  ;; xxx
  66     (defalias 'elmo-add-name-to-file 'add-name-to-file)
  67   (defun elmo-add-name-to-file
  68     (filename newname &optional ok-if-already-exists)
  69     (copy-file filename newname ok-if-already-exists t)))
  70
  71 (defmacro elmo-set-work-buf (&rest body)
  72   "Execute BODY on work buffer.  Work buffer remains."
  73   (` (save-excursion
  74        (set-buffer (get-buffer-create elmo-work-buf-name))
  75        (set-buffer-multibyte default-enable-multibyte-characters)
  76        (erase-buffer)
  77        (,@ body))))
  78
  79 (put 'elmo-set-work-buf 'lisp-indent-function 0)
  80 (def-edebug-spec elmo-set-work-buf t)
  81
  82 (defmacro elmo-bind-directory (dir &rest body)
  83   "Set current directory DIR and execute BODY."
  84   (` (let ((default-directory (file-name-as-directory (, dir))))
  85        (,@ body))))
  86
  87 (put 'elmo-bind-directory 'lisp-indent-function 1)
  88 (def-edebug-spec elmo-bind-directory
  89   (form &rest form))
  90
  91 (defconst elmo-multibyte-buffer-name " *elmo-multibyte-buffer*")
  92
  93 (defmacro elmo-with-enable-multibyte (&rest body)
  94   "Evaluate BODY with `default-enable-multibyte-character'."
  95   `(with-current-buffer (get-buffer-create elmo-multibyte-buffer-name)
  96      ,@body))
  97
  98 (put 'elmo-with-enable-multibyte 'lisp-indent-function 0)
  99 (def-edebug-spec elmo-with-enable-multibyte t)
 100
 101 (eval-when-compile
 102   (unless (fboundp 'coding-system-base)
 103     (defalias 'coding-system-base 'ignore))
 104   (unless (fboundp 'coding-system-name)
 105     (defalias 'coding-system-name 'ignore))
 106   (unless (fboundp 'find-file-coding-system-for-read-from-filename)
 107     (defalias 'find-file-coding-system-for-read-from-filename 'ignore))
 108   (unless (fboundp 'find-operation-coding-system)
 109     (defalias 'find-operation-coding-system 'ignore)))
 110
 111 (defun elmo-set-auto-coding (&optional filename)
 112   "Find coding system used to decode the contents of the current buffer.
 113 This function looks for the coding system magic cookie or examines the
 114 coding system specified by `file-coding-system-alist' being associated
 115 with FILENAME which defaults to `buffer-file-name'."
 116   (cond
 117    ((boundp 'set-auto-coding-function) ;; Emacs
 118     (if filename
 119         (or (funcall (symbol-value 'set-auto-coding-function)
 120                      filename (- (point-max) (point-min)))
 121             (car (find-operation-coding-system 'insert-file-contents
 122                                                filename)))
 123       (let (auto-coding-alist)
 124         (condition-case nil
 125             (funcall (symbol-value 'set-auto-coding-function)
 126                      nil (- (point-max) (point-min)))
 127           (error nil)))))
 128    ((featurep 'file-coding) ;; XEmacs
 129     (let ((case-fold-search t)
 130           (end (point-at-eol))
 131           codesys start)
 132       (or
 133        (and (re-search-forward "-\\*-+[\t ]*" end t)
 134             (progn
 135               (setq start (match-end 0))
 136               (re-search-forward "[\t ]*-+\\*-" end t))
 137             (progn
 138               (setq end (match-beginning 0))
 139               (goto-char start)
 140               (or (looking-at "coding:[\t ]*\\([^\t ;]+\\)")
 141                   (re-search-forward
 142                    "[\t ;]+coding:[\t ]*\\([^\t ;]+\\)"
 143                    end t)))
 144             (find-coding-system (setq codesys
 145                                       (intern (match-string 1))))
 146             codesys)
 147        (and (re-search-forward "^[\t ]*;+[\t ]*Local[\t ]+Variables:"
 148                                nil t)
 149             (progn
 150               (setq start (match-end 0))
 151               (re-search-forward "^[\t ]*;+[\t ]*End:" nil t))
 152             (progn
 153               (setq end (match-beginning 0))
 154               (goto-char start)
 155               (re-search-forward
 156                "^[\t ]*;+[\t ]*coding:[\t ]*\\([^\t\n\r ]+\\)"
 157                end t))
 158             (find-coding-system (setq codesys
 159                                       (intern (match-string 1))))
 160             codesys)
 161        (and (progn
 162               (goto-char (point-min))
 163               (setq case-fold-search nil)
 164               (re-search-forward "^;;;coding system: "
 165                                  ;;(+ (point-min) 3000) t))
 166                                  nil t))
 167             (looking-at "[^\t\n\r ]+")
 168             (find-coding-system
 169              (setq codesys (intern (match-string 0))))
 170             codesys)
 171        (and filename
 172             (setq codesys
 173                   (find-file-coding-system-for-read-from-filename
 174                    filename))
 175             (coding-system-name (coding-system-base codesys))))))))
 176
 177 (defun elmo-object-load (filename &optional mime-charset no-err)
 178   "Load OBJECT from the file specified by FILENAME.
 179 File content is decoded with MIME-CHARSET."
 180   (if (not (file-readable-p filename))
 181       nil
 182     (with-temp-buffer
 183       (insert-file-contents-as-binary filename)
 184       (let ((coding-system (or (elmo-set-auto-coding)
 185                                (mime-charset-to-coding-system
 186                                 mime-charset))))
 187         (when coding-system
 188           (decode-coding-region (point-min) (point-max) coding-system)))
 189       (goto-char (point-min))
 190       (condition-case nil
 191           (read (current-buffer))
 192         (error (unless no-err
 193                  (message "Warning: Loading object from %s failed."
 194                           filename)
 195                  (elmo-object-save filename nil mime-charset))
 196                nil)))))
 197
 198 (defsubst elmo-save-buffer (filename &optional mime-charset)
 199   "Save current buffer to the file specified by FILENAME.
 200 Directory of the file is created if it doesn't exist.
 201 File content is encoded with MIME-CHARSET."
 202   (let ((dir (directory-file-name (file-name-directory filename))))
 203     (if (file-directory-p dir)
 204         () ; ok.
 205       (unless (file-exists-p dir)
 206         (elmo-make-directory dir)))
 207     (if (file-writable-p filename)
 208         (progn
 209           (when mime-charset
 210 ;;;         (set-buffer-multibyte default-enable-multibyte-characters)
 211             (encode-mime-charset-region (point-min) (point-max) mime-charset))
 212           (as-binary-output-file
 213            (write-region (point-min) (point-max) filename nil 'no-msg)))
 214       (message "%s is not writable." filename))))
 215
 216 (defun elmo-object-save (filename object &optional mime-charset)
 217   "Save OBJECT to the file specified by FILENAME.
 218 Directory of the file is created if it doesn't exist.
 219 File content is encoded with MIME-CHARSET."
 220   (with-temp-buffer
 221     (let (print-length print-level)
 222       (prin1 object (current-buffer)))
 223     (when mime-charset
 224       (let ((coding (mime-charset-to-coding-system
 225                      (or (detect-mime-charset-region (point-min) (point-max))
 226                          mime-charset))))
 227         (goto-char (point-min))
 228         (insert ";;; -*- mode: emacs-lisp; coding: "
 229                 (symbol-name coding) " -*-\n")
 230         (encode-coding-region (point-min) (point-max) coding)))
 231     (elmo-save-buffer filename)))
 232
 233 ;;; Search Condition
 234
 235 (defconst elmo-condition-atom-regexp "[^/ \")|&]*")
 236
 237 (defsubst elmo-condition-parse-error ()
 238   (error "Syntax error in '%s'" (buffer-string)))
 239
 240 (defun elmo-parse-search-condition (condition)
 241   "Parse CONDITION.
 242 Return value is a cons cell of (STRUCTURE . REST)"
 243   (with-temp-buffer
 244     (insert condition)
 245     (goto-char (point-min))
 246     (cons (elmo-condition-parse) (buffer-substring (point) (point-max)))))
 247
 248 ;; condition    ::= or-expr
 249 (defun elmo-condition-parse ()
 250   (or (elmo-condition-parse-or-expr)
 251       (elmo-condition-parse-error)))
 252
 253 ;; or-expr      ::= and-expr /
 254 ;;                  and-expr "|" or-expr
 255 (defun elmo-condition-parse-or-expr ()
 256   (let ((left (elmo-condition-parse-and-expr)))
 257     (if (looking-at "| *")
 258         (progn
 259           (goto-char (match-end 0))
 260           (list 'or left (elmo-condition-parse-or-expr)))
 261       left)))
 262
 263 ;; and-expr     ::= primitive /
 264 ;;                  primitive "&" and-expr
 265 (defun elmo-condition-parse-and-expr ()
 266   (let ((left (elmo-condition-parse-primitive)))
 267     (if (looking-at "& *")
 268         (progn
 269           (goto-char (match-end 0))
 270           (list 'and left (elmo-condition-parse-and-expr)))
 271       left)))
 272
 273 ;; primitive    ::= "(" expr ")" /
 274 ;;                  ["!"] search-key SPACE* ":" SPACE* search-value
 275 (defun elmo-condition-parse-primitive ()
 276   (cond
 277    ((looking-at "( *")
 278     (goto-char (match-end 0))
 279     (prog1 (elmo-condition-parse)
 280       (unless (looking-at ") *")
 281         (elmo-condition-parse-error))
 282       (goto-char (match-end 0))))
 283 ;; search-key   ::= [A-Za-z-]+
 284 ;;                 ;; "since" / "before" / "last" / "first" /
 285 ;;                 ;; "body" / "flag" / field-name
 286    ((looking-at "\\(!\\)? *\\([A-Za-z-]+\\) *: *")
 287     (goto-char (match-end 0))
 288     (let ((search-key (vector
 289                        (if (match-beginning 1) 'unmatch 'match)
 290                        (downcase (elmo-match-buffer 2))
 291                        (elmo-condition-parse-search-value))))
 292       ;; syntax sugar.
 293       (if (string= (aref search-key 1) "tocc")
 294           (if (eq (aref search-key 0) 'match)
 295               (list 'or
 296                     (vector 'match "to" (aref search-key 2))
 297                     (vector 'match "cc" (aref search-key 2)))
 298             (list 'and
 299                   (vector 'unmatch "to" (aref search-key 2))
 300                   (vector 'unmatch "cc" (aref search-key 2))))
 301         search-key)))))
 302
 303 ;; search-value ::= quoted / time / number / atom
 304 ;; quoted       ::= <elisp string expression>
 305 ;; time         ::= "yesterday" / "lastweek" / "lastmonth" / "lastyear" /
 306 ;;                   number SPACE* "daysago" /
 307 ;;                   number "-" month "-" number  ; ex. 10-May-2000
 308 ;;                   number "-" number "-" number  ; ex. 2000-05-10
 309 ;; number       ::= [0-9]+
 310 ;; month        ::= "Jan" / "Feb" / "Mar" / "Apr" / "May" / "Jun" /
 311 ;;                  "Jul" / "Aug" / "Sep" / "Oct" / "Nov" / "Dec"
 312 ;; atom         ::= ATOM_CHARS*
 313 ;; SPACE        ::= <ascii space character, 0x20>
 314 ;; ATOM_CHARS   ::= <any character except specials>
 315 ;; specials     ::= SPACE / <"> / </> / <)> / <|> / <&>
 316 ;;                  ;; These characters should be quoted.
 317 (defun elmo-condition-parse-search-value ()
 318   (cond
 319    ((looking-at "\"")
 320     (read (current-buffer)))
 321    ((or (looking-at elmo-condition-atom-regexp)
 322         (looking-at "yesterday") (looking-at "lastweek")
 323         (looking-at "lastmonth") (looking-at "lastyear")
 324         (looking-at "[0-9]+ *daysago")
 325         (looking-at "[0-9]+-[A-Za-z]+-[0-9]+")
 326         (looking-at "[0-9]+-[0-9]+-[0-9]+")
 327         (looking-at "[0-9]+"))
 328     (prog1 (elmo-match-buffer 0)
 329       (goto-char (match-end 0))))
 330    (t (error "Syntax error '%s'" (buffer-string)))))
 331
 332 (defmacro elmo-filter-condition-p (filter)
 333   `(or (vectorp ,filter) (consp ,filter)))
 334
 335 (defmacro elmo-filter-type (filter)
 336   `(aref ,filter 0))
 337
 338 (defmacro elmo-filter-key (filter)
 339   `(aref ,filter 1))
 340
 341 (defmacro elmo-filter-value (filter)
 342   `(aref ,filter 2))
 343
 344 (defun elmo-condition-match (condition match-primitive args)
 345   (cond
 346    ((vectorp condition)
 347     (if (eq (elmo-filter-type condition) 'unmatch)
 348         (not (apply match-primitive condition args))
 349       (apply match-primitive condition args)))
 350    ((eq (car condition) 'and)
 351     (let ((lhs (elmo-condition-match (nth 1 condition) match-primitive args)))
 352       (cond
 353        ((elmo-filter-condition-p lhs)
 354         (let ((rhs (elmo-condition-match (nth 2 condition)
 355                                          match-primitive args)))
 356           (cond ((elmo-filter-condition-p rhs)
 357                  (list 'and lhs rhs))
 358                 (rhs
 359                  lhs))))
 360        (lhs
 361         (elmo-condition-match (nth 2 condition) match-primitive args)))))
 362    ((eq (car condition) 'or)
 363     (let ((lhs (elmo-condition-match (nth 1 condition) match-primitive args)))
 364       (cond
 365        ((elmo-filter-condition-p lhs)
 366         (let ((rhs (elmo-condition-match (nth 2 condition)
 367                                          match-primitive args)))
 368           (cond ((elmo-filter-condition-p rhs)
 369                  (list 'or lhs rhs))
 370                 (rhs
 371                  t)
 372                 (t
 373                  lhs))))
 374        (lhs
 375         t)
 376        (t
 377         (elmo-condition-match (nth 2 condition) match-primitive args)))))))
 378
 379 (defun elmo-condition-optimize (condition)
 380   (cond
 381    ((vectorp condition)
 382     (let ((key (elmo-filter-key condition)))
 383       (cond ((cdr (assoc key '(("first" . 0)
 384                                ("last"  . 0)
 385                                ("flag"  . 1)
 386                                ("body"  . 5)))))
 387             ((member key '("since" "before" "from" "subject" "to" "cc"))
 388              2)
 389             ((member key elmo-msgdb-extra-fields)
 390              3)
 391             (t
 392              4))))
 393    (t
 394     (let ((weight-l (elmo-condition-optimize (nth 1 condition)))
 395           (weight-r (elmo-condition-optimize (nth 2 condition))))
 396       (if (> weight-l weight-r)
 397           (let ((lhs (nth 1 condition)))
 398             (setcar (nthcdr 1 condition) (nth 2 condition))
 399             (setcar (nthcdr 2 condition) lhs)
 400             weight-l)
 401         weight-r)))))
 402
 403 ;;;
 404 (defsubst elmo-buffer-replace (regexp &optional newtext)
 405   (goto-char (point-min))
 406   (while (re-search-forward regexp nil t)
 407     (replace-match (or newtext ""))))
 408
 409 (defsubst elmo-delete-char (char string &optional unibyte)
 410   (save-match-data
 411     (elmo-set-work-buf
 412      (let ((coding-system-for-read 'no-conversion)
 413            (coding-system-for-write 'no-conversion))
 414        (if unibyte (set-buffer-multibyte nil))
 415        (insert string)
 416        (goto-char (point-min))
 417        (while (search-forward (char-to-string char) nil t)
 418          (replace-match ""))
 419        (buffer-string)))))
 420
 421 (defsubst elmo-delete-cr-buffer ()
 422   "Delete CR from buffer."
 423   (save-excursion
 424     (goto-char (point-min))
 425     (while (search-forward "\r\n" nil t)
 426       (replace-match "\n")) ))
 427
 428 (defsubst elmo-delete-cr-get-content-type ()
 429   (save-excursion
 430     (goto-char (point-min))
 431     (while (search-forward "\r\n" nil t)
 432       (replace-match "\n"))
 433     (goto-char (point-min))
 434     (or (std11-field-body "content-type")
 435         t)))
 436
 437 (defun elmo-delete-cr (string)
 438   (save-match-data
 439     (elmo-set-work-buf
 440      (insert string)
 441      (goto-char (point-min))
 442      (while (search-forward "\r\n" nil t)
 443        (replace-match "\n"))
 444      (buffer-string))))
 445
 446 (defun elmo-last (list)
 447   (and list (nth (1- (length list)) list)))
 448
 449 (defun elmo-set-list (vars vals)
 450   (while vars
 451     (when (car vars)
 452       (set (car vars) (car vals)))
 453     (setq vars (cdr vars)
 454           vals (cdr vals))))
 455
 456 (defun elmo-uniq-list (lst &optional delete-function)
 457   "Distractively uniqfy elements of LST."
 458   (setq delete-function (or delete-function #'delete))
 459   (let ((tmp lst))
 460     (while tmp
 461       (setq tmp
 462             (setcdr tmp
 463                     (and (cdr tmp)
 464                          (funcall delete-function
 465                                   (car tmp)
 466                                   (cdr tmp)))))))
 467   lst)
 468
 469 (defun elmo-uniq-sorted-list (list &optional equal-function)
 470   "Distractively uniqfy elements of sorted LIST."
 471   (setq equal-function (or equal-function #'equal))
 472   (let ((list list))
 473     (while list
 474       (while (funcall equal-function (car list) (cadr list))
 475         (setcdr list (cddr list)))
 476       (setq list (cdr list))))
 477   list)
 478
 479 (defun elmo-list-insert (list element after)
 480   (let* ((match (memq after list))
 481          (rest (and match (cdr (memq after list)))))
 482     (if match
 483         (progn
 484           (setcdr match (list element))
 485           (nconc list rest))
 486       (nconc list (list element)))))
 487
 488 (defun elmo-get-file-string (filename &optional remove-final-newline)
 489   (elmo-set-work-buf
 490    (let (insert-file-contents-pre-hook   ; To avoid autoconv-xmas...
 491          insert-file-contents-post-hook)
 492      (when (file-exists-p filename)
 493        (if filename
 494            (as-binary-input-file (insert-file-contents filename)))
 495        (when (and remove-final-newline
 496                   (> (buffer-size) 0)
 497                   (= (char-after (1- (point-max))) ?\n))
 498          (goto-char (point-max))
 499          (delete-backward-char 1))
 500        (buffer-string)))))
 501
 502 (defun elmo-save-string (string filename)
 503   (if string
 504       (elmo-set-work-buf
 505        (as-binary-output-file
 506         (insert string)
 507         (write-region (point-min) (point-max)
 508                       filename nil 'no-msg))
 509        )))
 510
 511 (defun elmo-max-of-list (nlist)
 512   (let ((l nlist)
 513         (max-num 0))
 514     (while l
 515       (if (< max-num (car l))
 516           (setq max-num (car l)))
 517       (setq l (cdr l)))
 518     max-num))
 519
 520 (defun elmo-concat-path (path filename)
 521   (if (not (string= path ""))
 522       (elmo-replace-in-string
 523        (if (string= elmo-path-sep (substring path (- (length path) 1)))
 524            (concat path filename)
 525          (concat path elmo-path-sep filename))
 526        (concat (regexp-quote elmo-path-sep)(regexp-quote elmo-path-sep))
 527        elmo-path-sep)
 528     filename))
 529
 530 (defvar elmo-passwd-alist nil)
 531
 532 (defun elmo-passwd-alist-load ()
 533   (with-temp-buffer
 534     (let ((filename (expand-file-name elmo-passwd-alist-file-name
 535                                       elmo-msgdb-directory))
 536           insert-file-contents-pre-hook ; To avoid autoconv-xmas...
 537           insert-file-contents-post-hook
 538           ret-val)
 539       (if (not (file-readable-p filename))
 540           ()
 541         (insert-file-contents filename)
 542         (condition-case nil
 543             (read (current-buffer))
 544           (error nil nil))))))
 545
 546 (defun elmo-passwd-alist-clear ()
 547   "Clear password cache."
 548   (interactive)
 549   (dolist (pair elmo-passwd-alist)
 550     (when (stringp (cdr-safe pair))
 551       (fillarray (cdr pair) 0)))
 552   (setq elmo-passwd-alist nil))
 553
 554 (defun elmo-passwd-alist-save ()
 555   "Save password into file."
 556   (interactive)
 557   (with-temp-buffer
 558     (let ((filename (expand-file-name elmo-passwd-alist-file-name
 559                                       elmo-msgdb-directory))
 560           print-length print-level)
 561       (prin1 elmo-passwd-alist (current-buffer))
 562       (princ "\n" (current-buffer))
 563 ;;;   (if (and (file-exists-p filename)
 564 ;;;            (not (equal 384 (file-modes filename))))
 565 ;;;       (error "%s is not safe.chmod 600 %s!" filename filename))
 566       (if (file-writable-p filename)
 567           (progn
 568             (write-region (point-min) (point-max)
 569                           filename nil 'no-msg)
 570             (set-file-modes filename 384))
 571         (message "%s is not writable." filename)))))
 572
 573 (defun elmo-get-passwd (key)
 574   "Get password from password pool."
 575   (let (pair pass)
 576     (if (not elmo-passwd-alist)
 577         (setq elmo-passwd-alist (elmo-passwd-alist-load)))
 578     (setq pair (assoc key elmo-passwd-alist))
 579     (if pair
 580         (elmo-base64-decode-string (cdr pair))
 581       (setq pass (elmo-read-passwd (format "Password for %s: "
 582                                            key) t))
 583       (setq elmo-passwd-alist
 584             (append elmo-passwd-alist
 585                     (list (cons key
 586                                 (elmo-base64-encode-string pass)))))
 587       (if elmo-passwd-life-time
 588           (run-with-timer elmo-passwd-life-time nil
 589                           (` (lambda () (elmo-remove-passwd (, key))))))
 590       pass)))
 591
 592 (defun elmo-remove-passwd (key)
 593   "Remove password from password pool (for failure)."
 594   (let (pass-cons)
 595     (while (setq pass-cons (assoc key elmo-passwd-alist))
 596       (unwind-protect
 597           (fillarray (cdr pass-cons) 0)
 598         (setq elmo-passwd-alist
 599               (delete pass-cons elmo-passwd-alist))))))
 600
 601 (defmacro elmo-read-char-exclusive ()
 602   (cond ((featurep 'xemacs)
 603          '(let ((table (quote ((backspace . ?\C-h) (delete . ?\C-?)
 604                                (left . ?\C-h))))
 605                 event key)
 606             (while (not
 607                     (and
 608                      (key-press-event-p (setq event (next-command-event)))
 609                      (setq key (or (event-to-character event)
 610                                    (cdr (assq (event-key event) table)))))))
 611             key))
 612         ((fboundp 'read-char-exclusive)
 613          '(read-char-exclusive))
 614         (t
 615          '(read-char))))
 616
 617 (defun elmo-read-passwd (prompt &optional stars)
 618   "Read a single line of text from user without echoing, and return it."
 619   (let ((ans "")
 620         (c 0)
 621         (echo-keystrokes 0)
 622         (cursor-in-echo-area t)
 623         (log-message-max-size 0)
 624         message-log-max done msg truncate)
 625     (while (not done)
 626       (if (or (not stars) (string= "" ans))
 627           (setq msg prompt)
 628         (setq msg (concat prompt (make-string (length ans) ?.)))
 629         (setq truncate
 630               (1+ (- (length msg) (window-width (minibuffer-window)))))
 631         (and (> truncate 0)
 632              (setq msg (concat "$" (substring msg (1+ truncate))))))
 633       (message "%s" msg)
 634       (setq c (elmo-read-char-exclusive))
 635       (cond ((= c ?\C-g)
 636              (setq quit-flag t
 637                    done t))
 638             ((or (= c ?\r) (= c ?\n) (= c ?\e))
 639              (setq done t))
 640             ((= c ?\C-u)
 641              (setq ans ""))
 642             ((and (/= c ?\b) (/= c ?\177))
 643              (setq ans (concat ans (char-to-string c))))
 644             ((> (length ans) 0)
 645              (setq ans (substring ans 0 -1)))))
 646     (if quit-flag
 647         (prog1
 648             (setq quit-flag nil)
 649           (message "Quit")
 650           (beep t))
 651       (message "")
 652       ans)))
 653
 654 (defun elmo-string-to-list (string)
 655   (elmo-set-work-buf
 656    (insert string)
 657    (goto-char (point-min))
 658    (insert "(")
 659    (goto-char (point-max))
 660    (insert ")")
 661    (goto-char (point-min))
 662    (read (current-buffer))))
 663
 664 (defun elmo-list-to-string (list)
 665   (let ((tlist list)
 666         str)
 667     (if (listp tlist)
 668         (progn
 669           (setq str "(")
 670           (while (car tlist)
 671             (setq str
 672                   (concat str
 673                           (if (symbolp (car tlist))
 674                               (symbol-name (car tlist))
 675                             (car tlist))))
 676             (if (cdr tlist)
 677                 (setq str
 678                       (concat str " ")))
 679             (setq tlist (cdr tlist)))
 680           (setq str
 681                 (concat str ")")))
 682       (setq str
 683             (if (symbolp tlist)
 684                 (symbol-name tlist)
 685               tlist)))
 686     str))
 687
 688
 689 (defun elmo-plug-on-by-servers (alist &optional servers)
 690   (let ((server-list (or servers elmo-plug-on-servers)))
 691     (catch 'plugged
 692       (while server-list
 693         (if (elmo-plugged-p (car server-list))
 694             (throw 'plugged t))
 695         (setq server-list (cdr server-list))))))
 696
 697 (defun elmo-plug-on-by-exclude-servers (alist &optional servers)
 698   (let ((server-list (or servers elmo-plug-on-exclude-servers))
 699         server other-servers)
 700     (while alist
 701       (when (and (not (member (setq server (caaar alist)) server-list))
 702                  (not (member server other-servers)))
 703         (push server other-servers))
 704       (setq alist (cdr alist)))
 705     (elmo-plug-on-by-servers alist other-servers)))
 706
 707 (defun elmo-plugged-p (&optional server port stream-type alist label-exp)
 708   (let ((alist (or alist elmo-plugged-alist))
 709         plugged-info)
 710     (cond ((and (not port) (not server))
 711            (cond ((eq elmo-plugged-condition 'one)
 712                   (if alist
 713                       (catch 'plugged
 714                         (while alist
 715                           (if (nth 2 (car alist))
 716                               (throw 'plugged t))
 717                           (setq alist (cdr alist))))
 718                     elmo-plugged))
 719                  ((eq elmo-plugged-condition 'all)
 720                   (if alist
 721                       (catch 'plugged
 722                         (while alist
 723                           (if (not (nth 2 (car alist)))
 724                               (throw 'plugged nil))
 725                           (setq alist (cdr alist)))
 726                         t)
 727                     elmo-plugged))
 728                  ((functionp elmo-plugged-condition)
 729                   (funcall elmo-plugged-condition alist))
 730                  (t ;; independent
 731                   elmo-plugged)))
 732           ((not port) ;; server
 733            (catch 'plugged
 734              (while alist
 735                (when (string= server (caaar alist))
 736                  (if (nth 2 (car alist))
 737                      (throw 'plugged t)))
 738                (setq alist (cdr alist)))))
 739           (t
 740            (setq plugged-info (assoc (list server port stream-type) alist))
 741            (if (not plugged-info)
 742                ;; add elmo-plugged-alist automatically
 743                (progn
 744                  (elmo-set-plugged elmo-plugged server port stream-type
 745                                    nil nil nil label-exp)
 746                  elmo-plugged)
 747              (if (and elmo-auto-change-plugged
 748                       (> elmo-auto-change-plugged 0)
 749                       (nth 3 plugged-info)  ;; time
 750                       (elmo-time-expire (nth 3 plugged-info)
 751                                         elmo-auto-change-plugged))
 752                  t
 753                (nth 2 plugged-info)))))))
 754
 755 (defun elmo-set-plugged (plugged &optional server port stream-type time
 756                                  alist label-exp add)
 757   (let ((alist (or alist elmo-plugged-alist))
 758         label plugged-info)
 759     (cond ((and (not port) (not server))
 760            (setq elmo-plugged plugged)
 761            ;; set plugged all element of elmo-plugged-alist.
 762            (while alist
 763              (setcdr (cdar alist) (list plugged time))
 764              (setq alist (cdr alist))))
 765           ((not port)
 766            ;; set plugged all port of server
 767            (while alist
 768              (when (string= server (caaar alist))
 769                (setcdr (cdar alist) (list plugged time)))
 770              (setq alist (cdr alist))))
 771           (t
 772            ;; set plugged one port of server
 773            (setq plugged-info (assoc (list server port stream-type) alist))
 774            (setq label (if label-exp
 775                            (eval label-exp)
 776                          (nth 1 plugged-info)))
 777            (if plugged-info
 778                ;; if add is non-nil, don't reset plug state.
 779                (unless add
 780                  (setcdr plugged-info (list label plugged time)))
 781              (setq alist
 782                    (setq elmo-plugged-alist
 783                          (nconc
 784                           elmo-plugged-alist
 785                           (list
 786                            (list (list server port stream-type)
 787                                  label plugged time))))))))
 788     alist))
 789
 790 (defun elmo-delete-plugged (&optional server port alist)
 791   (let* ((alist (or alist elmo-plugged-alist))
 792          (alist2 alist))
 793     (cond ((and (not port) (not server))
 794            (setq alist nil))
 795           ((not port)
 796            ;; delete plugged all port of server
 797            (while alist2
 798              (when (string= server (caaar alist2))
 799                (setq alist (delete (car alist2) alist)))
 800              (setq alist2 (cdr alist2))))
 801           (t
 802            ;; delete plugged one port of server
 803            (setq alist
 804                  (delete (assoc (cons server port) alist) alist))))
 805     alist))
 806
 807 (defun elmo-disk-usage (path)
 808   "Get disk usage (bytes) in PATH."
 809   (let ((file-attr
 810          (condition-case () (file-attributes path) (error nil))))
 811     (if file-attr
 812         (if (nth 0 file-attr) ; directory
 813             (let ((files (condition-case ()
 814                              (directory-files path t "^[^\\.]")
 815                            (error nil)))
 816                   (result 0.0))
 817               ;; (result (nth 7 file-attr))) ... directory size
 818               (while files
 819                 (setq result (+ result (or (elmo-disk-usage (car files)) 0)))
 820                 (setq files (cdr files)))
 821               result)
 822           (float (nth 7 file-attr)))
 823       0)))
 824
 825 (defun elmo-get-last-accessed-time (path &optional dir)
 826   "Return the last accessed time of PATH."
 827   (let ((last-accessed (nth 4 (file-attributes (or (and dir
 828                                                         (expand-file-name
 829                                                          path dir))
 830                                                    path)))))
 831     (if last-accessed
 832         (setq last-accessed (+ (* (nth 0 last-accessed)
 833                                   (float 65536)) (nth 1 last-accessed)))
 834       0)))
 835
 836 (defun elmo-get-last-modification-time (path &optional dir)
 837   "Return the last accessed time of PATH."
 838   (let ((last-modified (nth 5 (file-attributes (or (and dir
 839                                                         (expand-file-name
 840                                                          path dir))
 841                                                    path)))))
 842     (setq last-modified (+ (* (nth 0 last-modified)
 843                               (float 65536)) (nth 1 last-modified)))))
 844
 845 (defun elmo-make-directory (path &optional mode)
 846   "Create directory recursively."
 847   (let ((parent (directory-file-name (file-name-directory path))))
 848     (if (null (file-directory-p parent))
 849         (elmo-make-directory parent))
 850     (make-directory path)
 851     (set-file-modes path (or mode
 852                              (+ (* 64 7) (* 8 0) 0))))) ; chmod 0700
 853
 854 (defun elmo-delete-directory (path &optional no-hierarchy)
 855   "Delete directory recursively."
 856   (if (stringp path) ; nil is not permitted.
 857   (let ((dirent (directory-files path))
 858         relpath abspath hierarchy)
 859     (while dirent
 860       (setq relpath (car dirent)
 861             dirent (cdr dirent)
 862             abspath (expand-file-name relpath path))
 863       (when (not (string-match "^\\.\\.?$" relpath))
 864         (if (eq (nth 0 (file-attributes abspath)) t)
 865             (if no-hierarchy
 866                 (setq hierarchy t)
 867               (elmo-delete-directory abspath no-hierarchy))
 868           (delete-file abspath))))
 869     (unless hierarchy
 870       (delete-directory path)))))
 871
 872 (defun elmo-delete-match-files (path regexp &optional remove-if-empty)
 873   "Delete directory files specified by PATH.
 874 If optional REMOVE-IF-EMPTY is non-nil, delete directory itself if
 875 the directory becomes empty after deletion."
 876   (when (stringp path) ; nil is not permitted.
 877     (dolist (file (directory-files path t regexp))
 878       (delete-file file))
 879     (if remove-if-empty
 880         (ignore-errors
 881           (delete-directory path) ; should be removed if empty.
 882           ))))
 883
 884 (defun elmo-list-filter (l1 l2)
 885   "Return a list from L2 in which each element is a member of L1."
 886   (let (result)
 887     (dolist (element l2)
 888       (if (memq element l1)
 889         (setq result (cons element result))))
 890     (nreverse result)))
 891
 892 (defsubst elmo-list-delete-if-smaller (list number)
 893   (let ((ret-val (copy-sequence list)))
 894     (while list
 895       (if (< (car list) number)
 896           (setq ret-val (delq (car list) ret-val)))
 897       (setq list (cdr list)))
 898     ret-val))
 899
 900 (defun elmo-list-diff (list1 list2)
 901   (let ((clist1 (sort (copy-sequence list1) #'<))
 902         (clist2 (sort (copy-sequence list2) #'<))
 903         list1-only list2-only)
 904     (while (or clist1 clist2)
 905       (cond
 906        ((null clist1)
 907         (while clist2
 908           (setq list2-only (cons (car clist2) list2-only))
 909           (setq clist2 (cdr clist2))))
 910        ((null clist2)
 911         (while clist1
 912           (setq list1-only (cons (car clist1) list1-only))
 913           (setq clist1 (cdr clist1))))
 914        ((< (car clist1) (car clist2))
 915         (while (and clist1 (< (car clist1) (car clist2)))
 916           (setq list1-only (cons (car clist1) list1-only))
 917           (setq clist1 (cdr clist1))))
 918        ((< (car clist2) (car clist1))
 919         (while (and clist2 (< (car clist2) (car clist1)))
 920           (setq list2-only (cons (car clist2) list2-only))
 921           (setq clist2 (cdr clist2))))
 922        ((= (car clist1) (car clist2))
 923         (setq clist1 (cdr clist1)
 924               clist2 (cdr clist2)))))
 925     (list list1-only list2-only)))
 926
 927 (defun elmo-list-diff-nonsortable (list1 list2)
 928   (let ((clist1 (copy-sequence list1))
 929         (clist2 (copy-sequence list2)))
 930     (while list2
 931       (setq clist1 (delq (car list2) clist1))
 932       (setq list2 (cdr list2)))
 933     (while list1
 934       (setq clist2 (delq (car list1) clist2))
 935       (setq list1 (cdr list1)))
 936     (list clist1 clist2)))
 937
 938 (defun elmo-list-bigger-diff (list1 list2 &optional mes)
 939   "Returns a list (- +). + is bigger than max of LIST1, in LIST2."
 940   (if (null list2)
 941       (cons list1  nil)
 942     (let* ((l1 list1)
 943            (l2 list2)
 944            (max-of-l2 (or (nth (max 0 (1- (length l2))) l2) 0))
 945            diff1 num i percent
 946            )
 947       (setq i 0)
 948       (setq num (+ (length l1)))
 949       (while l1
 950         (if (memq (car l1) l2)
 951             (if (eq (car l1) (car l2))
 952                 (setq l2 (cdr l2))
 953               (delq (car l1) l2))
 954           (if (> (car l1) max-of-l2)
 955               (setq diff1 (nconc diff1 (list (car l1))))))
 956         (if mes
 957             (progn
 958               (setq i (+ i 1))
 959               (setq percent (/ (* i 100) num))
 960               (if (eq (% percent 5) 0)
 961                   (elmo-display-progress
 962                    'elmo-list-bigger-diff "%s%d%%" percent mes))))
 963         (setq l1 (cdr l1)))
 964       (cons diff1 (list l2)))))
 965
 966 (defmacro elmo-get-hash-val (string hashtable)
 967   (static-if (fboundp 'unintern)
 968       `(symbol-value (intern-soft ,string ,hashtable))
 969     `(let ((sym (intern-soft ,string ,hashtable)))
 970        (and (boundp sym)
 971             (symbol-value sym)))))
 972
 973 (defmacro elmo-set-hash-val (string value hashtable)
 974   `(set (intern ,string ,hashtable) ,value))
 975
 976 (defmacro elmo-clear-hash-val (string hashtable)
 977   (static-if (fboundp 'unintern)
 978       (list 'unintern string hashtable)
 979     (list 'makunbound (list 'intern string hashtable))))
 980
 981 (defmacro elmo-unintern (string)
 982   "`unintern' symbol named STRING,  When can use `unintern'.
 983 Emacs 19.28 or earlier does not have `unintern'."
 984   (static-if (fboundp 'unintern)
 985       (list 'unintern string)))
 986
 987 (defun elmo-make-hash (&optional hashsize)
 988   "Make a new hash table which have HASHSIZE size."
 989   (make-vector
 990    (if hashsize
 991        (max
 992         ;; Prime numbers as lengths tend to result in good
 993         ;; hashing; lengths one less than a power of two are
 994         ;; also good.
 995         (min
 996          (let ((i 1))
 997            (while (< (- i 1) hashsize)
 998              (setq i (* 2 i)))
 999            (- i 1))
1000          elmo-hash-maximum-size)
1001         elmo-hash-minimum-size)
1002      elmo-hash-minimum-size)
1003    0))
1004
1005 (defsubst elmo-mime-string (string)
1006   "Normalize MIME encoded STRING."
1007   (and string
1008        (elmo-with-enable-multibyte
1009          (encode-mime-charset-string
1010           (or (ignore-errors
1011                (eword-decode-and-unfold-unstructured-field-body string))
1012               string)
1013           elmo-mime-charset))))
1014
1015 (defsubst elmo-collect-field (beg end downcase-field-name)
1016   (save-excursion
1017     (save-restriction
1018       (narrow-to-region beg end)
1019       (goto-char (point-min))
1020       (let ((regexp (concat "\\(" std11-field-head-regexp "\\)[ \t]*"))
1021             dest name body)
1022         (while (re-search-forward regexp nil t)
1023           (setq name (buffer-substring-no-properties
1024                       (match-beginning 1)(1- (match-end 1))))
1025           (if downcase-field-name
1026               (setq name (downcase name)))
1027           (setq body (buffer-substring-no-properties
1028                       (match-end 0) (std11-field-end)))
1029           (or (assoc name dest)
1030               (setq dest (cons (cons name body) dest))))
1031         dest))))
1032
1033 (defsubst elmo-collect-field-from-string (string downcase-field-name)
1034   (with-temp-buffer
1035     (insert string)
1036     (goto-char (point-min))
1037     (let ((regexp (concat "\\(" std11-field-head-regexp "\\)[ \t]*"))
1038           dest name body)
1039       (while (re-search-forward regexp nil t)
1040         (setq name (buffer-substring-no-properties
1041                     (match-beginning 1)(1- (match-end 1))))
1042         (if downcase-field-name
1043             (setq name (downcase name)))
1044         (setq body (buffer-substring-no-properties
1045                     (match-end 0) (std11-field-end)))
1046         (or (assoc name dest)
1047             (setq dest (cons (cons name body) dest))))
1048       dest)))
1049
1050 (defun elmo-safe-filename (filename)
1051   (let* ((replace-alist '(("/" . " ")
1052                           (":" . "__")
1053                           ("|" . "_or_")
1054                           ("\"" . "_Q_")))
1055          (regexp (concat "["
1056                          (regexp-quote (mapconcat 'car replace-alist ""))
1057                          "]"))
1058          (rest filename)
1059          converted)
1060     (while (string-match regexp rest)
1061       (setq converted (concat converted
1062                               (substring rest 0 (match-beginning 0))
1063                               (cdr (assoc (substring rest
1064                                                      (match-beginning 0)
1065                                                      (match-end 0))
1066                                           replace-alist)))
1067             rest (substring rest (match-end 0))))
1068     (concat converted rest)))
1069
1070 (defvar elmo-filename-replace-chars nil)
1071
1072 (defsubst elmo-replace-string-as-filename (msgid)
1073   "Replace string as filename."
1074   (setq msgid (elmo-replace-in-string msgid " " "  "))
1075   (if (null elmo-filename-replace-chars)
1076       (setq elmo-filename-replace-chars
1077             (regexp-quote (mapconcat
1078                            'car elmo-filename-replace-string-alist ""))))
1079   (while (string-match (concat "[" elmo-filename-replace-chars "]")
1080                        msgid)
1081     (setq msgid (concat
1082                  (substring msgid 0 (match-beginning 0))
1083                  (cdr (assoc
1084                        (substring msgid
1085                                   (match-beginning 0) (match-end 0))
1086                        elmo-filename-replace-string-alist))
1087                  (substring msgid (match-end 0)))))
1088   msgid)
1089
1090 (defsubst elmo-recover-string-from-filename (filename)
1091   "Recover string from FILENAME."
1092   (let (tmp result)
1093     (while (string-match " " filename)
1094       (setq tmp (substring filename
1095                            (match-beginning 0)
1096                            (+ (match-end 0) 1)))
1097       (if (string= tmp "  ")
1098           (setq tmp " ")
1099         (setq tmp (car (rassoc tmp
1100                                elmo-filename-replace-string-alist))))
1101       (setq result
1102             (concat result
1103                     (substring filename 0 (match-beginning 0))
1104                     tmp))
1105       (setq filename (substring filename (+ (match-end 0) 1))))
1106     (concat result filename)))
1107
1108 (defsubst elmo-copy-file (src dst &optional ok-if-already-exists)
1109   (condition-case err
1110       (elmo-add-name-to-file src dst ok-if-already-exists)
1111     (error (copy-file src dst ok-if-already-exists t))))
1112
1113 (defsubst elmo-buffer-exists-p (buffer)
1114   (if (bufferp buffer)
1115       (buffer-live-p buffer)
1116     (get-buffer buffer)))
1117
1118 (defsubst elmo-kill-buffer (buffer)
1119   (when (elmo-buffer-exists-p buffer)
1120     (kill-buffer buffer)))
1121
1122 (defun elmo-delete-if (pred lst)
1123   "Return new list contain items which don't satisfy PRED in LST."
1124   (let (result)
1125     (while lst
1126       (unless (funcall pred (car lst))
1127         (setq result (cons (car lst) result)))
1128       (setq lst (cdr lst)))
1129     (nreverse result)))
1130
1131 (defun elmo-list-delete (list1 list2 &optional delete-function)
1132   "Delete by side effect any occurrences equal to elements of LIST1 from LIST2.
1133 Return the modified LIST2.  Deletion is done with `delete'.
1134 Write `(setq foo (elmo-list-delete bar foo))' to be sure of changing
1135 the value of `foo'.
1136 If optional DELETE-FUNCTION is speficied, it is used as delete procedure."
1137   (setq delete-function (or delete-function 'delete))
1138   (while list1
1139     (setq list2 (funcall delete-function (car list1) list2))
1140     (setq list1 (cdr list1)))
1141   list2)
1142
1143 (defun elmo-list-member (list1 list2)
1144   "If any element of LIST1 is member of LIST2, return t."
1145   (catch 'done
1146     (while list1
1147       (if (member (car list1) list2)
1148           (throw 'done t))
1149       (setq list1 (cdr list1)))))
1150
1151 (defun elmo-count-matches (regexp beg end)
1152   (let ((count 0))
1153     (save-excursion
1154       (goto-char beg)
1155       (while (re-search-forward regexp end t)
1156         (setq count (1+ count)))
1157       count)))
1158
1159 (if (fboundp 'display-error)
1160     (defalias 'elmo-display-error 'display-error)
1161   (defun elmo-display-error (error-object stream)
1162     "A tiny function to display ERROR-OBJECT to the STREAM."
1163     (let ((first t)
1164           (errobj error-object)
1165           err-mes)
1166       (while errobj
1167         (setq err-mes (concat err-mes (format
1168                                        (if (stringp (car errobj))
1169                                            "%s"
1170                                          "%S")
1171                                        (car errobj))))
1172         (setq errobj (cdr errobj))
1173         (if errobj (setq err-mes (concat err-mes (if first ": " ", "))))
1174         (setq first nil))
1175       (princ err-mes stream))))
1176
1177 (if (fboundp 'define-error)
1178     (defalias 'elmo-define-error 'define-error)
1179   (defun elmo-define-error (error doc &optional parents)
1180     (or parents
1181         (setq parents 'error))
1182     (let ((conds (get parents 'error-conditions)))
1183       (or conds
1184           (error "Not an error symbol: %s" error))
1185       (setplist error
1186                 (list 'error-message doc
1187                       'error-conditions (cons error conds))))))
1188
1189 (cond ((fboundp 'progress-feedback-with-label)
1190        (defalias 'elmo-display-progress 'progress-feedback-with-label))
1191       ((fboundp 'lprogress-display)
1192        (defalias 'elmo-display-progress 'lprogress-display))
1193       (t
1194        (defun elmo-display-progress (label format &optional value &rest args)
1195          "Print a progress message."
1196          (if (and (null format) (null args))
1197              (message nil)
1198            (apply (function message) (concat format " %d%%")
1199                   (nconc args (list value)))))))
1200
1201 (defvar elmo-progress-counter-alist nil)
1202
1203 (defmacro elmo-progress-counter-value (counter)
1204   (` (aref (cdr (, counter)) 0)))
1205
1206 (defmacro elmo-progress-counter-all-value (counter)
1207   (` (aref (cdr (, counter)) 1)))
1208
1209 (defmacro elmo-progress-counter-format (counter)
1210   (` (aref (cdr (, counter)) 2)))
1211
1212 (defmacro elmo-progress-counter-set-value (counter value)
1213   (` (aset (cdr (, counter)) 0 (, value))))
1214
1215 (defun elmo-progress-set (label all-value &optional format)
1216   (unless (assq label elmo-progress-counter-alist)
1217     (setq elmo-progress-counter-alist
1218           (cons (cons label (vector 0 all-value (or format "")))
1219                 elmo-progress-counter-alist))))
1220
1221 (defun elmo-progress-clear (label)
1222   (let ((counter (assq label elmo-progress-counter-alist)))
1223     (when counter
1224       (elmo-display-progress label
1225                              (elmo-progress-counter-format counter)
1226                              100)
1227       (setq elmo-progress-counter-alist
1228             (delq counter elmo-progress-counter-alist)))))
1229
1230 (defun elmo-progress-notify (label &optional value op &rest args)
1231   (let ((counter (assq label elmo-progress-counter-alist)))
1232     (when counter
1233       (let* ((value (or value 1))
1234              (cur-value (elmo-progress-counter-value counter))
1235              (all-value (elmo-progress-counter-all-value counter))
1236              (new-value (if (eq op 'set) value (+ cur-value value)))
1237              (cur-rate (/ (* cur-value 100) all-value))
1238              (new-rate (/ (* new-value 100) all-value)))
1239         (elmo-progress-counter-set-value counter new-value)
1240         (unless (= cur-rate new-rate)
1241           (apply 'elmo-display-progress
1242                  label
1243                  (elmo-progress-counter-format counter)
1244                  new-rate
1245                  args))
1246         (when (>= new-rate 100)
1247           (elmo-progress-clear label))))))
1248
1249 (put 'elmo-with-progress-display 'lisp-indent-function '2)
1250 (def-edebug-spec elmo-with-progress-display
1251   (form (symbolp form &optional form) &rest form))
1252
1253 (defmacro elmo-with-progress-display (condition spec &rest body)
1254   "Evaluate BODY with progress gauge if CONDITION is non-nil.
1255 SPEC is a list as followed (LABEL MAX-VALUE [FORMAT])."
1256   (let ((label (car spec))
1257         (max-value (cadr spec))
1258         (fmt (caddr spec)))
1259     `(unwind-protect
1260          (progn
1261            (when ,condition
1262              (elmo-progress-set (quote ,label) ,max-value ,fmt))
1263            ,@body)
1264        (elmo-progress-clear (quote ,label)))))
1265
1266 (defun elmo-time-expire (before-time diff-time)
1267   (let* ((current (current-time))
1268          (rest (when (< (nth 1 current) (nth 1 before-time))
1269                  (expt 2 16)))
1270          diff)
1271     (setq diff
1272           (list (- (+ (car current) (if rest -1 0)) (car before-time))
1273                 (- (+ (or rest 0) (nth 1 current)) (nth 1 before-time))))
1274     (and (eq (car diff) 0)
1275          (< diff-time (nth 1 diff)))))
1276
1277 (if (fboundp 'std11-fetch-field)
1278     (defalias 'elmo-field-body 'std11-fetch-field) ;;no narrow-to-region
1279   (defalias 'elmo-field-body 'std11-field-body))
1280
1281 (defun elmo-unfold-field-body (name)
1282   (let ((value (elmo-field-body name)))
1283     (and value
1284          (std11-unfold-string value))))
1285
1286 (defun elmo-decoded-field-body (field-name &optional mode)
1287   (let ((field-body (elmo-field-body field-name)))
1288     (and field-body
1289          (or (ignore-errors
1290               (elmo-with-enable-multibyte
1291                 (mime-decode-field-body field-body field-name mode)))
1292              field-body))))
1293
1294 (defun elmo-address-quote-specials (word)
1295   "Make quoted string of WORD if needed."
1296   (let ((lal (std11-lexical-analyze word)))
1297     (if (or (assq 'specials lal)
1298             (assq 'domain-literal lal))
1299         (prin1-to-string word)
1300       word)))
1301
1302 (defmacro elmo-string (string)
1303   "STRING without text property."
1304   (` (let ((obj (copy-sequence (, string))))
1305        (and obj (set-text-properties 0 (length obj) nil obj))
1306        obj)))
1307
1308 (defun elmo-flatten (list-of-list)
1309   "Flatten LIST-OF-LIST."
1310   (unless (null list-of-list)
1311     (append (if (and (car list-of-list)
1312                      (listp (car list-of-list)))
1313                 (car list-of-list)
1314               (list (car list-of-list)))
1315             (elmo-flatten (cdr list-of-list)))))
1316
1317 (defun elmo-y-or-n-p (prompt &optional auto default)
1318   "Same as `y-or-n-p'.
1319 But if optional argument AUTO is non-nil, DEFAULT is returned."
1320   (if auto
1321       default
1322     (y-or-n-p prompt)))
1323
1324 (defun elmo-string-member (string slist)
1325   (catch 'found
1326     (dolist (element slist)
1327       (cond ((null element))
1328             ((stringp element)
1329              (when (string= string element)
1330                (throw 'found t)))
1331             ((symbolp element)
1332              (when (string= string (symbol-value element))
1333                (throw 'found t)))))))
1334
1335 (static-cond ((fboundp 'member-ignore-case)
1336        (defalias 'elmo-string-member-ignore-case 'member-ignore-case))
1337       ((fboundp 'compare-strings)
1338        (defun elmo-string-member-ignore-case (elt list)
1339          "Like `member', but ignores differences in case and text representation.
1340 ELT must be a string.  Upper-case and lower-case letters are treated as equal.
1341 Unibyte strings are converted to multibyte for comparison."
1342          (while (and list (not (eq t (compare-strings elt 0 nil (car list) 0 nil t))))
1343            (setq list (cdr list)))
1344          list))
1345       (t
1346        (defun elmo-string-member-ignore-case (elt list)
1347          "Like `member', but ignores differences in case and text representation.
1348 ELT must be a string.  Upper-case and lower-case letters are treated as equal."
1349          (let ((str (downcase elt)))
1350            (while (and list (not (string= str (downcase (car list)))))
1351              (setq list (cdr list)))
1352            list))))
1353
1354 (defun elmo-string-match-member (str list &optional case-ignore)
1355   (let ((case-fold-search case-ignore))
1356     (catch 'member
1357       (while list
1358         (if (string-match (car list) str)
1359             (throw 'member (car list)))
1360         (setq list (cdr list))))))
1361
1362 (defun elmo-string-matched-member (str list &optional case-ignore)
1363   (let ((case-fold-search case-ignore))
1364     (catch 'member
1365       (while list
1366         (if (string-match str (car list))
1367             (throw 'member (car list)))
1368         (setq list (cdr list))))))
1369
1370 (defsubst elmo-string-delete-match (string pos)
1371   (concat (substring string
1372                      0 (match-beginning pos))
1373           (substring string
1374                      (match-end pos)
1375                      (length string))))
1376
1377 (defun elmo-string-match-assoc (key alist &optional case-ignore)
1378   (let ((case-fold-search case-ignore)
1379         a)
1380     (catch 'loop
1381       (while alist
1382         (setq a (car alist))
1383         (if (and (consp a)
1384                  (stringp (car a))
1385                  (string-match key (car a)))
1386             (throw 'loop a))
1387         (setq alist (cdr alist))))))
1388
1389 (defun elmo-string-matched-assoc (key alist &optional case-ignore)
1390   (let ((case-fold-search case-ignore)
1391         a)
1392     (catch 'loop
1393       (while alist
1394         (setq a (car alist))
1395         (if (and (consp a)
1396                  (stringp (car a))
1397                  (string-match (car a) key))
1398             (throw 'loop a))
1399         (setq alist (cdr alist))))))
1400
1401 (defun elmo-string-assoc (key alist)
1402   (let (a)
1403     (catch 'loop
1404       (while alist
1405         (setq a (car alist))
1406         (if (and (consp a)
1407                  (stringp (car a))
1408                  (string= key (car a)))
1409             (throw 'loop a))
1410         (setq alist (cdr alist))))))
1411
1412 (defun elmo-string-assoc-all (key alist)
1413   (let (matches)
1414     (while alist
1415       (if (string= key (car (car alist)))
1416           (setq matches
1417                 (cons (car alist)
1418                       matches)))
1419       (setq alist (cdr alist)))
1420     matches))
1421
1422 (defun elmo-string-rassoc (key alist)
1423   (let (a)
1424     (catch 'loop
1425       (while alist
1426         (setq a (car alist))
1427         (if (and (consp a)
1428                  (stringp (cdr a))
1429                  (string= key (cdr a)))
1430             (throw 'loop a))
1431         (setq alist (cdr alist))))))
1432
1433 (defun elmo-string-rassoc-all (key alist)
1434   (let (matches)
1435     (while alist
1436       (if (string= key (cdr (car alist)))
1437           (setq matches
1438                 (cons (car alist)
1439                       matches)))
1440       (setq alist (cdr alist)))
1441     matches))
1442
1443 (defun elmo-expand-newtext (newtext original)
1444   (let ((len (length newtext))
1445         (pos 0)
1446         c expanded beg N did-expand)
1447     (while (< pos len)
1448       (setq beg pos)
1449       (while (and (< pos len)
1450                   (not (= (aref newtext pos) ?\\)))
1451         (setq pos (1+ pos)))
1452       (unless (= beg pos)
1453         (push (substring newtext beg pos) expanded))
1454       (when (< pos len)
1455         ;; We hit a \; expand it.
1456         (setq did-expand t
1457               pos (1+ pos)
1458               c (aref newtext pos))
1459         (if (not (or (= c ?\&)
1460                      (and (>= c ?1)
1461                           (<= c ?9))))
1462             ;; \ followed by some character we don't expand.
1463             (push (char-to-string c) expanded)
1464           ;; \& or \N
1465           (if (= c ?\&)
1466               (setq N 0)
1467             (setq N (- c ?0)))
1468           (when (match-beginning N)
1469             (push (substring original (match-beginning N) (match-end N))
1470                   expanded))))
1471       (setq pos (1+ pos)))
1472     (if did-expand
1473         (apply (function concat) (nreverse expanded))
1474       newtext)))
1475
1476 ;;; Folder parser utils.
1477 (defconst elmo-quoted-specials-list '(?\\ ?\"))
1478
1479 (defun elmo-quoted-token (string)
1480   (concat "\""
1481           (std11-wrap-as-quoted-pairs string elmo-quoted-specials-list)
1482           "\""))
1483
1484 (defun elmo-token-valid-p (token requirement)
1485   (cond ((null requirement))
1486         ((stringp requirement)
1487          (string-match requirement token))
1488         ((functionp requirement)
1489          (funcall requirement token))))
1490
1491 (defun elmo-parse-token (string &optional seps requirement)
1492   "Parse atom from STRING using SEPS as a string of separator char list."
1493   (let ((len (length string))
1494         (seps (and seps (string-to-char-list seps)))
1495         (i 0)
1496         (sep nil)
1497         content c in)
1498     (if (eq len 0)
1499         (cons "" "")
1500       (while (and (< i len) (or in (null sep)))
1501         (setq c (aref string i))
1502         (cond
1503          ((and in (eq c ?\\))
1504           (setq i (1+ i)
1505                 content (cons (aref string i) content)
1506                 i (1+ i)))
1507          ((eq c ?\")
1508           (setq in (not in)
1509                 i (1+ i)))
1510          (in (setq content (cons c content)
1511                    i (1+ i)))
1512          ((memq c seps)
1513           (setq sep c))
1514          (t (setq content (cons c content)
1515                   i (1+ i)))))
1516       (if in (error "Parse error in quoted"))
1517       (let ((atom (if (null content)
1518                       ""
1519                     (char-list-to-string (nreverse content)))))
1520         (if (elmo-token-valid-p atom requirement)
1521             (cons atom (substring string i))
1522           (cons "" string))))))
1523
1524 (defun elmo-parse-prefixed-element (prefix string &optional seps requirement)
1525   (let (parsed)
1526     (if (and (not (eq (length string) 0))
1527              (eq (aref string 0) prefix)
1528              (setq parsed (elmo-parse-token (substring string 1) seps))
1529              (elmo-token-valid-p (car parsed) requirement))
1530         parsed
1531       (cons "" string))))
1532
1533 (defun elmo-collect-separators (spec)
1534   (when (listp spec)
1535     (let ((result (elmo-collect-separators-internal spec)))
1536       (and result
1537            (char-list-to-string (elmo-uniq-list result #'delq))))))
1538
1539 (defun elmo-collect-separators-internal (specs)
1540   (let (separators)
1541     (while specs
1542       (let ((spec (car specs)))
1543         (cond
1544          ((listp spec)
1545           (setq separators (nconc (elmo-collect-separators-internal spec)
1546                                   separators)
1547                 specs (cdr specs)))
1548          ((characterp spec)
1549           (setq separators (cons spec separators)
1550                 specs nil))
1551          (t
1552           (setq specs nil)))))
1553     separators))
1554
1555 (defun elmo-collect-trail-separators (element specs)
1556   (cond
1557    ((symbolp specs)
1558     (eq specs element))
1559    ((vectorp specs)
1560     (eq (aref specs 0) element))
1561    ((listp specs)
1562     (let (spec result)
1563       (while (setq spec (car specs))
1564         (if (setq result (elmo-collect-trail-separators element spec))
1565             (setq result (concat (if (stringp result) result)
1566                                  (elmo-collect-separators (cdr specs)))
1567                   specs nil)
1568           (setq specs (cdr specs))))
1569       result))))
1570
1571 (defun elmo-parse-separated-tokens (string spec)
1572   (let ((result (elmo-parse-separated-tokens-internal string spec)))
1573     (if (eq (car result) t)
1574         (cons nil (cdr result))
1575       result)))
1576
1577 (defun elmo-parse-separated-tokens-internal (string spec &optional separators)
1578   (cond
1579    ((symbolp spec)
1580     (let ((parse (elmo-parse-token string separators)))
1581       (cons (list (cons spec (car parse))) (cdr parse))))
1582    ((vectorp spec)
1583     (let ((parse (elmo-parse-token string separators)))
1584       (if (elmo-token-valid-p (car parse) (aref spec 1))
1585           (cons (list (cons (aref spec 0) (car parse))) (cdr parse))
1586         (cons nil string))))
1587    ((characterp spec)
1588     (if (and (> (length string) 0)
1589              (eq (aref string 0) spec))
1590         (cons t (substring string 1))
1591       (cons nil string)))
1592    ((listp spec)
1593     (catch 'unmatch
1594       (let ((rest string)
1595             result tokens)
1596         (while spec
1597           (setq result (elmo-parse-separated-tokens-internal
1598                         rest
1599                         (car spec)
1600                         (concat (elmo-collect-separators (cdr spec))
1601                                 separators)))
1602           (cond ((null (car result))
1603                  (throw 'unmatch (cons t string)))
1604                 ((eq t (car result)))
1605                 (t
1606                  (setq tokens (nconc (car result) tokens))))
1607           (setq rest (cdr result)
1608                 spec (cdr spec)))
1609         (cons (or tokens t) rest))))))
1610
1611 (defun elmo-quote-syntactical-element (value element syntax)
1612   (let ((separators (elmo-collect-trail-separators element syntax)))
1613     (if (and separators
1614              (string-match (concat "[" separators "]") value))
1615         (elmo-quoted-token value)
1616       value)))
1617
1618 ;;; Number set defined by OKAZAKI Tetsurou <okazaki@be.to>
1619 ;;
1620 ;; number          ::= [0-9]+
1621 ;; beg             ::= number
1622 ;; end             ::= number
1623 ;; number-range    ::= "(" beg " . " end ")"      ;; cons cell
1624 ;; number-set-elem ::= number / number-range
1625 ;; number-set      ::= "(" *number-set-elem ")"   ;; list
1626
1627 (defun elmo-number-set-member (number number-set)
1628   "Return non-nil if NUMBER is an element of NUMBER-SET.
1629 The value is actually the tail of NUMBER-RANGE whose car contains NUMBER."
1630   (or (memq number number-set)
1631       (let (found)
1632         (while (and number-set (not found))
1633           (if (and (consp (car number-set))
1634                    (and (<= (car (car number-set)) number)
1635                         (<= number (cdr (car number-set)))))
1636               (setq found t)
1637             (setq number-set (cdr number-set))))
1638         number-set)))
1639
1640 (defun elmo-number-set-append-list (number-set list)
1641   "Append LIST of numbers to the NUMBER-SET.
1642 NUMBER-SET is altered."
1643   (let ((appended number-set))
1644     (while list
1645       (setq appended (elmo-number-set-append appended (car list)))
1646       (setq list (cdr list)))
1647     appended))
1648
1649 (defun elmo-number-set-append (number-set number)
1650   "Append NUMBER to the NUMBER-SET.
1651 NUMBER-SET is altered."
1652   (let ((number-set-1 number-set)
1653         found elem)
1654     (while (and number-set (not found))
1655       (setq elem (car number-set))
1656       (cond
1657        ((and (consp elem)
1658              (eq (+ 1 (cdr elem)) number))
1659         (setcdr elem number)
1660         (setq found t))
1661        ((and (integerp elem)
1662              (eq (+ 1 elem) number))
1663         (setcar number-set (cons elem number))
1664         (setq found t))
1665        ((or (and (integerp elem) (eq elem number))
1666             (and (consp elem)
1667                  (<= (car elem) number)
1668                  (<= number (cdr elem))))
1669         (setq found t)))
1670       (setq number-set (cdr number-set)))
1671     (if (not found)
1672         (setq number-set-1 (nconc number-set-1 (list number))))
1673     number-set-1))
1674
1675 (defun elmo-number-set-delete-list (number-set list)
1676   "Delete LIST of numbers from the NUMBER-SET.
1677 NUMBER-SET is altered."
1678   (let ((deleted number-set))
1679     (dolist (number list)
1680       (setq deleted (elmo-number-set-delete deleted number)))
1681     deleted))
1682
1683 (defun elmo-number-set-delete (number-set number)
1684   "Delete NUMBER from the NUMBER-SET.
1685 NUMBER-SET is altered."
1686   (let* ((curr number-set)
1687          (top (cons 'dummy number-set))
1688          (prev top)
1689          elem found)
1690     (while (and curr (not found))
1691       (setq elem (car curr))
1692       (if (consp elem)
1693           (cond
1694            ((eq (car elem) number)
1695             (if (eq (cdr elem) (1+ number))
1696                 (setcar curr (cdr elem))
1697               (setcar elem (1+ number)))
1698             (setq found t))
1699            ((eq (cdr elem) number)
1700             (if (eq (car elem) (1- number))
1701                 (setcar curr (car elem))
1702               (setcdr elem (1- number)))
1703             (setq found t))
1704            ((and (> number (car elem))
1705                  (< number (cdr elem)))
1706             (setcdr
1707              prev
1708              (nconc
1709               (list
1710                ;; (beg . (1- number))
1711                (let ((new (cons (car elem) (1- number))))
1712                  (if (eq (car new) (cdr new))
1713                      (car new)
1714                    new))
1715                ;; ((1+ number) . end)
1716                (let ((new (cons (1+ number) (cdr elem))))
1717                  (if (eq (car new) (cdr new))
1718                      (car new)
1719                    new)))
1720               (cdr curr)))))
1721         (when (eq elem number)
1722           (setcdr prev (cdr curr))
1723           (setq found t)))
1724       (setq prev curr
1725             curr (cdr curr)))
1726     (cdr top)))
1727
1728 (defun elmo-make-number-list (beg end)
1729   (let (number-list i)
1730     (setq i end)
1731     (while (>= i beg)
1732       (setq number-list (cons i number-list))
1733       (setq i (1- i)))
1734     number-list))
1735
1736 (defun elmo-number-set-to-number-list (number-set)
1737   "Return a number list which corresponds to NUMBER-SET."
1738   (let ((number-list (list 'dummy))
1739         elem)
1740     (while number-set
1741       (setq elem (car number-set))
1742       (cond
1743        ((consp elem)
1744         (nconc number-list (elmo-make-number-list (car elem) (cdr elem))))
1745        ((integerp elem)
1746         (nconc number-list (list elem))))
1747       (setq number-set (cdr number-set)))
1748     (cdr number-list)))
1749
1750 (defcustom elmo-list-subdirectories-ignore-regexp "^\\(\\.\\.?\\|[0-9]+\\)$"
1751   "*Regexp to filter subfolders."
1752   :type 'regexp
1753   :group 'elmo)
1754
1755 (defun elmo-list-subdirectories-1 (basedir curdir one-level)
1756   (let ((root (zerop (length curdir)))
1757         (w32-get-true-file-link-count t) ; for Meadow
1758         attr dirs dir)
1759     (catch 'done
1760       (dolist (file (directory-files (setq dir (expand-file-name curdir basedir))))
1761         (when (and (not (string-match
1762                          elmo-list-subdirectories-ignore-regexp
1763                          file))
1764                    (car (setq attr (file-attributes
1765                                     (expand-file-name file dir)))))
1766           (when (eq one-level 'check) (throw 'done t))
1767           (let ((relpath
1768                  (concat curdir (and (not root) elmo-path-sep) file))
1769                 subdirs)
1770             (setq dirs (nconc dirs
1771                               (if (if elmo-have-link-count (< 2 (nth 1 attr))
1772                                     (setq subdirs
1773                                           (elmo-list-subdirectories-1
1774                                            basedir
1775                                            relpath
1776                                            (if one-level 'check))))
1777                                   (if one-level
1778                                       (list (list relpath))
1779                                     (cons relpath
1780                                           (or subdirs
1781                                               (elmo-list-subdirectories-1
1782                                                basedir
1783                                                relpath
1784                                                nil))))
1785                                 (list relpath)))))))
1786       dirs)))
1787
1788 (defun elmo-list-subdirectories (directory file one-level)
1789   (let ((subdirs (elmo-list-subdirectories-1 directory file one-level)))
1790     (if (zerop (length file))
1791         subdirs
1792       (cons file subdirs))))
1793
1794 (defun elmo-mapcar-list-of-list (func list-of-list)
1795   (mapcar
1796    (lambda (x)
1797      (cond ((listp x) (elmo-mapcar-list-of-list func x))
1798            (t (funcall func x))))
1799    list-of-list))
1800
1801 (defun elmo-map-recursive (function object)
1802   (if (consp object)
1803       (let* ((prev (list 'dummy))
1804              (result prev))
1805         (while (consp object)
1806           (setq prev (setcdr prev (list (elmo-map-recursive function
1807                                                             (car object))))
1808                 object (cdr object)))
1809         (when object
1810           (setcdr prev (funcall function object)))
1811         (cdr result))
1812     (funcall function object)))
1813
1814 (defun elmo-map-until-success (function sequence)
1815   (let (result)
1816     (while (and (null result)
1817                 sequence)
1818       (setq result (funcall function (car sequence))
1819             sequence (cdr sequence)))
1820     result))
1821
1822 (defun elmo-string-match-substring (regexp string &optional matchn)
1823   (when (string-match regexp string)
1824     (match-string (or matchn 1) string)))
1825
1826 (defun elmo-parse (string regexp &optional matchn)
1827   (or matchn (setq matchn 1))
1828   (let (list)
1829     (store-match-data nil)
1830     (while (string-match regexp string (match-end 0))
1831       (setq list (cons (substring string (match-beginning matchn)
1832                                   (match-end matchn)) list)))
1833     (nreverse list)))
1834
1835 (defun elmo-find-list-match-value (specs getter)
1836   (lexical-let ((getter getter))
1837     (elmo-map-until-success
1838      (lambda (spec)
1839        (cond
1840         ((symbolp spec)
1841          (funcall getter spec))
1842         ((consp spec)
1843          (lexical-let ((value (funcall getter (car spec))))
1844            (when value
1845              (elmo-map-until-success
1846               (lambda (rule)
1847                 (cond
1848                  ((stringp rule)
1849                   (elmo-string-match-substring rule value))
1850                  ((consp rule)
1851                   (elmo-string-match-substring (car rule) value (cdr rule)))))
1852               (cdr spec)))))))
1853      specs)))
1854
1855 ;;; File cache.
1856 (defmacro elmo-make-file-cache (path status)
1857   "PATH is the cache file name.
1858 STATUS is one of 'section, 'entire or nil.
1859  nil means no cache exists.
1860 'section means partial section cache exists.
1861 'entire means entire cache exists.
1862 If the cache is partial file-cache, TYPE is 'partial."
1863   (` (cons (, path) (, status))))
1864
1865 (defmacro elmo-file-cache-path (file-cache)
1866   "Returns the file path of the FILE-CACHE."
1867   (` (car (, file-cache))))
1868
1869 (defmacro elmo-file-cache-status (file-cache)
1870   "Returns the status of the FILE-CACHE."
1871   (` (cdr (, file-cache))))
1872
1873 (defsubst elmo-cache-to-msgid (filename)
1874   (concat "<" (elmo-recover-string-from-filename filename) ">"))
1875
1876 (defsubst elmo-cache-get-path-subr (msgid)
1877   (let ((chars '(?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9 ?A ?B ?C ?D ?E ?F))
1878         (clist (string-to-char-list msgid))
1879         (sum 0))
1880     (while clist
1881       (setq sum (+ sum (car clist)))
1882       (setq clist (cdr clist)))
1883     (format "%c%c"
1884             (nth (% (/ sum 16) 2) chars)
1885             (nth (% sum 16) chars))))
1886
1887 ;;;
1888 (defun elmo-file-cache-get-path (msgid &optional section)
1889   "Get cache path for MSGID.
1890 If optional argument SECTION is specified, partial cache path is returned."
1891   (if (setq msgid (elmo-msgid-to-cache msgid))
1892       (expand-file-name
1893        (if section
1894            (format "%s/%s/%s/%s"
1895                    elmo-cache-directory
1896                    (elmo-cache-get-path-subr msgid)
1897                    msgid
1898                    section)
1899          (format "%s/%s/%s"
1900                  elmo-cache-directory
1901                  (elmo-cache-get-path-subr msgid)
1902                  msgid)))))
1903
1904 (defmacro elmo-file-cache-expand-path (path section)
1905   "Return file name for the file-cache corresponds to the section.
1906 PATH is the file-cache path.
1907 SECTION is the section string."
1908   (` (expand-file-name (or (, section) "") (, path))))
1909
1910 (defun elmo-file-cache-delete (path)
1911   "Delete a cache on PATH."
1912   (when (file-exists-p path)
1913     (if (file-directory-p path)
1914         (progn
1915           (dolist (file (directory-files path t "^[^\\.]"))
1916             (delete-file file))
1917           (delete-directory path))
1918       (delete-file path))
1919     t))
1920
1921 (defun elmo-file-cache-exists-p (msgid)
1922   "Returns 'section or 'entire if a cache which corresponds to MSGID exists."
1923   (elmo-file-cache-status (elmo-file-cache-get msgid)))
1924
1925 (defun elmo-file-cache-save (cache-path section)
1926   "Save current buffer as cache on PATH.
1927 Return t if cache is saved successfully."
1928   (condition-case nil
1929       (let ((path (if section (expand-file-name section cache-path)
1930                     cache-path))
1931             files dir)
1932         (if (and (null section)
1933                  (file-directory-p path))
1934             (progn
1935               (setq files (directory-files path t "^[^\\.]"))
1936               (while files
1937                 (delete-file (car files))
1938                 (setq files (cdr files)))
1939               (delete-directory path))
1940           (if (and section
1941                    (not (file-directory-p cache-path)))
1942               (delete-file cache-path)))
1943         (when path
1944           (setq dir (directory-file-name (file-name-directory path)))
1945           (if (not (file-exists-p dir))
1946               (elmo-make-directory dir))
1947           (write-region-as-binary (point-min) (point-max)
1948                                   path nil 'no-msg)
1949           t))
1950     ;; ignore error
1951     (error)))
1952
1953 (defun elmo-file-cache-load (cache-path section)
1954   "Load cache on PATH into the current buffer.
1955 Return t if cache is loaded successfully."
1956   (condition-case nil
1957       (let (cache-file)
1958         (when (and cache-path
1959                    (if (elmo-cache-path-section-p cache-path)
1960                        section
1961                      (null section))
1962                    (setq cache-file (elmo-file-cache-expand-path
1963                                      cache-path
1964                                      section))
1965                    (file-exists-p cache-file))
1966           (insert-file-contents-as-binary cache-file)
1967           t))
1968     ;; igore error
1969     (error)))
1970
1971 (defun elmo-cache-path-section-p (path)
1972   "Return non-nil when PATH is `section' cache path."
1973   (file-directory-p path))
1974
1975 (defun elmo-file-cache-get (msgid &optional section)
1976   "Returns the current file-cache object associated with MSGID.
1977 MSGID is the message-id of the message.
1978 If optional argument SECTION is specified, get partial file-cache object
1979 associated with SECTION."
1980   (if msgid
1981       (let ((path (elmo-cache-get-path msgid)))
1982         (if (and path (file-exists-p path))
1983             (if (elmo-cache-path-section-p path)
1984                 (if section
1985                     (if (file-exists-p (setq path (expand-file-name
1986                                                    section path)))
1987                         (cons path 'section))
1988                   ;; section is not specified but sectional.
1989                   (cons path 'section))
1990               ;; not directory.
1991               (unless section
1992                 (cons path 'entire)))
1993           ;; no cache.
1994           (cons path nil)))))
1995
1996 ;;;
1997 ;; Expire cache.
1998
1999 (defun elmo-cache-expire ()
2000   (interactive)
2001   (let* ((completion-ignore-case t)
2002          (method (completing-read (format "Expire by (%s): "
2003                                           elmo-cache-expire-default-method)
2004                                   '(("size" . "size")
2005                                     ("age" . "age"))
2006                                   nil t)))
2007     (when (string= method "")
2008       (setq method elmo-cache-expire-default-method))
2009     (funcall (intern (concat "elmo-cache-expire-by-" method)))))
2010
2011 (defun elmo-read-float-value-from-minibuffer (prompt &optional initial)
2012   (let ((str (read-from-minibuffer prompt initial)))
2013     (cond
2014      ((string-match "[0-9]*\\.[0-9]+" str)
2015       (string-to-number str))
2016      ((string-match "[0-9]+" str)
2017       (string-to-number (concat str ".0")))
2018      (t (error "%s is not number" str)))))
2019
2020 (defun elmo-cache-expire-by-size (&optional kbytes)
2021   "Expire cache file by size.
2022 If KBYTES is kilo bytes (This value must be float)."
2023   (interactive)
2024   (let ((size (or kbytes
2025                   (and (interactive-p)
2026                        (elmo-read-float-value-from-minibuffer
2027                         "Enter cache disk size (Kbytes): "
2028                         (number-to-string
2029                          (if (integerp elmo-cache-expire-default-size)
2030                              (float elmo-cache-expire-default-size)
2031                            elmo-cache-expire-default-size))))
2032                   (if (integerp elmo-cache-expire-default-size)
2033                       (float elmo-cache-expire-default-size))))
2034         (count 0)
2035         (Kbytes 1024)
2036         total beginning)
2037     (message "Checking disk usage...")
2038     (setq total (/ (elmo-disk-usage
2039                     elmo-cache-directory) Kbytes))
2040     (setq beginning total)
2041     (message "Checking disk usage...done")
2042     (let ((cfl (elmo-cache-get-sorted-cache-file-list))
2043           (deleted 0)
2044           oldest
2045           cur-size cur-file)
2046       (while (and (<= size total)
2047                   (setq oldest (elmo-cache-get-oldest-cache-file-entity cfl)))
2048         (setq cur-file (expand-file-name (car (cdr oldest)) (car oldest)))
2049         (setq cur-size (/ (elmo-disk-usage cur-file) Kbytes))
2050         (when (elmo-file-cache-delete cur-file)
2051           (setq count (+ count 1))
2052           (message "%d cache(s) are expired." count))
2053         (setq deleted (+ deleted cur-size))
2054         (setq total (- total cur-size)))
2055       (message "%d cache(s) are expired from disk (%d Kbytes/%d Kbytes)."
2056                count deleted beginning))))
2057
2058 (defun elmo-cache-make-file-entity (filename path)
2059   (cons filename (elmo-get-last-accessed-time filename path)))
2060
2061 (defun elmo-cache-get-oldest-cache-file-entity (cache-file-list)
2062   (let ((cfl cache-file-list)
2063         flist firsts oldest-entity wonlist)
2064     (while cfl
2065       (setq flist (cdr (car cfl)))
2066       (setq firsts (append firsts (list
2067                                    (cons (car (car cfl))
2068                                          (car flist)))))
2069       (setq cfl (cdr cfl)))
2070 ;;; (prin1 firsts)
2071     (while firsts
2072       (if (and (not oldest-entity)
2073                (cdr (cdr (car firsts))))
2074           (setq oldest-entity (car firsts)))
2075       (if (and (cdr (cdr (car firsts)))
2076                (cdr (cdr oldest-entity))
2077                (> (cdr (cdr oldest-entity)) (cdr (cdr (car firsts)))))
2078           (setq oldest-entity (car firsts)))
2079       (setq firsts (cdr firsts)))
2080     (setq wonlist (assoc (car oldest-entity) cache-file-list))
2081     (and wonlist
2082          (setcdr wonlist (delete (car (cdr wonlist)) (cdr wonlist))))
2083     oldest-entity))
2084
2085 (defun elmo-cache-get-sorted-cache-file-list ()
2086   (let ((dirs (directory-files
2087                elmo-cache-directory
2088                t "^[^\\.]"))
2089         (i 0) num
2090         elist
2091         ret-val)
2092     (setq num (length dirs))
2093     (message "Collecting cache info...")
2094     (while dirs
2095       (setq elist (mapcar (lambda (x)
2096                             (elmo-cache-make-file-entity x (car dirs)))
2097                           (directory-files (car dirs) nil "^[^\\.]")))
2098       (setq ret-val (append ret-val
2099                             (list (cons
2100                                    (car dirs)
2101                                    (sort
2102                                     elist
2103                                     (lambda (x y)
2104                                       (< (cdr x)
2105                                          (cdr y))))))))
2106       (when (> num elmo-display-progress-threshold)
2107         (setq i (+ i 1))
2108         (elmo-display-progress
2109          'elmo-cache-get-sorted-cache-file-list "Collecting cache info..."
2110          (/ (* i 100) num)))
2111       (setq dirs (cdr dirs)))
2112     (message "Collecting cache info...done")
2113     ret-val))
2114
2115 (defun elmo-cache-expire-by-age (&optional days)
2116   (let ((age (or (and days (int-to-string days))
2117                  (and (interactive-p)
2118                       (read-from-minibuffer
2119                        (format "Enter days (%s): "
2120                                elmo-cache-expire-default-age)))
2121                  (int-to-string elmo-cache-expire-default-age)))
2122         (dirs (directory-files
2123                elmo-cache-directory
2124                t "^[^\\.]"))
2125         (count 0)
2126         curtime)
2127     (if (string= age "")
2128         (setq age elmo-cache-expire-default-age)
2129       (setq age (string-to-int age)))
2130     (setq curtime (current-time))
2131     (setq curtime (+ (* (nth 0 curtime)
2132                         (float 65536)) (nth 1 curtime)))
2133     (while dirs
2134       (let ((files (directory-files (car dirs) t "^[^\\.]"))
2135             (limit-age (* age 86400)))
2136         (while files
2137           (when (> (- curtime (elmo-get-last-accessed-time (car files)))
2138                    limit-age)
2139             (when (elmo-file-cache-delete (car files))
2140               (setq count (+ 1 count))
2141               (message "%d cache file(s) are expired." count)))
2142           (setq files (cdr files))))
2143       (setq dirs (cdr dirs)))))
2144
2145 ;;;
2146 ;; msgid to path.
2147 (defun elmo-msgid-to-cache (msgid)
2148   (save-match-data
2149     (when (and msgid
2150                (string-match "<\\(.+\\)>$" msgid))
2151       (elmo-replace-string-as-filename (elmo-match-string 1 msgid)))))
2152
2153 (defun elmo-cache-get-path (msgid &optional folder number)
2154   "Get path for cache file associated with MSGID, FOLDER, and NUMBER."
2155   (if (setq msgid (elmo-msgid-to-cache msgid))
2156       (expand-file-name
2157        (expand-file-name
2158         (if folder
2159             (format "%s/%s/%s@%s"
2160                     (elmo-cache-get-path-subr msgid)
2161                     msgid
2162                     (or number "")
2163                     (elmo-safe-filename folder))
2164           (format "%s/%s"
2165                   (elmo-cache-get-path-subr msgid)
2166                   msgid))
2167         elmo-cache-directory))))
2168
2169 ;;;
2170 ;; Warnings.
2171
2172 (static-if (fboundp 'display-warning)
2173     (defmacro elmo-warning (&rest args)
2174       "Display a warning with `elmo' group."
2175       `(display-warning 'elmo (format ,@args)))
2176   (defconst elmo-warning-buffer-name "*elmo warning*")
2177   (defun elmo-warning (&rest args)
2178     "Display a warning. ARGS are passed to `format'."
2179     (with-current-buffer (get-buffer-create elmo-warning-buffer-name)
2180       (goto-char (point-max))
2181       (funcall 'insert (apply 'format (append args '("\n"))))
2182       (ignore-errors (recenter 1))
2183       (display-buffer elmo-warning-buffer-name))))
2184
2185 (defvar elmo-obsolete-variable-alist nil)
2186
2187 (defcustom elmo-obsolete-variable-show-warnings t
2188   "Show warning window if obsolete variable is treated."
2189   :type 'boolean
2190   :group 'elmo)
2191
2192 (defun elmo-define-obsolete-variable (obsolete var)
2193   "Define obsolete variable.
2194 OBSOLETE is a symbol for obsolete variable.
2195 VAR is a symbol for new variable.
2196 Definition is stored in `elmo-obsolete-variable-alist'."
2197   (let ((pair (assq var elmo-obsolete-variable-alist)))
2198     (if pair
2199         (setcdr pair obsolete)
2200       (setq elmo-obsolete-variable-alist
2201             (cons (cons var obsolete)
2202                   elmo-obsolete-variable-alist)))))
2203
2204 (defun elmo-resque-obsolete-variable (obsolete var)
2205   "Resque obsolete variable OBSOLETE as VAR.
2206 If `elmo-obsolete-variable-show-warnings' is non-nil, show warning message."
2207   (when (boundp obsolete)
2208     (static-if (and (fboundp 'defvaralias)
2209                     (subrp (symbol-function 'defvaralias)))
2210         (defvaralias var obsolete)
2211       (set var (symbol-value obsolete)))
2212     (if elmo-obsolete-variable-show-warnings
2213         (elmo-warning "%s is obsolete. Use %s instead."
2214                       (symbol-name obsolete)
2215                       (symbol-name var)))))
2216
2217 (defun elmo-resque-obsolete-variables (&optional alist)
2218   "Resque obsolete variables in ALIST.
2219 ALIST is a list of cons cell of
2220 \(OBSOLETE-VARIABLE-SYMBOL . NEW-VARIABLE-SYMBOL\).
2221 If ALIST is nil, `elmo-obsolete-variable-alist' is used."
2222   (dolist (pair elmo-obsolete-variable-alist)
2223     (elmo-resque-obsolete-variable (cdr pair)
2224                                    (car pair))))
2225
2226 (defsubst elmo-msgdb-get-last-message-id (string)
2227   (if string
2228       (save-match-data
2229         (let (beg)
2230           (elmo-set-work-buf
2231            (insert string)
2232            (goto-char (point-max))
2233            (when (search-backward "<" nil t)
2234              (setq beg (point))
2235              (if (search-forward ">" nil t)
2236                  (elmo-replace-in-string
2237                   (buffer-substring beg (point)) "\n[ \t]*" ""))))))))
2238
2239 (defun elmo-msgdb-get-message-id-from-buffer ()
2240   (let ((msgid (elmo-field-body "message-id")))
2241     (if msgid
2242         (if (string-match "<\\(.+\\)>$" msgid)
2243             msgid
2244           (concat "<" msgid ">"))       ; Invaild message-id.
2245       ;; no message-id, so put dummy msgid.
2246       (concat "<"
2247               (if (elmo-unfold-field-body "date")
2248                   (timezone-make-date-sortable (elmo-unfold-field-body "date"))
2249                 (md5 (string-as-unibyte (buffer-string))))
2250               (nth 1 (eword-extract-address-components
2251                       (or (elmo-field-body "from") "nobody"))) ">"))))
2252
2253 (defun elmo-msgdb-get-references-from-buffer ()
2254   (if elmo-msgdb-prefer-in-reply-to-for-parent
2255       (or (elmo-msgdb-get-last-message-id (elmo-field-body "in-reply-to"))
2256           (elmo-msgdb-get-last-message-id (elmo-field-body "references")))
2257     (or (elmo-msgdb-get-last-message-id (elmo-field-body "references"))
2258         (elmo-msgdb-get-last-message-id (elmo-field-body "in-reply-to")))))
2259
2260 (defsubst elmo-msgdb-insert-file-header (file)
2261   "Insert the header of the article."
2262   (let ((beg 0)
2263         insert-file-contents-pre-hook   ; To avoid autoconv-xmas...
2264         insert-file-contents-post-hook
2265         format-alist)
2266     (when (file-exists-p file)
2267       ;; Read until header separator is found.
2268       (while (and (eq elmo-msgdb-file-header-chop-length
2269                       (nth 1
2270                            (insert-file-contents-as-binary
2271                             file nil beg
2272                             (incf beg elmo-msgdb-file-header-chop-length))))
2273                   (prog1 (not (search-forward "\n\n" nil t))
2274                     (goto-char (point-max))))))))
2275
2276 ;;
2277 ;; overview handling
2278 ;;
2279 (defun elmo-multiple-field-body (name &optional boundary)
2280   (save-excursion
2281     (save-restriction
2282       (std11-narrow-to-header boundary)
2283       (goto-char (point-min))
2284       (let ((case-fold-search t)
2285             (field-body nil))
2286         (while (re-search-forward (concat "^" name ":[ \t]*") nil t)
2287           (setq field-body
2288                 (nconc field-body
2289                        (list (buffer-substring-no-properties
2290                               (match-end 0) (std11-field-end))))))
2291         field-body))))
2292
2293 (defun elmo-parse-addresses (string)
2294   (if (null string)
2295       ()
2296     (elmo-set-work-buf
2297       (let (list start s char)
2298         (insert string)
2299         (goto-char (point-min))
2300         (skip-chars-forward "\t\f\n\r ")
2301         (setq start (point))
2302         (while (not (eobp))
2303           (skip-chars-forward "^\"\\,(")
2304           (setq char (following-char))
2305           (cond ((= char ?\\)
2306                  (forward-char 1)
2307                  (if (not (eobp))
2308                      (forward-char 1)))
2309                 ((= char ?,)
2310                  (setq s (buffer-substring start (point)))
2311                  (if (or (null (string-match "^[\t\f\n\r ]+$" s))
2312                          (not (string= s "")))
2313                      (setq list (cons s list)))
2314                  (skip-chars-forward ",\t\f\n\r ")
2315                  (setq start (point)))
2316                 ((= char ?\")
2317                  (re-search-forward "[^\\]\"" nil 0))
2318                 ((= char ?\()
2319                  (let ((parens 1))
2320                    (forward-char 1)
2321                    (while (and (not (eobp)) (not (zerop parens)))
2322                      (re-search-forward "[()]" nil 0)
2323                      (cond ((or (eobp)
2324                                 (= (char-after (- (point) 2)) ?\\)))
2325                            ((= (preceding-char) ?\()
2326                             (setq parens (1+ parens)))
2327                            (t
2328                             (setq parens (1- parens)))))))))
2329         (setq s (buffer-substring start (point)))
2330         (if (and (null (string-match "^[\t\f\n\r ]+$" s))
2331                  (not (string= s "")))
2332             (setq list (cons s list)))
2333         (nreverse list)))))
2334
2335 ;;; Queue.
2336 (defvar elmo-dop-queue-filename "queue"
2337   "*Disconnected operation queue is saved in this file.")
2338
2339 (defun elmo-dop-queue-load ()
2340   (setq elmo-dop-queue
2341         (elmo-object-load
2342          (expand-file-name elmo-dop-queue-filename
2343                            elmo-msgdb-directory))))
2344
2345 (defun elmo-dop-queue-save ()
2346   (elmo-object-save
2347    (expand-file-name elmo-dop-queue-filename
2348                      elmo-msgdb-directory)
2349    elmo-dop-queue))
2350
2351 (if (and (fboundp 'regexp-opt)
2352          (not (featurep 'xemacs)))
2353     (defalias 'elmo-regexp-opt 'regexp-opt)
2354   (defun elmo-regexp-opt (strings &optional paren)
2355     "Return a regexp to match a string in STRINGS.
2356 Each string should be unique in STRINGS and should not contain any regexps,
2357 quoted or not.  If optional PAREN is non-nil, ensure that the returned regexp
2358 is enclosed by at least one regexp grouping construct."
2359     (let ((open-paren (if paren "\\(" "")) (close-paren (if paren "\\)" "")))
2360       (concat open-paren (mapconcat 'regexp-quote strings "\\|")
2361               close-paren))))
2362
2363 (require 'product)
2364 (product-provide (provide 'elmo-util) (require 'elmo-version))
2365
2366 ;;; elmo-util.el ends here