elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type '(choice (integer :tag "Threshold (bytes)")
  50                  (const :tag "No limitation" nil))
  51   :group 'elmo)
  52
  53 (defcustom elmo-message-fetch-confirm t
  54   "If non-nil, confirm fetching if message size is larger than
  55 `elmo-message-fetch-threshold'.
  56 Otherwise, entire fetching of the message is aborted without confirmation."
  57   :type 'boolean
  58   :group 'elmo)
  59
  60 (defcustom elmo-folder-update-threshold 500
  61   "Update threshold."
  62   :type 'integer
  63   :group 'elmo)
  64
  65 (defcustom elmo-folder-update-confirm t
  66   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  67   :type 'boolean
  68   :group 'elmo)
  69
  70 (defvar elmo-message-displaying nil
  71   "A global switch to indicate message is displaying or not.")
  72
  73 ;;; internal
  74 (defvar elmo-folder-type-alist nil)
  75
  76 (defvar elmo-newsgroups-hashtb nil)
  77
  78 (elmo-define-error 'elmo-error "Error" 'error)
  79 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  80 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  81 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  82
  83 ;; autoloads
  84 (eval-and-compile
  85   (autoload 'elmo-dop-queue-flush "elmo-dop")
  86   (autoload 'elmo-nntp-post "elmo-nntp")
  87   (autoload 'elmo-global-flag-p "elmo-flag")
  88   (autoload 'elmo-global-flag-detach "elmo-flag")
  89   (autoload 'elmo-global-flag-detach-messages "elmo-flag")
  90   (autoload 'elmo-global-flag-set "elmo-flag")
  91   (autoload 'elmo-get-global-flags "elmo-flag")
  92   (autoload 'elmo-global-mark-migrate "elmo-flag")
  93   (autoload 'elmo-folder-list-global-flag-messages "elmo-flag"))
  94
  95 (defun elmo-define-folder (prefix backend)
  96   "Define a folder.
  97 If a folder name begins with PREFIX, use BACKEND."
  98   (let ((pair (assq prefix elmo-folder-type-alist)))
  99     (if pair
 100         (progn
 101           (setcar pair prefix)
 102           (setcdr pair backend))
 103       (setq elmo-folder-type-alist (cons (cons prefix backend)
 104                                          elmo-folder-type-alist)))))
 105
 106 (defmacro elmo-folder-type (name)
 107   "Get folder type from NAME string."
 108   `(and (stringp ,name)
 109         (cdr (assoc (string-to-char ,name) elmo-folder-type-alist))))
 110
 111 ;;; ELMO folder
 112 ;; A elmo folder provides uniformed (orchestrated) access
 113 ;; to the internet messages.
 114 (eval-and-compile
 115   (luna-define-class elmo-folder () (type   ; folder type symbol.
 116                                      name   ; orignal folder name string.
 117                                      prefix ; prefix for folder name
 118                                      path   ; directory path for msgdb.
 119                                      msgdb  ; msgdb (may be nil).
 120                                      killed-list  ; killed list.
 121                                      flag-table   ; flag table.
 122                                      persistent   ; non-nil if persistent.
 123                                      process-duplicates  ; read or hide
 124                                      biff   ; folder for biff
 125                                      ))
 126   (luna-define-internal-accessors 'elmo-folder))
 127
 128 (luna-define-generic elmo-folder-initialize (folder name)
 129   ;; Initialize a FOLDER structure with NAME."
 130   )
 131
 132 (defmacro elmo-folder-send (folder message &rest args)
 133   "Let FOLDER receive the MESSAGE with ARGS."
 134   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 135
 136 ;;;###autoload
 137 (defun elmo-make-folder (name &optional non-persistent)
 138   "Make an ELMO folder structure specified by NAME.
 139 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 140   (let ((type (elmo-folder-type name))
 141         prefix split class folder original)
 142     (setq original (elmo-string name))
 143     (if type
 144         (progn
 145           (setq prefix (substring name 0 1))
 146           (setq name (substring name 1)))
 147       (setq type (intern (car (setq split (split-string name ":")))))
 148       (if (>= (length split) 2)
 149           (setq name (substring name (+ 1 (length (car split)))))
 150         (error "Error in folder name `%s'" original))
 151       (setq prefix (concat (car split) ":")))
 152     (setq class (format "elmo-%s" (symbol-name type)))
 153     (require (intern class))
 154     (setq folder (luna-make-entity (intern (concat class "-folder"))
 155                                    :type type
 156                                    :prefix prefix
 157                                    :name original
 158                                    :persistent (not non-persistent)))
 159     (save-match-data
 160       (elmo-folder-send folder 'elmo-folder-initialize name))))
 161
 162 ;; Note that this function is for internal use only.
 163 (luna-define-generic elmo-folder-msgdb (folder)
 164   "Return the msgdb of FOLDER (on-demand loading).
 165 \(For internal use only.\)")
 166
 167 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 168   (or (elmo-folder-msgdb-internal folder)
 169       (elmo-folder-set-msgdb-internal folder
 170                                       (elmo-folder-msgdb-load folder))))
 171
 172 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 173   "Open and setup (load saved status) FOLDER.
 174 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 175 \(otherwise, msgdb is loaded on-demand)")
 176
 177 (luna-define-generic elmo-folder-open-internal (folder)
 178   "Open FOLDER (without loading saved folder status).")
 179
 180 (luna-define-generic elmo-folder-check (folder)
 181   "Check the FOLDER to obtain newest information at the next list operation.")
 182
 183 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 184   "Clear FOLDER to the initial state.
 185 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 186
 187 (luna-define-generic elmo-folder-commit (folder)
 188   "Save current status of FOLDER.")
 189
 190 (luna-define-generic elmo-folder-close (folder)
 191   "Close, save and clearnup FOLDER.")
 192
 193 (luna-define-generic elmo-folder-close-internal (folder)
 194   "Close FOLDER (without saving folder status).")
 195
 196 (luna-define-generic elmo-folder-plugged-p (folder)
 197   "Returns t if FOLDER is plugged.")
 198
 199 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 200   "Set FOLDER as plugged.")
 201
 202 (luna-define-generic elmo-net-port-info (folder)
 203   "Get port information of FOLDER.")
 204
 205 (luna-define-generic elmo-folder-use-flag-p (folder)
 206   "Returns t if FOLDER treats unread/important flag itself.")
 207
 208 (luna-define-generic elmo-folder-diff (folder)
 209   "Get diff of FOLDER.
 210 Return value is cons cell or list:
 211  - a cons cell (new . all)
 212  - a list (new unread all)")
 213
 214 (luna-define-generic elmo-folder-status (folder)
 215   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 216
 217 (luna-define-generic elmo-folder-reserve-status-p (folder)
 218   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 219
 220 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 221                                                        in-msgdb)
 222   "Return a list of message numbers contained in FOLDER.
 223 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 224 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 225
 226 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 227                                                &optional visible-only in-msgdb)
 228   (let ((list (if in-msgdb
 229                   t
 230                 (elmo-folder-list-messages-internal folder visible-only)))
 231         (killed-list (elmo-folder-killed-list-internal folder)))
 232     (unless (listp list)
 233       ;; Use current list.
 234       (setq list (elmo-msgdb-list-messages (elmo-folder-msgdb folder))))
 235     (if visible-only
 236         (elmo-living-messages list killed-list)
 237       (if (and in-msgdb killed-list)
 238           (elmo-uniq-sorted-list
 239            (sort (nconc (elmo-number-set-to-number-list killed-list) list) #'<)
 240            #'eq)
 241         list))))
 242
 243 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 244                                                                 visible-only)
 245   ;; Return a list of message numbers contained in FOLDER.
 246   ;; Return t if the message list is not available.
 247   )
 248
 249 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 250   "List messages in the FOLDER with FLAG.
 251 FLAG is a symbol which is one of the following:
 252   `new'        (new messages)
 253   `unread'     (unread messages (new messages are included))
 254   `answered'   (answered or forwarded)
 255   `important'  (marked as important)
 256 'sugar' flags:
 257   `read'       (not unread)
 258   `digest'     (unread + important + other flags)
 259   `any'        (digest + answered + other flags)
 260 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 261
 262 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 263                                               &optional in-msgdb)
 264   (let ((msgs (if in-msgdb
 265                   t
 266                 (elmo-folder-list-flagged-internal folder flag))))
 267     (unless (listp msgs)
 268       (setq msgs (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag)))
 269     (if in-msgdb
 270         msgs
 271       (elmo-uniq-list
 272        (nconc (elmo-folder-list-global-flag-messages folder flag) msgs)
 273        #'delq))))
 274
 275 (luna-define-generic elmo-folder-list-flagged-internal (folder flag)
 276   "Return a list of message in the FOLDER with FLAG.
 277 Return t if the message list is not available.")
 278
 279 (luna-define-method elmo-folder-list-flagged-internal ((folder elmo-folder)
 280                                                        flag)
 281   t)
 282
 283 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 284   "Returns a list of subfolders contained in FOLDER.
 285 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 286 \(a folder which have children is returned as a list\)
 287 Otherwise, all descendent folders are returned.")
 288
 289 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 290   "Return non-nil when FOLDER has subfolders.")
 291
 292 (luna-define-generic elmo-folder-exists-p (folder)
 293   "Returns non-nil when FOLDER exists.")
 294
 295 (luna-define-generic elmo-folder-creatable-p (folder)
 296   "Returns non-nil when FOLDER is creatable.")
 297
 298 (luna-define-generic elmo-folder-writable-p (folder)
 299   "Returns non-nil when FOLDER is writable.")
 300
 301 (luna-define-generic elmo-folder-persistent-p (folder)
 302   "Return non-nil when FOLDER is persistent.")
 303
 304 (luna-define-generic elmo-folder-create (folder)
 305   "Create a FOLDER.")
 306
 307 (luna-define-generic elmo-message-deletable-p (folder number)
 308   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 309
 310 (luna-define-generic elmo-folder-delete (folder)
 311   "Delete FOLDER completely.")
 312
 313 (luna-define-generic elmo-folder-rename (folder new-name)
 314   "Rename FOLDER to NEW-NAME (string).")
 315
 316 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 317   "Delete messages.
 318 FOLDER is the ELMO folder structure.
 319 NUMBERS is a list of message numbers to be deleted.
 320 It is not recommended to use this function other than internal use.
 321 Use `elmo-folder-move-messages' with dst-folder 'null instead.")
 322
 323 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 324   "Search and return list of message numbers.
 325 FOLDER is the ELMO folder structure.
 326 CONDITION is a condition structure for searching.
 327 If optional argument NUMBERS is specified and is a list of message numbers,
 328 messages are searched from the list.")
 329
 330 (luna-define-generic elmo-message-match-condition (folder number
 331                                                           condition
 332                                                           numbers)
 333   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 334 CONDITION is a condition structure for testing.
 335 NUMBERS is a list of message numbers,
 336 use to be test for \"last\" and \"first\" predicates.")
 337
 338 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 339   "Create a message database (implemented in each backends).
 340 FOLDER is the ELMO folder structure.
 341 NUMBERS is a list of message numbers to create msgdb.
 342 FLAG-TABLE is a hashtable of message-id and flag.")
 343
 344 (luna-define-generic elmo-folder-set-flag (folder numbers flag
 345                                                   &optional is-local)
 346   "Set messages flag.
 347 FOLDER is a ELMO folder structure.
 348 NUMBERS is a list of message number to set flag.
 349
 350 FLAG is a symbol which is one of the following:
 351   `unread'    (set the message as unread)
 352   `answered'  (set the message as answered)
 353   `important' (set the message as important)
 354 'sugar' flag:
 355   `read'      (remove new and unread flags)
 356 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 357
 358 (luna-define-generic elmo-folder-unset-flag (folder numbers flag
 359                                                     &optional is-local)
 360   "Unset messages flag.
 361 FOLDER is a ELMO folder structure.
 362 NUMBERS is a list of message number to unset flag.
 363
 364 FLAG is a symbol which is one of the following:
 365   `unread'    (remove unread and new flag)
 366   `answered'  (remove answered flag)
 367   `important' (remove important flag)
 368 'sugar' flag:
 369   `read'      (set unread flag)
 370   `all'       (remove all flags)
 371 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 372
 373 (luna-define-generic elmo-folder-next-message-number (folder)
 374   "The next message number that will be assigned to a new message.
 375 FOLDER is the ELMO folder structure.")
 376
 377 (luna-define-generic elmo-folder-append-buffer (folder &optional flags
 378                                                        number)
 379   "Append current buffer as a new message.
 380 FOLDER is the destination folder (ELMO folder structure).
 381 FLAGS is the status of appended message (list of symbols).
 382 If it is nil, it is not that there is no flag and what is not defined is meant.
 383 If optional argument NUMBER is specified, the new message number is set
 384 \(if possible\).
 385 Return nil on failure.")
 386
 387 (luna-define-generic elmo-folder-append-messages (folder
 388                                                   src-folder
 389                                                   numbers
 390                                                   &optional
 391                                                   same-number)
 392   "Append messages from folder.
 393 FOLDER is the ELMO folder structure.
 394 Caller should make sure FOLDER is `writable'.
 395 \(Can be checked with `elmo-folder-writable-p'\).
 396 SRC-FOLDER is the source ELMO folder structure.
 397 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 398 If second optional argument SAME-NUMBER is specified,
 399 message number is preserved \(if possible\).
 400 Returns a list of message numbers successfully appended.")
 401
 402 (luna-define-generic elmo-folder-pack-numbers (folder)
 403   "Pack message numbers of FOLDER.")
 404
 405 (luna-define-generic elmo-folder-update-number (folder)
 406   "Update number of FOLDER.")
 407
 408 (luna-define-generic elmo-folder-diff-async (folder)
 409   "Get diff of FOLDER asynchronously.")
 410
 411 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 412   "Expand path for FOLDER.")
 413
 414 (luna-define-generic elmo-folder-get-primitive-list (folder)
 415   "Get primitive folder structure list contained in FOLDER.")
 416
 417 (luna-define-generic elmo-folder-contains-type (folder type)
 418   "Returns t if FOLDER contains TYPE.")
 419
 420 (luna-define-generic elmo-folder-local-p (folder)
 421   "Returns t if FOLDER is local.")
 422
 423 (luna-define-generic elmo-folder-message-file-p (folder)
 424   "Returns t if all messages in the FOLDER are files.")
 425
 426 ;;; Message methods.
 427 (luna-define-generic elmo-message-use-cache-p (folder number)
 428   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 429
 430 (luna-define-generic elmo-message-file-name (folder number)
 431   "Return the file name of a message specified by FOLDER and NUMBER.")
 432
 433 ;;; For archive
 434
 435 ;;; Use original file
 436 (luna-define-generic elmo-folder-message-file-number-p (folder)
 437   "Return t if the file name in the FOLDER is the message number.")
 438
 439 (luna-define-generic elmo-folder-message-file-directory (folder)
 440   "Return the directory of the message files of FOLDER.")
 441
 442 ;;; Use temporary file
 443 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 444   "Return t if the messages in the FOLDER makes local temporary file.")
 445
 446 (luna-define-generic elmo-folder-message-make-temp-files (folder
 447                                                           numbers
 448                                                           &optional
 449                                                           start-number)
 450   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 451 If START-NUMBER is specified, temporary files begin from the number.
 452 Otherwise, same number is used for temporary files.
 453 Return newly created temporary directory name which contains temporary files.")
 454
 455 (luna-define-generic elmo-message-file-p (folder number)
 456   "Return t if message in the FOLDER with NUMBER is a file.")
 457
 458 (luna-define-generic elmo-message-flags (folder number &optional msgid)
 459   "Return a list of flags.
 460 FOLDER is a ELMO folder structure.
 461 NUMBER is a number of the message.
 462 If optional argument MSGID is specified,
 463 the message with NUMBER checks whether it has MSGID.")
 464
 465 (luna-define-method elmo-message-flags ((folder elmo-folder) number
 466                                         &optional msgid)
 467   (if msgid
 468       (let ((this-id (elmo-message-field folder number 'message-id)))
 469         (and this-id
 470              (string= this-id msgid)
 471              (or (elmo-msgdb-flags (elmo-folder-msgdb folder) number)
 472                  '(read))))
 473     (elmo-msgdb-flags (elmo-folder-msgdb folder) number)))
 474
 475 (defsubst elmo-message-flagged-p (folder number flag)
 476   "Return non-nil if the message is set FLAG.
 477 FOLDER is a ELMO folder structure.
 478 NUMBER is a message number to test."
 479   (let ((cur-flags (elmo-message-flags folder number)))
 480     (case flag
 481       (read
 482        (not (memq 'unread cur-flags)))
 483       (t
 484        (memq flag cur-flags)))))
 485
 486 (luna-define-generic elmo-find-fetch-strategy
 487   (folder entity &optional ignore-cache)
 488 ;; Returns the message fetching strategy suitable for the message.
 489 ;; FOLDER is the ELMO folder structure.
 490 ;; ENTITY is the overview entity of the message in the folder.
 491 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 492 ;; Returned value is a elmo-fetch-strategy object.
 493 ;; If return value is nil, message should not be nil.
 494   )
 495
 496 (defmacro elmo-make-fetch-strategy (entireness
 497                                     &optional
 498                                     use-cache
 499                                     save-cache
 500                                     cache-path)
 501 ;; Make elmo-message-fetching strategy.
 502 ;; ENTIRENESS is 'entire or 'section.
 503 ;; 'entire means fetch message entirely at once.
 504 ;; 'section means fetch message section by section.
 505 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 506 ;; existing cache is thrown away.
 507 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 508 ;; CACHE-PATH is the cache path to be used as a message cache file.
 509   (` (vector (, entireness)
 510              (, use-cache) (, save-cache) (, cache-path))))
 511
 512 (defmacro elmo-fetch-strategy-entireness (strategy)
 513   ;; Return entireness of STRATEGY.
 514   (` (aref (, strategy) 0)))
 515
 516 (defmacro elmo-fetch-strategy-use-cache (strategy)
 517   ;; Return use-cache of STRATEGY.
 518   (` (aref (, strategy) 1)))
 519
 520 (defmacro elmo-fetch-strategy-save-cache (strategy)
 521   ;; Return save-cache of STRATEGY.
 522   (` (aref (, strategy) 2)))
 523
 524 (defmacro elmo-fetch-strategy-cache-path (strategy)
 525   ;;  Return cache-path of STRATEGY.
 526   (` (aref (, strategy) 3)))
 527
 528 (luna-define-method elmo-find-fetch-strategy
 529   ((folder elmo-folder) entity &optional ignore-cache)
 530   (let (cache-file size message-id number)
 531     (setq size (elmo-message-entity-field entity 'size))
 532     (setq message-id (elmo-message-entity-field entity 'message-id))
 533     (setq number (elmo-message-entity-number entity))
 534     (setq cache-file (elmo-file-cache-get message-id))
 535     (setq ignore-cache (or ignore-cache
 536                            (null (elmo-message-use-cache-p folder number))))
 537     (if (or ignore-cache
 538             (null (elmo-file-cache-status cache-file)))
 539         ;; No cache or ignore-cache.
 540         (if (and (not (elmo-folder-local-p folder))
 541                  elmo-message-fetch-threshold
 542                  (integerp size)
 543                  (>= size elmo-message-fetch-threshold)
 544                  (or (not elmo-message-fetch-confirm)
 545                      (not (prog1 (y-or-n-p
 546                                   (format "Fetch entire message(%dbytes)? "
 547                                           size))
 548                             (message "")))))
 549             ;; Don't fetch message at all.
 550             nil
 551           ;; Don't use existing cache and fetch entire message at once.
 552           (elmo-make-fetch-strategy
 553            'entire nil
 554            (elmo-message-use-cache-p folder number)
 555            (elmo-file-cache-path cache-file)))
 556       ;; Cache exists.
 557       (if (not ignore-cache)
 558           (elmo-make-fetch-strategy
 559            'entire
 560            ;; ...But ignore current section cache and re-fetch
 561            ;; if section cache.
 562            (not (eq (elmo-file-cache-status cache-file) 'section))
 563            ;; Save cache.
 564            (elmo-message-use-cache-p folder number)
 565            (elmo-file-cache-path cache-file))))))
 566
 567 (luna-define-method elmo-folder-list-messages-internal
 568   ((folder elmo-folder) &optional visible-only)
 569   t)
 570
 571 (defun elmo-folder-encache (folder numbers &optional unread)
 572   "Encache messages in the FOLDER with NUMBERS.
 573 If UNREAD is non-nil, messages are not flaged as read."
 574   (dolist (number numbers)
 575     (elmo-message-encache folder number unread)))
 576
 577 (luna-define-generic elmo-message-encache (folder number &optional read)
 578   "Encache message in the FOLDER with NUMBER.
 579 If READ is non-nil, message is flaged as read.")
 580
 581 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 582                                           &optional read)
 583   (let (path)
 584     (elmo-message-fetch
 585      folder number
 586      (elmo-make-fetch-strategy 'entire
 587                                nil ;use-cache
 588                                t   ;save-cache
 589                                (setq path (elmo-file-cache-get-path
 590                                            (elmo-message-field
 591                                             folder number 'message-id))))
 592      nil nil (not read))
 593     path))
 594
 595 (luna-define-generic elmo-message-fetch-bodystructure (folder number strategy)
 596   "Fetch bodystructure of the message in FOLDER with NUMBER using STRATEGY.")
 597
 598 (luna-define-generic elmo-message-fetch (folder number strategy
 599                                                 &optional
 600                                                 section
 601                                                 outbuf
 602                                                 unread)
 603   "Fetch a message and return as a string.
 604 FOLDER is the ELMO folder structure.
 605 NUMBER is the number of the message in the FOLDER.
 606 STRATEGY is the message fetching strategy.
 607 If optional argument SECTION is specified, only the SECTION of the message
 608 is fetched (if possible).
 609 If second optional argument OUTBUF is specified, fetched message is
 610 inserted to the buffer and returns t if fetch was ended successfully.
 611 If third optional argument UNREAD is non-nil, message is not flaged as read.
 612 Returns non-nil if fetching was succeed.")
 613
 614 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 615                                                             number strategy
 616                                                             &optional
 617                                                             section
 618                                                             unread)
 619   "Fetch a message into current buffer with cache process.
 620 FOLDER is the ELMO folder structure.
 621 NUMBER is the number of the message in the FOLDER.
 622 STRATEGY is the message fetching strategy.
 623 If optional argument SECTION is specified, only the SECTION of the message
 624 is fetched (if possible).
 625 If second optional argument UNREAD is non-nil, message is not flaged as read.
 626 Returns non-nil if fetching was succeed.")
 627
 628 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 629                                                          &optional
 630                                                          section
 631                                                          unread)
 632   "Fetch a message into current buffer.
 633 FOLDER is the ELMO folder structure.
 634 NUMBER is the number of the message in the FOLDER.
 635 STRATEGY is the message fetching strategy.
 636 If optional argument SECTION is specified, only the SECTION of the message
 637 is fetched (if possible).
 638 If second optional argument UNREAD is non-nil, message is not flaged as read.
 639 Returns non-nil if fetching was succeed.")
 640
 641 (luna-define-generic elmo-message-fetch-field (folder number field)
 642   "Fetch a message field value.
 643 FOLDER is the ELMO folder structure.
 644 NUMBER is the number of the message in the FOLDER.
 645 FIELD is a symbol of the field name.")
 646
 647 (luna-define-generic elmo-message-folder (folder number)
 648   "Get primitive folder of the message.")
 649
 650 (luna-define-generic elmo-folder-process-crosspost (folder)
 651   "Process crosspost for FOLDER.
 652 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).")
 653
 654 (luna-define-generic elmo-folder-newsgroups (folder)
 655   "Return list of newsgroup name of FOLDER.")
 656
 657 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 658   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 659
 660 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 661   (if (listp condition)
 662       (or (elmo-folder-search-requires-msgdb-p-internal
 663            folder (nth 1 condition))
 664           (elmo-folder-search-requires-msgdb-p-internal
 665            folder (nth 2 condition)))
 666     (and (not (string= (elmo-filter-key condition) "last"))
 667          (not (string= (elmo-filter-key condition) "first")))))
 668
 669 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 670                                                          condition)
 671   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 672
 673 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 674   nil)
 675
 676 (luna-define-method elmo-folder-open ((folder elmo-folder)
 677                                       &optional load-msgdb)
 678   (elmo-generic-folder-open folder load-msgdb))
 679
 680 (defun elmo-generic-folder-open (folder load-msgdb)
 681   (let ((inhibit-quit t))
 682     (if load-msgdb (elmo-folder-msgdb folder))
 683     (elmo-folder-set-killed-list-internal
 684      folder
 685      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 686   (elmo-folder-open-internal folder))
 687
 688 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 689   nil ; default is do nothing.
 690   )
 691
 692 (luna-define-method elmo-folder-check ((folder elmo-folder))
 693   nil) ; default is noop.
 694
 695 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 696   (elmo-generic-folder-commit folder))
 697
 698 (defun elmo-generic-folder-commit (folder)
 699   (let ((msgdb (elmo-folder-msgdb-internal folder)))
 700     (when (and msgdb (elmo-folder-persistent-p folder))
 701       (when (elmo-msgdb-message-modified-p msgdb)
 702         (elmo-folder-set-info-max-by-numdb
 703          folder
 704          (elmo-folder-list-messages folder nil 'in-msgdb))
 705         (elmo-msgdb-killed-list-save
 706          (elmo-folder-msgdb-path folder)
 707          (elmo-folder-killed-list-internal folder)))
 708       (elmo-msgdb-save msgdb))))
 709
 710 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 711   ;; do nothing.
 712   )
 713
 714 (luna-define-method elmo-folder-close ((folder elmo-folder))
 715   (elmo-generic-folder-close folder)
 716   (elmo-folder-close-internal folder))
 717
 718 (defun elmo-generic-folder-close (folder)
 719   (elmo-folder-commit folder)
 720   (elmo-folder-set-msgdb-internal folder nil)
 721   (elmo-folder-set-killed-list-internal folder nil))
 722
 723 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 724   t) ; default is plugged.
 725
 726 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 727                                              &optional add)
 728   nil) ; default is do nothing.
 729
 730 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 731   nil) ; default is no flag.
 732
 733 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 734   (elmo-folder-persistent-internal folder))
 735
 736 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 737   nil) ; default is not creatable.
 738
 739 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 740   nil) ; default is not writable.
 741
 742 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 743   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 744                              (elmo-folder-name-internal folder)))
 745     (elmo-msgdb-delete-path folder)
 746     t))
 747
 748 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 749   (let* ((new-folder (elmo-make-folder new-name)))
 750     (unless (eq (elmo-folder-type-internal folder)
 751                 (elmo-folder-type-internal new-folder))
 752       (error "Not same folder type"))
 753     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 754             (elmo-folder-exists-p new-folder))
 755         (error "Already exists folder: %s" new-name))
 756     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 757     (elmo-msgdb-rename-path folder new-folder)))
 758
 759 (luna-define-method elmo-folder-search ((folder elmo-folder)
 760                                         condition
 761                                         &optional numbers)
 762   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 763         (msgdb (elmo-folder-msgdb folder))
 764         results)
 765     (setq results (elmo-msgdb-search msgdb condition numbers))
 766     (if (listp results)
 767         results
 768       (let ((len (length numbers))
 769             matched)
 770         (elmo-with-progress-display (> len elmo-display-progress-threshold)
 771             (elmo-folder-search len "Searching...")
 772           (dolist (number numbers)
 773             (let (result)
 774               (setq result (elmo-msgdb-match-condition msgdb
 775                                                        condition
 776                                                        number
 777                                                        numbers))
 778               (when (elmo-filter-condition-p result)
 779                 (setq result (elmo-message-match-condition folder
 780                                                            number
 781                                                            condition
 782                                                            numbers)))
 783               (when result
 784                 (setq matched (cons number matched))))
 785             (elmo-progress-notify 'elmo-folder-search)))
 786         (message "Searching...done")
 787         (nreverse matched)))))
 788
 789 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 790                                                   number condition
 791                                                   numbers)
 792   (let* (cache cache-path
 793          (filename (cond
 794                     ((elmo-message-file-name folder number))
 795                     ((progn
 796                        (setq cache (elmo-file-cache-get
 797                                     (elmo-message-field folder number
 798                                                         'message-id)))
 799                        (setq cache-path (elmo-file-cache-path cache))
 800                        (and cache-path
 801                             (not (elmo-cache-path-section-p cache-path))))
 802                      cache-path))))
 803     (when (and filename (file-readable-p filename))
 804       (with-temp-buffer
 805         (set-buffer-multibyte nil)
 806         ;;(insert-file-contents-as-binary filename)
 807         (elmo-message-fetch folder number
 808                             (elmo-make-fetch-strategy 'entire
 809                                                       (and cache t)
 810                                                       nil
 811                                                       cache-path)
 812                             nil (current-buffer) t)
 813         (set-buffer-multibyte default-enable-multibyte-characters)
 814         (decode-coding-region (point-min) (point-max)
 815                               elmo-mime-display-as-is-coding-system)
 816         (elmo-buffer-field-condition-match condition number numbers)))))
 817
 818 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 819   nil) ; default is noop.
 820
 821 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 822   nil) ; default is noop.
 823
 824 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 825   nil) ; default is not file.
 826
 827 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 828   nil) ; default is not number.
 829
 830 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 831   nil) ; default is not make temp file.
 832
 833 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 834                                                    number)
 835   nil) ; default is no name.
 836
 837 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 838   t)   ; default is local.
 839
 840 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 841   t)
 842
 843 ;; Flag table
 844 (luna-define-generic elmo-folder-flag-table (folder &optional if-exists)
 845   "Return the flag-table of FOLDER.
 846 If optional argument IF-EXISTS is nil, load on demand.
 847 \(For internal use only.\)")
 848
 849 (luna-define-generic elmo-folder-close-flag-table (folder)
 850   "Close flag-table of FOLDER.")
 851
 852 (luna-define-method elmo-folder-flag-table ((folder elmo-folder)
 853                                             &optional if-exists)
 854   (or (elmo-folder-flag-table-internal folder)
 855       (unless if-exists
 856         (elmo-folder-set-flag-table-internal
 857          folder
 858          (elmo-flag-table-load (elmo-folder-msgdb-path folder))))))
 859
 860 (luna-define-method elmo-folder-close-flag-table ((folder elmo-folder))
 861   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
 862                         (elmo-folder-flag-table folder))
 863   (elmo-folder-set-flag-table-internal folder nil))
 864
 865 (defun elmo-folder-preserve-flags (folder msgid flags)
 866   "Preserve FLAGS into FOLDER for a message that has MSGID."
 867   (when (and msgid flags)
 868     (let ((flag-table (elmo-folder-flag-table folder 'if-exists))
 869           load-now)
 870       (when (setq load-now (null flag-table))
 871         (setq flag-table (elmo-folder-flag-table folder)))
 872       (elmo-flag-table-set flag-table msgid flags)
 873       (when load-now
 874         (elmo-folder-close-flag-table folder)))))
 875
 876 ;;; Folder info
 877 ;; Folder info is a message number information cache (hashtable)
 878 (defsubst elmo-folder-get-info (folder &optional hashtb)
 879   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 880   (elmo-get-hash-val (elmo-folder-name-internal folder)
 881                      (or hashtb elmo-folder-info-hashtb)))
 882
 883 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 884   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 885   (let ((info (elmo-folder-get-info folder)))
 886     (when info
 887       (or new     (setq new     (nth 0 info)))
 888       (or unread  (setq unread  (nth 1 info)))
 889       (or numbers (setq numbers (nth 2 info)))
 890       (or max     (setq max     (nth 3 info))))
 891     (elmo-set-hash-val (elmo-folder-name-internal folder)
 892                        (list new unread numbers max)
 893                        elmo-folder-info-hashtb)))
 894
 895 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 896   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 897   (elmo-folder-set-info-hashtb
 898    folder
 899    (if numbers (apply #'max numbers) 0)
 900    nil ;;(length num-db)
 901    ))
 902
 903 (defun elmo-folder-get-info-max (folder)
 904   "Return max number of FODLER from folder info."
 905   (nth 3 (elmo-folder-get-info folder)))
 906
 907 (defun elmo-folder-get-info-length (folder)
 908   "Return length of FODLER from folder info."
 909   (nth 2 (elmo-folder-get-info folder)))
 910
 911 (defun elmo-folder-get-info-unread (folder)
 912   "Return unread of FODLER from folder info."
 913   (nth 1 (elmo-folder-get-info folder)))
 914
 915 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 916   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 917   (let* ((hashtb (or hashtb
 918                      (elmo-make-hash (length info-alist)))))
 919     (mapcar
 920      (lambda (x)
 921        (let ((info (cadr x)))
 922          (and (intern-soft (car x) hashtb)
 923               (elmo-set-hash-val (car x)
 924                                  (list (nth 2 info)   ;; new
 925                                        (nth 3 info)   ;; unread
 926                                        (nth 1 info)   ;; length
 927                                        (nth 0 info))  ;; max
 928                                  hashtb))))
 929      info-alist)
 930     (setq elmo-folder-info-hashtb hashtb)))
 931
 932 (defsubst elmo-diff-new (diff)
 933   (car diff))
 934
 935 (defsubst elmo-diff-unread (diff)
 936   (when (consp (cdr diff))
 937     (nth 1 diff)))
 938
 939 (defsubst elmo-diff-all (diff)
 940   (if (consp (cdr diff))
 941       (nth 2 diff)
 942     (cdr diff)))
 943
 944 (defsubst elmo-strict-folder-diff (folder)
 945   "Return folder diff information strictly from FOLDER."
 946   (let ((in-db (sort (elmo-msgdb-list-messages (elmo-folder-msgdb folder))
 947                      '<))
 948         (in-folder  (elmo-folder-list-messages folder))
 949         append-list delete-list diff)
 950     (cons (if (equal in-folder in-db)
 951               0
 952             (setq diff (elmo-list-diff in-folder in-db nil))
 953             (setq append-list (car diff))
 954             (setq delete-list (cadr diff))
 955             (if append-list
 956                 (length append-list)
 957               (if delete-list
 958                   (- 0 (length delete-list))
 959                 0)))
 960           (length in-folder))))
 961
 962 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 963   (elmo-generic-folder-diff folder))
 964
 965 (defun elmo-generic-folder-diff (folder)
 966   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 967                                 elmo-strict-diff-folder-list)
 968       (elmo-strict-folder-diff folder)
 969     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 970           (in-folder (elmo-folder-status folder))
 971           (in-db t)
 972           unsync messages
 973           in-db-max)
 974       (if (not cached-in-db-max)
 975           (let ((number-list (elmo-folder-list-messages folder
 976                                                         nil 'in-msgdb)))
 977             ;; No info-cache.
 978             (setq in-db number-list)
 979             (setq in-db-max (if in-db (apply #'max in-db) 0))
 980             (elmo-folder-set-info-hashtb folder in-db-max nil))
 981         (setq in-db-max cached-in-db-max))
 982       (setq unsync (if (and in-db (car in-folder))
 983                        (- (car in-folder) in-db-max)
 984                      (if (and in-folder (null in-db))
 985                          (cdr in-folder)
 986                        (car in-folder))))
 987       (setq messages (cdr in-folder))
 988       (if (and unsync messages (> unsync messages))
 989           (setq unsync messages))
 990       (cons (or unsync 0) (or messages 0)))))
 991
 992 (defvar elmo-folder-diff-async-callback nil)
 993 (defvar elmo-folder-diff-async-callback-data nil)
 994
 995 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 996   (and elmo-folder-diff-async-callback
 997        (funcall elmo-folder-diff-async-callback
 998                 folder
 999                 (elmo-folder-diff folder))))
1000
1001 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
1002   (list folder))
1003
1004 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
1005   (eq (elmo-folder-type-internal folder) type))
1006
1007 (luna-define-method elmo-folder-next-message-number ((folder elmo-folder))
1008   (+ 1 (elmo-max-of-list (or (elmo-folder-list-messages folder)
1009                              '(0)))))
1010
1011 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
1012                                                  src-folder
1013                                                  numbers
1014                                                  &optional
1015                                                  same-number)
1016   (elmo-generic-folder-append-messages folder src-folder numbers
1017                                        same-number))
1018
1019 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1020                                                    same-number)
1021   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
1022         unseen table
1023         succeed-numbers failure cache id)
1024     (setq table (elmo-folder-flag-table folder))
1025     (with-temp-buffer
1026       (set-buffer-multibyte nil)
1027       (while numbers
1028         (setq failure nil
1029               id (and src-msgdb-exists
1030                       (elmo-message-field src-folder (car numbers)
1031                                           'message-id)))
1032         (condition-case nil
1033             (setq cache (elmo-file-cache-get id)
1034                   failure
1035                   (not
1036                    (and
1037                     (elmo-message-fetch
1038                      src-folder (car numbers)
1039                      (if (elmo-folder-plugged-p src-folder)
1040                          (elmo-make-fetch-strategy
1041                           'entire 'maybe nil
1042                           (and cache (elmo-file-cache-path cache)))
1043                        (or (and elmo-enable-disconnected-operation
1044                                 cache
1045                                 (eq (elmo-file-cache-status cache) 'entire)
1046                                 (elmo-make-fetch-strategy
1047                                  'entire t nil
1048                                  (elmo-file-cache-path cache)))
1049                            (error "Unplugged")))
1050                      nil (current-buffer)
1051                      'unread)
1052                     (> (buffer-size) 0)
1053                     (elmo-folder-append-buffer
1054                      folder
1055                      (elmo-message-flags
1056                       src-folder
1057                       (car numbers)
1058                       (elmo-msgdb-get-message-id-from-buffer))
1059                      (if same-number (car numbers))))))
1060           (error (setq failure t)))
1061         ;; FETCH & APPEND finished
1062         (unless failure
1063           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1064         (elmo-progress-notify 'elmo-folder-move-messages)
1065         (setq numbers (cdr numbers)))
1066       (when (elmo-folder-persistent-p folder)
1067         (elmo-folder-close-flag-table folder))
1068       succeed-numbers)))
1069
1070 ;; Arguments should be reduced.
1071 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1072                                              &optional
1073                                              no-delete
1074                                              same-number)
1075   (save-excursion
1076     (let* ((messages msgs)
1077            (elmo-inhibit-display-retrieval-progress t)
1078            (len (length msgs))
1079            succeeds i result)
1080       (if (eq dst-folder 'null)
1081           (setq succeeds messages)
1082         (unless (elmo-folder-writable-p dst-folder)
1083           (error "move: %d is not writable"
1084                  (elmo-folder-name-internal dst-folder)))
1085         (when messages
1086           ;; src is already opened.
1087           (elmo-folder-open-internal dst-folder)
1088           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1089                                                               src-folder
1090                                                               messages
1091                                                               same-number))
1092             (error "move: append message to %s failed"
1093                    (elmo-folder-name-internal dst-folder)))
1094           (elmo-folder-close dst-folder)))
1095       (if (and (not no-delete) succeeds)
1096           (progn
1097             (if (and (elmo-folder-delete-messages src-folder succeeds)
1098                      (elmo-folder-detach-messages src-folder succeeds))
1099                 (progn
1100                   (elmo-global-flag-detach-messages
1101                    src-folder succeeds (eq dst-folder 'null))
1102                   (setq result t))
1103               (message "move: delete messages from %s failed."
1104                        (elmo-folder-name-internal src-folder))
1105               (setq result nil))
1106             result)
1107         (if no-delete
1108             (progn
1109               ;; (message "Copying messages...done")
1110               t)
1111           (if (eq len 0)
1112               (message "No message was moved.")
1113             (message "Moving messages failed.")
1114             nil ; failure
1115             ))))))
1116
1117 (defun elmo-folder-msgdb-path (folder)
1118   "Return the msgdb path for FOLDER."
1119   (or (elmo-folder-path-internal folder)
1120       (elmo-folder-set-path-internal
1121        folder
1122        (elmo-folder-expand-msgdb-path folder))))
1123
1124 (luna-define-generic elmo-message-cached-p (folder number)
1125   "Return non-nil if the message is cached.")
1126
1127 (luna-define-method elmo-message-cached-p ((folder elmo-folder) number)
1128   (elmo-message-flagged-p folder number 'cached))
1129
1130 (defun elmo-message-accessible-p (folder number)
1131   "Get accessibility of the message.
1132 Return non-nil when message is accessible."
1133   (or (elmo-folder-plugged-p folder)
1134       (elmo-folder-local-p folder)
1135       (elmo-message-cached-p folder number)))
1136
1137 (luna-define-generic elmo-message-set-cached (folder number cached)
1138   "Set cache status of the message in the msgdb.
1139 FOLDER is the ELMO folder structure.
1140 NUMBER is a number of the message.
1141 If CACHED is t, message is set as cached.")
1142
1143 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1144                                              number cached)
1145   (if cached
1146       (elmo-msgdb-set-flag (elmo-folder-msgdb folder) number 'cached)
1147     (elmo-msgdb-unset-flag (elmo-folder-msgdb folder) number 'cached)))
1148
1149 (defun elmo-message-copy-entity (entity)
1150   (elmo-msgdb-copy-message-entity (elmo-message-entity-handler entity)
1151                                   entity))
1152
1153 (luna-define-generic elmo-message-entity (folder key)
1154   "Return the message-entity structure which matches to the KEY.
1155 KEY is a number or a string.
1156 A number is for message number in the FOLDER.
1157 A string is for message-id of the message.")
1158
1159 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1160   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1161
1162 (luna-define-generic elmo-message-entity-parent (folder entity)
1163   "Return the parent message-entity structure in the FOLDER.
1164 ENTITY is the message-entity to get the parent.")
1165
1166 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1167   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1168
1169 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1170 (def-edebug-spec elmo-folder-do-each-message-entity
1171   ((symbolp form &rest form) &rest form))
1172
1173 (defsubst elmo-folder-list-message-entities (folder)
1174   ;; List all message entities in the FOLDER.
1175   (mapcar
1176    (lambda (number) (elmo-message-entity folder number))
1177    (elmo-folder-list-messages folder nil t))) ; XXX killed-list is not used.
1178
1179 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1180   "Iterator for message entity in the folder.
1181 \(elmo-folder-do-each-message-entity \(entity folder\)
1182  ... do the process using entity...
1183 \)"
1184   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1185      ,@form))
1186
1187 (luna-define-generic elmo-folder-count-flags (folder)
1188   "Count flagged message number in the msgdb of the FOLDER.
1189 Return a list of numbers (`new' `unread' `answered')")
1190
1191 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1192   (let* ((flag-count (elmo-msgdb-flag-count (elmo-folder-msgdb folder)))
1193          (new (or (cdr (assq 'new flag-count)) 0))
1194          (unread (or (cdr (assq 'unread flag-count)) 0))
1195          (answered(or (cdr (assq 'answered flag-count)) 0)))
1196     (list new (- unread new) answered)))
1197
1198 (defun elmo-message-set-flag (folder number flag &optional is-local)
1199   "Set message flag.
1200 FOLDER is a ELMO folder structure.
1201 NUMBER is a message number to set flag.
1202
1203 FLAG is a symbol which is one of the following:
1204   `unread'    (set the message as unread)
1205   `answered'  (set the message as answered)
1206   `important' (set the message as important)
1207 'sugar' flag:
1208   `read'      (remove new and unread flags)
1209 If optional IS-LOCAL is non-nil, update only local (not server) status."
1210   ;; XXX Transitional implementation.
1211   (elmo-folder-set-flag folder (list number) flag is-local))
1212
1213 (defun elmo-message-unset-flag (folder number flag &optional is-local)
1214   "Unset message flag.
1215 FOLDER is a ELMO folder structure.
1216 NUMBER is a message number to set flag.
1217
1218 FLAG is a symbol which is one of the following:
1219   `unread'    (remove unread and new flag)
1220   `answered'  (remove answered flag)
1221   `important' (remove important flag)
1222 'sugar' flag:
1223   `read'      (set unread flag)
1224 If optional IS-LOCAL is non-nil, update only local (not server) status."
1225   ;; XXX Transitional implementation.
1226   (elmo-folder-unset-flag folder (list number) flag is-local))
1227
1228 (luna-define-generic elmo-message-field (folder number field)
1229   "Get message field value in the msgdb.
1230 FOLDER is the ELMO folder structure.
1231 NUMBER is a number of the message.
1232 FIELD is a symbol of the field.")
1233
1234 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1235   (elmo-message-entity-field (elmo-message-entity folder number) field))
1236
1237 (luna-define-generic elmo-message-set-field (folder number field value)
1238   "Set message field value in the msgdb.
1239 FOLDER is the ELMO folder structure.
1240 NUMBER is a number of the message.
1241 FIELD is a symbol of the field.
1242 VALUE is a value to set.")
1243
1244 (luna-define-method elmo-message-set-field ((folder elmo-folder) number
1245                                             field value)
1246   (elmo-message-entity-set-field (elmo-message-entity folder number)
1247                                  field value))
1248
1249 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1250   nil) ; default is not use cache.
1251
1252 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1253   folder) ; default is folder
1254
1255 (luna-define-method elmo-folder-set-flag ((folder elmo-folder)
1256                                           numbers
1257                                           flag
1258                                           &optional is-local)
1259   (when (elmo-folder-msgdb-internal folder)
1260     (dolist (number numbers)
1261       (when (elmo-global-flag-p flag)
1262         (let ((message-id (elmo-message-field folder number 'message-id)))
1263           (elmo-global-flag-set flag folder number message-id)))
1264       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1265                            number
1266                            flag))))
1267
1268 (defun elmo-message-has-global-flag-p (folder number)
1269   "Return non-nil when the message in the FOLDER with NUMBER has global flag."
1270   (let ((flags (elmo-message-flags folder number))
1271         result)
1272     (while flags
1273       (when (and (elmo-global-flag-p (car flags))
1274                  (not (memq (car flags) '(answered unread cached))))
1275         (setq result t
1276               flags nil))
1277       (setq flags (cdr flags)))
1278     result))
1279
1280 (defun elmo-message-set-global-flags (folder number flags &optional local)
1281   "Set global flags of the message in the FOLDER with NUMBER as FLAGS.
1282 If Optional LOCAL is non-nil, don't update server flag."
1283   (dolist (flag flags)
1284     (unless (elmo-global-flag-p flag)
1285       (error "Not a global flag")))
1286   (let ((old-flags (elmo-get-global-flags (elmo-message-flags folder number))))
1287     (dolist (flag flags)
1288       (unless (memq flag old-flags)
1289         (elmo-message-set-flag folder number flag local)))
1290     (dolist (flag old-flags)
1291       (unless (memq flag flags)
1292         (elmo-message-unset-flag folder number flag local)))))
1293
1294 (luna-define-method elmo-folder-unset-flag ((folder elmo-folder)
1295                                             numbers
1296                                             flag
1297                                             &optional is-local)
1298   (when (elmo-folder-msgdb-internal folder)
1299     (dolist (number numbers)
1300       (when (elmo-global-flag-p flag)
1301         (elmo-global-flag-detach flag folder number 'always))
1302       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1303                              number
1304                              flag))))
1305
1306 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1307   ;; Do nothing.
1308   )
1309
1310 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1311 ;;                                                             &optional
1312 ;;                                                             flag-table)
1313 ;;  "Append ENTITY to the folder.")
1314
1315 (defun elmo-msgdb-merge (folder msgdb-merge)
1316   "Return a list of messages which have duplicated message-id."
1317   (let (msgdb duplicates)
1318     (setq msgdb (or (elmo-folder-msgdb-internal folder)
1319                     (elmo-make-msgdb (elmo-folder-msgdb-path folder))))
1320     (setq duplicates (elmo-msgdb-append msgdb msgdb-merge))
1321     (elmo-folder-set-msgdb-internal folder msgdb)
1322     duplicates))
1323
1324 (defsubst elmo-folder-append-msgdb (folder append-msgdb)
1325   (if append-msgdb
1326       (let ((duplicates (elmo-msgdb-merge folder append-msgdb)))
1327         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1328                    'hide)
1329                ;; Let duplicates be a temporary killed message.
1330                (elmo-folder-kill-messages folder duplicates)
1331                ;; Should be flag as read.
1332                (elmo-folder-set-flag folder duplicates 'read))
1333               ((eq (elmo-folder-process-duplicates-internal folder)
1334                    'read)
1335                ;; Flag as read duplicates.
1336                (elmo-folder-set-flag folder duplicates 'read))
1337               (t
1338                ;; Do nothing.
1339                (setq duplicates nil)))
1340         (length duplicates))
1341     0))
1342
1343 (defun elmo-folder-confirm-appends (appends)
1344   (let ((len (length appends))
1345         in)
1346     (if (and elmo-folder-update-threshold
1347              (> len elmo-folder-update-threshold)
1348              elmo-folder-update-confirm)
1349         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1350             appends
1351           (setq in elmo-folder-update-threshold)
1352           (catch 'end
1353             (while t
1354               (setq in (read-from-minibuffer "Update number: "
1355                                              (int-to-string in))
1356                     in (string-to-int in))
1357               (if (< len in)
1358                   (throw 'end len))
1359               (if (y-or-n-p (format
1360                              "%d messages are killed (not appeared). OK? "
1361                              (max (- len in) 0)))
1362                   (throw 'end in))))
1363           (nthcdr (max (- len in) 0) appends))
1364       (if (and elmo-folder-update-threshold
1365                (> len elmo-folder-update-threshold)
1366                (not elmo-folder-update-confirm))
1367           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1368         appends))))
1369
1370 (luna-define-method elmo-message-fetch-bodystructure ((folder elmo-folder)
1371                                                       number strategy)
1372   nil)
1373
1374 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1375                                         number strategy
1376                                         &optional
1377                                         section
1378                                         outbuf
1379                                         unread)
1380   (if outbuf
1381       (with-current-buffer outbuf
1382         (erase-buffer)
1383         (elmo-message-fetch-with-cache-process folder number
1384                                                strategy section unread))
1385     (with-temp-buffer
1386       (elmo-message-fetch-with-cache-process folder number
1387                                              strategy section unread)
1388       (buffer-string))))
1389
1390 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1391                                                            number strategy
1392                                                            &optional
1393                                                            section unread)
1394   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1395         (method-priorities
1396          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1397                 '(entity cache))
1398                ((elmo-fetch-strategy-use-cache strategy)
1399                 '(cache entity))
1400                (t
1401                 '(entity))))
1402         result err)
1403     (while (and method-priorities
1404                 (null result))
1405       (setq result
1406             (case (car method-priorities)
1407               (cache
1408                (elmo-file-cache-load cache-path section))
1409               (entity
1410                (when (and (condition-case error
1411                               (elmo-message-fetch-internal folder number
1412                                                            strategy
1413                                                            section
1414                                                            unread)
1415                             (error (setq err error) nil))
1416                           (> (buffer-size) 0))
1417                  (when (and (elmo-fetch-strategy-save-cache strategy)
1418                             cache-path)
1419                    (elmo-file-cache-save cache-path section))
1420                  t)))
1421             method-priorities (cdr method-priorities)))
1422     (or result
1423         (and err (signal (car err) (cdr err))))))
1424
1425 (defun elmo-folder-kill-messages-range (folder beg end)
1426   (elmo-folder-set-killed-list-internal
1427    folder
1428    (nconc
1429     (elmo-folder-killed-list-internal folder)
1430     (list (cons beg end)))))
1431
1432 (defun elmo-folder-kill-messages (folder numbers)
1433   "Kill(hide) messages in the FOLDER with NUMBERS."
1434   (elmo-folder-set-killed-list-internal
1435    folder
1436    (elmo-number-set-append-list
1437     (elmo-folder-killed-list-internal folder)
1438     numbers))
1439   (elmo-folder-unset-flag folder numbers 'all 'local-only))
1440
1441 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1442                                        &optional keep-killed)
1443   (unless keep-killed
1444     (elmo-folder-set-killed-list-internal folder nil))
1445   (if (eq elmo-msgdb-convert-type 'sync)
1446       (elmo-folder-set-msgdb-internal
1447        folder
1448        (elmo-make-msgdb (elmo-folder-msgdb-path folder)))
1449     (elmo-msgdb-clear (elmo-folder-msgdb folder))))
1450
1451 (luna-define-generic elmo-folder-synchronize (folder
1452                                               &optional
1453                                               disable-killed
1454                                               ignore-msgdb
1455                                               no-check
1456                                               mask)
1457   "Synchronize the folder data to the newest status.
1458 FOLDER is the ELMO folder structure.
1459
1460 If optional DISABLE-KILLED is non-nil, killed messages are also synchronized.
1461 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1462 flag status.
1463 If NO-CHECK is non-nil, rechecking folder is skipped.
1464 If optional argument MASK is specified and is a list of message numbers,
1465 synchronize messages only which are contained the list.
1466 Return amount of cross-posted messages.
1467 If update process is interrupted, return nil.")
1468
1469 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1470                                              &optional
1471                                              disable-killed
1472                                              ignore-msgdb
1473                                              no-check
1474                                              mask)
1475   (let ((killed-list (elmo-folder-killed-list-internal folder))
1476         (before-append t)
1477         old-msgdb diff diff-2 delete-list new-list new-msgdb flag
1478         flag-table crossed after-append)
1479     (setq old-msgdb (elmo-folder-msgdb folder))
1480     (setq flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1481     (when ignore-msgdb
1482       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1483       (elmo-folder-clear folder (not disable-killed)))
1484     (unless no-check (elmo-folder-check folder))
1485     (condition-case nil
1486         (progn
1487           (message "Checking folder diff...")
1488           (setq diff (elmo-list-diff (elmo-folder-list-messages
1489                                       folder
1490                                       (not disable-killed))
1491                                      (elmo-folder-list-messages
1492                                       folder
1493                                       (not disable-killed)
1494                                       'in-msgdb)))
1495           (when (and mask (car diff))
1496             (setcar diff (elmo-list-filter mask (car diff))))
1497           (message "Checking folder diff...done")
1498           (setq new-list (elmo-folder-confirm-appends (car diff)))
1499           ;; Set killed list as ((1 . MAX-OF-DISAPPEARED))
1500           (when (and (not (eq (length (car diff))
1501                               (length new-list)))
1502                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1503             (elmo-folder-kill-messages-range
1504              folder
1505              (car (car diff-2))
1506              (nth (- (length (car diff-2)) 1) (car diff-2))))
1507           (setq delete-list (cadr diff))
1508           (if (or (equal diff '(nil nil))
1509                   (equal diff '(nil))
1510                   (and (eq (length (car diff)) 0)
1511                        (eq (length (cadr diff)) 0)))
1512               (progn
1513                 (elmo-folder-update-number folder)
1514                 (elmo-folder-process-crosspost folder)
1515                 0 ; no updates.
1516                 )
1517             (when delete-list
1518               (elmo-folder-detach-messages folder delete-list))
1519             (when new-list
1520               (elmo-msgdb-out-of-date-messages (elmo-folder-msgdb folder))
1521               (setq new-msgdb (elmo-folder-msgdb-create
1522                                folder new-list flag-table))
1523               ;; Clear flag-table
1524               (if (elmo-folder-persistent-p folder)
1525                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1526                                         nil))
1527               (setq before-append nil)
1528               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1529               ;; process crosspost.
1530               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).
1531               (elmo-folder-process-crosspost folder))
1532             ;; return value.
1533             (or crossed 0)))
1534       (quit
1535        ;; Resume to the original status.
1536        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1537        (elmo-folder-set-killed-list-internal folder killed-list)
1538        nil))))
1539
1540 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1541   "Remove messages with NUMBERS from MSGDB.")
1542
1543 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1544                                                  numbers)
1545   (elmo-msgdb-delete-messages (elmo-folder-msgdb folder) numbers))
1546
1547 (luna-define-generic elmo-folder-length (folder)
1548   "Return number of messages in the FOLDER.")
1549
1550 (luna-define-method elmo-folder-length ((folder elmo-folder))
1551   (if (elmo-folder-msgdb-internal folder)
1552       (elmo-msgdb-length (elmo-folder-msgdb folder))
1553     0))
1554
1555 (defun elmo-folder-msgdb-load (folder &optional silent)
1556   (unless silent
1557     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1558   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1559     (elmo-folder-set-info-max-by-numdb
1560      folder
1561      (elmo-msgdb-list-messages msgdb))
1562     (unless silent
1563       (message "Loading msgdb for %s...done"
1564                (elmo-folder-name-internal folder)))
1565     msgdb))
1566
1567 (defun elmo-msgdb-delete-path (folder)
1568   (let ((path (elmo-folder-msgdb-path folder)))
1569     (if (file-directory-p path)
1570         (elmo-delete-directory path t))))
1571
1572 (defun elmo-msgdb-rename-path (old-folder new-folder)
1573   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1574          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1575          (new-dir (directory-file-name (file-name-directory new))))
1576     (if (not (file-directory-p old))
1577         ()
1578       (if (file-exists-p new)
1579           (error "Already exists directory: %s" new)
1580         (if (not (file-exists-p new-dir))
1581             (elmo-make-directory new-dir))
1582         (rename-file old new)))))
1583
1584 (defun elmo-setup-subscribed-newsgroups (groups)
1585   "Setup subscribed newsgroups.
1586 GROUPS is a list of newsgroup name string.
1587 Return a hashtable for newsgroups."
1588   (let ((hashtb (or elmo-newsgroups-hashtb
1589                     (setq elmo-newsgroups-hashtb
1590                           (elmo-make-hash (length groups))))))
1591     (dolist (group groups)
1592       (or (elmo-get-hash-val group hashtb)
1593           (elmo-set-hash-val group nil hashtb)))
1594     (setq elmo-newsgroups-hashtb hashtb)))
1595
1596 (defvar elmo-crosspost-message-alist-modified nil)
1597 (defun elmo-crosspost-message-alist-load ()
1598   "Load crosspost message alist."
1599   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1600   (setq elmo-crosspost-message-alist-modified nil))
1601
1602 (defun elmo-crosspost-message-alist-save ()
1603   "Save crosspost message alist."
1604   (when elmo-crosspost-message-alist-modified
1605     (let ((alist elmo-crosspost-message-alist)
1606           newsgroups)
1607       (while alist
1608         (setq newsgroups
1609               (elmo-delete-if
1610                '(lambda (x)
1611                   (not (intern-soft x elmo-newsgroups-hashtb)))
1612                (nth 1 (car alist))))
1613         (if newsgroups
1614             (setcar (cdar alist) newsgroups)
1615           (setq elmo-crosspost-message-alist
1616                 (delete (car alist) elmo-crosspost-message-alist)))
1617         (setq alist (cdr alist)))
1618       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1619       (setq elmo-crosspost-message-alist-modified nil))))
1620
1621 (defun elmo-folder-make-temporary-directory (folder)
1622   ;; Make a temporary directory for FOLDER.
1623   (let ((temp-dir (make-temp-name
1624                    (concat
1625                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1626                     "elmo"))))
1627     (elmo-make-directory temp-dir)
1628     temp-dir))
1629
1630 (defun elmo-init ()
1631   "Initialize ELMO module."
1632   (elmo-crosspost-message-alist-load)
1633   (elmo-resque-obsolete-variables)
1634   (elmo-dop-queue-load)
1635   (run-hooks 'elmo-init-hook))
1636
1637 (defun elmo-quit ()
1638   "Quit and cleanup ELMO."
1639   (elmo-crosspost-message-alist-save)
1640   (elmo-dop-queue-save)
1641   ;; Not implemented yet.
1642   (let ((types elmo-folder-type-alist)
1643         class)
1644     (while types
1645       (setq class
1646             (luna-find-class
1647              (intern (format "elmo-%s-folder"
1648                              (symbol-name (cdr (car types)))))))
1649       ;; Call all folder's `elmo-quit' method.
1650       (if class
1651           (dolist (func (luna-class-find-functions class 'elmo-quit))
1652             (funcall func nil)))
1653       (setq types (cdr types)))))
1654
1655 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1656                                                  new-folder)
1657   (error "Cannot rename %s folder"
1658          (symbol-name (elmo-folder-type-internal folder))))
1659
1660 ;;; Define folders.
1661 (elmo-define-folder ?% 'imap4)
1662 (elmo-define-folder ?-  'nntp)
1663 (elmo-define-folder ?\+ 'localdir)
1664 (elmo-define-folder ?\* 'multi)
1665 (elmo-define-folder ?\/ 'filter)
1666 (elmo-define-folder ?\$ 'archive)
1667 (elmo-define-folder ?&  'pop3)
1668 (elmo-define-folder ?=  'localnews)
1669 (elmo-define-folder ?|  'pipe)
1670 (elmo-define-folder ?.  'maildir)
1671 (elmo-define-folder ?'  'internal)
1672 (elmo-define-folder ?\[  'nmz)
1673 (elmo-define-folder ?@  'shimbun)
1674
1675 ;;; Obsolete variables.
1676 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1677                                'elmo-imap4-default-mailbox)
1678 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1679                                'elmo-imap4-default-server)
1680 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1681                                'elmo-imap4-default-authenticate-type)
1682 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1683                                'elmo-imap4-default-user)
1684 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1685                                'elmo-imap4-default-port)
1686 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1687                                'elmo-imap4-default-stream-type)
1688 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1689                                'elmo-nntp-default-server)
1690 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1691                                'elmo-nntp-default-user)
1692 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1693                                'elmo-nntp-default-port)
1694 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1695                                'elmo-nntp-default-stream-type)
1696 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1697                                'elmo-pop3-default-server)
1698 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1699                                'elmo-pop3-default-user)
1700 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1701                                'elmo-pop3-default-authenticate-type)
1702 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1703                                'elmo-pop3-default-port)
1704 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1705                                'elmo-pop3-default-stream-type)
1706 (elmo-define-obsolete-variable 'elmo-cache-dirname
1707                                'elmo-cache-directory)
1708 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1709                                'elmo-msgdb-directory)
1710
1711 ;; Obsolete functions.
1712 ;; 2001-12-11: *-dir -> *-directory
1713 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1714 (make-obsolete 'elmo-folder-make-temp-dir
1715                'elmo-folder-make-temporary-directory)
1716
1717 (require 'product)
1718 (product-provide (provide 'elmo) (require 'elmo-version))
1719
1720 ;;; elmo.el ends here