elmo/elmo-util.el

   1 ;;; elmo-util.el --- Utilities for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (eval-when-compile (require 'cl))
  33 (require 'elmo-vars)
  34 (require 'elmo-date)
  35 (require 'mcharset)
  36 (require 'pces)
  37 (require 'std11)
  38 (require 'eword-decode)
  39 (require 'utf7)
  40 (require 'poem)
  41
  42 (defmacro elmo-set-buffer-multibyte (flag)
  43   "Set the multibyte flag of the current buffer to FLAG."
  44   (cond ((boundp 'MULE)
  45          (list 'setq 'mc-flag flag))
  46         ((featurep 'xemacs)
  47          flag)
  48         ((and (boundp 'emacs-major-version) (>= emacs-major-version 20))
  49          (list 'set-buffer-multibyte flag))
  50         (t
  51          flag)))
  52
  53 (defvar elmo-work-buf-name " *elmo work*")
  54 (defvar elmo-temp-buf-name " *elmo temp*")
  55
  56 (or (boundp 'default-enable-multibyte-characters)
  57     (defvar default-enable-multibyte-characters (featurep 'mule)
  58       "The mock variable except for Emacs 20."))
  59
  60 (defun elmo-base64-encode-string (string &optional no-line-break))
  61 (defun elmo-base64-decode-string (string))
  62
  63 ;; base64 encoding/decoding
  64 (require 'mel)
  65 (fset 'elmo-base64-encode-string
  66       (mel-find-function 'mime-encode-string "base64"))
  67 (fset 'elmo-base64-decode-string
  68       (mel-find-function 'mime-decode-string "base64"))
  69
  70 ;; Any Emacsen may have add-name-to-file(), because loadup.el requires it. :-p
  71 ;; Check make-symbolic-link() instead.  -- 981002 by Fuji
  72 (if (fboundp 'make-symbolic-link)  ;; xxx
  73     (defalias 'elmo-add-name-to-file 'add-name-to-file)
  74   (defun elmo-add-name-to-file
  75     (filename newname &optional ok-if-already-exists)
  76     (copy-file filename newname ok-if-already-exists t)))
  77
  78 (defalias 'elmo-read 'read)
  79
  80 (defmacro elmo-set-work-buf (&rest body)
  81   "Execute BODY on work buffer.  Work buffer remains."
  82   (` (save-excursion
  83        (set-buffer (get-buffer-create elmo-work-buf-name))
  84        (elmo-set-buffer-multibyte default-enable-multibyte-characters)
  85        (erase-buffer)
  86        (,@ body))))
  87
  88 (defmacro elmo-bind-directory (dir &rest body)
  89   "Set current directory DIR and execute BODY."
  90   (` (let ((default-directory (file-name-as-directory (, dir))))
  91        (,@ body))))
  92
  93 (defun elmo-object-load (filename &optional mime-charset no-err)
  94   "Load OBJECT from the file specified by FILENAME.
  95 File content is decoded with MIME-CHARSET."
  96     (if (not (file-readable-p filename))
  97         nil
  98       (elmo-set-work-buf
  99        (as-binary-input-file
 100         (insert-file-contents filename))
 101        (when mime-charset
 102          (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 103          (decode-mime-charset-region (point-min) (point-max) mime-charset))
 104        (condition-case nil
 105            (read (current-buffer))
 106          (error (unless no-err
 107                   (message "Warning: Loading object from %s failed."
 108                            filename)
 109                   (elmo-object-save filename nil))
 110                 nil)))))
 111
 112 (defsubst elmo-save-buffer (filename &optional mime-charset)
 113   "Save current buffer to the file specified by FILENAME.
 114 Directory of the file is created if it doesn't exist.
 115 File content is encoded with MIME-CHARSET."
 116   (let ((dir (directory-file-name (file-name-directory filename))))
 117     (if (file-directory-p dir)
 118         () ; ok.
 119       (unless (file-exists-p dir)
 120         (elmo-make-directory dir)))
 121     (if (file-writable-p filename)
 122         (progn
 123           (when mime-charset
 124 ;;;         (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 125             (encode-mime-charset-region (point-min) (point-max) mime-charset))
 126           (as-binary-output-file
 127            (write-region (point-min) (point-max) filename nil 'no-msg)))
 128       (message "%s is not writable." filename))))
 129
 130 (defun elmo-object-save (filename object &optional mime-charset)
 131   "Save OBJECT to the file specified by FILENAME.
 132 Directory of the file is created if it doesn't exist.
 133 File content is encoded with MIME-CHARSET."
 134   (elmo-set-work-buf
 135    (prin1 object (current-buffer))
 136 ;;;(princ "\n" (current-buffer))
 137    (elmo-save-buffer filename mime-charset)))
 138
 139 ;;; Search Condition
 140
 141 (defconst elmo-condition-atom-regexp "[^/ \")|&]*")
 142
 143 (defun elmo-read-search-condition (default)
 144   "Read search condition string interactively."
 145   (elmo-read-search-condition-internal "Search by" default))
 146
 147 (defun elmo-read-search-condition-internal (prompt default)
 148   (let* ((completion-ignore-case t)
 149          (field (completing-read
 150                  (format "%s (%s): " prompt default)
 151                  (mapcar 'list
 152                          (append '("AND" "OR"
 153                                    "Last" "First"
 154                                    "From" "Subject" "To" "Cc" "Body"
 155                                    "Since" "Before" "ToCc"
 156                                    "!From" "!Subject" "!To" "!Cc" "!Body"
 157                                    "!Since" "!Before" "!ToCc")
 158                                  elmo-msgdb-extra-fields))))
 159          value)
 160     (setq field (if (string= field "")
 161                     (setq field default)
 162                   field))
 163     (cond
 164      ((or (string= field "AND") (string= field "OR"))
 165       (concat "("
 166               (elmo-read-search-condition-internal
 167                (concat field "(1) Search by") default)
 168               (if (string= field "AND") "&" "|")
 169               (elmo-read-search-condition-internal
 170                (concat field "(2) Search by") default)
 171               ")"))
 172      ((string-match "Since\\|Before" field)
 173       (let ((default (format-time-string "%Y-%m-%d")))
 174         (setq value (completing-read
 175                      (format "Value for '%s' [%s]: " field default)
 176                      (mapcar (function
 177                               (lambda (x)
 178                                 (list (format "%s" (car x)))))
 179                              elmo-date-descriptions)))
 180         (concat (downcase field) ":"
 181                 (if (equal value "") default value))))
 182      (t
 183       (setq value (read-from-minibuffer (format "Value for '%s': " field)))
 184       (unless (string-match (concat "^" elmo-condition-atom-regexp "$")
 185                             value)
 186         (setq value (prin1-to-string value)))
 187       (concat (downcase field) ":" value)))))
 188
 189 (defsubst elmo-condition-parse-error ()
 190   (error "Syntax error in '%s'" (buffer-string)))
 191
 192 (defun elmo-parse-search-condition (condition)
 193   "Parse CONDITION.
 194 Return value is a cons cell of (STRUCTURE . REST)"
 195   (with-temp-buffer
 196     (insert condition)
 197     (goto-char (point-min))
 198     (cons (elmo-condition-parse) (buffer-substring (point) (point-max)))))
 199
 200 ;; condition    ::= or-expr
 201 (defun elmo-condition-parse ()
 202   (or (elmo-condition-parse-or-expr)
 203       (elmo-condition-parse-error)))
 204
 205 ;; or-expr      ::= and-expr /
 206 ;;                  and-expr "|" or-expr
 207 (defun elmo-condition-parse-or-expr ()
 208   (let ((left (elmo-condition-parse-and-expr)))
 209     (if (looking-at "| *")
 210         (progn
 211           (goto-char (match-end 0))
 212           (list 'or left (elmo-condition-parse-or-expr)))
 213       left)))
 214
 215 ;; and-expr     ::= primitive /
 216 ;;                  primitive "&" and-expr
 217 (defun elmo-condition-parse-and-expr ()
 218   (let ((left (elmo-condition-parse-primitive)))
 219     (if (looking-at "& *")
 220         (progn
 221           (goto-char (match-end 0))
 222           (list 'and left (elmo-condition-parse-and-expr)))
 223       left)))
 224
 225 ;; primitive    ::= "(" expr ")" /
 226 ;;                  ["!"] search-key SPACE* ":" SPACE* search-value
 227 (defun elmo-condition-parse-primitive ()
 228   (cond
 229    ((looking-at "( *")
 230     (goto-char (match-end 0))
 231     (prog1 (elmo-condition-parse)
 232       (unless (looking-at ") *")
 233         (elmo-condition-parse-error))
 234       (goto-char (match-end 0))))
 235 ;; search-key   ::= [A-Za-z-]+
 236 ;;                 ;; "since" / "before" / "last" / "first" /
 237 ;;                 ;; "body" / field-name
 238    ((looking-at "\\(!\\)? *\\([A-Za-z-]+\\) *: *")
 239     (goto-char (match-end 0))
 240     (let ((search-key (vector
 241                        (if (match-beginning 1) 'unmatch 'match)
 242                        (elmo-match-buffer 2)
 243                        (elmo-condition-parse-search-value))))
 244       ;; syntax sugar.
 245       (if (string= (aref search-key 1) "tocc")
 246           (if (eq (aref search-key 0) 'match)
 247               (list 'or
 248                     (vector 'match "to" (aref search-key 2))
 249                     (vector 'match "cc" (aref search-key 2)))
 250             (list 'and
 251                   (vector 'unmatch "to" (aref search-key 2))
 252                   (vector 'unmatch "cc" (aref search-key 2))))
 253         search-key)))))
 254
 255 ;; search-value ::= quoted / time / number / atom
 256 ;; quoted       ::= <elisp string expression>
 257 ;; time         ::= "yesterday" / "lastweek" / "lastmonth" / "lastyear" /
 258 ;;                   number SPACE* "daysago" /
 259 ;;                   number "-" month "-" number  ; ex. 10-May-2000
 260 ;;                   number "-" number "-" number  ; ex. 2000-05-10
 261 ;; number       ::= [0-9]+
 262 ;; month        ::= "Jan" / "Feb" / "Mar" / "Apr" / "May" / "Jun" /
 263 ;;                  "Jul" / "Aug" / "Sep" / "Oct" / "Nov" / "Dec"
 264 ;; atom         ::= ATOM_CHARS*
 265 ;; SPACE        ::= <ascii space character, 0x20>
 266 ;; ATOM_CHARS   ::= <any character except specials>
 267 ;; specials     ::= SPACE / <"> / </> / <)> / <|> / <&>
 268 ;;                  ;; These characters should be quoted.
 269 (defun elmo-condition-parse-search-value ()
 270   (cond
 271    ((looking-at "\"")
 272     (elmo-read (current-buffer)))
 273    ((or (looking-at "yesterday") (looking-at "lastweek")
 274         (looking-at "lastmonth") (looking-at "lastyear")
 275         (looking-at "[0-9]+ *daysago")
 276         (looking-at "[0-9]+-[A-Za-z]+-[0-9]+")
 277         (looking-at "[0-9]+-[0-9]+-[0-9]+")
 278         (looking-at "[0-9]+")
 279         (looking-at elmo-condition-atom-regexp))
 280     (prog1 (elmo-match-buffer 0)
 281       (goto-char (match-end 0))))
 282    (t (error "Syntax error '%s'" (buffer-string)))))
 283
 284 ;;;
 285 (defsubst elmo-buffer-replace (regexp &optional newtext)
 286   (goto-char (point-min))
 287   (while (re-search-forward regexp nil t)
 288     (replace-match (or newtext ""))))
 289
 290 (defsubst elmo-delete-char (char string &optional unibyte)
 291   (save-match-data
 292     (elmo-set-work-buf
 293      (let ((coding-system-for-read 'no-conversion)
 294            (coding-system-for-write 'no-conversion))
 295        (if unibyte (elmo-set-buffer-multibyte nil))
 296        (insert string)
 297        (goto-char (point-min))
 298        (while (search-forward (char-to-string char) nil t)
 299          (replace-match ""))
 300        (buffer-string)))))
 301
 302 (defsubst elmo-delete-cr-buffer ()
 303   "Delete CR from buffer."
 304   (save-excursion
 305     (goto-char (point-min))
 306     (while (search-forward "\r\n" nil t)
 307       (replace-match "\n")) ))
 308
 309 (defsubst elmo-delete-cr-get-content-type ()
 310   (save-excursion
 311     (goto-char (point-min))
 312     (while (search-forward "\r\n" nil t)
 313       (replace-match "\n"))
 314     (goto-char (point-min))
 315     (or (std11-field-body "content-type")
 316         t)))
 317
 318 (defun elmo-delete-cr (string)
 319   (save-match-data
 320     (elmo-set-work-buf
 321      (insert string)
 322      (goto-char (point-min))
 323      (while (search-forward "\r\n" nil t)
 324        (replace-match "\n"))
 325      (buffer-string))))
 326
 327 (defun elmo-uniq-list (lst)
 328   "Distractively uniqfy elements of LST."
 329   (let ((tmp lst))
 330     (while tmp (setq tmp
 331                      (setcdr tmp
 332                              (and (cdr tmp)
 333                                   (delete (car tmp)
 334                                           (cdr tmp)))))))
 335   lst)
 336
 337 (defun elmo-list-insert (list element after)
 338   (let* ((match (memq after list))
 339          (rest (and match (cdr (memq after list)))))
 340     (if match
 341         (progn
 342           (setcdr match (list element))
 343           (nconc list rest))
 344       (nconc list (list element)))))
 345
 346 (defun elmo-string-partial-p (string)
 347   (and (stringp string) (string-match "message/partial" string)))
 348
 349 (defun elmo-get-file-string (filename &optional remove-final-newline)
 350   (elmo-set-work-buf
 351    (let (insert-file-contents-pre-hook   ; To avoid autoconv-xmas...
 352          insert-file-contents-post-hook)
 353      (when (file-exists-p filename)
 354        (if filename
 355            (as-binary-input-file (insert-file-contents filename)))
 356        (when (and remove-final-newline
 357                   (> (buffer-size) 0)
 358                   (= (char-after (1- (point-max))) ?\n))
 359          (goto-char (point-max))
 360          (delete-backward-char 1))
 361        (buffer-string)))))
 362
 363 (defun elmo-save-string (string filename)
 364   (if string
 365       (elmo-set-work-buf
 366        (as-binary-output-file
 367         (insert string)
 368         (write-region (point-min) (point-max)
 369                       filename nil 'no-msg))
 370        )))
 371
 372 (defun elmo-max-of-list (nlist)
 373   (let ((l nlist)
 374         (max-num 0))
 375     (while l
 376       (if (< max-num (car l))
 377           (setq max-num (car l)))
 378       (setq l (cdr l)))
 379     max-num))
 380
 381 (defun elmo-concat-path (path filename)
 382   (if (not (string= path ""))
 383       (if (string= elmo-path-sep (substring path (- (length path) 1)))
 384           (concat path filename)
 385         (concat path elmo-path-sep filename))
 386     filename))
 387
 388 (defvar elmo-passwd-alist nil)
 389
 390 (defun elmo-passwd-alist-load ()
 391   (save-excursion
 392     (let ((filename (expand-file-name elmo-passwd-alist-file-name
 393                                       elmo-msgdb-directory))
 394           (tmp-buffer (get-buffer-create " *elmo-passwd-alist-tmp*"))
 395           insert-file-contents-pre-hook ; To avoid autoconv-xmas...
 396           insert-file-contents-post-hook
 397           ret-val)
 398       (if (not (file-readable-p filename))
 399           ()
 400         (set-buffer tmp-buffer)
 401         (insert-file-contents filename)
 402         (setq ret-val
 403               (condition-case nil
 404                   (read (current-buffer))
 405                 (error nil nil))))
 406       (kill-buffer tmp-buffer)
 407       ret-val)))
 408
 409 (defun elmo-passwd-alist-clear ()
 410   "Clear password cache."
 411   (interactive)
 412   (setq elmo-passwd-alist nil))
 413
 414 (defun elmo-passwd-alist-save ()
 415   "Save password into file."
 416   (interactive)
 417   (save-excursion
 418     (let ((filename (expand-file-name elmo-passwd-alist-file-name
 419                                       elmo-msgdb-directory))
 420           (tmp-buffer (get-buffer-create " *elmo-passwd-alist-tmp*")))
 421       (set-buffer tmp-buffer)
 422       (erase-buffer)
 423       (prin1 elmo-passwd-alist tmp-buffer)
 424       (princ "\n" tmp-buffer)
 425 ;;;   (if (and (file-exists-p filename)
 426 ;;;            (not (equal 384 (file-modes filename))))
 427 ;;;       (error "%s is not safe.chmod 600 %s!" filename filename))
 428       (if (file-writable-p filename)
 429           (progn
 430             (write-region (point-min) (point-max)
 431                           filename nil 'no-msg)
 432             (set-file-modes filename 384))
 433         (message "%s is not writable." filename))
 434       (kill-buffer tmp-buffer))))
 435
 436 (defun elmo-get-passwd (key)
 437   "Get password from password pool."
 438   (let (pair pass)
 439     (if (not elmo-passwd-alist)
 440         (setq elmo-passwd-alist (elmo-passwd-alist-load)))
 441     (setq pair (assoc key elmo-passwd-alist))
 442     (if pair
 443         (elmo-base64-decode-string (cdr pair))
 444       (setq pass (elmo-read-passwd (format "Password for %s: "
 445                                            key) t))
 446       (setq elmo-passwd-alist
 447             (append elmo-passwd-alist
 448                     (list (cons key
 449                                 (elmo-base64-encode-string pass)))))
 450       (if elmo-passwd-life-time
 451           (run-with-timer elmo-passwd-life-time nil
 452                           (` (lambda () (elmo-remove-passwd (, key))))))
 453       pass)))
 454
 455 (defun elmo-remove-passwd (key)
 456   "Remove password from password pool (for failure)."
 457   (let (pass-cons)
 458     (if (setq pass-cons (assoc key elmo-passwd-alist))
 459         (progn
 460           (unwind-protect
 461               (fillarray (cdr pass-cons) 0))
 462           (setq elmo-passwd-alist
 463                 (delete pass-cons elmo-passwd-alist))))))
 464
 465 (defmacro elmo-read-char-exclusive ()
 466   (cond ((featurep 'xemacs)
 467          '(let ((table (quote ((backspace . ?\C-h) (delete . ?\C-?)
 468                                (left . ?\C-h))))
 469                 event key)
 470             (while (not
 471                     (and
 472                      (key-press-event-p (setq event (next-command-event)))
 473                      (setq key (or (event-to-character event)
 474                                    (cdr (assq (event-key event) table)))))))
 475             key))
 476         ((fboundp 'read-char-exclusive)
 477          '(read-char-exclusive))
 478         (t
 479          '(read-char))))
 480
 481 (defun elmo-read-passwd (prompt &optional stars)
 482   "Read a single line of text from user without echoing, and return it."
 483   (let ((ans "")
 484         (c 0)
 485         (echo-keystrokes 0)
 486         (cursor-in-echo-area t)
 487         (log-message-max-size 0)
 488         message-log-max done msg truncate)
 489     (while (not done)
 490       (if (or (not stars) (string= "" ans))
 491           (setq msg prompt)
 492         (setq msg (concat prompt (make-string (length ans) ?.)))
 493         (setq truncate
 494               (1+ (- (length msg) (window-width (minibuffer-window)))))
 495         (and (> truncate 0)
 496              (setq msg (concat "$" (substring msg (1+ truncate))))))
 497       (message "%s" msg)
 498       (setq c (elmo-read-char-exclusive))
 499       (cond ((= c ?\C-g)
 500              (setq quit-flag t
 501                    done t))
 502             ((or (= c ?\r) (= c ?\n) (= c ?\e))
 503              (setq done t))
 504             ((= c ?\C-u)
 505              (setq ans ""))
 506             ((and (/= c ?\b) (/= c ?\177))
 507              (setq ans (concat ans (char-to-string c))))
 508             ((> (length ans) 0)
 509              (setq ans (substring ans 0 -1)))))
 510     (if quit-flag
 511         (prog1
 512             (setq quit-flag nil)
 513           (message "Quit")
 514           (beep t))
 515       (message "")
 516       ans)))
 517
 518 (defun elmo-string-to-list (string)
 519   (elmo-set-work-buf
 520    (insert string)
 521    (goto-char (point-min))
 522    (insert "(")
 523    (goto-char (point-max))
 524    (insert ")")
 525    (goto-char (point-min))
 526    (read (current-buffer))))
 527
 528 (defun elmo-list-to-string (list)
 529   (let ((tlist list)
 530         str)
 531     (if (listp tlist)
 532         (progn
 533           (setq str "(")
 534           (while (car tlist)
 535             (setq str
 536                   (concat str
 537                           (if (symbolp (car tlist))
 538                               (symbol-name (car tlist))
 539                             (car tlist))))
 540             (if (cdr tlist)
 541                 (setq str
 542                       (concat str " ")))
 543             (setq tlist (cdr tlist)))
 544           (setq str
 545                 (concat str ")")))
 546       (setq str
 547             (if (symbolp tlist)
 548                 (symbol-name tlist)
 549               tlist)))
 550     str))
 551
 552
 553 (defun elmo-plug-on-by-servers (alist &optional servers)
 554   (let ((server-list (or servers elmo-plug-on-servers)))
 555     (catch 'plugged
 556       (while server-list
 557         (if (elmo-plugged-p (car server-list))
 558             (throw 'plugged t))
 559         (setq server-list (cdr server-list))))))
 560
 561 (defun elmo-plug-on-by-exclude-servers (alist &optional servers)
 562   (let ((server-list (or servers elmo-plug-on-exclude-servers))
 563         server other-servers)
 564     (while alist
 565       (when (and (not (member (setq server (caaar alist)) server-list))
 566                  (not (member server other-servers)))
 567         (push server other-servers))
 568       (setq alist (cdr alist)))
 569     (elmo-plug-on-by-servers alist other-servers)))
 570
 571 (defun elmo-plugged-p (&optional server port stream-type alist label-exp)
 572   (let ((alist (or alist elmo-plugged-alist))
 573         plugged-info)
 574     (cond ((and (not port) (not server))
 575            (cond ((eq elmo-plugged-condition 'one)
 576                   (if alist
 577                       (catch 'plugged
 578                         (while alist
 579                           (if (nth 2 (car alist))
 580                               (throw 'plugged t))
 581                           (setq alist (cdr alist))))
 582                     elmo-plugged))
 583                  ((eq elmo-plugged-condition 'all)
 584                   (if alist
 585                       (catch 'plugged
 586                         (while alist
 587                           (if (not (nth 2 (car alist)))
 588                               (throw 'plugged nil))
 589                           (setq alist (cdr alist)))
 590                         t)
 591                     elmo-plugged))
 592                  ((functionp elmo-plugged-condition)
 593                   (funcall elmo-plugged-condition alist))
 594                  (t ;; independent
 595                   elmo-plugged)))
 596           ((not port) ;; server
 597            (catch 'plugged
 598              (while alist
 599                (when (string= server (caaar alist))
 600                  (if (nth 2 (car alist))
 601                      (throw 'plugged t)))
 602                (setq alist (cdr alist)))))
 603           (t
 604            (setq plugged-info (assoc (list server port stream-type) alist))
 605            (if (not plugged-info)
 606                ;; add elmo-plugged-alist automatically
 607                (progn
 608                  (elmo-set-plugged elmo-plugged server port stream-type
 609                                    nil nil nil label-exp)
 610                  elmo-plugged)
 611              (if (and elmo-auto-change-plugged
 612                       (> elmo-auto-change-plugged 0)
 613                       (nth 3 plugged-info)  ;; time
 614                       (elmo-time-expire (nth 3 plugged-info)
 615                                         elmo-auto-change-plugged))
 616                  t
 617                (nth 2 plugged-info)))))))
 618
 619 (defun elmo-set-plugged (plugged &optional server port stream-type time
 620                                  alist label-exp add)
 621   (let ((alist (or alist elmo-plugged-alist))
 622         label plugged-info)
 623     (cond ((and (not port) (not server))
 624            (setq elmo-plugged plugged)
 625            ;; set plugged all element of elmo-plugged-alist.
 626            (while alist
 627              (setcdr (cdar alist) (list plugged time))
 628              (setq alist (cdr alist))))
 629           ((not port)
 630            ;; set plugged all port of server
 631            (while alist
 632              (when (string= server (caaar alist))
 633                (setcdr (cdar alist) (list plugged time)))
 634              (setq alist (cdr alist))))
 635           (t
 636            ;; set plugged one port of server
 637            (setq plugged-info (assoc (list server port stream-type) alist))
 638            (setq label (if label-exp
 639                            (eval label-exp)
 640                          (nth 1 plugged-info)))
 641            (if plugged-info
 642                ;; if add is non-nil, don't reset plug state.
 643                (unless add
 644                  (setcdr plugged-info (list label plugged time)))
 645              (setq alist
 646                    (setq elmo-plugged-alist
 647                          (nconc
 648                           elmo-plugged-alist
 649                           (list
 650                            (list (list server port stream-type)
 651                                  label plugged time))))))))
 652     alist))
 653
 654 (defun elmo-delete-plugged (&optional server port alist)
 655   (let* ((alist (or alist elmo-plugged-alist))
 656          (alist2 alist))
 657     (cond ((and (not port) (not server))
 658            (setq alist nil))
 659           ((not port)
 660            ;; delete plugged all port of server
 661            (while alist2
 662              (when (string= server (caaar alist2))
 663                (setq alist (delete (car alist2) alist)))
 664              (setq alist2 (cdr alist2))))
 665           (t
 666            ;; delete plugged one port of server
 667            (setq alist
 668                  (delete (assoc (cons server port) alist) alist))))
 669     alist))
 670
 671 (defun elmo-disk-usage (path)
 672   "Get disk usage (bytes) in PATH."
 673   (let ((file-attr
 674          (condition-case () (file-attributes path) (error nil))))
 675     (if file-attr
 676         (if (nth 0 file-attr) ; directory
 677             (let ((files (condition-case ()
 678                              (directory-files path t "^[^\\.]")
 679                            (error nil)))
 680                   (result 0.0))
 681               ;; (result (nth 7 file-attr))) ... directory size
 682               (while files
 683                 (setq result (+ result (or (elmo-disk-usage (car files)) 0)))
 684                 (setq files (cdr files)))
 685               result)
 686           (float (nth 7 file-attr)))
 687       0)))
 688
 689 (defun elmo-get-last-accessed-time (path &optional dir)
 690   "Return the last accessed time of PATH."
 691   (let ((last-accessed (nth 4 (file-attributes (or (and dir
 692                                                         (expand-file-name
 693                                                          path dir))
 694                                                    path)))))
 695     (if last-accessed
 696         (setq last-accessed (+ (* (nth 0 last-accessed)
 697                                   (float 65536)) (nth 1 last-accessed)))
 698       0)))
 699
 700 (defun elmo-get-last-modification-time (path &optional dir)
 701   "Return the last accessed time of PATH."
 702   (let ((last-modified (nth 5 (file-attributes (or (and dir
 703                                                         (expand-file-name
 704                                                          path dir))
 705                                                    path)))))
 706     (setq last-modified (+ (* (nth 0 last-modified)
 707                               (float 65536)) (nth 1 last-modified)))))
 708
 709 (defun elmo-make-directory (path &optional mode)
 710   "Create directory recursively."
 711   (let ((parent (directory-file-name (file-name-directory path))))
 712     (if (null (file-directory-p parent))
 713         (elmo-make-directory parent))
 714     (make-directory path)
 715     (set-file-modes path (or mode
 716                              (+ (* 64 7) (* 8 0) 0))))) ; chmod 0700
 717
 718 (defun elmo-delete-directory (path &optional no-hierarchy)
 719   "Delete directory recursively."
 720   (if (stringp path) ; nil is not permitted.
 721   (let ((dirent (directory-files path))
 722         relpath abspath hierarchy)
 723     (while dirent
 724       (setq relpath (car dirent)
 725             dirent (cdr dirent)
 726             abspath (expand-file-name relpath path))
 727       (when (not (string-match "^\\.\\.?$" relpath))
 728         (if (eq (nth 0 (file-attributes abspath)) t)
 729             (if no-hierarchy
 730                 (setq hierarchy t)
 731               (elmo-delete-directory abspath no-hierarchy))
 732           (delete-file abspath))))
 733     (unless hierarchy
 734       (delete-directory path)))))
 735
 736 (defun elmo-delete-match-files (path regexp &optional remove-if-empty)
 737   "Delete directory files specified by PATH.
 738 If optional REMOVE-IF-EMPTY is non-nil, delete directory itself if
 739 the directory becomes empty after deletion."
 740   (when (stringp path) ; nil is not permitted.
 741     (dolist (file (directory-files path t regexp))
 742       (delete-file file))
 743     (if remove-if-empty
 744         (ignore-errors
 745           (delete-directory path) ; should be removed if empty.
 746           ))))
 747
 748 (defun elmo-list-filter (l1 l2)
 749   "L1 is filter."
 750   (if (eq l1 t)
 751       ;; t means filter all.
 752       nil
 753     (if l1
 754         (elmo-delete-if (lambda (x) (not (memq x l1))) l2)
 755       ;; filter is nil
 756       l2)))
 757
 758 (defsubst elmo-list-delete-if-smaller (list number)
 759   (let ((ret-val (copy-sequence list)))
 760     (while list
 761       (if (< (car list) number)
 762           (setq ret-val (delq (car list) ret-val)))
 763       (setq list (cdr list)))
 764     ret-val))
 765
 766 (defun elmo-list-diff (list1 list2 &optional mes)
 767   (if mes
 768       (message mes))
 769   (let ((clist1 (copy-sequence list1))
 770         (clist2 (copy-sequence list2)))
 771     (while list2
 772       (setq clist1 (delq (car list2) clist1))
 773       (setq list2 (cdr list2)))
 774     (while list1
 775       (setq clist2 (delq (car list1) clist2))
 776       (setq list1 (cdr list1)))
 777     (if mes
 778         (message (concat mes "done.")))
 779     (list clist1 clist2)))
 780
 781 (defun elmo-list-bigger-diff (list1 list2 &optional mes)
 782   "Returns a list (- +). + is bigger than max of LIST1, in LIST2."
 783   (if (null list2)
 784       (cons list1  nil)
 785     (let* ((l1 list1)
 786            (l2 list2)
 787            (max-of-l2 (or (nth (max 0 (1- (length l2))) l2) 0))
 788            diff1 num i percent
 789            )
 790       (setq i 0)
 791       (setq num (+ (length l1)))
 792       (while l1
 793         (if (memq (car l1) l2)
 794             (if (eq (car l1) (car l2))
 795                 (setq l2 (cdr l2))
 796               (delq (car l1) l2))
 797           (if (> (car l1) max-of-l2)
 798               (setq diff1 (nconc diff1 (list (car l1))))))
 799         (if mes
 800             (progn
 801               (setq i (+ i 1))
 802               (setq percent (/ (* i 100) num))
 803               (if (eq (% percent 5) 0)
 804                   (elmo-display-progress
 805                    'elmo-list-bigger-diff "%s%d%%" percent mes))))
 806         (setq l1 (cdr l1)))
 807       (cons diff1 (list l2)))))
 808
 809 (defmacro elmo-filter-condition-p (filter)
 810   `(or (vectorp ,filter) (consp ,filter)))
 811
 812 (defmacro elmo-filter-type (filter)
 813   (` (aref (, filter) 0)))
 814
 815 (defmacro elmo-filter-key (filter)
 816   (` (aref (, filter) 1)))
 817
 818 (defmacro elmo-filter-value (filter)
 819   (` (aref (, filter) 2)))
 820
 821 (defsubst elmo-buffer-field-primitive-condition-match (condition
 822                                                        number
 823                                                        number-list)
 824   (let (result)
 825     (goto-char (point-min))
 826     (cond
 827      ((string= (elmo-filter-key condition) "last")
 828       (setq result (<= (length (memq number number-list))
 829                        (string-to-int (elmo-filter-value condition)))))
 830      ((string= (elmo-filter-key condition) "first")
 831       (setq result (< (- (length number-list)
 832                          (length (memq number number-list)))
 833                       (string-to-int (elmo-filter-value condition)))))
 834      ((string= (elmo-filter-key condition) "since")
 835       (let ((field-date (elmo-date-make-sortable-string
 836                          (timezone-fix-time
 837                           (std11-field-body "date")
 838                           (current-time-zone) nil)))
 839             (specified-date (elmo-date-make-sortable-string
 840                              (elmo-date-get-datevec
 841                               (elmo-filter-value condition)))))
 842         (setq result
 843               (or (string= field-date specified-date)
 844                   (string< specified-date field-date)))))
 845      ((string= (elmo-filter-key condition) "before")
 846       (setq result
 847             (string<
 848              (elmo-date-make-sortable-string
 849               (timezone-fix-time
 850                (std11-field-body "date")
 851                (current-time-zone) nil))
 852              (elmo-date-make-sortable-string
 853               (elmo-date-get-datevec
 854                (elmo-filter-value condition))))))
 855      ((string= (elmo-filter-key condition) "body")
 856       (and (re-search-forward "^$" nil t)          ; goto body
 857            (setq result (search-forward (elmo-filter-value condition)
 858                                         nil t))))
 859      (t
 860       (let ((fval (std11-field-body (elmo-filter-key condition))))
 861         (if (eq (length fval) 0) (setq fval nil))
 862         (if fval (setq fval (eword-decode-string fval)))
 863         (setq result (and fval (string-match
 864                                 (elmo-filter-value condition) fval))))))
 865     (if (eq (elmo-filter-type condition) 'unmatch)
 866         (setq result (not result)))
 867     result))
 868
 869 (defun elmo-condition-in-msgdb-p-internal (condition fields)
 870   (cond
 871    ((vectorp condition)
 872     (if (not (member (elmo-filter-key condition) fields))
 873         (throw 'found t)))
 874    ((or (eq (car condition) 'and)
 875         (eq (car condition) 'or))
 876     (elmo-condition-in-msgdb-p-internal (nth 1 condition) fields)
 877     (elmo-condition-in-msgdb-p-internal (nth 2 condition) fields))))
 878
 879 (defun elmo-condition-in-msgdb-p (condition)
 880   (not (catch 'found
 881          (elmo-condition-in-msgdb-p-internal condition
 882                                              (append
 883                                               elmo-msgdb-extra-fields
 884                                               '("last" "first" "from"
 885                                                 "subject" "to" "cc" "since"
 886                                                 "before"))))))
 887
 888 (defun elmo-buffer-field-condition-match (condition number number-list)
 889   (cond
 890    ((vectorp condition)
 891     (elmo-buffer-field-primitive-condition-match
 892      condition number number-list))
 893    ((eq (car condition) 'and)
 894     (and (elmo-buffer-field-condition-match
 895           (nth 1 condition) number number-list)
 896          (elmo-buffer-field-condition-match
 897           (nth 2 condition) number number-list)))
 898    ((eq (car condition) 'or)
 899     (or (elmo-buffer-field-condition-match
 900          (nth 1 condition) number number-list)
 901         (elmo-buffer-field-condition-match
 902          (nth 2 condition) number number-list)))))
 903
 904 (defsubst elmo-file-field-primitive-condition-match (file
 905                                                      condition
 906                                                      number
 907                                                      number-list)
 908   (let (result)
 909     (goto-char (point-min))
 910     (cond
 911      ((string= (elmo-filter-key condition) "last")
 912       (setq result (<= (length (memq number number-list))
 913                        (string-to-int (elmo-filter-value condition))))
 914       (if (eq (elmo-filter-type condition) 'unmatch)
 915           (setq result (not result))))
 916      ((string= (elmo-filter-key condition) "first")
 917       (setq result (< (- (length number-list)
 918                          (length (memq number number-list)))
 919                       (string-to-int (elmo-filter-value condition))))
 920       (if (eq (elmo-filter-type condition) 'unmatch)
 921           (setq result (not result))))
 922      (t
 923       (elmo-set-work-buf
 924        (as-binary-input-file (insert-file-contents file))
 925        (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 926        ;; Should consider charset?
 927        (decode-mime-charset-region (point-min)(point-max) elmo-mime-charset)
 928        (setq result
 929              (elmo-buffer-field-primitive-condition-match
 930               condition number number-list)))))
 931     result))
 932
 933 (defun elmo-file-field-condition-match (file condition number number-list)
 934   (cond
 935    ((vectorp condition)
 936     (elmo-file-field-primitive-condition-match
 937      file condition number number-list))
 938    ((eq (car condition) 'and)
 939     (and (elmo-file-field-condition-match
 940           file (nth 1 condition) number number-list)
 941          (elmo-file-field-condition-match
 942           file (nth 2 condition) number number-list)))
 943    ((eq (car condition) 'or)
 944     (or (elmo-file-field-condition-match
 945          file (nth 1 condition) number number-list)
 946         (elmo-file-field-condition-match
 947          file (nth 2 condition) number number-list)))))
 948
 949 (defmacro elmo-get-hash-val (string hashtable)
 950   `(and (stringp ,string)
 951         (let ((sym (intern-soft ,string ,hashtable)))
 952           (if (boundp sym)
 953               (symbol-value sym)))))
 954
 955 (defmacro elmo-set-hash-val (string value hashtable)
 956   (list 'set (list 'intern string hashtable) value))
 957
 958 (defmacro elmo-clear-hash-val (string hashtable)
 959   (static-if (fboundp 'unintern)
 960       (list 'unintern string hashtable)
 961     (list 'makunbound (list 'intern string hashtable))))
 962
 963 (defmacro elmo-unintern (string)
 964   "`unintern' symbol named STRING,  When can use `unintern'.
 965 Emacs 19.28 or earlier does not have `unintern'."
 966   (static-if (fboundp 'unintern)
 967       (list 'unintern string)))
 968
 969 (defun elmo-make-hash (&optional hashsize)
 970   "Make a new hash table which have HASHSIZE size."
 971   (make-vector
 972    (if hashsize
 973        (max
 974         ;; Prime numbers as lengths tend to result in good
 975         ;; hashing; lengths one less than a power of two are
 976         ;; also good.
 977         (min
 978          (let ((i 1))
 979            (while (< (- i 1) hashsize)
 980              (setq i (* 2 i)))
 981            (- i 1))
 982          elmo-hash-maximum-size)
 983         elmo-hash-minimum-size)
 984      elmo-hash-minimum-size)
 985    0))
 986
 987 (defsubst elmo-mime-string (string)
 988   "Normalize MIME encoded STRING."
 989   (and string
 990        (elmo-set-work-buf
 991         (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 992         (setq string
 993               (encode-mime-charset-string
 994                (eword-decode-and-unfold-unstructured-field-body
 995                 string)
 996                elmo-mime-charset))
 997         (elmo-set-buffer-multibyte nil)
 998         string)))
 999
1000 (defsubst elmo-collect-field (beg end downcase-field-name)
1001   (save-excursion
1002     (save-restriction
1003       (narrow-to-region beg end)
1004       (goto-char (point-min))
1005       (let ((regexp (concat "\\(" std11-field-head-regexp "\\)[ \t]*"))
1006             dest name body)
1007         (while (re-search-forward regexp nil t)
1008           (setq name (buffer-substring-no-properties
1009                       (match-beginning 1)(1- (match-end 1))))
1010           (if downcase-field-name
1011               (setq name (downcase name)))
1012           (setq body (buffer-substring-no-properties
1013                       (match-end 0) (std11-field-end)))
1014           (or (assoc name dest)
1015               (setq dest (cons (cons name body) dest))))
1016         dest))))
1017
1018 (defsubst elmo-collect-field-from-string (string downcase-field-name)
1019   (with-temp-buffer
1020     (insert string)
1021     (goto-char (point-min))
1022     (let ((regexp (concat "\\(" std11-field-head-regexp "\\)[ \t]*"))
1023           dest name body)
1024       (while (re-search-forward regexp nil t)
1025         (setq name (buffer-substring-no-properties
1026                     (match-beginning 1)(1- (match-end 1))))
1027         (if downcase-field-name
1028             (setq name (downcase name)))
1029         (setq body (buffer-substring-no-properties
1030                     (match-end 0) (std11-field-end)))
1031         (or (assoc name dest)
1032             (setq dest (cons (cons name body) dest))))
1033       dest)))
1034
1035 (defun elmo-safe-filename (folder)
1036   (elmo-replace-in-string
1037    (elmo-replace-in-string
1038     (elmo-replace-in-string folder "/" " ")
1039     ":" "__")
1040    "|" "_or_"))
1041
1042 (defvar elmo-filename-replace-chars nil)
1043
1044 (defsubst elmo-replace-string-as-filename (msgid)
1045   "Replace string as filename."
1046   (setq msgid (elmo-replace-in-string msgid " " "  "))
1047   (if (null elmo-filename-replace-chars)
1048       (setq elmo-filename-replace-chars
1049             (regexp-quote (mapconcat
1050                            'car elmo-filename-replace-string-alist ""))))
1051   (while (string-match (concat "[" elmo-filename-replace-chars "]")
1052                        msgid)
1053     (setq msgid (concat
1054                  (substring msgid 0 (match-beginning 0))
1055                  (cdr (assoc
1056                        (substring msgid
1057                                   (match-beginning 0) (match-end 0))
1058                        elmo-filename-replace-string-alist))
1059                  (substring msgid (match-end 0)))))
1060   msgid)
1061
1062 (defsubst elmo-recover-string-from-filename (filename)
1063   "Recover string from FILENAME."
1064   (let (tmp result)
1065     (while (string-match " " filename)
1066       (setq tmp (substring filename
1067                            (match-beginning 0)
1068                            (+ (match-end 0) 1)))
1069       (if (string= tmp "  ")
1070           (setq tmp " ")
1071         (setq tmp (car (rassoc tmp
1072                                elmo-filename-replace-string-alist))))
1073       (setq result
1074             (concat result
1075                     (substring filename 0 (match-beginning 0))
1076                     tmp))
1077       (setq filename (substring filename (+ (match-end 0) 1))))
1078     (concat result filename)))
1079
1080 (defsubst elmo-copy-file (src dst &optional ok-if-already-exists)
1081   (condition-case err
1082       (elmo-add-name-to-file src dst ok-if-already-exists)
1083     (error (copy-file src dst ok-if-already-exists t))))
1084
1085 (defsubst elmo-buffer-exists-p (buffer)
1086   (if (bufferp buffer)
1087       (buffer-live-p buffer)
1088     (get-buffer buffer)))
1089
1090 (defsubst elmo-kill-buffer (buffer)
1091   (when (elmo-buffer-exists-p buffer)
1092     (kill-buffer buffer)))
1093
1094 (defun elmo-delete-if (pred lst)
1095   "Return new list contain items which don't satisfy PRED in LST."
1096   (let (result)
1097     (while lst
1098       (unless (funcall pred (car lst))
1099         (setq result (nconc result (list (car lst)))))
1100       (setq lst (cdr lst)))
1101     result))
1102
1103 (defun elmo-list-delete (list1 list2)
1104   "Delete by side effect any occurrences equal to elements of LIST1 from LIST2.
1105 Return the modified LIST2.  Deletion is done with `delete'.
1106 Write `(setq foo (elmo-list-delete bar foo))' to be sure of changing
1107 the value of `foo'."
1108   (while list1
1109     (setq list2 (delete (car list1) list2))
1110     (setq list1 (cdr list1)))
1111   list2)
1112
1113 (defun elmo-list-member (list1 list2)
1114   "If any element of LIST1 is member of LIST2, return t."
1115   (catch 'done
1116     (while list1
1117       (if (member (car list1) list2)
1118           (throw 'done t))
1119       (setq list1 (cdr list1)))))
1120
1121 (defun elmo-count-matches (regexp beg end)
1122   (let ((count 0))
1123     (save-excursion
1124       (goto-char beg)
1125       (while (re-search-forward regexp end t)
1126         (setq count (1+ count)))
1127       count)))
1128
1129 (if (fboundp 'display-error)
1130     (defalias 'elmo-display-error 'display-error)
1131   (defun elmo-display-error (error-object stream)
1132     "A tiny function to display ERROR-OBJECT to the STREAM."
1133     (let ((first t)
1134           (errobj error-object)
1135           err-mes)
1136       (while errobj
1137         (setq err-mes (concat err-mes (format
1138                                        (if (stringp (car errobj))
1139                                            "%s"
1140                                          "%S")
1141                                        (car errobj))))
1142         (setq errobj (cdr errobj))
1143         (if errobj (setq err-mes (concat err-mes (if first ": " ", "))))
1144         (setq first nil))
1145       (princ err-mes stream))))
1146
1147 (if (fboundp 'define-error)
1148     (defalias 'elmo-define-error 'define-error)
1149   (defun elmo-define-error (error doc &optional parents)
1150     (or parents
1151         (setq parents 'error))
1152     (let ((conds (get parents 'error-conditions)))
1153       (or conds
1154           (error "Not an error symbol: %s" error))
1155       (setplist error
1156                 (list 'error-message doc
1157                       'error-conditions (cons error conds))))))
1158
1159 (cond ((fboundp 'progress-feedback-with-label)
1160        (defalias 'elmo-display-progress 'progress-feedback-with-label))
1161       ((fboundp 'lprogress-display)
1162        (defalias 'elmo-display-progress 'lprogress-display))
1163       (t
1164        (defun elmo-display-progress (label format &optional value &rest args)
1165          "Print a progress message."
1166          (if (and (null format) (null args))
1167              (message nil)
1168            (apply (function message) (concat format " %d%%")
1169                   (nconc args (list value)))))))
1170
1171 (defvar elmo-progress-counter-alist nil)
1172
1173 (defmacro elmo-progress-counter-value (counter)
1174   (` (aref (cdr (, counter)) 0)))
1175
1176 (defmacro elmo-progress-counter-all-value (counter)
1177   (` (aref (cdr (, counter)) 1)))
1178
1179 (defmacro elmo-progress-counter-format (counter)
1180   (` (aref (cdr (, counter)) 2)))
1181
1182 (defmacro elmo-progress-counter-set-value (counter value)
1183   (` (aset (cdr (, counter)) 0 (, value))))
1184
1185 (defun elmo-progress-set (label all-value &optional format)
1186   (unless (assq label elmo-progress-counter-alist)
1187     (setq elmo-progress-counter-alist
1188           (cons (cons label (vector 0 all-value (or format "")))
1189                 elmo-progress-counter-alist))))
1190
1191 (defun elmo-progress-clear (label)
1192   (let ((counter (assq label elmo-progress-counter-alist)))
1193     (when counter
1194       (elmo-display-progress label
1195                              (elmo-progress-counter-format counter)
1196                              100)
1197       (setq elmo-progress-counter-alist
1198             (delq counter elmo-progress-counter-alist)))))
1199
1200 (defun elmo-progress-notify (label &optional value op &rest args)
1201   (let ((counter (assq label elmo-progress-counter-alist)))
1202     (when counter
1203       (let* ((value (or value 1))
1204              (cur-value (elmo-progress-counter-value counter))
1205              (all-value (elmo-progress-counter-all-value counter))
1206              (new-value (if (eq op 'set) value (+ cur-value value)))
1207              (cur-rate (/ (* cur-value 100) all-value))
1208              (new-rate (/ (* new-value 100) all-value)))
1209         (elmo-progress-counter-set-value counter new-value)
1210         (unless (= cur-rate new-rate)
1211           (apply 'elmo-display-progress
1212                  label
1213                  (elmo-progress-counter-format counter)
1214                  new-rate
1215                  args))
1216         (when (>= new-rate 100)
1217           (elmo-progress-clear label))))))
1218
1219 (defun elmo-time-expire (before-time diff-time)
1220   (let* ((current (current-time))
1221          (rest (when (< (nth 1 current) (nth 1 before-time))
1222                  (expt 2 16)))
1223          diff)
1224     (setq diff
1225           (list (- (+ (car current) (if rest -1 0)) (car before-time))
1226                 (- (+ (or rest 0) (nth 1 current)) (nth 1 before-time))))
1227     (and (eq (car diff) 0)
1228          (< diff-time (nth 1 diff)))))
1229
1230 (if (fboundp 'std11-fetch-field)
1231     (defalias 'elmo-field-body 'std11-fetch-field) ;;no narrow-to-region
1232   (defalias 'elmo-field-body 'std11-field-body))
1233
1234 (defun elmo-address-quote-specials (word)
1235   "Make quoted string of WORD if needed."
1236   (let ((lal (std11-lexical-analyze word)))
1237     (if (or (assq 'specials lal)
1238             (assq 'domain-literal lal))
1239         (prin1-to-string word)
1240       word)))
1241
1242 (defmacro elmo-string (string)
1243   "STRING without text property."
1244   (` (let ((obj (copy-sequence (, string))))
1245        (and obj (set-text-properties 0 (length obj) nil obj))
1246        obj)))
1247
1248 (defun elmo-flatten (list-of-list)
1249   "Flatten LIST-OF-LIST."
1250   (unless (null list-of-list)
1251     (append (if (and (car list-of-list)
1252                      (listp (car list-of-list)))
1253                 (car list-of-list)
1254               (list (car list-of-list)))
1255             (elmo-flatten (cdr list-of-list)))))
1256
1257 (defun elmo-y-or-n-p (prompt &optional auto default)
1258   "Same as `y-or-n-p'.
1259 But if optional argument AUTO is non-nil, DEFAULT is returned."
1260   (if auto
1261       default
1262     (y-or-n-p prompt)))
1263
1264 (defun elmo-string-member (string slist)
1265   "Return t if STRING is a member of the SLIST."
1266   (catch 'found
1267     (while slist
1268       (if (and (stringp (car slist))
1269                (string= string (car slist)))
1270           (throw 'found t))
1271       (setq slist (cdr slist)))))
1272
1273 (defun elmo-string-match-member (str list &optional case-ignore)
1274   (let ((case-fold-search case-ignore))
1275     (catch 'member
1276       (while list
1277         (if (string-match (car list) str)
1278             (throw 'member (car list)))
1279         (setq list (cdr list))))))
1280
1281 (defun elmo-string-matched-member (str list &optional case-ignore)
1282   (let ((case-fold-search case-ignore))
1283     (catch 'member
1284       (while list
1285         (if (string-match str (car list))
1286             (throw 'member (car list)))
1287         (setq list (cdr list))))))
1288
1289 (defsubst elmo-string-delete-match (string pos)
1290   (concat (substring string
1291                      0 (match-beginning pos))
1292           (substring string
1293                      (match-end pos)
1294                      (length string))))
1295
1296 (defun elmo-string-match-assoc (key alist &optional case-ignore)
1297   (let ((case-fold-search case-ignore)
1298         a)
1299     (catch 'loop
1300       (while alist
1301         (setq a (car alist))
1302         (if (and (consp a)
1303                  (stringp (car a))
1304                  (string-match key (car a)))
1305             (throw 'loop a))
1306         (setq alist (cdr alist))))))
1307
1308 (defun elmo-string-matched-assoc (key alist &optional case-ignore)
1309   (let ((case-fold-search case-ignore)
1310         a)
1311     (catch 'loop
1312       (while alist
1313         (setq a (car alist))
1314         (if (and (consp a)
1315                  (stringp (car a))
1316                  (string-match (car a) key))
1317             (throw 'loop a))
1318         (setq alist (cdr alist))))))
1319
1320 (defun elmo-string-assoc (key alist)
1321   (let (a)
1322     (catch 'loop
1323       (while alist
1324         (setq a (car alist))
1325         (if (and (consp a)
1326                  (stringp (car a))
1327                  (string= key (car a)))
1328             (throw 'loop a))
1329         (setq alist (cdr alist))))))
1330
1331 (defun elmo-string-assoc-all (key alist)
1332   (let (matches)
1333     (while alist
1334       (if (string= key (car (car alist)))
1335           (setq matches
1336                 (cons (car alist)
1337                       matches)))
1338       (setq alist (cdr alist)))
1339     matches))
1340
1341 (defun elmo-string-rassoc (key alist)
1342   (let (a)
1343     (catch 'loop
1344       (while alist
1345         (setq a (car alist))
1346         (if (and (consp a)
1347                  (stringp (cdr a))
1348                  (string= key (cdr a)))
1349             (throw 'loop a))
1350         (setq alist (cdr alist))))))
1351
1352 (defun elmo-string-rassoc-all (key alist)
1353   (let (matches)
1354     (while alist
1355       (if (string= key (cdr (car alist)))
1356           (setq matches
1357                 (cons (car alist)
1358                       matches)))
1359       (setq alist (cdr alist)))
1360     matches))
1361
1362 (defun elmo-expand-newtext (newtext original)
1363   (let ((len (length newtext))
1364         (pos 0)
1365         c expanded beg N did-expand)
1366     (while (< pos len)
1367       (setq beg pos)
1368       (while (and (< pos len)
1369                   (not (= (aref newtext pos) ?\\)))
1370         (setq pos (1+ pos)))
1371       (unless (= beg pos)
1372         (push (substring newtext beg pos) expanded))
1373       (when (< pos len)
1374         ;; We hit a \; expand it.
1375         (setq did-expand t
1376               pos (1+ pos)
1377               c (aref newtext pos))
1378         (if (not (or (= c ?\&)
1379                      (and (>= c ?1)
1380                           (<= c ?9))))
1381             ;; \ followed by some character we don't expand.
1382             (push (char-to-string c) expanded)
1383           ;; \& or \N
1384           (if (= c ?\&)
1385               (setq N 0)
1386             (setq N (- c ?0)))
1387           (when (match-beginning N)
1388             (push (substring original (match-beginning N) (match-end N))
1389                   expanded))))
1390       (setq pos (1+ pos)))
1391     (if did-expand
1392         (apply (function concat) (nreverse expanded))
1393       newtext)))
1394
1395 ;;; Folder parser utils.
1396 (defun elmo-parse-token (string &optional seps)
1397   "Parse atom from STRING using SEPS as a string of separator char list."
1398   (let ((len (length string))
1399         (seps (and seps (string-to-char-list seps)))
1400         (i 0)
1401         (sep nil)
1402         content c in)
1403     (if (eq len 0)
1404         (cons "" "")
1405       (while (and (< i len) (or in (null sep)))
1406         (setq c (aref string i))
1407         (cond
1408          ((and in (eq c ?\\))
1409           (setq i (1+ i)
1410                 content (cons (aref string i) content)
1411                 i (1+ i)))
1412          ((eq c ?\")
1413           (setq in (not in)
1414                 i (1+ i)))
1415          (in (setq content (cons c content)
1416                    i (1+ i)))
1417          ((memq c seps)
1418           (setq sep c))
1419          (t (setq content (cons c content)
1420                   i (1+ i)))))
1421       (if in (error "Parse error in quoted"))
1422       (cons (if (null content) "" (char-list-to-string (nreverse content)))
1423             (substring string i)))))
1424
1425 (defun elmo-parse-prefixed-element (prefix string &optional seps)
1426   (if (and (not (eq (length string) 0))
1427            (eq (aref string 0) prefix))
1428       (elmo-parse-token (substring string 1) seps)
1429     (cons "" string)))
1430
1431 ;;; Number set defined by OKAZAKI Tetsurou <okazaki@be.to>
1432 ;;
1433 ;; number          ::= [0-9]+
1434 ;; beg             ::= number
1435 ;; end             ::= number
1436 ;; number-range    ::= "(" beg " . " end ")"      ;; cons cell
1437 ;; number-set-elem ::= number / number-range
1438 ;; number-set      ::= "(" *number-set-elem ")"   ;; list
1439
1440 (defun elmo-number-set-member (number number-set)
1441   "Return non-nil if NUMBER is an element of NUMBER-SET.
1442 The value is actually the tail of NUMBER-RANGE whose car contains NUMBER."
1443   (or (memq number number-set)
1444       (let (found)
1445         (while (and number-set (not found))
1446           (if (and (consp (car number-set))
1447                    (and (<= (car (car number-set)) number)
1448                         (<= number (cdr (car number-set)))))
1449               (setq found t)
1450             (setq number-set (cdr number-set))))
1451         number-set)))
1452
1453 (defun elmo-number-set-append-list (number-set list)
1454   "Append LIST of numbers to the NUMBER-SET.
1455 NUMBER-SET is altered."
1456   (let ((appended number-set))
1457     (while list
1458       (setq appended (elmo-number-set-append appended (car list)))
1459       (setq list (cdr list)))
1460     appended))
1461
1462 (defun elmo-number-set-append (number-set number)
1463   "Append NUMBER to the NUMBER-SET.
1464 NUMBER-SET is altered."
1465   (let ((number-set-1 number-set)
1466         found elem)
1467     (while (and number-set (not found))
1468       (setq elem (car number-set))
1469       (cond
1470        ((and (consp elem)
1471              (eq (+ 1 (cdr elem)) number))
1472         (setcdr elem number)
1473         (setq found t))
1474        ((and (integerp elem)
1475              (eq (+ 1 elem) number))
1476         (setcar number-set (cons elem number))
1477         (setq found t))
1478        ((or (and (integerp elem) (eq elem number))
1479             (and (consp elem)
1480                  (<= (car elem) number)
1481                  (<= number (cdr elem))))
1482         (setq found t)))
1483       (setq number-set (cdr number-set)))
1484     (if (not found)
1485         (setq number-set-1 (nconc number-set-1 (list number))))
1486     number-set-1))
1487
1488 (defun elmo-number-set-to-number-list (number-set)
1489   "Return a number list which corresponds to NUMBER-SET."
1490   (let (number-list elem i)
1491     (while number-set
1492       (setq elem (car number-set))
1493       (cond
1494        ((consp elem)
1495         (setq i (car elem))
1496         (while (<= i (cdr elem))
1497           (setq number-list (cons i number-list))
1498           (incf i)))
1499        ((integerp elem)
1500         (setq number-list (cons elem number-list))))
1501       (setq number-set (cdr number-set)))
1502     (nreverse number-list)))
1503
1504 (defcustom elmo-list-subdirectories-ignore-regexp "^\\(\\.\\.?\\|[0-9]+\\)$"
1505   "*Regexp to filter subfolders."
1506   :type 'regexp
1507   :group 'elmo)
1508
1509 (defun elmo-list-subdirectories-1 (basedir curdir one-level)
1510   (let ((root (zerop (length curdir)))
1511         (w32-get-true-file-link-count t) ; for Meadow
1512         attr dirs dir)
1513     (catch 'done
1514       (dolist (file (directory-files (setq dir (expand-file-name curdir basedir))))
1515         (when (and (not (string-match
1516                          elmo-list-subdirectories-ignore-regexp
1517                          file))
1518                    (car (setq attr (file-attributes
1519                                     (expand-file-name file dir)))))
1520           (when (eq one-level 'check) (throw 'done t))
1521           (let ((relpath
1522                  (concat curdir (and (not root) elmo-path-sep) file))
1523                 subdirs)
1524             (setq dirs (nconc dirs
1525                               (if (if elmo-have-link-count (< 2 (nth 1 attr))
1526                                     (setq subdirs
1527                                           (elmo-list-subdirectories-1
1528                                            basedir
1529                                            relpath
1530                                            (if one-level 'check))))
1531                                   (if one-level
1532                                       (list (list relpath))
1533                                     (cons relpath
1534                                           (or subdirs
1535                                               (elmo-list-subdirectories-1
1536                                                basedir
1537                                                relpath
1538                                                nil))))
1539                                 (list relpath)))))))
1540       dirs)))
1541
1542 (defun elmo-list-subdirectories (directory file one-level)
1543   (let ((subdirs (elmo-list-subdirectories-1 directory file one-level)))
1544     (if (zerop (length file))
1545         subdirs
1546       (cons file subdirs))))
1547
1548 (defun elmo-mapcar-list-of-list (func list-of-list)
1549   (mapcar
1550    (lambda (x)
1551      (cond ((listp x) (elmo-mapcar-list-of-list func x))
1552            (t (funcall func x))))
1553    list-of-list))
1554
1555 (defun elmo-parse (string regexp &optional matchn)
1556   (or matchn (setq matchn 1))
1557   (let (list)
1558     (store-match-data nil)
1559     (while (string-match regexp string (match-end 0))
1560       (setq list (cons (substring string (match-beginning matchn)
1561                                   (match-end matchn)) list)))
1562     (nreverse list)))
1563
1564 ;;; File cache.
1565 (defmacro elmo-make-file-cache (path status)
1566   "PATH is the cache file name.
1567 STATUS is one of 'section, 'entire or nil.
1568  nil means no cache exists.
1569 'section means partial section cache exists.
1570 'entire means entire cache exists.
1571 If the cache is partial file-cache, TYPE is 'partial."
1572   (` (cons (, path) (, status))))
1573
1574 (defmacro elmo-file-cache-path (file-cache)
1575   "Returns the file path of the FILE-CACHE."
1576   (` (car (, file-cache))))
1577
1578 (defmacro elmo-file-cache-status (file-cache)
1579   "Returns the status of the FILE-CACHE."
1580   (` (cdr (, file-cache))))
1581
1582 (defsubst elmo-cache-to-msgid (filename)
1583   (concat "<" (elmo-recover-string-from-filename filename) ">"))
1584
1585 (defsubst elmo-cache-get-path-subr (msgid)
1586   (let ((chars '(?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9 ?A ?B ?C ?D ?E ?F))
1587         (clist (string-to-char-list msgid))
1588         (sum 0))
1589     (while clist
1590       (setq sum (+ sum (car clist)))
1591       (setq clist (cdr clist)))
1592     (format "%c%c"
1593             (nth (% (/ sum 16) 2) chars)
1594             (nth (% sum 16) chars))))
1595
1596 (defun elmo-file-cache-get-path (msgid &optional section)
1597   "Get cache path for MSGID.
1598 If optional argument SECTION is specified, partial cache path is returned."
1599   (if (setq msgid (elmo-msgid-to-cache msgid))
1600       (expand-file-name
1601        (if section
1602            (format "%s/%s/%s/%s"
1603                    elmo-cache-directory
1604                    (elmo-cache-get-path-subr msgid)
1605                    msgid
1606                    section)
1607          (format "%s/%s/%s"
1608                  elmo-cache-directory
1609                  (elmo-cache-get-path-subr msgid)
1610                  msgid)))))
1611
1612 (defmacro elmo-file-cache-expand-path (path section)
1613   "Return file name for the file-cache corresponds to the section.
1614 PATH is the file-cache path.
1615 SECTION is the section string."
1616   (` (expand-file-name (or (, section) "") (, path))))
1617
1618 (defun elmo-file-cache-delete (path)
1619   "Delete a cache on PATH."
1620   (when (file-exists-p path)
1621     (if (file-directory-p path)
1622         (progn
1623           (dolist (file (directory-files path t "^[^\\.]"))
1624             (delete-file file))
1625           (delete-directory path))
1626       (delete-file path))
1627     t))
1628
1629 (defun elmo-file-cache-exists-p (msgid)
1630   "Returns 'section or 'entire if a cache which corresponds to MSGID exists."
1631   (elmo-file-cache-status (elmo-file-cache-get msgid)))
1632
1633 (defun elmo-file-cache-save (cache-path section)
1634   "Save current buffer as cache on PATH.
1635 Return t if cache is saved successfully."
1636   (condition-case nil
1637       (let ((path (if section (expand-file-name section cache-path)
1638                     cache-path))
1639             files dir)
1640         (if (and (null section)
1641                  (file-directory-p path))
1642             (progn
1643               (setq files (directory-files path t "^[^\\.]"))
1644               (while files
1645                 (delete-file (car files))
1646                 (setq files (cdr files)))
1647               (delete-directory path))
1648           (if (and section
1649                    (not (file-directory-p cache-path)))
1650               (delete-file cache-path)))
1651         (when path
1652           (setq dir (directory-file-name (file-name-directory path)))
1653           (if (not (file-exists-p dir))
1654               (elmo-make-directory dir))
1655           (write-region-as-binary (point-min) (point-max)
1656                                   path nil 'no-msg)
1657           t))
1658     ;; ignore error
1659     (error)))
1660
1661 (defun elmo-file-cache-load (cache-path section)
1662   "Load cache on PATH into the current buffer.
1663 Return t if cache is loaded successfully."
1664   (condition-case nil
1665       (let (cache-file)
1666         (when (and cache-path
1667                    (if (elmo-cache-path-section-p cache-path)
1668                        section
1669                      (null section))
1670                    (setq cache-file (elmo-file-cache-expand-path
1671                                      cache-path
1672                                      section))
1673                    (file-exists-p cache-file))
1674           (insert-file-contents-as-binary cache-file)
1675           t))
1676     ;; igore error
1677     (error)))
1678
1679 (defun elmo-cache-path-section-p (path)
1680   "Return non-nil when PATH is `section' cache path."
1681   (file-directory-p path))
1682
1683 (defun elmo-file-cache-get (msgid &optional section)
1684   "Returns the current file-cache object associated with MSGID.
1685 MSGID is the message-id of the message.
1686 If optional argument SECTION is specified, get partial file-cache object
1687 associated with SECTION."
1688   (if msgid
1689       (let ((path (elmo-cache-get-path msgid)))
1690         (if (and path (file-exists-p path))
1691             (if (elmo-cache-path-section-p path)
1692                 (if section
1693                     (if (file-exists-p (setq path (expand-file-name
1694                                                    section path)))
1695                         (cons path 'section))
1696                   ;; section is not specified but sectional.
1697                   (cons path 'section))
1698               ;; not directory.
1699               (unless section
1700                 (cons path 'entire)))
1701           ;; no cache.
1702           (cons path nil)))))
1703
1704 ;;;
1705 ;; Expire cache.
1706
1707 (defun elmo-cache-expire ()
1708   (interactive)
1709   (let* ((completion-ignore-case t)
1710          (method (completing-read (format "Expire by (%s): "
1711                                           elmo-cache-expire-default-method)
1712                                   '(("size" . "size")
1713                                     ("age" . "age")))))
1714     (if (string= method "")
1715         (setq method elmo-cache-expire-default-method))
1716     (funcall (intern (concat "elmo-cache-expire-by-" method)))))
1717
1718 (defun elmo-read-float-value-from-minibuffer (prompt &optional initial)
1719   (let ((str (read-from-minibuffer prompt initial)))
1720     (cond
1721      ((string-match "[0-9]*\\.[0-9]+" str)
1722       (string-to-number str))
1723      ((string-match "[0-9]+" str)
1724       (string-to-number (concat str ".0")))
1725      (t (error "%s is not number" str)))))
1726
1727 (defun elmo-cache-expire-by-size (&optional kbytes)
1728   "Expire cache file by size.
1729 If KBYTES is kilo bytes (This value must be float)."
1730   (interactive)
1731   (let ((size (or kbytes
1732                   (and (interactive-p)
1733                        (elmo-read-float-value-from-minibuffer
1734                         "Enter cache disk size (Kbytes): "
1735                         (number-to-string
1736                          (if (integerp elmo-cache-expire-default-size)
1737                              (float elmo-cache-expire-default-size)
1738                            elmo-cache-expire-default-size))))
1739                   (if (integerp elmo-cache-expire-default-size)
1740                       (float elmo-cache-expire-default-size))))
1741         (count 0)
1742         (Kbytes 1024)
1743         total beginning)
1744     (message "Checking disk usage...")
1745     (setq total (/ (elmo-disk-usage
1746                     elmo-cache-directory) Kbytes))
1747     (setq beginning total)
1748     (message "Checking disk usage...done")
1749     (let ((cfl (elmo-cache-get-sorted-cache-file-list))
1750           (deleted 0)
1751           oldest
1752           cur-size cur-file)
1753       (while (and (<= size total)
1754                   (setq oldest (elmo-cache-get-oldest-cache-file-entity cfl)))
1755         (setq cur-file (expand-file-name (car (cdr oldest)) (car oldest)))
1756         (setq cur-size (/ (elmo-disk-usage cur-file) Kbytes))
1757         (when (elmo-file-cache-delete cur-file)
1758           (setq count (+ count 1))
1759           (message "%d cache(s) are expired." count))
1760         (setq deleted (+ deleted cur-size))
1761         (setq total (- total cur-size)))
1762       (message "%d cache(s) are expired from disk (%d Kbytes/%d Kbytes)."
1763                count deleted beginning))))
1764
1765 (defun elmo-cache-make-file-entity (filename path)
1766   (cons filename (elmo-get-last-accessed-time filename path)))
1767
1768 (defun elmo-cache-get-oldest-cache-file-entity (cache-file-list)
1769   (let ((cfl cache-file-list)
1770         flist firsts oldest-entity wonlist)
1771     (while cfl
1772       (setq flist (cdr (car cfl)))
1773       (setq firsts (append firsts (list
1774                                    (cons (car (car cfl))
1775                                          (car flist)))))
1776       (setq cfl (cdr cfl)))
1777 ;;; (prin1 firsts)
1778     (while firsts
1779       (if (and (not oldest-entity)
1780                (cdr (cdr (car firsts))))
1781           (setq oldest-entity (car firsts)))
1782       (if (and (cdr (cdr (car firsts)))
1783                (cdr (cdr oldest-entity))
1784                (> (cdr (cdr oldest-entity)) (cdr (cdr (car firsts)))))
1785           (setq oldest-entity (car firsts)))
1786       (setq firsts (cdr firsts)))
1787     (setq wonlist (assoc (car oldest-entity) cache-file-list))
1788     (and wonlist
1789          (setcdr wonlist (delete (car (cdr wonlist)) (cdr wonlist))))
1790     oldest-entity))
1791
1792 (defun elmo-cache-get-sorted-cache-file-list ()
1793   (let ((dirs (directory-files
1794                elmo-cache-directory
1795                t "^[^\\.]"))
1796         (i 0) num
1797         elist
1798         ret-val)
1799     (setq num (length dirs))
1800     (message "Collecting cache info...")
1801     (while dirs
1802       (setq elist (mapcar (lambda (x)
1803                             (elmo-cache-make-file-entity x (car dirs)))
1804                           (directory-files (car dirs) nil "^[^\\.]")))
1805       (setq ret-val (append ret-val
1806                             (list (cons
1807                                    (car dirs)
1808                                    (sort
1809                                     elist
1810                                     (lambda (x y)
1811                                       (< (cdr x)
1812                                          (cdr y))))))))
1813       (when (> num elmo-display-progress-threshold)
1814         (setq i (+ i 1))
1815         (elmo-display-progress
1816          'elmo-cache-get-sorted-cache-file-list "Collecting cache info..."
1817          (/ (* i 100) num)))
1818       (setq dirs (cdr dirs)))
1819     (message "Collecting cache info...done")
1820     ret-val))
1821
1822 (defun elmo-cache-expire-by-age (&optional days)
1823   (let ((age (or (and days (int-to-string days))
1824                  (and (interactive-p)
1825                       (read-from-minibuffer
1826                        (format "Enter days (%s): "
1827                                elmo-cache-expire-default-age)))
1828                  (int-to-string elmo-cache-expire-default-age)))
1829         (dirs (directory-files
1830                elmo-cache-directory
1831                t "^[^\\.]"))
1832         (count 0)
1833         curtime)
1834     (if (string= age "")
1835         (setq age elmo-cache-expire-default-age)
1836       (setq age (string-to-int age)))
1837     (setq curtime (current-time))
1838     (setq curtime (+ (* (nth 0 curtime)
1839                         (float 65536)) (nth 1 curtime)))
1840     (while dirs
1841       (let ((files (directory-files (car dirs) t "^[^\\.]"))
1842             (limit-age (* age 86400)))
1843         (while files
1844           (when (> (- curtime (elmo-get-last-accessed-time (car files)))
1845                    limit-age)
1846             (when (elmo-file-cache-delete (car files))
1847               (setq count (+ 1 count))
1848               (message "%d cache file(s) are expired." count)))
1849           (setq files (cdr files))))
1850       (setq dirs (cdr dirs)))))
1851
1852 ;;;
1853 ;; msgid to path.
1854 (defun elmo-msgid-to-cache (msgid)
1855   (save-match-data
1856     (when (and msgid
1857                (string-match "<\\(.+\\)>$" msgid))
1858       (elmo-replace-string-as-filename (elmo-match-string 1 msgid)))))
1859
1860 (defun elmo-cache-get-path (msgid &optional folder number)
1861   "Get path for cache file associated with MSGID, FOLDER, and NUMBER."
1862   (if (setq msgid (elmo-msgid-to-cache msgid))
1863       (expand-file-name
1864        (expand-file-name
1865         (if folder
1866             (format "%s/%s/%s@%s"
1867                     (elmo-cache-get-path-subr msgid)
1868                     msgid
1869                     (or number "")
1870                     (elmo-safe-filename folder))
1871           (format "%s/%s"
1872                   (elmo-cache-get-path-subr msgid)
1873                   msgid))
1874         elmo-cache-directory))))
1875
1876 ;;;
1877 ;; Warnings.
1878
1879 (defconst elmo-warning-buffer-name "*elmo warning*")
1880
1881 (defun elmo-warning (&rest args)
1882   "Display a warning, making warning message by passing all args to `insert'."
1883   (with-current-buffer (get-buffer-create elmo-warning-buffer-name)
1884     (goto-char (point-max))
1885     (apply 'insert (append args '("\n")))
1886     (recenter 1))
1887   (display-buffer elmo-warning-buffer-name))
1888
1889 (defvar elmo-obsolete-variable-alist nil)
1890
1891 (defcustom elmo-obsolete-variable-show-warnings t
1892   "Show warning window if obsolete variable is treated."
1893   :type 'boolean
1894   :group 'elmo)
1895
1896 (defun elmo-define-obsolete-variable (obsolete var)
1897   "Define obsolete variable.
1898 OBSOLETE is a symbol for obsolete variable.
1899 VAR is a symbol for new variable.
1900 Definition is stored in `elmo-obsolete-variable-alist'."
1901   (let ((pair (assq var elmo-obsolete-variable-alist)))
1902     (if pair
1903         (setcdr pair obsolete)
1904       (setq elmo-obsolete-variable-alist
1905             (cons (cons var obsolete)
1906                   elmo-obsolete-variable-alist)))))
1907
1908 (defun elmo-resque-obsolete-variable (obsolete var)
1909   "Resque obsolete variable OBSOLETE as VAR.
1910 If `elmo-obsolete-variable-show-warnings' is non-nil, show warning message."
1911   (when (boundp obsolete)
1912     (static-if (and (fboundp 'defvaralias)
1913                     (subrp (symbol-function 'defvaralias)))
1914         (defvaralias var obsolete)
1915       (set var (symbol-value obsolete)))
1916     (if elmo-obsolete-variable-show-warnings
1917         (elmo-warning (format "%s is obsolete. Use %s instead."
1918                               (symbol-name obsolete)
1919                               (symbol-name var))))))
1920
1921 (defun elmo-resque-obsolete-variables (&optional alist)
1922   "Resque obsolete variables in ALIST.
1923 ALIST is a list of cons cell of
1924 \(OBSOLETE-VARIABLE-SYMBOL . NEW-VARIABLE-SYMBOL\).
1925 If ALIST is nil, `elmo-obsolete-variable-alist' is used."
1926   (dolist (pair elmo-obsolete-variable-alist)
1927     (elmo-resque-obsolete-variable (cdr pair)
1928                                    (car pair))))
1929
1930 ;;; Queue.
1931 (defvar elmo-dop-queue-filename "queue"
1932   "*Disconnected operation queue is saved in this file.")
1933
1934 (defun elmo-dop-queue-load ()
1935   (setq elmo-dop-queue
1936         (elmo-object-load
1937          (expand-file-name elmo-dop-queue-filename
1938                            elmo-msgdb-directory))))
1939
1940 (defun elmo-dop-queue-save ()
1941   (elmo-object-save
1942    (expand-file-name elmo-dop-queue-filename
1943                      elmo-msgdb-directory)
1944    elmo-dop-queue))
1945
1946 (require 'product)
1947 (product-provide (provide 'elmo-util) (require 'elmo-version))
1948
1949 ;;; elmo-util.el ends here