elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type 'integer
  50   :group 'elmo)
  51
  52 (defcustom elmo-message-fetch-confirm t
  53   "If non-nil, confirm fetching if message size is larger than
  54 `elmo-message-fetch-threshold'.
  55 Otherwise, entire fetching of the message is aborted without confirmation."
  56   :type 'boolean
  57   :group 'elmo)
  58
  59 (defcustom elmo-folder-update-threshold 500
  60   "Update threshold."
  61   :type 'integer
  62   :group 'elmo)
  63
  64 (defcustom elmo-folder-update-confirm t
  65   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  66   :type 'boolean
  67   :group 'elmo)
  68
  69 (defvar elmo-message-displaying nil
  70   "A global switch to indicate message is displaying or not.")
  71
  72 ;;; internal
  73 (defvar elmo-folder-type-alist nil)
  74
  75 (defvar elmo-newsgroups-hashtb nil)
  76
  77 (elmo-define-error 'elmo-error "Error" 'error)
  78 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  79 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  80 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  81
  82 (defun elmo-define-folder (prefix backend)
  83   "Define a folder.
  84 If a folder name begins with PREFIX, use BACKEND."
  85   (let ((pair (assq prefix elmo-folder-type-alist)))
  86     (if pair
  87         (progn
  88           (setcar pair prefix)
  89           (setcdr pair backend))
  90       (setq elmo-folder-type-alist (cons (cons prefix backend)
  91                                          elmo-folder-type-alist)))))
  92
  93 (defmacro elmo-folder-type (name)
  94   "Get folder type from NAME string."
  95   (` (and (stringp (, name))
  96           (cdr (assoc (string-to-char (, name)) elmo-folder-type-alist)))))
  97
  98 ;;; ELMO folder
  99 ;; A elmo folder provides uniformed (orchestrated) access
 100 ;; to the internet messages.
 101 (eval-and-compile
 102   (luna-define-class elmo-folder () (type   ; folder type symbol.
 103                                      name   ; orignal folder name string.
 104                                      prefix ; prefix for folder name
 105                                      path   ; directory path for msgdb.
 106                                      msgdb  ; msgdb (may be nil).
 107                                      killed-list  ; killed list.
 108                                      persistent   ; non-nil if persistent.
 109                                      message-modified ; message is modified.
 110                                      mark-modified    ; mark is modified.
 111                                      process-duplicates  ; read or hide
 112                                      biff   ; folder for biff
 113                                      ))
 114   (luna-define-internal-accessors 'elmo-folder))
 115
 116 (luna-define-generic elmo-folder-initialize (folder name)
 117   ;; Initialize a FOLDER structure with NAME."
 118   )
 119
 120 (defmacro elmo-folder-send (folder message &rest args)
 121   "Let FOLDER receive the MESSAGE with ARGS."
 122   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 123
 124 ;;;###autoload
 125 (defun elmo-make-folder (name &optional non-persistent)
 126   "Make an ELMO folder structure specified by NAME.
 127 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 128   (let ((type (elmo-folder-type name))
 129         prefix split class folder original)
 130     (setq original (elmo-string name))
 131     (if type
 132         (progn
 133           (setq prefix (substring name 0 1))
 134           (setq name (substring name 1)))
 135       (setq type (intern (car (setq split (split-string name ":")))))
 136       (if (> (length split) 2)
 137           (setq name (substring name (+ 1 (length (car split)))))
 138         (error "Error in folder name `%s'" original))
 139       (setq prefix (concat (car split) ":")))
 140     (setq class (format "elmo-%s" (symbol-name type)))
 141     (require (intern class))
 142     (setq folder (luna-make-entity (intern (concat class "-folder"))
 143                                    :type type
 144                                    :prefix prefix
 145                                    :name original
 146                                    :persistent (not non-persistent)))
 147     (save-match-data
 148       (elmo-folder-send folder 'elmo-folder-initialize name))))
 149
 150 ;; Note that this function is for internal use only.
 151 (luna-define-generic elmo-folder-msgdb (folder)
 152   "Return the msgdb of FOLDER (on-demand loading).
 153 \(For internal use only.\)")
 154
 155 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 156   (or (elmo-folder-msgdb-internal folder)
 157       (elmo-folder-set-msgdb-internal folder
 158                                       (elmo-folder-msgdb-load folder))))
 159
 160 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 161   "Open and setup (load saved status) FOLDER.
 162 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 163 \(otherwise, msgdb is loaded on-demand)")
 164
 165 (luna-define-generic elmo-folder-open-internal (folder)
 166   "Open FOLDER (without loading saved folder status).")
 167
 168 (luna-define-generic elmo-folder-check (folder)
 169   "Check the FOLDER to obtain newest information at the next list operation.")
 170
 171 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 172   "Clear FOLDER to the initial state.
 173 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 174
 175 (luna-define-generic elmo-folder-commit (folder)
 176   "Save current status of FOLDER.")
 177
 178 (luna-define-generic elmo-folder-close (folder)
 179   "Close, save and clearnup FOLDER.")
 180
 181 (luna-define-generic elmo-folder-close-internal (folder)
 182   "Close FOLDER (without saving folder status).")
 183
 184 (luna-define-generic elmo-folder-plugged-p (folder)
 185   "Returns t if FOLDER is plugged.")
 186
 187 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 188   "Set FOLDER as plugged.")
 189
 190 (luna-define-generic elmo-net-port-info (folder)
 191   "Get port information of FOLDER.")
 192
 193 (luna-define-generic elmo-folder-use-flag-p (folder)
 194   "Returns t if FOLDER treats unread/important flag itself.")
 195
 196 (luna-define-generic elmo-folder-diff (folder)
 197   "Get diff of FOLDER.
 198 Return value is cons cell or list:
 199  - a cons cell (new . all)
 200  - a list (new unread all)")
 201
 202 (luna-define-generic elmo-folder-status (folder)
 203   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 204
 205 (luna-define-generic elmo-folder-reserve-status-p (folder)
 206   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 207
 208 (luna-define-generic elmo-folder-set-message-modified (folder modified)
 209   "Set FOLDER as modified.")
 210 (luna-define-method elmo-folder-set-message-modified ((folder elmo-folder)
 211                                                       modified)
 212   (elmo-folder-set-message-modified-internal folder modified))
 213
 214 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 215                                                        in-msgdb)
 216   "Return a list of message numbers contained in FOLDER.
 217 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 218 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 219
 220 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 221                                                &optional visible-only in-msgdb)
 222   (let ((list (if in-msgdb
 223                   t
 224                 (elmo-folder-list-messages-internal folder visible-only)))
 225         (killed-list (elmo-folder-killed-list-internal folder)))
 226     (unless (listp list)
 227       ;; Use current list.
 228       (setq list (elmo-msgdb-list-messages (elmo-folder-msgdb folder))))
 229     (if visible-only
 230         (elmo-living-messages list killed-list)
 231       (elmo-uniq-list
 232        (nconc (elmo-number-set-to-number-list killed-list) list)))))
 233
 234 (luna-define-generic elmo-folder-list-unreads (folder)
 235   "Return a list of unread message numbers contained in FOLDER.")
 236 (luna-define-generic elmo-folder-list-importants (folder)
 237   "Return a list of important message numbers contained in FOLDER.")
 238 (luna-define-generic elmo-folder-list-answereds (folder)
 239   "Return a list of answered message numbers contained in FOLDER.")
 240
 241 ;; TODO: Should reconsider the structure of global mark.
 242 (defun elmo-folder-list-messages-with-global-mark (folder mark)
 243   (let (entity msgs)
 244     (dolist (mark-pair (or elmo-msgdb-global-mark-alist
 245                            (setq elmo-msgdb-global-mark-alist
 246                                  (elmo-object-load
 247                                   (expand-file-name
 248                                    elmo-msgdb-global-mark-filename
 249                                    elmo-msgdb-directory)))))
 250       (if (and (string= mark (cdr mark-pair))
 251                (setq entity
 252                      (elmo-msgdb-message-entity (elmo-folder-msgdb folder)
 253                                                 (car mark-pair))))
 254           (setq msgs (cons (elmo-msgdb-overview-entity-get-number entity)
 255                            msgs))))
 256     msgs))
 257
 258 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 259   "List messages in the FOLDER with FLAG.
 260 FLAG is a symbol which is one of the following:
 261   `new'        (new messages)
 262   `unread'     (unread messages (new messages are included))
 263   `answered'   (answered or forwarded)
 264   `important'  (marked as important)
 265 'sugar' flags:
 266   `read'       (not unread)
 267   `digest'     (unread + important)
 268   `any'        (digest + answered)
 269
 270 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 271
 272 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 273                                               &optional in-msgdb)
 274   ;; Currently, only in-msgdb is implemented.
 275   (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag))
 276
 277 (luna-define-method elmo-folder-list-unreads ((folder elmo-folder))
 278   (elmo-folder-list-flagged folder 'unread))
 279
 280 (luna-define-method elmo-folder-list-importants ((folder elmo-folder))
 281   (elmo-folder-list-flagged folder 'important))
 282
 283 (luna-define-method elmo-folder-list-answereds ((folder elmo-folder))
 284   (elmo-folder-list-flagged folder 'answered))
 285
 286 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 287                                                                 visible-only)
 288   ;; Return a list of message numbers contained in FOLDER.
 289   ;; Return t if the message list is not available.
 290   )
 291
 292 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 293   "Returns a list of subfolders contained in FOLDER.
 294 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 295 \(a folder which have children is returned as a list\)
 296 Otherwise, all descendent folders are returned.")
 297
 298 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 299   "Return non-nil when FOLDER has subfolders.")
 300
 301 (luna-define-generic elmo-folder-exists-p (folder)
 302   "Returns non-nil when FOLDER exists.")
 303
 304 (luna-define-generic elmo-folder-creatable-p (folder)
 305   "Returns non-nil when FOLDER is creatable.")
 306
 307 (luna-define-generic elmo-folder-writable-p (folder)
 308   "Returns non-nil when FOLDER is writable.")
 309
 310 (luna-define-generic elmo-folder-persistent-p (folder)
 311   "Return non-nil when FOLDER is persistent.")
 312
 313 (luna-define-generic elmo-folder-create (folder)
 314   "Create a FOLDER.")
 315
 316 (luna-define-generic elmo-message-deletable-p (folder number)
 317   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 318
 319 (luna-define-generic elmo-folder-delete (folder)
 320   "Delete FOLDER completely.")
 321
 322 (luna-define-generic elmo-folder-rename (folder new-name)
 323   "Rename FOLDER to NEW-NAME (string).")
 324
 325 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 326   "Delete messages.
 327 FOLDER is the ELMO folder structure.
 328 NUMBERS is a list of message numbers to be deleted.")
 329
 330 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 331   "Search and return list of message numbers.
 332 FOLDER is the ELMO folder structure.
 333 CONDITION is a condition structure for searching.
 334 If optional argument NUMBERS is specified and is a list of message numbers,
 335 messages are searched from the list.")
 336
 337 (luna-define-generic elmo-message-match-condition (folder number
 338                                                           condition
 339                                                           numbers)
 340   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 341 CONDITION is a condition structure for testing.
 342 NUMBERS is a list of message numbers,
 343 use to be test for \"last\" and \"first\" predicates.")
 344
 345 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 346   "Create a message database (implemented in each backends).
 347 FOLDER is the ELMO folder structure.
 348 NUMBERS is a list of message numbers to create msgdb.
 349 FLAG-TABLE is a hashtable of message-id and flag.")
 350
 351 (luna-define-generic elmo-folder-unmark-important (folder
 352                                                    numbers
 353                                                    &optional ignore-flags)
 354   "Un-mark messages as important.
 355 FOLDER is the ELMO folder structure.
 356 NUMBERS is a list of message numbers to be processed.
 357 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 358
 359 (luna-define-generic elmo-folder-mark-as-important (folder
 360                                                     numbers
 361                                                     &optional ignore-flags)
 362   "Mark messages as important.
 363 FOLDER is the ELMO folder structure.
 364 NUMBERS is a list of message numbers to be processed.
 365 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 366
 367 (luna-define-generic elmo-folder-unmark-read (folder numbers
 368                                                      &optional ignore-flags)
 369   "Un-mark messages as read.
 370 FOLDER is the ELMO folder structure.
 371 NUMBERS is a list of message numbers to be processed.
 372 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 373
 374 (luna-define-generic elmo-folder-mark-as-read (folder numbers
 375                                                       &optional ignore-flags)
 376   "Mark messages as read.
 377 FOLDER is the ELMO folder structure.
 378 NUMBERS is a list of message numbers to be processed.
 379 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 380
 381 (luna-define-generic elmo-folder-unmark-answered (folder numbers)
 382   "Un-mark messages as answered.
 383 FOLDER is the ELMO folder structure.
 384 NUMBERS is a list of message numbers to be processed.")
 385
 386 (luna-define-generic elmo-folder-mark-as-answered (folder numbers)
 387   "Mark messages as answered.
 388 FOLDER is the ELMO folder structure.
 389 NUMBERS is a list of message numbers to be processed.")
 390
 391 (luna-define-generic elmo-folder-append-buffer (folder &optional flag
 392                                                        number)
 393   "Append current buffer as a new message.
 394 FOLDER is the destination folder(ELMO folder structure).
 395 FLAG is the status of appended message.
 396 If optional argument NUMBER is specified, the new message number is set
 397 \(if possible\).")
 398
 399 (luna-define-generic elmo-folder-append-messages (folder
 400                                                   src-folder
 401                                                   numbers
 402                                                   &optional
 403                                                   same-number)
 404   "Append messages from folder.
 405 FOLDER is the ELMO folder structure.
 406 Caller should make sure FOLDER is `writable'.
 407 (Can be checked with `elmo-folder-writable-p').
 408 SRC-FOLDER is the source ELMO folder structure.
 409 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 410 If second optional argument SAME-NUMBER is specified,
 411 message number is preserved \(if possible\).")
 412
 413 (luna-define-generic elmo-folder-pack-numbers (folder)
 414   "Pack message numbers of FOLDER.")
 415
 416 (luna-define-generic elmo-folder-update-number (folder)
 417   "Update number of FOLDER.")
 418
 419 (luna-define-generic elmo-folder-diff-async (folder)
 420   "Get diff of FOLDER asynchronously.")
 421
 422 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 423   "Expand path for FOLDER.")
 424
 425 (luna-define-generic elmo-folder-get-primitive-list (folder)
 426   "Get primitive folder structure list contained in FOLDER.")
 427
 428 (luna-define-generic elmo-folder-contains-type (folder type)
 429   "Returns t if FOLDER contains TYPE.")
 430
 431 (luna-define-generic elmo-folder-local-p (folder)
 432   "Returns t if FOLDER is local.")
 433
 434 (luna-define-generic elmo-folder-message-file-p (folder)
 435   "Returns t if all messages in the FOLDER are files.")
 436
 437 ;;; Message methods.
 438 (luna-define-generic elmo-message-use-cache-p (folder number)
 439   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 440
 441 (luna-define-generic elmo-message-file-name (folder number)
 442   "Return the file name of a message specified by FOLDER and NUMBER.")
 443
 444 ;;; For archive
 445
 446 ;;; Use original file
 447 (luna-define-generic elmo-folder-message-file-number-p (folder)
 448   "Return t if the file name in the FOLDER is the message number.")
 449
 450 (luna-define-generic elmo-folder-message-file-directory (folder)
 451   "Return the directory of the message files of FOLDER.")
 452
 453 ;;; Use temporary file
 454 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 455   "Return t if the messages in the FOLDER makes local temporary file.")
 456
 457 (luna-define-generic elmo-folder-message-make-temp-files (folder
 458                                                           numbers
 459                                                           &optional
 460                                                           start-number)
 461   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 462 If START-NUMBER is specified, temporary files begin from the number.
 463 Otherwise, same number is used for temporary files.
 464 Return newly created temporary directory name which contains temporary files.")
 465
 466 (luna-define-generic elmo-message-file-p (folder number)
 467   "Return t if message in the FOLDER with NUMBER is a file.")
 468
 469 (luna-define-generic elmo-find-fetch-strategy
 470   (folder entity &optional ignore-cache)
 471 ;; Returns the message fetching strategy suitable for the message.
 472 ;; FOLDER is the ELMO folder structure.
 473 ;; ENTITY is the overview entity of the message in the folder.
 474 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 475 ;; Returned value is a elmo-fetch-strategy object.
 476 ;; If return value is nil, message should not be nil.
 477   )
 478
 479 (defmacro elmo-make-fetch-strategy (entireness
 480                                     &optional
 481                                     use-cache
 482                                     save-cache
 483                                     cache-path)
 484 ;; Make elmo-message-fetching strategy.
 485 ;; ENTIRENESS is 'entire or 'section.
 486 ;; 'entire means fetch message entirely at once.
 487 ;; 'section means fetch message section by section.
 488 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 489 ;; existing cache is thrown away.
 490 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 491 ;; CACHE-PATH is the cache path to be used as a message cache file.
 492   (` (vector (, entireness)
 493              (, use-cache) (, save-cache) (, cache-path))))
 494
 495 (defmacro elmo-fetch-strategy-entireness (strategy)
 496   ;; Return entireness of STRATEGY.
 497   (` (aref (, strategy) 0)))
 498
 499 (defmacro elmo-fetch-strategy-use-cache (strategy)
 500   ;; Return use-cache of STRATEGY.
 501   (` (aref (, strategy) 1)))
 502
 503 (defmacro elmo-fetch-strategy-save-cache (strategy)
 504   ;; Return save-cache of STRATEGY.
 505   (` (aref (, strategy) 2)))
 506
 507 (defmacro elmo-fetch-strategy-cache-path (strategy)
 508   ;;  Return cache-path of STRATEGY.
 509   (` (aref (, strategy) 3)))
 510
 511 (luna-define-method elmo-find-fetch-strategy
 512   ((folder elmo-folder) entity &optional ignore-cache)
 513   (let (cache-file size message-id number)
 514     (setq size (elmo-msgdb-overview-entity-get-size entity))
 515     (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 516     (setq number (elmo-msgdb-overview-entity-get-number entity))
 517     (setq cache-file (elmo-file-cache-get message-id))
 518     (setq ignore-cache (or ignore-cache
 519                            (null (elmo-message-use-cache-p folder number))))
 520     (if (or ignore-cache
 521             (null (elmo-file-cache-status cache-file)))
 522         ;; No cache or ignore-cache.
 523         (if (and (not (elmo-folder-local-p folder))
 524                  elmo-message-fetch-threshold
 525                  (integerp size)
 526                  (>= size elmo-message-fetch-threshold)
 527                  (or (not elmo-message-fetch-confirm)
 528                      (not (prog1 (y-or-n-p
 529                                   (format "Fetch entire message(%dbytes)? "
 530                                           size))
 531                             (message "")))))
 532             ;; Don't fetch message at all.
 533             nil
 534           ;; Don't use existing cache and fetch entire message at once.
 535           (elmo-make-fetch-strategy
 536            'entire nil
 537            (elmo-message-use-cache-p folder number)
 538            (elmo-file-cache-path cache-file)))
 539       ;; Cache exists.
 540       (if (not ignore-cache)
 541           (elmo-make-fetch-strategy
 542            'entire
 543            ;; ...But ignore current section cache and re-fetch
 544            ;; if section cache.
 545            (not (eq (elmo-file-cache-status cache-file) 'section))
 546            ;; Save cache.
 547            (elmo-message-use-cache-p folder number)
 548            (elmo-file-cache-path cache-file))))))
 549
 550 (luna-define-method elmo-folder-list-messages-internal
 551   ((folder elmo-folder) &optional visible-only)
 552   t)
 553
 554 (defun elmo-folder-encache (folder numbers &optional unread)
 555   "Encache messages in the FOLDER with NUMBERS.
 556 If UNREAD is non-nil, messages are not marked as read."
 557   (dolist (number numbers)
 558     (elmo-message-encache folder number unread)))
 559
 560 (luna-define-generic elmo-message-encache (folder number &optional read)
 561   "Encache message in the FOLDER with NUMBER.
 562 If READ is non-nil, message is marked as read.")
 563
 564 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 565                                           &optional read)
 566   (elmo-message-fetch
 567    folder number
 568    (elmo-make-fetch-strategy 'entire
 569                              nil ;use-cache
 570                              t   ;save-cache
 571                              (elmo-file-cache-get-path
 572                               (elmo-message-field
 573                                folder number 'message-id)))
 574    nil nil (not read)))
 575
 576 (luna-define-generic elmo-message-fetch (folder number strategy
 577                                                 &optional
 578                                                 section
 579                                                 outbuf
 580                                                 unread)
 581   "Fetch a message and return as a string.
 582 FOLDER is the ELMO folder structure.
 583 NUMBER is the number of the message in the FOLDER.
 584 STRATEGY is the message fetching strategy.
 585 If optional argument SECTION is specified, only the SECTION of the message
 586 is fetched (if possible).
 587 If second optional argument OUTBUF is specified, fetched message is
 588 inserted to the buffer and returns t if fetch was ended successfully.
 589 If third optional argument UNREAD is non-nil, message is not marked as read.
 590 Returns non-nil if fetching was succeed.")
 591
 592 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 593                                                             number strategy
 594                                                             &optional
 595                                                             section
 596                                                             unread)
 597   "Fetch a message into current buffer with cache process.
 598 FOLDER is the ELMO folder structure.
 599 NUMBER is the number of the message in the FOLDER.
 600 STRATEGY is the message fetching strategy.
 601 If optional argument SECTION is specified, only the SECTION of the message
 602 is fetched (if possible).
 603 If second optional argument UNREAD is non-nil, message is not marked as read.
 604 Returns non-nil if fetching was succeed.")
 605
 606 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 607                                                          &optional
 608                                                          section
 609                                                          unread)
 610   "Fetch a message into current buffer.
 611 FOLDER is the ELMO folder structure.
 612 NUMBER is the number of the message in the FOLDER.
 613 STRATEGY is the message fetching strategy.
 614 If optional argument SECTION is specified, only the SECTION of the message
 615 is fetched (if possible).
 616 If second optional argument UNREAD is non-nil, message is not marked as read.
 617 Returns non-nil if fetching was succeed.")
 618
 619 (luna-define-generic elmo-message-fetch-field (folder number field)
 620   "Fetch a message field value.
 621 FOLDER is the ELMO folder structure.
 622 NUMBER is the number of the message in the FOLDER.
 623 FIELD is a symbol of the field name.")
 624
 625 (luna-define-generic elmo-message-folder (folder number)
 626   "Get primitive folder of the message.")
 627
 628 (luna-define-generic elmo-folder-process-crosspost (folder)
 629   "Process crosspost for FOLDER.
 630 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).")
 631
 632 (luna-define-generic elmo-folder-newsgroups (folder)
 633   "Return list of newsgroup name of FOLDER.")
 634
 635 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 636   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 637
 638 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 639   (if (listp condition)
 640       (or (elmo-folder-search-requires-msgdb-p-internal
 641            folder (nth 1 condition))
 642           (elmo-folder-search-requires-msgdb-p-internal
 643            folder (nth 2 condition)))
 644     (and (not (string= (elmo-filter-key condition) "last"))
 645          (not (string= (elmo-filter-key condition) "first")))))
 646
 647 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 648                                                          condition)
 649   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 650
 651 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 652   nil)
 653
 654 (luna-define-method elmo-folder-open ((folder elmo-folder)
 655                                       &optional load-msgdb)
 656   (elmo-generic-folder-open folder load-msgdb))
 657
 658 (defun elmo-generic-folder-open (folder load-msgdb)
 659   (let ((inhibit-quit t))
 660     (if load-msgdb (elmo-folder-msgdb folder))
 661     (elmo-folder-set-killed-list-internal
 662      folder
 663      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 664   (elmo-folder-open-internal folder))
 665
 666 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 667   nil ; default is do nothing.
 668   )
 669
 670 (luna-define-method elmo-folder-check ((folder elmo-folder))
 671   nil) ; default is noop.
 672
 673 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 674   (elmo-generic-folder-commit folder))
 675
 676 (defun elmo-generic-folder-commit (folder)
 677   (let ((msgdb (elmo-folder-msgdb-internal folder)))
 678     (when (and msgdb (elmo-folder-persistent-p folder))
 679       (when (elmo-msgdb-message-modified-p msgdb)
 680         (elmo-folder-set-info-max-by-numdb
 681          folder
 682          (elmo-folder-list-messages folder nil 'in-msgdb))
 683         (elmo-msgdb-killed-list-save
 684          (elmo-folder-msgdb-path folder)
 685          (elmo-folder-killed-list-internal folder)))
 686       (elmo-folder-set-message-modified folder nil)
 687       (elmo-folder-set-mark-modified-internal folder nil)
 688       (elmo-msgdb-save msgdb))))
 689
 690 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 691   ;; do nothing.
 692   )
 693
 694 (luna-define-method elmo-folder-close ((folder elmo-folder))
 695   (elmo-generic-folder-close folder)
 696   (elmo-folder-close-internal folder))
 697
 698 (defun elmo-generic-folder-close (folder)
 699   (elmo-folder-commit folder)
 700   (elmo-folder-set-msgdb-internal folder nil)
 701   (elmo-folder-set-killed-list-internal folder nil))
 702
 703 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 704   t) ; default is plugged.
 705
 706 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 707                                              &optional add)
 708   nil) ; default is do nothing.
 709
 710 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 711   nil) ; default is no flag.
 712
 713 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 714   (elmo-folder-persistent-internal folder))
 715
 716 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 717   nil) ; default is not creatable.
 718
 719 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 720   nil) ; default is not writable.
 721
 722 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 723   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 724                              (elmo-folder-name-internal folder)))
 725     (elmo-msgdb-delete-path folder)
 726     t))
 727
 728 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 729   (let* ((new-folder (elmo-make-folder new-name)))
 730     (unless (eq (elmo-folder-type-internal folder)
 731                 (elmo-folder-type-internal new-folder))
 732       (error "Not same folder type"))
 733     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 734             (elmo-folder-exists-p new-folder))
 735         (error "Already exists folder: %s" new-name))
 736     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 737     (elmo-msgdb-rename-path folder new-folder)))
 738
 739 (defsubst elmo-folder-search-fast (folder condition numbers)
 740   "Search and return list of message numbers.
 741 Return t if CONDITION is not treated.
 742 FOLDER is the ELMO folder structure.
 743 CONDITION is a condition structure for searching.
 744 NUMBERS is a list of message numbers, messages are searched from the list."
 745   (if (and numbers
 746            (vectorp condition))
 747       (cond
 748        ((string= (elmo-filter-key condition) "flag")
 749         (let ((msgdb (elmo-folder-msgdb folder)))
 750           ;; msgdb should be synchronized at this point.
 751           (cond
 752            ((string= (elmo-filter-value condition) "unread")
 753             (elmo-folder-list-unreads folder))
 754            ((string= (elmo-filter-value condition) "important")
 755             (elmo-folder-list-importants folder))
 756            ((string= (elmo-filter-value condition) "answered")
 757             (elmo-folder-list-answereds folder))
 758            ((string= (elmo-filter-value condition) "digest")
 759             (nconc (elmo-folder-list-unreads folder)
 760                    (elmo-folder-list-importants folder)))
 761            ((string= (elmo-filter-value condition) "any")
 762             (nconc (elmo-folder-list-unreads folder)
 763                    (elmo-folder-list-importants folder)
 764                    (elmo-folder-list-answereds folder))))))
 765        ((member (elmo-filter-key condition) '("first" "last"))
 766         (let ((len (length numbers))
 767               (lastp (string= (elmo-filter-key condition) "last"))
 768               (value (string-to-number (elmo-filter-value condition))))
 769           (when (eq (elmo-filter-type condition) 'unmatch)
 770             (setq lastp (not lastp)
 771                   value  (- len value)))
 772           (if lastp
 773               (nthcdr (max (- len value) 0) numbers)
 774             (when (> value 0)
 775               (let* ((numbers (copy-sequence numbers))
 776                      (last (nthcdr (1- value) numbers)))
 777                 (when last
 778                   (setcdr last nil))
 779                 numbers)))))
 780        (t
 781         t))
 782     t))
 783
 784 (luna-define-method elmo-folder-search ((folder elmo-folder)
 785                                         condition
 786                                         &optional numbers)
 787   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 788         results)
 789     (if (listp (setq results (elmo-folder-search-fast folder
 790                                                       condition
 791                                                       numbers)))
 792         results
 793       (let ((msgdb (elmo-folder-msgdb folder))
 794             (len (length numbers))
 795             matched)
 796         (when (> len elmo-display-progress-threshold)
 797           (elmo-progress-set 'elmo-folder-search len "Searching..."))
 798         (unwind-protect
 799             (dolist (number numbers)
 800               (let (result)
 801                 (setq result (elmo-msgdb-match-condition
 802                               msgdb
 803                               condition
 804                               number
 805                               numbers))
 806                 (when (elmo-filter-condition-p result)
 807                   (setq result (elmo-message-match-condition
 808                                 folder
 809                                 number
 810                                 condition
 811                                 numbers)))
 812                 (when result
 813                   (setq matched (cons number matched))))
 814               (elmo-progress-notify 'elmo-folder-search))
 815           (elmo-progress-clear 'elmo-folder-search))
 816         (nreverse matched)))))
 817
 818 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 819                                                   number condition
 820                                                   numbers)
 821   (let ((filename (cond
 822                    ((elmo-message-file-name folder number))
 823                    ((let* ((cache (elmo-file-cache-get
 824                                    (elmo-message-field folder number
 825                                                        'message-id)))
 826                            (cache-path (elmo-file-cache-path cache)))
 827                       (when (and cache-path
 828                                  (not (elmo-cache-path-section-p cache-path)))
 829                         cache-path))))))
 830     (when (and filename
 831                (file-readable-p filename))
 832       (with-temp-buffer
 833         (insert-file-contents-as-binary filename)
 834         (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 835         ;; Should consider charset?
 836         (decode-mime-charset-region (point-min) (point-max) elmo-mime-charset)
 837         (elmo-buffer-field-condition-match condition number numbers)))))
 838
 839 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 840   nil) ; default is noop.
 841
 842 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 843   nil) ; default is noop.
 844
 845 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 846   nil) ; default is not file.
 847
 848 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 849   nil) ; default is not number.
 850
 851 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 852   nil) ; default is not make temp file.
 853
 854 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 855                                                    number)
 856   nil) ; default is no name.
 857
 858 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 859   t)   ; default is local.
 860
 861 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 862   t)
 863
 864 ;;; Folder info
 865 ;; Folder info is a message number information cache (hashtable)
 866 (defsubst elmo-folder-get-info (folder &optional hashtb)
 867   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 868   (elmo-get-hash-val (elmo-folder-name-internal folder)
 869                      (or hashtb elmo-folder-info-hashtb)))
 870
 871 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 872   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 873   (let ((info (elmo-folder-get-info folder)))
 874     (when info
 875       (or new     (setq new     (nth 0 info)))
 876       (or unread  (setq unread  (nth 1 info)))
 877       (or numbers (setq numbers (nth 2 info)))
 878       (or max     (setq max     (nth 3 info))))
 879     (elmo-set-hash-val (elmo-folder-name-internal folder)
 880                        (list new unread numbers max)
 881                        elmo-folder-info-hashtb)))
 882
 883 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 884   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 885   (elmo-folder-set-info-hashtb
 886    folder
 887    (or (car (sort numbers '>)) 0)
 888    nil ;;(length num-db)
 889    ))
 890
 891 (defun elmo-folder-get-info-max (folder)
 892   "Return max number of FODLER from folder info."
 893   (nth 3 (elmo-folder-get-info folder)))
 894
 895 (defun elmo-folder-get-info-length (folder)
 896   "Return length of FODLER from folder info."
 897   (nth 2 (elmo-folder-get-info folder)))
 898
 899 (defun elmo-folder-get-info-unread (folder)
 900   "Return unread of FODLER from folder info."
 901   (nth 1 (elmo-folder-get-info folder)))
 902
 903 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 904   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 905   (let* ((hashtb (or hashtb
 906                      (elmo-make-hash (length info-alist)))))
 907     (mapcar
 908      (lambda (x)
 909        (let ((info (cadr x)))
 910          (and (intern-soft (car x) hashtb)
 911               (elmo-set-hash-val (car x)
 912                                  (list (nth 2 info)   ;; new
 913                                        (nth 3 info)   ;; unread
 914                                        (nth 1 info)   ;; length
 915                                        (nth 0 info))  ;; max
 916                                  hashtb))))
 917      info-alist)
 918     (setq elmo-folder-info-hashtb hashtb)))
 919
 920 (defsubst elmo-diff-new (diff)
 921   (car diff))
 922
 923 (defsubst elmo-diff-unread (diff)
 924   (when (consp (cdr diff))
 925     (nth 1 diff)))
 926
 927 (defsubst elmo-diff-all (diff)
 928   (if (consp (cdr diff))
 929       (nth 2 diff)
 930     (cdr diff)))
 931
 932 (defsubst elmo-strict-folder-diff (folder)
 933   "Return folder diff information strictly from FOLDER."
 934   (let ((in-db (sort (elmo-msgdb-list-messages (elmo-folder-msgdb folder))
 935                      '<))
 936         (in-folder  (elmo-folder-list-messages folder))
 937         append-list delete-list diff)
 938     (cons (if (equal in-folder in-db)
 939               0
 940             (setq diff (elmo-list-diff in-folder in-db nil))
 941             (setq append-list (car diff))
 942             (setq delete-list (cadr diff))
 943             (if append-list
 944                 (length append-list)
 945               (if delete-list
 946                   (- 0 (length delete-list))
 947                 0)))
 948           (length in-folder))))
 949
 950 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 951   (elmo-generic-folder-diff folder))
 952
 953 (defun elmo-generic-folder-diff (folder)
 954   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 955                                 elmo-strict-diff-folder-list)
 956       (elmo-strict-folder-diff folder)
 957     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 958           (in-folder (elmo-folder-status folder))
 959           (in-db t)
 960           unsync messages
 961           in-db-max)
 962       (if (not cached-in-db-max)
 963           (let ((number-list (elmo-folder-list-messages folder
 964                                                         nil 'in-msgdb)))
 965             ;; No info-cache.
 966             (setq in-db (sort number-list '<))
 967             (setq in-db-max (or (nth (max 0 (1- (length in-db))) in-db)
 968                                 0))
 969             (elmo-folder-set-info-hashtb folder in-db-max nil))
 970         (setq in-db-max cached-in-db-max))
 971       (setq unsync (if (and in-db (car in-folder))
 972                        (- (car in-folder) in-db-max)
 973                      (if (and in-folder (null in-db))
 974                          (cdr in-folder)
 975                        (car in-folder))))
 976       (setq messages (cdr in-folder))
 977       (if (and unsync messages (> unsync messages))
 978           (setq unsync messages))
 979       (cons (or unsync 0) (or messages 0)))))
 980
 981 (defvar elmo-folder-diff-async-callback nil)
 982 (defvar elmo-folder-diff-async-callback-data nil)
 983
 984 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 985   (and elmo-folder-diff-async-callback
 986        (funcall elmo-folder-diff-async-callback
 987                 folder
 988                 (elmo-folder-diff folder))))
 989
 990 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
 991   (list folder))
 992
 993 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
 994   (eq (elmo-folder-type-internal folder) type))
 995
 996 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
 997                                                  src-folder
 998                                                  numbers
 999                                                  &optional
