elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type '(choice (integer :tag "Threshold (bytes)")
  50                  (const :tag "No limitation" nil))
  51   :group 'elmo)
  52
  53 (defcustom elmo-message-fetch-confirm t
  54   "If non-nil, confirm fetching if message size is larger than
  55 `elmo-message-fetch-threshold'.
  56 Otherwise, entire fetching of the message is aborted without confirmation."
  57   :type 'boolean
  58   :group 'elmo)
  59
  60 (defcustom elmo-folder-update-threshold 500
  61   "Update threshold."
  62   :type '(choice (integer :tag "Number of messages")
  63                  (const :tag "No limitation" nil))
  64   :group 'elmo)
  65
  66 (defcustom elmo-folder-update-confirm t
  67   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  68   :type 'boolean
  69   :group 'elmo)
  70
  71 (defvar elmo-message-displaying nil
  72   "A global switch to indicate message is displaying or not.")
  73
  74 ;;; internal
  75 (defvar elmo-folder-type-alist nil)
  76
  77 (defvar elmo-newsgroups-hashtb nil)
  78
  79 (elmo-define-error 'elmo-error "Error" 'error)
  80 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  81 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  82 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  83
  84 ;; autoloads
  85 (eval-and-compile
  86   (autoload 'elmo-dop-queue-flush "elmo-dop")
  87   (autoload 'elmo-nntp-post "elmo-nntp")
  88   (autoload 'elmo-global-flag-p "elmo-flag")
  89   (autoload 'elmo-local-flag-p "elmo-flag")
  90   (autoload 'elmo-global-flag-detach "elmo-flag")
  91   (autoload 'elmo-global-flag-detach-messages "elmo-flag")
  92   (autoload 'elmo-global-flag-set "elmo-flag")
  93   (autoload 'elmo-get-global-flags "elmo-flag")
  94   (autoload 'elmo-global-mark-migrate "elmo-flag")
  95   (autoload 'elmo-folder-list-global-flag-messages "elmo-flag"))
  96
  97 (defun elmo-define-folder (prefix backend)
  98   "Define a folder.
  99 If a folder name begins with PREFIX, use BACKEND."
 100   (let ((pair (assq prefix elmo-folder-type-alist)))
 101     (if pair
 102         (progn
 103           (setcar pair prefix)
 104           (setcdr pair backend))
 105       (setq elmo-folder-type-alist (cons (cons prefix backend)
 106                                          elmo-folder-type-alist)))))
 107
 108 (defmacro elmo-folder-type (name)
 109   "Get folder type from NAME string."
 110   `(and (stringp ,name)
 111         (cdr (assoc (string-to-char ,name) elmo-folder-type-alist))))
 112
 113 ;;; ELMO folder
 114 ;; A elmo folder provides uniformed (orchestrated) access
 115 ;; to the internet messages.
 116 (eval-and-compile
 117   (luna-define-class elmo-folder () (type   ; folder type symbol.
 118                                      name   ; orignal folder name string.
 119                                      prefix ; prefix for folder name
 120                                      path   ; directory path for msgdb.
 121                                      msgdb  ; msgdb (may be nil).
 122                                      killed-list  ; killed list.
 123                                      flag-table   ; flag table.
 124                                      persistent   ; non-nil if persistent.
 125                                      process-duplicates  ; read or hide
 126                                      biff   ; folder for biff
 127                                      handlers     ; list of event handler.
 128                                      ))
 129   (luna-define-internal-accessors 'elmo-folder))
 130
 131 (luna-define-generic elmo-folder-initialize (folder name)
 132   ;; Initialize a FOLDER structure with NAME."
 133   )
 134
 135 (defmacro elmo-folder-send (folder message &rest args)
 136   "Let FOLDER receive the MESSAGE with ARGS."
 137   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 138
 139 ;;;###autoload
 140 (defun elmo-make-folder (name &optional non-persistent)
 141   "Make an ELMO folder structure specified by NAME.
 142 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 143   (let ((type (elmo-folder-type name))
 144         prefix split class folder original)
 145     (setq original (elmo-string name))
 146     (if type
 147         (progn
 148           (setq prefix (elmo-string (substring name 0 1)))
 149           (setq name (elmo-string (substring name 1))))
 150       (setq type (intern (car (setq split (split-string name ":")))))
 151       (if (>= (length split) 2)
 152           (setq name (substring name (+ 1 (length (car split)))))
 153         (error "Error in folder name `%s'" original))
 154       (setq prefix (concat (car split) ":")))
 155     (setq class (format "elmo-%s" (symbol-name type)))
 156     (require (intern class))
 157     (setq folder (luna-make-entity (intern (concat class "-folder"))
 158                                    :type type
 159                                    :prefix prefix
 160                                    :name original
 161                                    :persistent (not non-persistent)))
 162     (save-match-data
 163       (elmo-folder-send folder 'elmo-folder-initialize name))))
 164
 165 ;; Note that this function is for internal use only.
 166 (luna-define-generic elmo-folder-msgdb (folder)
 167   "Return the msgdb of FOLDER (on-demand loading).
 168 \(For internal use only.\)")
 169
 170 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 171   (or (elmo-folder-msgdb-internal folder)
 172       (elmo-folder-set-msgdb-internal folder
 173                                       (elmo-folder-msgdb-load folder))))
 174
 175 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 176   "Open and setup (load saved status) FOLDER.
 177 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 178 \(otherwise, msgdb is loaded on-demand)")
 179
 180 (luna-define-generic elmo-folder-open-internal (folder)
 181   "Open FOLDER (without loading saved folder status).")
 182
 183 (luna-define-generic elmo-folder-check (folder)
 184   "Check the FOLDER to obtain newest information at the next list operation.")
 185
 186 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 187   "Clear FOLDER to the initial state.
 188 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 189
 190 (luna-define-generic elmo-folder-commit (folder)
 191   "Save current status of FOLDER.")
 192
 193 (luna-define-generic elmo-folder-close (folder)
 194   "Close, save and clearnup FOLDER.")
 195
 196 (luna-define-generic elmo-folder-close-internal (folder)
 197   "Close FOLDER (without saving folder status).")
 198
 199 (luna-define-generic elmo-folder-plugged-p (folder)
 200   "Returns t if FOLDER is plugged.")
 201
 202 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 203   "Set FOLDER as plugged.")
 204
 205 (luna-define-generic elmo-net-port-info (folder)
 206   "Get port information of FOLDER.")
 207
 208 (luna-define-generic elmo-folder-use-flag-p (folder)
 209   "Returns t if FOLDER treats unread/important flag itself.")
 210
 211 (luna-define-generic elmo-folder-diff (folder)
 212   "Get diff of FOLDER.
 213 Return value is cons cell or list:
 214  - a cons cell (new . all)
 215  - a list (new unread all)")
 216
 217 (luna-define-generic elmo-folder-status (folder)
 218   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 219
 220 (luna-define-generic elmo-folder-reserve-status-p (folder)
 221   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 222
 223 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 224                                                        in-msgdb)
 225   "Return a list of message numbers contained in FOLDER.
 226 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 227 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 228
 229 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 230                                                &optional visible-only in-msgdb)
 231   (let ((list (if in-msgdb
 232                   t
 233                 (elmo-folder-list-messages-internal folder visible-only)))
 234         (killed-list (elmo-folder-killed-list-internal folder)))
 235     (unless (listp list)
 236       ;; Use current list.
 237       (setq list (elmo-msgdb-list-messages (elmo-folder-msgdb folder))))
 238     (if visible-only
 239         (elmo-living-messages list killed-list)
 240       (if (and in-msgdb killed-list)
 241           (elmo-uniq-sorted-list
 242            (sort (nconc (elmo-number-set-to-number-list killed-list) list) #'<)
 243            #'eq)
 244         list))))
 245
 246 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 247                                                                 visible-only)
 248   ;; Return a list of message numbers contained in FOLDER.
 249   ;; Return t if the message list is not available.
 250   )
 251
 252 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 253   "List messages in the FOLDER with FLAG.
 254 FLAG is a symbol which is one of the following:
 255   `new'        (new messages)
 256   `unread'     (unread messages (new messages are included))
 257   `answered'   (answered or forwarded)
 258   `important'  (marked as important)
 259 'sugar' flags:
 260   `read'       (not unread)
 261   `digest'     (unread + important + other flags)
 262   `any'        (digest + answered + other flags)
 263 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 264
 265 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 266                                               &optional in-msgdb)
 267   (let ((msgs (if in-msgdb
 268                   t
 269                 (elmo-folder-list-flagged-internal folder flag))))
 270     (unless (listp msgs)
 271       (setq msgs (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag)))
 272     (if in-msgdb
 273         msgs
 274       (elmo-uniq-list
 275        (nconc (elmo-folder-list-global-flag-messages folder flag) msgs)
 276        #'delq))))
 277
 278 (luna-define-generic elmo-folder-list-flagged-internal (folder flag)
 279   "Return a list of message in the FOLDER with FLAG.
 280 Return t if the message list is not available.")
 281
 282 (luna-define-method elmo-folder-list-flagged-internal ((folder elmo-folder)
 283                                                        flag)
 284   t)
 285
 286 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 287   "Returns a list of subfolders contained in FOLDER.
 288 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 289 \(a folder which have children is returned as a list\)
 290 Otherwise, all descendent folders are returned.")
 291
 292 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 293   "Return non-nil when FOLDER has subfolders.")
 294
 295 (luna-define-generic elmo-folder-exists-p (folder)
 296   "Returns non-nil when FOLDER exists.")
 297
 298 (luna-define-generic elmo-folder-creatable-p (folder)
 299   "Returns non-nil when FOLDER is creatable.")
 300
 301 (luna-define-generic elmo-folder-writable-p (folder)
 302   "Returns non-nil when FOLDER is writable.")
 303
 304 (luna-define-generic elmo-folder-persistent-p (folder)
 305   "Return non-nil when FOLDER is persistent.")
 306
 307 (luna-define-generic elmo-folder-create (folder)
 308   "Create a FOLDER.")
 309
 310 (luna-define-generic elmo-message-deletable-p (folder number)
 311   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 312
 313 (luna-define-generic elmo-folder-delete (folder)
 314   "Delete FOLDER completely.")
 315
 316 (luna-define-generic elmo-folder-rename (folder new-name)
 317   "Rename FOLDER to NEW-NAME (string).")
 318
 319 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 320   "Delete messages with msgdb entity.
 321 FOLDER is the ELMO folder structure.
 322 NUMBERS is a list of message numbers to be deleted.
 323 It is not recommended to use this function other than internal use.
 324 Use `elmo-folder-move-messages' with dst-folder 'null instead.")
 325
 326 (luna-define-generic elmo-folder-delete-messages-internal (folder numbers)
 327   "Delete messages, but no delete msgdb entity.
 328 FOLDER is the ELMO folder structure.
 329 NUMBERS is a list of message numbers to be deleted.
 330 Override this method by each implement of `elmo-folder'.")
 331
 332 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 333   "Search and return list of message numbers.
 334 FOLDER is the ELMO folder structure.
 335 CONDITION is a condition structure for searching.
 336 If optional argument NUMBERS is specified and is a list of message numbers,
 337 messages are searched from the list.")
 338
 339 (luna-define-generic elmo-message-match-condition (folder number
 340                                                           condition
 341                                                           numbers)
 342   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 343 CONDITION is a condition structure for testing.
 344 NUMBERS is a list of message numbers,
 345 use to be test for \"last\" and \"first\" predicates.")
 346
 347 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 348   "Create a message database (implemented in each backends).
 349 FOLDER is the ELMO folder structure.
 350 NUMBERS is a list of message numbers to create msgdb.
 351 FLAG-TABLE is a hashtable of message-id and flag.")
 352
 353 (luna-define-generic elmo-folder-set-flag (folder numbers flag
 354                                                   &optional is-local)
 355   "Set messages flag.
 356 FOLDER is a ELMO folder structure.
 357 NUMBERS is a list of message number to set flag.
 358
 359 FLAG is a symbol which is one of the following:
 360   `unread'    (set the message as unread)
 361   `answered'  (set the message as answered)
 362   `important' (set the message as important)
 363 'sugar' flag:
 364   `read'      (remove new and unread flags)
 365 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 366
 367 (luna-define-generic elmo-folder-unset-flag (folder numbers flag
 368                                                     &optional is-local)
 369   "Unset messages flag.
 370 FOLDER is a ELMO folder structure.
 371 NUMBERS is a list of message number to unset flag.
 372
 373 FLAG is a symbol which is one of the following:
 374   `unread'    (remove unread and new flag)
 375   `answered'  (remove answered flag)
 376   `important' (remove important flag)
 377 'sugar' flag:
 378   `read'      (set unread flag)
 379   `all'       (remove all flags)
 380 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 381
 382 (luna-define-generic elmo-message-flag-available-p (folder number flag)
 383   "Return non-nil when a message in the FOLDER with NUMBER treats FLAG.")
 384
 385 (luna-define-generic elmo-folder-next-message-number (folder)
 386   "The next message number that will be assigned to a new message.
 387 FOLDER is the ELMO folder structure.")
 388
 389 (luna-define-generic elmo-folder-append-buffer (folder &optional flags
 390                                                        number)
 391   "Append current buffer as a new message.
 392 FOLDER is the destination folder (ELMO folder structure).
 393 FLAGS is the flag list for the appended message (list of symbols).
 394 If FLAGS contain `read', the message is appended as `not-unread'.
 395 If it is nil, the appended message will be treated as `new'.
 396 If optional argument NUMBER is specified, the new message number is set
 397 \(if possible\).
 398 Return nil on failure.")
 399
 400 (luna-define-generic elmo-folder-append-messages (folder
 401                                                   src-folder
 402                                                   numbers
 403                                                   &optional
 404                                                   same-number)
 405   "Append messages from folder.
 406 FOLDER is the ELMO folder structure.
 407 Caller should make sure FOLDER is `writable'.
 408 \(Can be checked with `elmo-folder-writable-p'\).
 409 SRC-FOLDER is the source ELMO folder structure.
 410 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 411 If second optional argument SAME-NUMBER is specified,
 412 message number is preserved \(if possible\).
 413 Returns a list of message numbers successfully appended.")
 414
 415 (luna-define-generic elmo-folder-pack-numbers (folder)
 416   "Pack message numbers of FOLDER.")
 417
 418 (luna-define-generic elmo-folder-update-number (folder)
 419   "Update number of FOLDER.")
 420
 421 (luna-define-generic elmo-folder-diff-async (folder)
 422   "Get diff of FOLDER asynchronously.")
 423
 424 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 425   "Expand path for FOLDER.")
 426
 427 (luna-define-generic elmo-folder-get-primitive-list (folder)
 428   "Get primitive folder structure list contained in FOLDER.")
 429
 430 (luna-define-generic elmo-folder-contains-type (folder type)
 431   "Returns t if FOLDER contains TYPE.")
 432
 433 (luna-define-generic elmo-folder-local-p (folder)
 434   "Returns t if FOLDER is local.")
 435
 436 (luna-define-generic elmo-folder-message-file-p (folder)
 437   "Returns t if all messages in the FOLDER are files.")
 438
 439 ;;; Message methods.
 440 (luna-define-generic elmo-message-use-cache-p (folder number)
 441   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 442
 443 (luna-define-generic elmo-message-file-name (folder number)
 444   "Return the file name of a message specified by FOLDER and NUMBER.")
 445
 446 ;;; For archive
 447
 448 ;;; Use original file
 449 (luna-define-generic elmo-folder-message-file-number-p (folder)
 450   "Return t if the file name in the FOLDER is the message number.")
 451
 452 (luna-define-generic elmo-folder-message-file-directory (folder)
 453   "Return the directory of the message files of FOLDER.")
 454
 455 ;;; Use temporary file
 456 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 457   "Return t if the messages in the FOLDER makes local temporary file.")
 458
 459 (luna-define-generic elmo-folder-message-make-temp-files (folder
 460                                                           numbers
 461                                                           &optional
 462                                                           start-number)
 463   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 464 If START-NUMBER is specified, temporary files begin from the number.
 465 Otherwise, same number is used for temporary files.
 466 Return newly created temporary directory name which contains temporary files.")
 467
 468 (luna-define-generic elmo-message-file-p (folder number)
 469   "Return t if message in the FOLDER with NUMBER is a file.")
 470
 471 (luna-define-generic elmo-message-flags (folder number)
 472   "Return a list of flags.
 473 FOLDER is a ELMO folder structure.
 474 NUMBER is a number of the message.")
 475
 476 (defun elmo-message-flags-for-append (folder number &optional message-id)
 477   "Return a list of flags for `elmo-folder-append-buffer'.
 478 FOLDER is a ELMO folder structure.
 479 NUMBER is a number of the message.
 480 If optional argument MESSAGES-ID is not specified, get it from current buffer."
 481   (let ((this-id (elmo-message-field folder number 'message-id)))
 482     (and this-id
 483          (string= this-id (or message-id
 484                               (elmo-msgdb-get-message-id-from-buffer)))
 485          (or (elmo-message-flags folder number)
 486              ;; message exists, but no flag.
 487              '(read)))))
 488
 489 (luna-define-method elmo-message-flag-available-p ((folder elmo-folder) number
 490                                                    flag)
 491   (elmo-msgdb-flag-available-p (elmo-folder-msgdb folder) flag))
 492
 493 (luna-define-method elmo-message-flags ((folder elmo-folder) number)
 494   (elmo-msgdb-flags (elmo-folder-msgdb folder) number))
 495
 496 (defsubst elmo-message-flagged-p (folder number flag)
 497   "Return non-nil if the message is set FLAG.
 498 FOLDER is a ELMO folder structure.
 499 NUMBER is a message number to test."
 500   (let ((cur-flags (elmo-message-flags folder number)))
 501     (case flag
 502       (read
 503        (not (memq 'unread cur-flags)))
 504       (t
 505        (memq flag cur-flags)))))
 506
 507 (luna-define-generic elmo-find-fetch-strategy (folder number
 508                                                       &optional
 509                                                       ignore-cache
 510                                                       require-entireness)
 511   "Return the message fetching strategy suitable for the message with NUMBER.
 512 FOLDER is the ELMO folder structure.
 513 If optional argument IGNORE-CACHE is non-nil, existing cache is ignored.
 514 If second optional argument REQUIRE-ENTIRENESS is non-nil,
 515 ensure that entireness of the returned strategy is entire.
 516 Returned value is a elmo-fetch-strategy object.
 517 If return value is nil, message should not be nil.")
 518
 519 (defmacro elmo-make-fetch-strategy (entireness
 520                                     &optional
 521                                     use-cache
 522                                     save-cache
 523                                     cache-path)
 524   "Make elmo-message-fetching strategy.
 525 ENTIRENESS is 'entire or 'section.
 526 'entire means fetch message entirely at once.
 527 'section means fetch message section by section.
 528 If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 529 existing cache is thrown away.
 530 If SAVE-CACHE is non-nil, fetched message is saved.
 531 CACHE-PATH is the cache path to be used as a message cache file."
 532   `(vector ,entireness ,use-cache ,save-cache ,cache-path))
 533
 534 (defmacro elmo-fetch-strategy-entireness (strategy)
 535   "Return entireness of STRATEGY."
 536   `(aref ,strategy 0))
 537
 538 (defmacro elmo-fetch-strategy-use-cache (strategy)
 539   "Return use-cache of STRATEGY."
 540   `(aref ,strategy 1))
 541
 542 (defmacro elmo-fetch-strategy-save-cache (strategy)
 543   "Return save-cache of STRATEGY."
 544   `(aref ,strategy 2))
 545
 546 (defmacro elmo-fetch-strategy-cache-path (strategy)
 547   "Return cache-path of STRATEGY."
 548   `(aref ,strategy 3))
 549
 550 (luna-define-method elmo-find-fetch-strategy ((folder elmo-folder) number
 551                                               &optional
 552                                               ignore-cache
 553                                               require-entireness)
 554   (let ((entity (elmo-message-entity folder number)))
 555     (if (null entity)
 556         (elmo-make-fetch-strategy 'entire)
 557       (let* ((size (elmo-message-entity-field entity 'size))
 558              (message-id (elmo-message-entity-field entity 'message-id))
 559              (cache-file (elmo-file-cache-get message-id))
 560              (use-cache (elmo-message-use-cache-p folder number)))
 561         (if (and (not ignore-cache)
 562                  use-cache
 563                  (eq (elmo-file-cache-status cache-file) 'entire))
 564             ;; Cache exists and use it.
 565             (elmo-make-fetch-strategy
 566              'entire
 567              t                          ; Use cache.
 568              use-cache                  ; Save cache.
 569              (elmo-file-cache-path cache-file))
 570           ;; No cache or ignore-cache.
 571           (if (and (not (elmo-folder-local-p folder))
 572                    (not require-entireness)
 573                    elmo-message-fetch-threshold
 574                    (integerp size)
 575                    (>= size elmo-message-fetch-threshold)
 576                    (or (not elmo-message-fetch-confirm)
 577                        (not (prog1
 578                                 (y-or-n-p
 579                                  (format "Fetch entire message(%dbytes)? "
 580                                          size))
 581                               (message "")))))
 582               ;; Don't fetch message at all.
 583               nil
 584             ;; Don't use existing cache and fetch entire message at once.
 585             (elmo-make-fetch-strategy
 586              'entire
 587              nil                        ; Don't use cache.
 588              use-cache                  ; Save cache.
 589              (elmo-file-cache-path cache-file))))))))
 590
 591 (luna-define-method elmo-folder-list-messages-internal
 592   ((folder elmo-folder) &optional visible-only)
 593   t)
 594
 595 (defun elmo-folder-encache (folder numbers &optional unread)
 596   "Encache messages in the FOLDER with NUMBERS.
 597 If UNREAD is non-nil, messages are not flaged as read."
 598   (dolist (number numbers)
 599     (elmo-message-encache folder number unread)))
 600
 601 (luna-define-generic elmo-message-encache (folder number &optional read)
 602   "Encache message in the FOLDER with NUMBER.
 603 If READ is non-nil, message is flaged as read.")
 604
 605 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 606                                           &optional read)
 607   (let (path)
 608     (elmo-message-fetch
 609      folder number
 610      (elmo-make-fetch-strategy 'entire
 611                                nil ;use-cache
 612                                t   ;save-cache
 613                                (setq path (elmo-file-cache-get-path
 614                                            (elmo-message-field
 615                                             folder number 'message-id))))
 616      nil nil (not read))
 617     path))
 618
 619 (luna-define-generic elmo-message-fetch-bodystructure (folder number strategy)
 620   "Fetch bodystructure of the message in FOLDER with NUMBER using STRATEGY.")
 621
 622 (luna-define-generic elmo-message-fetch (folder number strategy
 623                                                 &optional
 624                                                 section
 625                                                 outbuf
 626                                                 unread)
 627   "Fetch a message and return as a string.
 628 FOLDER is the ELMO folder structure.
 629 NUMBER is the number of the message in the FOLDER.
 630 STRATEGY is the message fetching strategy.
 631 If optional argument SECTION is specified, only the SECTION of the message
 632 is fetched (if possible).
 633 If second optional argument OUTBUF is specified, fetched message is
 634 inserted to the buffer and returns t if fetch was ended successfully.
 635 If third optional argument UNREAD is non-nil, message is not flaged as read.
 636 Returns non-nil if fetching was succeed.")
 637
 638 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 639                                                             number strategy
 640                                                             &optional
 641                                                             section
 642                                                             unread)
 643   "Fetch a message into current buffer with cache process.
 644 FOLDER is the ELMO folder structure.
 645 NUMBER is the number of the message in the FOLDER.
 646 STRATEGY is the message fetching strategy.
 647 If optional argument SECTION is specified, only the SECTION of the message
 648 is fetched (if possible).
 649 If second optional argument UNREAD is non-nil, message is not flaged as read.
 650 Returns non-nil if fetching was succeed.")
 651
 652 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 653                                                          &optional
 654                                                          section
 655                                                          unread)
 656   "Fetch a message into current buffer.
 657 FOLDER is the ELMO folder structure.
 658 NUMBER is the number of the message in the FOLDER.
 659 STRATEGY is the message fetching strategy.
 660 If optional argument SECTION is specified, only the SECTION of the message
 661 is fetched (if possible).
 662 If second optional argument UNREAD is non-nil, message is not flaged as read.
 663 Returns non-nil if fetching was succeed.")
 664
 665 (luna-define-generic elmo-message-fetch-field (folder number field)
 666   "Fetch a message field value.
 667 FOLDER is the ELMO folder structure.
 668 NUMBER is the number of the message in the FOLDER.
 669 FIELD is a symbol of the field name.")
 670
 671 (luna-define-generic elmo-message-folder (folder number)
 672   "Get primitive folder of the message.")
 673
 674 (luna-define-generic elmo-folder-process-crosspost (folder)
 675   "Process crosspost for FOLDER.
 676 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).")
 677
 678 (luna-define-generic elmo-folder-newsgroups (folder)
 679   "Return list of newsgroup name of FOLDER.")
 680
 681 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 682   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 683
 684 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 685   (if (listp condition)
 686       (or (elmo-folder-search-requires-msgdb-p-internal
 687            folder (nth 1 condition))
 688           (elmo-folder-search-requires-msgdb-p-internal
 689            folder (nth 2 condition)))
 690     (and (not (string= (elmo-filter-key condition) "last"))
 691          (not (string= (elmo-filter-key condition) "first")))))
 692
 693 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 694                                                          condition)
 695   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 696
 697 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 698   nil)
 699
 700 (luna-define-method elmo-folder-open ((folder elmo-folder)
 701                                       &optional load-msgdb)
 702   (elmo-generic-folder-open folder load-msgdb))
 703
 704 (defun elmo-generic-folder-open (folder load-msgdb)
 705   (let ((inhibit-quit t))
 706     (if load-msgdb (elmo-folder-msgdb folder))
 707     (elmo-folder-set-killed-list-internal
 708      folder
 709      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 710   (elmo-folder-open-internal folder))
 711
 712 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 713   nil ; default is do nothing.
 714   )
 715
 716 (luna-define-method elmo-folder-check ((folder elmo-folder))
 717   nil) ; default is noop.
 718
 719 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 720   (elmo-generic-folder-commit folder))
 721
 722 (defun elmo-generic-folder-commit (folder)
 723   (when (elmo-folder-persistent-p folder)
 724     (let ((msgdb (elmo-folder-msgdb-internal folder)))
 725       (when msgdb
 726         (when (elmo-msgdb-message-modified-p msgdb)
 727           (elmo-folder-set-info-max-by-numdb
 728            folder
 729            (elmo-folder-list-messages folder nil 'in-msgdb)))
 730         (elmo-msgdb-save msgdb)))
 731     (elmo-msgdb-killed-list-save
 732      (elmo-folder-msgdb-path folder)
 733      (elmo-folder-killed-list-internal folder))))
 734
 735 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 736   ;; do nothing.
 737   )
 738
 739 (luna-define-method elmo-folder-close ((folder elmo-folder))
 740   (elmo-generic-folder-close folder)
 741   (elmo-folder-close-internal folder))
 742
 743 (defun elmo-generic-folder-close (folder)
 744   (elmo-folder-commit folder)
 745   (elmo-folder-set-msgdb-internal folder nil)
 746   (elmo-folder-set-killed-list-internal folder nil))
 747
 748 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 749   t) ; default is plugged.
 750
 751 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 752                                              &optional add)
 753   nil) ; default is do nothing.
 754
 755 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 756   nil) ; default is no flag.
 757
 758 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 759   (elmo-folder-persistent-internal folder))
 760
 761 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 762   nil) ; default is not creatable.
 763
 764 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 765   nil) ; default is not writable.
 766
 767 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 768   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 769                              (elmo-folder-name-internal folder)))
 770     (elmo-msgdb-delete-path folder)
 771     t))
 772
 773 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 774   (let* ((new-folder (elmo-make-folder new-name)))
 775     (unless (eq (elmo-folder-type-internal folder)
 776                 (elmo-folder-type-internal new-folder))
 777       (error "Not same folder type"))
 778     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 779             (elmo-folder-exists-p new-folder))
 780         (error "Already exists folder: %s" new-name))
 781     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 782     (elmo-msgdb-rename-path folder new-folder)))
 783
 784 (luna-define-method elmo-folder-delete-messages ((folder elmo-folder)
 785                                                  numbers)
 786   (and (elmo-folder-delete-messages-internal folder numbers)
 787        (elmo-folder-detach-messages folder numbers)))
 788
 789 (luna-define-method elmo-folder-search ((folder elmo-folder)
 790                                         condition
 791                                         &optional numbers)
 792   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 793         (msgdb (elmo-folder-msgdb folder))
 794         results)
 795     (setq results (elmo-msgdb-search msgdb condition numbers))
 796     (if (listp results)
 797         results
 798       (let ((len (length numbers))
 799             matched)
 800         (elmo-with-progress-display (> len elmo-display-progress-threshold)
 801             (elmo-folder-search len "Searching...")
 802           (dolist (number numbers)
 803             (let (result)
 804               (setq result (elmo-msgdb-match-condition msgdb
 805                                                        condition
 806                                                        number
 807                                                        numbers))
 808               (when (elmo-filter-condition-p result)
 809                 (setq result (elmo-message-match-condition folder
 810                                                            number
 811                                                            condition
 812                                                            numbers)))
 813               (when result
 814                 (setq matched (cons number matched))))
 815             (elmo-progress-notify 'elmo-folder-search)))
 816         (message "Searching...done")
 817         (nreverse matched)))))
 818
 819 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 820                                                   number condition
 821                                                   numbers)
 822   (let* (cache cache-path
 823          (filename (cond
 824                     ((elmo-message-file-name folder number))
 825                     ((progn
 826                        (setq cache (elmo-file-cache-get
 827                                     (elmo-message-field folder number
 828                                                         'message-id)))
 829                        (setq cache-path (elmo-file-cache-path cache))
 830                        (and cache-path
 831                             (not (elmo-cache-path-section-p cache-path))))
 832                      cache-path))))
 833     (when (and filename (file-readable-p filename))
 834       (with-temp-buffer
 835         (set-buffer-multibyte nil)
 836         ;;(insert-file-contents-as-binary filename)
 837         (elmo-message-fetch folder number
 838                             (elmo-make-fetch-strategy 'entire
 839                                                       (and cache t)
 840                                                       nil
 841                                                       cache-path)
 842                             nil (current-buffer) t)
 843         (set-buffer-multibyte default-enable-multibyte-characters)
 844         (decode-coding-region (point-min) (point-max)
 845                               elmo-mime-display-as-is-coding-system)
 846         (elmo-buffer-field-condition-match condition number numbers)))))
 847
 848 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 849   nil) ; default is noop.
 850
 851 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 852   nil) ; default is noop.
 853
 854 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 855   nil) ; default is not file.
 856
 857 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 858   nil) ; default is not number.
 859
 860 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 861   nil) ; default is not make temp file.
 862
 863 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 864                                                    number)
 865   nil) ; default is no name.
 866
 867 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 868   t)   ; default is local.
 869
 870 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 871   t)
 872
 873 ;; Flag table
 874 (luna-define-generic elmo-folder-flag-table (folder &optional if-exists)
 875   "Return the flag-table of FOLDER.
 876 If optional argument IF-EXISTS is nil, load on demand.
 877 \(For internal use only.\)")
 878
 879 (luna-define-generic elmo-folder-close-flag-table (folder)
 880   "Close flag-table of FOLDER.")
 881
 882 (luna-define-method elmo-folder-flag-table ((folder elmo-folder)
 883                                             &optional if-exists)
 884   (or (elmo-folder-flag-table-internal folder)
 885       (unless if-exists
 886         (elmo-folder-set-flag-table-internal
 887          folder
 888          (elmo-flag-table-load (elmo-folder-msgdb-path folder))))))
 889
 890 (luna-define-method elmo-folder-close-flag-table ((folder elmo-folder))
 891   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
 892                         (elmo-folder-flag-table folder))
 893   (elmo-folder-set-flag-table-internal folder nil))
 894
 895 (defun elmo-folder-preserve-flags (folder msgid flags)
 896   "Preserve FLAGS into FOLDER for a message that has MSGID."
 897   (when (and msgid flags)
 898     (let ((flag-table (elmo-folder-flag-table folder 'if-exists))
 899           load-now)
 900       (when (setq load-now (null flag-table))
 901         (setq flag-table (elmo-folder-flag-table folder)))
 902       (elmo-flag-table-set flag-table msgid flags)
 903       (when load-now
 904         (elmo-folder-close-flag-table folder)))))
 905
 906 ;;; Folder info
 907 ;; Folder info is a message number information cache (hashtable)
 908 (defsubst elmo-folder-get-info (folder &optional hashtb)
 909   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 910   (elmo-get-hash-val (elmo-folder-name-internal folder)
 911                      (or hashtb elmo-folder-info-hashtb)))
 912
 913 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 914   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 915   (let ((info (elmo-folder-get-info folder)))
 916     (when info
 917       (or new     (setq new     (nth 0 info)))
 918       (or unread  (setq unread  (nth 1 info)))
 919       (or numbers (setq numbers (nth 2 info)))
 920       (or max     (setq max     (nth 3 info))))
 921     (elmo-set-hash-val (elmo-folder-name-internal folder)
 922                        (list new unread numbers max)
 923                        elmo-folder-info-hashtb)))
 924
 925 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 926   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 927   (elmo-folder-set-info-hashtb
 928    folder
 929    (if numbers (apply #'max numbers) 0)
 930    nil ;;(length num-db)
 931    ))
 932
 933 (defun elmo-folder-get-info-max (folder)
 934   "Return max number of FODLER from folder info."
 935   (nth 3 (elmo-folder-get-info folder)))
 936
 937 (defun elmo-folder-get-info-length (folder)
 938   "Return length of FODLER from folder info."
 939   (nth 2 (elmo-folder-get-info folder)))
 940
 941 (defun elmo-folder-get-info-unread (folder)
 942   "Return unread of FODLER from folder info."
 943   (nth 1 (elmo-folder-get-info folder)))
 944
 945 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 946   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 947   (let* ((hashtb (or hashtb
 948                      (elmo-make-hash (length info-alist)))))
 949     (mapcar
 950      (lambda (x)
 951        (let ((info (cadr x)))
 952          (and (intern-soft (car x) hashtb)
 953               (elmo-set-hash-val (car x)
 954                                  (list (nth 2 info)   ;; new
 955                                        (nth 3 info)   ;; unread
 956                                        (nth 1 info)   ;; length
 957                                        (nth 0 info))  ;; max
 958                                  hashtb))))
 959      info-alist)
 960     (setq elmo-folder-info-hashtb hashtb)))
 961
 962 (defsubst elmo-diff-new (diff)
 963   (car diff))
 964
 965 (defsubst elmo-diff-unread (diff)
 966   (when (consp (cdr diff))
 967     (nth 1 diff)))
 968
 969 (defsubst elmo-diff-all (diff)
 970   (if (consp (cdr diff))
 971       (nth 2 diff)
 972     (cdr diff)))
 973
 974 (defsubst elmo-strict-folder-diff (folder)
 975   "Return folder diff information strictly from FOLDER."
 976   (let ((in-db (sort (elmo-folder-list-messages folder nil 'in-msgdb) '<))
 977         (in-folder  (elmo-folder-list-messages folder))
 978         append-list delete-list diff)
 979     (cons (if (equal in-folder in-db)
 980               0
 981             (setq diff (elmo-list-diff in-folder in-db nil))
 982             (setq append-list (car diff))
 983             (setq delete-list (cadr diff))
 984             (if append-list
 985                 (length append-list)
 986               (if delete-list
 987                   (- 0 (length delete-list))
 988                 0)))
 989           (length in-folder))))
 990
 991 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 992   (elmo-generic-folder-diff folder))
 993
 994 (defun elmo-generic-folder-diff (folder)
 995   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 996                                 elmo-strict-diff-folder-list)
 997       (elmo-strict-folder-diff folder)
 998     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 999           (in-folder (elmo-folder-status folder))
1000           (in-db t)
1001           unsync messages
1002           in-db-max)
1003       (if (not cached-in-db-max)
1004           (let ((number-list (elmo-folder-list-messages folder
1005                                                         nil 'in-msgdb)))
1006             ;; No info-cache.
1007             (setq in-db number-list)
1008             (setq in-db-max (if in-db (apply #'max in-db) 0))
1009             (elmo-folder-set-info-hashtb folder in-db-max nil))
1010         (setq in-db-max cached-in-db-max))
1011       (setq unsync (if (and in-db (car in-folder))
1012                        (- (car in-folder) in-db-max)
1013                      (if (and in-folder (null in-db))
1014                          (cdr in-folder)
1015                        (car in-folder))))
1016       (setq messages (cdr in-folder))
1017       (if (and unsync messages (> unsync messages))
1018           (setq unsync messages))
1019       (cons (or unsync 0) (or messages 0)))))
1020
1021 (defvar elmo-folder-diff-async-callback nil)
1022 (defvar elmo-folder-diff-async-callback-data nil)
1023
1024 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
1025   (and elmo-folder-diff-async-callback
1026        (funcall elmo-folder-diff-async-callback
1027                 folder
1028                 (elmo-folder-diff folder))))
1029
1030 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
1031   (list folder))
1032
1033 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
1034   (eq (elmo-folder-type-internal folder) type))
1035
1036 (luna-define-method elmo-folder-next-message-number ((folder elmo-folder))
1037   (+ 1 (elmo-max-of-list (or (elmo-folder-list-messages folder)
1038                              '(0)))))
1039
1040 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
1041                                                  src-folder
1042                                                  numbers
1043                                                  &optional
1044                                                  same-number)
1045   (elmo-generic-folder-append-messages folder src-folder numbers
1046                                        same-number))
1047
1048 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1049                                                    same-number)
1050   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
1051         unseen table
1052         succeed-numbers failure cache id)
1053     (setq table (elmo-folder-flag-table folder))
1054     (with-temp-buffer
1055       (set-buffer-multibyte nil)
1056       (while numbers
1057         (setq failure nil
1058               id (and src-msgdb-exists
1059                       (elmo-message-field src-folder (car numbers)
1060                                           'message-id)))
1061         (condition-case nil
1062             (setq cache (elmo-file-cache-get id)
1063                   failure
1064                   (not
1065                    (and
1066                     (elmo-message-fetch
1067                      src-folder (car numbers)
1068                      (if (elmo-folder-plugged-p src-folder)
1069                          (elmo-make-fetch-strategy
1070                           'entire 'maybe nil
1071                           (and cache (elmo-file-cache-path cache)))
1072                        (or (and elmo-enable-disconnected-operation
1073                                 cache
1074                                 (eq (elmo-file-cache-status cache) 'entire)
1075                                 (elmo-make-fetch-strategy
1076                                  'entire t nil
1077                                  (elmo-file-cache-path cache)))
1078                            (error "Unplugged")))
1079                      nil (current-buffer)
1080                      'unread)
1081                     (> (buffer-size) 0)
1082                     (elmo-folder-append-buffer
1083                      folder
1084                      (elmo-message-flags-for-append src-folder (car numbers))
1085                      (if same-number (car numbers))))))
1086           (error (setq failure t)))
1087         ;; FETCH & APPEND finished
1088         (unless failure
1089           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1090         (elmo-progress-notify 'elmo-folder-move-messages)
1091         (setq numbers (cdr numbers)))
1092       (when (elmo-folder-persistent-p folder)
1093         (elmo-folder-close-flag-table folder))
1094       succeed-numbers)))
1095
1096 ;; Arguments should be reduced.
1097 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1098                                              &optional
1099                                              no-delete
1100                                              same-number)
1101   (save-excursion
1102     (let* ((messages msgs)
1103            (elmo-inhibit-display-retrieval-progress t)
1104            (len (length msgs))
1105            succeeds i result)
1106       (if (eq dst-folder 'null)
1107           (setq succeeds messages)
1108         (unless (elmo-folder-writable-p dst-folder)
1109           (error "move: %d is not writable"
1110                  (elmo-folder-name-internal dst-folder)))
1111         (when messages
1112           ;; src is already opened.
1113           (elmo-folder-open-internal dst-folder)
1114           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1115                                                               src-folder
1116                                                               messages
1117                                                               same-number))
1118             (error "move: append message to %s failed"
1119                    (elmo-folder-name-internal dst-folder)))
1120           (elmo-folder-close dst-folder)))
1121       (if (and (not no-delete) succeeds)
1122           (progn
1123             (if (elmo-folder-delete-messages src-folder succeeds)
1124                 (progn
1125                   (elmo-global-flag-detach-messages
1126                    src-folder succeeds (eq dst-folder 'null))
1127                   (setq result t))
1128               (message "move: delete messages from %s failed."
1129                        (elmo-folder-name-internal src-folder))
1130               (setq result nil))
1131             result)
1132         (if no-delete
1133             (progn
1134               ;; (message "Copying messages...done")
1135               t)
1136           (if (eq len 0)
1137               (message "No message was moved.")
1138             (message "Moving messages failed.")
1139             nil ; failure
1140             ))))))
1141
1142 (defun elmo-folder-msgdb-path (folder)
1143   "Return the msgdb path for FOLDER."
1144   (or (elmo-folder-path-internal folder)
1145       (elmo-folder-set-path-internal
1146        folder
1147        (elmo-folder-expand-msgdb-path folder))))
1148
1149 (luna-define-generic elmo-message-cached-p (folder number)
1150   "Return non-nil if the message is cached.")
1151
1152 (luna-define-method elmo-message-cached-p ((folder elmo-folder) number)
1153   (elmo-message-flagged-p folder number 'cached))
1154
1155 (defun elmo-message-accessible-p (folder number)
1156   "Get accessibility of the message.
1157 Return non-nil when message is accessible."
1158   (or (elmo-folder-plugged-p folder)
1159       (elmo-folder-local-p folder)
1160       (< number 0) ; in dop spool
1161       (elmo-message-cached-p folder number)))
1162
1163 (luna-define-generic elmo-message-set-cached (folder number cached)
1164   "Set cache status of the message in the msgdb.
1165 FOLDER is the ELMO folder structure.
1166 NUMBER is a number of the message.
1167 If CACHED is t, message is set as cached.")
1168
1169 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1170                                              number cached)
1171   (if cached
1172       (elmo-msgdb-set-flag (elmo-folder-msgdb folder) number 'cached)
1173     (elmo-msgdb-unset-flag (elmo-folder-msgdb folder) number 'cached))
1174   (elmo-folder-notify-event folder 'cache-changed number))
1175
1176 (defun elmo-message-copy-entity (entity)
1177   (elmo-msgdb-copy-message-entity (elmo-message-entity-handler entity)
1178                                   entity))
1179
1180 (luna-define-generic elmo-message-number (folder message-id)
1181   "Get message number from MSGDB which corresponds to MESSAGE-ID.")
1182
1183 (luna-define-method elmo-message-number ((folder elmo-folder) message-id)
1184   (elmo-msgdb-message-number (elmo-folder-msgdb folder) message-id))
1185
1186 (luna-define-generic elmo-message-entity (folder key)
1187   "Return the message-entity structure which matches to the KEY.
1188 KEY is a number or a string.
1189 A number is for message number in the FOLDER.
1190 A string is for message-id of the message.")
1191
1192 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1193   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1194
1195 (luna-define-generic elmo-message-entity-parent (folder entity)
1196   "Return the parent message-entity structure in the FOLDER.
1197 ENTITY is the message-entity to get the parent.")
1198
1199 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1200   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1201
1202 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1203 (def-edebug-spec elmo-folder-do-each-message-entity
1204   ((symbolp form &rest form) &rest form))
1205
1206 (defsubst elmo-folder-list-message-entities (folder)
1207   ;; List all message entities in the FOLDER.
1208   (mapcar
1209    (lambda (number) (elmo-message-entity folder number))
1210    (elmo-folder-list-messages folder nil t))) ; XXX killed-list is not used.
1211
1212 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1213   "Iterator for message entity in the folder.
1214 \(elmo-folder-do-each-message-entity \(entity folder\)
1215  ... do the process using entity...
1216 \)"
1217   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1218      ,@form))
1219
1220 (luna-define-generic elmo-folder-count-flags (folder)
1221   "Count flagged message number in the msgdb of the FOLDER.
1222 Return alist of flag and numbers.
1223 Example:
1224 \(\(new . 10\)
1225   \(unread . 20\)
1226   \(answered . 3\)\)")
1227
1228 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1229   (elmo-msgdb-flag-count (elmo-folder-msgdb folder)))
1230
1231 (defun elmo-message-set-flag (folder number flag &optional is-local)
1232   "Set message flag.
1233 FOLDER is a ELMO folder structure.
1234 NUMBER is a message number to set flag.
1235
1236 FLAG is a symbol which is one of the following:
1237   `unread'    (set the message as unread)
1238   `answered'  (set the message as answered)
1239   `important' (set the message as important)
1240 'sugar' flag:
1241   `read'      (remove new and unread flags)
1242 If optional IS-LOCAL is non-nil, update only local (not server) status."
1243   ;; XXX Transitional implementation.
1244   (elmo-folder-set-flag folder (list number) flag is-local))
1245
1246 (defun elmo-message-unset-flag (folder number flag &optional is-local)
1247   "Unset message flag.
1248 FOLDER is a ELMO folder structure.
1249 NUMBER is a message number to set flag.
1250
1251 FLAG is a symbol which is one of the following:
1252   `unread'    (remove unread and new flag)
1253   `answered'  (remove answered flag)
1254   `important' (remove important flag)
1255 'sugar' flag:
1256   `read'      (set unread flag)
1257 If optional IS-LOCAL is non-nil, update only local (not server) status."
1258   ;; XXX Transitional implementation.
1259   (elmo-folder-unset-flag folder (list number) flag is-local))
1260
1261 (luna-define-generic elmo-message-field (folder number field)
1262   "Get message field value in the msgdb.
1263 FOLDER is the ELMO folder structure.
1264 NUMBER is a number of the message.
1265 FIELD is a symbol of the field.")
1266
1267 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1268   (elmo-msgdb-message-field (elmo-folder-msgdb folder) number field))
1269
1270 (luna-define-generic elmo-message-set-field (folder number field value)
1271   "Set message field value in the msgdb.
1272 FOLDER is the ELMO folder structure.
1273 NUMBER is a number of the message.
1274 FIELD is a symbol of the field.
1275 VALUE is a value to set.")
1276
1277 (luna-define-method elmo-message-set-field ((folder elmo-folder) number
1278                                             field value)
1279   (elmo-message-entity-set-field (elmo-message-entity folder number)
1280                                  field value))
1281
1282 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1283   nil) ; default is not use cache.
1284
1285 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1286   folder) ; default is folder
1287
1288 (luna-define-method elmo-folder-set-flag ((folder elmo-folder)
1289                                           numbers
1290                                           flag
1291                                           &optional is-local)
1292   (when (elmo-folder-msgdb-internal folder)
1293     (dolist (number numbers)
1294       (when (elmo-global-flag-p flag)
1295         (let ((message-id (elmo-message-field folder number 'message-id)))
1296           (elmo-global-flag-set flag folder number message-id)))
1297       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1298                            number
1299                            flag))
1300     (elmo-folder-notify-event folder 'flag-changed numbers)))
1301
1302 (defun elmo-message-has-global-flag-p (folder number)
1303   "Return non-nil when the message in the FOLDER with NUMBER has global flag."
1304   (let ((flags (elmo-message-flags folder number))
1305         result)
1306     (while flags
1307       (when (and (elmo-global-flag-p (car flags))
1308                  (not (memq (car flags) '(answered unread cached))))
1309         (setq result t
1310               flags nil))
1311       (setq flags (cdr flags)))
1312     result))
1313
1314 (defun elmo-message-set-global-flags (folder number flags &optional local)
1315   "Set global flags of the message in the FOLDER with NUMBER as FLAGS.
1316 If Optional LOCAL is non-nil, don't update server flag."
1317   (dolist (flag flags)
1318     (unless (elmo-global-flag-p flag)
1319       (error "Not a global flag")))
1320   (let ((old-flags (elmo-get-global-flags (elmo-message-flags folder number))))
1321     (dolist (flag flags)
1322       (unless (memq flag old-flags)
1323         (elmo-message-set-flag folder number flag local)))
1324     (dolist (flag old-flags)
1325       (unless (memq flag flags)
1326         (elmo-message-unset-flag folder number flag local)))))
1327
1328 (luna-define-method elmo-folder-unset-flag ((folder elmo-folder)
1329                                             numbers
1330                                             flag
1331                                             &optional is-local)
1332   (when (elmo-folder-msgdb-internal folder)
1333     (dolist (number numbers)
1334       (when (elmo-global-flag-p flag)
1335         (elmo-global-flag-detach flag folder number 'always))
1336       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1337                              number
1338                              flag))
1339     (elmo-folder-notify-event folder 'flag-changed numbers)))
1340
1341 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1342   ;; Do nothing.
1343   )
1344
1345 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1346 ;;                                                             &optional
1347 ;;                                                             flag-table)
1348 ;;  "Append ENTITY to the folder.")
1349
1350 (defun elmo-msgdb-merge (folder msgdb-merge)
1351   "Return a list of messages which have duplicated message-id."
1352   (let (msgdb duplicates)
1353     (setq msgdb (or (elmo-folder-msgdb-internal folder)
1354                     (elmo-make-msgdb (elmo-folder-msgdb-path folder))))
1355     (setq duplicates (elmo-msgdb-append msgdb msgdb-merge))
1356     (elmo-folder-set-msgdb-internal folder msgdb)
1357     duplicates))
1358
1359 (defsubst elmo-folder-append-msgdb (folder append-msgdb)
1360   (if append-msgdb
1361       (let ((duplicates (elmo-msgdb-merge folder append-msgdb)))
1362         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1363                    'hide)
1364                ;; Let duplicates be a temporary killed message.
1365                (elmo-folder-kill-messages folder duplicates)
1366                ;; Should be flag as read.
1367                (elmo-folder-unset-flag folder duplicates 'unread))
1368               ((eq (elmo-folder-process-duplicates-internal folder)
1369                    'read)
1370                ;; Flag as read duplicates.
1371                (elmo-folder-unset-flag folder duplicates 'unread))
1372               (t
1373                ;; Do nothing.
1374                (setq duplicates nil)))
1375         (length duplicates))
1376     0))
1377
1378 (defun elmo-folder-confirm-appends (appends)
1379   (let ((len (length appends))
1380         in)
1381     (if (and elmo-folder-update-threshold
1382              (> len elmo-folder-update-threshold)
1383              elmo-folder-update-confirm)
1384         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1385             appends
1386           (setq in elmo-folder-update-threshold)
1387           (catch 'end
1388             (while t
1389               (setq in (read-from-minibuffer "Update number: "
1390                                              (int-to-string in))
1391                     in (string-to-int in))
1392               (if (< len in)
1393                   (throw 'end len))
1394               (if (y-or-n-p (format
1395                              "%d messages are killed (not appeared). OK? "
1396                              (max (- len in) 0)))
1397                   (throw 'end in))))
1398           (nthcdr (max (- len in) 0) appends))
1399       (if (and elmo-folder-update-threshold
1400                (> len elmo-folder-update-threshold)
1401                (not elmo-folder-update-confirm))
1402           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1403         appends))))
1404
1405 (luna-define-method elmo-message-fetch-bodystructure ((folder elmo-folder)
1406                                                       number strategy)
1407   nil)
1408
1409 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1410                                         number strategy
1411                                         &optional
1412                                         section
1413                                         outbuf
1414                                         unread)
1415   (let (result)
1416     (prog1
1417         (if outbuf
1418             (with-current-buffer outbuf
1419               (erase-buffer)
1420               (setq result (elmo-message-fetch-with-cache-process
1421                             folder number strategy section unread)))
1422           (with-temp-buffer
1423             (setq result (elmo-message-fetch-with-cache-process
1424                           folder number strategy section unread))
1425             (buffer-string)))
1426       (when (and result
1427                  (not unread)
1428                  (elmo-message-flagged-p folder number 'unread))
1429         (elmo-message-unset-flag folder number 'unread 'local)))))
1430
1431 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1432                                                            number strategy
1433                                                            &optional
1434                                                            section unread)
1435   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1436         (method-priorities
1437          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1438                 '(entity cache))
1439                ((elmo-fetch-strategy-use-cache strategy)
1440                 '(cache entity))
1441                (t
1442                 '(entity))))
1443         result err)
1444     (while (and method-priorities
1445                 (null result))
1446       (setq result
1447             (case (car method-priorities)
1448               (cache
1449                (elmo-file-cache-load cache-path section))
1450               (entity
1451                (when (and (condition-case error
1452                               (elmo-message-fetch-internal folder number
1453                                                            strategy
1454                                                            section
1455                                                            unread)
1456                             (error (setq err error) nil))
1457                           (> (buffer-size) 0))
1458                  (when (and (elmo-fetch-strategy-save-cache strategy)
1459                             cache-path)
1460                    (elmo-file-cache-save cache-path section))
1461                  t)))
1462             method-priorities (cdr method-priorities)))
1463     (or result
1464         (and err (signal (car err) (cdr err))))))
1465
1466 (defun elmo-folder-kill-messages-range (folder beg end)
1467   (elmo-folder-set-killed-list-internal
1468    folder
1469    (nconc
1470     (elmo-folder-killed-list-internal folder)
1471     (list (cons beg end)))))
1472
1473 (defun elmo-folder-kill-messages (folder numbers)
1474   "Kill(hide) messages in the FOLDER with NUMBERS."
1475   (elmo-folder-set-killed-list-internal
1476    folder
1477    (elmo-number-set-append-list
1478     (elmo-folder-killed-list-internal folder)
1479     numbers))
1480   (elmo-folder-unset-flag folder numbers 'all 'local-only))
1481
1482 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1483                                        &optional keep-killed)
1484   (unless keep-killed
1485     (elmo-folder-set-killed-list-internal folder nil))
1486   (if (eq elmo-msgdb-convert-type 'sync)
1487       (elmo-folder-set-msgdb-internal
1488        folder
1489        (elmo-make-msgdb (elmo-folder-msgdb-path folder)))
1490     (elmo-msgdb-clear (elmo-folder-msgdb folder))))
1491
1492 (luna-define-generic elmo-folder-synchronize (folder
1493                                               &optional
1494                                               disable-killed
1495                                               ignore-msgdb
1496                                               no-check
1497                                               mask)
1498   "Synchronize the folder data to the newest status.
1499 FOLDER is the ELMO folder structure.
1500
1501 If optional DISABLE-KILLED is non-nil, killed messages are also synchronized.
1502 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1503 flag status.
1504 If NO-CHECK is non-nil, rechecking folder is skipped.
1505 If optional argument MASK is specified and is a list of message numbers,
1506 synchronize messages only which are contained the list.
1507 Return amount of cross-posted messages.
1508 If update process is interrupted, return nil.")
1509
1510 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1511                                              &optional
1512                                              disable-killed
1513                                              ignore-msgdb
1514                                              no-check
1515                                              mask)
1516   (let ((old-msgdb (elmo-folder-msgdb folder))
1517         (killed-list (elmo-folder-killed-list-internal folder))
1518         (flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1519         (before-append t))
1520     (when ignore-msgdb
1521       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1522       (elmo-folder-clear folder (not disable-killed)))
1523     (unless no-check (elmo-folder-check folder))
1524     (condition-case nil
1525         (let ((killed-list (elmo-folder-killed-list-internal folder))
1526               diff-new diff-del
1527               delete-list new-list new-msgdb crossed)
1528           (message "Checking folder diff...")
1529           (elmo-set-list
1530            '(diff-new diff-del)
1531            (elmo-list-diff (elmo-folder-list-messages folder)
1532                            (elmo-folder-list-messages folder nil 'in-msgdb)))
1533           (when diff-new
1534             (unless disable-killed
1535               (setq diff-new (elmo-living-messages diff-new killed-list)))
1536             (when mask
1537               (setq diff-new (elmo-list-filter mask diff-new))))
1538           (message "Checking folder diff...done")
1539           (setq new-list (elmo-folder-confirm-appends diff-new))
1540           ;; Append to killed list as (MIN-OF-DISAPPEARED . MAX-OF-DISAPPEARED)
1541           (when (not (eq (length diff-new)
1542                          (length new-list)))
1543             (let* ((diff (elmo-list-diff diff-new new-list))
1544                    (disappeared (car diff)))
1545               (when disappeared
1546                 (elmo-folder-kill-messages-range folder
1547                                                  (car disappeared)
1548                                                  (elmo-last disappeared)))))
1549           (setq delete-list diff-del)
1550           (if (and (null diff-new) (null diff-del))
1551               (progn
1552                 (elmo-folder-update-number folder)
1553                 (elmo-folder-process-crosspost folder)
1554                 0)                      ; `0' means no updates.
1555             (when delete-list
1556               (elmo-folder-detach-messages folder delete-list))
1557             (when new-list
1558               (elmo-msgdb-out-of-date-messages (elmo-folder-msgdb folder))
1559               (setq new-msgdb (elmo-folder-msgdb-create
1560                                folder new-list flag-table))
1561               ;; Clear flag-table
1562               (if (elmo-folder-persistent-p folder)
1563                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1564                                         nil))
1565               (setq before-append nil)
1566               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1567               ;; process crosspost.
1568               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).
1569               (elmo-folder-process-crosspost folder))
1570             ;; return value.
1571             (or crossed 0)))
1572       (quit
1573        ;; Resume to the original status.
1574        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1575        (elmo-folder-set-killed-list-internal folder killed-list)
1576        nil))))
1577
1578 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1579   "Remove messages with NUMBERS from MSGDB.")
1580
1581 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1582                                                  numbers)
1583   (when (elmo-msgdb-delete-messages (elmo-folder-msgdb folder) numbers)
1584     ;; Remove NUMBERS from killed message list.
1585     (elmo-folder-set-killed-list-internal
1586      folder
1587      (elmo-number-set-delete-list
1588       (elmo-folder-killed-list-internal folder)
1589       numbers))
1590     t))
1591
1592 (luna-define-generic elmo-folder-length (folder)
1593   "Return number of messages in the FOLDER.")
1594
1595 (luna-define-method elmo-folder-length ((folder elmo-folder))
1596   (if (elmo-folder-msgdb-internal folder)
1597       (elmo-msgdb-length (elmo-folder-msgdb folder))
1598     0))
1599
1600 (defun elmo-folder-msgdb-load (folder &optional silent)
1601   (unless silent
1602     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1603   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1604     (elmo-folder-set-info-max-by-numdb
1605      folder
1606      (elmo-msgdb-list-messages msgdb))
1607     (unless silent
1608       (message "Loading msgdb for %s...done"
1609                (elmo-folder-name-internal folder)))
1610     msgdb))
1611
1612 (defun elmo-msgdb-delete-path (folder)
1613   (let ((path (elmo-folder-msgdb-path folder)))
1614     (if (file-directory-p path)
1615         (elmo-delete-directory path t))))
1616
1617 (defun elmo-msgdb-rename-path (old-folder new-folder)
1618   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1619          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1620          (new-dir (directory-file-name (file-name-directory new))))
1621     (if (not (file-directory-p old))
1622         ()
1623       (if (file-exists-p new)
1624           (error "Already exists directory: %s" new)
1625         (if (not (file-exists-p new-dir))
1626             (elmo-make-directory new-dir))
1627         (rename-file old new)))))
1628
1629 (defun elmo-setup-subscribed-newsgroups (groups)
1630   "Setup subscribed newsgroups.
1631 GROUPS is a list of newsgroup name string.
1632 Return a hashtable for newsgroups."
1633   (let ((hashtb (or elmo-newsgroups-hashtb
1634                     (setq elmo-newsgroups-hashtb
1635                           (elmo-make-hash (length groups))))))
1636     (dolist (group groups)
1637       (or (elmo-get-hash-val group hashtb)
1638           (elmo-set-hash-val group nil hashtb)))
1639     (setq elmo-newsgroups-hashtb hashtb)))
1640
1641 (defvar elmo-crosspost-message-alist-modified nil)
1642 (defun elmo-crosspost-message-alist-load ()
1643   "Load crosspost message alist."
1644   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1645   (setq elmo-crosspost-message-alist-modified nil))
1646
1647 (defun elmo-crosspost-message-alist-save ()
1648   "Save crosspost message alist."
1649   (when elmo-crosspost-message-alist-modified
1650     (let ((alist elmo-crosspost-message-alist)
1651           newsgroups)
1652       (while alist
1653         (setq newsgroups
1654               (elmo-delete-if
1655                '(lambda (x)
1656                   (not (intern-soft x elmo-newsgroups-hashtb)))
1657                (nth 1 (car alist))))
1658         (if newsgroups
1659             (setcar (cdar alist) newsgroups)
1660           (setq elmo-crosspost-message-alist
1661                 (delete (car alist) elmo-crosspost-message-alist)))
1662         (setq alist (cdr alist)))
1663       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1664       (setq elmo-crosspost-message-alist-modified nil))))
1665
1666 (defun elmo-folder-make-temporary-directory (folder)
1667   ;; Make a temporary directory for FOLDER.
1668   (let ((temp-dir (make-temp-name
1669                    (concat
1670                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1671                     "elmo"))))
1672     (elmo-make-directory temp-dir)
1673     temp-dir))
1674
1675 ;; Event notification/observer framework
1676 (eval-and-compile
1677   (luna-define-class elmo-event-handler ()))
1678
1679 (luna-define-generic elmo-event-handler-flag-changed (handler numbers)
1680   "Notify flag of the messages with NUMBERS is changed.")
1681
1682 (luna-define-generic elmo-event-handler-cache-changed (handler number)
1683   "Called when cache status of the message with NUMBER is changed.")
1684
1685 (defun elmo-folder-add-handler (folder handler)
1686   (unless (memq handler (elmo-folder-handlers-internal folder))
1687     (elmo-folder-set-handlers-internal
1688      folder
1689      (cons handler (elmo-folder-handlers-internal folder)))))
1690
1691 (defun elmo-folder-remove-handler (folder handler)
1692   (elmo-folder-set-handlers-internal
1693    folder
1694    (delq handler (elmo-folder-handlers-internal folder))))
1695
1696 (defun elmo-folder-notify-event (folder event &rest args)
1697   (when (elmo-folder-handlers-internal folder)
1698     (let ((message (format "elmo-event-handler-%s" event)))
1699       (dolist (handler (elmo-folder-handlers-internal folder))
1700         (apply #'luna-send handler message handler args)))))
1701
1702 ;;;
1703 (defun elmo-init ()
1704   "Initialize ELMO module."
1705   (elmo-crosspost-message-alist-load)
1706   (elmo-resque-obsolete-variables)
1707   (elmo-dop-queue-load)
1708   (run-hooks 'elmo-init-hook))
1709
1710 (defun elmo-quit ()
1711   "Quit and cleanup ELMO."
1712   (elmo-crosspost-message-alist-save)
1713   (elmo-dop-queue-save)
1714   ;; Not implemented yet.
1715   (let ((types elmo-folder-type-alist)
1716         class)
1717     (while types
1718       (setq class
1719             (luna-find-class
1720              (intern (format "elmo-%s-folder"
1721                              (symbol-name (cdr (car types)))))))
1722       ;; Call all folder's `elmo-quit' method.
1723       (if class
1724           (dolist (func (luna-class-find-functions class 'elmo-quit))
1725             (funcall func nil)))
1726       (setq types (cdr types)))))
1727
1728 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1729                                                  new-folder)
1730   (error "Cannot rename %s folder"
1731          (symbol-name (elmo-folder-type-internal folder))))
1732
1733 ;;; Define folders.
1734 (elmo-define-folder ?% 'imap4)
1735 (elmo-define-folder ?-  'nntp)
1736 (elmo-define-folder ?\+ 'localdir)
1737 (elmo-define-folder ?\* 'multi)
1738 (elmo-define-folder ?\/ 'filter)
1739 (elmo-define-folder ?\$ 'archive)
1740 (elmo-define-folder ?&  'pop3)
1741 (elmo-define-folder ?=  'localnews)
1742 (elmo-define-folder ?|  'pipe)
1743 (elmo-define-folder ?.  'maildir)
1744 (elmo-define-folder ?'  'internal)
1745 (elmo-define-folder ?\[  'nmz)
1746 (elmo-define-folder ?@  'shimbun)
1747
1748 ;;; Obsolete variables.
1749 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1750                                'elmo-imap4-default-mailbox)
1751 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1752                                'elmo-imap4-default-server)
1753 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1754                                'elmo-imap4-default-authenticate-type)
1755 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1756                                'elmo-imap4-default-user)
1757 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1758                                'elmo-imap4-default-port)
1759 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1760                                'elmo-imap4-default-stream-type)
1761 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1762                                'elmo-nntp-default-server)
1763 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1764                                'elmo-nntp-default-user)
1765 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1766                                'elmo-nntp-default-port)
1767 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1768                                'elmo-nntp-default-stream-type)
1769 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1770                                'elmo-pop3-default-server)
1771 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1772                                'elmo-pop3-default-user)
1773 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1774                                'elmo-pop3-default-authenticate-type)
1775 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1776                                'elmo-pop3-default-port)
1777 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1778                                'elmo-pop3-default-stream-type)
1779 (elmo-define-obsolete-variable 'elmo-cache-dirname
1780                                'elmo-cache-directory)
1781 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1782                                'elmo-msgdb-directory)
1783 (elmo-define-obsolete-variable 'elmo-global-flag-list
1784                                'elmo-global-flags)
1785
1786 ;; Obsolete functions.
1787 ;; 2001-12-11: *-dir -> *-directory
1788 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1789 (make-obsolete 'elmo-folder-make-temp-dir
1790                'elmo-folder-make-temporary-directory)
1791
1792 (require 'product)
1793 (product-provide (provide 'elmo) (require 'elmo-version))
1794
1795 ;;; elmo.el ends here