elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type 'integer
  50   :group 'elmo)
  51
  52 (defcustom elmo-message-fetch-confirm t
  53   "If non-nil, confirm fetching if message size is larger than
  54 `elmo-message-fetch-threshold'.
  55 Otherwise, entire fetching of the message is aborted without confirmation."
  56   :type 'boolean
  57   :group 'elmo)
  58
  59 (defcustom elmo-folder-update-threshold 500
  60   "Update threshold."
  61   :type 'integer
  62   :group 'elmo)
  63
  64 (defcustom elmo-folder-update-confirm t
  65   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  66   :type 'boolean
  67   :group 'elmo)
  68
  69 (defvar elmo-message-displaying nil
  70   "A global switch to indicate message is displaying or not.")
  71
  72 ;;; internal
  73 (defvar elmo-folder-type-alist nil)
  74
  75 (defvar elmo-newsgroups-hashtb nil)
  76
  77 (elmo-define-error 'elmo-error "Error" 'error)
  78 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  79 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  80 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  81
  82 (defun elmo-define-folder (prefix backend)
  83   "Define a folder.
  84 If a folder name begins with PREFIX, use BACKEND."
  85   (let ((pair (assq prefix elmo-folder-type-alist)))
  86     (if pair
  87         (progn
  88           (setcar pair prefix)
  89           (setcdr pair backend))
  90       (setq elmo-folder-type-alist (cons (cons prefix backend)
  91                                          elmo-folder-type-alist)))))
  92
  93 (defmacro elmo-folder-type (name)
  94   "Get folder type from NAME string."
  95   (` (and (stringp (, name))
  96           (cdr (assoc (string-to-char (, name)) elmo-folder-type-alist)))))
  97
  98 ;;; ELMO folder
  99 ;; A elmo folder provides uniformed (orchestrated) access
 100 ;; to the internet messages.
 101 (eval-and-compile
 102   (luna-define-class elmo-folder () (type   ; folder type symbol.
 103                                      name   ; orignal folder name string.
 104                                      prefix ; prefix for folder name
 105                                      path   ; directory path for msgdb.
 106                                      msgdb  ; msgdb (may be nil).
 107                                      killed-list  ; killed list.
 108                                      persistent   ; non-nil if persistent.
 109                                      message-modified ; message is modified.
 110                                      mark-modified    ; mark is modified.
 111                                      process-duplicates  ; read or hide
 112                                      biff   ; folder for biff
 113                                      ))
 114   (luna-define-internal-accessors 'elmo-folder))
 115
 116 (luna-define-generic elmo-folder-initialize (folder name)
 117   ;; Initialize a FOLDER structure with NAME."
 118   )
 119
 120 (defmacro elmo-folder-send (folder message &rest args)
 121   "Let FOLDER receive the MESSAGE with ARGS."
 122   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 123
 124 ;;;###autoload
 125 (defun elmo-make-folder (name &optional non-persistent)
 126   "Make an ELMO folder structure specified by NAME.
 127 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 128   (let ((type (elmo-folder-type name))
 129         prefix split class folder original)
 130     (setq original (elmo-string name))
 131     (if type
 132         (progn
 133           (setq prefix (substring name 0 1))
 134           (setq name (substring name 1)))
 135       (setq type (intern (car (setq split (split-string name ":")))))
 136       (if (> (length split) 2)
 137           (setq name (substring name (+ 1 (length (car split)))))
 138         (error "Error in folder name `%s'" original))
 139       (setq prefix (concat (car split) ":")))
 140     (setq class (format "elmo-%s" (symbol-name type)))
 141     (require (intern class))
 142     (setq folder (luna-make-entity (intern (concat class "-folder"))
 143                                    :type type
 144                                    :prefix prefix
 145                                    :name original
 146                                    :persistent (not non-persistent)))
 147     (save-match-data
 148       (elmo-folder-send folder 'elmo-folder-initialize name))))
 149
 150 ;; Note that this function is for internal use only.
 151 (luna-define-generic elmo-folder-msgdb (folder)
 152   "Return the msgdb of FOLDER (on-demand loading).
 153 \(For internal use only.\)")
 154
 155 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 156   (or (elmo-folder-msgdb-internal folder)
 157       (elmo-folder-set-msgdb-internal folder
 158                                       (elmo-msgdb-load folder))))
 159
 160 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 161   "Open and setup (load saved status) FOLDER.
 162 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 163 \(otherwise, msgdb is loaded on-demand)")
 164
 165 (luna-define-generic elmo-folder-open-internal (folder)
 166   "Open FOLDER (without loading saved folder status).")
 167
 168 (luna-define-generic elmo-folder-check (folder)
 169   "Check the FOLDER to obtain newest information at the next list operation.")
 170
 171 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 172   "Clear FOLDER to the initial state.
 173 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 174
 175 (luna-define-generic elmo-folder-commit (folder)
 176   "Save current status of FOLDER.")
 177
 178 (luna-define-generic elmo-folder-close (folder)
 179   "Close, save and clearnup FOLDER.")
 180
 181 (luna-define-generic elmo-folder-close-internal (folder)
 182   "Close FOLDER (without saving folder status).")
 183
 184 (luna-define-generic elmo-folder-plugged-p (folder)
 185   "Returns t if FOLDER is plugged.")
 186
 187 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 188   "Set FOLDER as plugged.")
 189
 190 (luna-define-generic elmo-net-port-info (folder)
 191   "Get port information of FOLDER.")
 192
 193 (luna-define-generic elmo-folder-use-flag-p (folder)
 194   "Returns t if FOLDER treats unread/important flag itself.")
 195
 196 (luna-define-generic elmo-folder-diff (folder)
 197   "Get diff of FOLDER.
 198 Return value is cons cell or list:
 199  - a cons cell (new . all)
 200  - a list (new unread all)")
 201
 202 (luna-define-generic elmo-folder-status (folder)
 203   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 204
 205 (luna-define-generic elmo-folder-reserve-status-p (folder)
 206   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 207
 208 (luna-define-generic elmo-folder-set-message-modified (folder modified)
 209   "Set FOLDER as modified.")
 210 (luna-define-method elmo-folder-set-message-modified ((folder elmo-folder)
 211                                                       modified)
 212   (elmo-folder-set-message-modified-internal folder modified))
 213
 214 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 215                                                        in-msgdb)
 216   "Return a list of message numbers contained in FOLDER.
 217 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 218 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 219 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 220                                                &optional visible-only in-msgdb)
 221   (let ((list (if in-msgdb
 222                   t
 223                 (elmo-folder-list-messages-internal folder visible-only))))
 224     (setq list
 225           (if (listp list)
 226               list
 227             ;; Use current list.
 228             (elmo-msgdb-list-messages (elmo-folder-msgdb folder))))
 229     (if visible-only
 230         (elmo-living-messages list (elmo-folder-killed-list-internal folder))
 231       list)))
 232
 233 (luna-define-generic elmo-folder-list-unreads (folder)
 234   "Return a list of unread message numbers contained in FOLDER.")
 235 (luna-define-generic elmo-folder-list-importants (folder)
 236   "Return a list of important message numbers contained in FOLDER.")
 237 (luna-define-generic elmo-folder-list-answereds (folder)
 238   "Return a list of answered message numbers contained in FOLDER.")
 239
 240 ;; TODO: Should reconsider the structure of global mark.
 241 (defun elmo-folder-list-messages-with-global-mark (folder mark)
 242   (let (entity msgs)
 243     (dolist (mark-pair (or elmo-msgdb-global-mark-alist
 244                            (setq elmo-msgdb-global-mark-alist
 245                                  (elmo-object-load
 246                                   (expand-file-name
 247                                    elmo-msgdb-global-mark-filename
 248                                    elmo-msgdb-directory)))))
 249       (if (and (string= mark (cdr mark-pair))
 250                (setq entity
 251                      (elmo-msgdb-overview-get-entity (car mark-pair)
 252                                                      (elmo-folder-msgdb
 253                                                       folder))))
 254           (setq msgs (cons (elmo-msgdb-overview-entity-get-number entity)
 255                            msgs))))
 256     msgs))
 257
 258 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 259   "List messages in the FOLDER with FLAG.
 260 FLAG is a symbol which is one of the following:
 261   `new'        (new messages)
 262   `unread'     (unread messages (new messages are included))
 263   `answered'   (answered or forwarded)
 264   `important'  (marked as important)
 265 'sugar' flags:
 266   `read'       (not unread)
 267   `digest'     (unread + important)
 268   `any'        (digest + answered)
 269
 270 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 271
 272 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 273                                               &optional in-msgdb)
 274   ;; Currently, only in-msgdb is implemented.
 275   (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag))
 276
 277 (luna-define-method elmo-folder-list-unreads ((folder elmo-folder))
 278   (elmo-folder-list-flagged folder 'unread))
 279
 280 (luna-define-method elmo-folder-list-importants ((folder elmo-folder))
 281   (elmo-folder-list-flagged folder 'important))
 282
 283 (luna-define-method elmo-folder-list-answereds ((folder elmo-folder))
 284   (elmo-folder-list-flagged folder 'answered))
 285
 286 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 287                                                                 visible-only)
 288   ;; Return a list of message numbers contained in FOLDER.
 289   ;; Return t if the message list is not available.
 290   )
 291
 292 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 293   "Returns a list of subfolders contained in FOLDER.
 294 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 295 \(a folder which have children is returned as a list\)
 296 Otherwise, all descendent folders are returned.")
 297
 298 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 299   "Return non-nil when FOLDER has subfolders.")
 300
 301 (luna-define-generic elmo-folder-exists-p (folder)
 302   "Returns non-nil when FOLDER exists.")
 303
 304 (luna-define-generic elmo-folder-creatable-p (folder)
 305   "Returns non-nil when FOLDER is creatable.")
 306
 307 (luna-define-generic elmo-folder-writable-p (folder)
 308   "Returns non-nil when FOLDER is writable.")
 309
 310 (luna-define-generic elmo-folder-persistent-p (folder)
 311   "Return non-nil when FOLDER is persistent.")
 312
 313 (luna-define-generic elmo-folder-create (folder)
 314   "Create a FOLDER.")
 315
 316 (luna-define-generic elmo-message-deletable-p (folder number)
 317   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 318
 319 (luna-define-generic elmo-folder-delete (folder)
 320   "Delete FOLDER completely.")
 321
 322 (luna-define-generic elmo-folder-rename (folder new-name)
 323   "Rename FOLDER to NEW-NAME (string).")
 324
 325 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 326   "Delete messages.
 327 FOLDER is the ELMO folder structure.
 328 NUMBERS is a list of message numbers to be deleted.")
 329
 330 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 331   "Search and return list of message numbers.
 332 FOLDER is the ELMO folder structure.
 333 CONDITION is a condition structure for searching.
 334 If optional argument NUMBERS is specified and is a list of message numbers,
 335 messages are searched from the list.")
 336
 337 (luna-define-generic elmo-message-match-condition (folder number
 338                                                           condition
 339                                                           numbers)
 340   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 341 CONDITION is a condition structure for testing.
 342 NUMBERS is a list of message numbers,
 343 use to be test for \"last\" and \"first\" predicates.")
 344
 345 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 346   "Create a message database (implemented in each backends).
 347 FOLDER is the ELMO folder structure.
 348 NUMBERS is a list of message numbers to create msgdb.
 349 FLAG-TABLE is a hashtable of message-id and flag.")
 350
 351 (luna-define-generic elmo-folder-unmark-important (folder
 352                                                    numbers
 353                                                    &optional ignore-flags)
 354   "Un-mark messages as important.
 355 FOLDER is the ELMO folder structure.
 356 NUMBERS is a list of message numbers to be processed.
 357 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 358
 359 (luna-define-generic elmo-folder-mark-as-important (folder
 360                                                     numbers
 361                                                     &optional ignore-flags)
 362   "Mark messages as important.
 363 FOLDER is the ELMO folder structure.
 364 NUMBERS is a list of message numbers to be processed.
 365 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 366
 367 (luna-define-generic elmo-folder-unmark-read (folder numbers
 368                                                      &optional ignore-flags)
 369   "Un-mark messages as read.
 370 FOLDER is the ELMO folder structure.
 371 NUMBERS is a list of message numbers to be processed.
 372 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 373
 374 (luna-define-generic elmo-folder-mark-as-read (folder numbers
 375                                                       &optional ignore-flags)
 376   "Mark messages as read.
 377 FOLDER is the ELMO folder structure.
 378 NUMBERS is a list of message numbers to be processed.
 379 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 380
 381 (luna-define-generic elmo-folder-unmark-answered (folder numbers)
 382   "Un-mark messages as answered.
 383 FOLDER is the ELMO folder structure.
 384 NUMBERS is a list of message numbers to be processed.")
 385
 386 (luna-define-generic elmo-folder-mark-as-answered (folder numbers)
 387   "Mark messages as answered.
 388 FOLDER is the ELMO folder structure.
 389 NUMBERS is a list of message numbers to be processed.")
 390
 391 (luna-define-generic elmo-folder-append-buffer (folder &optional flag
 392                                                        number)
 393   "Append current buffer as a new message.
 394 FOLDER is the destination folder(ELMO folder structure).
 395 FLAG is the status of appended message.
 396 If optional argument NUMBER is specified, the new message number is set
 397 \(if possible\).")
 398
 399 (luna-define-generic elmo-folder-append-messages (folder
 400                                                   src-folder
 401                                                   numbers
 402                                                   &optional
 403                                                   same-number)
 404   "Append messages from folder.
 405 FOLDER is the ELMO folder structure.
 406 Caller should make sure FOLDER is `writable'.
 407 (Can be checked with `elmo-folder-writable-p').
 408 SRC-FOLDER is the source ELMO folder structure.
 409 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 410 If second optional argument SAME-NUMBER is specified,
 411 message number is preserved (if possible).")
 412
 413 (luna-define-generic elmo-folder-pack-numbers (folder)
 414   "Pack message numbers of FOLDER.")
 415
 416 (luna-define-generic elmo-folder-update-number (folder)
 417   "Update number of FOLDER.")
 418
 419 (luna-define-generic elmo-folder-diff-async (folder)
 420   "Get diff of FOLDER asynchronously.")
 421
 422 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 423   "Expand path for FOLDER.")
 424
 425 (luna-define-generic elmo-folder-get-primitive-list (folder)
 426   "Get primitive folder structure list contained in FOLDER.")
 427
 428 (luna-define-generic elmo-folder-contains-type (folder type)
 429   "Returns t if FOLDER contains TYPE.")
 430
 431 (luna-define-generic elmo-folder-local-p (folder)
 432   "Returns t if FOLDER is local.")
 433
 434 (luna-define-generic elmo-folder-message-file-p (folder)
 435   "Returns t if all messages in the FOLDER are files.")
 436
 437 ;;; Message methods.
 438 (luna-define-generic elmo-message-use-cache-p (folder number)
 439   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 440
 441 (luna-define-generic elmo-message-file-name (folder number)
 442   "Return the file name of a message specified by FOLDER and NUMBER.")
 443
 444 ;;; For archive
 445
 446 ;;; Use original file
 447 (luna-define-generic elmo-folder-message-file-number-p (folder)
 448   "Return t if the file name in the FOLDER is the message number.")
 449
 450 (luna-define-generic elmo-folder-message-file-directory (folder)
 451   "Return the directory of the message files of FOLDER.")
 452
 453 ;;; Use temporary file
 454 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 455   "Return t if the messages in the FOLDER makes local temporary file.")
 456
 457 (luna-define-generic elmo-folder-message-make-temp-files (folder
 458                                                           numbers
 459                                                           &optional
 460                                                           start-number)
 461   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 462 If START-NUMBER is specified, temporary files begin from the number.
 463 Otherwise, same number is used for temporary files.
 464 Return newly created temporary directory name which contains temporary files.")
 465
 466 (luna-define-generic elmo-message-file-p (folder number)
 467   "Return t if message in the FOLDER with NUMBER is a file.")
 468
 469 (luna-define-generic elmo-find-fetch-strategy
 470   (folder entity &optional ignore-cache)
 471 ;; Returns the message fetching strategy suitable for the message.
 472 ;; FOLDER is the ELMO folder structure.
 473 ;; ENTITY is the overview entity of the message in the folder.
 474 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 475 ;; Returned value is a elmo-fetch-strategy object.
 476 ;; If return value is nil, message should not be nil.
 477   )
 478
 479 (defmacro elmo-make-fetch-strategy (entireness
 480                                     &optional
 481                                     use-cache
 482                                     save-cache
 483                                     cache-path)
 484 ;; Make elmo-message-fetching strategy.
 485 ;; ENTIRENESS is 'entire or 'section.
 486 ;; 'entire means fetch message entirely at once.
 487 ;; 'section means fetch message section by section.
 488 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 489 ;; existing cache is thrown away.
 490 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 491 ;; CACHE-PATH is the cache path to be used as a message cache file.
 492   (` (vector (, entireness)
 493              (, use-cache) (, save-cache) (, cache-path))))
 494
 495 (defmacro elmo-fetch-strategy-entireness (strategy)
 496   ;; Return entireness of STRATEGY.
 497   (` (aref (, strategy) 0)))
 498
 499 (defmacro elmo-fetch-strategy-use-cache (strategy)
 500   ;; Return use-cache of STRATEGY.
 501   (` (aref (, strategy) 1)))
 502
 503 (defmacro elmo-fetch-strategy-save-cache (strategy)
 504   ;; Return save-cache of STRATEGY.
 505   (` (aref (, strategy) 2)))
 506
 507 (defmacro elmo-fetch-strategy-cache-path (strategy)
 508   ;;  Return cache-path of STRATEGY.
 509   (` (aref (, strategy) 3)))
 510
 511 (luna-define-method elmo-find-fetch-strategy
 512   ((folder elmo-folder) entity &optional ignore-cache)
 513   (let (cache-file size message-id number)
 514     (setq size (elmo-msgdb-overview-entity-get-size entity))
 515     (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 516     (setq number (elmo-msgdb-overview-entity-get-number entity))
 517     (setq cache-file (elmo-file-cache-get message-id))
 518     (setq ignore-cache (or ignore-cache
 519                            (null (elmo-message-use-cache-p folder number))))
 520     (if (or ignore-cache
 521             (null (elmo-file-cache-status cache-file)))
 522         ;; No cache or ignore-cache.
 523         (if (and (not (elmo-folder-local-p folder))
 524                  elmo-message-fetch-threshold
 525                  (integerp size)
 526                  (>= size elmo-message-fetch-threshold)
 527                  (or (not elmo-message-fetch-confirm)
 528                      (not (prog1 (y-or-n-p
 529                                   (format "Fetch entire message(%dbytes)? "
 530                                           size))
 531                             (message "")))))
 532             ;; Don't fetch message at all.
 533             nil
 534           ;; Don't use existing cache and fetch entire message at once.
 535           (elmo-make-fetch-strategy
 536            'entire nil
 537            (elmo-message-use-cache-p folder number)
 538            (elmo-file-cache-path cache-file)))
 539       ;; Cache exists.
 540       (if (not ignore-cache)
 541           (elmo-make-fetch-strategy
 542            'entire
 543            ;; ...But ignore current section cache and re-fetch
 544            ;; if section cache.
 545            (not (eq (elmo-file-cache-status cache-file) 'section))
 546            ;; Save cache.
 547            (elmo-message-use-cache-p folder number)
 548            (elmo-file-cache-path cache-file))))))
 549
 550 (luna-define-method elmo-folder-list-messages-internal
 551   ((folder elmo-folder) &optional visible-only)
 552   t)
 553
 554 (defun elmo-folder-encache (folder numbers &optional unread)
 555   "Encache messages in the FOLDER with NUMBERS.
 556 If UNREAD is non-nil, messages are not marked as read."
 557   (dolist (number numbers)
 558     (elmo-message-encache folder number unread)))
 559
 560 (luna-define-generic elmo-message-encache (folder number &optional read)
 561   "Encache message in the FOLDER with NUMBER.
 562 If READ is non-nil, message is marked as read.")
 563
 564 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 565                                           &optional read)
 566   (elmo-message-fetch
 567    folder number
 568    (elmo-make-fetch-strategy 'entire
 569                              nil ;use-cache
 570                              t   ;save-cache
 571                              (elmo-file-cache-get-path
 572                               (elmo-message-field
 573                                folder number 'message-id)))
 574    nil nil (not read)))
 575
 576 (luna-define-generic elmo-message-fetch (folder number strategy
 577                                                 &optional
 578                                                 section
 579                                                 outbuf
 580                                                 unread)
 581   "Fetch a message and return as a string.
 582 FOLDER is the ELMO folder structure.
 583 NUMBER is the number of the message in the FOLDER.
 584 STRATEGY is the message fetching strategy.
 585 If optional argument SECTION is specified, only the SECTION of the message
 586 is fetched (if possible).
 587 If second optional argument OUTBUF is specified, fetched message is
 588 inserted to the buffer and returns t if fetch was ended successfully.
 589 If third optional argument UNREAD is non-nil, message is not marked as read.
 590 Returns non-nil if fetching was succeed.")
 591
 592 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 593                                                             number strategy
 594                                                             &optional
 595                                                             section
 596                                                             unread)
 597   "Fetch a message into current buffer with cache process.
 598 FOLDER is the ELMO folder structure.
 599 NUMBER is the number of the message in the FOLDER.
 600 STRATEGY is the message fetching strategy.
 601 If optional argument SECTION is specified, only the SECTION of the message
 602 is fetched (if possible).
 603 If second optional argument UNREAD is non-nil, message is not marked as read.
 604 Returns non-nil if fetching was succeed.")
 605
 606 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 607                                                          &optional
 608                                                          section
 609                                                          unread)
 610   "Fetch a message into current buffer.
 611 FOLDER is the ELMO folder structure.
 612 NUMBER is the number of the message in the FOLDER.
 613 STRATEGY is the message fetching strategy.
 614 If optional argument SECTION is specified, only the SECTION of the message
 615 is fetched (if possible).
 616 If second optional argument UNREAD is non-nil, message is not marked as read.
 617 Returns non-nil if fetching was succeed.")
 618
 619 (luna-define-generic elmo-message-fetch-field (folder number field)
 620   "Fetch a message field value.
 621 FOLDER is the ELMO folder structure.
 622 NUMBER is the number of the message in the FOLDER.
 623 FIELD is a symbol of the field name.")
 624
 625 (luna-define-generic elmo-message-folder (folder number)
 626   "Get primitive folder of the message.")
 627
 628 (luna-define-generic elmo-folder-process-crosspost (folder)
 629   "Process crosspost for FOLDER.
 630 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).")
 631
 632 (luna-define-generic elmo-folder-newsgroups (folder)
 633   "Return list of newsgroup name of FOLDER.")
 634
 635 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 636   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 637
 638 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 639   (if (listp condition)
 640       (or (elmo-folder-search-requires-msgdb-p-internal
 641            folder (nth 1 condition))
 642           (elmo-folder-search-requires-msgdb-p-internal
 643            folder (nth 2 condition)))
 644     (and (not (string= (elmo-filter-key condition) "last"))
 645          (not (string= (elmo-filter-key condition) "first")))))
 646
 647 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 648                                                          condition)
 649   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 650
 651 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 652   nil)
 653
 654 (luna-define-method elmo-folder-open ((folder elmo-folder)
 655                                       &optional load-msgdb)
 656   (elmo-generic-folder-open folder load-msgdb))
 657
 658 (defun elmo-generic-folder-open (folder load-msgdb)
 659   (let ((inhibit-quit t))
 660     (if load-msgdb (elmo-folder-msgdb folder))
 661     (elmo-folder-set-killed-list-internal
 662      folder
 663      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 664   (elmo-folder-open-internal folder))
 665
 666 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 667   nil ; default is do nothing.
 668   )
 669
 670 (luna-define-method elmo-folder-check ((folder elmo-folder))
 671   nil) ; default is noop.
 672
 673 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 674   (elmo-generic-folder-commit folder))
 675
 676 (defun elmo-generic-folder-commit (folder)
 677   (when (elmo-folder-persistent-p folder)
 678     (when (elmo-folder-message-modified-internal folder)
 679       (elmo-msgdb-overview-save
 680        (elmo-folder-msgdb-path folder)
 681        (elmo-msgdb-get-overview (elmo-folder-msgdb folder)))
 682       (elmo-msgdb-number-save
 683        (elmo-folder-msgdb-path folder)
 684        (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))
 685       (elmo-folder-set-info-max-by-numdb
 686        folder
 687        (elmo-folder-list-messages folder nil 'in-msgdb))
 688       (elmo-folder-set-message-modified folder nil)
 689       (elmo-msgdb-killed-list-save
 690        (elmo-folder-msgdb-path folder)
 691        (elmo-folder-killed-list-internal folder)))
 692     (when (elmo-folder-mark-modified-internal folder)
 693       (elmo-msgdb-mark-save
 694        (elmo-folder-msgdb-path folder)
 695        (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
 696       (elmo-folder-set-mark-modified-internal folder nil))))
 697
 698 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 699   ;; do nothing.
 700   )
 701
 702 (luna-define-method elmo-folder-close ((folder elmo-folder))
 703   (elmo-generic-folder-close folder)
 704   (elmo-folder-close-internal folder))
 705
 706 (defun elmo-generic-folder-close (folder)
 707   (elmo-folder-commit folder)
 708   (elmo-folder-set-msgdb-internal folder nil)
 709   (elmo-folder-set-killed-list-internal folder nil))
 710
 711 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 712   t) ; default is plugged.
 713
 714 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 715                                              &optional add)
 716   nil) ; default is do nothing.
 717
 718 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 719   nil) ; default is no flag.
 720
 721 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 722   (elmo-folder-persistent-internal folder))
 723
 724 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 725   nil) ; default is not creatable.
 726
 727 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 728   nil) ; default is not writable.
 729
 730 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 731   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 732                              (elmo-folder-name-internal folder)))
 733     (elmo-msgdb-delete-path folder)
 734     t))
 735
 736 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 737   (let* ((new-folder (elmo-make-folder new-name)))
 738     (unless (eq (elmo-folder-type-internal folder)
 739                 (elmo-folder-type-internal new-folder))
 740       (error "Not same folder type"))
 741     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 742             (elmo-folder-exists-p new-folder))
 743         (error "Already exists folder: %s" new-name))
 744     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 745     (elmo-msgdb-rename-path folder new-folder)))
 746
 747 (defsubst elmo-folder-search-fast (folder condition numbers)
 748   "Search and return list of message numbers.
 749 Return t if CONDITION is not treated.
 750 FOLDER is the ELMO folder structure.
 751 CONDITION is a condition structure for searching.
 752 NUMBERS is a list of message numbers, messages are searched from the list."
 753   (if (and numbers
 754            (vectorp condition))
 755       (cond
 756        ((string= (elmo-filter-key condition) "flag")
 757         (let ((msgdb (elmo-folder-msgdb folder)))
 758           ;; msgdb should be synchronized at this point.
 759           (cond
 760            ((string= (elmo-filter-value condition) "unread")
 761             (elmo-folder-list-unreads folder))
 762            ((string= (elmo-filter-value condition) "important")
 763             (elmo-folder-list-importants folder))
 764            ((string= (elmo-filter-value condition) "answered")
 765             (elmo-folder-list-answereds folder))
 766            ((string= (elmo-filter-value condition) "digest")
 767             (nconc (elmo-folder-list-unreads folder)
 768                    (elmo-folder-list-importants folder)))
 769            ((string= (elmo-filter-value condition) "any")
 770             (nconc (elmo-folder-list-unreads folder)
 771                    (elmo-folder-list-importants folder)
 772                    (elmo-folder-list-answereds folder))))))
 773        ((member (elmo-filter-key condition) '("first" "last"))
 774         (let ((len (length numbers))
 775               (lastp (string= (elmo-filter-key condition) "last"))
 776               (value (string-to-number (elmo-filter-value condition))))
 777           (when (eq (elmo-filter-type condition) 'unmatch)
 778             (setq lastp (not lastp)
 779                   value  (- len value)))
 780           (if lastp
 781               (nthcdr (max (- len value) 0) numbers)
 782             (when (> value 0)
 783               (let* ((numbers (copy-sequence numbers))
 784                      (last (nthcdr (1- value) numbers)))
 785                 (when last
 786                   (setcdr last nil))
 787                 numbers)))))
 788        (t
 789         t))
 790     t))
 791
 792 (luna-define-method elmo-folder-search ((folder elmo-folder)
 793                                         condition
 794                                         &optional numbers)
 795   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 796         results)
 797     (if (listp (setq results (elmo-folder-search-fast folder
 798                                                       condition
 799                                                       numbers)))
 800         results
 801       (let ((msgdb (elmo-folder-msgdb folder))
 802             (len (length numbers))
 803             matched)
 804         (when (> len elmo-display-progress-threshold)
 805           (elmo-progress-set 'elmo-folder-search len "Searching..."))
 806         (unwind-protect
 807             (dolist (number numbers)
 808               (let (result)
 809                 (setq result (elmo-msgdb-match-condition
 810                               msgdb
 811                               condition
 812                               number
 813                               numbers))
 814                 (when (elmo-filter-condition-p result)
 815                   (setq result (elmo-message-match-condition
 816                                 folder
 817                                 number
 818                                 condition
 819                                 numbers)))
 820                 (when result
 821                   (setq matched (cons number matched))))
 822               (elmo-progress-notify 'elmo-folder-search))
 823           (elmo-progress-clear 'elmo-folder-search))
 824         (nreverse matched)))))
 825
 826 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 827                                                   number condition
 828                                                   numbers)
 829   (let ((filename (cond
 830                    ((elmo-message-file-name folder number))
 831                    ((let* ((cache (elmo-file-cache-get
 832                                    (elmo-message-field folder number
 833                                                        'message-id)))
 834                            (cache-path (elmo-file-cache-path cache)))
 835                       (when (and cache-path
 836                                  (not (elmo-cache-path-section-p cache-path)))
 837                         cache-path))))))
 838     (when (and filename
 839                (file-readable-p filename))
 840       (with-temp-buffer
 841         (insert-file-contents-as-binary filename)
 842         (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 843         ;; Should consider charset?
 844         (decode-mime-charset-region (point-min) (point-max) elmo-mime-charset)
 845         (elmo-buffer-field-condition-match condition number numbers)))))
 846
 847 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 848   nil) ; default is noop.
 849
 850 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 851   nil) ; default is noop.
 852
 853 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 854   nil) ; default is not file.
 855
 856 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 857   nil) ; default is not number.
 858
 859 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 860   nil) ; default is not make temp file.
 861
 862 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 863                                                    number)
 864   nil) ; default is no name.
 865
 866 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 867   t)   ; default is local.
 868
 869 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 870   t)
 871
 872 ;;; Folder info
 873 ;; Folder info is a message number information cache (hashtable)
 874 (defsubst elmo-folder-get-info (folder &optional hashtb)
 875   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 876   (elmo-get-hash-val (elmo-folder-name-internal folder)
 877                      (or hashtb elmo-folder-info-hashtb)))
 878
 879 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 880   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 881   (let ((info (elmo-folder-get-info folder)))
 882     (when info
 883       (or new     (setq new     (nth 0 info)))
 884       (or unread  (setq unread  (nth 1 info)))
 885       (or numbers (setq numbers (nth 2 info)))
 886       (or max     (setq max     (nth 3 info))))
 887     (elmo-set-hash-val (elmo-folder-name-internal folder)
 888                        (list new unread numbers max)
 889                        elmo-folder-info-hashtb)))
 890
 891 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 892   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 893   (elmo-folder-set-info-hashtb
 894    folder
 895    (or (car (sort numbers '>)) 0)
 896    nil ;;(length num-db)
 897    ))
 898
 899 (defun elmo-folder-get-info-max (folder)
 900   "Return max number of FODLER from folder info."
 901   (nth 3 (elmo-folder-get-info folder)))
 902
 903 (defun elmo-folder-get-info-length (folder)
 904   "Return length of FODLER from folder info."
 905   (nth 2 (elmo-folder-get-info folder)))
 906
 907 (defun elmo-folder-get-info-unread (folder)
 908   "Return unread of FODLER from folder info."
 909   (nth 1 (elmo-folder-get-info folder)))
 910
 911 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 912   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 913   (let* ((hashtb (or hashtb
 914                      (elmo-make-hash (length info-alist)))))
 915     (mapcar
 916      (lambda (x)
 917        (let ((info (cadr x)))
 918          (and (intern-soft (car x) hashtb)
 919               (elmo-set-hash-val (car x)
 920                                  (list (nth 2 info)   ;; new
 921                                        (nth 3 info)   ;; unread
 922                                        (nth 1 info)   ;; length
 923                                        (nth 0 info))  ;; max
 924                                  hashtb))))
 925      info-alist)
 926     (setq elmo-folder-info-hashtb hashtb)))
 927
 928 (defsubst elmo-diff-new (diff)
 929   (car diff))
 930
 931 (defsubst elmo-diff-unread (diff)
 932   (when (consp (cdr diff))
 933     (nth 1 diff)))
 934
 935 (defsubst elmo-diff-all (diff)
 936   (if (consp (cdr diff))
 937       (nth 2 diff)
 938     (cdr diff)))
 939
 940 (defsubst elmo-strict-folder-diff (folder)
 941   "Return folder diff information strictly from FOLDER."
 942   (let ((in-db (sort (elmo-msgdb-list-messages (elmo-folder-msgdb folder))
 943                      '<))
 944         (in-folder  (elmo-folder-list-messages folder))
 945         append-list delete-list diff)
 946     (cons (if (equal in-folder in-db)
 947               0
 948             (setq diff (elmo-list-diff in-folder in-db nil))
 949             (setq append-list (car diff))
 950             (setq delete-list (cadr diff))
 951             (if append-list
 952                 (length append-list)
 953               (if delete-list
 954                   (- 0 (length delete-list))
 955                 0)))
 956           (length in-folder))))
 957
 958 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 959   (elmo-generic-folder-diff folder))
 960
 961 (defun elmo-generic-folder-diff (folder)
 962   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 963                                 elmo-strict-diff-folder-list)
 964       (elmo-strict-folder-diff folder)
 965     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 966           (in-folder (elmo-folder-status folder))
 967           (in-db t)
 968           unsync messages
 969           in-db-max)
 970       (if (not cached-in-db-max)
 971           (let ((number-list (elmo-folder-list-messages folder
 972                                                         nil 'in-msgdb)))
 973             ;; No info-cache.
 974             (setq in-db (sort number-list '<))
 975             (setq in-db-max (or (nth (max 0 (1- (length in-db))) in-db)
 976                                 0))
 977             (elmo-folder-set-info-hashtb folder in-db-max nil))
 978         (setq in-db-max cached-in-db-max))
 979       (setq unsync (if (and in-db (car in-folder))
 980                        (- (car in-folder) in-db-max)
 981                      (if (and in-folder (null in-db))
 982                          (cdr in-folder)
 983                        (car in-folder))))
 984       (setq messages (cdr in-folder))
 985       (if (and unsync messages (> unsync messages))
 986           (setq unsync messages))
 987       (cons (or unsync 0) (or messages 0)))))
 988
 989 (defvar elmo-folder-diff-async-callback nil)
 990 (defvar elmo-folder-diff-async-callback-data nil)
 991
 992 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 993   (and elmo-folder-diff-async-callback
 994        (funcall elmo-folder-diff-async-callback
 995                 folder
 996                 (elmo-folder-diff folder))))
 997
 998 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
 999   (list folder))
1000
1001 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
1002   (eq (elmo-folder-type-internal folder) type))
1003
1004 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
1005                                                  src-folder
1006                                                  numbers
1007                                                  &optional
1008                                                  same-number)
1009   (elmo-generic-folder-append-messages folder src-folder numbers
1010                                        same-number))
1011
1012 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1013                                                    same-number)
1014   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
1015         unseen table flag mark
1016         succeed-numbers failure cache id)
1017     (setq table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1018     (with-temp-buffer
1019       (set-buffer-multibyte nil)
1020       (while numbers
1021         (setq failure nil
1022               id (and src-msgdb-exists
1023                       (elmo-message-field src-folder (car numbers)
1024                                           'message-id))
1025               mark (and src-msgdb-exists
1026                         (elmo-message-mark src-folder (car numbers)))
1027               flag (and id
1028                         (cond
1029                          ((null mark) 'read)
1030                          ((member mark (elmo-msgdb-answered-marks))
1031                           'answered)
1032                          ;;
1033                          ((not (member mark (elmo-msgdb-unread-marks)))
1034                           'read))))
1035         (condition-case nil
1036             (setq cache (elmo-file-cache-get id)
1037                   failure
1038                   (not
1039                    (and
1040                     (elmo-message-fetch
1041                      src-folder (car numbers)
1042                      (if (elmo-folder-plugged-p src-folder)
1043                          (elmo-make-fetch-strategy
1044                           'entire 'maybe nil
1045                           (and cache (elmo-file-cache-path cache)))
1046                        (or (and elmo-enable-disconnected-operation
1047                                 cache
1048                                 (eq (elmo-file-cache-status cache) 'entire)
1049                                 (elmo-make-fetch-strategy
1050                                  'entire t nil
1051                                  (elmo-file-cache-path cache)))
1052                            (error "Unplugged")))
1053                      nil (current-buffer)
1054                      'unread)
1055                     (> (buffer-size) 0)
1056                     (elmo-folder-append-buffer
1057                      folder
1058                      flag
1059                      (if same-number (car numbers))))))
1060           (error (setq failure t)))
1061         ;; FETCH & APPEND finished
1062         (unless failure
1063           (when id
1064             (elmo-flag-table-set table id flag))
1065           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1066         (elmo-progress-notify 'elmo-folder-move-messages)
1067         (setq numbers (cdr numbers)))
1068       (when (elmo-folder-persistent-p folder)
1069         (elmo-flag-table-save (elmo-folder-msgdb-path folder) table))
1070       succeed-numbers)))
1071
1072 ;; Arguments should be reduced.
1073 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1074                                              &optional msgdb
1075                                              no-delete-info
1076                                              no-delete
1077                                              same-number
1078                                              save-unread)
1079   (save-excursion
1080     (let* ((messages msgs)
1081            (elmo-inhibit-display-retrieval-progress t)
1082            (len (length msgs))
1083            succeeds i result)
1084       (if (eq dst-folder 'null)
1085           (setq succeeds messages)
1086         (unless (elmo-folder-writable-p dst-folder)
1087           (error "move: %d is not writable"
1088                  (elmo-folder-name-internal dst-folder)))
1089         (when messages
1090           ;; src is already opened.
1091           (elmo-folder-open-internal dst-folder)
1092           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1093                                                               src-folder
1094                                                               messages
1095                                                               same-number))
1096             (error "move: append message to %s failed"
1097                    (elmo-folder-name-internal dst-folder)))
1098           (elmo-folder-close dst-folder)))
1099       (if (and (not no-delete) succeeds)
1100           (progn
1101             (if (and (elmo-folder-delete-messages src-folder succeeds)
1102                      (elmo-folder-detach-messages src-folder succeeds))
1103                 (setq result t)
1104               (message "move: delete messages from %s failed."
1105                        (elmo-folder-name-internal src-folder))
1106               (setq result nil))
1107             result)
1108         (if no-delete
1109             (progn
1110               ;; (message "Copying messages...done")
1111               t)
1112           (if (eq len 0)
1113               (message "No message was moved.")
1114             (message "Moving messages failed.")
1115             nil ; failure
1116             ))))))
1117
1118 (defun elmo-folder-msgdb-path (folder)
1119   "Return the msgdb path for FOLDER."
1120   (or (elmo-folder-path-internal folder)
1121       (elmo-folder-set-path-internal
1122        folder
1123        (elmo-folder-expand-msgdb-path folder))))
1124
1125 (defun elmo-message-accessible-p (folder number)
1126   "Get accessibility of the message.
1127 Return non-nil when message is accessible."
1128   (or (elmo-folder-plugged-p folder)
1129       (elmo-folder-local-p folder)
1130       (elmo-msgdb-get-cached (elmo-folder-msgdb folder) number)))
1131
1132 (luna-define-generic elmo-message-set-cached (folder number cached)
1133   "Set cache status of the message in the msgdb.
1134 FOLDER is the ELMO folder structure.
1135 NUMBER is a number of the message.
1136 If CACHED is t, message is set as cached.")
1137
1138 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1139                                              number cached)
1140   (when (elmo-msgdb-set-cached (elmo-folder-msgdb folder)
1141                                number
1142                                cached
1143                                (elmo-message-use-cache-p folder number))
1144     (elmo-folder-set-mark-modified-internal folder t)))
1145
1146 (defun elmo-message-copy-entity (entity)
1147   ;;
1148   (elmo-msgdb-copy-overview-entity entity))
1149
1150 (defun elmo-message-entity-set-number (entity number)
1151   (elmo-msgdb-overview-entity-set-number entity number))
1152
1153 (luna-define-generic elmo-message-entity (folder key)
1154   "Return the message-entity structure which matches to the KEY.
1155 KEY is a number or a string.
1156 A number is for message number in the FOLDER.
1157 A string is for message-id of the message.")
1158
1159 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1160   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1161
1162 (luna-define-generic elmo-message-entity-parent (folder entity)
1163   "Return the parent message-entity structure in the FOLDER.
1164 ENTITY is the message-entity to get the parent.")
1165
1166 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1167   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1168
1169 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1170 (def-edebug-spec elmo-folder-do-each-message-entity
1171   ((symbolp form &rest form) &rest form))
1172
1173 (defsubst elmo-folder-list-message-entities (folder)
1174   ;; List all message entities in the FOLDER.
1175   (mapcar
1176    (lambda (number) (elmo-message-entity folder number))
1177    (elmo-folder-list-messages folder nil t))) ; XXX killed-list is not used.
1178
1179 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1180   "Iterator for message entity in the folder.
1181 \(elmo-folder-do-each-message-entity \(entity folder\)
1182  ... do the process using entity...
1183 \)"
1184   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1185      ,@form))
1186
1187 (defmacro elmo-message-entity-number (entity)
1188   `(elmo-msgdb-overview-entity-get-number ,entity))
1189
1190 (defun elmo-message-entity-field (entity field &optional decode)
1191   "Get message entity field value.
1192 ENTITY is the message entity structure obtained by `elmo-message-entity'.
1193 FIELD is the symbol of the field name.
1194 if optional DECODE is non-nil, returned value is decoded."
1195   (elmo-msgdb-message-entity-field entity field decode))
1196
1197 (defun elmo-message-entity-set-field (entity field value)
1198   "Set message entity field value.
1199 ENTITY is the message entity structure.
1200 FIELD is the symbol of the field name.
1201 VALUE is the field value (raw)."
1202   (elmo-msgdb-message-entity-set-field entity field value))
1203
1204 (luna-define-generic elmo-folder-count-flags (folder)
1205   "Count flagged message number in the msgdb of the FOLDER.
1206 Return a list of numbers (`new' `unread' `answered')")
1207
1208 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1209   (let ((new 0)
1210         (unreads 0)
1211         (answered 0))
1212     (dolist (elem (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
1213       (cond
1214        ((string= (cadr elem) elmo-msgdb-new-mark)
1215         (incf new))
1216        ((member (cadr elem) (elmo-msgdb-unread-marks))
1217         (incf unreads))
1218        ((member (cadr elem) (elmo-msgdb-answered-marks))
1219         (incf answered))))
1220     (list new unreads answered)))
1221
1222 (defun elmo-message-set-flag (folder number flag)
1223   "Set message flag.
1224 FOLDER is a ELMO folder structure.
1225 NUMBER is a message number to set flag.
1226
1227 FLAG is a symbol which is one of the following:
1228   `unread'    (set the message as unread)
1229   `answered'  (set the message as answered)
1230   `important' (set the message as important)
1231 'sugar' flag:
1232   `read'      (remove new and unread flags)")
1233
1234 (defun elmo-message-unset-flag (folder number flag)
1235   "Unset message flag.
1236 FOLDER is a ELMO folder structure.
1237 NUMBER is a message number to set flag.
1238
1239 FLAG is a symbol which is one of the following:
1240   `unread'    (remove unread and new flag)
1241   `answered'  (remove answered flag)
1242   `important' (remove important flag)
1243 'sugar' flag:
1244   `read'      (set unread flag)")
1245
1246 (luna-define-generic elmo-message-mark (folder number)
1247   "Get mark of the message.
1248 FOLDER is the ELMO folder structure.
1249 NUMBER is a number of the message.")
1250
1251 (luna-define-method elmo-message-mark ((folder elmo-folder) number)
1252   (when (zerop (elmo-folder-length folder))
1253     (error "Cannot treat this folder correctly."))
1254   (elmo-msgdb-get-mark (elmo-folder-msgdb folder) number))
1255
1256 (luna-define-generic elmo-message-field (folder number field)
1257   "Get message field value in the msgdb.
1258 FOLDER is the ELMO folder structure.
1259 NUMBER is a number of the message.
1260 FIELD is a symbol of the field.")
1261
1262 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1263   (when (zerop (elmo-folder-length folder))
1264     (error "Cannot treat this folder correctly."))
1265   (elmo-msgdb-get-field (elmo-folder-msgdb folder) number field))
1266
1267 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1268   nil) ; default is not use cache.
1269
1270 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1271   folder) ; default is folder
1272
1273 (luna-define-method elmo-folder-unmark-important ((folder elmo-folder)
1274                                                   numbers
1275                                                   &optional ignore-flags)
1276   (when (elmo-folder-msgdb-internal folder)
1277     (dolist (number numbers)
1278       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1279                              folder
1280                              number
1281                              'important))))
1282
1283 (luna-define-method elmo-folder-mark-as-important ((folder elmo-folder)
1284                                                    numbers
1285                                                    &optional ignore-flags)
1286   (when (elmo-folder-msgdb-internal folder)
1287     (dolist (number numbers)
1288       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1289                            folder
1290                            number
1291                            'important))))
1292
1293 (luna-define-method elmo-folder-unmark-read ((folder elmo-folder)
1294                                              numbers
1295                                              &optional ignore-flags)
1296   (when (elmo-folder-msgdb-internal folder)
1297     (dolist (number numbers)
1298       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1299                              folder
1300                              number
1301                              'read))))
1302
1303 (luna-define-method elmo-folder-mark-as-read ((folder elmo-folder)
1304                                               numbers
1305                                               &optional ignore-flag)
1306   (when (elmo-folder-msgdb-internal folder)
1307     (dolist (number numbers)
1308       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1309                            folder
1310                            number
1311                            'read))))
1312
1313 (luna-define-method elmo-folder-unmark-answered ((folder elmo-folder) numbers)
1314   (when (elmo-folder-msgdb-internal folder)
1315     (dolist (number numbers)
1316       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1317                              folder
1318                              number
1319                              'answered))))
1320
1321 (luna-define-method elmo-folder-mark-as-answered ((folder elmo-folder) numbers)
1322   (when (elmo-folder-msgdb-internal folder)
1323     (dolist (number numbers)
1324       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1325                            folder
1326                            number
1327                            'answered))))
1328
1329 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1330   ;; Do nothing.
1331   )
1332
1333 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1334 ;;                                                             &optional
1335 ;;                                                             flag-table)
1336 ;;  "Append ENTITY to the folder.")
1337
1338 (defsubst elmo-folder-append-msgdb (folder append-msgdb)
1339   (if append-msgdb
1340       (let ((duplicates (elmo-msgdb-merge folder append-msgdb)))
1341         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1342                    'hide)
1343                ;; Let duplicates be a temporary killed message.
1344                (elmo-folder-kill-messages folder duplicates)
1345                ;; Should be mark as read.
1346                (elmo-folder-mark-as-read folder duplicates))
1347               ((eq (elmo-folder-process-duplicates-internal folder)
1348                    'read)
1349                ;; Mark as read duplicates.
1350                (elmo-folder-mark-as-read folder duplicates))
1351               (t
1352                ;; Do nothing.
1353                (setq duplicates nil)))
1354         (length duplicates))
1355     0))
1356
1357 (defun elmo-folder-confirm-appends (appends)
1358   (let ((len (length appends))
1359         in)
1360     (if (and elmo-folder-update-threshold
1361              (> len elmo-folder-update-threshold)
1362              elmo-folder-update-confirm)
1363         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1364             appends
1365           (setq in elmo-folder-update-threshold)
1366           (catch 'end
1367             (while t
1368               (setq in (read-from-minibuffer "Update number: "
1369                                              (int-to-string in))
1370                     in (string-to-int in))
1371               (if (< len in)
1372                   (throw 'end len))
1373               (if (y-or-n-p (format
1374                              "%d messages are killed (not appeared). OK? "
1375                              (max (- len in) 0)))
1376                   (throw 'end in))))
1377           (nthcdr (max (- len in) 0) appends))
1378       (if (and elmo-folder-update-threshold
1379                (> len elmo-folder-update-threshold)
1380                (not elmo-folder-update-confirm))
1381           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1382         appends))))
1383
1384 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1385                                         number strategy
1386                                         &optional
1387                                         section
1388                                         outbuf
1389                                         unread)
1390   (if outbuf
1391       (with-current-buffer outbuf
1392         (erase-buffer)
1393         (elmo-message-fetch-with-cache-process folder number
1394                                                strategy section unread))
1395     (with-temp-buffer
1396       (elmo-message-fetch-with-cache-process folder number
1397                                              strategy section unread)
1398       (buffer-string))))
1399
1400 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1401                                                            number strategy
1402                                                            &optional
1403                                                            section unread)
1404   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1405         (method-priorities
1406          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1407                 '(entity cache))
1408                ((elmo-fetch-strategy-use-cache strategy)
1409                 '(cache entity))
1410                (t
1411                 '(entity))))
1412         result err)
1413     (while (and method-priorities
1414                 (null result))
1415       (setq result
1416             (case (car method-priorities)
1417               (cache
1418                (elmo-file-cache-load cache-path section))
1419               (entity
1420                (when (and (condition-case error
1421                               (elmo-message-fetch-internal folder number
1422                                                            strategy
1423                                                            section
1424                                                            unread)
1425                             (error (setq err error) nil))
1426                           (> (buffer-size) 0))
1427                  (elmo-delete-cr-buffer)
1428                  (when (and (elmo-fetch-strategy-save-cache strategy)
1429                             cache-path)
1430                    (elmo-file-cache-save cache-path section))
1431                  t)))
1432             method-priorities (cdr method-priorities)))
1433     (or result
1434         (and err (signal (car err) (cdr err))))))
1435
1436 (defun elmo-folder-kill-messages-before (folder msg)
1437   (elmo-folder-set-killed-list-internal
1438    folder
1439    (list (cons 1 msg))))
1440
1441 (defun elmo-folder-kill-messages (folder numbers)
1442   "Kill(hide) messages in the FOLDER with NUMBERS."
1443   (elmo-folder-set-killed-list-internal
1444    folder
1445    (elmo-number-set-append-list (elmo-folder-killed-list-internal
1446                                  folder) numbers)))
1447
1448
1449 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1450                                        &optional keep-killed)
1451   (unless keep-killed
1452     (elmo-folder-set-killed-list-internal folder nil))
1453   (elmo-folder-set-msgdb-internal folder (elmo-msgdb-clear)))
1454
1455 (luna-define-generic elmo-folder-synchronize (folder
1456                                               &optional
1457                                               disable-killed
1458                                               ignore-msgdb
1459                                               no-check)
1460   "Synchronize the folder data to the newest status.
1461 FOLDER is the ELMO folder structure.
1462
1463 If optional DISABLE-KILLED is non-nil, killed messages are also synchronized.
1464 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1465 flag status.
1466 If NO-CHECK is non-nil, rechecking folder is skipped.
1467 Return a list of a cross-posted message number.
1468 If update process is interrupted, return nil.")
1469
1470 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1471                                              &optional
1472                                              disable-killed
1473                                              ignore-msgdb
1474                                              no-check)
1475   (let ((killed-list (elmo-folder-killed-list-internal folder))
1476         (before-append t)
1477         old-msgdb diff diff-2 delete-list new-list new-msgdb mark
1478         flag-table crossed after-append)
1479     (setq old-msgdb (elmo-folder-msgdb folder))
1480     (setq flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1481     (when ignore-msgdb
1482       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1483       (elmo-folder-clear folder (not disable-killed)))
1484     (unless no-check (elmo-folder-check folder))
1485     (condition-case nil
1486         (progn
1487           (message "Checking folder diff...")
1488           (setq diff (elmo-list-diff (elmo-folder-list-messages
1489                                       folder
1490                                       (not disable-killed))
1491                                      (elmo-folder-list-messages
1492                                       folder
1493                                       (not disable-killed)
1494                                       'in-msgdb)))
1495           (message "Checking folder diff...done")
1496           (setq new-list (elmo-folder-confirm-appends (car diff)))
1497           ;; Set killed list as ((1 . MAX-OF-DISAPPEARED))
1498           (when (and (not (eq (length (car diff))
1499                               (length new-list)))
1500                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1501             (elmo-folder-kill-messages-before folder
1502                                               (nth (- (length (car diff-2)) 1)
1503                                                    (car diff-2))))
1504           (setq delete-list (cadr diff))
1505           (if (or (equal diff '(nil nil))
1506                   (equal diff '(nil))
1507                   (and (eq (length (car diff)) 0)
1508                        (eq (length (cadr diff)) 0)))
1509               (progn
1510                 (elmo-folder-update-number folder)
1511                 (elmo-folder-process-crosspost folder)
1512                 0 ; no updates.
1513                 )
1514             (when delete-list
1515               (elmo-folder-detach-messages folder delete-list))
1516             (when new-list
1517               (elmo-msgdb-change-mark (elmo-folder-msgdb folder)
1518                                       elmo-msgdb-new-mark
1519                                       elmo-msgdb-unread-uncached-mark)
1520               (setq new-msgdb (elmo-folder-msgdb-create
1521                                folder new-list flag-table))
1522               ;; Clear flag-table
1523               (if (elmo-folder-persistent-p folder)
1524                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1525                                         nil))
1526               (setq before-append nil)
1527               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1528               ;; process crosspost.
1529               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).
1530               (elmo-folder-process-crosspost folder)
1531               (elmo-folder-set-message-modified folder t)
1532               (elmo-folder-set-mark-modified-internal folder t))
1533             ;; return value.
1534             (or crossed 0)))
1535       (quit
1536        ;; Resume to the original status.
1537        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1538        (elmo-folder-set-killed-list-internal folder killed-list)
1539        nil))))
1540
1541 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1542   "Remove messages with NUMBERS from MSGDB.")
1543
1544 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1545                                                  numbers)
1546   (elmo-msgdb-delete-msgs (elmo-folder-msgdb folder) numbers))
1547
1548 (luna-define-generic elmo-folder-length (folder)
1549   "Return number of messages in the FOLDER.")
1550
1551 (luna-define-method elmo-folder-length ((folder elmo-folder))
1552   (if (elmo-folder-msgdb-internal folder)
1553       (elmo-msgdb-length (elmo-folder-msgdb folder))
1554     0))
1555
1556 (defun elmo-msgdb-load (folder &optional silent)
1557   (unless silent
1558     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1559   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1560     (elmo-folder-set-info-max-by-numdb
1561      folder
1562      (elmo-msgdb-list-messages msgdb))
1563     (unless silent
1564       (message "Loading msgdb for %s...done"
1565                (elmo-folder-name-internal folder)))
1566     msgdb))
1567
1568 (defun elmo-msgdb-delete-path (folder)
1569   (let ((path (elmo-folder-msgdb-path folder)))
1570     (if (file-directory-p path)
1571         (elmo-delete-directory path t))))
1572
1573 (defun elmo-msgdb-rename-path (old-folder new-folder)
1574   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1575          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1576          (new-dir (directory-file-name (file-name-directory new))))
1577     (if (not (file-directory-p old))
1578         ()
1579       (if (file-exists-p new)
1580           (error "Already exists directory: %s" new)
1581         (if (not (file-exists-p new-dir))
1582             (elmo-make-directory new-dir))
1583         (rename-file old new)))))
1584
1585 (defun elmo-setup-subscribed-newsgroups (groups)
1586   "Setup subscribed newsgroups.
1587 GROUPS is a list of newsgroup name string.
1588 Return a hashtable for newsgroups."
1589   (let ((hashtb (or elmo-newsgroups-hashtb
1590                     (setq elmo-newsgroups-hashtb
1591                           (elmo-make-hash (length groups))))))
1592     (dolist (group groups)
1593       (or (elmo-get-hash-val group hashtb)
1594           (elmo-set-hash-val group nil hashtb)))
1595     (setq elmo-newsgroups-hashtb hashtb)))
1596
1597 (defvar elmo-crosspost-message-alist-modified nil)
1598 (defun elmo-crosspost-message-alist-load ()
1599   "Load crosspost message alist."
1600   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1601   (setq elmo-crosspost-message-alist-modified nil))
1602
1603 (defun elmo-crosspost-message-alist-save ()
1604   "Save crosspost message alist."
1605   (when elmo-crosspost-message-alist-modified
1606     (let ((alist elmo-crosspost-message-alist)
1607           newsgroups)
1608       (while alist
1609         (setq newsgroups
1610               (elmo-delete-if
1611                '(lambda (x)
1612                   (not (intern-soft x elmo-newsgroups-hashtb)))
1613                (nth 1 (car alist))))
1614         (if newsgroups
1615             (setcar (cdar alist) newsgroups)
1616           (setq elmo-crosspost-message-alist
1617                 (delete (car alist) elmo-crosspost-message-alist)))
1618         (setq alist (cdr alist)))
1619       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1620       (setq elmo-crosspost-message-alist-modified nil))))
1621
1622 (defun elmo-folder-make-temporary-directory (folder)
1623   ;; Make a temporary directory for FOLDER.
1624   (let ((temp-dir (make-temp-name
1625                    (concat
1626                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1627                     "elmo"))))
1628     (elmo-make-directory temp-dir)
1629     temp-dir))
1630
1631 (defun elmo-init ()
1632   "Initialize ELMO module."
1633   (elmo-crosspost-message-alist-load)
1634   (elmo-resque-obsolete-variables)
1635   (elmo-dop-queue-load))
1636
1637 (defun elmo-quit ()
1638   "Quit and cleanup ELMO."
1639   (elmo-crosspost-message-alist-save)
1640   (elmo-dop-queue-save)
1641   ;; Not implemented yet.
1642   (let ((types elmo-folder-type-alist)
1643         class)
1644     (while types
1645       (setq class
1646             (luna-find-class
1647              (intern (format "elmo-%s-folder" (symbol-name (cdr (car types)))))))
1648       ;; Call all folder's `elmo-quit' method.
1649       (if class
1650           (dolist (func (luna-class-find-functions class 'elmo-quit))
1651             (funcall func nil)))
1652       (setq types (cdr types)))))
1653
1654 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1655                                                  new-folder)
1656   (error "Cannot rename %s folder"
1657          (symbol-name (elmo-folder-type-internal folder))))
1658
1659 ;;; Define folders.
1660 (elmo-define-folder ?% 'imap4)
1661 (elmo-define-folder ?-  'nntp)
1662 (elmo-define-folder ?\+ 'localdir)
1663 (elmo-define-folder ?\* 'multi)
1664 (elmo-define-folder ?\/ 'filter)
1665 (elmo-define-folder ?\$ 'archive)
1666 (elmo-define-folder ?&  'pop3)
1667 (elmo-define-folder ?=  'localnews)
1668 (elmo-define-folder ?|  'pipe)
1669 (elmo-define-folder ?.  'maildir)
1670 (elmo-define-folder ?'  'internal)
1671 (elmo-define-folder ?\[  'nmz)
1672 (elmo-define-folder ?@  'shimbun)
1673
1674 ;;; Obsolete variables.
1675 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1676                                'elmo-imap4-default-mailbox)
1677 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1678                                'elmo-imap4-default-server)
1679 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1680                                'elmo-imap4-default-authenticate-type)
1681 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1682                                'elmo-imap4-default-user)
1683 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1684                                'elmo-imap4-default-port)
1685 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1686                                'elmo-imap4-default-stream-type)
1687 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1688                                'elmo-nntp-default-server)
1689 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1690                                'elmo-nntp-default-user)
1691 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1692                                'elmo-nntp-default-port)
1693 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1694                                'elmo-nntp-default-stream-type)
1695 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1696                                'elmo-pop3-default-server)
1697 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1698                                'elmo-pop3-default-user)
1699 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1700                                'elmo-pop3-default-authenticate-type)
1701 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1702                                'elmo-pop3-default-port)
1703 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1704                                'elmo-pop3-default-stream-type)
1705 (elmo-define-obsolete-variable 'elmo-cache-dirname
1706                                'elmo-cache-directory)
1707 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1708                                'elmo-msgdb-directory)
1709
1710 ;; Obsolete functions.
1711 ;; 2001-12-11: *-dir -> *-directory
1712 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1713 (make-obsolete 'elmo-folder-make-temp-dir
1714                'elmo-folder-make-temporary-directory)
1715
1716
1717 ;; autoloads
1718 (autoload 'elmo-dop-queue-flush "elmo-dop")
1719 (autoload 'elmo-nntp-post "elmo-nntp")
1720
1721 (require 'product)
1722 (product-provide (provide 'elmo) (require 'elmo-version))
1723
1724 ;;; elmo.el ends here