elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type 'integer
  50   :group 'elmo)
  51
  52 (defcustom elmo-message-fetch-confirm t
  53   "If non-nil, confirm fetching if message size is larger than
  54 `elmo-message-fetch-threshold'.
  55 Otherwise, entire fetching of the message is aborted without confirmation."
  56   :type 'boolean
  57   :group 'elmo)
  58
  59 (defcustom elmo-folder-update-threshold 500
  60   "Update threshold."
  61   :type 'integer
  62   :group 'elmo)
  63
  64 (defcustom elmo-folder-update-confirm t
  65   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  66   :type 'boolean
  67   :group 'elmo)
  68
  69 (defvar elmo-message-displaying nil
  70   "A global switch to indicate message is displaying or not.")
  71
  72 ;;; internal
  73 (defvar elmo-folder-type-alist nil)
  74
  75 (defvar elmo-newsgroups-hashtb nil)
  76
  77 (elmo-define-error 'elmo-error "Error" 'error)
  78 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  79 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  80 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  81
  82 (defun elmo-define-folder (prefix backend)
  83   "Define a folder.
  84 If a folder name begins with PREFIX, use BACKEND."
  85   (let ((pair (assq prefix elmo-folder-type-alist)))
  86     (if pair
  87         (progn
  88           (setcar pair prefix)
  89           (setcdr pair backend))
  90       (setq elmo-folder-type-alist (cons (cons prefix backend)
  91                                          elmo-folder-type-alist)))))
  92
  93 (defmacro elmo-folder-type (name)
  94   "Get folder type from NAME string."
  95   (` (and (stringp (, name))
  96           (cdr (assoc (string-to-char (, name)) elmo-folder-type-alist)))))
  97
  98 ;;; ELMO folder
  99 ;; A elmo folder provides uniformed (orchestrated) access
 100 ;; to the internet messages.
 101 (eval-and-compile
 102   (luna-define-class elmo-folder () (type   ; folder type symbol.
 103                                      name   ; orignal folder name string.
 104                                      prefix ; prefix for folder name
 105                                      path   ; directory path for msgdb.
 106                                      msgdb  ; msgdb (may be nil).
 107                                      killed-list  ; killed list.
 108                                      persistent   ; non-nil if persistent.
 109                                      message-modified ; message is modified.
 110                                      mark-modified    ; mark is modified.
 111                                      process-duplicates  ; read or hide
 112                                      biff   ; folder for biff
 113                                      ))
 114   (luna-define-internal-accessors 'elmo-folder))
 115
 116 (luna-define-generic elmo-folder-initialize (folder name)
 117   ;; Initialize a FOLDER structure with NAME."
 118   )
 119
 120 (defmacro elmo-folder-send (folder message &rest args)
 121   "Let FOLDER receive the MESSAGE with ARGS."
 122   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 123
 124 ;;;###autoload
 125 (defun elmo-make-folder (name &optional non-persistent)
 126   "Make an ELMO folder structure specified by NAME.
 127 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 128   (let ((type (elmo-folder-type name))
 129         prefix split class folder original)
 130     (setq original (elmo-string name))
 131     (if type
 132         (progn
 133           (setq prefix (substring name 0 1))
 134           (setq name (substring name 1)))
 135       (setq type (intern (car (setq split (split-string name ":")))))
 136       (if (> (length split) 2)
 137           (setq name (substring name (+ 1 (length (car split)))))
 138         (error "Error in folder name `%s'" original))
 139       (setq prefix (concat (car split) ":")))
 140     (setq class (format "elmo-%s" (symbol-name type)))
 141     (require (intern class))
 142     (setq folder (luna-make-entity (intern (concat class "-folder"))
 143                                    :type type
 144                                    :prefix prefix
 145                                    :name original
 146                                    :persistent (not non-persistent)))
 147     (save-match-data
 148       (elmo-folder-send folder 'elmo-folder-initialize name))))
 149
 150 ;; Note that this function is for internal use only.
 151 (luna-define-generic elmo-folder-msgdb (folder)
 152   "Return the msgdb of FOLDER (on-demand loading).
 153 \(For internal use only.\)")
 154
 155 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 156   (or (elmo-folder-msgdb-internal folder)
 157       (elmo-folder-set-msgdb-internal folder
 158                                       (elmo-msgdb-load folder))))
 159
 160 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 161   "Open and setup (load saved status) FOLDER.
 162 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 163 \(otherwise, msgdb is loaded on-demand)")
 164
 165 (luna-define-generic elmo-folder-open-internal (folder)
 166   "Open FOLDER (without loading saved folder status).")
 167
 168 (luna-define-generic elmo-folder-check (folder)
 169   "Check the FOLDER to obtain newest information at the next list operation.")
 170
 171 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 172   "Clear FOLDER to the initial state.
 173 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 174
 175 (luna-define-generic elmo-folder-commit (folder)
 176   "Save current status of FOLDER.")
 177
 178 (luna-define-generic elmo-folder-close (folder)
 179   "Close, save and clearnup FOLDER.")
 180
 181 (luna-define-generic elmo-folder-close-internal (folder)
 182   "Close FOLDER (without saving folder status).")
 183
 184 (luna-define-generic elmo-folder-plugged-p (folder)
 185   "Returns t if FOLDER is plugged.")
 186
 187 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 188   "Set FOLDER as plugged.")
 189
 190 (luna-define-generic elmo-net-port-info (folder)
 191   "Get port information of FOLDER.")
 192
 193 (luna-define-generic elmo-folder-use-flag-p (folder)
 194   "Returns t if FOLDER treats unread/important flag itself.")
 195
 196 (luna-define-generic elmo-folder-diff (folder)
 197   "Get diff of FOLDER.
 198 Return value is cons cell or list:
 199  - a cons cell (new . all)
 200  - a list (new unread all)")
 201
 202 (luna-define-generic elmo-folder-status (folder)
 203   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 204
 205 (luna-define-generic elmo-folder-reserve-status-p (folder)
 206   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 207
 208 (luna-define-generic elmo-folder-set-message-modified (folder modified)
 209   "Set FOLDER as modified.")
 210 (luna-define-method elmo-folder-set-message-modified ((folder elmo-folder)
 211                                                       modified)
 212   (elmo-folder-set-message-modified-internal folder modified))
 213
 214 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 215                                                        in-msgdb)
 216   "Return a list of message numbers contained in FOLDER.
 217 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 218 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 219
 220 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 221                                                &optional visible-only in-msgdb)
 222   (let ((list (if in-msgdb
 223                   t
 224                 (elmo-folder-list-messages-internal folder visible-only)))
 225         (killed-list (elmo-folder-killed-list-internal folder)))
 226     (unless (listp list)
 227       ;; Use current list.
 228       (setq list (elmo-msgdb-list-messages (elmo-folder-msgdb folder))))
 229     (if visible-only
 230         (elmo-living-messages list killed-list)
 231       (elmo-uniq-list
 232        (nconc (elmo-number-set-to-number-list killed-list) list)))))
 233
 234 (luna-define-generic elmo-folder-list-unreads (folder)
 235   "Return a list of unread message numbers contained in FOLDER.")
 236 (luna-define-generic elmo-folder-list-importants (folder)
 237   "Return a list of important message numbers contained in FOLDER.")
 238 (luna-define-generic elmo-folder-list-answereds (folder)
 239   "Return a list of answered message numbers contained in FOLDER.")
 240
 241 ;; TODO: Should reconsider the structure of global mark.
 242 (defun elmo-folder-list-messages-with-global-mark (folder mark)
 243   (let (entity msgs)
 244     (dolist (mark-pair (or elmo-msgdb-global-mark-alist
 245                            (setq elmo-msgdb-global-mark-alist
 246                                  (elmo-object-load
 247                                   (expand-file-name
 248                                    elmo-msgdb-global-mark-filename
 249                                    elmo-msgdb-directory)))))
 250       (if (and (string= mark (cdr mark-pair))
 251                (setq entity
 252                      (elmo-msgdb-overview-get-entity (car mark-pair)
 253                                                      (elmo-folder-msgdb
 254                                                       folder))))
 255           (setq msgs (cons (elmo-msgdb-overview-entity-get-number entity)
 256                            msgs))))
 257     msgs))
 258
 259 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 260   "List messages in the FOLDER with FLAG.
 261 FLAG is a symbol which is one of the following:
 262   `new'        (new messages)
 263   `unread'     (unread messages (new messages are included))
 264   `answered'   (answered or forwarded)
 265   `important'  (marked as important)
 266 'sugar' flags:
 267   `read'       (not unread)
 268   `digest'     (unread + important)
 269   `any'        (digest + answered)
 270
 271 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 272
 273 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 274                                               &optional in-msgdb)
 275   ;; Currently, only in-msgdb is implemented.
 276   (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag))
 277
 278 (luna-define-method elmo-folder-list-unreads ((folder elmo-folder))
 279   (elmo-folder-list-flagged folder 'unread))
 280
 281 (luna-define-method elmo-folder-list-importants ((folder elmo-folder))
 282   (elmo-folder-list-flagged folder 'important))
 283
 284 (luna-define-method elmo-folder-list-answereds ((folder elmo-folder))
 285   (elmo-folder-list-flagged folder 'answered))
 286
 287 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 288                                                                 visible-only)
 289   ;; Return a list of message numbers contained in FOLDER.
 290   ;; Return t if the message list is not available.
 291   )
 292
 293 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 294   "Returns a list of subfolders contained in FOLDER.
 295 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 296 \(a folder which have children is returned as a list\)
 297 Otherwise, all descendent folders are returned.")
 298
 299 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 300   "Return non-nil when FOLDER has subfolders.")
 301
 302 (luna-define-generic elmo-folder-exists-p (folder)
 303   "Returns non-nil when FOLDER exists.")
 304
 305 (luna-define-generic elmo-folder-creatable-p (folder)
 306   "Returns non-nil when FOLDER is creatable.")
 307
 308 (luna-define-generic elmo-folder-writable-p (folder)
 309   "Returns non-nil when FOLDER is writable.")
 310
 311 (luna-define-generic elmo-folder-persistent-p (folder)
 312   "Return non-nil when FOLDER is persistent.")
 313
 314 (luna-define-generic elmo-folder-create (folder)
 315   "Create a FOLDER.")
 316
 317 (luna-define-generic elmo-message-deletable-p (folder number)
 318   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 319
 320 (luna-define-generic elmo-folder-delete (folder)
 321   "Delete FOLDER completely.")
 322
 323 (luna-define-generic elmo-folder-rename (folder new-name)
 324   "Rename FOLDER to NEW-NAME (string).")
 325
 326 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 327   "Delete messages.
 328 FOLDER is the ELMO folder structure.
 329 NUMBERS is a list of message numbers to be deleted.")
 330
 331 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 332   "Search and return list of message numbers.
 333 FOLDER is the ELMO folder structure.
 334 CONDITION is a condition structure for searching.
 335 If optional argument NUMBERS is specified and is a list of message numbers,
 336 messages are searched from the list.")
 337
 338 (luna-define-generic elmo-message-match-condition (folder number
 339                                                           condition
 340                                                           numbers)
 341   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 342 CONDITION is a condition structure for testing.
 343 NUMBERS is a list of message numbers,
 344 use to be test for \"last\" and \"first\" predicates.")
 345
 346 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 347   "Create a message database (implemented in each backends).
 348 FOLDER is the ELMO folder structure.
 349 NUMBERS is a list of message numbers to create msgdb.
 350 FLAG-TABLE is a hashtable of message-id and flag.")
 351
 352 (luna-define-generic elmo-folder-unmark-important (folder
 353                                                    numbers
 354                                                    &optional ignore-flags)
 355   "Un-mark messages as important.
 356 FOLDER is the ELMO folder structure.
 357 NUMBERS is a list of message numbers to be processed.
 358 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 359
 360 (luna-define-generic elmo-folder-mark-as-important (folder
 361                                                     numbers
 362                                                     &optional ignore-flags)
 363   "Mark messages as important.
 364 FOLDER is the ELMO folder structure.
 365 NUMBERS is a list of message numbers to be processed.
 366 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 367
 368 (luna-define-generic elmo-folder-unmark-read (folder numbers
 369                                                      &optional ignore-flags)
 370   "Un-mark messages as read.
 371 FOLDER is the ELMO folder structure.
 372 NUMBERS is a list of message numbers to be processed.
 373 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 374
 375 (luna-define-generic elmo-folder-mark-as-read (folder numbers
 376                                                       &optional ignore-flags)
 377   "Mark messages as read.
 378 FOLDER is the ELMO folder structure.
 379 NUMBERS is a list of message numbers to be processed.
 380 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 381
 382 (luna-define-generic elmo-folder-unmark-answered (folder numbers)
 383   "Un-mark messages as answered.
 384 FOLDER is the ELMO folder structure.
 385 NUMBERS is a list of message numbers to be processed.")
 386
 387 (luna-define-generic elmo-folder-mark-as-answered (folder numbers)
 388   "Mark messages as answered.
 389 FOLDER is the ELMO folder structure.
 390 NUMBERS is a list of message numbers to be processed.")
 391
 392 (luna-define-generic elmo-folder-append-buffer (folder &optional flag
 393                                                        number)
 394   "Append current buffer as a new message.
 395 FOLDER is the destination folder(ELMO folder structure).
 396 FLAG is the status of appended message.
 397 If optional argument NUMBER is specified, the new message number is set
 398 \(if possible\).")
 399
 400 (luna-define-generic elmo-folder-append-messages (folder
 401                                                   src-folder
 402                                                   numbers
 403                                                   &optional
 404                                                   same-number)
 405   "Append messages from folder.
 406 FOLDER is the ELMO folder structure.
 407 Caller should make sure FOLDER is `writable'.
 408 (Can be checked with `elmo-folder-writable-p').
 409 SRC-FOLDER is the source ELMO folder structure.
 410 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 411 If second optional argument SAME-NUMBER is specified,
 412 message number is preserved \(if possible\).")
 413
 414 (luna-define-generic elmo-folder-pack-numbers (folder)
 415   "Pack message numbers of FOLDER.")
 416
 417 (luna-define-generic elmo-folder-update-number (folder)
 418   "Update number of FOLDER.")
 419
 420 (luna-define-generic elmo-folder-diff-async (folder)
 421   "Get diff of FOLDER asynchronously.")
 422
 423 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 424   "Expand path for FOLDER.")
 425
 426 (luna-define-generic elmo-folder-get-primitive-list (folder)
 427   "Get primitive folder structure list contained in FOLDER.")
 428
 429 (luna-define-generic elmo-folder-contains-type (folder type)
 430   "Returns t if FOLDER contains TYPE.")
 431
 432 (luna-define-generic elmo-folder-local-p (folder)
 433   "Returns t if FOLDER is local.")
 434
 435 (luna-define-generic elmo-folder-message-file-p (folder)
 436   "Returns t if all messages in the FOLDER are files.")
 437
 438 ;;; Message methods.
 439 (luna-define-generic elmo-message-use-cache-p (folder number)
 440   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 441
 442 (luna-define-generic elmo-message-file-name (folder number)
 443   "Return the file name of a message specified by FOLDER and NUMBER.")
 444
 445 ;;; For archive
 446
 447 ;;; Use original file
 448 (luna-define-generic elmo-folder-message-file-number-p (folder)
 449   "Return t if the file name in the FOLDER is the message number.")
 450
 451 (luna-define-generic elmo-folder-message-file-directory (folder)
 452   "Return the directory of the message files of FOLDER.")
 453
 454 ;;; Use temporary file
 455 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 456   "Return t if the messages in the FOLDER makes local temporary file.")
 457
 458 (luna-define-generic elmo-folder-message-make-temp-files (folder
 459                                                           numbers
 460                                                           &optional
 461                                                           start-number)
 462   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 463 If START-NUMBER is specified, temporary files begin from the number.
 464 Otherwise, same number is used for temporary files.
 465 Return newly created temporary directory name which contains temporary files.")
 466
 467 (luna-define-generic elmo-message-file-p (folder number)
 468   "Return t if message in the FOLDER with NUMBER is a file.")
 469
 470 (luna-define-generic elmo-find-fetch-strategy
 471   (folder entity &optional ignore-cache)
 472 ;; Returns the message fetching strategy suitable for the message.
 473 ;; FOLDER is the ELMO folder structure.
 474 ;; ENTITY is the overview entity of the message in the folder.
 475 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 476 ;; Returned value is a elmo-fetch-strategy object.
 477 ;; If return value is nil, message should not be nil.
 478   )
 479
 480 (defmacro elmo-make-fetch-strategy (entireness
 481                                     &optional
 482                                     use-cache
 483                                     save-cache
 484                                     cache-path)
 485 ;; Make elmo-message-fetching strategy.
 486 ;; ENTIRENESS is 'entire or 'section.
 487 ;; 'entire means fetch message entirely at once.
 488 ;; 'section means fetch message section by section.
 489 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 490 ;; existing cache is thrown away.
 491 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 492 ;; CACHE-PATH is the cache path to be used as a message cache file.
 493   (` (vector (, entireness)
 494              (, use-cache) (, save-cache) (, cache-path))))
 495
 496 (defmacro elmo-fetch-strategy-entireness (strategy)
 497   ;; Return entireness of STRATEGY.
 498   (` (aref (, strategy) 0)))
 499
 500 (defmacro elmo-fetch-strategy-use-cache (strategy)
 501   ;; Return use-cache of STRATEGY.
 502   (` (aref (, strategy) 1)))
 503
 504 (defmacro elmo-fetch-strategy-save-cache (strategy)
 505   ;; Return save-cache of STRATEGY.
 506   (` (aref (, strategy) 2)))
 507
 508 (defmacro elmo-fetch-strategy-cache-path (strategy)
 509   ;;  Return cache-path of STRATEGY.
 510   (` (aref (, strategy) 3)))
 511
 512 (luna-define-method elmo-find-fetch-strategy
 513   ((folder elmo-folder) entity &optional ignore-cache)
 514   (let (cache-file size message-id number)
 515     (setq size (elmo-msgdb-overview-entity-get-size entity))
 516     (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 517     (setq number (elmo-msgdb-overview-entity-get-number entity))
 518     (setq cache-file (elmo-file-cache-get message-id))
 519     (setq ignore-cache (or ignore-cache
 520                            (null (elmo-message-use-cache-p folder number))))
 521     (if (or ignore-cache
 522             (null (elmo-file-cache-status cache-file)))
 523         ;; No cache or ignore-cache.
 524         (if (and (not (elmo-folder-local-p folder))
 525                  elmo-message-fetch-threshold
 526                  (integerp size)
 527                  (>= size elmo-message-fetch-threshold)
 528                  (or (not elmo-message-fetch-confirm)
 529                      (not (prog1 (y-or-n-p
 530                                   (format "Fetch entire message(%dbytes)? "
 531                                           size))
 532                             (message "")))))
 533             ;; Don't fetch message at all.
 534             nil
 535           ;; Don't use existing cache and fetch entire message at once.
 536           (elmo-make-fetch-strategy
 537            'entire nil
 538            (elmo-message-use-cache-p folder number)
 539            (elmo-file-cache-path cache-file)))
 540       ;; Cache exists.
 541       (if (not ignore-cache)
 542           (elmo-make-fetch-strategy
 543            'entire
 544            ;; ...But ignore current section cache and re-fetch
 545            ;; if section cache.
 546            (not (eq (elmo-file-cache-status cache-file) 'section))
 547            ;; Save cache.
 548            (elmo-message-use-cache-p folder number)
 549            (elmo-file-cache-path cache-file))))))
 550
 551 (luna-define-method elmo-folder-list-messages-internal
 552   ((folder elmo-folder) &optional visible-only)
 553   t)
 554
 555 (defun elmo-folder-encache (folder numbers &optional unread)
 556   "Encache messages in the FOLDER with NUMBERS.
 557 If UNREAD is non-nil, messages are not marked as read."
 558   (dolist (number numbers)
 559     (elmo-message-encache folder number unread)))
 560
 561 (luna-define-generic elmo-message-encache (folder number &optional read)
 562   "Encache message in the FOLDER with NUMBER.
 563 If READ is non-nil, message is marked as read.")
 564
 565 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 566                                           &optional read)
 567   (elmo-message-fetch
 568    folder number
 569    (elmo-make-fetch-strategy 'entire
 570                              nil ;use-cache
 571                              t   ;save-cache
 572                              (elmo-file-cache-get-path
 573                               (elmo-message-field
 574                                folder number 'message-id)))
 575    nil nil (not read)))
 576
 577 (luna-define-generic elmo-message-fetch (folder number strategy
 578                                                 &optional
 579                                                 section
 580                                                 outbuf
 581                                                 unread)
 582   "Fetch a message and return as a string.
 583 FOLDER is the ELMO folder structure.
 584 NUMBER is the number of the message in the FOLDER.
 585 STRATEGY is the message fetching strategy.
 586 If optional argument SECTION is specified, only the SECTION of the message
 587 is fetched (if possible).
 588 If second optional argument OUTBUF is specified, fetched message is
 589 inserted to the buffer and returns t if fetch was ended successfully.
 590 If third optional argument UNREAD is non-nil, message is not marked as read.
 591 Returns non-nil if fetching was succeed.")
 592
 593 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 594                                                             number strategy
 595                                                             &optional
 596                                                             section
 597                                                             unread)
 598   "Fetch a message into current buffer with cache process.
 599 FOLDER is the ELMO folder structure.
 600 NUMBER is the number of the message in the FOLDER.
 601 STRATEGY is the message fetching strategy.
 602 If optional argument SECTION is specified, only the SECTION of the message
 603 is fetched (if possible).
 604 If second optional argument UNREAD is non-nil, message is not marked as read.
 605 Returns non-nil if fetching was succeed.")
 606
 607 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 608                                                          &optional
 609                                                          section
 610                                                          unread)
 611   "Fetch a message into current buffer.
 612 FOLDER is the ELMO folder structure.
 613 NUMBER is the number of the message in the FOLDER.
 614 STRATEGY is the message fetching strategy.
 615 If optional argument SECTION is specified, only the SECTION of the message
 616 is fetched (if possible).
 617 If second optional argument UNREAD is non-nil, message is not marked as read.
 618 Returns non-nil if fetching was succeed.")
 619
 620 (luna-define-generic elmo-message-fetch-field (folder number field)
 621   "Fetch a message field value.
 622 FOLDER is the ELMO folder structure.
 623 NUMBER is the number of the message in the FOLDER.
 624 FIELD is a symbol of the field name.")
 625
 626 (luna-define-generic elmo-message-folder (folder number)
 627   "Get primitive folder of the message.")
 628
 629 (luna-define-generic elmo-folder-process-crosspost (folder)
 630   "Process crosspost for FOLDER.
 631 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).")
 632
 633 (luna-define-generic elmo-folder-newsgroups (folder)
 634   "Return list of newsgroup name of FOLDER.")
 635
 636 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 637   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 638
 639 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 640   (if (listp condition)
 641       (or (elmo-folder-search-requires-msgdb-p-internal
 642            folder (nth 1 condition))
 643           (elmo-folder-search-requires-msgdb-p-internal
 644            folder (nth 2 condition)))
 645     (and (not (string= (elmo-filter-key condition) "last"))
 646          (not (string= (elmo-filter-key condition) "first")))))
 647
 648 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 649                                                          condition)
 650   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 651
 652 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 653   nil)
 654
 655 (luna-define-method elmo-folder-open ((folder elmo-folder)
 656                                       &optional load-msgdb)
 657   (elmo-generic-folder-open folder load-msgdb))
 658
 659 (defun elmo-generic-folder-open (folder load-msgdb)
 660   (let ((inhibit-quit t))
 661     (if load-msgdb (elmo-folder-msgdb folder))
 662     (elmo-folder-set-killed-list-internal
 663      folder
 664      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 665   (elmo-folder-open-internal folder))
 666
 667 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 668   nil ; default is do nothing.
 669   )
 670
 671 (luna-define-method elmo-folder-check ((folder elmo-folder))
 672   nil) ; default is noop.
 673
 674 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 675   (elmo-generic-folder-commit folder))
 676
 677 (defun elmo-generic-folder-commit (folder)
 678   (when (elmo-folder-persistent-p folder)
 679     (when (elmo-folder-message-modified-internal folder)
 680       (elmo-msgdb-overview-save
 681        (elmo-folder-msgdb-path folder)
 682        (elmo-msgdb-get-overview (elmo-folder-msgdb folder)))
 683       (elmo-msgdb-number-save
 684        (elmo-folder-msgdb-path folder)
 685        (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))
 686       (elmo-folder-set-info-max-by-numdb
 687        folder
 688        (elmo-folder-list-messages folder nil 'in-msgdb))
 689       (elmo-folder-set-message-modified folder nil)
 690       (elmo-msgdb-killed-list-save
 691        (elmo-folder-msgdb-path folder)
 692        (elmo-folder-killed-list-internal folder)))
 693     (when (elmo-folder-mark-modified-internal folder)
 694       (elmo-msgdb-mark-save
 695        (elmo-folder-msgdb-path folder)
 696        (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
 697       (elmo-folder-set-mark-modified-internal folder nil))))
 698
 699 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 700   ;; do nothing.
 701   )
 702
 703 (luna-define-method elmo-folder-close ((folder elmo-folder))
 704   (elmo-generic-folder-close folder)
 705   (elmo-folder-close-internal folder))
 706
 707 (defun elmo-generic-folder-close (folder)
 708   (elmo-folder-commit folder)
 709   (elmo-folder-set-msgdb-internal folder nil)
 710   (elmo-folder-set-killed-list-internal folder nil))
 711
 712 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 713   t) ; default is plugged.
 714
 715 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 716                                              &optional add)
 717   nil) ; default is do nothing.
 718
 719 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 720   nil) ; default is no flag.
 721
 722 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 723   (elmo-folder-persistent-internal folder))
 724
 725 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 726   nil) ; default is not creatable.
 727
 728 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 729   nil) ; default is not writable.
 730
 731 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 732   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 733                              (elmo-folder-name-internal folder)))
 734     (elmo-msgdb-delete-path folder)
 735     t))
 736
 737 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 738   (let* ((new-folder (elmo-make-folder new-name)))
 739     (unless (eq (elmo-folder-type-internal folder)
 740                 (elmo-folder-type-internal new-folder))
 741       (error "Not same folder type"))
 742     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 743             (elmo-folder-exists-p new-folder))
 744         (error "Already exists folder: %s" new-name))
 745     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 746     (elmo-msgdb-rename-path folder new-folder)))
 747
 748 (defsubst elmo-folder-search-fast (folder condition numbers)
 749   "Search and return list of message numbers.
 750 Return t if CONDITION is not treated.
 751 FOLDER is the ELMO folder structure.
 752 CONDITION is a condition structure for searching.
 753 NUMBERS is a list of message numbers, messages are searched from the list."
 754   (if (and numbers
 755            (vectorp condition))
 756       (cond
 757        ((string= (elmo-filter-key condition) "flag")
 758         (let ((msgdb (elmo-folder-msgdb folder)))
 759           ;; msgdb should be synchronized at this point.
 760           (cond
 761            ((string= (elmo-filter-value condition) "unread")
 762             (elmo-folder-list-unreads folder))
 763            ((string= (elmo-filter-value condition) "important")
 764             (elmo-folder-list-importants folder))
 765            ((string= (elmo-filter-value condition) "answered")
 766             (elmo-folder-list-answereds folder))
 767            ((string= (elmo-filter-value condition) "digest")
 768             (nconc (elmo-folder-list-unreads folder)
 769                    (elmo-folder-list-importants folder)))
 770            ((string= (elmo-filter-value condition) "any")
 771             (nconc (elmo-folder-list-unreads folder)
 772                    (elmo-folder-list-importants folder)
 773                    (elmo-folder-list-answereds folder))))))
 774        ((member (elmo-filter-key condition) '("first" "last"))
 775         (let ((len (length numbers))
 776               (lastp (string= (elmo-filter-key condition) "last"))
 777               (value (string-to-number (elmo-filter-value condition))))
 778           (when (eq (elmo-filter-type condition) 'unmatch)
 779             (setq lastp (not lastp)
 780                   value  (- len value)))
 781           (if lastp
 782               (nthcdr (max (- len value) 0) numbers)
 783             (when (> value 0)
 784               (let* ((numbers (copy-sequence numbers))
 785                      (last (nthcdr (1- value) numbers)))
 786                 (when last
 787                   (setcdr last nil))
 788                 numbers)))))
 789        (t
 790         t))
 791     t))
 792
 793 (luna-define-method elmo-folder-search ((folder elmo-folder)
 794                                         condition
 795                                         &optional numbers)
 796   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 797         results)
 798     (if (listp (setq results (elmo-folder-search-fast folder
 799                                                       condition
 800                                                       numbers)))
 801         results
 802       (let ((msgdb (elmo-folder-msgdb folder))
 803             (len (length numbers))
 804             matched)
 805         (when (> len elmo-display-progress-threshold)
 806           (elmo-progress-set 'elmo-folder-search len "Searching..."))
 807         (unwind-protect
 808             (dolist (number numbers)
 809               (let (result)
 810                 (setq result (elmo-msgdb-match-condition
 811                               msgdb
 812                               condition
 813                               number
 814                               numbers))
 815                 (when (elmo-filter-condition-p result)
 816                   (setq result (elmo-message-match-condition
 817                                 folder
 818                                 number
 819                                 condition
 820                                 numbers)))
 821                 (when result
 822                   (setq matched (cons number matched))))
 823               (elmo-progress-notify 'elmo-folder-search))
 824           (elmo-progress-clear 'elmo-folder-search))
 825         (nreverse matched)))))
 826
 827 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 828                                                   number condition
 829                                                   numbers)
 830   (let ((filename (cond
 831                    ((elmo-message-file-name folder number))
 832                    ((let* ((cache (elmo-file-cache-get
 833                                    (elmo-message-field folder number
 834                                                        'message-id)))
 835                            (cache-path (elmo-file-cache-path cache)))
 836                       (when (and cache-path
 837                                  (not (elmo-cache-path-section-p cache-path)))
 838                         cache-path))))))
 839     (when (and filename
 840                (file-readable-p filename))
 841       (with-temp-buffer
 842         (insert-file-contents-as-binary filename)
 843         (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 844         ;; Should consider charset?
 845         (decode-mime-charset-region (point-min) (point-max) elmo-mime-charset)
 846         (elmo-buffer-field-condition-match condition number numbers)))))
 847
 848 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 849   nil) ; default is noop.
 850
 851 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 852   nil) ; default is noop.
 853
 854 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 855   nil) ; default is not file.
 856
 857 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 858   nil) ; default is not number.
 859
 860 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 861   nil) ; default is not make temp file.
 862
 863 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 864                                                    number)
 865   nil) ; default is no name.
 866
 867 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 868   t)   ; default is local.
 869
 870 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 871   t)
 872
 873 ;;; Folder info
 874 ;; Folder info is a message number information cache (hashtable)
 875 (defsubst elmo-folder-get-info (folder &optional hashtb)
 876   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 877   (elmo-get-hash-val (elmo-folder-name-internal folder)
 878                      (or hashtb elmo-folder-info-hashtb)))
 879
 880 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 881   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 882   (let ((info (elmo-folder-get-info folder)))
 883     (when info
 884       (or new     (setq new     (nth 0 info)))
 885       (or unread  (setq unread  (nth 1 info)))
 886       (or numbers (setq numbers (nth 2 info)))
 887       (or max     (setq max     (nth 3 info))))
 888     (elmo-set-hash-val (elmo-folder-name-internal folder)
 889                        (list new unread numbers max)
 890                        elmo-folder-info-hashtb)))
 891
 892 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 893   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 894   (elmo-folder-set-info-hashtb
 895    folder
 896    (or (car (sort numbers '>)) 0)
 897    nil ;;(length num-db)
 898    ))
 899
 900 (defun elmo-folder-get-info-max (folder)
 901   "Return max number of FODLER from folder info."
 902   (nth 3 (elmo-folder-get-info folder)))
 903
 904 (defun elmo-folder-get-info-length (folder)
 905   "Return length of FODLER from folder info."
 906   (nth 2 (elmo-folder-get-info folder)))
 907
 908 (defun elmo-folder-get-info-unread (folder)
 909   "Return unread of FODLER from folder info."
 910   (nth 1 (elmo-folder-get-info folder)))
 911
 912 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 913   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 914   (let* ((hashtb (or hashtb
 915                      (elmo-make-hash (length info-alist)))))
 916     (mapcar
 917      (lambda (x)
 918        (let ((info (cadr x)))
 919          (and (intern-soft (car x) hashtb)
 920               (elmo-set-hash-val (car x)
 921                                  (list (nth 2 info)   ;; new
 922                                        (nth 3 info)   ;; unread
 923                                        (nth 1 info)   ;; length
 924                                        (nth 0 info))  ;; max
 925                                  hashtb))))
 926      info-alist)
 927     (setq elmo-folder-info-hashtb hashtb)))
 928
 929 (defsubst elmo-diff-new (diff)
 930   (car diff))
 931
 932 (defsubst elmo-diff-unread (diff)
 933   (when (consp (cdr diff))
 934     (nth 1 diff)))
 935
 936 (defsubst elmo-diff-all (diff)
 937   (if (consp (cdr diff))
 938       (nth 2 diff)
 939     (cdr diff)))
 940
 941 (defsubst elmo-strict-folder-diff (folder)
 942   "Return folder diff information strictly from FOLDER."
 943   (let ((in-db (sort (elmo-msgdb-list-messages (elmo-folder-msgdb folder))
 944                      '<))
 945         (in-folder  (elmo-folder-list-messages folder))
 946         append-list delete-list diff)
 947     (cons (if (equal in-folder in-db)
 948               0
 949             (setq diff (elmo-list-diff in-folder in-db nil))
 950             (setq append-list (car diff))
 951             (setq delete-list (cadr diff))
 952             (if append-list
 953                 (length append-list)
 954               (if delete-list
 955                   (- 0 (length delete-list))
 956                 0)))
 957           (length in-folder))))
 958
 959 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 960   (elmo-generic-folder-diff folder))
 961
 962 (defun elmo-generic-folder-diff (folder)
 963   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 964                                 elmo-strict-diff-folder-list)
 965       (elmo-strict-folder-diff folder)
 966     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 967           (in-folder (elmo-folder-status folder))
 968           (in-db t)
 969           unsync messages
 970           in-db-max)
 971       (if (not cached-in-db-max)
 972           (let ((number-list (elmo-folder-list-messages folder
 973                                                         nil 'in-msgdb)))
 974             ;; No info-cache.
 975             (setq in-db (sort number-list '<))
 976             (setq in-db-max (or (nth (max 0 (1- (length in-db))) in-db)
 977                                 0))
 978             (elmo-folder-set-info-hashtb folder in-db-max nil))
 979         (setq in-db-max cached-in-db-max))
 980       (setq unsync (if (and in-db (car in-folder))
 981                        (- (car in-folder) in-db-max)
 982                      (if (and in-folder (null in-db))
 983                          (cdr in-folder)
 984                        (car in-folder))))
 985       (setq messages (cdr in-folder))
 986       (if (and unsync messages (> unsync messages))
 987           (setq unsync messages))
 988       (cons (or unsync 0) (or messages 0)))))
 989
 990 (defvar elmo-folder-diff-async-callback nil)
 991 (defvar elmo-folder-diff-async-callback-data nil)
 992
 993 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 994   (and elmo-folder-diff-async-callback
 995        (funcall elmo-folder-diff-async-callback
 996                 folder
 997                 (elmo-folder-diff folder))))
 998
 999 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
1000   (list folder))
1001
1002 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
1003   (eq (elmo-folder-type-internal folder) type))
1004
1005 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
1006                                                  src-folder
1007                                                  numbers
1008                                                  &optional
1009                                                  same-number)
1010   (elmo-generic-folder-append-messages folder src-folder numbers
1011                                        same-number))
1012
1013 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1014                                                    same-number)
1015   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
1016         unseen table flags
1017         succeed-numbers failure cache id)
1018     (setq table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1019     (with-temp-buffer
1020       (set-buffer-multibyte nil)
1021       (while numbers
1022         (setq failure nil
1023               id (and src-msgdb-exists
1024                       (elmo-message-field src-folder (car numbers)
1025                                           'message-id))
1026               flags (elmo-message-flags src-folder (car numbers)))
1027         (condition-case nil
1028             (setq cache (elmo-file-cache-get id)
1029                   failure
1030                   (not
1031                    (and
1032                     (elmo-message-fetch
1033                      src-folder (car numbers)
1034                      (if (elmo-folder-plugged-p src-folder)
1035                          (elmo-make-fetch-strategy
1036                           'entire 'maybe nil
1037                           (and cache (elmo-file-cache-path cache)))
1038                        (or (and elmo-enable-disconnected-operation
1039                                 cache
1040                                 (eq (elmo-file-cache-status cache) 'entire)
1041                                 (elmo-make-fetch-strategy
1042                                  'entire t nil
1043                                  (elmo-file-cache-path cache)))
1044                            (error "Unplugged")))
1045                      nil (current-buffer)
1046                      'unread)
1047                     (> (buffer-size) 0)
1048                     (elmo-folder-append-buffer
1049                      folder
1050                      flags
1051                      (if same-number (car numbers))))))
1052           (error (setq failure t)))
1053         ;; FETCH & APPEND finished
1054         (unless failure
1055           (when id
1056             (elmo-flag-table-set table id flags))
1057           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1058         (elmo-progress-notify 'elmo-folder-move-messages)
1059         (setq numbers (cdr numbers)))
1060       (when (elmo-folder-persistent-p folder)
1061         (elmo-flag-table-save (elmo-folder-msgdb-path folder) table))
1062       succeed-numbers)))
1063
1064 ;; Arguments should be reduced.
1065 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1066                                              &optional
1067                                              no-delete
1068                                              same-number)
1069   (save-excursion
1070     (let* ((messages msgs)
1071            (elmo-inhibit-display-retrieval-progress t)
1072            (len (length msgs))
1073            succeeds i result)
1074       (if (eq dst-folder 'null)
1075           (setq succeeds messages)
1076         (unless (elmo-folder-writable-p dst-folder)
1077           (error "move: %d is not writable"
1078                  (elmo-folder-name-internal dst-folder)))
1079         (when messages
1080           ;; src is already opened.
1081           (elmo-folder-open-internal dst-folder)
1082           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1083                                                               src-folder
1084                                                               messages
1085                                                               same-number))
1086             (error "move: append message to %s failed"
1087                    (elmo-folder-name-internal dst-folder)))
1088           (elmo-folder-close dst-folder)))
1089       (if (and (not no-delete) succeeds)
1090           (progn
1091             (if (and (elmo-folder-delete-messages src-folder succeeds)
1092                      (elmo-folder-detach-messages src-folder succeeds))
1093                 (setq result t)
1094               (message "move: delete messages from %s failed."
1095                        (elmo-folder-name-internal src-folder))
1096               (setq result nil))
1097             result)
1098         (if no-delete
1099             (progn
1100               ;; (message "Copying messages...done")
1101               t)
1102           (if (eq len 0)
1103               (message "No message was moved.")
1104             (message "Moving messages failed.")
1105             nil ; failure
1106             ))))))
1107
1108 (defun elmo-folder-msgdb-path (folder)
1109   "Return the msgdb path for FOLDER."
1110   (or (elmo-folder-path-internal folder)
1111       (elmo-folder-set-path-internal
1112        folder
1113        (elmo-folder-expand-msgdb-path folder))))
1114
1115 (luna-define-generic elmo-message-cached-p (folder number)
1116   "Return non-nil if the message is cached.")
1117
1118 (luna-define-method elmo-message-cached-p ((folder elmo-folder) number)
1119   (elmo-msgdb-get-cached (elmo-folder-msgdb folder) number))
1120
1121 (defun elmo-message-accessible-p (folder number)
1122   "Get accessibility of the message.
1123 Return non-nil when message is accessible."
1124   (or (elmo-folder-plugged-p folder)
1125       (elmo-folder-local-p folder)
1126       (elmo-message-cached-p folder number)))
1127
1128 (luna-define-generic elmo-message-set-cached (folder number cached)
1129   "Set cache status of the message in the msgdb.
1130 FOLDER is the ELMO folder structure.
1131 NUMBER is a number of the message.
1132 If CACHED is t, message is set as cached.")
1133
1134 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1135                                              number cached)
1136   (when (elmo-msgdb-set-cached (elmo-folder-msgdb folder)
1137                                number
1138                                cached
1139                                (elmo-message-use-cache-p folder number))
1140     (elmo-folder-set-mark-modified-internal folder t)))
1141
1142 (defun elmo-message-copy-entity (entity)
1143   ;;
1144   (elmo-msgdb-copy-overview-entity entity))
1145
1146 (defun elmo-message-entity-set-number (entity number)
1147   (elmo-msgdb-overview-entity-set-number entity number))
1148
1149 (luna-define-generic elmo-message-entity (folder key)
1150   "Return the message-entity structure which matches to the KEY.
1151 KEY is a number or a string.
1152 A number is for message number in the FOLDER.
1153 A string is for message-id of the message.")
1154
1155 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1156   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1157
1158 (luna-define-generic elmo-message-entity-parent (folder entity)
1159   "Return the parent message-entity structure in the FOLDER.
1160 ENTITY is the message-entity to get the parent.")
1161
1162 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1163   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1164
1165 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1166 (def-edebug-spec elmo-folder-do-each-message-entity
1167   ((symbolp form &rest form) &rest form))
1168
1169 (defsubst elmo-folder-list-message-entities (folder)
1170   ;; List all message entities in the FOLDER.
1171   (mapcar
1172    (lambda (number) (elmo-message-entity folder number))
1173    (elmo-folder-list-messages folder nil t))) ; XXX killed-list is not used.
1174
1175 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1176   "Iterator for message entity in the folder.
1177 \(elmo-folder-do-each-message-entity \(entity folder\)
1178  ... do the process using entity...
1179 \)"
1180   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1181      ,@form))
1182
1183 (defmacro elmo-message-entity-number (entity)
1184   `(elmo-msgdb-overview-entity-get-number ,entity))
1185
1186 (defun elmo-message-entity-field (entity field &optional decode)
1187   "Get message entity field value.
1188 ENTITY is the message entity structure obtained by `elmo-message-entity'.
1189 FIELD is the symbol of the field name.
1190 if optional DECODE is non-nil, returned value is decoded."
1191   (elmo-msgdb-message-entity-field entity field decode))
1192
1193 (defun elmo-message-entity-set-field (entity field value)
1194   "Set message entity field value.
1195 ENTITY is the message entity structure.
1196 FIELD is the symbol of the field name.
1197 VALUE is the field value (raw)."
1198   (elmo-msgdb-message-entity-set-field entity field value))
1199
1200 (luna-define-generic elmo-folder-count-flags (folder)
1201   "Count flagged message number in the msgdb of the FOLDER.
1202 Return a list of numbers (`new' `unread' `answered')")
1203
1204 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1205   (let ((new 0)
1206         (unreads 0)
1207         (answered 0)
1208         flags)
1209     (dolist (number (elmo-folder-list-messages folder 'visible 'in-msgdb))
1210       (setq flags (elmo-message-flags folder number))
1211       (cond
1212        ((memq 'new flags)
1213         (incf new))
1214        ((memq 'unread flags)
1215         (incf unreads))
1216        ((memq 'answered flags)
1217         (incf answered))))
1218     (list new unreads answered)))
1219
1220 (luna-define-generic elmo-message-flags (folder number)
1221   "Return a list of flags.
1222 FOLDER is a ELMO folder structure.
1223 NUMBER is a number of the message.")
1224
1225 (luna-define-method elmo-message-flags ((folder elmo-folder) number)
1226   (elmo-msgdb-flags (elmo-folder-msgdb folder) number))
1227
1228 (defsubst elmo-message-flagged-p (folder number flag)
1229   "Return non-nil if the message is set FLAG.
1230 FOLDER is a ELMO folder structure.
1231 NUMBER is a message number to test."
1232   (let ((cur-flags (elmo-message-flags folder number)))
1233     (case flag
1234       (read
1235        (not (memq 'unread cur-flags)))
1236       (t
1237        (memq flag cur-flags)))))
1238
1239 (defun elmo-message-set-flag (folder number flag)
1240   "Set message flag.
1241 FOLDER is a ELMO folder structure.
1242 NUMBER is a message number to set flag.
1243
1244 FLAG is a symbol which is one of the following:
1245   `unread'    (set the message as unread)
1246   `answered'  (set the message as answered)
1247   `important' (set the message as important)
1248 'sugar' flag:
1249   `read'      (remove new and unread flags)")
1250
1251 (defun elmo-message-unset-flag (folder number flag)
1252   "Unset message flag.
1253 FOLDER is a ELMO folder structure.
1254 NUMBER is a message number to set flag.
1255
1256 FLAG is a symbol which is one of the following:
1257   `unread'    (remove unread and new flag)
1258   `answered'  (remove answered flag)
1259   `important' (remove important flag)
1260 'sugar' flag:
1261   `read'      (set unread flag)")
1262
1263 (luna-define-generic elmo-message-field (folder number field)
1264   "Get message field value in the msgdb.
1265 FOLDER is the ELMO folder structure.
1266 NUMBER is a number of the message.
1267 FIELD is a symbol of the field.")
1268
1269 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1270   (when (zerop (elmo-folder-length folder))
1271     (error "Cannot treat this folder correctly."))
1272   (elmo-msgdb-get-field (elmo-folder-msgdb folder) number field))
1273
1274 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1275   nil) ; default is not use cache.
1276
1277 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1278   folder) ; default is folder
1279
1280 (luna-define-method elmo-folder-unmark-important ((folder elmo-folder)
1281                                                   numbers
1282                                                   &optional ignore-flags)
1283   (when (elmo-folder-msgdb-internal folder)
1284     (dolist (number numbers)
1285       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1286                              folder
1287                              number
1288                              'important))))
1289
1290 (luna-define-method elmo-folder-mark-as-important ((folder elmo-folder)
1291                                                    numbers
1292                                                    &optional ignore-flags)
1293   (when (elmo-folder-msgdb-internal folder)
1294     (dolist (number numbers)
1295       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1296                            folder
1297                            number
1298                            'important))))
1299
1300 (luna-define-method elmo-folder-unmark-read ((folder elmo-folder)
1301                                              numbers
1302                                              &optional ignore-flags)
1303   (when (elmo-folder-msgdb-internal folder)
1304     (dolist (number numbers)
1305       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1306                              folder
1307                              number
1308                              'read))))
1309
1310 (luna-define-method elmo-folder-mark-as-read ((folder elmo-folder)
1311                                               numbers
1312                                               &optional ignore-flag)
1313   (when (elmo-folder-msgdb-internal folder)
1314     (dolist (number numbers)
1315       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1316                            folder
1317                            number
1318                            'read))))
1319
1320 (luna-define-method elmo-folder-unmark-answered ((folder elmo-folder) numbers)
1321   (when (elmo-folder-msgdb-internal folder)
1322     (dolist (number numbers)
1323       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1324                              folder
1325                              number
1326                              'answered))))
1327
1328 (luna-define-method elmo-folder-mark-as-answered ((folder elmo-folder) numbers)
1329   (when (elmo-folder-msgdb-internal folder)
1330     (dolist (number numbers)
1331       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1332                            folder
1333                            number
1334                            'answered))))
1335
1336 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1337   ;; Do nothing.
1338   )
1339
1340 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1341 ;;                                                             &optional
1342 ;;                                                             flag-table)
1343 ;;  "Append ENTITY to the folder.")
1344
1345 (defsubst elmo-folder-append-msgdb (folder append-msgdb)
1346   (if append-msgdb
1347       (let ((duplicates (elmo-msgdb-merge folder append-msgdb)))
1348         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1349                    'hide)
1350                ;; Let duplicates be a temporary killed message.
1351                (elmo-folder-kill-messages folder duplicates)
1352                ;; Should be mark as read.
1353                (elmo-folder-mark-as-read folder duplicates))
1354               ((eq (elmo-folder-process-duplicates-internal folder)
1355                    'read)
1356                ;; Mark as read duplicates.
1357                (elmo-folder-mark-as-read folder duplicates))
1358               (t
1359                ;; Do nothing.
1360                (setq duplicates nil)))
1361         (length duplicates))
1362     0))
1363
1364 (defun elmo-folder-confirm-appends (appends)
1365   (let ((len (length appends))
1366         in)
1367     (if (and elmo-folder-update-threshold
1368              (> len elmo-folder-update-threshold)
1369              elmo-folder-update-confirm)
1370         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1371             appends
1372           (setq in elmo-folder-update-threshold)
1373           (catch 'end
1374             (while t
1375               (setq in (read-from-minibuffer "Update number: "
1376                                              (int-to-string in))
1377                     in (string-to-int in))
1378               (if (< len in)
1379                   (throw 'end len))
1380               (if (y-or-n-p (format
1381                              "%d messages are killed (not appeared). OK? "
1382                              (max (- len in) 0)))
1383                   (throw 'end in))))
1384           (nthcdr (max (- len in) 0) appends))
1385       (if (and elmo-folder-update-threshold
1386                (> len elmo-folder-update-threshold)
1387                (not elmo-folder-update-confirm))
1388           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1389         appends))))
1390
1391 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1392                                         number strategy
1393                                         &optional
1394                                         section
1395                                         outbuf
1396                                         unread)
1397   (if outbuf
1398       (with-current-buffer outbuf
1399         (erase-buffer)
1400         (elmo-message-fetch-with-cache-process folder number
1401                                                strategy section unread))
1402     (with-temp-buffer
1403       (elmo-message-fetch-with-cache-process folder number
1404                                              strategy section unread)
1405       (buffer-string))))
1406
1407 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1408                                                            number strategy
1409                                                            &optional
1410                                                            section unread)
1411   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1412         (method-priorities
1413          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1414                 '(entity cache))
1415                ((elmo-fetch-strategy-use-cache strategy)
1416                 '(cache entity))
1417                (t
1418                 '(entity))))
1419         result err)
1420     (while (and method-priorities
1421                 (null result))
1422       (setq result
1423             (case (car method-priorities)
1424               (cache
1425                (elmo-file-cache-load cache-path section))
1426               (entity
1427                (when (and (condition-case error
1428                               (elmo-message-fetch-internal folder number
1429                                                            strategy
1430                                                            section
1431                                                            unread)
1432                             (error (setq err error) nil))
1433                           (> (buffer-size) 0))
1434                  (elmo-delete-cr-buffer)
1435                  (when (and (elmo-fetch-strategy-save-cache strategy)
1436                             cache-path)
1437                    (elmo-file-cache-save cache-path section))
1438                  t)))
1439             method-priorities (cdr method-priorities)))
1440     (or result
1441         (and err (signal (car err) (cdr err))))))
1442
1443 (defun elmo-folder-kill-messages-before (folder msg)
1444   (elmo-folder-set-killed-list-internal
1445    folder
1446    (list (cons 1 msg))))
1447
1448 (defun elmo-folder-kill-messages (folder numbers)
1449   "Kill(hide) messages in the FOLDER with NUMBERS."
1450   (elmo-folder-set-killed-list-internal
1451    folder
1452    (elmo-number-set-append-list (elmo-folder-killed-list-internal
1453                                  folder) numbers)))
1454
1455
1456 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1457                                        &optional keep-killed)
1458   (unless keep-killed
1459     (elmo-folder-set-killed-list-internal folder nil))
1460   (elmo-folder-set-msgdb-internal folder (elmo-msgdb-clear)))
1461
1462 (luna-define-generic elmo-folder-synchronize (folder
1463                                               &optional
1464                                               disable-killed
1465                                               ignore-msgdb
1466                                               no-check)
1467   "Synchronize the folder data to the newest status.
1468 FOLDER is the ELMO folder structure.
1469
1470 If optional DISABLE-KILLED is non-nil, killed messages are also synchronized.
1471 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1472 flag status.
1473 If NO-CHECK is non-nil, rechecking folder is skipped.
1474 Return a list of a cross-posted message number.
1475 If update process is interrupted, return nil.")
1476
1477 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1478                                              &optional
1479                                              disable-killed
1480                                              ignore-msgdb
1481                                              no-check)
1482   (let ((killed-list (elmo-folder-killed-list-internal folder))
1483         (before-append t)
1484         old-msgdb diff diff-2 delete-list new-list new-msgdb mark
1485         flag-table crossed after-append)
1486     (setq old-msgdb (elmo-folder-msgdb folder))
1487     (setq flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1488     (when ignore-msgdb
1489       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1490       (elmo-folder-clear folder (not disable-killed)))
1491     (unless no-check (elmo-folder-check folder))
1492     (condition-case nil
1493         (progn
1494           (message "Checking folder diff...")
1495           (setq diff (elmo-list-diff (elmo-folder-list-messages
1496                                       folder
1497                                       (not disable-killed))
1498                                      (elmo-folder-list-messages
1499                                       folder
1500                                       (not disable-killed)
1501                                       'in-msgdb)))
1502           (message "Checking folder diff...done")
1503           (setq new-list (elmo-folder-confirm-appends (car diff)))
1504           ;; Set killed list as ((1 . MAX-OF-DISAPPEARED))
1505           (when (and (not (eq (length (car diff))
1506                               (length new-list)))
1507                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1508             (elmo-folder-kill-messages-before folder
1509                                               (nth (- (length (car diff-2)) 1)
1510                                                    (car diff-2))))
1511           (setq delete-list (cadr diff))
1512           (if (or (equal diff '(nil nil))
1513                   (equal diff '(nil))
1514                   (and (eq (length (car diff)) 0)
1515                        (eq (length (cadr diff)) 0)))
1516               (progn
1517                 (elmo-folder-update-number folder)
1518                 (elmo-folder-process-crosspost folder)
1519                 0 ; no updates.
1520                 )
1521             (when delete-list
1522               (elmo-folder-detach-messages folder delete-list))
1523             (when new-list
1524               (elmo-msgdb-out-of-date-messages (elmo-folder-msgdb folder))
1525               (setq new-msgdb (elmo-folder-msgdb-create
1526                                folder new-list flag-table))
1527               ;; Clear flag-table
1528               (if (elmo-folder-persistent-p folder)
1529                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1530                                         nil))
1531               (setq before-append nil)
1532               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1533               ;; process crosspost.
1534               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).
1535               (elmo-folder-process-crosspost folder)
1536               (elmo-folder-set-message-modified folder t)
1537               (elmo-folder-set-mark-modified-internal folder t))
1538             ;; return value.
1539             (or crossed 0)))
1540       (quit
1541        ;; Resume to the original status.
1542        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1543        (elmo-folder-set-killed-list-internal folder killed-list)
1544        nil))))
1545
1546 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1547   "Remove messages with NUMBERS from MSGDB.")
1548
1549 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1550                                                  numbers)
1551   (elmo-msgdb-delete-messages (elmo-folder-msgdb folder) numbers))
1552
1553 (luna-define-generic elmo-folder-length (folder)
1554   "Return number of messages in the FOLDER.")
1555
1556 (luna-define-method elmo-folder-length ((folder elmo-folder))
1557   (if (elmo-folder-msgdb-internal folder)
1558       (elmo-msgdb-length (elmo-folder-msgdb folder))
1559     0))
1560
1561 (defun elmo-msgdb-load (folder &optional silent)
1562   (unless silent
1563     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1564   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1565     (elmo-folder-set-info-max-by-numdb
1566      folder
1567      (elmo-msgdb-list-messages msgdb))
1568     (unless silent
1569       (message "Loading msgdb for %s...done"
1570                (elmo-folder-name-internal folder)))
1571     msgdb))
1572
1573 (defun elmo-msgdb-delete-path (folder)
1574   (let ((path (elmo-folder-msgdb-path folder)))
1575     (if (file-directory-p path)
1576         (elmo-delete-directory path t))))
1577
1578 (defun elmo-msgdb-rename-path (old-folder new-folder)
1579   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1580          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1581          (new-dir (directory-file-name (file-name-directory new))))
1582     (if (not (file-directory-p old))
1583         ()
1584       (if (file-exists-p new)
1585           (error "Already exists directory: %s" new)
1586         (if (not (file-exists-p new-dir))
1587             (elmo-make-directory new-dir))
1588         (rename-file old new)))))
1589
1590 (defun elmo-setup-subscribed-newsgroups (groups)
1591   "Setup subscribed newsgroups.
1592 GROUPS is a list of newsgroup name string.
1593 Return a hashtable for newsgroups."
1594   (let ((hashtb (or elmo-newsgroups-hashtb
1595                     (setq elmo-newsgroups-hashtb
1596                           (elmo-make-hash (length groups))))))
1597     (dolist (group groups)
1598       (or (elmo-get-hash-val group hashtb)
1599           (elmo-set-hash-val group nil hashtb)))
1600     (setq elmo-newsgroups-hashtb hashtb)))
1601
1602 (defvar elmo-crosspost-message-alist-modified nil)
1603 (defun elmo-crosspost-message-alist-load ()
1604   "Load crosspost message alist."
1605   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1606   (setq elmo-crosspost-message-alist-modified nil))
1607
1608 (defun elmo-crosspost-message-alist-save ()
1609   "Save crosspost message alist."
1610   (when elmo-crosspost-message-alist-modified
1611     (let ((alist elmo-crosspost-message-alist)
1612           newsgroups)
1613       (while alist
1614         (setq newsgroups
1615               (elmo-delete-if
1616                '(lambda (x)
1617                   (not (intern-soft x elmo-newsgroups-hashtb)))
1618                (nth 1 (car alist))))
1619         (if newsgroups
1620             (setcar (cdar alist) newsgroups)
1621           (setq elmo-crosspost-message-alist
1622                 (delete (car alist) elmo-crosspost-message-alist)))
1623         (setq alist (cdr alist)))
1624       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1625       (setq elmo-crosspost-message-alist-modified nil))))
1626
1627 (defun elmo-folder-make-temporary-directory (folder)
1628   ;; Make a temporary directory for FOLDER.
1629   (let ((temp-dir (make-temp-name
1630                    (concat
1631                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1632                     "elmo"))))
1633     (elmo-make-directory temp-dir)
1634     temp-dir))
1635
1636 (defun elmo-init ()
1637   "Initialize ELMO module."
1638   (elmo-crosspost-message-alist-load)
1639   (elmo-resque-obsolete-variables)
1640   (elmo-dop-queue-load))
1641
1642 (defun elmo-quit ()
1643   "Quit and cleanup ELMO."
1644   (elmo-crosspost-message-alist-save)
1645   (elmo-dop-queue-save)
1646   ;; Not implemented yet.
1647   (let ((types elmo-folder-type-alist)
1648         class)
1649     (while types
1650       (setq class
1651             (luna-find-class
1652              (intern (format "elmo-%s-folder" (symbol-name (cdr (car types)))))))
1653       ;; Call all folder's `elmo-quit' method.
1654       (if class
1655           (dolist (func (luna-class-find-functions class 'elmo-quit))
1656             (funcall func nil)))
1657       (setq types (cdr types)))))
1658
1659 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1660                                                  new-folder)
1661   (error "Cannot rename %s folder"
1662          (symbol-name (elmo-folder-type-internal folder))))
1663
1664 ;;; Define folders.
1665 (elmo-define-folder ?% 'imap4)
1666 (elmo-define-folder ?-  'nntp)
1667 (elmo-define-folder ?\+ 'localdir)
1668 (elmo-define-folder ?\* 'multi)
1669 (elmo-define-folder ?\/ 'filter)
1670 (elmo-define-folder ?\$ 'archive)
1671 (elmo-define-folder ?&  'pop3)
1672 (elmo-define-folder ?=  'localnews)
1673 (elmo-define-folder ?|  'pipe)
1674 (elmo-define-folder ?.  'maildir)
1675 (elmo-define-folder ?'  'internal)
1676 (elmo-define-folder ?\[  'nmz)
1677 (elmo-define-folder ?@  'shimbun)
1678
1679 ;;; Obsolete variables.
1680 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1681                                'elmo-imap4-default-mailbox)
1682 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1683                                'elmo-imap4-default-server)
1684 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1685                                'elmo-imap4-default-authenticate-type)
1686 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1687                                'elmo-imap4-default-user)
1688 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1689                                'elmo-imap4-default-port)
1690 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1691                                'elmo-imap4-default-stream-type)
1692 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1693                                'elmo-nntp-default-server)
1694 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1695                                'elmo-nntp-default-user)
1696 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1697                                'elmo-nntp-default-port)
1698 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1699                                'elmo-nntp-default-stream-type)
1700 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1701                                'elmo-pop3-default-server)
1702 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1703                                'elmo-pop3-default-user)
1704 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1705                                'elmo-pop3-default-authenticate-type)
1706 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1707                                'elmo-pop3-default-port)
1708 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1709                                'elmo-pop3-default-stream-type)
1710 (elmo-define-obsolete-variable 'elmo-cache-dirname
1711                                'elmo-cache-directory)
1712 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1713                                'elmo-msgdb-directory)
1714
1715 ;; Obsolete functions.
1716 ;; 2001-12-11: *-dir -> *-directory
1717 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1718 (make-obsolete 'elmo-folder-make-temp-dir
1719                'elmo-folder-make-temporary-directory)
1720
1721
1722 ;; autoloads
1723 (autoload 'elmo-dop-queue-flush "elmo-dop")
1724 (autoload 'elmo-nntp-post "elmo-nntp")
1725
1726 (require 'product)
1727 (product-provide (provide 'elmo) (require 'elmo-version))
1728
1729 ;;; elmo.el ends here