elmo/elmo.el

   1 ;;; elmo.el -- Elisp Library for Message Orchestration
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; APIs which can be used before opened:
  29
  30 ;; elmo-make-folder
  31 ;; elmo-folder-diff
  32 ;; elmo-folder-open
  33
  34 ;;; Code:
  35 ;;
  36
  37 (require 'product)
  38 (require 'luna)
  39
  40 (require 'elmo-vars)
  41 (require 'elmo-util)
  42 (require 'elmo-msgdb)
  43 (require 'elmo-cache)
  44
  45 (eval-when-compile (require 'cl))
  46
  47 (if (or (featurep 'dbm)
  48         (featurep 'gnudbm)
  49         (featurep 'berkdb)
  50         (featurep 'berkeley-db))
  51     (require 'elmo-database))
  52
  53 (defcustom elmo-message-fetch-threshold 30000
  54   "Fetch threshold."
  55   :type 'integer
  56   :group 'elmo)
  57
  58 (defcustom elmo-message-fetch-confirm t
  59   "Confirm fetching if message size is larger than `elmo-fetch-threshold'.
  60 Otherwise, entire fetching of the message is aborted without confirmation."
  61   :type 'boolean
  62   :group 'elmo)
  63
  64 (defcustom elmo-folder-update-threshold 500
  65   "Update threshold."
  66   :type 'integer
  67   :group 'elmo)
  68
  69 (defcustom elmo-folder-update-confirm t
  70   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  71   :type 'boolean
  72   :group 'elmo)
  73
  74 ;;; internal
  75 (defvar elmo-folder-type-alist nil)
  76
  77 (defvar elmo-newsgroups-hashtb nil)
  78
  79 (elmo-define-error 'elmo-error "Error" 'error)
  80 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  81 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  82 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 BYE response" 'elmo-open-error)
  83
  84 (defun elmo-define-folder (prefix backend)
  85   "Define a folder.
  86 If a folder name begins with PREFIX, use BACKEND."
  87   (let ((pair (assq prefix elmo-folder-type-alist)))
  88     (if pair
  89         (progn
  90           (setcar pair prefix)
  91           (setcdr pair backend))
  92       (setq elmo-folder-type-alist (cons (cons prefix backend)
  93                                          elmo-folder-type-alist)))))
  94
  95 (defmacro elmo-folder-type (name)
  96   "Get folder type from NAME string."
  97   (` (and (stringp (, name))
  98           (cdr (assoc (string-to-char (, name)) elmo-folder-type-alist)))))
  99
 100 ;;; ELMO folder
 101 ;; A elmo folder provides uniformed (orchestrated) access
 102 ;; to the internet messages.
 103 (eval-and-compile
 104   (luna-define-class elmo-folder () (type   ; folder type symbol.
 105                                      name   ; orignal folder name string.
 106                                      prefix ; prefix for folder name
 107                                      path   ; directory path for msgdb.
 108                                      msgdb  ; msgdb (may be nil).
 109                                      killed-list  ; killed list.
 110                                      persistent   ; non-nil if persistent.
 111                                      message-modified ; message is modified.
 112                                      mark-modified    ; mark is modified.
 113                                      ))
 114   (luna-define-internal-accessors 'elmo-folder))
 115
 116 (luna-define-generic elmo-folder-initialize (folder name)
 117   ;; Initialize a FOLDER structure with NAME."
 118   )
 119
 120 (defmacro elmo-folder-send (folder message &rest args)
 121   "Let FOLDER receive the MESSAGE with ARGS."
 122   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 123
 124 ;;;###autoload
 125 (defun elmo-make-folder (name &optional non-persistent)
 126   "Make an ELMO folder structure specified by NAME.
 127 If optional argument NON-PERSISTENT is non-nil, folder is treated as
 128  non-persistent."
 129   (let ((type (elmo-folder-type name))
 130         prefix split class folder original)
 131     (setq original (elmo-string name))
 132     (if type
 133         (progn
 134           (setq prefix (substring name 0 1))
 135           (setq name (substring name 1)))
 136       (setq type (intern (car (setq split (split-string name ":")))))
 137       (setq name (substring name (+ 1 (length (car split)))))
 138       (setq prefix (concat (car split) ":")))
 139     (setq class (format "elmo-%s" (symbol-name type)))
 140     (require (intern class))
 141     (setq folder (luna-make-entity (intern (concat class "-folder"))
 142                                    :type   type
 143                                    :prefix prefix
 144                                    :name original
 145                                    :persistent (not non-persistent)))
 146     (save-match-data
 147       (elmo-folder-send folder 'elmo-folder-initialize name))))
 148
 149 (luna-define-generic elmo-folder-open (folder)
 150   "Open and setup (load saved status) FOLDER.")
 151
 152 (luna-define-generic elmo-folder-open-internal (folder)
 153   "Open FOLDER (without loading saved folder status).")
 154
 155 (luna-define-generic elmo-folder-check (folder)
 156   "Check the FOLDER to obtain newest information at the next list operation.")
 157
 158 (luna-define-generic elmo-folder-commit (folder)
 159   "Save current status of FOLDER.")
 160
 161 (luna-define-generic elmo-folder-close (folder)
 162   "Close, save and clearnup FOLDER.")
 163
 164 (luna-define-generic elmo-folder-close-internal (folder)
 165   "Close FOLDER (without saving folder status).")
 166
 167 (luna-define-generic elmo-folder-plugged-p (folder)
 168   "Returns t if FOLDER is plugged.")
 169
 170 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 171   "Set FOLDER as plugged.")
 172
 173 (luna-define-generic elmo-folder-use-flag-p (folder)
 174   "Returns t if FOLDER treats unread/important flag itself.")
 175
 176 (luna-define-generic elmo-folder-diff (folder &optional numbers)
 177   "Get diff of FOLDER.
 178 If optional NUMBERS is set, it is used as current NUMBERS.
 179 Otherwise, saved status for folder is used for comparison.
 180 Return value is a cons cell of NEWS and MESSAGES.")
 181
 182 (luna-define-generic elmo-folder-status (folder)
 183   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 184
 185 (defun elmo-folder-list-messages (folder &optional visible-only)
 186   "Return a list of message numbers contained in FOLDER.
 187 If optional VISIBLE-ONLY is non-nil, killed messages are not listed."
 188   (let ((list (elmo-folder-list-messages-internal folder visible-only))
 189         (killed (elmo-folder-killed-list-internal folder))
 190         numbers)
 191     (setq numbers
 192           (if (listp list)
 193               list
 194             ;; Not available, use current list.
 195             (mapcar
 196              'car
 197              (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))))
 198     (elmo-living-messages numbers killed)))
 199
 200 (defun elmo-folder-list-unreads (folder unread-marks)
 201   "Return a list of unread message numbers contained in FOLDER.
 202 UNREAD-MARKS is the unread marks."
 203   (let ((list (elmo-folder-list-unreads-internal folder
 204                                                  unread-marks)))
 205     (if (listp list)
 206         list
 207       ;; Not available, use current mark.
 208       (delq nil
 209             (mapcar
 210              (function
 211               (lambda (x)
 212                 (if (member (cadr x) unread-marks)
 213                     (car x))))
 214              (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))))))
 215
 216 (defun elmo-folder-list-importants (folder important-mark)
 217   "Returns a list of important message numbers contained in FOLDER.
 218 IMPORTANT-MARK is the important mark."
 219   (let ((list (elmo-folder-list-importants-internal folder important-mark)))
 220     (if (listp list)
 221         list
 222       ;; Not available, use current mark.
 223       (delq nil
 224             (mapcar
 225              (function
 226               (lambda (x)
 227                 (if (string= (cadr x) important-mark)
 228                     (car x))))
 229              (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))))))
 230
 231 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 232                                                                 visible-only)
 233   ;; Return a list of message numbers contained in FOLDER.
 234   ;; Return t if the message list is not available.
 235   )
 236
 237 (luna-define-generic elmo-folder-list-unreads-internal (folder
 238                                                         unread-marks
 239                                                         &optional mark-alist)
 240   ;; Return a list of unread message numbers contained in FOLDER.
 241   ;; If optional MARK-ALIST is set, it is used as mark-alist.
 242   ;; Return t if this feature is not available.
 243   )
 244
 245 (luna-define-generic elmo-folder-list-importants-internal (folder
 246                                                            important-mark)
 247   ;; Return a list of important message numbers contained in FOLDER.
 248   ;; Return t if this feature is not available.
 249   )
 250
 251 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 252   "Returns a list of subfolders contained in FOLDER.
 253 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 254 (a folder which have children is returned as a list)
 255 Otherwise, all descendent folders are returned.")
 256
 257 (luna-define-generic elmo-folder-exists-p (folder)
 258   "Returns non-nil when FOLDER exists.")
 259
 260 (luna-define-generic elmo-folder-creatable-p (folder)
 261   "Returns non-nil when FOLDER is creatable.")
 262
 263 (luna-define-generic elmo-folder-writable-p (folder)
 264   "Returns non-nil when FOLDER is writable.")
 265
 266 (luna-define-generic elmo-folder-persistent-p (folder)
 267   "Return non-nil when FOLDER is persistent.")
 268
 269 (luna-define-generic elmo-folder-create (folder)
 270   "Create a FOLDER.")
 271
 272 (luna-define-generic elmo-message-deletable-p (folder number)
 273   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 274
 275 (luna-define-generic elmo-folder-delete (folder)
 276   "Delete FOLDER completely.")
 277
 278 (luna-define-generic elmo-folder-rename (folder new-name)
 279   "Rename FOLDER to NEW-NAME (string).")
 280
 281 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 282   "Delete messages.
 283 FOLDER is the ELMO folder structure.
 284 NUMBERS is a list of message numbers to be deleted.")
 285
 286 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 287   "Search and return list of message numbers.
 288 FOLDER is the ELMO folder structure.
 289 CONDITION is a condition string for searching.
 290 If optional argument NUMBERS is specified and is a list of message numbers,
 291 messages are searched from the list.")
 292
 293 (luna-define-generic elmo-folder-msgdb-create
 294   (folder numbers new-mark already-mark seen-mark important-mark seen-list)
 295   "Create a message database (implemented in each backends).
 296 FOLDER is the ELMO folder structure.
 297 NUMBERS is a list of message numbers to create msgdb.
 298 NEW-MARK, ALREADY-MARK, SEEN-MARK, and IMPORTANT-MARK are mark string for
 299 new message, unread but cached message, read message and important message.
 300 SEEN-LIST is a list of message-id string which should be treated as read.")
 301
 302 (luna-define-generic elmo-folder-unmark-important (folder numbers)
 303   "Un-mark messages as important.
 304 FOLDER is the ELMO folder structure.
 305 NUMBERS is a list of message numbers to be processed.")
 306
 307 (luna-define-generic elmo-folder-mark-as-important (folder numbers)
 308   "Mark messages as important.
 309 FOLDER is the ELMO folder structure.
 310 NUMBERS is a list of message numbers to be processed.")
 311
 312 (luna-define-generic elmo-folder-unmark-read (folder numbers)
 313   "Un-mark messages as read.
 314 FOLDER is the ELMO folder structure.
 315 NUMBERS is a list of message numbers to be processed.")
 316
 317 (luna-define-generic elmo-folder-mark-as-read (folder numbers)
 318   "Mark messages as read.
 319 FOLDER is the ELMO folder structure.
 320 NUMBERS is a list of message numbers to be processed.")
 321
 322 (luna-define-generic elmo-folder-append-buffer (folder unread &optional number)
 323   "Append current buffer as a new message.
 324 FOLDER is the destination folder(ELMO folder structure).
 325 If UNREAD is non-nil, message is appended as unread.
 326 If optional argument NUMBER is specified, the new message number is set
 327 (if possible).")
 328
 329 (luna-define-generic elmo-folder-append-messages (folder
 330                                                   src-folder
 331                                                   numbers
 332                                                   unread-marks
 333                                                   &optional
 334                                                   same-number)
 335   "Append messages from folder.
 336 FOLDER is the ELMO folder structure.
 337 Caller should make sure FOLDER is `writable'.
 338 (Can be checked with `elmo-folder-writable-p').
 339 SRC-FOLDER is the source ELMO folder structure.
 340 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 341 UNREAD-MARKS is a list of unread mark string.
 342 If second optional argument SAME-NUMBER is specified,
 343 message number is preserved (if possible).")
 344
 345 (luna-define-generic elmo-folder-pack-numbers (folder)
 346   "Pack message numbers of FOLDER.")
 347
 348 (luna-define-generic elmo-folder-update-number (folder)
 349   "Update number of FOLDER.")
 350
 351 (luna-define-generic elmo-folder-diff-async (folder)
 352   "Get diff of FOLDER asynchronously.")
 353
 354 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 355   "Expand path for FOLDER.")
 356
 357 (luna-define-generic elmo-folder-get-primitive-list (folder)
 358   "Get primitive folder structure list contained in FOLDER.")
 359
 360 (luna-define-generic elmo-folder-contains-type (folder type)
 361   "Returns t if FOLDER contains TYPE.")
 362
 363 (luna-define-generic elmo-folder-local-p (folder)
 364   "Returns t if FOLDER is local.")
 365
 366 (luna-define-generic elmo-folder-message-file-p (folder)
 367   "Returns t if all messages in the FOLDER are files.")
 368
 369 ;;; Message methods.
 370 (luna-define-generic elmo-message-use-cache-p (folder number)
 371   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 372
 373 (luna-define-generic elmo-message-file-name (folder number)
 374   "Return the file name of a message specified by FOLDER and NUMBER.")
 375
 376 ;;; For archive
 377
 378 ;;; Use original file
 379 (luna-define-generic elmo-folder-message-file-number-p (folder)
 380   "Return t if the file name in the FOLDER is the message number.")
 381
 382 (luna-define-generic elmo-folder-message-file-directory (folder)
 383   "Return the directory of the message files of FOLDER.")
 384
 385 ;;; Use temporary file
 386 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 387   "Return t if the messages in the FOLDER makes local temporary file.")
 388
 389 (luna-define-generic elmo-folder-message-make-temp-files (folder
 390                                                           numbers
 391                                                           &optional
 392                                                           start-number)
 393   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 394 If START-NUMBER is specified, temporary files begin from the number.
 395 Otherwise, same number is used for temporary files.
 396 Return newly created temporary directory name which contains temporary files.")
 397
 398 (luna-define-generic elmo-message-file-p (folder number)
 399   "Return t if message in the FOLDER with NUMBER is a file.")
 400
 401 (luna-define-generic elmo-find-fetch-strategy
 402   (folder entity &optional ignore-cache)
 403 ;; Returns the message fetching strategy suitable for the message.
 404 ;; FOLDER is the ELMO folder structure.
 405 ;; ENTITY is the overview entity of the message in the folder.
 406 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 407 ;; Returned value is a elmo-fetch-strategy object.
 408 ;; If return value is nil, message should not be nil.
 409   )
 410
 411 (defmacro elmo-make-fetch-strategy (entireness
 412                                     &optional
 413                                     use-cache
 414                                     save-cache
 415                                     cache-path)
 416 ;; Make elmo-message-fetching strategy.
 417 ;; ENTIRENESS is 'entire or 'section.
 418 ;; 'entire means fetch message entirely at once.
 419 ;; 'section means fetch message section by section.
 420 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 421 ;; existing cache is thrown away.
 422 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 423 ;; CACHE-PATH is the cache path to be used as a message cache file.
 424   (` (vector (, entireness)
 425              (, use-cache) (, save-cache) (, cache-path))))
 426
 427 (defmacro elmo-fetch-strategy-entireness (strategy)
 428   ;; Return entireness of STRATEGY.
 429   (` (aref (, strategy) 0)))
 430
 431 (defmacro elmo-fetch-strategy-use-cache (strategy)
 432   ;; Return use-cache of STRATEGY.
 433   (` (aref (, strategy) 1)))
 434
 435 (defmacro elmo-fetch-strategy-save-cache (strategy)
 436   ;; Return save-cache of STRATEGY.
 437   (` (aref (, strategy) 2)))
 438
 439 (defmacro elmo-fetch-strategy-cache-path (strategy)
 440   ;;  Return cache-path of STRATEGY.
 441   (` (aref (, strategy) 3)))
 442
 443 (luna-define-method elmo-find-fetch-strategy
 444   ((folder elmo-folder) entity &optional ignore-cache)
 445   (let (cache-file size message-id number)
 446     (setq size (elmo-msgdb-overview-entity-get-size entity))
 447     (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 448     (setq number (elmo-msgdb-overview-entity-get-number entity))
 449     (setq cache-file (elmo-file-cache-get message-id))
 450     (if (or ignore-cache
 451             (null (elmo-file-cache-status cache-file)))
 452         ;; No cache or ignore-cache.
 453         (if (and (not (elmo-folder-local-p folder))
 454                  elmo-message-fetch-threshold
 455                  (integerp size)
 456                  (>= size elmo-message-fetch-threshold)
 457                  (or (not elmo-message-fetch-confirm)
 458                      (not (prog1 (y-or-n-p
 459                                   (format "Fetch entire message(%dbytes)? "
 460                                           size))
 461                             (message "")))))
 462             ;; Don't fetch message at all.
 463             nil
 464           ;; Don't use existing cache and fetch entire message at once.
 465           (elmo-make-fetch-strategy
 466            'entire nil
 467            (elmo-message-use-cache-p folder number)
 468            (elmo-file-cache-path cache-file)))
 469       ;; Cache exists.
 470       (if (not ignore-cache)
 471           (elmo-make-fetch-strategy
 472            'entire
 473            ;; ...But ignore current section cache and re-fetch
 474            ;; if section cache.
 475            (not (eq (elmo-file-cache-status cache-file) 'section))
 476            ;; Save cache.
 477            (elmo-message-use-cache-p folder number)
 478            (elmo-file-cache-path cache-file))))))
 479
 480 (luna-define-method elmo-folder-list-messages-internal
 481   ((folder elmo-folder))
 482   t)
 483
 484 (luna-define-method elmo-folder-list-unreads-internal
 485   ((folder elmo-folder) unread-marks &optional mark-alist)
 486   t)
 487
 488 (luna-define-method elmo-folder-list-importants-internal
 489   ((folder elmo-folder) important-mark)
 490   t)
 491
 492 (defun elmo-message-encache (folder number)
 493   (elmo-message-fetch
 494    folder number
 495    (elmo-make-fetch-strategy 'entire
 496                              nil ;use-cache
 497                              t   ;save-cache
 498                              (elmo-file-cache-get-path
 499                               (elmo-message-field
 500                                folder number 'message-id)))))
 501
 502 (luna-define-generic elmo-message-fetch (folder number strategy
 503                                                 &optional
 504                                                 section
 505                                                 outbuf
 506                                                 unread)
 507   "Fetch a message and return as a string.
 508 FOLDER is the ELMO folder structure.
 509 NUMBER is the number of the message in the FOLDER.
 510 STRATEGY is the message fetching strategy.
 511 If optional argument SECTION is specified, only the SECTION of the message
 512 is fetched (if possible).
 513 If second optional argument OUTBUF is specified, fetched message is
 514 inserted to the buffer and returns t if fetch was ended successfully.
 515 If third optional argument UNREAD is non-nil, message is not marked as read.
 516 Returns non-nil if fetching was succeed.")
 517
 518 (luna-define-generic elmo-message-folder (folder number)
 519   "Get primitive folder of the message.")
 520
 521 (luna-define-generic elmo-folder-process-crosspost (folder
 522                                                     &optional
 523                                                     number-alist)
 524   "Process crosspost for FOLDER.
 525 If NUMBER-ALIST is set, it is used as number-alist.
 526 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).")
 527
 528 (luna-define-generic elmo-folder-append-msgdb (folder append-msgdb)
 529   "Append  APPEND-MSGDB to the current msgdb of the folder.")
 530
 531 (luna-define-method elmo-folder-open ((folder elmo-folder))
 532   (elmo-generic-folder-open folder))
 533
 534 (defun elmo-generic-folder-open (folder)
 535   (elmo-folder-set-msgdb-internal folder (elmo-msgdb-load folder))
 536   (elmo-folder-set-killed-list-internal
 537    folder
 538    (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder)))
 539   (elmo-folder-open-internal folder))
 540
 541 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 542   nil ; default is do nothing.
 543   )
 544
 545 (luna-define-method elmo-folder-check ((folder elmo-folder))
 546   nil) ; default is noop.
 547
 548 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 549   (elmo-generic-folder-commit folder))
 550
 551 (defun elmo-generic-folder-commit (folder)
 552   (when (elmo-folder-persistent-p folder)
 553     (when (elmo-folder-message-modified-internal folder)
 554       (elmo-msgdb-overview-save
 555        (elmo-folder-msgdb-path folder)
 556        (elmo-msgdb-get-overview (elmo-folder-msgdb-internal folder)))
 557       (elmo-msgdb-number-save
 558        (elmo-folder-msgdb-path folder)
 559        (elmo-msgdb-get-number-alist (elmo-folder-msgdb-internal folder)))
 560       (elmo-folder-set-info-max-by-numdb
 561        folder
 562        (elmo-msgdb-get-number-alist
 563         (elmo-folder-msgdb-internal folder)))
 564       (elmo-folder-set-message-modified-internal folder nil)
 565       (elmo-msgdb-killed-list-save
 566        (elmo-folder-msgdb-path folder)
 567        (elmo-folder-killed-list-internal folder)))
 568     (when (elmo-folder-mark-modified-internal folder)
 569       (elmo-msgdb-mark-save
 570        (elmo-folder-msgdb-path folder)
 571        (elmo-msgdb-get-mark-alist (elmo-folder-msgdb-internal folder)))
 572       (elmo-folder-set-mark-modified-internal folder nil))))
 573
 574 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 575   ;; do nothing.
 576   )
 577
 578 (luna-define-method elmo-folder-close ((folder elmo-folder))
 579   (elmo-generic-folder-close folder)
 580   (elmo-folder-close-internal folder))
 581
 582 (defun elmo-generic-folder-close (folder)
 583   (elmo-folder-commit folder)
 584   (elmo-folder-set-msgdb-internal folder nil)
 585   (elmo-folder-set-killed-list-internal folder nil))
 586
 587 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 588   t) ; default is plugged.
 589
 590 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 591                                              &optional add)
 592   nil) ; default is do nothing.
 593
 594 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 595   nil) ; default is no flag.
 596
 597 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 598   (elmo-folder-persistent-internal folder))
 599
 600 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 601   t) ; default is creatable.
 602
 603 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 604   t) ; default is writable.
 605
 606 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 607   (let* ((new-folder (elmo-make-folder new-name)))
 608     (unless (eq (elmo-folder-type-internal folder)
 609                 (elmo-folder-type-internal new-folder))
 610       (error "Not same folder type"))
 611     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 612             (elmo-folder-exists-p new-folder))
 613         (error "Already exists folder: %s" new-name))
 614     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 615     (elmo-msgdb-rename-path folder new-folder)))
 616
 617 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 618   nil) ; default is noop.
 619
 620 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 621   nil) ; default is noop.
 622
 623 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 624   nil) ; default is not file.
 625
 626 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 627   nil) ; default is not number.
 628
 629 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 630   nil) ; default is not make temp file.
 631
 632 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 633                                                    number)
 634   nil) ; default is no name.
 635
 636 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 637   t)   ; default is local.
 638
 639 ;;; Folder info
 640 ;; Folder info is a message number information cache (hashtable)
 641 (defsubst elmo-folder-get-info (folder &optional hashtb)
 642   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 643   (elmo-get-hash-val (elmo-folder-name-internal folder)
 644                      (or hashtb elmo-folder-info-hashtb)))
 645
 646 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 647   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 648   (let ((info (elmo-folder-get-info folder)))
 649     (when info
 650       (or new     (setq new     (nth 0 info)))
 651       (or unread  (setq unread  (nth 1 info)))
 652       (or numbers (setq numbers (nth 2 info)))
 653       (or max     (setq max     (nth 3 info))))
 654     (elmo-set-hash-val (elmo-folder-name-internal folder)
 655                        (list new unread numbers max)
 656                        elmo-folder-info-hashtb)))
 657
 658 (defun elmo-folder-set-info-max-by-numdb (folder msgdb-number)
 659   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 660   (let ((num-db (sort (mapcar 'car msgdb-number) '<)))
 661     (elmo-folder-set-info-hashtb
 662      folder
 663      (or (nth (max 0 (1- (length num-db))) num-db) 0)
 664      nil ;;(length num-db)
 665      )))
 666
 667 (defun elmo-folder-get-info-max (folder)
 668   "Return max number of FODLER from folder info."
 669   (nth 3 (elmo-folder-get-info folder)))
 670
 671 (defun elmo-folder-get-info-length (folder)
 672   "Return length of FODLER from folder info."
 673   (nth 2 (elmo-folder-get-info folder)))
 674
 675 (defun elmo-folder-get-info-unread (folder)
 676   "Return unread of FODLER from folder info."
 677   (nth 1 (elmo-folder-get-info folder)))
 678
 679 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 680   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 681   (let* ((hashtb (or hashtb
 682                      (elmo-make-hash (length info-alist)))))
 683     (mapcar
 684      (lambda (x)
 685        (let ((info (cadr x)))
 686          (and (intern-soft (car x) hashtb)
 687               (elmo-set-hash-val (car x)
 688                                  (list (nth 2 info)   ;; new
 689                                        (nth 3 info)   ;; unread
 690                                        (nth 1 info)   ;; length
 691                                        (nth 0 info))  ;; max
 692                                  hashtb))))
 693      info-alist)
 694     (setq elmo-folder-info-hashtb hashtb)))
 695
 696 (defsubst elmo-strict-folder-diff (folder)
 697   "Return folder diff information strictly from FOLDER."
 698   (let* ((dir (elmo-folder-msgdb-path folder))
 699          (nalist (or (elmo-folder-msgdb-internal folder)
 700                      (elmo-msgdb-number-load dir)))
 701          (in-db (sort (mapcar 'car nalist) '<))
 702          (in-folder  (elmo-folder-list-messages folder))
 703          append-list delete-list diff)
 704     (cons (if (equal in-folder in-db)
 705               0
 706             (setq diff (elmo-list-diff
 707                         in-folder in-db
 708                         nil
 709                         ))
 710             (setq append-list (car diff))
 711             (setq delete-list (cadr diff))
 712             (if append-list
 713                 (length append-list)
 714               (if delete-list
 715                   (- 0 (length delete-list))
 716                 0)))
 717           (length in-folder))))
 718
 719 (luna-define-method elmo-folder-diff ((folder elmo-folder)
 720                                       &optional numbers)
 721   (elmo-generic-folder-diff folder numbers))
 722
 723 (defun elmo-generic-folder-diff (folder numbers)
 724   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 725                                 elmo-strict-diff-folder-list)
 726       (elmo-strict-folder-diff folder)
 727     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 728           (in-folder (elmo-folder-status folder))
 729           (in-db t)
 730           unsync messages
 731           in-db-max)
 732       (if numbers
 733           (setq in-db-max (or (nth (max 0 (1- (length numbers))) numbers)
 734                               0))
 735         (if (not cached-in-db-max)
 736             (let ((number-list (mapcar 'car
 737                                        (elmo-msgdb-number-load
 738                                         (elmo-folder-msgdb-path folder)))))
 739               ;; No info-cache.
 740               (setq in-db (sort number-list '<))
 741               (setq in-db-max (or (nth (max 0 (1- (length in-db))) in-db)
 742                                   0))
 743               (elmo-folder-set-info-hashtb folder in-db-max nil))
 744           (setq in-db-max cached-in-db-max)))
 745       (setq unsync (if (and in-db
 746                             (car in-folder))
 747                        (- (car in-folder) in-db-max)
 748                      (if (and in-folder
 749                               (null in-db))
 750                          (cdr in-folder)
 751                        (if (null (car in-folder))
 752                            nil))))
 753       (setq messages (cdr in-folder))
 754       (if (and unsync messages (> unsync messages))
 755           (setq unsync messages))
 756       (cons (or unsync 0) (or messages 0)))))
 757
 758 (defvar elmo-folder-diff-async-callback nil)
 759 (defvar elmo-folder-diff-async-callback-data nil)
 760
 761 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 762   (and elmo-folder-diff-async-callback
 763        (funcall elmo-folder-diff-async-callback
 764                 folder
 765                 (elmo-folder-diff folder))))
 766
 767 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
 768   (list folder))
 769
 770 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
 771   (eq (elmo-folder-type-internal folder) type))
 772
 773 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
 774                                                  src-folder
 775                                                  numbers
 776                                                  unread-marks
 777                                                  &optional
 778                                                  same-number)
 779   (elmo-generic-folder-append-messages folder src-folder numbers
 780                                        unread-marks same-number))
 781
 782 (defun elmo-generic-folder-append-messages (folder src-folder numbers
 783                                                    unread-marks same-number)
 784   (let (unseen seen-list succeed-numbers failure)
 785     (with-temp-buffer
 786       (while numbers
 787         (setq failure nil)
 788         (condition-case nil
 789             (progn
 790               (elmo-message-fetch src-folder (car numbers)
 791                                   (elmo-make-fetch-strategy
 792                                    'entire)
 793                                   nil (current-buffer)
 794                                   'unread)
 795               (unless (eq (buffer-size) 0)
 796                 (elmo-folder-append-buffer
 797                  folder
 798                  (setq unseen (member (elmo-message-mark
 799                                        src-folder (car numbers))
 800                                       unread-marks))
 801                  (if same-number (car numbers)))))
 802           (error (setq failure t)))
 803         ;; FETCH & APPEND finished
 804         (unless failure
 805           (if unseen (setq seen-list (cons
 806                                       (elmo-message-field
 807                                        src-folder (car numbers)
 808                                        'message-id)
 809                                       seen-list)))
 810           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
 811         (setq numbers (cdr numbers)))
 812       (if (and seen-list (elmo-folder-persistent-p folder))
 813           (elmo-msgdb-seen-save (elmo-folder-msgdb-path folder)
 814                                 (nconc (elmo-msgdb-seen-load
 815                                         (elmo-folder-msgdb-path folder))
 816                                        seen-list)))
 817       succeed-numbers)))
 818
 819 ;; Arguments should be reduced.
 820 (defun elmo-folder-move-messages (src-folder msgs dst-folder
 821                                              &optional msgdb all done
 822                                              no-delete-info
 823                                              no-delete
 824                                              same-number
 825                                              unread-marks
 826                                              save-unread)
 827   (save-excursion
 828     (let* ((messages msgs)
 829            (len (length msgs))
 830            (all-msg-num (or all len))
 831            (done-msg-num (or done 0))
 832            (progress-message (if no-delete
 833                                  "Copying messages..."
 834                                "Moving messages..."))
 835            succeeds i result)
 836       (unless (eq dst-folder 'null)
 837         ;; src is already opened.
 838         (when messages
 839           (elmo-folder-open-internal dst-folder)
 840           (unless (setq succeeds (elmo-folder-append-messages dst-folder
 841                                                               src-folder
 842                                                               messages
 843                                                               unread-marks
 844                                                               same-number))
 845             (error "move: append message to %s failed"
 846                    (elmo-folder-name-internal dst-folder)))
 847           (elmo-folder-close dst-folder))
 848         (when (and (elmo-folder-persistent-p dst-folder)
 849                    save-unread)
 850           ;; Save to seen list.
 851           (let* ((dir (elmo-folder-msgdb-path dst-folder))
 852                  (seen-list (elmo-msgdb-seen-load dir)))
 853             (setq seen-list
 854                   (elmo-msgdb-add-msgs-to-seen-list
 855                    msgs (elmo-folder-msgdb-internal src-folder)
 856                    unread-marks seen-list))
 857             (elmo-msgdb-seen-save dir seen-list))))
 858       (when (and done
 859                  (> all-msg-num elmo-display-progress-threshold))
 860         (elmo-display-progress
 861          'elmo-folder-move-messages progress-message
 862          (/ (* done-msg-num 100) all-msg-num)))
 863       (if (and (not no-delete) succeeds)
 864           (progn
 865             (if (not no-delete-info)
 866                 (message "Cleaning up src folder..."))
 867             (if (and (elmo-folder-delete-messages src-folder succeeds)
 868                      (elmo-msgdb-delete-msgs src-folder succeeds))
 869                 (setq result t)
 870               (message "move: delete messages from %s failed."
 871                        (elmo-folder-name-internal src-folder))
 872               (setq result nil))
 873             (if (and result
 874                      (not no-delete-info))
 875                 (message "Cleaning up src folder...done"))
 876             result)
 877         (if no-delete
 878             (progn
 879               (message "Copying messages...done")
 880               t)
 881           (if (eq len 0)
 882               (message "No message was moved.")
 883             (message "Moving messages failed.")
 884             nil ; failure
 885             ))))))
 886
 887 (defun elmo-folder-msgdb-path (folder)
 888   "Return the msgdb path for FOLDER."
 889   (or (elmo-folder-path-internal folder)
 890       (elmo-folder-set-path-internal
 891        folder
 892        (elmo-folder-expand-msgdb-path folder))))
 893
 894 (defun elmo-folder-msgdb (folder)
 895   "Return the msgdb of FOLDER (on-demand loading)."
 896   (or (elmo-folder-msgdb-internal folder)
 897       (elmo-msgdb-load folder)))
 898
 899 (defun elmo-message-mark (folder number)
 900   "Get mark of the message.
 901 FOLDER is the ELMO folder structure.
 902 NUMBER is a number of the message."
 903   (cdr (assq number (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))))
 904
 905 (defun elmo-message-field (folder number field)
 906   "Get message field value in the msgdb.
 907 FOLDER is the ELMO folder structure.
 908 NUMBER is a number of the message.
 909 FIELD is a symbol of the field."
 910   (case field
 911     (message-id (elmo-msgdb-overview-entity-get-id
 912                  (elmo-msgdb-overview-get-entity
 913                   number (elmo-folder-msgdb folder))))
 914     (subject (elmo-msgdb-overview-entity-get-subject
 915               (elmo-msgdb-overview-get-entity
 916                number (elmo-folder-msgdb folder))))
 917     (size (elmo-msgdb-overview-entity-get-size
 918            (elmo-msgdb-overview-get-entity
 919             number (elmo-folder-msgdb folder))))
 920     (date (elmo-msgdb-overview-entity-get-date
 921            (elmo-msgdb-overview-get-entity
 922             number (elmo-folder-msgdb folder))))
 923     (to (elmo-msgdb-overview-entity-get-to
 924          (elmo-msgdb-overview-get-entity
 925           number (elmo-folder-msgdb folder))))
 926     (cc (elmo-msgdb-overview-entity-get-cc
 927          (elmo-msgdb-overview-get-entity
 928           number (elmo-folder-msgdb folder))))))
 929
 930 (defun elmo-message-set-mark (folder number mark)
 931   "Set mark for the message in the FOLDER with NUMBER as MARK."
 932   (elmo-msgdb-set-mark-alist
 933    (elmo-folder-msgdb-internal folder)
 934    (elmo-msgdb-mark-set
 935     (elmo-msgdb-get-mark-alist (elmo-folder-msgdb-internal folder))
 936     number mark)))
 937
 938 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
 939   nil) ; default is not use cache.
 940
 941 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
 942   folder) ; default is folder
 943
 944 (luna-define-method elmo-folder-unmark-important ((folder elmo-folder) numbers)
 945   t)
 946
 947 (luna-define-method elmo-folder-mark-as-important ((folder elmo-folder)
 948                                                    numbers)
 949   t)
 950
 951 (luna-define-method elmo-folder-unmark-read ((folder elmo-folder) numbers)
 952   t)
 953
 954 (luna-define-method elmo-folder-mark-as-read ((folder elmo-folder) numbers)
 955   t)
 956
 957 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder)
 958                                                    &optional
 959                                                    number-alist)
 960   ;; Do nothing.
 961   )
 962
 963 (defun elmo-generic-folder-append-msgdb (folder append-msgdb)
 964   (if append-msgdb
 965       (let* ((number-alist (elmo-msgdb-get-number-alist append-msgdb))
 966              (all-alist (copy-sequence (append
 967                                         (elmo-msgdb-get-number-alist
 968                                          (elmo-folder-msgdb-internal folder))
 969                                         number-alist)))
 970              (cur number-alist)
 971              pair
 972              to-be-deleted
 973              mark-alist)
 974         (while cur
 975           (setq all-alist (delq (car cur) all-alist))
 976           ;; same message id exists.
 977           (if (setq pair (rassoc (cdr (car cur)) all-alist))
 978               (setq to-be-deleted (nconc to-be-deleted (list (car pair)))))
 979           (setq cur (cdr cur)))
 980         ;; XXXX If caching is enabled, read-uncached mark should be set.
 981         (setq mark-alist (elmo-delete-if
 982                           (function
 983                            (lambda (x)
 984                              (memq (car x) to-be-deleted)))
 985                           (elmo-msgdb-get-mark-alist append-msgdb)))
 986         (elmo-msgdb-set-mark-alist append-msgdb mark-alist)
 987         (elmo-folder-set-msgdb-internal folder
 988                                         (elmo-msgdb-append
 989                                          (elmo-folder-msgdb-internal folder)
 990                                          append-msgdb t))
 991         (length to-be-deleted))
 992     0))
 993
 994 (luna-define-method elmo-folder-append-msgdb ((folder elmo-folder)
 995                                               append-msgdb)
 996   (elmo-generic-folder-append-msgdb folder append-msgdb))
 997
 998 (defun elmo-folder-confirm-appends (appends)
 999   (let ((len (length appends))
1000         in)
1001     (if (and (> len elmo-folder-update-threshold)
1002              elmo-folder-update-confirm)
1003         (if (y-or-n-p (format "Too many messages(%d).  Continue? " len))
1004             appends
1005           (setq in elmo-folder-update-threshold)
1006           (catch 'end
1007             (while t
1008               (setq in (read-from-minibuffer "Update number: "
1009                                              (int-to-string in))
1010                     in (string-to-int in))
1011               (if (< len in)
1012                   (throw 'end len))
1013               (if (y-or-n-p (format "%d messages are disappeared.  OK? "
1014                                     (max (- len in) 0)))
1015                   (throw 'end in))))
1016           (nthcdr (max (- len in) 0) appends))
1017       (if (and (> len elmo-folder-update-threshold)
1018                (not elmo-folder-update-confirm))
1019           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1020         appends))))
1021
1022 (defun elmo-folder-synchronize (folder
1023                                 new-mark             ;"N"
1024                                 unread-uncached-mark ;"U"
1025                                 unread-cached-mark   ;"!"
1026                                 read-uncached-mark   ;"u"
1027                                 important-mark       ;"$"
1028                                 &optional ignore-msgdb)
1029   "Synchronize the folder data to the newest status.
1030 FOLDER is the ELMO folder structure.
1031 NEW-MARK, UNREAD-CACHED-MARK, READ-UNCACHED-MARK, and IMPORTANT-MARK
1032 are mark strings for new messages, unread but cached messages,
1033 read but not cached messages, and important messages.
1034 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1035 read mark status. If IGNORE-MSGDB is 'visible-only, only visible messages
1036 are thrown away and synchronized.
1037
1038 Return a list of
1039 \(NEW-MSGDB DELETE-LIST CROSSED\)
1040 NEW-MSGDB is the newly appended msgdb.
1041 DELETE-LIST is a list of deleted message number.
1042 CROSSED is cross-posted message number."
1043   (let ((killed-list (elmo-folder-killed-list-internal folder))
1044         (before-append t)
1045         number-alist mark-alist
1046         old-msgdb diff diff-2 delete-list new-list new-msgdb mark
1047         seen-list crossed after-append)
1048     (setq old-msgdb (elmo-folder-msgdb-internal folder))
1049     ;; Load seen-list.
1050     (setq seen-list (elmo-msgdb-seen-load (elmo-folder-msgdb-path folder)))
1051     (setq number-alist (elmo-msgdb-get-number-alist
1052                         (elmo-folder-msgdb-internal folder)))
1053     (setq mark-alist (elmo-msgdb-get-mark-alist
1054                       (elmo-folder-msgdb-internal folder)))
1055     (if ignore-msgdb
1056         (progn
1057           (setq seen-list (nconc
1058                            (elmo-msgdb-mark-alist-to-seen-list
1059                             number-alist mark-alist
1060                             (concat important-mark read-uncached-mark))
1061                            seen-list))
1062           ;; Make killed list as nil.
1063           (unless (eq ignore-msgdb 'visible-only)
1064             (elmo-folder-set-killed-list-internal folder nil))
1065           (elmo-folder-set-msgdb-internal folder
1066                                           (elmo-msgdb-clear))))
1067     (elmo-folder-check folder)
1068     (condition-case nil
1069         (progn
1070           (message "Checking folder diff...")
1071           ;; TODO: killed list is loaded in elmo-folder-open and
1072           ;; list-messages use internal killed-list-folder.
1073           (setq diff (elmo-list-diff (elmo-folder-list-messages
1074                                       folder
1075                                       (eq 'visible-only ignore-msgdb))
1076                                      (unless ignore-msgdb
1077                                        (sort (mapcar
1078                                               'car
1079                                               number-alist)
1080                                              '<))))
1081           (message "Checking folder diff...done")
1082           (setq new-list (elmo-folder-confirm-appends (car diff)))
1083           ;; Set killed list.
1084           (when (and (not (eq (length (car diff))
1085                               (length new-list)))
1086                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1087             (elmo-msgdb-append-to-killed-list folder (car diff-2)))
1088           ;; Don't delete important marked messages.
1089           (setq delete-list
1090                 (elmo-delete-if
1091                  (lambda (x)
1092                    (and (setq mark (cadr (assq x mark-alist)))
1093                         (string= mark important-mark)))
1094                  ;; delete message list
1095                  (cadr diff)))
1096           (if (or (equal diff '(nil nil))
1097                   (equal diff '(nil))
1098                   (and (eq (length (car diff)) 0)
1099                        (eq (length (cadr diff)) 0)))
1100               (progn
1101                 (elmo-folder-update-number folder)
1102                 (elmo-folder-process-crosspost folder)
1103                 nil ; no update.
1104                 )
1105             (if delete-list (elmo-msgdb-delete-msgs folder delete-list))
1106             (when new-list
1107               (setq new-msgdb (elmo-folder-msgdb-create
1108                                folder
1109                                new-list
1110                                new-mark unread-cached-mark
1111                                read-uncached-mark important-mark
1112                                seen-list))
1113               (elmo-msgdb-change-mark (elmo-folder-msgdb-internal folder)
1114                                       new-mark unread-uncached-mark)
1115               ;; Clear seen-list.
1116               (if (elmo-folder-persistent-p folder)
1117                   (setq seen-list (elmo-msgdb-seen-save
1118                                    (elmo-folder-msgdb-path folder) nil)))
1119               (setq before-append nil)
1120               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1121               ;; process crosspost.
1122               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).
1123               (elmo-folder-process-crosspost folder)
1124               (elmo-folder-set-message-modified-internal folder t)
1125               (elmo-folder-set-mark-modified-internal folder t)
1126               ;; return value.
1127               (list new-msgdb delete-list crossed))))
1128       (quit
1129        ;; Resume to the original status.
1130        (if before-append
1131            (elmo-folder-set-msgdb-internal folder old-msgdb))
1132        (elmo-folder-set-killed-list-internal folder killed-list)
1133        nil))))
1134
1135 (defun elmo-folder-messages (folder)
1136   "Return number of messages in the FOLDER."
1137   (length
1138    (elmo-msgdb-get-number-alist
1139     (elmo-folder-msgdb-internal folder))))
1140
1141 ;;;
1142 (defun elmo-msgdb-search (folder condition msgdb)
1143   "Search messages which satisfy CONDITION from FOLDER with MSGDB."
1144   (let* ((condition (car (elmo-parse-search-condition condition)))
1145          (overview (elmo-msgdb-get-overview msgdb))
1146          (number-alist (elmo-msgdb-get-number-alist msgdb))
1147          (number-list (mapcar 'car number-alist))
1148          (length (length overview))
1149          (i 0)
1150          result)
1151     (if (elmo-condition-find-key condition "body")
1152         (elmo-folder-search folder condition number-list)
1153       (while overview
1154         (if (elmo-msgdb-search-internal condition (car overview)
1155                                         number-list)
1156             (setq result
1157                   (cons
1158                    (elmo-msgdb-overview-entity-get-number (car overview))
1159                    result)))
1160         (setq i (1+ i))
1161         (elmo-display-progress
1162          'elmo-msgdb-search "Searching..." (/ (* i 100) length))
1163         (setq overview (cdr overview)))
1164       (nreverse result))))
1165
1166 (defun elmo-msgdb-load (folder)
1167   (message "Loading msgdb for %s..." (elmo-folder-name-internal folder))
1168   (let* ((path (elmo-folder-msgdb-path folder))
1169          (overview (elmo-msgdb-overview-load path))
1170          (msgdb (list overview
1171                       (elmo-msgdb-number-load path)
1172                       (elmo-msgdb-mark-load path)
1173                       (elmo-msgdb-make-overview-hashtb overview))))
1174     (message "Loading msgdb for %s...done" (elmo-folder-name-internal folder))
1175     (elmo-folder-set-info-max-by-numdb folder
1176                                        (elmo-msgdb-get-number-alist msgdb))
1177     msgdb))
1178
1179 (defun elmo-msgdb-delete-path (folder)
1180   (let ((path (elmo-folder-msgdb-path folder)))
1181     (if (file-directory-p path)
1182         (elmo-delete-directory path t))))
1183
1184 (defun elmo-msgdb-rename-path (old-folder new-folder)
1185   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1186          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1187          (new-dir (directory-file-name (file-name-directory new))))
1188     (if (not (file-directory-p old))
1189         ()
1190       (if (file-exists-p new)
1191           (error "Already exists directory: %s" new)
1192         (if (not (file-exists-p new-dir))
1193             (elmo-make-directory new-dir))
1194         (rename-file old new)))))
1195
1196 (defun elmo-setup-subscribed-newsgroups (groups)
1197   "Setup subscribed newsgroups.
1198 GROUPS is a list of newsgroup name string.
1199 Return a hashtable for newsgroups."
1200   (let ((hashtb (or elmo-newsgroups-hashtb
1201                     (setq elmo-newsgroups-hashtb
1202                           (elmo-make-hash (length groups))))))
1203     (dolist (group groups)
1204       (or (elmo-get-hash-val group hashtb)
1205           (elmo-set-hash-val group nil hashtb)))
1206     (setq elmo-newsgroups-hashtb hashtb)))
1207
1208 (defvar elmo-crosspost-message-alist-modified nil)
1209 (defun elmo-crosspost-message-alist-load ()
1210   "Load crosspost message alist."
1211   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1212   (setq elmo-crosspost-message-alist-modified nil))
1213
1214 (defun elmo-crosspost-message-alist-save ()
1215   "Save crosspost message alist."
1216   (when elmo-crosspost-message-alist-modified
1217     (let ((alist elmo-crosspost-message-alist)
1218           newsgroups)
1219       (while alist
1220         (setq newsgroups
1221               (elmo-delete-if
1222                '(lambda (x)
1223                   (not (intern-soft x elmo-newsgroups-hashtb)))
1224                (nth 1 (car alist))))
1225         (if newsgroups
1226             (setcar (cdar alist) newsgroups)
1227           (setq elmo-crosspost-message-alist
1228                 (delete (car alist) elmo-crosspost-message-alist)))
1229         (setq alist (cdr alist)))
1230       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1231       (setq elmo-crosspost-message-alist-modified nil))))
1232
1233 (defun elmo-folder-make-temp-dir (folder)
1234   ;; Make a temporary directory for FOLDER.
1235   (let ((temp-dir (make-temp-name
1236                    (concat
1237                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1238                     "elmo"))))
1239     (elmo-make-directory temp-dir)
1240     temp-dir))
1241
1242 (defun elmo-init ()
1243   "Initialize ELMO module."
1244   (elmo-crosspost-message-alist-load)
1245   (elmo-resque-obsolete-variables))
1246
1247 (defun elmo-quit ()
1248   "Quit and cleanup ELMO."
1249 ;  (setq elmo-newsgroups-hashtb nil)
1250   (elmo-crosspost-message-alist-save)
1251   ;; Not implemented yet.
1252   (let ((types elmo-folder-type-alist)
1253         class)
1254     (while types
1255       (setq class
1256             (luna-find-class
1257              (intern (format "elmo-%s-folder" (symbol-name (cdr (car types)))))))
1258       ;; Call all folder's `elmo-quit' method.
1259       (if class
1260           (dolist (func (luna-class-find-functions class 'elmo-quit))
1261             (funcall func nil)))
1262       (setq types (cdr types)))))
1263
1264
1265 ;;; Define folders.
1266 (elmo-define-folder ?% 'imap4)
1267 (elmo-define-folder ?-  'nntp)
1268 (elmo-define-folder ?\+ 'localdir)
1269 (elmo-define-folder ?\* 'multi)
1270 (elmo-define-folder ?\/ 'filter)
1271 (elmo-define-folder ?\$ 'archive)
1272 (elmo-define-folder ?&  'pop3)
1273 (elmo-define-folder ?=  'localnews)
1274 (elmo-define-folder ?|  'pipe)
1275 (elmo-define-folder ?.  'maildir)
1276 (elmo-define-folder ?'  'internal)
1277 (elmo-define-folder ?[  'nmz)
1278
1279 (product-provide (provide 'elmo) (require 'elmo-version))
1280
1281 ;; elmo.el ends here.
1282 (provide 'elmo)
1283
1284 ;;; elmo.el ends here