elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type 'integer
  50   :group 'elmo)
  51
  52 (defcustom elmo-message-fetch-confirm t
  53   "If non-nil, confirm fetching if message size is larger than
  54 `elmo-message-fetch-threshold'.
  55 Otherwise, entire fetching of the message is aborted without confirmation."
  56   :type 'boolean
  57   :group 'elmo)
  58
  59 (defcustom elmo-folder-update-threshold 500
  60   "Update threshold."
  61   :type 'integer
  62   :group 'elmo)
  63
  64 (defcustom elmo-folder-update-confirm t
  65   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  66   :type 'boolean
  67   :group 'elmo)
  68
  69 (defvar elmo-message-displaying nil
  70   "A global switch to indicate message is displaying or not.")
  71
  72 ;;; internal
  73 (defvar elmo-folder-type-alist nil)
  74
  75 (defvar elmo-newsgroups-hashtb nil)
  76
  77 (elmo-define-error 'elmo-error "Error" 'error)
  78 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  79 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  80 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  81
  82 (defun elmo-define-folder (prefix backend)
  83   "Define a folder.
  84 If a folder name begins with PREFIX, use BACKEND."
  85   (let ((pair (assq prefix elmo-folder-type-alist)))
  86     (if pair
  87         (progn
  88           (setcar pair prefix)
  89           (setcdr pair backend))
  90       (setq elmo-folder-type-alist (cons (cons prefix backend)
  91                                          elmo-folder-type-alist)))))
  92
  93 (defmacro elmo-folder-type (name)
  94   "Get folder type from NAME string."
  95   (` (and (stringp (, name))
  96           (cdr (assoc (string-to-char (, name)) elmo-folder-type-alist)))))
  97
  98 ;;; ELMO folder
  99 ;; A elmo folder provides uniformed (orchestrated) access
 100 ;; to the internet messages.
 101 (eval-and-compile
 102   (luna-define-class elmo-folder () (type   ; folder type symbol.
 103                                      name   ; orignal folder name string.
 104                                      prefix ; prefix for folder name
 105                                      path   ; directory path for msgdb.
 106                                      msgdb  ; msgdb (may be nil).
 107                                      killed-list  ; killed list.
 108                                      persistent   ; non-nil if persistent.
 109                                      message-modified ; message is modified.
 110                                      flag-modified    ; flag is modified.
 111                                      process-duplicates  ; read or hide
 112                                      biff   ; folder for biff
 113                                      ))
 114   (luna-define-internal-accessors 'elmo-folder))
 115
 116 (luna-define-generic elmo-folder-initialize (folder name)
 117   ;; Initialize a FOLDER structure with NAME."
 118   )
 119
 120 (defmacro elmo-folder-send (folder message &rest args)
 121   "Let FOLDER receive the MESSAGE with ARGS."
 122   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 123
 124 ;;;###autoload
 125 (defun elmo-make-folder (name &optional non-persistent)
 126   "Make an ELMO folder structure specified by NAME.
 127 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 128   (let ((type (elmo-folder-type name))
 129         prefix split class folder original)
 130     (setq original (elmo-string name))
 131     (if type
 132         (progn
 133           (setq prefix (substring name 0 1))
 134           (setq name (substring name 1)))
 135       (setq type (intern (car (setq split (split-string name ":")))))
 136       (if (>= (length split) 2)
 137           (setq name (substring name (+ 1 (length (car split)))))
 138         (error "Error in folder name `%s'" original))
 139       (setq prefix (concat (car split) ":")))
 140     (setq class (format "elmo-%s" (symbol-name type)))
 141     (require (intern class))
 142     (setq folder (luna-make-entity (intern (concat class "-folder"))
 143                                    :type type
 144                                    :prefix prefix
 145                                    :name original
 146                                    :persistent (not non-persistent)))
 147     (save-match-data
 148       (elmo-folder-send folder 'elmo-folder-initialize name))))
 149
 150 ;; Note that this function is for internal use only.
 151 (luna-define-generic elmo-folder-msgdb (folder)
 152   "Return the msgdb of FOLDER (on-demand loading).
 153 \(For internal use only.\)")
 154
 155 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 156   (or (elmo-folder-msgdb-internal folder)
 157       (elmo-folder-set-msgdb-internal folder
 158                                       (elmo-folder-msgdb-load folder))))
 159
 160 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 161   "Open and setup (load saved status) FOLDER.
 162 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 163 \(otherwise, msgdb is loaded on-demand)")
 164
 165 (luna-define-generic elmo-folder-open-internal (folder)
 166   "Open FOLDER (without loading saved folder status).")
 167
 168 (luna-define-generic elmo-folder-check (folder)
 169   "Check the FOLDER to obtain newest information at the next list operation.")
 170
 171 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 172   "Clear FOLDER to the initial state.
 173 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 174
 175 (luna-define-generic elmo-folder-commit (folder)
 176   "Save current status of FOLDER.")
 177
 178 (luna-define-generic elmo-folder-close (folder)
 179   "Close, save and clearnup FOLDER.")
 180
 181 (luna-define-generic elmo-folder-close-internal (folder)
 182   "Close FOLDER (without saving folder status).")
 183
 184 (luna-define-generic elmo-folder-plugged-p (folder)
 185   "Returns t if FOLDER is plugged.")
 186
 187 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 188   "Set FOLDER as plugged.")
 189
 190 (luna-define-generic elmo-net-port-info (folder)
 191   "Get port information of FOLDER.")
 192
 193 (luna-define-generic elmo-folder-use-flag-p (folder)
 194   "Returns t if FOLDER treats unread/important flag itself.")
 195
 196 (luna-define-generic elmo-folder-diff (folder)
 197   "Get diff of FOLDER.
 198 Return value is cons cell or list:
 199  - a cons cell (new . all)
 200  - a list (new unread all)")
 201
 202 (luna-define-generic elmo-folder-status (folder)
 203   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 204
 205 (luna-define-generic elmo-folder-reserve-status-p (folder)
 206   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 207
 208 (luna-define-generic elmo-folder-set-message-modified (folder modified)
 209   "Set FOLDER as modified.")
 210 (luna-define-method elmo-folder-set-message-modified ((folder elmo-folder)
 211                                                       modified)
 212   (elmo-folder-set-message-modified-internal folder modified))
 213
 214 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 215                                                        in-msgdb)
 216   "Return a list of message numbers contained in FOLDER.
 217 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 218 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 219
 220 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 221                                                &optional visible-only in-msgdb)
 222   (let ((list (if in-msgdb
 223                   t
 224                 (elmo-folder-list-messages-internal folder visible-only)))
 225         (killed-list (elmo-folder-killed-list-internal folder)))
 226     (unless (listp list)
 227       ;; Use current list.
 228       (setq list (elmo-msgdb-list-messages (elmo-folder-msgdb folder))))
 229     (if visible-only
 230         (elmo-living-messages list killed-list)
 231       (elmo-uniq-list
 232        (nconc (elmo-number-set-to-number-list killed-list) list)))))
 233
 234 (luna-define-generic elmo-folder-list-unreads (folder)
 235   "Return a list of unread message numbers contained in FOLDER.")
 236 (luna-define-generic elmo-folder-list-importants (folder)
 237   "Return a list of important message numbers contained in FOLDER.")
 238 (luna-define-generic elmo-folder-list-answereds (folder)
 239   "Return a list of answered message numbers contained in FOLDER.")
 240
 241 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 242   "List messages in the FOLDER with FLAG.
 243 FLAG is a symbol which is one of the following:
 244   `new'        (new messages)
 245   `unread'     (unread messages (new messages are included))
 246   `answered'   (answered or forwarded)
 247   `important'  (marked as important)
 248 'sugar' flags:
 249   `read'       (not unread)
 250   `digest'     (unread + important)
 251   `any'        (digest + answered)
 252
 253 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 254
 255 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 256                                               &optional in-msgdb)
 257   ;; Currently, only in-msgdb is implemented.
 258   (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag))
 259
 260 (luna-define-method elmo-folder-list-unreads ((folder elmo-folder))
 261   (elmo-folder-list-flagged folder 'unread))
 262
 263 (luna-define-method elmo-folder-list-importants ((folder elmo-folder))
 264   (elmo-folder-list-flagged folder 'important))
 265
 266 (luna-define-method elmo-folder-list-answereds ((folder elmo-folder))
 267   (elmo-folder-list-flagged folder 'answered))
 268
 269 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 270                                                                 visible-only)
 271   ;; Return a list of message numbers contained in FOLDER.
 272   ;; Return t if the message list is not available.
 273   )
 274
 275 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 276   "Returns a list of subfolders contained in FOLDER.
 277 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 278 \(a folder which have children is returned as a list\)
 279 Otherwise, all descendent folders are returned.")
 280
 281 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 282   "Return non-nil when FOLDER has subfolders.")
 283
 284 (luna-define-generic elmo-folder-exists-p (folder)
 285   "Returns non-nil when FOLDER exists.")
 286
 287 (luna-define-generic elmo-folder-creatable-p (folder)
 288   "Returns non-nil when FOLDER is creatable.")
 289
 290 (luna-define-generic elmo-folder-writable-p (folder)
 291   "Returns non-nil when FOLDER is writable.")
 292
 293 (luna-define-generic elmo-folder-persistent-p (folder)
 294   "Return non-nil when FOLDER is persistent.")
 295
 296 (luna-define-generic elmo-folder-create (folder)
 297   "Create a FOLDER.")
 298
 299 (luna-define-generic elmo-message-deletable-p (folder number)
 300   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 301
 302 (luna-define-generic elmo-folder-delete (folder)
 303   "Delete FOLDER completely.")
 304
 305 (luna-define-generic elmo-folder-rename (folder new-name)
 306   "Rename FOLDER to NEW-NAME (string).")
 307
 308 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 309   "Delete messages.
 310 FOLDER is the ELMO folder structure.
 311 NUMBERS is a list of message numbers to be deleted.
 312 It is not recommended to use this function other than internal use.
 313 Use `elmo-folder-move-messages' with dst-folder 'null instead.")
 314
 315 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 316   "Search and return list of message numbers.
 317 FOLDER is the ELMO folder structure.
 318 CONDITION is a condition structure for searching.
 319 If optional argument NUMBERS is specified and is a list of message numbers,
 320 messages are searched from the list.")
 321
 322 (luna-define-generic elmo-message-match-condition (folder number
 323                                                           condition
 324                                                           numbers)
 325   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 326 CONDITION is a condition structure for testing.
 327 NUMBERS is a list of message numbers,
 328 use to be test for \"last\" and \"first\" predicates.")
 329
 330 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 331   "Create a message database (implemented in each backends).
 332 FOLDER is the ELMO folder structure.
 333 NUMBERS is a list of message numbers to create msgdb.
 334 FLAG-TABLE is a hashtable of message-id and flag.")
 335
 336 (luna-define-generic elmo-folder-unflag-important (folder
 337                                                    numbers
 338                                                    &optional is-local)
 339   "Un-flag messages as important.
 340 FOLDER is the ELMO folder structure.
 341 NUMBERS is a list of message numbers to be processed.
 342 If IS-LOCAL is non-nil, only the local flag is updated.")
 343
 344 (luna-define-generic elmo-folder-flag-as-important (folder
 345                                                     numbers
 346                                                     &optional is-local)
 347   "Flag messages as important.
 348 FOLDER is the ELMO folder structure.
 349 NUMBERS is a list of message numbers to be processed.
 350 If IS-LOCAL is non-nil, only the local flag is updated.")
 351
 352 (luna-define-generic elmo-folder-unflag-read (folder numbers
 353                                                      &optional is-local)
 354   "Un-flag messages as read.
 355 FOLDER is the ELMO folder structure.
 356 NUMBERS is a list of message numbers to be processed.
 357 If IS-LOCAL is non-nil, only the local flag is updated.")
 358
 359 (luna-define-generic elmo-folder-flag-as-read (folder numbers
 360                                                       &optional is-local)
 361   "Flag messages as read.
 362 FOLDER is the ELMO folder structure.
 363 NUMBERS is a list of message numbers to be processed.
 364 If IS-LOCAL is non-nil, only the local flag is updated.")
 365
 366 (luna-define-generic elmo-folder-unflag-answered (folder numbers
 367                                                          &optional is-local)
 368   "Un-flag messages as answered.
 369 FOLDER is the ELMO folder structure.
 370 If IS-LOCAL is non-nil, only the local flag is updated.")
 371
 372 (luna-define-generic elmo-folder-flag-as-answered (folder numbers
 373                                                           &optional is-local)
 374   "Flag messages as answered.
 375 FOLDER is the ELMO folder structure.
 376 If IS-LOCAL is non-nil, only the local flag is updated.")
 377
 378 (luna-define-generic elmo-folder-append-buffer (folder &optional flag
 379                                                        number)
 380   "Append current buffer as a new message.
 381 FOLDER is the destination folder(ELMO folder structure).
 382 FLAG is the status of appended message.
 383 If optional argument NUMBER is specified, the new message number is set
 384 \(if possible\).")
 385
 386 (luna-define-generic elmo-folder-append-messages (folder
 387                                                   src-folder
 388                                                   numbers
 389                                                   &optional
 390                                                   same-number)
 391   "Append messages from folder.
 392 FOLDER is the ELMO folder structure.
 393 Caller should make sure FOLDER is `writable'.
 394 \(Can be checked with `elmo-folder-writable-p'\).
 395 SRC-FOLDER is the source ELMO folder structure.
 396 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 397 If second optional argument SAME-NUMBER is specified,
 398 message number is preserved \(if possible\).")
 399
 400 (luna-define-generic elmo-folder-pack-numbers (folder)
 401   "Pack message numbers of FOLDER.")
 402
 403 (luna-define-generic elmo-folder-update-number (folder)
 404   "Update number of FOLDER.")
 405
 406 (luna-define-generic elmo-folder-diff-async (folder)
 407   "Get diff of FOLDER asynchronously.")
 408
 409 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 410   "Expand path for FOLDER.")
 411
 412 (luna-define-generic elmo-folder-get-primitive-list (folder)
 413   "Get primitive folder structure list contained in FOLDER.")
 414
 415 (luna-define-generic elmo-folder-contains-type (folder type)
 416   "Returns t if FOLDER contains TYPE.")
 417
 418 (luna-define-generic elmo-folder-local-p (folder)
 419   "Returns t if FOLDER is local.")
 420
 421 (luna-define-generic elmo-folder-message-file-p (folder)
 422   "Returns t if all messages in the FOLDER are files.")
 423
 424 ;;; Message methods.
 425 (luna-define-generic elmo-message-use-cache-p (folder number)
 426   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 427
 428 (luna-define-generic elmo-message-file-name (folder number)
 429   "Return the file name of a message specified by FOLDER and NUMBER.")
 430
 431 ;;; For archive
 432
 433 ;;; Use original file
 434 (luna-define-generic elmo-folder-message-file-number-p (folder)
 435   "Return t if the file name in the FOLDER is the message number.")
 436
 437 (luna-define-generic elmo-folder-message-file-directory (folder)
 438   "Return the directory of the message files of FOLDER.")
 439
 440 ;;; Use temporary file
 441 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 442   "Return t if the messages in the FOLDER makes local temporary file.")
 443
 444 (luna-define-generic elmo-folder-message-make-temp-files (folder
 445                                                           numbers
 446                                                           &optional
 447                                                           start-number)
 448   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 449 If START-NUMBER is specified, temporary files begin from the number.
 450 Otherwise, same number is used for temporary files.
 451 Return newly created temporary directory name which contains temporary files.")
 452
 453 (luna-define-generic elmo-message-file-p (folder number)
 454   "Return t if message in the FOLDER with NUMBER is a file.")
 455
 456 (luna-define-generic elmo-find-fetch-strategy
 457   (folder entity &optional ignore-cache)
 458 ;; Returns the message fetching strategy suitable for the message.
 459 ;; FOLDER is the ELMO folder structure.
 460 ;; ENTITY is the overview entity of the message in the folder.
 461 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 462 ;; Returned value is a elmo-fetch-strategy object.
 463 ;; If return value is nil, message should not be nil.
 464   )
 465
 466 (defmacro elmo-make-fetch-strategy (entireness
 467                                     &optional
 468                                     use-cache
 469                                     save-cache
 470                                     cache-path)
 471 ;; Make elmo-message-fetching strategy.
 472 ;; ENTIRENESS is 'entire or 'section.
 473 ;; 'entire means fetch message entirely at once.
 474 ;; 'section means fetch message section by section.
 475 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 476 ;; existing cache is thrown away.
 477 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 478 ;; CACHE-PATH is the cache path to be used as a message cache file.
 479   (` (vector (, entireness)
 480              (, use-cache) (, save-cache) (, cache-path))))
 481
 482 (defmacro elmo-fetch-strategy-entireness (strategy)
 483   ;; Return entireness of STRATEGY.
 484   (` (aref (, strategy) 0)))
 485
 486 (defmacro elmo-fetch-strategy-use-cache (strategy)
 487   ;; Return use-cache of STRATEGY.
 488   (` (aref (, strategy) 1)))
 489
 490 (defmacro elmo-fetch-strategy-save-cache (strategy)
 491   ;; Return save-cache of STRATEGY.
 492   (` (aref (, strategy) 2)))
 493
 494 (defmacro elmo-fetch-strategy-cache-path (strategy)
 495   ;;  Return cache-path of STRATEGY.
 496   (` (aref (, strategy) 3)))
 497
 498 (luna-define-method elmo-find-fetch-strategy
 499   ((folder elmo-folder) entity &optional ignore-cache)
 500   (let (cache-file size message-id number)
 501     (setq size (elmo-msgdb-overview-entity-get-size entity))
 502     (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 503     (setq number (elmo-msgdb-overview-entity-get-number entity))
 504     (setq cache-file (elmo-file-cache-get message-id))
 505     (setq ignore-cache (or ignore-cache
 506                            (null (elmo-message-use-cache-p folder number))))
 507     (if (or ignore-cache
 508             (null (elmo-file-cache-status cache-file)))
 509         ;; No cache or ignore-cache.
 510         (if (and (not (elmo-folder-local-p folder))
 511                  elmo-message-fetch-threshold
 512                  (integerp size)
 513                  (>= size elmo-message-fetch-threshold)
 514                  (or (not elmo-message-fetch-confirm)
 515                      (not (prog1 (y-or-n-p
 516                                   (format "Fetch entire message(%dbytes)? "
 517                                           size))
 518                             (message "")))))
 519             ;; Don't fetch message at all.
 520             nil
 521           ;; Don't use existing cache and fetch entire message at once.
 522           (elmo-make-fetch-strategy
 523            'entire nil
 524            (elmo-message-use-cache-p folder number)
 525            (elmo-file-cache-path cache-file)))
 526       ;; Cache exists.
 527       (if (not ignore-cache)
 528           (elmo-make-fetch-strategy
 529            'entire
 530            ;; ...But ignore current section cache and re-fetch
 531            ;; if section cache.
 532            (not (eq (elmo-file-cache-status cache-file) 'section))
 533            ;; Save cache.
 534            (elmo-message-use-cache-p folder number)
 535            (elmo-file-cache-path cache-file))))))
 536
 537 (luna-define-method elmo-folder-list-messages-internal
 538   ((folder elmo-folder) &optional visible-only)
 539   t)
 540
 541 (defun elmo-folder-encache (folder numbers &optional unread)
 542   "Encache messages in the FOLDER with NUMBERS.
 543 If UNREAD is non-nil, messages are not flaged as read."
 544   (dolist (number numbers)
 545     (elmo-message-encache folder number unread)))
 546
 547 (luna-define-generic elmo-message-encache (folder number &optional read)
 548   "Encache message in the FOLDER with NUMBER.
 549 If READ is non-nil, message is flaged as read.")
 550
 551 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 552                                           &optional read)
 553   (let (path)
 554     (elmo-message-fetch
 555      folder number
 556      (elmo-make-fetch-strategy 'entire
 557                                nil ;use-cache
 558                                t   ;save-cache
 559                                (setq path (elmo-file-cache-get-path
 560                                            (elmo-message-field
 561                                             folder number 'message-id))))
 562      nil nil (not read))
 563     path))
 564
 565 (luna-define-generic elmo-message-fetch (folder number strategy
 566                                                 &optional
 567                                                 section
 568                                                 outbuf
 569                                                 unread)
 570   "Fetch a message and return as a string.
 571 FOLDER is the ELMO folder structure.
 572 NUMBER is the number of the message in the FOLDER.
 573 STRATEGY is the message fetching strategy.
 574 If optional argument SECTION is specified, only the SECTION of the message
 575 is fetched (if possible).
 576 If second optional argument OUTBUF is specified, fetched message is
 577 inserted to the buffer and returns t if fetch was ended successfully.
 578 If third optional argument UNREAD is non-nil, message is not flaged as read.
 579 Returns non-nil if fetching was succeed.")
 580
 581 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 582                                                             number strategy
 583                                                             &optional
 584                                                             section
 585                                                             unread)
 586   "Fetch a message into current buffer with cache process.
 587 FOLDER is the ELMO folder structure.
 588 NUMBER is the number of the message in the FOLDER.
 589 STRATEGY is the message fetching strategy.
 590 If optional argument SECTION is specified, only the SECTION of the message
 591 is fetched (if possible).
 592 If second optional argument UNREAD is non-nil, message is not flaged as read.
 593 Returns non-nil if fetching was succeed.")
 594
 595 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 596                                                          &optional
 597                                                          section
 598                                                          unread)
 599   "Fetch a message into current buffer.
 600 FOLDER is the ELMO folder structure.
 601 NUMBER is the number of the message in the FOLDER.
 602 STRATEGY is the message fetching strategy.
 603 If optional argument SECTION is specified, only the SECTION of the message
 604 is fetched (if possible).
 605 If second optional argument UNREAD is non-nil, message is not flaged as read.
 606 Returns non-nil if fetching was succeed.")
 607
 608 (luna-define-generic elmo-message-fetch-field (folder number field)
 609   "Fetch a message field value.
 610 FOLDER is the ELMO folder structure.
 611 NUMBER is the number of the message in the FOLDER.
 612 FIELD is a symbol of the field name.")
 613
 614 (luna-define-generic elmo-message-folder (folder number)
 615   "Get primitive folder of the message.")
 616
 617 (luna-define-generic elmo-folder-process-crosspost (folder)
 618   "Process crosspost for FOLDER.
 619 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).")
 620
 621 (luna-define-generic elmo-folder-newsgroups (folder)
 622   "Return list of newsgroup name of FOLDER.")
 623
 624 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 625   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 626
 627 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 628   (if (listp condition)
 629       (or (elmo-folder-search-requires-msgdb-p-internal
 630            folder (nth 1 condition))
 631           (elmo-folder-search-requires-msgdb-p-internal
 632            folder (nth 2 condition)))
 633     (and (not (string= (elmo-filter-key condition) "last"))
 634          (not (string= (elmo-filter-key condition) "first")))))
 635
 636 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 637                                                          condition)
 638   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 639
 640 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 641   nil)
 642
 643 (luna-define-method elmo-folder-open ((folder elmo-folder)
 644                                       &optional load-msgdb)
 645   (elmo-generic-folder-open folder load-msgdb))
 646
 647 (defun elmo-generic-folder-open (folder load-msgdb)
 648   (let ((inhibit-quit t))
 649     (if load-msgdb (elmo-folder-msgdb folder))
 650     (elmo-folder-set-killed-list-internal
 651      folder
 652      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 653   (elmo-folder-open-internal folder))
 654
 655 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 656   nil ; default is do nothing.
 657   )
 658
 659 (luna-define-method elmo-folder-check ((folder elmo-folder))
 660   nil) ; default is noop.
 661
 662 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 663   (elmo-generic-folder-commit folder))
 664
 665 (defun elmo-generic-folder-commit (folder)
 666   (let ((msgdb (elmo-folder-msgdb-internal folder)))
 667     (when (and msgdb (elmo-folder-persistent-p folder))
 668       (when (elmo-msgdb-message-modified-p msgdb)
 669         (elmo-folder-set-info-max-by-numdb
 670          folder
 671          (elmo-folder-list-messages folder nil 'in-msgdb))
 672         (elmo-msgdb-killed-list-save
 673          (elmo-folder-msgdb-path folder)
 674          (elmo-folder-killed-list-internal folder)))
 675       (elmo-folder-set-message-modified folder nil)
 676       (elmo-folder-set-flag-modified-internal folder nil)
 677       (elmo-msgdb-save msgdb))))
 678
 679 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 680   ;; do nothing.
 681   )
 682
 683 (luna-define-method elmo-folder-close ((folder elmo-folder))
 684   (elmo-generic-folder-close folder)
 685   (elmo-folder-close-internal folder))
 686
 687 (defun elmo-generic-folder-close (folder)
 688   (elmo-folder-commit folder)
 689   (elmo-folder-set-msgdb-internal folder nil)
 690   (elmo-folder-set-killed-list-internal folder nil))
 691
 692 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 693   t) ; default is plugged.
 694
 695 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 696                                              &optional add)
 697   nil) ; default is do nothing.
 698
 699 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 700   nil) ; default is no flag.
 701
 702 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 703   (elmo-folder-persistent-internal folder))
 704
 705 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 706   nil) ; default is not creatable.
 707
 708 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 709   nil) ; default is not writable.
 710
 711 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 712   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 713                              (elmo-folder-name-internal folder)))
 714     (elmo-msgdb-delete-path folder)
 715     t))
 716
 717 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 718   (let* ((new-folder (elmo-make-folder new-name)))
 719     (unless (eq (elmo-folder-type-internal folder)
 720                 (elmo-folder-type-internal new-folder))
 721       (error "Not same folder type"))
 722     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 723             (elmo-folder-exists-p new-folder))
 724         (error "Already exists folder: %s" new-name))
 725     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 726     (elmo-msgdb-rename-path folder new-folder)))
 727
 728 (defsubst elmo-folder-search-fast (folder condition numbers)
 729   "Search and return list of message numbers.
 730 Return t if CONDITION is not treated.
 731 FOLDER is the ELMO folder structure.
 732 CONDITION is a condition structure for searching.
 733 NUMBERS is a list of message numbers, messages are searched from the list."
 734   (if (and numbers
 735            (vectorp condition))
 736       (cond
 737        ((string= (elmo-filter-key condition) "flag")
 738         (let ((msgdb (elmo-folder-msgdb folder)))
 739           ;; msgdb should be synchronized at this point.
 740           (cond
 741            ((string= (elmo-filter-value condition) "unread")
 742             (elmo-folder-list-unreads folder))
 743            ((string= (elmo-filter-value condition) "important")
 744             (elmo-folder-list-importants folder))
 745            ((string= (elmo-filter-value condition) "answered")
 746             (elmo-folder-list-answereds folder))
 747            ((string= (elmo-filter-value condition) "digest")
 748             (nconc (elmo-folder-list-unreads folder)
 749                    (elmo-folder-list-importants folder)))
 750            ((string= (elmo-filter-value condition) "any")
 751             (nconc (elmo-folder-list-unreads folder)
 752                    (elmo-folder-list-importants folder)
 753                    (elmo-folder-list-answereds folder))))))
 754        ((member (elmo-filter-key condition) '("first" "last"))
 755         (let ((len (length numbers))
 756               (lastp (string= (elmo-filter-key condition) "last"))
 757               (value (string-to-number (elmo-filter-value condition))))
 758           (when (eq (elmo-filter-type condition) 'unmatch)
 759             (setq lastp (not lastp)
 760                   value  (- len value)))
 761           (if lastp
 762               (nthcdr (max (- len value) 0) numbers)
 763             (when (> value 0)
 764               (let* ((numbers (copy-sequence numbers))
 765                      (last (nthcdr (1- value) numbers)))
 766                 (when last
 767                   (setcdr last nil))
 768                 numbers)))))
 769        (t
 770         t))
 771     t))
 772
 773 (luna-define-method elmo-folder-search ((folder elmo-folder)
 774                                         condition
 775                                         &optional numbers)
 776   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 777         results)
 778     (if (listp (setq results (elmo-folder-search-fast folder
 779                                                       condition
 780                                                       numbers)))
 781         results
 782       (let ((msgdb (elmo-folder-msgdb folder))
 783             (len (length numbers))
 784             matched)
 785         (when (> len elmo-display-progress-threshold)
 786           (elmo-progress-set 'elmo-folder-search len "Searching..."))
 787         (unwind-protect
 788             (dolist (number numbers)
 789               (let (result)
 790                 (setq result (elmo-msgdb-match-condition
 791                               msgdb
 792                               condition
 793                               number
 794                               numbers))
 795                 (when (elmo-filter-condition-p result)
 796                   (setq result (elmo-message-match-condition
 797                                 folder
 798                                 number
 799                                 condition
 800                                 numbers)))
 801                 (when result
 802                   (setq matched (cons number matched))))
 803               (elmo-progress-notify 'elmo-folder-search))
 804           (elmo-progress-clear 'elmo-folder-search))
 805         (nreverse matched)))))
 806
 807 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 808                                                   number condition
 809                                                   numbers)
 810   (let ((filename (cond
 811                    ((elmo-message-file-name folder number))
 812                    ((let* ((cache (elmo-file-cache-get
 813                                    (elmo-message-field folder number
 814                                                        'message-id)))
 815                            (cache-path (elmo-file-cache-path cache)))
 816                       (when (and cache-path
 817                                  (not (elmo-cache-path-section-p cache-path)))
 818                         cache-path))))))
 819     (when (and filename
 820                (file-readable-p filename))
 821       (with-temp-buffer
 822         (insert-file-contents-as-binary filename)
 823         (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 824         ;; Should consider charset?
 825         (decode-mime-charset-region (point-min) (point-max) elmo-mime-charset)
 826         (elmo-buffer-field-condition-match condition number numbers)))))
 827
 828 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 829   nil) ; default is noop.
 830
 831 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 832   nil) ; default is noop.
 833
 834 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 835   nil) ; default is not file.
 836
 837 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 838   nil) ; default is not number.
 839
 840 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 841   nil) ; default is not make temp file.
 842
 843 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 844                                                    number)
 845   nil) ; default is no name.
 846
 847 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 848   t)   ; default is local.
 849
 850 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 851   t)
 852
 853 ;;; Folder info
 854 ;; Folder info is a message number information cache (hashtable)
 855 (defsubst elmo-folder-get-info (folder &optional hashtb)
 856   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 857   (elmo-get-hash-val (elmo-folder-name-internal folder)
 858                      (or hashtb elmo-folder-info-hashtb)))
 859
 860 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 861   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 862   (let ((info (elmo-folder-get-info folder)))
 863     (when info
 864       (or new     (setq new     (nth 0 info)))
 865       (or unread  (setq unread  (nth 1 info)))
 866       (or numbers (setq numbers (nth 2 info)))
 867       (or max     (setq max     (nth 3 info))))
 868     (elmo-set-hash-val (elmo-folder-name-internal folder)
 869                        (list new unread numbers max)
 870                        elmo-folder-info-hashtb)))
 871
 872 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 873   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 874   (elmo-folder-set-info-hashtb
 875    folder
 876    (or (car (sort numbers '>)) 0)
 877    nil ;;(length num-db)
 878    ))
 879
 880 (defun elmo-folder-get-info-max (folder)
 881   "Return max number of FODLER from folder info."
 882   (nth 3 (elmo-folder-get-info folder)))
 883
 884 (defun elmo-folder-get-info-length (folder)
 885   "Return length of FODLER from folder info."
 886   (nth 2 (elmo-folder-get-info folder)))
 887
 888 (defun elmo-folder-get-info-unread (folder)
 889   "Return unread of FODLER from folder info."
 890   (nth 1 (elmo-folder-get-info folder)))
 891
 892 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 893   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 894   (let* ((hashtb (or hashtb
 895                      (elmo-make-hash (length info-alist)))))
 896     (mapcar
 897      (lambda (x)
 898        (let ((info (cadr x)))
 899          (and (intern-soft (car x) hashtb)
 900               (elmo-set-hash-val (car x)
 901                                  (list (nth 2 info)   ;; new
 902                                        (nth 3 info)   ;; unread
 903                                        (nth 1 info)   ;; length
 904                                        (nth 0 info))  ;; max
 905                                  hashtb))))
 906      info-alist)
 907     (setq elmo-folder-info-hashtb hashtb)))
 908
 909 (defsubst elmo-diff-new (diff)
 910   (car diff))
 911
 912 (defsubst elmo-diff-unread (diff)
 913   (when (consp (cdr diff))
 914     (nth 1 diff)))
 915
 916 (defsubst elmo-diff-all (diff)
 917   (if (consp (cdr diff))
 918       (nth 2 diff)
 919     (cdr diff)))
 920
 921 (defsubst elmo-strict-folder-diff (folder)
 922   "Return folder diff information strictly from FOLDER."
 923   (let ((in-db (sort (elmo-msgdb-list-messages (elmo-folder-msgdb folder))
 924                      '<))
 925         (in-folder  (elmo-folder-list-messages folder))
 926         append-list delete-list diff)
 927     (cons (if (equal in-folder in-db)
 928               0
 929             (setq diff (elmo-list-diff in-folder in-db nil))
 930             (setq append-list (car diff))
 931             (setq delete-list (cadr diff))
 932             (if append-list
 933                 (length append-list)
 934               (if delete-list
 935                   (- 0 (length delete-list))
 936                 0)))
 937           (length in-folder))))
 938
 939 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 940   (elmo-generic-folder-diff folder))
 941
 942 (defun elmo-generic-folder-diff (folder)
 943   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 944                                 elmo-strict-diff-folder-list)
 945       (elmo-strict-folder-diff folder)
 946     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 947           (in-folder (elmo-folder-status folder))
 948           (in-db t)
 949           unsync messages
 950           in-db-max)
 951       (if (not cached-in-db-max)
 952           (let ((number-list (elmo-folder-list-messages folder
 953                                                         nil 'in-msgdb)))
 954             ;; No info-cache.
 955             (setq in-db (sort number-list '<))
 956             (setq in-db-max (or (nth (max 0 (1- (length in-db))) in-db)
 957                                 0))
 958             (elmo-folder-set-info-hashtb folder in-db-max nil))
 959         (setq in-db-max cached-in-db-max))
 960       (setq unsync (if (and in-db (car in-folder))
 961                        (- (car in-folder) in-db-max)
 962                      (if (and in-folder (null in-db))
 963                          (cdr in-folder)
 964                        (car in-folder))))
 965       (setq messages (cdr in-folder))
 966       (if (and unsync messages (> unsync messages))
 967           (setq unsync messages))
 968       (cons (or unsync 0) (or messages 0)))))
 969
 970 (defvar elmo-folder-diff-async-callback nil)
 971 (defvar elmo-folder-diff-async-callback-data nil)
 972
 973 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 974   (and elmo-folder-diff-async-callback
 975        (funcall elmo-folder-diff-async-callback
 976                 folder
 977                 (elmo-folder-diff folder))))
 978
 979 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
 980   (list folder))
 981
 982 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
 983   (eq (elmo-folder-type-internal folder) type))
 984
 985 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
 986                                                  src-folder
 987                                                  numbers
 988                                                  &optional
 989                                                  same-number)
 990   (elmo-generic-folder-append-messages folder src-folder numbers
 991                                        same-number))
 992
 993 (defun elmo-generic-folder-append-messages (folder src-folder numbers
 994                                                    same-number)
 995   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
 996         unseen table flags
 997         succeed-numbers failure cache id)
 998     (setq table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
 999     (with-temp-buffer
1000       (set-buffer-multibyte nil)
1001       (while numbers
1002         (setq failure nil
1003               id (and src-msgdb-exists
1004                       (elmo-message-field src-folder (car numbers)
1005                                           'message-id))
1006               flags (elmo-message-flags src-folder (car numbers)))
1007         (condition-case nil
1008             (setq cache (elmo-file-cache-get id)
1009                   failure
1010                   (not
1011                    (and
1012                     (elmo-message-fetch
1013                      src-folder (car numbers)
1014                      (if (elmo-folder-plugged-p src-folder)
1015                          (elmo-make-fetch-strategy
1016                           'entire 'maybe nil
1017                           (and cache (elmo-file-cache-path cache)))
1018                        (or (and elmo-enable-disconnected-operation
1019                                 cache
1020                                 (eq (elmo-file-cache-status cache) 'entire)
1021                                 (elmo-make-fetch-strategy
1022                                  'entire t nil
1023                                  (elmo-file-cache-path cache)))
1024                            (error "Unplugged")))
1025                      nil (current-buffer)
1026                      'unread)
1027                     (> (buffer-size) 0)
1028                     (elmo-folder-append-buffer
1029                      folder
1030                      (or flags '(read))
1031                      (if same-number (car numbers))))))
1032           (error (setq failure t)))
1033         ;; FETCH & APPEND finished
1034         (unless failure
1035           (when id
1036             (elmo-flag-table-set table id flags))
1037           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1038         (elmo-progress-notify 'elmo-folder-move-messages)
1039         (setq numbers (cdr numbers)))
1040       (when (elmo-folder-persistent-p folder)
1041         (elmo-flag-table-save (elmo-folder-msgdb-path folder) table))
1042       succeed-numbers)))
1043
1044 ;; Arguments should be reduced.
1045 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1046                                              &optional
1047                                              no-delete
1048                                              same-number)
1049   (save-excursion
1050     (let* ((messages msgs)
1051            (elmo-inhibit-display-retrieval-progress t)
1052            (len (length msgs))
1053            succeeds i result)
1054       (if (eq dst-folder 'null)
1055           (setq succeeds messages)
1056         (unless (elmo-folder-writable-p dst-folder)
1057           (error "move: %d is not writable"
1058                  (elmo-folder-name-internal dst-folder)))
1059         (when messages
1060           ;; src is already opened.
1061           (elmo-folder-open-internal dst-folder)
1062           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1063                                                               src-folder
1064                                                               messages
1065                                                               same-number))
1066             (error "move: append message to %s failed"
1067                    (elmo-folder-name-internal dst-folder)))
1068           (elmo-folder-close dst-folder)))
1069       (if (and (not no-delete) succeeds)
1070           (progn
1071             (if (and (elmo-folder-delete-messages src-folder succeeds)
1072                      (elmo-folder-detach-messages src-folder succeeds))
1073                 (progn
1074                   (elmo-global-flag-detach-messages
1075                    src-folder succeeds (eq dst-folder 'null))
1076                   (setq result t))
1077               (message "move: delete messages from %s failed."
1078                        (elmo-folder-name-internal src-folder))
1079               (setq result nil))
1080             result)
1081         (if no-delete
1082             (progn
1083               ;; (message "Copying messages...done")
1084               t)
1085           (if (eq len 0)
1086               (message "No message was moved.")
1087             (message "Moving messages failed.")
1088             nil ; failure
1089             ))))))
1090
1091 (defun elmo-folder-msgdb-path (folder)
1092   "Return the msgdb path for FOLDER."
1093   (or (elmo-folder-path-internal folder)
1094       (elmo-folder-set-path-internal
1095        folder
1096        (elmo-folder-expand-msgdb-path folder))))
1097
1098 (luna-define-generic elmo-message-cached-p (folder number)
1099   "Return non-nil if the message is cached.")
1100
1101 (luna-define-method elmo-message-cached-p ((folder elmo-folder) number)
1102   (elmo-message-flagged-p folder number 'cached))
1103
1104 (defun elmo-message-accessible-p (folder number)
1105   "Get accessibility of the message.
1106 Return non-nil when message is accessible."
1107   (or (elmo-folder-plugged-p folder)
1108       (elmo-folder-local-p folder)
1109       (elmo-message-cached-p folder number)))
1110
1111 (luna-define-generic elmo-message-set-cached (folder number cached)
1112   "Set cache status of the message in the msgdb.
1113 FOLDER is the ELMO folder structure.
1114 NUMBER is a number of the message.
1115 If CACHED is t, message is set as cached.")
1116
1117 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1118                                              number cached)
1119   (if cached
1120       (elmo-msgdb-set-flag (elmo-folder-msgdb folder) number 'cached)
1121     (elmo-msgdb-unset-flag (elmo-folder-msgdb folder) number 'cached)))
1122
1123 (defun elmo-message-copy-entity (entity)
1124   ;;
1125   (elmo-msgdb-copy-overview-entity entity))
1126
1127 (defun elmo-message-entity-set-number (entity number)
1128   (elmo-msgdb-overview-entity-set-number entity number))
1129
1130 (luna-define-generic elmo-message-entity (folder key)
1131   "Return the message-entity structure which matches to the KEY.
1132 KEY is a number or a string.
1133 A number is for message number in the FOLDER.
1134 A string is for message-id of the message.")
1135
1136 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1137   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1138
1139 (luna-define-generic elmo-message-entity-parent (folder entity)
1140   "Return the parent message-entity structure in the FOLDER.
1141 ENTITY is the message-entity to get the parent.")
1142
1143 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1144   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1145
1146 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1147 (def-edebug-spec elmo-folder-do-each-message-entity
1148   ((symbolp form &rest form) &rest form))
1149
1150 (defsubst elmo-folder-list-message-entities (folder)
1151   ;; List all message entities in the FOLDER.
1152   (mapcar
1153    (lambda (number) (elmo-message-entity folder number))
1154    (elmo-folder-list-messages folder nil t))) ; XXX killed-list is not used.
1155
1156 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1157   "Iterator for message entity in the folder.
1158 \(elmo-folder-do-each-message-entity \(entity folder\)
1159  ... do the process using entity...
1160 \)"
1161   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1162      ,@form))
1163
1164 (defmacro elmo-message-entity-number (entity)
1165   `(elmo-msgdb-overview-entity-get-number ,entity))
1166
1167 (defun elmo-message-entity-field (entity field &optional decode)
1168   "Get message entity field value.
1169 ENTITY is the message entity structure obtained by `elmo-message-entity'.
1170 FIELD is the symbol of the field name.
1171 if optional DECODE is non-nil, returned value is decoded."
1172   (elmo-msgdb-message-entity-field entity field decode))
1173
1174 (defun elmo-message-entity-set-field (entity field value)
1175   "Set message entity field value.
1176 ENTITY is the message entity structure.
1177 FIELD is the symbol of the field name.
1178 VALUE is the field value (raw)."
1179   (elmo-msgdb-message-entity-set-field entity field value))
1180
1181 (luna-define-generic elmo-folder-count-flags (folder)
1182   "Count flagged message number in the msgdb of the FOLDER.
1183 Return a list of numbers (`new' `unread' `answered')")
1184
1185 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1186   (let ((new 0)
1187         (unreads 0)
1188         (answered 0)
1189         flags)
1190     (dolist (number (elmo-folder-list-messages folder 'visible 'in-msgdb))
1191       (setq flags (elmo-message-flags folder number))
1192       (cond
1193        ((memq 'new flags)
1194         (incf new))
1195        ((memq 'unread flags)
1196         (incf unreads))
1197        ((memq 'answered flags)
1198         (incf answered))))
1199     (list new unreads answered)))
1200
1201 (luna-define-generic elmo-message-flags (folder number)
1202   "Return a list of flags.
1203 FOLDER is a ELMO folder structure.
1204 NUMBER is a number of the message.")
1205
1206 (luna-define-method elmo-message-flags ((folder elmo-folder) number)
1207   (elmo-msgdb-flags (elmo-folder-msgdb folder) number))
1208
1209 (defsubst elmo-message-flagged-p (folder number flag)
1210   "Return non-nil if the message is set FLAG.
1211 FOLDER is a ELMO folder structure.
1212 NUMBER is a message number to test."
1213   (let ((cur-flags (elmo-message-flags folder number)))
1214     (case flag
1215       (read
1216        (not (memq 'unread cur-flags)))
1217       (t
1218        (memq flag cur-flags)))))
1219
1220 (defun elmo-message-set-flag (folder number flag &optional is-local)
1221   "Set message flag.
1222 FOLDER is a ELMO folder structure.
1223 NUMBER is a message number to set flag.
1224
1225 FLAG is a symbol which is one of the following:
1226   `unread'    (set the message as unread)
1227   `answered'  (set the message as answered)
1228   `important' (set the message as important)
1229 'sugar' flag:
1230   `read'      (remove new and unread flags)
1231 If optional IS-LOCAL is non-nil, update only local (not server) status."
1232   ;; XXX Transitional implementation.
1233   (case flag
1234     (unread
1235      (elmo-folder-unflag-read folder (list number) is-local))
1236     (read
1237      (elmo-folder-flag-as-read folder (list number) is-local))
1238     (answered
1239      (elmo-folder-flag-as-answered folder (list number) is-local))
1240     (important
1241      (elmo-folder-flag-as-important folder (list number) is-local))))
1242
1243 (defun elmo-message-unset-flag (folder number flag &optional is-local)
1244   "Unset message flag.
1245 FOLDER is a ELMO folder structure.
1246 NUMBER is a message number to set flag.
1247
1248 FLAG is a symbol which is one of the following:
1249   `unread'    (remove unread and new flag)
1250   `answered'  (remove answered flag)
1251   `important' (remove important flag)
1252 'sugar' flag:
1253   `read'      (set unread flag)
1254 If optional IS-LOCAL is non-nil, update only local (not server) status."
1255   ;; XXX Transitional implementation.
1256   (case flag
1257     (unread
1258      (elmo-folder-flag-as-read folder (list number) is-local))
1259     (read
1260      (elmo-folder-unflag-read folder (list number) is-local))
1261     (answered
1262      (elmo-folder-unflag-answered folder (list number) is-local))
1263     (important
1264      (elmo-folder-unflag-important folder (list number) is-local))))
1265
1266 (luna-define-generic elmo-message-field (folder number field)
1267   "Get message field value in the msgdb.
1268 FOLDER is the ELMO folder structure.
1269 NUMBER is a number of the message.
1270 FIELD is a symbol of the field.")
1271
1272 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1273   (when (zerop (elmo-folder-length folder))
1274     (error "Cannot treat this folder correctly."))
1275   (elmo-msgdb-get-field (elmo-folder-msgdb folder) number field))
1276
1277 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1278   nil) ; default is not use cache.
1279
1280 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1281   folder) ; default is folder
1282
1283 (luna-define-method elmo-folder-unflag-important ((folder elmo-folder)
1284                                                   numbers
1285                                                   &optional is-local)
1286   (when (elmo-folder-msgdb-internal folder)
1287     (dolist (number numbers)
1288       (when (elmo-global-flag-p 'important)
1289         (elmo-global-flag-detach 'important folder number 'remove-if-none))
1290       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1291                              number
1292                              'important))))
1293
1294 (luna-define-method elmo-folder-flag-as-important ((folder elmo-folder)
1295                                                    numbers
1296                                                    &optional is-local)
1297   (let (path message-id)
1298     (when (elmo-folder-msgdb-internal folder)
1299       (dolist (number numbers)
1300         ;; important message should always be a read message.
1301         (if (eq (elmo-file-cache-exists-p
1302                  (setq message-id
1303                        (elmo-message-field folder number 'message-id)))
1304                 'entire)
1305             (elmo-folder-flag-as-read folder (list number)))
1306         (when (elmo-global-flag-p 'important)
1307           (elmo-global-flag-set 'important folder number message-id))
1308         (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1309                              number
1310                              'important)))))
1311
1312 (luna-define-method elmo-folder-unflag-read ((folder elmo-folder)
1313                                              numbers
1314                                              &optional is-local)
1315   (when (elmo-folder-msgdb-internal folder)
1316     (dolist (number numbers)
1317       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1318                              number
1319                              'read))))
1320
1321 (luna-define-method elmo-folder-flag-as-read ((folder elmo-folder)
1322                                               numbers
1323                                               &optional is-local)
1324   (when (elmo-folder-msgdb-internal folder)
1325     (dolist (number numbers)
1326       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1327                            number
1328                            'read))))
1329
1330 (luna-define-method elmo-folder-unflag-answered ((folder elmo-folder)
1331                                                  numbers
1332                                                  &optional is-local)
1333   (when (elmo-folder-msgdb-internal folder)
1334     (dolist (number numbers)
1335       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1336                              number
1337                              'answered))))
1338
1339 (luna-define-method elmo-folder-flag-as-answered ((folder elmo-folder)
1340                                                   numbers
1341                                                   &optional is-local)
1342   (when (elmo-folder-msgdb-internal folder)
1343     (dolist (number numbers)
1344       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1345                            number
1346                            'answered))))
1347
1348 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1349   ;; Do nothing.
1350   )
1351
1352 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1353 ;;                                                             &optional
1354 ;;                                                             flag-table)
1355 ;;  "Append ENTITY to the folder.")
1356
1357 (defun elmo-msgdb-merge (folder msgdb-merge)
1358   "Return a list of messages which have duplicated message-id."
1359   (let (msgdb duplicates)
1360     (setq msgdb (or (elmo-folder-msgdb-internal folder)
1361                     (elmo-make-msgdb (elmo-folder-msgdb-path folder))))
1362     (setq duplicates (elmo-msgdb-append msgdb msgdb-merge))
1363     (elmo-folder-set-msgdb-internal folder msgdb)
1364     duplicates))
1365
1366 (defsubst elmo-folder-append-msgdb (folder append-msgdb)
1367   (if append-msgdb
1368       (let ((duplicates (elmo-msgdb-merge folder append-msgdb)))
1369         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1370                    'hide)
1371                ;; Let duplicates be a temporary killed message.
1372                (elmo-folder-kill-messages folder duplicates)
1373                ;; Should be flag as read.
1374                (elmo-folder-flag-as-read folder duplicates))
1375               ((eq (elmo-folder-process-duplicates-internal folder)
1376                    'read)
1377                ;; Flag as read duplicates.
1378                (elmo-folder-flag-as-read folder duplicates))
1379               (t
1380                ;; Do nothing.
1381                (setq duplicates nil)))
1382         (length duplicates))
1383     0))
1384
1385 (defun elmo-folder-confirm-appends (appends)
1386   (let ((len (length appends))
1387         in)
1388     (if (and elmo-folder-update-threshold
1389              (> len elmo-folder-update-threshold)
1390              elmo-folder-update-confirm)
1391         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1392             appends
1393           (setq in elmo-folder-update-threshold)
1394           (catch 'end
1395             (while t
1396               (setq in (read-from-minibuffer "Update number: "
1397                                              (int-to-string in))
1398                     in (string-to-int in))
1399               (if (< len in)
1400                   (throw 'end len))
1401               (if (y-or-n-p (format
1402                              "%d messages are killed (not appeared). OK? "
1403                              (max (- len in) 0)))
1404                   (throw 'end in))))
1405           (nthcdr (max (- len in) 0) appends))
1406       (if (and elmo-folder-update-threshold
1407                (> len elmo-folder-update-threshold)
1408                (not elmo-folder-update-confirm))
1409           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1410         appends))))
1411
1412 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1413                                         number strategy
1414                                         &optional
1415                                         section
1416                                         outbuf
1417                                         unread)
1418   (if outbuf
1419       (with-current-buffer outbuf
1420         (erase-buffer)
1421         (elmo-message-fetch-with-cache-process folder number
1422                                                strategy section unread))
1423     (with-temp-buffer
1424       (elmo-message-fetch-with-cache-process folder number
1425                                              strategy section unread)
1426       (buffer-string))))
1427
1428 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1429                                                            number strategy
1430                                                            &optional
1431                                                            section unread)
1432   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1433         (method-priorities
1434          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1435                 '(entity cache))
1436                ((elmo-fetch-strategy-use-cache strategy)
1437                 '(cache entity))
1438                (t
1439                 '(entity))))
1440         result err)
1441     (while (and method-priorities
1442                 (null result))
1443       (setq result
1444             (case (car method-priorities)
1445               (cache
1446                (elmo-file-cache-load cache-path section))
1447               (entity
1448                (when (and (condition-case error
1449                               (elmo-message-fetch-internal folder number
1450                                                            strategy
1451                                                            section
1452                                                            unread)
1453                             (error (setq err error) nil))
1454                           (> (buffer-size) 0))
1455                  (elmo-delete-cr-buffer)
1456                  (when (and (elmo-fetch-strategy-save-cache strategy)
1457                             cache-path)
1458                    (elmo-file-cache-save cache-path section))
1459                  t)))
1460             method-priorities (cdr method-priorities)))
1461     (or result
1462         (and err (signal (car err) (cdr err))))))
1463
1464 (defun elmo-folder-kill-messages-before (folder msg)
1465   (elmo-folder-set-killed-list-internal
1466    folder
1467    (list (cons 1 msg))))
1468
1469 (defun elmo-folder-kill-messages (folder numbers)
1470   "Kill(hide) messages in the FOLDER with NUMBERS."
1471   (elmo-folder-set-killed-list-internal
1472    folder
1473    (elmo-number-set-append-list (elmo-folder-killed-list-internal
1474                                  folder) numbers)))
1475
1476
1477 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1478                                        &optional keep-killed)
1479   (unless keep-killed
1480     (elmo-folder-set-killed-list-internal folder nil))
1481   (elmo-msgdb-clear (elmo-folder-msgdb folder)))
1482
1483 (luna-define-generic elmo-folder-synchronize (folder
1484                                               &optional
1485                                               disable-killed
1486                                               ignore-msgdb
1487                                               no-check)
1488   "Synchronize the folder data to the newest status.
1489 FOLDER is the ELMO folder structure.
1490
1491 If optional DISABLE-KILLED is non-nil, killed messages are also synchronized.
1492 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1493 flag status.
1494 If NO-CHECK is non-nil, rechecking folder is skipped.
1495 Return a list of a cross-posted message number.
1496 If update process is interrupted, return nil.")
1497
1498 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1499                                              &optional
1500                                              disable-killed
1501                                              ignore-msgdb
1502                                              no-check)
1503   (let ((killed-list (elmo-folder-killed-list-internal folder))
1504         (before-append t)
1505         old-msgdb diff diff-2 delete-list new-list new-msgdb flag
1506         flag-table crossed after-append)
1507     (setq old-msgdb (elmo-folder-msgdb folder))
1508     (setq flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1509     (when ignore-msgdb
1510       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1511       (elmo-folder-clear folder (not disable-killed)))
1512     (unless no-check (elmo-folder-check folder))
1513     (condition-case nil
1514         (progn
1515           (message "Checking folder diff...")
1516           (setq diff (elmo-list-diff (elmo-folder-list-messages
1517                                       folder
1518                                       (not disable-killed))
1519                                      (elmo-folder-list-messages
1520                                       folder
1521                                       (not disable-killed)
1522                                       'in-msgdb)))
1523           (message "Checking folder diff...done")
1524           (setq new-list (elmo-folder-confirm-appends (car diff)))
1525           ;; Set killed list as ((1 . MAX-OF-DISAPPEARED))
1526           (when (and (not (eq (length (car diff))
1527                               (length new-list)))
1528                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1529             (elmo-folder-kill-messages-before folder
1530                                               (nth (- (length (car diff-2)) 1)
1531                                                    (car diff-2))))
1532           (setq delete-list (cadr diff))
1533           (if (or (equal diff '(nil nil))
1534                   (equal diff '(nil))
1535                   (and (eq (length (car diff)) 0)
1536                        (eq (length (cadr diff)) 0)))
1537               (progn
1538                 (elmo-folder-update-number folder)
1539                 (elmo-folder-process-crosspost folder)
1540                 0 ; no updates.
1541                 )
1542             (when delete-list
1543               (elmo-folder-detach-messages folder delete-list))
1544             (when new-list
1545               (elmo-msgdb-out-of-date-messages (elmo-folder-msgdb folder))
1546               (setq new-msgdb (elmo-folder-msgdb-create
1547                                folder new-list flag-table))
1548               ;; Clear flag-table
1549               (if (elmo-folder-persistent-p folder)
1550                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1551                                         nil))
1552               (setq before-append nil)
1553               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1554               ;; process crosspost.
1555               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).
1556               (elmo-folder-process-crosspost folder)
1557               (elmo-folder-set-message-modified folder t)
1558               (elmo-folder-set-flag-modified-internal folder t))
1559             ;; return value.
1560             (or crossed 0)))
1561       (quit
1562        ;; Resume to the original status.
1563        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1564        (elmo-folder-set-killed-list-internal folder killed-list)
1565        nil))))
1566
1567 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1568   "Remove messages with NUMBERS from MSGDB.")
1569
1570 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1571                                                  numbers)
1572   (elmo-msgdb-delete-messages (elmo-folder-msgdb folder) numbers))
1573
1574 (luna-define-generic elmo-folder-length (folder)
1575   "Return number of messages in the FOLDER.")
1576
1577 (luna-define-method elmo-folder-length ((folder elmo-folder))
1578   (if (elmo-folder-msgdb-internal folder)
1579       (elmo-msgdb-length (elmo-folder-msgdb folder))
1580     0))
1581
1582 (defun elmo-folder-msgdb-load (folder &optional silent)
1583   (unless silent
1584     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1585   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1586     (elmo-folder-set-info-max-by-numdb
1587      folder
1588      (elmo-msgdb-list-messages msgdb))
1589     (unless silent
1590       (message "Loading msgdb for %s...done"
1591                (elmo-folder-name-internal folder)))
1592     msgdb))
1593
1594 (defun elmo-msgdb-delete-path (folder)
1595   (let ((path (elmo-folder-msgdb-path folder)))
1596     (if (file-directory-p path)
1597         (elmo-delete-directory path t))))
1598
1599 (defun elmo-msgdb-rename-path (old-folder new-folder)
1600   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1601          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1602          (new-dir (directory-file-name (file-name-directory new))))
1603     (if (not (file-directory-p old))
1604         ()
1605       (if (file-exists-p new)
1606           (error "Already exists directory: %s" new)
1607         (if (not (file-exists-p new-dir))
1608             (elmo-make-directory new-dir))
1609         (rename-file old new)))))
1610
1611 (defun elmo-setup-subscribed-newsgroups (groups)
1612   "Setup subscribed newsgroups.
1613 GROUPS is a list of newsgroup name string.
1614 Return a hashtable for newsgroups."
1615   (let ((hashtb (or elmo-newsgroups-hashtb
1616                     (setq elmo-newsgroups-hashtb
1617                           (elmo-make-hash (length groups))))))
1618     (dolist (group groups)
1619       (or (elmo-get-hash-val group hashtb)
1620           (elmo-set-hash-val group nil hashtb)))
1621     (setq elmo-newsgroups-hashtb hashtb)))
1622
1623 (defvar elmo-crosspost-message-alist-modified nil)
1624 (defun elmo-crosspost-message-alist-load ()
1625   "Load crosspost message alist."
1626   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1627   (setq elmo-crosspost-message-alist-modified nil))
1628
1629 (defun elmo-crosspost-message-alist-save ()
1630   "Save crosspost message alist."
1631   (when elmo-crosspost-message-alist-modified
1632     (let ((alist elmo-crosspost-message-alist)
1633           newsgroups)
1634       (while alist
1635         (setq newsgroups
1636               (elmo-delete-if
1637                '(lambda (x)
1638                   (not (intern-soft x elmo-newsgroups-hashtb)))
1639                (nth 1 (car alist))))
1640         (if newsgroups
1641             (setcar (cdar alist) newsgroups)
1642           (setq elmo-crosspost-message-alist
1643                 (delete (car alist) elmo-crosspost-message-alist)))
1644         (setq alist (cdr alist)))
1645       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1646       (setq elmo-crosspost-message-alist-modified nil))))
1647
1648 (defun elmo-folder-make-temporary-directory (folder)
1649   ;; Make a temporary directory for FOLDER.
1650   (let ((temp-dir (make-temp-name
1651                    (concat
1652                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1653                     "elmo"))))
1654     (elmo-make-directory temp-dir)
1655     temp-dir))
1656
1657 (defun elmo-init ()
1658   "Initialize ELMO module."
1659   (elmo-crosspost-message-alist-load)
1660   (elmo-resque-obsolete-variables)
1661   (elmo-global-flag-initialize)
1662   (elmo-dop-queue-load))
1663
1664 (defun elmo-quit ()
1665   "Quit and cleanup ELMO."
1666   (elmo-crosspost-message-alist-save)
1667   (elmo-dop-queue-save)
1668   ;; Not implemented yet.
1669   (let ((types elmo-folder-type-alist)
1670         class)
1671     (while types
1672       (setq class
1673             (luna-find-class
1674              (intern (format "elmo-%s-folder"
1675                              (symbol-name (cdr (car types)))))))
1676       ;; Call all folder's `elmo-quit' method.
1677       (if class
1678           (dolist (func (luna-class-find-functions class 'elmo-quit))
1679             (funcall func nil)))
1680       (setq types (cdr types)))))
1681
1682 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1683                                                  new-folder)
1684   (error "Cannot rename %s folder"
1685          (symbol-name (elmo-folder-type-internal folder))))
1686
1687 ;;; Define folders.
1688 (elmo-define-folder ?% 'imap4)
1689 (elmo-define-folder ?-  'nntp)
1690 (elmo-define-folder ?\+ 'localdir)
1691 (elmo-define-folder ?\* 'multi)
1692 (elmo-define-folder ?\/ 'filter)
1693 (elmo-define-folder ?\$ 'archive)
1694 (elmo-define-folder ?&  'pop3)
1695 (elmo-define-folder ?=  'localnews)
1696 (elmo-define-folder ?|  'pipe)
1697 (elmo-define-folder ?.  'maildir)
1698 (elmo-define-folder ?'  'internal)
1699 (elmo-define-folder ?\[  'nmz)
1700 (elmo-define-folder ?@  'shimbun)
1701
1702 ;;; Obsolete variables.
1703 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1704                                'elmo-imap4-default-mailbox)
1705 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1706                                'elmo-imap4-default-server)
1707 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1708                                'elmo-imap4-default-authenticate-type)
1709 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1710                                'elmo-imap4-default-user)
1711 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1712                                'elmo-imap4-default-port)
1713 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1714                                'elmo-imap4-default-stream-type)
1715 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1716                                'elmo-nntp-default-server)
1717 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1718                                'elmo-nntp-default-user)
1719 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1720                                'elmo-nntp-default-port)
1721 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1722                                'elmo-nntp-default-stream-type)
1723 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1724                                'elmo-pop3-default-server)
1725 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1726                                'elmo-pop3-default-user)
1727 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1728                                'elmo-pop3-default-authenticate-type)
1729 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1730                                'elmo-pop3-default-port)
1731 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1732                                'elmo-pop3-default-stream-type)
1733 (elmo-define-obsolete-variable 'elmo-cache-dirname
1734                                'elmo-cache-directory)
1735 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1736                                'elmo-msgdb-directory)
1737
1738 ;; Obsolete functions.
1739 ;; 2001-12-11: *-dir -> *-directory
1740 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1741 (make-obsolete 'elmo-folder-make-temp-dir
1742                'elmo-folder-make-temporary-directory)
1743
1744
1745 ;; autoloads
1746 (autoload 'elmo-dop-queue-flush "elmo-dop")
1747 (autoload 'elmo-nntp-post "elmo-nntp")
1748 (autoload 'elmo-global-flag-initialize "elmo-flag")
1749 (autoload 'elmo-global-flag-p "elmo-flag")
1750 (autoload 'elmo-global-flag-detach "elmo-flag")
1751 (autoload 'elmo-global-flag-detach-messages "elmo-flag")
1752 (autoload 'elmo-global-flag-set "elmo-flag")
1753
1754 (require 'product)
1755 (product-provide (provide 'elmo) (require 'elmo-version))
1756
1757 ;;; elmo.el ends here