elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type 'integer
  50   :group 'elmo)
  51
  52 (defcustom elmo-message-fetch-confirm t
  53   "If non-nil, confirm fetching if message size is larger than
  54 `elmo-message-fetch-threshold'.
  55 Otherwise, entire fetching of the message is aborted without confirmation."
  56   :type 'boolean
  57   :group 'elmo)
  58
  59 (defcustom elmo-folder-update-threshold 500
  60   "Update threshold."
  61   :type 'integer
  62   :group 'elmo)
  63
  64 (defcustom elmo-folder-update-confirm t
  65   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  66   :type 'boolean
  67   :group 'elmo)
  68
  69 (defvar elmo-message-displaying nil
  70   "A global switch to indicate message is displaying or not.")
  71
  72 ;;; internal
  73 (defvar elmo-folder-type-alist nil)
  74
  75 (defvar elmo-newsgroups-hashtb nil)
  76
  77 (elmo-define-error 'elmo-error "Error" 'error)
  78 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  79 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  80 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  81
  82 ;; autoloads
  83 (eval-and-compile
  84   (autoload 'elmo-dop-queue-flush "elmo-dop")
  85   (autoload 'elmo-nntp-post "elmo-nntp")
  86   (autoload 'elmo-global-flag-p "elmo-flag")
  87   (autoload 'elmo-global-flag-detach "elmo-flag")
  88   (autoload 'elmo-global-flag-detach-messages "elmo-flag")
  89   (autoload 'elmo-global-flag-set "elmo-flag")
  90   (autoload 'elmo-get-global-flags "elmo-flag")
  91   (autoload 'elmo-global-mark-migrate "elmo-flag")
  92   (autoload 'elmo-folder-list-global-flag-messages "elmo-flag"))
  93
  94 (defun elmo-define-folder (prefix backend)
  95   "Define a folder.
  96 If a folder name begins with PREFIX, use BACKEND."
  97   (let ((pair (assq prefix elmo-folder-type-alist)))
  98     (if pair
  99         (progn
 100           (setcar pair prefix)
 101           (setcdr pair backend))
 102       (setq elmo-folder-type-alist (cons (cons prefix backend)
 103                                          elmo-folder-type-alist)))))
 104
 105 (defmacro elmo-folder-type (name)
 106   "Get folder type from NAME string."
 107   `(and (stringp ,name)
 108         (cdr (assoc (string-to-char ,name) elmo-folder-type-alist))))
 109
 110 ;;; ELMO folder
 111 ;; A elmo folder provides uniformed (orchestrated) access
 112 ;; to the internet messages.
 113 (eval-and-compile
 114   (luna-define-class elmo-folder () (type   ; folder type symbol.
 115                                      name   ; orignal folder name string.
 116                                      prefix ; prefix for folder name
 117                                      path   ; directory path for msgdb.
 118                                      msgdb  ; msgdb (may be nil).
 119                                      killed-list  ; killed list.
 120                                      flag-table   ; flag table.
 121                                      persistent   ; non-nil if persistent.
 122                                      process-duplicates  ; read or hide
 123                                      biff   ; folder for biff
 124                                      ))
 125   (luna-define-internal-accessors 'elmo-folder))
 126
 127 (luna-define-generic elmo-folder-initialize (folder name)
 128   ;; Initialize a FOLDER structure with NAME."
 129   )
 130
 131 (defmacro elmo-folder-send (folder message &rest args)
 132   "Let FOLDER receive the MESSAGE with ARGS."
 133   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 134
 135 ;;;###autoload
 136 (defun elmo-make-folder (name &optional non-persistent)
 137   "Make an ELMO folder structure specified by NAME.
 138 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 139   (let ((type (elmo-folder-type name))
 140         prefix split class folder original)
 141     (setq original (elmo-string name))
 142     (if type
 143         (progn
 144           (setq prefix (substring name 0 1))
 145           (setq name (substring name 1)))
 146       (setq type (intern (car (setq split (split-string name ":")))))
 147       (if (>= (length split) 2)
 148           (setq name (substring name (+ 1 (length (car split)))))
 149         (error "Error in folder name `%s'" original))
 150       (setq prefix (concat (car split) ":")))
 151     (setq class (format "elmo-%s" (symbol-name type)))
 152     (require (intern class))
 153     (setq folder (luna-make-entity (intern (concat class "-folder"))
 154                                    :type type
 155                                    :prefix prefix
 156                                    :name original
 157                                    :persistent (not non-persistent)))
 158     (save-match-data
 159       (elmo-folder-send folder 'elmo-folder-initialize name))))
 160
 161 ;; Note that this function is for internal use only.
 162 (luna-define-generic elmo-folder-msgdb (folder)
 163   "Return the msgdb of FOLDER (on-demand loading).
 164 \(For internal use only.\)")
 165
 166 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 167   (or (elmo-folder-msgdb-internal folder)
 168       (elmo-folder-set-msgdb-internal folder
 169                                       (elmo-folder-msgdb-load folder))))
 170
 171 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 172   "Open and setup (load saved status) FOLDER.
 173 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 174 \(otherwise, msgdb is loaded on-demand)")
 175
 176 (luna-define-generic elmo-folder-open-internal (folder)
 177   "Open FOLDER (without loading saved folder status).")
 178
 179 (luna-define-generic elmo-folder-check (folder)
 180   "Check the FOLDER to obtain newest information at the next list operation.")
 181
 182 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 183   "Clear FOLDER to the initial state.
 184 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 185
 186 (luna-define-generic elmo-folder-commit (folder)
 187   "Save current status of FOLDER.")
 188
 189 (luna-define-generic elmo-folder-close (folder)
 190   "Close, save and clearnup FOLDER.")
 191
 192 (luna-define-generic elmo-folder-close-internal (folder)
 193   "Close FOLDER (without saving folder status).")
 194
 195 (luna-define-generic elmo-folder-plugged-p (folder)
 196   "Returns t if FOLDER is plugged.")
 197
 198 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 199   "Set FOLDER as plugged.")
 200
 201 (luna-define-generic elmo-net-port-info (folder)
 202   "Get port information of FOLDER.")
 203
 204 (luna-define-generic elmo-folder-use-flag-p (folder)
 205   "Returns t if FOLDER treats unread/important flag itself.")
 206
 207 (luna-define-generic elmo-folder-diff (folder)
 208   "Get diff of FOLDER.
 209 Return value is cons cell or list:
 210  - a cons cell (new . all)
 211  - a list (new unread all)")
 212
 213 (luna-define-generic elmo-folder-status (folder)
 214   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 215
 216 (luna-define-generic elmo-folder-reserve-status-p (folder)
 217   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 218
 219 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 220                                                        in-msgdb)
 221   "Return a list of message numbers contained in FOLDER.
 222 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 223 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 224
 225 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 226                                                &optional visible-only in-msgdb)
 227   (let ((list (if in-msgdb
 228                   t
 229                 (elmo-folder-list-messages-internal folder visible-only)))
 230         (killed-list (elmo-folder-killed-list-internal folder)))
 231     (unless (listp list)
 232       ;; Use current list.
 233       (setq list (elmo-msgdb-list-messages (elmo-folder-msgdb folder))))
 234     (if visible-only
 235         (elmo-living-messages list killed-list)
 236       (if (and in-msgdb killed-list)
 237           (elmo-uniq-sorted-list
 238            (sort (nconc (elmo-number-set-to-number-list killed-list) list) #'<)
 239            #'eq)
 240         list))))
 241
 242 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 243                                                                 visible-only)
 244   ;; Return a list of message numbers contained in FOLDER.
 245   ;; Return t if the message list is not available.
 246   )
 247
 248 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 249   "List messages in the FOLDER with FLAG.
 250 FLAG is a symbol which is one of the following:
 251   `new'        (new messages)
 252   `unread'     (unread messages (new messages are included))
 253   `answered'   (answered or forwarded)
 254   `important'  (marked as important)
 255 'sugar' flags:
 256   `read'       (not unread)
 257   `digest'     (unread + important + other flags)
 258   `any'        (digest + answered + other flags)
 259 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 260
 261 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 262                                               &optional in-msgdb)
 263   (let ((msgs (if in-msgdb
 264                   t
 265                 (elmo-folder-list-flagged-internal folder flag))))
 266     (unless (listp msgs)
 267       (setq msgs (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag)))
 268     (if in-msgdb
 269         msgs
 270       (elmo-uniq-list
 271        (nconc (elmo-folder-list-global-flag-messages folder flag) msgs)
 272        #'delq))))
 273
 274 (luna-define-generic elmo-folder-list-flagged-internal (folder flag)
 275   "Return a list of message in the FOLDER with FLAG.
 276 Return t if the message list is not available.")
 277
 278 (luna-define-method elmo-folder-list-flagged-internal ((folder elmo-folder)
 279                                                        flag)
 280   t)
 281
 282 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 283   "Returns a list of subfolders contained in FOLDER.
 284 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 285 \(a folder which have children is returned as a list\)
 286 Otherwise, all descendent folders are returned.")
 287
 288 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 289   "Return non-nil when FOLDER has subfolders.")
 290
 291 (luna-define-generic elmo-folder-exists-p (folder)
 292   "Returns non-nil when FOLDER exists.")
 293
 294 (luna-define-generic elmo-folder-creatable-p (folder)
 295   "Returns non-nil when FOLDER is creatable.")
 296
 297 (luna-define-generic elmo-folder-writable-p (folder)
 298   "Returns non-nil when FOLDER is writable.")
 299
 300 (luna-define-generic elmo-folder-persistent-p (folder)
 301   "Return non-nil when FOLDER is persistent.")
 302
 303 (luna-define-generic elmo-folder-create (folder)
 304   "Create a FOLDER.")
 305
 306 (luna-define-generic elmo-message-deletable-p (folder number)
 307   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 308
 309 (luna-define-generic elmo-folder-delete (folder)
 310   "Delete FOLDER completely.")
 311
 312 (luna-define-generic elmo-folder-rename (folder new-name)
 313   "Rename FOLDER to NEW-NAME (string).")
 314
 315 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 316   "Delete messages.
 317 FOLDER is the ELMO folder structure.
 318 NUMBERS is a list of message numbers to be deleted.
 319 It is not recommended to use this function other than internal use.
 320 Use `elmo-folder-move-messages' with dst-folder 'null instead.")
 321
 322 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 323   "Search and return list of message numbers.
 324 FOLDER is the ELMO folder structure.
 325 CONDITION is a condition structure for searching.
 326 If optional argument NUMBERS is specified and is a list of message numbers,
 327 messages are searched from the list.")
 328
 329 (luna-define-generic elmo-message-match-condition (folder number
 330                                                           condition
 331                                                           numbers)
 332   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 333 CONDITION is a condition structure for testing.
 334 NUMBERS is a list of message numbers,
 335 use to be test for \"last\" and \"first\" predicates.")
 336
 337 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 338   "Create a message database (implemented in each backends).
 339 FOLDER is the ELMO folder structure.
 340 NUMBERS is a list of message numbers to create msgdb.
 341 FLAG-TABLE is a hashtable of message-id and flag.")
 342
 343 (luna-define-generic elmo-folder-set-flag (folder numbers flag
 344                                                   &optional is-local)
 345   "Set messages flag.
 346 FOLDER is a ELMO folder structure.
 347 NUMBERS is a list of message number to set flag.
 348
 349 FLAG is a symbol which is one of the following:
 350   `unread'    (set the message as unread)
 351   `answered'  (set the message as answered)
 352   `important' (set the message as important)
 353 'sugar' flag:
 354   `read'      (remove new and unread flags)
 355 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 356
 357 (luna-define-generic elmo-folder-unset-flag (folder numbers flag
 358                                                     &optional is-local)
 359   "Unset messages flag.
 360 FOLDER is a ELMO folder structure.
 361 NUMBERS is a list of message number to unset flag.
 362
 363 FLAG is a symbol which is one of the following:
 364   `unread'    (remove unread and new flag)
 365   `answered'  (remove answered flag)
 366   `important' (remove important flag)
 367 'sugar' flag:
 368   `read'      (set unread flag)
 369   `all'       (remove all flags)
 370 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 371
 372 (luna-define-generic elmo-folder-next-message-number (folder)
 373   "The next message number that will be assigned to a new message.
 374 FOLDER is the ELMO folder structure.")
 375
 376 (luna-define-generic elmo-folder-append-buffer (folder &optional flags
 377                                                        number)
 378   "Append current buffer as a new message.
 379 FOLDER is the destination folder (ELMO folder structure).
 380 FLAGS is the status of appended message (list of symbols).
 381 If it is nil, it is not that there is no flag and what is not defined is meant.
 382 If optional argument NUMBER is specified, the new message number is set
 383 \(if possible\).
 384 Return nil on failure.")
 385
 386 (luna-define-generic elmo-folder-append-messages (folder
 387                                                   src-folder
 388                                                   numbers
 389                                                   &optional
 390                                                   same-number)
 391   "Append messages from folder.
 392 FOLDER is the ELMO folder structure.
 393 Caller should make sure FOLDER is `writable'.
 394 \(Can be checked with `elmo-folder-writable-p'\).
 395 SRC-FOLDER is the source ELMO folder structure.
 396 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 397 If second optional argument SAME-NUMBER is specified,
 398 message number is preserved \(if possible\).")
 399
 400 (luna-define-generic elmo-folder-pack-numbers (folder)
 401   "Pack message numbers of FOLDER.")
 402
 403 (luna-define-generic elmo-folder-update-number (folder)
 404   "Update number of FOLDER.")
 405
 406 (luna-define-generic elmo-folder-diff-async (folder)
 407   "Get diff of FOLDER asynchronously.")
 408
 409 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 410   "Expand path for FOLDER.")
 411
 412 (luna-define-generic elmo-folder-get-primitive-list (folder)
 413   "Get primitive folder structure list contained in FOLDER.")
 414
 415 (luna-define-generic elmo-folder-contains-type (folder type)
 416   "Returns t if FOLDER contains TYPE.")
 417
 418 (luna-define-generic elmo-folder-local-p (folder)
 419   "Returns t if FOLDER is local.")
 420
 421 (luna-define-generic elmo-folder-message-file-p (folder)
 422   "Returns t if all messages in the FOLDER are files.")
 423
 424 ;;; Message methods.
 425 (luna-define-generic elmo-message-use-cache-p (folder number)
 426   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 427
 428 (luna-define-generic elmo-message-file-name (folder number)
 429   "Return the file name of a message specified by FOLDER and NUMBER.")
 430
 431 ;;; For archive
 432
 433 ;;; Use original file
 434 (luna-define-generic elmo-folder-message-file-number-p (folder)
 435   "Return t if the file name in the FOLDER is the message number.")
 436
 437 (luna-define-generic elmo-folder-message-file-directory (folder)
 438   "Return the directory of the message files of FOLDER.")
 439
 440 ;;; Use temporary file
 441 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 442   "Return t if the messages in the FOLDER makes local temporary file.")
 443
 444 (luna-define-generic elmo-folder-message-make-temp-files (folder
 445                                                           numbers
 446                                                           &optional
 447                                                           start-number)
 448   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 449 If START-NUMBER is specified, temporary files begin from the number.
 450 Otherwise, same number is used for temporary files.
 451 Return newly created temporary directory name which contains temporary files.")
 452
 453 (luna-define-generic elmo-message-file-p (folder number)
 454   "Return t if message in the FOLDER with NUMBER is a file.")
 455
 456 (luna-define-generic elmo-message-flags (folder number &optional msgid)
 457   "Return a list of flags.
 458 FOLDER is a ELMO folder structure.
 459 NUMBER is a number of the message.
 460 If optional argument MSGID is specified,
 461 the message with NUMBER checks whether it has MSGID.")
 462
 463 (luna-define-method elmo-message-flags ((folder elmo-folder) number
 464                                         &optional msgid)
 465   (if msgid
 466       (let ((this-id (elmo-message-field folder number 'message-id)))
 467         (and this-id
 468              (string= this-id msgid)
 469              (or (elmo-msgdb-flags (elmo-folder-msgdb folder) number)
 470                  '(read))))
 471     (elmo-msgdb-flags (elmo-folder-msgdb folder) number)))
 472
 473 (defsubst elmo-message-flagged-p (folder number flag)
 474   "Return non-nil if the message is set FLAG.
 475 FOLDER is a ELMO folder structure.
 476 NUMBER is a message number to test."
 477   (let ((cur-flags (elmo-message-flags folder number)))
 478     (case flag
 479       (read
 480        (not (memq 'unread cur-flags)))
 481       (t
 482        (memq flag cur-flags)))))
 483
 484 (luna-define-generic elmo-find-fetch-strategy
 485   (folder entity &optional ignore-cache)
 486 ;; Returns the message fetching strategy suitable for the message.
 487 ;; FOLDER is the ELMO folder structure.
 488 ;; ENTITY is the overview entity of the message in the folder.
 489 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 490 ;; Returned value is a elmo-fetch-strategy object.
 491 ;; If return value is nil, message should not be nil.
 492   )
 493
 494 (defmacro elmo-make-fetch-strategy (entireness
 495                                     &optional
 496                                     use-cache
 497                                     save-cache
 498                                     cache-path)
 499 ;; Make elmo-message-fetching strategy.
 500 ;; ENTIRENESS is 'entire or 'section.
 501 ;; 'entire means fetch message entirely at once.
 502 ;; 'section means fetch message section by section.
 503 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 504 ;; existing cache is thrown away.
 505 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 506 ;; CACHE-PATH is the cache path to be used as a message cache file.
 507   (` (vector (, entireness)
 508              (, use-cache) (, save-cache) (, cache-path))))
 509
 510 (defmacro elmo-fetch-strategy-entireness (strategy)
 511   ;; Return entireness of STRATEGY.
 512   (` (aref (, strategy) 0)))
 513
 514 (defmacro elmo-fetch-strategy-use-cache (strategy)
 515   ;; Return use-cache of STRATEGY.
 516   (` (aref (, strategy) 1)))
 517
 518 (defmacro elmo-fetch-strategy-save-cache (strategy)
 519   ;; Return save-cache of STRATEGY.
 520   (` (aref (, strategy) 2)))
 521
 522 (defmacro elmo-fetch-strategy-cache-path (strategy)
 523   ;;  Return cache-path of STRATEGY.
 524   (` (aref (, strategy) 3)))
 525
 526 (luna-define-method elmo-find-fetch-strategy
 527   ((folder elmo-folder) entity &optional ignore-cache)
 528   (let (cache-file size message-id number)
 529     (setq size (elmo-message-entity-field entity 'size))
 530     (setq message-id (elmo-message-entity-field entity 'message-id))
 531     (setq number (elmo-message-entity-number entity))
 532     (setq cache-file (elmo-file-cache-get message-id))
 533     (setq ignore-cache (or ignore-cache
 534                            (null (elmo-message-use-cache-p folder number))))
 535     (if (or ignore-cache
 536             (null (elmo-file-cache-status cache-file)))
 537         ;; No cache or ignore-cache.
 538         (if (and (not (elmo-folder-local-p folder))
 539                  elmo-message-fetch-threshold
 540                  (integerp size)
 541                  (>= size elmo-message-fetch-threshold)
 542                  (or (not elmo-message-fetch-confirm)
 543                      (not (prog1 (y-or-n-p
 544                                   (format "Fetch entire message(%dbytes)? "
 545                                           size))
 546                             (message "")))))
 547             ;; Don't fetch message at all.
 548             nil
 549           ;; Don't use existing cache and fetch entire message at once.
 550           (elmo-make-fetch-strategy
 551            'entire nil
 552            (elmo-message-use-cache-p folder number)
 553            (elmo-file-cache-path cache-file)))
 554       ;; Cache exists.
 555       (if (not ignore-cache)
 556           (elmo-make-fetch-strategy
 557            'entire
 558            ;; ...But ignore current section cache and re-fetch
 559            ;; if section cache.
 560            (not (eq (elmo-file-cache-status cache-file) 'section))
 561            ;; Save cache.
 562            (elmo-message-use-cache-p folder number)
 563            (elmo-file-cache-path cache-file))))))
 564
 565 (luna-define-method elmo-folder-list-messages-internal
 566   ((folder elmo-folder) &optional visible-only)
 567   t)
 568
 569 (defun elmo-folder-encache (folder numbers &optional unread)
 570   "Encache messages in the FOLDER with NUMBERS.
 571 If UNREAD is non-nil, messages are not flaged as read."
 572   (dolist (number numbers)
 573     (elmo-message-encache folder number unread)))
 574
 575 (luna-define-generic elmo-message-encache (folder number &optional read)
 576   "Encache message in the FOLDER with NUMBER.
 577 If READ is non-nil, message is flaged as read.")
 578
 579 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 580                                           &optional read)
 581   (let (path)
 582     (elmo-message-fetch
 583      folder number
 584      (elmo-make-fetch-strategy 'entire
 585                                nil ;use-cache
 586                                t   ;save-cache
 587                                (setq path (elmo-file-cache-get-path
 588                                            (elmo-message-field
 589                                             folder number 'message-id))))
 590      nil nil (not read))
 591     path))
 592
 593 (luna-define-generic elmo-message-fetch-bodystructure (folder number strategy)
 594   "Fetch bodystructure of the message in FOLDER with NUMBER using STRATEGY.")
 595
 596 (luna-define-generic elmo-message-fetch (folder number strategy
 597                                                 &optional
 598                                                 section
 599                                                 outbuf
 600                                                 unread)
 601   "Fetch a message and return as a string.
 602 FOLDER is the ELMO folder structure.
 603 NUMBER is the number of the message in the FOLDER.
 604 STRATEGY is the message fetching strategy.
 605 If optional argument SECTION is specified, only the SECTION of the message
 606 is fetched (if possible).
 607 If second optional argument OUTBUF is specified, fetched message is
 608 inserted to the buffer and returns t if fetch was ended successfully.
 609 If third optional argument UNREAD is non-nil, message is not flaged as read.
 610 Returns non-nil if fetching was succeed.")
 611
 612 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 613                                                             number strategy
 614                                                             &optional
 615                                                             section
 616                                                             unread)
 617   "Fetch a message into current buffer with cache process.
 618 FOLDER is the ELMO folder structure.
 619 NUMBER is the number of the message in the FOLDER.
 620 STRATEGY is the message fetching strategy.
 621 If optional argument SECTION is specified, only the SECTION of the message
 622 is fetched (if possible).
 623 If second optional argument UNREAD is non-nil, message is not flaged as read.
 624 Returns non-nil if fetching was succeed.")
 625
 626 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 627                                                          &optional
 628                                                          section
 629                                                          unread)
 630   "Fetch a message into current buffer.
 631 FOLDER is the ELMO folder structure.
 632 NUMBER is the number of the message in the FOLDER.
 633 STRATEGY is the message fetching strategy.
 634 If optional argument SECTION is specified, only the SECTION of the message
 635 is fetched (if possible).
 636 If second optional argument UNREAD is non-nil, message is not flaged as read.
 637 Returns non-nil if fetching was succeed.")
 638
 639 (luna-define-generic elmo-message-fetch-field (folder number field)
 640   "Fetch a message field value.
 641 FOLDER is the ELMO folder structure.
 642 NUMBER is the number of the message in the FOLDER.
 643 FIELD is a symbol of the field name.")
 644
 645 (luna-define-generic elmo-message-folder (folder number)
 646   "Get primitive folder of the message.")
 647
 648 (luna-define-generic elmo-folder-process-crosspost (folder)
 649   "Process crosspost for FOLDER.
 650 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).")
 651
 652 (luna-define-generic elmo-folder-newsgroups (folder)
 653   "Return list of newsgroup name of FOLDER.")
 654
 655 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 656   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 657
 658 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 659   (if (listp condition)
 660       (or (elmo-folder-search-requires-msgdb-p-internal
 661            folder (nth 1 condition))
 662           (elmo-folder-search-requires-msgdb-p-internal
 663            folder (nth 2 condition)))
 664     (and (not (string= (elmo-filter-key condition) "last"))
 665          (not (string= (elmo-filter-key condition) "first")))))
 666
 667 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 668                                                          condition)
 669   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 670
 671 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 672   nil)
 673
 674 (luna-define-method elmo-folder-open ((folder elmo-folder)
 675                                       &optional load-msgdb)
 676   (elmo-generic-folder-open folder load-msgdb))
 677
 678 (defun elmo-generic-folder-open (folder load-msgdb)
 679   (let ((inhibit-quit t))
 680     (if load-msgdb (elmo-folder-msgdb folder))
 681     (elmo-folder-set-killed-list-internal
 682      folder
 683      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 684   (elmo-folder-open-internal folder))
 685
 686 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 687   nil ; default is do nothing.
 688   )
 689
 690 (luna-define-method elmo-folder-check ((folder elmo-folder))
 691   nil) ; default is noop.
 692
 693 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 694   (elmo-generic-folder-commit folder))
 695
 696 (defun elmo-generic-folder-commit (folder)
 697   (let ((msgdb (elmo-folder-msgdb-internal folder)))
 698     (when (and msgdb (elmo-folder-persistent-p folder))
 699       (when (elmo-msgdb-message-modified-p msgdb)
 700         (elmo-folder-set-info-max-by-numdb
 701          folder
 702          (elmo-folder-list-messages folder nil 'in-msgdb))
 703         (elmo-msgdb-killed-list-save
 704          (elmo-folder-msgdb-path folder)
 705          (elmo-folder-killed-list-internal folder)))
 706       (elmo-msgdb-save msgdb))))
 707
 708 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 709   ;; do nothing.
 710   )
 711
 712 (luna-define-method elmo-folder-close ((folder elmo-folder))
 713   (elmo-generic-folder-close folder)
 714   (elmo-folder-close-internal folder))
 715
 716 (defun elmo-generic-folder-close (folder)
 717   (elmo-folder-commit folder)
 718   (elmo-folder-set-msgdb-internal folder nil)
 719   (elmo-folder-set-killed-list-internal folder nil))
 720
 721 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 722   t) ; default is plugged.
 723
 724 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 725                                              &optional add)
 726   nil) ; default is do nothing.
 727
 728 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 729   nil) ; default is no flag.
 730
 731 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 732   (elmo-folder-persistent-internal folder))
 733
 734 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 735   nil) ; default is not creatable.
 736
 737 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 738   nil) ; default is not writable.
 739
 740 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 741   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 742                              (elmo-folder-name-internal folder)))
 743     (elmo-msgdb-delete-path folder)
 744     t))
 745
 746 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 747   (let* ((new-folder (elmo-make-folder new-name)))
 748     (unless (eq (elmo-folder-type-internal folder)
 749                 (elmo-folder-type-internal new-folder))
 750       (error "Not same folder type"))
 751     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 752             (elmo-folder-exists-p new-folder))
 753         (error "Already exists folder: %s" new-name))
 754     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 755     (elmo-msgdb-rename-path folder new-folder)))
 756
 757 (luna-define-method elmo-folder-search ((folder elmo-folder)
 758                                         condition
 759                                         &optional numbers)
 760   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 761         (msgdb (elmo-folder-msgdb folder))
 762         results)
 763     (setq results (elmo-msgdb-search msgdb condition numbers))
 764     (if (listp results)
 765         results
 766       (let ((len (length numbers))
 767             matched)
 768         (elmo-with-progress-display (> len elmo-display-progress-threshold)
 769             (elmo-folder-search len "Searching...")
 770           (dolist (number numbers)
 771             (let (result)
 772               (setq result (elmo-msgdb-match-condition msgdb
 773                                                        condition
 774                                                        number
 775                                                        numbers))
 776               (when (elmo-filter-condition-p result)
 777                 (setq result (elmo-message-match-condition folder
 778                                                            number
 779                                                            condition
 780                                                            numbers)))
 781               (when result
 782                 (setq matched (cons number matched))))
 783             (elmo-progress-notify 'elmo-folder-search)))
 784         (message "Searching...done")
 785         (nreverse matched)))))
 786
 787 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 788                                                   number condition
 789                                                   numbers)
 790   (let* (cache cache-path
 791          (filename (cond
 792                     ((elmo-message-file-name folder number))
 793                     ((progn
 794                        (setq cache (elmo-file-cache-get
 795                                     (elmo-message-field folder number
 796                                                         'message-id)))
 797                        (setq cache-path (elmo-file-cache-path cache))
 798                        (and cache-path
 799                             (not (elmo-cache-path-section-p cache-path))))
 800                      cache-path))))
 801     (when (and filename (file-readable-p filename))
 802       (with-temp-buffer
 803         (set-buffer-multibyte nil)
 804         ;;(insert-file-contents-as-binary filename)
 805         (elmo-message-fetch folder number
 806                             (elmo-make-fetch-strategy 'entire
 807                                                       (and cache t)
 808                                                       nil
 809                                                       cache-path)
 810                             nil (current-buffer) t)
 811         (set-buffer-multibyte default-enable-multibyte-characters)
 812         (decode-coding-region (point-min) (point-max)
 813                               elmo-mime-display-as-is-coding-system)
 814         (elmo-buffer-field-condition-match condition number numbers)))))
 815
 816 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 817   nil) ; default is noop.
 818
 819 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 820   nil) ; default is noop.
 821
 822 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 823   nil) ; default is not file.
 824
 825 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 826   nil) ; default is not number.
 827
 828 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 829   nil) ; default is not make temp file.
 830
 831 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 832                                                    number)
 833   nil) ; default is no name.
 834
 835 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 836   t)   ; default is local.
 837
 838 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 839   t)
 840
 841 ;; Flag table
 842 (luna-define-generic elmo-folder-flag-table (folder &optional if-exists)
 843   "Return the flag-table of FOLDER.
 844 If optional argument IF-EXISTS is nil, load on demand.
 845 \(For internal use only.\)")
 846
 847 (luna-define-generic elmo-folder-close-flag-table (folder)
 848   "Close flag-table of FOLDER.")
 849
 850 (luna-define-method elmo-folder-flag-table ((folder elmo-folder)
 851                                             &optional if-exists)
 852   (or (elmo-folder-flag-table-internal folder)
 853       (unless if-exists
 854         (elmo-folder-set-flag-table-internal
 855          folder
 856          (elmo-flag-table-load (elmo-folder-msgdb-path folder))))))
 857
 858 (luna-define-method elmo-folder-close-flag-table ((folder elmo-folder))
 859   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
 860                         (elmo-folder-flag-table folder))
 861   (elmo-folder-set-flag-table-internal folder nil))
 862
 863 (defun elmo-folder-preserve-flags (folder msgid flags)
 864   "Preserve FLAGS into FOLDER for a message that has MSGID."
 865   (when (and msgid flags)
 866     (let ((flag-table (elmo-folder-flag-table folder 'if-exists))
 867           load-now)
 868       (when (setq load-now (null flag-table))
 869         (setq flag-table (elmo-folder-flag-table folder)))
 870       (elmo-flag-table-set flag-table msgid flags)
 871       (when load-now
 872         (elmo-folder-close-flag-table folder)))))
 873
 874 ;;; Folder info
 875 ;; Folder info is a message number information cache (hashtable)
 876 (defsubst elmo-folder-get-info (folder &optional hashtb)
 877   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 878   (elmo-get-hash-val (elmo-folder-name-internal folder)
 879                      (or hashtb elmo-folder-info-hashtb)))
 880
 881 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 882   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 883   (let ((info (elmo-folder-get-info folder)))
 884     (when info
 885       (or new     (setq new     (nth 0 info)))
 886       (or unread  (setq unread  (nth 1 info)))
 887       (or numbers (setq numbers (nth 2 info)))
 888       (or max     (setq max     (nth 3 info))))
 889     (elmo-set-hash-val (elmo-folder-name-internal folder)
 890                        (list new unread numbers max)
 891                        elmo-folder-info-hashtb)))
 892
 893 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 894   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 895   (elmo-folder-set-info-hashtb
 896    folder
 897    (if numbers (apply #'max numbers) 0)
 898    nil ;;(length num-db)
 899    ))
 900
 901 (defun elmo-folder-get-info-max (folder)
 902   "Return max number of FODLER from folder info."
 903   (nth 3 (elmo-folder-get-info folder)))
 904
 905 (defun elmo-folder-get-info-length (folder)
 906   "Return length of FODLER from folder info."
 907   (nth 2 (elmo-folder-get-info folder)))
 908
 909 (defun elmo-folder-get-info-unread (folder)
 910   "Return unread of FODLER from folder info."
 911   (nth 1 (elmo-folder-get-info folder)))
 912
 913 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 914   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 915   (let* ((hashtb (or hashtb
 916                      (elmo-make-hash (length info-alist)))))
 917     (mapcar
 918      (lambda (x)
 919        (let ((info (cadr x)))
 920          (and (intern-soft (car x) hashtb)
 921               (elmo-set-hash-val (car x)
 922                                  (list (nth 2 info)   ;; new
 923                                        (nth 3 info)   ;; unread
 924                                        (nth 1 info)   ;; length
 925                                        (nth 0 info))  ;; max
 926                                  hashtb))))
 927      info-alist)
 928     (setq elmo-folder-info-hashtb hashtb)))
 929
 930 (defsubst elmo-diff-new (diff)
 931   (car diff))
 932
 933 (defsubst elmo-diff-unread (diff)
 934   (when (consp (cdr diff))
 935     (nth 1 diff)))
 936
 937 (defsubst elmo-diff-all (diff)
 938   (if (consp (cdr diff))
 939       (nth 2 diff)
 940     (cdr diff)))
 941
 942 (defsubst elmo-strict-folder-diff (folder)
 943   "Return folder diff information strictly from FOLDER."
 944   (let ((in-db (sort (elmo-msgdb-list-messages (elmo-folder-msgdb folder))
 945                      '<))
 946         (in-folder  (elmo-folder-list-messages folder))
 947         append-list delete-list diff)
 948     (cons (if (equal in-folder in-db)
 949               0
 950             (setq diff (elmo-list-diff in-folder in-db nil))
 951             (setq append-list (car diff))
 952             (setq delete-list (cadr diff))
 953             (if append-list
 954                 (length append-list)
 955               (if delete-list
 956                   (- 0 (length delete-list))
 957                 0)))
 958           (length in-folder))))
 959
 960 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 961   (elmo-generic-folder-diff folder))
 962
 963 (defun elmo-generic-folder-diff (folder)
 964   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 965                                 elmo-strict-diff-folder-list)
 966       (elmo-strict-folder-diff folder)
 967     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 968           (in-folder (elmo-folder-status folder))
 969           (in-db t)
 970           unsync messages
 971           in-db-max)
 972       (if (not cached-in-db-max)
 973           (let ((number-list (elmo-folder-list-messages folder
 974                                                         nil 'in-msgdb)))
 975             ;; No info-cache.
 976             (setq in-db number-list)
 977             (setq in-db-max (if in-db (apply #'max in-db) 0))
 978             (elmo-folder-set-info-hashtb folder in-db-max nil))
 979         (setq in-db-max cached-in-db-max))
 980       (setq unsync (if (and in-db (car in-folder))
 981                        (- (car in-folder) in-db-max)
 982                      (if (and in-folder (null in-db))
 983                          (cdr in-folder)
 984                        (car in-folder))))
 985       (setq messages (cdr in-folder))
 986       (if (and unsync messages (> unsync messages))
 987           (setq unsync messages))
 988       (cons (or unsync 0) (or messages 0)))))
 989
 990 (defvar elmo-folder-diff-async-callback nil)
 991 (defvar elmo-folder-diff-async-callback-data nil)
 992
 993 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 994   (and elmo-folder-diff-async-callback
 995        (funcall elmo-folder-diff-async-callback
 996                 folder
 997                 (elmo-folder-diff folder))))
 998
 999 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
1000   (list folder))
1001
1002 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
1003   (eq (elmo-folder-type-internal folder) type))
1004
1005 (luna-define-method elmo-folder-next-message-number ((folder elmo-folder))
1006   (+ 1 (elmo-max-of-list (or (elmo-folder-list-messages folder)
1007                              '(0)))))
1008
1009 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
1010                                                  src-folder
1011                                                  numbers
1012                                                  &optional
1013                                                  same-number)
1014   (elmo-generic-folder-append-messages folder src-folder numbers
1015                                        same-number))
1016
1017 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1018                                                    same-number)
1019   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
1020         unseen table
1021         succeed-numbers failure cache id)
1022     (setq table (elmo-folder-flag-table folder))
1023     (with-temp-buffer
1024       (set-buffer-multibyte nil)
1025       (while numbers
1026         (setq failure nil
1027               id (and src-msgdb-exists
1028                       (elmo-message-field src-folder (car numbers)
1029                                           'message-id)))
1030         (condition-case nil
1031             (setq cache (elmo-file-cache-get id)
1032                   failure
1033                   (not
1034                    (and
1035                     (elmo-message-fetch
1036                      src-folder (car numbers)
1037                      (if (elmo-folder-plugged-p src-folder)
1038                          (elmo-make-fetch-strategy
1039                           'entire 'maybe nil
1040                           (and cache (elmo-file-cache-path cache)))
1041                        (or (and elmo-enable-disconnected-operation
1042                                 cache
1043                                 (eq (elmo-file-cache-status cache) 'entire)
1044                                 (elmo-make-fetch-strategy
1045                                  'entire t nil
1046                                  (elmo-file-cache-path cache)))
1047                            (error "Unplugged")))
1048                      nil (current-buffer)
1049                      'unread)
1050                     (> (buffer-size) 0)
1051                     (elmo-folder-append-buffer
1052                      folder
1053                      (elmo-message-flags
1054                       src-folder
1055                       (car numbers)
1056                       (elmo-msgdb-get-message-id-from-buffer))
1057                      (if same-number (car numbers))))))
1058           (error (setq failure t)))
1059         ;; FETCH & APPEND finished
1060         (unless failure
1061           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1062         (elmo-progress-notify 'elmo-folder-move-messages)
1063         (setq numbers (cdr numbers)))
1064       (when (elmo-folder-persistent-p folder)
1065         (elmo-folder-close-flag-table folder))
1066       succeed-numbers)))
1067
1068 ;; Arguments should be reduced.
1069 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1070                                              &optional
1071                                              no-delete
1072                                              same-number)
1073   (save-excursion
1074     (let* ((messages msgs)
1075            (elmo-inhibit-display-retrieval-progress t)
1076            (len (length msgs))
1077            succeeds i result)
1078       (if (eq dst-folder 'null)
1079           (setq succeeds messages)
1080         (unless (elmo-folder-writable-p dst-folder)
1081           (error "move: %d is not writable"
1082                  (elmo-folder-name-internal dst-folder)))
1083         (when messages
1084           ;; src is already opened.
1085           (elmo-folder-open-internal dst-folder)
1086           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1087                                                               src-folder
1088                                                               messages
1089                                                               same-number))
1090             (error "move: append message to %s failed"
1091                    (elmo-folder-name-internal dst-folder)))
1092           (elmo-folder-close dst-folder)))
1093       (if (and (not no-delete) succeeds)
1094           (progn
1095             (if (and (elmo-folder-delete-messages src-folder succeeds)
1096                      (elmo-folder-detach-messages src-folder succeeds))
1097                 (progn
1098                   (elmo-global-flag-detach-messages
1099                    src-folder succeeds (eq dst-folder 'null))
1100                   (setq result t))
1101               (message "move: delete messages from %s failed."
1102                        (elmo-folder-name-internal src-folder))
1103               (setq result nil))
1104             result)
1105         (if no-delete
1106             (progn
1107               ;; (message "Copying messages...done")
1108               t)
1109           (if (eq len 0)
1110               (message "No message was moved.")
1111             (message "Moving messages failed.")
1112             nil ; failure
1113             ))))))
1114
1115 (defun elmo-folder-msgdb-path (folder)
1116   "Return the msgdb path for FOLDER."
1117   (or (elmo-folder-path-internal folder)
1118       (elmo-folder-set-path-internal
1119        folder
1120        (elmo-folder-expand-msgdb-path folder))))
1121
1122 (luna-define-generic elmo-message-cached-p (folder number)
1123   "Return non-nil if the message is cached.")
1124
1125 (luna-define-method elmo-message-cached-p ((folder elmo-folder) number)
1126   (elmo-message-flagged-p folder number 'cached))
1127
1128 (defun elmo-message-accessible-p (folder number)
1129   "Get accessibility of the message.
1130 Return non-nil when message is accessible."
1131   (or (elmo-folder-plugged-p folder)
1132       (elmo-folder-local-p folder)
1133       (elmo-message-cached-p folder number)))
1134
1135 (luna-define-generic elmo-message-set-cached (folder number cached)
1136   "Set cache status of the message in the msgdb.
1137 FOLDER is the ELMO folder structure.
1138 NUMBER is a number of the message.
1139 If CACHED is t, message is set as cached.")
1140
1141 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1142                                              number cached)
1143   (if cached
1144       (elmo-msgdb-set-flag (elmo-folder-msgdb folder) number 'cached)
1145     (elmo-msgdb-unset-flag (elmo-folder-msgdb folder) number 'cached)))
1146
1147 (defun elmo-message-copy-entity (entity)
1148   (elmo-msgdb-copy-message-entity (elmo-message-entity-handler entity)
1149                                   entity))
1150
1151 (luna-define-generic elmo-message-entity (folder key)
1152   "Return the message-entity structure which matches to the KEY.
1153 KEY is a number or a string.
1154 A number is for message number in the FOLDER.
1155 A string is for message-id of the message.")
1156
1157 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1158   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1159
1160 (luna-define-generic elmo-message-entity-parent (folder entity)
1161   "Return the parent message-entity structure in the FOLDER.
1162 ENTITY is the message-entity to get the parent.")
1163
1164 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1165   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1166
1167 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1168 (def-edebug-spec elmo-folder-do-each-message-entity
1169   ((symbolp form &rest form) &rest form))
1170
1171 (defsubst elmo-folder-list-message-entities (folder)
1172   ;; List all message entities in the FOLDER.
1173   (mapcar
1174    (lambda (number) (elmo-message-entity folder number))
1175    (elmo-folder-list-messages folder nil t))) ; XXX killed-list is not used.
1176
1177 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1178   "Iterator for message entity in the folder.
1179 \(elmo-folder-do-each-message-entity \(entity folder\)
1180  ... do the process using entity...
1181 \)"
1182   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1183      ,@form))
1184
1185 (luna-define-generic elmo-folder-count-flags (folder)
1186   "Count flagged message number in the msgdb of the FOLDER.
1187 Return a list of numbers (`new' `unread' `answered')")
1188
1189 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1190   (let* ((flag-count (elmo-msgdb-flag-count (elmo-folder-msgdb folder)))
1191          (new (or (cdr (assq 'new flag-count)) 0))
1192          (unread (or (cdr (assq 'unread flag-count)) 0))
1193          (answered(or (cdr (assq 'answered flag-count)) 0)))
1194     (list new (- unread new) answered)))
1195
1196 (defun elmo-message-set-flag (folder number flag &optional is-local)
1197   "Set message flag.
1198 FOLDER is a ELMO folder structure.
1199 NUMBER is a message number to set flag.
1200
1201 FLAG is a symbol which is one of the following:
1202   `unread'    (set the message as unread)
1203   `answered'  (set the message as answered)
1204   `important' (set the message as important)
1205 'sugar' flag:
1206   `read'      (remove new and unread flags)
1207 If optional IS-LOCAL is non-nil, update only local (not server) status."
1208   ;; XXX Transitional implementation.
1209   (elmo-folder-set-flag folder (list number) flag is-local))
1210
1211 (defun elmo-message-unset-flag (folder number flag &optional is-local)
1212   "Unset message flag.
1213 FOLDER is a ELMO folder structure.
1214 NUMBER is a message number to set flag.
1215
1216 FLAG is a symbol which is one of the following:
1217   `unread'    (remove unread and new flag)
1218   `answered'  (remove answered flag)
1219   `important' (remove important flag)
1220 'sugar' flag:
1221   `read'      (set unread flag)
1222 If optional IS-LOCAL is non-nil, update only local (not server) status."
1223   ;; XXX Transitional implementation.
1224   (elmo-folder-unset-flag folder (list number) flag is-local))
1225
1226 (luna-define-generic elmo-message-field (folder number field)
1227   "Get message field value in the msgdb.
1228 FOLDER is the ELMO folder structure.
1229 NUMBER is a number of the message.
1230 FIELD is a symbol of the field.")
1231
1232 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1233   (elmo-message-entity-field (elmo-message-entity folder number) field))
1234
1235 (luna-define-generic elmo-message-set-field (folder number field value)
1236   "Set message field value in the msgdb.
1237 FOLDER is the ELMO folder structure.
1238 NUMBER is a number of the message.
1239 FIELD is a symbol of the field.
1240 VALUE is a value to set.")
1241
1242 (luna-define-method elmo-message-set-field ((folder elmo-folder) number
1243                                             field value)
1244   (elmo-message-entity-set-field (elmo-message-entity folder number)
1245                                  field value))
1246
1247 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1248   nil) ; default is not use cache.
1249
1250 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1251   folder) ; default is folder
1252
1253 (luna-define-method elmo-folder-set-flag ((folder elmo-folder)
1254                                           numbers
1255                                           flag
1256                                           &optional is-local)
1257   (when (elmo-folder-msgdb-internal folder)
1258     (dolist (number numbers)
1259       (when (elmo-global-flag-p flag)
1260         (let ((message-id (elmo-message-field folder number 'message-id)))
1261           (elmo-global-flag-set flag folder number message-id)))
1262       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1263                            number
1264                            flag))))
1265
1266 (defun elmo-message-has-global-flag-p (folder number)
1267   "Return non-nil when the message in the FOLDER with NUMBER has global flag."
1268   (let ((flags (elmo-message-flags folder number))
1269         result)
1270     (while flags
1271       (when (and (elmo-global-flag-p (car flags))
1272                  (not (memq (car flags) '(answered unread cached))))
1273         (setq result t
1274               flags nil))
1275       (setq flags (cdr flags)))
1276     result))
1277
1278 (defun elmo-message-set-global-flags (folder number flags &optional local)
1279   "Set global flags of the message in the FOLDER with NUMBER as FLAGS.
1280 If Optional LOCAL is non-nil, don't update server flag."
1281   (dolist (flag flags)
1282     (unless (elmo-global-flag-p flag)
1283       (error "Not a global flag")))
1284   (let ((old-flags (elmo-get-global-flags (elmo-message-flags folder number))))
1285     (dolist (flag flags)
1286       (unless (memq flag old-flags)
1287         (elmo-message-set-flag folder number flag local)))
1288     (dolist (flag old-flags)
1289       (unless (memq flag flags)
1290         (elmo-message-unset-flag folder number flag local)))))
1291
1292 (luna-define-method elmo-folder-unset-flag ((folder elmo-folder)
1293                                             numbers
1294                                             flag
1295                                             &optional is-local)
1296   (when (elmo-folder-msgdb-internal folder)
1297     (dolist (number numbers)
1298       (when (elmo-global-flag-p flag)
1299         (elmo-global-flag-detach flag folder number 'always))
1300       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1301                              number
1302                              flag))))
1303
1304 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1305   ;; Do nothing.
1306   )
1307
1308 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1309 ;;                                                             &optional
1310 ;;                                                             flag-table)
1311 ;;  "Append ENTITY to the folder.")
1312
1313 (defun elmo-msgdb-merge (folder msgdb-merge)
1314   "Return a list of messages which have duplicated message-id."
1315   (let (msgdb duplicates)
1316     (setq msgdb (or (elmo-folder-msgdb-internal folder)
1317                     (elmo-make-msgdb (elmo-folder-msgdb-path folder))))
1318     (setq duplicates (elmo-msgdb-append msgdb msgdb-merge))
1319     (elmo-folder-set-msgdb-internal folder msgdb)
1320     duplicates))
1321
1322 (defsubst elmo-folder-append-msgdb (folder append-msgdb)
1323   (if append-msgdb
1324       (let ((duplicates (elmo-msgdb-merge folder append-msgdb)))
1325         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1326                    'hide)
1327                ;; Let duplicates be a temporary killed message.
1328                (elmo-folder-kill-messages folder duplicates)
1329                ;; Should be flag as read.
1330                (elmo-folder-set-flag folder duplicates 'read))
1331               ((eq (elmo-folder-process-duplicates-internal folder)
1332                    'read)
1333                ;; Flag as read duplicates.
1334                (elmo-folder-set-flag folder duplicates 'read))
1335               (t
1336                ;; Do nothing.
1337                (setq duplicates nil)))
1338         (length duplicates))
1339     0))
1340
1341 (defun elmo-folder-confirm-appends (appends)
1342   (let ((len (length appends))
1343         in)
1344     (if (and elmo-folder-update-threshold
1345              (> len elmo-folder-update-threshold)
1346              elmo-folder-update-confirm)
1347         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1348             appends
1349           (setq in elmo-folder-update-threshold)
1350           (catch 'end
1351             (while t
1352               (setq in (read-from-minibuffer "Update number: "
1353                                              (int-to-string in))
1354                     in (string-to-int in))
1355               (if (< len in)
1356                   (throw 'end len))
1357               (if (y-or-n-p (format
1358                              "%d messages are killed (not appeared). OK? "
1359                              (max (- len in) 0)))
1360                   (throw 'end in))))
1361           (nthcdr (max (- len in) 0) appends))
1362       (if (and elmo-folder-update-threshold
1363                (> len elmo-folder-update-threshold)
1364                (not elmo-folder-update-confirm))
1365           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1366         appends))))
1367
1368 (luna-define-method elmo-message-fetch-bodystructure ((folder elmo-folder)
1369                                                       number strategy)
1370   nil)
1371
1372 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1373                                         number strategy
1374                                         &optional
1375                                         section
1376                                         outbuf
1377                                         unread)
1378   (if outbuf
1379       (with-current-buffer outbuf
1380         (erase-buffer)
1381         (elmo-message-fetch-with-cache-process folder number
1382                                                strategy section unread))
1383     (with-temp-buffer
1384       (elmo-message-fetch-with-cache-process folder number
1385                                              strategy section unread)
1386       (buffer-string))))
1387
1388 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1389                                                            number strategy
1390                                                            &optional
1391                                                            section unread)
1392   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1393         (method-priorities
1394          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1395                 '(entity cache))
1396                ((elmo-fetch-strategy-use-cache strategy)
1397                 '(cache entity))
1398                (t
1399                 '(entity))))
1400         result err)
1401     (while (and method-priorities
1402                 (null result))
1403       (setq result
1404             (case (car method-priorities)
1405               (cache
1406                (elmo-file-cache-load cache-path section))
1407               (entity
1408                (when (and (condition-case error
1409                               (elmo-message-fetch-internal folder number
1410                                                            strategy
1411                                                            section
1412                                                            unread)
1413                             (error (setq err error) nil))
1414                           (> (buffer-size) 0))
1415                  (when (and (elmo-fetch-strategy-save-cache strategy)
1416                             cache-path)
1417                    (elmo-file-cache-save cache-path section))
1418                  t)))
1419             method-priorities (cdr method-priorities)))
1420     (or result
1421         (and err (signal (car err) (cdr err))))))
1422
1423 (defun elmo-folder-kill-messages-range (folder beg end)
1424   (elmo-folder-set-killed-list-internal
1425    folder
1426    (nconc
1427     (elmo-folder-killed-list-internal folder)
1428     (list (cons beg end)))))
1429
1430 (defun elmo-folder-kill-messages (folder numbers)
1431   "Kill(hide) messages in the FOLDER with NUMBERS."
1432   (elmo-folder-set-killed-list-internal
1433    folder
1434    (elmo-number-set-append-list
1435     (elmo-folder-killed-list-internal folder)
1436     numbers))
1437   (elmo-folder-unset-flag folder numbers 'all 'local-only))
1438
1439 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1440                                        &optional keep-killed)
1441   (unless keep-killed
1442     (elmo-folder-set-killed-list-internal folder nil))
1443   (if (eq elmo-msgdb-convert-type 'sync)
1444       (elmo-folder-set-msgdb-internal
1445        folder
1446        (elmo-make-msgdb (elmo-folder-msgdb-path folder)))
1447     (elmo-msgdb-clear (elmo-folder-msgdb folder))))
1448
1449 (luna-define-generic elmo-folder-synchronize (folder
1450                                               &optional
1451                                               disable-killed
1452                                               ignore-msgdb
1453                                               no-check)
1454   "Synchronize the folder data to the newest status.
1455 FOLDER is the ELMO folder structure.
1456
1457 If optional DISABLE-KILLED is non-nil, killed messages are also synchronized.
1458 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1459 flag status.
1460 If NO-CHECK is non-nil, rechecking folder is skipped.
1461 Return amount of cross-posted messages.
1462 If update process is interrupted, return nil.")
1463
1464 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1465                                              &optional
1466                                              disable-killed
1467                                              ignore-msgdb
1468                                              no-check)
1469   (let ((killed-list (elmo-folder-killed-list-internal folder))
1470         (before-append t)
1471         old-msgdb diff diff-2 delete-list new-list new-msgdb flag
1472         flag-table crossed after-append)
1473     (setq old-msgdb (elmo-folder-msgdb folder))
1474     (setq flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1475     (when ignore-msgdb
1476       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1477       (elmo-folder-clear folder (not disable-killed)))
1478     (unless no-check (elmo-folder-check folder))
1479     (condition-case nil
1480         (progn
1481           (message "Checking folder diff...")
1482           (setq diff (elmo-list-diff (elmo-folder-list-messages
1483                                       folder
1484                                       (not disable-killed))
1485                                      (elmo-folder-list-messages
1486                                       folder
1487                                       (not disable-killed)
1488                                       'in-msgdb)))
1489           (message "Checking folder diff...done")
1490           (setq new-list (elmo-folder-confirm-appends (car diff)))
1491           ;; Set killed list as ((1 . MAX-OF-DISAPPEARED))
1492           (when (and (not (eq (length (car diff))
1493                               (length new-list)))
1494                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1495             (elmo-folder-kill-messages-range
1496              folder
1497              (car (car diff-2))
1498              (nth (- (length (car diff-2)) 1) (car diff-2))))
1499           (setq delete-list (cadr diff))
1500           (if (or (equal diff '(nil nil))
1501                   (equal diff '(nil))
1502                   (and (eq (length (car diff)) 0)
1503                        (eq (length (cadr diff)) 0)))
1504               (progn
1505                 (elmo-folder-update-number folder)
1506                 (elmo-folder-process-crosspost folder)
1507                 0 ; no updates.
1508                 )
1509             (when delete-list
1510               (elmo-folder-detach-messages folder delete-list))
1511             (when new-list
1512               (elmo-msgdb-out-of-date-messages (elmo-folder-msgdb folder))
1513               (setq new-msgdb (elmo-folder-msgdb-create
1514                                folder new-list flag-table))
1515               ;; Clear flag-table
1516               (if (elmo-folder-persistent-p folder)
1517                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1518                                         nil))
1519               (setq before-append nil)
1520               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1521               ;; process crosspost.
1522               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).
1523               (elmo-folder-process-crosspost folder))
1524             ;; return value.
1525             (or crossed 0)))
1526       (quit
1527        ;; Resume to the original status.
1528        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1529        (elmo-folder-set-killed-list-internal folder killed-list)
1530        nil))))
1531
1532 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1533   "Remove messages with NUMBERS from MSGDB.")
1534
1535 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1536                                                  numbers)
1537   (elmo-msgdb-delete-messages (elmo-folder-msgdb folder) numbers))
1538
1539 (luna-define-generic elmo-folder-length (folder)
1540   "Return number of messages in the FOLDER.")
1541
1542 (luna-define-method elmo-folder-length ((folder elmo-folder))
1543   (if (elmo-folder-msgdb-internal folder)
1544       (elmo-msgdb-length (elmo-folder-msgdb folder))
1545     0))
1546
1547 (defun elmo-folder-msgdb-load (folder &optional silent)
1548   (unless silent
1549     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1550   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1551     (elmo-folder-set-info-max-by-numdb
1552      folder
1553      (elmo-msgdb-list-messages msgdb))
1554     (unless silent
1555       (message "Loading msgdb for %s...done"
1556                (elmo-folder-name-internal folder)))
1557     msgdb))
1558
1559 (defun elmo-msgdb-delete-path (folder)
1560   (let ((path (elmo-folder-msgdb-path folder)))
1561     (if (file-directory-p path)
1562         (elmo-delete-directory path t))))
1563
1564 (defun elmo-msgdb-rename-path (old-folder new-folder)
1565   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1566          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1567          (new-dir (directory-file-name (file-name-directory new))))
1568     (if (not (file-directory-p old))
1569         ()
1570       (if (file-exists-p new)
1571           (error "Already exists directory: %s" new)
1572         (if (not (file-exists-p new-dir))
1573             (elmo-make-directory new-dir))
1574         (rename-file old new)))))
1575
1576 (defun elmo-setup-subscribed-newsgroups (groups)
1577   "Setup subscribed newsgroups.
1578 GROUPS is a list of newsgroup name string.
1579 Return a hashtable for newsgroups."
1580   (let ((hashtb (or elmo-newsgroups-hashtb
1581                     (setq elmo-newsgroups-hashtb
1582                           (elmo-make-hash (length groups))))))
1583     (dolist (group groups)
1584       (or (elmo-get-hash-val group hashtb)
1585           (elmo-set-hash-val group nil hashtb)))
1586     (setq elmo-newsgroups-hashtb hashtb)))
1587
1588 (defvar elmo-crosspost-message-alist-modified nil)
1589 (defun elmo-crosspost-message-alist-load ()
1590   "Load crosspost message alist."
1591   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1592   (setq elmo-crosspost-message-alist-modified nil))
1593
1594 (defun elmo-crosspost-message-alist-save ()
1595   "Save crosspost message alist."
1596   (when elmo-crosspost-message-alist-modified
1597     (let ((alist elmo-crosspost-message-alist)
1598           newsgroups)
1599       (while alist
1600         (setq newsgroups
1601               (elmo-delete-if
1602                '(lambda (x)
1603                   (not (intern-soft x elmo-newsgroups-hashtb)))
1604                (nth 1 (car alist))))
1605         (if newsgroups
1606             (setcar (cdar alist) newsgroups)
1607           (setq elmo-crosspost-message-alist
1608                 (delete (car alist) elmo-crosspost-message-alist)))
1609         (setq alist (cdr alist)))
1610       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1611       (setq elmo-crosspost-message-alist-modified nil))))
1612
1613 (defun elmo-folder-make-temporary-directory (folder)
1614   ;; Make a temporary directory for FOLDER.
1615   (let ((temp-dir (make-temp-name
1616                    (concat
1617                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1618                     "elmo"))))
1619     (elmo-make-directory temp-dir)
1620     temp-dir))
1621
1622 (defun elmo-init ()
1623   "Initialize ELMO module."
1624   (elmo-crosspost-message-alist-load)
1625   (elmo-resque-obsolete-variables)
1626   (elmo-dop-queue-load)
1627   (run-hooks 'elmo-init-hook))
1628
1629 (defun elmo-quit ()
1630   "Quit and cleanup ELMO."
1631   (elmo-crosspost-message-alist-save)
1632   (elmo-dop-queue-save)
1633   ;; Not implemented yet.
1634   (let ((types elmo-folder-type-alist)
1635         class)
1636     (while types
1637       (setq class
1638             (luna-find-class
1639              (intern (format "elmo-%s-folder"
1640                              (symbol-name (cdr (car types)))))))
1641       ;; Call all folder's `elmo-quit' method.
1642       (if class
1643           (dolist (func (luna-class-find-functions class 'elmo-quit))
1644             (funcall func nil)))
1645       (setq types (cdr types)))))
1646
1647 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1648                                                  new-folder)
1649   (error "Cannot rename %s folder"
1650          (symbol-name (elmo-folder-type-internal folder))))
1651
1652 ;;; Define folders.
1653 (elmo-define-folder ?% 'imap4)
1654 (elmo-define-folder ?-  'nntp)
1655 (elmo-define-folder ?\+ 'localdir)
1656 (elmo-define-folder ?\* 'multi)
1657 (elmo-define-folder ?\/ 'filter)
1658 (elmo-define-folder ?\$ 'archive)
1659 (elmo-define-folder ?&  'pop3)
1660 (elmo-define-folder ?=  'localnews)
1661 (elmo-define-folder ?|  'pipe)
1662 (elmo-define-folder ?.  'maildir)
1663 (elmo-define-folder ?'  'internal)
1664 (elmo-define-folder ?\[  'nmz)
1665 (elmo-define-folder ?@  'shimbun)
1666
1667 ;;; Obsolete variables.
1668 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1669                                'elmo-imap4-default-mailbox)
1670 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1671                                'elmo-imap4-default-server)
1672 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1673                                'elmo-imap4-default-authenticate-type)
1674 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1675                                'elmo-imap4-default-user)
1676 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1677                                'elmo-imap4-default-port)
1678 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1679                                'elmo-imap4-default-stream-type)
1680 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1681                                'elmo-nntp-default-server)
1682 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1683                                'elmo-nntp-default-user)
1684 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1685                                'elmo-nntp-default-port)
1686 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1687                                'elmo-nntp-default-stream-type)
1688 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1689                                'elmo-pop3-default-server)
1690 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1691                                'elmo-pop3-default-user)
1692 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1693                                'elmo-pop3-default-authenticate-type)
1694 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1695                                'elmo-pop3-default-port)
1696 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1697                                'elmo-pop3-default-stream-type)
1698 (elmo-define-obsolete-variable 'elmo-cache-dirname
1699                                'elmo-cache-directory)
1700 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1701                                'elmo-msgdb-directory)
1702
1703 ;; Obsolete functions.
1704 ;; 2001-12-11: *-dir -> *-directory
1705 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1706 (make-obsolete 'elmo-folder-make-temp-dir
1707                'elmo-folder-make-temporary-directory)
1708
1709 (require 'product)
1710 (product-provide (provide 'elmo) (require 'elmo-version))
1711
1712 ;;; elmo.el ends here