elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type 'integer
  50   :group 'elmo)
  51
  52 (defcustom elmo-message-fetch-confirm t
  53   "If non-nil, confirm fetching if message size is larger than
  54 `elmo-message-fetch-threshold'.
  55 Otherwise, entire fetching of the message is aborted without confirmation."
  56   :type 'boolean
  57   :group 'elmo)
  58
  59 (defcustom elmo-folder-update-threshold 500
  60   "Update threshold."
  61   :type 'integer
  62   :group 'elmo)
  63
  64 (defcustom elmo-folder-update-confirm t
  65   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  66   :type 'boolean
  67   :group 'elmo)
  68
  69 (defvar elmo-message-displaying nil
  70   "A global switch to indicate message is displaying or not.")
  71
  72 ;;; internal
  73 (defvar elmo-folder-type-alist nil)
  74
  75 (defvar elmo-newsgroups-hashtb nil)
  76
  77 (elmo-define-error 'elmo-error "Error" 'error)
  78 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  79 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  80 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  81
  82 (defun elmo-define-folder (prefix backend)
  83   "Define a folder.
  84 If a folder name begins with PREFIX, use BACKEND."
  85   (let ((pair (assq prefix elmo-folder-type-alist)))
  86     (if pair
  87         (progn
  88           (setcar pair prefix)
  89           (setcdr pair backend))
  90       (setq elmo-folder-type-alist (cons (cons prefix backend)
  91                                          elmo-folder-type-alist)))))
  92
  93 (defmacro elmo-folder-type (name)
  94   "Get folder type from NAME string."
  95   (` (and (stringp (, name))
  96           (cdr (assoc (string-to-char (, name)) elmo-folder-type-alist)))))
  97
  98 ;;; ELMO folder
  99 ;; A elmo folder provides uniformed (orchestrated) access
 100 ;; to the internet messages.
 101 (eval-and-compile
 102   (luna-define-class elmo-folder () (type   ; folder type symbol.
 103                                      name   ; orignal folder name string.
 104                                      prefix ; prefix for folder name
 105                                      path   ; directory path for msgdb.
 106                                      msgdb  ; msgdb (may be nil).
 107                                      killed-list  ; killed list.
 108                                      persistent   ; non-nil if persistent.
 109                                      message-modified ; message is modified.
 110                                      mark-modified    ; mark is modified.
 111                                      process-duplicates  ; read or hide
 112                                      biff   ; folder for biff
 113                                      ))
 114   (luna-define-internal-accessors 'elmo-folder))
 115
 116 (luna-define-generic elmo-folder-initialize (folder name)
 117   ;; Initialize a FOLDER structure with NAME."
 118   )
 119
 120 (defmacro elmo-folder-send (folder message &rest args)
 121   "Let FOLDER receive the MESSAGE with ARGS."
 122   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 123
 124 ;;;###autoload
 125 (defun elmo-make-folder (name &optional non-persistent)
 126   "Make an ELMO folder structure specified by NAME.
 127 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 128   (let ((type (elmo-folder-type name))
 129         prefix split class folder original)
 130     (setq original (elmo-string name))
 131     (if type
 132         (progn
 133           (setq prefix (substring name 0 1))
 134           (setq name (substring name 1)))
 135       (setq type (intern (car (setq split (split-string name ":")))))
 136       (if (> (length split) 2)
 137           (setq name (substring name (+ 1 (length (car split)))))
 138         (error "Error in folder name `%s'" original))
 139       (setq prefix (concat (car split) ":")))
 140     (setq class (format "elmo-%s" (symbol-name type)))
 141     (require (intern class))
 142     (setq folder (luna-make-entity (intern (concat class "-folder"))
 143                                    :type type
 144                                    :prefix prefix
 145                                    :name original
 146                                    :persistent (not non-persistent)))
 147     (save-match-data
 148       (elmo-folder-send folder 'elmo-folder-initialize name))))
 149
 150 ;; Note that this function is for internal use only.
 151 (luna-define-generic elmo-folder-msgdb (folder)
 152   "Return the msgdb of FOLDER (on-demand loading).
 153 \(For internal use only.\)")
 154
 155 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 156   (or (elmo-folder-msgdb-internal folder)
 157       (elmo-folder-set-msgdb-internal folder
 158                                       (elmo-msgdb-load folder))))
 159 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 160   "Open and setup (load saved status) FOLDER.
 161 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 162 \(otherwise, msgdb is loaded on-demand)")
 163
 164 (luna-define-generic elmo-folder-open-internal (folder)
 165   "Open FOLDER (without loading saved folder status).")
 166
 167 (luna-define-generic elmo-folder-check (folder)
 168   "Check the FOLDER to obtain newest information at the next list operation.")
 169
 170 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 171   "Clear FOLDER to the initial state.
 172 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 173
 174 (luna-define-generic elmo-folder-commit (folder)
 175   "Save current status of FOLDER.")
 176
 177 (luna-define-generic elmo-folder-close (folder)
 178   "Close, save and clearnup FOLDER.")
 179
 180 (luna-define-generic elmo-folder-close-internal (folder)
 181   "Close FOLDER (without saving folder status).")
 182
 183 (luna-define-generic elmo-folder-plugged-p (folder)
 184   "Returns t if FOLDER is plugged.")
 185
 186 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 187   "Set FOLDER as plugged.")
 188
 189 (luna-define-generic elmo-net-port-info (folder)
 190   "Get port information of FOLDER.")
 191
 192 (luna-define-generic elmo-folder-use-flag-p (folder)
 193   "Returns t if FOLDER treats unread/important flag itself.")
 194
 195 (luna-define-generic elmo-folder-diff (folder)
 196   "Get diff of FOLDER.
 197 Return value is cons cell or list:
 198  - a cons cell (new . all)
 199  - a list (new unread all)")
 200
 201 (luna-define-generic elmo-folder-status (folder)
 202   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 203
 204 (luna-define-generic elmo-folder-reserve-status-p (folder)
 205   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 206
 207 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 208                                                        in-msgdb)
 209   "Return a list of message numbers contained in FOLDER.
 210 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 211 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 212 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 213                                                &optional visible-only in-msgdb)
 214   (let ((list (if in-msgdb
 215                   t
 216                 (elmo-folder-list-messages-internal folder visible-only))))
 217     (elmo-living-messages
 218      (if (listp list)
 219          list
 220        ;; Use current list.
 221        (elmo-msgdb-list-messages (elmo-folder-msgdb folder)))
 222      (elmo-folder-killed-list-internal folder))))
 223
 224 (luna-define-generic elmo-folder-list-unreads (folder)
 225   "Return a list of unread message numbers contained in FOLDER.")
 226 (luna-define-generic elmo-folder-list-importants (folder)
 227   "Return a list of important message numbers contained in FOLDER.")
 228 (luna-define-generic elmo-folder-list-answereds (folder)
 229   "Return a list of answered message numbers contained in FOLDER.")
 230
 231 ;; TODO: Should reconsider the structure of global mark.
 232 (defun elmo-folder-list-messages-with-global-mark (folder mark)
 233   (let (entity msgs)
 234     (dolist (mark-pair (or elmo-msgdb-global-mark-alist
 235                            (setq elmo-msgdb-global-mark-alist
 236                                  (elmo-object-load
 237                                   (expand-file-name
 238                                    elmo-msgdb-global-mark-filename
 239                                    elmo-msgdb-directory)))))
 240       (if (and (string= mark (cdr mark-pair))
 241                (setq entity
 242                      (elmo-msgdb-overview-get-entity (car mark-pair)
 243                                                      (elmo-folder-msgdb
 244                                                       folder))))
 245           (setq msgs (cons (elmo-msgdb-overview-entity-get-number entity)
 246                            msgs))))
 247     msgs))
 248
 249 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 250   "List messages in the FOLDER with FLAG.
 251 FLAG is a symbol which is one of the following:
 252   `new'        (new messages)
 253   `unread'     (unread messages (new messages are included))
 254   `answered'   (answered or forwarded)
 255   `important'  (marked as important)
 256 'sugar' flags:
 257   `read'       (not unread)
 258   `digest'     (unread + important)
 259   `any'        (digest + answered)
 260
 261 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 262
 263 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 264                                               &optional in-msgdb)
 265   ;; Currently, only in-msgdb is implemented.
 266   (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag))
 267
 268 (luna-define-method elmo-folder-list-unreads ((folder elmo-folder))
 269   (elmo-folder-list-flagged folder 'unread))
 270
 271 (luna-define-method elmo-folder-list-importants ((folder elmo-folder))
 272   (elmo-folder-list-flagged folder 'important))
 273
 274 (luna-define-method elmo-folder-list-answereds ((folder elmo-folder))
 275   (elmo-folder-list-flagged folder 'answered))
 276
 277 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 278                                                                 visible-only)
 279   ;; Return a list of message numbers contained in FOLDER.
 280   ;; Return t if the message list is not available.
 281   )
 282
 283 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 284   "Returns a list of subfolders contained in FOLDER.
 285 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 286 \(a folder which have children is returned as a list\)
 287 Otherwise, all descendent folders are returned.")
 288
 289 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 290   "Return non-nil when FOLDER has subfolders.")
 291
 292 (luna-define-generic elmo-folder-exists-p (folder)
 293   "Returns non-nil when FOLDER exists.")
 294
 295 (luna-define-generic elmo-folder-creatable-p (folder)
 296   "Returns non-nil when FOLDER is creatable.")
 297
 298 (luna-define-generic elmo-folder-writable-p (folder)
 299   "Returns non-nil when FOLDER is writable.")
 300
 301 (luna-define-generic elmo-folder-persistent-p (folder)
 302   "Return non-nil when FOLDER is persistent.")
 303
 304 (luna-define-generic elmo-folder-create (folder)
 305   "Create a FOLDER.")
 306
 307 (luna-define-generic elmo-message-deletable-p (folder number)
 308   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 309
 310 (luna-define-generic elmo-folder-delete (folder)
 311   "Delete FOLDER completely.")
 312
 313 (luna-define-generic elmo-folder-rename (folder new-name)
 314   "Rename FOLDER to NEW-NAME (string).")
 315
 316 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 317   "Delete messages.
 318 FOLDER is the ELMO folder structure.
 319 NUMBERS is a list of message numbers to be deleted.")
 320
 321 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 322   "Search and return list of message numbers.
 323 FOLDER is the ELMO folder structure.
 324 CONDITION is a condition structure for searching.
 325 If optional argument NUMBERS is specified and is a list of message numbers,
 326 messages are searched from the list.")
 327
 328 (luna-define-generic elmo-message-match-condition (folder number
 329                                                           condition
 330                                                           numbers)
 331   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 332 CONDITION is a condition structure for testing.
 333 NUMBERS is a list of message numbers,
 334 use to be test for \"last\" and \"first\" predicates.")
 335
 336 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 337   "Create a message database (implemented in each backends).
 338 FOLDER is the ELMO folder structure.
 339 NUMBERS is a list of message numbers to create msgdb.
 340 FLAG-TABLE is a hashtable of message-id and flag.")
 341
 342 (luna-define-generic elmo-folder-unmark-important (folder
 343                                                    numbers
 344                                                    &optional ignore-flags)
 345   "Un-mark messages as important.
 346 FOLDER is the ELMO folder structure.
 347 NUMBERS is a list of message numbers to be processed.
 348 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 349
 350 (luna-define-generic elmo-folder-mark-as-important (folder
 351                                                     numbers
 352                                                     &optional ignore-flags)
 353   "Mark messages as important.
 354 FOLDER is the ELMO folder structure.
 355 NUMBERS is a list of message numbers to be processed.
 356 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 357
 358 (luna-define-generic elmo-folder-unmark-read (folder numbers
 359                                                      &optional ignore-flags)
 360   "Un-mark messages as read.
 361 FOLDER is the ELMO folder structure.
 362 NUMBERS is a list of message numbers to be processed.
 363 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 364
 365 (luna-define-generic elmo-folder-mark-as-read (folder numbers
 366                                                       &optional ignore-flags)
 367   "Mark messages as read.
 368 FOLDER is the ELMO folder structure.
 369 NUMBERS is a list of message numbers to be processed.
 370 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 371
 372 (luna-define-generic elmo-folder-unmark-answered (folder numbers)
 373   "Un-mark messages as answered.
 374 FOLDER is the ELMO folder structure.
 375 NUMBERS is a list of message numbers to be processed.")
 376
 377 (luna-define-generic elmo-folder-mark-as-answered (folder numbers)
 378   "Mark messages as answered.
 379 FOLDER is the ELMO folder structure.
 380 NUMBERS is a list of message numbers to be processed.")
 381
 382 (luna-define-generic elmo-folder-append-buffer (folder &optional flag
 383                                                        number)
 384   "Append current buffer as a new message.
 385 FOLDER is the destination folder(ELMO folder structure).
 386 FLAG is the status of appended message.
 387 If optional argument NUMBER is specified, the new message number is set
 388 \(if possible\).")
 389
 390 (luna-define-generic elmo-folder-append-messages (folder
 391                                                   src-folder
 392                                                   numbers
 393                                                   &optional
 394                                                   same-number)
 395   "Append messages from folder.
 396 FOLDER is the ELMO folder structure.
 397 Caller should make sure FOLDER is `writable'.
 398 (Can be checked with `elmo-folder-writable-p').
 399 SRC-FOLDER is the source ELMO folder structure.
 400 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 401 If second optional argument SAME-NUMBER is specified,
 402 message number is preserved (if possible).")
 403
 404 (luna-define-generic elmo-folder-pack-numbers (folder)
 405   "Pack message numbers of FOLDER.")
 406
 407 (luna-define-generic elmo-folder-update-number (folder)
 408   "Update number of FOLDER.")
 409
 410 (luna-define-generic elmo-folder-diff-async (folder)
 411   "Get diff of FOLDER asynchronously.")
 412
 413 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 414   "Expand path for FOLDER.")
 415
 416 (luna-define-generic elmo-folder-get-primitive-list (folder)
 417   "Get primitive folder structure list contained in FOLDER.")
 418
 419 (luna-define-generic elmo-folder-contains-type (folder type)
 420   "Returns t if FOLDER contains TYPE.")
 421
 422 (luna-define-generic elmo-folder-local-p (folder)
 423   "Returns t if FOLDER is local.")
 424
 425 (luna-define-generic elmo-folder-message-file-p (folder)
 426   "Returns t if all messages in the FOLDER are files.")
 427
 428 ;;; Message methods.
 429 (luna-define-generic elmo-message-use-cache-p (folder number)
 430   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 431
 432 (luna-define-generic elmo-message-file-name (folder number)
 433   "Return the file name of a message specified by FOLDER and NUMBER.")
 434
 435 ;;; For archive
 436
 437 ;;; Use original file
 438 (luna-define-generic elmo-folder-message-file-number-p (folder)
 439   "Return t if the file name in the FOLDER is the message number.")
 440
 441 (luna-define-generic elmo-folder-message-file-directory (folder)
 442   "Return the directory of the message files of FOLDER.")
 443
 444 ;;; Use temporary file
 445 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 446   "Return t if the messages in the FOLDER makes local temporary file.")
 447
 448 (luna-define-generic elmo-folder-message-make-temp-files (folder
 449                                                           numbers
 450                                                           &optional
 451                                                           start-number)
 452   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 453 If START-NUMBER is specified, temporary files begin from the number.
 454 Otherwise, same number is used for temporary files.
 455 Return newly created temporary directory name which contains temporary files.")
 456
 457 (luna-define-generic elmo-message-file-p (folder number)
 458   "Return t if message in the FOLDER with NUMBER is a file.")
 459
 460 (luna-define-generic elmo-find-fetch-strategy
 461   (folder entity &optional ignore-cache)
 462 ;; Returns the message fetching strategy suitable for the message.
 463 ;; FOLDER is the ELMO folder structure.
 464 ;; ENTITY is the overview entity of the message in the folder.
 465 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 466 ;; Returned value is a elmo-fetch-strategy object.
 467 ;; If return value is nil, message should not be nil.
 468   )
 469
 470 (defmacro elmo-make-fetch-strategy (entireness
 471                                     &optional
 472                                     use-cache
 473                                     save-cache
 474                                     cache-path)
 475 ;; Make elmo-message-fetching strategy.
 476 ;; ENTIRENESS is 'entire or 'section.
 477 ;; 'entire means fetch message entirely at once.
 478 ;; 'section means fetch message section by section.
 479 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 480 ;; existing cache is thrown away.
 481 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 482 ;; CACHE-PATH is the cache path to be used as a message cache file.
 483   (` (vector (, entireness)
 484              (, use-cache) (, save-cache) (, cache-path))))
 485
 486 (defmacro elmo-fetch-strategy-entireness (strategy)
 487   ;; Return entireness of STRATEGY.
 488   (` (aref (, strategy) 0)))
 489
 490 (defmacro elmo-fetch-strategy-use-cache (strategy)
 491   ;; Return use-cache of STRATEGY.
 492   (` (aref (, strategy) 1)))
 493
 494 (defmacro elmo-fetch-strategy-save-cache (strategy)
 495   ;; Return save-cache of STRATEGY.
 496   (` (aref (, strategy) 2)))
 497
 498 (defmacro elmo-fetch-strategy-cache-path (strategy)
 499   ;;  Return cache-path of STRATEGY.
 500   (` (aref (, strategy) 3)))
 501
 502 (luna-define-method elmo-find-fetch-strategy
 503   ((folder elmo-folder) entity &optional ignore-cache)
 504   (let (cache-file size message-id number)
 505     (setq size (elmo-msgdb-overview-entity-get-size entity))
 506     (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 507     (setq number (elmo-msgdb-overview-entity-get-number entity))
 508     (setq cache-file (elmo-file-cache-get message-id))
 509     (setq ignore-cache (or ignore-cache
 510                            (null (elmo-message-use-cache-p folder number))))
 511     (if (or ignore-cache
 512             (null (elmo-file-cache-status cache-file)))
 513         ;; No cache or ignore-cache.
 514         (if (and (not (elmo-folder-local-p folder))
 515                  elmo-message-fetch-threshold
 516                  (integerp size)
 517                  (>= size elmo-message-fetch-threshold)
 518                  (or (not elmo-message-fetch-confirm)
 519                      (not (prog1 (y-or-n-p
 520                                   (format "Fetch entire message(%dbytes)? "
 521                                           size))
 522                             (message "")))))
 523             ;; Don't fetch message at all.
 524             nil
 525           ;; Don't use existing cache and fetch entire message at once.
 526           (elmo-make-fetch-strategy
 527            'entire nil
 528            (elmo-message-use-cache-p folder number)
 529            (elmo-file-cache-path cache-file)))
 530       ;; Cache exists.
 531       (if (not ignore-cache)
 532           (elmo-make-fetch-strategy
 533            'entire
 534            ;; ...But ignore current section cache and re-fetch
 535            ;; if section cache.
 536            (not (eq (elmo-file-cache-status cache-file) 'section))
 537            ;; Save cache.
 538            (elmo-message-use-cache-p folder number)
 539            (elmo-file-cache-path cache-file))))))
 540
 541 (luna-define-method elmo-folder-list-messages-internal
 542   ((folder elmo-folder) &optional visible-only)
 543   t)
 544
 545 (defun elmo-folder-encache (folder numbers &optional unread)
 546   "Encache messages in the FOLDER with NUMBERS.
 547 If UNREAD is non-nil, messages are not marked as read."
 548   (dolist (number numbers)
 549     (elmo-message-encache folder number unread)))
 550
 551 (luna-define-generic elmo-message-encache (folder number &optional read)
 552   "Encache message in the FOLDER with NUMBER.
 553 If READ is non-nil, message is marked as read.")
 554
 555 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 556                                           &optional read)
 557   (elmo-message-fetch
 558    folder number
 559    (elmo-make-fetch-strategy 'entire
 560                              nil ;use-cache
 561                              t   ;save-cache
 562                              (elmo-file-cache-get-path
 563                               (elmo-message-field
 564                                folder number 'message-id)))
 565    nil nil (not read)))
 566
 567 (luna-define-generic elmo-message-fetch (folder number strategy
 568                                                 &optional
 569                                                 section
 570                                                 outbuf
 571                                                 unread)
 572   "Fetch a message and return as a string.
 573 FOLDER is the ELMO folder structure.
 574 NUMBER is the number of the message in the FOLDER.
 575 STRATEGY is the message fetching strategy.
 576 If optional argument SECTION is specified, only the SECTION of the message
 577 is fetched (if possible).
 578 If second optional argument OUTBUF is specified, fetched message is
 579 inserted to the buffer and returns t if fetch was ended successfully.
 580 If third optional argument UNREAD is non-nil, message is not marked as read.
 581 Returns non-nil if fetching was succeed.")
 582
 583 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 584                                                             number strategy
 585                                                             &optional
 586                                                             section
 587                                                             unread)
 588   "Fetch a message into current buffer with cache process.
 589 FOLDER is the ELMO folder structure.
 590 NUMBER is the number of the message in the FOLDER.
 591 STRATEGY is the message fetching strategy.
 592 If optional argument SECTION is specified, only the SECTION of the message
 593 is fetched (if possible).
 594 If second optional argument UNREAD is non-nil, message is not marked as read.
 595 Returns non-nil if fetching was succeed.")
 596
 597 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 598                                                          &optional
 599                                                          section
 600                                                          unread)
 601   "Fetch a message into current buffer.
 602 FOLDER is the ELMO folder structure.
 603 NUMBER is the number of the message in the FOLDER.
 604 STRATEGY is the message fetching strategy.
 605 If optional argument SECTION is specified, only the SECTION of the message
 606 is fetched (if possible).
 607 If second optional argument UNREAD is non-nil, message is not marked as read.
 608 Returns non-nil if fetching was succeed.")
 609
 610 (luna-define-generic elmo-message-fetch-field (folder number field)
 611   "Fetch a message field value.
 612 FOLDER is the ELMO folder structure.
 613 NUMBER is the number of the message in the FOLDER.
 614 FIELD is a symbol of the field name.")
 615
 616 (luna-define-generic elmo-message-folder (folder number)
 617   "Get primitive folder of the message.")
 618
 619 (luna-define-generic elmo-folder-process-crosspost (folder)
 620   "Process crosspost for FOLDER.
 621 If NUMBER-ALIST is set, it is used as number-alist.
 622 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).")
 623
 624 (luna-define-generic elmo-folder-append-msgdb (folder append-msgdb)
 625   "Append  APPEND-MSGDB to the current msgdb of the folder.")
 626
 627 (luna-define-generic elmo-folder-newsgroups (folder)
 628   "Return list of newsgroup name of FOLDER.")
 629
 630 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 631   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 632
 633 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 634   (if (listp condition)
 635       (or (elmo-folder-search-requires-msgdb-p-internal
 636            folder (nth 1 condition))
 637           (elmo-folder-search-requires-msgdb-p-internal
 638            folder (nth 2 condition)))
 639     (and (not (string= (elmo-filter-key condition) "last"))
 640          (not (string= (elmo-filter-key condition) "first")))))
 641
 642 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 643                                                          condition)
 644   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 645
 646 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 647   nil)
 648
 649 (luna-define-method elmo-folder-open ((folder elmo-folder)
 650                                       &optional load-msgdb)
 651   (elmo-generic-folder-open folder load-msgdb))
 652
 653 (defun elmo-generic-folder-open (folder load-msgdb)
 654   (let ((inhibit-quit t))
 655     (if load-msgdb (elmo-folder-msgdb folder))
 656     (elmo-folder-set-killed-list-internal
 657      folder
 658      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 659   (elmo-folder-open-internal folder))
 660
 661 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 662   nil ; default is do nothing.
 663   )
 664
 665 (luna-define-method elmo-folder-check ((folder elmo-folder))
 666   nil) ; default is noop.
 667
 668 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 669   (elmo-generic-folder-commit folder))
 670
 671 (defun elmo-generic-folder-commit (folder)
 672   (when (elmo-folder-persistent-p folder)
 673     (when (elmo-folder-message-modified-internal folder)
 674       (elmo-msgdb-overview-save
 675        (elmo-folder-msgdb-path folder)
 676        (elmo-msgdb-get-overview (elmo-folder-msgdb folder)))
 677       (elmo-msgdb-number-save
 678        (elmo-folder-msgdb-path folder)
 679        (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))
 680       (elmo-folder-set-info-max-by-numdb
 681        folder
 682        (elmo-folder-list-messages folder nil 'in-msgdb))
 683       (elmo-folder-set-message-modified-internal folder nil)
 684       (elmo-msgdb-killed-list-save
 685        (elmo-folder-msgdb-path folder)
 686        (elmo-folder-killed-list-internal folder)))
 687     (when (elmo-folder-mark-modified-internal folder)
 688       (elmo-msgdb-mark-save
 689        (elmo-folder-msgdb-path folder)
 690        (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
 691       (elmo-folder-set-mark-modified-internal folder nil))))
 692
 693 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 694   ;; do nothing.
 695   )
 696
 697 (luna-define-method elmo-folder-close ((folder elmo-folder))
 698   (elmo-generic-folder-close folder)
 699   (elmo-folder-close-internal folder))
 700
 701 (defun elmo-generic-folder-close (folder)
 702   (elmo-folder-commit folder)
 703   (elmo-folder-set-msgdb-internal folder nil)
 704   (elmo-folder-set-killed-list-internal folder nil))
 705
 706 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 707   t) ; default is plugged.
 708
 709 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 710                                              &optional add)
 711   nil) ; default is do nothing.
 712
 713 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 714   nil) ; default is no flag.
 715
 716 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 717   (elmo-folder-persistent-internal folder))
 718
 719 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 720   nil) ; default is not creatable.
 721
 722 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 723   nil) ; default is not writable.
 724
 725 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 726   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 727                              (elmo-folder-name-internal folder)))
 728     (elmo-msgdb-delete-path folder)
 729     t))
 730
 731 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 732   (let* ((new-folder (elmo-make-folder new-name)))
 733     (unless (eq (elmo-folder-type-internal folder)
 734                 (elmo-folder-type-internal new-folder))
 735       (error "Not same folder type"))
 736     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 737             (elmo-folder-exists-p new-folder))
 738         (error "Already exists folder: %s" new-name))
 739     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 740     (elmo-msgdb-rename-path folder new-folder)))
 741
 742 (defsubst elmo-folder-search-fast (folder condition numbers)
 743   "Search and return list of message numbers.
 744 Return t if CONDITION is not treated.
 745 FOLDER is the ELMO folder structure.
 746 CONDITION is a condition structure for searching.
 747 NUMBERS is a list of message numbers, messages are searched from the list."
 748   (if (and numbers
 749            (vectorp condition))
 750       (cond
 751        ((string= (elmo-filter-key condition) "flag")
 752         (let ((msgdb (elmo-folder-msgdb folder)))
 753           ;; msgdb should be synchronized at this point.
 754           (cond
 755            ((string= (elmo-filter-value condition) "unread")
 756             (elmo-folder-list-unreads folder))
 757            ((string= (elmo-filter-value condition) "important")
 758             (elmo-folder-list-importants folder))
 759            ((string= (elmo-filter-value condition) "answered")
 760             (elmo-folder-list-answereds folder))
 761            ((string= (elmo-filter-value condition) "digest")
 762             (nconc (elmo-folder-list-unreads folder)
 763                    (elmo-folder-list-importants folder)))
 764            ((string= (elmo-filter-value condition) "any")
 765             (nconc (elmo-folder-list-unreads folder)
 766                    (elmo-folder-list-importants folder)
 767                    (elmo-folder-list-answereds folder))))))
 768        ((member (elmo-filter-key condition) '("first" "last"))
 769         (let ((len (length numbers))
 770               (lastp (string= (elmo-filter-key condition) "last"))
 771               (value (string-to-number (elmo-filter-value condition))))
 772           (when (eq (elmo-filter-type condition) 'unmatch)
 773             (setq lastp (not lastp)
 774                   value  (- len value)))
 775           (if lastp
 776               (nthcdr (max (- len value) 0) numbers)
 777             (when (> value 0)
 778               (let* ((numbers (copy-sequence numbers))
 779                      (last (nthcdr (1- value) numbers)))
 780                 (when last
 781                   (setcdr last nil))
 782                 numbers)))))
 783        (t
 784         t))
 785     t))
 786
 787 (luna-define-method elmo-folder-search ((folder elmo-folder)
 788                                         condition
 789                                         &optional numbers)
 790   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 791         results)
 792     (if (listp (setq results (elmo-folder-search-fast folder
 793                                                       condition
 794                                                       numbers)))
 795         results
 796       (let ((msgdb (elmo-folder-msgdb folder))
 797             (len (length numbers))
 798             matched)
 799         (when (> len elmo-display-progress-threshold)
 800           (elmo-progress-set 'elmo-folder-search len "Searching..."))
 801         (unwind-protect
 802             (dolist (number numbers)
 803               (let (result)
 804                 (setq result (elmo-msgdb-match-condition
 805                               msgdb
 806                               condition
 807                               number
 808                               numbers))
 809                 (when (elmo-filter-condition-p result)
 810                   (setq result (elmo-message-match-condition
 811                                 folder
 812                                 number
 813                                 condition
 814                                 numbers)))
 815                 (when result
 816                   (setq matched (cons number matched))))
 817               (elmo-progress-notify 'elmo-folder-search))
 818           (elmo-progress-clear 'elmo-folder-search))
 819         (nreverse matched)))))
 820
 821 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 822                                                   number condition
 823                                                   numbers)
 824   (let ((filename (cond
 825                    ((elmo-message-file-name folder number))
 826                    ((let* ((cache (elmo-file-cache-get
 827                                    (elmo-message-field folder number
 828                                                        'message-id)))
 829                            (cache-path (elmo-file-cache-path cache)))
 830                       (when (and cache-path
 831                                  (not (elmo-cache-path-section-p cache-path)))
 832                         cache-path))))))
 833     (when (and filename
 834                (file-readable-p filename))
 835       (with-temp-buffer
 836         (insert-file-contents-as-binary filename)
 837         (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 838         ;; Should consider charset?
 839         (decode-mime-charset-region (point-min) (point-max) elmo-mime-charset)
 840         (elmo-buffer-field-condition-match condition number numbers)))))
 841
 842 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 843   nil) ; default is noop.
 844
 845 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 846   nil) ; default is noop.
 847
 848 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 849   nil) ; default is not file.
 850
 851 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 852   nil) ; default is not number.
 853
 854 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 855   nil) ; default is not make temp file.
 856
 857 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 858                                                    number)
 859   nil) ; default is no name.
 860
 861 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 862   t)   ; default is local.
 863
 864 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 865   t)
 866
 867 ;;; Folder info
 868 ;; Folder info is a message number information cache (hashtable)
 869 (defsubst elmo-folder-get-info (folder &optional hashtb)
 870   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 871   (elmo-get-hash-val (elmo-folder-name-internal folder)
 872                      (or hashtb elmo-folder-info-hashtb)))
 873
 874 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 875   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 876   (let ((info (elmo-folder-get-info folder)))
 877     (when info
 878       (or new     (setq new     (nth 0 info)))
 879       (or unread  (setq unread  (nth 1 info)))
 880       (or numbers (setq numbers (nth 2 info)))
 881       (or max     (setq max     (nth 3 info))))
 882     (elmo-set-hash-val (elmo-folder-name-internal folder)
 883                        (list new unread numbers max)
 884                        elmo-folder-info-hashtb)))
 885
 886 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 887   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 888   (let ((numbers (sort numbers '<)))
 889     (elmo-folder-set-info-hashtb
 890      folder
 891      (or (nth (max 0 (1- (length numbers))) numbers) 0)
 892      nil ;;(length num-db)
 893      )))
 894
 895 (defun elmo-folder-get-info-max (folder)
 896   "Return max number of FODLER from folder info."
 897   (nth 3 (elmo-folder-get-info folder)))
 898
 899 (defun elmo-folder-get-info-length (folder)
 900   "Return length of FODLER from folder info."
 901   (nth 2 (elmo-folder-get-info folder)))
 902
 903 (defun elmo-folder-get-info-unread (folder)
 904   "Return unread of FODLER from folder info."
 905   (nth 1 (elmo-folder-get-info folder)))
 906
 907 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 908   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 909   (let* ((hashtb (or hashtb
 910                      (elmo-make-hash (length info-alist)))))
 911     (mapcar
 912      (lambda (x)
 913        (let ((info (cadr x)))
 914          (and (intern-soft (car x) hashtb)
 915               (elmo-set-hash-val (car x)
 916                                  (list (nth 2 info)   ;; new
 917                                        (nth 3 info)   ;; unread
 918                                        (nth 1 info)   ;; length
 919                                        (nth 0 info))  ;; max
 920                                  hashtb))))
 921      info-alist)
 922     (setq elmo-folder-info-hashtb hashtb)))
 923
 924 (defsubst elmo-diff-new (diff)
 925   (car diff))
 926
 927 (defsubst elmo-diff-unread (diff)
 928   (when (consp (cdr diff))
 929     (nth 1 diff)))
 930
 931 (defsubst elmo-diff-all (diff)
 932   (if (consp (cdr diff))
 933       (nth 2 diff)
 934     (cdr diff)))
 935
 936 (defsubst elmo-strict-folder-diff (folder)
 937   "Return folder diff information strictly from FOLDER."
 938   (let* ((dir (elmo-folder-msgdb-path folder))
 939          (nalist (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))
 940          (in-db (sort (mapcar 'car nalist) '<))
 941          (in-folder  (elmo-folder-list-messages folder))
 942          append-list delete-list diff)
 943     (cons (if (equal in-folder in-db)
 944               0
 945             (setq diff (elmo-list-diff in-folder in-db nil))
 946             (setq append-list (car diff))
 947             (setq delete-list (cadr diff))
 948             (if append-list
 949                 (length append-list)
 950               (if delete-list
 951                   (- 0 (length delete-list))
 952                 0)))
 953           (length in-folder))))
 954
 955 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 956   (elmo-generic-folder-diff folder))
 957
 958 (defun elmo-generic-folder-diff (folder)
 959   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 960                                 elmo-strict-diff-folder-list)
 961       (elmo-strict-folder-diff folder)
 962     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 963           (in-folder (elmo-folder-status folder))
 964           (in-db t)
 965           unsync messages
 966           in-db-max)
 967       (if (not cached-in-db-max)
 968           (let ((number-list (elmo-folder-list-messages folder
 969                                                         nil 'in-msgdb)))
 970             ;; No info-cache.
 971             (setq in-db (sort number-list '<))
 972             (setq in-db-max (or (nth (max 0 (1- (length in-db))) in-db)
 973                                 0))
 974             (elmo-folder-set-info-hashtb folder in-db-max nil))
 975         (setq in-db-max cached-in-db-max))
 976       (setq unsync (if (and in-db (car in-folder))
 977                        (- (car in-folder) in-db-max)
 978                      (if (and in-folder (null in-db))
 979                          (cdr in-folder)
 980                        (car in-folder))))
 981       (setq messages (cdr in-folder))
 982       (if (and unsync messages (> unsync messages))
 983           (setq unsync messages))
 984       (cons (or unsync 0) (or messages 0)))))
 985
 986 (defvar elmo-folder-diff-async-callback nil)
 987 (defvar elmo-folder-diff-async-callback-data nil)
 988
 989 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 990   (and elmo-folder-diff-async-callback
 991        (funcall elmo-folder-diff-async-callback
 992                 folder
 993                 (elmo-folder-diff folder))))
 994
 995 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
 996   (list folder))
 997
 998 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
 999   (eq (elmo-folder-type-internal folder) type))