1000                                                  same-number)
1001   (elmo-generic-folder-append-messages folder src-folder numbers
1002                                        same-number))
1003
1004 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1005                                                    same-number)
1006   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
1007         unseen table flags
1008         succeed-numbers failure cache id)
1009     (setq table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1010     (with-temp-buffer
1011       (set-buffer-multibyte nil)
1012       (while numbers
1013         (setq failure nil
1014               id (and src-msgdb-exists
1015                       (elmo-message-field src-folder (car numbers)
1016                                           'message-id))
1017               flags (elmo-message-flags src-folder (car numbers)))
1018         (condition-case nil
1019             (setq cache (elmo-file-cache-get id)
1020                   failure
1021                   (not
1022                    (and
1023                     (elmo-message-fetch
1024                      src-folder (car numbers)
1025                      (if (elmo-folder-plugged-p src-folder)
1026                          (elmo-make-fetch-strategy
1027                           'entire 'maybe nil
1028                           (and cache (elmo-file-cache-path cache)))
1029                        (or (and elmo-enable-disconnected-operation
1030                                 cache
1031                                 (eq (elmo-file-cache-status cache) 'entire)
1032                                 (elmo-make-fetch-strategy
1033                                  'entire t nil
1034                                  (elmo-file-cache-path cache)))
1035                            (error "Unplugged")))
1036                      nil (current-buffer)
1037                      'unread)
1038                     (> (buffer-size) 0)
1039                     (elmo-folder-append-buffer
1040                      folder
1041                      flags
1042                      (if same-number (car numbers))))))
1043           (error (setq failure t)))
1044         ;; FETCH & APPEND finished
1045         (unless failure
1046           (when id
1047             (elmo-flag-table-set table id flags))
1048           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1049         (elmo-progress-notify 'elmo-folder-move-messages)
1050         (setq numbers (cdr numbers)))
1051       (when (elmo-folder-persistent-p folder)
1052         (elmo-flag-table-save (elmo-folder-msgdb-path folder) table))
1053       succeed-numbers)))
1054
1055 ;; Arguments should be reduced.
1056 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1057                                              &optional
1058                                              no-delete
1059                                              same-number)
1060   (save-excursion
1061     (let* ((messages msgs)
1062            (elmo-inhibit-display-retrieval-progress t)
1063            (len (length msgs))
1064            succeeds i result)
1065       (if (eq dst-folder 'null)
1066           (setq succeeds messages)
1067         (unless (elmo-folder-writable-p dst-folder)
1068           (error "move: %d is not writable"
1069                  (elmo-folder-name-internal dst-folder)))
1070         (when messages
1071           ;; src is already opened.
1072           (elmo-folder-open-internal dst-folder)
1073           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1074                                                               src-folder
1075                                                               messages
1076                                                               same-number))
1077             (error "move: append message to %s failed"
1078                    (elmo-folder-name-internal dst-folder)))
1079           (elmo-folder-close dst-folder)))
1080       (if (and (not no-delete) succeeds)
1081           (progn
1082             (if (and (elmo-folder-delete-messages src-folder succeeds)
1083                      (elmo-folder-detach-messages src-folder succeeds))
1084                 (setq result t)
1085               (message "move: delete messages from %s failed."
1086                        (elmo-folder-name-internal src-folder))
1087               (setq result nil))
1088             result)
1089         (if no-delete
1090             (progn
1091               ;; (message "Copying messages...done")
1092               t)
1093           (if (eq len 0)
1094               (message "No message was moved.")
1095             (message "Moving messages failed.")
1096             nil ; failure
1097             ))))))
1098
1099 (defun elmo-folder-msgdb-path (folder)
1100   "Return the msgdb path for FOLDER."
1101   (or (elmo-folder-path-internal folder)
1102       (elmo-folder-set-path-internal
1103        folder
1104        (elmo-folder-expand-msgdb-path folder))))
1105
1106 (luna-define-generic elmo-message-cached-p (folder number)
1107   "Return non-nil if the message is cached.")
1108
1109 (luna-define-method elmo-message-cached-p ((folder elmo-folder) number)
1110   (elmo-message-flagged-p folder number 'cached))
1111
1112 (defun elmo-message-accessible-p (folder number)
1113   "Get accessibility of the message.
1114 Return non-nil when message is accessible."
1115   (or (elmo-folder-plugged-p folder)
1116       (elmo-folder-local-p folder)
1117       (elmo-message-cached-p folder number)))
1118
1119 (luna-define-generic elmo-message-set-cached (folder number cached)
1120   "Set cache status of the message in the msgdb.
1121 FOLDER is the ELMO folder structure.
1122 NUMBER is a number of the message.
1123 If CACHED is t, message is set as cached.")
1124
1125 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1126                                              number cached)
1127   (if cached
1128       (elmo-msgdb-set-flag (elmo-folder-msgdb folder) number 'cached)
1129     (elmo-msgdb-unset-flag (elmo-folder-msgdb folder) number 'cached)))
1130
1131 (defun elmo-message-copy-entity (entity)
1132   ;;
1133   (elmo-msgdb-copy-overview-entity entity))
1134
1135 (defun elmo-message-entity-set-number (entity number)
1136   (elmo-msgdb-overview-entity-set-number entity number))
1137
1138 (luna-define-generic elmo-message-entity (folder key)
1139   "Return the message-entity structure which matches to the KEY.
1140 KEY is a number or a string.
1141 A number is for message number in the FOLDER.
1142 A string is for message-id of the message.")
1143
1144 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1145   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1146
1147 (luna-define-generic elmo-message-entity-parent (folder entity)
1148   "Return the parent message-entity structure in the FOLDER.
1149 ENTITY is the message-entity to get the parent.")
1150
1151 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1152   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1153
1154 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1155 (def-edebug-spec elmo-folder-do-each-message-entity
1156   ((symbolp form &rest form) &rest form))
1157
1158 (defsubst elmo-folder-list-message-entities (folder)
1159   ;; List all message entities in the FOLDER.
1160   (mapcar
1161    (lambda (number) (elmo-message-entity folder number))
1162    (elmo-folder-list-messages folder nil t))) ; XXX killed-list is not used.
1163
1164 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1165   "Iterator for message entity in the folder.
1166 \(elmo-folder-do-each-message-entity \(entity folder\)
1167  ... do the process using entity...
1168 \)"
1169   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1170      ,@form))
1171
1172 (defmacro elmo-message-entity-number (entity)
1173   `(elmo-msgdb-overview-entity-get-number ,entity))
1174
1175 (defun elmo-message-entity-field (entity field &optional decode)
1176   "Get message entity field value.
1177 ENTITY is the message entity structure obtained by `elmo-message-entity'.
1178 FIELD is the symbol of the field name.
1179 if optional DECODE is non-nil, returned value is decoded."
1180   (elmo-msgdb-message-entity-field entity field decode))
1181
1182 (defun elmo-message-entity-set-field (entity field value)
1183   "Set message entity field value.
1184 ENTITY is the message entity structure.
1185 FIELD is the symbol of the field name.
1186 VALUE is the field value (raw)."
1187   (elmo-msgdb-message-entity-set-field entity field value))
1188
1189 (luna-define-generic elmo-folder-count-flags (folder)
1190   "Count flagged message number in the msgdb of the FOLDER.
1191 Return a list of numbers (`new' `unread' `answered')")
1192
1193 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1194   (let ((new 0)
1195         (unreads 0)
1196         (answered 0)
1197         flags)
1198     (dolist (number (elmo-folder-list-messages folder 'visible 'in-msgdb))
1199       (setq flags (elmo-message-flags folder number))
1200       (cond
1201        ((memq 'new flags)
1202         (incf new))
1203        ((memq 'unread flags)
1204         (incf unreads))
1205        ((memq 'answered flags)
1206         (incf answered))))
1207     (list new unreads answered)))
1208
1209 (luna-define-generic elmo-message-flags (folder number)
1210   "Return a list of flags.
1211 FOLDER is a ELMO folder structure.
1212 NUMBER is a number of the message.")
1213
1214 (luna-define-method elmo-message-flags ((folder elmo-folder) number)
1215   (elmo-msgdb-flags (elmo-folder-msgdb folder) number))
1216
1217 (defsubst elmo-message-flagged-p (folder number flag)
1218   "Return non-nil if the message is set FLAG.
1219 FOLDER is a ELMO folder structure.
1220 NUMBER is a message number to test."
1221   (let ((cur-flags (elmo-message-flags folder number)))
1222     (case flag
1223       (read
1224        (not (memq 'unread cur-flags)))
1225       (t
1226        (memq flag cur-flags)))))
1227
1228 (defun elmo-message-set-flag (folder number flag)
1229   "Set message flag.
1230 FOLDER is a ELMO folder structure.
1231 NUMBER is a message number to set flag.
1232
1233 FLAG is a symbol which is one of the following:
1234   `unread'    (set the message as unread)
1235   `answered'  (set the message as answered)
1236   `important' (set the message as important)
1237 'sugar' flag:
1238   `read'      (remove new and unread flags)")
1239
1240 (defun elmo-message-unset-flag (folder number flag)
1241   "Unset message flag.
1242 FOLDER is a ELMO folder structure.
1243 NUMBER is a message number to set flag.
1244
1245 FLAG is a symbol which is one of the following:
1246   `unread'    (remove unread and new flag)
1247   `answered'  (remove answered flag)
1248   `important' (remove important flag)
1249 'sugar' flag:
1250   `read'      (set unread flag)")
1251
1252 (luna-define-generic elmo-message-field (folder number field)
1253   "Get message field value in the msgdb.
1254 FOLDER is the ELMO folder structure.
1255 NUMBER is a number of the message.
1256 FIELD is a symbol of the field.")
1257
1258 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1259   (when (zerop (elmo-folder-length folder))
1260     (error "Cannot treat this folder correctly."))
1261   (elmo-msgdb-get-field (elmo-folder-msgdb folder) number field))
1262
1263 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1264   nil) ; default is not use cache.
1265
1266 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1267   folder) ; default is folder
1268
1269 (luna-define-method elmo-folder-unmark-important ((folder elmo-folder)
1270                                                   numbers
1271                                                   &optional ignore-flags)
1272   (when (elmo-folder-msgdb-internal folder)
1273     (dolist (number numbers)
1274       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1275                              number
1276                              'important))))
1277
1278 (luna-define-method elmo-folder-mark-as-important ((folder elmo-folder)
1279                                                    numbers
1280                                                    &optional ignore-flags)
1281   (when (elmo-folder-msgdb-internal folder)
1282     (dolist (number numbers)
1283       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1284                            number
1285                            'important))))
1286
1287 (luna-define-method elmo-folder-unmark-read ((folder elmo-folder)
1288                                              numbers
1289                                              &optional ignore-flags)
1290   (when (elmo-folder-msgdb-internal folder)
1291     (dolist (number numbers)
1292       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1293                              number
1294                              'read))))
1295
1296 (luna-define-method elmo-folder-mark-as-read ((folder elmo-folder)
1297                                               numbers
1298                                               &optional ignore-flag)
1299   (when (elmo-folder-msgdb-internal folder)
1300     (dolist (number numbers)
1301       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1302                            number
1303                            'read))))
1304
1305 (luna-define-method elmo-folder-unmark-answered ((folder elmo-folder) numbers)
1306   (when (elmo-folder-msgdb-internal folder)
1307     (dolist (number numbers)
1308       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1309                              number
1310                              'answered))))
1311
1312 (luna-define-method elmo-folder-mark-as-answered ((folder elmo-folder) numbers)
1313   (when (elmo-folder-msgdb-internal folder)
1314     (dolist (number numbers)
1315       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1316                            number
1317                            'answered))))
1318
1319 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1320   ;; Do nothing.
1321   )
1322
1323 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1324 ;;                                                             &optional
1325 ;;                                                             flag-table)
1326 ;;  "Append ENTITY to the folder.")
1327
1328 (defun elmo-msgdb-merge (folder msgdb-merge)
1329   "Return a list of messages which have duplicated message-id."
1330   (let (msgdb duplicates)
1331     (setq msgdb (or (elmo-folder-msgdb-internal folder)
1332                     (elmo-make-msgdb (elmo-folder-msgdb-path folder))))
1333     (setq duplicates (elmo-msgdb-append msgdb msgdb-merge))
1334     (elmo-folder-set-msgdb-internal folder msgdb)
1335     duplicates))
1336
1337 (defsubst elmo-folder-append-msgdb (folder append-msgdb)
1338   (if append-msgdb
1339       (let ((duplicates (elmo-msgdb-merge folder append-msgdb)))
1340         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1341                    'hide)
1342                ;; Let duplicates be a temporary killed message.
1343                (elmo-folder-kill-messages folder duplicates)
1344                ;; Should be mark as read.
1345                (elmo-folder-mark-as-read folder duplicates))
1346               ((eq (elmo-folder-process-duplicates-internal folder)
1347                    'read)
1348                ;; Mark as read duplicates.
1349                (elmo-folder-mark-as-read folder duplicates))
1350               (t
1351                ;; Do nothing.
1352                (setq duplicates nil)))
1353         (length duplicates))
1354     0))
1355
1356 (defun elmo-folder-confirm-appends (appends)
1357   (let ((len (length appends))
1358         in)
1359     (if (and elmo-folder-update-threshold
1360              (> len elmo-folder-update-threshold)
1361              elmo-folder-update-confirm)
1362         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1363             appends
1364           (setq in elmo-folder-update-threshold)
1365           (catch 'end
1366             (while t
1367               (setq in (read-from-minibuffer "Update number: "
1368                                              (int-to-string in))
1369                     in (string-to-int in))
1370               (if (< len in)
1371                   (throw 'end len))
1372               (if (y-or-n-p (format
1373                              "%d messages are killed (not appeared). OK? "
1374                              (max (- len in) 0)))
1375                   (throw 'end in))))
1376           (nthcdr (max (- len in) 0) appends))
1377       (if (and elmo-folder-update-threshold
1378                (> len elmo-folder-update-threshold)
1379                (not elmo-folder-update-confirm))
1380           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1381         appends))))
1382
1383 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1384                                         number strategy
1385                                         &optional
1386                                         section
1387                                         outbuf
1388                                         unread)
1389   (if outbuf
1390       (with-current-buffer outbuf
1391         (erase-buffer)
1392         (elmo-message-fetch-with-cache-process folder number
1393                                                strategy section unread))
1394     (with-temp-buffer
1395       (elmo-message-fetch-with-cache-process folder number
1396                                              strategy section unread)
1397       (buffer-string))))
1398
1399 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1400                                                            number strategy
1401                                                            &optional
1402                                                            section unread)
1403   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1404         (method-priorities
1405          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1406                 '(entity cache))
1407                ((elmo-fetch-strategy-use-cache strategy)
1408                 '(cache entity))
1409                (t
1410                 '(entity))))
1411         result err)
1412     (while (and method-priorities
1413                 (null result))
1414       (setq result
1415             (case (car method-priorities)
1416               (cache
1417                (elmo-file-cache-load cache-path section))
1418               (entity
1419                (when (and (condition-case error
1420                               (elmo-message-fetch-internal folder number
1421                                                            strategy
1422                                                            section
1423                                                            unread)
1424                             (error (setq err error) nil))
1425                           (> (buffer-size) 0))
1426                  (elmo-delete-cr-buffer)
1427                  (when (and (elmo-fetch-strategy-save-cache strategy)
1428                             cache-path)
1429                    (elmo-file-cache-save cache-path section))
1430                  t)))
1431             method-priorities (cdr method-priorities)))
1432     (or result
1433         (and err (signal (car err) (cdr err))))))
1434
1435 (defun elmo-folder-kill-messages-before (folder msg)
1436   (elmo-folder-set-killed-list-internal
1437    folder
1438    (list (cons 1 msg))))
1439
1440 (defun elmo-folder-kill-messages (folder numbers)
1441   "Kill(hide) messages in the FOLDER with NUMBERS."
1442   (elmo-folder-set-killed-list-internal
1443    folder
1444    (elmo-number-set-append-list (elmo-folder-killed-list-internal
1445                                  folder) numbers)))
1446
1447
1448 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1449                                        &optional keep-killed)
1450   (unless keep-killed
1451     (elmo-folder-set-killed-list-internal folder nil))
1452   (elmo-msgdb-clear (elmo-folder-msgdb folder)))
1453
1454 (luna-define-generic elmo-folder-synchronize (folder
1455                                               &optional
1456                                               disable-killed
1457                                               ignore-msgdb
1458                                               no-check)
1459   "Synchronize the folder data to the newest status.
1460 FOLDER is the ELMO folder structure.
1461
1462 If optional DISABLE-KILLED is non-nil, killed messages are also synchronized.
1463 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1464 flag status.
1465 If NO-CHECK is non-nil, rechecking folder is skipped.
1466 Return a list of a cross-posted message number.
1467 If update process is interrupted, return nil.")
1468
1469 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1470                                              &optional
1471                                              disable-killed
1472                                              ignore-msgdb
1473                                              no-check)
1474   (let ((killed-list (elmo-folder-killed-list-internal folder))
1475         (before-append t)
1476         old-msgdb diff diff-2 delete-list new-list new-msgdb mark
1477         flag-table crossed after-append)
1478     (setq old-msgdb (elmo-folder-msgdb folder))
1479     (setq flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1480     (when ignore-msgdb
1481       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1482       (elmo-folder-clear folder (not disable-killed)))
1483     (unless no-check (elmo-folder-check folder))
1484     (condition-case nil
1485         (progn
1486           (message "Checking folder diff...")
1487           (setq diff (elmo-list-diff (elmo-folder-list-messages
1488                                       folder
1489                                       (not disable-killed))
1490                                      (elmo-folder-list-messages
1491                                       folder
1492                                       (not disable-killed)
1493                                       'in-msgdb)))
1494           (message "Checking folder diff...done")
1495           (setq new-list (elmo-folder-confirm-appends (car diff)))
1496           ;; Set killed list as ((1 . MAX-OF-DISAPPEARED))
1497           (when (and (not (eq (length (car diff))
1498                               (length new-list)))
1499                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1500             (elmo-folder-kill-messages-before folder
1501                                               (nth (- (length (car diff-2)) 1)
1502                                                    (car diff-2))))
1503           (setq delete-list (cadr diff))
1504           (if (or (equal diff '(nil nil))
1505                   (equal diff '(nil))
1506                   (and (eq (length (car diff)) 0)
1507                        (eq (length (cadr diff)) 0)))
1508               (progn
1509                 (elmo-folder-update-number folder)
1510                 (elmo-folder-process-crosspost folder)
1511                 0 ; no updates.
1512                 )
1513             (when delete-list
1514               (elmo-folder-detach-messages folder delete-list))
1515             (when new-list
1516               (elmo-msgdb-out-of-date-messages (elmo-folder-msgdb folder))
1517               (setq new-msgdb (elmo-folder-msgdb-create
1518                                folder new-list flag-table))
1519               ;; Clear flag-table
1520               (if (elmo-folder-persistent-p folder)
1521                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1522                                         nil))
1523               (setq before-append nil)
1524               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1525               ;; process crosspost.
1526               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).
1527               (elmo-folder-process-crosspost folder)
1528               (elmo-folder-set-message-modified folder t)
1529               (elmo-folder-set-mark-modified-internal folder t))
1530             ;; return value.
1531             (or crossed 0)))
1532       (quit
1533        ;; Resume to the original status.
1534        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1535        (elmo-folder-set-killed-list-internal folder killed-list)
1536        nil))))
1537
1538 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1539   "Remove messages with NUMBERS from MSGDB.")
1540
1541 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1542                                                  numbers)
1543   (elmo-msgdb-delete-messages (elmo-folder-msgdb folder) numbers))
1544
1545 (luna-define-generic elmo-folder-length (folder)
1546   "Return number of messages in the FOLDER.")
1547
1548 (luna-define-method elmo-folder-length ((folder elmo-folder))
1549   (if (elmo-folder-msgdb-internal folder)
1550       (elmo-msgdb-length (elmo-folder-msgdb folder))
1551     0))
1552
1553 (defun elmo-folder-msgdb-load (folder &optional silent)
1554   (unless silent
1555     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1556   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1557     (elmo-folder-set-info-max-by-numdb
1558      folder
1559      (elmo-msgdb-list-messages msgdb))
1560     (unless silent
1561       (message "Loading msgdb for %s...done"
1562                (elmo-folder-name-internal folder)))
1563     msgdb))
1564
1565 (defun elmo-msgdb-delete-path (folder)
1566   (let ((path (elmo-folder-msgdb-path folder)))
1567     (if (file-directory-p path)
1568         (elmo-delete-directory path t))))
1569
1570 (defun elmo-msgdb-rename-path (old-folder new-folder)
1571   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1572          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1573          (new-dir (directory-file-name (file-name-directory new))))
1574     (if (not (file-directory-p old))
1575         ()
1576       (if (file-exists-p new)
1577           (error "Already exists directory: %s" new)
1578         (if (not (file-exists-p new-dir))
1579             (elmo-make-directory new-dir))
1580         (rename-file old new)))))
1581
1582 (defun elmo-setup-subscribed-newsgroups (groups)
1583   "Setup subscribed newsgroups.
1584 GROUPS is a list of newsgroup name string.
1585 Return a hashtable for newsgroups."
1586   (let ((hashtb (or elmo-newsgroups-hashtb
1587                     (setq elmo-newsgroups-hashtb
1588                           (elmo-make-hash (length groups))))))
1589     (dolist (group groups)
1590       (or (elmo-get-hash-val group hashtb)
1591           (elmo-set-hash-val group nil hashtb)))
1592     (setq elmo-newsgroups-hashtb hashtb)))
1593
1594 (defvar elmo-crosspost-message-alist-modified nil)
1595 (defun elmo-crosspost-message-alist-load ()
1596   "Load crosspost message alist."
1597   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1598   (setq elmo-crosspost-message-alist-modified nil))
1599
1600 (defun elmo-crosspost-message-alist-save ()
1601   "Save crosspost message alist."
1602   (when elmo-crosspost-message-alist-modified
1603     (let ((alist elmo-crosspost-message-alist)
1604           newsgroups)
1605       (while alist
1606         (setq newsgroups
1607               (elmo-delete-if
1608                '(lambda (x)
1609                   (not (intern-soft x elmo-newsgroups-hashtb)))
1610                (nth 1 (car alist))))
1611         (if newsgroups
1612             (setcar (cdar alist) newsgroups)
1613           (setq elmo-crosspost-message-alist
1614                 (delete (car alist) elmo-crosspost-message-alist)))
1615         (setq alist (cdr alist)))
1616       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1617       (setq elmo-crosspost-message-alist-modified nil))))
1618
1619 (defun elmo-folder-make-temporary-directory (folder)
1620   ;; Make a temporary directory for FOLDER.
1621   (let ((temp-dir (make-temp-name
1622                    (concat
1623                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1624                     "elmo"))))
1625     (elmo-make-directory temp-dir)
1626     temp-dir))
1627
1628 (defun elmo-init ()
1629   "Initialize ELMO module."
1630   (elmo-crosspost-message-alist-load)
1631   (elmo-resque-obsolete-variables)
1632   (elmo-dop-queue-load))
1633
1634 (defun elmo-quit ()
1635   "Quit and cleanup ELMO."
1636   (elmo-crosspost-message-alist-save)
1637   (elmo-dop-queue-save)
1638   ;; Not implemented yet.
1639   (let ((types elmo-folder-type-alist)
1640         class)
1641     (while types
1642       (setq class
1643             (luna-find-class
1644              (intern (format "elmo-%s-folder" (symbol-name (cdr (car types)))))))
1645       ;; Call all folder's `elmo-quit' method.
1646       (if class
1647           (dolist (func (luna-class-find-functions class 'elmo-quit))
1648             (funcall func nil)))
1649       (setq types (cdr types)))))
1650
1651 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1652                                                  new-folder)
1653   (error "Cannot rename %s folder"
1654          (symbol-name (elmo-folder-type-internal folder))))
1655
1656 ;;; Define folders.
1657 (elmo-define-folder ?% 'imap4)
1658 (elmo-define-folder ?-  'nntp)
1659 (elmo-define-folder ?\+ 'localdir)
1660 (elmo-define-folder ?\* 'multi)
1661 (elmo-define-folder ?\/ 'filter)
1662 (elmo-define-folder ?\$ 'archive)
1663 (elmo-define-folder ?&  'pop3)
1664 (elmo-define-folder ?=  'localnews)
1665 (elmo-define-folder ?|  'pipe)
1666 (elmo-define-folder ?.  'maildir)
1667 (elmo-define-folder ?'  'internal)
1668 (elmo-define-folder ?\[  'nmz)
1669 (elmo-define-folder ?@  'shimbun)
1670
1671 ;;; Obsolete variables.
1672 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1673                                'elmo-imap4-default-mailbox)
1674 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1675                                'elmo-imap4-default-server)
1676 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1677                                'elmo-imap4-default-authenticate-type)
1678 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1679                                'elmo-imap4-default-user)
1680 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1681                                'elmo-imap4-default-port)
1682 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1683                                'elmo-imap4-default-stream-type)
1684 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1685                                'elmo-nntp-default-server)
1686 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1687                                'elmo-nntp-default-user)
1688 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1689                                'elmo-nntp-default-port)
1690 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1691                                'elmo-nntp-default-stream-type)
1692 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1693                                'elmo-pop3-default-server)
1694 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1695                                'elmo-pop3-default-user)
1696 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1697                                'elmo-pop3-default-authenticate-type)
1698 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1699                                'elmo-pop3-default-port)
1700 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1701                                'elmo-pop3-default-stream-type)
1702 (elmo-define-obsolete-variable 'elmo-cache-dirname
1703                                'elmo-cache-directory)
1704 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1705                                'elmo-msgdb-directory)
1706
1707 ;; Obsolete functions.
1708 ;; 2001-12-11: *-dir -> *-directory
1709 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1710 (make-obsolete 'elmo-folder-make-temp-dir
1711                'elmo-folder-make-temporary-directory)
1712
1713
1714 ;; autoloads
1715 (autoload 'elmo-dop-queue-flush "elmo-dop")
1716 (autoload 'elmo-nntp-post "elmo-nntp")
1717
1718 (require 'product)
1719 (product-provide (provide 'elmo) (require 'elmo-version))
1720
1721 ;;; elmo.el ends here