elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38 (require 'elmo-signal)
  39
  40 (eval-when-compile (require 'cl))
  41
  42 (if (or (featurep 'dbm)
  43         (featurep 'gnudbm)
  44         (featurep 'berkdb)
  45         (featurep 'berkeley-db))
  46     (require 'elmo-database))
  47
  48 (defcustom elmo-message-fetch-threshold 30000
  49   "Fetch threshold."
  50   :type '(choice (integer :tag "Threshold (bytes)")
  51                  (const :tag "No limitation" nil))
  52   :group 'elmo)
  53
  54 (defcustom elmo-message-fetch-confirm t
  55   "If non-nil, confirm fetching if message size is larger than
  56 `elmo-message-fetch-threshold'.
  57 Otherwise, entire fetching of the message is aborted without confirmation."
  58   :type 'boolean
  59   :group 'elmo)
  60
  61 (defcustom elmo-folder-update-threshold 500
  62   "Update threshold."
  63   :type '(choice (integer :tag "Number of messages")
  64                  (const :tag "No limitation" nil))
  65   :group 'elmo)
  66
  67 (defcustom elmo-folder-update-confirm t
  68   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  69   :type 'boolean
  70   :group 'elmo)
  71
  72 (defcustom elmo-msgdb-path-encode-threshold nil
  73   "*Encode msgdb path if its length is longer than this value."
  74   :type '(choice (const :tag "No encode" nil)
  75                  number)
  76   :group 'elmo)
  77
  78 (defvar elmo-message-displaying nil
  79   "A global switch to indicate message is displaying or not.")
  80
  81 ;;; internal
  82 (defvar elmo-folder-type-alist nil)
  83
  84 (defvar elmo-newsgroups-hashtb nil)
  85
  86 (elmo-define-error 'elmo-error "Error" 'error)
  87 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  88 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  89 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  90
  91 ;; Event declarations
  92 (elmo-define-signal flag-changing (number old-flags new-flags)
  93   "Notify the changing flag of the messages with NUMBER.")
  94
  95 (elmo-define-signal flag-changed (numbers)
  96   "Notify the change flag of the messages with NUMBERS.")
  97
  98 (elmo-define-signal cache-changed (number)
  99   "Notify the change cache status of the message with NUMBER.")
 100
 101 (elmo-define-signal update-overview (number)
 102   "Notify update overview of the message with NUMBER.")
 103
 104 (elmo-define-signal message-number-changed (old-number new-number)
 105   "Notify change of message number within the folder.")
 106
 107 ;; autoloads
 108 (eval-and-compile
 109   (autoload 'md5 "md5")
 110   (autoload 'elmo-dop-queue-flush "elmo-dop")
 111   (autoload 'elmo-nntp-post "elmo-nntp")
 112   (autoload 'elmo-global-flag-p "elmo-flag")
 113   (autoload 'elmo-local-flag-p "elmo-flag")
 114   (autoload 'elmo-global-flag-detach "elmo-flag")
 115   (autoload 'elmo-global-flag-detach-messages "elmo-flag")
 116   (autoload 'elmo-global-flag-set "elmo-flag")
 117   (autoload 'elmo-get-global-flags "elmo-flag")
 118   (autoload 'elmo-global-flags-initialize "elmo-flag")
 119   (autoload 'elmo-global-mark-migrate "elmo-flag")
 120   (autoload 'elmo-folder-list-global-flag-messages "elmo-flag"))
 121
 122 (defun elmo-define-folder (prefix backend)
 123   "Define a folder.
 124 If a folder name begins with PREFIX, use BACKEND."
 125   (let ((pair (assq prefix elmo-folder-type-alist)))
 126     (if pair
 127         (progn
 128           (setcar pair prefix)
 129           (setcdr pair backend))
 130       (setq elmo-folder-type-alist (cons (cons prefix backend)
 131                                          elmo-folder-type-alist)))))
 132
 133 (defmacro elmo-folder-type (name)
 134   "Get folder type from NAME string."
 135   `(and (stringp ,name)
 136         (cdr (assoc (string-to-char ,name) elmo-folder-type-alist))))
 137
 138 ;;; ELMO folder
 139 ;; A elmo folder provides uniformed (orchestrated) access
 140 ;; to the internet messages.
 141 (eval-and-compile
 142   (luna-define-class elmo-folder () (type   ; folder type symbol.
 143                                      name   ; orignal folder name string.
 144                                      prefix ; prefix for folder name
 145                                      path   ; directory path for msgdb.
 146                                      msgdb  ; msgdb (may be nil).
 147                                      killed-list  ; killed list.
 148                                      flag-table   ; flag table.
 149                                      persistent   ; non-nil if persistent.
 150                                      process-duplicates  ; read or hide
 151                                      biff   ; folder for biff
 152                                      ))
 153   (luna-define-internal-accessors 'elmo-folder))
 154
 155 (luna-define-generic elmo-folder-initialize (folder name)
 156   ;; Initialize a FOLDER structure with NAME."
 157   )
 158
 159 (defmacro elmo-folder-send (folder message &rest args)
 160   "Let FOLDER receive the MESSAGE with ARGS."
 161   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 162
 163 ;;;###autoload
 164 (defun elmo-make-folder (name &optional non-persistent)
 165   "Make an ELMO folder structure specified by NAME.
 166 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 167   (let ((type (elmo-folder-type name))
 168         prefix split class folder original)
 169     (setq original (elmo-string name))
 170     (if type
 171         (progn
 172           (setq prefix (elmo-string (substring name 0 1)))
 173           (setq name (elmo-string (substring name 1))))
 174       (setq type (intern (car (setq split (split-string name ":")))))
 175       (if (>= (length split) 2)
 176           (setq name (substring name (+ 1 (length (car split)))))
 177         (error "Error in folder name `%s'" original))
 178       (setq prefix (concat (car split) ":")))
 179     (setq class (format "elmo-%s" (symbol-name type)))
 180     (require (intern class))
 181     (setq folder (luna-make-entity (intern (concat class "-folder"))
 182                                    :type type
 183                                    :prefix prefix
 184                                    :name original
 185                                    :persistent (not non-persistent)))
 186     (save-match-data
 187       (elmo-folder-send folder 'elmo-folder-initialize name))))
 188
 189 ;; Note that this function is for internal use only.
 190 (luna-define-generic elmo-folder-msgdb (folder)
 191   "Return the msgdb of FOLDER (on-demand loading).
 192 \(For internal use only.\)")
 193
 194 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 195   (or (elmo-folder-msgdb-internal folder)
 196       (elmo-folder-set-msgdb-internal folder
 197                                       (elmo-folder-msgdb-load folder))))
 198
 199 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 200   "Open and setup (load saved status) FOLDER.
 201 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 202 \(otherwise, msgdb is loaded on-demand)")
 203
 204 (luna-define-generic elmo-folder-open-internal (folder)
 205   "Open FOLDER (without loading saved folder status).")
 206
 207 (luna-define-generic elmo-folder-check (folder)
 208   "Check the FOLDER to obtain newest information at the next list operation.")
 209
 210 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 211   "Clear FOLDER to the initial state.
 212 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 213
 214 (luna-define-generic elmo-folder-commit (folder)
 215   "Save current status of FOLDER.")
 216
 217 (luna-define-generic elmo-folder-close (folder)
 218   "Close, save and clearnup FOLDER.")
 219
 220 (luna-define-generic elmo-folder-close-internal (folder)
 221   "Close FOLDER (without saving folder status).")
 222
 223 (luna-define-generic elmo-folder-plugged-p (folder)
 224   "Returns t if FOLDER is plugged.")
 225
 226 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 227   "Set FOLDER as plugged.")
 228
 229 (luna-define-generic elmo-net-port-info (folder)
 230   "Get port information of FOLDER.")
 231
 232 (luna-define-generic elmo-folder-use-flag-p (folder)
 233   "Returns t if FOLDER treats unread/important flag itself.")
 234
 235 (luna-define-generic elmo-folder-diff (folder)
 236   "Get diff of FOLDER.
 237 Return value is cons cell or list:
 238  - a cons cell (new . all)
 239  - a list (new unread all)")
 240
 241 (luna-define-generic elmo-folder-status (folder)
 242   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 243
 244 (luna-define-generic elmo-folder-reserve-status-p (folder)
 245   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 246
 247 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 248                                                        in-msgdb)
 249   "Return a list of message numbers contained in FOLDER.
 250 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 251 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 252
 253 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 254                                                &optional visible-only in-msgdb)
 255   (let ((list (if in-msgdb
 256                   t
 257                 (elmo-folder-list-messages-internal folder visible-only)))
 258         (killed-list (elmo-folder-killed-list-internal folder)))
 259     (unless (listp list)
 260       ;; Use current list.
 261       (setq list (elmo-msgdb-list-messages (elmo-folder-msgdb folder))))
 262     (if visible-only
 263         (elmo-living-messages list killed-list)
 264       (if (and in-msgdb killed-list)
 265           (elmo-uniq-sorted-list
 266            (sort (nconc (elmo-number-set-to-number-list killed-list) list) #'<)
 267            #'eq)
 268         list))))
 269
 270 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 271                                                                 visible-only)
 272   ;; Return a list of message numbers contained in FOLDER.
 273   ;; Return t if the message list is not available.
 274   )
 275
 276 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 277   "List messages in the FOLDER with FLAG.
 278 FLAG is a symbol which is one of the following:
 279   `new'        (new messages)
 280   `unread'     (unread messages (new messages are included))
 281   `answered'   (answered or forwarded)
 282   `important'  (marked as important)
 283 'sugar' flags:
 284   `read'       (not unread)
 285   `digest'     (unread + important + other flags)
 286   `any'        (digest + answered + other flags)
 287 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 288
 289 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 290                                               &optional in-msgdb)
 291   (let ((msgs (if in-msgdb
 292                   t
 293                 (elmo-folder-list-flagged-internal folder flag))))
 294     (unless (listp msgs)
 295       (setq msgs (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag)))
 296     (if in-msgdb
 297         msgs
 298       (elmo-uniq-list
 299        (nconc (elmo-folder-list-global-flag-messages folder flag) msgs)
 300        #'delq))))
 301
 302 (luna-define-generic elmo-folder-list-flagged-internal (folder flag)
 303   "Return a list of message in the FOLDER with FLAG.
 304 Return t if the message list is not available.")
 305
 306 (luna-define-method elmo-folder-list-flagged-internal ((folder elmo-folder)
 307                                                        flag)
 308   t)
 309
 310 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 311   "Returns a list of subfolders contained in FOLDER.
 312 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 313 \(a folder which have children is returned as a list\)
 314 Otherwise, all descendent folders are returned.")
 315
 316 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 317   "Return non-nil when FOLDER has subfolders.")
 318
 319 (luna-define-generic elmo-folder-exists-p (folder)
 320   "Returns non-nil when FOLDER exists.")
 321
 322 (luna-define-generic elmo-folder-creatable-p (folder)
 323   "Returns non-nil when FOLDER is creatable.")
 324
 325 (luna-define-generic elmo-folder-writable-p (folder)
 326   "Returns non-nil when FOLDER is writable.")
 327
 328 (luna-define-generic elmo-folder-persistent-p (folder)
 329   "Return non-nil when FOLDER is persistent.")
 330
 331 (luna-define-generic elmo-folder-create (folder)
 332   "Create a FOLDER.")
 333
 334 (luna-define-generic elmo-message-deletable-p (folder number)
 335   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 336
 337 (luna-define-generic elmo-folder-delete (folder)
 338   "Delete FOLDER completely.")
 339
 340 (luna-define-generic elmo-folder-rename (folder new-name)
 341   "Rename FOLDER to NEW-NAME (string).")
 342
 343 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 344   "Delete messages with msgdb entity.
 345 FOLDER is the ELMO folder structure.
 346 NUMBERS is a list of message numbers to be deleted.
 347 It is not recommended to use this function other than internal use.
 348 Use `elmo-folder-move-messages' with dst-folder 'null instead.")
 349
 350 (luna-define-generic elmo-folder-delete-messages-internal (folder numbers)
 351   "Delete messages, but no delete msgdb entity.
 352 FOLDER is the ELMO folder structure.
 353 NUMBERS is a list of message numbers to be deleted.
 354 Override this method by each implement of `elmo-folder'.")
 355
 356 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 357   "Search and return list of message numbers.
 358 FOLDER is the ELMO folder structure.
 359 CONDITION is a condition structure for searching.
 360 If optional argument NUMBERS is specified and is a list of message numbers,
 361 messages are searched from the list.")
 362
 363 (luna-define-generic elmo-message-match-condition (folder number
 364                                                           condition
 365                                                           numbers)
 366   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 367 CONDITION is a condition structure for testing.
 368 NUMBERS is a list of message numbers,
 369 use to be test for \"last\" and \"first\" predicates.")
 370
 371 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 372   "Create a message database (implemented in each backends).
 373 FOLDER is the ELMO folder structure.
 374 NUMBERS is a list of message numbers to create msgdb.
 375 FLAG-TABLE is a hashtable of message-id and flag.")
 376
 377 (luna-define-generic elmo-folder-set-flag (folder numbers flag
 378                                                   &optional is-local)
 379   "Set messages flag.
 380 FOLDER is a ELMO folder structure.
 381 NUMBERS is a list of message number to set flag.
 382
 383 FLAG is a symbol which is one of the following:
 384   `unread'    (set the message as unread)
 385   `answered'  (set the message as answered)
 386   `important' (set the message as important)
 387 'sugar' flag:
 388   `read'      (remove new and unread flags)
 389 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 390
 391 (luna-define-generic elmo-folder-unset-flag (folder numbers flag
 392                                                     &optional is-local)
 393   "Unset messages flag.
 394 FOLDER is a ELMO folder structure.
 395 NUMBERS is a list of message number to unset flag.
 396
 397 FLAG is a symbol which is one of the following:
 398   `unread'    (remove unread and new flag)
 399   `answered'  (remove answered flag)
 400   `important' (remove important flag)
 401 'sugar' flag:
 402   `read'      (set unread flag)
 403   `all'       (remove all flags)
 404 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 405
 406 (luna-define-generic elmo-message-flag-available-p (folder number flag)
 407   "Return non-nil when a message in the FOLDER with NUMBER treats FLAG.")
 408
 409 (luna-define-generic elmo-folder-next-message-number (folder)
 410   "The next message number that will be assigned to a new message.
 411 FOLDER is the ELMO folder structure.")
 412
 413 (luna-define-generic elmo-folder-append-buffer (folder &optional flags
 414                                                        number)
 415   "Append current buffer as a new message.
 416 FOLDER is the destination folder (ELMO folder structure).
 417 FLAGS is the flag list for the appended message (list of symbols).
 418 If FLAGS contain `read', the message is appended as `not-unread'.
 419 If it is nil, the appended message will be treated as `new'.
 420 If optional argument NUMBER is specified, the new message number is set
 421 \(if possible\).
 422 Return nil on failure.")
 423
 424 (luna-define-generic elmo-folder-append-messages (folder
 425                                                   src-folder
 426                                                   numbers
 427                                                   &optional
 428                                                   same-number)
 429   "Append messages from folder.
 430 FOLDER is the ELMO folder structure.
 431 Caller should make sure FOLDER is `writable'.
 432 \(Can be checked with `elmo-folder-writable-p'\).
 433 SRC-FOLDER is the source ELMO folder structure.
 434 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 435 If second optional argument SAME-NUMBER is specified,
 436 message number is preserved \(if possible\).
 437 Returns a list of message numbers successfully appended.")
 438
 439 (luna-define-generic elmo-folder-pack-numbers (folder)
 440   "Pack message numbers of FOLDER.")
 441
 442 (luna-define-generic elmo-folder-update-number (folder)
 443   "Update number of FOLDER.")
 444
 445 (luna-define-generic elmo-folder-diff-async (folder)
 446   "Get diff of FOLDER asynchronously.")
 447
 448 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 449   "Expand path for FOLDER.")
 450
 451 (luna-define-generic elmo-folder-get-primitive-list (folder)
 452   "Get primitive folder structure list contained in FOLDER.")
 453
 454 (luna-define-generic elmo-folder-contains-type (folder type)
 455   "Returns t if FOLDER contains TYPE.")
 456
 457 (luna-define-generic elmo-folder-local-p (folder)
 458   "Returns t if FOLDER is local.")
 459
 460 (luna-define-generic elmo-folder-message-file-p (folder)
 461   "Returns t if all messages in the FOLDER are files.")
 462
 463 ;;; Message methods.
 464 (luna-define-generic elmo-message-use-cache-p (folder number)
 465   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 466
 467 (luna-define-generic elmo-message-file-name (folder number)
 468   "Return the file name of a message specified by FOLDER and NUMBER.")
 469
 470 ;;; For archive
 471
 472 ;;; Use original file
 473 (luna-define-generic elmo-folder-message-file-number-p (folder)
 474   "Return t if the file name in the FOLDER is the message number.")
 475
 476 (luna-define-generic elmo-folder-message-file-directory (folder)
 477   "Return the directory of the message files of FOLDER.")
 478
 479 ;;; Use temporary file
 480 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 481   "Return t if the messages in the FOLDER makes local temporary file.")
 482
 483 (luna-define-generic elmo-folder-message-make-temp-files (folder
 484                                                           numbers
 485                                                           &optional
 486                                                           start-number)
 487   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 488 If START-NUMBER is specified, temporary files begin from the number.
 489 Otherwise, same number is used for temporary files.
 490 Return newly created temporary directory name which contains temporary files.")
 491
 492 (luna-define-generic elmo-message-file-p (folder number)
 493   "Return t if message in the FOLDER with NUMBER is a file.")
 494
 495 (luna-define-generic elmo-message-flags (folder number)
 496   "Return a list of flags.
 497 FOLDER is a ELMO folder structure.
 498 NUMBER is a number of the message.")
 499
 500 (defun elmo-message-flags-for-append (folder number &optional message-id)
 501   "Return a list of flags for `elmo-folder-append-buffer'.
 502 FOLDER is a ELMO folder structure.
 503 NUMBER is a number of the message.
 504 If optional argument MESSAGES-ID is not specified, get it from current buffer."
 505   (let ((this-id (elmo-message-field folder number 'message-id)))
 506     (and this-id
 507          (string= this-id (or message-id
 508                               (elmo-msgdb-get-message-id-from-buffer)))
 509          (or (elmo-message-flags folder number)
 510              ;; message exists, but no flag.
 511              '(read)))))
 512
 513 (luna-define-method elmo-message-flag-available-p ((folder elmo-folder) number
 514                                                    flag)
 515   (elmo-msgdb-flag-available-p (elmo-folder-msgdb folder) flag))
 516
 517 (luna-define-method elmo-message-flags ((folder elmo-folder) number)
 518   (elmo-msgdb-flags (elmo-folder-msgdb folder) number))
 519
 520 (defsubst elmo-message-flagged-p (folder number flag)
 521   "Return non-nil if the message is set FLAG.
 522 FOLDER is a ELMO folder structure.
 523 NUMBER is a message number to test."
 524   (let ((cur-flags (elmo-message-flags folder number)))
 525     (case flag
 526       (read
 527        (not (memq 'unread cur-flags)))
 528       (t
 529        (memq flag cur-flags)))))
 530
 531 (luna-define-generic elmo-find-fetch-strategy (folder number
 532                                                       &optional
 533                                                       ignore-cache
 534                                                       require-entireness)
 535   "Return the message fetching strategy suitable for the message with NUMBER.
 536 FOLDER is the ELMO folder structure.
 537 If optional argument IGNORE-CACHE is non-nil, existing cache is ignored.
 538 If second optional argument REQUIRE-ENTIRENESS is non-nil,
 539 ensure that entireness of the returned strategy is entire.
 540 Returned value is a elmo-fetch-strategy object.
 541 If return value is nil, message should not be nil.")
 542
 543 (defmacro elmo-make-fetch-strategy (entireness
 544                                     &optional
 545                                     use-cache
 546                                     save-cache
 547                                     cache-path)
 548   "Make elmo-message-fetching strategy.
 549 ENTIRENESS is 'entire or 'section.
 550 'entire means fetch message entirely at once.
 551 'section means fetch message section by section.
 552 If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 553 existing cache is thrown away.
 554 If SAVE-CACHE is non-nil, fetched message is saved.
 555 CACHE-PATH is the cache path to be used as a message cache file."
 556   `(vector ,entireness ,use-cache ,save-cache ,cache-path))
 557
 558 (defmacro elmo-fetch-strategy-entireness (strategy)
 559   "Return entireness of STRATEGY."
 560   `(aref ,strategy 0))
 561
 562 (defmacro elmo-fetch-strategy-use-cache (strategy)
 563   "Return use-cache of STRATEGY."
 564   `(aref ,strategy 1))
 565
 566 (defmacro elmo-fetch-strategy-save-cache (strategy)
 567   "Return save-cache of STRATEGY."
 568   `(aref ,strategy 2))
 569
 570 (defmacro elmo-fetch-strategy-cache-path (strategy)
 571   "Return cache-path of STRATEGY."
 572   `(aref ,strategy 3))
 573
 574 (luna-define-method elmo-find-fetch-strategy ((folder elmo-folder) number
 575                                               &optional
 576                                               ignore-cache
 577                                               require-entireness)
 578   (let ((entity (elmo-message-entity folder number)))
 579     (if (null entity)
 580         (elmo-make-fetch-strategy 'entire)
 581       (let* ((size (elmo-message-entity-field entity 'size))
 582              (message-id (elmo-message-entity-field entity 'message-id))
 583              (cache-file (elmo-file-cache-get message-id))
 584              (use-cache (elmo-message-use-cache-p folder number)))
 585         (if (and (not ignore-cache)
 586                  use-cache
 587                  (eq (elmo-file-cache-status cache-file) 'entire))
 588             ;; Cache exists and use it.
 589             (elmo-make-fetch-strategy
 590              'entire
 591              t                          ; Use cache.
 592              use-cache                  ; Save cache.
 593              (elmo-file-cache-path cache-file))
 594           ;; No cache or ignore-cache.
 595           (if (and (not (elmo-folder-local-p folder))
 596                    (not require-entireness)
 597                    elmo-message-fetch-threshold
 598                    (integerp size)
 599                    (>= size elmo-message-fetch-threshold)
 600                    (or (not elmo-message-fetch-confirm)
 601                        (not (prog1
 602                                 (y-or-n-p
 603                                  (format "Fetch entire message(%dbytes)? "
 604                                          size))
 605                               (message "")))))
 606               ;; Don't fetch message at all.
 607               nil
 608             ;; Don't use existing cache and fetch entire message at once.
 609             (elmo-make-fetch-strategy
 610              'entire
 611              nil                        ; Don't use cache.
 612              use-cache                  ; Save cache.
 613              (elmo-file-cache-path cache-file))))))))
 614
 615 (luna-define-method elmo-folder-list-messages-internal
 616   ((folder elmo-folder) &optional visible-only)
 617   t)
 618
 619 (luna-define-generic elmo-message-encache (folder number &optional read)
 620   "Encache message in the FOLDER with NUMBER.
 621 If READ is non-nil, message is flaged as read.")
 622
 623 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 624                                           &optional read)
 625   (let (path)
 626     (with-temp-buffer
 627       (elmo-message-fetch
 628        folder number
 629        (elmo-make-fetch-strategy 'entire
 630                                  nil ;use-cache
 631                                  t   ;save-cache
 632                                  (setq path (elmo-file-cache-get-path
 633                                              (elmo-message-field
 634                                               folder number 'message-id))))
 635        (not read)))
 636     path))
 637
 638 (luna-define-generic elmo-message-fetch-bodystructure (folder number strategy)
 639   "Fetch bodystructure of the message in FOLDER with NUMBER using STRATEGY.")
 640
 641 (luna-define-generic elmo-message-fetch (folder number strategy
 642                                                 &optional
 643                                                 unread
 644                                                 section)
 645   "Fetch a message into current buffer.
 646 FOLDER is the ELMO folder structure.
 647 NUMBER is the number of the message in the FOLDER.
 648 STRATEGY is the message fetching strategy.
 649 If optional argument UNREAD is non-nil, message is not flaged as read.
 650 If second optional argument SECTION is specified, only the
 651 SECTION of the message is fetched (if possible).
 652 Returns non-nil if fetching was succeed.")
 653
 654 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 655                                                          &optional
 656                                                          section
 657                                                          unread)
 658   "Fetch a message into current buffer.
 659 FOLDER is the ELMO folder structure.
 660 NUMBER is the number of the message in the FOLDER.
 661 STRATEGY is the message fetching strategy.
 662 If optional argument SECTION is specified, only the SECTION of the message
 663 is fetched (if possible).
 664 If second optional argument UNREAD is non-nil, message is not flaged as read.
 665 Returns non-nil if fetching was succeed.")
 666
 667 (luna-define-generic elmo-message-fetch-field (folder number field)
 668   "Fetch a message field value.
 669 FOLDER is the ELMO folder structure.
 670 NUMBER is the number of the message in the FOLDER.
 671 FIELD is a symbol of the field name.")
 672
 673 (luna-define-generic elmo-message-folder (folder number)
 674   "Get primitive folder of the message.")
 675
 676 (luna-define-generic elmo-folder-process-crosspost (folder)
 677   "Process crosspost for FOLDER.
 678 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).")
 679
 680 (luna-define-generic elmo-folder-newsgroups (folder)
 681   "Return list of newsgroup name of FOLDER.")
 682
 683 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 684   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 685
 686 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 687   (if (listp condition)
 688       (or (elmo-folder-search-requires-msgdb-p-internal
 689            folder (nth 1 condition))
 690           (elmo-folder-search-requires-msgdb-p-internal
 691            folder (nth 2 condition)))
 692     (and (not (string= (elmo-filter-key condition) "last"))
 693          (not (string= (elmo-filter-key condition) "first")))))
 694
 695 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 696                                                          condition)
 697   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 698
 699 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 700   nil)
 701
 702 (luna-define-method elmo-folder-open ((folder elmo-folder)
 703                                       &optional load-msgdb)
 704   (elmo-generic-folder-open folder load-msgdb))
 705
 706 (defun elmo-generic-folder-open (folder load-msgdb)
 707   (let ((inhibit-quit t))
 708     (if load-msgdb (elmo-folder-msgdb folder))
 709     (elmo-folder-set-killed-list-internal
 710      folder
 711      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 712   (elmo-folder-open-internal folder))
 713
 714 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 715   nil ; default is do nothing.
 716   )
 717
 718 (luna-define-method elmo-folder-check ((folder elmo-folder))
 719   nil) ; default is noop.
 720
 721 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 722   (elmo-generic-folder-commit folder))
 723
 724 (defun elmo-generic-folder-commit (folder)
 725   (when (elmo-folder-persistent-p folder)
 726     (let ((msgdb (elmo-folder-msgdb-internal folder)))
 727       (when msgdb
 728         (when (elmo-msgdb-message-modified-p msgdb)
 729           (elmo-folder-set-info-max-by-numdb
 730            folder
 731            (elmo-folder-list-messages folder nil 'in-msgdb)))
 732         (elmo-msgdb-save msgdb)))
 733     (elmo-msgdb-killed-list-save
 734      (elmo-folder-msgdb-path folder)
 735      (elmo-folder-killed-list-internal folder))))
 736
 737 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 738   ;; do nothing.
 739   )
 740
 741 (luna-define-method elmo-folder-close ((folder elmo-folder))
 742   (elmo-generic-folder-close folder)
 743   (elmo-folder-close-internal folder))
 744
 745 (defun elmo-generic-folder-close (folder)
 746   (elmo-folder-commit folder)
 747   (elmo-folder-set-msgdb-internal folder nil)
 748   (elmo-folder-set-killed-list-internal folder nil))
 749
 750 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 751   t) ; default is plugged.
 752
 753 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 754                                              &optional add)
 755   nil) ; default is do nothing.
 756
 757 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 758   nil) ; default is no flag.
 759
 760 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 761   (elmo-folder-persistent-internal folder))
 762
 763 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 764   nil) ; default is not creatable.
 765
 766 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 767   nil) ; default is not writable.
 768
 769 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 770   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 771                              (elmo-folder-name-internal folder)))
 772     (elmo-msgdb-delete-path folder)
 773     t))
 774
 775 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 776   (let* ((new-folder (elmo-make-folder new-name)))
 777     (unless (eq (elmo-folder-type-internal folder)
 778                 (elmo-folder-type-internal new-folder))
 779       (error "Not same folder type"))
 780     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 781             (elmo-folder-exists-p new-folder))
 782         (error "Already exists folder: %s" new-name))
 783     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 784     (elmo-msgdb-rename-path folder new-folder)))
 785
 786 (luna-define-method elmo-folder-delete-messages ((folder elmo-folder)
 787                                                  numbers)
 788   (and (elmo-folder-delete-messages-internal folder numbers)
 789        (elmo-folder-detach-messages folder numbers)))
 790
 791 (luna-define-method elmo-folder-search ((folder elmo-folder)
 792                                         condition
 793                                         &optional numbers)
 794   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 795         (msgdb (elmo-folder-msgdb folder))
 796         results)
 797     (setq results (elmo-msgdb-search msgdb condition numbers))
 798     (if (listp results)
 799         results
 800       (let ((len (length numbers))
 801             matched)
 802         (elmo-with-progress-display (> len elmo-display-progress-threshold)
 803             (elmo-folder-search len "Searching...")
 804           (dolist (number numbers)
 805             (let (result)
 806               (setq result (elmo-msgdb-match-condition msgdb
 807                                                        condition
 808                                                        number
 809                                                        numbers))
 810               (when (elmo-filter-condition-p result)
 811                 (setq result (elmo-message-match-condition folder
 812                                                            number
 813                                                            condition
 814                                                            numbers)))
 815               (when result
 816                 (setq matched (cons number matched))))
 817             (elmo-progress-notify 'elmo-folder-search)))
 818         (message "Searching...done")
 819         (nreverse matched)))))
 820
 821 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 822                                                   number condition
 823                                                   numbers)
 824   (let* (cache cache-path
 825          (filename (cond
 826                     ((elmo-message-file-name folder number))
 827                     ((progn
 828                        (setq cache (elmo-file-cache-get
 829                                     (elmo-message-field folder number
 830                                                         'message-id)))
 831                        (setq cache-path (elmo-file-cache-path cache))
 832                        (and cache-path
 833                             (not (elmo-cache-path-section-p cache-path))))
 834                      cache-path))))
 835     (when (and filename (file-readable-p filename))
 836       (with-temp-buffer
 837         (set-buffer-multibyte nil)
 838         ;;(insert-file-contents-as-binary filename)
 839         (elmo-message-fetch folder number
 840                             (elmo-make-fetch-strategy 'entire
 841                                                       (and cache t)
 842                                                       nil
 843                                                       cache-path)
 844                             'unread)
 845         (set-buffer-multibyte default-enable-multibyte-characters)
 846         (decode-coding-region (point-min) (point-max)
 847                               elmo-mime-display-as-is-coding-system)
 848         (elmo-buffer-field-condition-match condition number numbers)))))
 849
 850 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 851   nil) ; default is noop.
 852
 853 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 854   nil) ; default is noop.
 855
 856 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 857   nil) ; default is not file.
 858
 859 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 860   nil) ; default is not number.
 861
 862 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 863   nil) ; default is not make temp file.
 864
 865 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 866                                                    number)
 867   nil) ; default is no name.
 868
 869 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 870   t)   ; default is local.
 871
 872 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 873   t)
 874
 875 ;; Flag table
 876 (luna-define-generic elmo-folder-flag-table (folder &optional if-exists)
 877   "Return the flag-table of FOLDER.
 878 If optional argument IF-EXISTS is nil, load on demand.
 879 \(For internal use only.\)")
 880
 881 (luna-define-generic elmo-folder-close-flag-table (folder)
 882   "Close flag-table of FOLDER.")
 883
 884 (luna-define-method elmo-folder-flag-table ((folder elmo-folder)
 885                                             &optional if-exists)
 886   (or (elmo-folder-flag-table-internal folder)
 887       (unless if-exists
 888         (elmo-folder-set-flag-table-internal
 889          folder
 890          (elmo-flag-table-load (elmo-folder-msgdb-path folder))))))
 891
 892 (luna-define-method elmo-folder-close-flag-table ((folder elmo-folder))
 893   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
 894                         (elmo-folder-flag-table folder))
 895   (elmo-folder-set-flag-table-internal folder nil))
 896
 897 (defun elmo-folder-preserve-flags (folder msgid flags)
 898   "Preserve FLAGS into FOLDER for a message that has MSGID."
 899   (when (and msgid flags)
 900     (let ((flag-table (elmo-folder-flag-table folder 'if-exists))
 901           load-now)
 902       (when (setq load-now (null flag-table))
 903         (setq flag-table (elmo-folder-flag-table folder)))
 904       (elmo-flag-table-set flag-table msgid flags)
 905       (when load-now
 906         (elmo-folder-close-flag-table folder)))))
 907
 908 ;;; Folder info
 909 ;; Folder info is a message number information cache (hashtable)
 910 (defsubst elmo-folder-get-info (folder &optional hashtb)
 911   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 912   (elmo-get-hash-val (elmo-folder-name-internal folder)
 913                      (or hashtb elmo-folder-info-hashtb)))
 914
 915 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 916   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 917   (let ((info (elmo-folder-get-info folder)))
 918     (when info
 919       (or new     (setq new     (nth 0 info)))
 920       (or unread  (setq unread  (nth 1 info)))
 921       (or numbers (setq numbers (nth 2 info)))
 922       (or max     (setq max     (nth 3 info))))
 923     (elmo-set-hash-val (elmo-folder-name-internal folder)
 924                        (list new unread numbers max)
 925                        elmo-folder-info-hashtb)))
 926
 927 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 928   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 929   (elmo-folder-set-info-hashtb
 930    folder
 931    (if numbers (apply #'max numbers) 0)
 932    nil ;;(length num-db)
 933    ))
 934
 935 (defun elmo-folder-get-info-max (folder)
 936   "Return max number of FODLER from folder info."
 937   (nth 3 (elmo-folder-get-info folder)))
 938
 939 (defun elmo-folder-get-info-length (folder)
 940   "Return length of FODLER from folder info."
 941   (nth 2 (elmo-folder-get-info folder)))
 942
 943 (defun elmo-folder-get-info-unread (folder)
 944   "Return unread of FODLER from folder info."
 945   (nth 1 (elmo-folder-get-info folder)))
 946
 947 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 948   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 949   (let* ((hashtb (or hashtb
 950                      (elmo-make-hash (length info-alist)))))
 951     (mapcar
 952      (lambda (x)
 953        (let ((info (cadr x)))
 954          (and (intern-soft (car x) hashtb)
 955               (elmo-set-hash-val (car x)
 956                                  (list (nth 2 info)   ;; new
 957                                        (nth 3 info)   ;; unread
 958                                        (nth 1 info)   ;; length
 959                                        (nth 0 info))  ;; max
 960                                  hashtb))))
 961      info-alist)
 962     (setq elmo-folder-info-hashtb hashtb)))
 963
 964 (defsubst elmo-diff-new (diff)
 965   (car diff))
 966
 967 (defsubst elmo-diff-unread (diff)
 968   (when (consp (cdr diff))
 969     (nth 1 diff)))
 970
 971 (defsubst elmo-diff-all (diff)
 972   (if (consp (cdr diff))
 973       (nth 2 diff)
 974     (cdr diff)))
 975
 976 (defsubst elmo-strict-folder-diff (folder)
 977   "Return folder diff information strictly from FOLDER."
 978   (let ((in-db (sort (elmo-folder-list-messages folder nil 'in-msgdb) '<))
 979         (in-folder  (elmo-folder-list-messages folder))
 980         append-list delete-list diff)
 981     (cons (if (equal in-folder in-db)
 982               0
 983             (setq diff (elmo-list-diff in-folder in-db))
 984             (setq append-list (car diff))
 985             (setq delete-list (cadr diff))
 986             (if append-list
 987                 (length append-list)
 988               (if delete-list
 989                   (- 0 (length delete-list))
 990                 0)))
 991           (length in-folder))))
 992
 993 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 994   (elmo-generic-folder-diff folder))
 995
 996 (defun elmo-generic-folder-diff (folder)
 997   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 998                                 elmo-strict-diff-folder-list)
 999       (elmo-strict-folder-diff folder)
1000     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
1001           (in-folder (elmo-folder-status folder))
1002           (in-db t)
1003           unsync messages
1004           in-db-max)
1005       (if (not cached-in-db-max)
1006           (let ((number-list (elmo-folder-list-messages folder
1007                                                         nil 'in-msgdb)))
1008             ;; No info-cache.
1009             (setq in-db number-list)
1010             (setq in-db-max (if in-db (apply #'max in-db) 0))
1011             (elmo-folder-set-info-hashtb folder in-db-max nil))
1012         (setq in-db-max cached-in-db-max))
1013       (setq unsync (if (and in-db (car in-folder))
1014                        (- (car in-folder) in-db-max)
1015                      (if (and in-folder (null in-db))
1016                          (cdr in-folder)
1017                        (car in-folder))))
1018       (setq messages (cdr in-folder))
1019       (if (and unsync messages (> unsync messages))
1020           (setq unsync messages))
1021       (cons (or unsync 0) (or messages 0)))))
1022
1023 (defvar elmo-folder-diff-async-callback nil)
1024 (defvar elmo-folder-diff-async-callback-data nil)
1025
1026 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
1027   (and elmo-folder-diff-async-callback
1028        (funcall elmo-folder-diff-async-callback
1029                 folder
1030                 (elmo-folder-diff folder))))
1031
1032 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
1033   (list folder))
1034
1035 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
1036   (eq (elmo-folder-type-internal folder) type))
1037
1038 (luna-define-method elmo-folder-next-message-number ((folder elmo-folder))
1039   (+ 1 (elmo-max-of-list (or (elmo-folder-list-messages folder)
1040                              '(0)))))
1041
1042 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
1043                                                  src-folder
1044                                                  numbers
1045                                                  &optional
1046                                                  same-number)
1047   (elmo-generic-folder-append-messages folder src-folder numbers
1048                                        same-number))
1049
1050 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1051                                                    same-number)
1052   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
1053         unseen table
1054         succeed-numbers failure cache id)
1055     (setq table (elmo-folder-flag-table folder))
1056     (with-temp-buffer
1057       (set-buffer-multibyte nil)
1058       (while numbers
1059         (setq failure nil
1060               id (and src-msgdb-exists
1061                       (elmo-message-field src-folder (car numbers)
1062                                           'message-id)))
1063         (condition-case nil
1064             (setq cache (elmo-file-cache-get id)
1065                   failure
1066                   (not
1067                    (and
1068                     (elmo-message-fetch
1069                      src-folder (car numbers)
1070                      (if (elmo-folder-plugged-p src-folder)
1071                          (elmo-make-fetch-strategy
1072                           'entire 'maybe nil
1073                           (and cache (elmo-file-cache-path cache)))
1074                        (or (and elmo-enable-disconnected-operation
1075                                 cache
1076                                 (eq (elmo-file-cache-status cache) 'entire)
1077                                 (elmo-make-fetch-strategy
1078                                  'entire t nil
1079                                  (elmo-file-cache-path cache)))
1080                            (error "Unplugged")))
1081                      'unread)
1082                     (> (buffer-size) 0)
1083                     (elmo-folder-append-buffer
1084                      folder
1085                      (elmo-message-flags-for-append src-folder (car numbers))
1086                      (if same-number (car numbers))))))
1087           (error (setq failure t)))
1088         ;; FETCH & APPEND finished
1089         (unless failure
1090           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1091         (elmo-progress-notify 'elmo-folder-move-messages)
1092         (setq numbers (cdr numbers)))
1093       (when (elmo-folder-persistent-p folder)
1094         (elmo-folder-close-flag-table folder))
1095       succeed-numbers)))
1096
1097 ;; Arguments should be reduced.
1098 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1099                                              &optional
1100                                              no-delete
1101                                              same-number)
1102   (save-excursion
1103     (let* ((messages msgs)
1104            (elmo-inhibit-display-retrieval-progress t)
1105            (len (length msgs))
1106            succeeds i result)
1107       (if (eq dst-folder 'null)
1108           (setq succeeds messages)
1109         (unless (elmo-folder-writable-p dst-folder)
1110           (error "move: %d is not writable"
1111                  (elmo-folder-name-internal dst-folder)))
1112         (when messages
1113           ;; src is already opened.
1114           (elmo-folder-open-internal dst-folder)
1115           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1116                                                               src-folder
1117                                                               messages
1118                                                               same-number))
1119             (error "move: append message to %s failed"
1120                    (elmo-folder-name-internal dst-folder)))
1121           (elmo-folder-close dst-folder)))
1122       (if (and (not no-delete) succeeds)
1123           (progn
1124             (if (elmo-folder-delete-messages src-folder succeeds)
1125                 (progn
1126                   (elmo-global-flag-detach-messages
1127                    src-folder succeeds (eq dst-folder 'null))
1128                   (setq result t))
1129               (message "move: delete messages from %s failed."
1130                        (elmo-folder-name-internal src-folder))
1131               (setq result nil))
1132             result)
1133         (if no-delete
1134             (progn
1135               ;; (message "Copying messages...done")
1136               t)
1137           (if (eq len 0)
1138               (message "No message was moved.")
1139             (message "Moving messages failed.")
1140             nil ; failure
1141             ))))))
1142
1143 (defun elmo-folder-msgdb-path (folder)
1144   "Return the msgdb path for FOLDER."
1145   (or (elmo-folder-path-internal folder)
1146       (elmo-folder-set-path-internal
1147        folder
1148        (if (null elmo-msgdb-path-encode-threshold)
1149            (elmo-folder-expand-msgdb-path folder)
1150          (let* ((path (directory-file-name
1151                        (elmo-folder-expand-msgdb-path folder)))
1152                 (dirname (file-name-nondirectory path)))
1153            (if (<= (length dirname) elmo-msgdb-path-encode-threshold)
1154                path
1155              (require 'md5)
1156              (setq dirname (md5 dirname))
1157              (when (> (length dirname) elmo-msgdb-path-encode-threshold)
1158                (error "Cannot shrink msgdb path for `%s'"
1159                       (elmo-folder-name-internal folder)))
1160              (expand-file-name dirname (file-name-directory path))))))))
1161
1162 (luna-define-generic elmo-message-cached-p (folder number)
1163   "Return non-nil if the message is cached.")
1164
1165 (luna-define-method elmo-message-cached-p ((folder elmo-folder) number)
1166   (elmo-message-flagged-p folder number 'cached))
1167
1168 (defun elmo-message-accessible-p (folder number)
1169   "Get accessibility of the message.
1170 Return non-nil when message is accessible."
1171   (or (elmo-folder-plugged-p folder)
1172       (elmo-folder-local-p folder)
1173       (< number 0) ; in dop spool
1174       (elmo-message-cached-p folder number)))
1175
1176 (luna-define-generic elmo-message-set-cached (folder number cached)
1177   "Set cache status of the message in the msgdb.
1178 FOLDER is the ELMO folder structure.
1179 NUMBER is a number of the message.
1180 If CACHED is t, message is set as cached.")
1181
1182 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1183                                              number cached)
1184   (if cached
1185       (elmo-msgdb-set-flag (elmo-folder-msgdb folder) number 'cached)
1186     (elmo-msgdb-unset-flag (elmo-folder-msgdb folder) number 'cached))
1187   (elmo-emit-signal 'cache-changed folder number))
1188
1189 (defun elmo-message-copy-entity (entity)
1190   (elmo-msgdb-copy-message-entity (elmo-message-entity-handler entity)
1191                                   entity))
1192
1193 (luna-define-generic elmo-message-number (folder message-id)
1194   "Get message number from MSGDB which corresponds to MESSAGE-ID.")
1195
1196 (luna-define-method elmo-message-number ((folder elmo-folder) message-id)
1197   (elmo-msgdb-message-number (elmo-folder-msgdb folder) message-id))
1198
1199 (luna-define-generic elmo-message-entity (folder key)
1200   "Return the message-entity structure which matches to the KEY.
1201 KEY is a number or a string.
1202 A number is for message number in the FOLDER.
1203 A string is for message-id of the message.")
1204
1205 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1206   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1207
1208 (luna-define-generic elmo-message-entity-parent (folder entity)
1209   "Return the parent message-entity structure in the FOLDER.
1210 ENTITY is the message-entity to get the parent.")
1211
1212 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1213   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1214
1215 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1216 (def-edebug-spec elmo-folder-do-each-message-entity
1217   ((symbolp form &rest form) &rest form))
1218
1219 (defsubst elmo-folder-list-message-entities (folder)
1220   ;; List all message entities in the FOLDER.
1221   (mapcar
1222    (lambda (number) (elmo-message-entity folder number))
1223    (elmo-folder-list-messages folder nil t))) ; XXX killed-list is not used.
1224
1225 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1226   "Iterator for message entity in the folder.
1227 \(elmo-folder-do-each-message-entity \(entity folder\)
1228  ... do the process using entity...
1229 \)"
1230   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1231      ,@form))
1232
1233 (luna-define-generic elmo-folder-count-flags (folder)
1234   "Count flagged message number in the msgdb of the FOLDER.
1235 Return alist of flag and numbers.
1236 Example:
1237 \(\(new . 10\)
1238   \(unread . 20\)
1239   \(answered . 3\)\)")
1240
1241 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1242   (elmo-msgdb-flag-count (elmo-folder-msgdb folder)))
1243
1244 (defun elmo-message-set-flag (folder number flag &optional is-local)
1245   "Set message flag.
1246 FOLDER is a ELMO folder structure.
1247 NUMBER is a message number to set flag.
1248
1249 FLAG is a symbol which is one of the following:
1250   `unread'    (set the message as unread)
1251   `answered'  (set the message as answered)
1252   `important' (set the message as important)
1253 'sugar' flag:
1254   `read'      (remove new and unread flags)
1255 If optional IS-LOCAL is non-nil, update only local (not server) status."
1256   ;; XXX Transitional implementation.
1257   (elmo-folder-set-flag folder (list number) flag is-local))
1258
1259 (defun elmo-message-unset-flag (folder number flag &optional is-local)
1260   "Unset message flag.
1261 FOLDER is a ELMO folder structure.
1262 NUMBER is a message number to set flag.
1263
1264 FLAG is a symbol which is one of the following:
1265   `unread'    (remove unread and new flag)
1266   `answered'  (remove answered flag)
1267   `important' (remove important flag)
1268 'sugar' flag:
1269   `read'      (set unread flag)
1270 If optional IS-LOCAL is non-nil, update only local (not server) status."
1271   ;; XXX Transitional implementation.
1272   (elmo-folder-unset-flag folder (list number) flag is-local))
1273
1274 (luna-define-generic elmo-message-field (folder number field)
1275   "Get message field value in the msgdb.
1276 FOLDER is the ELMO folder structure.
1277 NUMBER is a number of the message.
1278 FIELD is a symbol of the field.")
1279
1280 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1281   (elmo-msgdb-message-field (elmo-folder-msgdb folder) number field))
1282
1283 (luna-define-generic elmo-message-set-field (folder number field value)
1284   "Set message field value in the msgdb.
1285 FOLDER is the ELMO folder structure.
1286 NUMBER is a number of the message.
1287 FIELD is a symbol of the field.
1288 VALUE is a value to set.")
1289
1290 (luna-define-method elmo-message-set-field ((folder elmo-folder) number
1291                                             field value)
1292   (elmo-message-entity-set-field (elmo-message-entity folder number)
1293                                  field value))
1294
1295 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1296   nil) ; default is not use cache.
1297
1298 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1299   folder) ; default is folder
1300
1301 (luna-define-method elmo-folder-set-flag ((folder elmo-folder)
1302                                           numbers
1303                                           flag
1304                                           &optional is-local)
1305   (when (elmo-folder-msgdb-internal folder)
1306     (dolist (number numbers)
1307       (let ((old-flags (elmo-message-flags folder number)))
1308         (when (elmo-global-flag-p flag)
1309           (let ((message-id (elmo-message-field folder number 'message-id)))
1310             (elmo-global-flag-set flag folder number message-id)))
1311         (elmo-msgdb-set-flag (elmo-folder-msgdb folder) number flag)
1312         (elmo-emit-signal 'flag-changing
1313                           folder
1314                           number
1315                           old-flags
1316                           (elmo-message-flags folder number))))
1317     (elmo-emit-signal 'flag-changed folder numbers)))
1318
1319 (defun elmo-message-has-global-flag-p (folder number)
1320   "Return non-nil when the message in the FOLDER with NUMBER has global flag."
1321   (let ((flags (elmo-message-flags folder number))
1322         result)
1323     (while flags
1324       (when (and (elmo-global-flag-p (car flags))
1325                  (not (memq (car flags) '(answered unread cached))))
1326         (setq result t
1327               flags nil))
1328       (setq flags (cdr flags)))
1329     result))
1330
1331 (defun elmo-message-set-global-flags (folder number flags &optional local)
1332   "Set global flags of the message in the FOLDER with NUMBER as FLAGS.
1333 If Optional LOCAL is non-nil, don't update server flag."
1334   (dolist (flag flags)
1335     (unless (elmo-global-flag-p flag)
1336       (error "Not a global flag")))
1337   (let ((old-flags (elmo-get-global-flags (elmo-message-flags folder number))))
1338     (dolist (flag flags)
1339       (unless (memq flag old-flags)
1340         (elmo-message-set-flag folder number flag local)))
1341     (dolist (flag old-flags)
1342       (unless (memq flag flags)
1343         (elmo-message-unset-flag folder number flag local)))))
1344
1345 (luna-define-method elmo-folder-unset-flag ((folder elmo-folder)
1346                                             numbers
1347                                             flag
1348                                             &optional is-local)
1349   (when (elmo-folder-msgdb-internal folder)
1350     (dolist (number numbers)
1351       (let ((old-flags (elmo-message-flags folder number)))
1352         (when (elmo-global-flag-p flag)
1353           (elmo-global-flag-detach flag folder number 'always))
1354         (elmo-msgdb-unset-flag (elmo-folder-msgdb folder) number flag)
1355         (elmo-emit-signal 'flag-changing
1356                           folder
1357                           number
1358                           old-flags
1359                           (elmo-message-flags folder number))))
1360     (elmo-emit-signal 'flag-changed folder numbers)))
1361
1362 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1363   ;; Do nothing.
1364   )
1365
1366 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1367 ;;                                                             &optional
1368 ;;                                                             flag-table)
1369 ;;  "Append ENTITY to the folder.")
1370
1371 (defun elmo-msgdb-merge (folder msgdb-merge)
1372   "Return a list of messages which have duplicated message-id."
1373   (let (msgdb duplicates)
1374     (setq msgdb (or (elmo-folder-msgdb-internal folder)
1375                     (elmo-make-msgdb (elmo-folder-msgdb-path folder))))
1376     (setq duplicates (elmo-msgdb-append msgdb msgdb-merge))
1377     (elmo-folder-set-msgdb-internal folder msgdb)
1378     duplicates))
1379
1380 (defsubst elmo-folder-append-msgdb (folder append-msgdb)
1381   (if append-msgdb
1382       (let ((duplicates (elmo-msgdb-merge folder append-msgdb)))
1383         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1384                    'hide)
1385                ;; Let duplicates be a temporary killed message.
1386                (elmo-folder-kill-messages folder duplicates)
1387                ;; Should be flag as read.
1388                (elmo-folder-unset-flag folder duplicates 'unread))
1389               ((eq (elmo-folder-process-duplicates-internal folder)
1390                    'read)
1391                ;; Flag as read duplicates.
1392                (elmo-folder-unset-flag folder duplicates 'unread))
1393               (t
1394                ;; Do nothing.
1395                (setq duplicates nil)))
1396         (length duplicates))
1397     0))
1398
1399 (defun elmo-folder-confirm-appends (appends)
1400   (let ((len (length appends))
1401         in)
1402     (if (and elmo-folder-update-threshold
1403              (> len elmo-folder-update-threshold)
1404              elmo-folder-update-confirm)
1405         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1406             appends
1407           (setq in elmo-folder-update-threshold)
1408           (catch 'end
1409             (while t
1410               (setq in (read-from-minibuffer "Update number: "
1411                                              (int-to-string in))
1412                     in (string-to-int in))
1413               (if (< len in)
1414                   (throw 'end len))
1415               (if (y-or-n-p (format
1416                              "%d messages are killed (not appeared). OK? "
1417                              (max (- len in) 0)))
1418                   (throw 'end in))))
1419           (nthcdr (max (- len in) 0) appends))
1420       (if (and elmo-folder-update-threshold
1421                (> len elmo-folder-update-threshold)
1422                (not elmo-folder-update-confirm))
1423           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1424         appends))))
1425
1426 (luna-define-method elmo-message-fetch-bodystructure ((folder elmo-folder)
1427                                                       number strategy)
1428   nil)
1429
1430 (defun elmo-message-fetch-string (folder number strategy
1431                                          &optional
1432                                          unread
1433                                          section)
1434   (with-temp-buffer
1435     (set-buffer-multibyte nil)
1436     (when (elmo-message-fetch folder number strategy unread section)
1437       (buffer-string))))
1438
1439 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1440                                         number strategy
1441                                         &optional
1442                                         unread
1443                                         section)
1444   (erase-buffer)
1445   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1446         (method-priorities
1447          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1448                 '(entity cache))
1449                ((elmo-fetch-strategy-use-cache strategy)
1450                 '(cache entity))
1451                (t
1452                 '(entity))))
1453         result err updated-server-flag)
1454     (while (and method-priorities
1455                 (not result))
1456       (setq result
1457             (case (car method-priorities)
1458               (cache
1459                (elmo-file-cache-load cache-path section))
1460               (entity
1461                (when (condition-case error
1462                          (elmo-message-fetch-internal folder number
1463                                                       strategy
1464                                                       section
1465                                                       unread)
1466                        (error (setq err error) nil))
1467                  (setq updated-server-flag t)
1468                  (when (and (elmo-fetch-strategy-save-cache strategy)
1469                             cache-path)
1470                    (elmo-file-cache-save cache-path section))
1471                  t)))
1472             method-priorities (cdr method-priorities)))
1473     (if result
1474         (when (and (not unread)
1475                    (elmo-message-flagged-p folder number 'unread))
1476           (elmo-message-unset-flag folder number 'unread updated-server-flag))
1477       (when err
1478         (signal (car err) (cdr err))))
1479     result))
1480
1481 (defun elmo-folder-kill-messages-range (folder beg end)
1482   (elmo-folder-set-killed-list-internal
1483    folder
1484    (nconc
1485     (elmo-folder-killed-list-internal folder)
1486     (list (cons beg end)))))
1487
1488 (defun elmo-folder-kill-messages (folder numbers)
1489   "Kill(hide) messages in the FOLDER with NUMBERS."
1490   (elmo-folder-set-killed-list-internal
1491    folder
1492    (elmo-number-set-append-list
1493     (elmo-folder-killed-list-internal folder)
1494     numbers))
1495   (elmo-folder-unset-flag folder numbers 'all 'local-only))
1496
1497 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1498                                        &optional keep-killed)
1499   (unless keep-killed
1500     (elmo-folder-set-killed-list-internal folder nil))
1501   (if (eq elmo-msgdb-convert-type 'sync)
1502       (elmo-folder-set-msgdb-internal
1503        folder
1504        (elmo-make-msgdb (elmo-folder-msgdb-path folder)))
1505     (elmo-msgdb-clear (elmo-folder-msgdb folder))))
1506
1507 (luna-define-generic elmo-folder-synchronize (folder
1508                                               &optional
1509                                               disable-killed
1510                                               ignore-msgdb
1511                                               no-check
1512                                               mask)
1513   "Synchronize the folder data to the newest status.
1514 FOLDER is the ELMO folder structure.
1515
1516 If optional DISABLE-KILLED is non-nil, killed messages are also synchronized.
1517 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1518 flag status.
1519 If NO-CHECK is non-nil, rechecking folder is skipped.
1520 If optional argument MASK is specified and is a list of message numbers,
1521 synchronize messages only which are contained the list.
1522 Return amount of cross-posted messages.
1523 If update process is interrupted, return nil.")
1524
1525 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1526                                              &optional
1527                                              disable-killed
1528                                              ignore-msgdb
1529                                              no-check
1530                                              mask)
1531   (let ((old-msgdb (elmo-folder-msgdb folder))
1532         (killed-list (elmo-folder-killed-list-internal folder))
1533         (flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1534         (before-append t))
1535     (when ignore-msgdb
1536       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1537       (elmo-folder-clear folder (not disable-killed)))
1538     (unless no-check (elmo-folder-check folder))
1539     (condition-case nil
1540         (let ((killed-list (elmo-folder-killed-list-internal folder))
1541               diff-new diff-del
1542               delete-list new-list new-msgdb crossed)
1543           (message "Checking folder diff...")
1544           (elmo-set-list
1545            '(diff-new diff-del)
1546            (elmo-list-diff (elmo-folder-list-messages folder)
1547                            (elmo-folder-list-messages folder nil 'in-msgdb)))
1548           (when diff-new
1549             (setq diff-new (sort diff-new #'<))
1550             (unless disable-killed
1551               (setq diff-new (elmo-living-messages diff-new killed-list)))
1552             (when (and mask (not ignore-msgdb))
1553               (setq diff-new (elmo-list-filter mask diff-new))))
1554           (message "Checking folder diff...done")
1555           (setq new-list (elmo-folder-confirm-appends diff-new))
1556           ;; Append to killed list as (MIN-OF-DISAPPEARED . MAX-OF-DISAPPEARED)
1557           (when (not (eq (length diff-new)
1558                          (length new-list)))
1559             (let* ((diff (elmo-list-diff diff-new new-list))
1560                    (disappeared (sort (car diff) #'<)))
1561               (when disappeared
1562                 (elmo-folder-kill-messages-range folder
1563                                                  (car disappeared)
1564                                                  (elmo-last disappeared)))))
1565           (setq delete-list diff-del)
1566           (if (and (null diff-new) (null diff-del))
1567               (progn
1568                 (elmo-folder-update-number folder)
1569                 (elmo-folder-process-crosspost folder)
1570                 0)                      ; `0' means no updates.
1571             (when delete-list
1572               (elmo-folder-detach-messages folder delete-list))
1573             (when new-list
1574               (elmo-msgdb-out-of-date-messages (elmo-folder-msgdb folder))
1575               (setq new-msgdb (elmo-folder-msgdb-create
1576                                folder new-list flag-table))
1577               ;; Clear flag-table
1578               (if (elmo-folder-persistent-p folder)
1579                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1580                                         nil))
1581               (setq before-append nil)
1582               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1583               ;; process crosspost.
1584               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).
1585               (elmo-folder-process-crosspost folder))
1586             ;; return value.
1587             (or crossed 0)))
1588       (quit
1589        ;; Resume to the original status.
1590        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1591        (elmo-folder-set-killed-list-internal folder killed-list)
1592        nil))))
1593
1594 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1595   "Remove messages with NUMBERS from MSGDB.")
1596
1597 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1598                                                  numbers)
1599   (when (elmo-msgdb-delete-messages (elmo-folder-msgdb folder) numbers)
1600     ;; Remove NUMBERS from killed message list.
1601     (elmo-folder-set-killed-list-internal
1602      folder
1603      (elmo-number-set-delete-list
1604       (elmo-folder-killed-list-internal folder)
1605       numbers))
1606     t))
1607
1608 (luna-define-generic elmo-folder-length (folder)
1609   "Return number of messages in the FOLDER.")
1610
1611 (luna-define-method elmo-folder-length ((folder elmo-folder))
1612   (if (elmo-folder-msgdb-internal folder)
1613       (elmo-msgdb-length (elmo-folder-msgdb folder))
1614     0))
1615
1616 (defun elmo-folder-msgdb-load (folder &optional silent)
1617   (unless silent
1618     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1619   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1620     (elmo-folder-set-info-max-by-numdb
1621      folder
1622      (elmo-msgdb-list-messages msgdb))
1623     (unless silent
1624       (message "Loading msgdb for %s...done"
1625                (elmo-folder-name-internal folder)))
1626     msgdb))
1627
1628 (defun elmo-msgdb-delete-path (folder)
1629   (let ((path (elmo-folder-msgdb-path folder)))
1630     (if (file-directory-p path)
1631         (elmo-delete-directory path t))))
1632
1633 (defun elmo-msgdb-rename-path (old-folder new-folder)
1634   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1635          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1636          (new-dir (directory-file-name (file-name-directory new))))
1637     (if (not (file-directory-p old))
1638         ()
1639       (if (file-exists-p new)
1640           (error "Already exists directory: %s" new)
1641         (if (not (file-exists-p new-dir))
1642             (elmo-make-directory new-dir))
1643         (rename-file old new)))))
1644
1645 (defun elmo-setup-subscribed-newsgroups (groups)
1646   "Setup subscribed newsgroups.
1647 GROUPS is a list of newsgroup name string.
1648 Return a hashtable for newsgroups."
1649   (let ((hashtb (or elmo-newsgroups-hashtb
1650                     (setq elmo-newsgroups-hashtb
1651                           (elmo-make-hash (length groups))))))
1652     (dolist (group groups)
1653       (or (elmo-get-hash-val group hashtb)
1654           (elmo-set-hash-val group nil hashtb)))
1655     (setq elmo-newsgroups-hashtb hashtb)))
1656
1657 (defvar elmo-crosspost-message-alist-modified nil)
1658 (defun elmo-crosspost-message-alist-load ()
1659   "Load crosspost message alist."
1660   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1661   (setq elmo-crosspost-message-alist-modified nil))
1662
1663 (defun elmo-crosspost-message-alist-save ()
1664   "Save crosspost message alist."
1665   (when elmo-crosspost-message-alist-modified
1666     (let ((alist elmo-crosspost-message-alist)
1667           newsgroups)
1668       (while alist
1669         (setq newsgroups
1670               (elmo-delete-if
1671                '(lambda (x)
1672                   (not (intern-soft x elmo-newsgroups-hashtb)))
1673                (nth 1 (car alist))))
1674         (if newsgroups
1675             (setcar (cdar alist) newsgroups)
1676           (setq elmo-crosspost-message-alist
1677                 (delete (car alist) elmo-crosspost-message-alist)))
1678         (setq alist (cdr alist)))
1679       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1680       (setq elmo-crosspost-message-alist-modified nil))))
1681
1682 (defun elmo-folder-make-temporary-directory (folder)
1683   ;; Make a temporary directory for FOLDER.
1684   (let ((temp-dir (make-temp-name
1685                    (concat
1686                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1687                     "elmo"))))
1688     (elmo-make-directory temp-dir)
1689     temp-dir))
1690
1691 ;;;
1692 (defun elmo-init ()
1693   "Initialize ELMO module."
1694   (elmo-crosspost-message-alist-load)
1695   (elmo-resque-obsolete-variables)
1696   (elmo-dop-queue-load)
1697   (run-hooks 'elmo-init-hook))
1698
1699 (defun elmo-quit ()
1700   "Quit and cleanup ELMO."
1701   (elmo-crosspost-message-alist-save)
1702   (elmo-dop-queue-save)
1703   ;; Not implemented yet.
1704   (let ((types elmo-folder-type-alist)
1705         class)
1706     (while types
1707       (setq class
1708             (luna-find-class
1709              (intern (format "elmo-%s-folder"
1710                              (symbol-name (cdr (car types)))))))
1711       ;; Call all folder's `elmo-quit' method.
1712       (if class
1713           (dolist (func (luna-class-find-functions class 'elmo-quit))
1714             (funcall func nil)))
1715       (setq types (cdr types)))))
1716
1717 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1718                                                  new-folder)
1719   (error "Cannot rename %s folder"
1720          (symbol-name (elmo-folder-type-internal folder))))
1721
1722 ;;; Define folders.
1723 (elmo-define-folder ?% 'imap4)
1724 (elmo-define-folder ?-  'nntp)
1725 (elmo-define-folder ?\+ 'localdir)
1726 (elmo-define-folder ?\* 'multi)
1727 (elmo-define-folder ?\/ 'filter)
1728 (elmo-define-folder ?\$ 'archive)
1729 (elmo-define-folder ?&  'pop3)
1730 (elmo-define-folder ?=  'localnews)
1731 (elmo-define-folder ?|  'pipe)
1732 (elmo-define-folder ?.  'maildir)
1733 (elmo-define-folder ?'  'internal)
1734 (elmo-define-folder ?\[  'nmz)
1735 (elmo-define-folder ?@  'shimbun)
1736
1737 ;;; Obsolete variables.
1738 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1739                                'elmo-imap4-default-mailbox)
1740 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1741                                'elmo-imap4-default-server)
1742 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1743                                'elmo-imap4-default-authenticate-type)
1744 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1745                                'elmo-imap4-default-user)
1746 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1747                                'elmo-imap4-default-port)
1748 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1749                                'elmo-imap4-default-stream-type)
1750 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1751                                'elmo-nntp-default-server)
1752 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1753                                'elmo-nntp-default-user)
1754 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1755                                'elmo-nntp-default-port)
1756 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1757                                'elmo-nntp-default-stream-type)
1758 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1759                                'elmo-pop3-default-server)
1760 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1761                                'elmo-pop3-default-user)
1762 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1763                                'elmo-pop3-default-authenticate-type)
1764 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1765                                'elmo-pop3-default-port)
1766 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1767                                'elmo-pop3-default-stream-type)
1768 (elmo-define-obsolete-variable 'elmo-cache-dirname
1769                                'elmo-cache-directory)
1770 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1771                                'elmo-msgdb-directory)
1772 (elmo-define-obsolete-variable 'elmo-global-flag-list
1773                                'elmo-global-flags)
1774
1775 ;; Obsolete functions.
1776 ;; 2001-12-11: *-dir -> *-directory
1777 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1778 (make-obsolete 'elmo-folder-make-temp-dir
1779                'elmo-folder-make-temporary-directory)
1780
1781 (require 'product)
1782 (product-provide (provide 'elmo) (require 'elmo-version))
1783
1784 ;;; elmo.el ends here