elmo/elsp-bsfilter.el

   1 ;;; elsp-bsfilter.el --- Bsfilter support for elmo-spam.
   2
   3 ;; Copyright (C) 2004 Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   4 ;; Copyright (C) 2004 Yuuichi Teranishi <teranisi@gohome.org>
   5
   6 ;; Author: Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   7 ;; Keywords: mail, net news, spam
   8
   9 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29
  30 ;;; Code:
  31 ;;
  32 (require 'elmo-spam)
  33 (require 'luna)
  34
  35 (defgroup elmo-spam-bsfilter nil
  36   "Spam bsfilter configuration."
  37   :group 'elmo-spam)
  38
  39 (defcustom elmo-spam-bsfilter-shell-program "ruby"
  40   "*"
  41   :type 'string
  42   :group 'elmo-spam-bsfilter)
  43
  44 (defcustom elmo-spam-bsfilter-shell-switch nil
  45   "*"
  46   :type 'string
  47   :group 'elmo-spam-bsfilter)
  48
  49 (defcustom elmo-spam-bsfilter-program (exec-installed-p "bsfilter")
  50   "*Program name of the Bsfilter."
  51   :type '(string :tag "Program name of the bsfilter")
  52   :group 'elmo-spam-bsfilter)
  53
  54 (defcustom elmo-spam-bsfilter-args nil
  55   "*Argument list for bsfilter."
  56   :type '(repeat string)
  57   :group 'elmo-spam-bsfilter)
  58
  59 (defcustom elmo-spam-bsfilter-update-switch "--synchronous-auto-update"
  60   "*The switch that Bsfilter uses to update database with classify."
  61   :type 'string
  62   :group 'elmo-spam-bsfilter)
  63
  64 (defcustom elmo-spam-bsfilter-database-directory nil
  65   "*Directory path of the Bsfilter databases."
  66   :type '(choice (directory :tag "Location of the Bsfilter database directory")
  67                  (const :tag "Use the default"))
  68   :group 'elmo-spam-bsfilter)
  69
  70 (defcustom elmo-spam-bsfilter-max-files-per-process 100
  71   "Number of files processed at once."
  72   :type 'integer
  73   :group 'elmo-spam-bsfilter)
  74
  75 (defcustom elmo-spam-bsfilter-max-messages-per-process 30
  76   "Number of messages processed at once."
  77   :type 'integer
  78   :group 'elmo-spam-bsfilter)
  79
  80 (defcustom elmo-spam-bsfilter-debug nil
  81   "Non-nil to debug elmo bsfilter spam backend."
  82   :type 'boolean
  83   :group 'elmo-spam-bsfilter)
  84
  85 (eval-and-compile
  86   (luna-define-class elsp-bsfilter (elsp-generic)))
  87
  88 (defsubst elsp-bsfilter-call-bsfilter (&rest args)
  89   (apply #'call-process-region
  90          (point-min) (point-max)
  91          elmo-spam-bsfilter-shell-program
  92          nil (if elmo-spam-bsfilter-debug
  93                  (get-buffer-create "*Debug ELMO Bsfilter*"))
  94          nil
  95          (append (if elmo-spam-bsfilter-shell-switch
  96                      (list elmo-spam-bsfilter-shell-switch))
  97                  (list elmo-spam-bsfilter-program)
  98                  elmo-spam-bsfilter-args
  99                  (if elmo-spam-bsfilter-database-directory
 100                      (list "--homedir" elmo-spam-bsfilter-database-directory))
 101                  (elmo-flatten args))))
 102
 103 (luna-define-method elmo-spam-buffer-spam-p ((processor elsp-bsfilter)
 104                                              buffer &optional register)
 105   (with-current-buffer buffer
 106     (= 0 (elsp-bsfilter-call-bsfilter
 107           (if register elmo-spam-bsfilter-update-switch)))))
 108
 109 (defsubst elsp-bsfilter-list-spam-files (targets)
 110   (apply
 111    #'call-process
 112    elmo-spam-bsfilter-shell-program
 113    nil
 114    (list t (if elmo-spam-bsfilter-debug
 115                (get-buffer-create "*Debug ELMO Bsfilter*")))
 116    nil
 117    (append (if elmo-spam-bsfilter-shell-switch
 118                (list elmo-spam-bsfilter-shell-switch))
 119            (list elmo-spam-bsfilter-program "--list-spam")
 120            elmo-spam-bsfilter-args
 121            (if elmo-spam-bsfilter-database-directory
 122                (list "--homedir" elmo-spam-bsfilter-database-directory))
 123            targets)))
 124
 125 (luna-define-method elmo-spam-list-spam-messages :around
 126   ((processor elsp-bsfilter) folder &optional numbers)
 127   (if (not (elmo-folder-message-file-p folder))
 128       (luna-call-next-method)
 129     (let* ((nth-of-targets (1- (or elmo-spam-bsfilter-max-files-per-process
 130                                    100)))
 131            (numbers (or numbers (elmo-folder-list-messages folder t t)))
 132            (hash (elmo-make-hash (length numbers)))
 133            (targets (mapcar
 134                      (lambda (number)
 135                        (let ((filename (elmo-message-file-name folder number)))
 136                          (elmo-set-hash-val filename number hash)
 137                          filename))
 138                      numbers))
 139            results)
 140       (with-temp-buffer
 141         (while targets
 142           (let* ((last (nthcdr nth-of-targets targets))
 143                  (next (cdr last)))
 144             (when last
 145               (setcdr last nil))
 146             (elsp-bsfilter-list-spam-files targets)
 147             (elmo-progress-notify 'elmo-spam-check-spam (length targets))
 148             (setq targets next)))
 149         (goto-char (point-min))
 150         (while (not (eobp))
 151           (let* ((filename (buffer-substring (point) (save-excursion
 152                                                        (end-of-line)
 153                                                        (point))))
 154                  (number (elmo-get-hash-val filename hash)))
 155             (when number
 156               (setq results (cons number results)))
 157             (forward-line))))
 158       results)))
 159
 160
 161 (defsubst elsp-bsfilter-register-buffer (buffer spam restore &optional mbox)
 162   (with-current-buffer buffer
 163     (elsp-bsfilter-call-bsfilter
 164      "--update"
 165      (if restore (if spam "--sub-clean" "--sub-spam"))
 166      (if spam "--add-spam" "--add-clean")
 167      (if mbox "--mbox"))))
 168
 169 (luna-define-method elmo-spam-register-spam-buffer ((processor elsp-bsfilter)
 170                                                     buffer &optional restore)
 171   (elsp-bsfilter-register-buffer buffer t restore))
 172
 173 (luna-define-method elmo-spam-register-good-buffer ((processor elsp-bsfilter)
 174                                                     buffer &optional restore)
 175   (elsp-bsfilter-register-buffer buffer nil restore))
 176
 177 (defsubst elmo-spam-bsfilter-register-messages (folder numbers spam restore)
 178   (let ((numbers (or numbers (elmo-folder-list-messages folder t t))))
 179     (if (and (> (length numbers) 1)
 180              elmo-spam-bsfilter-max-messages-per-process
 181              (> elmo-spam-bsfilter-max-messages-per-process 0))
 182         (elmo-spam-process-messages-as-mbox
 183          folder numbers
 184          elmo-spam-bsfilter-max-messages-per-process
 185          (lambda (count spam restore)
 186            (elsp-bsfilter-register-buffer (current-buffer) spam restore 'mbox)
 187            (elmo-progress-notify 'elmo-spam-register count))
 188          spam restore)
 189       (luna-call-next-method))))
 190
 191 (luna-define-method elmo-spam-register-spam-messages :around
 192   ((processor elsp-bsfilter) folder &optional numbers restore)
 193   (elmo-spam-bsfilter-register-messages folder numbers t restore))
 194
 195 (luna-define-method elmo-spam-register-good-messages :around
 196   ((processor elsp-bsfilter) folder &optional numbers restore)
 197   (elmo-spam-bsfilter-register-messages folder numbers nil restore))
 198
 199 (require 'product)
 200 (product-provide (provide 'elsp-bsfilter) (require 'elmo-version))
 201
 202 ;;; elsp-bsfilter.el ends here