1000
1001 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
1002                                                  src-folder
1003                                                  numbers
1004                                                  &optional
1005                                                  same-number)
1006   (elmo-generic-folder-append-messages folder src-folder numbers
1007                                        same-number))
1008
1009 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1010                                                    same-number)
1011   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
1012         unseen table flag mark
1013         succeed-numbers failure cache id)
1014     (setq table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1015     (with-temp-buffer
1016       (set-buffer-multibyte nil)
1017       (while numbers
1018         (setq failure nil
1019               id (and src-msgdb-exists
1020                       (elmo-message-field src-folder (car numbers)
1021                                           'message-id))
1022               mark (and src-msgdb-exists
1023                         (elmo-message-mark src-folder (car numbers)))
1024               flag (and id
1025                         (cond
1026                          ((null mark) 'read)
1027                          ((member mark (elmo-msgdb-answered-marks))
1028                           'answered)
1029                          ;;
1030                          ((not (member mark (elmo-msgdb-unread-marks)))
1031                           'read))))
1032         (condition-case nil
1033             (setq cache (elmo-file-cache-get id)
1034                   failure
1035                   (not
1036                    (and
1037                     (elmo-message-fetch
1038                      src-folder (car numbers)
1039                      (if (elmo-folder-plugged-p src-folder)
1040                          (elmo-make-fetch-strategy
1041                           'entire 'maybe nil
1042                           (and cache (elmo-file-cache-path cache)))
1043                        (or (and elmo-enable-disconnected-operation
1044                                 cache
1045                                 (eq (elmo-file-cache-status cache) 'entire)
1046                                 (elmo-make-fetch-strategy
1047                                  'entire t nil
1048                                  (elmo-file-cache-path cache)))
1049                            (error "Unplugged")))
1050                      nil (current-buffer)
1051                      'unread)
1052                     (> (buffer-size) 0)
1053                     (elmo-folder-append-buffer
1054                      folder
1055                      flag
1056                      (if same-number (car numbers))))))
1057           (error (setq failure t)))
1058         ;; FETCH & APPEND finished
1059         (unless failure
1060           (when id
1061             (elmo-flag-table-set table id flag))
1062           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1063         (elmo-progress-notify 'elmo-folder-move-messages)
1064         (setq numbers (cdr numbers)))
1065       (when (elmo-folder-persistent-p folder)
1066         (elmo-flag-table-save (elmo-folder-msgdb-path folder) table))
1067       succeed-numbers)))
1068
1069 ;; Arguments should be reduced.
1070 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1071                                              &optional msgdb
1072                                              no-delete-info
1073                                              no-delete
1074                                              same-number
1075                                              save-unread)
1076   (save-excursion
1077     (let* ((messages msgs)
1078            (elmo-inhibit-display-retrieval-progress t)
1079            (len (length msgs))
1080            succeeds i result)
1081       (if (eq dst-folder 'null)
1082           (setq succeeds messages)
1083         (unless (elmo-folder-writable-p dst-folder)
1084           (error "move: %d is not writable"
1085                  (elmo-folder-name-internal dst-folder)))
1086         (when messages
1087           ;; src is already opened.
1088           (elmo-folder-open-internal dst-folder)
1089           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1090                                                               src-folder
1091                                                               messages
1092                                                               same-number))
1093             (error "move: append message to %s failed"
1094                    (elmo-folder-name-internal dst-folder)))
1095           (elmo-folder-close dst-folder)))
1096       (if (and (not no-delete) succeeds)
1097           (progn
1098             (if (and (elmo-folder-delete-messages src-folder succeeds)
1099                      (elmo-folder-detach-messages src-folder succeeds))
1100                 (setq result t)
1101               (message "move: delete messages from %s failed."
1102                        (elmo-folder-name-internal src-folder))
1103               (setq result nil))
1104             result)
1105         (if no-delete
1106             (progn
1107               ;; (message "Copying messages...done")
1108               t)
1109           (if (eq len 0)
1110               (message "No message was moved.")
1111             (message "Moving messages failed.")
1112             nil ; failure
1113             ))))))
1114
1115 (defun elmo-folder-msgdb-path (folder)
1116   "Return the msgdb path for FOLDER."
1117   (or (elmo-folder-path-internal folder)
1118       (elmo-folder-set-path-internal
1119        folder
1120        (elmo-folder-expand-msgdb-path folder))))
1121
1122 (defun elmo-message-accessible-p (folder number)
1123   "Get accessibility of the message.
1124 Return non-nil when message is accessible."
1125   (or (elmo-folder-plugged-p folder)
1126       (elmo-folder-local-p folder)
1127       (elmo-msgdb-get-cached (elmo-folder-msgdb folder) number)))
1128
1129 (luna-define-generic elmo-message-set-cached (folder number cached)
1130   "Set cache status of the message in the msgdb.
1131 FOLDER is the ELMO folder structure.
1132 NUMBER is a number of the message.
1133 If CACHED is t, message is set as cached.")
1134
1135 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1136                                              number cached)
1137   (when (elmo-msgdb-set-cached (elmo-folder-msgdb folder)
1138                                number
1139                                cached
1140                                (elmo-message-use-cache-p folder number))
1141     (elmo-folder-set-mark-modified-internal folder t)))
1142
1143 (defun elmo-message-copy-entity (entity)
1144   ;;
1145   (elmo-msgdb-copy-overview-entity entity))
1146
1147 (defun elmo-message-entity-set-number (entity number)
1148   (elmo-msgdb-overview-entity-set-number entity number))
1149
1150 (luna-define-generic elmo-message-entity (folder key)
1151   "Return the message-entity structure which matches to the KEY.
1152 KEY is a number or a string.
1153 A number is for message number in the FOLDER.
1154 A string is for message-id of the message.")
1155
1156 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1157   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1158
1159 (luna-define-generic elmo-message-entity-parent (folder entity)
1160   "Return the parent message-entity structure in the FOLDER.
1161 ENTITY is the message-entity to get the parent.")
1162
1163 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1164   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1165
1166 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1167 (def-edebug-spec elmo-folder-do-each-message-entity
1168   ((symbolp form &rest form) &rest form))
1169
1170 (defsubst elmo-folder-list-message-entities (folder)
1171   ;; List all message entities in the FOLDER.
1172   (mapcar
1173    (lambda (number) (elmo-message-entity folder number))
1174    (elmo-folder-list-messages folder t t)))
1175
1176 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1177   "Iterator for message entity in the folder.
1178 \(elmo-folder-do-each-message-entity \(entity folder\)
1179  ... do the process using entity...
1180 \)"
1181   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1182      ,@form))
1183
1184 (defmacro elmo-message-entity-number (entity)
1185   `(elmo-msgdb-overview-entity-get-number ,entity))
1186
1187 (defun elmo-message-entity-field (entity field &optional decode)
1188   "Get message entity field value.
1189 ENTITY is the message entity structure obtained by `elmo-message-entity'.
1190 FIELD is the symbol of the field name.
1191 if optional DECODE is non-nil, returned value is decoded."
1192   (elmo-msgdb-message-entity-field entity field decode))
1193
1194 (defun elmo-message-entity-set-field (entity field value)
1195   "Set message entity field value.
1196 ENTITY is the message entity structure.
1197 FIELD is the symbol of the field name.
1198 VALUE is the field value (raw)."
1199   (elmo-msgdb-message-entity-set-field entity field value))
1200
1201 (luna-define-generic elmo-folder-count-flags (folder)
1202   "Count flagged message number in the msgdb of the FOLDER.
1203 Return a list of numbers (`new' `unread' `answered')")
1204
1205 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1206   (let ((new 0)
1207         (unreads 0)
1208         (answered 0))
1209     (dolist (elem (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
1210       (cond
1211        ((string= (cadr elem) elmo-msgdb-new-mark)
1212         (incf new))
1213        ((member (cadr elem) (elmo-msgdb-unread-marks))
1214         (incf unreads))
1215        ((member (cadr elem) (elmo-msgdb-answered-marks))
1216         (incf answered))))
1217     (list new unreads answered)))
1218
1219 (defun elmo-message-set-flag (folder number flag)
1220   "Set message flag.
1221 FOLDER is a ELMO folder structure.
1222 NUMBER is a message number to set flag.
1223
1224 FLAG is a symbol which is one of the following:
1225   `unread'    (set the message as unread)
1226   `answered'  (set the message as answered)
1227   `important' (set the message as important)
1228 'sugar' flag:
1229   `read'      (remove new and unread flags)")
1230
1231 (defun elmo-message-unset-flag (folder number flag)
1232   "Unset message flag.
1233 FOLDER is a ELMO folder structure.
1234 NUMBER is a message number to set flag.
1235
1236 FLAG is a symbol which is one of the following:
1237   `unread'    (remove unread and new flag)
1238   `answered'  (remove answered flag)
1239   `important' (remove important flag)
1240 'sugar' flag:
1241   `read'      (set unread flag)")
1242
1243 (luna-define-generic elmo-message-mark (folder number)
1244   "Get mark of the message.
1245 FOLDER is the ELMO folder structure.
1246 NUMBER is a number of the message.")
1247
1248 (luna-define-method elmo-message-mark ((folder elmo-folder) number)
1249   (when (zerop (elmo-folder-length folder))
1250     (error "Cannot treat this folder correctly."))
1251   (elmo-msgdb-get-mark (elmo-folder-msgdb folder) number))
1252
1253 (luna-define-generic elmo-message-field (folder number field)
1254   "Get message field value in the msgdb.
1255 FOLDER is the ELMO folder structure.
1256 NUMBER is a number of the message.
1257 FIELD is a symbol of the field.")
1258
1259 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1260   (when (zerop (elmo-folder-length folder))
1261     (error "Cannot treat this folder correctly."))
1262   (elmo-msgdb-get-field (elmo-folder-msgdb folder) number field))
1263
1264 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1265   nil) ; default is not use cache.
1266
1267 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1268   folder) ; default is folder
1269
1270 (luna-define-method elmo-folder-unmark-important ((folder elmo-folder)
1271                                                   numbers
1272                                                   &optional ignore-flags)
1273   (when (elmo-folder-msgdb-internal folder)
1274     (dolist (number numbers)
1275       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1276                              folder
1277                              number
1278                              'important))))
1279
1280 (luna-define-method elmo-folder-mark-as-important ((folder elmo-folder)
1281                                                    numbers
1282                                                    &optional ignore-flags)
1283   (when (elmo-folder-msgdb-internal folder)
1284     (dolist (number numbers)
1285       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1286                            folder
1287                            number
1288                            'important))))
1289
1290 (luna-define-method elmo-folder-unmark-read ((folder elmo-folder)
1291                                              numbers
1292                                              &optional ignore-flags)
1293   (when (elmo-folder-msgdb-internal folder)
1294     (dolist (number numbers)
1295       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1296                              folder
1297                              number
1298                              'read))))
1299
1300 (luna-define-method elmo-folder-mark-as-read ((folder elmo-folder)
1301                                               numbers
1302                                               &optional ignore-flag)
1303   (when (elmo-folder-msgdb-internal folder)
1304     (dolist (number numbers)
1305       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1306                            folder
1307                            number
1308                            'read))))
1309
1310 (luna-define-method elmo-folder-unmark-answered ((folder elmo-folder) numbers)
1311   (when (elmo-folder-msgdb-internal folder)
1312     (dolist (number numbers)
1313       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1314                              folder
1315                              number
1316                              'answered))))
1317
1318 (luna-define-method elmo-folder-mark-as-answered ((folder elmo-folder) numbers)
1319   (when (elmo-folder-msgdb-internal folder)
1320     (dolist (number numbers)
1321       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1322                            folder
1323                            number
1324                            'answered))))
1325
1326 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1327   ;; Do nothing.
1328   )
1329
1330 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1331 ;;                                                             &optional
1332 ;;                                                             flag-table)
1333 ;;  "Append ENTITY to the folder.")
1334
1335 (defun elmo-generic-folder-append-msgdb (folder append-msgdb)
1336   (if append-msgdb
1337       (let* ((number-alist (elmo-msgdb-get-number-alist append-msgdb))
1338              (all-alist (copy-sequence (append
1339                                         (elmo-msgdb-get-number-alist
1340                                          (elmo-folder-msgdb folder))
1341                                         number-alist)))
1342              (cur number-alist)
1343              pair overview
1344              to-be-deleted
1345              mark-alist)
1346         (elmo-folder-set-msgdb-internal folder
1347                                         (elmo-msgdb-append
1348                                          (elmo-folder-msgdb folder)
1349                                          append-msgdb))
1350         (while cur
1351           (setq all-alist (delq (car cur) all-alist))
1352           ;; same message id exists.
1353           (if (setq pair (rassoc (cdr (car cur)) all-alist))
1354               (setq to-be-deleted (nconc to-be-deleted (list (car pair)))))
1355           (setq cur (cdr cur)))
1356         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1357                    'hide)
1358                ;; Hide duplicates.
1359                (setq overview (elmo-delete-if
1360                                (lambda (x)
1361                                  (memq (elmo-msgdb-overview-entity-get-number
1362                                         x)
1363                                        to-be-deleted))
1364                                (elmo-msgdb-get-overview append-msgdb)))
1365                ;; Should be mark as read.
1366                (elmo-folder-mark-as-read folder to-be-deleted)
1367                (elmo-msgdb-set-overview append-msgdb overview))
1368               ((eq (elmo-folder-process-duplicates-internal folder)
1369                    'read)
1370                ;; Mark as read duplicates.
1371                (elmo-folder-mark-as-read folder to-be-deleted))
1372               (t
1373                ;; Do nothing.
1374                (setq to-be-deleted nil)))
1375         (length to-be-deleted))
1376     0))
1377
1378 (luna-define-method elmo-folder-append-msgdb ((folder elmo-folder)
1379                                               append-msgdb)
1380   (elmo-generic-folder-append-msgdb folder append-msgdb))
1381
1382 (defun elmo-folder-confirm-appends (appends)
1383   (let ((len (length appends))
1384         in)
1385     (if (and elmo-folder-update-threshold
1386              (> len elmo-folder-update-threshold)
1387              elmo-folder-update-confirm)
1388         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1389             appends
1390           (setq in elmo-folder-update-threshold)
1391           (catch 'end
1392             (while t
1393               (setq in (read-from-minibuffer "Update number: "
1394                                              (int-to-string in))
1395                     in (string-to-int in))
1396               (if (< len in)
1397                   (throw 'end len))
1398               (if (y-or-n-p (format "%d messages are not appeared.  OK? "
1399                                     (max (- len in) 0)))
1400                   (throw 'end in))))
1401           (nthcdr (max (- len in) 0) appends))
1402       (if (and elmo-folder-update-threshold
1403                (> len elmo-folder-update-threshold)
1404                (not elmo-folder-update-confirm))
1405           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1406         appends))))
1407
1408 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1409                                         number strategy
1410                                         &optional
1411                                         section
1412                                         outbuf
1413                                         unread)
1414   (if outbuf
1415       (with-current-buffer outbuf
1416         (erase-buffer)
1417         (elmo-message-fetch-with-cache-process folder number
1418                                                strategy section unread))
1419     (with-temp-buffer
1420       (elmo-message-fetch-with-cache-process folder number
1421                                              strategy section unread)
1422       (buffer-string))))
1423
1424 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1425                                                            number strategy
1426                                                            &optional
1427                                                            section unread)
1428   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1429         (method-priorities
1430          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1431                 '(entity cache))
1432                ((elmo-fetch-strategy-use-cache strategy)
1433                 '(cache entity))
1434                (t
1435                 '(entity))))
1436         result err)
1437     (while (and method-priorities
1438                 (null result))
1439       (setq result
1440             (case (car method-priorities)
1441               (cache
1442                (elmo-file-cache-load cache-path section))
1443               (entity
1444                (when (and (condition-case error
1445                               (elmo-message-fetch-internal folder number
1446                                                            strategy
1447                                                            section
1448                                                            unread)
1449                             (error (setq err error) nil))
1450                           (> (buffer-size) 0))
1451                  (elmo-delete-cr-buffer)
1452                  (when (and (elmo-fetch-strategy-save-cache strategy)
1453                             cache-path)
1454                    (elmo-file-cache-save cache-path section))
1455                  t)))
1456             method-priorities (cdr method-priorities)))
1457     (or result
1458         (and err (signal (car err) (cdr err))))))
1459
1460 (defun elmo-folder-kill-messages-before (folder msg)
1461   (elmo-folder-set-killed-list-internal
1462    folder
1463    (list (cons 1 msg))))
1464
1465 (defun elmo-folder-kill-messages (folder numbers)
1466   "Kill(hide) messages in the FOLDER with NUMBERS."
1467   (elmo-folder-set-killed-list-internal
1468    folder
1469    (elmo-number-set-append-list (elmo-folder-killed-list-internal
1470                                  folder) numbers)))
1471
1472
1473 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1474                                        &optional keep-killed)
1475   (unless keep-killed
1476     (elmo-folder-set-killed-list-internal folder nil))
1477   (elmo-folder-set-msgdb-internal folder (elmo-msgdb-clear)))
1478
1479 (luna-define-generic elmo-folder-synchronize (folder
1480                                               &optional ignore-msgdb
1481                                               no-check)
1482   "Synchronize the folder data to the newest status.
1483 FOLDER is the ELMO folder structure.
1484
1485 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1486 flag status. If IGNORE-MSGDB is 'visible-only, only visible messages
1487 \(the messages which are not in the killed-list\) are thrown away and
1488 synchronized.
1489 If NO-CHECK is non-nil, rechecking folder is skipped.
1490 Return a list of a cross-posted message number.
1491 If update process is interrupted, return nil.")
1492
1493 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1494                                              &optional ignore-msgdb no-check)
1495   (let ((killed-list (elmo-folder-killed-list-internal folder))
1496         (before-append t)
1497         number-alist
1498         old-msgdb diff diff-2 delete-list new-list new-msgdb mark
1499         flag-table crossed after-append numbers)
1500     (setq old-msgdb (elmo-folder-msgdb folder))
1501     (setq flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1502     (when ignore-msgdb
1503       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1504       (elmo-folder-clear folder (eq ignore-msgdb 'visible-only)))
1505     (setq numbers (sort (elmo-folder-list-messages folder nil t) '<))
1506     (unless no-check (elmo-folder-check folder))
1507     (condition-case nil
1508         (progn
1509           (message "Checking folder diff...")
1510           (setq diff (elmo-list-diff (elmo-folder-list-messages
1511                                       folder
1512                                       (eq 'visible-only ignore-msgdb))
1513                                      numbers))
1514           (message "Checking folder diff...done")
1515           (setq new-list (elmo-folder-confirm-appends (car diff)))
1516           ;; Set killed list as ((1 . MAX-OF-DISAPPEARED))
1517           (when (and (not (eq (length (car diff))
1518                               (length new-list)))
1519                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1520             (elmo-folder-kill-messages-before folder
1521                                               (nth (- (length (car diff-2)) 1)
1522                                                    (car diff-2))))
1523           (setq delete-list (cadr diff))
1524           (if (or (equal diff '(nil nil))
1525                   (equal diff '(nil))
1526                   (and (eq (length (car diff)) 0)
1527                        (eq (length (cadr diff)) 0)))
1528               (progn
1529                 (elmo-folder-update-number folder)
1530                 (elmo-folder-process-crosspost folder)
1531                 0 ; no updates.
1532                 )
1533             (when delete-list
1534               (elmo-folder-detach-messages folder delete-list))
1535             (when new-list
1536               (elmo-msgdb-change-mark (elmo-folder-msgdb folder)
1537                                       elmo-msgdb-new-mark
1538                                       elmo-msgdb-unread-uncached-mark)
1539               (setq new-msgdb (elmo-folder-msgdb-create
1540                                folder new-list flag-table))
1541               ;; Clear flag-table
1542               (if (elmo-folder-persistent-p folder)
1543                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1544                                         nil))
1545               (setq before-append nil)
1546               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1547               ;; process crosspost.
1548               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).
1549               (elmo-folder-process-crosspost folder)
1550               (elmo-folder-set-message-modified-internal folder t)
1551               (elmo-folder-set-mark-modified-internal folder t))
1552             ;; return value.
1553             (or crossed 0)))
1554       (quit
1555        ;; Resume to the original status.
1556        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1557        (elmo-folder-set-killed-list-internal folder killed-list)
1558        nil))))
1559
1560 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1561   "Remove messages with NUMBERS from MSGDB.")
1562
1563 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1564                                                  numbers)
1565   (elmo-msgdb-delete-msgs (elmo-folder-msgdb folder) numbers))
1566
1567 (luna-define-generic elmo-folder-length (folder)
1568   "Return number of messages in the FOLDER.")
1569
1570 (luna-define-method elmo-folder-length ((folder elmo-folder))
1571   (if (elmo-folder-msgdb-internal folder)
1572       (elmo-msgdb-length (elmo-folder-msgdb folder))
1573     0))
1574
1575 (defun elmo-msgdb-load (folder &optional silent)
1576   (unless silent
1577     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1578   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1579     (elmo-folder-set-info-max-by-numdb
1580      folder
1581      (mapcar 'elmo-msgdb-overview-entity-get-number
1582              (elmo-msgdb-get-overview msgdb)))
1583     (unless silent
1584       (message "Loading msgdb for %s...done"
1585                (elmo-folder-name-internal folder)))
1586     msgdb))
1587
1588 (defun elmo-msgdb-delete-path (folder)
1589   (let ((path (elmo-folder-msgdb-path folder)))
1590     (if (file-directory-p path)
1591         (elmo-delete-directory path t))))
1592
1593 (defun elmo-msgdb-rename-path (old-folder new-folder)
1594   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1595          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1596          (new-dir (directory-file-name (file-name-directory new))))
1597     (if (not (file-directory-p old))
1598         ()
1599       (if (file-exists-p new)
1600           (error "Already exists directory: %s" new)
1601         (if (not (file-exists-p new-dir))
1602             (elmo-make-directory new-dir))
1603         (rename-file old new)))))
1604
1605 (defun elmo-setup-subscribed-newsgroups (groups)
1606   "Setup subscribed newsgroups.
1607 GROUPS is a list of newsgroup name string.
1608 Return a hashtable for newsgroups."
1609   (let ((hashtb (or elmo-newsgroups-hashtb
1610                     (setq elmo-newsgroups-hashtb
1611                           (elmo-make-hash (length groups))))))
1612     (dolist (group groups)
1613       (or (elmo-get-hash-val group hashtb)
1614           (elmo-set-hash-val group nil hashtb)))
1615     (setq elmo-newsgroups-hashtb hashtb)))
1616
1617 (defvar elmo-crosspost-message-alist-modified nil)
1618 (defun elmo-crosspost-message-alist-load ()
1619   "Load crosspost message alist."
1620   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1621   (setq elmo-crosspost-message-alist-modified nil))
1622
1623 (defun elmo-crosspost-message-alist-save ()
1624   "Save crosspost message alist."
1625   (when elmo-crosspost-message-alist-modified
1626     (let ((alist elmo-crosspost-message-alist)
1627           newsgroups)
1628       (while alist
1629         (setq newsgroups
1630               (elmo-delete-if
1631                '(lambda (x)
1632                   (not (intern-soft x elmo-newsgroups-hashtb)))
1633                (nth 1 (car alist))))
1634         (if newsgroups
1635             (setcar (cdar alist) newsgroups)
1636           (setq elmo-crosspost-message-alist
1637                 (delete (car alist) elmo-crosspost-message-alist)))
1638         (setq alist (cdr alist)))
1639       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1640       (setq elmo-crosspost-message-alist-modified nil))))
1641
1642 (defun elmo-folder-make-temporary-directory (folder)
1643   ;; Make a temporary directory for FOLDER.
1644   (let ((temp-dir (make-temp-name
1645                    (concat
1646                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1647                     "elmo"))))
1648     (elmo-make-directory temp-dir)
1649     temp-dir))
1650
1651 (defun elmo-init ()
1652   "Initialize ELMO module."
1653   (elmo-crosspost-message-alist-load)
1654   (elmo-resque-obsolete-variables)
1655   (elmo-dop-queue-load))
1656
1657 (defun elmo-quit ()
1658   "Quit and cleanup ELMO."
1659   (elmo-crosspost-message-alist-save)
1660   (elmo-dop-queue-save)
1661   ;; Not implemented yet.
1662   (let ((types elmo-folder-type-alist)
1663         class)
1664     (while types
1665       (setq class
1666             (luna-find-class
1667              (intern (format "elmo-%s-folder" (symbol-name (cdr (car types)))))))
1668       ;; Call all folder's `elmo-quit' method.
1669       (if class
1670           (dolist (func (luna-class-find-functions class 'elmo-quit))
1671             (funcall func nil)))
1672       (setq types (cdr types)))))
1673
1674 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1675                                                  new-folder)
1676   (error "Cannot rename %s folder"
1677          (symbol-name (elmo-folder-type-internal folder))))
1678
1679
1680 ;;; Define folders.
1681 (elmo-define-folder ?% 'imap4)
1682 (elmo-define-folder ?-  'nntp)
1683 (elmo-define-folder ?\+ 'localdir)
1684 (elmo-define-folder ?\* 'multi)
1685 (elmo-define-folder ?\/ 'filter)
1686 (elmo-define-folder ?\$ 'archive)
1687 (elmo-define-folder ?&  'pop3)
1688 (elmo-define-folder ?=  'localnews)
1689 (elmo-define-folder ?|  'pipe)
1690 (elmo-define-folder ?.  'maildir)
1691 (elmo-define-folder ?'  'internal)
1692 (elmo-define-folder ?\[  'nmz)
1693 (elmo-define-folder ?@  'shimbun)
1694
1695 ;;; Obsolete variables.
1696 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1697                                'elmo-imap4-default-mailbox)
1698 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1699                                'elmo-imap4-default-server)
1700 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1701                                'elmo-imap4-default-authenticate-type)
1702 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1703                                'elmo-imap4-default-user)
1704 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1705                                'elmo-imap4-default-port)
1706 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1707                                'elmo-imap4-default-stream-type)
1708 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1709                                'elmo-nntp-default-server)
1710 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1711                                'elmo-nntp-default-user)
1712 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1713                                'elmo-nntp-default-port)
1714 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1715                                'elmo-nntp-default-stream-type)
1716 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1717                                'elmo-pop3-default-server)
1718 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1719                                'elmo-pop3-default-user)
1720 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1721                                'elmo-pop3-default-authenticate-type)
1722 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1723                                'elmo-pop3-default-port)
1724 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1725                                'elmo-pop3-default-stream-type)
1726 (elmo-define-obsolete-variable 'elmo-cache-dirname
1727                                'elmo-cache-directory)
1728 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1729                                'elmo-msgdb-directory)
1730
1731 ;; Obsolete functions.
1732 ;; 2001-12-11: *-dir -> *-directory
1733 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1734 (make-obsolete 'elmo-folder-make-temp-dir
1735                'elmo-folder-make-temporary-directory)
1736
1737
1738 ;; autoloads
1739 (autoload 'elmo-dop-queue-flush "elmo-dop")
1740 (autoload 'elmo-nntp-post "elmo-nntp")
1741
1742 (require 'product)
1743 (product-provide (provide 'elmo) (require 'elmo-version))
1744
1745 ;;; elmo.el ends here